src/Pure/tctical.ML
author berghofe
Mon Jan 21 14:18:49 2008 +0100 (2008-01-21)
changeset 25939 ddea202704b4
parent 24359 44556727197a
child 26626 c6231d64d264
permissions -rw-r--r--
Removed Logic.auto_rename.
     1 (*  Title:      Pure/tctical.ML
     2     ID:         $Id$
     3     Author:     Lawrence C Paulson, Cambridge University Computer Laboratory
     4     Copyright   1993  University of Cambridge
     5 
     6 Tacticals.
     7 *)
     8 
     9 infix 1 THEN THEN' THEN_ALL_NEW;
    10 infix 0 ORELSE APPEND INTLEAVE ORELSE' APPEND' INTLEAVE';
    11 infix 0 THEN_ELSE;
    12 
    13 signature TACTICAL =
    14 sig
    15   type tactic = thm -> thm Seq.seq
    16   val THEN: tactic * tactic -> tactic
    17   val ORELSE: tactic * tactic -> tactic
    18   val APPEND: tactic * tactic -> tactic
    19   val INTLEAVE: tactic * tactic -> tactic
    20   val THEN_ELSE: tactic * (tactic*tactic) -> tactic
    21   val THEN': ('a -> tactic) * ('a -> tactic) -> 'a -> tactic
    22   val ORELSE': ('a -> tactic) * ('a -> tactic) -> 'a -> tactic
    23   val APPEND': ('a -> tactic) * ('a -> tactic) -> 'a -> tactic
    24   val INTLEAVE': ('a -> tactic) * ('a -> tactic) -> 'a -> tactic
    25   val all_tac: tactic
    26   val no_tac: tactic
    27   val DETERM: tactic -> tactic
    28   val COND: (thm -> bool) -> tactic -> tactic -> tactic
    29   val TRY: tactic -> tactic
    30   val EVERY: tactic list -> tactic
    31   val EVERY': ('a -> tactic) list -> 'a -> tactic
    32   val EVERY1: (int -> tactic) list -> tactic
    33   val FIRST: tactic list -> tactic
    34   val FIRST': ('a -> tactic) list -> 'a -> tactic
    35   val FIRST1: (int -> tactic) list -> tactic
    36   val RANGE: (int -> tactic) list -> int -> tactic
    37   val print_tac: string -> tactic
    38   val pause_tac: tactic
    39   val trace_REPEAT: bool ref
    40   val suppress_tracing: bool ref
    41   val tracify: bool ref -> tactic -> tactic
    42   val traced_tac: (thm -> (thm * thm Seq.seq) option) -> tactic
    43   val DETERM_UNTIL: (thm -> bool) -> tactic -> tactic
    44   val REPEAT_DETERM_N: int -> tactic -> tactic
    45   val REPEAT_DETERM: tactic -> tactic
    46   val REPEAT: tactic -> tactic
    47   val REPEAT_DETERM1: tactic -> tactic
    48   val REPEAT1: tactic -> tactic
    49   val FILTER: (thm -> bool) -> tactic -> tactic
    50   val CHANGED: tactic -> tactic
    51   val CHANGED_PROP: tactic -> tactic
    52   val ALLGOALS: (int -> tactic) -> tactic
    53   val SOMEGOAL: (int -> tactic) -> tactic
    54   val FIRSTGOAL: (int -> tactic) -> tactic
    55   val REPEAT_SOME: (int -> tactic) -> tactic
    56   val REPEAT_DETERM_SOME: (int -> tactic) -> tactic
    57   val REPEAT_FIRST: (int -> tactic) -> tactic
    58   val REPEAT_DETERM_FIRST: (int -> tactic) -> tactic
    59   val TRYALL: (int -> tactic) -> tactic
    60   val CSUBGOAL: ((cterm * int) -> tactic) -> int -> tactic
    61   val SUBGOAL: ((term * int) -> tactic) -> int -> tactic
    62   val CHANGED_GOAL: (int -> tactic) -> int -> tactic
    63   val THEN_ALL_NEW: (int -> tactic) * (int -> tactic) -> int -> tactic
    64   val REPEAT_ALL_NEW: (int -> tactic) -> int -> tactic
    65   val strip_context: term -> (string * typ) list * term list * term
    66   val metahyps_thms: int -> thm -> thm list option
    67   val METAHYPS: (thm list -> tactic) -> int -> tactic
    68   val PRIMSEQ: (thm -> thm Seq.seq) -> tactic
    69   val PRIMITIVE: (thm -> thm) -> tactic
    70   val SINGLE: tactic -> thm -> thm option
    71   val CONVERSION: conv -> int -> tactic
    72 end;
    73 
    74 structure Tactical : TACTICAL =
    75 struct
    76 
    77 (**** Tactics ****)
    78 
    79 (*A tactic maps a proof tree to a sequence of proof trees:
    80     if length of sequence = 0 then the tactic does not apply;
    81     if length > 1 then backtracking on the alternatives can occur.*)
    82 
    83 type tactic = thm -> thm Seq.seq;
    84 
    85 
    86 (*** LCF-style tacticals ***)
    87 
    88 (*the tactical THEN performs one tactic followed by another*)
    89 fun (tac1 THEN tac2) st = Seq.maps tac2 (tac1 st);
    90 
    91 
    92 (*The tactical ORELSE uses the first tactic that returns a nonempty sequence.
    93   Like in LCF, ORELSE commits to either tac1 or tac2 immediately.
    94   Does not backtrack to tac2 if tac1 was initially chosen. *)
    95 fun (tac1 ORELSE tac2) st =
    96     case Seq.pull(tac1 st) of
    97         NONE       => tac2 st
    98       | sequencecell => Seq.make(fn()=> sequencecell);
    99 
   100 
   101 (*The tactical APPEND combines the results of two tactics.
   102   Like ORELSE, but allows backtracking on both tac1 and tac2.
   103   The tactic tac2 is not applied until needed.*)
   104 fun (tac1 APPEND tac2) st =
   105   Seq.append (tac1 st) (Seq.make(fn()=> Seq.pull (tac2 st)));
   106 
   107 (*Like APPEND, but interleaves results of tac1 and tac2.*)
   108 fun (tac1 INTLEAVE tac2) st =
   109     Seq.interleave(tac1 st,
   110                         Seq.make(fn()=> Seq.pull (tac2 st)));
   111 
   112 (*Conditional tactic.
   113         tac1 ORELSE tac2 = tac1 THEN_ELSE (all_tac, tac2)
   114         tac1 THEN tac2   = tac1 THEN_ELSE (tac2, no_tac)
   115 *)
   116 fun (tac THEN_ELSE (tac1, tac2)) st =
   117     case Seq.pull(tac st) of
   118         NONE    => tac2 st                                   (*failed; try tactic 2*)
   119       | seqcell => Seq.maps tac1 (Seq.make(fn()=> seqcell)); (*succeeded; use tactic 1*)
   120 
   121 
   122 (*Versions for combining tactic-valued functions, as in
   123      SOMEGOAL (resolve_tac rls THEN' assume_tac) *)
   124 fun (tac1 THEN' tac2) x = tac1 x THEN tac2 x;
   125 fun (tac1 ORELSE' tac2) x = tac1 x ORELSE tac2 x;
   126 fun (tac1 APPEND' tac2) x = tac1 x APPEND tac2 x;
   127 fun (tac1 INTLEAVE' tac2) x = tac1 x INTLEAVE tac2 x;
   128 
   129 (*passes all proofs through unchanged;  identity of THEN*)
   130 fun all_tac st = Seq.single st;
   131 
   132 (*passes no proofs through;  identity of ORELSE and APPEND*)
   133 fun no_tac st  = Seq.empty;
   134 
   135 
   136 (*Make a tactic deterministic by chopping the tail of the proof sequence*)
   137 fun DETERM tac = Seq.DETERM tac;
   138 
   139 (*Conditional tactical: testfun controls which tactic to use next.
   140   Beware: due to eager evaluation, both thentac and elsetac are evaluated.*)
   141 fun COND testfun thenf elsef = (fn prf =>
   142     if testfun prf then  thenf prf   else  elsef prf);
   143 
   144 (*Do the tactic or else do nothing*)
   145 fun TRY tac = tac ORELSE all_tac;
   146 
   147 (*** List-oriented tactics ***)
   148 
   149 local
   150   (*This version of EVERY avoids backtracking over repeated states*)
   151 
   152   fun EVY (trail, []) st =
   153         Seq.make (fn()=> SOME(st,
   154                         Seq.make (fn()=> Seq.pull (evyBack trail))))
   155     | EVY (trail, tac::tacs) st =
   156           case Seq.pull(tac st) of
   157               NONE    => evyBack trail              (*failed: backtrack*)
   158             | SOME(st',q) => EVY ((st',q,tacs)::trail, tacs) st'
   159   and evyBack [] = Seq.empty (*no alternatives*)
   160     | evyBack ((st',q,tacs)::trail) =
   161           case Seq.pull q of
   162               NONE        => evyBack trail
   163             | SOME(st,q') => if Thm.eq_thm (st',st)
   164                              then evyBack ((st',q',tacs)::trail)
   165                              else EVY ((st,q',tacs)::trail, tacs) st
   166 in
   167 
   168 (* EVERY [tac1,...,tacn]   equals    tac1 THEN ... THEN tacn   *)
   169 fun EVERY tacs = EVY ([], tacs);
   170 end;
   171 
   172 
   173 (* EVERY' [tac1,...,tacn] i  equals    tac1 i THEN ... THEN tacn i   *)
   174 fun EVERY' tacs i = EVERY (map (fn f => f i) tacs);
   175 
   176 (*Apply every tactic to 1*)
   177 fun EVERY1 tacs = EVERY' tacs 1;
   178 
   179 (* FIRST [tac1,...,tacn]   equals    tac1 ORELSE ... ORELSE tacn   *)
   180 fun FIRST tacs = fold_rev (curry op ORELSE) tacs no_tac;
   181 
   182 (* FIRST' [tac1,...,tacn] i  equals    tac1 i ORELSE ... ORELSE tacn i   *)
   183 fun FIRST' tacs = fold_rev (curry op ORELSE') tacs (K no_tac);
   184 
   185 (*Apply first tactic to 1*)
   186 fun FIRST1 tacs = FIRST' tacs 1;
   187 
   188 (*Apply tactics on consecutive subgoals*)
   189 fun RANGE [] _ = all_tac
   190   | RANGE (tac :: tacs) i = RANGE tacs (i + 1) THEN tac i;
   191 
   192 
   193 (*** Tracing tactics ***)
   194 
   195 (*Print the current proof state and pass it on.*)
   196 fun print_tac msg =
   197     (fn st =>
   198      (tracing msg;
   199       tracing ((Pretty.string_of o Pretty.chunks o
   200                  Display.pretty_goals (! Display.goals_limit)) st);
   201       Seq.single st));
   202 
   203 (*Pause until a line is typed -- if non-empty then fail. *)
   204 fun pause_tac st =
   205   (tracing "** Press RETURN to continue:";
   206    if TextIO.inputLine TextIO.stdIn = SOME "\n" then Seq.single st
   207    else (tracing "Goodbye";  Seq.empty));
   208 
   209 exception TRACE_EXIT of thm
   210 and TRACE_QUIT;
   211 
   212 (*Tracing flags*)
   213 val trace_REPEAT= ref false
   214 and suppress_tracing = ref false;
   215 
   216 (*Handle all tracing commands for current state and tactic *)
   217 fun exec_trace_command flag (tac, st) =
   218    case TextIO.inputLine TextIO.stdIn of
   219        SOME "\n" => tac st
   220      | SOME "f\n" => Seq.empty
   221      | SOME "o\n" => (flag:=false;  tac st)
   222      | SOME "s\n" => (suppress_tracing:=true;  tac st)
   223      | SOME "x\n" => (tracing "Exiting now";  raise (TRACE_EXIT st))
   224      | SOME "quit\n" => raise TRACE_QUIT
   225      | _     => (tracing
   226 "Type RETURN to continue or...\n\
   227 \     f    - to fail here\n\
   228 \     o    - to switch tracing off\n\
   229 \     s    - to suppress tracing until next entry to a tactical\n\
   230 \     x    - to exit at this point\n\
   231 \     quit - to abort this tracing run\n\
   232 \** Well? "     ;  exec_trace_command flag (tac, st));
   233 
   234 
   235 (*Extract from a tactic, a thm->thm seq function that handles tracing*)
   236 fun tracify flag tac st =
   237   if !flag andalso not (!suppress_tracing)
   238            then (Display.print_goals (! Display.goals_limit) st;
   239                  tracing "** Press RETURN to continue:";
   240                  exec_trace_command flag (tac,st))
   241   else tac st;
   242 
   243 (*Create a tactic whose outcome is given by seqf, handling TRACE_EXIT*)
   244 fun traced_tac seqf st =
   245     (suppress_tracing := false;
   246      Seq.make (fn()=> seqf st
   247                          handle TRACE_EXIT st' => SOME(st', Seq.empty)));
   248 
   249 
   250 (*Deterministic DO..UNTIL: only retains the first outcome; tail recursive.
   251   Forces repitition until predicate on state is fulfilled.*)
   252 fun DETERM_UNTIL p tac =
   253 let val tac = tracify trace_REPEAT tac
   254     fun drep st = if p st then SOME (st, Seq.empty)
   255                           else (case Seq.pull(tac st) of
   256                                   NONE        => NONE
   257                                 | SOME(st',_) => drep st')
   258 in  traced_tac drep  end;
   259 
   260 (*Deterministic REPEAT: only retains the first outcome;
   261   uses less space than REPEAT; tail recursive.
   262   If non-negative, n bounds the number of repetitions.*)
   263 fun REPEAT_DETERM_N n tac =
   264   let val tac = tracify trace_REPEAT tac
   265       fun drep 0 st = SOME(st, Seq.empty)
   266         | drep n st =
   267            (case Seq.pull(tac st) of
   268                 NONE       => SOME(st, Seq.empty)
   269               | SOME(st',_) => drep (n-1) st')
   270   in  traced_tac (drep n)  end;
   271 
   272 (*Allows any number of repetitions*)
   273 val REPEAT_DETERM = REPEAT_DETERM_N ~1;
   274 
   275 (*General REPEAT: maintains a stack of alternatives; tail recursive*)
   276 fun REPEAT tac =
   277   let val tac = tracify trace_REPEAT tac
   278       fun rep qs st =
   279         case Seq.pull(tac st) of
   280             NONE       => SOME(st, Seq.make(fn()=> repq qs))
   281           | SOME(st',q) => rep (q::qs) st'
   282       and repq [] = NONE
   283         | repq(q::qs) = case Seq.pull q of
   284             NONE       => repq qs
   285           | SOME(st,q) => rep (q::qs) st
   286   in  traced_tac (rep [])  end;
   287 
   288 (*Repeat 1 or more times*)
   289 fun REPEAT_DETERM1 tac = DETERM tac THEN REPEAT_DETERM tac;
   290 fun REPEAT1 tac = tac THEN REPEAT tac;
   291 
   292 
   293 (** Filtering tacticals **)
   294 
   295 fun FILTER pred tac st = Seq.filter pred (tac st);
   296 
   297 (*Accept only next states that change the theorem somehow*)
   298 fun CHANGED tac st =
   299   let fun diff st' = not (Thm.eq_thm (st, st'));
   300   in Seq.filter diff (tac st) end;
   301 
   302 (*Accept only next states that change the theorem's prop field
   303   (changes to signature, hyps, etc. don't count)*)
   304 fun CHANGED_PROP tac st =
   305   let fun diff st' = not (Thm.eq_thm_prop (st, st'));
   306   in Seq.filter diff (tac st) end;
   307 
   308 
   309 (*** Tacticals based on subgoal numbering ***)
   310 
   311 (*For n subgoals, performs tac(n) THEN ... THEN tac(1)
   312   Essential to work backwards since tac(i) may add/delete subgoals at i. *)
   313 fun ALLGOALS tac st =
   314   let fun doall 0 = all_tac
   315         | doall n = tac(n) THEN doall(n-1)
   316   in  doall(nprems_of st)st  end;
   317 
   318 (*For n subgoals, performs tac(n) ORELSE ... ORELSE tac(1)  *)
   319 fun SOMEGOAL tac st =
   320   let fun find 0 = no_tac
   321         | find n = tac(n) ORELSE find(n-1)
   322   in  find(nprems_of st)st  end;
   323 
   324 (*For n subgoals, performs tac(1) ORELSE ... ORELSE tac(n).
   325   More appropriate than SOMEGOAL in some cases.*)
   326 fun FIRSTGOAL tac st =
   327   let fun find (i,n) = if i>n then no_tac else  tac(i) ORELSE find (i+1,n)
   328   in  find(1, nprems_of st)st  end;
   329 
   330 (*Repeatedly solve some using tac. *)
   331 fun REPEAT_SOME tac = REPEAT1 (SOMEGOAL (REPEAT1 o tac));
   332 fun REPEAT_DETERM_SOME tac = REPEAT_DETERM1 (SOMEGOAL (REPEAT_DETERM1 o tac));
   333 
   334 (*Repeatedly solve the first possible subgoal using tac. *)
   335 fun REPEAT_FIRST tac = REPEAT1 (FIRSTGOAL (REPEAT1 o tac));
   336 fun REPEAT_DETERM_FIRST tac = REPEAT_DETERM1 (FIRSTGOAL (REPEAT_DETERM1 o tac));
   337 
   338 (*For n subgoals, tries to apply tac to n,...1  *)
   339 fun TRYALL tac = ALLGOALS (TRY o tac);
   340 
   341 
   342 (*Make a tactic for subgoal i, if there is one.  *)
   343 fun CSUBGOAL goalfun i st =
   344   (case SOME (Thm.cprem_of st i) handle THM _ => NONE of
   345     SOME goal => goalfun (goal, i) st
   346   | NONE => Seq.empty);
   347 
   348 fun SUBGOAL goalfun =
   349   CSUBGOAL (fn (goal, i) => goalfun (Thm.term_of goal, i));
   350 
   351 (*Returns all states that have changed in subgoal i, counted from the LAST
   352   subgoal.  For stac, for example.*)
   353 fun CHANGED_GOAL tac i st =
   354     let val np = nprems_of st
   355         val d = np-i                 (*distance from END*)
   356         val t = List.nth(prems_of st, i-1)
   357         fun diff st' =
   358             nprems_of st' - d <= 0   (*the subgoal no longer exists*)
   359             orelse
   360              not (Pattern.aeconv (t,
   361                                   List.nth(prems_of st',
   362                                            nprems_of st' - d - 1)))
   363     in  Seq.filter diff (tac i st)  end
   364     handle Subscript => Seq.empty  (*no subgoal i*);
   365 
   366 fun (tac1 THEN_ALL_NEW tac2) i st =
   367   st |> (tac1 i THEN (fn st' => Seq.INTERVAL tac2 i (i + nprems_of st' - nprems_of st) st'));
   368 
   369 (*repeatedly dig into any emerging subgoals*)
   370 fun REPEAT_ALL_NEW tac =
   371   tac THEN_ALL_NEW (TRY o (fn i => REPEAT_ALL_NEW tac i));
   372 
   373 
   374 (*Strips assumptions in goal yielding  ( [x1,...,xm], [H1,...,Hn], B )
   375     H1,...,Hn are the hypotheses;  x1...xm are variants of the parameters.
   376   Main difference from strip_assums concerns parameters:
   377     it replaces the bound variables by free variables.  *)
   378 fun strip_context_aux (params, Hs, Const("==>", _) $ H $ B) =
   379         strip_context_aux (params, H::Hs, B)
   380   | strip_context_aux (params, Hs, Const("all",_)$Abs(a,T,t)) =
   381         let val (b,u) = Syntax.variant_abs(a,T,t)
   382         in  strip_context_aux ((b,T)::params, Hs, u)  end
   383   | strip_context_aux (params, Hs, B) = (rev params, rev Hs, B);
   384 
   385 fun strip_context A = strip_context_aux ([],[],A);
   386 
   387 
   388 (**** METAHYPS -- tactical for using hypotheses as meta-level assumptions
   389        METAHYPS (fn prems => tac prems) i
   390 
   391 converts subgoal i, of the form !!x1...xm. [| A1;...;An] ==> A into a new
   392 proof state A==>A, supplying A1,...,An as meta-level assumptions (in
   393 "prems").  The parameters x1,...,xm become free variables.  If the
   394 resulting proof state is [| B1;...;Bk] ==> C (possibly assuming A1,...,An)
   395 then it is lifted back into the original context, yielding k subgoals.
   396 
   397 Replaces unknowns in the context by Frees having the prefix METAHYP_
   398 New unknowns in [| B1;...;Bk] ==> C are lifted over x1,...,xm.
   399 DOES NOT HANDLE TYPE UNKNOWNS.
   400 ****)
   401 
   402 local
   403 
   404   (*Left-to-right replacements: ctpairs = [...,(vi,ti),...].
   405     Instantiates distinct free variables by terms of same type.*)
   406   fun free_instantiate ctpairs =
   407       forall_elim_list (map snd ctpairs) o forall_intr_list (map fst ctpairs);
   408 
   409   fun free_of s ((a,i), T) =
   410         Free(s ^ (case i of 0 => a | _ => a ^ "_" ^ string_of_int i),
   411              T)
   412 
   413   fun mk_inst (var as Var(v,T))  = (var,  free_of "METAHYP1_" (v,T))
   414 in
   415 
   416 (*Common code for METAHYPS and metahyps_thms*)
   417 fun metahyps_split_prem prem =
   418   let (*find all vars in the hyps -- should find tvars also!*)
   419       val hyps_vars = List.foldr add_term_vars [] (Logic.strip_assums_hyp prem)
   420       val insts = map mk_inst hyps_vars
   421       (*replace the hyps_vars by Frees*)
   422       val prem' = subst_atomic insts prem
   423       val (params,hyps,concl) = strip_context prem'
   424   in (insts,params,hyps,concl)  end;
   425 
   426 fun metahyps_aux_tac tacf (prem,gno) state =
   427   let val (insts,params,hyps,concl) = metahyps_split_prem prem
   428       val {thy = sign,maxidx,...} = rep_thm state
   429       val cterm = cterm_of sign
   430       val chyps = map cterm hyps
   431       val hypths = map assume chyps
   432       val subprems = map (forall_elim_vars 0) hypths
   433       val fparams = map Free params
   434       val cparams = map cterm fparams
   435       fun swap_ctpair (t,u) = (cterm u, cterm t)
   436       (*Subgoal variables: make Free; lift type over params*)
   437       fun mk_subgoal_inst concl_vars (var as Var(v,T)) =
   438           if member (op =) concl_vars var
   439           then (var, true, free_of "METAHYP2_" (v,T))
   440           else (var, false,
   441                 free_of "METAHYP2_" (v, map #2 params --->T))
   442       (*Instantiate subgoal vars by Free applied to params*)
   443       fun mk_ctpair (t,in_concl,u) =
   444           if in_concl then (cterm t,  cterm u)
   445           else (cterm t,  cterm (list_comb (u,fparams)))
   446       (*Restore Vars with higher type and index*)
   447       fun mk_subgoal_swap_ctpair
   448                 (t as Var((a,i),_), in_concl, u as Free(_,U)) =
   449           if in_concl then (cterm u, cterm t)
   450           else (cterm u, cterm(Var((a, i+maxidx), U)))
   451       (*Embed B in the original context of params and hyps*)
   452       fun embed B = list_all_free (params, Logic.list_implies (hyps, B))
   453       (*Strip the context using elimination rules*)
   454       fun elim Bhyp = implies_elim_list (forall_elim_list cparams Bhyp) hypths
   455       (*A form of lifting that discharges assumptions.*)
   456       fun relift st =
   457         let val prop = Thm.prop_of st
   458             val subgoal_vars = (*Vars introduced in the subgoals*)
   459                   List.foldr add_term_vars [] (Logic.strip_imp_prems prop)
   460             and concl_vars = add_term_vars (Logic.strip_imp_concl prop, [])
   461             val subgoal_insts = map (mk_subgoal_inst concl_vars) subgoal_vars
   462             val st' = Thm.instantiate ([], map mk_ctpair subgoal_insts) st
   463             val emBs = map (cterm o embed) (prems_of st')
   464             val Cth  = implies_elim_list st' (map (elim o assume) emBs)
   465         in  (*restore the unknowns to the hypotheses*)
   466             free_instantiate (map swap_ctpair insts @
   467                               map mk_subgoal_swap_ctpair subgoal_insts)
   468                 (*discharge assumptions from state in same order*)
   469                 (implies_intr_list emBs
   470                   (forall_intr_list cparams (implies_intr_list chyps Cth)))
   471         end
   472       (*function to replace the current subgoal*)
   473       fun next st = bicompose false (false, relift st, nprems_of st)
   474                     gno state
   475   in Seq.maps next (tacf subprems (trivial (cterm concl))) end;
   476 
   477 end;
   478 
   479 (*Returns the theorem list that METAHYPS would supply to its tactic*)
   480 fun metahyps_thms i state =
   481   let val prem = Logic.nth_prem (i, Thm.prop_of state)
   482       and cterm = cterm_of (Thm.theory_of_thm state)
   483       val (_,_,hyps,_) = metahyps_split_prem prem
   484   in SOME (map (forall_elim_vars 0 o assume o cterm) hyps) end
   485   handle TERM ("nth_prem", [A]) => NONE;
   486 
   487 local
   488 
   489 fun print_vars_terms thy (n,thm) =
   490   let
   491     fun typed ty = " has type: " ^ Sign.string_of_typ thy ty;
   492     fun find_vars thy (Const (c, ty)) =
   493         (case Term.typ_tvars ty
   494          of [] => I
   495           | _ => insert (op =) (c ^ typed ty))
   496       | find_vars thy (Var (xi, ty)) = insert (op =) (Term.string_of_vname xi ^ typed ty)
   497       | find_vars _ (Free _) = I
   498       | find_vars _ (Bound _) = I
   499       | find_vars thy (Abs (_, _, t)) = find_vars thy t
   500       | find_vars thy (t1 $ t2) =
   501           find_vars thy t1 #> find_vars thy t1;
   502     val prem = Logic.nth_prem (n, Thm.prop_of thm)
   503     val tms = find_vars thy prem []
   504   in
   505     (warning "Found schematic vars in assumptions:"; warning (cat_lines tms))
   506   end;
   507 
   508 in
   509 
   510 fun METAHYPS tacf n thm = SUBGOAL (metahyps_aux_tac tacf) n thm
   511   handle THM("assume: variables",_,_) => (print_vars_terms (theory_of_thm thm) (n,thm); Seq.empty)
   512 
   513 end;
   514 
   515 (*Makes a tactic whose effect on a state is given by thmfun: thm->thm seq.*)
   516 fun PRIMSEQ thmfun st =  thmfun st handle THM _ => Seq.empty;
   517 
   518 (*Makes a tactic whose effect on a state is given by thmfun: thm->thm.*)
   519 fun PRIMITIVE thmfun = PRIMSEQ (Seq.single o thmfun);
   520 
   521 (*Inverse (more or less) of PRIMITIVE*)
   522 fun SINGLE tacf = Option.map fst o Seq.pull o tacf
   523 
   524 (*Conversions as tactics*)
   525 fun CONVERSION cv i st = Seq.single (Conv.gconv_rule cv i st)
   526   handle THM _ => Seq.empty
   527     | CTERM _ => Seq.empty
   528     | TERM _ => Seq.empty
   529     | TYPE _ => Seq.empty;
   530 
   531 end;
   532 
   533 open Tactical;