src/HOL/Decision_Procs/Reflected_Multivariate_Polynomial.thy
author wenzelm
Sun Mar 09 18:43:38 2014 +0100 (2014-03-09)
changeset 56009 dda076a32aea
parent 56000 899ad5a3ad00
child 56043 0b25c3d34b77
permissions -rw-r--r--
tuned proofs;
     1 (*  Title:      HOL/Decision_Procs/Reflected_Multivariate_Polynomial.thy
     2     Author:     Amine Chaieb
     3 *)
     4 
     5 header {* Implementation and verification of multivariate polynomials *}
     6 
     7 theory Reflected_Multivariate_Polynomial
     8 imports Complex_Main Rat_Pair Polynomial_List
     9 begin
    10 
    11 subsection{* Datatype of polynomial expressions *}
    12 
    13 datatype poly = C Num| Bound nat| Add poly poly|Sub poly poly
    14   | Mul poly poly| Neg poly| Pw poly nat| CN poly nat poly
    15 
    16 abbreviation poly_0 :: "poly" ("0\<^sub>p") where "0\<^sub>p \<equiv> C (0\<^sub>N)"
    17 abbreviation poly_p :: "int \<Rightarrow> poly" ("'((_)')\<^sub>p") where "(i)\<^sub>p \<equiv> C (i)\<^sub>N"
    18 
    19 
    20 subsection{* Boundedness, substitution and all that *}
    21 
    22 primrec polysize:: "poly \<Rightarrow> nat"
    23 where
    24   "polysize (C c) = 1"
    25 | "polysize (Bound n) = 1"
    26 | "polysize (Neg p) = 1 + polysize p"
    27 | "polysize (Add p q) = 1 + polysize p + polysize q"
    28 | "polysize (Sub p q) = 1 + polysize p + polysize q"
    29 | "polysize (Mul p q) = 1 + polysize p + polysize q"
    30 | "polysize (Pw p n) = 1 + polysize p"
    31 | "polysize (CN c n p) = 4 + polysize c + polysize p"
    32 
    33 primrec polybound0:: "poly \<Rightarrow> bool" -- {* a poly is INDEPENDENT of Bound 0 *}
    34 where
    35   "polybound0 (C c) \<longleftrightarrow> True"
    36 | "polybound0 (Bound n) \<longleftrightarrow> n > 0"
    37 | "polybound0 (Neg a) \<longleftrightarrow> polybound0 a"
    38 | "polybound0 (Add a b) \<longleftrightarrow> polybound0 a \<and> polybound0 b"
    39 | "polybound0 (Sub a b) \<longleftrightarrow> polybound0 a \<and> polybound0 b"
    40 | "polybound0 (Mul a b) \<longleftrightarrow> polybound0 a \<and> polybound0 b"
    41 | "polybound0 (Pw p n) \<longleftrightarrow> polybound0 p"
    42 | "polybound0 (CN c n p) \<longleftrightarrow> n \<noteq> 0 \<and> polybound0 c \<and> polybound0 p"
    43 
    44 primrec polysubst0:: "poly \<Rightarrow> poly \<Rightarrow> poly" -- {* substitute a poly into a poly for Bound 0 *}
    45 where
    46   "polysubst0 t (C c) = C c"
    47 | "polysubst0 t (Bound n) = (if n = 0 then t else Bound n)"
    48 | "polysubst0 t (Neg a) = Neg (polysubst0 t a)"
    49 | "polysubst0 t (Add a b) = Add (polysubst0 t a) (polysubst0 t b)"
    50 | "polysubst0 t (Sub a b) = Sub (polysubst0 t a) (polysubst0 t b)"
    51 | "polysubst0 t (Mul a b) = Mul (polysubst0 t a) (polysubst0 t b)"
    52 | "polysubst0 t (Pw p n) = Pw (polysubst0 t p) n"
    53 | "polysubst0 t (CN c n p) =
    54     (if n = 0 then Add (polysubst0 t c) (Mul t (polysubst0 t p))
    55      else CN (polysubst0 t c) n (polysubst0 t p))"
    56 
    57 fun decrpoly:: "poly \<Rightarrow> poly"
    58 where
    59   "decrpoly (Bound n) = Bound (n - 1)"
    60 | "decrpoly (Neg a) = Neg (decrpoly a)"
    61 | "decrpoly (Add a b) = Add (decrpoly a) (decrpoly b)"
    62 | "decrpoly (Sub a b) = Sub (decrpoly a) (decrpoly b)"
    63 | "decrpoly (Mul a b) = Mul (decrpoly a) (decrpoly b)"
    64 | "decrpoly (Pw p n) = Pw (decrpoly p) n"
    65 | "decrpoly (CN c n p) = CN (decrpoly c) (n - 1) (decrpoly p)"
    66 | "decrpoly a = a"
    67 
    68 
    69 subsection{* Degrees and heads and coefficients *}
    70 
    71 fun degree:: "poly \<Rightarrow> nat"
    72 where
    73   "degree (CN c 0 p) = 1 + degree p"
    74 | "degree p = 0"
    75 
    76 fun head:: "poly \<Rightarrow> poly"
    77 where
    78   "head (CN c 0 p) = head p"
    79 | "head p = p"
    80 
    81 (* More general notions of degree and head *)
    82 fun degreen:: "poly \<Rightarrow> nat \<Rightarrow> nat"
    83 where
    84   "degreen (CN c n p) = (\<lambda>m. if n = m then 1 + degreen p n else 0)"
    85 | "degreen p = (\<lambda>m. 0)"
    86 
    87 fun headn:: "poly \<Rightarrow> nat \<Rightarrow> poly"
    88 where
    89   "headn (CN c n p) = (\<lambda>m. if n \<le> m then headn p m else CN c n p)"
    90 | "headn p = (\<lambda>m. p)"
    91 
    92 fun coefficients:: "poly \<Rightarrow> poly list"
    93 where
    94   "coefficients (CN c 0 p) = c # coefficients p"
    95 | "coefficients p = [p]"
    96 
    97 fun isconstant:: "poly \<Rightarrow> bool"
    98 where
    99   "isconstant (CN c 0 p) = False"
   100 | "isconstant p = True"
   101 
   102 fun behead:: "poly \<Rightarrow> poly"
   103 where
   104   "behead (CN c 0 p) = (let p' = behead p in if p' = 0\<^sub>p then c else CN c 0 p')"
   105 | "behead p = 0\<^sub>p"
   106 
   107 fun headconst:: "poly \<Rightarrow> Num"
   108 where
   109   "headconst (CN c n p) = headconst p"
   110 | "headconst (C n) = n"
   111 
   112 
   113 subsection{* Operations for normalization *}
   114 
   115 declare if_cong[fundef_cong del]
   116 declare let_cong[fundef_cong del]
   117 
   118 fun polyadd :: "poly \<Rightarrow> poly \<Rightarrow> poly" (infixl "+\<^sub>p" 60)
   119 where
   120   "polyadd (C c) (C c') = C (c +\<^sub>N c')"
   121 | "polyadd (C c) (CN c' n' p') = CN (polyadd (C c) c') n' p'"
   122 | "polyadd (CN c n p) (C c') = CN (polyadd c (C c')) n p"
   123 | "polyadd (CN c n p) (CN c' n' p') =
   124     (if n < n' then CN (polyadd c (CN c' n' p')) n p
   125      else if n' < n then CN (polyadd (CN c n p) c') n' p'
   126      else
   127       let
   128         cc' = polyadd c c';
   129         pp' = polyadd p p'
   130       in if pp' = 0\<^sub>p then cc' else CN cc' n pp')"
   131 | "polyadd a b = Add a b"
   132 
   133 
   134 fun polyneg :: "poly \<Rightarrow> poly" ("~\<^sub>p")
   135 where
   136   "polyneg (C c) = C (~\<^sub>N c)"
   137 | "polyneg (CN c n p) = CN (polyneg c) n (polyneg p)"
   138 | "polyneg a = Neg a"
   139 
   140 definition polysub :: "poly \<Rightarrow> poly \<Rightarrow> poly" (infixl "-\<^sub>p" 60)
   141   where "p -\<^sub>p q = polyadd p (polyneg q)"
   142 
   143 fun polymul :: "poly \<Rightarrow> poly \<Rightarrow> poly" (infixl "*\<^sub>p" 60)
   144 where
   145   "polymul (C c) (C c') = C (c*\<^sub>Nc')"
   146 | "polymul (C c) (CN c' n' p') =
   147     (if c = 0\<^sub>N then 0\<^sub>p else CN (polymul (C c) c') n' (polymul (C c) p'))"
   148 | "polymul (CN c n p) (C c') =
   149     (if c' = 0\<^sub>N  then 0\<^sub>p else CN (polymul c (C c')) n (polymul p (C c')))"
   150 | "polymul (CN c n p) (CN c' n' p') =
   151     (if n < n' then CN (polymul c (CN c' n' p')) n (polymul p (CN c' n' p'))
   152      else if n' < n then CN (polymul (CN c n p) c') n' (polymul (CN c n p) p')
   153      else polyadd (polymul (CN c n p) c') (CN 0\<^sub>p n' (polymul (CN c n p) p')))"
   154 | "polymul a b = Mul a b"
   155 
   156 declare if_cong[fundef_cong]
   157 declare let_cong[fundef_cong]
   158 
   159 fun polypow :: "nat \<Rightarrow> poly \<Rightarrow> poly"
   160 where
   161   "polypow 0 = (\<lambda>p. (1)\<^sub>p)"
   162 | "polypow n =
   163     (\<lambda>p.
   164       let
   165         q = polypow (n div 2) p;
   166         d = polymul q q
   167       in if even n then d else polymul p d)"
   168 
   169 abbreviation poly_pow :: "poly \<Rightarrow> nat \<Rightarrow> poly" (infixl "^\<^sub>p" 60)
   170   where "a ^\<^sub>p k \<equiv> polypow k a"
   171 
   172 function polynate :: "poly \<Rightarrow> poly"
   173 where
   174   "polynate (Bound n) = CN 0\<^sub>p n (1)\<^sub>p"
   175 | "polynate (Add p q) = polynate p +\<^sub>p polynate q"
   176 | "polynate (Sub p q) = polynate p -\<^sub>p polynate q"
   177 | "polynate (Mul p q) = polynate p *\<^sub>p polynate q"
   178 | "polynate (Neg p) = ~\<^sub>p (polynate p)"
   179 | "polynate (Pw p n) = polynate p ^\<^sub>p n"
   180 | "polynate (CN c n p) = polynate (Add c (Mul (Bound n) p))"
   181 | "polynate (C c) = C (normNum c)"
   182 by pat_completeness auto
   183 termination by (relation "measure polysize") auto
   184 
   185 fun poly_cmul :: "Num \<Rightarrow> poly \<Rightarrow> poly"
   186 where
   187   "poly_cmul y (C x) = C (y *\<^sub>N x)"
   188 | "poly_cmul y (CN c n p) = CN (poly_cmul y c) n (poly_cmul y p)"
   189 | "poly_cmul y p = C y *\<^sub>p p"
   190 
   191 definition monic :: "poly \<Rightarrow> poly \<times> bool"
   192 where
   193   "monic p =
   194     (let h = headconst p
   195      in if h = 0\<^sub>N then (p, False) else (C (Ninv h) *\<^sub>p p, 0>\<^sub>N h))"
   196 
   197 
   198 subsection {* Pseudo-division *}
   199 
   200 definition shift1 :: "poly \<Rightarrow> poly"
   201   where "shift1 p = CN 0\<^sub>p 0 p"
   202 
   203 abbreviation funpow :: "nat \<Rightarrow> ('a \<Rightarrow> 'a) \<Rightarrow> 'a \<Rightarrow> 'a"
   204   where "funpow \<equiv> compow"
   205 
   206 partial_function (tailrec) polydivide_aux :: "poly \<Rightarrow> nat \<Rightarrow> poly \<Rightarrow> nat \<Rightarrow> poly \<Rightarrow> nat \<times> poly"
   207 where
   208   "polydivide_aux a n p k s =
   209     (if s = 0\<^sub>p then (k, s)
   210      else
   211       let
   212         b = head s;
   213         m = degree s
   214       in
   215         if m < n then (k,s)
   216         else
   217           let p' = funpow (m - n) shift1 p
   218           in
   219             if a = b then polydivide_aux a n p k (s -\<^sub>p p')
   220             else polydivide_aux a n p (Suc k) ((a *\<^sub>p s) -\<^sub>p (b *\<^sub>p p')))"
   221 
   222 definition polydivide :: "poly \<Rightarrow> poly \<Rightarrow> nat \<times> poly"
   223   where "polydivide s p = polydivide_aux (head p) (degree p) p 0 s"
   224 
   225 fun poly_deriv_aux :: "nat \<Rightarrow> poly \<Rightarrow> poly"
   226 where
   227   "poly_deriv_aux n (CN c 0 p) = CN (poly_cmul ((int n)\<^sub>N) c) 0 (poly_deriv_aux (n + 1) p)"
   228 | "poly_deriv_aux n p = poly_cmul ((int n)\<^sub>N) p"
   229 
   230 fun poly_deriv :: "poly \<Rightarrow> poly"
   231 where
   232   "poly_deriv (CN c 0 p) = poly_deriv_aux 1 p"
   233 | "poly_deriv p = 0\<^sub>p"
   234 
   235 
   236 subsection{* Semantics of the polynomial representation *}
   237 
   238 primrec Ipoly :: "'a list \<Rightarrow> poly \<Rightarrow> 'a::{field_char_0,field_inverse_zero,power}"
   239 where
   240   "Ipoly bs (C c) = INum c"
   241 | "Ipoly bs (Bound n) = bs!n"
   242 | "Ipoly bs (Neg a) = - Ipoly bs a"
   243 | "Ipoly bs (Add a b) = Ipoly bs a + Ipoly bs b"
   244 | "Ipoly bs (Sub a b) = Ipoly bs a - Ipoly bs b"
   245 | "Ipoly bs (Mul a b) = Ipoly bs a * Ipoly bs b"
   246 | "Ipoly bs (Pw t n) = Ipoly bs t ^ n"
   247 | "Ipoly bs (CN c n p) = Ipoly bs c + (bs!n) * Ipoly bs p"
   248 
   249 abbreviation Ipoly_syntax :: "poly \<Rightarrow> 'a list \<Rightarrow>'a::{field_char_0,field_inverse_zero,power}"
   250     ("\<lparr>_\<rparr>\<^sub>p\<^bsup>_\<^esup>")
   251   where "\<lparr>p\<rparr>\<^sub>p\<^bsup>bs\<^esup> \<equiv> Ipoly bs p"
   252 
   253 lemma Ipoly_CInt: "Ipoly bs (C (i, 1)) = of_int i"
   254   by (simp add: INum_def)
   255 
   256 lemma Ipoly_CRat: "Ipoly bs (C (i, j)) = of_int i / of_int j"
   257   by (simp  add: INum_def)
   258 
   259 lemmas RIpoly_eqs = Ipoly.simps(2-7) Ipoly_CInt Ipoly_CRat
   260 
   261 
   262 subsection {* Normal form and normalization *}
   263 
   264 fun isnpolyh:: "poly \<Rightarrow> nat \<Rightarrow> bool"
   265 where
   266   "isnpolyh (C c) = (\<lambda>k. isnormNum c)"
   267 | "isnpolyh (CN c n p) = (\<lambda>k. n \<ge> k \<and> isnpolyh c (Suc n) \<and> isnpolyh p n \<and> p \<noteq> 0\<^sub>p)"
   268 | "isnpolyh p = (\<lambda>k. False)"
   269 
   270 lemma isnpolyh_mono: "n' \<le> n \<Longrightarrow> isnpolyh p n \<Longrightarrow> isnpolyh p n'"
   271   by (induct p rule: isnpolyh.induct) auto
   272 
   273 definition isnpoly :: "poly \<Rightarrow> bool"
   274   where "isnpoly p = isnpolyh p 0"
   275 
   276 text{* polyadd preserves normal forms *}
   277 
   278 lemma polyadd_normh: "isnpolyh p n0 \<Longrightarrow> isnpolyh q n1 \<Longrightarrow> isnpolyh (polyadd p q) (min n0 n1)"
   279 proof (induct p q arbitrary: n0 n1 rule: polyadd.induct)
   280   case (2 ab c' n' p' n0 n1)
   281   from 2 have  th1: "isnpolyh (C ab) (Suc n')"
   282     by simp
   283   from 2(3) have th2: "isnpolyh c' (Suc n')"  and nplen1: "n' \<ge> n1"
   284     by simp_all
   285   with isnpolyh_mono have cp: "isnpolyh c' (Suc n')"
   286     by simp
   287   with 2(1)[OF th1 th2] have th3:"isnpolyh (C ab +\<^sub>p c') (Suc n')"
   288     by simp
   289   from nplen1 have n01len1: "min n0 n1 \<le> n'"
   290     by simp
   291   then show ?case using 2 th3
   292     by simp
   293 next
   294   case (3 c' n' p' ab n1 n0)
   295   from 3 have  th1: "isnpolyh (C ab) (Suc n')"
   296     by simp
   297   from 3(2) have th2: "isnpolyh c' (Suc n')"  and nplen1: "n' \<ge> n1"
   298     by simp_all
   299   with isnpolyh_mono have cp: "isnpolyh c' (Suc n')"
   300     by simp
   301   with 3(1)[OF th2 th1] have th3:"isnpolyh (c' +\<^sub>p C ab) (Suc n')"
   302     by simp
   303   from nplen1 have n01len1: "min n0 n1 \<le> n'"
   304     by simp
   305   then show ?case using 3 th3
   306     by simp
   307 next
   308   case (4 c n p c' n' p' n0 n1)
   309   then have nc: "isnpolyh c (Suc n)" and np: "isnpolyh p n"
   310     by simp_all
   311   from 4 have nc': "isnpolyh c' (Suc n')" and np': "isnpolyh p' n'"
   312     by simp_all
   313   from 4 have ngen0: "n \<ge> n0"
   314     by simp
   315   from 4 have n'gen1: "n' \<ge> n1"
   316     by simp
   317   have "n < n' \<or> n' < n \<or> n = n'"
   318     by auto
   319   moreover
   320   {
   321     assume eq: "n = n'"
   322     with "4.hyps"(3)[OF nc nc']
   323     have ncc':"isnpolyh (c +\<^sub>p c') (Suc n)"
   324       by auto
   325     then have ncc'n01: "isnpolyh (c +\<^sub>p c') (min n0 n1)"
   326       using isnpolyh_mono[where n'="min n0 n1" and n="Suc n"] ngen0 n'gen1
   327       by auto
   328     from eq "4.hyps"(4)[OF np np'] have npp': "isnpolyh (p +\<^sub>p p') n"
   329       by simp
   330     have minle: "min n0 n1 \<le> n'"
   331       using ngen0 n'gen1 eq by simp
   332     from minle npp' ncc'n01 4 eq ngen0 n'gen1 ncc' have ?case
   333       by (simp add: Let_def)
   334   }
   335   moreover
   336   {
   337     assume lt: "n < n'"
   338     have "min n0 n1 \<le> n0"
   339       by simp
   340     with 4 lt have th1:"min n0 n1 \<le> n"
   341       by auto
   342     from 4 have th21: "isnpolyh c (Suc n)"
   343       by simp
   344     from 4 have th22: "isnpolyh (CN c' n' p') n'"
   345       by simp
   346     from lt have th23: "min (Suc n) n' = Suc n"
   347       by arith
   348     from "4.hyps"(1)[OF th21 th22] have "isnpolyh (polyadd c (CN c' n' p')) (Suc n)"
   349       using th23 by simp
   350     with 4 lt th1 have ?case
   351       by simp
   352   }
   353   moreover
   354   {
   355     assume gt: "n' < n"
   356     then have gt': "n' < n \<and> \<not> n < n'"
   357       by simp
   358     have "min n0 n1 \<le> n1"
   359       by simp
   360     with 4 gt have th1: "min n0 n1 \<le> n'"
   361       by auto
   362     from 4 have th21: "isnpolyh c' (Suc n')"
   363       by simp_all
   364     from 4 have th22: "isnpolyh (CN c n p) n"
   365       by simp
   366     from gt have th23: "min n (Suc n') = Suc n'"
   367       by arith
   368     from "4.hyps"(2)[OF th22 th21] have "isnpolyh (polyadd (CN c n p) c') (Suc n')"
   369       using th23 by simp
   370     with 4 gt th1 have ?case
   371       by simp
   372   }
   373   ultimately show ?case by blast
   374 qed auto
   375 
   376 lemma polyadd[simp]: "Ipoly bs (polyadd p q) = Ipoly bs p + Ipoly bs q"
   377   by (induct p q rule: polyadd.induct)
   378     (auto simp add: Let_def field_simps distrib_left[symmetric] simp del: distrib_left)
   379 
   380 lemma polyadd_norm: "isnpoly p \<Longrightarrow> isnpoly q \<Longrightarrow> isnpoly (polyadd p q)"
   381   using polyadd_normh[of "p" "0" "q" "0"] isnpoly_def by simp
   382 
   383 text{* The degree of addition and other general lemmas needed for the normal form of polymul *}
   384 
   385 lemma polyadd_different_degreen:
   386   assumes "isnpolyh p n0"
   387     and "isnpolyh q n1"
   388     and "degreen p m \<noteq> degreen q m"
   389     and "m \<le> min n0 n1"
   390   shows "degreen (polyadd p q) m = max (degreen p m) (degreen q m)"
   391   using assms
   392 proof (induct p q arbitrary: m n0 n1 rule: polyadd.induct)
   393   case (4 c n p c' n' p' m n0 n1)
   394   have "n' = n \<or> n < n' \<or> n' < n" by arith
   395   then show ?case
   396   proof (elim disjE)
   397     assume [simp]: "n' = n"
   398     from 4(4)[of n n m] 4(3)[of "Suc n" "Suc n" m] 4(5-7)
   399     show ?thesis by (auto simp: Let_def)
   400   next
   401     assume "n < n'"
   402     with 4 show ?thesis by auto
   403   next
   404     assume "n' < n"
   405     with 4 show ?thesis by auto
   406   qed
   407 qed auto
   408 
   409 lemma headnz[simp]: "isnpolyh p n \<Longrightarrow> p \<noteq> 0\<^sub>p \<Longrightarrow> headn p m \<noteq> 0\<^sub>p"
   410   by (induct p arbitrary: n rule: headn.induct) auto
   411 
   412 lemma degree_isnpolyh_Suc[simp]: "isnpolyh p (Suc n) \<Longrightarrow> degree p = 0"
   413   by (induct p arbitrary: n rule: degree.induct) auto
   414 
   415 lemma degreen_0[simp]: "isnpolyh p n \<Longrightarrow> m < n \<Longrightarrow> degreen p m = 0"
   416   by (induct p arbitrary: n rule: degreen.induct) auto
   417 
   418 lemma degree_isnpolyh_Suc': "n > 0 \<Longrightarrow> isnpolyh p n \<Longrightarrow> degree p = 0"
   419   by (induct p arbitrary: n rule: degree.induct) auto
   420 
   421 lemma degree_npolyhCN[simp]: "isnpolyh (CN c n p) n0 \<Longrightarrow> degree c = 0"
   422   using degree_isnpolyh_Suc by auto
   423 
   424 lemma degreen_npolyhCN[simp]: "isnpolyh (CN c n p) n0 \<Longrightarrow> degreen c n = 0"
   425   using degreen_0 by auto
   426 
   427 
   428 lemma degreen_polyadd:
   429   assumes np: "isnpolyh p n0"
   430     and nq: "isnpolyh q n1"
   431     and m: "m \<le> max n0 n1"
   432   shows "degreen (p +\<^sub>p q) m \<le> max (degreen p m) (degreen q m)"
   433   using np nq m
   434 proof (induct p q arbitrary: n0 n1 m rule: polyadd.induct)
   435   case (2 c c' n' p' n0 n1)
   436   then show ?case
   437     by (cases n') simp_all
   438 next
   439   case (3 c n p c' n0 n1)
   440   then show ?case
   441     by (cases n) auto
   442 next
   443   case (4 c n p c' n' p' n0 n1 m)
   444   have "n' = n \<or> n < n' \<or> n' < n" by arith
   445   then show ?case
   446   proof (elim disjE)
   447     assume [simp]: "n' = n"
   448     from 4(4)[of n n m] 4(3)[of "Suc n" "Suc n" m] 4(5-7)
   449     show ?thesis by (auto simp: Let_def)
   450   qed simp_all
   451 qed auto
   452 
   453 lemma polyadd_eq_const_degreen:
   454   assumes "isnpolyh p n0"
   455     and "isnpolyh q n1"
   456     and "polyadd p q = C c"
   457   shows "degreen p m = degreen q m"
   458   using assms
   459 proof (induct p q arbitrary: m n0 n1 c rule: polyadd.induct)
   460   case (4 c n p c' n' p' m n0 n1 x)
   461   {
   462     assume nn': "n' < n"
   463     then have ?case using 4 by simp
   464   }
   465   moreover
   466   {
   467     assume nn': "\<not> n' < n"
   468     then have "n < n' \<or> n = n'" by arith
   469     moreover { assume "n < n'" with 4 have ?case by simp }
   470     moreover
   471     {
   472       assume eq: "n = n'"
   473       then have ?case using 4
   474         apply (cases "p +\<^sub>p p' = 0\<^sub>p")
   475         apply (auto simp add: Let_def)
   476         apply blast
   477         done
   478     }
   479     ultimately have ?case by blast
   480   }
   481   ultimately show ?case by blast
   482 qed simp_all
   483 
   484 lemma polymul_properties:
   485   assumes "SORT_CONSTRAINT('a::{field_char_0,field_inverse_zero})"
   486     and np: "isnpolyh p n0"
   487     and nq: "isnpolyh q n1"
   488     and m: "m \<le> min n0 n1"
   489   shows "isnpolyh (p *\<^sub>p q) (min n0 n1)"
   490     and "p *\<^sub>p q = 0\<^sub>p \<longleftrightarrow> p = 0\<^sub>p \<or> q = 0\<^sub>p"
   491     and "degreen (p *\<^sub>p q) m = (if p = 0\<^sub>p \<or> q = 0\<^sub>p then 0 else degreen p m + degreen q m)"
   492   using np nq m
   493 proof (induct p q arbitrary: n0 n1 m rule: polymul.induct)
   494   case (2 c c' n' p')
   495   {
   496     case (1 n0 n1)
   497     with "2.hyps"(4-6)[of n' n' n'] and "2.hyps"(1-3)[of "Suc n'" "Suc n'" n']
   498     show ?case by (auto simp add: min_def)
   499   next
   500     case (2 n0 n1)
   501     then show ?case by auto
   502   next
   503     case (3 n0 n1)
   504     then show ?case  using "2.hyps" by auto
   505   }
   506 next
   507   case (3 c n p c')
   508   {
   509     case (1 n0 n1)
   510     with "3.hyps"(4-6)[of n n n] and "3.hyps"(1-3)[of "Suc n" "Suc n" n]
   511     show ?case by (auto simp add: min_def)
   512   next
   513     case (2 n0 n1)
   514     then show ?case by auto
   515   next
   516     case (3 n0 n1)
   517     then show ?case  using "3.hyps" by auto
   518   }
   519 next
   520   case (4 c n p c' n' p')
   521   let ?cnp = "CN c n p" let ?cnp' = "CN c' n' p'"
   522   {
   523     case (1 n0 n1)
   524     then have cnp: "isnpolyh ?cnp n"
   525       and cnp': "isnpolyh ?cnp' n'"
   526       and np: "isnpolyh p n"
   527       and nc: "isnpolyh c (Suc n)"
   528       and np': "isnpolyh p' n'"
   529       and nc': "isnpolyh c' (Suc n')"
   530       and nn0: "n \<ge> n0"
   531       and nn1: "n' \<ge> n1"
   532       by simp_all
   533     {
   534       assume "n < n'"
   535       with "4.hyps"(4-5)[OF np cnp', of n] and "4.hyps"(1)[OF nc cnp', of n] nn0 cnp
   536       have ?case by (simp add: min_def)
   537     } moreover {
   538       assume "n' < n"
   539       with "4.hyps"(16-17)[OF cnp np', of "n'"] and "4.hyps"(13)[OF cnp nc', of "Suc n'"] nn1 cnp'
   540       have ?case by (cases "Suc n' = n") (simp_all add: min_def)
   541     } moreover {
   542       assume "n' = n"
   543       with "4.hyps"(16-17)[OF cnp np', of n] and "4.hyps"(13)[OF cnp nc', of n] cnp cnp' nn1 nn0
   544       have ?case
   545         apply (auto intro!: polyadd_normh)
   546         apply (simp_all add: min_def isnpolyh_mono[OF nn0])
   547         done
   548     }
   549     ultimately show ?case by arith
   550   next
   551     fix n0 n1 m
   552     assume np: "isnpolyh ?cnp n0"
   553     assume np':"isnpolyh ?cnp' n1"
   554     assume m: "m \<le> min n0 n1"
   555     let ?d = "degreen (?cnp *\<^sub>p ?cnp') m"
   556     let ?d1 = "degreen ?cnp m"
   557     let ?d2 = "degreen ?cnp' m"
   558     let ?eq = "?d = (if ?cnp = 0\<^sub>p \<or> ?cnp' = 0\<^sub>p then 0  else ?d1 + ?d2)"
   559     have "n'<n \<or> n < n' \<or> n' = n" by auto
   560     moreover
   561     {
   562       assume "n' < n \<or> n < n'"
   563       with "4.hyps"(3,6,18) np np' m have ?eq
   564         by auto
   565     }
   566     moreover
   567     {
   568       assume nn': "n' = n"
   569       then have nn: "\<not> n' < n \<and> \<not> n < n'" by arith
   570       from "4.hyps"(16,18)[of n n' n]
   571         "4.hyps"(13,14)[of n "Suc n'" n]
   572         np np' nn'
   573       have norm: "isnpolyh ?cnp n" "isnpolyh c' (Suc n)" "isnpolyh (?cnp *\<^sub>p c') n"
   574         "isnpolyh p' n" "isnpolyh (?cnp *\<^sub>p p') n" "isnpolyh (CN 0\<^sub>p n (CN c n p *\<^sub>p p')) n"
   575         "(?cnp *\<^sub>p c' = 0\<^sub>p) = (c' = 0\<^sub>p)"
   576         "?cnp *\<^sub>p p' \<noteq> 0\<^sub>p" by (auto simp add: min_def)
   577       {
   578         assume mn: "m = n"
   579         from "4.hyps"(17,18)[OF norm(1,4), of n]
   580           "4.hyps"(13,15)[OF norm(1,2), of n] norm nn' mn
   581         have degs:
   582           "degreen (?cnp *\<^sub>p c') n = (if c' = 0\<^sub>p then 0 else ?d1 + degreen c' n)"
   583           "degreen (?cnp *\<^sub>p p') n = ?d1  + degreen p' n"
   584           by (simp_all add: min_def)
   585         from degs norm have th1: "degreen (?cnp *\<^sub>p c') n < degreen (CN 0\<^sub>p n (?cnp *\<^sub>p p')) n"
   586           by simp
   587         then have neq: "degreen (?cnp *\<^sub>p c') n \<noteq> degreen (CN 0\<^sub>p n (?cnp *\<^sub>p p')) n"
   588           by simp
   589         have nmin: "n \<le> min n n"
   590           by (simp add: min_def)
   591         from polyadd_different_degreen[OF norm(3,6) neq nmin] th1
   592         have deg: "degreen (CN c n p *\<^sub>p c' +\<^sub>p CN 0\<^sub>p n (CN c n p *\<^sub>p p')) n =
   593             degreen (CN 0\<^sub>p n (CN c n p *\<^sub>p p')) n"
   594           by simp
   595         from "4.hyps"(16-18)[OF norm(1,4), of n]
   596           "4.hyps"(13-15)[OF norm(1,2), of n]
   597           mn norm m nn' deg
   598         have ?eq by simp
   599       }
   600       moreover
   601       {
   602         assume mn: "m \<noteq> n"
   603         then have mn': "m < n"
   604           using m np by auto
   605         from nn' m np have max1: "m \<le> max n n"
   606           by simp
   607         then have min1: "m \<le> min n n"
   608           by simp
   609         then have min2: "m \<le> min n (Suc n)"
   610           by simp
   611         from "4.hyps"(16-18)[OF norm(1,4) min1]
   612           "4.hyps"(13-15)[OF norm(1,2) min2]
   613           degreen_polyadd[OF norm(3,6) max1]
   614         have "degreen (?cnp *\<^sub>p c' +\<^sub>p CN 0\<^sub>p n (?cnp *\<^sub>p p')) m \<le>
   615             max (degreen (?cnp *\<^sub>p c') m) (degreen (CN 0\<^sub>p n (?cnp *\<^sub>p p')) m)"
   616           using mn nn' np np' by simp
   617         with "4.hyps"(16-18)[OF norm(1,4) min1]
   618           "4.hyps"(13-15)[OF norm(1,2) min2]
   619           degreen_0[OF norm(3) mn']
   620         have ?eq using nn' mn np np' by clarsimp
   621       }
   622       ultimately have ?eq by blast
   623     }
   624     ultimately show ?eq by blast
   625   }
   626   {
   627     case (2 n0 n1)
   628     then have np: "isnpolyh ?cnp n0"
   629       and np': "isnpolyh ?cnp' n1"
   630       and m: "m \<le> min n0 n1" by simp_all
   631     then have mn: "m \<le> n" by simp
   632     let ?c0p = "CN 0\<^sub>p n (?cnp *\<^sub>p p')"
   633     {
   634       assume C: "?cnp *\<^sub>p c' +\<^sub>p ?c0p = 0\<^sub>p" "n' = n"
   635       then have nn: "\<not> n' < n \<and> \<not> n < n'"
   636         by simp
   637       from "4.hyps"(16-18) [of n n n]
   638         "4.hyps"(13-15)[of n "Suc n" n]
   639         np np' C(2) mn
   640       have norm:
   641         "isnpolyh ?cnp n"
   642         "isnpolyh c' (Suc n)"
   643         "isnpolyh (?cnp *\<^sub>p c') n"
   644         "isnpolyh p' n"
   645         "isnpolyh (?cnp *\<^sub>p p') n"
   646         "isnpolyh (CN 0\<^sub>p n (CN c n p *\<^sub>p p')) n"
   647         "?cnp *\<^sub>p c' = 0\<^sub>p \<longleftrightarrow> c' = 0\<^sub>p"
   648         "?cnp *\<^sub>p p' \<noteq> 0\<^sub>p"
   649         "degreen (?cnp *\<^sub>p c') n = (if c' = 0\<^sub>p then 0 else degreen ?cnp n + degreen c' n)"
   650         "degreen (?cnp *\<^sub>p p') n = degreen ?cnp n + degreen p' n"
   651         by (simp_all add: min_def)
   652       from norm have cn: "isnpolyh (CN 0\<^sub>p n (CN c n p *\<^sub>p p')) n"
   653         by simp
   654       have degneq: "degreen (?cnp *\<^sub>p c') n < degreen (CN 0\<^sub>p n (?cnp *\<^sub>p p')) n"
   655         using norm by simp
   656       from polyadd_eq_const_degreen[OF norm(3) cn C(1), where m="n"] degneq
   657       have False by simp
   658     }
   659     then show ?case using "4.hyps" by clarsimp
   660   }
   661 qed auto
   662 
   663 lemma polymul[simp]: "Ipoly bs (p *\<^sub>p q) = Ipoly bs p * Ipoly bs q"
   664   by (induct p q rule: polymul.induct) (auto simp add: field_simps)
   665 
   666 lemma polymul_normh:
   667   assumes "SORT_CONSTRAINT('a::{field_char_0,field_inverse_zero})"
   668   shows "isnpolyh p n0 \<Longrightarrow> isnpolyh q n1 \<Longrightarrow> isnpolyh (p *\<^sub>p q) (min n0 n1)"
   669   using polymul_properties(1) by blast
   670 
   671 lemma polymul_eq0_iff:
   672   assumes "SORT_CONSTRAINT('a::{field_char_0,field_inverse_zero})"
   673   shows "isnpolyh p n0 \<Longrightarrow> isnpolyh q n1 \<Longrightarrow> p *\<^sub>p q = 0\<^sub>p \<longleftrightarrow> p = 0\<^sub>p \<or> q = 0\<^sub>p"
   674   using polymul_properties(2) by blast
   675 
   676 lemma polymul_degreen:  (* FIXME duplicate? *)
   677   assumes "SORT_CONSTRAINT('a::{field_char_0,field_inverse_zero})"
   678   shows "isnpolyh p n0 \<Longrightarrow> isnpolyh q n1 \<Longrightarrow> m \<le> min n0 n1 \<Longrightarrow>
   679     degreen (p *\<^sub>p q) m = (if p = 0\<^sub>p \<or> q = 0\<^sub>p then 0 else degreen p m + degreen q m)"
   680   using polymul_properties(3) by blast
   681 
   682 lemma polymul_norm:
   683   assumes "SORT_CONSTRAINT('a::{field_char_0,field_inverse_zero})"
   684   shows "isnpoly p \<Longrightarrow> isnpoly q \<Longrightarrow> isnpoly (polymul p q)"
   685   using polymul_normh[of "p" "0" "q" "0"] isnpoly_def by simp
   686 
   687 lemma headconst_zero: "isnpolyh p n0 \<Longrightarrow> headconst p = 0\<^sub>N \<longleftrightarrow> p = 0\<^sub>p"
   688   by (induct p arbitrary: n0 rule: headconst.induct) auto
   689 
   690 lemma headconst_isnormNum: "isnpolyh p n0 \<Longrightarrow> isnormNum (headconst p)"
   691   by (induct p arbitrary: n0) auto
   692 
   693 lemma monic_eqI:
   694   assumes np: "isnpolyh p n0"
   695   shows "INum (headconst p) * Ipoly bs (fst (monic p)) =
   696     (Ipoly bs p ::'a::{field_char_0,field_inverse_zero, power})"
   697   unfolding monic_def Let_def
   698 proof (cases "headconst p = 0\<^sub>N", simp_all add: headconst_zero[OF np])
   699   let ?h = "headconst p"
   700   assume pz: "p \<noteq> 0\<^sub>p"
   701   {
   702     assume hz: "INum ?h = (0::'a)"
   703     from headconst_isnormNum[OF np] have norm: "isnormNum ?h" "isnormNum 0\<^sub>N" by simp_all
   704     from isnormNum_unique[where ?'a = 'a, OF norm] hz have "?h = 0\<^sub>N" by simp
   705     with headconst_zero[OF np] have "p =0\<^sub>p" by blast with pz have "False" by blast}
   706   then show "INum (headconst p) = (0::'a) \<longrightarrow> \<lparr>p\<rparr>\<^sub>p\<^bsup>bs\<^esup> = 0" by blast
   707 qed
   708 
   709 
   710 text{* polyneg is a negation and preserves normal forms *}
   711 
   712 lemma polyneg[simp]: "Ipoly bs (polyneg p) = - Ipoly bs p"
   713   by (induct p rule: polyneg.induct) auto
   714 
   715 lemma polyneg0: "isnpolyh p n \<Longrightarrow> (~\<^sub>p p) = 0\<^sub>p \<longleftrightarrow> p = 0\<^sub>p"
   716   by (induct p arbitrary: n rule: polyneg.induct) (auto simp add: Nneg_def)
   717 
   718 lemma polyneg_polyneg: "isnpolyh p n0 \<Longrightarrow> ~\<^sub>p (~\<^sub>p p) = p"
   719   by (induct p arbitrary: n0 rule: polyneg.induct) auto
   720 
   721 lemma polyneg_normh: "isnpolyh p n \<Longrightarrow> isnpolyh (polyneg p) n"
   722   by (induct p arbitrary: n rule: polyneg.induct) (auto simp add: polyneg0)
   723 
   724 lemma polyneg_norm: "isnpoly p \<Longrightarrow> isnpoly (polyneg p)"
   725   using isnpoly_def polyneg_normh by simp
   726 
   727 
   728 text{* polysub is a substraction and preserves normal forms *}
   729 
   730 lemma polysub[simp]: "Ipoly bs (polysub p q) = Ipoly bs p - Ipoly bs q"
   731   by (simp add: polysub_def)
   732 
   733 lemma polysub_normh: "isnpolyh p n0 \<Longrightarrow> isnpolyh q n1 \<Longrightarrow> isnpolyh (polysub p q) (min n0 n1)"
   734   by (simp add: polysub_def polyneg_normh polyadd_normh)
   735 
   736 lemma polysub_norm: "isnpoly p \<Longrightarrow> isnpoly q \<Longrightarrow> isnpoly (polysub p q)"
   737   using polyadd_norm polyneg_norm by (simp add: polysub_def)
   738 
   739 lemma polysub_same_0[simp]:
   740   assumes "SORT_CONSTRAINT('a::{field_char_0,field_inverse_zero})"
   741   shows "isnpolyh p n0 \<Longrightarrow> polysub p p = 0\<^sub>p"
   742   unfolding polysub_def split_def fst_conv snd_conv
   743   by (induct p arbitrary: n0) (auto simp add: Let_def Nsub0[simplified Nsub_def])
   744 
   745 lemma polysub_0:
   746   assumes "SORT_CONSTRAINT('a::{field_char_0,field_inverse_zero})"
   747   shows "isnpolyh p n0 \<Longrightarrow> isnpolyh q n1 \<Longrightarrow> p -\<^sub>p q = 0\<^sub>p \<longleftrightarrow> p = q"
   748   unfolding polysub_def split_def fst_conv snd_conv
   749   by (induct p q arbitrary: n0 n1 rule:polyadd.induct)
   750     (auto simp: Nsub0[simplified Nsub_def] Let_def)
   751 
   752 text{* polypow is a power function and preserves normal forms *}
   753 
   754 lemma polypow[simp]:
   755   "Ipoly bs (polypow n p) = (Ipoly bs p :: 'a::{field_char_0,field_inverse_zero}) ^ n"
   756 proof (induct n rule: polypow.induct)
   757   case 1
   758   then show ?case by simp
   759 next
   760   case (2 n)
   761   let ?q = "polypow ((Suc n) div 2) p"
   762   let ?d = "polymul ?q ?q"
   763   have "odd (Suc n) \<or> even (Suc n)" by simp
   764   moreover
   765   { assume odd: "odd (Suc n)"
   766     have th: "(Suc (Suc (Suc 0) * (Suc n div Suc (Suc 0)))) = Suc n div 2 + Suc n div 2 + 1"
   767       by arith
   768     from odd have "Ipoly bs (p ^\<^sub>p Suc n) = Ipoly bs (polymul p ?d)" by (simp add: Let_def)
   769     also have "\<dots> = (Ipoly bs p) * (Ipoly bs p)^(Suc n div 2)*(Ipoly bs p)^(Suc n div 2)"
   770       using "2.hyps" by simp
   771     also have "\<dots> = (Ipoly bs p) ^ (Suc n div 2 + Suc n div 2 + 1)"
   772       by (simp only: power_add power_one_right) simp
   773     also have "\<dots> = (Ipoly bs p) ^ (Suc (Suc (Suc 0) * (Suc n div Suc (Suc 0))))"
   774       by (simp only: th)
   775     finally have ?case
   776     using odd_nat_div_two_times_two_plus_one[OF odd, symmetric] by simp  }
   777   moreover
   778   { assume even: "even (Suc n)"
   779     have th: "(Suc (Suc 0)) * (Suc n div Suc (Suc 0)) = Suc n div 2 + Suc n div 2"
   780       by arith
   781     from even have "Ipoly bs (p ^\<^sub>p Suc n) = Ipoly bs ?d" by (simp add: Let_def)
   782     also have "\<dots> = (Ipoly bs p) ^ (Suc n div 2 + Suc n div 2)"
   783       using "2.hyps" apply (simp only: power_add) by simp
   784     finally have ?case using even_nat_div_two_times_two[OF even] by (simp only: th)}
   785   ultimately show ?case by blast
   786 qed
   787 
   788 lemma polypow_normh:
   789   assumes "SORT_CONSTRAINT('a::{field_char_0,field_inverse_zero})"
   790   shows "isnpolyh p n \<Longrightarrow> isnpolyh (polypow k p) n"
   791 proof (induct k arbitrary: n rule: polypow.induct)
   792   case (2 k n)
   793   let ?q = "polypow (Suc k div 2) p"
   794   let ?d = "polymul ?q ?q"
   795   from 2 have th1:"isnpolyh ?q n" and th2: "isnpolyh p n" by blast+
   796   from polymul_normh[OF th1 th1] have dn: "isnpolyh ?d n" by simp
   797   from polymul_normh[OF th2 dn] have on: "isnpolyh (polymul p ?d) n" by simp
   798   from dn on show ?case by (simp add: Let_def)
   799 qed auto
   800 
   801 lemma polypow_norm:
   802   assumes "SORT_CONSTRAINT('a::{field_char_0,field_inverse_zero})"
   803   shows "isnpoly p \<Longrightarrow> isnpoly (polypow k p)"
   804   by (simp add: polypow_normh isnpoly_def)
   805 
   806 text{* Finally the whole normalization *}
   807 
   808 lemma polynate [simp]:
   809   "Ipoly bs (polynate p) = (Ipoly bs p :: 'a ::{field_char_0,field_inverse_zero})"
   810   by (induct p rule:polynate.induct) auto
   811 
   812 lemma polynate_norm[simp]:
   813   assumes "SORT_CONSTRAINT('a::{field_char_0,field_inverse_zero})"
   814   shows "isnpoly (polynate p)"
   815   by (induct p rule: polynate.induct)
   816      (simp_all add: polyadd_norm polymul_norm polysub_norm polyneg_norm polypow_norm,
   817       simp_all add: isnpoly_def)
   818 
   819 text{* shift1 *}
   820 
   821 
   822 lemma shift1: "Ipoly bs (shift1 p) = Ipoly bs (Mul (Bound 0) p)"
   823   by (simp add: shift1_def)
   824 
   825 lemma shift1_isnpoly:
   826   assumes pn: "isnpoly p"
   827     and pnz: "p \<noteq> 0\<^sub>p"
   828   shows "isnpoly (shift1 p) "
   829   using pn pnz by (simp add: shift1_def isnpoly_def)
   830 
   831 lemma shift1_nz[simp]:"shift1 p \<noteq> 0\<^sub>p"
   832   by (simp add: shift1_def)
   833 lemma funpow_shift1_isnpoly:
   834   "\<lbrakk> isnpoly p ; p \<noteq> 0\<^sub>p\<rbrakk> \<Longrightarrow> isnpoly (funpow n shift1 p)"
   835   by (induct n arbitrary: p) (auto simp add: shift1_isnpoly funpow_swap1)
   836 
   837 lemma funpow_isnpolyh:
   838   assumes f: "\<And> p. isnpolyh p n \<Longrightarrow> isnpolyh (f p) n"
   839     and np: "isnpolyh p n"
   840   shows "isnpolyh (funpow k f p) n"
   841   using f np by (induct k arbitrary: p) auto
   842 
   843 lemma funpow_shift1:
   844   "(Ipoly bs (funpow n shift1 p) :: 'a :: {field_char_0,field_inverse_zero}) =
   845     Ipoly bs (Mul (Pw (Bound 0) n) p)"
   846   by (induct n arbitrary: p) (simp_all add: shift1_isnpoly shift1)
   847 
   848 lemma shift1_isnpolyh: "isnpolyh p n0 \<Longrightarrow> p\<noteq> 0\<^sub>p \<Longrightarrow> isnpolyh (shift1 p) 0"
   849   using isnpolyh_mono[where n="n0" and n'="0" and p="p"] by (simp add: shift1_def)
   850 
   851 lemma funpow_shift1_1:
   852   "(Ipoly bs (funpow n shift1 p) :: 'a :: {field_char_0,field_inverse_zero}) =
   853     Ipoly bs (funpow n shift1 (1)\<^sub>p *\<^sub>p p)"
   854   by (simp add: funpow_shift1)
   855 
   856 lemma poly_cmul[simp]: "Ipoly bs (poly_cmul c p) = Ipoly bs (Mul (C c) p)"
   857   by (induct p rule: poly_cmul.induct) (auto simp add: field_simps)
   858 
   859 lemma behead:
   860   assumes np: "isnpolyh p n"
   861   shows "Ipoly bs (Add (Mul (head p) (Pw (Bound 0) (degree p))) (behead p)) =
   862     (Ipoly bs p :: 'a :: {field_char_0,field_inverse_zero})"
   863   using np
   864 proof (induct p arbitrary: n rule: behead.induct)
   865   case (1 c p n)
   866   then have pn: "isnpolyh p n" by simp
   867   from 1(1)[OF pn]
   868   have th:"Ipoly bs (Add (Mul (head p) (Pw (Bound 0) (degree p))) (behead p)) = Ipoly bs p" .
   869   then show ?case using "1.hyps"
   870     apply (simp add: Let_def,cases "behead p = 0\<^sub>p")
   871     apply (simp_all add: th[symmetric] field_simps)
   872     done
   873 qed (auto simp add: Let_def)
   874 
   875 lemma behead_isnpolyh:
   876   assumes np: "isnpolyh p n"
   877   shows "isnpolyh (behead p) n"
   878   using np by (induct p rule: behead.induct) (auto simp add: Let_def isnpolyh_mono)
   879 
   880 
   881 subsection{* Miscellaneous lemmas about indexes, decrementation, substitution  etc ... *}
   882 
   883 lemma isnpolyh_polybound0: "isnpolyh p (Suc n) \<Longrightarrow> polybound0 p"
   884 proof (induct p arbitrary: n rule: poly.induct, auto)
   885   case (goal1 c n p n')
   886   then have "n = Suc (n - 1)"
   887     by simp
   888   then have "isnpolyh p (Suc (n - 1))"
   889     using `isnpolyh p n` by simp
   890   with goal1(2) show ?case
   891     by simp
   892 qed
   893 
   894 lemma isconstant_polybound0: "isnpolyh p n0 \<Longrightarrow> isconstant p \<longleftrightarrow> polybound0 p"
   895   by (induct p arbitrary: n0 rule: isconstant.induct) (auto simp add: isnpolyh_polybound0)
   896 
   897 lemma decrpoly_zero[simp]: "decrpoly p = 0\<^sub>p \<longleftrightarrow> p = 0\<^sub>p"
   898   by (induct p) auto
   899 
   900 lemma decrpoly_normh: "isnpolyh p n0 \<Longrightarrow> polybound0 p \<Longrightarrow> isnpolyh (decrpoly p) (n0 - 1)"
   901   apply (induct p arbitrary: n0)
   902   apply auto
   903   apply (atomize)
   904   apply (erule_tac x = "Suc nat" in allE)
   905   apply auto
   906   done
   907 
   908 lemma head_polybound0: "isnpolyh p n0 \<Longrightarrow> polybound0 (head p)"
   909   by (induct p  arbitrary: n0 rule: head.induct) (auto intro: isnpolyh_polybound0)
   910 
   911 lemma polybound0_I:
   912   assumes nb: "polybound0 a"
   913   shows "Ipoly (b # bs) a = Ipoly (b' # bs) a"
   914   using nb
   915   by (induct a rule: poly.induct) auto
   916 
   917 lemma polysubst0_I: "Ipoly (b # bs) (polysubst0 a t) = Ipoly ((Ipoly (b # bs) a) # bs) t"
   918   by (induct t) simp_all
   919 
   920 lemma polysubst0_I':
   921   assumes nb: "polybound0 a"
   922   shows "Ipoly (b # bs) (polysubst0 a t) = Ipoly ((Ipoly (b' # bs) a) # bs) t"
   923   by (induct t) (simp_all add: polybound0_I[OF nb, where b="b" and b'="b'"])
   924 
   925 lemma decrpoly:
   926   assumes nb: "polybound0 t"
   927   shows "Ipoly (x#bs) t = Ipoly bs (decrpoly t)"
   928   using nb by (induct t rule: decrpoly.induct) simp_all
   929 
   930 lemma polysubst0_polybound0:
   931   assumes nb: "polybound0 t"
   932   shows "polybound0 (polysubst0 t a)"
   933   using nb by (induct a rule: poly.induct) auto
   934 
   935 lemma degree0_polybound0: "isnpolyh p n \<Longrightarrow> degree p = 0 \<Longrightarrow> polybound0 p"
   936   by (induct p arbitrary: n rule: degree.induct) (auto simp add: isnpolyh_polybound0)
   937 
   938 primrec maxindex :: "poly \<Rightarrow> nat" where
   939   "maxindex (Bound n) = n + 1"
   940 | "maxindex (CN c n p) = max  (n + 1) (max (maxindex c) (maxindex p))"
   941 | "maxindex (Add p q) = max (maxindex p) (maxindex q)"
   942 | "maxindex (Sub p q) = max (maxindex p) (maxindex q)"
   943 | "maxindex (Mul p q) = max (maxindex p) (maxindex q)"
   944 | "maxindex (Neg p) = maxindex p"
   945 | "maxindex (Pw p n) = maxindex p"
   946 | "maxindex (C x) = 0"
   947 
   948 definition wf_bs :: "'a list \<Rightarrow> poly \<Rightarrow> bool"
   949   where "wf_bs bs p \<longleftrightarrow> length bs \<ge> maxindex p"
   950 
   951 lemma wf_bs_coefficients: "wf_bs bs p \<Longrightarrow> \<forall> c \<in> set (coefficients p). wf_bs bs c"
   952 proof (induct p rule: coefficients.induct)
   953   case (1 c p)
   954   show ?case
   955   proof
   956     fix x
   957     assume xc: "x \<in> set (coefficients (CN c 0 p))"
   958     then have "x = c \<or> x \<in> set (coefficients p)"
   959       by simp
   960     moreover
   961     {
   962       assume "x = c"
   963       then have "wf_bs bs x"
   964         using "1.prems"  unfolding wf_bs_def by simp
   965     }
   966     moreover
   967     {
   968       assume H: "x \<in> set (coefficients p)"
   969       from "1.prems" have "wf_bs bs p"
   970         unfolding wf_bs_def by simp
   971       with "1.hyps" H have "wf_bs bs x"
   972         by blast
   973     }
   974     ultimately  show "wf_bs bs x"
   975       by blast
   976   qed
   977 qed simp_all
   978 
   979 lemma maxindex_coefficients: "\<forall>c\<in> set (coefficients p). maxindex c \<le> maxindex p"
   980   by (induct p rule: coefficients.induct) auto
   981 
   982 lemma wf_bs_I: "wf_bs bs p \<Longrightarrow> Ipoly (bs @ bs') p = Ipoly bs p"
   983   unfolding wf_bs_def by (induct p) (auto simp add: nth_append)
   984 
   985 lemma take_maxindex_wf:
   986   assumes wf: "wf_bs bs p"
   987   shows "Ipoly (take (maxindex p) bs) p = Ipoly bs p"
   988 proof -
   989   let ?ip = "maxindex p"
   990   let ?tbs = "take ?ip bs"
   991   from wf have "length ?tbs = ?ip"
   992     unfolding wf_bs_def by simp
   993   then have wf': "wf_bs ?tbs p"
   994     unfolding wf_bs_def by  simp
   995   have eq: "bs = ?tbs @ (drop ?ip bs)"
   996     by simp
   997   from wf_bs_I[OF wf', of "drop ?ip bs"] show ?thesis
   998     using eq by simp
   999 qed
  1000 
  1001 lemma decr_maxindex: "polybound0 p \<Longrightarrow> maxindex (decrpoly p) = maxindex p - 1"
  1002   by (induct p) auto
  1003 
  1004 lemma wf_bs_insensitive: "length bs = length bs' \<Longrightarrow> wf_bs bs p = wf_bs bs' p"
  1005   unfolding wf_bs_def by simp
  1006 
  1007 lemma wf_bs_insensitive': "wf_bs (x#bs) p = wf_bs (y#bs) p"
  1008   unfolding wf_bs_def by simp
  1009 
  1010 
  1011 
  1012 lemma wf_bs_coefficients': "\<forall>c \<in> set (coefficients p). wf_bs bs c \<Longrightarrow> wf_bs (x#bs) p"
  1013   by (induct p rule: coefficients.induct) (auto simp add: wf_bs_def)
  1014 lemma coefficients_Nil[simp]: "coefficients p \<noteq> []"
  1015   by (induct p rule: coefficients.induct) simp_all
  1016 
  1017 
  1018 lemma coefficients_head: "last (coefficients p) = head p"
  1019   by (induct p rule: coefficients.induct) auto
  1020 
  1021 lemma wf_bs_decrpoly: "wf_bs bs (decrpoly p) \<Longrightarrow> wf_bs (x#bs) p"
  1022   unfolding wf_bs_def by (induct p rule: decrpoly.induct) auto
  1023 
  1024 lemma length_le_list_ex: "length xs \<le> n \<Longrightarrow> \<exists> ys. length (xs @ ys) = n"
  1025   apply (rule exI[where x="replicate (n - length xs) z"])
  1026   apply simp
  1027   done
  1028 
  1029 lemma isnpolyh_Suc_const:"isnpolyh p (Suc n) \<Longrightarrow> isconstant p"
  1030   apply (cases p)
  1031   apply auto
  1032   apply (case_tac "nat")
  1033   apply simp_all
  1034   done
  1035 
  1036 lemma wf_bs_polyadd: "wf_bs bs p \<and> wf_bs bs q \<longrightarrow> wf_bs bs (p +\<^sub>p q)"
  1037   unfolding wf_bs_def
  1038   apply (induct p q rule: polyadd.induct)
  1039   apply (auto simp add: Let_def)
  1040   done
  1041 
  1042 lemma wf_bs_polyul: "wf_bs bs p \<Longrightarrow> wf_bs bs q \<Longrightarrow> wf_bs bs (p *\<^sub>p q)"
  1043   unfolding wf_bs_def
  1044   apply (induct p q arbitrary: bs rule: polymul.induct)
  1045   apply (simp_all add: wf_bs_polyadd)
  1046   apply clarsimp
  1047   apply (rule wf_bs_polyadd[unfolded wf_bs_def, rule_format])
  1048   apply auto
  1049   done
  1050 
  1051 lemma wf_bs_polyneg: "wf_bs bs p \<Longrightarrow> wf_bs bs (~\<^sub>p p)"
  1052   unfolding wf_bs_def by (induct p rule: polyneg.induct) auto
  1053 
  1054 lemma wf_bs_polysub: "wf_bs bs p \<Longrightarrow> wf_bs bs q \<Longrightarrow> wf_bs bs (p -\<^sub>p q)"
  1055   unfolding polysub_def split_def fst_conv snd_conv using wf_bs_polyadd wf_bs_polyneg by blast
  1056 
  1057 
  1058 subsection{* Canonicity of polynomial representation, see lemma isnpolyh_unique*}
  1059 
  1060 definition "polypoly bs p = map (Ipoly bs) (coefficients p)"
  1061 definition "polypoly' bs p = map ((Ipoly bs o decrpoly)) (coefficients p)"
  1062 definition "poly_nate bs p = map ((Ipoly bs o decrpoly)) (coefficients (polynate p))"
  1063 
  1064 lemma coefficients_normh: "isnpolyh p n0 \<Longrightarrow> \<forall> q \<in> set (coefficients p). isnpolyh q n0"
  1065 proof (induct p arbitrary: n0 rule: coefficients.induct)
  1066   case (1 c p n0)
  1067   have cp: "isnpolyh (CN c 0 p) n0"
  1068     by fact
  1069   then have norm: "isnpolyh c 0" "isnpolyh p 0" "p \<noteq> 0\<^sub>p" "n0 = 0"
  1070     by (auto simp add: isnpolyh_mono[where n'=0])
  1071   from "1.hyps"[OF norm(2)] norm(1) norm(4) show ?case
  1072     by simp
  1073 qed auto
  1074 
  1075 lemma coefficients_isconst:
  1076   "isnpolyh p n \<Longrightarrow> \<forall>q\<in>set (coefficients p). isconstant q"
  1077   by (induct p arbitrary: n rule: coefficients.induct)
  1078     (auto simp add: isnpolyh_Suc_const)
  1079 
  1080 lemma polypoly_polypoly':
  1081   assumes np: "isnpolyh p n0"
  1082   shows "polypoly (x#bs) p = polypoly' bs p"
  1083 proof-
  1084   let ?cf = "set (coefficients p)"
  1085   from coefficients_normh[OF np] have cn_norm: "\<forall> q\<in> ?cf. isnpolyh q n0" .
  1086   {fix q assume q: "q \<in> ?cf"
  1087     from q cn_norm have th: "isnpolyh q n0" by blast
  1088     from coefficients_isconst[OF np] q have "isconstant q" by blast
  1089     with isconstant_polybound0[OF th] have "polybound0 q" by blast}
  1090   then have "\<forall>q \<in> ?cf. polybound0 q" ..
  1091   then have "\<forall>q \<in> ?cf. Ipoly (x#bs) q = Ipoly bs (decrpoly q)"
  1092     using polybound0_I[where b=x and bs=bs and b'=y] decrpoly[where x=x and bs=bs]
  1093     by auto
  1094   then show ?thesis unfolding polypoly_def polypoly'_def by simp
  1095 qed
  1096 
  1097 lemma polypoly_poly:
  1098   assumes np: "isnpolyh p n0"
  1099   shows "Ipoly (x#bs) p = poly (polypoly (x#bs) p) x"
  1100   using np
  1101   by (induct p arbitrary: n0 bs rule: coefficients.induct) (auto simp add: polypoly_def)
  1102 
  1103 lemma polypoly'_poly:
  1104   assumes np: "isnpolyh p n0"
  1105   shows "\<lparr>p\<rparr>\<^sub>p\<^bsup>x # bs\<^esup> = poly (polypoly' bs p) x"
  1106   using polypoly_poly[OF np, simplified polypoly_polypoly'[OF np]] .
  1107 
  1108 
  1109 lemma polypoly_poly_polybound0:
  1110   assumes np: "isnpolyh p n0" and nb: "polybound0 p"
  1111   shows "polypoly bs p = [Ipoly bs p]"
  1112   using np nb unfolding polypoly_def
  1113   apply (cases p)
  1114   apply auto
  1115   apply (case_tac nat)
  1116   apply auto
  1117   done
  1118 
  1119 lemma head_isnpolyh: "isnpolyh p n0 \<Longrightarrow> isnpolyh (head p) n0"
  1120   by (induct p rule: head.induct) auto
  1121 
  1122 lemma headn_nz[simp]: "isnpolyh p n0 \<Longrightarrow> (headn p m = 0\<^sub>p) = (p = 0\<^sub>p)"
  1123   by (cases p) auto
  1124 
  1125 lemma head_eq_headn0: "head p = headn p 0"
  1126   by (induct p rule: head.induct) simp_all
  1127 
  1128 lemma head_nz[simp]: "isnpolyh p n0 \<Longrightarrow> (head p = 0\<^sub>p) = (p = 0\<^sub>p)"
  1129   by (simp add: head_eq_headn0)
  1130 
  1131 lemma isnpolyh_zero_iff:
  1132   assumes nq: "isnpolyh p n0"
  1133     and eq :"\<forall>bs. wf_bs bs p \<longrightarrow> \<lparr>p\<rparr>\<^sub>p\<^bsup>bs\<^esup> = (0::'a::{field_char_0,field_inverse_zero, power})"
  1134   shows "p = 0\<^sub>p"
  1135   using nq eq
  1136 proof (induct "maxindex p" arbitrary: p n0 rule: less_induct)
  1137   case less
  1138   note np = `isnpolyh p n0` and zp = `\<forall>bs. wf_bs bs p \<longrightarrow> \<lparr>p\<rparr>\<^sub>p\<^bsup>bs\<^esup> = (0::'a)`
  1139   {
  1140     assume nz: "maxindex p = 0"
  1141     then obtain c where "p = C c"
  1142       using np by (cases p) auto
  1143     with zp np have "p = 0\<^sub>p"
  1144       unfolding wf_bs_def by simp
  1145   }
  1146   moreover
  1147   {
  1148     assume nz: "maxindex p \<noteq> 0"
  1149     let ?h = "head p"
  1150     let ?hd = "decrpoly ?h"
  1151     let ?ihd = "maxindex ?hd"
  1152     from head_isnpolyh[OF np] head_polybound0[OF np]
  1153     have h: "isnpolyh ?h n0" "polybound0 ?h"
  1154       by simp_all
  1155     then have nhd: "isnpolyh ?hd (n0 - 1)"
  1156       using decrpoly_normh by blast
  1157 
  1158     from maxindex_coefficients[of p] coefficients_head[of p, symmetric]
  1159     have mihn: "maxindex ?h \<le> maxindex p"
  1160       by auto
  1161     with decr_maxindex[OF h(2)] nz have ihd_lt_n: "?ihd < maxindex p"
  1162       by auto
  1163     {
  1164       fix bs :: "'a list"
  1165       assume bs: "wf_bs bs ?hd"
  1166       let ?ts = "take ?ihd bs"
  1167       let ?rs = "drop ?ihd bs"
  1168       have ts: "wf_bs ?ts ?hd"
  1169         using bs unfolding wf_bs_def by simp
  1170       have bs_ts_eq: "?ts @ ?rs = bs"
  1171         by simp
  1172       from wf_bs_decrpoly[OF ts] have tsh: " \<forall>x. wf_bs (x # ?ts) ?h"
  1173         by simp
  1174       from ihd_lt_n have "\<forall>x. length (x # ?ts) \<le> maxindex p"
  1175         by simp
  1176       with length_le_list_ex obtain xs where xs: "length ((x # ?ts) @ xs) = maxindex p"
  1177         by blast
  1178       then have "\<forall>x. wf_bs ((x # ?ts) @ xs) p"
  1179         unfolding wf_bs_def by simp
  1180       with zp have "\<forall>x. Ipoly ((x # ?ts) @ xs) p = 0"
  1181         by blast
  1182       then have "\<forall>x. Ipoly (x # (?ts @ xs)) p = 0"
  1183         by simp
  1184       with polypoly_poly[OF np, where ?'a = 'a] polypoly_polypoly'[OF np, where ?'a = 'a]
  1185       have "\<forall>x. poly (polypoly' (?ts @ xs) p) x = poly [] x"
  1186         by simp
  1187       then have "poly (polypoly' (?ts @ xs) p) = poly []"
  1188         by auto
  1189       then have "\<forall>c \<in> set (coefficients p). Ipoly (?ts @ xs) (decrpoly c) = 0"
  1190         using poly_zero[where ?'a='a] by (simp add: polypoly'_def list_all_iff)
  1191       with coefficients_head[of p, symmetric]
  1192       have th0: "Ipoly (?ts @ xs) ?hd = 0"
  1193         by simp
  1194       from bs have wf'': "wf_bs ?ts ?hd"
  1195         unfolding wf_bs_def by simp
  1196       with th0 wf_bs_I[of ?ts ?hd xs] have "Ipoly ?ts ?hd = 0"
  1197         by simp
  1198       with wf'' wf_bs_I[of ?ts ?hd ?rs] bs_ts_eq have "\<lparr>?hd\<rparr>\<^sub>p\<^bsup>bs\<^esup> = 0"
  1199         by simp
  1200     }
  1201     then have hdz: "\<forall>bs. wf_bs bs ?hd \<longrightarrow> \<lparr>?hd\<rparr>\<^sub>p\<^bsup>bs\<^esup> = (0::'a)"
  1202       by blast
  1203     from less(1)[OF ihd_lt_n nhd] hdz have "?hd = 0\<^sub>p"
  1204       by blast
  1205     then have "?h = 0\<^sub>p" by simp
  1206     with head_nz[OF np] have "p = 0\<^sub>p" by simp
  1207   }
  1208   ultimately show "p = 0\<^sub>p"
  1209     by blast
  1210 qed
  1211 
  1212 lemma isnpolyh_unique:
  1213   assumes np: "isnpolyh p n0"
  1214     and nq: "isnpolyh q n1"
  1215   shows "(\<forall>bs. \<lparr>p\<rparr>\<^sub>p\<^bsup>bs\<^esup> = (\<lparr>q\<rparr>\<^sub>p\<^bsup>bs\<^esup> :: 'a::{field_char_0,field_inverse_zero,power})) \<longleftrightarrow> p = q"
  1216 proof auto
  1217   assume H: "\<forall>bs. (\<lparr>p\<rparr>\<^sub>p\<^bsup>bs\<^esup> ::'a) = \<lparr>q\<rparr>\<^sub>p\<^bsup>bs\<^esup>"
  1218   then have "\<forall>bs.\<lparr>p -\<^sub>p q\<rparr>\<^sub>p\<^bsup>bs\<^esup>= (0::'a)"
  1219     by simp
  1220   then have "\<forall>bs. wf_bs bs (p -\<^sub>p q) \<longrightarrow> \<lparr>p -\<^sub>p q\<rparr>\<^sub>p\<^bsup>bs\<^esup> = (0::'a)"
  1221     using wf_bs_polysub[where p=p and q=q] by auto
  1222   with isnpolyh_zero_iff[OF polysub_normh[OF np nq]] polysub_0[OF np nq] show "p = q"
  1223     by blast
  1224 qed
  1225 
  1226 
  1227 text{* consequences of unicity on the algorithms for polynomial normalization *}
  1228 
  1229 lemma polyadd_commute:
  1230   assumes "SORT_CONSTRAINT('a::{field_char_0,field_inverse_zero})"
  1231     and np: "isnpolyh p n0"
  1232     and nq: "isnpolyh q n1"
  1233   shows "p +\<^sub>p q = q +\<^sub>p p"
  1234   using isnpolyh_unique[OF polyadd_normh[OF np nq] polyadd_normh[OF nq np]]
  1235   by simp
  1236 
  1237 lemma zero_normh: "isnpolyh 0\<^sub>p n"
  1238   by simp
  1239 
  1240 lemma one_normh: "isnpolyh (1)\<^sub>p n"
  1241   by simp
  1242 
  1243 lemma polyadd_0[simp]:
  1244   assumes "SORT_CONSTRAINT('a::{field_char_0,field_inverse_zero})"
  1245     and np: "isnpolyh p n0"
  1246   shows "p +\<^sub>p 0\<^sub>p = p"
  1247     and "0\<^sub>p +\<^sub>p p = p"
  1248   using isnpolyh_unique[OF polyadd_normh[OF np zero_normh] np]
  1249     isnpolyh_unique[OF polyadd_normh[OF zero_normh np] np] by simp_all
  1250 
  1251 lemma polymul_1[simp]:
  1252   assumes "SORT_CONSTRAINT('a::{field_char_0,field_inverse_zero})"
  1253     and np: "isnpolyh p n0"
  1254   shows "p *\<^sub>p (1)\<^sub>p = p"
  1255     and "(1)\<^sub>p *\<^sub>p p = p"
  1256   using isnpolyh_unique[OF polymul_normh[OF np one_normh] np]
  1257     isnpolyh_unique[OF polymul_normh[OF one_normh np] np] by simp_all
  1258 
  1259 lemma polymul_0[simp]:
  1260   assumes "SORT_CONSTRAINT('a::{field_char_0,field_inverse_zero})"
  1261     and np: "isnpolyh p n0"
  1262   shows "p *\<^sub>p 0\<^sub>p = 0\<^sub>p"
  1263     and "0\<^sub>p *\<^sub>p p = 0\<^sub>p"
  1264   using isnpolyh_unique[OF polymul_normh[OF np zero_normh] zero_normh]
  1265     isnpolyh_unique[OF polymul_normh[OF zero_normh np] zero_normh] by simp_all
  1266 
  1267 lemma polymul_commute:
  1268   assumes "SORT_CONSTRAINT('a::{field_char_0,field_inverse_zero})"
  1269     and np: "isnpolyh p n0"
  1270     and nq: "isnpolyh q n1"
  1271   shows "p *\<^sub>p q = q *\<^sub>p p"
  1272   using isnpolyh_unique[OF polymul_normh[OF np nq] polymul_normh[OF nq np], where ?'a = "'a::{field_char_0,field_inverse_zero, power}"]
  1273   by simp
  1274 
  1275 declare polyneg_polyneg [simp]
  1276 
  1277 lemma isnpolyh_polynate_id [simp]:
  1278   assumes "SORT_CONSTRAINT('a::{field_char_0,field_inverse_zero})"
  1279     and np: "isnpolyh p n0"
  1280   shows "polynate p = p"
  1281   using isnpolyh_unique[where ?'a= "'a::{field_char_0,field_inverse_zero}", OF polynate_norm[of p, unfolded isnpoly_def] np] polynate[where ?'a = "'a::{field_char_0,field_inverse_zero}"]
  1282   by simp
  1283 
  1284 lemma polynate_idempotent[simp]:
  1285   assumes "SORT_CONSTRAINT('a::{field_char_0,field_inverse_zero})"
  1286   shows "polynate (polynate p) = polynate p"
  1287   using isnpolyh_polynate_id[OF polynate_norm[of p, unfolded isnpoly_def]] .
  1288 
  1289 lemma poly_nate_polypoly': "poly_nate bs p = polypoly' bs (polynate p)"
  1290   unfolding poly_nate_def polypoly'_def ..
  1291 
  1292 lemma poly_nate_poly:
  1293   "poly (poly_nate bs p) = (\<lambda>x:: 'a ::{field_char_0,field_inverse_zero}. \<lparr>p\<rparr>\<^sub>p\<^bsup>x # bs\<^esup>)"
  1294   using polypoly'_poly[OF polynate_norm[unfolded isnpoly_def], symmetric, of bs p]
  1295   unfolding poly_nate_polypoly' by auto
  1296 
  1297 
  1298 subsection{* heads, degrees and all that *}
  1299 
  1300 lemma degree_eq_degreen0: "degree p = degreen p 0"
  1301   by (induct p rule: degree.induct) simp_all
  1302 
  1303 lemma degree_polyneg:
  1304   assumes n: "isnpolyh p n"
  1305   shows "degree (polyneg p) = degree p"
  1306   apply (induct p arbitrary: n rule: polyneg.induct)
  1307   using n apply simp_all
  1308   apply (case_tac na)
  1309   apply auto
  1310   done
  1311 
  1312 lemma degree_polyadd:
  1313   assumes np: "isnpolyh p n0" and nq: "isnpolyh q n1"
  1314   shows "degree (p +\<^sub>p q) \<le> max (degree p) (degree q)"
  1315   using degreen_polyadd[OF np nq, where m= "0"] degree_eq_degreen0 by simp
  1316 
  1317 
  1318 lemma degree_polysub:
  1319   assumes np: "isnpolyh p n0"
  1320     and nq: "isnpolyh q n1"
  1321   shows "degree (p -\<^sub>p q) \<le> max (degree p) (degree q)"
  1322 proof-
  1323   from nq have nq': "isnpolyh (~\<^sub>p q) n1" using polyneg_normh by simp
  1324   from degree_polyadd[OF np nq'] show ?thesis by (simp add: polysub_def degree_polyneg[OF nq])
  1325 qed
  1326 
  1327 lemma degree_polysub_samehead:
  1328   assumes "SORT_CONSTRAINT('a::{field_char_0,field_inverse_zero})"
  1329     and np: "isnpolyh p n0" and nq: "isnpolyh q n1" and h: "head p = head q"
  1330     and d: "degree p = degree q"
  1331   shows "degree (p -\<^sub>p q) < degree p \<or> (p -\<^sub>p q = 0\<^sub>p)"
  1332   unfolding polysub_def split_def fst_conv snd_conv
  1333   using np nq h d
  1334 proof (induct p q rule: polyadd.induct)
  1335   case (1 c c')
  1336   then show ?case
  1337     by (simp add: Nsub_def Nsub0[simplified Nsub_def])
  1338 next
  1339   case (2 c c' n' p')
  1340   from 2 have "degree (C c) = degree (CN c' n' p')"
  1341     by simp
  1342   then have nz: "n' > 0"
  1343     by (cases n') auto
  1344   then have "head (CN c' n' p') = CN c' n' p'"
  1345     by (cases n') auto
  1346   with 2 show ?case
  1347     by simp
  1348 next
  1349   case (3 c n p c')
  1350   then have "degree (C c') = degree (CN c n p)"
  1351     by simp
  1352   then have nz: "n > 0"
  1353     by (cases n) auto
  1354   then have "head (CN c n p) = CN c n p"
  1355     by (cases n) auto
  1356   with 3 show ?case by simp
  1357 next
  1358   case (4 c n p c' n' p')
  1359   then have H:
  1360     "isnpolyh (CN c n p) n0"
  1361     "isnpolyh (CN c' n' p') n1"
  1362     "head (CN c n p) = head (CN c' n' p')"
  1363     "degree (CN c n p) = degree (CN c' n' p')"
  1364     by simp_all
  1365   then have degc: "degree c = 0" and degc': "degree c' = 0"
  1366     by simp_all
  1367   then have degnc: "degree (~\<^sub>p c) = 0" and degnc': "degree (~\<^sub>p c') = 0"
  1368     using H(1-2) degree_polyneg by auto
  1369   from H have cnh: "isnpolyh c (Suc n)" and c'nh: "isnpolyh c' (Suc n')"
  1370     by simp_all
  1371   from degree_polysub[OF cnh c'nh, simplified polysub_def] degc degc'
  1372   have degcmc': "degree (c +\<^sub>p  ~\<^sub>pc') = 0"
  1373     by simp
  1374   from H have pnh: "isnpolyh p n" and p'nh: "isnpolyh p' n'"
  1375     by auto
  1376   have "n = n' \<or> n < n' \<or> n > n'"
  1377     by arith
  1378   moreover
  1379   {
  1380     assume nn': "n = n'"
  1381     have "n = 0 \<or> n > 0" by arith
  1382     moreover {
  1383       assume nz: "n = 0"
  1384       then have ?case using 4 nn'
  1385         by (auto simp add: Let_def degcmc')
  1386     }
  1387     moreover {
  1388       assume nz: "n > 0"
  1389       with nn' H(3) have  cc': "c = c'" and pp': "p = p'"
  1390         by (cases n, auto)+
  1391       then have ?case
  1392         using polysub_same_0[OF p'nh, simplified polysub_def split_def fst_conv snd_conv]
  1393         using polysub_same_0[OF c'nh, simplified polysub_def]
  1394         using nn' 4 by (simp add: Let_def)
  1395     }
  1396     ultimately have ?case by blast
  1397   }
  1398   moreover
  1399   {
  1400     assume nn': "n < n'"
  1401     then have n'p: "n' > 0"
  1402       by simp
  1403     then have headcnp':"head (CN c' n' p') = CN c' n' p'"
  1404       by (cases n') simp_all
  1405     have degcnp': "degree (CN c' n' p') = 0"
  1406       and degcnpeq: "degree (CN c n p) = degree (CN c' n' p')"
  1407       using 4 nn' by (cases n', simp_all)
  1408     then have "n > 0"
  1409       by (cases n) simp_all
  1410     then have headcnp: "head (CN c n p) = CN c n p"
  1411       by (cases n) auto
  1412     from H(3) headcnp headcnp' nn' have ?case
  1413       by auto
  1414   }
  1415   moreover
  1416   {
  1417     assume nn': "n > n'"
  1418     then have np: "n > 0" by simp
  1419     then have headcnp:"head (CN c n p) = CN c n p"
  1420       by (cases n) simp_all
  1421     from 4 have degcnpeq: "degree (CN c' n' p') = degree (CN c n p)"
  1422       by simp
  1423     from np have degcnp: "degree (CN c n p) = 0"
  1424       by (cases n) simp_all
  1425     with degcnpeq have "n' > 0"
  1426       by (cases n') simp_all
  1427     then have headcnp': "head (CN c' n' p') = CN c' n' p'"
  1428       by (cases n') auto
  1429     from H(3) headcnp headcnp' nn' have ?case by auto
  1430   }
  1431   ultimately show ?case by blast
  1432 qed auto
  1433 
  1434 lemma shift1_head : "isnpolyh p n0 \<Longrightarrow> head (shift1 p) = head p"
  1435   by (induct p arbitrary: n0 rule: head.induct) (simp_all add: shift1_def)
  1436 
  1437 lemma funpow_shift1_head: "isnpolyh p n0 \<Longrightarrow> p\<noteq> 0\<^sub>p \<Longrightarrow> head (funpow k shift1 p) = head p"
  1438 proof (induct k arbitrary: n0 p)
  1439   case 0
  1440   then show ?case by auto
  1441 next
  1442   case (Suc k n0 p)
  1443   then have "isnpolyh (shift1 p) 0" by (simp add: shift1_isnpolyh)
  1444   with Suc have "head (funpow k shift1 (shift1 p)) = head (shift1 p)"
  1445     and "head (shift1 p) = head p" by (simp_all add: shift1_head)
  1446   then show ?case by (simp add: funpow_swap1)
  1447 qed
  1448 
  1449 lemma shift1_degree: "degree (shift1 p) = 1 + degree p"
  1450   by (simp add: shift1_def)
  1451 
  1452 lemma funpow_shift1_degree: "degree (funpow k shift1 p) = k + degree p "
  1453   by (induct k arbitrary: p) (auto simp add: shift1_degree)
  1454 
  1455 lemma funpow_shift1_nz: "p \<noteq> 0\<^sub>p \<Longrightarrow> funpow n shift1 p \<noteq> 0\<^sub>p"
  1456   by (induct n arbitrary: p) simp_all
  1457 
  1458 lemma head_isnpolyh_Suc[simp]: "isnpolyh p (Suc n) \<Longrightarrow> head p = p"
  1459   by (induct p arbitrary: n rule: degree.induct) auto
  1460 lemma headn_0[simp]: "isnpolyh p n \<Longrightarrow> m < n \<Longrightarrow> headn p m = p"
  1461   by (induct p arbitrary: n rule: degreen.induct) auto
  1462 lemma head_isnpolyh_Suc': "n > 0 \<Longrightarrow> isnpolyh p n \<Longrightarrow> head p = p"
  1463   by (induct p arbitrary: n rule: degree.induct) auto
  1464 lemma head_head[simp]: "isnpolyh p n0 \<Longrightarrow> head (head p) = head p"
  1465   by (induct p rule: head.induct) auto
  1466 
  1467 lemma polyadd_eq_const_degree:
  1468   "isnpolyh p n0 \<Longrightarrow> isnpolyh q n1 \<Longrightarrow> polyadd p q = C c \<Longrightarrow> degree p = degree q"
  1469   using polyadd_eq_const_degreen degree_eq_degreen0 by simp
  1470 
  1471 lemma polyadd_head:
  1472   assumes np: "isnpolyh p n0"
  1473     and nq: "isnpolyh q n1"
  1474     and deg: "degree p \<noteq> degree q"
  1475   shows "head (p +\<^sub>p q) = (if degree p < degree q then head q else head p)"
  1476   using np nq deg
  1477   apply (induct p q arbitrary: n0 n1 rule: polyadd.induct)
  1478   using np
  1479   apply simp_all
  1480   apply (case_tac n', simp, simp)
  1481   apply (case_tac n, simp, simp)
  1482   apply (case_tac n, case_tac n', simp add: Let_def)
  1483   apply (auto simp add: polyadd_eq_const_degree)[2]
  1484   apply (metis head_nz)
  1485   apply (metis head_nz)
  1486   apply (metis degree.simps(9) gr0_conv_Suc head.simps(1) less_Suc0 not_less_eq)
  1487   done
  1488 
  1489 lemma polymul_head_polyeq:
  1490   assumes "SORT_CONSTRAINT('a::{field_char_0,field_inverse_zero})"
  1491   shows "\<lbrakk>isnpolyh p n0; isnpolyh q n1 ; p \<noteq> 0\<^sub>p ; q \<noteq> 0\<^sub>p \<rbrakk> \<Longrightarrow> head (p *\<^sub>p q) = head p *\<^sub>p head q"
  1492 proof (induct p q arbitrary: n0 n1 rule: polymul.induct)
  1493   case (2 c c' n' p' n0 n1)
  1494   then have "isnpolyh (head (CN c' n' p')) n1" "isnormNum c"
  1495     by (simp_all add: head_isnpolyh)
  1496   then show ?case
  1497     using 2 by (cases n') auto
  1498 next
  1499   case (3 c n p c' n0 n1)
  1500   then have "isnpolyh (head (CN c n p)) n0" "isnormNum c'"
  1501     by (simp_all add: head_isnpolyh)
  1502   then show ?case using 3
  1503     by (cases n) auto
  1504 next
  1505   case (4 c n p c' n' p' n0 n1)
  1506   hence norm: "isnpolyh p n" "isnpolyh c (Suc n)" "isnpolyh p' n'" "isnpolyh c' (Suc n')"
  1507     "isnpolyh (CN c n p) n" "isnpolyh (CN c' n' p') n'"
  1508     by simp_all
  1509   have "n < n' \<or> n' < n \<or> n = n'" by arith
  1510   moreover
  1511   {
  1512     assume nn': "n < n'"
  1513     then have ?case
  1514       using norm "4.hyps"(2)[OF norm(1,6)] "4.hyps"(1)[OF norm(2,6)]
  1515       apply simp
  1516       apply (cases n)
  1517       apply simp
  1518       apply (cases n')
  1519       apply simp_all
  1520       done
  1521   }
  1522   moreover {
  1523     assume nn': "n'< n"
  1524     then have ?case
  1525       using norm "4.hyps"(6) [OF norm(5,3)] "4.hyps"(5)[OF norm(5,4)]
  1526       apply simp
  1527       apply (cases n')
  1528       apply simp
  1529       apply (cases n)
  1530       apply auto
  1531       done
  1532   }
  1533   moreover {
  1534     assume nn': "n' = n"
  1535     from nn' polymul_normh[OF norm(5,4)]
  1536     have ncnpc':"isnpolyh (CN c n p *\<^sub>p c') n" by (simp add: min_def)
  1537     from nn' polymul_normh[OF norm(5,3)] norm
  1538     have ncnpp':"isnpolyh (CN c n p *\<^sub>p p') n" by simp
  1539     from nn' ncnpp' polymul_eq0_iff[OF norm(5,3)] norm(6)
  1540     have ncnpp0':"isnpolyh (CN 0\<^sub>p n (CN c n p *\<^sub>p p')) n" by simp
  1541     from polyadd_normh[OF ncnpc' ncnpp0']
  1542     have nth: "isnpolyh ((CN c n p *\<^sub>p c') +\<^sub>p (CN 0\<^sub>p n (CN c n p *\<^sub>p p'))) n"
  1543       by (simp add: min_def)
  1544     {
  1545       assume np: "n > 0"
  1546       with nn' head_isnpolyh_Suc'[OF np nth]
  1547         head_isnpolyh_Suc'[OF np norm(5)] head_isnpolyh_Suc'[OF np norm(6)[simplified nn']]
  1548       have ?case by simp
  1549     }
  1550     moreover
  1551     {
  1552       assume nz: "n = 0"
  1553       from polymul_degreen[OF norm(5,4), where m="0"]
  1554         polymul_degreen[OF norm(5,3), where m="0"] nn' nz degree_eq_degreen0
  1555       norm(5,6) degree_npolyhCN[OF norm(6)]
  1556     have dth:"degree (CN c 0 p *\<^sub>p c') < degree (CN 0\<^sub>p 0 (CN c 0 p *\<^sub>p p'))" by simp
  1557     hence dth':"degree (CN c 0 p *\<^sub>p c') \<noteq> degree (CN 0\<^sub>p 0 (CN c 0 p *\<^sub>p p'))" by simp
  1558     from polyadd_head[OF ncnpc'[simplified nz] ncnpp0'[simplified nz] dth'] dth
  1559     have ?case   using norm "4.hyps"(6)[OF norm(5,3)]
  1560         "4.hyps"(5)[OF norm(5,4)] nn' nz by simp
  1561     }
  1562     ultimately have ?case by (cases n) auto
  1563   }
  1564   ultimately show ?case by blast
  1565 qed simp_all
  1566 
  1567 lemma degree_coefficients: "degree p = length (coefficients p) - 1"
  1568   by (induct p rule: degree.induct) auto
  1569 
  1570 lemma degree_head[simp]: "degree (head p) = 0"
  1571   by (induct p rule: head.induct) auto
  1572 
  1573 lemma degree_CN: "isnpolyh p n \<Longrightarrow> degree (CN c n p) \<le> 1 + degree p"
  1574   by (cases n) simp_all
  1575 lemma degree_CN': "isnpolyh p n \<Longrightarrow> degree (CN c n p) \<ge>  degree p"
  1576   by (cases n) simp_all
  1577 
  1578 lemma polyadd_different_degree:
  1579   "\<lbrakk>isnpolyh p n0 ; isnpolyh q n1; degree p \<noteq> degree q\<rbrakk> \<Longrightarrow>
  1580     degree (polyadd p q) = max (degree p) (degree q)"
  1581   using polyadd_different_degreen degree_eq_degreen0 by simp
  1582 
  1583 lemma degreen_polyneg: "isnpolyh p n0 \<Longrightarrow> degreen (~\<^sub>p p) m = degreen p m"
  1584   by (induct p arbitrary: n0 rule: polyneg.induct) auto
  1585 
  1586 lemma degree_polymul:
  1587   assumes "SORT_CONSTRAINT('a::{field_char_0,field_inverse_zero})"
  1588     and np: "isnpolyh p n0"
  1589     and nq: "isnpolyh q n1"
  1590   shows "degree (p *\<^sub>p q) \<le> degree p + degree q"
  1591   using polymul_degreen[OF np nq, where m="0"]  degree_eq_degreen0 by simp
  1592 
  1593 lemma polyneg_degree: "isnpolyh p n \<Longrightarrow> degree (polyneg p) = degree p"
  1594   by (induct p arbitrary: n rule: degree.induct) auto
  1595 
  1596 lemma polyneg_head: "isnpolyh p n \<Longrightarrow> head(polyneg p) = polyneg (head p)"
  1597   by (induct p arbitrary: n rule: degree.induct) auto
  1598 
  1599 
  1600 subsection {* Correctness of polynomial pseudo division *}
  1601 
  1602 lemma polydivide_aux_properties:
  1603   assumes "SORT_CONSTRAINT('a::{field_char_0,field_inverse_zero})"
  1604     and np: "isnpolyh p n0"
  1605     and ns: "isnpolyh s n1"
  1606     and ap: "head p = a"
  1607     and ndp: "degree p = n" and pnz: "p \<noteq> 0\<^sub>p"
  1608   shows "(polydivide_aux a n p k s = (k',r) \<longrightarrow> (k' \<ge> k) \<and> (degree r = 0 \<or> degree r < degree p)
  1609           \<and> (\<exists>nr. isnpolyh r nr) \<and> (\<exists>q n1. isnpolyh q n1 \<and> ((polypow (k' - k) a) *\<^sub>p s = p *\<^sub>p q +\<^sub>p r)))"
  1610   using ns
  1611 proof (induct "degree s" arbitrary: s k k' r n1 rule: less_induct)
  1612   case less
  1613   let ?qths = "\<exists>q n1. isnpolyh q n1 \<and> (a ^\<^sub>p (k' - k) *\<^sub>p s = p *\<^sub>p q +\<^sub>p r)"
  1614   let ?ths = "polydivide_aux a n p k s = (k', r) \<longrightarrow>  k \<le> k' \<and> (degree r = 0 \<or> degree r < degree p)
  1615     \<and> (\<exists>nr. isnpolyh r nr) \<and> ?qths"
  1616   let ?b = "head s"
  1617   let ?p' = "funpow (degree s - n) shift1 p"
  1618   let ?xdn = "funpow (degree s - n) shift1 (1)\<^sub>p"
  1619   let ?akk' = "a ^\<^sub>p (k' - k)"
  1620   note ns = `isnpolyh s n1`
  1621   from np have np0: "isnpolyh p 0"
  1622     using isnpolyh_mono[where n="n0" and n'="0" and p="p"] by simp
  1623   have np': "isnpolyh ?p' 0"
  1624     using funpow_shift1_isnpoly[OF np0[simplified isnpoly_def[symmetric]] pnz, where n="degree s - n"] isnpoly_def
  1625     by simp
  1626   have headp': "head ?p' = head p"
  1627     using funpow_shift1_head[OF np pnz] by simp
  1628   from funpow_shift1_isnpoly[where p="(1)\<^sub>p"] have nxdn: "isnpolyh ?xdn 0"
  1629     by (simp add: isnpoly_def)
  1630   from polypow_normh [OF head_isnpolyh[OF np0], where k="k' - k"] ap
  1631   have nakk':"isnpolyh ?akk' 0" by blast
  1632   { assume sz: "s = 0\<^sub>p"
  1633     hence ?ths using np polydivide_aux.simps
  1634       apply clarsimp
  1635       apply (rule exI[where x="0\<^sub>p"])
  1636       apply simp
  1637       done }
  1638   moreover
  1639   { assume sz: "s \<noteq> 0\<^sub>p"
  1640     { assume dn: "degree s < n"
  1641       hence "?ths" using ns ndp np polydivide_aux.simps
  1642         apply auto
  1643         apply (rule exI[where x="0\<^sub>p"])
  1644         apply simp
  1645         done }
  1646     moreover
  1647     { assume dn': "\<not> degree s < n" hence dn: "degree s \<ge> n" by arith
  1648       have degsp': "degree s = degree ?p'"
  1649         using dn ndp funpow_shift1_degree[where k = "degree s - n" and p="p"] by simp
  1650       { assume ba: "?b = a"
  1651         hence headsp': "head s = head ?p'"
  1652           using ap headp' by simp
  1653         have nr: "isnpolyh (s -\<^sub>p ?p') 0"
  1654           using polysub_normh[OF ns np'] by simp
  1655         from degree_polysub_samehead[OF ns np' headsp' degsp']
  1656         have "degree (s -\<^sub>p ?p') < degree s \<or> s -\<^sub>p ?p' = 0\<^sub>p" by simp
  1657         moreover
  1658         { assume deglt:"degree (s -\<^sub>p ?p') < degree s"
  1659           from polydivide_aux.simps sz dn' ba
  1660           have eq: "polydivide_aux a n p k s = polydivide_aux a n p k (s -\<^sub>p ?p')"
  1661             by (simp add: Let_def)
  1662           { assume h1: "polydivide_aux a n p k s = (k', r)"
  1663             from less(1)[OF deglt nr, of k k' r] trans[OF eq[symmetric] h1]
  1664             have kk': "k \<le> k'"
  1665               and nr:"\<exists>nr. isnpolyh r nr"
  1666               and dr: "degree r = 0 \<or> degree r < degree p"
  1667               and q1: "\<exists>q nq. isnpolyh q nq \<and> (a ^\<^sub>p k' - k *\<^sub>p (s -\<^sub>p ?p') = p *\<^sub>p q +\<^sub>p r)"
  1668               by auto
  1669             from q1 obtain q n1 where nq: "isnpolyh q n1"
  1670               and asp:"a^\<^sub>p (k' - k) *\<^sub>p (s -\<^sub>p ?p') = p *\<^sub>p q +\<^sub>p r" by blast
  1671             from nr obtain nr where nr': "isnpolyh r nr" by blast
  1672             from polymul_normh[OF nakk' ns] have nakks': "isnpolyh (a ^\<^sub>p (k' - k) *\<^sub>p s) 0"
  1673               by simp
  1674             from polyadd_normh[OF polymul_normh[OF nakk' nxdn] nq]
  1675             have nq': "isnpolyh (?akk' *\<^sub>p ?xdn +\<^sub>p q) 0" by simp
  1676             from polyadd_normh[OF polymul_normh[OF np
  1677               polyadd_normh[OF polymul_normh[OF nakk' nxdn] nq]] nr']
  1678             have nqr': "isnpolyh (p *\<^sub>p (?akk' *\<^sub>p ?xdn +\<^sub>p q) +\<^sub>p r) 0"
  1679               by simp
  1680             from asp have "\<forall> (bs:: 'a::{field_char_0,field_inverse_zero} list). Ipoly bs (a^\<^sub>p (k' - k) *\<^sub>p (s -\<^sub>p ?p')) =
  1681               Ipoly bs (p *\<^sub>p q +\<^sub>p r)" by simp
  1682             hence " \<forall>(bs:: 'a::{field_char_0,field_inverse_zero} list). Ipoly bs (a^\<^sub>p (k' - k)*\<^sub>p s) =
  1683               Ipoly bs (a^\<^sub>p (k' - k)) * Ipoly bs ?p' + Ipoly bs p * Ipoly bs q + Ipoly bs r"
  1684               by (simp add: field_simps)
  1685             hence " \<forall>(bs:: 'a::{field_char_0,field_inverse_zero} list). Ipoly bs (a ^\<^sub>p (k' - k) *\<^sub>p s) =
  1686               Ipoly bs (a^\<^sub>p (k' - k)) * Ipoly bs (funpow (degree s - n) shift1 (1)\<^sub>p *\<^sub>p p) +
  1687               Ipoly bs p * Ipoly bs q + Ipoly bs r"
  1688               by (auto simp only: funpow_shift1_1)
  1689             hence "\<forall>(bs:: 'a::{field_char_0,field_inverse_zero} list). Ipoly bs (a ^\<^sub>p (k' - k) *\<^sub>p s) =
  1690               Ipoly bs p * (Ipoly bs (a^\<^sub>p (k' - k)) * Ipoly bs (funpow (degree s - n) shift1 (1)\<^sub>p) +
  1691               Ipoly bs q) + Ipoly bs r"
  1692               by (simp add: field_simps)
  1693             hence "\<forall>(bs:: 'a::{field_char_0,field_inverse_zero} list). Ipoly bs (a ^\<^sub>p (k' - k) *\<^sub>p s) =
  1694               Ipoly bs (p *\<^sub>p ((a^\<^sub>p (k' - k)) *\<^sub>p (funpow (degree s - n) shift1 (1)\<^sub>p) +\<^sub>p q) +\<^sub>p r)"
  1695               by simp
  1696             with isnpolyh_unique[OF nakks' nqr']
  1697             have "a ^\<^sub>p (k' - k) *\<^sub>p s =
  1698               p *\<^sub>p ((a^\<^sub>p (k' - k)) *\<^sub>p (funpow (degree s - n) shift1 (1)\<^sub>p) +\<^sub>p q) +\<^sub>p r"
  1699               by blast
  1700             hence ?qths using nq'
  1701               apply (rule_tac x="(a^\<^sub>p (k' - k)) *\<^sub>p (funpow (degree s - n) shift1 (1)\<^sub>p) +\<^sub>p q" in exI)
  1702               apply (rule_tac x="0" in exI)
  1703               apply simp
  1704               done
  1705             with kk' nr dr have "k \<le> k' \<and> (degree r = 0 \<or> degree r < degree p) \<and> (\<exists>nr. isnpolyh r nr) \<and> ?qths"
  1706               by blast
  1707           }
  1708           hence ?ths by blast
  1709         }
  1710         moreover
  1711         { assume spz:"s -\<^sub>p ?p' = 0\<^sub>p"
  1712           from spz isnpolyh_unique[OF polysub_normh[OF ns np'], where q="0\<^sub>p", symmetric, where ?'a = "'a::{field_char_0,field_inverse_zero}"]
  1713           have " \<forall>(bs:: 'a::{field_char_0,field_inverse_zero} list). Ipoly bs s = Ipoly bs ?p'"
  1714             by simp
  1715           hence "\<forall>(bs:: 'a::{field_char_0,field_inverse_zero} list). Ipoly bs s = Ipoly bs (?xdn *\<^sub>p p)"
  1716             using np nxdn
  1717             apply simp
  1718             apply (simp only: funpow_shift1_1)
  1719             apply simp
  1720             done
  1721           hence sp': "s = ?xdn *\<^sub>p p" using isnpolyh_unique[OF ns polymul_normh[OF nxdn np]]
  1722             by blast
  1723           { assume h1: "polydivide_aux a n p k s = (k',r)"
  1724             from polydivide_aux.simps sz dn' ba
  1725             have eq: "polydivide_aux a n p k s = polydivide_aux a n p k (s -\<^sub>p ?p')"
  1726               by (simp add: Let_def)
  1727             also have "\<dots> = (k,0\<^sub>p)"
  1728               using polydivide_aux.simps spz by simp
  1729             finally have "(k',r) = (k,0\<^sub>p)" using h1 by simp
  1730             with sp'[symmetric] ns np nxdn polyadd_0(1)[OF polymul_normh[OF np nxdn]]
  1731               polyadd_0(2)[OF polymul_normh[OF np nxdn]] have ?ths
  1732               apply auto
  1733               apply (rule exI[where x="?xdn"])
  1734               apply (auto simp add: polymul_commute[of p])
  1735               done
  1736           }
  1737         }
  1738         ultimately have ?ths by blast
  1739       }
  1740       moreover
  1741       { assume ba: "?b \<noteq> a"
  1742         from polysub_normh[OF polymul_normh[OF head_isnpolyh[OF np0, simplified ap] ns]
  1743           polymul_normh[OF head_isnpolyh[OF ns] np']]
  1744         have nth: "isnpolyh ((a *\<^sub>p s) -\<^sub>p (?b *\<^sub>p ?p')) 0"
  1745           by (simp add: min_def)
  1746         have nzths: "a *\<^sub>p s \<noteq> 0\<^sub>p" "?b *\<^sub>p ?p' \<noteq> 0\<^sub>p"
  1747           using polymul_eq0_iff[OF head_isnpolyh[OF np0, simplified ap] ns]
  1748             polymul_eq0_iff[OF head_isnpolyh[OF ns] np']head_nz[OF np0] ap pnz sz head_nz[OF ns]
  1749             funpow_shift1_nz[OF pnz]
  1750           by simp_all
  1751         from polymul_head_polyeq[OF head_isnpolyh[OF np] ns] head_nz[OF np] sz ap head_head[OF np] pnz
  1752           polymul_head_polyeq[OF head_isnpolyh[OF ns] np'] head_nz [OF ns] sz funpow_shift1_nz[OF pnz, where n="degree s - n"]
  1753         have hdth: "head (a *\<^sub>p s) = head (?b *\<^sub>p ?p')"
  1754           using head_head[OF ns] funpow_shift1_head[OF np pnz]
  1755             polymul_commute[OF head_isnpolyh[OF np] head_isnpolyh[OF ns]]
  1756           by (simp add: ap)
  1757         from polymul_degreen[OF head_isnpolyh[OF np] ns, where m="0"]
  1758           head_nz[OF np] pnz sz ap[symmetric]
  1759           funpow_shift1_nz[OF pnz, where n="degree s - n"]
  1760           polymul_degreen[OF head_isnpolyh[OF ns] np', where m="0"] head_nz[OF ns]
  1761           ndp dn
  1762         have degth: "degree (a *\<^sub>p s) = degree (?b *\<^sub>p ?p')"
  1763           by (simp add: degree_eq_degreen0[symmetric] funpow_shift1_degree)
  1764         { assume dth: "degree ((a *\<^sub>p s) -\<^sub>p (?b *\<^sub>p ?p')) < degree s"
  1765           from polysub_normh[OF polymul_normh[OF head_isnpolyh[OF np] ns]
  1766             polymul_normh[OF head_isnpolyh[OF ns]np']] ap
  1767           have nasbp': "isnpolyh ((a *\<^sub>p s) -\<^sub>p (?b *\<^sub>p ?p')) 0"
  1768             by simp
  1769           { assume h1:"polydivide_aux a n p k s = (k', r)"
  1770             from h1 polydivide_aux.simps sz dn' ba
  1771             have eq:"polydivide_aux a n p (Suc k) ((a *\<^sub>p s) -\<^sub>p (?b *\<^sub>p ?p')) = (k',r)"
  1772               by (simp add: Let_def)
  1773             with less(1)[OF dth nasbp', of "Suc k" k' r]
  1774             obtain q nq nr where kk': "Suc k \<le> k'"
  1775               and nr: "isnpolyh r nr"
  1776               and nq: "isnpolyh q nq"
  1777               and dr: "degree r = 0 \<or> degree r < degree p"
  1778               and qr: "a ^\<^sub>p (k' - Suc k) *\<^sub>p ((a *\<^sub>p s) -\<^sub>p (?b *\<^sub>p ?p')) = p *\<^sub>p q +\<^sub>p r"
  1779               by auto
  1780             from kk' have kk'':"Suc (k' - Suc k) = k' - k" by arith
  1781             {
  1782               fix bs:: "'a::{field_char_0,field_inverse_zero} list"
  1783               from qr isnpolyh_unique[OF polypow_normh[OF head_isnpolyh[OF np], where k="k' - Suc k", simplified ap] nasbp', symmetric]
  1784               have "Ipoly bs (a ^\<^sub>p (k' - Suc k) *\<^sub>p ((a *\<^sub>p s) -\<^sub>p (?b *\<^sub>p ?p'))) = Ipoly bs (p *\<^sub>p q +\<^sub>p r)"
  1785                 by simp
  1786               hence "Ipoly bs a ^ (Suc (k' - Suc k)) * Ipoly bs s =
  1787                 Ipoly bs p * Ipoly bs q + Ipoly bs a ^ (k' - Suc k) * Ipoly bs ?b * Ipoly bs ?p' + Ipoly bs r"
  1788                 by (simp add: field_simps)
  1789               hence "Ipoly bs a ^ (k' - k)  * Ipoly bs s =
  1790                 Ipoly bs p * Ipoly bs q + Ipoly bs a ^ (k' - Suc k) * Ipoly bs ?b * Ipoly bs ?xdn * Ipoly bs p + Ipoly bs r"
  1791                 by (simp add: kk'' funpow_shift1_1[where n="degree s - n" and p="p"])
  1792               hence "Ipoly bs (a ^\<^sub>p (k' - k) *\<^sub>p s) =
  1793                 Ipoly bs p * (Ipoly bs q + Ipoly bs a ^ (k' - Suc k) * Ipoly bs ?b * Ipoly bs ?xdn) + Ipoly bs r"
  1794                 by (simp add: field_simps)
  1795             }
  1796             hence ieq:"\<forall>(bs :: 'a::{field_char_0,field_inverse_zero} list). Ipoly bs (a ^\<^sub>p (k' - k) *\<^sub>p s) =
  1797               Ipoly bs (p *\<^sub>p (q +\<^sub>p (a ^\<^sub>p (k' - Suc k) *\<^sub>p ?b *\<^sub>p ?xdn)) +\<^sub>p r)"
  1798               by auto
  1799             let ?q = "q +\<^sub>p (a ^\<^sub>p (k' - Suc k) *\<^sub>p ?b *\<^sub>p ?xdn)"
  1800             from polyadd_normh[OF nq polymul_normh[OF polymul_normh[OF polypow_normh[OF head_isnpolyh[OF np], where k="k' - Suc k"] head_isnpolyh[OF ns], simplified ap ] nxdn]]
  1801             have nqw: "isnpolyh ?q 0"
  1802               by simp
  1803             from ieq isnpolyh_unique[OF polymul_normh[OF polypow_normh[OF head_isnpolyh[OF np], where k="k' - k"] ns, simplified ap] polyadd_normh[OF polymul_normh[OF np nqw] nr]]
  1804             have asth: "(a ^\<^sub>p (k' - k) *\<^sub>p s) = p *\<^sub>p (q +\<^sub>p (a ^\<^sub>p (k' - Suc k) *\<^sub>p ?b *\<^sub>p ?xdn)) +\<^sub>p r"
  1805               by blast
  1806             from dr kk' nr h1 asth nqw have ?ths
  1807               apply simp
  1808               apply (rule conjI)
  1809               apply (rule exI[where x="nr"], simp)
  1810               apply (rule exI[where x="(q +\<^sub>p (a ^\<^sub>p (k' - Suc k) *\<^sub>p ?b *\<^sub>p ?xdn))"], simp)
  1811               apply (rule exI[where x="0"], simp)
  1812               done
  1813           }
  1814           hence ?ths by blast
  1815         }
  1816         moreover
  1817         { assume spz: "a *\<^sub>p s -\<^sub>p (?b *\<^sub>p ?p') = 0\<^sub>p"
  1818           {
  1819             fix bs :: "'a::{field_char_0,field_inverse_zero} list"
  1820             from isnpolyh_unique[OF nth, where ?'a="'a" and q="0\<^sub>p",simplified,symmetric] spz
  1821             have "Ipoly bs (a*\<^sub>p s) = Ipoly bs ?b * Ipoly bs ?p'"
  1822               by simp
  1823             hence "Ipoly bs (a*\<^sub>p s) = Ipoly bs (?b *\<^sub>p ?xdn) * Ipoly bs p"
  1824               by (simp add: funpow_shift1_1[where n="degree s - n" and p="p"])
  1825             hence "Ipoly bs (a*\<^sub>p s) = Ipoly bs (p *\<^sub>p (?b *\<^sub>p ?xdn))"
  1826               by simp
  1827           }
  1828           hence hth: "\<forall> (bs:: 'a::{field_char_0,field_inverse_zero} list). Ipoly bs (a*\<^sub>p s) =
  1829             Ipoly bs (p *\<^sub>p (?b *\<^sub>p ?xdn))" ..
  1830           from hth have asq: "a *\<^sub>p s = p *\<^sub>p (?b *\<^sub>p ?xdn)"
  1831             using isnpolyh_unique[where ?'a = "'a::{field_char_0,field_inverse_zero}", OF polymul_normh[OF head_isnpolyh[OF np] ns]
  1832                     polymul_normh[OF np polymul_normh[OF head_isnpolyh[OF ns] nxdn]],
  1833               simplified ap] by simp
  1834           { assume h1: "polydivide_aux a n p k s = (k', r)"
  1835             from h1 sz ba dn' spz polydivide_aux.simps polydivide_aux.simps
  1836             have "(k',r) = (Suc k, 0\<^sub>p)" by (simp add: Let_def)
  1837             with h1 np head_isnpolyh[OF np, simplified ap] ns polymul_normh[OF head_isnpolyh[OF ns] nxdn]
  1838               polymul_normh[OF np polymul_normh[OF head_isnpolyh[OF ns] nxdn]] asq
  1839             have ?ths
  1840               apply (clarsimp simp add: Let_def)
  1841               apply (rule exI[where x="?b *\<^sub>p ?xdn"])
  1842               apply simp
  1843               apply (rule exI[where x="0"], simp)
  1844               done
  1845           }
  1846           hence ?ths by blast
  1847         }
  1848         ultimately have ?ths
  1849           using  degree_polysub_samehead[OF polymul_normh[OF head_isnpolyh[OF np0, simplified ap] ns] polymul_normh[OF head_isnpolyh[OF ns] np'] hdth degth] polymul_degreen[OF head_isnpolyh[OF np] ns, where m="0"]
  1850             head_nz[OF np] pnz sz ap[symmetric]
  1851           by (simp add: degree_eq_degreen0[symmetric]) blast
  1852       }
  1853       ultimately have ?ths by blast
  1854     }
  1855     ultimately have ?ths by blast
  1856   }
  1857   ultimately show ?ths by blast
  1858 qed
  1859 
  1860 lemma polydivide_properties:
  1861   assumes "SORT_CONSTRAINT('a::{field_char_0,field_inverse_zero})"
  1862     and np: "isnpolyh p n0" and ns: "isnpolyh s n1" and pnz: "p \<noteq> 0\<^sub>p"
  1863   shows "\<exists>k r. polydivide s p = (k,r) \<and>
  1864     (\<exists>nr. isnpolyh r nr) \<and> (degree r = 0 \<or> degree r < degree p) \<and>
  1865     (\<exists>q n1. isnpolyh q n1 \<and> ((polypow k (head p)) *\<^sub>p s = p *\<^sub>p q +\<^sub>p r))"
  1866 proof -
  1867   have trv: "head p = head p" "degree p = degree p"
  1868     by simp_all
  1869   from polydivide_def[where s="s" and p="p"] have ex: "\<exists> k r. polydivide s p = (k,r)"
  1870     by auto
  1871   then obtain k r where kr: "polydivide s p = (k,r)"
  1872     by blast
  1873   from trans[OF polydivide_def[where s="s"and p="p", symmetric] kr]
  1874     polydivide_aux_properties[OF np ns trv pnz, where k="0" and k'="k" and r="r"]
  1875   have "(degree r = 0 \<or> degree r < degree p) \<and>
  1876     (\<exists>nr. isnpolyh r nr) \<and> (\<exists>q n1. isnpolyh q n1 \<and> head p ^\<^sub>p k - 0 *\<^sub>p s = p *\<^sub>p q +\<^sub>p r)"
  1877     by blast
  1878   with kr show ?thesis
  1879     apply -
  1880     apply (rule exI[where x="k"])
  1881     apply (rule exI[where x="r"])
  1882     apply simp
  1883     done
  1884 qed
  1885 
  1886 
  1887 subsection{* More about polypoly and pnormal etc *}
  1888 
  1889 definition "isnonconstant p \<longleftrightarrow> \<not> isconstant p"
  1890 
  1891 lemma isnonconstant_pnormal_iff:
  1892   assumes nc: "isnonconstant p"
  1893   shows "pnormal (polypoly bs p) \<longleftrightarrow> Ipoly bs (head p) \<noteq> 0"
  1894 proof
  1895   let ?p = "polypoly bs p"
  1896   assume H: "pnormal ?p"
  1897   have csz: "coefficients p \<noteq> []" using nc by (cases p) auto
  1898 
  1899   from coefficients_head[of p] last_map[OF csz, of "Ipoly bs"]
  1900     pnormal_last_nonzero[OF H]
  1901   show "Ipoly bs (head p) \<noteq> 0" by (simp add: polypoly_def)
  1902 next
  1903   assume h: "\<lparr>head p\<rparr>\<^sub>p\<^bsup>bs\<^esup> \<noteq> 0"
  1904   let ?p = "polypoly bs p"
  1905   have csz: "coefficients p \<noteq> []" using nc by (cases p) auto
  1906   hence pz: "?p \<noteq> []" by (simp add: polypoly_def)
  1907   hence lg: "length ?p > 0" by simp
  1908   from h coefficients_head[of p] last_map[OF csz, of "Ipoly bs"]
  1909   have lz: "last ?p \<noteq> 0" by (simp add: polypoly_def)
  1910   from pnormal_last_length[OF lg lz] show "pnormal ?p" .
  1911 qed
  1912 
  1913 lemma isnonconstant_coefficients_length: "isnonconstant p \<Longrightarrow> length (coefficients p) > 1"
  1914   unfolding isnonconstant_def
  1915   apply (cases p)
  1916   apply simp_all
  1917   apply (case_tac nat)
  1918   apply auto
  1919   done
  1920 
  1921 lemma isnonconstant_nonconstant:
  1922   assumes inc: "isnonconstant p"
  1923   shows "nonconstant (polypoly bs p) \<longleftrightarrow> Ipoly bs (head p) \<noteq> 0"
  1924 proof
  1925   let ?p = "polypoly bs p"
  1926   assume nc: "nonconstant ?p"
  1927   from isnonconstant_pnormal_iff[OF inc, of bs] nc
  1928   show "\<lparr>head p\<rparr>\<^sub>p\<^bsup>bs\<^esup> \<noteq> 0" unfolding nonconstant_def by blast
  1929 next
  1930   let ?p = "polypoly bs p"
  1931   assume h: "\<lparr>head p\<rparr>\<^sub>p\<^bsup>bs\<^esup> \<noteq> 0"
  1932   from isnonconstant_pnormal_iff[OF inc, of bs] h
  1933   have pn: "pnormal ?p" by blast
  1934   {
  1935     fix x
  1936     assume H: "?p = [x]"
  1937     from H have "length (coefficients p) = 1"
  1938       unfolding polypoly_def by auto
  1939     with isnonconstant_coefficients_length[OF inc]
  1940       have False by arith
  1941   }
  1942   then show "nonconstant ?p"
  1943     using pn unfolding nonconstant_def by blast
  1944 qed
  1945 
  1946 lemma pnormal_length: "p\<noteq>[] \<Longrightarrow> pnormal p \<longleftrightarrow> length (pnormalize p) = length p"
  1947   apply (induct p)
  1948   apply (simp_all add: pnormal_def)
  1949   apply (case_tac "p = []")
  1950   apply simp_all
  1951   done
  1952 
  1953 lemma degree_degree:
  1954   assumes inc: "isnonconstant p"
  1955   shows "degree p = Polynomial_List.degree (polypoly bs p) \<longleftrightarrow> \<lparr>head p\<rparr>\<^sub>p\<^bsup>bs\<^esup> \<noteq> 0"
  1956 proof
  1957   let ?p = "polypoly bs p"
  1958   assume H: "degree p = Polynomial_List.degree ?p"
  1959   from isnonconstant_coefficients_length[OF inc] have pz: "?p \<noteq> []"
  1960     unfolding polypoly_def by auto
  1961   from H degree_coefficients[of p] isnonconstant_coefficients_length[OF inc]
  1962   have lg:"length (pnormalize ?p) = length ?p"
  1963     unfolding Polynomial_List.degree_def polypoly_def by simp
  1964   hence "pnormal ?p" using pnormal_length[OF pz] by blast
  1965   with isnonconstant_pnormal_iff[OF inc]
  1966   show "\<lparr>head p\<rparr>\<^sub>p\<^bsup>bs\<^esup> \<noteq> 0" by blast
  1967 next
  1968   let  ?p = "polypoly bs p"
  1969   assume H: "\<lparr>head p\<rparr>\<^sub>p\<^bsup>bs\<^esup> \<noteq> 0"
  1970   with isnonconstant_pnormal_iff[OF inc] have "pnormal ?p" by blast
  1971   with degree_coefficients[of p] isnonconstant_coefficients_length[OF inc]
  1972   show "degree p = Polynomial_List.degree ?p"
  1973     unfolding polypoly_def pnormal_def Polynomial_List.degree_def by auto
  1974 qed
  1975 
  1976 
  1977 section {* Swaps ; Division by a certain variable *}
  1978 
  1979 primrec swap :: "nat \<Rightarrow> nat \<Rightarrow> poly \<Rightarrow> poly" where
  1980   "swap n m (C x) = C x"
  1981 | "swap n m (Bound k) = Bound (if k = n then m else if k=m then n else k)"
  1982 | "swap n m (Neg t) = Neg (swap n m t)"
  1983 | "swap n m (Add s t) = Add (swap n m s) (swap n m t)"
  1984 | "swap n m (Sub s t) = Sub (swap n m s) (swap n m t)"
  1985 | "swap n m (Mul s t) = Mul (swap n m s) (swap n m t)"
  1986 | "swap n m (Pw t k) = Pw (swap n m t) k"
  1987 | "swap n m (CN c k p) =
  1988     CN (swap n m c) (if k = n then m else if k=m then n else k) (swap n m p)"
  1989 
  1990 lemma swap:
  1991   assumes nbs: "n < length bs"
  1992     and mbs: "m < length bs"
  1993   shows "Ipoly bs (swap n m t) = Ipoly ((bs[n:= bs!m])[m:= bs!n]) t"
  1994 proof (induct t)
  1995   case (Bound k)
  1996   then show ?case using nbs mbs by simp
  1997 next
  1998   case (CN c k p)
  1999   then show ?case using nbs mbs by simp
  2000 qed simp_all
  2001 
  2002 lemma swap_swap_id [simp]: "swap n m (swap m n t) = t"
  2003   by (induct t) simp_all
  2004 
  2005 lemma swap_commute: "swap n m p = swap m n p"
  2006   by (induct p) simp_all
  2007 
  2008 lemma swap_same_id[simp]: "swap n n t = t"
  2009   by (induct t) simp_all
  2010 
  2011 definition "swapnorm n m t = polynate (swap n m t)"
  2012 
  2013 lemma swapnorm:
  2014   assumes nbs: "n < length bs"
  2015     and mbs: "m < length bs"
  2016   shows "((Ipoly bs (swapnorm n m t) :: 'a::{field_char_0,field_inverse_zero})) =
  2017     Ipoly ((bs[n:= bs!m])[m:= bs!n]) t"
  2018   using swap[OF assms] swapnorm_def by simp
  2019 
  2020 lemma swapnorm_isnpoly [simp]:
  2021   assumes "SORT_CONSTRAINT('a::{field_char_0,field_inverse_zero})"
  2022   shows "isnpoly (swapnorm n m p)"
  2023   unfolding swapnorm_def by simp
  2024 
  2025 definition "polydivideby n s p =
  2026   (let
  2027     ss = swapnorm 0 n s;
  2028     sp = swapnorm 0 n p;
  2029     h = head sp;
  2030     (k, r) = polydivide ss sp
  2031    in (k, swapnorm 0 n h, swapnorm 0 n r))"
  2032 
  2033 lemma swap_nz [simp]: "swap n m p = 0\<^sub>p \<longleftrightarrow> p = 0\<^sub>p"
  2034   by (induct p) simp_all
  2035 
  2036 fun isweaknpoly :: "poly \<Rightarrow> bool"
  2037 where
  2038   "isweaknpoly (C c) = True"
  2039 | "isweaknpoly (CN c n p) \<longleftrightarrow> isweaknpoly c \<and> isweaknpoly p"
  2040 | "isweaknpoly p = False"
  2041 
  2042 lemma isnpolyh_isweaknpoly: "isnpolyh p n0 \<Longrightarrow> isweaknpoly p"
  2043   by (induct p arbitrary: n0) auto
  2044 
  2045 lemma swap_isweanpoly: "isweaknpoly p \<Longrightarrow> isweaknpoly (swap n m p)"
  2046   by (induct p) auto
  2047 
  2048 end