src/Pure/library.ML
author wenzelm
Sat May 20 23:37:02 2006 +0200 (2006-05-20)
changeset 19691 dd9ccb370f52
parent 19644 0b01436e1843
child 19799 666de5708ae8
permissions -rw-r--r--
removed obsolete partition (cf. List.partition);
tuned;
     1 (*  Title:      Pure/library.ML
     2     ID:         $Id$
     3     Author:     Lawrence C Paulson, Cambridge University Computer Laboratory
     4     Author:     Markus Wenzel, TU Muenchen
     5 
     6 Basic library: functions, options, pairs, booleans, lists, integers,
     7 strings, lists as sets, balanced trees, orders, current directory, misc.
     8 *)
     9 
    10 infix 1 |> |-> ||> ||>> |>> |>>> #> #->;
    11 infix 2 ?;
    12 infix 3 o oo ooo oooo;
    13 
    14 infix 4 ~~ upto downto;
    15 infix orf andf \ \\ ins ins_string ins_int mem mem_int mem_string union union_int
    16   union_string inter inter_int inter_string subset subset_int subset_string;
    17 
    18 signature BASIC_LIBRARY =
    19 sig
    20   (*functions*)
    21   val I: 'a -> 'a
    22   val K: 'a -> 'b -> 'a
    23   val curry: ('a * 'b -> 'c) -> 'a -> 'b -> 'c
    24   val uncurry: ('a -> 'b -> 'c) -> 'a * 'b -> 'c
    25   val |> : 'a * ('a -> 'b) -> 'b
    26   val |-> : ('c * 'a) * ('c -> 'a -> 'b) -> 'b
    27   val ||> : ('c * 'a) * ('a -> 'b) -> 'c * 'b
    28   val ||>> : ('c * 'a) * ('a -> 'd * 'b) -> ('c * 'd) * 'b
    29   val |>> : ('a * 'c) * ('a -> 'b) -> 'b * 'c
    30   val |>>> : ('a * 'c) * ('a -> 'b * 'd) -> 'b * ('c * 'd)
    31   val #> : ('a -> 'b) * ('b -> 'c) -> 'a -> 'c
    32   val #-> : ('a -> 'c * 'b) * ('c -> 'b -> 'd) -> 'a -> 'd
    33   val ? : ('a -> bool) * ('a -> 'a) -> 'a -> 'a
    34   val ` : ('b -> 'a) -> 'b -> 'a * 'b
    35   val tap: ('b -> 'a) -> 'b -> 'b
    36   val oo: ('a -> 'b) * ('c -> 'd -> 'a) -> 'c -> 'd -> 'b
    37   val ooo: ('a -> 'b) * ('c -> 'd -> 'e -> 'a) -> 'c -> 'd -> 'e -> 'b
    38   val oooo: ('a -> 'b) * ('c -> 'd -> 'e -> 'f -> 'a) -> 'c -> 'd -> 'e -> 'f -> 'b
    39   val funpow: int -> ('a -> 'a) -> 'a -> 'a
    40 
    41   (*options*)
    42   val the: 'a option -> 'a
    43   val these: 'a list option -> 'a list
    44   val the_default: 'a -> 'a option -> 'a
    45   val the_list: 'a option -> 'a list
    46   val is_some: 'a option -> bool
    47   val is_none: 'a option -> bool
    48   val perhaps: ('a -> 'a option) -> 'a -> 'a
    49   val merge_opt: ('a * 'a -> bool) -> 'a option * 'a option -> 'a option
    50 
    51   (*exceptions*)
    52   val try: ('a -> 'b) -> 'a -> 'b option
    53   val can: ('a -> 'b) -> 'a -> bool
    54   exception EXCEPTION of exn * string
    55   val do_transform_failure: bool ref
    56   val transform_failure: (exn -> exn) -> ('a -> 'b) -> 'a -> 'b
    57   datatype 'a result = Result of 'a | Exn of exn
    58   val capture: ('a -> 'b) -> 'a -> 'b result
    59   val release: 'a result -> 'a
    60   val get_result: 'a result -> 'a option
    61   val get_exn: 'a result -> exn option
    62 
    63   (*errors*)
    64   exception SYS_ERROR of string
    65   val sys_error: string -> 'a
    66   exception ERROR of string
    67   val error: string -> 'a
    68   val cat_error: string -> string -> 'a
    69   val assert: bool -> string -> unit
    70   val deny: bool -> string -> unit
    71   val assert_all: ('a -> bool) -> 'a list -> ('a -> string) -> unit
    72 
    73   (*pairs*)
    74   val pair: 'a -> 'b -> 'a * 'b
    75   val rpair: 'a -> 'b -> 'b * 'a
    76   val fst: 'a * 'b -> 'a
    77   val snd: 'a * 'b -> 'b
    78   val eq_fst: ('a * 'c -> bool) -> ('a * 'b) * ('c * 'd) -> bool
    79   val eq_snd: ('b * 'd -> bool) -> ('a * 'b) * ('c * 'd) -> bool
    80   val eq_pair: ('a * 'c -> bool) -> ('b * 'd -> bool) -> ('a * 'b) * ('c * 'd) -> bool
    81   val swap: 'a * 'b -> 'b * 'a
    82   val apfst: ('a -> 'b) -> 'a * 'c -> 'b * 'c
    83   val apsnd: ('a -> 'b) -> 'c * 'a -> 'c * 'b
    84   val pairself: ('a -> 'b) -> 'a * 'a -> 'b * 'b
    85   val string_of_pair: ('a -> string) -> ('b -> string) -> 'a * 'b -> string
    86 
    87   (*booleans*)
    88   val equal: ''a -> ''a -> bool
    89   val not_equal: ''a -> ''a -> bool
    90   val orf: ('a -> bool) * ('a -> bool) -> 'a -> bool
    91   val andf: ('a -> bool) * ('a -> bool) -> 'a -> bool
    92   val exists: ('a -> bool) -> 'a list -> bool
    93   val forall: ('a -> bool) -> 'a list -> bool
    94   val set: bool ref -> bool
    95   val reset: bool ref -> bool
    96   val toggle: bool ref -> bool
    97   val change: 'a ref -> ('a -> 'a) -> unit
    98   val setmp: 'a ref -> 'a -> ('b -> 'c) -> 'b -> 'c
    99   val conditional: bool -> (unit -> unit) -> unit
   100 
   101   (*lists*)
   102   exception UnequalLengths
   103   val cons: 'a -> 'a list -> 'a list
   104   val single: 'a -> 'a list
   105   val singleton: ('a list -> 'b list) -> 'a -> 'b
   106   val append: 'a list -> 'a list -> 'a list
   107   val apply: ('a -> 'a) list -> 'a -> 'a
   108   val fold: ('a -> 'b -> 'b) -> 'a list -> 'b -> 'b
   109   val fold_rev: ('a -> 'b -> 'b) -> 'a list -> 'b -> 'b
   110   val fold_map: ('a -> 'b -> 'c * 'b) -> 'a list -> 'b -> 'c list * 'b
   111   val foldr1: ('a * 'a -> 'a) -> 'a list -> 'a
   112   val foldl_map: ('a * 'b -> 'a * 'c) -> 'a * 'b list -> 'a * 'c list
   113   val flat: 'a list list -> 'a list
   114   val maps: ('a -> 'b list) -> 'a list -> 'b list
   115   val unflat: 'a list list -> 'b list -> 'b list list
   116   val burrow: ('a list -> 'b list) -> 'a list list -> 'b list list
   117   val fold_burrow: ('a list -> 'c -> 'b list * 'd) -> 'a list list -> 'c -> 'b list list * 'd
   118   val chop: int -> 'a list -> 'a list * 'a list
   119   val dropwhile: ('a -> bool) -> 'a list -> 'a list
   120   val nth: 'a list -> int -> 'a
   121   val nth_update: int * 'a -> 'a list -> 'a list
   122   val nth_map: int -> ('a -> 'a) -> 'a list -> 'a list
   123   val nth_list: 'a list list -> int -> 'a list
   124   val map_index: (int * 'a -> 'b) -> 'a list -> 'b list
   125   val fold_index: (int * 'a -> 'b -> 'b) -> 'a list -> 'b -> 'b
   126   val split_last: 'a list -> 'a list * 'a
   127   val find_index: ('a -> bool) -> 'a list -> int
   128   val find_index_eq: ''a -> ''a list -> int
   129   val find_first: ('a -> bool) -> 'a list -> 'a option
   130   val get_index: ('a -> 'b option) -> 'a list -> (int * 'b) option
   131   val get_first: ('a -> 'b option) -> 'a list -> 'b option
   132   val eq_list: ('a * 'b -> bool) -> 'a list * 'b list -> bool
   133   val map2: ('a -> 'b -> 'c) -> 'a list -> 'b list -> 'c list
   134   val fold2: ('a -> 'b -> 'c -> 'c) -> 'a list -> 'b list -> 'c -> 'c
   135   val ~~ : 'a list * 'b list -> ('a * 'b) list
   136   val split_list: ('a * 'b) list -> 'a list * 'b list
   137   val separate: 'a -> 'a list -> 'a list
   138   val replicate: int -> 'a -> 'a list
   139   val multiply: 'a list -> 'a list list -> 'a list list
   140   val product: 'a list -> 'b list -> ('a * 'b) list
   141   val filter: ('a -> bool) -> 'a list -> 'a list
   142   val filter_out: ('a -> bool) -> 'a list -> 'a list
   143   val map_filter: ('a -> 'b option) -> 'a list -> 'b list
   144   val equal_lists: ('a * 'b -> bool) -> 'a list * 'b list -> bool
   145   val is_prefix: ('a * 'a -> bool) -> 'a list -> 'a list -> bool
   146   val take_prefix: ('a -> bool) -> 'a list -> 'a list * 'a list
   147   val take_suffix: ('a -> bool) -> 'a list -> 'a list * 'a list
   148   val prefixes1: 'a list -> 'a list list
   149   val prefixes: 'a list -> 'a list list
   150   val suffixes1: 'a list -> 'a list list
   151   val suffixes: 'a list -> 'a list list
   152 
   153   (*integers*)
   154   val gcd: IntInf.int * IntInf.int -> IntInf.int
   155   val lcm: IntInf.int * IntInf.int -> IntInf.int
   156   val inc: int ref -> int
   157   val dec: int ref -> int
   158   val upto: int * int -> int list
   159   val downto: int * int -> int list
   160   val downto0: int list * int -> bool
   161   val radixpand: int * int -> int list
   162   val radixstring: int * string * int -> string
   163   val string_of_int: int -> string
   164   val string_of_indexname: string * int -> string
   165   val read_radixint: int * string list -> int * string list
   166   val read_int: string list -> int * string list
   167   val oct_char: string -> string
   168 
   169   (*strings*)
   170   val nth_string: string -> int -> string
   171   val fold_string: (string -> 'a -> 'a) -> string -> 'a -> 'a
   172   val exists_string: (string -> bool) -> string -> bool
   173   val forall_string: (string -> bool) -> string -> bool
   174   val enclose: string -> string -> string -> string
   175   val unenclose: string -> string
   176   val quote: string -> string
   177   val space_implode: string -> string list -> string
   178   val commas: string list -> string
   179   val commas_quote: string list -> string
   180   val cat_lines: string list -> string
   181   val space_explode: string -> string -> string list
   182   val split_lines: string -> string list
   183   val prefix_lines: string -> string -> string
   184   val untabify: string list -> string list
   185   val prefix: string -> string -> string
   186   val suffix: string -> string -> string
   187   val unprefix: string -> string -> string
   188   val unsuffix: string -> string -> string
   189   val replicate_string: int -> string -> string
   190   val translate_string: (string -> string) -> string -> string
   191   val string_of_list: ('a -> string) -> 'a list -> string
   192   val string_of_option: ('a -> string) -> 'a option -> string
   193 
   194   (*lists as sets -- see also Pure/General/ord_list.ML*)
   195   val member: ('b * 'a -> bool) -> 'a list -> 'b -> bool
   196   val insert: ('a * 'a -> bool) -> 'a -> 'a list -> 'a list
   197   val remove: ('b * 'a -> bool) -> 'b -> 'a list -> 'a list
   198   val subtract: ('b * 'a -> bool) -> 'b list -> 'a list -> 'a list
   199   val merge: ('a * 'a -> bool) -> 'a list * 'a list -> 'a list
   200   val mem: ''a * ''a list -> bool
   201   val mem_int: int * int list -> bool
   202   val mem_string: string * string list -> bool
   203   val ins: ''a * ''a list -> ''a list
   204   val ins_int: int * int list -> int list
   205   val ins_string: string * string list -> string list
   206   val union: ''a list * ''a list -> ''a list
   207   val union_int: int list * int list -> int list
   208   val union_string: string list * string list -> string list
   209   val gen_union: ('a * 'a -> bool) -> 'a list * 'a list -> 'a list
   210   val gen_inter: ('a * 'b -> bool) -> 'a list * 'b list -> 'a list
   211   val inter: ''a list * ''a list -> ''a list
   212   val inter_int: int list * int list -> int list
   213   val inter_string: string list * string list -> string list
   214   val subset: ''a list * ''a list -> bool
   215   val subset_int: int list * int list -> bool
   216   val subset_string: string list * string list -> bool
   217   val eq_set: ''a list * ''a list -> bool
   218   val eq_set_string: string list * string list -> bool
   219   val gen_subset: ('a * 'b -> bool) -> 'a list * 'b list -> bool
   220   val gen_eq_set: ('a * 'b -> bool) -> 'a list * 'b list -> bool
   221   val \ : ''a list * ''a -> ''a list
   222   val \\ : ''a list * ''a list -> ''a list
   223   val gen_rem: ('a * 'b -> bool) -> 'a list * 'b -> 'a list
   224   val gen_rems: ('a * 'b -> bool) -> 'a list * 'b list -> 'a list
   225   val findrep: ''a list -> ''a list
   226   val distinct: ('a * 'a -> bool) -> 'a list -> 'a list
   227   val duplicates: ('a * 'a -> bool) -> 'a list -> 'a list
   228   val has_duplicates: ('a * 'a -> bool) -> 'a list -> bool
   229 
   230   (*lists as tables -- see also Pure/General/alist.ML*)
   231   val gen_merge_lists: ('a * 'a -> bool) -> 'a list -> 'a list -> 'a list
   232   val merge_lists: ''a list -> ''a list -> ''a list
   233   val merge_alists: (''a * 'b) list -> (''a * 'b) list -> (''a * 'b) list
   234 
   235   (*balanced trees*)
   236   exception Balance
   237   val fold_bal: ('a * 'a -> 'a) -> 'a list -> 'a
   238   val access_bal: ('a -> 'a) * ('a -> 'a) * 'a -> int -> int -> 'a
   239   val accesses_bal: ('a -> 'a) * ('a -> 'a) * 'a -> int -> 'a list
   240 
   241   (*orders*)
   242   val is_equal: order -> bool
   243   val rev_order: order -> order
   244   val make_ord: ('a * 'a -> bool) -> 'a * 'a -> order
   245   val int_ord: int * int -> order
   246   val string_ord: string * string -> order
   247   val fast_string_ord: string * string -> order
   248   val option_ord: ('a * 'b -> order) -> 'a option * 'b option -> order
   249   val prod_ord: ('a * 'b -> order) -> ('c * 'd -> order) -> ('a * 'c) * ('b * 'd) -> order
   250   val dict_ord: ('a * 'b -> order) -> 'a list * 'b list -> order
   251   val list_ord: ('a * 'b -> order) -> 'a list * 'b list -> order
   252   val sort: ('a * 'a -> order) -> 'a list -> 'a list
   253   val sort_distinct: ('a * 'a -> order) -> 'a list -> 'a list
   254   val sort_strings: string list -> string list
   255   val sort_wrt: ('a -> string) -> 'a list -> 'a list
   256 
   257   (*random numbers*)
   258   exception RANDOM
   259   val random: unit -> real
   260   val random_range: int -> int -> int
   261   val one_of: 'a list -> 'a
   262   val frequency: (int * 'a) list -> 'a
   263 
   264   (*current directory*)
   265   val cd: string -> unit
   266   val pwd: unit -> string
   267 
   268   (*misc*)
   269   val divide_and_conquer: ('a -> 'a list * ('b list -> 'b)) -> 'a -> 'b
   270   val partition_eq: ('a * 'a -> bool) -> 'a list -> 'a list list
   271   val partition_list: (int -> 'a -> bool) -> int -> int -> 'a list -> 'a list list
   272   val gensym: string -> string
   273   val scanwords: (string -> bool) -> string list -> string list
   274   type stamp
   275   val stamp: unit -> stamp
   276   type serial
   277   val serial: unit -> serial
   278   val serial_string: unit -> string
   279   structure Object: sig type T end
   280 end;
   281 
   282 signature LIBRARY =
   283 sig
   284   include BASIC_LIBRARY
   285   val foldl: ('a * 'b -> 'a) -> 'a * 'b list -> 'a
   286   val foldr: ('a * 'b -> 'b) -> 'a list * 'b -> 'b
   287   val take: int * 'a list -> 'a list
   288   val drop: int * 'a list -> 'a list
   289   val last_elem: 'a list -> 'a
   290   val seq: ('a -> unit) -> 'a list -> unit
   291 end;
   292 
   293 structure Library: LIBRARY =
   294 struct
   295 
   296 
   297 (** functions **)
   298 
   299 fun I x = x;
   300 fun K x = fn _ => x;
   301 fun curry f x y = f (x, y);
   302 fun uncurry f (x, y) = f x y;
   303 
   304 (*reverse application and structured results*)
   305 fun x |> f = f x;
   306 fun (x, y) |-> f = f x y;
   307 fun (x, y) |>> f = (f x, y);
   308 fun (x, y) ||> f = (x, f y);
   309 fun (x, y) |>>> f = let val (x', z) = f x in (x', (y, z)) end;
   310 fun (x, y) ||>> f = let val (z, y') = f y in ((x, z), y') end;
   311 
   312 (*reverse composition*)
   313 fun f #> g = g o f;
   314 fun f #-> g = uncurry g o f;
   315 
   316 (*conditional application*)
   317 fun b ? f = fn x => if b x then f x else x;
   318 
   319 (*view results*)
   320 fun `f = fn x => (f x, x);
   321 fun tap f = fn x => (f x; x);
   322 
   323 (*composition with multiple args*)
   324 fun (f oo g) x y = f (g x y);
   325 fun (f ooo g) x y z = f (g x y z);
   326 fun (f oooo g) x y z w = f (g x y z w);
   327 
   328 (*function exponentiation: f(...(f x)...) with n applications of f*)
   329 fun funpow n f x =
   330   let fun rep (0, x) = x
   331         | rep (n, x) = rep (n - 1, f x)
   332   in rep (n, x) end;
   333 
   334 
   335 (** options **)
   336 
   337 val the = Option.valOf;
   338 
   339 fun these (SOME x) = x
   340   | these _ = [];
   341 
   342 fun the_default x (SOME y) = y
   343   | the_default x _ = x;
   344 
   345 fun the_list (SOME x) = [x]
   346   | the_list _ = []
   347 
   348 fun is_some (SOME _) = true
   349   | is_some NONE = false;
   350 
   351 fun is_none (SOME _) = false
   352   | is_none NONE = true;
   353 
   354 fun perhaps f x = the_default x (f x);
   355 
   356 fun merge_opt _ (NONE, y) = y
   357   | merge_opt _ (x, NONE) = x
   358   | merge_opt eq (SOME x, SOME y) = if eq (x, y) then SOME y else raise Option;
   359 
   360 
   361 (* exceptions *)
   362 
   363 val do_transform_failure = ref true;
   364 
   365 fun transform_failure exn f x =
   366   if ! do_transform_failure then
   367     f x handle Interrupt => raise Interrupt | e => raise exn e
   368   else f x;
   369 
   370 exception EXCEPTION of exn * string;
   371 
   372 
   373 fun try f x = SOME (f x)
   374   handle Interrupt => raise Interrupt | _ => NONE;
   375 
   376 fun can f x = is_some (try f x);
   377 
   378 
   379 datatype 'a result =
   380   Result of 'a |
   381   Exn of exn;
   382 
   383 fun capture f x = Result (f x) handle e => Exn e;
   384 
   385 fun release (Result y) = y
   386   | release (Exn e) = raise e;
   387 
   388 fun get_result (Result x) = SOME x
   389   | get_result _ = NONE;
   390 
   391 fun get_exn (Exn exn) = SOME exn
   392   | get_exn _ = NONE;
   393 
   394 
   395 (* errors *)
   396 
   397 exception SYS_ERROR of string;
   398 fun sys_error msg = raise SYS_ERROR msg;
   399 
   400 exception ERROR of string;
   401 fun error msg = raise ERROR msg;
   402 
   403 fun cat_error "" msg = error msg
   404   | cat_error msg1 msg2 = error (msg1 ^ "\n" ^ msg2);
   405 
   406 fun assert p msg = if p then () else error msg;
   407 fun deny p msg = if p then error msg else ();
   408 
   409 fun assert_all pred list msg =
   410   let
   411     fun ass [] = ()
   412       | ass (x :: xs) = if pred x then ass xs else error (msg x);
   413   in ass list end;
   414 
   415 
   416 (** pairs **)
   417 
   418 fun pair x y = (x, y);
   419 fun rpair x y = (y, x);
   420 
   421 fun fst (x, y) = x;
   422 fun snd (x, y) = y;
   423 
   424 fun eq_fst eq ((x1, _), (x2, _)) = eq (x1, x2);
   425 fun eq_snd eq ((_, y1), (_, y2)) = eq (y1, y2);
   426 fun eq_pair eqx eqy ((x1, y1), (x2, y2)) = eqx (x1, x2) andalso eqy (y1, y2);
   427 
   428 fun swap (x, y) = (y, x);
   429 
   430 (*apply function to components*)
   431 fun apfst f (x, y) = (f x, y);
   432 fun apsnd f (x, y) = (x, f y);
   433 fun pairself f (x, y) = (f x, f y);
   434 
   435 fun string_of_pair f1 f2 (x, y) = "(" ^ f1 x ^ ", " ^ f2 y ^ ")";
   436 
   437 
   438 (** booleans **)
   439 
   440 (* equality *)
   441 
   442 fun equal x y = x = y;
   443 fun not_equal x y = x <> y;
   444 
   445 (* operators for combining predicates *)
   446 
   447 fun p orf q = fn x => p x orelse q x;
   448 fun p andf q = fn x => p x andalso q x;
   449 
   450 (* predicates on lists *)
   451 
   452 (*exists pred [x1, ..., xn] ===> pred x1 orelse ... orelse pred xn*)
   453 fun exists (pred: 'a -> bool) : 'a list -> bool =
   454   let fun boolf [] = false
   455         | boolf (x :: xs) = pred x orelse boolf xs
   456   in boolf end;
   457 
   458 (*forall pred [x1, ..., xn] ===> pred x1 andalso ... andalso pred xn*)
   459 fun forall (pred: 'a -> bool) : 'a list -> bool =
   460   let fun boolf [] = true
   461         | boolf (x :: xs) = pred x andalso boolf xs
   462   in boolf end;
   463 
   464 
   465 (* flags *)
   466 
   467 fun set flag = (flag := true; true);
   468 fun reset flag = (flag := false; false);
   469 fun toggle flag = (flag := not (! flag); ! flag);
   470 
   471 fun change r f = r := f (! r);
   472 
   473 (*temporarily set flag during execution*)
   474 fun setmp flag value f x =
   475   let
   476     val orig_value = ! flag;
   477     val _ = flag := value;
   478     val result = capture f x;
   479     val _ = flag := orig_value;
   480   in release result end;
   481 
   482 
   483 (* conditional execution *)
   484 
   485 fun conditional b f = if b then f () else ();
   486 
   487 
   488 (** lists **)
   489 
   490 exception UnequalLengths;
   491 
   492 fun cons x xs = x :: xs;
   493 fun single x = [x];
   494 
   495 fun singleton f x = (case f [x] of [y] => y | _ => raise Empty);
   496 
   497 fun append xs ys = xs @ ys;
   498 
   499 fun apply [] x = x
   500   | apply (f :: fs) x = apply fs (f x);
   501 
   502 
   503 (* fold *)
   504 
   505 fun fold f =
   506   let
   507     fun fold_aux [] y = y
   508       | fold_aux (x :: xs) y = fold_aux xs (f x y);
   509   in fold_aux end;
   510 
   511 fun fold_rev f =
   512   let
   513     fun fold_aux [] y = y
   514       | fold_aux (x :: xs) y = f x (fold_aux xs y);
   515   in fold_aux end;
   516 
   517 fun fold_map f =
   518   let
   519     fun fold_aux [] y = ([], y)
   520       | fold_aux (x :: xs) y =
   521           let
   522             val (x', y') = f x y;
   523             val (xs', y'') = fold_aux xs y';
   524           in (x' :: xs', y'') end;
   525   in fold_aux end;
   526 
   527 (*the following versions of fold are designed to fit nicely with infixes*)
   528 
   529 (*  (op @) (e, [x1, ..., xn])  ===>  ((e @ x1) @ x2) ... @ xn
   530     for operators that associate to the left (TAIL RECURSIVE)*)
   531 fun foldl (f: 'a * 'b -> 'a) : 'a * 'b list -> 'a =
   532   let fun itl (e, [])  = e
   533         | itl (e, a::l) = itl (f(e, a), l)
   534   in  itl end;
   535 
   536 (*  (op @) ([x1, ..., xn], e)  ===>   x1 @ (x2 ... @ (xn @ e))
   537     for operators that associate to the right (not tail recursive)*)
   538 fun foldr f (l, e) =
   539   let fun itr [] = e
   540         | itr (a::l) = f(a, itr l)
   541   in  itr l  end;
   542 
   543 (*  (op @) [x1, ..., xn]  ===>   x1 @ (x2 ... @ (x[n-1] @ xn))
   544     for n > 0, operators that associate to the right (not tail recursive)*)
   545 fun foldr1 f l =
   546   let fun itr [x] = x
   547         | itr (x::l) = f(x, itr l)
   548   in  itr l  end;
   549 
   550 fun fold_index f =
   551   let
   552     fun fold_aux _ [] y = y
   553       | fold_aux i (x :: xs) y = fold_aux (i+1) xs (f (i, x) y);
   554   in fold_aux 0 end;
   555 
   556 fun foldl_map f =
   557   let
   558     fun fold_aux (x, []) = (x, [])
   559       | fold_aux (x, y :: ys) =
   560           let
   561             val (x', y') = f (x, y);
   562             val (x'', ys') = fold_aux (x', ys);
   563           in (x'', y' :: ys') end;
   564   in fold_aux end;
   565 
   566 
   567 (* basic list functions *)
   568 
   569 fun maps f [] = []
   570   | maps f (x :: xs) = f x @ maps f xs;
   571 
   572 fun chop 0 xs = ([], xs)
   573   | chop _ [] = ([], [])
   574   | chop n (x :: xs) = chop (n - 1) xs |>> cons x;
   575 
   576 (*take the first n elements from a list*)
   577 fun take (n, []) = []
   578   | take (n, x :: xs) =
   579       if n > 0 then x :: take (n - 1, xs) else [];
   580 
   581 (*drop the first n elements from a list*)
   582 fun drop (n, []) = []
   583   | drop (n, x :: xs) =
   584       if n > 0 then drop (n - 1, xs) else x :: xs;
   585 
   586 fun dropwhile P [] = []
   587   | dropwhile P (ys as x::xs) = if P x then dropwhile P xs else ys;
   588 
   589 (*return nth element of a list, where 0 designates the first element;
   590   raise Subscript if list too short*)
   591 fun nth xs i = List.nth (xs, i);
   592 
   593 fun nth_list xss i = nth xss i handle Subscript => [];
   594 
   595 (*update nth element*)
   596 fun nth_update (n, x) xs =
   597   (case chop n xs of
   598     (_, []) => raise Subscript
   599   | (prfx, _ :: sffx') => prfx @ (x :: sffx'));
   600 
   601 fun nth_map 0 f (x :: xs) = f x :: xs
   602   | nth_map n f (x :: xs) = x :: nth_map (n - 1) f xs
   603   | nth_map _ _ [] = raise Subscript;
   604 
   605 fun map_index f =
   606   let
   607     fun mapp _ [] = []
   608       | mapp i (x :: xs) = f (i, x) :: mapp (i+1) xs
   609   in mapp 0 end;
   610 
   611 val last_elem = List.last;
   612 
   613 (*rear decomposition*)
   614 fun split_last [] = raise Empty
   615   | split_last [x] = ([], x)
   616   | split_last (x :: xs) = apfst (cons x) (split_last xs);
   617 
   618 (*find the position of an element in a list*)
   619 fun find_index pred =
   620   let fun find _ [] = ~1
   621         | find n (x :: xs) = if pred x then n else find (n + 1) xs;
   622   in find 0 end;
   623 
   624 fun find_index_eq x = find_index (equal x);
   625 
   626 (*find first element satisfying predicate*)
   627 fun find_first _ [] = NONE
   628   | find_first pred (x :: xs) =
   629       if pred x then SOME x else find_first pred xs;
   630 
   631 (*get first element by lookup function*)
   632 fun get_first _ [] = NONE
   633   | get_first f (x :: xs) =
   634       (case f x of
   635         NONE => get_first f xs
   636       | some => some);
   637 
   638 fun get_index f =
   639   let
   640     fun get _ [] = NONE
   641       | get i (x :: xs) =
   642           case f x
   643            of NONE => get (i + 1) xs
   644             | SOME y => SOME (i, y)
   645   in get 0 end;
   646 
   647 fun eq_list _ ([], []) = true
   648   | eq_list eq (x :: xs, y :: ys) = eq (x, y) andalso eq_list eq (xs, ys)
   649   | eq_list _ _ = false;
   650 
   651 val flat = List.concat;
   652 
   653 fun unflat (xs :: xss) ys =
   654       let val (ps, qs) = chop (length xs) ys
   655       in ps :: unflat xss qs end
   656   | unflat [] [] = []
   657   | unflat _ _ = raise UnequalLengths;
   658 
   659 fun burrow f xss =
   660   unflat xss ((f o flat) xss);
   661 
   662 fun fold_burrow f xss s =
   663   apfst (unflat xss) (f (flat xss) s);
   664 
   665 (*like Lisp's MAPC -- seq proc [x1, ..., xn] evaluates
   666   (proc x1; ...; proc xn) for side effects*)
   667 val seq = List.app;
   668 
   669 (*separate s [x1, x2, ..., xn]  ===>  [x1, s, x2, s, ..., s, xn]*)
   670 fun separate s (x :: (xs as _ :: _)) = x :: s :: separate s xs
   671   | separate _ xs = xs;
   672 
   673 (*make the list [x, x, ..., x] of length n*)
   674 fun replicate n (x: 'a) : 'a list =
   675   let fun rep (0, xs) = xs
   676         | rep (n, xs) = rep (n - 1, x :: xs)
   677   in
   678     if n < 0 then raise Subscript
   679     else rep (n, [])
   680   end;
   681 
   682 fun translate_string f = String.translate (f o String.str);
   683 
   684 (*multiply [a, b, c, ...] * [xs, ys, zs, ...]*)
   685 fun multiply [] _ = []
   686   | multiply (x :: xs) yss = map (cons x) yss @ multiply xs yss;
   687 
   688 (*direct product*)
   689 fun product _ [] = []
   690   | product [] _ = []
   691   | product (x :: xs) ys = map (pair x) ys @ product xs ys;
   692 
   693 
   694 (* filter *)
   695 
   696 (*copy the list preserving elements that satisfy the predicate*)
   697 val filter = List.filter;
   698 fun filter_out f = filter (not o f);
   699 val map_filter = List.mapPartial;
   700 
   701 
   702 (* lists of pairs *)
   703 
   704 exception UnequalLengths;
   705 
   706 fun map2 _ [] [] = []
   707   | map2 f (x :: xs) (y :: ys) = f x y :: map2 f xs ys
   708   | map2 _ _ _ = raise UnequalLengths;
   709 
   710 fun fold2 f =
   711   let
   712     fun fold_aux [] [] z = z
   713       | fold_aux (x :: xs) (y :: ys) z = fold_aux xs ys (f x y z)
   714       | fold_aux _ _ _ = raise UnequalLengths;
   715   in fold_aux end;
   716 
   717 
   718 (*combine two lists forming a list of pairs:
   719   [x1, ..., xn] ~~ [y1, ..., yn]  ===>  [(x1, y1), ..., (xn, yn)]*)
   720 fun [] ~~ [] = []
   721   | (x :: xs) ~~ (y :: ys) = (x, y) :: (xs ~~ ys)
   722   | _ ~~ _ = raise UnequalLengths;
   723 
   724 (*inverse of ~~; the old 'split':
   725   [(x1, y1), ..., (xn, yn)]  ===>  ([x1, ..., xn], [y1, ..., yn])*)
   726 val split_list = ListPair.unzip;
   727 
   728 fun equal_lists eq (xs, ys) =
   729   let
   730     fun eq' [] [] = true
   731       | eq' (x :: xs) (y :: ys) = eq (x, y) andalso eq' xs ys
   732   in length xs = length ys andalso eq' xs ys end;
   733 
   734 
   735 (* prefixes, suffixes *)
   736 
   737 fun is_prefix _ [] _ = true
   738   | is_prefix eq (x :: xs) (y :: ys) = eq (x, y) andalso is_prefix eq xs ys
   739   | is_prefix eq _ _ = false;
   740 
   741 (* [x1, ..., xi, ..., xn]  --->  ([x1, ..., x(i-1)], [xi, ..., xn])
   742    where xi is the first element that does not satisfy the predicate*)
   743 fun take_prefix (pred : 'a -> bool)  (xs: 'a list) : 'a list * 'a list =
   744   let fun take (rxs, []) = (rev rxs, [])
   745         | take (rxs, x :: xs) =
   746             if  pred x  then  take(x :: rxs, xs)  else  (rev rxs, x :: xs)
   747   in  take([], xs)  end;
   748 
   749 (* [x1, ..., xi, ..., xn]  --->  ([x1, ..., xi], [x(i+1), ..., xn])
   750    where xi is the last element that does not satisfy the predicate*)
   751 fun take_suffix _ [] = ([], [])
   752   | take_suffix pred (x :: xs) =
   753       (case take_suffix pred xs of
   754         ([], sffx) => if pred x then ([], x :: sffx) else ([x], sffx)
   755       | (prfx, sffx) => (x :: prfx, sffx));
   756 
   757 fun prefixes1 [] = []
   758   | prefixes1 (x :: xs) = map (cons x) ([] :: prefixes1 xs);
   759 
   760 fun prefixes xs = [] :: prefixes1 xs;
   761 
   762 fun suffixes1 xs = map rev (prefixes1 (rev xs));
   763 fun suffixes xs = [] :: suffixes1 xs;
   764 
   765 
   766 (** integers **)
   767 
   768 fun gcd (x, y) =
   769   let fun gxd x y : IntInf.int =
   770     if y = 0 then x else gxd y (x mod y)
   771   in if x < y then gxd y x else gxd x y end;
   772 
   773 fun lcm (x, y) = (x * y) div gcd (x, y);
   774 
   775 fun inc i = (i := ! i + 1; ! i);
   776 fun dec i = (i := ! i - 1; ! i);
   777 
   778 
   779 (* lists of integers *)
   780 
   781 (*make the list [from, from + 1, ..., to]*)
   782 fun (from upto to) =
   783   if from > to then [] else from :: ((from + 1) upto to);
   784 
   785 (*make the list [from, from - 1, ..., to]*)
   786 fun (from downto to) =
   787   if from < to then [] else from :: ((from - 1) downto to);
   788 
   789 (*predicate: downto0 (is, n) <=> is = [n, n - 1, ..., 0]*)
   790 fun downto0 (i :: is, n) = i = n andalso downto0 (is, n - 1)
   791   | downto0 ([], n) = n = ~1;
   792 
   793 
   794 (* convert integers to strings *)
   795 
   796 (*expand the number in the given base;
   797   example: radixpand (2, 8) gives [1, 0, 0, 0]*)
   798 fun radixpand (base, num) : int list =
   799   let
   800     fun radix (n, tail) =
   801       if n < base then n :: tail
   802       else radix (n div base, (n mod base) :: tail)
   803   in radix (num, []) end;
   804 
   805 (*expands a number into a string of characters starting from "zerochar";
   806   example: radixstring (2, "0", 8) gives "1000"*)
   807 fun radixstring (base, zerochar, num) =
   808   let val offset = ord zerochar;
   809       fun chrof n = chr (offset + n)
   810   in implode (map chrof (radixpand (base, num))) end;
   811 
   812 
   813 val string_of_int = Int.toString;
   814 
   815 fun string_of_indexname (a,0) = a
   816   | string_of_indexname (a,i) = a ^ "_" ^ Int.toString i;
   817 
   818 
   819 (* read integers *)
   820 
   821 fun read_radixint (radix: int, cs) : int * string list =
   822   let val zero = ord"0"
   823       val limit = zero+radix
   824       fun scan (num,[]) = (num,[])
   825         | scan (num, c::cs) =
   826               if  zero <= ord c  andalso  ord c < limit
   827               then scan(radix*num + ord c - zero, cs)
   828               else (num, c::cs)
   829   in  scan(0,cs)  end;
   830 
   831 fun read_int cs = read_radixint (10, cs);
   832 
   833 fun oct_char s = chr (#1 (read_radixint (8, explode s)));
   834 
   835 
   836 
   837 (** strings **)
   838 
   839 (* functions tuned for strings, avoiding explode *)
   840 
   841 fun nth_string str i =
   842   (case try String.substring (str, i, 1) of
   843     SOME s => s
   844   | NONE => raise Subscript);
   845 
   846 fun fold_string f str x0 =
   847   let
   848     val n = size str;
   849     fun iter (x, i) =
   850       if i < n then iter (f (String.substring (str, i, 1)) x, i + 1) else x;
   851   in iter (x0, 0) end;
   852 
   853 fun exists_string pred str =
   854   let
   855     val n = size str;
   856     fun ex i = i < n andalso (pred (String.substring (str, i, 1)) orelse ex (i + 1));
   857   in ex 0 end;
   858 
   859 fun forall_string pred = not o exists_string (not o pred);
   860 
   861 (*enclose in brackets*)
   862 fun enclose lpar rpar str = lpar ^ str ^ rpar;
   863 fun unenclose str = String.substring (str, 1, size str - 2);
   864 
   865 (*simple quoting (does not escape special chars)*)
   866 val quote = enclose "\"" "\"";
   867 
   868 (*space_implode "..." (explode "hello") = "h...e...l...l...o"*)
   869 fun space_implode a bs = implode (separate a bs);
   870 
   871 val commas = space_implode ", ";
   872 val commas_quote = commas o map quote;
   873 
   874 (*concatenate messages, one per line, into a string*)
   875 val cat_lines = space_implode "\n";
   876 
   877 (*space_explode "." "h.e..l.lo" = ["h", "e", "", "l", "lo"]*)
   878 fun space_explode _ "" = []
   879   | space_explode sep str =
   880       let
   881         fun expl chs =
   882           (case take_prefix (fn s => s <> sep) chs of
   883             (cs, []) => [implode cs]
   884           | (cs, _ :: cs') => implode cs :: expl cs');
   885       in expl (explode str) end;
   886 
   887 val split_lines = space_explode "\n";
   888 
   889 fun prefix_lines "" txt = txt
   890   | prefix_lines prfx txt = txt |> split_lines |> map (fn s => prfx ^ s) |> cat_lines;
   891 
   892 fun untabify chs =
   893   let
   894     val tab_width = 8;
   895 
   896     fun untab (_, "\n") = (0, ["\n"])
   897       | untab (pos, "\t") =
   898           let val d = tab_width - (pos mod tab_width) in (pos + d, replicate d " ") end
   899       | untab (pos, c) = (pos + 1, [c]);
   900   in
   901     if not (exists (fn c => c = "\t") chs) then chs
   902     else flat (#2 (foldl_map untab (0, chs)))
   903   end;
   904 
   905 fun prefix prfx s = prfx ^ s;
   906 fun suffix sffx s = s ^ sffx;
   907 
   908 fun unprefix prfx s =
   909   if String.isPrefix prfx s then String.substring (s, size prfx, size s - size prfx)
   910   else raise Fail "unprefix";
   911 
   912 fun unsuffix sffx s =
   913   if String.isSuffix sffx s then String.substring (s, 0, size s - size sffx)
   914   else raise Fail "unsuffix";
   915 
   916 fun replicate_string 0 _ = ""
   917   | replicate_string 1 a = a
   918   | replicate_string k a =
   919       if k mod 2 = 0 then replicate_string (k div 2) (a ^ a)
   920       else replicate_string (k div 2) (a ^ a) ^ a;
   921 
   922 fun string_of_list f = enclose "[" "]" o commas o map f;
   923 
   924 fun string_of_option f NONE = "NONE"
   925   | string_of_option f (SOME x) = "SOME (" ^ f x ^ ")";
   926 
   927 
   928 
   929 (** lists as sets -- see also Pure/General/ord_list.ML **)
   930 
   931 (*canonical member, insert, remove*)
   932 fun member eq list x =
   933   let
   934     fun memb [] = false
   935       | memb (y :: ys) = eq (x, y) orelse memb ys;
   936   in memb list end;
   937 
   938 fun insert eq x xs = if member eq xs x then xs else x :: xs;
   939 fun remove eq x xs = if member eq xs x then filter_out (fn y => eq (x, y)) xs else xs;
   940 
   941 fun subtract eq = fold (remove eq);
   942 
   943 fun merge _ ([], ys) = ys
   944   | merge eq (xs, ys) = fold_rev (insert eq) ys xs;
   945 
   946 (*old-style infixes*)
   947 fun x mem xs = member (op =) xs x;
   948 fun (x: int) mem_int xs = member (op =) xs x;
   949 fun (x: string) mem_string xs = member (op =) xs x;
   950 
   951 fun x ins xs = insert (op =) x xs;
   952 fun (x: int) ins_int xs = insert (op =) x xs;
   953 fun (x: string) ins_string xs = insert (op =) x xs;
   954 
   955 
   956 (*union of sets represented as lists: no repetitions*)
   957 fun xs union [] = xs
   958   | [] union ys = ys
   959   | (x :: xs) union ys = xs union (x ins ys);
   960 
   961 (*union of sets, optimized version for ints*)
   962 fun (xs:int list) union_int [] = xs
   963   | [] union_int ys = ys
   964   | (x :: xs) union_int ys = xs union_int (x ins_int ys);
   965 
   966 (*union of sets, optimized version for strings*)
   967 fun (xs:string list) union_string [] = xs
   968   | [] union_string ys = ys
   969   | (x :: xs) union_string ys = xs union_string (x ins_string ys);
   970 
   971 (*generalized union*)
   972 fun gen_union eq (xs, []) = xs
   973   | gen_union eq ([], ys) = ys
   974   | gen_union eq (x :: xs, ys) = gen_union eq (xs, insert eq x ys);
   975 
   976 
   977 (*intersection*)
   978 fun [] inter ys = []
   979   | (x :: xs) inter ys =
   980       if x mem ys then x :: (xs inter ys) else xs inter ys;
   981 
   982 (*intersection, optimized version for ints*)
   983 fun ([]:int list) inter_int ys = []
   984   | (x :: xs) inter_int ys =
   985       if x mem_int ys then x :: (xs inter_int ys) else xs inter_int ys;
   986 
   987 (*intersection, optimized version for strings *)
   988 fun ([]:string list) inter_string ys = []
   989   | (x :: xs) inter_string ys =
   990       if x mem_string ys then x :: (xs inter_string ys) else xs inter_string ys;
   991 
   992 (*generalized intersection*)
   993 fun gen_inter eq ([], ys) = []
   994   | gen_inter eq (x::xs, ys) =
   995       if member eq ys x then x :: gen_inter eq (xs, ys)
   996       else gen_inter eq (xs, ys);
   997 
   998 
   999 (*subset*)
  1000 fun [] subset ys = true
  1001   | (x :: xs) subset ys = x mem ys andalso xs subset ys;
  1002 
  1003 (*subset, optimized version for ints*)
  1004 fun ([]: int list) subset_int ys = true
  1005   | (x :: xs) subset_int ys = x mem_int ys andalso xs subset_int ys;
  1006 
  1007 (*subset, optimized version for strings*)
  1008 fun ([]: string list) subset_string ys = true
  1009   | (x :: xs) subset_string ys = x mem_string ys andalso xs subset_string ys;
  1010 
  1011 (*set equality*)
  1012 fun eq_set (xs, ys) =
  1013   xs = ys orelse (xs subset ys andalso ys subset xs);
  1014 
  1015 (*set equality for strings*)
  1016 fun eq_set_string ((xs: string list), ys) =
  1017   xs = ys orelse (xs subset_string ys andalso ys subset_string xs);
  1018 
  1019 fun gen_subset eq (xs, ys) = forall (member eq ys) xs;
  1020 
  1021 fun gen_eq_set eq (xs, ys) =
  1022   equal_lists eq (xs, ys) orelse
  1023     (gen_subset eq (xs, ys) andalso gen_subset (eq o swap) (ys, xs));
  1024 
  1025 
  1026 (*removing an element from a list WITHOUT duplicates*)
  1027 fun (y :: ys) \ x = if x = y then ys else y :: (ys \ x)
  1028   | [] \ x = [];
  1029 
  1030 fun ys \\ xs = foldl (op \) (ys,xs);
  1031 
  1032 (*removing an element from a list -- possibly WITH duplicates*)
  1033 fun gen_rem eq (xs, y) = filter_out (fn x => eq (x, y)) xs;
  1034 fun gen_rems eq (xs, ys) = filter_out (member eq ys) xs;
  1035 
  1036 (*returns the tail beginning with the first repeated element, or []*)
  1037 fun findrep [] = []
  1038   | findrep (x :: xs) = if x mem xs then x :: xs else findrep xs;
  1039 
  1040 
  1041 (*makes a list of the distinct members of the input; preserves order, takes
  1042   first of equal elements*)
  1043 fun distinct eq lst =
  1044   let
  1045     fun dist (rev_seen, []) = rev rev_seen
  1046       | dist (rev_seen, x :: xs) =
  1047           if member eq rev_seen x then dist (rev_seen, xs)
  1048           else dist (x :: rev_seen, xs);
  1049   in dist ([], lst) end;
  1050 
  1051 (*returns a list containing all repeated elements exactly once; preserves
  1052   order, takes first of equal elements*)
  1053 fun duplicates eq lst =
  1054   let
  1055     fun dups (rev_dups, []) = rev rev_dups
  1056       | dups (rev_dups, x :: xs) =
  1057           if member eq rev_dups x orelse not (member eq xs x) then
  1058             dups (rev_dups, xs)
  1059           else dups (x :: rev_dups, xs);
  1060   in dups ([], lst) end;
  1061 
  1062 fun has_duplicates eq =
  1063   let
  1064     fun dups [] = false
  1065       | dups (x :: xs) = member eq xs x orelse dups xs;
  1066   in dups end;
  1067 
  1068 
  1069 (** association lists -- legacy operations **)
  1070 
  1071 fun gen_merge_lists _ xs [] = xs
  1072   | gen_merge_lists _ [] ys = ys
  1073   | gen_merge_lists eq xs ys = xs @ gen_rems eq (ys, xs);
  1074 
  1075 fun merge_lists xs ys = gen_merge_lists (op =) xs ys;
  1076 fun merge_alists al = gen_merge_lists (eq_fst (op =)) al;
  1077 
  1078 
  1079 (** balanced trees **)
  1080 
  1081 exception Balance;      (*indicates non-positive argument to balancing fun*)
  1082 
  1083 (*balanced folding; avoids deep nesting*)
  1084 fun fold_bal f [x] = x
  1085   | fold_bal f [] = raise Balance
  1086   | fold_bal f xs =
  1087       let val (ps, qs) = chop (length xs div 2) xs
  1088       in  f (fold_bal f ps, fold_bal f qs)  end;
  1089 
  1090 (*construct something of the form f(...g(...(x)...)) for balanced access*)
  1091 fun access_bal (f, g, x) n i =
  1092   let fun acc n i =     (*1<=i<=n*)
  1093           if n=1 then x else
  1094           let val n2 = n div 2
  1095           in  if i<=n2 then f (acc n2 i)
  1096                        else g (acc (n-n2) (i-n2))
  1097           end
  1098   in  if 1<=i andalso i<=n then acc n i else raise Balance  end;
  1099 
  1100 (*construct ALL such accesses; could try harder to share recursive calls!*)
  1101 fun accesses_bal (f, g, x) n =
  1102   let fun acc n =
  1103           if n=1 then [x] else
  1104           let val n2 = n div 2
  1105               val acc2 = acc n2
  1106           in  if n-n2=n2 then map f acc2 @ map g acc2
  1107                          else map f acc2 @ map g (acc (n-n2)) end
  1108   in  if 1<=n then acc n else raise Balance  end;
  1109 
  1110 
  1111 
  1112 (** orders **)
  1113 
  1114 fun is_equal EQUAL = true
  1115   | is_equal _ = false;
  1116 
  1117 fun rev_order LESS = GREATER
  1118   | rev_order EQUAL = EQUAL
  1119   | rev_order GREATER = LESS;
  1120 
  1121 (*assume rel is a linear strict order*)
  1122 fun make_ord rel (x, y) =
  1123   if rel (x, y) then LESS
  1124   else if rel (y, x) then GREATER
  1125   else EQUAL;
  1126 
  1127 val int_ord = Int.compare;
  1128 val string_ord = String.compare;
  1129 
  1130 fun fast_string_ord (s1, s2) =
  1131   (case int_ord (size s1, size s2) of EQUAL => string_ord (s1, s2) | ord => ord);
  1132 
  1133 fun option_ord ord (SOME x, SOME y) = ord (x, y)
  1134   | option_ord _ (NONE, NONE) = EQUAL
  1135   | option_ord _ (NONE, SOME _) = LESS
  1136   | option_ord _ (SOME _, NONE) = GREATER;
  1137 
  1138 (*lexicographic product*)
  1139 fun prod_ord a_ord b_ord ((x, y), (x', y')) =
  1140   (case a_ord (x, x') of EQUAL => b_ord (y, y') | ord => ord);
  1141 
  1142 (*dictionary order -- in general NOT well-founded!*)
  1143 fun dict_ord elem_ord (x :: xs, y :: ys) =
  1144       (case elem_ord (x, y) of EQUAL => dict_ord elem_ord (xs, ys) | ord => ord)
  1145   | dict_ord _ ([], []) = EQUAL
  1146   | dict_ord _ ([], _ :: _) = LESS
  1147   | dict_ord _ (_ :: _, []) = GREATER;
  1148 
  1149 (*lexicographic product of lists*)
  1150 fun list_ord elem_ord (xs, ys) =
  1151   (case int_ord (length xs, length ys) of EQUAL => dict_ord elem_ord (xs, ys) | ord => ord);
  1152 
  1153 
  1154 (* sorting *)
  1155 
  1156 (*quicksort -- stable, i.e. does not reorder equal elements*)
  1157 fun quicksort unique ord =
  1158   let
  1159     fun qsort [] = []
  1160       | qsort (xs as [_]) = xs
  1161       | qsort (xs as [x, y]) =
  1162           (case ord (x, y) of
  1163             LESS => xs
  1164           | EQUAL => if unique then [x] else xs
  1165           | GREATER => [y, x])
  1166       | qsort xs =
  1167           let val (lts, eqs, gts) = part (nth xs (length xs div 2)) xs
  1168           in qsort lts @ eqs @ qsort gts end
  1169     and part _ [] = ([], [], [])
  1170       | part pivot (x :: xs) = add (ord (x, pivot)) x (part pivot xs)
  1171     and add LESS x (lts, eqs, gts) = (x :: lts, eqs, gts)
  1172       | add EQUAL x (lts, [], gts) = (lts, [x], gts)
  1173       | add EQUAL x (res as (lts, eqs, gts)) = if unique then res else (lts, x :: eqs, gts)
  1174       | add GREATER x (lts, eqs, gts) = (lts, eqs, x :: gts);
  1175   in qsort end;
  1176 
  1177 fun sort ord = quicksort false ord;
  1178 fun sort_distinct ord = quicksort true ord;
  1179 
  1180 val sort_strings = sort string_ord;
  1181 fun sort_wrt sel xs = sort (string_ord o pairself sel) xs;
  1182 
  1183 
  1184 
  1185 (** random numbers **)
  1186 
  1187 exception RANDOM;
  1188 
  1189 fun rmod x y = x - y * Real.realFloor (x / y);
  1190 
  1191 local
  1192   val a = 16807.0;
  1193   val m = 2147483647.0;
  1194   val random_seed = ref 1.0;
  1195 in
  1196 
  1197 fun random () =
  1198   let val r = rmod (a * !random_seed) m
  1199   in (random_seed := r; r) end;
  1200 
  1201 end;
  1202 
  1203 fun random_range l h =
  1204   if h < l orelse l < 0 then raise RANDOM
  1205   else l + Real.floor (rmod (random ()) (real (h - l + 1)));
  1206 
  1207 fun one_of xs = nth xs (random_range 0 (length xs - 1));
  1208 
  1209 fun frequency xs =
  1210   let
  1211     val sum = foldl op + (0, map fst xs);
  1212     fun pick n ((k: int, x) :: xs) =
  1213       if n <= k then x else pick (n - k) xs
  1214   in pick (random_range 1 sum) xs end;
  1215 
  1216 
  1217 (** current directory **)
  1218 
  1219 val cd = OS.FileSys.chDir;
  1220 val pwd = OS.FileSys.getDir;
  1221 
  1222 
  1223 
  1224 (** misc **)
  1225 
  1226 fun divide_and_conquer decomp x =
  1227   let val (ys, recomb) = decomp x
  1228   in recomb (map (divide_and_conquer decomp) ys) end;
  1229 
  1230 
  1231 (*Partition a list into buckets  [ bi, b(i+1), ..., bj ]
  1232    putting x in bk if p(k)(x) holds.  Preserve order of elements if possible.*)
  1233 fun partition_list p i j =
  1234   let fun part k xs =
  1235             if k>j then
  1236               (case xs of [] => []
  1237                          | _ => raise Fail "partition_list")
  1238             else
  1239             let val (ns, rest) = List.partition (p k) xs;
  1240             in  ns :: part(k+1)rest  end
  1241   in  part i end;
  1242 
  1243 fun partition_eq (eq:'a * 'a -> bool) =
  1244   let
  1245     fun part [] = []
  1246       | part (x :: ys) =
  1247           let val (xs, xs') = List.partition (fn y => eq (x, y)) ys
  1248           in (x::xs)::(part xs') end
  1249   in part end;
  1250 
  1251 
  1252 
  1253 (* generating identifiers *)
  1254 
  1255 (** Freshly generated identifiers; supplied prefix MUST start with a letter **)
  1256 local
  1257 (*Maps 0-63 to A-Z, a-z, 0-9 or _ or ' for generating random identifiers*)
  1258 fun char i =      if i<26 then chr (ord "A" + i)
  1259              else if i<52 then chr (ord "a" + i - 26)
  1260              else if i<62 then chr (ord"0" + i - 52)
  1261              else if i=62 then "_"
  1262              else  (*i=63*)    "'";
  1263 
  1264 val charVec = Vector.tabulate (64, char);
  1265 
  1266 fun newid n =
  1267   let
  1268   in  implode (map (fn i => Vector.sub(charVec,i)) (radixpand (64,n)))  end;
  1269 
  1270 val seedr = ref 0;
  1271 
  1272 in
  1273 
  1274 fun gensym pre = pre ^ (#1(newid (!seedr), inc seedr));
  1275 
  1276 end;
  1277 
  1278 
  1279 (* lexical scanning *)
  1280 
  1281 (*scan a list of characters into "words" composed of "letters" (recognized by
  1282   is_let) and separated by any number of non-"letters"*)
  1283 fun scanwords is_let cs =
  1284   let fun scan1 [] = []
  1285         | scan1 cs =
  1286             let val (lets, rest) = take_prefix is_let cs
  1287             in implode lets :: scanwords is_let rest end;
  1288   in scan1 (#2 (take_prefix (not o is_let) cs)) end;
  1289 
  1290 
  1291 (* stamps and serial numbers *)
  1292 
  1293 type stamp = unit ref;
  1294 val stamp: unit -> stamp = ref;
  1295 
  1296 type serial = int;
  1297 local val count = ref 0
  1298 in fun serial () = inc count end;
  1299 
  1300 val serial_string = string_of_int o serial;
  1301 
  1302 
  1303 (* generic objects *)
  1304 
  1305 (*note that the builtin exception datatype may be extended by new
  1306   constructors at any time*)
  1307 structure Object = struct type T = exn end;
  1308 
  1309 end;
  1310 
  1311 structure BasicLibrary: BASIC_LIBRARY = Library;
  1312 open BasicLibrary;