src/HOL/Codatatype/Tools/bnf_wrap.ML
author blanchet
Tue Sep 11 18:39:47 2012 +0200 (2012-09-11)
changeset 49286 dde4967c9233
parent 49285 036b833b99aa
child 49297 47fbf2e3e89c
permissions -rw-r--r--
added "defaults" option
     1 (*  Title:      HOL/Codatatype/Tools/bnf_wrap.ML
     2     Author:     Jasmin Blanchette, TU Muenchen
     3     Copyright   2012
     4 
     5 Wrapping existing datatypes.
     6 *)
     7 
     8 signature BNF_WRAP =
     9 sig
    10   val no_binder: binding
    11   val mk_half_pairss: 'a list -> ('a * 'a) list list
    12   val mk_ctr: typ list -> term -> term
    13   val wrap_datatype: ({prems: thm list, context: Proof.context} -> tactic) list list ->
    14     ((bool * term list) * term) *
    15       (binding list * (binding list list * (binding * term) list list)) -> local_theory ->
    16     (term list list * thm list * thm list list) * local_theory
    17   val parse_wrap_options: bool parser
    18   val parse_bound_term: (binding * string) parser
    19 end;
    20 
    21 structure BNF_Wrap : BNF_WRAP =
    22 struct
    23 
    24 open BNF_Util
    25 open BNF_Wrap_Tactics
    26 
    27 val isN = "is_";
    28 val unN = "un_";
    29 fun mk_unN 1 1 suf = unN ^ suf
    30   | mk_unN _ l suf = unN ^ suf ^ string_of_int l;
    31 
    32 val case_congN = "case_cong";
    33 val case_eqN = "case_eq";
    34 val casesN = "cases";
    35 val collapseN = "collapse";
    36 val disc_excludeN = "disc_exclude";
    37 val disc_exhaustN = "disc_exhaust";
    38 val discsN = "discs";
    39 val distinctN = "distinct";
    40 val exhaustN = "exhaust";
    41 val injectN = "inject";
    42 val nchotomyN = "nchotomy";
    43 val selsN = "sels";
    44 val splitN = "split";
    45 val split_asmN = "split_asm";
    46 val weak_case_cong_thmsN = "weak_case_cong";
    47 
    48 val no_binder = @{binding ""};
    49 val fallback_binder = @{binding _};
    50 
    51 fun pad_list x n xs = xs @ replicate (n - length xs) x;
    52 
    53 fun unflat_lookup eq ys zs = map (map (fn x => nth zs (find_index (curry eq x) ys)));
    54 
    55 fun mk_half_pairss' _ [] = []
    56   | mk_half_pairss' indent (y :: ys) =
    57     indent @ fold_rev (cons o single o pair y) ys (mk_half_pairss' ([] :: indent) ys);
    58 
    59 fun mk_half_pairss ys = mk_half_pairss' [[]] ys;
    60 
    61 fun mk_undefined T = Const (@{const_name undefined}, T);
    62 
    63 fun mk_ctr Ts ctr =
    64   let val Type (_, Ts0) = body_type (fastype_of ctr) in
    65     Term.subst_atomic_types (Ts0 ~~ Ts) ctr
    66   end;
    67 
    68 fun eta_expand_case_arg xs f_xs = fold_rev Term.lambda xs f_xs;
    69 
    70 fun name_of_ctr c =
    71   (case head_of c of
    72     Const (s, _) => s
    73   | Free (s, _) => s
    74   | _ => error "Cannot extract name of constructor");
    75 
    76 fun prepare_wrap_datatype prep_term (((no_dests, raw_ctrs), raw_case),
    77     (raw_disc_binders, (raw_sel_binderss, raw_sel_defaultss))) no_defs_lthy =
    78   let
    79     (* TODO: sanity checks on arguments *)
    80     (* TODO: attributes (simp, case_names, etc.) *)
    81     (* TODO: case syntax *)
    82     (* TODO: integration with function package ("size") *)
    83 
    84     val n = length raw_ctrs;
    85     val ks = 1 upto n;
    86 
    87     val _ = if n > 0 then () else error "No constructors specified";
    88 
    89     val ctrs0 = map (prep_term no_defs_lthy) raw_ctrs;
    90     val case0 = prep_term no_defs_lthy raw_case;
    91     val sel_defaultss =
    92       pad_list [] n (map (map (apsnd (prep_term no_defs_lthy))) raw_sel_defaultss);
    93 
    94     val Type (fpT_name, As0) = body_type (fastype_of (hd ctrs0));
    95     val b = Binding.qualified_name fpT_name;
    96 
    97     val (As, B) =
    98       no_defs_lthy
    99       |> mk_TFrees (length As0)
   100       ||> the_single o fst o mk_TFrees 1;
   101 
   102     val fpT = Type (fpT_name, As);
   103     val ctrs = map (mk_ctr As) ctrs0;
   104     val ctr_Tss = map (binder_types o fastype_of) ctrs;
   105 
   106     val ms = map length ctr_Tss;
   107 
   108     val raw_disc_binders' = pad_list no_binder n raw_disc_binders;
   109 
   110     fun can_really_rely_on_disc k =
   111       not (Binding.eq_name (nth raw_disc_binders' (k - 1), no_binder)) orelse nth ms (k - 1) = 0;
   112     fun can_rely_on_disc k =
   113       can_really_rely_on_disc k orelse (k = 1 andalso not (can_really_rely_on_disc 2));
   114     fun can_omit_disc_binder k m =
   115       n = 1 orelse m = 0 orelse (n = 2 andalso can_rely_on_disc (3 - k));
   116 
   117     val fallback_disc_binder = Binding.name o prefix isN o Long_Name.base_name o name_of_ctr;
   118 
   119     val disc_binders =
   120       raw_disc_binders'
   121       |> map4 (fn k => fn m => fn ctr => fn disc =>
   122         if Binding.eq_name (disc, no_binder) then
   123           if can_omit_disc_binder k m then NONE else SOME (fallback_disc_binder ctr)
   124         else if Binding.eq_name (disc, fallback_binder) then
   125           SOME (fallback_disc_binder ctr)
   126         else
   127           SOME disc) ks ms ctrs0;
   128 
   129     val no_discs = map is_none disc_binders;
   130     val no_discs_at_all = forall I no_discs;
   131 
   132     fun fallback_sel_binder m l = Binding.name o mk_unN m l o Long_Name.base_name o name_of_ctr;
   133 
   134     val sel_binderss =
   135       pad_list [] n raw_sel_binderss
   136       |> map3 (fn ctr => fn m => map2 (fn l => fn sel =>
   137         if Binding.eq_name (sel, no_binder) orelse Binding.eq_name (sel, fallback_binder) then
   138           fallback_sel_binder m l ctr
   139         else
   140           sel) (1 upto m) o pad_list no_binder m) ctrs0 ms;
   141 
   142     fun mk_case Ts T =
   143       let
   144         val (binders, body) = strip_type (fastype_of case0)
   145         val Type (_, Ts0) = List.last binders
   146       in Term.subst_atomic_types ((body, T) :: (Ts0 ~~ Ts)) case0 end;
   147 
   148     val casex = mk_case As B;
   149     val case_Ts = map (fn Ts => Ts ---> B) ctr_Tss;
   150 
   151     val (((((((xss, yss), fs), gs), (v, v')), w), (p, p')), names_lthy) = no_defs_lthy |>
   152       mk_Freess "x" ctr_Tss
   153       ||>> mk_Freess "y" ctr_Tss
   154       ||>> mk_Frees "f" case_Ts
   155       ||>> mk_Frees "g" case_Ts
   156       ||>> yield_singleton (apfst (op ~~) oo mk_Frees' "v") fpT
   157       ||>> yield_singleton (mk_Frees "w") fpT
   158       ||>> yield_singleton (apfst (op ~~) oo mk_Frees' "P") HOLogic.boolT;
   159 
   160     val q = Free (fst p', B --> HOLogic.boolT);
   161 
   162     fun ap_v t = t $ v;
   163     fun mk_v_eq_v () = HOLogic.mk_eq (v, v);
   164 
   165     val xctrs = map2 (curry Term.list_comb) ctrs xss;
   166     val yctrs = map2 (curry Term.list_comb) ctrs yss;
   167 
   168     val xfs = map2 (curry Term.list_comb) fs xss;
   169     val xgs = map2 (curry Term.list_comb) gs xss;
   170 
   171     val eta_fs = map2 eta_expand_case_arg xss xfs;
   172     val eta_gs = map2 eta_expand_case_arg xss xgs;
   173 
   174     val fcase = Term.list_comb (casex, eta_fs);
   175     val gcase = Term.list_comb (casex, eta_gs);
   176 
   177     val exist_xs_v_eq_ctrs =
   178       map2 (fn xctr => fn xs => list_exists_free xs (HOLogic.mk_eq (v, xctr))) xctrs xss;
   179 
   180     val unique_disc_no_def = TrueI; (*arbitrary marker*)
   181     val alternate_disc_no_def = FalseE; (*arbitrary marker*)
   182 
   183     fun alternate_disc_lhs get_disc k =
   184       HOLogic.mk_not
   185         (case nth disc_binders (k - 1) of
   186           NONE => nth exist_xs_v_eq_ctrs (k - 1)
   187         | SOME b => get_disc b (k - 1) $ v);
   188 
   189     val (all_sels_distinct, discs, selss, disc_defs, sel_defs, sel_defss, lthy') =
   190       if no_dests then
   191         (true, [], [], [], [], [], no_defs_lthy)
   192       else
   193         let
   194           fun disc_free b = Free (Binding.name_of b, fpT --> HOLogic.boolT);
   195 
   196           fun disc_spec b exist_xs_v_eq_ctr = mk_Trueprop_eq (disc_free b $ v, exist_xs_v_eq_ctr);
   197 
   198           fun alternate_disc k = Term.lambda v (alternate_disc_lhs (K o disc_free) (3 - k));
   199 
   200           fun mk_sel_case_args b proto_sels T =
   201             map2 (fn Ts => fn k =>
   202               (case AList.lookup (op =) proto_sels k of
   203                 NONE =>
   204                 let val def_T = Ts ---> T in
   205                   (case AList.lookup Binding.eq_name (rev (nth sel_defaultss (k - 1))) b of
   206                     NONE => mk_undefined def_T
   207                   | SOME t => fold_rev (fn T => Term.lambda (Free (Name.uu, T))) Ts
   208                       (Term.subst_atomic_types [(fastype_of t, T)] t))
   209                 end
   210               | SOME (xs, x) => fold_rev Term.lambda xs x)) ctr_Tss ks;
   211 
   212           fun sel_spec b proto_sels =
   213             let
   214               val _ =
   215                 (case duplicates (op =) (map fst proto_sels) of
   216                    k :: _ => error ("Duplicate selector name " ^ quote (Binding.name_of b) ^
   217                      " for constructor " ^
   218                      quote (Syntax.string_of_term no_defs_lthy (nth ctrs (k - 1))))
   219                  | [] => ())
   220               val T =
   221                 (case distinct (op =) (map (fastype_of o snd o snd) proto_sels) of
   222                   [T] => T
   223                 | T :: T' :: _ => error ("Inconsistent range type for selector " ^
   224                     quote (Binding.name_of b) ^ ": " ^ quote (Syntax.string_of_typ no_defs_lthy T) ^
   225                     " vs. " ^ quote (Syntax.string_of_typ no_defs_lthy T')));
   226             in
   227               mk_Trueprop_eq (Free (Binding.name_of b, fpT --> T) $ v,
   228                 Term.list_comb (mk_case As T, mk_sel_case_args b proto_sels T) $ v)
   229             end;
   230 
   231           val sel_binders = flat sel_binderss;
   232           val uniq_sel_binders = distinct Binding.eq_name sel_binders;
   233           val all_sels_distinct = (length uniq_sel_binders = length sel_binders);
   234 
   235           val sel_binder_index =
   236             if all_sels_distinct then 1 upto length sel_binders
   237             else map (fn b => find_index (curry Binding.eq_name b) uniq_sel_binders) sel_binders;
   238 
   239           val proto_sels = flat (map3 (fn k => fn xs => map (fn x => (k, (xs, x)))) ks xss xss);
   240           val sel_bundles =
   241             AList.group (op =) (sel_binder_index ~~ proto_sels)
   242             |> sort (int_ord o pairself fst)
   243             |> map snd |> curry (op ~~) uniq_sel_binders;
   244           val sel_binders = map fst sel_bundles;
   245 
   246           fun unflat_selss xs = unflat_lookup Binding.eq_name sel_binders xs sel_binderss;
   247 
   248           val (((raw_discs, raw_disc_defs), (raw_sels, raw_sel_defs)), (lthy', lthy)) =
   249             no_defs_lthy
   250             |> apfst split_list o fold_map4 (fn k => fn m => fn exist_xs_v_eq_ctr =>
   251               fn NONE =>
   252                  if n = 1 then pair (Term.lambda v (mk_v_eq_v ()), unique_disc_no_def)
   253                  else if m = 0 then pair (Term.lambda v exist_xs_v_eq_ctr, refl)
   254                  else pair (alternate_disc k, alternate_disc_no_def)
   255                | SOME b => Specification.definition (SOME (b, NONE, NoSyn),
   256                    ((Thm.def_binding b, []), disc_spec b exist_xs_v_eq_ctr)) #>> apsnd snd)
   257               ks ms exist_xs_v_eq_ctrs disc_binders
   258             ||>> apfst split_list o fold_map (fn (b, proto_sels) =>
   259               Specification.definition (SOME (b, NONE, NoSyn),
   260                 ((Thm.def_binding b, []), sel_spec b proto_sels)) #>> apsnd snd) sel_bundles
   261             ||> `Local_Theory.restore;
   262 
   263           (*transforms defined frees into consts (and more)*)
   264           val phi = Proof_Context.export_morphism lthy lthy';
   265 
   266           val disc_defs = map (Morphism.thm phi) raw_disc_defs;
   267           val sel_defs = map (Morphism.thm phi) raw_sel_defs;
   268           val sel_defss = unflat_selss sel_defs;
   269 
   270           val discs0 = map (Morphism.term phi) raw_discs;
   271           val selss0 = unflat_selss (map (Morphism.term phi) raw_sels);
   272 
   273           fun mk_disc_or_sel Ts c =
   274             Term.subst_atomic_types (snd (Term.dest_Type (domain_type (fastype_of c))) ~~ Ts) c;
   275 
   276           val discs = map (mk_disc_or_sel As) discs0;
   277           val selss = map (map (mk_disc_or_sel As)) selss0;
   278         in
   279           (all_sels_distinct, discs, selss, disc_defs, sel_defs, sel_defss, lthy')
   280         end;
   281 
   282     fun mk_imp_p Qs = Logic.list_implies (Qs, HOLogic.mk_Trueprop p);
   283 
   284     val goal_exhaust =
   285       let fun mk_prem xctr xs = fold_rev Logic.all xs (mk_imp_p [mk_Trueprop_eq (v, xctr)]) in
   286         fold_rev Logic.all [p, v] (mk_imp_p (map2 mk_prem xctrs xss))
   287       end;
   288 
   289     val goal_injectss =
   290       let
   291         fun mk_goal _ _ [] [] = []
   292           | mk_goal xctr yctr xs ys =
   293             [fold_rev Logic.all (xs @ ys) (mk_Trueprop_eq (HOLogic.mk_eq (xctr, yctr),
   294               Library.foldr1 HOLogic.mk_conj (map2 (curry HOLogic.mk_eq) xs ys)))];
   295       in
   296         map4 mk_goal xctrs yctrs xss yss
   297       end;
   298 
   299     val goal_half_distinctss =
   300       let
   301         fun mk_goal ((xs, xc), (xs', xc')) =
   302           fold_rev Logic.all (xs @ xs')
   303             (HOLogic.mk_Trueprop (HOLogic.mk_not (HOLogic.mk_eq (xc, xc'))));
   304       in
   305         map (map mk_goal) (mk_half_pairss (xss ~~ xctrs))
   306       end;
   307 
   308     val goal_cases =
   309       map3 (fn xs => fn xctr => fn xf =>
   310         fold_rev Logic.all (fs @ xs) (mk_Trueprop_eq (fcase $ xctr, xf))) xss xctrs xfs;
   311 
   312     val goalss = [goal_exhaust] :: goal_injectss @ goal_half_distinctss @ [goal_cases];
   313 
   314     fun after_qed thmss lthy =
   315       let
   316         val ([exhaust_thm], (inject_thmss, (half_distinct_thmss, [case_thms]))) =
   317           (hd thmss, apsnd (chop (n * n)) (chop n (tl thmss)));
   318 
   319         val exhaust_thm' =
   320           let val Tinst = map (pairself (certifyT lthy)) (map Logic.varifyT_global As ~~ As) in
   321             Drule.instantiate' [] [SOME (certify lthy v)]
   322               (Thm.instantiate (Tinst, []) (Drule.zero_var_indexes exhaust_thm))
   323           end;
   324 
   325         val other_half_distinct_thmss = map (map (fn thm => thm RS not_sym)) half_distinct_thmss;
   326 
   327         val (distinct_thmsss', distinct_thmsss) =
   328           map2 (map2 append) (Library.chop_groups n half_distinct_thmss)
   329             (transpose (Library.chop_groups n other_half_distinct_thmss))
   330           |> `transpose;
   331         val distinct_thms = interleave (flat half_distinct_thmss) (flat other_half_distinct_thmss);
   332 
   333         val nchotomy_thm =
   334           let
   335             val goal =
   336               HOLogic.mk_Trueprop (HOLogic.mk_all (fst v', snd v',
   337                 Library.foldr1 HOLogic.mk_disj exist_xs_v_eq_ctrs));
   338           in
   339             Skip_Proof.prove lthy [] [] goal (fn _ => mk_nchotomy_tac n exhaust_thm)
   340           end;
   341 
   342         val (all_sel_thms, sel_thmss, disc_thms, discI_thms, disc_exclude_thms, disc_exhaust_thms,
   343              collapse_thms, case_eq_thms) =
   344           if no_dests then
   345             ([], [], [], [], [], [], [], [])
   346           else
   347             let
   348               fun make_sel_thm case_thm sel_def = case_thm RS (sel_def RS trans);
   349 
   350               fun has_undefined_rhs thm =
   351                 (case snd (HOLogic.dest_eq (HOLogic.dest_Trueprop (prop_of thm))) of
   352                   Const (@{const_name undefined}, _) => true
   353                 | _ => false);
   354 
   355               val sel_thmss = map2 (map o make_sel_thm) case_thms sel_defss;
   356 
   357               val all_sel_thms =
   358                 (if all_sels_distinct andalso forall null sel_defaultss then
   359                    flat sel_thmss
   360                  else
   361                    map_product (fn s => fn c => make_sel_thm c s) sel_defs case_thms)
   362                 |> filter_out has_undefined_rhs;
   363 
   364               fun mk_unique_disc_def () =
   365                 let
   366                   val m = the_single ms;
   367                   val goal = mk_Trueprop_eq (mk_v_eq_v (), the_single exist_xs_v_eq_ctrs);
   368                 in
   369                   Skip_Proof.prove lthy [] [] goal (fn _ => mk_unique_disc_def_tac m exhaust_thm')
   370                   |> singleton (Proof_Context.export names_lthy lthy)
   371                   |> Thm.close_derivation
   372                 end;
   373 
   374               fun mk_alternate_disc_def k =
   375                 let
   376                   val goal =
   377                     mk_Trueprop_eq (alternate_disc_lhs (K (nth discs)) (3 - k),
   378                       nth exist_xs_v_eq_ctrs (k - 1));
   379                 in
   380                   Skip_Proof.prove lthy [] [] goal (fn {context = ctxt, ...} =>
   381                     mk_alternate_disc_def_tac ctxt k (nth disc_defs (2 - k))
   382                       (nth distinct_thms (2 - k)) exhaust_thm')
   383                   |> singleton (Proof_Context.export names_lthy lthy)
   384                   |> Thm.close_derivation
   385                 end;
   386 
   387               val has_alternate_disc_def =
   388                 exists (fn def => Thm.eq_thm_prop (def, alternate_disc_no_def)) disc_defs;
   389 
   390               val disc_defs' =
   391                 map2 (fn k => fn def =>
   392                   if Thm.eq_thm_prop (def, unique_disc_no_def) then mk_unique_disc_def ()
   393                   else if Thm.eq_thm_prop (def, alternate_disc_no_def) then mk_alternate_disc_def k
   394                   else def) ks disc_defs;
   395 
   396               val discD_thms = map (fn def => def RS iffD1) disc_defs';
   397               val discI_thms =
   398                 map2 (fn m => fn def => funpow m (fn thm => exI RS thm) (def RS iffD2)) ms
   399                   disc_defs';
   400               val not_discI_thms =
   401                 map2 (fn m => fn def => funpow m (fn thm => allI RS thm)
   402                     (Local_Defs.unfold lthy @{thms not_ex} (def RS @{thm ssubst[of _ _ Not]})))
   403                   ms disc_defs';
   404 
   405               val (disc_thmss', disc_thmss) =
   406                 let
   407                   fun mk_thm discI _ [] = refl RS discI
   408                     | mk_thm _ not_discI [distinct] = distinct RS not_discI;
   409                   fun mk_thms discI not_discI distinctss = map (mk_thm discI not_discI) distinctss;
   410                 in
   411                   map3 mk_thms discI_thms not_discI_thms distinct_thmsss' |> `transpose
   412                 end;
   413 
   414               val disc_thms = flat (map2 (fn true => K [] | false => I) no_discs disc_thmss);
   415 
   416               val disc_exclude_thms =
   417                 if has_alternate_disc_def then
   418                   []
   419                 else
   420                   let
   421                     fun mk_goal [] = []
   422                       | mk_goal [((_, true), (_, true))] = []
   423                       | mk_goal [(((_, disc), _), ((_, disc'), _))] =
   424                         [Logic.all v (Logic.mk_implies (HOLogic.mk_Trueprop (betapply (disc, v)),
   425                            HOLogic.mk_Trueprop (HOLogic.mk_not (betapply (disc', v)))))];
   426                     fun prove tac goal = Skip_Proof.prove lthy [] [] goal (K tac);
   427 
   428                     val bundles = ms ~~ discD_thms ~~ discs ~~ no_discs;
   429                     val half_pairss = mk_half_pairss bundles;
   430 
   431                     val goal_halvess = map mk_goal half_pairss;
   432                     val half_thmss =
   433                       map3 (fn [] => K (K []) | [goal] => fn [((((m, discD), _), _), _)] =>
   434                           fn disc_thm => [prove (mk_half_disc_exclude_tac m discD disc_thm) goal])
   435                         goal_halvess half_pairss (flat disc_thmss');
   436 
   437                     val goal_other_halvess = map (mk_goal o map swap) half_pairss;
   438                     val other_half_thmss =
   439                       map2 (map2 (prove o mk_other_half_disc_exclude_tac)) half_thmss
   440                         goal_other_halvess;
   441                   in
   442                     interleave (flat half_thmss) (flat other_half_thmss)
   443                   end;
   444 
   445               val disc_exhaust_thms =
   446                 if has_alternate_disc_def orelse no_discs_at_all then
   447                   []
   448                 else
   449                   let
   450                     fun mk_prem disc = mk_imp_p [HOLogic.mk_Trueprop (betapply (disc, v))];
   451                     val goal = fold_rev Logic.all [p, v] (mk_imp_p (map mk_prem discs));
   452                   in
   453                     [Skip_Proof.prove lthy [] [] goal (fn _ =>
   454                        mk_disc_exhaust_tac n exhaust_thm discI_thms)]
   455                   end;
   456 
   457               val collapse_thms =
   458                 if no_dests then
   459                   []
   460                 else
   461                   let
   462                     fun mk_goal ctr disc sels =
   463                       let
   464                         val prem = HOLogic.mk_Trueprop (betapply (disc, v));
   465                         val concl =
   466                           mk_Trueprop_eq ((null sels ? swap)
   467                             (Term.list_comb (ctr, map ap_v sels), v));
   468                       in
   469                         if prem aconv concl then NONE
   470                         else SOME (Logic.all v (Logic.mk_implies (prem, concl)))
   471                       end;
   472                     val goals = map3 mk_goal ctrs discs selss;
   473                   in
   474                     map4 (fn m => fn discD => fn sel_thms => Option.map (fn goal =>
   475                       Skip_Proof.prove lthy [] [] goal (fn {context = ctxt, ...} =>
   476                         mk_collapse_tac ctxt m discD sel_thms)
   477                       |> perhaps (try (fn thm => refl RS thm)))) ms discD_thms sel_thmss goals
   478                     |> map_filter I
   479                   end;
   480 
   481               val case_eq_thms =
   482                 if no_dests then
   483                   []
   484                 else
   485                   let
   486                     fun mk_body f sels = Term.list_comb (f, map ap_v sels);
   487                     val goal =
   488                       mk_Trueprop_eq (fcase $ v, mk_IfN B (map ap_v discs) (map2 mk_body fs selss));
   489                   in
   490                     [Skip_Proof.prove lthy [] [] goal (fn {context = ctxt, ...} =>
   491                       mk_case_eq_tac ctxt n exhaust_thm' case_thms disc_thmss' sel_thmss)]
   492                     |> Proof_Context.export names_lthy lthy
   493                   end;
   494             in
   495               (all_sel_thms, sel_thmss, disc_thms, discI_thms, disc_exclude_thms, disc_exhaust_thms,
   496                collapse_thms, case_eq_thms)
   497             end;
   498 
   499         val (case_cong_thm, weak_case_cong_thm) =
   500           let
   501             fun mk_prem xctr xs f g =
   502               fold_rev Logic.all xs (Logic.mk_implies (mk_Trueprop_eq (w, xctr),
   503                 mk_Trueprop_eq (f, g)));
   504 
   505             val v_eq_w = mk_Trueprop_eq (v, w);
   506 
   507             val goal =
   508               Logic.list_implies (v_eq_w :: map4 mk_prem xctrs xss fs gs,
   509                  mk_Trueprop_eq (fcase $ v, gcase $ w));
   510             val goal_weak = Logic.mk_implies (v_eq_w, mk_Trueprop_eq (fcase $ v, fcase $ w));
   511           in
   512             (Skip_Proof.prove lthy [] [] goal (fn _ => mk_case_cong_tac exhaust_thm' case_thms),
   513              Skip_Proof.prove lthy [] [] goal_weak (K (etac arg_cong 1)))
   514             |> pairself (singleton (Proof_Context.export names_lthy lthy))
   515           end;
   516 
   517         val (split_thm, split_asm_thm) =
   518           let
   519             fun mk_conjunct xctr xs f_xs =
   520               list_all_free xs (HOLogic.mk_imp (HOLogic.mk_eq (v, xctr), q $ f_xs));
   521             fun mk_disjunct xctr xs f_xs =
   522               list_exists_free xs (HOLogic.mk_conj (HOLogic.mk_eq (v, xctr),
   523                 HOLogic.mk_not (q $ f_xs)));
   524 
   525             val lhs = q $ (fcase $ v);
   526 
   527             val goal =
   528               mk_Trueprop_eq (lhs, Library.foldr1 HOLogic.mk_conj (map3 mk_conjunct xctrs xss xfs));
   529             val goal_asm =
   530               mk_Trueprop_eq (lhs, HOLogic.mk_not (Library.foldr1 HOLogic.mk_disj
   531                 (map3 mk_disjunct xctrs xss xfs)));
   532 
   533             val split_thm =
   534               Skip_Proof.prove lthy [] [] goal
   535                 (fn _ => mk_split_tac exhaust_thm' case_thms inject_thmss distinct_thmsss)
   536               |> singleton (Proof_Context.export names_lthy lthy)
   537             val split_asm_thm =
   538               Skip_Proof.prove lthy [] [] goal_asm (fn {context = ctxt, ...} =>
   539                 mk_split_asm_tac ctxt split_thm)
   540               |> singleton (Proof_Context.export names_lthy lthy)
   541           in
   542             (split_thm, split_asm_thm)
   543           end;
   544 
   545         val notes =
   546           [(case_congN, [case_cong_thm]),
   547            (case_eqN, case_eq_thms),
   548            (casesN, case_thms),
   549            (collapseN, collapse_thms),
   550            (discsN, disc_thms),
   551            (disc_excludeN, disc_exclude_thms),
   552            (disc_exhaustN, disc_exhaust_thms),
   553            (distinctN, distinct_thms),
   554            (exhaustN, [exhaust_thm]),
   555            (injectN, flat inject_thmss),
   556            (nchotomyN, [nchotomy_thm]),
   557            (selsN, all_sel_thms),
   558            (splitN, [split_thm]),
   559            (split_asmN, [split_asm_thm]),
   560            (weak_case_cong_thmsN, [weak_case_cong_thm])]
   561           |> filter_out (null o snd)
   562           |> map (fn (thmN, thms) =>
   563             ((Binding.qualify true (Binding.name_of b) (Binding.name thmN), []), [(thms, [])]));
   564       in
   565         ((selss, discI_thms, sel_thmss), lthy |> Local_Theory.notes notes |> snd)
   566       end;
   567   in
   568     (goalss, after_qed, lthy')
   569   end;
   570 
   571 fun wrap_datatype tacss = (fn (goalss, after_qed, lthy) =>
   572   map2 (map2 (Skip_Proof.prove lthy [] [])) goalss tacss
   573   |> (fn thms => after_qed thms lthy)) oo prepare_wrap_datatype (K I);
   574 
   575 fun parse_bracket_list parser = @{keyword "["} |-- Parse.list parser --|  @{keyword "]"};
   576 
   577 val parse_bindings = parse_bracket_list Parse.binding;
   578 val parse_bindingss = parse_bracket_list parse_bindings;
   579 
   580 val parse_bound_term = (Parse.binding --| @{keyword ":"}) -- Parse.term;
   581 val parse_bound_terms = parse_bracket_list parse_bound_term;
   582 val parse_bound_termss = parse_bracket_list parse_bound_terms;
   583 
   584 val wrap_datatype_cmd = (fn (goalss, after_qed, lthy) =>
   585   Proof.theorem NONE (snd oo after_qed) (map (map (rpair [])) goalss) lthy) oo
   586   prepare_wrap_datatype Syntax.read_term;
   587 
   588 val parse_wrap_options =
   589   Scan.optional (@{keyword "("} |-- (@{keyword "no_dests"} >> K true) --| @{keyword ")"}) false;
   590 
   591 val _ =
   592   Outer_Syntax.local_theory_to_proof @{command_spec "wrap_data"} "wraps an existing datatype"
   593     ((parse_wrap_options -- (@{keyword "["} |-- Parse.list Parse.term --| @{keyword "]"}) --
   594       Parse.term -- Scan.optional (parse_bindings -- Scan.optional (parse_bindingss --
   595         Scan.optional parse_bound_termss []) ([], [])) ([], ([], [])))
   596      >> wrap_datatype_cmd);
   597 
   598 end;