src/HOL/Probability/Infinite_Product_Measure.thy
author immler
Tue Nov 27 11:29:47 2012 +0100 (2012-11-27)
changeset 50244 de72bbe42190
parent 50123 69b35a75caf3
child 50252 4aa34bd43228
permissions -rw-r--r--
qualified interpretation of sigma_algebra, to avoid name clashes
     1 (*  Title:      HOL/Probability/Infinite_Product_Measure.thy
     2     Author:     Johannes Hölzl, TU München
     3 *)
     4 
     5 header {*Infinite Product Measure*}
     6 
     7 theory Infinite_Product_Measure
     8   imports Probability_Measure Caratheodory Projective_Family
     9 begin
    10 
    11 lemma (in product_prob_space) emeasure_PiM_emb_not_empty:
    12   assumes X: "J \<noteq> {}" "J \<subseteq> I" "finite J" "\<forall>i\<in>J. X i \<in> sets (M i)"
    13   shows "emeasure (Pi\<^isub>M I M) (emb I J (Pi\<^isub>E J X)) = emeasure (Pi\<^isub>M J M) (Pi\<^isub>E J X)"
    14 proof cases
    15   assume "finite I" with X show ?thesis by simp
    16 next
    17   let ?\<Omega> = "\<Pi>\<^isub>E i\<in>I. space (M i)"
    18   let ?G = generator
    19   assume "\<not> finite I"
    20   then have I_not_empty: "I \<noteq> {}" by auto
    21   interpret G!: algebra ?\<Omega> generator by (rule algebra_generator) fact
    22   note \<mu>G_mono =
    23     G.additive_increasing[OF positive_\<mu>G[OF I_not_empty] additive_\<mu>G[OF I_not_empty], THEN increasingD]
    24 
    25   { fix Z J assume J: "J \<noteq> {}" "finite J" "J \<subseteq> I" and Z: "Z \<in> ?G"
    26 
    27     from `infinite I` `finite J` obtain k where k: "k \<in> I" "k \<notin> J"
    28       by (metis rev_finite_subset subsetI)
    29     moreover from Z guess K' X' by (rule generatorE)
    30     moreover def K \<equiv> "insert k K'"
    31     moreover def X \<equiv> "emb K K' X'"
    32     ultimately have K: "K \<noteq> {}" "finite K" "K \<subseteq> I" "X \<in> sets (Pi\<^isub>M K M)" "Z = emb I K X"
    33       "K - J \<noteq> {}" "K - J \<subseteq> I" "\<mu>G Z = emeasure (Pi\<^isub>M K M) X"
    34       by (auto simp: subset_insertI)
    35     let ?M = "\<lambda>y. (\<lambda>x. merge J (K - J) (y, x)) -` emb (J \<union> K) K X \<inter> space (Pi\<^isub>M (K - J) M)"
    36     { fix y assume y: "y \<in> space (Pi\<^isub>M J M)"
    37       note * = merge_emb[OF `K \<subseteq> I` `J \<subseteq> I` y, of X]
    38       moreover
    39       have **: "?M y \<in> sets (Pi\<^isub>M (K - J) M)"
    40         using J K y by (intro merge_sets) auto
    41       ultimately
    42       have ***: "((\<lambda>x. merge J (I - J) (y, x)) -` Z \<inter> space (Pi\<^isub>M I M)) \<in> ?G"
    43         using J K by (intro generatorI) auto
    44       have "\<mu>G ((\<lambda>x. merge J (I - J) (y, x)) -` emb I K X \<inter> space (Pi\<^isub>M I M)) = emeasure (Pi\<^isub>M (K - J) M) (?M y)"
    45         unfolding * using K J by (subst \<mu>G_eq[OF _ _ _ **]) auto
    46       note * ** *** this }
    47     note merge_in_G = this
    48 
    49     have "finite (K - J)" using K by auto
    50 
    51     interpret J: finite_product_prob_space M J by default fact+
    52     interpret KmJ: finite_product_prob_space M "K - J" by default fact+
    53 
    54     have "\<mu>G Z = emeasure (Pi\<^isub>M (J \<union> (K - J)) M) (emb (J \<union> (K - J)) K X)"
    55       using K J by simp
    56     also have "\<dots> = (\<integral>\<^isup>+ x. emeasure (Pi\<^isub>M (K - J) M) (?M x) \<partial>Pi\<^isub>M J M)"
    57       using K J by (subst emeasure_fold_integral) auto
    58     also have "\<dots> = (\<integral>\<^isup>+ y. \<mu>G ((\<lambda>x. merge J (I - J) (y, x)) -` Z \<inter> space (Pi\<^isub>M I M)) \<partial>Pi\<^isub>M J M)"
    59       (is "_ = (\<integral>\<^isup>+x. \<mu>G (?MZ x) \<partial>Pi\<^isub>M J M)")
    60     proof (intro positive_integral_cong)
    61       fix x assume x: "x \<in> space (Pi\<^isub>M J M)"
    62       with K merge_in_G(2)[OF this]
    63       show "emeasure (Pi\<^isub>M (K - J) M) (?M x) = \<mu>G (?MZ x)"
    64         unfolding `Z = emb I K X` merge_in_G(1)[OF x] by (subst \<mu>G_eq) auto
    65     qed
    66     finally have fold: "\<mu>G Z = (\<integral>\<^isup>+x. \<mu>G (?MZ x) \<partial>Pi\<^isub>M J M)" .
    67 
    68     { fix x assume x: "x \<in> space (Pi\<^isub>M J M)"
    69       then have "\<mu>G (?MZ x) \<le> 1"
    70         unfolding merge_in_G(4)[OF x] `Z = emb I K X`
    71         by (intro KmJ.measure_le_1 merge_in_G(2)[OF x]) }
    72     note le_1 = this
    73 
    74     let ?q = "\<lambda>y. \<mu>G ((\<lambda>x. merge J (I - J) (y,x)) -` Z \<inter> space (Pi\<^isub>M I M))"
    75     have "?q \<in> borel_measurable (Pi\<^isub>M J M)"
    76       unfolding `Z = emb I K X` using J K merge_in_G(3)
    77       by (simp add: merge_in_G  \<mu>G_eq emeasure_fold_measurable cong: measurable_cong)
    78     note this fold le_1 merge_in_G(3) }
    79   note fold = this
    80 
    81   have "\<exists>\<mu>. (\<forall>s\<in>?G. \<mu> s = \<mu>G s) \<and> measure_space ?\<Omega> (sigma_sets ?\<Omega> ?G) \<mu>"
    82   proof (rule G.caratheodory_empty_continuous[OF positive_\<mu>G additive_\<mu>G])
    83     fix A assume "A \<in> ?G"
    84     with generatorE guess J X . note JX = this
    85     interpret JK: finite_product_prob_space M J by default fact+ 
    86     from JX show "\<mu>G A \<noteq> \<infinity>" by simp
    87   next
    88     fix A assume A: "range A \<subseteq> ?G" "decseq A" "(\<Inter>i. A i) = {}"
    89     then have "decseq (\<lambda>i. \<mu>G (A i))"
    90       by (auto intro!: \<mu>G_mono simp: decseq_def)
    91     moreover
    92     have "(INF i. \<mu>G (A i)) = 0"
    93     proof (rule ccontr)
    94       assume "(INF i. \<mu>G (A i)) \<noteq> 0" (is "?a \<noteq> 0")
    95       moreover have "0 \<le> ?a"
    96         using A positive_\<mu>G[OF I_not_empty] by (auto intro!: INF_greatest simp: positive_def)
    97       ultimately have "0 < ?a" by auto
    98 
    99       have "\<forall>n. \<exists>J X. J \<noteq> {} \<and> finite J \<and> J \<subseteq> I \<and> X \<in> sets (Pi\<^isub>M J M) \<and> A n = emb I J X \<and> \<mu>G (A n) = emeasure (limP J M (\<lambda>J. (Pi\<^isub>M J M))) X"
   100         using A by (intro allI generator_Ex) auto
   101       then obtain J' X' where J': "\<And>n. J' n \<noteq> {}" "\<And>n. finite (J' n)" "\<And>n. J' n \<subseteq> I" "\<And>n. X' n \<in> sets (Pi\<^isub>M (J' n) M)"
   102         and A': "\<And>n. A n = emb I (J' n) (X' n)"
   103         unfolding choice_iff by blast
   104       moreover def J \<equiv> "\<lambda>n. (\<Union>i\<le>n. J' i)"
   105       moreover def X \<equiv> "\<lambda>n. emb (J n) (J' n) (X' n)"
   106       ultimately have J: "\<And>n. J n \<noteq> {}" "\<And>n. finite (J n)" "\<And>n. J n \<subseteq> I" "\<And>n. X n \<in> sets (Pi\<^isub>M (J n) M)"
   107         by auto
   108       with A' have A_eq: "\<And>n. A n = emb I (J n) (X n)" "\<And>n. A n \<in> ?G"
   109         unfolding J_def X_def by (subst prod_emb_trans) (insert A, auto)
   110 
   111       have J_mono: "\<And>n m. n \<le> m \<Longrightarrow> J n \<subseteq> J m"
   112         unfolding J_def by force
   113 
   114       interpret J: finite_product_prob_space M "J i" for i by default fact+
   115 
   116       have a_le_1: "?a \<le> 1"
   117         using \<mu>G_spec[of "J 0" "A 0" "X 0"] J A_eq
   118         by (auto intro!: INF_lower2[of 0] J.measure_le_1)
   119 
   120       let ?M = "\<lambda>K Z y. (\<lambda>x. merge K (I - K) (y, x)) -` Z \<inter> space (Pi\<^isub>M I M)"
   121 
   122       { fix Z k assume Z: "range Z \<subseteq> ?G" "decseq Z" "\<forall>n. ?a / 2^k \<le> \<mu>G (Z n)"
   123         then have Z_sets: "\<And>n. Z n \<in> ?G" by auto
   124         fix J' assume J': "J' \<noteq> {}" "finite J'" "J' \<subseteq> I"
   125         interpret J': finite_product_prob_space M J' by default fact+
   126 
   127         let ?q = "\<lambda>n y. \<mu>G (?M J' (Z n) y)"
   128         let ?Q = "\<lambda>n. ?q n -` {?a / 2^(k+1) ..} \<inter> space (Pi\<^isub>M J' M)"
   129         { fix n
   130           have "?q n \<in> borel_measurable (Pi\<^isub>M J' M)"
   131             using Z J' by (intro fold(1)) auto
   132           then have "?Q n \<in> sets (Pi\<^isub>M J' M)"
   133             by (rule measurable_sets) auto }
   134         note Q_sets = this
   135 
   136         have "?a / 2^(k+1) \<le> (INF n. emeasure (Pi\<^isub>M J' M) (?Q n))"
   137         proof (intro INF_greatest)
   138           fix n
   139           have "?a / 2^k \<le> \<mu>G (Z n)" using Z by auto
   140           also have "\<dots> \<le> (\<integral>\<^isup>+ x. indicator (?Q n) x + ?a / 2^(k+1) \<partial>Pi\<^isub>M J' M)"
   141             unfolding fold(2)[OF J' `Z n \<in> ?G`]
   142           proof (intro positive_integral_mono)
   143             fix x assume x: "x \<in> space (Pi\<^isub>M J' M)"
   144             then have "?q n x \<le> 1 + 0"
   145               using J' Z fold(3) Z_sets by auto
   146             also have "\<dots> \<le> 1 + ?a / 2^(k+1)"
   147               using `0 < ?a` by (intro add_mono) auto
   148             finally have "?q n x \<le> 1 + ?a / 2^(k+1)" .
   149             with x show "?q n x \<le> indicator (?Q n) x + ?a / 2^(k+1)"
   150               by (auto split: split_indicator simp del: power_Suc)
   151           qed
   152           also have "\<dots> = emeasure (Pi\<^isub>M J' M) (?Q n) + ?a / 2^(k+1)"
   153             using `0 \<le> ?a` Q_sets J'.emeasure_space_1
   154             by (subst positive_integral_add) auto
   155           finally show "?a / 2^(k+1) \<le> emeasure (Pi\<^isub>M J' M) (?Q n)" using `?a \<le> 1`
   156             by (cases rule: ereal2_cases[of ?a "emeasure (Pi\<^isub>M J' M) (?Q n)"])
   157                (auto simp: field_simps)
   158         qed
   159         also have "\<dots> = emeasure (Pi\<^isub>M J' M) (\<Inter>n. ?Q n)"
   160         proof (intro INF_emeasure_decseq)
   161           show "range ?Q \<subseteq> sets (Pi\<^isub>M J' M)" using Q_sets by auto
   162           show "decseq ?Q"
   163             unfolding decseq_def
   164           proof (safe intro!: vimageI[OF refl])
   165             fix m n :: nat assume "m \<le> n"
   166             fix x assume x: "x \<in> space (Pi\<^isub>M J' M)"
   167             assume "?a / 2^(k+1) \<le> ?q n x"
   168             also have "?q n x \<le> ?q m x"
   169             proof (rule \<mu>G_mono)
   170               from fold(4)[OF J', OF Z_sets x]
   171               show "?M J' (Z n) x \<in> ?G" "?M J' (Z m) x \<in> ?G" by auto
   172               show "?M J' (Z n) x \<subseteq> ?M J' (Z m) x"
   173                 using `decseq Z`[THEN decseqD, OF `m \<le> n`] by auto
   174             qed
   175             finally show "?a / 2^(k+1) \<le> ?q m x" .
   176           qed
   177         qed simp
   178         finally have "(\<Inter>n. ?Q n) \<noteq> {}"
   179           using `0 < ?a` `?a \<le> 1` by (cases ?a) (auto simp: divide_le_0_iff power_le_zero_eq)
   180         then have "\<exists>w\<in>space (Pi\<^isub>M J' M). \<forall>n. ?a / 2 ^ (k + 1) \<le> ?q n w" by auto }
   181       note Ex_w = this
   182 
   183       let ?q = "\<lambda>k n y. \<mu>G (?M (J k) (A n) y)"
   184 
   185       have "\<forall>n. ?a / 2 ^ 0 \<le> \<mu>G (A n)" by (auto intro: INF_lower)
   186       from Ex_w[OF A(1,2) this J(1-3), of 0] guess w0 .. note w0 = this
   187 
   188       let ?P =
   189         "\<lambda>k wk w. w \<in> space (Pi\<^isub>M (J (Suc k)) M) \<and> restrict w (J k) = wk \<and>
   190           (\<forall>n. ?a / 2 ^ (Suc k + 1) \<le> ?q (Suc k) n w)"
   191       def w \<equiv> "nat_rec w0 (\<lambda>k wk. Eps (?P k wk))"
   192 
   193       { fix k have w: "w k \<in> space (Pi\<^isub>M (J k) M) \<and>
   194           (\<forall>n. ?a / 2 ^ (k + 1) \<le> ?q k n (w k)) \<and> (k \<noteq> 0 \<longrightarrow> restrict (w k) (J (k - 1)) = w (k - 1))"
   195         proof (induct k)
   196           case 0 with w0 show ?case
   197             unfolding w_def nat_rec_0 by auto
   198         next
   199           case (Suc k)
   200           then have wk: "w k \<in> space (Pi\<^isub>M (J k) M)" by auto
   201           have "\<exists>w'. ?P k (w k) w'"
   202           proof cases
   203             assume [simp]: "J k = J (Suc k)"
   204             show ?thesis
   205             proof (intro exI[of _ "w k"] conjI allI)
   206               fix n
   207               have "?a / 2 ^ (Suc k + 1) \<le> ?a / 2 ^ (k + 1)"
   208                 using `0 < ?a` `?a \<le> 1` by (cases ?a) (auto simp: field_simps)
   209               also have "\<dots> \<le> ?q k n (w k)" using Suc by auto
   210               finally show "?a / 2 ^ (Suc k + 1) \<le> ?q (Suc k) n (w k)" by simp
   211             next
   212               show "w k \<in> space (Pi\<^isub>M (J (Suc k)) M)"
   213                 using Suc by simp
   214               then show "restrict (w k) (J k) = w k"
   215                 by (simp add: extensional_restrict space_PiM)
   216             qed
   217           next
   218             assume "J k \<noteq> J (Suc k)"
   219             with J_mono[of k "Suc k"] have "J (Suc k) - J k \<noteq> {}" (is "?D \<noteq> {}") by auto
   220             have "range (\<lambda>n. ?M (J k) (A n) (w k)) \<subseteq> ?G"
   221               "decseq (\<lambda>n. ?M (J k) (A n) (w k))"
   222               "\<forall>n. ?a / 2 ^ (k + 1) \<le> \<mu>G (?M (J k) (A n) (w k))"
   223               using `decseq A` fold(4)[OF J(1-3) A_eq(2), of "w k" k] Suc
   224               by (auto simp: decseq_def)
   225             from Ex_w[OF this `?D \<noteq> {}`] J[of "Suc k"]
   226             obtain w' where w': "w' \<in> space (Pi\<^isub>M ?D M)"
   227               "\<forall>n. ?a / 2 ^ (Suc k + 1) \<le> \<mu>G (?M ?D (?M (J k) (A n) (w k)) w')" by auto
   228             let ?w = "merge (J k) ?D (w k, w')"
   229             have [simp]: "\<And>x. merge (J k) (I - J k) (w k, merge ?D (I - ?D) (w', x)) =
   230               merge (J (Suc k)) (I - (J (Suc k))) (?w, x)"
   231               using J(3)[of "Suc k"] J(3)[of k] J_mono[of k "Suc k"]
   232               by (auto intro!: ext split: split_merge)
   233             have *: "\<And>n. ?M ?D (?M (J k) (A n) (w k)) w' = ?M (J (Suc k)) (A n) ?w"
   234               using w'(1) J(3)[of "Suc k"]
   235               by (auto simp: space_PiM split: split_merge intro!: extensional_merge_sub) force+
   236             show ?thesis
   237               using w' J_mono[of k "Suc k"] wk unfolding *
   238               by (intro exI[of _ ?w])
   239                  (auto split: split_merge intro!: extensional_merge_sub ext simp: space_PiM PiE_iff)
   240           qed
   241           then have "?P k (w k) (w (Suc k))"
   242             unfolding w_def nat_rec_Suc unfolding w_def[symmetric]
   243             by (rule someI_ex)
   244           then show ?case by auto
   245         qed
   246         moreover
   247         then have "w k \<in> space (Pi\<^isub>M (J k) M)" by auto
   248         moreover
   249         from w have "?a / 2 ^ (k + 1) \<le> ?q k k (w k)" by auto
   250         then have "?M (J k) (A k) (w k) \<noteq> {}"
   251           using positive_\<mu>G[OF I_not_empty, unfolded positive_def] `0 < ?a` `?a \<le> 1`
   252           by (cases ?a) (auto simp: divide_le_0_iff power_le_zero_eq)
   253         then obtain x where "x \<in> ?M (J k) (A k) (w k)" by auto
   254         then have "merge (J k) (I - J k) (w k, x) \<in> A k" by auto
   255         then have "\<exists>x\<in>A k. restrict x (J k) = w k"
   256           using `w k \<in> space (Pi\<^isub>M (J k) M)`
   257           by (intro rev_bexI) (auto intro!: ext simp: extensional_def space_PiM)
   258         ultimately have "w k \<in> space (Pi\<^isub>M (J k) M)"
   259           "\<exists>x\<in>A k. restrict x (J k) = w k"
   260           "k \<noteq> 0 \<Longrightarrow> restrict (w k) (J (k - 1)) = w (k - 1)"
   261           by auto }
   262       note w = this
   263 
   264       { fix k l i assume "k \<le> l" "i \<in> J k"
   265         { fix l have "w k i = w (k + l) i"
   266           proof (induct l)
   267             case (Suc l)
   268             from `i \<in> J k` J_mono[of k "k + l"] have "i \<in> J (k + l)" by auto
   269             with w(3)[of "k + Suc l"]
   270             have "w (k + l) i = w (k + Suc l) i"
   271               by (auto simp: restrict_def fun_eq_iff split: split_if_asm)
   272             with Suc show ?case by simp
   273           qed simp }
   274         from this[of "l - k"] `k \<le> l` have "w l i = w k i" by simp }
   275       note w_mono = this
   276 
   277       def w' \<equiv> "\<lambda>i. if i \<in> (\<Union>k. J k) then w (LEAST k. i \<in> J k) i else if i \<in> I then (SOME x. x \<in> space (M i)) else undefined"
   278       { fix i k assume k: "i \<in> J k"
   279         have "w k i = w (LEAST k. i \<in> J k) i"
   280           by (intro w_mono Least_le k LeastI[of _ k])
   281         then have "w' i = w k i"
   282           unfolding w'_def using k by auto }
   283       note w'_eq = this
   284       have w'_simps1: "\<And>i. i \<notin> I \<Longrightarrow> w' i = undefined"
   285         using J by (auto simp: w'_def)
   286       have w'_simps2: "\<And>i. i \<notin> (\<Union>k. J k) \<Longrightarrow> i \<in> I \<Longrightarrow> w' i \<in> space (M i)"
   287         using J by (auto simp: w'_def intro!: someI_ex[OF M.not_empty[unfolded ex_in_conv[symmetric]]])
   288       { fix i assume "i \<in> I" then have "w' i \<in> space (M i)"
   289           using w(1) by (cases "i \<in> (\<Union>k. J k)") (force simp: w'_simps2 w'_eq space_PiM)+ }
   290       note w'_simps[simp] = w'_eq w'_simps1 w'_simps2 this
   291 
   292       have w': "w' \<in> space (Pi\<^isub>M I M)"
   293         using w(1) by (auto simp add: Pi_iff extensional_def space_PiM)
   294 
   295       { fix n
   296         have "restrict w' (J n) = w n" using w(1)[of n]
   297           by (auto simp add: fun_eq_iff space_PiM)
   298         with w[of n] obtain x where "x \<in> A n" "restrict x (J n) = restrict w' (J n)" by auto
   299         then have "w' \<in> A n" unfolding A_eq using w' by (auto simp: prod_emb_def space_PiM) }
   300       then have "w' \<in> (\<Inter>i. A i)" by auto
   301       with `(\<Inter>i. A i) = {}` show False by auto
   302     qed
   303     ultimately show "(\<lambda>i. \<mu>G (A i)) ----> 0"
   304       using LIMSEQ_ereal_INFI[of "\<lambda>i. \<mu>G (A i)"] by simp
   305   qed fact+
   306   then guess \<mu> .. note \<mu> = this
   307   show ?thesis
   308   proof (subst emeasure_extend_measure_Pair[OF PiM_def, of I M \<mu> J X])
   309     from assms show "(J \<noteq> {} \<or> I = {}) \<and> finite J \<and> J \<subseteq> I \<and> X \<in> (\<Pi> j\<in>J. sets (M j))"
   310       by (simp add: Pi_iff)
   311   next
   312     fix J X assume J: "(J \<noteq> {} \<or> I = {}) \<and> finite J \<and> J \<subseteq> I \<and> X \<in> (\<Pi> j\<in>J. sets (M j))"
   313     then show "emb I J (Pi\<^isub>E J X) \<in> Pow (\<Pi>\<^isub>E i\<in>I. space (M i))"
   314       by (auto simp: Pi_iff prod_emb_def dest: sets.sets_into_space)
   315     have "emb I J (Pi\<^isub>E J X) \<in> generator"
   316       using J `I \<noteq> {}` by (intro generatorI') (auto simp: Pi_iff)
   317     then have "\<mu> (emb I J (Pi\<^isub>E J X)) = \<mu>G (emb I J (Pi\<^isub>E J X))"
   318       using \<mu> by simp
   319     also have "\<dots> = (\<Prod> j\<in>J. if j \<in> J then emeasure (M j) (X j) else emeasure (M j) (space (M j)))"
   320       using J  `I \<noteq> {}` by (subst \<mu>G_spec[OF _ _ _ refl]) (auto simp: emeasure_PiM Pi_iff)
   321     also have "\<dots> = (\<Prod>j\<in>J \<union> {i \<in> I. emeasure (M i) (space (M i)) \<noteq> 1}.
   322       if j \<in> J then emeasure (M j) (X j) else emeasure (M j) (space (M j)))"
   323       using J `I \<noteq> {}` by (intro setprod_mono_one_right) (auto simp: M.emeasure_space_1)
   324     finally show "\<mu> (emb I J (Pi\<^isub>E J X)) = \<dots>" .
   325   next
   326     let ?F = "\<lambda>j. if j \<in> J then emeasure (M j) (X j) else emeasure (M j) (space (M j))"
   327     have "(\<Prod>j\<in>J \<union> {i \<in> I. emeasure (M i) (space (M i)) \<noteq> 1}. ?F j) = (\<Prod>j\<in>J. ?F j)"
   328       using X `I \<noteq> {}` by (intro setprod_mono_one_right) (auto simp: M.emeasure_space_1)
   329     then show "(\<Prod>j\<in>J \<union> {i \<in> I. emeasure (M i) (space (M i)) \<noteq> 1}. ?F j) =
   330       emeasure (Pi\<^isub>M J M) (Pi\<^isub>E J X)"
   331       using X by (auto simp add: emeasure_PiM) 
   332   next
   333     show "positive (sets (Pi\<^isub>M I M)) \<mu>" "countably_additive (sets (Pi\<^isub>M I M)) \<mu>"
   334       using \<mu> unfolding sets_PiM_generator by (auto simp: measure_space_def)
   335   qed
   336 qed
   337 
   338 sublocale product_prob_space \<subseteq> P: prob_space "Pi\<^isub>M I M"
   339 proof
   340   show "emeasure (Pi\<^isub>M I M) (space (Pi\<^isub>M I M)) = 1"
   341   proof cases
   342     assume "I = {}" then show ?thesis by (simp add: space_PiM_empty)
   343   next
   344     assume "I \<noteq> {}"
   345     then obtain i where "i \<in> I" by auto
   346     moreover then have "emb I {i} (\<Pi>\<^isub>E i\<in>{i}. space (M i)) = (space (Pi\<^isub>M I M))"
   347       by (auto simp: prod_emb_def space_PiM)
   348     ultimately show ?thesis
   349       using emeasure_PiM_emb_not_empty[of "{i}" "\<lambda>i. space (M i)"]
   350       by (simp add: emeasure_PiM emeasure_space_1)
   351   qed
   352 qed
   353 
   354 lemma (in product_prob_space) emeasure_PiM_emb:
   355   assumes X: "J \<subseteq> I" "finite J" "\<And>i. i \<in> J \<Longrightarrow> X i \<in> sets (M i)"
   356   shows "emeasure (Pi\<^isub>M I M) (emb I J (Pi\<^isub>E J X)) = (\<Prod> i\<in>J. emeasure (M i) (X i))"
   357 proof cases
   358   assume "J = {}"
   359   moreover have "emb I {} {\<lambda>x. undefined} = space (Pi\<^isub>M I M)"
   360     by (auto simp: space_PiM prod_emb_def)
   361   ultimately show ?thesis
   362     by (simp add: space_PiM_empty P.emeasure_space_1)
   363 next
   364   assume "J \<noteq> {}" with X show ?thesis
   365     by (subst emeasure_PiM_emb_not_empty) (auto simp: emeasure_PiM)
   366 qed
   367 
   368 lemma (in product_prob_space) emeasure_PiM_Collect:
   369   assumes X: "J \<subseteq> I" "finite J" "\<And>i. i \<in> J \<Longrightarrow> X i \<in> sets (M i)"
   370   shows "emeasure (Pi\<^isub>M I M) {x\<in>space (Pi\<^isub>M I M). \<forall>i\<in>J. x i \<in> X i} = (\<Prod> i\<in>J. emeasure (M i) (X i))"
   371 proof -
   372   have "{x\<in>space (Pi\<^isub>M I M). \<forall>i\<in>J. x i \<in> X i} = emb I J (Pi\<^isub>E J X)"
   373     unfolding prod_emb_def using assms by (auto simp: space_PiM Pi_iff)
   374   with emeasure_PiM_emb[OF assms] show ?thesis by simp
   375 qed
   376 
   377 lemma (in product_prob_space) emeasure_PiM_Collect_single:
   378   assumes X: "i \<in> I" "A \<in> sets (M i)"
   379   shows "emeasure (Pi\<^isub>M I M) {x\<in>space (Pi\<^isub>M I M). x i \<in> A} = emeasure (M i) A"
   380   using emeasure_PiM_Collect[of "{i}" "\<lambda>i. A"] assms
   381   by simp
   382 
   383 lemma (in product_prob_space) measure_PiM_emb:
   384   assumes "J \<subseteq> I" "finite J" "\<And>i. i \<in> J \<Longrightarrow> X i \<in> sets (M i)"
   385   shows "measure (PiM I M) (emb I J (Pi\<^isub>E J X)) = (\<Prod> i\<in>J. measure (M i) (X i))"
   386   using emeasure_PiM_emb[OF assms]
   387   unfolding emeasure_eq_measure M.emeasure_eq_measure by (simp add: setprod_ereal)
   388 
   389 lemma sets_Collect_single':
   390   "i \<in> I \<Longrightarrow> {x\<in>space (M i). P x} \<in> sets (M i) \<Longrightarrow> {x\<in>space (PiM I M). P (x i)} \<in> sets (PiM I M)"
   391   using sets_Collect_single[of i I "{x\<in>space (M i). P x}" M]
   392   by (simp add: space_PiM PiE_iff cong: conj_cong)
   393 
   394 lemma (in finite_product_prob_space) finite_measure_PiM_emb:
   395   "(\<And>i. i \<in> I \<Longrightarrow> A i \<in> sets (M i)) \<Longrightarrow> measure (PiM I M) (Pi\<^isub>E I A) = (\<Prod>i\<in>I. measure (M i) (A i))"
   396   using measure_PiM_emb[of I A] finite_index prod_emb_PiE_same_index[OF sets.sets_into_space, of I A M]
   397   by auto
   398 
   399 lemma (in product_prob_space) PiM_component:
   400   assumes "i \<in> I"
   401   shows "distr (PiM I M) (M i) (\<lambda>\<omega>. \<omega> i) = M i"
   402 proof (rule measure_eqI[symmetric])
   403   fix A assume "A \<in> sets (M i)"
   404   moreover have "((\<lambda>\<omega>. \<omega> i) -` A \<inter> space (PiM I M)) = {x\<in>space (PiM I M). x i \<in> A}"
   405     by auto
   406   ultimately show "emeasure (M i) A = emeasure (distr (PiM I M) (M i) (\<lambda>\<omega>. \<omega> i)) A"
   407     by (auto simp: `i\<in>I` emeasure_distr measurable_component_singleton emeasure_PiM_Collect_single)
   408 qed simp
   409 
   410 lemma (in product_prob_space) PiM_eq:
   411   assumes "I \<noteq> {}"
   412   assumes "sets M' = sets (PiM I M)"
   413   assumes eq: "\<And>J F. finite J \<Longrightarrow> J \<subseteq> I \<Longrightarrow> (\<And>j. j \<in> J \<Longrightarrow> F j \<in> sets (M j)) \<Longrightarrow>
   414     emeasure M' (prod_emb I M J (\<Pi>\<^isub>E j\<in>J. F j)) = (\<Prod>j\<in>J. emeasure (M j) (F j))"
   415   shows "M' = (PiM I M)"
   416 proof (rule measure_eqI_generator_eq[symmetric, OF Int_stable_prod_algebra prod_algebra_sets_into_space])
   417   show "sets (PiM I M) = sigma_sets (\<Pi>\<^isub>E i\<in>I. space (M i)) (prod_algebra I M)"
   418     by (rule sets_PiM)
   419   then show "sets M' = sigma_sets (\<Pi>\<^isub>E i\<in>I. space (M i)) (prod_algebra I M)"
   420     unfolding `sets M' = sets (PiM I M)` by simp
   421 
   422   def i \<equiv> "SOME i. i \<in> I"
   423   with `I \<noteq> {}` have i: "i \<in> I"
   424     by (auto intro: someI_ex)
   425 
   426   def A \<equiv> "\<lambda>n::nat. prod_emb I M {i} (\<Pi>\<^isub>E j\<in>{i}. space (M i))"
   427   then show "range A \<subseteq> prod_algebra I M"
   428     by (auto intro!: prod_algebraI i)
   429 
   430   have A_eq: "\<And>i. A i = space (PiM I M)"
   431     by (auto simp: prod_emb_def space_PiM Pi_iff A_def i)
   432   show "(\<Union>i. A i) = (\<Pi>\<^isub>E i\<in>I. space (M i))"
   433     unfolding A_eq by (auto simp: space_PiM)
   434   show "\<And>i. emeasure (PiM I M) (A i) \<noteq> \<infinity>"
   435     unfolding A_eq P.emeasure_space_1 by simp
   436 next
   437   fix X assume X: "X \<in> prod_algebra I M"
   438   then obtain J E where X: "X = prod_emb I M J (PIE j:J. E j)"
   439     and J: "finite J" "J \<subseteq> I" "\<And>j. j \<in> J \<Longrightarrow> E j \<in> sets (M j)"
   440     by (force elim!: prod_algebraE)
   441   from eq[OF J] have "emeasure M' X = (\<Prod>j\<in>J. emeasure (M j) (E j))"
   442     by (simp add: X)
   443   also have "\<dots> = emeasure (PiM I M) X"
   444     unfolding X using J by (intro emeasure_PiM_emb[symmetric]) auto
   445   finally show "emeasure (PiM I M) X = emeasure M' X" ..
   446 qed
   447 
   448 subsection {* Sequence space *}
   449 
   450 definition comb_seq :: "nat \<Rightarrow> (nat \<Rightarrow> 'a) \<Rightarrow> (nat \<Rightarrow> 'a) \<Rightarrow> (nat \<Rightarrow> 'a)" where
   451   "comb_seq i \<omega> \<omega>' j = (if j < i then \<omega> j else \<omega>' (j - i))"
   452 
   453 lemma split_comb_seq: "P (comb_seq i \<omega> \<omega>' j) \<longleftrightarrow> (j < i \<longrightarrow> P (\<omega> j)) \<and> (\<forall>k. j = i + k \<longrightarrow> P (\<omega>' k))"
   454   by (auto simp: comb_seq_def not_less)
   455 
   456 lemma split_comb_seq_asm: "P (comb_seq i \<omega> \<omega>' j) \<longleftrightarrow> \<not> ((j < i \<and> \<not> P (\<omega> j)) \<or> (\<exists>k. j = i + k \<and> \<not> P (\<omega>' k)))"
   457   by (auto simp: comb_seq_def)
   458 
   459 lemma measurable_comb_seq:
   460   "(\<lambda>(\<omega>, \<omega>'). comb_seq i \<omega> \<omega>') \<in> measurable ((\<Pi>\<^isub>M i\<in>UNIV. M) \<Otimes>\<^isub>M (\<Pi>\<^isub>M i\<in>UNIV. M)) (\<Pi>\<^isub>M i\<in>UNIV. M)"
   461 proof (rule measurable_PiM_single)
   462   show "(\<lambda>(\<omega>, \<omega>'). comb_seq i \<omega> \<omega>') \<in> space ((\<Pi>\<^isub>M i\<in>UNIV. M) \<Otimes>\<^isub>M (\<Pi>\<^isub>M i\<in>UNIV. M)) \<rightarrow> (UNIV \<rightarrow>\<^isub>E space M)"
   463     by (auto simp: space_pair_measure space_PiM PiE_iff split: split_comb_seq)
   464   fix j :: nat and A assume A: "A \<in> sets M"
   465   then have *: "{\<omega> \<in> space ((\<Pi>\<^isub>M i\<in>UNIV. M) \<Otimes>\<^isub>M (\<Pi>\<^isub>M i\<in>UNIV. M)). prod_case (comb_seq i) \<omega> j \<in> A} =
   466     (if j < i then {\<omega> \<in> space (\<Pi>\<^isub>M i\<in>UNIV. M). \<omega> j \<in> A} \<times> space (\<Pi>\<^isub>M i\<in>UNIV. M)
   467               else space (\<Pi>\<^isub>M i\<in>UNIV. M) \<times> {\<omega> \<in> space (\<Pi>\<^isub>M i\<in>UNIV. M). \<omega> (j - i) \<in> A})"
   468     by (auto simp: space_PiM space_pair_measure comb_seq_def dest: sets.sets_into_space)
   469   show "{\<omega> \<in> space ((\<Pi>\<^isub>M i\<in>UNIV. M) \<Otimes>\<^isub>M (\<Pi>\<^isub>M i\<in>UNIV. M)). prod_case (comb_seq i) \<omega> j \<in> A} \<in> sets ((\<Pi>\<^isub>M i\<in>UNIV. M) \<Otimes>\<^isub>M (\<Pi>\<^isub>M i\<in>UNIV. M))"
   470     unfolding * by (auto simp: A intro!: sets_Collect_single)
   471 qed
   472 
   473 lemma measurable_comb_seq'[measurable (raw)]:
   474   assumes f: "f \<in> measurable N (\<Pi>\<^isub>M i\<in>UNIV. M)" and g: "g \<in> measurable N (\<Pi>\<^isub>M i\<in>UNIV. M)"
   475   shows "(\<lambda>x. comb_seq i (f x) (g x)) \<in> measurable N (\<Pi>\<^isub>M i\<in>UNIV. M)"
   476   using measurable_compose[OF measurable_Pair[OF f g] measurable_comb_seq] by simp
   477 
   478 lemma comb_seq_0: "comb_seq 0 \<omega> \<omega>' = \<omega>'"
   479   by (auto simp add: comb_seq_def)
   480 
   481 lemma comb_seq_Suc: "comb_seq (Suc n) \<omega> \<omega>' = comb_seq n \<omega> (nat_case (\<omega> n) \<omega>')"
   482   by (auto simp add: comb_seq_def not_less less_Suc_eq le_imp_diff_is_add intro!: ext split: nat.split)
   483 
   484 lemma comb_seq_Suc_0[simp]: "comb_seq (Suc 0) \<omega> = nat_case (\<omega> 0)"
   485   by (intro ext) (simp add: comb_seq_Suc comb_seq_0)
   486 
   487 lemma comb_seq_less: "i < n \<Longrightarrow> comb_seq n \<omega> \<omega>' i = \<omega> i"
   488   by (auto split: split_comb_seq)
   489 
   490 lemma comb_seq_add: "comb_seq n \<omega> \<omega>' (i + n) = \<omega>' i"
   491   by (auto split: nat.split split_comb_seq)
   492 
   493 lemma nat_case_comb_seq: "nat_case s' (comb_seq n \<omega> \<omega>') (i + n) = nat_case (nat_case s' \<omega> n) \<omega>' i"
   494   by (auto split: nat.split split_comb_seq)
   495 
   496 lemma nat_case_comb_seq':
   497   "nat_case s (comb_seq i \<omega> \<omega>') = comb_seq (Suc i) (nat_case s \<omega>) \<omega>'"
   498   by (auto split: split_comb_seq nat.split)
   499 
   500 locale sequence_space = product_prob_space "\<lambda>i. M" "UNIV :: nat set" for M
   501 begin
   502 
   503 abbreviation "S \<equiv> \<Pi>\<^isub>M i\<in>UNIV::nat set. M"
   504 
   505 lemma infprod_in_sets[intro]:
   506   fixes E :: "nat \<Rightarrow> 'a set" assumes E: "\<And>i. E i \<in> sets M"
   507   shows "Pi UNIV E \<in> sets S"
   508 proof -
   509   have "Pi UNIV E = (\<Inter>i. emb UNIV {..i} (\<Pi>\<^isub>E j\<in>{..i}. E j))"
   510     using E E[THEN sets.sets_into_space]
   511     by (auto simp: prod_emb_def Pi_iff extensional_def) blast
   512   with E show ?thesis by auto
   513 qed
   514 
   515 lemma measure_PiM_countable:
   516   fixes E :: "nat \<Rightarrow> 'a set" assumes E: "\<And>i. E i \<in> sets M"
   517   shows "(\<lambda>n. \<Prod>i\<le>n. measure M (E i)) ----> measure S (Pi UNIV E)"
   518 proof -
   519   let ?E = "\<lambda>n. emb UNIV {..n} (Pi\<^isub>E {.. n} E)"
   520   have "\<And>n. (\<Prod>i\<le>n. measure M (E i)) = measure S (?E n)"
   521     using E by (simp add: measure_PiM_emb)
   522   moreover have "Pi UNIV E = (\<Inter>n. ?E n)"
   523     using E E[THEN sets.sets_into_space]
   524     by (auto simp: prod_emb_def extensional_def Pi_iff) blast
   525   moreover have "range ?E \<subseteq> sets S"
   526     using E by auto
   527   moreover have "decseq ?E"
   528     by (auto simp: prod_emb_def Pi_iff decseq_def)
   529   ultimately show ?thesis
   530     by (simp add: finite_Lim_measure_decseq)
   531 qed
   532 
   533 lemma nat_eq_diff_eq: 
   534   fixes a b c :: nat
   535   shows "c \<le> b \<Longrightarrow> a = b - c \<longleftrightarrow> a + c = b"
   536   by auto
   537 
   538 lemma PiM_comb_seq:
   539   "distr (S \<Otimes>\<^isub>M S) S (\<lambda>(\<omega>, \<omega>'). comb_seq i \<omega> \<omega>') = S" (is "?D = _")
   540 proof (rule PiM_eq)
   541   let ?I = "UNIV::nat set" and ?M = "\<lambda>n. M"
   542   let "distr _ _ ?f" = "?D"
   543 
   544   fix J E assume J: "finite J" "J \<subseteq> ?I" "\<And>j. j \<in> J \<Longrightarrow> E j \<in> sets M"
   545   let ?X = "prod_emb ?I ?M J (\<Pi>\<^isub>E j\<in>J. E j)"
   546   have "\<And>j x. j \<in> J \<Longrightarrow> x \<in> E j \<Longrightarrow> x \<in> space M"
   547     using J(3)[THEN sets.sets_into_space] by (auto simp: space_PiM Pi_iff subset_eq)
   548   with J have "?f -` ?X \<inter> space (S \<Otimes>\<^isub>M S) =
   549     (prod_emb ?I ?M (J \<inter> {..<i}) (PIE j:J \<inter> {..<i}. E j)) \<times>
   550     (prod_emb ?I ?M ((op + i) -` J) (PIE j:(op + i) -` J. E (i + j)))" (is "_ = ?E \<times> ?F")
   551    by (auto simp: space_pair_measure space_PiM prod_emb_def all_conj_distrib PiE_iff
   552                split: split_comb_seq split_comb_seq_asm)
   553   then have "emeasure ?D ?X = emeasure (S \<Otimes>\<^isub>M S) (?E \<times> ?F)"
   554     by (subst emeasure_distr[OF measurable_comb_seq])
   555        (auto intro!: sets_PiM_I simp: split_beta' J)
   556   also have "\<dots> = emeasure S ?E * emeasure S ?F"
   557     using J by (intro P.emeasure_pair_measure_Times)  (auto intro!: sets_PiM_I finite_vimageI simp: inj_on_def)
   558   also have "emeasure S ?F = (\<Prod>j\<in>(op + i) -` J. emeasure M (E (i + j)))"
   559     using J by (intro emeasure_PiM_emb) (simp_all add: finite_vimageI inj_on_def)
   560   also have "\<dots> = (\<Prod>j\<in>J - (J \<inter> {..<i}). emeasure M (E j))"
   561     by (rule strong_setprod_reindex_cong[where f="\<lambda>x. x - i"])
   562        (auto simp: image_iff Bex_def not_less nat_eq_diff_eq ac_simps cong: conj_cong intro!: inj_onI)
   563   also have "emeasure S ?E = (\<Prod>j\<in>J \<inter> {..<i}. emeasure M (E j))"
   564     using J by (intro emeasure_PiM_emb) simp_all
   565   also have "(\<Prod>j\<in>J \<inter> {..<i}. emeasure M (E j)) * (\<Prod>j\<in>J - (J \<inter> {..<i}). emeasure M (E j)) = (\<Prod>j\<in>J. emeasure M (E j))"
   566     by (subst mult_commute) (auto simp: J setprod_subset_diff[symmetric])
   567   finally show "emeasure ?D ?X = (\<Prod>j\<in>J. emeasure M (E j))" .
   568 qed simp_all
   569 
   570 lemma PiM_iter:
   571   "distr (M \<Otimes>\<^isub>M S) S (\<lambda>(s, \<omega>). nat_case s \<omega>) = S" (is "?D = _")
   572 proof (rule PiM_eq)
   573   let ?I = "UNIV::nat set" and ?M = "\<lambda>n. M"
   574   let "distr _ _ ?f" = "?D"
   575 
   576   fix J E assume J: "finite J" "J \<subseteq> ?I" "\<And>j. j \<in> J \<Longrightarrow> E j \<in> sets M"
   577   let ?X = "prod_emb ?I ?M J (PIE j:J. E j)"
   578   have "\<And>j x. j \<in> J \<Longrightarrow> x \<in> E j \<Longrightarrow> x \<in> space M"
   579     using J(3)[THEN sets.sets_into_space] by (auto simp: space_PiM Pi_iff subset_eq)
   580   with J have "?f -` ?X \<inter> space (M \<Otimes>\<^isub>M S) = (if 0 \<in> J then E 0 else space M) \<times>
   581     (prod_emb ?I ?M (Suc -` J) (PIE j:Suc -` J. E (Suc j)))" (is "_ = ?E \<times> ?F")
   582    by (auto simp: space_pair_measure space_PiM PiE_iff prod_emb_def all_conj_distrib
   583       split: nat.split nat.split_asm)
   584   then have "emeasure ?D ?X = emeasure (M \<Otimes>\<^isub>M S) (?E \<times> ?F)"
   585     by (subst emeasure_distr)
   586        (auto intro!: sets_PiM_I simp: split_beta' J)
   587   also have "\<dots> = emeasure M ?E * emeasure S ?F"
   588     using J by (intro P.emeasure_pair_measure_Times) (auto intro!: sets_PiM_I finite_vimageI)
   589   also have "emeasure S ?F = (\<Prod>j\<in>Suc -` J. emeasure M (E (Suc j)))"
   590     using J by (intro emeasure_PiM_emb) (simp_all add: finite_vimageI)
   591   also have "\<dots> = (\<Prod>j\<in>J - {0}. emeasure M (E j))"
   592     by (rule strong_setprod_reindex_cong[where f="\<lambda>x. x - 1"])
   593        (auto simp: image_iff Bex_def not_less nat_eq_diff_eq ac_simps cong: conj_cong intro!: inj_onI)
   594   also have "emeasure M ?E * (\<Prod>j\<in>J - {0}. emeasure M (E j)) = (\<Prod>j\<in>J. emeasure M (E j))"
   595     by (auto simp: M.emeasure_space_1 setprod.remove J)
   596   finally show "emeasure ?D ?X = (\<Prod>j\<in>J. emeasure M (E j))" .
   597 qed simp_all
   598 
   599 end
   600 
   601 end