src/Pure/term.ML
author berghofe
Mon Jan 21 14:18:49 2008 +0100 (2008-01-21)
changeset 25939 ddea202704b4
parent 25050 0dc445970b4b
child 27335 e8eef124d0fd
permissions -rw-r--r--
Removed Logic.auto_rename.
     1 (*  Title:      Pure/term.ML
     2     ID:         $Id$
     3     Author:     Lawrence C Paulson, Cambridge University Computer Laboratory
     4     Copyright   Cambridge University 1992
     5 
     6 Simply typed lambda-calculus: types, terms, and basic operations.
     7 *)
     8 
     9 infix 9  $;
    10 infixr 5 -->;
    11 infixr --->;
    12 infix aconv;
    13 
    14 signature BASIC_TERM =
    15 sig
    16   eqtype indexname
    17   eqtype class
    18   eqtype sort
    19   eqtype arity
    20   datatype typ =
    21     Type  of string * typ list |
    22     TFree of string * sort |
    23     TVar  of indexname * sort
    24   datatype term =
    25     Const of string * typ |
    26     Free of string * typ |
    27     Var of indexname * typ |
    28     Bound of int |
    29     Abs of string * typ * term |
    30     $ of term * term
    31   exception TYPE of string * typ list * term list
    32   exception TERM of string * term list
    33   val dummyS: sort
    34   val dummyT: typ
    35   val no_dummyT: typ -> typ
    36   val --> : typ * typ -> typ
    37   val ---> : typ list * typ -> typ
    38   val dest_Type: typ -> string * typ list
    39   val dest_TVar: typ -> indexname * sort
    40   val dest_TFree: typ -> string * sort
    41   val is_Bound: term -> bool
    42   val is_Const: term -> bool
    43   val is_Free: term -> bool
    44   val is_Var: term -> bool
    45   val is_TVar: typ -> bool
    46   val dest_Const: term -> string * typ
    47   val dest_Free: term -> string * typ
    48   val dest_Var: term -> indexname * typ
    49   val domain_type: typ -> typ
    50   val range_type: typ -> typ
    51   val binder_types: typ -> typ list
    52   val body_type: typ -> typ
    53   val strip_type: typ -> typ list * typ
    54   val type_of1: typ list * term -> typ
    55   val type_of: term -> typ
    56   val fastype_of1: typ list * term -> typ
    57   val fastype_of: term -> typ
    58   val list_abs: (string * typ) list * term -> term
    59   val strip_abs: term -> (string * typ) list * term
    60   val strip_abs_body: term -> term
    61   val strip_abs_vars: term -> (string * typ) list
    62   val strip_qnt_body: string -> term -> term
    63   val strip_qnt_vars: string -> term -> (string * typ) list
    64   val list_comb: term * term list -> term
    65   val strip_comb: term -> term * term list
    66   val head_of: term -> term
    67   val size_of_term: term -> int
    68   val map_atyps: (typ -> typ) -> typ -> typ
    69   val map_aterms: (term -> term) -> term -> term
    70   val map_type_tvar: (indexname * sort -> typ) -> typ -> typ
    71   val map_type_tfree: (string * sort -> typ) -> typ -> typ
    72   val map_types: (typ -> typ) -> term -> term
    73   val fold_atyps: (typ -> 'a -> 'a) -> typ -> 'a -> 'a
    74   val fold_aterms: (term -> 'a -> 'a) -> term -> 'a -> 'a
    75   val fold_term_types: (term -> typ -> 'a -> 'a) -> term -> 'a -> 'a
    76   val fold_types: (typ -> 'a -> 'a) -> term -> 'a -> 'a
    77   val burrow_types: (typ list -> typ list) -> term list -> term list
    78   val it_term_types: (typ * 'a -> 'a) -> term * 'a -> 'a
    79   val add_term_names: term * string list -> string list
    80   val aconv: term * term -> bool
    81   structure Vartab: TABLE
    82   structure Typtab: TABLE
    83   structure Termtab: TABLE
    84   val propT: typ
    85   val implies: term
    86   val all: typ -> term
    87   val equals: typ -> term
    88   val strip_all_body: term -> term
    89   val strip_all_vars: term -> (string * typ) list
    90   val incr_bv: int * int * term -> term
    91   val incr_boundvars: int -> term -> term
    92   val add_loose_bnos: term * int * int list -> int list
    93   val loose_bnos: term -> int list
    94   val loose_bvar: term * int -> bool
    95   val loose_bvar1: term * int -> bool
    96   val subst_bounds: term list * term -> term
    97   val subst_bound: term * term -> term
    98   val betapply: term * term -> term
    99   val betapplys: term * term list -> term
   100   val eq_ix: indexname * indexname -> bool
   101   val could_unify: term * term -> bool
   102   val subst_free: (term * term) list -> term -> term
   103   val abstract_over: term * term -> term
   104   val lambda: term -> term -> term
   105   val absfree: string * typ * term -> term
   106   val absdummy: typ * term -> term
   107   val list_abs_free: (string * typ) list * term -> term
   108   val list_all_free: (string * typ) list * term -> term
   109   val list_all: (string * typ) list * term -> term
   110   val subst_atomic: (term * term) list -> term -> term
   111   val typ_subst_atomic: (typ * typ) list -> typ -> typ
   112   val subst_atomic_types: (typ * typ) list -> term -> term
   113   val typ_subst_TVars: (indexname * typ) list -> typ -> typ
   114   val subst_TVars: (indexname * typ) list -> term -> term
   115   val subst_Vars: (indexname * term) list -> term -> term
   116   val subst_vars: (indexname * typ) list * (indexname * term) list -> term -> term
   117   val is_first_order: string list -> term -> bool
   118   val maxidx_of_typ: typ -> int
   119   val maxidx_of_typs: typ list -> int
   120   val maxidx_of_term: term -> int
   121   val add_term_consts: term * string list -> string list
   122   val term_consts: term -> string list
   123   val exists_subtype: (typ -> bool) -> typ -> bool
   124   val exists_type: (typ -> bool) -> term -> bool
   125   val exists_subterm: (term -> bool) -> term -> bool
   126   val exists_Const: (string * typ -> bool) -> term -> bool
   127   val add_term_free_names: term * string list -> string list
   128   val add_typ_tvars: typ * (indexname * sort) list -> (indexname * sort) list
   129   val add_typ_tfree_names: typ * string list -> string list
   130   val add_typ_tfrees: typ * (string * sort) list -> (string * sort) list
   131   val add_typ_varnames: typ * string list -> string list
   132   val add_term_tvars: term * (indexname * sort) list -> (indexname * sort) list
   133   val add_term_tfrees: term * (string * sort) list -> (string * sort) list
   134   val add_term_tfree_names: term * string list -> string list
   135   val typ_tfrees: typ -> (string * sort) list
   136   val typ_tvars: typ -> (indexname * sort) list
   137   val term_tfrees: term -> (string * sort) list
   138   val term_tvars: term -> (indexname * sort) list
   139   val add_typ_ixns: indexname list * typ -> indexname list
   140   val add_term_tvar_ixns: term * indexname list -> indexname list
   141   val add_term_vars: term * term list -> term list
   142   val term_vars: term -> term list
   143   val add_term_frees: term * term list -> term list
   144   val term_frees: term -> term list
   145   val rename_wrt_term: term -> (string * 'a) list -> (string * 'a) list
   146   val show_question_marks: bool ref
   147 end;
   148 
   149 signature TERM =
   150 sig
   151   include BASIC_TERM
   152   val aT: sort -> typ
   153   val itselfT: typ -> typ
   154   val a_itselfT: typ
   155   val argument_type_of: term -> int -> typ
   156   val head_name_of: term -> string
   157   val add_tvarsT: typ -> (indexname * sort) list -> (indexname * sort) list
   158   val add_tvars: term -> (indexname * sort) list -> (indexname * sort) list
   159   val add_vars: term -> (indexname * typ) list -> (indexname * typ) list
   160   val add_varnames: term -> indexname list -> indexname list
   161   val add_tfreesT: typ -> (string * sort) list -> (string * sort) list
   162   val add_tfrees: term -> (string * sort) list -> (string * sort) list
   163   val add_frees: term -> (string * typ) list -> (string * typ) list
   164   val hidden_polymorphism: term -> (indexname * sort) list
   165   val strip_abs_eta: int -> term -> (string * typ) list * term
   166   val fast_indexname_ord: indexname * indexname -> order
   167   val indexname_ord: indexname * indexname -> order
   168   val sort_ord: sort * sort -> order
   169   val typ_ord: typ * typ -> order
   170   val fast_term_ord: term * term -> order
   171   val term_ord: term * term -> order
   172   val hd_ord: term * term -> order
   173   val termless: term * term -> bool
   174   val term_lpo: (term -> int) -> term * term -> order
   175   val match_bvars: (term * term) * (string * string) list -> (string * string) list
   176   val map_abs_vars: (string -> string) -> term -> term
   177   val rename_abs: term -> term -> term -> term option
   178   val eq_tvar: (indexname * sort) * (indexname * sort) -> bool
   179   val eq_var: (indexname * typ) * (indexname * typ) -> bool
   180   val tvar_ord: (indexname * sort) * (indexname * sort) -> order
   181   val var_ord: (indexname * typ) * (indexname * typ) -> order
   182   val close_schematic_term: term -> term
   183   val maxidx_typ: typ -> int -> int
   184   val maxidx_typs: typ list -> int -> int
   185   val maxidx_term: term -> int -> int
   186   val has_abs: term -> bool
   187   val dest_abs: string * typ * term -> string * term
   188   val declare_typ_names: typ -> Name.context -> Name.context
   189   val declare_term_names: term -> Name.context -> Name.context
   190   val variant_frees: term -> (string * 'a) list -> (string * 'a) list
   191   val dummy_patternN: string
   192   val dummy_pattern: typ -> term
   193   val is_dummy_pattern: term -> bool
   194   val free_dummy_patterns: term -> Name.context -> term * Name.context
   195   val no_dummy_patterns: term -> term
   196   val replace_dummy_patterns: term -> int -> term * int
   197   val is_replaced_dummy_pattern: indexname -> bool
   198   val show_dummy_patterns: term -> term
   199   val string_of_vname: indexname -> string
   200   val string_of_vname': indexname -> string
   201 end;
   202 
   203 structure Term: TERM =
   204 struct
   205 
   206 (*Indexnames can be quickly renamed by adding an offset to the integer part,
   207   for resolution.*)
   208 type indexname = string * int;
   209 
   210 (* Types are classified by sorts. *)
   211 type class = string;
   212 type sort  = class list;
   213 type arity = string * sort list * sort;
   214 
   215 (* The sorts attached to TFrees and TVars specify the sort of that variable *)
   216 datatype typ = Type  of string * typ list
   217              | TFree of string * sort
   218              | TVar  of indexname * sort;
   219 
   220 (*Terms.  Bound variables are indicated by depth number.
   221   Free variables, (scheme) variables and constants have names.
   222   An term is "closed" if every bound variable of level "lev"
   223   is enclosed by at least "lev" abstractions.
   224 
   225   It is possible to create meaningless terms containing loose bound vars
   226   or type mismatches.  But such terms are not allowed in rules. *)
   227 
   228 datatype term =
   229     Const of string * typ
   230   | Free  of string * typ
   231   | Var   of indexname * typ
   232   | Bound of int
   233   | Abs   of string*typ*term
   234   | op $  of term*term;
   235 
   236 (*Errors involving type mismatches*)
   237 exception TYPE of string * typ list * term list;
   238 
   239 (*Errors errors involving terms*)
   240 exception TERM of string * term list;
   241 
   242 (*Note variable naming conventions!
   243     a,b,c: string
   244     f,g,h: functions (including terms of function type)
   245     i,j,m,n: int
   246     t,u: term
   247     v,w: indexnames
   248     x,y: any
   249     A,B,C: term (denoting formulae)
   250     T,U: typ
   251 *)
   252 
   253 
   254 (** Types **)
   255 
   256 (*dummies for type-inference etc.*)
   257 val dummyS = [""];
   258 val dummyT = Type ("dummy", []);
   259 
   260 fun no_dummyT typ =
   261   let
   262     fun check (T as Type ("dummy", _)) =
   263           raise TYPE ("Illegal occurrence of '_' dummy type", [T], [])
   264       | check (Type (_, Ts)) = List.app check Ts
   265       | check _ = ();
   266   in check typ; typ end;
   267 
   268 fun S --> T = Type("fun",[S,T]);
   269 
   270 (*handy for multiple args: [T1,...,Tn]--->T  gives  T1-->(T2--> ... -->T)*)
   271 val op ---> = Library.foldr (op -->);
   272 
   273 fun dest_Type (Type x) = x
   274   | dest_Type T = raise TYPE ("dest_Type", [T], []);
   275 fun dest_TVar (TVar x) = x
   276   | dest_TVar T = raise TYPE ("dest_TVar", [T], []);
   277 fun dest_TFree (TFree x) = x
   278   | dest_TFree T = raise TYPE ("dest_TFree", [T], []);
   279 
   280 
   281 (** Discriminators **)
   282 
   283 fun is_Bound (Bound _) = true
   284   | is_Bound _         = false;
   285 
   286 fun is_Const (Const _) = true
   287   | is_Const _ = false;
   288 
   289 fun is_Free (Free _) = true
   290   | is_Free _ = false;
   291 
   292 fun is_Var (Var _) = true
   293   | is_Var _ = false;
   294 
   295 fun is_TVar (TVar _) = true
   296   | is_TVar _ = false;
   297 
   298 
   299 (** Destructors **)
   300 
   301 fun dest_Const (Const x) =  x
   302   | dest_Const t = raise TERM("dest_Const", [t]);
   303 
   304 fun dest_Free (Free x) =  x
   305   | dest_Free t = raise TERM("dest_Free", [t]);
   306 
   307 fun dest_Var (Var x) =  x
   308   | dest_Var t = raise TERM("dest_Var", [t]);
   309 
   310 
   311 fun domain_type (Type("fun", [T,_])) = T
   312 and range_type  (Type("fun", [_,T])) = T;
   313 
   314 (* maps  [T1,...,Tn]--->T  to the list  [T1,T2,...,Tn]*)
   315 fun binder_types (Type("fun",[S,T])) = S :: binder_types T
   316   | binder_types _   =  [];
   317 
   318 (* maps  [T1,...,Tn]--->T  to T*)
   319 fun body_type (Type("fun",[S,T])) = body_type T
   320   | body_type T   =  T;
   321 
   322 (* maps  [T1,...,Tn]--->T  to   ([T1,T2,...,Tn], T)  *)
   323 fun strip_type T : typ list * typ =
   324   (binder_types T, body_type T);
   325 
   326 
   327 (*Compute the type of the term, checking that combinations are well-typed
   328   Ts = [T0,T1,...] holds types of bound variables 0, 1, ...*)
   329 fun type_of1 (Ts, Const (_,T)) = T
   330   | type_of1 (Ts, Free  (_,T)) = T
   331   | type_of1 (Ts, Bound i) = (List.nth (Ts,i)
   332         handle Subscript => raise TYPE("type_of: bound variable", [], [Bound i]))
   333   | type_of1 (Ts, Var (_,T)) = T
   334   | type_of1 (Ts, Abs (_,T,body)) = T --> type_of1(T::Ts, body)
   335   | type_of1 (Ts, f$u) =
   336       let val U = type_of1(Ts,u)
   337           and T = type_of1(Ts,f)
   338       in case T of
   339             Type("fun",[T1,T2]) =>
   340               if T1=U then T2  else raise TYPE
   341                     ("type_of: type mismatch in application", [T1,U], [f$u])
   342           | _ => raise TYPE
   343                     ("type_of: function type is expected in application",
   344                      [T,U], [f$u])
   345       end;
   346 
   347 fun type_of t : typ = type_of1 ([],t);
   348 
   349 (*Determines the type of a term, with minimal checking*)
   350 fun fastype_of1 (Ts, f$u) =
   351     (case fastype_of1 (Ts,f) of
   352         Type("fun",[_,T]) => T
   353         | _ => raise TERM("fastype_of: expected function type", [f$u]))
   354   | fastype_of1 (_, Const (_,T)) = T
   355   | fastype_of1 (_, Free (_,T)) = T
   356   | fastype_of1 (Ts, Bound i) = (List.nth(Ts,i)
   357          handle Subscript => raise TERM("fastype_of: Bound", [Bound i]))
   358   | fastype_of1 (_, Var (_,T)) = T
   359   | fastype_of1 (Ts, Abs (_,T,u)) = T --> fastype_of1 (T::Ts, u);
   360 
   361 fun fastype_of t : typ = fastype_of1 ([],t);
   362 
   363 (*Determine the argument type of a function*)
   364 fun argument_type_of tm k =
   365   let
   366     fun argT i (Type ("fun", [T, U])) = if i = 0 then T else argT (i - 1) U
   367       | argT _ T = raise TYPE ("argument_type_of", [T], []);
   368 
   369     fun arg 0 _ (Abs (_, T, _)) = T
   370       | arg i Ts (Abs (_, T, t)) = arg (i - 1) (T :: Ts) t
   371       | arg i Ts (t $ _) = arg (i + 1) Ts t
   372       | arg i Ts a = argT i (fastype_of1 (Ts, a));
   373   in arg k [] tm end;
   374 
   375 
   376 val list_abs = uncurry (fold_rev (fn (x, T) => fn t => Abs (x, T, t)));
   377 
   378 fun strip_abs (Abs (a, T, t)) =
   379       let val (a', t') = strip_abs t
   380       in ((a, T) :: a', t') end
   381   | strip_abs t = ([], t);
   382 
   383 (* maps  (x1,...,xn)t   to   t  *)
   384 fun strip_abs_body (Abs(_,_,t))  =  strip_abs_body t
   385   | strip_abs_body u  =  u;
   386 
   387 (* maps  (x1,...,xn)t   to   [x1, ..., xn]  *)
   388 fun strip_abs_vars (Abs(a,T,t))  =  (a,T) :: strip_abs_vars t
   389   | strip_abs_vars u  =  [] : (string*typ) list;
   390 
   391 
   392 fun strip_qnt_body qnt =
   393 let fun strip(tm as Const(c,_)$Abs(_,_,t)) = if c=qnt then strip t else tm
   394       | strip t = t
   395 in strip end;
   396 
   397 fun strip_qnt_vars qnt =
   398 let fun strip(Const(c,_)$Abs(a,T,t)) = if c=qnt then (a,T)::strip t else []
   399       | strip t  =  [] : (string*typ) list
   400 in strip end;
   401 
   402 
   403 (* maps   (f, [t1,...,tn])  to  f(t1,...,tn) *)
   404 val list_comb : term * term list -> term = Library.foldl (op $);
   405 
   406 
   407 (* maps   f(t1,...,tn)  to  (f, [t1,...,tn]) ; naturally tail-recursive*)
   408 fun strip_comb u : term * term list =
   409     let fun stripc (f$t, ts) = stripc (f, t::ts)
   410         |   stripc  x =  x
   411     in  stripc(u,[])  end;
   412 
   413 
   414 (* maps   f(t1,...,tn)  to  f , which is never a combination *)
   415 fun head_of (f$t) = head_of f
   416   | head_of u = u;
   417 
   418 fun head_name_of tm =
   419   (case head_of tm of
   420     t as Const (c, _) =>
   421       if NameSpace.is_qualified c then c
   422       else raise TERM ("Malformed constant name", [t])
   423   | t as Free (x, _) =>
   424       if not (NameSpace.is_qualified x) then x
   425       else raise TERM ("Malformed fixed variable name", [t])
   426   | t => raise TERM ("No fixed head of term", [t]));
   427 
   428 (*number of atoms and abstractions in a term*)
   429 fun size_of_term tm =
   430   let
   431     fun add_size (t $ u, n) = add_size (t, add_size (u, n))
   432       | add_size (Abs (_ ,_, t), n) = add_size (t, n + 1)
   433       | add_size (_, n) = n + 1;
   434   in add_size (tm, 0) end;
   435 
   436 fun map_atyps f (Type (a, Ts)) = Type (a, map (map_atyps f) Ts)
   437   | map_atyps f T = f T;
   438 
   439 fun map_aterms f (t $ u) = map_aterms f t $ map_aterms f u
   440   | map_aterms f (Abs (a, T, t)) = Abs (a, T, map_aterms f t)
   441   | map_aterms f t = f t;
   442 
   443 fun map_type_tvar f = map_atyps (fn TVar x => f x | T => T);
   444 fun map_type_tfree f = map_atyps (fn TFree x => f x | T => T);
   445 
   446 fun map_types f =
   447   let
   448     fun map_aux (Const (a, T)) = Const (a, f T)
   449       | map_aux (Free (a, T)) = Free (a, f T)
   450       | map_aux (Var (v, T)) = Var (v, f T)
   451       | map_aux (t as Bound _)  = t
   452       | map_aux (Abs (a, T, t)) = Abs (a, f T, map_aux t)
   453       | map_aux (t $ u) = map_aux t $ map_aux u;
   454   in map_aux end;
   455 
   456 (* iterate a function over all types in a term *)
   457 fun it_term_types f =
   458 let fun iter(Const(_,T), a) = f(T,a)
   459       | iter(Free(_,T), a) = f(T,a)
   460       | iter(Var(_,T), a) = f(T,a)
   461       | iter(Abs(_,T,t), a) = iter(t,f(T,a))
   462       | iter(f$u, a) = iter(f, iter(u, a))
   463       | iter(Bound _, a) = a
   464 in iter end
   465 
   466 
   467 (* fold types and terms *)
   468 
   469 (*fold atoms of type*)
   470 fun fold_atyps f (Type (_, Ts)) = fold (fold_atyps f) Ts
   471   | fold_atyps f T = f T;
   472 
   473 (*fold atoms of term*)
   474 fun fold_aterms f (t $ u) = fold_aterms f t #> fold_aterms f u
   475   | fold_aterms f (Abs (_, _, t)) = fold_aterms f t
   476   | fold_aterms f a = f a;
   477 
   478 (*fold types of term*)
   479 fun fold_term_types f (t as Const (_, T)) = f t T
   480   | fold_term_types f (t as Free (_, T)) = f t T
   481   | fold_term_types f (t as Var (_, T)) = f t T
   482   | fold_term_types f (Bound _) = I
   483   | fold_term_types f (t as Abs (_, T, b)) = f t T #> fold_term_types f b
   484   | fold_term_types f (t $ u) = fold_term_types f t #> fold_term_types f u;
   485 
   486 fun fold_types f = fold_term_types (K f);
   487 
   488 fun replace_types (Const (c, _)) (T :: Ts) = (Const (c, T), Ts)
   489   | replace_types (Free (x, _)) (T :: Ts) = (Free (x, T), Ts)
   490   | replace_types (Var (xi, _)) (T :: Ts) = (Var (xi, T), Ts)
   491   | replace_types (Bound i) Ts = (Bound i, Ts)
   492   | replace_types (Abs (x, _, b)) (T :: Ts) =
   493       let val (b', Ts') = replace_types b Ts
   494       in (Abs (x, T, b'), Ts') end
   495   | replace_types (t $ u) Ts =
   496       let
   497         val (t', Ts') = replace_types t Ts;
   498         val (u', Ts'') = replace_types u Ts';
   499       in (t' $ u', Ts'') end;
   500 
   501 fun burrow_types f ts =
   502   let
   503     val Ts = rev (fold (fold_types cons) ts []);
   504     val Ts' = f Ts;
   505     val (ts', []) = fold_map replace_types ts Ts';
   506   in ts' end;
   507 
   508 (*collect variables*)
   509 val add_tvarsT = fold_atyps (fn TVar v => insert (op =) v | _ => I);
   510 val add_tvars = fold_types add_tvarsT;
   511 val add_vars = fold_aterms (fn Var v => insert (op =) v | _ => I);
   512 val add_varnames = fold_aterms (fn Var (xi, _) => insert (op =) xi | _ => I);
   513 val add_tfreesT = fold_atyps (fn TFree v => insert (op =) v | _ => I);
   514 val add_tfrees = fold_types add_tfreesT;
   515 val add_frees = fold_aterms (fn Free v => insert (op =) v | _ => I);
   516 
   517 (*extra type variables in a term, not covered by its type*)
   518 fun hidden_polymorphism t =
   519   let
   520     val T = fastype_of t;
   521     val tvarsT = add_tvarsT T [];
   522     val extra_tvars = fold_types (fold_atyps
   523       (fn TVar v => if member (op =) tvarsT v then I else insert (op =) v | _ => I)) t [];
   524   in extra_tvars end;
   525 
   526 
   527 
   528 (** Comparing terms, types, sorts etc. **)
   529 
   530 (* alpha equivalence -- tuned for equalities *)
   531 
   532 fun tm1 aconv tm2 =
   533   pointer_eq (tm1, tm2) orelse
   534     (case (tm1, tm2) of
   535       (t1 $ u1, t2 $ u2) => t1 aconv t2 andalso u1 aconv u2
   536     | (Abs (_, T1, t1), Abs (_, T2, t2)) => t1 aconv t2 andalso T1 = T2
   537     | (a1, a2) => a1 = a2);
   538 
   539 
   540 (* fast syntactic ordering -- tuned for inequalities *)
   541 
   542 fun fast_indexname_ord ((x, i), (y, j)) =
   543   (case int_ord (i, j) of EQUAL => fast_string_ord (x, y) | ord => ord);
   544 
   545 fun sort_ord SS =
   546   if pointer_eq SS then EQUAL
   547   else dict_ord fast_string_ord SS;
   548 
   549 local
   550 
   551 fun cons_nr (TVar _) = 0
   552   | cons_nr (TFree _) = 1
   553   | cons_nr (Type _) = 2;
   554 
   555 in
   556 
   557 fun typ_ord TU =
   558   if pointer_eq TU then EQUAL
   559   else
   560     (case TU of
   561       (Type (a, Ts), Type (b, Us)) =>
   562         (case fast_string_ord (a, b) of EQUAL => dict_ord typ_ord (Ts, Us) | ord => ord)
   563     | (TFree (a, S), TFree (b, S')) =>
   564         (case fast_string_ord (a, b) of EQUAL => sort_ord (S, S') | ord => ord)
   565     | (TVar (xi, S), TVar (yj, S')) =>
   566         (case fast_indexname_ord (xi, yj) of EQUAL => sort_ord (S, S') | ord => ord)
   567     | (T, U) => int_ord (cons_nr T, cons_nr U));
   568 
   569 end;
   570 
   571 local
   572 
   573 fun cons_nr (Const _) = 0
   574   | cons_nr (Free _) = 1
   575   | cons_nr (Var _) = 2
   576   | cons_nr (Bound _) = 3
   577   | cons_nr (Abs _) = 4
   578   | cons_nr (_ $ _) = 5;
   579 
   580 fun struct_ord (Abs (_, _, t), Abs (_, _, u)) = struct_ord (t, u)
   581   | struct_ord (t1 $ t2, u1 $ u2) =
   582       (case struct_ord (t1, u1) of EQUAL => struct_ord (t2, u2) | ord => ord)
   583   | struct_ord (t, u) = int_ord (cons_nr t, cons_nr u);
   584 
   585 fun atoms_ord (Abs (_, _, t), Abs (_, _, u)) = atoms_ord (t, u)
   586   | atoms_ord (t1 $ t2, u1 $ u2) =
   587       (case atoms_ord (t1, u1) of EQUAL => atoms_ord (t2, u2) | ord => ord)
   588   | atoms_ord (Const (a, _), Const (b, _)) = fast_string_ord (a, b)
   589   | atoms_ord (Free (x, _), Free (y, _)) = fast_string_ord (x, y)
   590   | atoms_ord (Var (xi, _), Var (yj, _)) = fast_indexname_ord (xi, yj)
   591   | atoms_ord (Bound i, Bound j) = int_ord (i, j)
   592   | atoms_ord _ = sys_error "atoms_ord";
   593 
   594 fun types_ord (Abs (_, T, t), Abs (_, U, u)) =
   595       (case typ_ord (T, U) of EQUAL => types_ord (t, u) | ord => ord)
   596   | types_ord (t1 $ t2, u1 $ u2) =
   597       (case types_ord (t1, u1) of EQUAL => types_ord (t2, u2) | ord => ord)
   598   | types_ord (Const (_, T), Const (_, U)) = typ_ord (T, U)
   599   | types_ord (Free (_, T), Free (_, U)) = typ_ord (T, U)
   600   | types_ord (Var (_, T), Var (_, U)) = typ_ord (T, U)
   601   | types_ord (Bound _, Bound _) = EQUAL
   602   | types_ord _ = sys_error "types_ord";
   603 
   604 in
   605 
   606 fun fast_term_ord tu =
   607   if pointer_eq tu then EQUAL
   608   else
   609     (case struct_ord tu of
   610       EQUAL => (case atoms_ord tu of EQUAL => types_ord tu | ord => ord)
   611     | ord => ord);
   612 
   613 structure Vartab = TableFun(type key = indexname val ord = fast_indexname_ord);
   614 structure Typtab = TableFun(type key = typ val ord = typ_ord);
   615 structure Termtab = TableFun(type key = term val ord = fast_term_ord);
   616 
   617 end;
   618 
   619 
   620 (* term_ord *)
   621 
   622 (*a linear well-founded AC-compatible ordering for terms:
   623   s < t <=> 1. size(s) < size(t) or
   624             2. size(s) = size(t) and s=f(...) and t=g(...) and f<g or
   625             3. size(s) = size(t) and s=f(s1..sn) and t=f(t1..tn) and
   626                (s1..sn) < (t1..tn) (lexicographically)*)
   627 
   628 fun indexname_ord ((x, i), (y, j)) =
   629   (case int_ord (i, j) of EQUAL => string_ord (x, y) | ord => ord);
   630 
   631 local
   632 
   633 fun hd_depth (t $ _, n) = hd_depth (t, n + 1)
   634   | hd_depth p = p;
   635 
   636 fun dest_hd (Const (a, T)) = (((a, 0), T), 0)
   637   | dest_hd (Free (a, T)) = (((a, 0), T), 1)
   638   | dest_hd (Var v) = (v, 2)
   639   | dest_hd (Bound i) = ((("", i), dummyT), 3)
   640   | dest_hd (Abs (_, T, _)) = ((("", 0), T), 4);
   641 
   642 in
   643 
   644 fun term_ord tu =
   645   if pointer_eq tu then EQUAL
   646   else
   647     (case tu of
   648       (Abs (_, T, t), Abs(_, U, u)) =>
   649         (case term_ord (t, u) of EQUAL => typ_ord (T, U) | ord => ord)
   650     | (t, u) =>
   651         (case int_ord (size_of_term t, size_of_term u) of
   652           EQUAL =>
   653             (case prod_ord hd_ord int_ord (hd_depth (t, 0), hd_depth (u, 0)) of
   654               EQUAL => args_ord (t, u) | ord => ord)
   655         | ord => ord))
   656 and hd_ord (f, g) =
   657   prod_ord (prod_ord indexname_ord typ_ord) int_ord (dest_hd f, dest_hd g)
   658 and args_ord (f $ t, g $ u) =
   659       (case args_ord (f, g) of EQUAL => term_ord (t, u) | ord => ord)
   660   | args_ord _ = EQUAL;
   661 
   662 fun termless tu = (term_ord tu = LESS);
   663 
   664 end;
   665 
   666 
   667 (** Lexicographic path order on terms **)
   668 
   669 (*
   670   See Baader & Nipkow, Term rewriting, CUP 1998.
   671   Without variables.  Const, Var, Bound, Free and Abs are treated all as
   672   constants.
   673 
   674   f_ord maps terms to integers and serves two purposes:
   675   - Predicate on constant symbols.  Those that are not recognised by f_ord
   676     must be mapped to ~1.
   677   - Order on the recognised symbols.  These must be mapped to distinct
   678     integers >= 0.
   679   The argument of f_ord is never an application.
   680 *)
   681 
   682 local
   683 
   684 fun unrecognized (Const (a, T)) = ((1, ((a, 0), T)), 0)
   685   | unrecognized (Free (a, T)) = ((1, ((a, 0), T)), 0)
   686   | unrecognized (Var v) = ((1, v), 1)
   687   | unrecognized (Bound i) = ((1, (("", i), dummyT)), 2)
   688   | unrecognized (Abs (_, T, _)) = ((1, (("", 0), T)), 3);
   689 
   690 fun dest_hd f_ord t =
   691       let val ord = f_ord t in
   692         if ord = ~1 then unrecognized t else ((0, (("", ord), fastype_of t)), 0)
   693       end
   694 
   695 fun term_lpo f_ord (s, t) =
   696   let val (f, ss) = strip_comb s and (g, ts) = strip_comb t in
   697     if forall (fn si => term_lpo f_ord (si, t) = LESS) ss
   698     then case hd_ord f_ord (f, g) of
   699         GREATER =>
   700           if forall (fn ti => term_lpo f_ord (s, ti) = GREATER) ts
   701           then GREATER else LESS
   702       | EQUAL =>
   703           if forall (fn ti => term_lpo f_ord (s, ti) = GREATER) ts
   704           then list_ord (term_lpo f_ord) (ss, ts)
   705           else LESS
   706       | LESS => LESS
   707     else GREATER
   708   end
   709 and hd_ord f_ord (f, g) = case (f, g) of
   710     (Abs (_, T, t), Abs (_, U, u)) =>
   711       (case term_lpo f_ord (t, u) of EQUAL => typ_ord (T, U) | ord => ord)
   712   | (_, _) => prod_ord (prod_ord int_ord
   713                   (prod_ord indexname_ord typ_ord)) int_ord
   714                 (dest_hd f_ord f, dest_hd f_ord g)
   715 in
   716 val term_lpo = term_lpo
   717 end;
   718 
   719 
   720 (** Connectives of higher order logic **)
   721 
   722 fun aT S = TFree (Name.aT, S);
   723 
   724 fun itselfT ty = Type ("itself", [ty]);
   725 val a_itselfT = itselfT (TFree (Name.aT, []));
   726 
   727 val propT : typ = Type("prop",[]);
   728 
   729 val implies = Const("==>", propT-->propT-->propT);
   730 
   731 fun all T = Const("all", (T-->propT)-->propT);
   732 
   733 fun equals T = Const("==", T-->T-->propT);
   734 
   735 (* maps  !!x1...xn. t   to   t  *)
   736 fun strip_all_body (Const("all",_)$Abs(_,_,t))  =  strip_all_body t
   737   | strip_all_body t  =  t;
   738 
   739 (* maps  !!x1...xn. t   to   [x1, ..., xn]  *)
   740 fun strip_all_vars (Const("all",_)$Abs(a,T,t))  =
   741                 (a,T) :: strip_all_vars t
   742   | strip_all_vars t  =  [] : (string*typ) list;
   743 
   744 (*increments a term's non-local bound variables
   745   required when moving a term within abstractions
   746      inc is  increment for bound variables
   747      lev is  level at which a bound variable is considered 'loose'*)
   748 fun incr_bv (inc, lev, u as Bound i) = if i>=lev then Bound(i+inc) else u
   749   | incr_bv (inc, lev, Abs(a,T,body)) =
   750         Abs(a, T, incr_bv(inc,lev+1,body))
   751   | incr_bv (inc, lev, f$t) =
   752       incr_bv(inc,lev,f) $ incr_bv(inc,lev,t)
   753   | incr_bv (inc, lev, u) = u;
   754 
   755 fun incr_boundvars  0  t = t
   756   | incr_boundvars inc t = incr_bv(inc,0,t);
   757 
   758 (*Scan a pair of terms; while they are similar,
   759   accumulate corresponding bound vars in "al"*)
   760 fun match_bvs(Abs(x,_,s),Abs(y,_,t), al) =
   761       match_bvs(s, t, if x="" orelse y="" then al
   762                                           else (x,y)::al)
   763   | match_bvs(f$s, g$t, al) = match_bvs(f,g,match_bvs(s,t,al))
   764   | match_bvs(_,_,al) = al;
   765 
   766 (* strip abstractions created by parameters *)
   767 fun match_bvars((s,t),al) = match_bvs(strip_abs_body s, strip_abs_body t, al);
   768 
   769 fun map_abs_vars f (t $ u) = map_abs_vars f t $ map_abs_vars f u
   770   | map_abs_vars f (Abs (a, T, t)) = Abs (f a, T, map_abs_vars f t)
   771   | map_abs_vars f t = t;
   772 
   773 fun rename_abs pat obj t =
   774   let
   775     val ren = match_bvs (pat, obj, []);
   776     fun ren_abs (Abs (x, T, b)) =
   777           Abs (the_default x (AList.lookup (op =) ren x), T, ren_abs b)
   778       | ren_abs (f $ t) = ren_abs f $ ren_abs t
   779       | ren_abs t = t
   780   in if null ren then NONE else SOME (ren_abs t) end;
   781 
   782 (*Accumulate all 'loose' bound vars referring to level 'lev' or beyond.
   783    (Bound 0) is loose at level 0 *)
   784 fun add_loose_bnos (Bound i, lev, js) =
   785         if i<lev then js else insert (op =) (i - lev) js
   786   | add_loose_bnos (Abs (_,_,t), lev, js) = add_loose_bnos (t, lev+1, js)
   787   | add_loose_bnos (f$t, lev, js) =
   788         add_loose_bnos (f, lev, add_loose_bnos (t, lev, js))
   789   | add_loose_bnos (_, _, js) = js;
   790 
   791 fun loose_bnos t = add_loose_bnos (t, 0, []);
   792 
   793 (* loose_bvar(t,k) iff t contains a 'loose' bound variable referring to
   794    level k or beyond. *)
   795 fun loose_bvar(Bound i,k) = i >= k
   796   | loose_bvar(f$t, k) = loose_bvar(f,k) orelse loose_bvar(t,k)
   797   | loose_bvar(Abs(_,_,t),k) = loose_bvar(t,k+1)
   798   | loose_bvar _ = false;
   799 
   800 fun loose_bvar1(Bound i,k) = i = k
   801   | loose_bvar1(f$t, k) = loose_bvar1(f,k) orelse loose_bvar1(t,k)
   802   | loose_bvar1(Abs(_,_,t),k) = loose_bvar1(t,k+1)
   803   | loose_bvar1 _ = false;
   804 
   805 (*Substitute arguments for loose bound variables.
   806   Beta-reduction of arg(n-1)...arg0 into t replacing (Bound i) with (argi).
   807   Note that for ((%x y. c) a b), the bound vars in c are x=1 and y=0
   808         and the appropriate call is  subst_bounds([b,a], c) .
   809   Loose bound variables >=n are reduced by "n" to
   810      compensate for the disappearance of lambdas.
   811 *)
   812 fun subst_bounds (args: term list, t) : term =
   813   let
   814     exception SAME;
   815     val n = length args;
   816     fun subst (t as Bound i, lev) =
   817          (if i < lev then raise SAME   (*var is locally bound*)
   818           else incr_boundvars lev (List.nth (args, i - lev))
   819             handle Subscript => Bound (i - n))  (*loose: change it*)
   820       | subst (Abs (a, T, body), lev) = Abs (a, T, subst (body, lev + 1))
   821       | subst (f $ t, lev) =
   822           (subst (f, lev) $ (subst (t, lev) handle SAME => t) handle SAME => f $ subst (t, lev))
   823       | subst _ = raise SAME;
   824   in case args of [] => t | _ => (subst (t, 0) handle SAME => t) end;
   825 
   826 (*Special case: one argument*)
   827 fun subst_bound (arg, t) : term =
   828   let
   829     exception SAME;
   830     fun subst (Bound i, lev) =
   831           if i < lev then raise SAME   (*var is locally bound*)
   832           else if i = lev then incr_boundvars lev arg
   833           else Bound (i - 1)   (*loose: change it*)
   834       | subst (Abs (a, T, body), lev) = Abs (a, T, subst (body, lev + 1))
   835       | subst (f $ t, lev) =
   836           (subst (f, lev) $ (subst (t, lev) handle SAME => t) handle SAME => f $ subst (t, lev))
   837       | subst _ = raise SAME;
   838   in subst (t, 0) handle SAME => t end;
   839 
   840 (*beta-reduce if possible, else form application*)
   841 fun betapply (Abs(_,_,t), u) = subst_bound (u,t)
   842   | betapply (f,u) = f$u;
   843 
   844 val betapplys = Library.foldl betapply;
   845 
   846 
   847 (*unfolding abstractions with substitution
   848   of bound variables and implicit eta-expansion*)
   849 fun strip_abs_eta k t =
   850   let
   851     val used = fold_aterms (fn Free (v, _) => Name.declare v | _ => I) t Name.context;
   852     fun strip_abs t (0, used) = (([], t), (0, used))
   853       | strip_abs (Abs (v, T, t)) (k, used) =
   854           let
   855             val ([v'], used') = Name.variants [v] used;
   856             val t' = subst_bound (Free (v', T), t);
   857             val ((vs, t''), (k', used'')) = strip_abs t' (k - 1, used');
   858           in (((v', T) :: vs, t''), (k', used'')) end
   859       | strip_abs t (k, used) = (([], t), (k, used));
   860     fun expand_eta [] t _ = ([], t)
   861       | expand_eta (T::Ts) t used =
   862           let
   863             val ([v], used') = Name.variants [""] used;
   864             val (vs, t') = expand_eta Ts (t $ Free (v, T)) used';
   865           in ((v, T) :: vs, t') end;
   866     val ((vs1, t'), (k', used')) = strip_abs t (k, used);
   867     val Ts = (fst o chop k' o fst o strip_type o fastype_of) t';
   868     val (vs2, t'') = expand_eta Ts t' used';
   869   in (vs1 @ vs2, t'') end;
   870 
   871 
   872 (* comparing variables *)
   873 
   874 fun eq_ix ((x, i): indexname, (y, j)) = i = j andalso x = y;
   875 
   876 fun eq_tvar ((xi, S: sort), (xi', S')) = eq_ix (xi, xi') andalso S = S';
   877 fun eq_var ((xi, T: typ), (xi', T')) = eq_ix (xi, xi') andalso T = T';
   878 
   879 val tvar_ord = prod_ord indexname_ord sort_ord;
   880 val var_ord = prod_ord indexname_ord typ_ord;
   881 
   882 
   883 (*A fast unification filter: true unless the two terms cannot be unified.
   884   Terms must be NORMAL.  Treats all Vars as distinct. *)
   885 fun could_unify (t,u) =
   886   let fun matchrands (f$t, g$u) = could_unify(t,u) andalso  matchrands(f,g)
   887         | matchrands _ = true
   888   in case (head_of t , head_of u) of
   889         (_, Var _) => true
   890       | (Var _, _) => true
   891       | (Const(a,_), Const(b,_)) =>  a=b andalso matchrands(t,u)
   892       | (Free(a,_), Free(b,_)) =>  a=b andalso matchrands(t,u)
   893       | (Bound i, Bound j) =>  i=j andalso matchrands(t,u)
   894       | (Abs _, _) =>  true   (*because of possible eta equality*)
   895       | (_, Abs _) =>  true
   896       | _ => false
   897   end;
   898 
   899 (*Substitute new for free occurrences of old in a term*)
   900 fun subst_free [] = (fn t=>t)
   901   | subst_free pairs =
   902       let fun substf u =
   903             case AList.lookup (op aconv) pairs u of
   904                 SOME u' => u'
   905               | NONE => (case u of Abs(a,T,t) => Abs(a, T, substf t)
   906                                  | t$u' => substf t $ substf u'
   907                                  | _ => u)
   908       in  substf  end;
   909 
   910 (*Abstraction of the term "body" over its occurrences of v,
   911     which must contain no loose bound variables.
   912   The resulting term is ready to become the body of an Abs.*)
   913 fun abstract_over (v, body) =
   914   let
   915     exception SAME;
   916     fun abs lev tm =
   917       if v aconv tm then Bound lev
   918       else
   919         (case tm of
   920           Abs (a, T, t) => Abs (a, T, abs (lev + 1) t)
   921         | t $ u => (abs lev t $ (abs lev u handle SAME => u) handle SAME => t $ abs lev u)
   922         | _ => raise SAME);
   923   in abs 0 body handle SAME => body end;
   924 
   925 fun lambda v t =
   926   let val x =
   927     (case v of
   928       Const (x, _) => NameSpace.base x
   929     | Free (x, _) => x
   930     | Var ((x, _), _) => x
   931     | _ => Name.uu)
   932   in Abs (x, fastype_of v, abstract_over (v, t)) end;
   933 
   934 (*Form an abstraction over a free variable.*)
   935 fun absfree (a,T,body) = Abs (a, T, abstract_over (Free (a, T), body));
   936 fun absdummy (T, body) = Abs (Name.internal Name.uu, T, body);
   937 
   938 (*Abstraction over a list of free variables*)
   939 fun list_abs_free ([ ] ,     t) = t
   940   | list_abs_free ((a,T)::vars, t) =
   941       absfree(a, T, list_abs_free(vars,t));
   942 
   943 (*Quantification over a list of free variables*)
   944 fun list_all_free ([], t: term) = t
   945   | list_all_free ((a,T)::vars, t) =
   946         (all T) $ (absfree(a, T, list_all_free(vars,t)));
   947 
   948 (*Quantification over a list of variables (already bound in body) *)
   949 fun list_all ([], t) = t
   950   | list_all ((a,T)::vars, t) =
   951         (all T) $ (Abs(a, T, list_all(vars,t)));
   952 
   953 (*Replace the ATOMIC term ti by ui;    inst = [(t1,u1), ..., (tn,un)].
   954   A simultaneous substitution:  [ (a,b), (b,a) ] swaps a and b.  *)
   955 fun subst_atomic [] tm = tm
   956   | subst_atomic inst tm =
   957       let
   958         fun subst (Abs (a, T, body)) = Abs (a, T, subst body)
   959           | subst (t $ u) = subst t $ subst u
   960           | subst t = the_default t (AList.lookup (op aconv) inst t);
   961       in subst tm end;
   962 
   963 (*Replace the ATOMIC type Ti by Ui;    inst = [(T1,U1), ..., (Tn,Un)].*)
   964 fun typ_subst_atomic [] ty = ty
   965   | typ_subst_atomic inst ty =
   966       let
   967         fun subst (Type (a, Ts)) = Type (a, map subst Ts)
   968           | subst T = the_default T (AList.lookup (op = : typ * typ -> bool) inst T);
   969       in subst ty end;
   970 
   971 fun subst_atomic_types [] tm = tm
   972   | subst_atomic_types inst tm = map_types (typ_subst_atomic inst) tm;
   973 
   974 fun typ_subst_TVars [] ty = ty
   975   | typ_subst_TVars inst ty =
   976       let
   977         fun subst (Type (a, Ts)) = Type (a, map subst Ts)
   978           | subst (T as TVar (xi, _)) = the_default T (AList.lookup (op =) inst xi)
   979           | subst T = T;
   980       in subst ty end;
   981 
   982 fun subst_TVars [] tm = tm
   983   | subst_TVars inst tm = map_types (typ_subst_TVars inst) tm;
   984 
   985 fun subst_Vars [] tm = tm
   986   | subst_Vars inst tm =
   987       let
   988         fun subst (t as Var (xi, _)) = the_default t (AList.lookup (op =) inst xi)
   989           | subst (Abs (a, T, t)) = Abs (a, T, subst t)
   990           | subst (t $ u) = subst t $ subst u
   991           | subst t = t;
   992       in subst tm end;
   993 
   994 fun subst_vars ([], []) tm = tm
   995   | subst_vars ([], inst) tm = subst_Vars inst tm
   996   | subst_vars (instT, inst) tm =
   997       let
   998         fun subst (Const (a, T)) = Const (a, typ_subst_TVars instT T)
   999           | subst (Free (a, T)) = Free (a, typ_subst_TVars instT T)
  1000           | subst (t as Var (xi, T)) =
  1001               (case AList.lookup (op =) inst xi of
  1002                 NONE => Var (xi, typ_subst_TVars instT T)
  1003               | SOME t => t)
  1004           | subst (t as Bound _) = t
  1005           | subst (Abs (a, T, t)) = Abs (a, typ_subst_TVars instT T, subst t)
  1006           | subst (t $ u) = subst t $ subst u;
  1007       in subst tm end;
  1008 
  1009 fun close_schematic_term t =
  1010   let
  1011     val extra_types = map (fn v => Const ("TYPE", itselfT (TVar v))) (hidden_polymorphism t);
  1012     val extra_terms = map Var (rev (add_vars t []));
  1013   in fold_rev lambda (extra_types @ extra_terms) t end;
  1014 
  1015 
  1016 
  1017 (** Identifying first-order terms **)
  1018 
  1019 (*Differs from proofterm/is_fun in its treatment of TVar*)
  1020 fun is_funtype (Type("fun",[_,_])) = true
  1021   | is_funtype _ = false;
  1022 
  1023 (*Argument Ts is a reverse list of binder types, needed if term t contains Bound vars*)
  1024 fun has_not_funtype Ts t = not (is_funtype (fastype_of1 (Ts,t)));
  1025 
  1026 (*First order means in all terms of the form f(t1,...,tn) no argument has a
  1027   function type. The supplied quantifiers are excluded: their argument always
  1028   has a function type through a recursive call into its body.*)
  1029 fun is_first_order quants =
  1030   let fun first_order1 Ts (Abs (_,T,body)) = first_order1 (T::Ts) body
  1031         | first_order1 Ts (Const(q,_) $ Abs(a,T,body)) =
  1032             member (op =) quants q  andalso   (*it is a known quantifier*)
  1033             not (is_funtype T)   andalso first_order1 (T::Ts) body
  1034         | first_order1 Ts t =
  1035             case strip_comb t of
  1036                  (Var _, ts) => forall (first_order1 Ts andf has_not_funtype Ts) ts
  1037                | (Free _, ts) => forall (first_order1 Ts andf has_not_funtype Ts) ts
  1038                | (Const _, ts) => forall (first_order1 Ts andf has_not_funtype Ts) ts
  1039                | (Bound _, ts) => forall (first_order1 Ts andf has_not_funtype Ts) ts
  1040                | (Abs _, ts) => false (*not in beta-normal form*)
  1041                | _ => error "first_order: unexpected case"
  1042     in  first_order1 []  end;
  1043 
  1044 
  1045 (* maximum index of typs and terms *)
  1046 
  1047 fun maxidx_typ (TVar ((_, j), _)) i = Int.max (i, j)
  1048   | maxidx_typ (Type (_, Ts)) i = maxidx_typs Ts i
  1049   | maxidx_typ (TFree _) i = i
  1050 and maxidx_typs [] i = i
  1051   | maxidx_typs (T :: Ts) i = maxidx_typs Ts (maxidx_typ T i);
  1052 
  1053 fun maxidx_term (Var ((_, j), T)) i = maxidx_typ T (Int.max (i, j))
  1054   | maxidx_term (Const (_, T)) i = maxidx_typ T i
  1055   | maxidx_term (Free (_, T)) i = maxidx_typ T i
  1056   | maxidx_term (Bound _) i = i
  1057   | maxidx_term (Abs (_, T, t)) i = maxidx_term t (maxidx_typ T i)
  1058   | maxidx_term (t $ u) i = maxidx_term u (maxidx_term t i);
  1059 
  1060 fun maxidx_of_typ T = maxidx_typ T ~1;
  1061 fun maxidx_of_typs Ts = maxidx_typs Ts ~1;
  1062 fun maxidx_of_term t = maxidx_term t ~1;
  1063 
  1064 
  1065 
  1066 (**** Syntax-related declarations ****)
  1067 
  1068 (* substructure *)
  1069 
  1070 fun exists_subtype P =
  1071   let
  1072     fun ex ty = P ty orelse
  1073       (case ty of Type (_, Ts) => exists ex Ts | _ => false);
  1074   in ex end;
  1075 
  1076 fun exists_type P =
  1077   let
  1078     fun ex (Const (_, T)) = P T
  1079       | ex (Free (_, T)) = P T
  1080       | ex (Var (_, T)) = P T
  1081       | ex (Bound _) = false
  1082       | ex (Abs (_, T, t)) = P T orelse ex t
  1083       | ex (t $ u) = ex t orelse ex u;
  1084   in ex end;
  1085 
  1086 fun exists_subterm P =
  1087   let
  1088     fun ex tm = P tm orelse
  1089       (case tm of
  1090         t $ u => ex t orelse ex u
  1091       | Abs (_, _, t) => ex t
  1092       | _ => false);
  1093   in ex end;
  1094 
  1095 fun has_abs (Abs _) = true
  1096   | has_abs (t $ u) = has_abs t orelse has_abs u
  1097   | has_abs _ = false;
  1098 
  1099 
  1100 
  1101 (** Consts etc. **)
  1102 
  1103 fun add_term_consts (Const (c, _), cs) = insert (op =) c cs
  1104   | add_term_consts (t $ u, cs) = add_term_consts (t, add_term_consts (u, cs))
  1105   | add_term_consts (Abs (_, _, t), cs) = add_term_consts (t, cs)
  1106   | add_term_consts (_, cs) = cs;
  1107 
  1108 fun term_consts t = add_term_consts(t,[]);
  1109 
  1110 fun exists_Const P = exists_subterm (fn Const c => P c | _ => false);
  1111 
  1112 
  1113 (** TFrees and TVars **)
  1114 
  1115 (*Accumulates the names of Frees in the term, suppressing duplicates.*)
  1116 fun add_term_free_names (Free(a,_), bs) = insert (op =) a bs
  1117   | add_term_free_names (f$u, bs) = add_term_free_names (f, add_term_free_names(u, bs))
  1118   | add_term_free_names (Abs(_,_,t), bs) = add_term_free_names(t,bs)
  1119   | add_term_free_names (_, bs) = bs;
  1120 
  1121 (*Accumulates the names in the term, suppressing duplicates.
  1122   Includes Frees and Consts.  For choosing unambiguous bound var names.*)
  1123 fun add_term_names (Const(a,_), bs) = insert (op =) (NameSpace.base a) bs
  1124   | add_term_names (Free(a,_), bs) = insert (op =) a bs
  1125   | add_term_names (f$u, bs) = add_term_names (f, add_term_names(u, bs))
  1126   | add_term_names (Abs(_,_,t), bs) = add_term_names(t,bs)
  1127   | add_term_names (_, bs) = bs;
  1128 
  1129 (*Accumulates the TVars in a type, suppressing duplicates. *)
  1130 fun add_typ_tvars(Type(_,Ts),vs) = List.foldr add_typ_tvars vs Ts
  1131   | add_typ_tvars(TFree(_),vs) = vs
  1132   | add_typ_tvars(TVar(v),vs) = insert (op =) v vs;
  1133 
  1134 (*Accumulates the TFrees in a type, suppressing duplicates. *)
  1135 fun add_typ_tfree_names(Type(_,Ts),fs) = List.foldr add_typ_tfree_names fs Ts
  1136   | add_typ_tfree_names(TFree(f,_),fs) = insert (op =) f fs
  1137   | add_typ_tfree_names(TVar(_),fs) = fs;
  1138 
  1139 fun add_typ_tfrees(Type(_,Ts),fs) = List.foldr add_typ_tfrees fs Ts
  1140   | add_typ_tfrees(TFree(f),fs) = insert (op =) f fs
  1141   | add_typ_tfrees(TVar(_),fs) = fs;
  1142 
  1143 fun add_typ_varnames(Type(_,Ts),nms) = List.foldr add_typ_varnames nms Ts
  1144   | add_typ_varnames(TFree(nm,_),nms) = insert (op =) nm nms
  1145   | add_typ_varnames(TVar((nm,_),_),nms) = insert (op =) nm nms;
  1146 
  1147 (*Accumulates the TVars in a term, suppressing duplicates. *)
  1148 val add_term_tvars = it_term_types add_typ_tvars;
  1149 
  1150 (*Accumulates the TFrees in a term, suppressing duplicates. *)
  1151 val add_term_tfrees = it_term_types add_typ_tfrees;
  1152 val add_term_tfree_names = it_term_types add_typ_tfree_names;
  1153 
  1154 (*Non-list versions*)
  1155 fun typ_tfrees T = add_typ_tfrees(T,[]);
  1156 fun typ_tvars T = add_typ_tvars(T,[]);
  1157 fun term_tfrees t = add_term_tfrees(t,[]);
  1158 fun term_tvars t = add_term_tvars(t,[]);
  1159 
  1160 (*special code to enforce left-to-right collection of TVar-indexnames*)
  1161 
  1162 fun add_typ_ixns(ixns,Type(_,Ts)) = Library.foldl add_typ_ixns (ixns,Ts)
  1163   | add_typ_ixns(ixns,TVar(ixn,_)) = if member (op =) ixns ixn then ixns
  1164                                      else ixns@[ixn]
  1165   | add_typ_ixns(ixns,TFree(_)) = ixns;
  1166 
  1167 fun add_term_tvar_ixns(Const(_,T),ixns) = add_typ_ixns(ixns,T)
  1168   | add_term_tvar_ixns(Free(_,T),ixns) = add_typ_ixns(ixns,T)
  1169   | add_term_tvar_ixns(Var(_,T),ixns) = add_typ_ixns(ixns,T)
  1170   | add_term_tvar_ixns(Bound _,ixns) = ixns
  1171   | add_term_tvar_ixns(Abs(_,T,t),ixns) =
  1172       add_term_tvar_ixns(t,add_typ_ixns(ixns,T))
  1173   | add_term_tvar_ixns(f$t,ixns) =
  1174       add_term_tvar_ixns(t,add_term_tvar_ixns(f,ixns));
  1175 
  1176 
  1177 (** Frees and Vars **)
  1178 
  1179 (*Accumulates the Vars in the term, suppressing duplicates*)
  1180 fun add_term_vars (t, vars: term list) = case t of
  1181     Var   _ => OrdList.insert term_ord t vars
  1182   | Abs (_,_,body) => add_term_vars(body,vars)
  1183   | f$t =>  add_term_vars (f, add_term_vars(t, vars))
  1184   | _ => vars;
  1185 
  1186 fun term_vars t = add_term_vars(t,[]);
  1187 
  1188 (*Accumulates the Frees in the term, suppressing duplicates*)
  1189 fun add_term_frees (t, frees: term list) = case t of
  1190     Free   _ => OrdList.insert term_ord t frees
  1191   | Abs (_,_,body) => add_term_frees(body,frees)
  1192   | f$t =>  add_term_frees (f, add_term_frees(t, frees))
  1193   | _ => frees;
  1194 
  1195 fun term_frees t = add_term_frees(t,[]);
  1196 
  1197 
  1198 (* dest abstraction *)
  1199 
  1200 fun dest_abs (x, T, body) =
  1201   let
  1202     fun name_clash (Free (y, _)) = (x = y)
  1203       | name_clash (t $ u) = name_clash t orelse name_clash u
  1204       | name_clash (Abs (_, _, t)) = name_clash t
  1205       | name_clash _ = false;
  1206   in
  1207     if name_clash body then
  1208       dest_abs (Name.variant [x] x, T, body)    (*potentially slow, but rarely happens*)
  1209     else (x, subst_bound (Free (x, T), body))
  1210   end;
  1211 
  1212 
  1213 (* renaming variables *)
  1214 
  1215 val declare_typ_names = fold_atyps (fn TFree (a, _) => Name.declare a | _ => I);
  1216 
  1217 fun declare_term_names tm =
  1218   fold_aterms
  1219     (fn Const (a, _) => Name.declare (NameSpace.base a)
  1220       | Free (a, _) => Name.declare a
  1221       | _ => I) tm #>
  1222   fold_types declare_typ_names tm;
  1223 
  1224 fun variant_frees t frees =
  1225   fst (Name.variants (map fst frees) (declare_term_names t Name.context)) ~~ map snd frees;
  1226 
  1227 fun rename_wrt_term t frees = rev (variant_frees t frees);  (*reversed result!*)
  1228 
  1229 
  1230 (* dummy patterns *)
  1231 
  1232 val dummy_patternN = "dummy_pattern";
  1233 
  1234 fun dummy_pattern T = Const (dummy_patternN, T);
  1235 
  1236 fun is_dummy_pattern (Const ("dummy_pattern", _)) = true
  1237   | is_dummy_pattern _ = false;
  1238 
  1239 fun no_dummy_patterns tm =
  1240   if not (fold_aterms (fn t => fn b => b orelse is_dummy_pattern t) tm false) then tm
  1241   else raise TERM ("Illegal occurrence of '_' dummy pattern", [tm]);
  1242 
  1243 fun free_dummy_patterns (Const ("dummy_pattern", T)) used =
  1244       let val [x] = Name.invents used Name.uu 1
  1245       in (Free (Name.internal x, T), Name.declare x used) end
  1246   | free_dummy_patterns (Abs (x, T, b)) used =
  1247       let val (b', used') = free_dummy_patterns b used
  1248       in (Abs (x, T, b'), used') end
  1249   | free_dummy_patterns (t $ u) used =
  1250       let
  1251         val (t', used') = free_dummy_patterns t used;
  1252         val (u', used'') = free_dummy_patterns u used';
  1253       in (t' $ u', used'') end
  1254   | free_dummy_patterns a used = (a, used);
  1255 
  1256 fun replace_dummy Ts (Const ("dummy_pattern", T)) i =
  1257       (list_comb (Var (("_dummy_", i), Ts ---> T), map Bound (0 upto length Ts - 1)), i + 1)
  1258   | replace_dummy Ts (Abs (x, T, t)) i =
  1259       let val (t', i') = replace_dummy (T :: Ts) t i
  1260       in (Abs (x, T, t'), i') end
  1261   | replace_dummy Ts (t $ u) i =
  1262       let
  1263         val (t', i') = replace_dummy Ts t i;
  1264         val (u', i'') = replace_dummy Ts u i';
  1265       in (t' $ u', i'') end
  1266   | replace_dummy _ a i = (a, i);
  1267 
  1268 val replace_dummy_patterns = replace_dummy [];
  1269 
  1270 fun is_replaced_dummy_pattern ("_dummy_", _) = true
  1271   | is_replaced_dummy_pattern _ = false;
  1272 
  1273 fun show_dummy_patterns (Var (("_dummy_", _), T)) = Const ("dummy_pattern", T)
  1274   | show_dummy_patterns (t $ u) = show_dummy_patterns t $ show_dummy_patterns u
  1275   | show_dummy_patterns (Abs (x, T, t)) = Abs (x, T, show_dummy_patterns t)
  1276   | show_dummy_patterns a = a;
  1277 
  1278 
  1279 (* display variables *)
  1280 
  1281 val show_question_marks = ref true;
  1282 
  1283 fun string_of_vname (x, i) =
  1284   let
  1285     val question_mark = if ! show_question_marks then "?" else "";
  1286     val idx = string_of_int i;
  1287     val dot =
  1288       (case rev (Symbol.explode x) of
  1289         _ :: "\\<^isub>" :: _ => false
  1290       | _ :: "\\<^isup>" :: _ => false
  1291       | c :: _ => Symbol.is_digit c
  1292       | _ => true);
  1293   in
  1294     if dot then question_mark ^ x ^ "." ^ idx
  1295     else if i <> 0 then question_mark ^ x ^ idx
  1296     else question_mark ^ x
  1297   end;
  1298 
  1299 fun string_of_vname' (x, ~1) = x
  1300   | string_of_vname' xi = string_of_vname xi;
  1301 
  1302 end;
  1303 
  1304 structure BasicTerm: BASIC_TERM = Term;
  1305 open BasicTerm;