src/Pure/sign.ML
author wenzelm
Wed Jun 18 18:55:05 2008 +0200 (2008-06-18)
changeset 27257 ddc00dbad26b
parent 27205 56c96c02ab79
child 27284 2ddb6a2db65c
permissions -rw-r--r--
removed obsolete term reading operations (cf. old_goals.ML for legacy emulations);
     1 (*  Title:      Pure/sign.ML
     2     ID:         $Id$
     3     Author:     Lawrence C Paulson and Markus Wenzel
     4 
     5 Logical signature content: naming conventions, concrete syntax, type
     6 signature, polymorphic constants.
     7 *)
     8 
     9 signature SIGN =
    10 sig
    11   val rep_sg: theory ->
    12    {naming: NameSpace.naming,
    13     syn: Syntax.syntax,
    14     tsig: Type.tsig,
    15     consts: Consts.T}
    16   val naming_of: theory -> NameSpace.naming
    17   val base_name: string -> bstring
    18   val full_name: theory -> bstring -> string
    19   val full_name_path: theory -> string -> bstring -> string
    20   val declare_name: theory -> string -> NameSpace.T -> NameSpace.T
    21   val syn_of: theory -> Syntax.syntax
    22   val tsig_of: theory -> Type.tsig
    23   val classes_of: theory -> Sorts.algebra
    24   val all_classes: theory -> class list
    25   val super_classes: theory -> class -> class list
    26   val minimize_sort: theory -> sort -> sort
    27   val complete_sort: theory -> sort -> sort
    28   val defaultS: theory -> sort
    29   val subsort: theory -> sort * sort -> bool
    30   val of_sort: theory -> typ * sort -> bool
    31   val witness_sorts: theory -> sort list -> sort list -> (typ * sort) list
    32   val is_logtype: theory -> string -> bool
    33   val typ_instance: theory -> typ * typ -> bool
    34   val typ_equiv: theory -> typ * typ -> bool
    35   val typ_match: theory -> typ * typ -> Type.tyenv -> Type.tyenv
    36   val typ_unify: theory -> typ * typ -> Type.tyenv * int -> Type.tyenv * int
    37   val consts_of: theory -> Consts.T
    38   val the_const_constraint: theory -> string -> typ
    39   val const_type: theory -> string -> typ option
    40   val the_const_type: theory -> string -> typ
    41   val declared_tyname: theory -> string -> bool
    42   val declared_const: theory -> string -> bool
    43   val const_monomorphic: theory -> string -> bool
    44   val const_syntax_name: theory -> string -> string
    45   val const_typargs: theory -> string * typ -> typ list
    46   val const_instance: theory -> string * typ list -> typ
    47   val mk_const: theory -> string * typ list -> term
    48   val class_space: theory -> NameSpace.T
    49   val type_space: theory -> NameSpace.T
    50   val const_space: theory -> NameSpace.T
    51   val intern_class: theory -> xstring -> string
    52   val extern_class: theory -> string -> xstring
    53   val intern_type: theory -> xstring -> string
    54   val extern_type: theory -> string -> xstring
    55   val intern_const: theory -> xstring -> string
    56   val extern_const: theory -> string -> xstring
    57   val intern_sort: theory -> sort -> sort
    58   val extern_sort: theory -> sort -> sort
    59   val intern_typ: theory -> typ -> typ
    60   val extern_typ: theory -> typ -> typ
    61   val intern_term: theory -> term -> term
    62   val extern_term: (string -> xstring) -> theory -> term -> term
    63   val intern_tycons: theory -> typ -> typ
    64   val arity_number: theory -> string -> int
    65   val arity_sorts: theory -> string -> sort -> sort list
    66   val certify_class: theory -> class -> class
    67   val certify_sort: theory -> sort -> sort
    68   val certify_typ: theory -> typ -> typ
    69   val certify_typ_mode: Type.mode -> theory -> typ -> typ
    70   val certify': bool -> Pretty.pp -> bool -> Consts.T -> theory -> term -> term * typ * int
    71   val certify_term: theory -> term -> term * typ * int
    72   val certify_prop: theory -> term -> term * typ * int
    73   val cert_term: theory -> term -> term
    74   val cert_prop: theory -> term -> term
    75   val no_frees: Pretty.pp -> term -> term
    76   val no_vars: Pretty.pp -> term -> term
    77   val cert_def: Proof.context -> term -> (string * typ) * term
    78   val read_class: theory -> xstring -> class
    79   val read_arity: theory -> xstring * string list * string -> arity
    80   val cert_arity: theory -> arity -> arity
    81   val get_sort: theory ->
    82     (indexname -> sort option) -> (indexname * sort) list -> indexname -> sort
    83   val read_def_typ: theory * (indexname -> sort option) -> string -> typ
    84   val read_typ: theory -> string -> typ
    85   val read_typ_syntax: theory -> string -> typ
    86   val read_typ_abbrev: theory -> string -> typ
    87   val add_defsort: string -> theory -> theory
    88   val add_defsort_i: sort -> theory -> theory
    89   val add_types: (bstring * int * mixfix) list -> theory -> theory
    90   val add_nonterminals: bstring list -> theory -> theory
    91   val add_tyabbrs: (bstring * string list * string * mixfix) list -> theory -> theory
    92   val add_tyabbrs_i: (bstring * string list * typ * mixfix) list -> theory -> theory
    93   val add_syntax: (bstring * string * mixfix) list -> theory -> theory
    94   val add_syntax_i: (bstring * typ * mixfix) list -> theory -> theory
    95   val add_modesyntax: Syntax.mode -> (bstring * string * mixfix) list -> theory -> theory
    96   val add_modesyntax_i: Syntax.mode -> (bstring * typ * mixfix) list -> theory -> theory
    97   val del_modesyntax: Syntax.mode -> (bstring * string * mixfix) list -> theory -> theory
    98   val del_modesyntax_i: Syntax.mode -> (bstring * typ * mixfix) list -> theory -> theory
    99   val notation: bool -> Syntax.mode -> (term * mixfix) list -> theory -> theory
   100   val add_consts: (bstring * string * mixfix) list -> theory -> theory
   101   val add_consts_i: (bstring * typ * mixfix) list -> theory -> theory
   102   val declare_const: Markup.property list -> bstring * typ * mixfix -> theory -> term * theory
   103   val add_abbrev: string -> Markup.property list ->
   104     bstring * term -> theory -> (term * term) * theory
   105   val revert_abbrev: string -> string -> theory -> theory
   106   val add_const_constraint: string * typ option -> theory -> theory
   107   val primitive_class: string * class list -> theory -> theory
   108   val primitive_classrel: class * class -> theory -> theory
   109   val primitive_arity: arity -> theory -> theory
   110   val add_trfuns:
   111     (string * (ast list -> ast)) list *
   112     (string * (term list -> term)) list *
   113     (string * (term list -> term)) list *
   114     (string * (ast list -> ast)) list -> theory -> theory
   115   val add_trfunsT:
   116     (string * (bool -> typ -> term list -> term)) list -> theory -> theory
   117   val add_advanced_trfuns:
   118     (string * (Proof.context -> ast list -> ast)) list *
   119     (string * (Proof.context -> term list -> term)) list *
   120     (string * (Proof.context -> term list -> term)) list *
   121     (string * (Proof.context -> ast list -> ast)) list -> theory -> theory
   122   val add_advanced_trfunsT:
   123     (string * (Proof.context -> bool -> typ -> term list -> term)) list -> theory -> theory
   124   val add_tokentrfuns:
   125     (string * string * (Proof.context -> string -> Pretty.T)) list -> theory -> theory
   126   val add_mode_tokentrfuns: string -> (string * (Proof.context -> string -> Pretty.T)) list
   127     -> theory -> theory
   128   val add_trrules: (xstring * string) Syntax.trrule list -> theory -> theory
   129   val del_trrules: (xstring * string) Syntax.trrule list -> theory -> theory
   130   val add_trrules_i: ast Syntax.trrule list -> theory -> theory
   131   val del_trrules_i: ast Syntax.trrule list -> theory -> theory
   132   val add_path: string -> theory -> theory
   133   val parent_path: theory -> theory
   134   val root_path: theory -> theory
   135   val absolute_path: theory -> theory
   136   val local_path: theory -> theory
   137   val no_base_names: theory -> theory
   138   val qualified_names: theory -> theory
   139   val sticky_prefix: string -> theory -> theory
   140   val restore_naming: theory -> theory -> theory
   141   val hide_class: bool -> string -> theory -> theory
   142   val hide_type: bool -> string -> theory -> theory
   143   val hide_const: bool -> string -> theory -> theory
   144 end
   145 
   146 structure Sign: SIGN =
   147 struct
   148 
   149 (** datatype sign **)
   150 
   151 datatype sign = Sign of
   152  {naming: NameSpace.naming,     (*common naming conventions*)
   153   syn: Syntax.syntax,           (*concrete syntax for terms, types, sorts*)
   154   tsig: Type.tsig,              (*order-sorted signature of types*)
   155   consts: Consts.T};            (*polymorphic constants*)
   156 
   157 fun make_sign (naming, syn, tsig, consts) =
   158   Sign {naming = naming, syn = syn, tsig = tsig, consts = consts};
   159 
   160 structure SignData = TheoryDataFun
   161 (
   162   type T = sign;
   163   val copy = I;
   164   fun extend (Sign {syn, tsig, consts, ...}) =
   165     make_sign (NameSpace.default_naming, syn, tsig, consts);
   166 
   167   val empty =
   168     make_sign (NameSpace.default_naming, Syntax.basic_syn, Type.empty_tsig, Consts.empty);
   169 
   170   fun merge pp (sign1, sign2) =
   171     let
   172       val Sign {naming = _, syn = syn1, tsig = tsig1, consts = consts1} = sign1;
   173       val Sign {naming = _, syn = syn2, tsig = tsig2, consts = consts2} = sign2;
   174 
   175       val naming = NameSpace.default_naming;
   176       val syn = Syntax.merge_syntaxes syn1 syn2;
   177       val tsig = Type.merge_tsigs pp (tsig1, tsig2);
   178       val consts = Consts.merge (consts1, consts2);
   179     in make_sign (naming, syn, tsig, consts) end;
   180 );
   181 
   182 fun rep_sg thy = SignData.get thy |> (fn Sign args => args);
   183 
   184 fun map_sign f = SignData.map (fn Sign {naming, syn, tsig, consts} =>
   185   make_sign (f (naming, syn, tsig, consts)));
   186 
   187 fun map_naming f = map_sign (fn (naming, syn, tsig, consts) => (f naming, syn, tsig, consts));
   188 fun map_syn f = map_sign (fn (naming, syn, tsig, consts) => (naming, f syn, tsig, consts));
   189 fun map_tsig f = map_sign (fn (naming, syn, tsig, consts) => (naming, syn, f tsig, consts));
   190 fun map_consts f = map_sign (fn (naming, syn, tsig, consts) => (naming, syn, tsig, f consts));
   191 
   192 
   193 (* naming *)
   194 
   195 val naming_of = #naming o rep_sg;
   196 val base_name = NameSpace.base;
   197 val full_name = NameSpace.full o naming_of;
   198 fun full_name_path thy elems = NameSpace.full (NameSpace.add_path elems (naming_of thy));
   199 val declare_name = NameSpace.declare o naming_of;
   200 
   201 
   202 (* syntax *)
   203 
   204 val syn_of = #syn o rep_sg;
   205 
   206 
   207 (* type signature *)
   208 
   209 val tsig_of = #tsig o rep_sg;
   210 
   211 val classes_of = #2 o #classes o Type.rep_tsig o tsig_of;
   212 val all_classes = Sorts.all_classes o classes_of;
   213 val super_classes = Sorts.super_classes o classes_of;
   214 val minimize_sort = Sorts.minimize_sort o classes_of;
   215 val complete_sort = Sorts.complete_sort o classes_of;
   216 
   217 val defaultS = Type.defaultS o tsig_of;
   218 val subsort = Type.subsort o tsig_of;
   219 val of_sort = Type.of_sort o tsig_of;
   220 val witness_sorts = Type.witness_sorts o tsig_of;
   221 val is_logtype = member (op =) o Type.logical_types o tsig_of;
   222 
   223 val typ_instance = Type.typ_instance o tsig_of;
   224 fun typ_equiv thy (T, U) = typ_instance thy (T, U) andalso typ_instance thy (U, T);
   225 val typ_match = Type.typ_match o tsig_of;
   226 val typ_unify = Type.unify o tsig_of;
   227 
   228 
   229 (* polymorphic constants *)
   230 
   231 val consts_of = #consts o rep_sg;
   232 val the_const_constraint = Consts.the_constraint o consts_of;
   233 val the_const_type = Consts.the_type o consts_of;
   234 val const_type = try o the_const_type;
   235 val const_monomorphic = Consts.is_monomorphic o consts_of;
   236 val const_syntax_name = Consts.syntax_name o consts_of;
   237 val const_typargs = Consts.typargs o consts_of;
   238 val const_instance = Consts.instance o consts_of;
   239 
   240 fun mk_const thy (c, Ts) = Const (c, const_instance thy (c, Ts));
   241 
   242 val declared_tyname = Symtab.defined o #2 o #types o Type.rep_tsig o tsig_of;
   243 val declared_const = can o the_const_constraint;
   244 
   245 
   246 
   247 (** intern / extern names **)
   248 
   249 val class_space = #1 o #classes o Type.rep_tsig o tsig_of;
   250 val type_space = #1 o #types o Type.rep_tsig o tsig_of;
   251 val const_space = Consts.space_of o consts_of;
   252 
   253 val intern_class = NameSpace.intern o class_space;
   254 val extern_class = NameSpace.extern o class_space;
   255 val intern_type = NameSpace.intern o type_space;
   256 val extern_type = NameSpace.extern o type_space;
   257 val intern_const = NameSpace.intern o const_space;
   258 val extern_const = NameSpace.extern o const_space;
   259 
   260 val intern_sort = map o intern_class;
   261 val extern_sort = map o extern_class;
   262 
   263 local
   264 
   265 fun map_typ f g (Type (c, Ts)) = Type (g c, map (map_typ f g) Ts)
   266   | map_typ f _ (TFree (x, S)) = TFree (x, map f S)
   267   | map_typ f _ (TVar (xi, S)) = TVar (xi, map f S);
   268 
   269 fun map_term f g h (Const (c, T)) = Const (h c, map_typ f g T)
   270   | map_term f g _ (Free (x, T)) = Free (x, map_typ f g T)
   271   | map_term f g _ (Var (xi, T)) = Var (xi, map_typ f g T)
   272   | map_term _ _ _ (t as Bound _) = t
   273   | map_term f g h (Abs (x, T, t)) = Abs (x, map_typ f g T, map_term f g h t)
   274   | map_term f g h (t $ u) = map_term f g h t $ map_term f g h u;
   275 
   276 val add_classesT = Term.fold_atyps
   277   (fn TFree (_, S) => fold (insert (op =)) S
   278     | TVar (_, S) => fold (insert (op =)) S
   279     | _ => I);
   280 
   281 fun add_tyconsT (Type (c, Ts)) = insert (op =) c #> fold add_tyconsT Ts
   282   | add_tyconsT _ = I;
   283 
   284 val add_consts = Term.fold_aterms (fn Const (c, _) => insert (op =) c | _ => I);
   285 
   286 fun mapping add_names f t =
   287   let
   288     fun f' (x: string) = let val y = f x in if x = y then NONE else SOME (x, y) end;
   289     val tab = map_filter f' (add_names t []);
   290     fun get x = the_default x (AList.lookup (op =) tab x);
   291   in get end;
   292 
   293 fun typ_mapping f g thy T =
   294   T |> map_typ
   295     (mapping add_classesT (f thy) T)
   296     (mapping add_tyconsT (g thy) T);
   297 
   298 fun term_mapping f g h thy t =
   299   t |> map_term
   300     (mapping (Term.fold_types add_classesT) (f thy) t)
   301     (mapping (Term.fold_types add_tyconsT) (g thy) t)
   302     (mapping add_consts (h thy) t);
   303 
   304 in
   305 
   306 val intern_typ = typ_mapping intern_class intern_type;
   307 val extern_typ = typ_mapping extern_class extern_type;
   308 val intern_term = term_mapping intern_class intern_type intern_const;
   309 fun extern_term h = term_mapping extern_class extern_type (K h);
   310 val intern_tycons = typ_mapping (K I) intern_type;
   311 
   312 end;
   313 
   314 
   315 
   316 (** certify entities **)    (*exception TYPE*)
   317 
   318 (* certify wrt. type signature *)
   319 
   320 val arity_number = Type.arity_number o tsig_of;
   321 fun arity_sorts thy = Type.arity_sorts (Syntax.pp_global thy) (tsig_of thy);
   322 
   323 val certify_class         = Type.cert_class o tsig_of;
   324 val certify_sort          = Type.cert_sort o tsig_of;
   325 val certify_typ           = Type.cert_typ o tsig_of;
   326 fun certify_typ_mode mode = Type.cert_typ_mode mode o tsig_of;
   327 
   328 
   329 (* certify term/prop *)
   330 
   331 local
   332 
   333 fun type_check pp tm =
   334   let
   335     fun err_appl why bs t T u U =
   336       let
   337         val xs = map Free bs;           (*we do not rename here*)
   338         val t' = subst_bounds (xs, t);
   339         val u' = subst_bounds (xs, u);
   340         val msg = cat_lines
   341           (TypeInfer.appl_error (Syntax.pp_show_brackets pp) why t' T u' U);
   342       in raise TYPE (msg, [T, U], [t', u']) end;
   343 
   344     fun typ_of (_, Const (_, T)) = T
   345       | typ_of (_, Free  (_, T)) = T
   346       | typ_of (_, Var (_, T)) = T
   347       | typ_of (bs, Bound i) = snd (List.nth (bs, i) handle Subscript =>
   348           raise TYPE ("Loose bound variable: B." ^ string_of_int i, [], [Bound i]))
   349       | typ_of (bs, Abs (x, T, body)) = T --> typ_of ((x, T) :: bs, body)
   350       | typ_of (bs, t $ u) =
   351           let val T = typ_of (bs, t) and U = typ_of (bs, u) in
   352             (case T of
   353               Type ("fun", [T1, T2]) =>
   354                 if T1 = U then T2 else err_appl "Incompatible operand type" bs t T u U
   355             | _ => err_appl "Operator not of function type" bs t T u U)
   356           end;
   357   in typ_of ([], tm) end;
   358 
   359 fun err msg = raise TYPE (msg, [], []);
   360 
   361 fun check_vars (t $ u) = (check_vars t; check_vars u)
   362   | check_vars (Abs (_, _, t)) = check_vars t
   363   | check_vars (Free (x, _)) =
   364       if NameSpace.is_qualified x then err ("Malformed variable: " ^ quote x) else ()
   365   | check_vars (Var (xi as (_, i), _)) =
   366       if i < 0 then err ("Malformed variable: " ^ quote (Term.string_of_vname xi)) else ()
   367   | check_vars _ = ();
   368 
   369 in
   370 
   371 fun certify' prop pp do_expand consts thy tm =
   372   let
   373     val _ = check_vars tm;
   374     val tm' = Term.map_types (certify_typ thy) tm;
   375     val T = type_check pp tm';
   376     val _ = if prop andalso T <> propT then err "Term not of type prop" else ();
   377     val tm'' = Consts.certify pp (tsig_of thy) do_expand consts tm';
   378   in (if tm = tm'' then tm else tm'', T, Term.maxidx_of_term tm'') end;
   379 
   380 fun certify_term thy = certify' false (Syntax.pp_global thy) true (consts_of thy) thy;
   381 fun certify_prop thy = certify' true (Syntax.pp_global thy) true (consts_of thy) thy;
   382 
   383 fun cert_term_abbrev thy = #1 o certify' false (Syntax.pp_global thy) false (consts_of thy) thy;
   384 val cert_term = #1 oo certify_term;
   385 val cert_prop = #1 oo certify_prop;
   386 
   387 end;
   388 
   389 
   390 (* specifications *)
   391 
   392 fun no_variables kind add addT mk mkT pp tm =
   393   (case (add tm [], addT tm []) of
   394     ([], []) => tm
   395   | (frees, tfrees) => error (Pretty.string_of (Pretty.block
   396       (Pretty.str ("Illegal " ^ kind ^ " variable(s) in term:") :: Pretty.brk 1 ::
   397        Pretty.commas (map (Pretty.term pp o mk) frees @ map (Pretty.typ pp o mkT) tfrees)))));
   398 
   399 val no_frees = no_variables "free" Term.add_frees Term.add_tfrees Free TFree;
   400 val no_vars = no_variables "schematic" Term.add_vars Term.add_tvars Var TVar;
   401 
   402 fun cert_def ctxt tm =
   403   let val ((lhs, rhs), _) = tm
   404     |> no_vars (Syntax.pp ctxt)
   405     |> Logic.strip_imp_concl
   406     |> PrimitiveDefs.dest_def ctxt Term.is_Const (K false) (K false)
   407   in (Term.dest_Const (Term.head_of lhs), rhs) end
   408   handle TERM (msg, _) => error msg;
   409 
   410 
   411 
   412 (** read and certify entities **)    (*exception ERROR*)
   413 
   414 (* classes *)
   415 
   416 fun read_class thy c = certify_class thy (intern_class thy c)
   417   handle TYPE (msg, _, _) => error msg;
   418 
   419 
   420 (* type arities *)
   421 
   422 fun prep_arity prep_tycon prep_sort thy (t, Ss, S) =
   423   let val arity = (prep_tycon thy t, map (prep_sort thy) Ss, prep_sort thy S)
   424   in Type.add_arity (Syntax.pp_global thy) arity (tsig_of thy); arity end;
   425 
   426 val read_arity = prep_arity intern_type Syntax.read_sort_global;
   427 val cert_arity = prep_arity (K I) certify_sort;
   428 
   429 
   430 (* types *)
   431 
   432 fun get_sort thy def_sort raw_env =
   433   let
   434     val tsig = tsig_of thy;
   435 
   436     fun eq ((xi, S), (xi', S')) =
   437       Term.eq_ix (xi, xi') andalso Type.eq_sort tsig (S, S');
   438     val env = distinct eq raw_env;
   439     val _ = (case duplicates (eq_fst (op =)) env of [] => ()
   440       | dups => error ("Inconsistent sort constraints for type variable(s) "
   441           ^ commas_quote (map (Term.string_of_vname' o fst) dups)));
   442 
   443     fun get xi =
   444       (case (AList.lookup (op =) env xi, def_sort xi) of
   445         (NONE, NONE) => Type.defaultS tsig
   446       | (NONE, SOME S) => S
   447       | (SOME S, NONE) => S
   448       | (SOME S, SOME S') =>
   449           if Type.eq_sort tsig (S, S') then S'
   450           else error ("Sort constraint inconsistent with default for type variable " ^
   451             quote (Term.string_of_vname' xi)));
   452   in get end;
   453 
   454 local
   455 
   456 fun gen_read_typ mode (thy, def_sort) str =
   457   let
   458     val ctxt = ProofContext.init thy;
   459     val syn = syn_of thy;
   460     val T = intern_tycons thy
   461       (Syntax.standard_parse_typ ctxt syn (get_sort thy def_sort) (intern_sort thy) str);
   462   in certify_typ_mode mode thy T handle TYPE (msg, _, _) => error msg end
   463   handle ERROR msg => cat_error msg ("The error(s) above occurred in type " ^ quote str);
   464 
   465 in
   466 
   467 fun no_def_sort thy = (thy: theory, K NONE);
   468 
   469 val read_def_typ     = gen_read_typ Type.mode_default;
   470 val read_typ         = gen_read_typ Type.mode_default o no_def_sort;
   471 val read_typ_syntax  = gen_read_typ Type.mode_syntax o no_def_sort;
   472 val read_typ_abbrev  = gen_read_typ Type.mode_abbrev o no_def_sort;
   473 
   474 end;
   475 
   476 
   477 
   478 (** signature extension functions **)  (*exception ERROR/TYPE*)
   479 
   480 (* add default sort *)
   481 
   482 fun gen_add_defsort prep_sort s thy =
   483   thy |> map_tsig (Type.set_defsort (prep_sort thy s));
   484 
   485 val add_defsort = gen_add_defsort Syntax.read_sort_global;
   486 val add_defsort_i = gen_add_defsort certify_sort;
   487 
   488 
   489 (* add type constructors *)
   490 
   491 fun add_types types thy = thy |> map_sign (fn (naming, syn, tsig, consts) =>
   492   let
   493     val syn' = Syntax.update_type_gram types syn;
   494     val decls = map (fn (a, n, mx) => (Syntax.type_name a mx, n)) types;
   495     val tsig' = Type.add_types naming decls tsig;
   496   in (naming, syn', tsig', consts) end);
   497 
   498 
   499 (* add nonterminals *)
   500 
   501 fun add_nonterminals ns thy = thy |> map_sign (fn (naming, syn, tsig, consts) =>
   502   let
   503     val syn' = Syntax.update_consts ns syn;
   504     val tsig' = Type.add_nonterminals naming ns tsig;
   505   in (naming, syn', tsig', consts) end);
   506 
   507 
   508 (* add type abbreviations *)
   509 
   510 fun gen_add_tyabbr parse_typ (a, vs, rhs, mx) thy =
   511   thy |> map_sign (fn (naming, syn, tsig, consts) =>
   512     let
   513       val ctxt = ProofContext.init thy;
   514       val syn' = Syntax.update_type_gram [(a, length vs, mx)] syn;
   515       val a' = Syntax.type_name a mx;
   516       val abbr = (a', vs, certify_typ_mode Type.mode_syntax thy (parse_typ ctxt rhs))
   517         handle ERROR msg => cat_error msg ("in type abbreviation " ^ quote a');
   518       val tsig' = Type.add_abbrevs naming [abbr] tsig;
   519     in (naming, syn', tsig', consts) end);
   520 
   521 val add_tyabbrs = fold (gen_add_tyabbr Syntax.parse_typ);
   522 val add_tyabbrs_i = fold (gen_add_tyabbr (K I));
   523 
   524 
   525 (* modify syntax *)
   526 
   527 fun gen_syntax change_gram parse_typ mode args thy =
   528   let
   529     val ctxt = ProofContext.init thy;
   530     fun prep (c, T, mx) = (c, certify_typ_mode Type.mode_syntax thy (parse_typ ctxt T), mx)
   531       handle ERROR msg =>
   532         cat_error msg ("in syntax declaration " ^ quote (Syntax.const_name c mx));
   533   in thy |> map_syn (change_gram (is_logtype thy) mode (map prep args)) end;
   534 
   535 fun gen_add_syntax x = gen_syntax Syntax.update_const_gram x;
   536 
   537 val add_modesyntax = gen_add_syntax Syntax.parse_typ;
   538 val add_modesyntax_i = gen_add_syntax (K I);
   539 val add_syntax = add_modesyntax Syntax.mode_default;
   540 val add_syntax_i = add_modesyntax_i Syntax.mode_default;
   541 val del_modesyntax = gen_syntax Syntax.remove_const_gram Syntax.parse_typ;
   542 val del_modesyntax_i = gen_syntax Syntax.remove_const_gram (K I);
   543 
   544 fun notation add mode args thy =
   545   let
   546     val change_gram = if add then Syntax.update_const_gram else Syntax.remove_const_gram;
   547     fun const_syntax (Const (c, _), mx) = try (Consts.syntax (consts_of thy)) (c, mx)
   548       | const_syntax _ = NONE;
   549   in gen_syntax change_gram (K I) mode (map_filter const_syntax args) thy end;
   550 
   551 
   552 (* add constants *)
   553 
   554 local
   555 
   556 fun gen_add_consts parse_typ authentic tags raw_args thy =
   557   let
   558     val ctxt = ProofContext.init thy;
   559     val prepT = Type.no_tvars o Term.no_dummyT o certify_typ thy o parse_typ ctxt;
   560     fun prep (raw_c, raw_T, raw_mx) =
   561       let
   562         val (c, mx) = Syntax.const_mixfix raw_c raw_mx;
   563         val full_c = full_name thy c;
   564         val c' = if authentic then Syntax.constN ^ full_c else c;
   565         val T = (prepT raw_T handle TYPE (msg, _, _) => error msg) handle ERROR msg =>
   566           cat_error msg ("in declaration of constant " ^ quote c);
   567         val T' = Logic.varifyT T;
   568       in ((c, T'), (c', T', mx), Const (full_c, T)) end;
   569     val args = map prep raw_args;
   570     val tags' = tags |> AList.update (op =) (Markup.theory_nameN, Context.theory_name thy);
   571   in
   572     thy
   573     |> map_consts (fold (Consts.declare authentic (naming_of thy) tags' o #1) args)
   574     |> add_syntax_i (map #2 args)
   575     |> pair (map #3 args)
   576   end;
   577 
   578 in
   579 
   580 val add_consts = snd oo gen_add_consts Syntax.parse_typ false [];
   581 val add_consts_i = snd oo gen_add_consts (K I) false [];
   582 
   583 fun declare_const tags arg = gen_add_consts (K I) true tags [arg] #>> the_single;
   584 
   585 end;
   586 
   587 
   588 (* abbreviations *)
   589 
   590 fun add_abbrev mode tags (c, raw_t) thy =
   591   let
   592     val pp = Syntax.pp_global thy;
   593     val prep_tm = no_frees pp o Term.no_dummy_patterns o cert_term_abbrev thy;
   594     val t = (prep_tm raw_t handle TYPE (msg, _, _) => error msg | TERM (msg, _) => error msg)
   595       handle ERROR msg => cat_error msg ("in constant abbreviation " ^ quote c);
   596     val (res, consts') = consts_of thy
   597       |> Consts.abbreviate pp (tsig_of thy) (naming_of thy) mode tags (c, t);
   598   in (res, thy |> map_consts (K consts')) end;
   599 
   600 fun revert_abbrev mode c = map_consts (Consts.revert_abbrev mode c);
   601 
   602 
   603 (* add constraints *)
   604 
   605 fun add_const_constraint (c, opt_T) thy =
   606   let
   607     fun prepT raw_T =
   608       let val T = Logic.varifyT (Type.no_tvars (Term.no_dummyT (certify_typ thy raw_T)))
   609       in cert_term thy (Const (c, T)); T end
   610       handle TYPE (msg, _, _) => error msg;
   611   in thy |> map_consts (Consts.constrain (c, Option.map prepT opt_T)) end;
   612 
   613 
   614 (* primitive classes and arities *)
   615 
   616 fun primitive_class (bclass, classes) thy =
   617   thy |> map_sign (fn (naming, syn, tsig, consts) =>
   618     let
   619       val syn' = Syntax.update_consts [bclass] syn;
   620       val tsig' = Type.add_class (Syntax.pp_global thy) naming (bclass, classes) tsig;
   621     in (naming, syn', tsig', consts) end)
   622   |> add_consts_i [(Logic.const_of_class bclass, Term.a_itselfT --> propT, NoSyn)];
   623 
   624 fun primitive_classrel arg thy = thy |> map_tsig (Type.add_classrel (Syntax.pp_global thy) arg);
   625 fun primitive_arity arg thy = thy |> map_tsig (Type.add_arity (Syntax.pp_global thy) arg);
   626 
   627 
   628 (* add translation functions *)
   629 
   630 local
   631 
   632 fun mk trs = map Syntax.mk_trfun trs;
   633 
   634 fun gen_add_trfuns ext non_typed (atrs, trs, tr's, atr's) =
   635   map_syn (ext (mk atrs, mk trs, mk (map (apsnd non_typed) tr's), mk atr's));
   636 
   637 fun gen_add_trfunsT ext tr's = map_syn (ext ([], [], mk tr's, []));
   638 
   639 in
   640 
   641 val add_trfuns = gen_add_trfuns Syntax.update_trfuns Syntax.non_typed_tr';
   642 val add_trfunsT = gen_add_trfunsT Syntax.update_trfuns;
   643 val add_advanced_trfuns = gen_add_trfuns Syntax.update_advanced_trfuns Syntax.non_typed_tr'';
   644 val add_advanced_trfunsT = gen_add_trfunsT Syntax.update_advanced_trfuns;
   645 
   646 end;
   647 
   648 val add_tokentrfuns = map_syn o Syntax.extend_tokentrfuns;
   649 fun add_mode_tokentrfuns m = add_tokentrfuns o map (fn (s, f) => (m, s, f));
   650 
   651 
   652 (* translation rules *)
   653 
   654 fun gen_trrules f args thy = thy |> map_syn (fn syn =>
   655   let val rules = map (Syntax.map_trrule (apfst (intern_type thy))) args
   656   in f (ProofContext.init thy) (is_logtype thy) syn rules syn end);
   657 
   658 val add_trrules = gen_trrules Syntax.update_trrules;
   659 val del_trrules = gen_trrules Syntax.remove_trrules;
   660 val add_trrules_i = map_syn o Syntax.update_trrules_i;
   661 val del_trrules_i = map_syn o Syntax.remove_trrules_i;
   662 
   663 
   664 (* naming *)
   665 
   666 val add_path        = map_naming o NameSpace.add_path;
   667 val no_base_names   = map_naming NameSpace.no_base_names;
   668 val qualified_names = map_naming NameSpace.qualified_names;
   669 val sticky_prefix   = map_naming o NameSpace.sticky_prefix;
   670 val restore_naming  = map_naming o K o naming_of;
   671 
   672 val parent_path   = add_path "..";
   673 val root_path     = add_path "/";
   674 val absolute_path = add_path "//";
   675 
   676 fun local_path thy = thy |> root_path |> add_path (Context.theory_name thy);
   677 
   678 
   679 (* hide names *)
   680 
   681 val hide_class = map_tsig oo Type.hide_class;
   682 val hide_type = map_tsig oo Type.hide_type;
   683 val hide_const = map_consts oo Consts.hide;
   684 
   685 end;