src/HOL/Orderings.thy
author wenzelm
Sat Sep 29 18:23:46 2012 +0200 (2012-09-29)
changeset 49660 de49d9b4d7bc
parent 48891 c0eafbd55de3
child 49769 c7c2152322f2
permissions -rw-r--r--
more explicit Syntax_Trans.mark_bound_abs/mark_bound_body: preserve type information for show_markup;
     1 (*  Title:      HOL/Orderings.thy
     2     Author:     Tobias Nipkow, Markus Wenzel, and Larry Paulson
     3 *)
     4 
     5 header {* Abstract orderings *}
     6 
     7 theory Orderings
     8 imports HOL
     9 keywords "print_orders" :: diag
    10 begin
    11 
    12 ML_file "~~/src/Provers/order.ML"
    13 ML_file "~~/src/Provers/quasi.ML"  (* FIXME unused? *)
    14 
    15 subsection {* Syntactic orders *}
    16 
    17 class ord =
    18   fixes less_eq :: "'a \<Rightarrow> 'a \<Rightarrow> bool"
    19     and less :: "'a \<Rightarrow> 'a \<Rightarrow> bool"
    20 begin
    21 
    22 notation
    23   less_eq  ("op <=") and
    24   less_eq  ("(_/ <= _)" [51, 51] 50) and
    25   less  ("op <") and
    26   less  ("(_/ < _)"  [51, 51] 50)
    27   
    28 notation (xsymbols)
    29   less_eq  ("op \<le>") and
    30   less_eq  ("(_/ \<le> _)"  [51, 51] 50)
    31 
    32 notation (HTML output)
    33   less_eq  ("op \<le>") and
    34   less_eq  ("(_/ \<le> _)"  [51, 51] 50)
    35 
    36 abbreviation (input)
    37   greater_eq  (infix ">=" 50) where
    38   "x >= y \<equiv> y <= x"
    39 
    40 notation (input)
    41   greater_eq  (infix "\<ge>" 50)
    42 
    43 abbreviation (input)
    44   greater  (infix ">" 50) where
    45   "x > y \<equiv> y < x"
    46 
    47 end
    48 
    49 
    50 subsection {* Quasi orders *}
    51 
    52 class preorder = ord +
    53   assumes less_le_not_le: "x < y \<longleftrightarrow> x \<le> y \<and> \<not> (y \<le> x)"
    54   and order_refl [iff]: "x \<le> x"
    55   and order_trans: "x \<le> y \<Longrightarrow> y \<le> z \<Longrightarrow> x \<le> z"
    56 begin
    57 
    58 text {* Reflexivity. *}
    59 
    60 lemma eq_refl: "x = y \<Longrightarrow> x \<le> y"
    61     -- {* This form is useful with the classical reasoner. *}
    62 by (erule ssubst) (rule order_refl)
    63 
    64 lemma less_irrefl [iff]: "\<not> x < x"
    65 by (simp add: less_le_not_le)
    66 
    67 lemma less_imp_le: "x < y \<Longrightarrow> x \<le> y"
    68 unfolding less_le_not_le by blast
    69 
    70 
    71 text {* Asymmetry. *}
    72 
    73 lemma less_not_sym: "x < y \<Longrightarrow> \<not> (y < x)"
    74 by (simp add: less_le_not_le)
    75 
    76 lemma less_asym: "x < y \<Longrightarrow> (\<not> P \<Longrightarrow> y < x) \<Longrightarrow> P"
    77 by (drule less_not_sym, erule contrapos_np) simp
    78 
    79 
    80 text {* Transitivity. *}
    81 
    82 lemma less_trans: "x < y \<Longrightarrow> y < z \<Longrightarrow> x < z"
    83 by (auto simp add: less_le_not_le intro: order_trans) 
    84 
    85 lemma le_less_trans: "x \<le> y \<Longrightarrow> y < z \<Longrightarrow> x < z"
    86 by (auto simp add: less_le_not_le intro: order_trans) 
    87 
    88 lemma less_le_trans: "x < y \<Longrightarrow> y \<le> z \<Longrightarrow> x < z"
    89 by (auto simp add: less_le_not_le intro: order_trans) 
    90 
    91 
    92 text {* Useful for simplification, but too risky to include by default. *}
    93 
    94 lemma less_imp_not_less: "x < y \<Longrightarrow> (\<not> y < x) \<longleftrightarrow> True"
    95 by (blast elim: less_asym)
    96 
    97 lemma less_imp_triv: "x < y \<Longrightarrow> (y < x \<longrightarrow> P) \<longleftrightarrow> True"
    98 by (blast elim: less_asym)
    99 
   100 
   101 text {* Transitivity rules for calculational reasoning *}
   102 
   103 lemma less_asym': "a < b \<Longrightarrow> b < a \<Longrightarrow> P"
   104 by (rule less_asym)
   105 
   106 
   107 text {* Dual order *}
   108 
   109 lemma dual_preorder:
   110   "class.preorder (op \<ge>) (op >)"
   111 proof qed (auto simp add: less_le_not_le intro: order_trans)
   112 
   113 end
   114 
   115 
   116 subsection {* Partial orders *}
   117 
   118 class order = preorder +
   119   assumes antisym: "x \<le> y \<Longrightarrow> y \<le> x \<Longrightarrow> x = y"
   120 begin
   121 
   122 text {* Reflexivity. *}
   123 
   124 lemma less_le: "x < y \<longleftrightarrow> x \<le> y \<and> x \<noteq> y"
   125 by (auto simp add: less_le_not_le intro: antisym)
   126 
   127 lemma le_less: "x \<le> y \<longleftrightarrow> x < y \<or> x = y"
   128     -- {* NOT suitable for iff, since it can cause PROOF FAILED. *}
   129 by (simp add: less_le) blast
   130 
   131 lemma le_imp_less_or_eq: "x \<le> y \<Longrightarrow> x < y \<or> x = y"
   132 unfolding less_le by blast
   133 
   134 
   135 text {* Useful for simplification, but too risky to include by default. *}
   136 
   137 lemma less_imp_not_eq: "x < y \<Longrightarrow> (x = y) \<longleftrightarrow> False"
   138 by auto
   139 
   140 lemma less_imp_not_eq2: "x < y \<Longrightarrow> (y = x) \<longleftrightarrow> False"
   141 by auto
   142 
   143 
   144 text {* Transitivity rules for calculational reasoning *}
   145 
   146 lemma neq_le_trans: "a \<noteq> b \<Longrightarrow> a \<le> b \<Longrightarrow> a < b"
   147 by (simp add: less_le)
   148 
   149 lemma le_neq_trans: "a \<le> b \<Longrightarrow> a \<noteq> b \<Longrightarrow> a < b"
   150 by (simp add: less_le)
   151 
   152 
   153 text {* Asymmetry. *}
   154 
   155 lemma eq_iff: "x = y \<longleftrightarrow> x \<le> y \<and> y \<le> x"
   156 by (blast intro: antisym)
   157 
   158 lemma antisym_conv: "y \<le> x \<Longrightarrow> x \<le> y \<longleftrightarrow> x = y"
   159 by (blast intro: antisym)
   160 
   161 lemma less_imp_neq: "x < y \<Longrightarrow> x \<noteq> y"
   162 by (erule contrapos_pn, erule subst, rule less_irrefl)
   163 
   164 
   165 text {* Least value operator *}
   166 
   167 definition (in ord)
   168   Least :: "('a \<Rightarrow> bool) \<Rightarrow> 'a" (binder "LEAST " 10) where
   169   "Least P = (THE x. P x \<and> (\<forall>y. P y \<longrightarrow> x \<le> y))"
   170 
   171 lemma Least_equality:
   172   assumes "P x"
   173     and "\<And>y. P y \<Longrightarrow> x \<le> y"
   174   shows "Least P = x"
   175 unfolding Least_def by (rule the_equality)
   176   (blast intro: assms antisym)+
   177 
   178 lemma LeastI2_order:
   179   assumes "P x"
   180     and "\<And>y. P y \<Longrightarrow> x \<le> y"
   181     and "\<And>x. P x \<Longrightarrow> \<forall>y. P y \<longrightarrow> x \<le> y \<Longrightarrow> Q x"
   182   shows "Q (Least P)"
   183 unfolding Least_def by (rule theI2)
   184   (blast intro: assms antisym)+
   185 
   186 
   187 text {* Dual order *}
   188 
   189 lemma dual_order:
   190   "class.order (op \<ge>) (op >)"
   191 by (intro_locales, rule dual_preorder) (unfold_locales, rule antisym)
   192 
   193 end
   194 
   195 
   196 subsection {* Linear (total) orders *}
   197 
   198 class linorder = order +
   199   assumes linear: "x \<le> y \<or> y \<le> x"
   200 begin
   201 
   202 lemma less_linear: "x < y \<or> x = y \<or> y < x"
   203 unfolding less_le using less_le linear by blast
   204 
   205 lemma le_less_linear: "x \<le> y \<or> y < x"
   206 by (simp add: le_less less_linear)
   207 
   208 lemma le_cases [case_names le ge]:
   209   "(x \<le> y \<Longrightarrow> P) \<Longrightarrow> (y \<le> x \<Longrightarrow> P) \<Longrightarrow> P"
   210 using linear by blast
   211 
   212 lemma linorder_cases [case_names less equal greater]:
   213   "(x < y \<Longrightarrow> P) \<Longrightarrow> (x = y \<Longrightarrow> P) \<Longrightarrow> (y < x \<Longrightarrow> P) \<Longrightarrow> P"
   214 using less_linear by blast
   215 
   216 lemma not_less: "\<not> x < y \<longleftrightarrow> y \<le> x"
   217 apply (simp add: less_le)
   218 using linear apply (blast intro: antisym)
   219 done
   220 
   221 lemma not_less_iff_gr_or_eq:
   222  "\<not>(x < y) \<longleftrightarrow> (x > y | x = y)"
   223 apply(simp add:not_less le_less)
   224 apply blast
   225 done
   226 
   227 lemma not_le: "\<not> x \<le> y \<longleftrightarrow> y < x"
   228 apply (simp add: less_le)
   229 using linear apply (blast intro: antisym)
   230 done
   231 
   232 lemma neq_iff: "x \<noteq> y \<longleftrightarrow> x < y \<or> y < x"
   233 by (cut_tac x = x and y = y in less_linear, auto)
   234 
   235 lemma neqE: "x \<noteq> y \<Longrightarrow> (x < y \<Longrightarrow> R) \<Longrightarrow> (y < x \<Longrightarrow> R) \<Longrightarrow> R"
   236 by (simp add: neq_iff) blast
   237 
   238 lemma antisym_conv1: "\<not> x < y \<Longrightarrow> x \<le> y \<longleftrightarrow> x = y"
   239 by (blast intro: antisym dest: not_less [THEN iffD1])
   240 
   241 lemma antisym_conv2: "x \<le> y \<Longrightarrow> \<not> x < y \<longleftrightarrow> x = y"
   242 by (blast intro: antisym dest: not_less [THEN iffD1])
   243 
   244 lemma antisym_conv3: "\<not> y < x \<Longrightarrow> \<not> x < y \<longleftrightarrow> x = y"
   245 by (blast intro: antisym dest: not_less [THEN iffD1])
   246 
   247 lemma leI: "\<not> x < y \<Longrightarrow> y \<le> x"
   248 unfolding not_less .
   249 
   250 lemma leD: "y \<le> x \<Longrightarrow> \<not> x < y"
   251 unfolding not_less .
   252 
   253 (*FIXME inappropriate name (or delete altogether)*)
   254 lemma not_leE: "\<not> y \<le> x \<Longrightarrow> x < y"
   255 unfolding not_le .
   256 
   257 
   258 text {* Dual order *}
   259 
   260 lemma dual_linorder:
   261   "class.linorder (op \<ge>) (op >)"
   262 by (rule class.linorder.intro, rule dual_order) (unfold_locales, rule linear)
   263 
   264 
   265 text {* min/max *}
   266 
   267 definition (in ord) min :: "'a \<Rightarrow> 'a \<Rightarrow> 'a" where
   268   "min a b = (if a \<le> b then a else b)"
   269 
   270 definition (in ord) max :: "'a \<Rightarrow> 'a \<Rightarrow> 'a" where
   271   "max a b = (if a \<le> b then b else a)"
   272 
   273 lemma min_le_iff_disj:
   274   "min x y \<le> z \<longleftrightarrow> x \<le> z \<or> y \<le> z"
   275 unfolding min_def using linear by (auto intro: order_trans)
   276 
   277 lemma le_max_iff_disj:
   278   "z \<le> max x y \<longleftrightarrow> z \<le> x \<or> z \<le> y"
   279 unfolding max_def using linear by (auto intro: order_trans)
   280 
   281 lemma min_less_iff_disj:
   282   "min x y < z \<longleftrightarrow> x < z \<or> y < z"
   283 unfolding min_def le_less using less_linear by (auto intro: less_trans)
   284 
   285 lemma less_max_iff_disj:
   286   "z < max x y \<longleftrightarrow> z < x \<or> z < y"
   287 unfolding max_def le_less using less_linear by (auto intro: less_trans)
   288 
   289 lemma min_less_iff_conj [simp]:
   290   "z < min x y \<longleftrightarrow> z < x \<and> z < y"
   291 unfolding min_def le_less using less_linear by (auto intro: less_trans)
   292 
   293 lemma max_less_iff_conj [simp]:
   294   "max x y < z \<longleftrightarrow> x < z \<and> y < z"
   295 unfolding max_def le_less using less_linear by (auto intro: less_trans)
   296 
   297 lemma split_min [no_atp]:
   298   "P (min i j) \<longleftrightarrow> (i \<le> j \<longrightarrow> P i) \<and> (\<not> i \<le> j \<longrightarrow> P j)"
   299 by (simp add: min_def)
   300 
   301 lemma split_max [no_atp]:
   302   "P (max i j) \<longleftrightarrow> (i \<le> j \<longrightarrow> P j) \<and> (\<not> i \<le> j \<longrightarrow> P i)"
   303 by (simp add: max_def)
   304 
   305 end
   306 
   307 
   308 subsection {* Reasoning tools setup *}
   309 
   310 ML {*
   311 
   312 signature ORDERS =
   313 sig
   314   val print_structures: Proof.context -> unit
   315   val attrib_setup: theory -> theory
   316   val order_tac: Proof.context -> thm list -> int -> tactic
   317 end;
   318 
   319 structure Orders: ORDERS =
   320 struct
   321 
   322 (** Theory and context data **)
   323 
   324 fun struct_eq ((s1: string, ts1), (s2, ts2)) =
   325   (s1 = s2) andalso eq_list (op aconv) (ts1, ts2);
   326 
   327 structure Data = Generic_Data
   328 (
   329   type T = ((string * term list) * Order_Tac.less_arith) list;
   330     (* Order structures:
   331        identifier of the structure, list of operations and record of theorems
   332        needed to set up the transitivity reasoner,
   333        identifier and operations identify the structure uniquely. *)
   334   val empty = [];
   335   val extend = I;
   336   fun merge data = AList.join struct_eq (K fst) data;
   337 );
   338 
   339 fun print_structures ctxt =
   340   let
   341     val structs = Data.get (Context.Proof ctxt);
   342     fun pretty_term t = Pretty.block
   343       [Pretty.quote (Syntax.pretty_term ctxt t), Pretty.brk 1,
   344         Pretty.str "::", Pretty.brk 1,
   345         Pretty.quote (Syntax.pretty_typ ctxt (type_of t))];
   346     fun pretty_struct ((s, ts), _) = Pretty.block
   347       [Pretty.str s, Pretty.str ":", Pretty.brk 1,
   348        Pretty.enclose "(" ")" (Pretty.breaks (map pretty_term ts))];
   349   in
   350     Pretty.writeln (Pretty.big_list "Order structures:" (map pretty_struct structs))
   351   end;
   352 
   353 
   354 (** Method **)
   355 
   356 fun struct_tac ((s, [eq, le, less]), thms) ctxt prems =
   357   let
   358     fun decomp thy (@{const Trueprop} $ t) =
   359       let
   360         fun excluded t =
   361           (* exclude numeric types: linear arithmetic subsumes transitivity *)
   362           let val T = type_of t
   363           in
   364             T = HOLogic.natT orelse T = HOLogic.intT orelse T = HOLogic.realT
   365           end;
   366         fun rel (bin_op $ t1 $ t2) =
   367               if excluded t1 then NONE
   368               else if Pattern.matches thy (eq, bin_op) then SOME (t1, "=", t2)
   369               else if Pattern.matches thy (le, bin_op) then SOME (t1, "<=", t2)
   370               else if Pattern.matches thy (less, bin_op) then SOME (t1, "<", t2)
   371               else NONE
   372           | rel _ = NONE;
   373         fun dec (Const (@{const_name Not}, _) $ t) = (case rel t
   374               of NONE => NONE
   375                | SOME (t1, rel, t2) => SOME (t1, "~" ^ rel, t2))
   376           | dec x = rel x;
   377       in dec t end
   378       | decomp thy _ = NONE;
   379   in
   380     case s of
   381       "order" => Order_Tac.partial_tac decomp thms ctxt prems
   382     | "linorder" => Order_Tac.linear_tac decomp thms ctxt prems
   383     | _ => error ("Unknown kind of order `" ^ s ^ "' encountered in transitivity reasoner.")
   384   end
   385 
   386 fun order_tac ctxt prems =
   387   FIRST' (map (fn s => CHANGED o struct_tac s ctxt prems) (Data.get (Context.Proof ctxt)));
   388 
   389 
   390 (** Attribute **)
   391 
   392 fun add_struct_thm s tag =
   393   Thm.declaration_attribute
   394     (fn thm => Data.map (AList.map_default struct_eq (s, Order_Tac.empty TrueI) (Order_Tac.update tag thm)));
   395 fun del_struct s =
   396   Thm.declaration_attribute
   397     (fn _ => Data.map (AList.delete struct_eq s));
   398 
   399 val attrib_setup =
   400   Attrib.setup @{binding order}
   401     (Scan.lift ((Args.add -- Args.name >> (fn (_, s) => SOME s) || Args.del >> K NONE) --|
   402       Args.colon (* FIXME || Scan.succeed true *) ) -- Scan.lift Args.name --
   403       Scan.repeat Args.term
   404       >> (fn ((SOME tag, n), ts) => add_struct_thm (n, ts) tag
   405            | ((NONE, n), ts) => del_struct (n, ts)))
   406     "theorems controlling transitivity reasoner";
   407 
   408 
   409 (** Diagnostic command **)
   410 
   411 val _ =
   412   Outer_Syntax.improper_command @{command_spec "print_orders"}
   413     "print order structures available to transitivity reasoner"
   414     (Scan.succeed (Toplevel.no_timing o Toplevel.unknown_context o
   415         Toplevel.keep (print_structures o Toplevel.context_of)));
   416 
   417 end;
   418 
   419 *}
   420 
   421 setup Orders.attrib_setup
   422 
   423 method_setup order = {*
   424   Scan.succeed (fn ctxt => SIMPLE_METHOD' (Orders.order_tac ctxt []))
   425 *} "transitivity reasoner"
   426 
   427 
   428 text {* Declarations to set up transitivity reasoner of partial and linear orders. *}
   429 
   430 context order
   431 begin
   432 
   433 (* The type constraint on @{term op =} below is necessary since the operation
   434    is not a parameter of the locale. *)
   435 
   436 declare less_irrefl [THEN notE, order add less_reflE: order "op = :: 'a \<Rightarrow> 'a \<Rightarrow> bool" "op <=" "op <"]
   437   
   438 declare order_refl  [order add le_refl: order "op = :: 'a => 'a => bool" "op <=" "op <"]
   439   
   440 declare less_imp_le [order add less_imp_le: order "op = :: 'a => 'a => bool" "op <=" "op <"]
   441   
   442 declare antisym [order add eqI: order "op = :: 'a => 'a => bool" "op <=" "op <"]
   443 
   444 declare eq_refl [order add eqD1: order "op = :: 'a => 'a => bool" "op <=" "op <"]
   445 
   446 declare sym [THEN eq_refl, order add eqD2: order "op = :: 'a => 'a => bool" "op <=" "op <"]
   447 
   448 declare less_trans [order add less_trans: order "op = :: 'a => 'a => bool" "op <=" "op <"]
   449   
   450 declare less_le_trans [order add less_le_trans: order "op = :: 'a => 'a => bool" "op <=" "op <"]
   451   
   452 declare le_less_trans [order add le_less_trans: order "op = :: 'a => 'a => bool" "op <=" "op <"]
   453 
   454 declare order_trans [order add le_trans: order "op = :: 'a => 'a => bool" "op <=" "op <"]
   455 
   456 declare le_neq_trans [order add le_neq_trans: order "op = :: 'a => 'a => bool" "op <=" "op <"]
   457 
   458 declare neq_le_trans [order add neq_le_trans: order "op = :: 'a => 'a => bool" "op <=" "op <"]
   459 
   460 declare less_imp_neq [order add less_imp_neq: order "op = :: 'a => 'a => bool" "op <=" "op <"]
   461 
   462 declare eq_neq_eq_imp_neq [order add eq_neq_eq_imp_neq: order "op = :: 'a => 'a => bool" "op <=" "op <"]
   463 
   464 declare not_sym [order add not_sym: order "op = :: 'a => 'a => bool" "op <=" "op <"]
   465 
   466 end
   467 
   468 context linorder
   469 begin
   470 
   471 declare [[order del: order "op = :: 'a => 'a => bool" "op <=" "op <"]]
   472 
   473 declare less_irrefl [THEN notE, order add less_reflE: linorder "op = :: 'a => 'a => bool" "op <=" "op <"]
   474 
   475 declare order_refl [order add le_refl: linorder "op = :: 'a => 'a => bool" "op <=" "op <"]
   476 
   477 declare less_imp_le [order add less_imp_le: linorder "op = :: 'a => 'a => bool" "op <=" "op <"]
   478 
   479 declare not_less [THEN iffD2, order add not_lessI: linorder "op = :: 'a => 'a => bool" "op <=" "op <"]
   480 
   481 declare not_le [THEN iffD2, order add not_leI: linorder "op = :: 'a => 'a => bool" "op <=" "op <"]
   482 
   483 declare not_less [THEN iffD1, order add not_lessD: linorder "op = :: 'a => 'a => bool" "op <=" "op <"]
   484 
   485 declare not_le [THEN iffD1, order add not_leD: linorder "op = :: 'a => 'a => bool" "op <=" "op <"]
   486 
   487 declare antisym [order add eqI: linorder "op = :: 'a => 'a => bool" "op <=" "op <"]
   488 
   489 declare eq_refl [order add eqD1: linorder "op = :: 'a => 'a => bool" "op <=" "op <"]
   490 
   491 declare sym [THEN eq_refl, order add eqD2: linorder "op = :: 'a => 'a => bool" "op <=" "op <"]
   492 
   493 declare less_trans [order add less_trans: linorder "op = :: 'a => 'a => bool" "op <=" "op <"]
   494 
   495 declare less_le_trans [order add less_le_trans: linorder "op = :: 'a => 'a => bool" "op <=" "op <"]
   496 
   497 declare le_less_trans [order add le_less_trans: linorder "op = :: 'a => 'a => bool" "op <=" "op <"]
   498 
   499 declare order_trans [order add le_trans: linorder "op = :: 'a => 'a => bool" "op <=" "op <"]
   500 
   501 declare le_neq_trans [order add le_neq_trans: linorder "op = :: 'a => 'a => bool" "op <=" "op <"]
   502 
   503 declare neq_le_trans [order add neq_le_trans: linorder "op = :: 'a => 'a => bool" "op <=" "op <"]
   504 
   505 declare less_imp_neq [order add less_imp_neq: linorder "op = :: 'a => 'a => bool" "op <=" "op <"]
   506 
   507 declare eq_neq_eq_imp_neq [order add eq_neq_eq_imp_neq: linorder "op = :: 'a => 'a => bool" "op <=" "op <"]
   508 
   509 declare not_sym [order add not_sym: linorder "op = :: 'a => 'a => bool" "op <=" "op <"]
   510 
   511 end
   512 
   513 
   514 setup {*
   515 let
   516 
   517 fun prp t thm = Thm.prop_of thm = t;  (* FIXME aconv!? *)
   518 
   519 fun prove_antisym_le sg ss ((le as Const(_,T)) $ r $ s) =
   520   let val prems = Simplifier.prems_of ss;
   521       val less = Const (@{const_name less}, T);
   522       val t = HOLogic.mk_Trueprop(le $ s $ r);
   523   in case find_first (prp t) prems of
   524        NONE =>
   525          let val t = HOLogic.mk_Trueprop(HOLogic.Not $ (less $ r $ s))
   526          in case find_first (prp t) prems of
   527               NONE => NONE
   528             | SOME thm => SOME(mk_meta_eq(thm RS @{thm linorder_class.antisym_conv1}))
   529          end
   530      | SOME thm => SOME(mk_meta_eq(thm RS @{thm order_class.antisym_conv}))
   531   end
   532   handle THM _ => NONE;
   533 
   534 fun prove_antisym_less sg ss (NotC $ ((less as Const(_,T)) $ r $ s)) =
   535   let val prems = Simplifier.prems_of ss;
   536       val le = Const (@{const_name less_eq}, T);
   537       val t = HOLogic.mk_Trueprop(le $ r $ s);
   538   in case find_first (prp t) prems of
   539        NONE =>
   540          let val t = HOLogic.mk_Trueprop(NotC $ (less $ s $ r))
   541          in case find_first (prp t) prems of
   542               NONE => NONE
   543             | SOME thm => SOME(mk_meta_eq(thm RS @{thm linorder_class.antisym_conv3}))
   544          end
   545      | SOME thm => SOME(mk_meta_eq(thm RS @{thm linorder_class.antisym_conv2}))
   546   end
   547   handle THM _ => NONE;
   548 
   549 fun add_simprocs procs thy =
   550   Simplifier.map_simpset_global (fn ss => ss
   551     addsimprocs (map (fn (name, raw_ts, proc) =>
   552       Simplifier.simproc_global thy name raw_ts proc) procs)) thy;
   553 
   554 fun add_solver name tac =
   555   Simplifier.map_simpset_global (fn ss => ss addSolver
   556     mk_solver name (fn ss => tac (Simplifier.the_context ss) (Simplifier.prems_of ss)));
   557 
   558 in
   559   add_simprocs [
   560        ("antisym le", ["(x::'a::order) <= y"], prove_antisym_le),
   561        ("antisym less", ["~ (x::'a::linorder) < y"], prove_antisym_less)
   562      ]
   563   #> add_solver "Transitivity" Orders.order_tac
   564   (* Adding the transitivity reasoners also as safe solvers showed a slight
   565      speed up, but the reasoning strength appears to be not higher (at least
   566      no breaking of additional proofs in the entire HOL distribution, as
   567      of 5 March 2004, was observed). *)
   568 end
   569 *}
   570 
   571 
   572 subsection {* Bounded quantifiers *}
   573 
   574 syntax
   575   "_All_less" :: "[idt, 'a, bool] => bool"    ("(3ALL _<_./ _)"  [0, 0, 10] 10)
   576   "_Ex_less" :: "[idt, 'a, bool] => bool"    ("(3EX _<_./ _)"  [0, 0, 10] 10)
   577   "_All_less_eq" :: "[idt, 'a, bool] => bool"    ("(3ALL _<=_./ _)" [0, 0, 10] 10)
   578   "_Ex_less_eq" :: "[idt, 'a, bool] => bool"    ("(3EX _<=_./ _)" [0, 0, 10] 10)
   579 
   580   "_All_greater" :: "[idt, 'a, bool] => bool"    ("(3ALL _>_./ _)"  [0, 0, 10] 10)
   581   "_Ex_greater" :: "[idt, 'a, bool] => bool"    ("(3EX _>_./ _)"  [0, 0, 10] 10)
   582   "_All_greater_eq" :: "[idt, 'a, bool] => bool"    ("(3ALL _>=_./ _)" [0, 0, 10] 10)
   583   "_Ex_greater_eq" :: "[idt, 'a, bool] => bool"    ("(3EX _>=_./ _)" [0, 0, 10] 10)
   584 
   585 syntax (xsymbols)
   586   "_All_less" :: "[idt, 'a, bool] => bool"    ("(3\<forall>_<_./ _)"  [0, 0, 10] 10)
   587   "_Ex_less" :: "[idt, 'a, bool] => bool"    ("(3\<exists>_<_./ _)"  [0, 0, 10] 10)
   588   "_All_less_eq" :: "[idt, 'a, bool] => bool"    ("(3\<forall>_\<le>_./ _)" [0, 0, 10] 10)
   589   "_Ex_less_eq" :: "[idt, 'a, bool] => bool"    ("(3\<exists>_\<le>_./ _)" [0, 0, 10] 10)
   590 
   591   "_All_greater" :: "[idt, 'a, bool] => bool"    ("(3\<forall>_>_./ _)"  [0, 0, 10] 10)
   592   "_Ex_greater" :: "[idt, 'a, bool] => bool"    ("(3\<exists>_>_./ _)"  [0, 0, 10] 10)
   593   "_All_greater_eq" :: "[idt, 'a, bool] => bool"    ("(3\<forall>_\<ge>_./ _)" [0, 0, 10] 10)
   594   "_Ex_greater_eq" :: "[idt, 'a, bool] => bool"    ("(3\<exists>_\<ge>_./ _)" [0, 0, 10] 10)
   595 
   596 syntax (HOL)
   597   "_All_less" :: "[idt, 'a, bool] => bool"    ("(3! _<_./ _)"  [0, 0, 10] 10)
   598   "_Ex_less" :: "[idt, 'a, bool] => bool"    ("(3? _<_./ _)"  [0, 0, 10] 10)
   599   "_All_less_eq" :: "[idt, 'a, bool] => bool"    ("(3! _<=_./ _)" [0, 0, 10] 10)
   600   "_Ex_less_eq" :: "[idt, 'a, bool] => bool"    ("(3? _<=_./ _)" [0, 0, 10] 10)
   601 
   602 syntax (HTML output)
   603   "_All_less" :: "[idt, 'a, bool] => bool"    ("(3\<forall>_<_./ _)"  [0, 0, 10] 10)
   604   "_Ex_less" :: "[idt, 'a, bool] => bool"    ("(3\<exists>_<_./ _)"  [0, 0, 10] 10)
   605   "_All_less_eq" :: "[idt, 'a, bool] => bool"    ("(3\<forall>_\<le>_./ _)" [0, 0, 10] 10)
   606   "_Ex_less_eq" :: "[idt, 'a, bool] => bool"    ("(3\<exists>_\<le>_./ _)" [0, 0, 10] 10)
   607 
   608   "_All_greater" :: "[idt, 'a, bool] => bool"    ("(3\<forall>_>_./ _)"  [0, 0, 10] 10)
   609   "_Ex_greater" :: "[idt, 'a, bool] => bool"    ("(3\<exists>_>_./ _)"  [0, 0, 10] 10)
   610   "_All_greater_eq" :: "[idt, 'a, bool] => bool"    ("(3\<forall>_\<ge>_./ _)" [0, 0, 10] 10)
   611   "_Ex_greater_eq" :: "[idt, 'a, bool] => bool"    ("(3\<exists>_\<ge>_./ _)" [0, 0, 10] 10)
   612 
   613 translations
   614   "ALL x<y. P"   =>  "ALL x. x < y \<longrightarrow> P"
   615   "EX x<y. P"    =>  "EX x. x < y \<and> P"
   616   "ALL x<=y. P"  =>  "ALL x. x <= y \<longrightarrow> P"
   617   "EX x<=y. P"   =>  "EX x. x <= y \<and> P"
   618   "ALL x>y. P"   =>  "ALL x. x > y \<longrightarrow> P"
   619   "EX x>y. P"    =>  "EX x. x > y \<and> P"
   620   "ALL x>=y. P"  =>  "ALL x. x >= y \<longrightarrow> P"
   621   "EX x>=y. P"   =>  "EX x. x >= y \<and> P"
   622 
   623 print_translation {*
   624 let
   625   val All_binder = Mixfix.binder_name @{const_syntax All};
   626   val Ex_binder = Mixfix.binder_name @{const_syntax Ex};
   627   val impl = @{const_syntax HOL.implies};
   628   val conj = @{const_syntax HOL.conj};
   629   val less = @{const_syntax less};
   630   val less_eq = @{const_syntax less_eq};
   631 
   632   val trans =
   633    [((All_binder, impl, less),
   634     (@{syntax_const "_All_less"}, @{syntax_const "_All_greater"})),
   635     ((All_binder, impl, less_eq),
   636     (@{syntax_const "_All_less_eq"}, @{syntax_const "_All_greater_eq"})),
   637     ((Ex_binder, conj, less),
   638     (@{syntax_const "_Ex_less"}, @{syntax_const "_Ex_greater"})),
   639     ((Ex_binder, conj, less_eq),
   640     (@{syntax_const "_Ex_less_eq"}, @{syntax_const "_Ex_greater_eq"}))];
   641 
   642   fun matches_bound v t =
   643     (case t of
   644       Const (@{syntax_const "_bound"}, _) $ Free (v', _) => v = v'
   645     | _ => false);
   646   fun contains_var v = Term.exists_subterm (fn Free (x, _) => x = v | _ => false);
   647   fun mk x c n P = Syntax.const c $ Syntax_Trans.mark_bound_body x $ n $ P;
   648 
   649   fun tr' q = (q,
   650     fn [Const (@{syntax_const "_bound"}, _) $ Free (v, T),
   651         Const (c, _) $ (Const (d, _) $ t $ u) $ P] =>
   652         (case AList.lookup (op =) trans (q, c, d) of
   653           NONE => raise Match
   654         | SOME (l, g) =>
   655             if matches_bound v t andalso not (contains_var v u) then mk (v, T) l u P
   656             else if matches_bound v u andalso not (contains_var v t) then mk (v, T) g t P
   657             else raise Match)
   658      | _ => raise Match);
   659 in [tr' All_binder, tr' Ex_binder] end
   660 *}
   661 
   662 
   663 subsection {* Transitivity reasoning *}
   664 
   665 context ord
   666 begin
   667 
   668 lemma ord_le_eq_trans: "a \<le> b \<Longrightarrow> b = c \<Longrightarrow> a \<le> c"
   669   by (rule subst)
   670 
   671 lemma ord_eq_le_trans: "a = b \<Longrightarrow> b \<le> c \<Longrightarrow> a \<le> c"
   672   by (rule ssubst)
   673 
   674 lemma ord_less_eq_trans: "a < b \<Longrightarrow> b = c \<Longrightarrow> a < c"
   675   by (rule subst)
   676 
   677 lemma ord_eq_less_trans: "a = b \<Longrightarrow> b < c \<Longrightarrow> a < c"
   678   by (rule ssubst)
   679 
   680 end
   681 
   682 lemma order_less_subst2: "(a::'a::order) < b ==> f b < (c::'c::order) ==>
   683   (!!x y. x < y ==> f x < f y) ==> f a < c"
   684 proof -
   685   assume r: "!!x y. x < y ==> f x < f y"
   686   assume "a < b" hence "f a < f b" by (rule r)
   687   also assume "f b < c"
   688   finally (less_trans) show ?thesis .
   689 qed
   690 
   691 lemma order_less_subst1: "(a::'a::order) < f b ==> (b::'b::order) < c ==>
   692   (!!x y. x < y ==> f x < f y) ==> a < f c"
   693 proof -
   694   assume r: "!!x y. x < y ==> f x < f y"
   695   assume "a < f b"
   696   also assume "b < c" hence "f b < f c" by (rule r)
   697   finally (less_trans) show ?thesis .
   698 qed
   699 
   700 lemma order_le_less_subst2: "(a::'a::order) <= b ==> f b < (c::'c::order) ==>
   701   (!!x y. x <= y ==> f x <= f y) ==> f a < c"
   702 proof -
   703   assume r: "!!x y. x <= y ==> f x <= f y"
   704   assume "a <= b" hence "f a <= f b" by (rule r)
   705   also assume "f b < c"
   706   finally (le_less_trans) show ?thesis .
   707 qed
   708 
   709 lemma order_le_less_subst1: "(a::'a::order) <= f b ==> (b::'b::order) < c ==>
   710   (!!x y. x < y ==> f x < f y) ==> a < f c"
   711 proof -
   712   assume r: "!!x y. x < y ==> f x < f y"
   713   assume "a <= f b"
   714   also assume "b < c" hence "f b < f c" by (rule r)
   715   finally (le_less_trans) show ?thesis .
   716 qed
   717 
   718 lemma order_less_le_subst2: "(a::'a::order) < b ==> f b <= (c::'c::order) ==>
   719   (!!x y. x < y ==> f x < f y) ==> f a < c"
   720 proof -
   721   assume r: "!!x y. x < y ==> f x < f y"
   722   assume "a < b" hence "f a < f b" by (rule r)
   723   also assume "f b <= c"
   724   finally (less_le_trans) show ?thesis .
   725 qed
   726 
   727 lemma order_less_le_subst1: "(a::'a::order) < f b ==> (b::'b::order) <= c ==>
   728   (!!x y. x <= y ==> f x <= f y) ==> a < f c"
   729 proof -
   730   assume r: "!!x y. x <= y ==> f x <= f y"
   731   assume "a < f b"
   732   also assume "b <= c" hence "f b <= f c" by (rule r)
   733   finally (less_le_trans) show ?thesis .
   734 qed
   735 
   736 lemma order_subst1: "(a::'a::order) <= f b ==> (b::'b::order) <= c ==>
   737   (!!x y. x <= y ==> f x <= f y) ==> a <= f c"
   738 proof -
   739   assume r: "!!x y. x <= y ==> f x <= f y"
   740   assume "a <= f b"
   741   also assume "b <= c" hence "f b <= f c" by (rule r)
   742   finally (order_trans) show ?thesis .
   743 qed
   744 
   745 lemma order_subst2: "(a::'a::order) <= b ==> f b <= (c::'c::order) ==>
   746   (!!x y. x <= y ==> f x <= f y) ==> f a <= c"
   747 proof -
   748   assume r: "!!x y. x <= y ==> f x <= f y"
   749   assume "a <= b" hence "f a <= f b" by (rule r)
   750   also assume "f b <= c"
   751   finally (order_trans) show ?thesis .
   752 qed
   753 
   754 lemma ord_le_eq_subst: "a <= b ==> f b = c ==>
   755   (!!x y. x <= y ==> f x <= f y) ==> f a <= c"
   756 proof -
   757   assume r: "!!x y. x <= y ==> f x <= f y"
   758   assume "a <= b" hence "f a <= f b" by (rule r)
   759   also assume "f b = c"
   760   finally (ord_le_eq_trans) show ?thesis .
   761 qed
   762 
   763 lemma ord_eq_le_subst: "a = f b ==> b <= c ==>
   764   (!!x y. x <= y ==> f x <= f y) ==> a <= f c"
   765 proof -
   766   assume r: "!!x y. x <= y ==> f x <= f y"
   767   assume "a = f b"
   768   also assume "b <= c" hence "f b <= f c" by (rule r)
   769   finally (ord_eq_le_trans) show ?thesis .
   770 qed
   771 
   772 lemma ord_less_eq_subst: "a < b ==> f b = c ==>
   773   (!!x y. x < y ==> f x < f y) ==> f a < c"
   774 proof -
   775   assume r: "!!x y. x < y ==> f x < f y"
   776   assume "a < b" hence "f a < f b" by (rule r)
   777   also assume "f b = c"
   778   finally (ord_less_eq_trans) show ?thesis .
   779 qed
   780 
   781 lemma ord_eq_less_subst: "a = f b ==> b < c ==>
   782   (!!x y. x < y ==> f x < f y) ==> a < f c"
   783 proof -
   784   assume r: "!!x y. x < y ==> f x < f y"
   785   assume "a = f b"
   786   also assume "b < c" hence "f b < f c" by (rule r)
   787   finally (ord_eq_less_trans) show ?thesis .
   788 qed
   789 
   790 text {*
   791   Note that this list of rules is in reverse order of priorities.
   792 *}
   793 
   794 lemmas [trans] =
   795   order_less_subst2
   796   order_less_subst1
   797   order_le_less_subst2
   798   order_le_less_subst1
   799   order_less_le_subst2
   800   order_less_le_subst1
   801   order_subst2
   802   order_subst1
   803   ord_le_eq_subst
   804   ord_eq_le_subst
   805   ord_less_eq_subst
   806   ord_eq_less_subst
   807   forw_subst
   808   back_subst
   809   rev_mp
   810   mp
   811 
   812 lemmas (in order) [trans] =
   813   neq_le_trans
   814   le_neq_trans
   815 
   816 lemmas (in preorder) [trans] =
   817   less_trans
   818   less_asym'
   819   le_less_trans
   820   less_le_trans
   821   order_trans
   822 
   823 lemmas (in order) [trans] =
   824   antisym
   825 
   826 lemmas (in ord) [trans] =
   827   ord_le_eq_trans
   828   ord_eq_le_trans
   829   ord_less_eq_trans
   830   ord_eq_less_trans
   831 
   832 lemmas [trans] =
   833   trans
   834 
   835 lemmas order_trans_rules =
   836   order_less_subst2
   837   order_less_subst1
   838   order_le_less_subst2
   839   order_le_less_subst1
   840   order_less_le_subst2
   841   order_less_le_subst1
   842   order_subst2
   843   order_subst1
   844   ord_le_eq_subst
   845   ord_eq_le_subst
   846   ord_less_eq_subst
   847   ord_eq_less_subst
   848   forw_subst
   849   back_subst
   850   rev_mp
   851   mp
   852   neq_le_trans
   853   le_neq_trans
   854   less_trans
   855   less_asym'
   856   le_less_trans
   857   less_le_trans
   858   order_trans
   859   antisym
   860   ord_le_eq_trans
   861   ord_eq_le_trans
   862   ord_less_eq_trans
   863   ord_eq_less_trans
   864   trans
   865 
   866 text {* These support proving chains of decreasing inequalities
   867     a >= b >= c ... in Isar proofs. *}
   868 
   869 lemma xt1 [no_atp]:
   870   "a = b ==> b > c ==> a > c"
   871   "a > b ==> b = c ==> a > c"
   872   "a = b ==> b >= c ==> a >= c"
   873   "a >= b ==> b = c ==> a >= c"
   874   "(x::'a::order) >= y ==> y >= x ==> x = y"
   875   "(x::'a::order) >= y ==> y >= z ==> x >= z"
   876   "(x::'a::order) > y ==> y >= z ==> x > z"
   877   "(x::'a::order) >= y ==> y > z ==> x > z"
   878   "(a::'a::order) > b ==> b > a ==> P"
   879   "(x::'a::order) > y ==> y > z ==> x > z"
   880   "(a::'a::order) >= b ==> a ~= b ==> a > b"
   881   "(a::'a::order) ~= b ==> a >= b ==> a > b"
   882   "a = f b ==> b > c ==> (!!x y. x > y ==> f x > f y) ==> a > f c" 
   883   "a > b ==> f b = c ==> (!!x y. x > y ==> f x > f y) ==> f a > c"
   884   "a = f b ==> b >= c ==> (!!x y. x >= y ==> f x >= f y) ==> a >= f c"
   885   "a >= b ==> f b = c ==> (!! x y. x >= y ==> f x >= f y) ==> f a >= c"
   886   by auto
   887 
   888 lemma xt2 [no_atp]:
   889   "(a::'a::order) >= f b ==> b >= c ==> (!!x y. x >= y ==> f x >= f y) ==> a >= f c"
   890 by (subgoal_tac "f b >= f c", force, force)
   891 
   892 lemma xt3 [no_atp]: "(a::'a::order) >= b ==> (f b::'b::order) >= c ==>
   893     (!!x y. x >= y ==> f x >= f y) ==> f a >= c"
   894 by (subgoal_tac "f a >= f b", force, force)
   895 
   896 lemma xt4 [no_atp]: "(a::'a::order) > f b ==> (b::'b::order) >= c ==>
   897   (!!x y. x >= y ==> f x >= f y) ==> a > f c"
   898 by (subgoal_tac "f b >= f c", force, force)
   899 
   900 lemma xt5 [no_atp]: "(a::'a::order) > b ==> (f b::'b::order) >= c==>
   901     (!!x y. x > y ==> f x > f y) ==> f a > c"
   902 by (subgoal_tac "f a > f b", force, force)
   903 
   904 lemma xt6 [no_atp]: "(a::'a::order) >= f b ==> b > c ==>
   905     (!!x y. x > y ==> f x > f y) ==> a > f c"
   906 by (subgoal_tac "f b > f c", force, force)
   907 
   908 lemma xt7 [no_atp]: "(a::'a::order) >= b ==> (f b::'b::order) > c ==>
   909     (!!x y. x >= y ==> f x >= f y) ==> f a > c"
   910 by (subgoal_tac "f a >= f b", force, force)
   911 
   912 lemma xt8 [no_atp]: "(a::'a::order) > f b ==> (b::'b::order) > c ==>
   913     (!!x y. x > y ==> f x > f y) ==> a > f c"
   914 by (subgoal_tac "f b > f c", force, force)
   915 
   916 lemma xt9 [no_atp]: "(a::'a::order) > b ==> (f b::'b::order) > c ==>
   917     (!!x y. x > y ==> f x > f y) ==> f a > c"
   918 by (subgoal_tac "f a > f b", force, force)
   919 
   920 lemmas xtrans = xt1 xt2 xt3 xt4 xt5 xt6 xt7 xt8 xt9 [no_atp]
   921 
   922 (* 
   923   Since "a >= b" abbreviates "b <= a", the abbreviation "..." stands
   924   for the wrong thing in an Isar proof.
   925 
   926   The extra transitivity rules can be used as follows: 
   927 
   928 lemma "(a::'a::order) > z"
   929 proof -
   930   have "a >= b" (is "_ >= ?rhs")
   931     sorry
   932   also have "?rhs >= c" (is "_ >= ?rhs")
   933     sorry
   934   also (xtrans) have "?rhs = d" (is "_ = ?rhs")
   935     sorry
   936   also (xtrans) have "?rhs >= e" (is "_ >= ?rhs")
   937     sorry
   938   also (xtrans) have "?rhs > f" (is "_ > ?rhs")
   939     sorry
   940   also (xtrans) have "?rhs > z"
   941     sorry
   942   finally (xtrans) show ?thesis .
   943 qed
   944 
   945   Alternatively, one can use "declare xtrans [trans]" and then
   946   leave out the "(xtrans)" above.
   947 *)
   948 
   949 
   950 subsection {* Monotonicity, least value operator and min/max *}
   951 
   952 context order
   953 begin
   954 
   955 definition mono :: "('a \<Rightarrow> 'b\<Colon>order) \<Rightarrow> bool" where
   956   "mono f \<longleftrightarrow> (\<forall>x y. x \<le> y \<longrightarrow> f x \<le> f y)"
   957 
   958 lemma monoI [intro?]:
   959   fixes f :: "'a \<Rightarrow> 'b\<Colon>order"
   960   shows "(\<And>x y. x \<le> y \<Longrightarrow> f x \<le> f y) \<Longrightarrow> mono f"
   961   unfolding mono_def by iprover
   962 
   963 lemma monoD [dest?]:
   964   fixes f :: "'a \<Rightarrow> 'b\<Colon>order"
   965   shows "mono f \<Longrightarrow> x \<le> y \<Longrightarrow> f x \<le> f y"
   966   unfolding mono_def by iprover
   967 
   968 definition strict_mono :: "('a \<Rightarrow> 'b\<Colon>order) \<Rightarrow> bool" where
   969   "strict_mono f \<longleftrightarrow> (\<forall>x y. x < y \<longrightarrow> f x < f y)"
   970 
   971 lemma strict_monoI [intro?]:
   972   assumes "\<And>x y. x < y \<Longrightarrow> f x < f y"
   973   shows "strict_mono f"
   974   using assms unfolding strict_mono_def by auto
   975 
   976 lemma strict_monoD [dest?]:
   977   "strict_mono f \<Longrightarrow> x < y \<Longrightarrow> f x < f y"
   978   unfolding strict_mono_def by auto
   979 
   980 lemma strict_mono_mono [dest?]:
   981   assumes "strict_mono f"
   982   shows "mono f"
   983 proof (rule monoI)
   984   fix x y
   985   assume "x \<le> y"
   986   show "f x \<le> f y"
   987   proof (cases "x = y")
   988     case True then show ?thesis by simp
   989   next
   990     case False with `x \<le> y` have "x < y" by simp
   991     with assms strict_monoD have "f x < f y" by auto
   992     then show ?thesis by simp
   993   qed
   994 qed
   995 
   996 end
   997 
   998 context linorder
   999 begin
  1000 
  1001 lemma strict_mono_eq:
  1002   assumes "strict_mono f"
  1003   shows "f x = f y \<longleftrightarrow> x = y"
  1004 proof
  1005   assume "f x = f y"
  1006   show "x = y" proof (cases x y rule: linorder_cases)
  1007     case less with assms strict_monoD have "f x < f y" by auto
  1008     with `f x = f y` show ?thesis by simp
  1009   next
  1010     case equal then show ?thesis .
  1011   next
  1012     case greater with assms strict_monoD have "f y < f x" by auto
  1013     with `f x = f y` show ?thesis by simp
  1014   qed
  1015 qed simp
  1016 
  1017 lemma strict_mono_less_eq:
  1018   assumes "strict_mono f"
  1019   shows "f x \<le> f y \<longleftrightarrow> x \<le> y"
  1020 proof
  1021   assume "x \<le> y"
  1022   with assms strict_mono_mono monoD show "f x \<le> f y" by auto
  1023 next
  1024   assume "f x \<le> f y"
  1025   show "x \<le> y" proof (rule ccontr)
  1026     assume "\<not> x \<le> y" then have "y < x" by simp
  1027     with assms strict_monoD have "f y < f x" by auto
  1028     with `f x \<le> f y` show False by simp
  1029   qed
  1030 qed
  1031   
  1032 lemma strict_mono_less:
  1033   assumes "strict_mono f"
  1034   shows "f x < f y \<longleftrightarrow> x < y"
  1035   using assms
  1036     by (auto simp add: less_le Orderings.less_le strict_mono_eq strict_mono_less_eq)
  1037 
  1038 lemma min_of_mono:
  1039   fixes f :: "'a \<Rightarrow> 'b\<Colon>linorder"
  1040   shows "mono f \<Longrightarrow> min (f m) (f n) = f (min m n)"
  1041   by (auto simp: mono_def Orderings.min_def min_def intro: Orderings.antisym)
  1042 
  1043 lemma max_of_mono:
  1044   fixes f :: "'a \<Rightarrow> 'b\<Colon>linorder"
  1045   shows "mono f \<Longrightarrow> max (f m) (f n) = f (max m n)"
  1046   by (auto simp: mono_def Orderings.max_def max_def intro: Orderings.antisym)
  1047 
  1048 end
  1049 
  1050 lemma min_absorb1: "x \<le> y \<Longrightarrow> min x y = x"
  1051 by (simp add: min_def)
  1052 
  1053 lemma max_absorb2: "x \<le> y ==> max x y = y"
  1054 by (simp add: max_def)
  1055 
  1056 lemma min_absorb2: "(y\<Colon>'a\<Colon>order) \<le> x \<Longrightarrow> min x y = y"
  1057 by (simp add:min_def)
  1058 
  1059 lemma max_absorb1: "(y\<Colon>'a\<Colon>order) \<le> x \<Longrightarrow> max x y = x"
  1060 by (simp add: max_def)
  1061 
  1062 
  1063 
  1064 subsection {* (Unique) top and bottom elements *}
  1065 
  1066 class bot = order +
  1067   fixes bot :: 'a ("\<bottom>")
  1068   assumes bot_least [simp]: "\<bottom> \<le> a"
  1069 begin
  1070 
  1071 lemma le_bot:
  1072   "a \<le> \<bottom> \<Longrightarrow> a = \<bottom>"
  1073   by (auto intro: antisym)
  1074 
  1075 lemma bot_unique:
  1076   "a \<le> \<bottom> \<longleftrightarrow> a = \<bottom>"
  1077   by (auto intro: antisym)
  1078 
  1079 lemma not_less_bot [simp]:
  1080   "\<not> (a < \<bottom>)"
  1081   using bot_least [of a] by (auto simp: le_less)
  1082 
  1083 lemma bot_less:
  1084   "a \<noteq> \<bottom> \<longleftrightarrow> \<bottom> < a"
  1085   by (auto simp add: less_le_not_le intro!: antisym)
  1086 
  1087 end
  1088 
  1089 class top = order +
  1090   fixes top :: 'a ("\<top>")
  1091   assumes top_greatest [simp]: "a \<le> \<top>"
  1092 begin
  1093 
  1094 lemma top_le:
  1095   "\<top> \<le> a \<Longrightarrow> a = \<top>"
  1096   by (rule antisym) auto
  1097 
  1098 lemma top_unique:
  1099   "\<top> \<le> a \<longleftrightarrow> a = \<top>"
  1100   by (auto intro: antisym)
  1101 
  1102 lemma not_top_less [simp]: "\<not> (\<top> < a)"
  1103   using top_greatest [of a] by (auto simp: le_less)
  1104 
  1105 lemma less_top:
  1106   "a \<noteq> \<top> \<longleftrightarrow> a < \<top>"
  1107   by (auto simp add: less_le_not_le intro!: antisym)
  1108 
  1109 end
  1110 
  1111 
  1112 subsection {* Dense orders *}
  1113 
  1114 class dense_linorder = linorder + 
  1115   assumes gt_ex: "\<exists>y. x < y" 
  1116   and lt_ex: "\<exists>y. y < x"
  1117   and dense: "x < y \<Longrightarrow> (\<exists>z. x < z \<and> z < y)"
  1118 begin
  1119 
  1120 lemma dense_le:
  1121   fixes y z :: 'a
  1122   assumes "\<And>x. x < y \<Longrightarrow> x \<le> z"
  1123   shows "y \<le> z"
  1124 proof (rule ccontr)
  1125   assume "\<not> ?thesis"
  1126   hence "z < y" by simp
  1127   from dense[OF this]
  1128   obtain x where "x < y" and "z < x" by safe
  1129   moreover have "x \<le> z" using assms[OF `x < y`] .
  1130   ultimately show False by auto
  1131 qed
  1132 
  1133 lemma dense_le_bounded:
  1134   fixes x y z :: 'a
  1135   assumes "x < y"
  1136   assumes *: "\<And>w. \<lbrakk> x < w ; w < y \<rbrakk> \<Longrightarrow> w \<le> z"
  1137   shows "y \<le> z"
  1138 proof (rule dense_le)
  1139   fix w assume "w < y"
  1140   from dense[OF `x < y`] obtain u where "x < u" "u < y" by safe
  1141   from linear[of u w]
  1142   show "w \<le> z"
  1143   proof (rule disjE)
  1144     assume "u \<le> w"
  1145     from less_le_trans[OF `x < u` `u \<le> w`] `w < y`
  1146     show "w \<le> z" by (rule *)
  1147   next
  1148     assume "w \<le> u"
  1149     from `w \<le> u` *[OF `x < u` `u < y`]
  1150     show "w \<le> z" by (rule order_trans)
  1151   qed
  1152 qed
  1153 
  1154 end
  1155 
  1156 subsection {* Wellorders *}
  1157 
  1158 class wellorder = linorder +
  1159   assumes less_induct [case_names less]: "(\<And>x. (\<And>y. y < x \<Longrightarrow> P y) \<Longrightarrow> P x) \<Longrightarrow> P a"
  1160 begin
  1161 
  1162 lemma wellorder_Least_lemma:
  1163   fixes k :: 'a
  1164   assumes "P k"
  1165   shows LeastI: "P (LEAST x. P x)" and Least_le: "(LEAST x. P x) \<le> k"
  1166 proof -
  1167   have "P (LEAST x. P x) \<and> (LEAST x. P x) \<le> k"
  1168   using assms proof (induct k rule: less_induct)
  1169     case (less x) then have "P x" by simp
  1170     show ?case proof (rule classical)
  1171       assume assm: "\<not> (P (LEAST a. P a) \<and> (LEAST a. P a) \<le> x)"
  1172       have "\<And>y. P y \<Longrightarrow> x \<le> y"
  1173       proof (rule classical)
  1174         fix y
  1175         assume "P y" and "\<not> x \<le> y"
  1176         with less have "P (LEAST a. P a)" and "(LEAST a. P a) \<le> y"
  1177           by (auto simp add: not_le)
  1178         with assm have "x < (LEAST a. P a)" and "(LEAST a. P a) \<le> y"
  1179           by auto
  1180         then show "x \<le> y" by auto
  1181       qed
  1182       with `P x` have Least: "(LEAST a. P a) = x"
  1183         by (rule Least_equality)
  1184       with `P x` show ?thesis by simp
  1185     qed
  1186   qed
  1187   then show "P (LEAST x. P x)" and "(LEAST x. P x) \<le> k" by auto
  1188 qed
  1189 
  1190 -- "The following 3 lemmas are due to Brian Huffman"
  1191 lemma LeastI_ex: "\<exists>x. P x \<Longrightarrow> P (Least P)"
  1192   by (erule exE) (erule LeastI)
  1193 
  1194 lemma LeastI2:
  1195   "P a \<Longrightarrow> (\<And>x. P x \<Longrightarrow> Q x) \<Longrightarrow> Q (Least P)"
  1196   by (blast intro: LeastI)
  1197 
  1198 lemma LeastI2_ex:
  1199   "\<exists>a. P a \<Longrightarrow> (\<And>x. P x \<Longrightarrow> Q x) \<Longrightarrow> Q (Least P)"
  1200   by (blast intro: LeastI_ex)
  1201 
  1202 lemma LeastI2_wellorder:
  1203   assumes "P a"
  1204   and "\<And>a. \<lbrakk> P a; \<forall>b. P b \<longrightarrow> a \<le> b \<rbrakk> \<Longrightarrow> Q a"
  1205   shows "Q (Least P)"
  1206 proof (rule LeastI2_order)
  1207   show "P (Least P)" using `P a` by (rule LeastI)
  1208 next
  1209   fix y assume "P y" thus "Least P \<le> y" by (rule Least_le)
  1210 next
  1211   fix x assume "P x" "\<forall>y. P y \<longrightarrow> x \<le> y" thus "Q x" by (rule assms(2))
  1212 qed
  1213 
  1214 lemma not_less_Least: "k < (LEAST x. P x) \<Longrightarrow> \<not> P k"
  1215 apply (simp (no_asm_use) add: not_le [symmetric])
  1216 apply (erule contrapos_nn)
  1217 apply (erule Least_le)
  1218 done
  1219 
  1220 end
  1221 
  1222 
  1223 subsection {* Order on @{typ bool} *}
  1224 
  1225 instantiation bool :: "{bot, top, linorder}"
  1226 begin
  1227 
  1228 definition
  1229   le_bool_def [simp]: "P \<le> Q \<longleftrightarrow> P \<longrightarrow> Q"
  1230 
  1231 definition
  1232   [simp]: "(P\<Colon>bool) < Q \<longleftrightarrow> \<not> P \<and> Q"
  1233 
  1234 definition
  1235   [simp]: "\<bottom> \<longleftrightarrow> False"
  1236 
  1237 definition
  1238   [simp]: "\<top> \<longleftrightarrow> True"
  1239 
  1240 instance proof
  1241 qed auto
  1242 
  1243 end
  1244 
  1245 lemma le_boolI: "(P \<Longrightarrow> Q) \<Longrightarrow> P \<le> Q"
  1246   by simp
  1247 
  1248 lemma le_boolI': "P \<longrightarrow> Q \<Longrightarrow> P \<le> Q"
  1249   by simp
  1250 
  1251 lemma le_boolE: "P \<le> Q \<Longrightarrow> P \<Longrightarrow> (Q \<Longrightarrow> R) \<Longrightarrow> R"
  1252   by simp
  1253 
  1254 lemma le_boolD: "P \<le> Q \<Longrightarrow> P \<longrightarrow> Q"
  1255   by simp
  1256 
  1257 lemma bot_boolE: "\<bottom> \<Longrightarrow> P"
  1258   by simp
  1259 
  1260 lemma top_boolI: \<top>
  1261   by simp
  1262 
  1263 lemma [code]:
  1264   "False \<le> b \<longleftrightarrow> True"
  1265   "True \<le> b \<longleftrightarrow> b"
  1266   "False < b \<longleftrightarrow> b"
  1267   "True < b \<longleftrightarrow> False"
  1268   by simp_all
  1269 
  1270 
  1271 subsection {* Order on @{typ "_ \<Rightarrow> _"} *}
  1272 
  1273 instantiation "fun" :: (type, ord) ord
  1274 begin
  1275 
  1276 definition
  1277   le_fun_def: "f \<le> g \<longleftrightarrow> (\<forall>x. f x \<le> g x)"
  1278 
  1279 definition
  1280   "(f\<Colon>'a \<Rightarrow> 'b) < g \<longleftrightarrow> f \<le> g \<and> \<not> (g \<le> f)"
  1281 
  1282 instance ..
  1283 
  1284 end
  1285 
  1286 instance "fun" :: (type, preorder) preorder proof
  1287 qed (auto simp add: le_fun_def less_fun_def
  1288   intro: order_trans antisym)
  1289 
  1290 instance "fun" :: (type, order) order proof
  1291 qed (auto simp add: le_fun_def intro: antisym)
  1292 
  1293 instantiation "fun" :: (type, bot) bot
  1294 begin
  1295 
  1296 definition
  1297   "\<bottom> = (\<lambda>x. \<bottom>)"
  1298 
  1299 lemma bot_apply [simp] (* CANDIDATE [code] *):
  1300   "\<bottom> x = \<bottom>"
  1301   by (simp add: bot_fun_def)
  1302 
  1303 instance proof
  1304 qed (simp add: le_fun_def)
  1305 
  1306 end
  1307 
  1308 instantiation "fun" :: (type, top) top
  1309 begin
  1310 
  1311 definition
  1312   [no_atp]: "\<top> = (\<lambda>x. \<top>)"
  1313 
  1314 lemma top_apply [simp] (* CANDIDATE [code] *):
  1315   "\<top> x = \<top>"
  1316   by (simp add: top_fun_def)
  1317 
  1318 instance proof
  1319 qed (simp add: le_fun_def)
  1320 
  1321 end
  1322 
  1323 lemma le_funI: "(\<And>x. f x \<le> g x) \<Longrightarrow> f \<le> g"
  1324   unfolding le_fun_def by simp
  1325 
  1326 lemma le_funE: "f \<le> g \<Longrightarrow> (f x \<le> g x \<Longrightarrow> P) \<Longrightarrow> P"
  1327   unfolding le_fun_def by simp
  1328 
  1329 lemma le_funD: "f \<le> g \<Longrightarrow> f x \<le> g x"
  1330   unfolding le_fun_def by simp
  1331 
  1332 
  1333 subsection {* Order on unary and binary predicates *}
  1334 
  1335 lemma predicate1I:
  1336   assumes PQ: "\<And>x. P x \<Longrightarrow> Q x"
  1337   shows "P \<le> Q"
  1338   apply (rule le_funI)
  1339   apply (rule le_boolI)
  1340   apply (rule PQ)
  1341   apply assumption
  1342   done
  1343 
  1344 lemma predicate1D:
  1345   "P \<le> Q \<Longrightarrow> P x \<Longrightarrow> Q x"
  1346   apply (erule le_funE)
  1347   apply (erule le_boolE)
  1348   apply assumption+
  1349   done
  1350 
  1351 lemma rev_predicate1D:
  1352   "P x \<Longrightarrow> P \<le> Q \<Longrightarrow> Q x"
  1353   by (rule predicate1D)
  1354 
  1355 lemma predicate2I:
  1356   assumes PQ: "\<And>x y. P x y \<Longrightarrow> Q x y"
  1357   shows "P \<le> Q"
  1358   apply (rule le_funI)+
  1359   apply (rule le_boolI)
  1360   apply (rule PQ)
  1361   apply assumption
  1362   done
  1363 
  1364 lemma predicate2D:
  1365   "P \<le> Q \<Longrightarrow> P x y \<Longrightarrow> Q x y"
  1366   apply (erule le_funE)+
  1367   apply (erule le_boolE)
  1368   apply assumption+
  1369   done
  1370 
  1371 lemma rev_predicate2D:
  1372   "P x y \<Longrightarrow> P \<le> Q \<Longrightarrow> Q x y"
  1373   by (rule predicate2D)
  1374 
  1375 lemma bot1E [no_atp]: "\<bottom> x \<Longrightarrow> P"
  1376   by (simp add: bot_fun_def)
  1377 
  1378 lemma bot2E: "\<bottom> x y \<Longrightarrow> P"
  1379   by (simp add: bot_fun_def)
  1380 
  1381 lemma top1I: "\<top> x"
  1382   by (simp add: top_fun_def)
  1383 
  1384 lemma top2I: "\<top> x y"
  1385   by (simp add: top_fun_def)
  1386 
  1387 
  1388 subsection {* Name duplicates *}
  1389 
  1390 lemmas order_eq_refl = preorder_class.eq_refl
  1391 lemmas order_less_irrefl = preorder_class.less_irrefl
  1392 lemmas order_less_imp_le = preorder_class.less_imp_le
  1393 lemmas order_less_not_sym = preorder_class.less_not_sym
  1394 lemmas order_less_asym = preorder_class.less_asym
  1395 lemmas order_less_trans = preorder_class.less_trans
  1396 lemmas order_le_less_trans = preorder_class.le_less_trans
  1397 lemmas order_less_le_trans = preorder_class.less_le_trans
  1398 lemmas order_less_imp_not_less = preorder_class.less_imp_not_less
  1399 lemmas order_less_imp_triv = preorder_class.less_imp_triv
  1400 lemmas order_less_asym' = preorder_class.less_asym'
  1401 
  1402 lemmas order_less_le = order_class.less_le
  1403 lemmas order_le_less = order_class.le_less
  1404 lemmas order_le_imp_less_or_eq = order_class.le_imp_less_or_eq
  1405 lemmas order_less_imp_not_eq = order_class.less_imp_not_eq
  1406 lemmas order_less_imp_not_eq2 = order_class.less_imp_not_eq2
  1407 lemmas order_neq_le_trans = order_class.neq_le_trans
  1408 lemmas order_le_neq_trans = order_class.le_neq_trans
  1409 lemmas order_antisym = order_class.antisym
  1410 lemmas order_eq_iff = order_class.eq_iff
  1411 lemmas order_antisym_conv = order_class.antisym_conv
  1412 
  1413 lemmas linorder_linear = linorder_class.linear
  1414 lemmas linorder_less_linear = linorder_class.less_linear
  1415 lemmas linorder_le_less_linear = linorder_class.le_less_linear
  1416 lemmas linorder_le_cases = linorder_class.le_cases
  1417 lemmas linorder_not_less = linorder_class.not_less
  1418 lemmas linorder_not_le = linorder_class.not_le
  1419 lemmas linorder_neq_iff = linorder_class.neq_iff
  1420 lemmas linorder_neqE = linorder_class.neqE
  1421 lemmas linorder_antisym_conv1 = linorder_class.antisym_conv1
  1422 lemmas linorder_antisym_conv2 = linorder_class.antisym_conv2
  1423 lemmas linorder_antisym_conv3 = linorder_class.antisym_conv3
  1424 
  1425 end