src/HOL/Library/FuncSet.thy
author hoelzl
Fri Nov 16 18:45:57 2012 +0100 (2012-11-16)
changeset 50104 de19856feb54
parent 47761 dfe747e72fa8
child 50123 69b35a75caf3
permissions -rw-r--r--
move theorems to be more generally useable
     1 (*  Title:      HOL/Library/FuncSet.thy
     2     Author:     Florian Kammueller and Lawrence C Paulson, Lukas Bulwahn
     3 *)
     4 
     5 header {* Pi and Function Sets *}
     6 
     7 theory FuncSet
     8 imports Hilbert_Choice Main
     9 begin
    10 
    11 definition
    12   Pi :: "['a set, 'a => 'b set] => ('a => 'b) set" where
    13   "Pi A B = {f. \<forall>x. x \<in> A --> f x \<in> B x}"
    14 
    15 definition
    16   extensional :: "'a set => ('a => 'b) set" where
    17   "extensional A = {f. \<forall>x. x~:A --> f x = undefined}"
    18 
    19 definition
    20   "restrict" :: "['a => 'b, 'a set] => ('a => 'b)" where
    21   "restrict f A = (%x. if x \<in> A then f x else undefined)"
    22 
    23 abbreviation
    24   funcset :: "['a set, 'b set] => ('a => 'b) set"
    25     (infixr "->" 60) where
    26   "A -> B == Pi A (%_. B)"
    27 
    28 notation (xsymbols)
    29   funcset  (infixr "\<rightarrow>" 60)
    30 
    31 syntax
    32   "_Pi"  :: "[pttrn, 'a set, 'b set] => ('a => 'b) set"  ("(3PI _:_./ _)" 10)
    33   "_lam" :: "[pttrn, 'a set, 'a => 'b] => ('a=>'b)"  ("(3%_:_./ _)" [0,0,3] 3)
    34 
    35 syntax (xsymbols)
    36   "_Pi" :: "[pttrn, 'a set, 'b set] => ('a => 'b) set"  ("(3\<Pi> _\<in>_./ _)"   10)
    37   "_lam" :: "[pttrn, 'a set, 'a => 'b] => ('a=>'b)"  ("(3\<lambda>_\<in>_./ _)" [0,0,3] 3)
    38 
    39 syntax (HTML output)
    40   "_Pi" :: "[pttrn, 'a set, 'b set] => ('a => 'b) set"  ("(3\<Pi> _\<in>_./ _)"   10)
    41   "_lam" :: "[pttrn, 'a set, 'a => 'b] => ('a=>'b)"  ("(3\<lambda>_\<in>_./ _)" [0,0,3] 3)
    42 
    43 translations
    44   "PI x:A. B" == "CONST Pi A (%x. B)"
    45   "%x:A. f" == "CONST restrict (%x. f) A"
    46 
    47 definition
    48   "compose" :: "['a set, 'b => 'c, 'a => 'b] => ('a => 'c)" where
    49   "compose A g f = (\<lambda>x\<in>A. g (f x))"
    50 
    51 
    52 subsection{*Basic Properties of @{term Pi}*}
    53 
    54 lemma Pi_I[intro!]: "(!!x. x \<in> A ==> f x \<in> B x) ==> f \<in> Pi A B"
    55   by (simp add: Pi_def)
    56 
    57 lemma Pi_I'[simp]: "(!!x. x : A --> f x : B x) ==> f : Pi A B"
    58 by(simp add:Pi_def)
    59 
    60 lemma funcsetI: "(!!x. x \<in> A ==> f x \<in> B) ==> f \<in> A -> B"
    61   by (simp add: Pi_def)
    62 
    63 lemma Pi_mem: "[|f: Pi A B; x \<in> A|] ==> f x \<in> B x"
    64   by (simp add: Pi_def)
    65 
    66 lemma Pi_iff: "f \<in> Pi I X \<longleftrightarrow> (\<forall>i\<in>I. f i \<in> X i)"
    67   unfolding Pi_def by auto
    68 
    69 lemma PiE [elim]:
    70   "f : Pi A B ==> (f x : B x ==> Q) ==> (x ~: A ==> Q) ==> Q"
    71 by(auto simp: Pi_def)
    72 
    73 lemma Pi_cong:
    74   "(\<And> w. w \<in> A \<Longrightarrow> f w = g w) \<Longrightarrow> f \<in> Pi A B \<longleftrightarrow> g \<in> Pi A B"
    75   by (auto simp: Pi_def)
    76 
    77 lemma funcset_id [simp]: "(\<lambda>x. x) \<in> A \<rightarrow> A"
    78   by auto
    79 
    80 lemma funcset_mem: "[|f \<in> A -> B; x \<in> A|] ==> f x \<in> B"
    81   by (simp add: Pi_def)
    82 
    83 lemma funcset_image: "f \<in> A\<rightarrow>B ==> f ` A \<subseteq> B"
    84   by auto
    85 
    86 lemma image_subset_iff_funcset: "F ` A \<subseteq> B \<longleftrightarrow> F \<in> A \<rightarrow> B"
    87   by auto
    88 
    89 lemma Pi_eq_empty[simp]: "((PI x: A. B x) = {}) = (\<exists>x\<in>A. B(x) = {})"
    90 apply (simp add: Pi_def, auto)
    91 txt{*Converse direction requires Axiom of Choice to exhibit a function
    92 picking an element from each non-empty @{term "B x"}*}
    93 apply (drule_tac x = "%u. SOME y. y \<in> B u" in spec, auto)
    94 apply (cut_tac P= "%y. y \<in> B x" in some_eq_ex, auto)
    95 done
    96 
    97 lemma Pi_empty [simp]: "Pi {} B = UNIV"
    98 by (simp add: Pi_def)
    99 
   100 lemma Pi_UNIV [simp]: "A -> UNIV = UNIV"
   101 by (simp add: Pi_def)
   102 (*
   103 lemma funcset_id [simp]: "(%x. x): A -> A"
   104   by (simp add: Pi_def)
   105 *)
   106 text{*Covariance of Pi-sets in their second argument*}
   107 lemma Pi_mono: "(!!x. x \<in> A ==> B x <= C x) ==> Pi A B <= Pi A C"
   108 by auto
   109 
   110 text{*Contravariance of Pi-sets in their first argument*}
   111 lemma Pi_anti_mono: "A' <= A ==> Pi A B <= Pi A' B"
   112 by auto
   113 
   114 lemma prod_final:
   115   assumes 1: "fst \<circ> f \<in> Pi A B" and 2: "snd \<circ> f \<in> Pi A C"
   116   shows "f \<in> (\<Pi> z \<in> A. B z \<times> C z)"
   117 proof (rule Pi_I) 
   118   fix z
   119   assume z: "z \<in> A" 
   120   have "f z = (fst (f z), snd (f z))" 
   121     by simp
   122   also have "...  \<in> B z \<times> C z"
   123     by (metis SigmaI PiE o_apply 1 2 z) 
   124   finally show "f z \<in> B z \<times> C z" .
   125 qed
   126 
   127 
   128 subsection{*Composition With a Restricted Domain: @{term compose}*}
   129 
   130 lemma funcset_compose:
   131   "[| f \<in> A -> B; g \<in> B -> C |]==> compose A g f \<in> A -> C"
   132 by (simp add: Pi_def compose_def restrict_def)
   133 
   134 lemma compose_assoc:
   135     "[| f \<in> A -> B; g \<in> B -> C; h \<in> C -> D |]
   136       ==> compose A h (compose A g f) = compose A (compose B h g) f"
   137 by (simp add: fun_eq_iff Pi_def compose_def restrict_def)
   138 
   139 lemma compose_eq: "x \<in> A ==> compose A g f x = g(f(x))"
   140 by (simp add: compose_def restrict_def)
   141 
   142 lemma surj_compose: "[| f ` A = B; g ` B = C |] ==> compose A g f ` A = C"
   143   by (auto simp add: image_def compose_eq)
   144 
   145 
   146 subsection{*Bounded Abstraction: @{term restrict}*}
   147 
   148 lemma restrict_in_funcset: "(!!x. x \<in> A ==> f x \<in> B) ==> (\<lambda>x\<in>A. f x) \<in> A -> B"
   149   by (simp add: Pi_def restrict_def)
   150 
   151 lemma restrictI[intro!]: "(!!x. x \<in> A ==> f x \<in> B x) ==> (\<lambda>x\<in>A. f x) \<in> Pi A B"
   152   by (simp add: Pi_def restrict_def)
   153 
   154 lemma restrict_apply [simp]:
   155     "(\<lambda>y\<in>A. f y) x = (if x \<in> A then f x else undefined)"
   156   by (simp add: restrict_def)
   157 
   158 lemma restrict_ext:
   159     "(!!x. x \<in> A ==> f x = g x) ==> (\<lambda>x\<in>A. f x) = (\<lambda>x\<in>A. g x)"
   160   by (simp add: fun_eq_iff Pi_def restrict_def)
   161 
   162 lemma inj_on_restrict_eq [simp]: "inj_on (restrict f A) A = inj_on f A"
   163   by (simp add: inj_on_def restrict_def)
   164 
   165 lemma Id_compose:
   166     "[|f \<in> A -> B;  f \<in> extensional A|] ==> compose A (\<lambda>y\<in>B. y) f = f"
   167   by (auto simp add: fun_eq_iff compose_def extensional_def Pi_def)
   168 
   169 lemma compose_Id:
   170     "[|g \<in> A -> B;  g \<in> extensional A|] ==> compose A g (\<lambda>x\<in>A. x) = g"
   171   by (auto simp add: fun_eq_iff compose_def extensional_def Pi_def)
   172 
   173 lemma image_restrict_eq [simp]: "(restrict f A) ` A = f ` A"
   174   by (auto simp add: restrict_def)
   175 
   176 
   177 subsection{*Bijections Between Sets*}
   178 
   179 text{*The definition of @{const bij_betw} is in @{text "Fun.thy"}, but most of
   180 the theorems belong here, or need at least @{term Hilbert_Choice}.*}
   181 
   182 lemma bij_betwI:
   183 assumes "f \<in> A \<rightarrow> B" and "g \<in> B \<rightarrow> A"
   184     and g_f: "\<And>x. x\<in>A \<Longrightarrow> g (f x) = x" and f_g: "\<And>y. y\<in>B \<Longrightarrow> f (g y) = y"
   185 shows "bij_betw f A B"
   186 unfolding bij_betw_def
   187 proof
   188   show "inj_on f A" by (metis g_f inj_on_def)
   189 next
   190   have "f ` A \<subseteq> B" using `f \<in> A \<rightarrow> B` by auto
   191   moreover
   192   have "B \<subseteq> f ` A" by auto (metis Pi_mem `g \<in> B \<rightarrow> A` f_g image_iff)
   193   ultimately show "f ` A = B" by blast
   194 qed
   195 
   196 lemma bij_betw_imp_funcset: "bij_betw f A B \<Longrightarrow> f \<in> A \<rightarrow> B"
   197 by (auto simp add: bij_betw_def)
   198 
   199 lemma inj_on_compose:
   200   "[| bij_betw f A B; inj_on g B |] ==> inj_on (compose A g f) A"
   201 by (auto simp add: bij_betw_def inj_on_def compose_eq)
   202 
   203 lemma bij_betw_compose:
   204   "[| bij_betw f A B; bij_betw g B C |] ==> bij_betw (compose A g f) A C"
   205 apply (simp add: bij_betw_def compose_eq inj_on_compose)
   206 apply (auto simp add: compose_def image_def)
   207 done
   208 
   209 lemma bij_betw_restrict_eq [simp]:
   210   "bij_betw (restrict f A) A B = bij_betw f A B"
   211 by (simp add: bij_betw_def)
   212 
   213 
   214 subsection{*Extensionality*}
   215 
   216 lemma extensional_arb: "[|f \<in> extensional A; x\<notin> A|] ==> f x = undefined"
   217 by (simp add: extensional_def)
   218 
   219 lemma restrict_extensional [simp]: "restrict f A \<in> extensional A"
   220 by (simp add: restrict_def extensional_def)
   221 
   222 lemma compose_extensional [simp]: "compose A f g \<in> extensional A"
   223 by (simp add: compose_def)
   224 
   225 lemma extensionalityI:
   226   "[| f \<in> extensional A; g \<in> extensional A;
   227       !!x. x\<in>A ==> f x = g x |] ==> f = g"
   228 by (force simp add: fun_eq_iff extensional_def)
   229 
   230 lemma extensional_restrict:  "f \<in> extensional A \<Longrightarrow> restrict f A = f"
   231 by(rule extensionalityI[OF restrict_extensional]) auto
   232 
   233 lemma inv_into_funcset: "f ` A = B ==> (\<lambda>x\<in>B. inv_into A f x) : B -> A"
   234 by (unfold inv_into_def) (fast intro: someI2)
   235 
   236 lemma compose_inv_into_id:
   237   "bij_betw f A B ==> compose A (\<lambda>y\<in>B. inv_into A f y) f = (\<lambda>x\<in>A. x)"
   238 apply (simp add: bij_betw_def compose_def)
   239 apply (rule restrict_ext, auto)
   240 done
   241 
   242 lemma compose_id_inv_into:
   243   "f ` A = B ==> compose B f (\<lambda>y\<in>B. inv_into A f y) = (\<lambda>x\<in>B. x)"
   244 apply (simp add: compose_def)
   245 apply (rule restrict_ext)
   246 apply (simp add: f_inv_into_f)
   247 done
   248 
   249 
   250 subsection{*Cardinality*}
   251 
   252 lemma card_inj: "[|f \<in> A\<rightarrow>B; inj_on f A; finite B|] ==> card(A) \<le> card(B)"
   253 by (rule card_inj_on_le) auto
   254 
   255 lemma card_bij:
   256   "[|f \<in> A\<rightarrow>B; inj_on f A;
   257      g \<in> B\<rightarrow>A; inj_on g B; finite A; finite B|] ==> card(A) = card(B)"
   258 by (blast intro: card_inj order_antisym)
   259 
   260 subsection {* Extensional Function Spaces *} 
   261 
   262 definition extensional_funcset
   263 where "extensional_funcset S T = (S -> T) \<inter> (extensional S)"
   264 
   265 lemma extensional_empty[simp]: "extensional {} = {%x. undefined}"
   266 unfolding extensional_def by auto
   267 
   268 lemma extensional_funcset_empty_domain: "extensional_funcset {} T = {%x. undefined}"
   269 unfolding extensional_funcset_def by simp
   270 
   271 lemma extensional_funcset_empty_range:
   272   assumes "S \<noteq> {}"
   273   shows "extensional_funcset S {} = {}"
   274 using assms unfolding extensional_funcset_def by auto
   275 
   276 lemma extensional_funcset_arb:
   277   assumes "f \<in> extensional_funcset S T" "x \<notin> S"
   278   shows "f x = undefined"
   279 using assms
   280 unfolding extensional_funcset_def by auto (auto dest!: extensional_arb)
   281 
   282 lemma extensional_funcset_mem: "f \<in> extensional_funcset S T \<Longrightarrow> x \<in> S \<Longrightarrow> f x \<in> T"
   283 unfolding extensional_funcset_def by auto
   284 
   285 lemma extensional_subset: "f : extensional A ==> A <= B ==> f : extensional B"
   286 unfolding extensional_def by auto
   287 
   288 lemma extensional_funcset_extend_domainI: "\<lbrakk> y \<in> T; f \<in> extensional_funcset S T\<rbrakk> \<Longrightarrow> f(x := y) \<in> extensional_funcset (insert x S) T"
   289 unfolding extensional_funcset_def extensional_def by auto
   290 
   291 lemma extensional_funcset_restrict_domain:
   292   "x \<notin> S \<Longrightarrow> f \<in> extensional_funcset (insert x S) T \<Longrightarrow> f(x := undefined) \<in> extensional_funcset S T"
   293 unfolding extensional_funcset_def extensional_def by auto
   294 
   295 lemma extensional_funcset_extend_domain_eq:
   296   assumes "x \<notin> S"
   297   shows
   298     "extensional_funcset (insert x S) T = (\<lambda>(y, g). g(x := y)) ` {(y, g). y \<in> T \<and> g \<in> extensional_funcset S T}"
   299   using assms
   300 proof -
   301   {
   302     fix f
   303     assume "f : extensional_funcset (insert x S) T"
   304     from this assms have "f : (%(y, g). g(x := y)) ` (T <*> extensional_funcset S T)"
   305       unfolding image_iff
   306       apply (rule_tac x="(f x, f(x := undefined))" in bexI)
   307     apply (auto intro: extensional_funcset_extend_domainI extensional_funcset_restrict_domain extensional_funcset_mem) done 
   308   }
   309   moreover
   310   {
   311     fix f
   312     assume "f : (%(y, g). g(x := y)) ` (T <*> extensional_funcset S T)"
   313     from this assms have "f : extensional_funcset (insert x S) T"
   314       by (auto intro: extensional_funcset_extend_domainI)
   315   }
   316   ultimately show ?thesis by auto
   317 qed
   318 
   319 lemma extensional_funcset_fun_upd_restricts_rangeI:  "\<forall> y \<in> S. f x \<noteq> f y ==> f : extensional_funcset (insert x S) T ==> f(x := undefined) : extensional_funcset S (T - {f x})"
   320 unfolding extensional_funcset_def extensional_def
   321 apply auto
   322 apply (case_tac "x = xa")
   323 apply auto done
   324 
   325 lemma extensional_funcset_fun_upd_extends_rangeI:
   326   assumes "a \<in> T" "f : extensional_funcset S (T - {a})"
   327   shows "f(x := a) : extensional_funcset (insert x S) T"
   328   using assms unfolding extensional_funcset_def extensional_def by auto
   329 
   330 subsubsection {* Injective Extensional Function Spaces *}
   331 
   332 lemma extensional_funcset_fun_upd_inj_onI:
   333   assumes "f \<in> extensional_funcset S (T - {a})" "inj_on f S"
   334   shows "inj_on (f(x := a)) S"
   335   using assms unfolding extensional_funcset_def by (auto intro!: inj_on_fun_updI)
   336 
   337 lemma extensional_funcset_extend_domain_inj_on_eq:
   338   assumes "x \<notin> S"
   339   shows"{f. f \<in> extensional_funcset (insert x S) T \<and> inj_on f (insert x S)} =
   340     (%(y, g). g(x:=y)) ` {(y, g). y \<in> T \<and> g \<in> extensional_funcset S (T - {y}) \<and> inj_on g S}"
   341 proof -
   342   from assms show ?thesis
   343     apply auto
   344     apply (auto intro: extensional_funcset_fun_upd_inj_onI extensional_funcset_fun_upd_extends_rangeI)
   345     apply (auto simp add: image_iff inj_on_def)
   346     apply (rule_tac x="xa x" in exI)
   347     apply (auto intro: extensional_funcset_mem)
   348     apply (rule_tac x="xa(x := undefined)" in exI)
   349     apply (auto intro!: extensional_funcset_fun_upd_restricts_rangeI)
   350     apply (auto dest!: extensional_funcset_mem split: split_if_asm)
   351     done
   352 qed
   353 
   354 lemma extensional_funcset_extend_domain_inj_onI:
   355   assumes "x \<notin> S"
   356   shows "inj_on (\<lambda>(y, g). g(x := y)) {(y, g). y \<in> T \<and> g \<in> extensional_funcset S (T - {y}) \<and> inj_on g S}"
   357 proof -
   358   from assms show ?thesis
   359     apply (auto intro!: inj_onI)
   360     apply (metis fun_upd_same)
   361     by (metis assms extensional_funcset_arb fun_upd_triv fun_upd_upd)
   362 qed
   363   
   364 
   365 subsubsection {* Cardinality *}
   366 
   367 lemma card_extensional_funcset:
   368   assumes "finite S"
   369   shows "card (extensional_funcset S T) = (card T) ^ (card S)"
   370 using assms
   371 proof (induct rule: finite_induct)
   372   case empty
   373   show ?case
   374     by (auto simp add: extensional_funcset_empty_domain)
   375 next
   376   case (insert x S)
   377   {
   378     fix g g' y y'
   379     assume assms: "g \<in> extensional_funcset S T"
   380       "g' \<in> extensional_funcset S T"
   381       "y \<in> T" "y' \<in> T"
   382       "g(x := y) = g'(x := y')"
   383     from this have "y = y'"
   384       by (metis fun_upd_same)
   385     have "g = g'"
   386       by (metis assms(1) assms(2) assms(5) extensional_funcset_arb fun_upd_triv fun_upd_upd insert(2))
   387   from `y = y'` `g = g'` have "y = y' & g = g'" by simp
   388   }
   389   from this have "inj_on (\<lambda>(y, g). g (x := y)) (T \<times> extensional_funcset S T)"
   390     by (auto intro: inj_onI)
   391   from this insert.hyps show ?case
   392     by (simp add: extensional_funcset_extend_domain_eq card_image card_cartesian_product)
   393 qed
   394 
   395 lemma finite_extensional_funcset:
   396   assumes "finite S" "finite T"
   397   shows "finite (extensional_funcset S T)"
   398 proof -
   399   from card_extensional_funcset[OF assms(1), of T] assms(2)
   400   have "(card (extensional_funcset S T) \<noteq> 0) \<or> (S \<noteq> {} \<and> T = {})"
   401     by auto
   402   from this show ?thesis
   403   proof
   404     assume "card (extensional_funcset S T) \<noteq> 0"
   405     from this show ?thesis
   406       by (auto intro: card_ge_0_finite)
   407   next
   408     assume "S \<noteq> {} \<and> T = {}"
   409     from this show ?thesis
   410       by (auto simp add: extensional_funcset_empty_range)
   411   qed
   412 qed
   413 
   414 end