src/Pure/pure_thy.ML
author berghofe
Mon Jan 21 14:18:49 2008 +0100 (2008-01-21)
changeset 25939 ddea202704b4
parent 25598 2f0b4544f4b3
child 25981 870ae1d0452e
permissions -rw-r--r--
Removed Logic.auto_rename.
     1 (*  Title:      Pure/pure_thy.ML
     2     ID:         $Id$
     3     Author:     Markus Wenzel, TU Muenchen
     4 
     5 Theorem storage.  The ProtoPure theory.
     6 *)
     7 
     8 signature BASIC_PURE_THY =
     9 sig
    10   datatype interval = FromTo of int * int | From of int | Single of int
    11   datatype thmref =
    12     Name of string |
    13     NameSelection of string * interval list |
    14     Fact of string
    15   val get_thm: theory -> thmref -> thm
    16   val get_thms: theory -> thmref -> thm list
    17   val get_thmss: theory -> thmref list -> thm list
    18   structure ProtoPure:
    19     sig
    20       val thy: theory
    21       val prop_def: thm
    22       val term_def: thm
    23       val conjunction_def: thm
    24     end
    25 end;
    26 
    27 signature PURE_THY =
    28 sig
    29   include BASIC_PURE_THY
    30   val tag_rule: Markup.property -> thm -> thm
    31   val untag_rule: string -> thm -> thm
    32   val tag: Markup.property -> attribute
    33   val untag: string -> attribute
    34   val has_name_hint: thm -> bool
    35   val get_name_hint: thm -> string
    36   val put_name_hint: string -> thm -> thm
    37   val has_kind: thm -> bool
    38   val get_kind: thm -> string
    39   val kind_rule: string -> thm -> thm
    40   val kind: string -> attribute
    41   val kind_internal: attribute
    42   val has_internal: Markup.property list -> bool
    43   val is_internal: thm -> bool
    44   val string_of_thmref: thmref -> string
    45   val get_thm_closure: theory -> thmref -> thm
    46   val get_thms_closure: theory -> thmref -> thm list
    47   val single_thm: string -> thm list -> thm
    48   val name_of_thmref: thmref -> string
    49   val map_name_of_thmref: (string -> string) -> thmref -> thmref
    50   val select_thm: thmref -> thm list -> thm list
    51   val selections: string * thm list -> (thmref * thm) list
    52   val theorems_of: theory -> thm list NameSpace.table
    53   val fact_index_of: theory -> FactIndex.T
    54   val valid_thms: theory -> thmref * thm list -> bool
    55   val thms_containing: theory -> FactIndex.spec -> (string * thm list) list
    56   val thms_containing_consts: theory -> string list -> (string * thm) list
    57   val thms_of: theory -> (string * thm) list
    58   val all_thms_of: theory -> (string * thm) list
    59   val hide_thms: bool -> string list -> theory -> theory
    60   val map_facts: ('a -> 'b) -> ('c * ('a list * 'd) list) list -> ('c * ('b list * 'd) list) list
    61   val burrow_fact: ('a list -> 'b list) -> ('a list * 'c) list -> ('b list * 'c) list
    62   val burrow_facts: ('a list -> 'b list) ->
    63     ('c * ('a list * 'd) list) list -> ('c * ('b list * 'd) list) list
    64   val name_multi: string -> 'a list -> (string * 'a) list
    65   val name_thm: bool -> bool -> string -> thm -> thm
    66   val name_thms: bool -> bool -> string -> thm list -> thm list
    67   val name_thmss: bool -> string -> (thm list * 'a) list -> (thm list * 'a) list
    68   val store_thm: (bstring * thm) * attribute list -> theory -> thm * theory
    69   val smart_store_thms: (bstring * thm list) -> thm list
    70   val smart_store_thms_open: (bstring * thm list) -> thm list
    71   val forall_elim_var: int -> thm -> thm
    72   val forall_elim_vars: int -> thm -> thm
    73   val add_thms: ((bstring * thm) * attribute list) list -> theory -> thm list * theory
    74   val add_thmss: ((bstring * thm list) * attribute list) list -> theory -> thm list list * theory
    75   val note: string -> string * thm -> theory -> thm * theory
    76   val note_thmss: string -> ((bstring * attribute list) *
    77     (thmref * attribute list) list) list -> theory -> (bstring * thm list) list * theory
    78   val note_thmss_i: string -> ((bstring * attribute list) *
    79     (thm list * attribute list) list) list -> theory -> (bstring * thm list) list * theory
    80   val note_thmss_qualified: string -> string -> ((bstring * attribute list) *
    81     (thm list * attribute list) list) list -> theory -> (bstring * thm list) list * theory
    82   val add_axioms: ((bstring * string) * attribute list) list -> theory -> thm list * theory
    83   val add_axioms_i: ((bstring * term) * attribute list) list -> theory -> thm list * theory
    84   val add_axiomss: ((bstring * string list) * attribute list) list ->
    85     theory -> thm list list * theory
    86   val add_axiomss_i: ((bstring * term list) * attribute list) list ->
    87     theory -> thm list list * theory
    88   val add_defs: bool -> ((bstring * string) * attribute list) list ->
    89     theory -> thm list * theory
    90   val add_defs_i: bool -> ((bstring * term) * attribute list) list ->
    91     theory -> thm list * theory
    92   val add_defs_unchecked: bool -> ((bstring * string) * attribute list) list ->
    93     theory -> thm list * theory
    94   val add_defs_unchecked_i: bool -> ((bstring * term) * attribute list) list ->
    95     theory -> thm list * theory
    96   val appl_syntax: (string * typ * mixfix) list
    97   val applC_syntax: (string * typ * mixfix) list
    98 end;
    99 
   100 structure PureThy: PURE_THY =
   101 struct
   102 
   103 
   104 (*** theorem tags ***)
   105 
   106 (* add / delete tags *)
   107 
   108 fun tag_rule tg = Thm.map_tags (insert (op =) tg);
   109 fun untag_rule s = Thm.map_tags (filter_out (fn (s', _) => s = s'));
   110 
   111 fun tag tg x = Thm.rule_attribute (K (tag_rule tg)) x;
   112 fun untag s x = Thm.rule_attribute (K (untag_rule s)) x;
   113 
   114 
   115 (* unofficial theorem names *)
   116 
   117 fun the_name_hint thm = the (AList.lookup (op =) (Thm.get_tags thm) Markup.nameN);
   118 
   119 val has_name_hint = can the_name_hint;
   120 val get_name_hint = the_default "??.unknown" o try the_name_hint;
   121 
   122 fun put_name_hint name = untag_rule Markup.nameN #> tag_rule (Markup.nameN, name);
   123 
   124 
   125 (* theorem kinds *)
   126 
   127 fun the_kind thm = the (AList.lookup (op =) (Thm.get_tags thm) Markup.kindN);
   128 
   129 val has_kind = can the_kind;
   130 val get_kind = the_default "??.unknown" o try the_kind;
   131 
   132 fun kind_rule k = tag_rule (Markup.kindN, k) o untag_rule Markup.kindN;
   133 fun kind k x = if k = "" then x else Thm.rule_attribute (K (kind_rule k)) x;
   134 fun kind_internal x = kind Thm.internalK x;
   135 fun has_internal tags = exists (fn tg => tg = (Markup.kindN, Thm.internalK)) tags;
   136 val is_internal = has_internal o Thm.get_tags;
   137 
   138 
   139 
   140 (*** theorem database ***)
   141 
   142 (** dataype theorems **)
   143 
   144 structure TheoremsData = TheoryDataFun
   145 (
   146   type T =
   147    {theorems: thm list NameSpace.table,
   148     index: FactIndex.T} ref;
   149 
   150   fun mk_empty _ =
   151     ref {theorems = NameSpace.empty_table, index = FactIndex.empty}: T;
   152 
   153   val empty = mk_empty ();
   154   fun copy (ref x) = ref x;
   155   val extend = mk_empty;
   156   fun merge _ = mk_empty;
   157 );
   158 
   159 val get_theorems_ref = TheoremsData.get;
   160 val get_theorems = ! o get_theorems_ref;
   161 val theorems_of = #theorems o get_theorems;
   162 val fact_index_of = #index o get_theorems;
   163 
   164 
   165 
   166 (** retrieve theorems **)
   167 
   168 fun the_thms _ (SOME thms) = thms
   169   | the_thms name NONE = error ("Unknown theorem(s) " ^ quote name);
   170 
   171 fun single_thm _ [thm] = thm
   172   | single_thm name _ = error ("Single theorem expected " ^ quote name);
   173 
   174 
   175 (* datatype interval *)
   176 
   177 datatype interval =
   178   FromTo of int * int |
   179   From of int |
   180   Single of int;
   181 
   182 fun string_of_interval (FromTo (i, j)) = string_of_int i ^ "-" ^ string_of_int j
   183   | string_of_interval (From i) = string_of_int i ^ "-"
   184   | string_of_interval (Single i) = string_of_int i;
   185 
   186 fun interval n iv =
   187   let fun err () = raise Fail ("Bad interval specification " ^ string_of_interval iv) in
   188     (case iv of
   189       FromTo (i, j) => if i <= j then i upto j else err ()
   190     | From i => if i <= n then i upto n else err ()
   191     | Single i => [i])
   192   end;
   193 
   194 
   195 (* datatype thmref *)
   196 
   197 datatype thmref =
   198   Name of string |
   199   NameSelection of string * interval list |
   200   Fact of string;
   201 
   202 fun name_of_thmref (Name name) = name
   203   | name_of_thmref (NameSelection (name, _)) = name
   204   | name_of_thmref (Fact _) = error "Illegal literal fact";
   205 
   206 fun map_name_of_thmref f (Name name) = Name (f name)
   207   | map_name_of_thmref f (NameSelection (name, is)) = NameSelection (f name, is)
   208   | map_name_of_thmref _ thmref = thmref;
   209 
   210 fun string_of_thmref (Name name) = name
   211   | string_of_thmref (NameSelection (name, is)) =
   212       name ^ enclose "(" ")" (commas (map string_of_interval is))
   213   | string_of_thmref (Fact _) = error "Illegal literal fact";
   214 
   215 
   216 (* select_thm *)
   217 
   218 fun select_thm (Name _) thms = thms
   219   | select_thm (Fact _) thms = thms
   220   | select_thm (NameSelection (name, ivs)) thms =
   221       let
   222         val n = length thms;
   223         fun err msg = error (msg ^ " for " ^ quote name ^ " (length " ^ string_of_int n ^ ")");
   224         fun select i =
   225           if i < 1 orelse i > n then err ("Bad subscript " ^ string_of_int i)
   226           else nth thms (i - 1);
   227         val is = maps (interval n) ivs handle Fail msg => err msg;
   228       in map select is end;
   229 
   230 
   231 (* selections *)
   232 
   233 fun selections (name, [thm]) = [(Name name, thm)]
   234   | selections (name, thms) = (1 upto length thms, thms) |> ListPair.map (fn (i, thm) =>
   235       (NameSelection (name, [Single i]), thm));
   236 
   237 
   238 (* get_thm(s)_closure -- statically scoped versions *)
   239 
   240 (*beware of proper order of evaluation!*)
   241 
   242 fun lookup_thms thy =
   243   let
   244     val (space, thms) = #theorems (get_theorems thy);
   245     val thy_ref = Theory.check_thy thy;
   246   in
   247     fn name =>
   248       Option.map (map (Thm.transfer (Theory.deref thy_ref)))     (*dynamic identity*)
   249       (Symtab.lookup thms (NameSpace.intern space name)) (*static content*)
   250   end;
   251 
   252 fun get_thms_closure thy =
   253   let val closures = map lookup_thms (thy :: Theory.ancestors_of thy) in
   254     fn thmref =>
   255       let val name = name_of_thmref thmref;
   256       in select_thm thmref (the_thms name (get_first (fn f => f name) closures)) end
   257   end;
   258 
   259 fun get_thm_closure thy =
   260   let val get = get_thms_closure thy
   261   in fn thmref => single_thm (name_of_thmref thmref) (get thmref) end;
   262 
   263 
   264 (* get_thms etc. *)
   265 
   266 fun get_thms theory thmref =
   267   let val name = name_of_thmref thmref in
   268     get_first (fn thy => lookup_thms thy name) (theory :: Theory.ancestors_of theory)
   269     |> the_thms name |> select_thm thmref |> map (Thm.transfer theory)
   270   end;
   271 
   272 fun get_thmss thy thmrefs = maps (get_thms thy) thmrefs;
   273 fun get_thm thy thmref = single_thm (name_of_thmref thmref) (get_thms thy thmref);
   274 
   275 
   276 (* thms_containing etc. *)
   277 
   278 fun valid_thms thy (thmref, ths) =
   279   (case try (get_thms thy) thmref of
   280     NONE => false
   281   | SOME ths' => Thm.eq_thms (ths, ths'));
   282 
   283 fun thms_containing theory spec =
   284   (theory :: Theory.ancestors_of theory)
   285   |> maps (fn thy =>
   286       FactIndex.find (fact_index_of thy) spec
   287       |> List.filter (fn (name, ths) => valid_thms theory (Name name, ths))
   288       |> distinct (eq_fst (op =)));
   289 
   290 fun thms_containing_consts thy consts =
   291   thms_containing thy (consts, []) |> maps #2
   292   |> map (`(get_name_hint));
   293 
   294 
   295 (* thms_of etc. *)
   296 
   297 fun thms_of thy =
   298   let val thms = #2 (theorems_of thy)
   299   in map (`(get_name_hint)) (maps snd (Symtab.dest thms)) end;
   300 
   301 fun all_thms_of thy = maps thms_of (thy :: Theory.ancestors_of thy);
   302 
   303 
   304 
   305 (** store theorems **)                    (*DESTRUCTIVE*)
   306 
   307 (* hiding -- affects current theory node only *)
   308 
   309 fun hide_thms fully names thy = CRITICAL (fn () =>
   310   let
   311     val r as ref {theorems = (space, thms), index} = get_theorems_ref thy;
   312     val space' = fold (NameSpace.hide fully) names space;
   313   in r := {theorems = (space', thms), index = index}; thy end);
   314 
   315 
   316 (* fact specifications *)
   317 
   318 fun map_facts f = map (apsnd (map (apfst (map f))));
   319 fun burrow_fact f = split_list #>> burrow f #> op ~~;
   320 fun burrow_facts f = split_list ##> burrow (burrow_fact f) #> op ~~;
   321 
   322 
   323 (* naming *)
   324 
   325 fun gen_names _ len "" = replicate len ""
   326   | gen_names j len name = map (fn i => name ^ "_" ^ string_of_int i) (j + 1 upto j + len);
   327 
   328 fun name_multi name [x] = [(name, x)]
   329   | name_multi name xs = gen_names 0 (length xs) name ~~ xs;
   330 
   331 fun name_thm pre official name thm = thm
   332   |> (if Thm.get_name thm <> "" andalso pre orelse not official then I else Thm.put_name name)
   333   |> (if has_name_hint thm andalso pre orelse name = "" then I else put_name_hint name);
   334 
   335 fun name_thms pre official name xs =
   336   map (uncurry (name_thm pre official)) (name_multi name xs);
   337 
   338 fun name_thmss official name fact =
   339   burrow_fact (name_thms true official name) fact;
   340 
   341 
   342 (* enter_thms *)
   343 
   344 fun warn_overwrite name = warning ("Replaced old copy of theorems " ^ quote name);
   345 fun warn_same name = warning ("Theorem database already contains a copy of " ^ quote name);
   346 
   347 fun enter_thms _ _ app_att ("", thms) thy = app_att (thy, thms) |> swap
   348   | enter_thms pre_name post_name app_att (bname, thms) thy = CRITICAL (fn () =>
   349       let
   350         val name = Sign.full_name thy bname;
   351         val (thy', thms') = apsnd (post_name name) (app_att (thy, pre_name name thms));
   352         val r as ref {theorems = (space, theorems), index} = get_theorems_ref thy';
   353         val space' = Sign.declare_name thy' name space;
   354         val theorems' = Symtab.update (name, thms') theorems;
   355         val index' = FactIndex.add_global (name, thms') index;
   356       in
   357         (case Symtab.lookup theorems name of
   358           NONE => ()
   359         | SOME thms'' =>
   360             if Thm.eq_thms (thms', thms'') then warn_same name
   361             else warn_overwrite name);
   362         r := {theorems = (space', theorems'), index = index'};
   363         (thms', thy')
   364       end);
   365 
   366 
   367 (* add_thms(s) *)
   368 
   369 fun add_thms_atts pre_name ((bname, thms), atts) =
   370   enter_thms pre_name (name_thms false true)
   371     (foldl_map (Thm.theory_attributes atts)) (bname, thms);
   372 
   373 fun gen_add_thmss pre_name =
   374   fold_map (add_thms_atts pre_name);
   375 
   376 fun gen_add_thms pre_name args =
   377   apfst (map hd) o gen_add_thmss pre_name (map (apfst (apsnd single)) args);
   378 
   379 val add_thmss = gen_add_thmss (name_thms true true);
   380 val add_thms = gen_add_thms (name_thms true true);
   381 
   382 
   383 (* note_thmss(_i) *)
   384 
   385 local
   386 
   387 fun gen_note_thmss get k = fold_map (fn ((bname, more_atts), ths_atts) => fn thy =>
   388   let
   389     fun app (x, (ths, atts)) = foldl_map (Thm.theory_attributes atts) (x, ths);
   390     val (thms, thy') = thy |> enter_thms
   391       (name_thmss true) (name_thms false true) (apsnd flat o foldl_map app)
   392       (bname, map (fn (ths, atts) => (get thy ths, atts @ more_atts @ [kind k])) ths_atts);
   393   in ((bname, thms), thy') end);
   394 
   395 in
   396 
   397 val note_thmss = gen_note_thmss get_thms;
   398 val note_thmss_i = gen_note_thmss (K I);
   399 
   400 end;
   401 
   402 fun note kind (name, thm) =
   403   note_thmss_i kind [((name, []), [([thm], [])])]
   404   #>> (fn [(_, [thm])] => thm);
   405 
   406 fun note_thmss_qualified k path facts thy =
   407   thy
   408   |> Sign.add_path path
   409   |> Sign.no_base_names
   410   |> note_thmss_i k facts
   411   ||> Sign.restore_naming thy;
   412 
   413 
   414 (* store_thm *)
   415 
   416 fun store_thm ((bname, thm), atts) thy =
   417   let val ([th'], thy') = add_thms_atts (name_thms true true) ((bname, [thm]), atts) thy
   418   in (th', thy') end;
   419 
   420 
   421 (* smart_store_thms(_open) *)
   422 
   423 local
   424 
   425 fun smart_store _ (name, []) =
   426       error ("Cannot store empty list of theorems: " ^ quote name)
   427   | smart_store official (name, [thm]) =
   428       fst (enter_thms (name_thms true official) (name_thms false official) I (name, [thm])
   429         (Thm.theory_of_thm thm))
   430   | smart_store official (name, thms) =
   431       let val thy = Theory.merge_list (map Thm.theory_of_thm thms) in
   432         fst (enter_thms (name_thms true official) (name_thms false official) I (name, thms) thy)
   433       end;
   434 
   435 in
   436 
   437 val smart_store_thms = smart_store true;
   438 val smart_store_thms_open = smart_store false;
   439 
   440 end;
   441 
   442 
   443 (* forall_elim_var(s) -- belongs to drule.ML *)
   444 
   445 fun forall_elim_vars_aux strip_vars i th =
   446   let
   447     val {thy, tpairs, prop, ...} = Thm.rep_thm th;
   448     val add_used = Term.fold_aterms
   449       (fn Var ((x, j), _) => if i = j then insert (op =) x else I | _ => I);
   450     val used = fold (fn (t, u) => add_used t o add_used u) tpairs (add_used prop []);
   451     val vars = strip_vars prop;
   452     val cvars = (Name.variant_list used (map #1 vars), vars)
   453       |> ListPair.map (fn (x, (_, T)) => Thm.cterm_of thy (Var ((x, i), T)));
   454   in fold Thm.forall_elim cvars th end;
   455 
   456 val forall_elim_vars = forall_elim_vars_aux Term.strip_all_vars;
   457 
   458 fun forall_elim_var i th = forall_elim_vars_aux
   459   (fn Const ("all", _) $ Abs (a, T, _) => [(a, T)]
   460   | _ => raise THM ("forall_elim_vars", i, [th])) i th;
   461 
   462 
   463 (* store axioms as theorems *)
   464 
   465 local
   466   fun get_ax thy (name, _) = Thm.get_axiom_i thy (Sign.full_name thy name);
   467   fun get_axs thy named_axs = map (forall_elim_vars 0 o get_ax thy) named_axs;
   468   fun add_single add ((name, ax), atts) thy =
   469     let
   470       val named_ax = [(name, ax)];
   471       val thy' = add named_ax thy;
   472       val thm = hd (get_axs thy' named_ax);
   473     in apfst hd (gen_add_thms (K I) [((name, thm), atts)] thy') end;
   474   fun add_multi add ((name, axs), atts) thy =
   475     let
   476       val named_axs = name_multi name axs;
   477       val thy' = add named_axs thy;
   478       val thms = get_axs thy' named_axs;
   479     in apfst hd (gen_add_thmss (K I) [((name, thms), atts)] thy') end;
   480   fun add_singles add = fold_map (add_single add);
   481   fun add_multis add = fold_map (add_multi add);
   482 in
   483   val add_axioms           = add_singles Theory.add_axioms;
   484   val add_axioms_i         = add_singles Theory.add_axioms_i;
   485   val add_axiomss          = add_multis Theory.add_axioms;
   486   val add_axiomss_i        = add_multis Theory.add_axioms_i;
   487   val add_defs             = add_singles o Theory.add_defs false;
   488   val add_defs_i           = add_singles o Theory.add_defs_i false;
   489   val add_defs_unchecked   = add_singles o Theory.add_defs true;
   490   val add_defs_unchecked_i = add_singles o Theory.add_defs_i true;
   491 end;
   492 
   493 
   494 
   495 (*** the ProtoPure theory ***)
   496 
   497 val typ = SimpleSyntax.read_typ;
   498 val term = SimpleSyntax.read_term;
   499 val prop = SimpleSyntax.read_prop;
   500 
   501 val appl_syntax =
   502  [("_appl", typ "('b => 'a) => args => logic", Mixfix ("(1_/(1'(_')))", [1000, 0], 1000)),
   503   ("_appl", typ "('b => 'a) => args => aprop", Mixfix ("(1_/(1'(_')))", [1000, 0], 1000))];
   504 
   505 val applC_syntax =
   506  [("",       typ "'a => cargs",                  Delimfix "_"),
   507   ("_cargs", typ "'a => cargs => cargs",         Mixfix ("_/ _", [1000, 1000], 1000)),
   508   ("_applC", typ "('b => 'a) => cargs => logic", Mixfix ("(1_/ _)", [1000, 1000], 999)),
   509   ("_applC", typ "('b => 'a) => cargs => aprop", Mixfix ("(1_/ _)", [1000, 1000], 999))];
   510 
   511 val proto_pure =
   512   Context.pre_pure_thy
   513   |> Compress.init_data
   514   |> TheoremsData.init
   515   |> Sign.add_types
   516    [("fun", 2, NoSyn),
   517     ("prop", 0, NoSyn),
   518     ("itself", 1, NoSyn),
   519     ("dummy", 0, NoSyn)]
   520   |> Sign.add_nonterminals Syntax.basic_nonterms
   521   |> Sign.add_syntax_i
   522    [("_lambda",     typ "pttrns => 'a => logic",     Mixfix ("(3%_./ _)", [0, 3], 3)),
   523     ("_abs",        typ "'a",                        NoSyn),
   524     ("",            typ "'a => args",                Delimfix "_"),
   525     ("_args",       typ "'a => args => args",        Delimfix "_,/ _"),
   526     ("",            typ "id => idt",                 Delimfix "_"),
   527     ("_idtdummy",   typ "idt",                       Delimfix "'_"),
   528     ("_idtyp",      typ "id => type => idt",         Mixfix ("_::_", [], 0)),
   529     ("_idtypdummy", typ "type => idt",               Mixfix ("'_()::_", [], 0)),
   530     ("",            typ "idt => idt",                Delimfix "'(_')"),
   531     ("",            typ "idt => idts",               Delimfix "_"),
   532     ("_idts",       typ "idt => idts => idts",       Mixfix ("_/ _", [1, 0], 0)),
   533     ("",            typ "idt => pttrn",              Delimfix "_"),
   534     ("",            typ "pttrn => pttrns",           Delimfix "_"),
   535     ("_pttrns",     typ "pttrn => pttrns => pttrns", Mixfix ("_/ _", [1, 0], 0)),
   536     ("",            typ "id => aprop",               Delimfix "_"),
   537     ("",            typ "longid => aprop",           Delimfix "_"),
   538     ("",            typ "var => aprop",              Delimfix "_"),
   539     ("_DDDOT",      typ "aprop",                     Delimfix "..."),
   540     ("_aprop",      typ "aprop => prop",             Delimfix "PROP _"),
   541     ("_asm",        typ "prop => asms",              Delimfix "_"),
   542     ("_asms",       typ "prop => asms => asms",      Delimfix "_;/ _"),
   543     ("_bigimpl",    typ "asms => prop => prop",      Mixfix ("((3[| _ |])/ ==> _)", [0, 1], 1)),
   544     ("_ofclass",    typ "type => logic => prop",     Delimfix "(1OFCLASS/(1'(_,/ _')))"),
   545     ("_mk_ofclass", typ "dummy",                     NoSyn),
   546     ("_TYPE",       typ "type => logic",             Delimfix "(1TYPE/(1'(_')))"),
   547     ("",            typ "id => logic",               Delimfix "_"),
   548     ("",            typ "longid => logic",           Delimfix "_"),
   549     ("",            typ "var => logic",              Delimfix "_"),
   550     ("_DDDOT",      typ "logic",                     Delimfix "..."),
   551     ("_constify",   typ "num => num_const",          Delimfix "_"),
   552     ("_indexnum",   typ "num_const => index",        Delimfix "\\<^sub>_"),
   553     ("_index",      typ "logic => index",            Delimfix "(00\\<^bsub>_\\<^esub>)"),
   554     ("_indexdefault", typ "index",                   Delimfix ""),
   555     ("_indexvar",   typ "index",                     Delimfix "'\\<index>"),
   556     ("_struct",     typ "index => logic",            Mixfix ("\\<struct>_", [1000], 1000)),
   557     ("==>",         typ "prop => prop => prop",      Delimfix "op ==>"),
   558     (Term.dummy_patternN, typ "aprop",               Delimfix "'_")]
   559   |> Sign.add_syntax_i appl_syntax
   560   |> Sign.add_modesyntax_i (Symbol.xsymbolsN, true)
   561    [("fun",      typ "type => type => type",   Mixfix ("(_/ \\<Rightarrow> _)", [1, 0], 0)),
   562     ("_bracket", typ "types => type => type",  Mixfix ("([_]/ \\<Rightarrow> _)", [0, 0], 0)),
   563     ("_ofsort",  typ "tid => sort => type",    Mixfix ("_\\<Colon>_", [1000, 0], 1000)),
   564     ("_constrain", typ "'a => type => 'a",     Mixfix ("_\\<Colon>_", [4, 0], 3)),
   565     ("_idtyp",    typ "id => type => idt",     Mixfix ("_\\<Colon>_", [], 0)),
   566     ("_idtypdummy", typ "type => idt",         Mixfix ("'_()\\<Colon>_", [], 0)),
   567     ("_type_constraint_", typ "'a",            NoSyn),
   568     ("_lambda",  typ "pttrns => 'a => logic",  Mixfix ("(3\\<lambda>_./ _)", [0, 3], 3)),
   569     ("==",       typ "'a => 'a => prop",       InfixrName ("\\<equiv>", 2)),
   570     ("all_binder", typ "idts => prop => prop", Mixfix ("(3\\<And>_./ _)", [0, 0], 0)),
   571     ("==>",      typ "prop => prop => prop",   InfixrName ("\\<Longrightarrow>", 1)),
   572     ("_DDDOT",   typ "aprop",                  Delimfix "\\<dots>"),
   573     ("_bigimpl", typ "asms => prop => prop",   Mixfix ("((1\\<lbrakk>_\\<rbrakk>)/ \\<Longrightarrow> _)", [0, 1], 1)),
   574     ("_DDDOT",   typ "logic",                  Delimfix "\\<dots>")]
   575   |> Sign.add_modesyntax_i ("", false)
   576    [("prop", typ "prop => prop", Mixfix ("_", [0], 0)),
   577     ("ProtoPure.term", typ "'a => prop", Delimfix "TERM _"),
   578     ("ProtoPure.conjunction", typ "prop => prop => prop", InfixrName ("&&", 2))]
   579   |> Sign.add_modesyntax_i ("HTML", false)
   580    [("_lambda", typ "pttrns => 'a => logic", Mixfix ("(3\\<lambda>_./ _)", [0, 3], 3))]
   581   |> Sign.add_consts_i
   582    [("==", typ "'a => 'a => prop", InfixrName ("==", 2)),
   583     ("==>", typ "prop => prop => prop", Mixfix ("(_/ ==> _)", [2, 1], 1)),
   584     ("all", typ "('a => prop) => prop", Binder ("!!", 0, 0)),
   585     ("prop", typ "prop => prop", NoSyn),
   586     ("TYPE", typ "'a itself", NoSyn),
   587     (Term.dummy_patternN, typ "'a", Delimfix "'_")]
   588   |> Theory.add_deps "==" ("==", typ "'a => 'a => prop") []
   589   |> Theory.add_deps "==>" ("==>", typ "prop => prop => prop") []
   590   |> Theory.add_deps "all" ("all", typ "('a => prop) => prop") []
   591   |> Theory.add_deps "TYPE" ("TYPE", typ "'a itself") []
   592   |> Theory.add_deps Term.dummy_patternN (Term.dummy_patternN, typ "'a") []
   593   |> Sign.add_trfuns Syntax.pure_trfuns
   594   |> Sign.add_trfunsT Syntax.pure_trfunsT
   595   |> Sign.local_path
   596   |> Sign.add_consts_i
   597    [("term", typ "'a => prop", NoSyn),
   598     ("conjunction", typ "prop => prop => prop", NoSyn)]
   599   |> (add_defs_i false o map Thm.no_attributes)
   600    [("prop_def", prop "(CONST prop :: prop => prop) (A::prop) == A::prop"),
   601     ("term_def", prop "(CONST ProtoPure.term :: 'a => prop) (x::'a) == (!!A::prop. A ==> A)"),
   602     ("conjunction_def", prop "(A && B) == (!!C::prop. (A ==> B ==> C) ==> C)")] |> snd
   603   |> Sign.hide_consts false ["conjunction", "term"]
   604   |> add_thmss [(("nothing", []), [])] |> snd
   605   |> Theory.add_axioms_i Proofterm.equality_axms
   606   |> Theory.end_theory;
   607 
   608 structure ProtoPure =
   609 struct
   610   val thy = proto_pure;
   611   val prop_def = get_axiom thy "prop_def";
   612   val term_def = get_axiom thy "term_def";
   613   val conjunction_def = get_axiom thy "conjunction_def";
   614 end;
   615 
   616 end;
   617 
   618 structure BasicPureThy: BASIC_PURE_THY = PureThy;
   619 open BasicPureThy;