src/HOL/Tools/datatype_package.ML
author wenzelm
Sat Dec 01 18:52:32 2001 +0100 (2001-12-01)
changeset 12338 de0f4a63baa5
parent 12311 ce5f9e61c037
child 12448 473cb9f9e237
permissions -rw-r--r--
renamed class "term" to "type" (actually "HOL.type");
     1 (*  Title:      HOL/Tools/datatype_package.ML
     2     ID:         $Id$
     3     Author:     Stefan Berghofer, TU Muenchen
     4     License:    GPL (GNU GENERAL PUBLIC LICENSE)
     5 
     6 Datatype package for Isabelle/HOL.
     7 *)
     8 
     9 signature BASIC_DATATYPE_PACKAGE =
    10 sig
    11   val induct_tac : string -> int -> tactic
    12   val induct_thm_tac : thm -> string -> int -> tactic
    13   val case_tac : string -> int -> tactic
    14   val distinct_simproc : simproc
    15 end;
    16 
    17 signature DATATYPE_PACKAGE =
    18 sig
    19   include BASIC_DATATYPE_PACKAGE
    20   val quiet_mode : bool ref
    21   val add_datatype : bool -> string list -> (string list * bstring * mixfix *
    22     (bstring * string list * mixfix) list) list -> theory -> theory *
    23       {distinct : thm list list,
    24        inject : thm list list,
    25        exhaustion : thm list,
    26        rec_thms : thm list,
    27        case_thms : thm list list,
    28        split_thms : (thm * thm) list,
    29        induction : thm,
    30        size : thm list,
    31        simps : thm list}
    32   val add_datatype_i : bool -> string list -> (string list * bstring * mixfix *
    33     (bstring * typ list * mixfix) list) list -> theory -> theory *
    34       {distinct : thm list list,
    35        inject : thm list list,
    36        exhaustion : thm list,
    37        rec_thms : thm list,
    38        case_thms : thm list list,
    39        split_thms : (thm * thm) list,
    40        induction : thm,
    41        size : thm list,
    42        simps : thm list}
    43   val rep_datatype_i : string list option -> (thm * theory attribute list) list list ->
    44     (thm * theory attribute list) list list -> (thm * theory attribute list) -> theory -> theory *
    45       {distinct : thm list list,
    46        inject : thm list list,
    47        exhaustion : thm list,
    48        rec_thms : thm list,
    49        case_thms : thm list list,
    50        split_thms : (thm * thm) list,
    51        induction : thm,
    52        size : thm list,
    53        simps : thm list}
    54   val rep_datatype : string list option -> (xstring * Args.src list) list list ->
    55     (xstring * Args.src list) list list -> xstring * Args.src list -> theory -> theory *
    56       {distinct : thm list list,
    57        inject : thm list list,
    58        exhaustion : thm list,
    59        rec_thms : thm list,
    60        case_thms : thm list list,
    61        split_thms : (thm * thm) list,
    62        induction : thm,
    63        size : thm list,
    64        simps : thm list}
    65   val get_datatypes : theory -> DatatypeAux.datatype_info Symtab.table
    66   val get_datatypes_sg : Sign.sg -> DatatypeAux.datatype_info Symtab.table
    67   val print_datatypes : theory -> unit
    68   val datatype_info_sg : Sign.sg -> string -> DatatypeAux.datatype_info option
    69   val datatype_info : theory -> string -> DatatypeAux.datatype_info option
    70   val datatype_info_sg_err : Sign.sg -> string -> DatatypeAux.datatype_info
    71   val datatype_info_err : theory -> string -> DatatypeAux.datatype_info
    72   val constrs_of : theory -> string -> term list option
    73   val constrs_of_sg : Sign.sg -> string -> term list option
    74   val case_const_of : theory -> string -> term option
    75   val weak_case_congs_of : theory -> thm list
    76   val weak_case_congs_of_sg : Sign.sg -> thm list
    77   val setup: (theory -> theory) list
    78 end;
    79 
    80 structure DatatypePackage : DATATYPE_PACKAGE =
    81 struct
    82 
    83 open DatatypeAux;
    84 
    85 val quiet_mode = quiet_mode;
    86 
    87 
    88 (* data kind 'HOL/datatypes' *)
    89 
    90 structure DatatypesArgs =
    91 struct
    92   val name = "HOL/datatypes";
    93   type T = datatype_info Symtab.table;
    94 
    95   val empty = Symtab.empty;
    96   val copy = I;
    97   val prep_ext = I;
    98   val merge: T * T -> T = Symtab.merge (K true);
    99 
   100   fun print sg tab =
   101     Pretty.writeln (Pretty.strs ("datatypes:" ::
   102       map #1 (Sign.cond_extern_table sg Sign.typeK tab)));
   103 end;
   104 
   105 structure DatatypesData = TheoryDataFun(DatatypesArgs);
   106 val get_datatypes_sg = DatatypesData.get_sg;
   107 val get_datatypes = DatatypesData.get;
   108 val put_datatypes = DatatypesData.put;
   109 val print_datatypes = DatatypesData.print;
   110 
   111 
   112 (** theory information about datatypes **)
   113 
   114 fun datatype_info_sg sg name = Symtab.lookup (get_datatypes_sg sg, name);
   115 
   116 fun datatype_info_sg_err sg name = (case datatype_info_sg sg name of
   117       Some info => info
   118     | None => error ("Unknown datatype " ^ quote name));
   119 
   120 val datatype_info = datatype_info_sg o Theory.sign_of;
   121 
   122 fun datatype_info_err thy name = (case datatype_info thy name of
   123       Some info => info
   124     | None => error ("Unknown datatype " ^ quote name));
   125 
   126 fun constrs_of_sg sg tname = (case datatype_info_sg sg tname of
   127    Some {index, descr, ...} =>
   128      let val (_, _, constrs) = the (assoc (descr, index))
   129      in Some (map (fn (cname, _) => Const (cname, the (Sign.const_type sg cname))) constrs)
   130      end
   131  | _ => None);
   132 
   133 val constrs_of = constrs_of_sg o Theory.sign_of;
   134 
   135 fun case_const_of thy tname = (case datatype_info thy tname of
   136    Some {case_name, ...} => Some (Const (case_name, the (Sign.const_type
   137      (Theory.sign_of thy) case_name)))
   138  | _ => None);
   139 
   140 val weak_case_congs_of_sg = map (#weak_case_cong o #2) o Symtab.dest o get_datatypes_sg;
   141 val weak_case_congs_of = weak_case_congs_of_sg o Theory.sign_of;
   142 
   143 fun find_tname var Bi =
   144   let val frees = map dest_Free (term_frees Bi)
   145       val params = Logic.strip_params Bi;
   146   in case assoc (frees @ params, var) of
   147        None => error ("No such variable in subgoal: " ^ quote var)
   148      | Some(Type (tn, _)) => tn
   149      | _ => error ("Cannot determine type of " ^ quote var)
   150   end;
   151 
   152 fun infer_tname state i aterm =
   153   let
   154     val sign = Thm.sign_of_thm state;
   155     val (_, _, Bi, _) = Thm.dest_state (state, i)
   156     val params = Logic.strip_params Bi;   (*params of subgoal i*)
   157     val params = rev (rename_wrt_term Bi params);   (*as they are printed*)
   158     val (types, sorts) = types_sorts state;
   159     fun types' (a, ~1) = (case assoc (params, a) of None => types(a, ~1) | sm => sm)
   160       | types' ixn = types ixn;
   161     val (ct, _) = read_def_cterm (sign, types', sorts) [] false (aterm, TypeInfer.logicT);
   162   in case #T (rep_cterm ct) of
   163        Type (tn, _) => tn
   164      | _ => error ("Cannot determine type of " ^ quote aterm)
   165   end;
   166 
   167 (*Warn if the (induction) variable occurs Free among the premises, which
   168   usually signals a mistake.  But calls the tactic either way!*)
   169 fun occs_in_prems tacf vars =
   170   SUBGOAL (fn (Bi, i) =>
   171            (if  exists (fn Free (a, _) => a mem vars)
   172                       (foldr add_term_frees (#2 (strip_context Bi), []))
   173              then warning "Induction variable occurs also among premises!"
   174              else ();
   175             tacf i));
   176 
   177 
   178 (* generic induction tactic for datatypes *)
   179 
   180 local
   181 
   182 fun prep_var (Var (ixn, _), Some x) = Some (implode (tl (explode (Syntax.string_of_vname ixn))), x)
   183   | prep_var _ = None;
   184 
   185 fun prep_inst (concl, xs) =	(*exception LIST*)
   186   let val vs = InductAttrib.vars_of concl
   187   in mapfilter prep_var (Library.drop (length vs - length xs, vs) ~~ xs) end;
   188 
   189 in
   190 
   191 fun gen_induct_tac (varss, opt_rule) i state =
   192   let
   193     val (_, _, Bi, _) = Thm.dest_state (state, i);
   194     val {sign, ...} = Thm.rep_thm state;
   195     val (rule, rule_name) =
   196       (case opt_rule of
   197         Some r => (r, "Induction rule")
   198       | None =>
   199           let val tn = find_tname (hd (mapfilter I (flat varss))) Bi
   200           in (#induction (datatype_info_sg_err sign tn), "Induction rule for type " ^ tn) end);
   201 
   202     val concls = HOLogic.dest_concls (Thm.concl_of rule);
   203     val insts = flat (map prep_inst (concls ~~ varss)) handle LIST _ =>
   204       error (rule_name ^ " has different numbers of variables");
   205   in occs_in_prems (Tactic.res_inst_tac insts rule) (map #2 insts) i state end;
   206 
   207 fun induct_tac s = gen_induct_tac (map (Library.single o Some) (Syntax.read_idents s), None);
   208 
   209 fun induct_thm_tac th s =
   210   gen_induct_tac ([map Some (Syntax.read_idents s)], Some th);
   211 
   212 end;
   213 
   214 
   215 (* generic case tactic for datatypes *)
   216 
   217 fun case_inst_tac t rule i state =
   218   let
   219     val _ $ Var (ixn, _) $ _ = HOLogic.dest_Trueprop
   220       (hd (Logic.strip_assums_hyp (hd (Thm.prems_of rule))));
   221     val exh_vname = implode (tl (explode (Syntax.string_of_vname ixn)));
   222   in Tactic.res_inst_tac [(exh_vname, t)] rule i state end;
   223 
   224 fun gen_case_tac (t, Some rule) i state = case_inst_tac t rule i state
   225   | gen_case_tac (t, None) i state =
   226       let val tn = infer_tname state i t in
   227         if tn = HOLogic.boolN then Tactic.res_inst_tac [("P", t)] case_split_thm i state
   228         else case_inst_tac t (#exhaustion (datatype_info_sg_err (Thm.sign_of_thm state) tn)) i state
   229       end;
   230 
   231 fun case_tac t = gen_case_tac (t, None);
   232 
   233 
   234 
   235 (** Isar tactic emulations **)
   236 
   237 local
   238 
   239 val rule_spec = Scan.lift (Args.$$$ "rule" -- Args.$$$ ":");
   240 val opt_rule = Scan.option (rule_spec |-- Attrib.local_thm);
   241 
   242 val varss = Args.and_list (Scan.repeat (Scan.unless rule_spec (Scan.lift Args.name_dummy)));
   243 
   244 in
   245 
   246 val tactic_emulations =
   247  [("induct_tac", Method.goal_args' (varss -- opt_rule) gen_induct_tac,
   248     "induct_tac emulation (dynamic instantiation!)"),
   249   ("case_tac", Method.goal_args' (Scan.lift Args.name -- opt_rule) gen_case_tac,
   250     "case_tac emulation (dynamic instantiation!)")];
   251 
   252 end;
   253 
   254 
   255 
   256 (** induct method setup **)
   257 
   258 (* case names *)
   259 
   260 local
   261 
   262 fun dt_recs (DtTFree _) = []
   263   | dt_recs (DtType (_, dts)) = flat (map dt_recs dts)
   264   | dt_recs (DtRec i) = [i];
   265 
   266 fun dt_cases (descr: descr) (_, args, constrs) =
   267   let
   268     fun the_bname i = Sign.base_name (#1 (the (assoc (descr, i))));
   269     val bnames = map the_bname (distinct (flat (map dt_recs args)));
   270   in map (fn (c, _) => space_implode "_" (Sign.base_name c :: bnames)) constrs end;
   271 
   272 
   273 fun induct_cases descr =
   274   DatatypeProp.indexify_names (flat (map (dt_cases descr) (map #2 descr)));
   275 
   276 fun exhaust_cases descr i = dt_cases descr (the (assoc (descr, i)));
   277 
   278 in
   279 
   280 fun mk_case_names_induct descr = RuleCases.case_names (induct_cases descr);
   281 
   282 fun mk_case_names_exhausts descr new =
   283   map (RuleCases.case_names o exhaust_cases descr o #1)
   284     (filter (fn ((_, (name, _, _))) => name mem_string new) descr);
   285 
   286 end;
   287 
   288 fun add_rules simps case_thms size_thms rec_thms inject distinct
   289                   weak_case_congs cong_att =
   290   (#1 o PureThy.add_thmss [(("simps", simps), []),
   291     (("", flat case_thms @ size_thms @ 
   292           flat distinct  @ rec_thms), [Simplifier.simp_add_global]),
   293     (("", flat inject),               [iff_add_global]),
   294     (("", flat distinct RL [notE]),   [Classical.safe_elim_global]),
   295     (("", weak_case_congs),           [cong_att])]);
   296 
   297 
   298 (* add_cases_induct *)
   299 
   300 fun add_cases_induct infos induction =
   301   let
   302     val n = length (HOLogic.dest_concls (Thm.concl_of induction));
   303     fun proj i thm =
   304       if n = 1 then thm
   305       else (if i + 1 < n then (fn th => th RS conjunct1) else I)
   306         (Library.funpow i (fn th => th RS conjunct2) thm)
   307         |> Drule.zero_var_indexes
   308         |> RuleCases.save thm;
   309 
   310     fun named_rules (name, {index, exhaustion, ...}: datatype_info) =
   311       [(("", proj index induction), [InductAttrib.induct_type_global name]),
   312        (("", exhaustion), [InductAttrib.cases_type_global name])];
   313     fun unnamed_rule i =
   314       (("", proj i induction), [InductAttrib.induct_type_global ""]);
   315     val rules = flat (map named_rules infos) @ map unnamed_rule (length infos upto n - 1);
   316   in #1 o PureThy.add_thms rules end;
   317 
   318 
   319 
   320 (**** simplification procedure for showing distinctness of constructors ****)
   321 
   322 fun stripT (i, Type ("fun", [_, T])) = stripT (i + 1, T)
   323   | stripT p = p;
   324 
   325 fun stripC (i, f $ x) = stripC (i + 1, f)
   326   | stripC p = p;
   327 
   328 val distinctN = "constr_distinct";
   329 
   330 exception ConstrDistinct of term;
   331 
   332 fun distinct_proc sg _ (t as Const ("op =", _) $ t1 $ t2) =
   333   (case (stripC (0, t1), stripC (0, t2)) of
   334      ((i, Const (cname1, T1)), (j, Const (cname2, T2))) =>
   335          (case (stripT (0, T1), stripT (0, T2)) of
   336             ((i', Type (tname1, _)), (j', Type (tname2, _))) =>
   337                 if tname1 = tname2 andalso not (cname1 = cname2) andalso i = i' andalso j = j' then
   338                    (case (constrs_of_sg sg tname1) of
   339                       Some constrs => let val cnames = map (fst o dest_Const) constrs
   340                         in if cname1 mem cnames andalso cname2 mem cnames then
   341                              let val eq_t = Logic.mk_equals (t, Const ("False", HOLogic.boolT));
   342                                  val eq_ct = cterm_of sg eq_t;
   343                                  val Datatype_thy = theory "Datatype";
   344                                  val [In0_inject, In1_inject, In0_not_In1, In1_not_In0] =
   345                                    map (get_thm Datatype_thy)
   346                                      ["In0_inject", "In1_inject", "In0_not_In1", "In1_not_In0"]
   347                              in (case (#distinct (datatype_info_sg_err sg tname1)) of
   348                                  QuickAndDirty => Some (Thm.invoke_oracle
   349                                    Datatype_thy distinctN (sg, ConstrDistinct eq_t))
   350                                | FewConstrs thms => Some (prove_goalw_cterm [] eq_ct (K
   351                                    [rtac eq_reflection 1, rtac iffI 1, rtac notE 1,
   352                                     atac 2, resolve_tac thms 1, etac FalseE 1]))
   353                                | ManyConstrs (thm, ss) => Some (prove_goalw_cterm [] eq_ct (K
   354                                    [rtac eq_reflection 1, rtac iffI 1, dtac thm 1,
   355                                     full_simp_tac ss 1,
   356                                     REPEAT (dresolve_tac [In0_inject, In1_inject] 1),
   357                                     eresolve_tac [In0_not_In1 RS notE, In1_not_In0 RS notE] 1,
   358                                     etac FalseE 1])))
   359                              end
   360                            else None
   361                         end
   362                     | None => None)
   363                 else None
   364           | _ => None)
   365    | _ => None)
   366   | distinct_proc sg _ _ = None;
   367 
   368 val distinct_pats = [HOLogic.read_cterm (Theory.sign_of HOL.thy) "s = t"];
   369 val distinct_simproc = mk_simproc distinctN distinct_pats distinct_proc;
   370 
   371 val dist_ss = HOL_ss addsimprocs [distinct_simproc];
   372 
   373 val simproc_setup =
   374   [Theory.add_oracle (distinctN, fn (_, ConstrDistinct t) => t),
   375    fn thy => (simpset_ref_of thy := simpset_of thy addsimprocs [distinct_simproc]; thy)];
   376 
   377 
   378 (* prepare types *)
   379 
   380 fun read_typ sign ((Ts, sorts), str) =
   381   let
   382     val T = Type.no_tvars (Sign.read_typ (sign, (curry assoc)
   383       (map (apfst (rpair ~1)) sorts)) str) handle TYPE (msg, _, _) => error msg
   384   in (Ts @ [T], add_typ_tfrees (T, sorts)) end;
   385 
   386 fun cert_typ sign ((Ts, sorts), raw_T) =
   387   let
   388     val T = Type.no_tvars (Sign.certify_typ sign raw_T) handle
   389       TYPE (msg, _, _) => error msg;
   390     val sorts' = add_typ_tfrees (T, sorts)
   391   in (Ts @ [T],
   392       case duplicates (map fst sorts') of
   393          [] => sorts'
   394        | dups => error ("Inconsistent sort constraints for " ^ commas dups))
   395   end;
   396 
   397 
   398 (**** make datatype info ****)
   399 
   400 fun make_dt_info descr induct reccomb_names rec_thms
   401     (((((((((i, (_, (tname, _, _))), case_name), case_thms),
   402       exhaustion_thm), distinct_thm), inject), nchotomy), case_cong), weak_case_cong) =
   403   (tname,
   404    {index = i,
   405     descr = descr,
   406     rec_names = reccomb_names,
   407     rec_rewrites = rec_thms,
   408     case_name = case_name,
   409     case_rewrites = case_thms,
   410     induction = induct,
   411     exhaustion = exhaustion_thm,
   412     distinct = distinct_thm,
   413     inject = inject,
   414     nchotomy = nchotomy,
   415     case_cong = case_cong,
   416     weak_case_cong = weak_case_cong});
   417 
   418 
   419 (********************* axiomatic introduction of datatypes ********************)
   420 
   421 fun add_and_get_axioms_atts label tnames attss ts thy =
   422   foldr (fn (((tname, atts), t), (thy', axs)) =>
   423     let
   424       val (thy'', [ax]) = thy' |>
   425         Theory.add_path tname |>
   426         PureThy.add_axioms_i [((label, t), atts)];
   427     in (Theory.parent_path thy'', ax::axs)
   428     end) (tnames ~~ attss ~~ ts, (thy, []));
   429 
   430 fun add_and_get_axioms label tnames =
   431   add_and_get_axioms_atts label tnames (replicate (length tnames) []);
   432 
   433 fun add_and_get_axiomss label tnames tss thy =
   434   foldr (fn ((tname, ts), (thy', axss)) =>
   435     let
   436       val (thy'', [axs]) = thy' |>
   437         Theory.add_path tname |>
   438         PureThy.add_axiomss_i [((label, ts), [])];
   439     in (Theory.parent_path thy'', axs::axss)
   440     end) (tnames ~~ tss, (thy, []));
   441 
   442 fun add_datatype_axm flat_names new_type_names descr sorts types_syntax constr_syntax dt_info
   443     case_names_induct case_names_exhausts thy =
   444   let
   445     val descr' = flat descr;
   446     val recTs = get_rec_types descr' sorts;
   447     val used = foldr add_typ_tfree_names (recTs, []);
   448     val newTs = take (length (hd descr), recTs);
   449 
   450     val no_size = exists (fn (_, (_, _, constrs)) => exists (fn (_, cargs) => exists
   451       (fn (DtType ("fun", [_, DtRec _])) => true | _ => false) cargs) constrs) descr';
   452 
   453     (**** declare new types and constants ****)
   454 
   455     val tyvars = map (fn (_, (_, Ts, _)) => map dest_DtTFree Ts) (hd descr);
   456 
   457     val constr_decls = map (fn (((_, (_, _, constrs)), T), constr_syntax') =>
   458       map (fn ((_, cargs), (cname, mx)) =>
   459         (cname, map (typ_of_dtyp descr' sorts) cargs ---> T, mx))
   460           (constrs ~~ constr_syntax')) ((hd descr) ~~ newTs ~~ constr_syntax);
   461 
   462     val rec_result_Ts = map TFree (variantlist (replicate (length descr') "'t", used) ~~
   463       replicate (length descr') HOLogic.typeS);
   464 
   465     val reccomb_fn_Ts = flat (map (fn (i, (_, _, constrs)) =>
   466       map (fn (_, cargs) =>
   467         let
   468           val Ts = map (typ_of_dtyp descr' sorts) cargs;
   469           val recs = filter (is_rec_type o fst) (cargs ~~ Ts);
   470 
   471           fun mk_argT (DtRec k, _) = nth_elem (k, rec_result_Ts)
   472             | mk_argT (DtType ("fun", [_, DtRec k]), Type ("fun", [T, _])) =
   473                T --> nth_elem (k, rec_result_Ts);
   474 
   475           val argTs = Ts @ map mk_argT recs
   476         in argTs ---> nth_elem (i, rec_result_Ts)
   477         end) constrs) descr');
   478 
   479     val big_reccomb_name = (space_implode "_" new_type_names) ^ "_rec";
   480     val reccomb_names = if length descr' = 1 then [big_reccomb_name] else
   481       (map ((curry (op ^) (big_reccomb_name ^ "_")) o string_of_int)
   482         (1 upto (length descr')));
   483 
   484     val size_names = DatatypeProp.indexify_names
   485       (map (fn T => name_of_typ T ^ "_size") (drop (length (hd descr), recTs)));
   486 
   487     val freeT = TFree (variant used "'t", HOLogic.typeS);
   488     val case_fn_Ts = map (fn (i, (_, _, constrs)) =>
   489       map (fn (_, cargs) =>
   490         let val Ts = map (typ_of_dtyp descr' sorts) cargs
   491         in Ts ---> freeT end) constrs) (hd descr);
   492 
   493     val case_names = map (fn s => (s ^ "_case")) new_type_names;
   494 
   495     val thy2' = thy |>
   496 
   497       (** new types **)
   498 
   499       curry (foldr (fn (((name, mx), tvs), thy') => thy' |>
   500           TypedefPackage.add_typedecls [(name, tvs, mx)]))
   501         (types_syntax ~~ tyvars) |>
   502       add_path flat_names (space_implode "_" new_type_names) |>
   503 
   504       (** primrec combinators **)
   505 
   506       Theory.add_consts_i (map (fn ((name, T), T') =>
   507         (name, reccomb_fn_Ts @ [T] ---> T', NoSyn))
   508           (reccomb_names ~~ recTs ~~ rec_result_Ts)) |>
   509 
   510       (** case combinators **)
   511 
   512       Theory.add_consts_i (map (fn ((name, T), Ts) =>
   513         (name, Ts @ [T] ---> freeT, NoSyn))
   514           (case_names ~~ newTs ~~ case_fn_Ts)) |>
   515       Theory.add_trrules_i (DatatypeProp.make_case_trrules new_type_names descr);
   516 
   517     val reccomb_names' = map (Sign.intern_const (Theory.sign_of thy2')) reccomb_names;
   518     val case_names' = map (Sign.intern_const (Theory.sign_of thy2')) case_names;
   519 
   520     val thy2 = thy2' |>
   521 
   522       (** size functions **)
   523 
   524       (if no_size then I else Theory.add_consts_i (map (fn (s, T) =>
   525         (Sign.base_name s, T --> HOLogic.natT, NoSyn))
   526           (size_names ~~ drop (length (hd descr), recTs)))) |>
   527 
   528       (** constructors **)
   529 
   530       parent_path flat_names |>
   531       curry (foldr (fn (((((_, (_, _, constrs)), T), tname),
   532         constr_syntax'), thy') => thy' |>
   533           add_path flat_names tname |>
   534             Theory.add_consts_i (map (fn ((_, cargs), (cname, mx)) =>
   535               (cname, map (typ_of_dtyp descr' sorts) cargs ---> T, mx))
   536                 (constrs ~~ constr_syntax')) |>
   537           parent_path flat_names))
   538             (hd descr ~~ newTs ~~ new_type_names ~~ constr_syntax);
   539 
   540     (**** introduction of axioms ****)
   541 
   542     val rec_axs = DatatypeProp.make_primrecs new_type_names descr sorts thy2;
   543     val size_axs = if no_size then [] else DatatypeProp.make_size descr sorts thy2;
   544 
   545     val (thy3, (([induct], [rec_thms]), inject)) =
   546       thy2 |>
   547       Theory.add_path (space_implode "_" new_type_names) |>
   548       PureThy.add_axioms_i [(("induct", DatatypeProp.make_ind descr sorts),
   549         [Drule.rule_attribute (K InductivePackage.rulify), case_names_induct])] |>>>
   550       PureThy.add_axiomss_i [(("recs", rec_axs), [])] |>>
   551       (if no_size then I else #1 o PureThy.add_axiomss_i [(("size", size_axs), [])]) |>>
   552       Theory.parent_path |>>>
   553       add_and_get_axiomss "inject" new_type_names
   554         (DatatypeProp.make_injs descr sorts);
   555     val size_thms = if no_size then [] else get_thms thy3 "size";
   556     val (thy4, distinct) = add_and_get_axiomss "distinct" new_type_names
   557       (DatatypeProp.make_distincts new_type_names descr sorts thy3) thy3;
   558 
   559     val exhaust_ts = DatatypeProp.make_casedists descr sorts;
   560     val (thy5, exhaustion) = add_and_get_axioms_atts "exhaust" new_type_names
   561       (map Library.single case_names_exhausts) exhaust_ts thy4;
   562     val (thy6, case_thms) = add_and_get_axiomss "cases" new_type_names
   563       (DatatypeProp.make_cases new_type_names descr sorts thy5) thy5;
   564     val (split_ts, split_asm_ts) = ListPair.unzip
   565       (DatatypeProp.make_splits new_type_names descr sorts thy6);
   566     val (thy7, split) = add_and_get_axioms "split" new_type_names split_ts thy6;
   567     val (thy8, split_asm) = add_and_get_axioms "split_asm" new_type_names
   568       split_asm_ts thy7;
   569     val (thy9, nchotomys) = add_and_get_axioms "nchotomy" new_type_names
   570       (DatatypeProp.make_nchotomys descr sorts) thy8;
   571     val (thy10, case_congs) = add_and_get_axioms "case_cong" new_type_names
   572       (DatatypeProp.make_case_congs new_type_names descr sorts thy9) thy9;
   573     val (thy11, weak_case_congs) = add_and_get_axioms "weak_case_cong" new_type_names
   574       (DatatypeProp.make_weak_case_congs new_type_names descr sorts thy10) thy10;
   575 
   576     val dt_infos = map (make_dt_info descr' induct reccomb_names' rec_thms)
   577       ((0 upto length (hd descr) - 1) ~~ (hd descr) ~~ case_names' ~~ case_thms ~~
   578         exhaustion ~~ replicate (length (hd descr)) QuickAndDirty ~~ inject ~~
   579           nchotomys ~~ case_congs ~~ weak_case_congs);
   580 
   581     val simps = flat (distinct @ inject @ case_thms) @ size_thms @ rec_thms;
   582     val split_thms = split ~~ split_asm;
   583 
   584     val thy12 = thy11 |>
   585       Theory.add_path (space_implode "_" new_type_names) |>
   586       add_rules simps case_thms size_thms rec_thms inject distinct
   587                 weak_case_congs Simplifier.cong_add_global |> 
   588       put_datatypes (foldr Symtab.update (dt_infos, dt_info)) |>
   589       add_cases_induct dt_infos induct |>
   590       Theory.parent_path |>
   591       (#1 o store_thmss "splits" new_type_names (map (fn (x, y) => [x, y]) split_thms));
   592   in
   593     (thy12,
   594      {distinct = distinct,
   595       inject = inject,
   596       exhaustion = exhaustion,
   597       rec_thms = rec_thms,
   598       case_thms = case_thms,
   599       split_thms = split_thms,
   600       induction = induct,
   601       size = size_thms,
   602       simps = simps})
   603   end;
   604 
   605 
   606 (******************* definitional introduction of datatypes *******************)
   607 
   608 fun add_datatype_def flat_names new_type_names descr sorts types_syntax constr_syntax dt_info
   609     case_names_induct case_names_exhausts thy =
   610   let
   611     val _ = message ("Proofs for datatype(s) " ^ commas_quote new_type_names);
   612 
   613     val (thy2, inject, distinct, dist_rewrites, simproc_dists, induct) = thy |>
   614       DatatypeRepProofs.representation_proofs flat_names dt_info new_type_names descr sorts
   615         types_syntax constr_syntax case_names_induct;
   616 
   617     val (thy3, casedist_thms) = DatatypeAbsProofs.prove_casedist_thms new_type_names descr
   618       sorts induct case_names_exhausts thy2;
   619     val (thy4, (reccomb_names, rec_thms)) = DatatypeAbsProofs.prove_primrec_thms
   620       flat_names new_type_names descr sorts dt_info inject dist_rewrites dist_ss induct thy3;
   621     val (thy6, (case_thms, case_names)) = DatatypeAbsProofs.prove_case_thms
   622       flat_names new_type_names descr sorts reccomb_names rec_thms thy4;
   623     val (thy7, split_thms) = DatatypeAbsProofs.prove_split_thms new_type_names
   624       descr sorts inject dist_rewrites casedist_thms case_thms thy6;
   625     val (thy8, nchotomys) = DatatypeAbsProofs.prove_nchotomys new_type_names
   626       descr sorts casedist_thms thy7;
   627     val (thy9, case_congs) = DatatypeAbsProofs.prove_case_congs new_type_names
   628       descr sorts nchotomys case_thms thy8;
   629     val (thy10, weak_case_congs) = DatatypeAbsProofs.prove_weak_case_congs new_type_names
   630       descr sorts thy9;
   631     val (thy11, size_thms) = DatatypeAbsProofs.prove_size_thms flat_names new_type_names
   632       descr sorts reccomb_names rec_thms thy10;
   633 
   634     val dt_infos = map (make_dt_info (flat descr) induct reccomb_names rec_thms)
   635       ((0 upto length (hd descr) - 1) ~~ (hd descr) ~~ case_names ~~ case_thms ~~
   636         casedist_thms ~~ simproc_dists ~~ inject ~~ nchotomys ~~ case_congs ~~ weak_case_congs);
   637 
   638     val simps = flat (distinct @ inject @ case_thms) @ size_thms @ rec_thms;
   639 
   640     val thy12 = thy11 |>
   641       Theory.add_path (space_implode "_" new_type_names) |>
   642       add_rules simps case_thms size_thms rec_thms inject distinct
   643                 weak_case_congs (Simplifier.change_global_ss (op addcongs)) |> 
   644       put_datatypes (foldr Symtab.update (dt_infos, dt_info)) |>
   645       add_cases_induct dt_infos induct |>
   646       Theory.parent_path |>
   647       (#1 o store_thmss "splits" new_type_names (map (fn (x, y) => [x, y]) split_thms));
   648   in
   649     (thy12,
   650      {distinct = distinct,
   651       inject = inject,
   652       exhaustion = casedist_thms,
   653       rec_thms = rec_thms,
   654       case_thms = case_thms,
   655       split_thms = split_thms,
   656       induction = induct,
   657       size = size_thms,
   658       simps = simps})
   659   end;
   660 
   661 
   662 (*********************** declare existing type as datatype *********************)
   663 
   664 fun gen_rep_datatype apply_theorems alt_names raw_distinct raw_inject raw_induction thy0 =
   665   let
   666     fun app_thmss srcs thy = foldl_map (fn (thy, x) => apply_theorems x thy) (thy, srcs);
   667     fun app_thm src thy = apsnd Library.hd (apply_theorems [src] thy);
   668 
   669     val (((thy1, induction), inject), distinct) = thy0
   670       |> app_thmss raw_distinct
   671       |> apfst (app_thmss raw_inject)
   672       |> apfst (apfst (app_thm raw_induction));
   673     val sign = Theory.sign_of thy1;
   674 
   675     val induction' = freezeT induction;
   676 
   677     fun err t = error ("Ill-formed predicate in induction rule: " ^
   678       Sign.string_of_term sign t);
   679 
   680     fun get_typ (t as _ $ Var (_, Type (tname, Ts))) =
   681           ((tname, map dest_TFree Ts) handle TERM _ => err t)
   682       | get_typ t = err t;
   683 
   684     val dtnames = map get_typ (HOLogic.dest_conj (HOLogic.dest_Trueprop (Thm.concl_of induction')));
   685     val new_type_names = if_none alt_names (map fst dtnames);
   686 
   687     fun get_constr t = (case Logic.strip_assums_concl t of
   688         _ $ (_ $ t') => (case head_of t' of
   689             Const (cname, cT) => (case strip_type cT of
   690                 (Ts, Type (tname, _)) => (tname, (cname, map (dtyp_of_typ dtnames) Ts))
   691               | _ => err t)
   692           | _ => err t)
   693       | _ => err t);
   694 
   695     fun make_dt_spec [] _ _ = []
   696       | make_dt_spec ((tname, tvs)::dtnames') i constrs =
   697           let val (constrs', constrs'') = take_prefix (equal tname o fst) constrs
   698           in (i, (tname, map DtTFree tvs, map snd constrs'))::
   699             (make_dt_spec dtnames' (i + 1) constrs'')
   700           end;
   701 
   702     val descr = make_dt_spec dtnames 0 (map get_constr (prems_of induction'));
   703     val sorts = add_term_tfrees (concl_of induction', []);
   704     val dt_info = get_datatypes thy1;
   705 
   706     val case_names_induct = mk_case_names_induct descr;
   707     val case_names_exhausts = mk_case_names_exhausts descr (map #1 dtnames);
   708     
   709 
   710     val _ = message ("Proofs for datatype(s) " ^ commas_quote new_type_names);
   711 
   712     val (thy2, casedist_thms) = thy1 |>
   713       DatatypeAbsProofs.prove_casedist_thms new_type_names [descr] sorts induction
   714         case_names_exhausts;
   715     val (thy3, (reccomb_names, rec_thms)) = DatatypeAbsProofs.prove_primrec_thms
   716       false new_type_names [descr] sorts dt_info inject distinct dist_ss induction thy2;
   717     val (thy4, (case_thms, case_names)) = DatatypeAbsProofs.prove_case_thms false
   718       new_type_names [descr] sorts reccomb_names rec_thms thy3;
   719     val (thy5, split_thms) = DatatypeAbsProofs.prove_split_thms
   720       new_type_names [descr] sorts inject distinct casedist_thms case_thms thy4;
   721     val (thy6, nchotomys) = DatatypeAbsProofs.prove_nchotomys new_type_names
   722       [descr] sorts casedist_thms thy5;
   723     val (thy7, case_congs) = DatatypeAbsProofs.prove_case_congs new_type_names
   724       [descr] sorts nchotomys case_thms thy6;
   725     val (thy8, weak_case_congs) = DatatypeAbsProofs.prove_weak_case_congs new_type_names
   726       [descr] sorts thy7;
   727     val (thy9, size_thms) =
   728       if Sign.exists_stamp "NatArith" (Theory.sign_of thy8) then
   729         DatatypeAbsProofs.prove_size_thms false new_type_names
   730           [descr] sorts reccomb_names rec_thms thy8
   731       else (thy8, []);
   732 
   733     val (thy10, [induction']) = thy9 |>
   734       (#1 o store_thmss "inject" new_type_names inject) |>
   735       (#1 o store_thmss "distinct" new_type_names distinct) |>
   736       Theory.add_path (space_implode "_" new_type_names) |>
   737       PureThy.add_thms [(("induct", induction), [case_names_induct])];
   738 
   739     val dt_infos = map (make_dt_info descr induction' reccomb_names rec_thms)
   740       ((0 upto length descr - 1) ~~ descr ~~ case_names ~~ case_thms ~~ casedist_thms ~~
   741         map FewConstrs distinct ~~ inject ~~ nchotomys ~~ case_congs ~~ weak_case_congs);
   742 
   743     val simps = flat (distinct @ inject @ case_thms) @ size_thms @ rec_thms;
   744 
   745     val thy11 = thy10 |>
   746       add_rules simps case_thms size_thms rec_thms inject distinct
   747                 weak_case_congs (Simplifier.change_global_ss (op addcongs)) |> 
   748       put_datatypes (foldr Symtab.update (dt_infos, dt_info)) |>
   749       add_cases_induct dt_infos induction' |>
   750       Theory.parent_path |>
   751       (#1 o store_thmss "splits" new_type_names (map (fn (x, y) => [x, y]) split_thms));
   752   in
   753     (thy11,
   754      {distinct = distinct,
   755       inject = inject,
   756       exhaustion = casedist_thms,
   757       rec_thms = rec_thms,
   758       case_thms = case_thms,
   759       split_thms = split_thms,
   760       induction = induction',
   761       size = size_thms,
   762       simps = simps})
   763   end;
   764 
   765 val rep_datatype = gen_rep_datatype IsarThy.apply_theorems;
   766 val rep_datatype_i = gen_rep_datatype IsarThy.apply_theorems_i;
   767 
   768 
   769 
   770 (******************************** add datatype ********************************)
   771 
   772 fun gen_add_datatype prep_typ flat_names new_type_names dts thy =
   773   let
   774     val _ = Theory.requires thy "Datatype" "datatype definitions";
   775 
   776     (* this theory is used just for parsing *)
   777 
   778     val tmp_thy = thy |>
   779       Theory.copy |>
   780       Theory.add_types (map (fn (tvs, tname, mx, _) =>
   781         (tname, length tvs, mx)) dts);
   782 
   783     val sign = Theory.sign_of tmp_thy;
   784 
   785     val (tyvars, _, _, _)::_ = dts;
   786     val (new_dts, types_syntax) = ListPair.unzip (map (fn (tvs, tname, mx, _) =>
   787       let val full_tname = Sign.full_name sign (Syntax.type_name tname mx)
   788       in (case duplicates tvs of
   789             [] => if eq_set (tyvars, tvs) then ((full_tname, tvs), (tname, mx))
   790                   else error ("Mutually recursive datatypes must have same type parameters")
   791           | dups => error ("Duplicate parameter(s) for datatype " ^ full_tname ^
   792               " : " ^ commas dups))
   793       end) dts);
   794 
   795     val _ = (case duplicates (map fst new_dts) @ duplicates new_type_names of
   796       [] => () | dups => error ("Duplicate datatypes: " ^ commas dups));
   797 
   798     fun prep_dt_spec ((dts', constr_syntax, sorts, i), (tvs, tname, mx, constrs)) =
   799       let
   800         fun prep_constr ((constrs, constr_syntax', sorts'), (cname, cargs, mx')) =
   801           let
   802             val (cargs', sorts'') = foldl (prep_typ sign) (([], sorts'), cargs);
   803             val _ = (case foldr add_typ_tfree_names (cargs', []) \\ tvs of
   804                 [] => ()
   805               | vs => error ("Extra type variables on rhs: " ^ commas vs))
   806           in (constrs @ [((if flat_names then Sign.full_name sign else
   807                 Sign.full_name_path sign tname) (Syntax.const_name cname mx'),
   808                    map (dtyp_of_typ new_dts) cargs')],
   809               constr_syntax' @ [(cname, mx')], sorts'')
   810           end handle ERROR =>
   811             error ("The error above occured in constructor " ^ cname ^
   812               " of datatype " ^ tname);
   813 
   814         val (constrs', constr_syntax', sorts') =
   815           foldl prep_constr (([], [], sorts), constrs)
   816 
   817       in
   818         case duplicates (map fst constrs') of
   819            [] =>
   820              (dts' @ [(i, (Sign.full_name sign (Syntax.type_name tname mx),
   821                 map DtTFree tvs, constrs'))],
   822               constr_syntax @ [constr_syntax'], sorts', i + 1)
   823          | dups => error ("Duplicate constructors " ^ commas dups ^
   824              " in datatype " ^ tname)
   825       end;
   826 
   827     val (dts', constr_syntax, sorts', i) = foldl prep_dt_spec (([], [], [], 0), dts);
   828     val sorts = sorts' @ (map (rpair (Sign.defaultS sign)) (tyvars \\ map fst sorts'));
   829     val dt_info = get_datatypes thy;
   830     val (descr, _) = unfold_datatypes sign dts' sorts dt_info dts' i;
   831     val _ = check_nonempty descr;
   832 
   833     val descr' = flat descr;
   834     val case_names_induct = mk_case_names_induct descr';
   835     val case_names_exhausts = mk_case_names_exhausts descr' (map #1 new_dts);
   836   in
   837     (if (!quick_and_dirty) then add_datatype_axm else add_datatype_def)
   838       flat_names new_type_names descr sorts types_syntax constr_syntax dt_info
   839       case_names_induct case_names_exhausts thy
   840   end;
   841 
   842 val add_datatype_i = gen_add_datatype cert_typ;
   843 val add_datatype = gen_add_datatype read_typ;
   844 
   845 
   846 (** package setup **)
   847 
   848 (* setup theory *)
   849 
   850 val setup = [DatatypesData.init, Method.add_methods tactic_emulations] @ simproc_setup;
   851 
   852 
   853 (* outer syntax *)
   854 
   855 local structure P = OuterParse and K = OuterSyntax.Keyword in
   856 
   857 val datatype_decl =
   858   Scan.option (P.$$$ "(" |-- P.name --| P.$$$ ")") -- P.type_args -- P.name -- P.opt_infix --
   859     (P.$$$ "=" |-- P.enum1 "|" (P.name -- Scan.repeat P.typ -- P.opt_mixfix --| P.marg_comment));
   860 
   861 fun mk_datatype args =
   862   let
   863     val names = map (fn ((((None, _), t), _), _) => t | ((((Some t, _), _), _), _) => t) args;
   864     val specs = map (fn ((((_, vs), t), mx), cons) => (vs, t, mx, map (fn ((x, y), z) => (x, y, z)) cons)) args;
   865   in #1 o add_datatype false names specs end;
   866 
   867 val datatypeP =
   868   OuterSyntax.command "datatype" "define inductive datatypes" K.thy_decl
   869     (P.and_list1 datatype_decl >> (Toplevel.theory o mk_datatype));
   870 
   871 
   872 val rep_datatype_decl =
   873   Scan.option (Scan.repeat1 P.name) --
   874     Scan.optional (P.$$$ "distinct" |-- P.!!! (P.and_list1 P.xthms1)) [[]] --
   875     Scan.optional (P.$$$ "inject" |-- P.!!! (P.and_list1 P.xthms1)) [[]] --
   876     (P.$$$ "induction" |-- P.!!! P.xthm);
   877 
   878 fun mk_rep_datatype (((opt_ts, dss), iss), ind) = #1 o rep_datatype opt_ts dss iss ind;
   879 
   880 val rep_datatypeP =
   881   OuterSyntax.command "rep_datatype" "represent existing types inductively" K.thy_decl
   882     (rep_datatype_decl >> (Toplevel.theory o mk_rep_datatype));
   883 
   884 
   885 val _ = OuterSyntax.add_keywords ["distinct", "inject", "induction"];
   886 val _ = OuterSyntax.add_parsers [datatypeP, rep_datatypeP];
   887 
   888 end;
   889 
   890 
   891 end;
   892 
   893 structure BasicDatatypePackage: BASIC_DATATYPE_PACKAGE = DatatypePackage;
   894 open BasicDatatypePackage;