src/HOL/Complex.thy
 author paulson Wed Mar 18 17:23:22 2015 +0000 (2015-03-18) changeset 59746 ddae5727c5a9 parent 59741 5b762cd73a8e child 59862 44b3f4fa33ca permissions -rw-r--r--
new HOL Light material about exp, sin, cos
1 (*  Title:       HOL/Complex.thy
2     Author:      Jacques D. Fleuriot
3     Copyright:   2001 University of Edinburgh
4     Conversion to Isar and new proofs by Lawrence C Paulson, 2003/4
5 *)
7 section {* Complex Numbers: Rectangular and Polar Representations *}
9 theory Complex
10 imports Transcendental
11 begin
13 text {*
14 We use the @{text codatatype} command to define the type of complex numbers. This allows us to use
15 @{text primcorec} to define complex functions by defining their real and imaginary result
16 separately.
17 *}
19 codatatype complex = Complex (Re: real) (Im: real)
21 lemma complex_surj: "Complex (Re z) (Im z) = z"
22   by (rule complex.collapse)
24 lemma complex_eqI [intro?]: "\<lbrakk>Re x = Re y; Im x = Im y\<rbrakk> \<Longrightarrow> x = y"
25   by (rule complex.expand) simp
27 lemma complex_eq_iff: "x = y \<longleftrightarrow> Re x = Re y \<and> Im x = Im y"
28   by (auto intro: complex.expand)
30 subsection {* Addition and Subtraction *}
32 instantiation complex :: ab_group_add
33 begin
35 primcorec zero_complex where
36   "Re 0 = 0"
37 | "Im 0 = 0"
39 primcorec plus_complex where
40   "Re (x + y) = Re x + Re y"
41 | "Im (x + y) = Im x + Im y"
43 primcorec uminus_complex where
44   "Re (- x) = - Re x"
45 | "Im (- x) = - Im x"
47 primcorec minus_complex where
48   "Re (x - y) = Re x - Re y"
49 | "Im (x - y) = Im x - Im y"
51 instance
52   by intro_classes (simp_all add: complex_eq_iff)
54 end
56 subsection {* Multiplication and Division *}
58 instantiation complex :: field_inverse_zero
59 begin
61 primcorec one_complex where
62   "Re 1 = 1"
63 | "Im 1 = 0"
65 primcorec times_complex where
66   "Re (x * y) = Re x * Re y - Im x * Im y"
67 | "Im (x * y) = Re x * Im y + Im x * Re y"
69 primcorec inverse_complex where
70   "Re (inverse x) = Re x / ((Re x)\<^sup>2 + (Im x)\<^sup>2)"
71 | "Im (inverse x) = - Im x / ((Re x)\<^sup>2 + (Im x)\<^sup>2)"
73 definition "x / (y\<Colon>complex) = x * inverse y"
75 instance
76   by intro_classes
77      (simp_all add: complex_eq_iff divide_complex_def
78       distrib_left distrib_right right_diff_distrib left_diff_distrib
79       power2_eq_square add_divide_distrib [symmetric])
81 end
83 lemma Re_divide: "Re (x / y) = (Re x * Re y + Im x * Im y) / ((Re y)\<^sup>2 + (Im y)\<^sup>2)"
84   unfolding divide_complex_def by (simp add: add_divide_distrib)
86 lemma Im_divide: "Im (x / y) = (Im x * Re y - Re x * Im y) / ((Re y)\<^sup>2 + (Im y)\<^sup>2)"
87   unfolding divide_complex_def times_complex.sel inverse_complex.sel
88   by (simp_all add: divide_simps)
90 lemma Re_power2: "Re (x ^ 2) = (Re x)^2 - (Im x)^2"
91   by (simp add: power2_eq_square)
93 lemma Im_power2: "Im (x ^ 2) = 2 * Re x * Im x"
94   by (simp add: power2_eq_square)
96 lemma Re_power_real: "Im x = 0 \<Longrightarrow> Re (x ^ n) = Re x ^ n "
97   by (induct n) simp_all
99 lemma Im_power_real: "Im x = 0 \<Longrightarrow> Im (x ^ n) = 0"
100   by (induct n) simp_all
102 subsection {* Scalar Multiplication *}
104 instantiation complex :: real_field
105 begin
107 primcorec scaleR_complex where
108   "Re (scaleR r x) = r * Re x"
109 | "Im (scaleR r x) = r * Im x"
111 instance
112 proof
113   fix a b :: real and x y :: complex
114   show "scaleR a (x + y) = scaleR a x + scaleR a y"
115     by (simp add: complex_eq_iff distrib_left)
116   show "scaleR (a + b) x = scaleR a x + scaleR b x"
117     by (simp add: complex_eq_iff distrib_right)
118   show "scaleR a (scaleR b x) = scaleR (a * b) x"
119     by (simp add: complex_eq_iff mult.assoc)
120   show "scaleR 1 x = x"
121     by (simp add: complex_eq_iff)
122   show "scaleR a x * y = scaleR a (x * y)"
123     by (simp add: complex_eq_iff algebra_simps)
124   show "x * scaleR a y = scaleR a (x * y)"
125     by (simp add: complex_eq_iff algebra_simps)
126 qed
128 end
130 subsection {* Numerals, Arithmetic, and Embedding from Reals *}
132 abbreviation complex_of_real :: "real \<Rightarrow> complex"
133   where "complex_of_real \<equiv> of_real"
135 declare [[coercion "of_real :: real \<Rightarrow> complex"]]
136 declare [[coercion "of_rat :: rat \<Rightarrow> complex"]]
137 declare [[coercion "of_int :: int \<Rightarrow> complex"]]
138 declare [[coercion "of_nat :: nat \<Rightarrow> complex"]]
140 lemma complex_Re_of_nat [simp]: "Re (of_nat n) = of_nat n"
141   by (induct n) simp_all
143 lemma complex_Im_of_nat [simp]: "Im (of_nat n) = 0"
144   by (induct n) simp_all
146 lemma complex_Re_of_int [simp]: "Re (of_int z) = of_int z"
147   by (cases z rule: int_diff_cases) simp
149 lemma complex_Im_of_int [simp]: "Im (of_int z) = 0"
150   by (cases z rule: int_diff_cases) simp
152 lemma complex_Re_numeral [simp]: "Re (numeral v) = numeral v"
153   using complex_Re_of_int [of "numeral v"] by simp
155 lemma complex_Im_numeral [simp]: "Im (numeral v) = 0"
156   using complex_Im_of_int [of "numeral v"] by simp
158 lemma Re_complex_of_real [simp]: "Re (complex_of_real z) = z"
159   by (simp add: of_real_def)
161 lemma Im_complex_of_real [simp]: "Im (complex_of_real z) = 0"
162   by (simp add: of_real_def)
164 lemma Re_divide_numeral [simp]: "Re (z / numeral w) = Re z / numeral w"
165   by (simp add: Re_divide sqr_conv_mult)
167 lemma Im_divide_numeral [simp]: "Im (z / numeral w) = Im z / numeral w"
168   by (simp add: Im_divide sqr_conv_mult)
170 subsection {* The Complex Number $i$ *}
172 primcorec "ii" :: complex  ("\<i>") where
173   "Re ii = 0"
174 | "Im ii = 1"
176 lemma Complex_eq[simp]: "Complex a b = a + \<i> * b"
177   by (simp add: complex_eq_iff)
179 lemma complex_eq: "a = Re a + \<i> * Im a"
180   by (simp add: complex_eq_iff)
182 lemma fun_complex_eq: "f = (\<lambda>x. Re (f x) + \<i> * Im (f x))"
183   by (simp add: fun_eq_iff complex_eq)
185 lemma i_squared [simp]: "ii * ii = -1"
186   by (simp add: complex_eq_iff)
188 lemma power2_i [simp]: "ii\<^sup>2 = -1"
189   by (simp add: power2_eq_square)
191 lemma inverse_i [simp]: "inverse ii = - ii"
192   by (rule inverse_unique) simp
194 lemma divide_i [simp]: "x / ii = - ii * x"
195   by (simp add: divide_complex_def)
197 lemma complex_i_mult_minus [simp]: "ii * (ii * x) = - x"
198   by (simp add: mult.assoc [symmetric])
200 lemma complex_i_not_zero [simp]: "ii \<noteq> 0"
201   by (simp add: complex_eq_iff)
203 lemma complex_i_not_one [simp]: "ii \<noteq> 1"
204   by (simp add: complex_eq_iff)
206 lemma complex_i_not_numeral [simp]: "ii \<noteq> numeral w"
207   by (simp add: complex_eq_iff)
209 lemma complex_i_not_neg_numeral [simp]: "ii \<noteq> - numeral w"
210   by (simp add: complex_eq_iff)
212 lemma complex_split_polar: "\<exists>r a. z = complex_of_real r * (cos a + \<i> * sin a)"
213   by (simp add: complex_eq_iff polar_Ex)
215 lemma i_even_power [simp]: "\<i> ^ (n * 2) = (-1) ^ n"
216   by (metis mult.commute power2_i power_mult)
218 lemma Re_ii_times [simp]: "Re (ii*z) = - Im z"
219   by simp
221 lemma Im_ii_times [simp]: "Im (ii*z) = Re z"
222   by simp
224 lemma ii_times_eq_iff: "ii*w = z \<longleftrightarrow> w = -(ii*z)"
225   by auto
227 lemma divide_numeral_i [simp]: "z / (numeral n * ii) = -(ii*z) / numeral n"
228   by (metis divide_divide_eq_left divide_i mult.commute mult_minus_right)
230 subsection {* Vector Norm *}
232 instantiation complex :: real_normed_field
233 begin
235 definition "norm z = sqrt ((Re z)\<^sup>2 + (Im z)\<^sup>2)"
237 abbreviation cmod :: "complex \<Rightarrow> real"
238   where "cmod \<equiv> norm"
240 definition complex_sgn_def:
241   "sgn x = x /\<^sub>R cmod x"
243 definition dist_complex_def:
244   "dist x y = cmod (x - y)"
246 definition open_complex_def:
247   "open (S :: complex set) \<longleftrightarrow> (\<forall>x\<in>S. \<exists>e>0. \<forall>y. dist y x < e \<longrightarrow> y \<in> S)"
249 instance proof
250   fix r :: real and x y :: complex and S :: "complex set"
251   show "(norm x = 0) = (x = 0)"
252     by (simp add: norm_complex_def complex_eq_iff)
253   show "norm (x + y) \<le> norm x + norm y"
254     by (simp add: norm_complex_def complex_eq_iff real_sqrt_sum_squares_triangle_ineq)
255   show "norm (scaleR r x) = \<bar>r\<bar> * norm x"
256     by (simp add: norm_complex_def complex_eq_iff power_mult_distrib distrib_left [symmetric] real_sqrt_mult)
257   show "norm (x * y) = norm x * norm y"
258     by (simp add: norm_complex_def complex_eq_iff real_sqrt_mult [symmetric] power2_eq_square algebra_simps)
259 qed (rule complex_sgn_def dist_complex_def open_complex_def)+
261 end
263 lemma norm_ii [simp]: "norm ii = 1"
264   by (simp add: norm_complex_def)
266 lemma cmod_unit_one: "cmod (cos a + \<i> * sin a) = 1"
267   by (simp add: norm_complex_def)
269 lemma cmod_complex_polar: "cmod (r * (cos a + \<i> * sin a)) = \<bar>r\<bar>"
270   by (simp add: norm_mult cmod_unit_one)
272 lemma complex_Re_le_cmod: "Re x \<le> cmod x"
273   unfolding norm_complex_def
274   by (rule real_sqrt_sum_squares_ge1)
276 lemma complex_mod_minus_le_complex_mod: "- cmod x \<le> cmod x"
277   by (rule order_trans [OF _ norm_ge_zero]) simp
279 lemma complex_mod_triangle_ineq2: "cmod (b + a) - cmod b \<le> cmod a"
280   by (rule ord_le_eq_trans [OF norm_triangle_ineq2]) simp
282 lemma abs_Re_le_cmod: "\<bar>Re x\<bar> \<le> cmod x"
283   by (simp add: norm_complex_def)
285 lemma abs_Im_le_cmod: "\<bar>Im x\<bar> \<le> cmod x"
286   by (simp add: norm_complex_def)
288 lemma cmod_le: "cmod z \<le> \<bar>Re z\<bar> + \<bar>Im z\<bar>"
289   apply (subst complex_eq)
290   apply (rule order_trans)
291   apply (rule norm_triangle_ineq)
292   apply (simp add: norm_mult)
293   done
295 lemma cmod_eq_Re: "Im z = 0 \<Longrightarrow> cmod z = \<bar>Re z\<bar>"
296   by (simp add: norm_complex_def)
298 lemma cmod_eq_Im: "Re z = 0 \<Longrightarrow> cmod z = \<bar>Im z\<bar>"
299   by (simp add: norm_complex_def)
301 lemma cmod_power2: "cmod z ^ 2 = (Re z)^2 + (Im z)^2"
302   by (simp add: norm_complex_def)
304 lemma cmod_plus_Re_le_0_iff: "cmod z + Re z \<le> 0 \<longleftrightarrow> Re z = - cmod z"
305   using abs_Re_le_cmod[of z] by auto
307 lemma Im_eq_0: "\<bar>Re z\<bar> = cmod z \<Longrightarrow> Im z = 0"
308   by (subst (asm) power_eq_iff_eq_base[symmetric, where n=2])
309      (auto simp add: norm_complex_def)
311 lemma abs_sqrt_wlog:
312   fixes x::"'a::linordered_idom"
313   assumes "\<And>x::'a. x \<ge> 0 \<Longrightarrow> P x (x\<^sup>2)" shows "P \<bar>x\<bar> (x\<^sup>2)"
314 by (metis abs_ge_zero assms power2_abs)
316 lemma complex_abs_le_norm: "\<bar>Re z\<bar> + \<bar>Im z\<bar> \<le> sqrt 2 * norm z"
317   unfolding norm_complex_def
318   apply (rule abs_sqrt_wlog [where x="Re z"])
319   apply (rule abs_sqrt_wlog [where x="Im z"])
320   apply (rule power2_le_imp_le)
321   apply (simp_all add: power2_sum add.commute sum_squares_bound real_sqrt_mult [symmetric])
322   done
324 lemma complex_unit_circle: "z \<noteq> 0 \<Longrightarrow> (Re z / cmod z)\<^sup>2 + (Im z / cmod z)\<^sup>2 = 1"
325   by (simp add: norm_complex_def divide_simps complex_eq_iff)
328 text {* Properties of complex signum. *}
330 lemma sgn_eq: "sgn z = z / complex_of_real (cmod z)"
331   by (simp add: sgn_div_norm divide_inverse scaleR_conv_of_real mult.commute)
333 lemma Re_sgn [simp]: "Re(sgn z) = Re(z)/cmod z"
334   by (simp add: complex_sgn_def divide_inverse)
336 lemma Im_sgn [simp]: "Im(sgn z) = Im(z)/cmod z"
337   by (simp add: complex_sgn_def divide_inverse)
340 subsection {* Completeness of the Complexes *}
342 lemma bounded_linear_Re: "bounded_linear Re"
343   by (rule bounded_linear_intro [where K=1], simp_all add: norm_complex_def)
345 lemma bounded_linear_Im: "bounded_linear Im"
346   by (rule bounded_linear_intro [where K=1], simp_all add: norm_complex_def)
348 lemmas Cauchy_Re = bounded_linear.Cauchy [OF bounded_linear_Re]
349 lemmas Cauchy_Im = bounded_linear.Cauchy [OF bounded_linear_Im]
350 lemmas tendsto_Re [tendsto_intros] = bounded_linear.tendsto [OF bounded_linear_Re]
351 lemmas tendsto_Im [tendsto_intros] = bounded_linear.tendsto [OF bounded_linear_Im]
352 lemmas isCont_Re [simp] = bounded_linear.isCont [OF bounded_linear_Re]
353 lemmas isCont_Im [simp] = bounded_linear.isCont [OF bounded_linear_Im]
354 lemmas continuous_Re [simp] = bounded_linear.continuous [OF bounded_linear_Re]
355 lemmas continuous_Im [simp] = bounded_linear.continuous [OF bounded_linear_Im]
356 lemmas continuous_on_Re [continuous_intros] = bounded_linear.continuous_on[OF bounded_linear_Re]
357 lemmas continuous_on_Im [continuous_intros] = bounded_linear.continuous_on[OF bounded_linear_Im]
358 lemmas has_derivative_Re [derivative_intros] = bounded_linear.has_derivative[OF bounded_linear_Re]
359 lemmas has_derivative_Im [derivative_intros] = bounded_linear.has_derivative[OF bounded_linear_Im]
360 lemmas sums_Re = bounded_linear.sums [OF bounded_linear_Re]
361 lemmas sums_Im = bounded_linear.sums [OF bounded_linear_Im]
363 lemma tendsto_Complex [tendsto_intros]:
364   "(f ---> a) F \<Longrightarrow> (g ---> b) F \<Longrightarrow> ((\<lambda>x. Complex (f x) (g x)) ---> Complex a b) F"
365   by (auto intro!: tendsto_intros)
367 lemma tendsto_complex_iff:
368   "(f ---> x) F \<longleftrightarrow> (((\<lambda>x. Re (f x)) ---> Re x) F \<and> ((\<lambda>x. Im (f x)) ---> Im x) F)"
369 proof safe
370   assume "((\<lambda>x. Re (f x)) ---> Re x) F" "((\<lambda>x. Im (f x)) ---> Im x) F"
371   from tendsto_Complex[OF this] show "(f ---> x) F"
372     unfolding complex.collapse .
373 qed (auto intro: tendsto_intros)
375 lemma continuous_complex_iff: "continuous F f \<longleftrightarrow>
376     continuous F (\<lambda>x. Re (f x)) \<and> continuous F (\<lambda>x. Im (f x))"
377   unfolding continuous_def tendsto_complex_iff ..
379 lemma has_vector_derivative_complex_iff: "(f has_vector_derivative x) F \<longleftrightarrow>
380     ((\<lambda>x. Re (f x)) has_field_derivative (Re x)) F \<and>
381     ((\<lambda>x. Im (f x)) has_field_derivative (Im x)) F"
382   unfolding has_vector_derivative_def has_field_derivative_def has_derivative_def tendsto_complex_iff
383   by (simp add: field_simps bounded_linear_scaleR_left bounded_linear_mult_right)
385 lemma has_field_derivative_Re[derivative_intros]:
386   "(f has_vector_derivative D) F \<Longrightarrow> ((\<lambda>x. Re (f x)) has_field_derivative (Re D)) F"
387   unfolding has_vector_derivative_complex_iff by safe
389 lemma has_field_derivative_Im[derivative_intros]:
390   "(f has_vector_derivative D) F \<Longrightarrow> ((\<lambda>x. Im (f x)) has_field_derivative (Im D)) F"
391   unfolding has_vector_derivative_complex_iff by safe
393 instance complex :: banach
394 proof
395   fix X :: "nat \<Rightarrow> complex"
396   assume X: "Cauchy X"
397   then have "(\<lambda>n. Complex (Re (X n)) (Im (X n))) ----> Complex (lim (\<lambda>n. Re (X n))) (lim (\<lambda>n. Im (X n)))"
398     by (intro tendsto_Complex convergent_LIMSEQ_iff[THEN iffD1] Cauchy_convergent_iff[THEN iffD1] Cauchy_Re Cauchy_Im)
399   then show "convergent X"
400     unfolding complex.collapse by (rule convergentI)
401 qed
403 declare
404   DERIV_power[where 'a=complex, unfolded of_nat_def[symmetric], derivative_intros]
406 subsection {* Complex Conjugation *}
408 primcorec cnj :: "complex \<Rightarrow> complex" where
409   "Re (cnj z) = Re z"
410 | "Im (cnj z) = - Im z"
412 lemma complex_cnj_cancel_iff [simp]: "(cnj x = cnj y) = (x = y)"
413   by (simp add: complex_eq_iff)
415 lemma complex_cnj_cnj [simp]: "cnj (cnj z) = z"
416   by (simp add: complex_eq_iff)
418 lemma complex_cnj_zero [simp]: "cnj 0 = 0"
419   by (simp add: complex_eq_iff)
421 lemma complex_cnj_zero_iff [iff]: "(cnj z = 0) = (z = 0)"
422   by (simp add: complex_eq_iff)
424 lemma complex_cnj_add [simp]: "cnj (x + y) = cnj x + cnj y"
425   by (simp add: complex_eq_iff)
427 lemma cnj_setsum [simp]: "cnj (setsum f s) = (\<Sum>x\<in>s. cnj (f x))"
428   by (induct s rule: infinite_finite_induct) auto
430 lemma complex_cnj_diff [simp]: "cnj (x - y) = cnj x - cnj y"
431   by (simp add: complex_eq_iff)
433 lemma complex_cnj_minus [simp]: "cnj (- x) = - cnj x"
434   by (simp add: complex_eq_iff)
436 lemma complex_cnj_one [simp]: "cnj 1 = 1"
437   by (simp add: complex_eq_iff)
439 lemma complex_cnj_mult [simp]: "cnj (x * y) = cnj x * cnj y"
440   by (simp add: complex_eq_iff)
442 lemma cnj_setprod [simp]: "cnj (setprod f s) = (\<Prod>x\<in>s. cnj (f x))"
443   by (induct s rule: infinite_finite_induct) auto
445 lemma complex_cnj_inverse [simp]: "cnj (inverse x) = inverse (cnj x)"
446   by (simp add: complex_eq_iff)
448 lemma complex_cnj_divide [simp]: "cnj (x / y) = cnj x / cnj y"
449   by (simp add: divide_complex_def)
451 lemma complex_cnj_power [simp]: "cnj (x ^ n) = cnj x ^ n"
452   by (induct n) simp_all
454 lemma complex_cnj_of_nat [simp]: "cnj (of_nat n) = of_nat n"
455   by (simp add: complex_eq_iff)
457 lemma complex_cnj_of_int [simp]: "cnj (of_int z) = of_int z"
458   by (simp add: complex_eq_iff)
460 lemma complex_cnj_numeral [simp]: "cnj (numeral w) = numeral w"
461   by (simp add: complex_eq_iff)
463 lemma complex_cnj_neg_numeral [simp]: "cnj (- numeral w) = - numeral w"
464   by (simp add: complex_eq_iff)
466 lemma complex_cnj_scaleR [simp]: "cnj (scaleR r x) = scaleR r (cnj x)"
467   by (simp add: complex_eq_iff)
469 lemma complex_mod_cnj [simp]: "cmod (cnj z) = cmod z"
470   by (simp add: norm_complex_def)
472 lemma complex_cnj_complex_of_real [simp]: "cnj (of_real x) = of_real x"
473   by (simp add: complex_eq_iff)
475 lemma complex_cnj_i [simp]: "cnj ii = - ii"
476   by (simp add: complex_eq_iff)
478 lemma complex_add_cnj: "z + cnj z = complex_of_real (2 * Re z)"
479   by (simp add: complex_eq_iff)
481 lemma complex_diff_cnj: "z - cnj z = complex_of_real (2 * Im z) * ii"
482   by (simp add: complex_eq_iff)
484 lemma complex_mult_cnj: "z * cnj z = complex_of_real ((Re z)\<^sup>2 + (Im z)\<^sup>2)"
485   by (simp add: complex_eq_iff power2_eq_square)
487 lemma complex_mod_mult_cnj: "cmod (z * cnj z) = (cmod z)\<^sup>2"
488   by (simp add: norm_mult power2_eq_square)
490 lemma complex_mod_sqrt_Re_mult_cnj: "cmod z = sqrt (Re (z * cnj z))"
491   by (simp add: norm_complex_def power2_eq_square)
493 lemma complex_In_mult_cnj_zero [simp]: "Im (z * cnj z) = 0"
494   by simp
496 lemma bounded_linear_cnj: "bounded_linear cnj"
497   using complex_cnj_add complex_cnj_scaleR
498   by (rule bounded_linear_intro [where K=1], simp)
500 lemmas tendsto_cnj [tendsto_intros] = bounded_linear.tendsto [OF bounded_linear_cnj]
501 lemmas isCont_cnj [simp] = bounded_linear.isCont [OF bounded_linear_cnj]
502 lemmas continuous_cnj [simp, continuous_intros] = bounded_linear.continuous [OF bounded_linear_cnj]
503 lemmas continuous_on_cnj [simp, continuous_intros] = bounded_linear.continuous_on [OF bounded_linear_cnj]
504 lemmas has_derivative_cnj [simp, derivative_intros] = bounded_linear.has_derivative [OF bounded_linear_cnj]
506 lemma lim_cnj: "((\<lambda>x. cnj(f x)) ---> cnj l) F \<longleftrightarrow> (f ---> l) F"
507   by (simp add: tendsto_iff dist_complex_def complex_cnj_diff [symmetric] del: complex_cnj_diff)
509 lemma sums_cnj: "((\<lambda>x. cnj(f x)) sums cnj l) \<longleftrightarrow> (f sums l)"
510   by (simp add: sums_def lim_cnj cnj_setsum [symmetric] del: cnj_setsum)
513 subsection{*Basic Lemmas*}
515 lemma complex_eq_0: "z=0 \<longleftrightarrow> (Re z)\<^sup>2 + (Im z)\<^sup>2 = 0"
516   by (metis zero_complex.sel complex_eqI sum_power2_eq_zero_iff)
518 lemma complex_neq_0: "z\<noteq>0 \<longleftrightarrow> (Re z)\<^sup>2 + (Im z)\<^sup>2 > 0"
519   by (metis complex_eq_0 less_numeral_extra(3) sum_power2_gt_zero_iff)
521 lemma complex_norm_square: "of_real ((norm z)\<^sup>2) = z * cnj z"
522 by (cases z)
523    (auto simp: complex_eq_iff norm_complex_def power2_eq_square[symmetric] of_real_power[symmetric]
524          simp del: of_real_power)
526 lemma Re_complex_div_eq_0: "Re (a / b) = 0 \<longleftrightarrow> Re (a * cnj b) = 0"
527   by (auto simp add: Re_divide)
529 lemma Im_complex_div_eq_0: "Im (a / b) = 0 \<longleftrightarrow> Im (a * cnj b) = 0"
530   by (auto simp add: Im_divide)
532 lemma complex_div_gt_0:
533   "(Re (a / b) > 0 \<longleftrightarrow> Re (a * cnj b) > 0) \<and> (Im (a / b) > 0 \<longleftrightarrow> Im (a * cnj b) > 0)"
534 proof cases
535   assume "b = 0" then show ?thesis by auto
536 next
537   assume "b \<noteq> 0"
538   then have "0 < (Re b)\<^sup>2 + (Im b)\<^sup>2"
539     by (simp add: complex_eq_iff sum_power2_gt_zero_iff)
540   then show ?thesis
541     by (simp add: Re_divide Im_divide zero_less_divide_iff)
542 qed
544 lemma Re_complex_div_gt_0: "Re (a / b) > 0 \<longleftrightarrow> Re (a * cnj b) > 0"
545   and Im_complex_div_gt_0: "Im (a / b) > 0 \<longleftrightarrow> Im (a * cnj b) > 0"
546   using complex_div_gt_0 by auto
548 lemma Re_complex_div_ge_0: "Re(a / b) \<ge> 0 \<longleftrightarrow> Re(a * cnj b) \<ge> 0"
549   by (metis le_less Re_complex_div_eq_0 Re_complex_div_gt_0)
551 lemma Im_complex_div_ge_0: "Im(a / b) \<ge> 0 \<longleftrightarrow> Im(a * cnj b) \<ge> 0"
552   by (metis Im_complex_div_eq_0 Im_complex_div_gt_0 le_less)
554 lemma Re_complex_div_lt_0: "Re(a / b) < 0 \<longleftrightarrow> Re(a * cnj b) < 0"
555   by (metis less_asym neq_iff Re_complex_div_eq_0 Re_complex_div_gt_0)
557 lemma Im_complex_div_lt_0: "Im(a / b) < 0 \<longleftrightarrow> Im(a * cnj b) < 0"
558   by (metis Im_complex_div_eq_0 Im_complex_div_gt_0 less_asym neq_iff)
560 lemma Re_complex_div_le_0: "Re(a / b) \<le> 0 \<longleftrightarrow> Re(a * cnj b) \<le> 0"
561   by (metis not_le Re_complex_div_gt_0)
563 lemma Im_complex_div_le_0: "Im(a / b) \<le> 0 \<longleftrightarrow> Im(a * cnj b) \<le> 0"
564   by (metis Im_complex_div_gt_0 not_le)
566 lemma Re_setsum[simp]: "Re (setsum f s) = (\<Sum>x\<in>s. Re (f x))"
567   by (induct s rule: infinite_finite_induct) auto
569 lemma Im_setsum[simp]: "Im (setsum f s) = (\<Sum>x\<in>s. Im(f x))"
570   by (induct s rule: infinite_finite_induct) auto
572 lemma sums_complex_iff: "f sums x \<longleftrightarrow> ((\<lambda>x. Re (f x)) sums Re x) \<and> ((\<lambda>x. Im (f x)) sums Im x)"
573   unfolding sums_def tendsto_complex_iff Im_setsum Re_setsum ..
575 lemma summable_complex_iff: "summable f \<longleftrightarrow> summable (\<lambda>x. Re (f x)) \<and>  summable (\<lambda>x. Im (f x))"
576   unfolding summable_def sums_complex_iff[abs_def] by (metis complex.sel)
578 lemma summable_complex_of_real [simp]: "summable (\<lambda>n. complex_of_real (f n)) \<longleftrightarrow> summable f"
579   unfolding summable_complex_iff by simp
581 lemma summable_Re: "summable f \<Longrightarrow> summable (\<lambda>x. Re (f x))"
582   unfolding summable_complex_iff by blast
584 lemma summable_Im: "summable f \<Longrightarrow> summable (\<lambda>x. Im (f x))"
585   unfolding summable_complex_iff by blast
587 lemma complex_is_Real_iff: "z \<in> \<real> \<longleftrightarrow> Im z = 0"
588   by (auto simp: Reals_def complex_eq_iff)
590 lemma Reals_cnj_iff: "z \<in> \<real> \<longleftrightarrow> cnj z = z"
591   by (auto simp: complex_is_Real_iff complex_eq_iff)
593 lemma in_Reals_norm: "z \<in> \<real> \<Longrightarrow> norm(z) = abs(Re z)"
594   by (simp add: complex_is_Real_iff norm_complex_def)
596 lemma series_comparison_complex:
597   fixes f:: "nat \<Rightarrow> 'a::banach"
598   assumes sg: "summable g"
599      and "\<And>n. g n \<in> \<real>" "\<And>n. Re (g n) \<ge> 0"
600      and fg: "\<And>n. n \<ge> N \<Longrightarrow> norm(f n) \<le> norm(g n)"
601   shows "summable f"
602 proof -
603   have g: "\<And>n. cmod (g n) = Re (g n)" using assms
604     by (metis abs_of_nonneg in_Reals_norm)
605   show ?thesis
606     apply (rule summable_comparison_test' [where g = "\<lambda>n. norm (g n)" and N=N])
607     using sg
608     apply (auto simp: summable_def)
609     apply (rule_tac x="Re s" in exI)
610     apply (auto simp: g sums_Re)
611     apply (metis fg g)
612     done
613 qed
615 subsection{*Polar Form for Complex Numbers*}
617 lemma complex_unimodular_polar: "(norm z = 1) \<Longrightarrow> \<exists>x. z = Complex (cos x) (sin x)"
618   using sincos_total_2pi [of "Re z" "Im z"]
619   by auto (metis cmod_power2 complex_eq power_one)
621 subsubsection {* $\cos \theta + i \sin \theta$ *}
623 primcorec cis :: "real \<Rightarrow> complex" where
624   "Re (cis a) = cos a"
625 | "Im (cis a) = sin a"
627 lemma cis_zero [simp]: "cis 0 = 1"
628   by (simp add: complex_eq_iff)
630 lemma norm_cis [simp]: "norm (cis a) = 1"
631   by (simp add: norm_complex_def)
633 lemma sgn_cis [simp]: "sgn (cis a) = cis a"
634   by (simp add: sgn_div_norm)
636 lemma cis_neq_zero [simp]: "cis a \<noteq> 0"
637   by (metis norm_cis norm_zero zero_neq_one)
639 lemma cis_mult: "cis a * cis b = cis (a + b)"
642 lemma DeMoivre: "(cis a) ^ n = cis (real n * a)"
643   by (induct n, simp_all add: real_of_nat_Suc algebra_simps cis_mult)
645 lemma cis_inverse [simp]: "inverse(cis a) = cis (-a)"
646   by (simp add: complex_eq_iff)
648 lemma cis_divide: "cis a / cis b = cis (a - b)"
649   by (simp add: divide_complex_def cis_mult)
651 lemma cos_n_Re_cis_pow_n: "cos (real n * a) = Re(cis a ^ n)"
652   by (auto simp add: DeMoivre)
654 lemma sin_n_Im_cis_pow_n: "sin (real n * a) = Im(cis a ^ n)"
655   by (auto simp add: DeMoivre)
657 lemma cis_pi: "cis pi = -1"
658   by (simp add: complex_eq_iff)
660 subsubsection {* $r(\cos \theta + i \sin \theta)$ *}
662 definition rcis :: "real \<Rightarrow> real \<Rightarrow> complex" where
663   "rcis r a = complex_of_real r * cis a"
665 lemma Re_rcis [simp]: "Re(rcis r a) = r * cos a"
666   by (simp add: rcis_def)
668 lemma Im_rcis [simp]: "Im(rcis r a) = r * sin a"
669   by (simp add: rcis_def)
671 lemma rcis_Ex: "\<exists>r a. z = rcis r a"
672   by (simp add: complex_eq_iff polar_Ex)
674 lemma complex_mod_rcis [simp]: "cmod(rcis r a) = abs r"
675   by (simp add: rcis_def norm_mult)
677 lemma cis_rcis_eq: "cis a = rcis 1 a"
678   by (simp add: rcis_def)
680 lemma rcis_mult: "rcis r1 a * rcis r2 b = rcis (r1*r2) (a + b)"
681   by (simp add: rcis_def cis_mult)
683 lemma rcis_zero_mod [simp]: "rcis 0 a = 0"
684   by (simp add: rcis_def)
686 lemma rcis_zero_arg [simp]: "rcis r 0 = complex_of_real r"
687   by (simp add: rcis_def)
689 lemma rcis_eq_zero_iff [simp]: "rcis r a = 0 \<longleftrightarrow> r = 0"
690   by (simp add: rcis_def)
692 lemma DeMoivre2: "(rcis r a) ^ n = rcis (r ^ n) (real n * a)"
693   by (simp add: rcis_def power_mult_distrib DeMoivre)
695 lemma rcis_inverse: "inverse(rcis r a) = rcis (1/r) (-a)"
696   by (simp add: divide_inverse rcis_def)
698 lemma rcis_divide: "rcis r1 a / rcis r2 b = rcis (r1/r2) (a - b)"
699   by (simp add: rcis_def cis_divide [symmetric])
701 subsubsection {* Complex exponential *}
703 abbreviation Exp :: "complex \<Rightarrow> complex"
704   where "Exp \<equiv> exp"
706 lemma cis_conv_exp: "cis b = exp (\<i> * b)"
707 proof -
708   { fix n :: nat
709     have "\<i> ^ n = fact n *\<^sub>R (cos_coeff n + \<i> * sin_coeff n)"
710       by (induct n)
711          (simp_all add: sin_coeff_Suc cos_coeff_Suc complex_eq_iff Re_divide Im_divide field_simps
712                         power2_eq_square real_of_nat_Suc add_nonneg_eq_0_iff
713                         real_of_nat_def[symmetric])
714     then have "(\<i> * complex_of_real b) ^ n /\<^sub>R fact n =
715         of_real (cos_coeff n * b^n) + \<i> * of_real (sin_coeff n * b^n)"
716       by (simp add: field_simps) }
717   then show ?thesis using sin_converges [of b] cos_converges [of b]
718     by (auto simp add: cis.ctr exp_def simp del: of_real_mult
719              intro!: sums_unique sums_add sums_mult sums_of_real)
720 qed
722 lemma Exp_eq_polar: "Exp z = exp (Re z) * cis (Im z)"
723   unfolding cis_conv_exp exp_of_real [symmetric] mult_exp_exp by (cases z) simp
725 lemma Re_exp: "Re (exp z) = exp (Re z) * cos (Im z)"
726   unfolding Exp_eq_polar by simp
728 lemma Im_exp: "Im (exp z) = exp (Re z) * sin (Im z)"
729   unfolding Exp_eq_polar by simp
731 lemma norm_cos_sin [simp]: "norm (Complex (cos t) (sin t)) = 1"
732   by (simp add: norm_complex_def)
734 lemma norm_exp_eq_Re [simp]: "norm (exp z) = exp (Re z)"
735   by (simp add: cis.code cmod_complex_polar Exp_eq_polar)
737 lemma complex_Exp_Ex: "\<exists>a r. z = complex_of_real r * Exp a"
738   apply (insert rcis_Ex [of z])
739   apply (auto simp add: Exp_eq_polar rcis_def mult.assoc [symmetric])
740   apply (rule_tac x = "ii * complex_of_real a" in exI, auto)
741   done
743 lemma Exp_two_pi_i [simp]: "Exp((2::complex) * complex_of_real pi * ii) = 1"
744   by (simp add: Exp_eq_polar complex_eq_iff)
746 subsubsection {* Complex argument *}
748 definition arg :: "complex \<Rightarrow> real" where
749   "arg z = (if z = 0 then 0 else (SOME a. sgn z = cis a \<and> -pi < a \<and> a \<le> pi))"
751 lemma arg_zero: "arg 0 = 0"
752   by (simp add: arg_def)
754 lemma arg_unique:
755   assumes "sgn z = cis x" and "-pi < x" and "x \<le> pi"
756   shows "arg z = x"
757 proof -
758   from assms have "z \<noteq> 0" by auto
759   have "(SOME a. sgn z = cis a \<and> -pi < a \<and> a \<le> pi) = x"
760   proof
761     fix a def d \<equiv> "a - x"
762     assume a: "sgn z = cis a \<and> - pi < a \<and> a \<le> pi"
763     from a assms have "- (2*pi) < d \<and> d < 2*pi"
764       unfolding d_def by simp
765     moreover from a assms have "cos a = cos x" and "sin a = sin x"
766       by (simp_all add: complex_eq_iff)
767     hence cos: "cos d = 1" unfolding d_def cos_diff by simp
768     moreover from cos have "sin d = 0" by (rule cos_one_sin_zero)
769     ultimately have "d = 0"
770       unfolding sin_zero_iff
771       by (auto elim!: evenE dest!: less_2_cases)
772     thus "a = x" unfolding d_def by simp
773   qed (simp add: assms del: Re_sgn Im_sgn)
774   with z \<noteq> 0 show "arg z = x"
775     unfolding arg_def by simp
776 qed
778 lemma arg_correct:
779   assumes "z \<noteq> 0" shows "sgn z = cis (arg z) \<and> -pi < arg z \<and> arg z \<le> pi"
780 proof (simp add: arg_def assms, rule someI_ex)
781   obtain r a where z: "z = rcis r a" using rcis_Ex by fast
782   with assms have "r \<noteq> 0" by auto
783   def b \<equiv> "if 0 < r then a else a + pi"
784   have b: "sgn z = cis b"
785     unfolding z b_def rcis_def using r \<noteq> 0
786     by (simp add: of_real_def sgn_scaleR sgn_if complex_eq_iff)
787   have cis_2pi_nat: "\<And>n. cis (2 * pi * real_of_nat n) = 1"
788     by (induct_tac n) (simp_all add: distrib_left cis_mult [symmetric] complex_eq_iff)
789   have cis_2pi_int: "\<And>x. cis (2 * pi * real_of_int x) = 1"
790     by (case_tac x rule: int_diff_cases)
791        (simp add: right_diff_distrib cis_divide [symmetric] cis_2pi_nat)
792   def c \<equiv> "b - 2*pi * of_int \<lceil>(b - pi) / (2*pi)\<rceil>"
793   have "sgn z = cis c"
794     unfolding b c_def
795     by (simp add: cis_divide [symmetric] cis_2pi_int)
796   moreover have "- pi < c \<and> c \<le> pi"
797     using ceiling_correct [of "(b - pi) / (2*pi)"]
798     by (simp add: c_def less_divide_eq divide_le_eq algebra_simps)
799   ultimately show "\<exists>a. sgn z = cis a \<and> -pi < a \<and> a \<le> pi" by fast
800 qed
802 lemma arg_bounded: "- pi < arg z \<and> arg z \<le> pi"
803   by (cases "z = 0") (simp_all add: arg_zero arg_correct)
805 lemma cis_arg: "z \<noteq> 0 \<Longrightarrow> cis (arg z) = sgn z"
806   by (simp add: arg_correct)
808 lemma rcis_cmod_arg: "rcis (cmod z) (arg z) = z"
809   by (cases "z = 0") (simp_all add: rcis_def cis_arg sgn_div_norm of_real_def)
811 lemma cos_arg_i_mult_zero [simp]: "y \<noteq> 0 \<Longrightarrow> Re y = 0 \<Longrightarrow> cos (arg y) = 0"
812   using cis_arg [of y] by (simp add: complex_eq_iff)
814 subsection {* Square root of complex numbers *}
816 primcorec csqrt :: "complex \<Rightarrow> complex" where
817   "Re (csqrt z) = sqrt ((cmod z + Re z) / 2)"
818 | "Im (csqrt z) = (if Im z = 0 then 1 else sgn (Im z)) * sqrt ((cmod z - Re z) / 2)"
820 lemma csqrt_of_real_nonneg [simp]: "Im x = 0 \<Longrightarrow> Re x \<ge> 0 \<Longrightarrow> csqrt x = sqrt (Re x)"
821   by (simp add: complex_eq_iff norm_complex_def)
823 lemma csqrt_of_real_nonpos [simp]: "Im x = 0 \<Longrightarrow> Re x \<le> 0 \<Longrightarrow> csqrt x = \<i> * sqrt \<bar>Re x\<bar>"
824   by (simp add: complex_eq_iff norm_complex_def)
826 lemma csqrt_0 [simp]: "csqrt 0 = 0"
827   by simp
829 lemma csqrt_1 [simp]: "csqrt 1 = 1"
830   by simp
832 lemma csqrt_ii [simp]: "csqrt \<i> = (1 + \<i>) / sqrt 2"
833   by (simp add: complex_eq_iff Re_divide Im_divide real_sqrt_divide real_div_sqrt)
835 lemma power2_csqrt[simp,algebra]: "(csqrt z)\<^sup>2 = z"
836 proof cases
837   assume "Im z = 0" then show ?thesis
838     using real_sqrt_pow2[of "Re z"] real_sqrt_pow2[of "- Re z"]
839     by (cases "0::real" "Re z" rule: linorder_cases)
840        (simp_all add: complex_eq_iff Re_power2 Im_power2 power2_eq_square cmod_eq_Re)
841 next
842   assume "Im z \<noteq> 0"
843   moreover
844   have "cmod z * cmod z - Re z * Re z = Im z * Im z"
845     by (simp add: norm_complex_def power2_eq_square)
846   moreover
847   have "\<bar>Re z\<bar> \<le> cmod z"
848     by (simp add: norm_complex_def)
849   ultimately show ?thesis
850     by (simp add: Re_power2 Im_power2 complex_eq_iff real_sgn_eq
851                   field_simps real_sqrt_mult[symmetric] real_sqrt_divide)
852 qed
854 lemma csqrt_eq_0 [simp]: "csqrt z = 0 \<longleftrightarrow> z = 0"
855   by auto (metis power2_csqrt power_eq_0_iff)
857 lemma csqrt_eq_1 [simp]: "csqrt z = 1 \<longleftrightarrow> z = 1"
858   by auto (metis power2_csqrt power2_eq_1_iff)
860 lemma csqrt_principal: "0 < Re (csqrt z) \<or> Re (csqrt z) = 0 \<and> 0 \<le> Im (csqrt z)"
861   by (auto simp add: not_less cmod_plus_Re_le_0_iff Im_eq_0)
863 lemma Re_csqrt: "0 \<le> Re (csqrt z)"
864   by (metis csqrt_principal le_less)
866 lemma csqrt_square:
867   assumes "0 < Re b \<or> (Re b = 0 \<and> 0 \<le> Im b)"
868   shows "csqrt (b^2) = b"
869 proof -
870   have "csqrt (b^2) = b \<or> csqrt (b^2) = - b"
871     unfolding power2_eq_iff[symmetric] by (simp add: power2_csqrt)
872   moreover have "csqrt (b^2) \<noteq> -b \<or> b = 0"
873     using csqrt_principal[of "b ^ 2"] assms by (intro disjCI notI) (auto simp: complex_eq_iff)
874   ultimately show ?thesis
875     by auto
876 qed
878 lemma csqrt_unique:
879     "w^2 = z \<Longrightarrow> (0 < Re w \<or> Re w = 0 \<and> 0 \<le> Im w) \<Longrightarrow> csqrt z = w"
880   by (auto simp: csqrt_square)
882 lemma csqrt_minus [simp]:
883   assumes "Im x < 0 \<or> (Im x = 0 \<and> 0 \<le> Re x)"
884   shows "csqrt (- x) = \<i> * csqrt x"
885 proof -
886   have "csqrt ((\<i> * csqrt x)^2) = \<i> * csqrt x"
887   proof (rule csqrt_square)
888     have "Im (csqrt x) \<le> 0"
889       using assms by (auto simp add: cmod_eq_Re mult_le_0_iff field_simps complex_Re_le_cmod)
890     then show "0 < Re (\<i> * csqrt x) \<or> Re (\<i> * csqrt x) = 0 \<and> 0 \<le> Im (\<i> * csqrt x)"
891       by (auto simp add: Re_csqrt simp del: csqrt.simps)
892   qed
893   also have "(\<i> * csqrt x)^2 = - x"
894     by (simp add: power_mult_distrib)
895   finally show ?thesis .
896 qed
898 text {* Legacy theorem names *}
900 lemmas expand_complex_eq = complex_eq_iff
901 lemmas complex_Re_Im_cancel_iff = complex_eq_iff
902 lemmas complex_equality = complex_eqI
903 lemmas cmod_def = norm_complex_def
904 lemmas complex_norm_def = norm_complex_def
905 lemmas complex_divide_def = divide_complex_def
907 lemma legacy_Complex_simps:
908   shows Complex_eq_0: "Complex a b = 0 \<longleftrightarrow> a = 0 \<and> b = 0"
909     and complex_add: "Complex a b + Complex c d = Complex (a + c) (b + d)"
910     and complex_minus: "- (Complex a b) = Complex (- a) (- b)"
911     and complex_diff: "Complex a b - Complex c d = Complex (a - c) (b - d)"
912     and Complex_eq_1: "Complex a b = 1 \<longleftrightarrow> a = 1 \<and> b = 0"
913     and Complex_eq_neg_1: "Complex a b = - 1 \<longleftrightarrow> a = - 1 \<and> b = 0"
914     and complex_mult: "Complex a b * Complex c d = Complex (a * c - b * d) (a * d + b * c)"
915     and complex_inverse: "inverse (Complex a b) = Complex (a / (a\<^sup>2 + b\<^sup>2)) (- b / (a\<^sup>2 + b\<^sup>2))"
916     and Complex_eq_numeral: "Complex a b = numeral w \<longleftrightarrow> a = numeral w \<and> b = 0"
917     and Complex_eq_neg_numeral: "Complex a b = - numeral w \<longleftrightarrow> a = - numeral w \<and> b = 0"
918     and complex_scaleR: "scaleR r (Complex a b) = Complex (r * a) (r * b)"
919     and Complex_eq_i: "(Complex x y = ii) = (x = 0 \<and> y = 1)"
920     and i_mult_Complex: "ii * Complex a b = Complex (- b) a"
921     and Complex_mult_i: "Complex a b * ii = Complex (- b) a"
922     and i_complex_of_real: "ii * complex_of_real r = Complex 0 r"
923     and complex_of_real_i: "complex_of_real r * ii = Complex 0 r"
924     and Complex_add_complex_of_real: "Complex x y + complex_of_real r = Complex (x+r) y"
925     and complex_of_real_add_Complex: "complex_of_real r + Complex x y = Complex (r+x) y"
926     and Complex_mult_complex_of_real: "Complex x y * complex_of_real r = Complex (x*r) (y*r)"
927     and complex_of_real_mult_Complex: "complex_of_real r * Complex x y = Complex (r*x) (r*y)"
928     and complex_eq_cancel_iff2: "(Complex x y = complex_of_real xa) = (x = xa & y = 0)"
929     and complex_cn: "cnj (Complex a b) = Complex a (- b)"
930     and Complex_setsum': "setsum (%x. Complex (f x) 0) s = Complex (setsum f s) 0"
931     and Complex_setsum: "Complex (setsum f s) 0 = setsum (%x. Complex (f x) 0) s"
932     and complex_of_real_def: "complex_of_real r = Complex r 0"
933     and complex_norm: "cmod (Complex x y) = sqrt (x\<^sup>2 + y\<^sup>2)"
934   by (simp_all add: norm_complex_def field_simps complex_eq_iff Re_divide Im_divide del: Complex_eq)
936 lemma Complex_in_Reals: "Complex x 0 \<in> \<real>"
937   by (metis Reals_of_real complex_of_real_def)
939 end