src/HOL/Archimedean_Field.thy
author paulson <lp15@cam.ac.uk>
Mon Oct 09 15:34:23 2017 +0100 (20 months ago)
changeset 66793 deabce3ccf1f
parent 66515 85c505c98332
child 68499 d4312962161a
permissions -rw-r--r--
new material about connectedness, etc.
     1 (*  Title:      HOL/Archimedean_Field.thy
     2     Author:     Brian Huffman
     3 *)
     4 
     5 section \<open>Archimedean Fields, Floor and Ceiling Functions\<close>
     6 
     7 theory Archimedean_Field
     8 imports Main
     9 begin
    10 
    11 lemma cInf_abs_ge:
    12   fixes S :: "'a::{linordered_idom,conditionally_complete_linorder} set"
    13   assumes "S \<noteq> {}"
    14     and bdd: "\<And>x. x\<in>S \<Longrightarrow> \<bar>x\<bar> \<le> a"
    15   shows "\<bar>Inf S\<bar> \<le> a"
    16 proof -
    17   have "Sup (uminus ` S) = - (Inf S)"
    18   proof (rule antisym)
    19     show "- (Inf S) \<le> Sup (uminus ` S)"
    20       apply (subst minus_le_iff)
    21       apply (rule cInf_greatest [OF \<open>S \<noteq> {}\<close>])
    22       apply (subst minus_le_iff)
    23       apply (rule cSup_upper)
    24        apply force
    25       using bdd
    26       apply (force simp: abs_le_iff bdd_above_def)
    27       done
    28   next
    29     show "Sup (uminus ` S) \<le> - Inf S"
    30       apply (rule cSup_least)
    31       using \<open>S \<noteq> {}\<close>
    32        apply force
    33       apply clarsimp
    34       apply (rule cInf_lower)
    35        apply assumption
    36       using bdd
    37       apply (simp add: bdd_below_def)
    38       apply (rule_tac x = "- a" in exI)
    39       apply force
    40       done
    41   qed
    42   with cSup_abs_le [of "uminus ` S"] assms show ?thesis
    43     by fastforce
    44 qed
    45 
    46 lemma cSup_asclose:
    47   fixes S :: "'a::{linordered_idom,conditionally_complete_linorder} set"
    48   assumes S: "S \<noteq> {}"
    49     and b: "\<forall>x\<in>S. \<bar>x - l\<bar> \<le> e"
    50   shows "\<bar>Sup S - l\<bar> \<le> e"
    51 proof -
    52   have *: "\<bar>x - l\<bar> \<le> e \<longleftrightarrow> l - e \<le> x \<and> x \<le> l + e" for x l e :: 'a
    53     by arith
    54   have "bdd_above S"
    55     using b by (auto intro!: bdd_aboveI[of _ "l + e"])
    56   with S b show ?thesis
    57     unfolding * by (auto intro!: cSup_upper2 cSup_least)
    58 qed
    59 
    60 lemma cInf_asclose:
    61   fixes S :: "'a::{linordered_idom,conditionally_complete_linorder} set"
    62   assumes S: "S \<noteq> {}"
    63     and b: "\<forall>x\<in>S. \<bar>x - l\<bar> \<le> e"
    64   shows "\<bar>Inf S - l\<bar> \<le> e"
    65 proof -
    66   have *: "\<bar>x - l\<bar> \<le> e \<longleftrightarrow> l - e \<le> x \<and> x \<le> l + e" for x l e :: 'a
    67     by arith
    68   have "bdd_below S"
    69     using b by (auto intro!: bdd_belowI[of _ "l - e"])
    70   with S b show ?thesis
    71     unfolding * by (auto intro!: cInf_lower2 cInf_greatest)
    72 qed
    73 
    74 
    75 subsection \<open>Class of Archimedean fields\<close>
    76 
    77 text \<open>Archimedean fields have no infinite elements.\<close>
    78 
    79 class archimedean_field = linordered_field +
    80   assumes ex_le_of_int: "\<exists>z. x \<le> of_int z"
    81 
    82 lemma ex_less_of_int: "\<exists>z. x < of_int z"
    83   for x :: "'a::archimedean_field"
    84 proof -
    85   from ex_le_of_int obtain z where "x \<le> of_int z" ..
    86   then have "x < of_int (z + 1)" by simp
    87   then show ?thesis ..
    88 qed
    89 
    90 lemma ex_of_int_less: "\<exists>z. of_int z < x"
    91   for x :: "'a::archimedean_field"
    92 proof -
    93   from ex_less_of_int obtain z where "- x < of_int z" ..
    94   then have "of_int (- z) < x" by simp
    95   then show ?thesis ..
    96 qed
    97 
    98 lemma reals_Archimedean2: "\<exists>n. x < of_nat n"
    99   for x :: "'a::archimedean_field"
   100 proof -
   101   obtain z where "x < of_int z"
   102     using ex_less_of_int ..
   103   also have "\<dots> \<le> of_int (int (nat z))"
   104     by simp
   105   also have "\<dots> = of_nat (nat z)"
   106     by (simp only: of_int_of_nat_eq)
   107   finally show ?thesis ..
   108 qed
   109 
   110 lemma real_arch_simple: "\<exists>n. x \<le> of_nat n"
   111   for x :: "'a::archimedean_field"
   112 proof -
   113   obtain n where "x < of_nat n"
   114     using reals_Archimedean2 ..
   115   then have "x \<le> of_nat n"
   116     by simp
   117   then show ?thesis ..
   118 qed
   119 
   120 text \<open>Archimedean fields have no infinitesimal elements.\<close>
   121 
   122 lemma reals_Archimedean:
   123   fixes x :: "'a::archimedean_field"
   124   assumes "0 < x"
   125   shows "\<exists>n. inverse (of_nat (Suc n)) < x"
   126 proof -
   127   from \<open>0 < x\<close> have "0 < inverse x"
   128     by (rule positive_imp_inverse_positive)
   129   obtain n where "inverse x < of_nat n"
   130     using reals_Archimedean2 ..
   131   then obtain m where "inverse x < of_nat (Suc m)"
   132     using \<open>0 < inverse x\<close> by (cases n) (simp_all del: of_nat_Suc)
   133   then have "inverse (of_nat (Suc m)) < inverse (inverse x)"
   134     using \<open>0 < inverse x\<close> by (rule less_imp_inverse_less)
   135   then have "inverse (of_nat (Suc m)) < x"
   136     using \<open>0 < x\<close> by (simp add: nonzero_inverse_inverse_eq)
   137   then show ?thesis ..
   138 qed
   139 
   140 lemma ex_inverse_of_nat_less:
   141   fixes x :: "'a::archimedean_field"
   142   assumes "0 < x"
   143   shows "\<exists>n>0. inverse (of_nat n) < x"
   144   using reals_Archimedean [OF \<open>0 < x\<close>] by auto
   145 
   146 lemma ex_less_of_nat_mult:
   147   fixes x :: "'a::archimedean_field"
   148   assumes "0 < x"
   149   shows "\<exists>n. y < of_nat n * x"
   150 proof -
   151   obtain n where "y / x < of_nat n"
   152     using reals_Archimedean2 ..
   153   with \<open>0 < x\<close> have "y < of_nat n * x"
   154     by (simp add: pos_divide_less_eq)
   155   then show ?thesis ..
   156 qed
   157 
   158 
   159 subsection \<open>Existence and uniqueness of floor function\<close>
   160 
   161 lemma exists_least_lemma:
   162   assumes "\<not> P 0" and "\<exists>n. P n"
   163   shows "\<exists>n. \<not> P n \<and> P (Suc n)"
   164 proof -
   165   from \<open>\<exists>n. P n\<close> have "P (Least P)"
   166     by (rule LeastI_ex)
   167   with \<open>\<not> P 0\<close> obtain n where "Least P = Suc n"
   168     by (cases "Least P") auto
   169   then have "n < Least P"
   170     by simp
   171   then have "\<not> P n"
   172     by (rule not_less_Least)
   173   then have "\<not> P n \<and> P (Suc n)"
   174     using \<open>P (Least P)\<close> \<open>Least P = Suc n\<close> by simp
   175   then show ?thesis ..
   176 qed
   177 
   178 lemma floor_exists:
   179   fixes x :: "'a::archimedean_field"
   180   shows "\<exists>z. of_int z \<le> x \<and> x < of_int (z + 1)"
   181 proof (cases "0 \<le> x")
   182   case True
   183   then have "\<not> x < of_nat 0"
   184     by simp
   185   then have "\<exists>n. \<not> x < of_nat n \<and> x < of_nat (Suc n)"
   186     using reals_Archimedean2 by (rule exists_least_lemma)
   187   then obtain n where "\<not> x < of_nat n \<and> x < of_nat (Suc n)" ..
   188   then have "of_int (int n) \<le> x \<and> x < of_int (int n + 1)"
   189     by simp
   190   then show ?thesis ..
   191 next
   192   case False
   193   then have "\<not> - x \<le> of_nat 0"
   194     by simp
   195   then have "\<exists>n. \<not> - x \<le> of_nat n \<and> - x \<le> of_nat (Suc n)"
   196     using real_arch_simple by (rule exists_least_lemma)
   197   then obtain n where "\<not> - x \<le> of_nat n \<and> - x \<le> of_nat (Suc n)" ..
   198   then have "of_int (- int n - 1) \<le> x \<and> x < of_int (- int n - 1 + 1)"
   199     by simp
   200   then show ?thesis ..
   201 qed
   202 
   203 lemma floor_exists1: "\<exists>!z. of_int z \<le> x \<and> x < of_int (z + 1)"
   204   for x :: "'a::archimedean_field"
   205 proof (rule ex_ex1I)
   206   show "\<exists>z. of_int z \<le> x \<and> x < of_int (z + 1)"
   207     by (rule floor_exists)
   208 next
   209   fix y z
   210   assume "of_int y \<le> x \<and> x < of_int (y + 1)"
   211     and "of_int z \<le> x \<and> x < of_int (z + 1)"
   212   with le_less_trans [of "of_int y" "x" "of_int (z + 1)"]
   213        le_less_trans [of "of_int z" "x" "of_int (y + 1)"] show "y = z"
   214     by (simp del: of_int_add)
   215 qed
   216 
   217 
   218 subsection \<open>Floor function\<close>
   219 
   220 class floor_ceiling = archimedean_field +
   221   fixes floor :: "'a \<Rightarrow> int"  ("\<lfloor>_\<rfloor>")
   222   assumes floor_correct: "of_int \<lfloor>x\<rfloor> \<le> x \<and> x < of_int (\<lfloor>x\<rfloor> + 1)"
   223 
   224 lemma floor_unique: "of_int z \<le> x \<Longrightarrow> x < of_int z + 1 \<Longrightarrow> \<lfloor>x\<rfloor> = z"
   225   using floor_correct [of x] floor_exists1 [of x] by auto
   226 
   227 lemma floor_eq_iff: "\<lfloor>x\<rfloor> = a \<longleftrightarrow> of_int a \<le> x \<and> x < of_int a + 1"
   228 using floor_correct floor_unique by auto
   229 
   230 lemma of_int_floor_le [simp]: "of_int \<lfloor>x\<rfloor> \<le> x"
   231   using floor_correct ..
   232 
   233 lemma le_floor_iff: "z \<le> \<lfloor>x\<rfloor> \<longleftrightarrow> of_int z \<le> x"
   234 proof
   235   assume "z \<le> \<lfloor>x\<rfloor>"
   236   then have "(of_int z :: 'a) \<le> of_int \<lfloor>x\<rfloor>" by simp
   237   also have "of_int \<lfloor>x\<rfloor> \<le> x" by (rule of_int_floor_le)
   238   finally show "of_int z \<le> x" .
   239 next
   240   assume "of_int z \<le> x"
   241   also have "x < of_int (\<lfloor>x\<rfloor> + 1)" using floor_correct ..
   242   finally show "z \<le> \<lfloor>x\<rfloor>" by (simp del: of_int_add)
   243 qed
   244 
   245 lemma floor_less_iff: "\<lfloor>x\<rfloor> < z \<longleftrightarrow> x < of_int z"
   246   by (simp add: not_le [symmetric] le_floor_iff)
   247 
   248 lemma less_floor_iff: "z < \<lfloor>x\<rfloor> \<longleftrightarrow> of_int z + 1 \<le> x"
   249   using le_floor_iff [of "z + 1" x] by auto
   250 
   251 lemma floor_le_iff: "\<lfloor>x\<rfloor> \<le> z \<longleftrightarrow> x < of_int z + 1"
   252   by (simp add: not_less [symmetric] less_floor_iff)
   253 
   254 lemma floor_split[arith_split]: "P \<lfloor>t\<rfloor> \<longleftrightarrow> (\<forall>i. of_int i \<le> t \<and> t < of_int i + 1 \<longrightarrow> P i)"
   255   by (metis floor_correct floor_unique less_floor_iff not_le order_refl)
   256 
   257 lemma floor_mono:
   258   assumes "x \<le> y"
   259   shows "\<lfloor>x\<rfloor> \<le> \<lfloor>y\<rfloor>"
   260 proof -
   261   have "of_int \<lfloor>x\<rfloor> \<le> x" by (rule of_int_floor_le)
   262   also note \<open>x \<le> y\<close>
   263   finally show ?thesis by (simp add: le_floor_iff)
   264 qed
   265 
   266 lemma floor_less_cancel: "\<lfloor>x\<rfloor> < \<lfloor>y\<rfloor> \<Longrightarrow> x < y"
   267   by (auto simp add: not_le [symmetric] floor_mono)
   268 
   269 lemma floor_of_int [simp]: "\<lfloor>of_int z\<rfloor> = z"
   270   by (rule floor_unique) simp_all
   271 
   272 lemma floor_of_nat [simp]: "\<lfloor>of_nat n\<rfloor> = int n"
   273   using floor_of_int [of "of_nat n"] by simp
   274 
   275 lemma le_floor_add: "\<lfloor>x\<rfloor> + \<lfloor>y\<rfloor> \<le> \<lfloor>x + y\<rfloor>"
   276   by (simp only: le_floor_iff of_int_add add_mono of_int_floor_le)
   277 
   278 
   279 text \<open>Floor with numerals.\<close>
   280 
   281 lemma floor_zero [simp]: "\<lfloor>0\<rfloor> = 0"
   282   using floor_of_int [of 0] by simp
   283 
   284 lemma floor_one [simp]: "\<lfloor>1\<rfloor> = 1"
   285   using floor_of_int [of 1] by simp
   286 
   287 lemma floor_numeral [simp]: "\<lfloor>numeral v\<rfloor> = numeral v"
   288   using floor_of_int [of "numeral v"] by simp
   289 
   290 lemma floor_neg_numeral [simp]: "\<lfloor>- numeral v\<rfloor> = - numeral v"
   291   using floor_of_int [of "- numeral v"] by simp
   292 
   293 lemma zero_le_floor [simp]: "0 \<le> \<lfloor>x\<rfloor> \<longleftrightarrow> 0 \<le> x"
   294   by (simp add: le_floor_iff)
   295 
   296 lemma one_le_floor [simp]: "1 \<le> \<lfloor>x\<rfloor> \<longleftrightarrow> 1 \<le> x"
   297   by (simp add: le_floor_iff)
   298 
   299 lemma numeral_le_floor [simp]: "numeral v \<le> \<lfloor>x\<rfloor> \<longleftrightarrow> numeral v \<le> x"
   300   by (simp add: le_floor_iff)
   301 
   302 lemma neg_numeral_le_floor [simp]: "- numeral v \<le> \<lfloor>x\<rfloor> \<longleftrightarrow> - numeral v \<le> x"
   303   by (simp add: le_floor_iff)
   304 
   305 lemma zero_less_floor [simp]: "0 < \<lfloor>x\<rfloor> \<longleftrightarrow> 1 \<le> x"
   306   by (simp add: less_floor_iff)
   307 
   308 lemma one_less_floor [simp]: "1 < \<lfloor>x\<rfloor> \<longleftrightarrow> 2 \<le> x"
   309   by (simp add: less_floor_iff)
   310 
   311 lemma numeral_less_floor [simp]: "numeral v < \<lfloor>x\<rfloor> \<longleftrightarrow> numeral v + 1 \<le> x"
   312   by (simp add: less_floor_iff)
   313 
   314 lemma neg_numeral_less_floor [simp]: "- numeral v < \<lfloor>x\<rfloor> \<longleftrightarrow> - numeral v + 1 \<le> x"
   315   by (simp add: less_floor_iff)
   316 
   317 lemma floor_le_zero [simp]: "\<lfloor>x\<rfloor> \<le> 0 \<longleftrightarrow> x < 1"
   318   by (simp add: floor_le_iff)
   319 
   320 lemma floor_le_one [simp]: "\<lfloor>x\<rfloor> \<le> 1 \<longleftrightarrow> x < 2"
   321   by (simp add: floor_le_iff)
   322 
   323 lemma floor_le_numeral [simp]: "\<lfloor>x\<rfloor> \<le> numeral v \<longleftrightarrow> x < numeral v + 1"
   324   by (simp add: floor_le_iff)
   325 
   326 lemma floor_le_neg_numeral [simp]: "\<lfloor>x\<rfloor> \<le> - numeral v \<longleftrightarrow> x < - numeral v + 1"
   327   by (simp add: floor_le_iff)
   328 
   329 lemma floor_less_zero [simp]: "\<lfloor>x\<rfloor> < 0 \<longleftrightarrow> x < 0"
   330   by (simp add: floor_less_iff)
   331 
   332 lemma floor_less_one [simp]: "\<lfloor>x\<rfloor> < 1 \<longleftrightarrow> x < 1"
   333   by (simp add: floor_less_iff)
   334 
   335 lemma floor_less_numeral [simp]: "\<lfloor>x\<rfloor> < numeral v \<longleftrightarrow> x < numeral v"
   336   by (simp add: floor_less_iff)
   337 
   338 lemma floor_less_neg_numeral [simp]: "\<lfloor>x\<rfloor> < - numeral v \<longleftrightarrow> x < - numeral v"
   339   by (simp add: floor_less_iff)
   340 
   341 lemma le_mult_floor_Ints:
   342   assumes "0 \<le> a" "a \<in> Ints"
   343   shows "of_int (\<lfloor>a\<rfloor> * \<lfloor>b\<rfloor>) \<le> (of_int\<lfloor>a * b\<rfloor> :: 'a :: linordered_idom)"
   344   by (metis Ints_cases assms floor_less_iff floor_of_int linorder_not_less mult_left_mono of_int_floor_le of_int_less_iff of_int_mult)
   345 
   346 
   347 text \<open>Addition and subtraction of integers.\<close>
   348 
   349 lemma floor_add_int: "\<lfloor>x\<rfloor> + z = \<lfloor>x + of_int z\<rfloor>"
   350   using floor_correct [of x] by (simp add: floor_unique[symmetric])
   351 
   352 lemma int_add_floor: "z + \<lfloor>x\<rfloor> = \<lfloor>of_int z + x\<rfloor>"
   353   using floor_correct [of x] by (simp add: floor_unique[symmetric])
   354 
   355 lemma one_add_floor: "\<lfloor>x\<rfloor> + 1 = \<lfloor>x + 1\<rfloor>"
   356   using floor_add_int [of x 1] by simp
   357 
   358 lemma floor_diff_of_int [simp]: "\<lfloor>x - of_int z\<rfloor> = \<lfloor>x\<rfloor> - z"
   359   using floor_add_int [of x "- z"] by (simp add: algebra_simps)
   360 
   361 lemma floor_uminus_of_int [simp]: "\<lfloor>- (of_int z)\<rfloor> = - z"
   362   by (metis floor_diff_of_int [of 0] diff_0 floor_zero)
   363 
   364 lemma floor_diff_numeral [simp]: "\<lfloor>x - numeral v\<rfloor> = \<lfloor>x\<rfloor> - numeral v"
   365   using floor_diff_of_int [of x "numeral v"] by simp
   366 
   367 lemma floor_diff_one [simp]: "\<lfloor>x - 1\<rfloor> = \<lfloor>x\<rfloor> - 1"
   368   using floor_diff_of_int [of x 1] by simp
   369 
   370 lemma le_mult_floor:
   371   assumes "0 \<le> a" and "0 \<le> b"
   372   shows "\<lfloor>a\<rfloor> * \<lfloor>b\<rfloor> \<le> \<lfloor>a * b\<rfloor>"
   373 proof -
   374   have "of_int \<lfloor>a\<rfloor> \<le> a" and "of_int \<lfloor>b\<rfloor> \<le> b"
   375     by (auto intro: of_int_floor_le)
   376   then have "of_int (\<lfloor>a\<rfloor> * \<lfloor>b\<rfloor>) \<le> a * b"
   377     using assms by (auto intro!: mult_mono)
   378   also have "a * b < of_int (\<lfloor>a * b\<rfloor> + 1)"
   379     using floor_correct[of "a * b"] by auto
   380   finally show ?thesis
   381     unfolding of_int_less_iff by simp
   382 qed
   383 
   384 lemma floor_divide_of_int_eq: "\<lfloor>of_int k / of_int l\<rfloor> = k div l"
   385   for k l :: int
   386 proof (cases "l = 0")
   387   case True
   388   then show ?thesis by simp
   389 next
   390   case False
   391   have *: "\<lfloor>of_int (k mod l) / of_int l :: 'a\<rfloor> = 0"
   392   proof (cases "l > 0")
   393     case True
   394     then show ?thesis
   395       by (auto intro: floor_unique)
   396   next
   397     case False
   398     obtain r where "r = - l"
   399       by blast
   400     then have l: "l = - r"
   401       by simp
   402     with \<open>l \<noteq> 0\<close> False have "r > 0"
   403       by simp
   404     with l show ?thesis
   405       using pos_mod_bound [of r]
   406       by (auto simp add: zmod_zminus2_eq_if less_le field_simps intro: floor_unique)
   407   qed
   408   have "(of_int k :: 'a) = of_int (k div l * l + k mod l)"
   409     by simp
   410   also have "\<dots> = (of_int (k div l) + of_int (k mod l) / of_int l) * of_int l"
   411     using False by (simp only: of_int_add) (simp add: field_simps)
   412   finally have "(of_int k / of_int l :: 'a) = \<dots> / of_int l"
   413     by simp
   414   then have "(of_int k / of_int l :: 'a) = of_int (k div l) + of_int (k mod l) / of_int l"
   415     using False by (simp only:) (simp add: field_simps)
   416   then have "\<lfloor>of_int k / of_int l :: 'a\<rfloor> = \<lfloor>of_int (k div l) + of_int (k mod l) / of_int l :: 'a\<rfloor>"
   417     by simp
   418   then have "\<lfloor>of_int k / of_int l :: 'a\<rfloor> = \<lfloor>of_int (k mod l) / of_int l + of_int (k div l) :: 'a\<rfloor>"
   419     by (simp add: ac_simps)
   420   then have "\<lfloor>of_int k / of_int l :: 'a\<rfloor> = \<lfloor>of_int (k mod l) / of_int l :: 'a\<rfloor> + k div l"
   421     by (simp add: floor_add_int)
   422   with * show ?thesis
   423     by simp
   424 qed
   425 
   426 lemma floor_divide_of_nat_eq: "\<lfloor>of_nat m / of_nat n\<rfloor> = of_nat (m div n)"
   427   for m n :: nat
   428 proof (cases "n = 0")
   429   case True
   430   then show ?thesis by simp
   431 next
   432   case False
   433   then have *: "\<lfloor>of_nat (m mod n) / of_nat n :: 'a\<rfloor> = 0"
   434     by (auto intro: floor_unique)
   435   have "(of_nat m :: 'a) = of_nat (m div n * n + m mod n)"
   436     by simp
   437   also have "\<dots> = (of_nat (m div n) + of_nat (m mod n) / of_nat n) * of_nat n"
   438     using False by (simp only: of_nat_add) (simp add: field_simps)
   439   finally have "(of_nat m / of_nat n :: 'a) = \<dots> / of_nat n"
   440     by simp
   441   then have "(of_nat m / of_nat n :: 'a) = of_nat (m div n) + of_nat (m mod n) / of_nat n"
   442     using False by (simp only:) simp
   443   then have "\<lfloor>of_nat m / of_nat n :: 'a\<rfloor> = \<lfloor>of_nat (m div n) + of_nat (m mod n) / of_nat n :: 'a\<rfloor>"
   444     by simp
   445   then have "\<lfloor>of_nat m / of_nat n :: 'a\<rfloor> = \<lfloor>of_nat (m mod n) / of_nat n + of_nat (m div n) :: 'a\<rfloor>"
   446     by (simp add: ac_simps)
   447   moreover have "(of_nat (m div n) :: 'a) = of_int (of_nat (m div n))"
   448     by simp
   449   ultimately have "\<lfloor>of_nat m / of_nat n :: 'a\<rfloor> =
   450       \<lfloor>of_nat (m mod n) / of_nat n :: 'a\<rfloor> + of_nat (m div n)"
   451     by (simp only: floor_add_int)
   452   with * show ?thesis
   453     by simp
   454 qed
   455 
   456 
   457 subsection \<open>Ceiling function\<close>
   458 
   459 definition ceiling :: "'a::floor_ceiling \<Rightarrow> int"  ("\<lceil>_\<rceil>")
   460   where "\<lceil>x\<rceil> = - \<lfloor>- x\<rfloor>"
   461 
   462 lemma ceiling_correct: "of_int \<lceil>x\<rceil> - 1 < x \<and> x \<le> of_int \<lceil>x\<rceil>"
   463   unfolding ceiling_def using floor_correct [of "- x"]
   464   by (simp add: le_minus_iff)
   465 
   466 lemma ceiling_unique: "of_int z - 1 < x \<Longrightarrow> x \<le> of_int z \<Longrightarrow> \<lceil>x\<rceil> = z"
   467   unfolding ceiling_def using floor_unique [of "- z" "- x"] by simp
   468 
   469 lemma ceiling_eq_iff: "\<lceil>x\<rceil> = a \<longleftrightarrow> of_int a - 1 < x \<and> x \<le> of_int a"
   470 using ceiling_correct ceiling_unique by auto
   471 
   472 lemma le_of_int_ceiling [simp]: "x \<le> of_int \<lceil>x\<rceil>"
   473   using ceiling_correct ..
   474 
   475 lemma ceiling_le_iff: "\<lceil>x\<rceil> \<le> z \<longleftrightarrow> x \<le> of_int z"
   476   unfolding ceiling_def using le_floor_iff [of "- z" "- x"] by auto
   477 
   478 lemma less_ceiling_iff: "z < \<lceil>x\<rceil> \<longleftrightarrow> of_int z < x"
   479   by (simp add: not_le [symmetric] ceiling_le_iff)
   480 
   481 lemma ceiling_less_iff: "\<lceil>x\<rceil> < z \<longleftrightarrow> x \<le> of_int z - 1"
   482   using ceiling_le_iff [of x "z - 1"] by simp
   483 
   484 lemma le_ceiling_iff: "z \<le> \<lceil>x\<rceil> \<longleftrightarrow> of_int z - 1 < x"
   485   by (simp add: not_less [symmetric] ceiling_less_iff)
   486 
   487 lemma ceiling_mono: "x \<ge> y \<Longrightarrow> \<lceil>x\<rceil> \<ge> \<lceil>y\<rceil>"
   488   unfolding ceiling_def by (simp add: floor_mono)
   489 
   490 lemma ceiling_less_cancel: "\<lceil>x\<rceil> < \<lceil>y\<rceil> \<Longrightarrow> x < y"
   491   by (auto simp add: not_le [symmetric] ceiling_mono)
   492 
   493 lemma ceiling_of_int [simp]: "\<lceil>of_int z\<rceil> = z"
   494   by (rule ceiling_unique) simp_all
   495 
   496 lemma ceiling_of_nat [simp]: "\<lceil>of_nat n\<rceil> = int n"
   497   using ceiling_of_int [of "of_nat n"] by simp
   498 
   499 lemma ceiling_add_le: "\<lceil>x + y\<rceil> \<le> \<lceil>x\<rceil> + \<lceil>y\<rceil>"
   500   by (simp only: ceiling_le_iff of_int_add add_mono le_of_int_ceiling)
   501 
   502 lemma mult_ceiling_le:
   503   assumes "0 \<le> a" and "0 \<le> b"
   504   shows "\<lceil>a * b\<rceil> \<le> \<lceil>a\<rceil> * \<lceil>b\<rceil>"
   505   by (metis assms ceiling_le_iff ceiling_mono le_of_int_ceiling mult_mono of_int_mult)
   506 
   507 lemma mult_ceiling_le_Ints:
   508   assumes "0 \<le> a" "a \<in> Ints"
   509   shows "(of_int \<lceil>a * b\<rceil> :: 'a :: linordered_idom) \<le> of_int(\<lceil>a\<rceil> * \<lceil>b\<rceil>)"
   510   by (metis Ints_cases assms ceiling_le_iff ceiling_of_int le_of_int_ceiling mult_left_mono of_int_le_iff of_int_mult)
   511 
   512 lemma finite_int_segment:
   513   fixes a :: "'a::floor_ceiling"
   514   shows "finite {x \<in> \<int>. a \<le> x \<and> x \<le> b}"
   515 proof -
   516   have "finite {ceiling a..floor b}"
   517     by simp
   518   moreover have "{x \<in> \<int>. a \<le> x \<and> x \<le> b} = of_int ` {ceiling a..floor b}"
   519     by (auto simp: le_floor_iff ceiling_le_iff elim!: Ints_cases)
   520   ultimately show ?thesis
   521     by simp
   522 qed
   523 
   524 corollary finite_abs_int_segment:
   525   fixes a :: "'a::floor_ceiling"
   526   shows "finite {k \<in> \<int>. \<bar>k\<bar> \<le> a}" 
   527   using finite_int_segment [of "-a" a] by (auto simp add: abs_le_iff conj_commute minus_le_iff)
   528 
   529 
   530 subsubsection \<open>Ceiling with numerals.\<close>
   531 
   532 lemma ceiling_zero [simp]: "\<lceil>0\<rceil> = 0"
   533   using ceiling_of_int [of 0] by simp
   534 
   535 lemma ceiling_one [simp]: "\<lceil>1\<rceil> = 1"
   536   using ceiling_of_int [of 1] by simp
   537 
   538 lemma ceiling_numeral [simp]: "\<lceil>numeral v\<rceil> = numeral v"
   539   using ceiling_of_int [of "numeral v"] by simp
   540 
   541 lemma ceiling_neg_numeral [simp]: "\<lceil>- numeral v\<rceil> = - numeral v"
   542   using ceiling_of_int [of "- numeral v"] by simp
   543 
   544 lemma ceiling_le_zero [simp]: "\<lceil>x\<rceil> \<le> 0 \<longleftrightarrow> x \<le> 0"
   545   by (simp add: ceiling_le_iff)
   546 
   547 lemma ceiling_le_one [simp]: "\<lceil>x\<rceil> \<le> 1 \<longleftrightarrow> x \<le> 1"
   548   by (simp add: ceiling_le_iff)
   549 
   550 lemma ceiling_le_numeral [simp]: "\<lceil>x\<rceil> \<le> numeral v \<longleftrightarrow> x \<le> numeral v"
   551   by (simp add: ceiling_le_iff)
   552 
   553 lemma ceiling_le_neg_numeral [simp]: "\<lceil>x\<rceil> \<le> - numeral v \<longleftrightarrow> x \<le> - numeral v"
   554   by (simp add: ceiling_le_iff)
   555 
   556 lemma ceiling_less_zero [simp]: "\<lceil>x\<rceil> < 0 \<longleftrightarrow> x \<le> -1"
   557   by (simp add: ceiling_less_iff)
   558 
   559 lemma ceiling_less_one [simp]: "\<lceil>x\<rceil> < 1 \<longleftrightarrow> x \<le> 0"
   560   by (simp add: ceiling_less_iff)
   561 
   562 lemma ceiling_less_numeral [simp]: "\<lceil>x\<rceil> < numeral v \<longleftrightarrow> x \<le> numeral v - 1"
   563   by (simp add: ceiling_less_iff)
   564 
   565 lemma ceiling_less_neg_numeral [simp]: "\<lceil>x\<rceil> < - numeral v \<longleftrightarrow> x \<le> - numeral v - 1"
   566   by (simp add: ceiling_less_iff)
   567 
   568 lemma zero_le_ceiling [simp]: "0 \<le> \<lceil>x\<rceil> \<longleftrightarrow> -1 < x"
   569   by (simp add: le_ceiling_iff)
   570 
   571 lemma one_le_ceiling [simp]: "1 \<le> \<lceil>x\<rceil> \<longleftrightarrow> 0 < x"
   572   by (simp add: le_ceiling_iff)
   573 
   574 lemma numeral_le_ceiling [simp]: "numeral v \<le> \<lceil>x\<rceil> \<longleftrightarrow> numeral v - 1 < x"
   575   by (simp add: le_ceiling_iff)
   576 
   577 lemma neg_numeral_le_ceiling [simp]: "- numeral v \<le> \<lceil>x\<rceil> \<longleftrightarrow> - numeral v - 1 < x"
   578   by (simp add: le_ceiling_iff)
   579 
   580 lemma zero_less_ceiling [simp]: "0 < \<lceil>x\<rceil> \<longleftrightarrow> 0 < x"
   581   by (simp add: less_ceiling_iff)
   582 
   583 lemma one_less_ceiling [simp]: "1 < \<lceil>x\<rceil> \<longleftrightarrow> 1 < x"
   584   by (simp add: less_ceiling_iff)
   585 
   586 lemma numeral_less_ceiling [simp]: "numeral v < \<lceil>x\<rceil> \<longleftrightarrow> numeral v < x"
   587   by (simp add: less_ceiling_iff)
   588 
   589 lemma neg_numeral_less_ceiling [simp]: "- numeral v < \<lceil>x\<rceil> \<longleftrightarrow> - numeral v < x"
   590   by (simp add: less_ceiling_iff)
   591 
   592 lemma ceiling_altdef: "\<lceil>x\<rceil> = (if x = of_int \<lfloor>x\<rfloor> then \<lfloor>x\<rfloor> else \<lfloor>x\<rfloor> + 1)"
   593   by (intro ceiling_unique; simp, linarith?)
   594 
   595 lemma floor_le_ceiling [simp]: "\<lfloor>x\<rfloor> \<le> \<lceil>x\<rceil>"
   596   by (simp add: ceiling_altdef)
   597 
   598 
   599 subsubsection \<open>Addition and subtraction of integers.\<close>
   600 
   601 lemma ceiling_add_of_int [simp]: "\<lceil>x + of_int z\<rceil> = \<lceil>x\<rceil> + z"
   602   using ceiling_correct [of x] by (simp add: ceiling_def)
   603 
   604 lemma ceiling_add_numeral [simp]: "\<lceil>x + numeral v\<rceil> = \<lceil>x\<rceil> + numeral v"
   605   using ceiling_add_of_int [of x "numeral v"] by simp
   606 
   607 lemma ceiling_add_one [simp]: "\<lceil>x + 1\<rceil> = \<lceil>x\<rceil> + 1"
   608   using ceiling_add_of_int [of x 1] by simp
   609 
   610 lemma ceiling_diff_of_int [simp]: "\<lceil>x - of_int z\<rceil> = \<lceil>x\<rceil> - z"
   611   using ceiling_add_of_int [of x "- z"] by (simp add: algebra_simps)
   612 
   613 lemma ceiling_diff_numeral [simp]: "\<lceil>x - numeral v\<rceil> = \<lceil>x\<rceil> - numeral v"
   614   using ceiling_diff_of_int [of x "numeral v"] by simp
   615 
   616 lemma ceiling_diff_one [simp]: "\<lceil>x - 1\<rceil> = \<lceil>x\<rceil> - 1"
   617   using ceiling_diff_of_int [of x 1] by simp
   618 
   619 lemma ceiling_split[arith_split]: "P \<lceil>t\<rceil> \<longleftrightarrow> (\<forall>i. of_int i - 1 < t \<and> t \<le> of_int i \<longrightarrow> P i)"
   620   by (auto simp add: ceiling_unique ceiling_correct)
   621 
   622 lemma ceiling_diff_floor_le_1: "\<lceil>x\<rceil> - \<lfloor>x\<rfloor> \<le> 1"
   623 proof -
   624   have "of_int \<lceil>x\<rceil> - 1 < x"
   625     using ceiling_correct[of x] by simp
   626   also have "x < of_int \<lfloor>x\<rfloor> + 1"
   627     using floor_correct[of x] by simp_all
   628   finally have "of_int (\<lceil>x\<rceil> - \<lfloor>x\<rfloor>) < (of_int 2::'a)"
   629     by simp
   630   then show ?thesis
   631     unfolding of_int_less_iff by simp
   632 qed
   633 
   634 lemma nat_approx_posE:
   635   fixes e:: "'a::{archimedean_field,floor_ceiling}"
   636   assumes "0 < e"
   637   obtains n :: nat where "1 / of_nat(Suc n) < e"
   638 proof 
   639   have "(1::'a) / of_nat (Suc (nat \<lceil>1/e\<rceil>)) < 1 / of_int (\<lceil>1/e\<rceil>)"
   640   proof (rule divide_strict_left_mono)
   641     show "(of_int \<lceil>1 / e\<rceil>::'a) < of_nat (Suc (nat \<lceil>1 / e\<rceil>))"
   642       using assms by (simp add: field_simps)
   643     show "(0::'a) < of_nat (Suc (nat \<lceil>1 / e\<rceil>)) * of_int \<lceil>1 / e\<rceil>"
   644       using assms by (auto simp: zero_less_mult_iff pos_add_strict)
   645   qed auto
   646   also have "1 / of_int (\<lceil>1/e\<rceil>) \<le> 1 / (1/e)"
   647     by (rule divide_left_mono) (auto simp: \<open>0 < e\<close> ceiling_correct)
   648   also have "\<dots> = e" by simp
   649   finally show  "1 / of_nat (Suc (nat \<lceil>1 / e\<rceil>)) < e"
   650     by metis 
   651 qed
   652 
   653 subsection \<open>Negation\<close>
   654 
   655 lemma floor_minus: "\<lfloor>- x\<rfloor> = - \<lceil>x\<rceil>"
   656   unfolding ceiling_def by simp
   657 
   658 lemma ceiling_minus: "\<lceil>- x\<rceil> = - \<lfloor>x\<rfloor>"
   659   unfolding ceiling_def by simp
   660 
   661 
   662 subsection \<open>Natural numbers\<close>
   663 
   664 lemma of_nat_floor: "r\<ge>0 \<Longrightarrow> of_nat (nat \<lfloor>r\<rfloor>) \<le> r"
   665   by simp
   666 
   667 lemma of_nat_ceiling: "of_nat (nat \<lceil>r\<rceil>) \<ge> r"
   668   by (cases "r\<ge>0") auto
   669 
   670 
   671 subsection \<open>Frac Function\<close>
   672 
   673 definition frac :: "'a \<Rightarrow> 'a::floor_ceiling"
   674   where "frac x \<equiv> x - of_int \<lfloor>x\<rfloor>"
   675 
   676 lemma frac_lt_1: "frac x < 1"
   677   by (simp add: frac_def) linarith
   678 
   679 lemma frac_eq_0_iff [simp]: "frac x = 0 \<longleftrightarrow> x \<in> \<int>"
   680   by (simp add: frac_def) (metis Ints_cases Ints_of_int floor_of_int )
   681 
   682 lemma frac_ge_0 [simp]: "frac x \<ge> 0"
   683   unfolding frac_def by linarith
   684 
   685 lemma frac_gt_0_iff [simp]: "frac x > 0 \<longleftrightarrow> x \<notin> \<int>"
   686   by (metis frac_eq_0_iff frac_ge_0 le_less less_irrefl)
   687 
   688 lemma frac_of_int [simp]: "frac (of_int z) = 0"
   689   by (simp add: frac_def)
   690 
   691 lemma floor_add: "\<lfloor>x + y\<rfloor> = (if frac x + frac y < 1 then \<lfloor>x\<rfloor> + \<lfloor>y\<rfloor> else (\<lfloor>x\<rfloor> + \<lfloor>y\<rfloor>) + 1)"
   692 proof -
   693   have "x + y < 1 + (of_int \<lfloor>x\<rfloor> + of_int \<lfloor>y\<rfloor>) \<Longrightarrow> \<lfloor>x + y\<rfloor> = \<lfloor>x\<rfloor> + \<lfloor>y\<rfloor>"
   694     by (metis add.commute floor_unique le_floor_add le_floor_iff of_int_add)
   695   moreover
   696   have "\<not> x + y < 1 + (of_int \<lfloor>x\<rfloor> + of_int \<lfloor>y\<rfloor>) \<Longrightarrow> \<lfloor>x + y\<rfloor> = 1 + (\<lfloor>x\<rfloor> + \<lfloor>y\<rfloor>)"
   697     apply (simp add: floor_eq_iff)
   698     apply (auto simp add: algebra_simps)
   699     apply linarith
   700     done
   701   ultimately show ?thesis by (auto simp add: frac_def algebra_simps)
   702 qed
   703 
   704 lemma floor_add2[simp]: "x \<in> \<int> \<or> y \<in> \<int> \<Longrightarrow> \<lfloor>x + y\<rfloor> = \<lfloor>x\<rfloor> + \<lfloor>y\<rfloor>"
   705 by (metis add.commute add.left_neutral frac_lt_1 floor_add frac_eq_0_iff)
   706 
   707 lemma frac_add:
   708   "frac (x + y) = (if frac x + frac y < 1 then frac x + frac y else (frac x + frac y) - 1)"
   709   by (simp add: frac_def floor_add)
   710 
   711 lemma frac_unique_iff: "frac x = a \<longleftrightarrow> x - a \<in> \<int> \<and> 0 \<le> a \<and> a < 1"
   712   for x :: "'a::floor_ceiling"
   713   apply (auto simp: Ints_def frac_def algebra_simps floor_unique)
   714    apply linarith+
   715   done
   716 
   717 lemma frac_eq: "frac x = x \<longleftrightarrow> 0 \<le> x \<and> x < 1"
   718   by (simp add: frac_unique_iff)
   719 
   720 lemma frac_neg: "frac (- x) = (if x \<in> \<int> then 0 else 1 - frac x)"
   721   for x :: "'a::floor_ceiling"
   722   apply (auto simp add: frac_unique_iff)
   723    apply (simp add: frac_def)
   724   apply (meson frac_lt_1 less_iff_diff_less_0 not_le not_less_iff_gr_or_eq)
   725   done
   726 
   727 
   728 subsection \<open>Rounding to the nearest integer\<close>
   729 
   730 definition round :: "'a::floor_ceiling \<Rightarrow> int"
   731   where "round x = \<lfloor>x + 1/2\<rfloor>"
   732 
   733 lemma of_int_round_ge: "of_int (round x) \<ge> x - 1/2"
   734   and of_int_round_le: "of_int (round x) \<le> x + 1/2"
   735   and of_int_round_abs_le: "\<bar>of_int (round x) - x\<bar> \<le> 1/2"
   736   and of_int_round_gt: "of_int (round x) > x - 1/2"
   737 proof -
   738   from floor_correct[of "x + 1/2"] have "x + 1/2 < of_int (round x) + 1"
   739     by (simp add: round_def)
   740   from add_strict_right_mono[OF this, of "-1"] show A: "of_int (round x) > x - 1/2"
   741     by simp
   742   then show "of_int (round x) \<ge> x - 1/2"
   743     by simp
   744   from floor_correct[of "x + 1/2"] show "of_int (round x) \<le> x + 1/2"
   745     by (simp add: round_def)
   746   with A show "\<bar>of_int (round x) - x\<bar> \<le> 1/2"
   747     by linarith
   748 qed
   749 
   750 lemma round_of_int [simp]: "round (of_int n) = n"
   751   unfolding round_def by (subst floor_eq_iff) force
   752 
   753 lemma round_0 [simp]: "round 0 = 0"
   754   using round_of_int[of 0] by simp
   755 
   756 lemma round_1 [simp]: "round 1 = 1"
   757   using round_of_int[of 1] by simp
   758 
   759 lemma round_numeral [simp]: "round (numeral n) = numeral n"
   760   using round_of_int[of "numeral n"] by simp
   761 
   762 lemma round_neg_numeral [simp]: "round (-numeral n) = -numeral n"
   763   using round_of_int[of "-numeral n"] by simp
   764 
   765 lemma round_of_nat [simp]: "round (of_nat n) = of_nat n"
   766   using round_of_int[of "int n"] by simp
   767 
   768 lemma round_mono: "x \<le> y \<Longrightarrow> round x \<le> round y"
   769   unfolding round_def by (intro floor_mono) simp
   770 
   771 lemma round_unique: "of_int y > x - 1/2 \<Longrightarrow> of_int y \<le> x + 1/2 \<Longrightarrow> round x = y"
   772   unfolding round_def
   773 proof (rule floor_unique)
   774   assume "x - 1 / 2 < of_int y"
   775   from add_strict_left_mono[OF this, of 1] show "x + 1 / 2 < of_int y + 1"
   776     by simp
   777 qed
   778 
   779 lemma round_unique': "\<bar>x - of_int n\<bar> < 1/2 \<Longrightarrow> round x = n"
   780   by (subst (asm) abs_less_iff, rule round_unique) (simp_all add: field_simps)
   781 
   782 lemma round_altdef: "round x = (if frac x \<ge> 1/2 then \<lceil>x\<rceil> else \<lfloor>x\<rfloor>)"
   783   by (cases "frac x \<ge> 1/2")
   784     (rule round_unique, ((simp add: frac_def field_simps ceiling_altdef; linarith)+)[2])+
   785 
   786 lemma floor_le_round: "\<lfloor>x\<rfloor> \<le> round x"
   787   unfolding round_def by (intro floor_mono) simp
   788 
   789 lemma ceiling_ge_round: "\<lceil>x\<rceil> \<ge> round x"
   790   unfolding round_altdef by simp
   791 
   792 lemma round_diff_minimal: "\<bar>z - of_int (round z)\<bar> \<le> \<bar>z - of_int m\<bar>"
   793   for z :: "'a::floor_ceiling"
   794 proof (cases "of_int m \<ge> z")
   795   case True
   796   then have "\<bar>z - of_int (round z)\<bar> \<le> \<bar>of_int \<lceil>z\<rceil> - z\<bar>"
   797     unfolding round_altdef by (simp add: field_simps ceiling_altdef frac_def) linarith
   798   also have "of_int \<lceil>z\<rceil> - z \<ge> 0"
   799     by linarith
   800   with True have "\<bar>of_int \<lceil>z\<rceil> - z\<bar> \<le> \<bar>z - of_int m\<bar>"
   801     by (simp add: ceiling_le_iff)
   802   finally show ?thesis .
   803 next
   804   case False
   805   then have "\<bar>z - of_int (round z)\<bar> \<le> \<bar>of_int \<lfloor>z\<rfloor> - z\<bar>"
   806     unfolding round_altdef by (simp add: field_simps ceiling_altdef frac_def) linarith
   807   also have "z - of_int \<lfloor>z\<rfloor> \<ge> 0"
   808     by linarith
   809   with False have "\<bar>of_int \<lfloor>z\<rfloor> - z\<bar> \<le> \<bar>z - of_int m\<bar>"
   810     by (simp add: le_floor_iff)
   811   finally show ?thesis .
   812 qed
   813 
   814 end