src/Pure/sign.ML
author wenzelm
Sat Jan 14 17:14:06 2006 +0100 (2006-01-14)
changeset 18678 dd0c569fa43d
parent 18667 85d04c28224a
child 18714 1c310b042d69
permissions -rw-r--r--
sane ERROR handling;
     1 (*  Title:      Pure/sign.ML
     2     ID:         $Id$
     3     Author:     Lawrence C Paulson and Markus Wenzel
     4 
     5 Logical signature content: naming conventions, concrete syntax, type
     6 signature, polymorphic constants.
     7 *)
     8 
     9 signature SIGN_THEORY =
    10 sig
    11   val add_defsort: string -> theory -> theory
    12   val add_defsort_i: sort -> theory -> theory
    13   val add_types: (bstring * int * mixfix) list -> theory -> theory
    14   val add_typedecls: (bstring * string list * mixfix) list -> theory -> theory
    15   val add_nonterminals: bstring list -> theory -> theory
    16   val add_tyabbrs: (bstring * string list * string * mixfix) list -> theory -> theory
    17   val add_tyabbrs_i: (bstring * string list * typ * mixfix) list -> theory -> theory
    18   val add_arities: (xstring * string list * string) list -> theory -> theory
    19   val add_arities_i: (string * sort list * sort) list -> theory -> theory
    20   val add_syntax: (bstring * string * mixfix) list -> theory -> theory
    21   val add_syntax_i: (bstring * typ * mixfix) list -> theory -> theory
    22   val add_modesyntax: (string * bool) -> (bstring * string * mixfix) list -> theory -> theory
    23   val add_modesyntax_i: (string * bool) -> (bstring * typ * mixfix) list -> theory -> theory
    24   val del_modesyntax: (string * bool) -> (bstring * string * mixfix) list -> theory -> theory
    25   val del_modesyntax_i: (string * bool) -> (bstring * typ * mixfix) list -> theory -> theory
    26   val add_consts: (bstring * string * mixfix) list -> theory -> theory
    27   val add_consts_i: (bstring * typ * mixfix) list -> theory -> theory
    28   val add_const_constraint: xstring * string -> theory -> theory
    29   val add_const_constraint_i: string * typ -> theory -> theory
    30   val add_classes: (bstring * xstring list) list -> theory -> theory
    31   val add_classes_i: (bstring * class list) list -> theory -> theory
    32   val add_classrel: (xstring * xstring) list -> theory -> theory
    33   val add_classrel_i: (class * class) list -> theory -> theory
    34   val add_trfuns:
    35     (string * (ast list -> ast)) list *
    36     (string * (term list -> term)) list *
    37     (string * (term list -> term)) list *
    38     (string * (ast list -> ast)) list -> theory -> theory
    39   val add_trfunsT:
    40     (string * (bool -> typ -> term list -> term)) list -> theory -> theory
    41   val add_advanced_trfuns:
    42     (string * (theory -> ast list -> ast)) list *
    43     (string * (theory -> term list -> term)) list *
    44     (string * (theory -> term list -> term)) list *
    45     (string * (theory -> ast list -> ast)) list -> theory -> theory
    46   val add_advanced_trfunsT:
    47     (string * (theory -> bool -> typ -> term list -> term)) list -> theory -> theory
    48   val add_tokentrfuns:
    49     (string * string * (string -> string * real)) list -> theory -> theory
    50   val add_mode_tokentrfuns: string -> (string * (string -> string * real)) list
    51     -> theory -> theory
    52   val parse_ast_translation: bool * string -> theory -> theory
    53   val parse_translation: bool * string -> theory -> theory
    54   val print_translation: bool * string -> theory -> theory
    55   val typed_print_translation: bool * string -> theory -> theory
    56   val print_ast_translation: bool * string -> theory -> theory
    57   val token_translation: string -> theory -> theory
    58   val add_trrules: (xstring * string) Syntax.trrule list -> theory -> theory
    59   val add_trrules_i: ast Syntax.trrule list -> theory -> theory
    60   val add_path: string -> theory -> theory
    61   val parent_path: theory -> theory
    62   val root_path: theory -> theory
    63   val absolute_path: theory -> theory
    64   val local_path: theory -> theory
    65   val qualified_names: theory -> theory
    66   val no_base_names: theory -> theory
    67   val custom_accesses: (string list -> string list list) -> theory -> theory
    68   val set_policy: (string -> bstring -> string) * (string list -> string list list) ->
    69     theory -> theory
    70   val restore_naming: theory -> theory -> theory
    71   val hide_classes: bool -> xstring list -> theory -> theory
    72   val hide_classes_i: bool -> string list -> theory -> theory
    73   val hide_types: bool -> xstring list -> theory -> theory
    74   val hide_types_i: bool -> string list -> theory -> theory
    75   val hide_consts: bool -> xstring list -> theory -> theory
    76   val hide_consts_i: bool -> string list -> theory -> theory
    77   val hide_names: bool -> string * xstring list -> theory -> theory
    78   val hide_names_i: bool -> string * string list -> theory -> theory
    79 end
    80 
    81 signature SIGN =
    82 sig
    83   type sg    (*obsolete*)
    84   val init_data: theory -> theory
    85   val rep_sg: theory ->
    86    {naming: NameSpace.naming,
    87     syn: Syntax.syntax,
    88     tsig: Type.tsig,
    89     consts: Consts.T}
    90   val naming_of: theory -> NameSpace.naming
    91   val base_name: string -> bstring
    92   val full_name: theory -> bstring -> string
    93   val full_name_path: theory -> string -> bstring -> string
    94   val declare_name: theory -> string -> NameSpace.T -> NameSpace.T
    95   val syn_of: theory -> Syntax.syntax
    96   val tsig_of: theory -> Type.tsig
    97   val classes_of: theory -> Sorts.classes
    98   val classes_arities_of: theory -> Sorts.classes * Sorts.arities
    99   val classes: theory -> class list
   100   val defaultS: theory -> sort
   101   val subsort: theory -> sort * sort -> bool
   102   val of_sort: theory -> typ * sort -> bool
   103   val witness_sorts: theory -> sort list -> sort list -> (typ * sort) list
   104   val universal_witness: theory -> (typ * sort) option
   105   val all_sorts_nonempty: theory -> bool
   106   val typ_instance: theory -> typ * typ -> bool
   107   val typ_match: theory -> typ * typ -> Type.tyenv -> Type.tyenv
   108   val typ_unify: theory -> typ * typ -> Type.tyenv * int -> Type.tyenv * int
   109   val is_logtype: theory -> string -> bool
   110   val const_constraint: theory -> string -> typ option
   111   val the_const_constraint: theory -> string -> typ
   112   val const_type: theory -> string -> typ option
   113   val the_const_type: theory -> string -> typ
   114   val declared_tyname: theory -> string -> bool
   115   val declared_const: theory -> string -> bool
   116   val const_monomorphic: theory -> string -> bool
   117   val const_typargs: theory -> string * typ -> typ list
   118   val const_instance: theory -> string * typ list -> typ
   119   val class_space: theory -> NameSpace.T
   120   val type_space: theory -> NameSpace.T
   121   val const_space: theory -> NameSpace.T
   122   val intern_class: theory -> xstring -> string
   123   val extern_class: theory -> string -> xstring
   124   val intern_type: theory -> xstring -> string
   125   val extern_type: theory -> string -> xstring
   126   val intern_const: theory -> xstring -> string
   127   val extern_const: theory -> string -> xstring
   128   val intern_sort: theory -> sort -> sort
   129   val extern_sort: theory -> sort -> sort
   130   val intern_typ: theory -> typ -> typ
   131   val extern_typ: theory -> typ -> typ
   132   val intern_term: theory -> term -> term
   133   val extern_term: theory -> term -> term
   134   val intern_tycons: theory -> typ -> typ
   135   val pretty_term': Syntax.syntax -> theory -> term -> Pretty.T
   136   val pretty_term: theory -> term -> Pretty.T
   137   val pretty_typ: theory -> typ -> Pretty.T
   138   val pretty_sort: theory -> sort -> Pretty.T
   139   val pretty_classrel: theory -> class list -> Pretty.T
   140   val pretty_arity: theory -> arity -> Pretty.T
   141   val string_of_term: theory -> term -> string
   142   val string_of_typ: theory -> typ -> string
   143   val string_of_sort: theory -> sort -> string
   144   val string_of_classrel: theory -> class list -> string
   145   val string_of_arity: theory -> arity -> string
   146   val pprint_term: theory -> term -> pprint_args -> unit
   147   val pprint_typ: theory -> typ -> pprint_args -> unit
   148   val pp: theory -> Pretty.pp
   149   val certify_class: theory -> class -> class
   150   val certify_sort: theory -> sort -> sort
   151   val certify_typ: theory -> typ -> typ
   152   val certify_typ_syntax: theory -> typ -> typ
   153   val certify_typ_abbrev: theory -> typ -> typ
   154   val certify_term: Pretty.pp -> theory -> term -> term * typ * int
   155   val certify_prop: Pretty.pp -> theory -> term -> term * typ * int
   156   val cert_term: theory -> term -> term
   157   val cert_prop: theory -> term -> term
   158   val read_sort': Syntax.syntax -> theory -> string -> sort
   159   val read_sort: theory -> string -> sort
   160   val read_typ': Syntax.syntax -> theory * (indexname -> sort option) -> string -> typ
   161   val read_typ_syntax': Syntax.syntax -> theory * (indexname -> sort option) -> string -> typ
   162   val read_typ_abbrev': Syntax.syntax -> theory * (indexname -> sort option) -> string -> typ
   163   val read_typ: theory * (indexname -> sort option) -> string -> typ
   164   val read_typ_syntax: theory * (indexname -> sort option) -> string -> typ
   165   val read_typ_abbrev: theory * (indexname -> sort option) -> string -> typ
   166   val read_tyname: theory -> string -> typ
   167   val read_const: theory -> string -> term
   168   val infer_types_simult: Pretty.pp -> theory -> (indexname -> typ option) ->
   169     (indexname -> sort option) -> string list -> bool
   170     -> (term list * typ) list -> term list * (indexname * typ) list
   171   val infer_types: Pretty.pp -> theory -> (indexname -> typ option) ->
   172     (indexname -> sort option) -> string list -> bool
   173     -> term list * typ -> term * (indexname * typ) list
   174   val read_def_terms': Pretty.pp -> (string -> bool) -> Syntax.syntax ->
   175     theory * (indexname -> typ option) * (indexname -> sort option) ->
   176     string list -> bool -> (string * typ) list -> term list * (indexname * typ) list
   177   val read_def_terms:
   178     theory * (indexname -> typ option) * (indexname -> sort option) ->
   179     string list -> bool -> (string * typ) list -> term list * (indexname * typ) list
   180   val simple_read_term: theory -> typ -> string -> term
   181   val read_term: theory -> string -> term
   182   val read_prop: theory -> string -> term
   183   val const_of_class: class -> string
   184   val class_of_const: string -> class
   185   include SIGN_THEORY
   186 end
   187 
   188 structure Sign: SIGN =
   189 struct
   190 
   191 type sg = theory;
   192 
   193 
   194 (** datatype sign **)
   195 
   196 datatype sign = Sign of
   197  {naming: NameSpace.naming,     (*common naming conventions*)
   198   syn: Syntax.syntax,           (*concrete syntax for terms, types, sorts*)
   199   tsig: Type.tsig,              (*order-sorted signature of types*)
   200   consts: Consts.T};            (*polymorphic constants*)
   201 
   202 fun make_sign (naming, syn, tsig, consts) =
   203   Sign {naming = naming, syn = syn, tsig = tsig, consts = consts};
   204 
   205 structure SignData = TheoryDataFun
   206 (struct
   207   val name = "Pure/sign";
   208   type T = sign;
   209   val copy = I;
   210   fun extend (Sign {syn, tsig, consts, ...}) =
   211     make_sign (NameSpace.default_naming, syn, tsig, consts);
   212 
   213   val empty =
   214     make_sign (NameSpace.default_naming, Syntax.pure_syn, Type.empty_tsig, Consts.empty);
   215 
   216   fun merge pp (sign1, sign2) =
   217     let
   218       val Sign {naming = _, syn = syn1, tsig = tsig1, consts = consts1} = sign1;
   219       val Sign {naming = _, syn = syn2, tsig = tsig2, consts = consts2} = sign2;
   220 
   221       val naming = NameSpace.default_naming;
   222       val syn = Syntax.merge_syntaxes syn1 syn2;
   223       val tsig = Type.merge_tsigs pp (tsig1, tsig2);
   224       val consts = Consts.merge (consts1, consts2);
   225     in make_sign (naming, syn, tsig, consts) end;
   226 
   227   fun print _ _ = ();
   228 end);
   229 
   230 val init_data = SignData.init;
   231 
   232 fun rep_sg thy = SignData.get thy |> (fn Sign args => args);
   233 
   234 fun map_sign f = SignData.map (fn Sign {naming, syn, tsig, consts} =>
   235   make_sign (f (naming, syn, tsig, consts)));
   236 
   237 fun map_naming f = map_sign (fn (naming, syn, tsig, consts) => (f naming, syn, tsig, consts));
   238 fun map_syn f = map_sign (fn (naming, syn, tsig, consts) => (naming, f syn, tsig, consts));
   239 fun map_tsig f = map_sign (fn (naming, syn, tsig, consts) => (naming, syn, f tsig, consts));
   240 fun map_consts f = map_sign (fn (naming, syn, tsig, consts) => (naming, syn, tsig, f consts));
   241 
   242 
   243 (* naming *)
   244 
   245 val naming_of = #naming o rep_sg;
   246 val base_name = NameSpace.base;
   247 val full_name = NameSpace.full o naming_of;
   248 fun full_name_path thy elems = NameSpace.full (NameSpace.add_path elems (naming_of thy));
   249 val declare_name = NameSpace.declare o naming_of;
   250 
   251 
   252 (* syntax *)
   253 
   254 val syn_of = #syn o rep_sg;
   255 
   256 
   257 (* type signature *)
   258 
   259 val tsig_of = #tsig o rep_sg;
   260 val classes_of = snd o #classes o Type.rep_tsig o tsig_of;
   261 fun classes_arities_of thy = (classes_of thy, #arities (Type.rep_tsig (tsig_of thy)));
   262 val classes = Type.classes o tsig_of;
   263 val defaultS = Type.defaultS o tsig_of;
   264 val subsort = Type.subsort o tsig_of;
   265 val of_sort = Type.of_sort o tsig_of;
   266 val witness_sorts = Type.witness_sorts o tsig_of;
   267 val universal_witness = Type.universal_witness o tsig_of;
   268 val all_sorts_nonempty = is_some o universal_witness;
   269 val typ_instance = Type.typ_instance o tsig_of;
   270 val typ_match = Type.typ_match o tsig_of;
   271 val typ_unify = Type.unify o tsig_of;
   272 fun is_logtype thy c = c mem_string Type.logical_types (tsig_of thy);
   273 
   274 
   275 (* polymorphic constants *)
   276 
   277 val consts_of = #consts o rep_sg;
   278 val the_const_constraint = Consts.constraint o consts_of;
   279 val const_constraint = try o the_const_constraint;
   280 val the_const_type = Consts.declaration o consts_of;
   281 val const_type = try o the_const_type;
   282 val const_monomorphic = Consts.monomorphic o consts_of;
   283 val const_typargs = Consts.typargs o consts_of;
   284 val const_instance = Consts.instance o consts_of;
   285 
   286 val declared_tyname = Symtab.defined o #2 o #types o Type.rep_tsig o tsig_of;
   287 val declared_const = is_some oo const_type;
   288 
   289 
   290 
   291 (** intern / extern names **)
   292 
   293 val class_space = #1 o #classes o Type.rep_tsig o tsig_of;
   294 val type_space = #1 o #types o Type.rep_tsig o tsig_of;
   295 val const_space = Consts.space o consts_of;
   296 
   297 val intern_class = NameSpace.intern o class_space;
   298 val extern_class = NameSpace.extern o class_space;
   299 val intern_type = NameSpace.intern o type_space;
   300 val extern_type = NameSpace.extern o type_space;
   301 val intern_const = NameSpace.intern o const_space;
   302 val extern_const = NameSpace.extern o const_space;
   303 
   304 val intern_sort = map o intern_class;
   305 val extern_sort = map o extern_class;
   306 
   307 local
   308 
   309 fun mapping add_names f t =
   310   let
   311     fun f' x = let val y = f x in if x = y then NONE else SOME (x, y) end;
   312     val tab = List.mapPartial f' (add_names (t, []));
   313     fun get x = if_none (AList.lookup (op =) tab x) x;
   314   in get end;
   315 
   316 fun typ_mapping f g thy T =
   317   T |> Term.map_typ
   318     (mapping add_typ_classes (f thy) T)
   319     (mapping add_typ_tycons (g thy) T);
   320 
   321 fun term_mapping f g h thy t =
   322   t |> Term.map_term
   323     (mapping add_term_classes (f thy) t)
   324     (mapping add_term_tycons (g thy) t)
   325     (mapping add_term_consts (h thy) t);
   326 
   327 in
   328 
   329 val intern_typ = typ_mapping intern_class intern_type;
   330 val extern_typ = typ_mapping extern_class extern_type;
   331 val intern_term = term_mapping intern_class intern_type intern_const;
   332 val extern_term = term_mapping extern_class extern_type extern_const;
   333 val intern_tycons = typ_mapping (K I) intern_type;
   334 
   335 end;
   336 
   337 
   338 
   339 (** pretty printing of terms, types etc. **)
   340 
   341 fun pretty_term' syn thy t =
   342   Syntax.pretty_term thy syn (Context.exists_name Context.CPureN thy) (extern_term thy t);
   343 fun pretty_term thy t = pretty_term' (syn_of thy) thy t;
   344 fun pretty_typ thy T = Syntax.pretty_typ thy (syn_of thy) (extern_typ thy T);
   345 fun pretty_sort thy S = Syntax.pretty_sort thy (syn_of thy) (extern_sort thy S);
   346 
   347 fun pretty_classrel thy cs = Pretty.block (List.concat
   348   (separate [Pretty.str " <", Pretty.brk 1] (map (single o pretty_sort thy o single) cs)));
   349 
   350 fun pretty_arity thy (a, Ss, S) =
   351   let
   352     val a' = extern_type thy a;
   353     val dom =
   354       if null Ss then []
   355       else [Pretty.list "(" ")" (map (pretty_sort thy) Ss), Pretty.brk 1];
   356   in Pretty.block ([Pretty.str (a' ^ " ::"), Pretty.brk 1] @ dom @ [pretty_sort thy S]) end;
   357 
   358 val string_of_term = Pretty.string_of oo pretty_term;
   359 val string_of_typ = Pretty.string_of oo pretty_typ;
   360 val string_of_sort = Pretty.string_of oo pretty_sort;
   361 val string_of_classrel = Pretty.string_of oo pretty_classrel;
   362 val string_of_arity = Pretty.string_of oo pretty_arity;
   363 
   364 val pprint_term = (Pretty.pprint o Pretty.quote) oo pretty_term;
   365 val pprint_typ = (Pretty.pprint o Pretty.quote) oo pretty_typ;
   366 
   367 fun pp thy = Pretty.pp (pretty_term thy, pretty_typ thy, pretty_sort thy,
   368   pretty_classrel thy, pretty_arity thy);
   369 
   370 
   371 
   372 (** certify entities **)    (*exception TYPE*)
   373 
   374 (* certify wrt. type signature *)
   375 
   376 fun certify cert = cert o tsig_of o Context.check_thy;
   377 
   378 val certify_class      = certify Type.cert_class;
   379 val certify_sort       = certify Type.cert_sort;
   380 val certify_typ        = certify Type.cert_typ;
   381 val certify_typ_syntax = certify Type.cert_typ_syntax;
   382 val certify_typ_abbrev = certify Type.cert_typ_abbrev;
   383 
   384 
   385 (* certify_term *)
   386 
   387 local
   388 
   389 (*determine and check the type of a term*)
   390 fun type_check pp tm =
   391   let
   392     fun err_appl why bs t T u U =
   393       let
   394         val xs = map Free bs;           (*we do not rename here*)
   395         val t' = subst_bounds (xs, t);
   396         val u' = subst_bounds (xs, u);
   397         val msg = cat_lines
   398           (TypeInfer.appl_error (Syntax.pp_show_brackets pp) why t' T u' U);
   399       in raise TYPE (msg, [T, U], [t', u']) end;
   400 
   401     fun typ_of (_, Const (_, T)) = T
   402       | typ_of (_, Free  (_, T)) = T
   403       | typ_of (_, Var (_, T)) = T
   404       | typ_of (bs, Bound i) = snd (List.nth (bs, i) handle Subscript =>
   405           raise TYPE ("Loose bound variable: B." ^ string_of_int i, [], [Bound i]))
   406       | typ_of (bs, Abs (x, T, body)) = T --> typ_of ((x, T) :: bs, body)
   407       | typ_of (bs, t $ u) =
   408           let val T = typ_of (bs, t) and U = typ_of (bs, u) in
   409             (case T of
   410               Type ("fun", [T1, T2]) =>
   411                 if T1 = U then T2 else err_appl "Incompatible operand type" bs t T u U
   412             | _ => err_appl "Operator not of function type" bs t T u U)
   413           end;
   414 
   415   in typ_of ([], tm) end;
   416 
   417 in
   418 
   419 fun certify_term pp thy tm =
   420   let
   421     val _ = Context.check_thy thy;
   422 
   423     val tm' = map_term_types (certify_typ thy) tm;
   424     val tm' = if tm = tm' then tm else tm';  (*avoid copying of already normal term*)
   425 
   426     fun err msg = raise TYPE (msg, [], [tm']);
   427 
   428     fun show_const a T = quote a ^ " :: " ^ Pretty.string_of_typ pp T;
   429 
   430     fun check_atoms (t $ u) = (check_atoms t; check_atoms u)
   431       | check_atoms (Abs (_, _, t)) = check_atoms t
   432       | check_atoms (Const (a, T)) =
   433           (case const_type thy a of
   434             NONE => err ("Undeclared constant " ^ show_const a T)
   435           | SOME U =>
   436               if typ_instance thy (T, U) then ()
   437               else err ("Illegal type for constant " ^ show_const a T))
   438       | check_atoms (Var ((x, i), _)) =
   439           if i < 0 then err ("Malformed variable: " ^ quote x) else ()
   440       | check_atoms _ = ();
   441   in
   442     check_atoms tm';
   443     (tm', type_check pp tm', maxidx_of_term tm')
   444   end;
   445 
   446 end;
   447 
   448 fun certify_prop pp thy tm =
   449   let val res as (tm', T, _) = certify_term pp thy tm
   450   in if T <> propT then raise TYPE ("Term not of type prop", [T], [tm']) else res end;
   451 
   452 fun cert_term thy tm = #1 (certify_term (pp thy) thy tm);
   453 fun cert_prop thy tm = #1 (certify_prop (pp thy) thy tm);
   454 
   455 
   456 
   457 (** read and certify entities **)    (*exception ERROR*)
   458 
   459 (* sorts *)
   460 
   461 fun read_sort' syn thy str =
   462   let
   463     val _ = Context.check_thy thy;
   464     val S = intern_sort thy (Syntax.read_sort thy syn str);
   465   in certify_sort thy S handle TYPE (msg, _, _) => error msg end;
   466 
   467 fun read_sort thy str = read_sort' (syn_of thy) thy str;
   468 
   469 
   470 (* types *)
   471 
   472 local
   473 
   474 fun gen_read_typ' cert syn (thy, def_sort) str =
   475   let
   476     val _ = Context.check_thy thy;
   477     val get_sort = TypeInfer.get_sort (tsig_of thy) def_sort (intern_sort thy);
   478     val T = intern_tycons thy (Syntax.read_typ thy syn get_sort (intern_sort thy) str);
   479   in cert thy T handle TYPE (msg, _, _) => error msg end
   480   handle ERROR msg => cat_error msg ("The error(s) above occurred in type " ^ quote str);
   481 
   482 fun gen_read_typ cert (thy, def_sort) str =
   483   gen_read_typ' cert (syn_of thy) (thy, def_sort) str;
   484 
   485 in
   486 
   487 fun no_def_sort thy = (thy: theory, K NONE);
   488 
   489 val read_typ'        = gen_read_typ' certify_typ;
   490 val read_typ_syntax' = gen_read_typ' certify_typ_syntax;
   491 val read_typ_abbrev' = gen_read_typ' certify_typ_abbrev;
   492 val read_typ         = gen_read_typ certify_typ;
   493 val read_typ_syntax  = gen_read_typ certify_typ_syntax;
   494 val read_typ_abbrev  = gen_read_typ certify_typ_abbrev;
   495 
   496 end;
   497 
   498 
   499 (* type and constant names *)
   500 
   501 fun read_tyname thy raw_c =
   502   let val c = intern_type thy raw_c in
   503     (case Symtab.lookup (#2 (#types (Type.rep_tsig (tsig_of thy)))) c of
   504       SOME (Type.LogicalType n, _) => Type (c, replicate n dummyT)
   505     | _ => error ("Undeclared type constructor: " ^ quote c))
   506   end;
   507 
   508 fun read_const thy raw_c =
   509   let
   510     val c = intern_const thy raw_c;
   511     val _ = the_const_type thy c handle TYPE (msg, _, _) => error msg;
   512   in Const (c, dummyT) end;
   513 
   514 
   515 
   516 (** infer_types **)         (*exception ERROR*)
   517 
   518 (*
   519   def_type: partial map from indexnames to types (constrains Frees and Vars)
   520   def_sort: partial map from indexnames to sorts (constrains TFrees and TVars)
   521   used: list of already used type variables
   522   freeze: if true then generated parameters are turned into TFrees, else TVars
   523 
   524   termss: lists of alternative parses (only one combination should be type-correct)
   525   typs: expected types
   526 *)
   527 
   528 fun infer_types_simult pp thy def_type def_sort used freeze args =
   529   let
   530     val termss = fold_rev (multiply o fst) args [[]];
   531     val typs =
   532       map (fn (_, T) => certify_typ thy T handle TYPE (msg, _, _) => error msg) args;
   533 
   534     fun infer ts = Result (TypeInfer.infer_types (Syntax.pp_show_brackets pp) (tsig_of thy)
   535         (const_constraint thy) def_type def_sort (intern_const thy) (intern_tycons thy)
   536         (intern_sort thy) used freeze typs ts)
   537       handle TYPE (msg, _, _) => Exn (ERROR msg);
   538 
   539     val err_results = map infer termss;
   540     val errs = List.mapPartial (fn Exn (ERROR msg) => SOME msg | _ => NONE) err_results;
   541     val results = List.mapPartial get_result err_results;
   542 
   543     val ambiguity = length termss;
   544     fun ambig_msg () =
   545       if ambiguity > 1 andalso ambiguity <= ! Syntax.ambiguity_level then
   546         "Got more than one parse tree.\n\
   547         \Retry with smaller Syntax.ambiguity_level for more information."
   548       else "";
   549   in
   550     if null results then (cat_error (ambig_msg ()) (cat_lines errs))
   551     else if length results = 1 then
   552       (if ambiguity > ! Syntax.ambiguity_level then
   553         warning "Fortunately, only one parse tree is type correct.\n\
   554           \You may still want to disambiguate your grammar or your input."
   555       else (); hd results)
   556     else (cat_error (ambig_msg ()) ("More than one term is type correct:\n" ^
   557       cat_lines (map (Pretty.string_of_term pp) (List.concat (map fst results)))))
   558   end;
   559 
   560 fun infer_types pp thy def_type def_sort used freeze tsT =
   561   apfst hd (infer_types_simult pp thy def_type def_sort used freeze [tsT]);
   562 
   563 
   564 (* read_def_terms -- read terms and infer types *)    (*exception ERROR*)
   565 
   566 fun read_def_terms' pp is_logtype syn (thy, types, sorts) used freeze sTs =
   567   let
   568     fun read (s, T) =
   569       let val T' = certify_typ thy T handle TYPE (msg, _, _) => error msg
   570       in (Syntax.read thy is_logtype syn T' s, T') end;
   571   in infer_types_simult pp thy types sorts used freeze (map read sTs) end;
   572 
   573 fun read_def_terms (thy, types, sorts) =
   574   read_def_terms' (pp thy) (is_logtype thy) (syn_of thy) (thy, types, sorts);
   575 
   576 fun simple_read_term thy T s =
   577   let val ([t], _) = read_def_terms (thy, K NONE, K NONE) [] true [(s, T)]
   578   in t end
   579   handle ERROR msg => cat_error msg ("The error(s) above occurred for term " ^ s);
   580 
   581 fun read_term thy = simple_read_term thy TypeInfer.logicT;
   582 fun read_prop thy = simple_read_term thy propT;
   583 
   584 
   585 
   586 (** signature extension functions **)  (*exception ERROR/TYPE*)
   587 
   588 (* add default sort *)
   589 
   590 fun gen_add_defsort prep_sort s thy =
   591   thy |> map_tsig (Type.set_defsort (prep_sort thy s));
   592 
   593 val add_defsort = gen_add_defsort read_sort;
   594 val add_defsort_i = gen_add_defsort certify_sort;
   595 
   596 
   597 (* add type constructors *)
   598 
   599 fun add_types types thy = thy |> map_sign (fn (naming, syn, tsig, consts) =>
   600   let
   601     val syn' = Syntax.extend_type_gram types syn;
   602     val decls = map (fn (a, n, mx) => (Syntax.type_name a mx, n)) types;
   603     val tsig' = Type.add_types naming decls tsig;
   604   in (naming, syn', tsig', consts) end);
   605 
   606 fun add_typedecls decls thy =
   607   let
   608     fun type_of (a, vs, mx) =
   609       if null (duplicates vs) then (a, length vs, mx)
   610       else error ("Duplicate parameters in type declaration: " ^ quote a);
   611   in add_types (map type_of decls) thy end;
   612 
   613 
   614 (* add nonterminals *)
   615 
   616 fun add_nonterminals ns thy = thy |> map_sign (fn (naming, syn, tsig, consts) =>
   617   let
   618     val syn' = Syntax.extend_consts ns syn;
   619     val tsig' = Type.add_nonterminals naming ns tsig;
   620   in (naming, syn', tsig', consts) end);
   621 
   622 
   623 (* add type abbreviations *)
   624 
   625 fun gen_add_tyabbr prep_typ (a, vs, rhs, mx) thy =
   626   thy |> map_sign (fn (naming, syn, tsig, consts) =>
   627     let
   628       val syn' = Syntax.extend_type_gram [(a, length vs, mx)] syn;
   629       val a' = Syntax.type_name a mx;
   630       val abbr = (a', vs, prep_typ thy rhs)
   631         handle ERROR msg => cat_error msg ("in type abbreviation " ^ quote a');
   632       val tsig' = Type.add_abbrevs naming [abbr] tsig;
   633     in (naming, syn', tsig', consts) end);
   634 
   635 val add_tyabbrs = fold (gen_add_tyabbr (read_typ_syntax o no_def_sort));
   636 val add_tyabbrs_i = fold (gen_add_tyabbr certify_typ_syntax);
   637 
   638 
   639 (* add type arities *)
   640 
   641 fun gen_add_arities int_type prep_sort arities thy = thy |> map_tsig (fn tsig =>
   642   let
   643     fun prep_arity (a, Ss, S) = (int_type thy a, map (prep_sort thy) Ss, prep_sort thy S)
   644       handle ERROR msg => cat_error msg ("in arity for type " ^ quote a);
   645     val tsig' = Type.add_arities (pp thy) (map prep_arity arities) tsig;
   646   in tsig' end);
   647 
   648 val add_arities = gen_add_arities intern_type read_sort;
   649 val add_arities_i = gen_add_arities (K I) certify_sort;
   650 
   651 
   652 (* modify syntax *)
   653 
   654 fun gen_syntax change_gram prep_typ prmode args thy =
   655   let
   656     fun prep (c, T, mx) = (c, prep_typ thy T, mx) handle ERROR msg =>
   657       cat_error msg ("in syntax declaration " ^ quote (Syntax.const_name c mx));
   658   in thy |> map_syn (change_gram (is_logtype thy) prmode (map prep args)) end;
   659 
   660 fun gen_add_syntax x = gen_syntax Syntax.extend_const_gram x;
   661 
   662 val add_modesyntax = gen_add_syntax (read_typ_syntax o no_def_sort);
   663 val add_modesyntax_i = gen_add_syntax certify_typ_syntax;
   664 val add_syntax = add_modesyntax Syntax.default_mode;
   665 val add_syntax_i = add_modesyntax_i Syntax.default_mode;
   666 val del_modesyntax = gen_syntax Syntax.remove_const_gram (read_typ_syntax o no_def_sort);
   667 val del_modesyntax_i = gen_syntax Syntax.remove_const_gram certify_typ_syntax;
   668 
   669 
   670 (* add constants *)
   671 
   672 local
   673 
   674 fun gen_add_consts prep_typ raw_args thy =
   675   let
   676     val prepT = Compress.typ thy o Type.varifyT o Type.no_tvars o Term.no_dummyT o prep_typ thy;
   677     fun prep (c, T, mx) = ((c, prepT T, mx) handle TYPE (msg, _, _) => error msg)
   678       handle ERROR msg =>
   679         cat_error msg ("in declaration of constant " ^ quote (Syntax.const_name c mx));
   680     val args = map prep raw_args;
   681     val decls = args |> map (fn (c, T, mx) => (Syntax.const_name c mx, T));
   682   in
   683     thy
   684     |> map_consts (fold (Consts.declare (naming_of thy)) decls)
   685     |> add_syntax_i args
   686   end;
   687 
   688 in
   689 
   690 val add_consts = gen_add_consts (read_typ o no_def_sort);
   691 val add_consts_i = gen_add_consts certify_typ;
   692 
   693 end;
   694 
   695 
   696 (* add constraints *)
   697 
   698 fun gen_add_constraint int_const prep_typ (raw_c, raw_T) thy =
   699   let
   700     val c = int_const thy raw_c;
   701     val T = Term.zero_var_indexesT (Term.no_dummyT (prep_typ thy raw_T))
   702       handle TYPE (msg, _, _) => error msg;
   703     val _ = cert_term thy (Const (c, T))
   704       handle TYPE (msg, _, _) => error msg;
   705   in thy |> map_consts (Consts.constrain (c, T)) end;
   706 
   707 val add_const_constraint = gen_add_constraint intern_const (read_typ o no_def_sort);
   708 val add_const_constraint_i = gen_add_constraint (K I) certify_typ;
   709 
   710 
   711 (* add type classes *)
   712 
   713 val classN = "_class";
   714 
   715 val const_of_class = suffix classN;
   716 fun class_of_const c = unsuffix classN c
   717   handle Fail _ => raise TERM ("class_of_const: bad name " ^ quote c, []);
   718 
   719 fun gen_add_class int_class (bclass, raw_classes) thy =
   720   thy |> map_sign (fn (naming, syn, tsig, consts) =>
   721     let
   722       val classes = map (int_class thy) raw_classes;
   723       val syn' = Syntax.extend_consts [bclass] syn;
   724       val tsig' = Type.add_classes (pp thy) naming [(bclass, classes)] tsig;
   725     in (naming, syn', tsig', consts) end)
   726   |> add_consts_i [(const_of_class bclass, a_itselfT --> propT, NoSyn)];
   727 
   728 val add_classes = fold (gen_add_class intern_class);
   729 val add_classes_i = fold (gen_add_class (K I));
   730 
   731 
   732 (* add to classrel *)
   733 
   734 fun gen_add_classrel int_class raw_pairs thy = thy |> map_tsig (fn tsig =>
   735   let
   736     val pairs = map (pairself (int_class thy)) raw_pairs;
   737     val tsig' = Type.add_classrel (pp thy) pairs tsig;
   738   in tsig' end);
   739 
   740 val add_classrel = gen_add_classrel intern_class;
   741 val add_classrel_i = gen_add_classrel (K I);
   742 
   743 
   744 (* add translation functions *)
   745 
   746 local
   747 
   748 fun mk trs = map Syntax.mk_trfun trs;
   749 
   750 fun gen_add_trfuns ext non_typed (atrs, trs, tr's, atr's) =
   751   map_syn (ext (mk atrs, mk trs, mk (map (apsnd non_typed) tr's), mk atr's));
   752 
   753 fun gen_add_trfunsT ext tr's = map_syn (ext ([], [], mk tr's, []));
   754 
   755 in
   756 
   757 val add_trfuns = gen_add_trfuns Syntax.extend_trfuns Syntax.non_typed_tr';
   758 val add_trfunsT = gen_add_trfunsT Syntax.extend_trfuns;
   759 val add_advanced_trfuns = gen_add_trfuns Syntax.extend_advanced_trfuns Syntax.non_typed_tr'';
   760 val add_advanced_trfunsT = gen_add_trfunsT Syntax.extend_advanced_trfuns;
   761 
   762 end;
   763 
   764 val add_tokentrfuns = map_syn o Syntax.extend_tokentrfuns;
   765 fun add_mode_tokentrfuns m = add_tokentrfuns o map (fn (s, f) => (m, s, f));
   766 
   767 
   768 (* compile translation functions *)
   769 
   770 local
   771 
   772 fun advancedT false = ""
   773   | advancedT true = "theory -> ";
   774 
   775 fun advancedN false = ""
   776   | advancedN true = "advanced_";
   777 
   778 in
   779 
   780 fun parse_ast_translation (a, txt) =
   781   txt |> Context.use_let ("val parse_ast_translation: (string * (" ^ advancedT a ^
   782       "Syntax.ast list -> Syntax.ast)) list")
   783     ("Sign.add_" ^ advancedN a ^ "trfuns (parse_ast_translation, [], [], [])");
   784 
   785 fun parse_translation (a, txt) =
   786   txt |> Context.use_let ("val parse_translation: (string * (" ^ advancedT a ^
   787       "term list -> term)) list")
   788     ("Sign.add_" ^ advancedN a ^ "trfuns ([], parse_translation, [], [])");
   789 
   790 fun print_translation (a, txt) =
   791   txt |> Context.use_let ("val print_translation: (string * (" ^ advancedT a ^
   792       "term list -> term)) list")
   793     ("Sign.add_" ^ advancedN a ^ "trfuns ([], [], print_translation, [])");
   794 
   795 fun print_ast_translation (a, txt) =
   796   txt |> Context.use_let ("val print_ast_translation: (string * (" ^ advancedT a ^
   797       "Syntax.ast list -> Syntax.ast)) list")
   798     ("Sign.add_" ^ advancedN a ^ "trfuns ([], [], [], print_ast_translation)");
   799 
   800 fun typed_print_translation (a, txt) =
   801   txt |> Context.use_let ("val typed_print_translation: (string * (" ^ advancedT a ^
   802       "bool -> typ -> term list -> term)) list")
   803     ("Sign.add_" ^ advancedN a ^ "trfunsT typed_print_translation");
   804 
   805 val token_translation =
   806   Context.use_let "val token_translation: (string * string * (string -> string * real)) list"
   807     "Sign.add_tokentrfuns token_translation";
   808 
   809 end;
   810 
   811 
   812 (* add translation rules *)
   813 
   814 fun add_trrules args thy = thy |> map_syn (fn syn =>
   815   let val rules = map (Syntax.map_trrule (apfst (intern_type thy))) args
   816   in Syntax.extend_trrules thy (is_logtype thy) syn rules syn end);
   817 
   818 val add_trrules_i = map_syn o Syntax.extend_trrules_i;
   819 
   820 
   821 (* modify naming *)
   822 
   823 val add_path        = map_naming o NameSpace.add_path;
   824 val qualified_names = map_naming NameSpace.qualified_names;
   825 val no_base_names   = map_naming NameSpace.no_base_names;
   826 val custom_accesses = map_naming o NameSpace.custom_accesses;
   827 val set_policy      = map_naming o NameSpace.set_policy;
   828 val restore_naming  = map_naming o K o naming_of;
   829 
   830 val parent_path     = add_path "..";
   831 val root_path       = add_path "/";
   832 val absolute_path   = add_path "//";
   833 
   834 fun local_path thy = thy |> root_path |> add_path (Context.theory_name thy);
   835 
   836 
   837 (* hide names *)
   838 
   839 fun hide_classes b xs thy = thy |> map_tsig (Type.hide_classes b (map (intern_class thy) xs));
   840 val hide_classes_i = map_tsig oo Type.hide_classes;
   841 fun hide_types b xs thy = thy |> map_tsig (Type.hide_types b (map (intern_type thy) xs));
   842 val hide_types_i = map_tsig oo Type.hide_types;
   843 fun hide_consts b xs thy = thy |> map_consts (fold (Consts.hide b o intern_const thy) xs);
   844 val hide_consts_i = map_consts oo (fold o Consts.hide);
   845 
   846 local
   847 
   848 val kinds =
   849  [("class", (intern_class, can o certify_class, hide_classes_i)),
   850   ("type", (intern_type, declared_tyname, hide_types_i)),
   851   ("const", (intern_const, declared_const, hide_consts_i))];
   852 
   853 fun gen_hide int b (kind, xnames) thy =
   854   (case AList.lookup (op =) kinds kind of
   855     SOME (intern, check, hide) =>
   856       let
   857         val names = if int then map (intern thy) xnames else xnames;
   858         val bads = filter_out (check thy) names;
   859       in
   860         if null bads then hide b names thy
   861         else error ("Attempt to hide undeclared item(s): " ^ commas_quote bads)
   862       end
   863   | NONE => error ("Bad name space specification: " ^ quote kind));
   864 
   865 in
   866 
   867 val hide_names = gen_hide true;
   868 val hide_names_i = gen_hide false;
   869 
   870 end;
   871 
   872 end;