src/HOL/Limits.thy
 author paulson Mon Oct 09 15:34:23 2017 +0100 (23 months ago) changeset 66793 deabce3ccf1f parent 66456 621897f47fab child 66827 c94531b5007d permissions -rw-r--r--
new material about connectedness, etc.
```     1 (*  Title:      HOL/Limits.thy
```
```     2     Author:     Brian Huffman
```
```     3     Author:     Jacques D. Fleuriot, University of Cambridge
```
```     4     Author:     Lawrence C Paulson
```
```     5     Author:     Jeremy Avigad
```
```     6 *)
```
```     7
```
```     8 section \<open>Limits on Real Vector Spaces\<close>
```
```     9
```
```    10 theory Limits
```
```    11   imports Real_Vector_Spaces
```
```    12 begin
```
```    13
```
```    14 subsection \<open>Filter going to infinity norm\<close>
```
```    15
```
```    16 definition at_infinity :: "'a::real_normed_vector filter"
```
```    17   where "at_infinity = (INF r. principal {x. r \<le> norm x})"
```
```    18
```
```    19 lemma eventually_at_infinity: "eventually P at_infinity \<longleftrightarrow> (\<exists>b. \<forall>x. b \<le> norm x \<longrightarrow> P x)"
```
```    20   unfolding at_infinity_def
```
```    21   by (subst eventually_INF_base)
```
```    22      (auto simp: subset_eq eventually_principal intro!: exI[of _ "max a b" for a b])
```
```    23
```
```    24 corollary eventually_at_infinity_pos:
```
```    25   "eventually p at_infinity \<longleftrightarrow> (\<exists>b. 0 < b \<and> (\<forall>x. norm x \<ge> b \<longrightarrow> p x))"
```
```    26   apply (simp add: eventually_at_infinity)
```
```    27   apply auto
```
```    28   apply (case_tac "b \<le> 0")
```
```    29   using norm_ge_zero order_trans zero_less_one apply blast
```
```    30   apply force
```
```    31   done
```
```    32
```
```    33 lemma at_infinity_eq_at_top_bot: "(at_infinity :: real filter) = sup at_top at_bot"
```
```    34   apply (simp add: filter_eq_iff eventually_sup eventually_at_infinity
```
```    35       eventually_at_top_linorder eventually_at_bot_linorder)
```
```    36   apply safe
```
```    37     apply (rule_tac x="b" in exI)
```
```    38     apply simp
```
```    39    apply (rule_tac x="- b" in exI)
```
```    40    apply simp
```
```    41   apply (rule_tac x="max (- Na) N" in exI)
```
```    42   apply (auto simp: abs_real_def)
```
```    43   done
```
```    44
```
```    45 lemma at_top_le_at_infinity: "at_top \<le> (at_infinity :: real filter)"
```
```    46   unfolding at_infinity_eq_at_top_bot by simp
```
```    47
```
```    48 lemma at_bot_le_at_infinity: "at_bot \<le> (at_infinity :: real filter)"
```
```    49   unfolding at_infinity_eq_at_top_bot by simp
```
```    50
```
```    51 lemma filterlim_at_top_imp_at_infinity: "filterlim f at_top F \<Longrightarrow> filterlim f at_infinity F"
```
```    52   for f :: "_ \<Rightarrow> real"
```
```    53   by (rule filterlim_mono[OF _ at_top_le_at_infinity order_refl])
```
```    54
```
```    55 lemma lim_infinity_imp_sequentially: "(f \<longlongrightarrow> l) at_infinity \<Longrightarrow> ((\<lambda>n. f(n)) \<longlongrightarrow> l) sequentially"
```
```    56   by (simp add: filterlim_at_top_imp_at_infinity filterlim_compose filterlim_real_sequentially)
```
```    57
```
```    58
```
```    59 subsubsection \<open>Boundedness\<close>
```
```    60
```
```    61 definition Bfun :: "('a \<Rightarrow> 'b::metric_space) \<Rightarrow> 'a filter \<Rightarrow> bool"
```
```    62   where Bfun_metric_def: "Bfun f F = (\<exists>y. \<exists>K>0. eventually (\<lambda>x. dist (f x) y \<le> K) F)"
```
```    63
```
```    64 abbreviation Bseq :: "(nat \<Rightarrow> 'a::metric_space) \<Rightarrow> bool"
```
```    65   where "Bseq X \<equiv> Bfun X sequentially"
```
```    66
```
```    67 lemma Bseq_conv_Bfun: "Bseq X \<longleftrightarrow> Bfun X sequentially" ..
```
```    68
```
```    69 lemma Bseq_ignore_initial_segment: "Bseq X \<Longrightarrow> Bseq (\<lambda>n. X (n + k))"
```
```    70   unfolding Bfun_metric_def by (subst eventually_sequentially_seg)
```
```    71
```
```    72 lemma Bseq_offset: "Bseq (\<lambda>n. X (n + k)) \<Longrightarrow> Bseq X"
```
```    73   unfolding Bfun_metric_def by (subst (asm) eventually_sequentially_seg)
```
```    74
```
```    75 lemma Bfun_def: "Bfun f F \<longleftrightarrow> (\<exists>K>0. eventually (\<lambda>x. norm (f x) \<le> K) F)"
```
```    76   unfolding Bfun_metric_def norm_conv_dist
```
```    77 proof safe
```
```    78   fix y K
```
```    79   assume K: "0 < K" and *: "eventually (\<lambda>x. dist (f x) y \<le> K) F"
```
```    80   moreover have "eventually (\<lambda>x. dist (f x) 0 \<le> dist (f x) y + dist 0 y) F"
```
```    81     by (intro always_eventually) (metis dist_commute dist_triangle)
```
```    82   with * have "eventually (\<lambda>x. dist (f x) 0 \<le> K + dist 0 y) F"
```
```    83     by eventually_elim auto
```
```    84   with \<open>0 < K\<close> show "\<exists>K>0. eventually (\<lambda>x. dist (f x) 0 \<le> K) F"
```
```    85     by (intro exI[of _ "K + dist 0 y"] add_pos_nonneg conjI zero_le_dist) auto
```
```    86 qed (force simp del: norm_conv_dist [symmetric])
```
```    87
```
```    88 lemma BfunI:
```
```    89   assumes K: "eventually (\<lambda>x. norm (f x) \<le> K) F"
```
```    90   shows "Bfun f F"
```
```    91   unfolding Bfun_def
```
```    92 proof (intro exI conjI allI)
```
```    93   show "0 < max K 1" by simp
```
```    94   show "eventually (\<lambda>x. norm (f x) \<le> max K 1) F"
```
```    95     using K by (rule eventually_mono) simp
```
```    96 qed
```
```    97
```
```    98 lemma BfunE:
```
```    99   assumes "Bfun f F"
```
```   100   obtains B where "0 < B" and "eventually (\<lambda>x. norm (f x) \<le> B) F"
```
```   101   using assms unfolding Bfun_def by blast
```
```   102
```
```   103 lemma Cauchy_Bseq: "Cauchy X \<Longrightarrow> Bseq X"
```
```   104   unfolding Cauchy_def Bfun_metric_def eventually_sequentially
```
```   105   apply (erule_tac x=1 in allE)
```
```   106   apply simp
```
```   107   apply safe
```
```   108   apply (rule_tac x="X M" in exI)
```
```   109   apply (rule_tac x=1 in exI)
```
```   110   apply (erule_tac x=M in allE)
```
```   111   apply simp
```
```   112   apply (rule_tac x=M in exI)
```
```   113   apply (auto simp: dist_commute)
```
```   114   done
```
```   115
```
```   116
```
```   117 subsubsection \<open>Bounded Sequences\<close>
```
```   118
```
```   119 lemma BseqI': "(\<And>n. norm (X n) \<le> K) \<Longrightarrow> Bseq X"
```
```   120   by (intro BfunI) (auto simp: eventually_sequentially)
```
```   121
```
```   122 lemma BseqI2': "\<forall>n\<ge>N. norm (X n) \<le> K \<Longrightarrow> Bseq X"
```
```   123   by (intro BfunI) (auto simp: eventually_sequentially)
```
```   124
```
```   125 lemma Bseq_def: "Bseq X \<longleftrightarrow> (\<exists>K>0. \<forall>n. norm (X n) \<le> K)"
```
```   126   unfolding Bfun_def eventually_sequentially
```
```   127 proof safe
```
```   128   fix N K
```
```   129   assume "0 < K" "\<forall>n\<ge>N. norm (X n) \<le> K"
```
```   130   then show "\<exists>K>0. \<forall>n. norm (X n) \<le> K"
```
```   131     by (intro exI[of _ "max (Max (norm ` X ` {..N})) K"] max.strict_coboundedI2)
```
```   132        (auto intro!: imageI not_less[where 'a=nat, THEN iffD1] Max_ge simp: le_max_iff_disj)
```
```   133 qed auto
```
```   134
```
```   135 lemma BseqE: "Bseq X \<Longrightarrow> (\<And>K. 0 < K \<Longrightarrow> \<forall>n. norm (X n) \<le> K \<Longrightarrow> Q) \<Longrightarrow> Q"
```
```   136   unfolding Bseq_def by auto
```
```   137
```
```   138 lemma BseqD: "Bseq X \<Longrightarrow> \<exists>K. 0 < K \<and> (\<forall>n. norm (X n) \<le> K)"
```
```   139   by (simp add: Bseq_def)
```
```   140
```
```   141 lemma BseqI: "0 < K \<Longrightarrow> \<forall>n. norm (X n) \<le> K \<Longrightarrow> Bseq X"
```
```   142   by (auto simp add: Bseq_def)
```
```   143
```
```   144 lemma Bseq_bdd_above: "Bseq X \<Longrightarrow> bdd_above (range X)"
```
```   145   for X :: "nat \<Rightarrow> real"
```
```   146 proof (elim BseqE, intro bdd_aboveI2)
```
```   147   fix K n
```
```   148   assume "0 < K" "\<forall>n. norm (X n) \<le> K"
```
```   149   then show "X n \<le> K"
```
```   150     by (auto elim!: allE[of _ n])
```
```   151 qed
```
```   152
```
```   153 lemma Bseq_bdd_above': "Bseq X \<Longrightarrow> bdd_above (range (\<lambda>n. norm (X n)))"
```
```   154   for X :: "nat \<Rightarrow> 'a :: real_normed_vector"
```
```   155 proof (elim BseqE, intro bdd_aboveI2)
```
```   156   fix K n
```
```   157   assume "0 < K" "\<forall>n. norm (X n) \<le> K"
```
```   158   then show "norm (X n) \<le> K"
```
```   159     by (auto elim!: allE[of _ n])
```
```   160 qed
```
```   161
```
```   162 lemma Bseq_bdd_below: "Bseq X \<Longrightarrow> bdd_below (range X)"
```
```   163   for X :: "nat \<Rightarrow> real"
```
```   164 proof (elim BseqE, intro bdd_belowI2)
```
```   165   fix K n
```
```   166   assume "0 < K" "\<forall>n. norm (X n) \<le> K"
```
```   167   then show "- K \<le> X n"
```
```   168     by (auto elim!: allE[of _ n])
```
```   169 qed
```
```   170
```
```   171 lemma Bseq_eventually_mono:
```
```   172   assumes "eventually (\<lambda>n. norm (f n) \<le> norm (g n)) sequentially" "Bseq g"
```
```   173   shows "Bseq f"
```
```   174 proof -
```
```   175   from assms(1) obtain N where N: "\<And>n. n \<ge> N \<Longrightarrow> norm (f n) \<le> norm (g n)"
```
```   176     by (auto simp: eventually_at_top_linorder)
```
```   177   moreover from assms(2) obtain K where K: "\<And>n. norm (g n) \<le> K"
```
```   178     by (blast elim!: BseqE)
```
```   179   ultimately have "norm (f n) \<le> max K (Max {norm (f n) |n. n < N})" for n
```
```   180     apply (cases "n < N")
```
```   181     subgoal by (rule max.coboundedI2, rule Max.coboundedI) auto
```
```   182     subgoal by (rule max.coboundedI1) (force intro: order.trans[OF N K])
```
```   183     done
```
```   184   then show ?thesis by (blast intro: BseqI')
```
```   185 qed
```
```   186
```
```   187 lemma lemma_NBseq_def: "(\<exists>K > 0. \<forall>n. norm (X n) \<le> K) \<longleftrightarrow> (\<exists>N. \<forall>n. norm (X n) \<le> real(Suc N))"
```
```   188 proof safe
```
```   189   fix K :: real
```
```   190   from reals_Archimedean2 obtain n :: nat where "K < real n" ..
```
```   191   then have "K \<le> real (Suc n)" by auto
```
```   192   moreover assume "\<forall>m. norm (X m) \<le> K"
```
```   193   ultimately have "\<forall>m. norm (X m) \<le> real (Suc n)"
```
```   194     by (blast intro: order_trans)
```
```   195   then show "\<exists>N. \<forall>n. norm (X n) \<le> real (Suc N)" ..
```
```   196 next
```
```   197   show "\<And>N. \<forall>n. norm (X n) \<le> real (Suc N) \<Longrightarrow> \<exists>K>0. \<forall>n. norm (X n) \<le> K"
```
```   198     using of_nat_0_less_iff by blast
```
```   199 qed
```
```   200
```
```   201 text \<open>Alternative definition for \<open>Bseq\<close>.\<close>
```
```   202 lemma Bseq_iff: "Bseq X \<longleftrightarrow> (\<exists>N. \<forall>n. norm (X n) \<le> real(Suc N))"
```
```   203   by (simp add: Bseq_def) (simp add: lemma_NBseq_def)
```
```   204
```
```   205 lemma lemma_NBseq_def2: "(\<exists>K > 0. \<forall>n. norm (X n) \<le> K) = (\<exists>N. \<forall>n. norm (X n) < real(Suc N))"
```
```   206   apply (subst lemma_NBseq_def)
```
```   207   apply auto
```
```   208    apply (rule_tac x = "Suc N" in exI)
```
```   209    apply (rule_tac [2] x = N in exI)
```
```   210    apply auto
```
```   211    prefer 2 apply (blast intro: order_less_imp_le)
```
```   212   apply (drule_tac x = n in spec)
```
```   213   apply simp
```
```   214   done
```
```   215
```
```   216 text \<open>Yet another definition for Bseq.\<close>
```
```   217 lemma Bseq_iff1a: "Bseq X \<longleftrightarrow> (\<exists>N. \<forall>n. norm (X n) < real (Suc N))"
```
```   218   by (simp add: Bseq_def lemma_NBseq_def2)
```
```   219
```
```   220 subsubsection \<open>A Few More Equivalence Theorems for Boundedness\<close>
```
```   221
```
```   222 text \<open>Alternative formulation for boundedness.\<close>
```
```   223 lemma Bseq_iff2: "Bseq X \<longleftrightarrow> (\<exists>k > 0. \<exists>x. \<forall>n. norm (X n + - x) \<le> k)"
```
```   224   apply (unfold Bseq_def)
```
```   225   apply safe
```
```   226    apply (rule_tac [2] x = "k + norm x" in exI)
```
```   227    apply (rule_tac x = K in exI)
```
```   228    apply simp
```
```   229    apply (rule exI [where x = 0])
```
```   230    apply auto
```
```   231    apply (erule order_less_le_trans)
```
```   232    apply simp
```
```   233   apply (drule_tac x=n in spec)
```
```   234   apply (drule order_trans [OF norm_triangle_ineq2])
```
```   235   apply simp
```
```   236   done
```
```   237
```
```   238 text \<open>Alternative formulation for boundedness.\<close>
```
```   239 lemma Bseq_iff3: "Bseq X \<longleftrightarrow> (\<exists>k>0. \<exists>N. \<forall>n. norm (X n + - X N) \<le> k)"
```
```   240   (is "?P \<longleftrightarrow> ?Q")
```
```   241 proof
```
```   242   assume ?P
```
```   243   then obtain K where *: "0 < K" and **: "\<And>n. norm (X n) \<le> K"
```
```   244     by (auto simp add: Bseq_def)
```
```   245   from * have "0 < K + norm (X 0)" by (rule order_less_le_trans) simp
```
```   246   from ** have "\<forall>n. norm (X n - X 0) \<le> K + norm (X 0)"
```
```   247     by (auto intro: order_trans norm_triangle_ineq4)
```
```   248   then have "\<forall>n. norm (X n + - X 0) \<le> K + norm (X 0)"
```
```   249     by simp
```
```   250   with \<open>0 < K + norm (X 0)\<close> show ?Q by blast
```
```   251 next
```
```   252   assume ?Q
```
```   253   then show ?P by (auto simp add: Bseq_iff2)
```
```   254 qed
```
```   255
```
```   256 lemma BseqI2: "\<forall>n. k \<le> f n \<and> f n \<le> K \<Longrightarrow> Bseq f"
```
```   257   for k K :: real
```
```   258   apply (simp add: Bseq_def)
```
```   259   apply (rule_tac x = "(\<bar>k\<bar> + \<bar>K\<bar>) + 1" in exI)
```
```   260   apply auto
```
```   261   apply (drule_tac x = n in spec)
```
```   262   apply arith
```
```   263   done
```
```   264
```
```   265
```
```   266 subsubsection \<open>Upper Bounds and Lubs of Bounded Sequences\<close>
```
```   267
```
```   268 lemma Bseq_minus_iff: "Bseq (\<lambda>n. - (X n) :: 'a::real_normed_vector) \<longleftrightarrow> Bseq X"
```
```   269   by (simp add: Bseq_def)
```
```   270
```
```   271 lemma Bseq_add:
```
```   272   fixes f :: "nat \<Rightarrow> 'a::real_normed_vector"
```
```   273   assumes "Bseq f"
```
```   274   shows "Bseq (\<lambda>x. f x + c)"
```
```   275 proof -
```
```   276   from assms obtain K where K: "\<And>x. norm (f x) \<le> K"
```
```   277     unfolding Bseq_def by blast
```
```   278   {
```
```   279     fix x :: nat
```
```   280     have "norm (f x + c) \<le> norm (f x) + norm c" by (rule norm_triangle_ineq)
```
```   281     also have "norm (f x) \<le> K" by (rule K)
```
```   282     finally have "norm (f x + c) \<le> K + norm c" by simp
```
```   283   }
```
```   284   then show ?thesis by (rule BseqI')
```
```   285 qed
```
```   286
```
```   287 lemma Bseq_add_iff: "Bseq (\<lambda>x. f x + c) \<longleftrightarrow> Bseq f"
```
```   288   for f :: "nat \<Rightarrow> 'a::real_normed_vector"
```
```   289   using Bseq_add[of f c] Bseq_add[of "\<lambda>x. f x + c" "-c"] by auto
```
```   290
```
```   291 lemma Bseq_mult:
```
```   292   fixes f g :: "nat \<Rightarrow> 'a::real_normed_field"
```
```   293   assumes "Bseq f" and "Bseq g"
```
```   294   shows "Bseq (\<lambda>x. f x * g x)"
```
```   295 proof -
```
```   296   from assms obtain K1 K2 where K: "norm (f x) \<le> K1" "K1 > 0" "norm (g x) \<le> K2" "K2 > 0"
```
```   297     for x
```
```   298     unfolding Bseq_def by blast
```
```   299   then have "norm (f x * g x) \<le> K1 * K2" for x
```
```   300     by (auto simp: norm_mult intro!: mult_mono)
```
```   301   then show ?thesis by (rule BseqI')
```
```   302 qed
```
```   303
```
```   304 lemma Bfun_const [simp]: "Bfun (\<lambda>_. c) F"
```
```   305   unfolding Bfun_metric_def by (auto intro!: exI[of _ c] exI[of _ "1::real"])
```
```   306
```
```   307 lemma Bseq_cmult_iff:
```
```   308   fixes c :: "'a::real_normed_field"
```
```   309   assumes "c \<noteq> 0"
```
```   310   shows "Bseq (\<lambda>x. c * f x) \<longleftrightarrow> Bseq f"
```
```   311 proof
```
```   312   assume "Bseq (\<lambda>x. c * f x)"
```
```   313   with Bfun_const have "Bseq (\<lambda>x. inverse c * (c * f x))"
```
```   314     by (rule Bseq_mult)
```
```   315   with \<open>c \<noteq> 0\<close> show "Bseq f"
```
```   316     by (simp add: divide_simps)
```
```   317 qed (intro Bseq_mult Bfun_const)
```
```   318
```
```   319 lemma Bseq_subseq: "Bseq f \<Longrightarrow> Bseq (\<lambda>x. f (g x))"
```
```   320   for f :: "nat \<Rightarrow> 'a::real_normed_vector"
```
```   321   unfolding Bseq_def by auto
```
```   322
```
```   323 lemma Bseq_Suc_iff: "Bseq (\<lambda>n. f (Suc n)) \<longleftrightarrow> Bseq f"
```
```   324   for f :: "nat \<Rightarrow> 'a::real_normed_vector"
```
```   325   using Bseq_offset[of f 1] by (auto intro: Bseq_subseq)
```
```   326
```
```   327 lemma increasing_Bseq_subseq_iff:
```
```   328   assumes "\<And>x y. x \<le> y \<Longrightarrow> norm (f x :: 'a::real_normed_vector) \<le> norm (f y)" "strict_mono g"
```
```   329   shows "Bseq (\<lambda>x. f (g x)) \<longleftrightarrow> Bseq f"
```
```   330 proof
```
```   331   assume "Bseq (\<lambda>x. f (g x))"
```
```   332   then obtain K where K: "\<And>x. norm (f (g x)) \<le> K"
```
```   333     unfolding Bseq_def by auto
```
```   334   {
```
```   335     fix x :: nat
```
```   336     from filterlim_subseq[OF assms(2)] obtain y where "g y \<ge> x"
```
```   337       by (auto simp: filterlim_at_top eventually_at_top_linorder)
```
```   338     then have "norm (f x) \<le> norm (f (g y))"
```
```   339       using assms(1) by blast
```
```   340     also have "norm (f (g y)) \<le> K" by (rule K)
```
```   341     finally have "norm (f x) \<le> K" .
```
```   342   }
```
```   343   then show "Bseq f" by (rule BseqI')
```
```   344 qed (use Bseq_subseq[of f g] in simp_all)
```
```   345
```
```   346 lemma nonneg_incseq_Bseq_subseq_iff:
```
```   347   fixes f :: "nat \<Rightarrow> real"
```
```   348     and g :: "nat \<Rightarrow> nat"
```
```   349   assumes "\<And>x. f x \<ge> 0" "incseq f" "strict_mono g"
```
```   350   shows "Bseq (\<lambda>x. f (g x)) \<longleftrightarrow> Bseq f"
```
```   351   using assms by (intro increasing_Bseq_subseq_iff) (auto simp: incseq_def)
```
```   352
```
```   353 lemma Bseq_eq_bounded: "range f \<subseteq> {a..b} \<Longrightarrow> Bseq f"
```
```   354   for a b :: real
```
```   355   apply (simp add: subset_eq)
```
```   356   apply (rule BseqI'[where K="max (norm a) (norm b)"])
```
```   357   apply (erule_tac x=n in allE)
```
```   358   apply auto
```
```   359   done
```
```   360
```
```   361 lemma incseq_bounded: "incseq X \<Longrightarrow> \<forall>i. X i \<le> B \<Longrightarrow> Bseq X"
```
```   362   for B :: real
```
```   363   by (intro Bseq_eq_bounded[of X "X 0" B]) (auto simp: incseq_def)
```
```   364
```
```   365 lemma decseq_bounded: "decseq X \<Longrightarrow> \<forall>i. B \<le> X i \<Longrightarrow> Bseq X"
```
```   366   for B :: real
```
```   367   by (intro Bseq_eq_bounded[of X B "X 0"]) (auto simp: decseq_def)
```
```   368
```
```   369
```
```   370 subsection \<open>Bounded Monotonic Sequences\<close>
```
```   371
```
```   372 subsubsection \<open>A Bounded and Monotonic Sequence Converges\<close>
```
```   373
```
```   374 (* TODO: delete *)
```
```   375 (* FIXME: one use in NSA/HSEQ.thy *)
```
```   376 lemma Bmonoseq_LIMSEQ: "\<forall>n. m \<le> n \<longrightarrow> X n = X m \<Longrightarrow> \<exists>L. X \<longlonglongrightarrow> L"
```
```   377   apply (rule_tac x="X m" in exI)
```
```   378   apply (rule filterlim_cong[THEN iffD2, OF refl refl _ tendsto_const])
```
```   379   unfolding eventually_sequentially
```
```   380   apply blast
```
```   381   done
```
```   382
```
```   383
```
```   384 subsection \<open>Convergence to Zero\<close>
```
```   385
```
```   386 definition Zfun :: "('a \<Rightarrow> 'b::real_normed_vector) \<Rightarrow> 'a filter \<Rightarrow> bool"
```
```   387   where "Zfun f F = (\<forall>r>0. eventually (\<lambda>x. norm (f x) < r) F)"
```
```   388
```
```   389 lemma ZfunI: "(\<And>r. 0 < r \<Longrightarrow> eventually (\<lambda>x. norm (f x) < r) F) \<Longrightarrow> Zfun f F"
```
```   390   by (simp add: Zfun_def)
```
```   391
```
```   392 lemma ZfunD: "Zfun f F \<Longrightarrow> 0 < r \<Longrightarrow> eventually (\<lambda>x. norm (f x) < r) F"
```
```   393   by (simp add: Zfun_def)
```
```   394
```
```   395 lemma Zfun_ssubst: "eventually (\<lambda>x. f x = g x) F \<Longrightarrow> Zfun g F \<Longrightarrow> Zfun f F"
```
```   396   unfolding Zfun_def by (auto elim!: eventually_rev_mp)
```
```   397
```
```   398 lemma Zfun_zero: "Zfun (\<lambda>x. 0) F"
```
```   399   unfolding Zfun_def by simp
```
```   400
```
```   401 lemma Zfun_norm_iff: "Zfun (\<lambda>x. norm (f x)) F = Zfun (\<lambda>x. f x) F"
```
```   402   unfolding Zfun_def by simp
```
```   403
```
```   404 lemma Zfun_imp_Zfun:
```
```   405   assumes f: "Zfun f F"
```
```   406     and g: "eventually (\<lambda>x. norm (g x) \<le> norm (f x) * K) F"
```
```   407   shows "Zfun (\<lambda>x. g x) F"
```
```   408 proof (cases "0 < K")
```
```   409   case K: True
```
```   410   show ?thesis
```
```   411   proof (rule ZfunI)
```
```   412     fix r :: real
```
```   413     assume "0 < r"
```
```   414     then have "0 < r / K" using K by simp
```
```   415     then have "eventually (\<lambda>x. norm (f x) < r / K) F"
```
```   416       using ZfunD [OF f] by blast
```
```   417     with g show "eventually (\<lambda>x. norm (g x) < r) F"
```
```   418     proof eventually_elim
```
```   419       case (elim x)
```
```   420       then have "norm (f x) * K < r"
```
```   421         by (simp add: pos_less_divide_eq K)
```
```   422       then show ?case
```
```   423         by (simp add: order_le_less_trans [OF elim(1)])
```
```   424     qed
```
```   425   qed
```
```   426 next
```
```   427   case False
```
```   428   then have K: "K \<le> 0" by (simp only: not_less)
```
```   429   show ?thesis
```
```   430   proof (rule ZfunI)
```
```   431     fix r :: real
```
```   432     assume "0 < r"
```
```   433     from g show "eventually (\<lambda>x. norm (g x) < r) F"
```
```   434     proof eventually_elim
```
```   435       case (elim x)
```
```   436       also have "norm (f x) * K \<le> norm (f x) * 0"
```
```   437         using K norm_ge_zero by (rule mult_left_mono)
```
```   438       finally show ?case
```
```   439         using \<open>0 < r\<close> by simp
```
```   440     qed
```
```   441   qed
```
```   442 qed
```
```   443
```
```   444 lemma Zfun_le: "Zfun g F \<Longrightarrow> \<forall>x. norm (f x) \<le> norm (g x) \<Longrightarrow> Zfun f F"
```
```   445   by (erule Zfun_imp_Zfun [where K = 1]) simp
```
```   446
```
```   447 lemma Zfun_add:
```
```   448   assumes f: "Zfun f F"
```
```   449     and g: "Zfun g F"
```
```   450   shows "Zfun (\<lambda>x. f x + g x) F"
```
```   451 proof (rule ZfunI)
```
```   452   fix r :: real
```
```   453   assume "0 < r"
```
```   454   then have r: "0 < r / 2" by simp
```
```   455   have "eventually (\<lambda>x. norm (f x) < r/2) F"
```
```   456     using f r by (rule ZfunD)
```
```   457   moreover
```
```   458   have "eventually (\<lambda>x. norm (g x) < r/2) F"
```
```   459     using g r by (rule ZfunD)
```
```   460   ultimately
```
```   461   show "eventually (\<lambda>x. norm (f x + g x) < r) F"
```
```   462   proof eventually_elim
```
```   463     case (elim x)
```
```   464     have "norm (f x + g x) \<le> norm (f x) + norm (g x)"
```
```   465       by (rule norm_triangle_ineq)
```
```   466     also have "\<dots> < r/2 + r/2"
```
```   467       using elim by (rule add_strict_mono)
```
```   468     finally show ?case
```
```   469       by simp
```
```   470   qed
```
```   471 qed
```
```   472
```
```   473 lemma Zfun_minus: "Zfun f F \<Longrightarrow> Zfun (\<lambda>x. - f x) F"
```
```   474   unfolding Zfun_def by simp
```
```   475
```
```   476 lemma Zfun_diff: "Zfun f F \<Longrightarrow> Zfun g F \<Longrightarrow> Zfun (\<lambda>x. f x - g x) F"
```
```   477   using Zfun_add [of f F "\<lambda>x. - g x"] by (simp add: Zfun_minus)
```
```   478
```
```   479 lemma (in bounded_linear) Zfun:
```
```   480   assumes g: "Zfun g F"
```
```   481   shows "Zfun (\<lambda>x. f (g x)) F"
```
```   482 proof -
```
```   483   obtain K where "norm (f x) \<le> norm x * K" for x
```
```   484     using bounded by blast
```
```   485   then have "eventually (\<lambda>x. norm (f (g x)) \<le> norm (g x) * K) F"
```
```   486     by simp
```
```   487   with g show ?thesis
```
```   488     by (rule Zfun_imp_Zfun)
```
```   489 qed
```
```   490
```
```   491 lemma (in bounded_bilinear) Zfun:
```
```   492   assumes f: "Zfun f F"
```
```   493     and g: "Zfun g F"
```
```   494   shows "Zfun (\<lambda>x. f x ** g x) F"
```
```   495 proof (rule ZfunI)
```
```   496   fix r :: real
```
```   497   assume r: "0 < r"
```
```   498   obtain K where K: "0 < K"
```
```   499     and norm_le: "norm (x ** y) \<le> norm x * norm y * K" for x y
```
```   500     using pos_bounded by blast
```
```   501   from K have K': "0 < inverse K"
```
```   502     by (rule positive_imp_inverse_positive)
```
```   503   have "eventually (\<lambda>x. norm (f x) < r) F"
```
```   504     using f r by (rule ZfunD)
```
```   505   moreover
```
```   506   have "eventually (\<lambda>x. norm (g x) < inverse K) F"
```
```   507     using g K' by (rule ZfunD)
```
```   508   ultimately
```
```   509   show "eventually (\<lambda>x. norm (f x ** g x) < r) F"
```
```   510   proof eventually_elim
```
```   511     case (elim x)
```
```   512     have "norm (f x ** g x) \<le> norm (f x) * norm (g x) * K"
```
```   513       by (rule norm_le)
```
```   514     also have "norm (f x) * norm (g x) * K < r * inverse K * K"
```
```   515       by (intro mult_strict_right_mono mult_strict_mono' norm_ge_zero elim K)
```
```   516     also from K have "r * inverse K * K = r"
```
```   517       by simp
```
```   518     finally show ?case .
```
```   519   qed
```
```   520 qed
```
```   521
```
```   522 lemma (in bounded_bilinear) Zfun_left: "Zfun f F \<Longrightarrow> Zfun (\<lambda>x. f x ** a) F"
```
```   523   by (rule bounded_linear_left [THEN bounded_linear.Zfun])
```
```   524
```
```   525 lemma (in bounded_bilinear) Zfun_right: "Zfun f F \<Longrightarrow> Zfun (\<lambda>x. a ** f x) F"
```
```   526   by (rule bounded_linear_right [THEN bounded_linear.Zfun])
```
```   527
```
```   528 lemmas Zfun_mult = bounded_bilinear.Zfun [OF bounded_bilinear_mult]
```
```   529 lemmas Zfun_mult_right = bounded_bilinear.Zfun_right [OF bounded_bilinear_mult]
```
```   530 lemmas Zfun_mult_left = bounded_bilinear.Zfun_left [OF bounded_bilinear_mult]
```
```   531
```
```   532 lemma tendsto_Zfun_iff: "(f \<longlongrightarrow> a) F = Zfun (\<lambda>x. f x - a) F"
```
```   533   by (simp only: tendsto_iff Zfun_def dist_norm)
```
```   534
```
```   535 lemma tendsto_0_le:
```
```   536   "(f \<longlongrightarrow> 0) F \<Longrightarrow> eventually (\<lambda>x. norm (g x) \<le> norm (f x) * K) F \<Longrightarrow> (g \<longlongrightarrow> 0) F"
```
```   537   by (simp add: Zfun_imp_Zfun tendsto_Zfun_iff)
```
```   538
```
```   539
```
```   540 subsubsection \<open>Distance and norms\<close>
```
```   541
```
```   542 lemma tendsto_dist [tendsto_intros]:
```
```   543   fixes l m :: "'a::metric_space"
```
```   544   assumes f: "(f \<longlongrightarrow> l) F"
```
```   545     and g: "(g \<longlongrightarrow> m) F"
```
```   546   shows "((\<lambda>x. dist (f x) (g x)) \<longlongrightarrow> dist l m) F"
```
```   547 proof (rule tendstoI)
```
```   548   fix e :: real
```
```   549   assume "0 < e"
```
```   550   then have e2: "0 < e/2" by simp
```
```   551   from tendstoD [OF f e2] tendstoD [OF g e2]
```
```   552   show "eventually (\<lambda>x. dist (dist (f x) (g x)) (dist l m) < e) F"
```
```   553   proof (eventually_elim)
```
```   554     case (elim x)
```
```   555     then show "dist (dist (f x) (g x)) (dist l m) < e"
```
```   556       unfolding dist_real_def
```
```   557       using dist_triangle2 [of "f x" "g x" "l"]
```
```   558         and dist_triangle2 [of "g x" "l" "m"]
```
```   559         and dist_triangle3 [of "l" "m" "f x"]
```
```   560         and dist_triangle [of "f x" "m" "g x"]
```
```   561       by arith
```
```   562   qed
```
```   563 qed
```
```   564
```
```   565 lemma continuous_dist[continuous_intros]:
```
```   566   fixes f g :: "_ \<Rightarrow> 'a :: metric_space"
```
```   567   shows "continuous F f \<Longrightarrow> continuous F g \<Longrightarrow> continuous F (\<lambda>x. dist (f x) (g x))"
```
```   568   unfolding continuous_def by (rule tendsto_dist)
```
```   569
```
```   570 lemma continuous_on_dist[continuous_intros]:
```
```   571   fixes f g :: "_ \<Rightarrow> 'a :: metric_space"
```
```   572   shows "continuous_on s f \<Longrightarrow> continuous_on s g \<Longrightarrow> continuous_on s (\<lambda>x. dist (f x) (g x))"
```
```   573   unfolding continuous_on_def by (auto intro: tendsto_dist)
```
```   574
```
```   575 lemma tendsto_norm [tendsto_intros]: "(f \<longlongrightarrow> a) F \<Longrightarrow> ((\<lambda>x. norm (f x)) \<longlongrightarrow> norm a) F"
```
```   576   unfolding norm_conv_dist by (intro tendsto_intros)
```
```   577
```
```   578 lemma continuous_norm [continuous_intros]: "continuous F f \<Longrightarrow> continuous F (\<lambda>x. norm (f x))"
```
```   579   unfolding continuous_def by (rule tendsto_norm)
```
```   580
```
```   581 lemma continuous_on_norm [continuous_intros]:
```
```   582   "continuous_on s f \<Longrightarrow> continuous_on s (\<lambda>x. norm (f x))"
```
```   583   unfolding continuous_on_def by (auto intro: tendsto_norm)
```
```   584
```
```   585 lemma tendsto_norm_zero: "(f \<longlongrightarrow> 0) F \<Longrightarrow> ((\<lambda>x. norm (f x)) \<longlongrightarrow> 0) F"
```
```   586   by (drule tendsto_norm) simp
```
```   587
```
```   588 lemma tendsto_norm_zero_cancel: "((\<lambda>x. norm (f x)) \<longlongrightarrow> 0) F \<Longrightarrow> (f \<longlongrightarrow> 0) F"
```
```   589   unfolding tendsto_iff dist_norm by simp
```
```   590
```
```   591 lemma tendsto_norm_zero_iff: "((\<lambda>x. norm (f x)) \<longlongrightarrow> 0) F \<longleftrightarrow> (f \<longlongrightarrow> 0) F"
```
```   592   unfolding tendsto_iff dist_norm by simp
```
```   593
```
```   594 lemma tendsto_rabs [tendsto_intros]: "(f \<longlongrightarrow> l) F \<Longrightarrow> ((\<lambda>x. \<bar>f x\<bar>) \<longlongrightarrow> \<bar>l\<bar>) F"
```
```   595   for l :: real
```
```   596   by (fold real_norm_def) (rule tendsto_norm)
```
```   597
```
```   598 lemma continuous_rabs [continuous_intros]:
```
```   599   "continuous F f \<Longrightarrow> continuous F (\<lambda>x. \<bar>f x :: real\<bar>)"
```
```   600   unfolding real_norm_def[symmetric] by (rule continuous_norm)
```
```   601
```
```   602 lemma continuous_on_rabs [continuous_intros]:
```
```   603   "continuous_on s f \<Longrightarrow> continuous_on s (\<lambda>x. \<bar>f x :: real\<bar>)"
```
```   604   unfolding real_norm_def[symmetric] by (rule continuous_on_norm)
```
```   605
```
```   606 lemma tendsto_rabs_zero: "(f \<longlongrightarrow> (0::real)) F \<Longrightarrow> ((\<lambda>x. \<bar>f x\<bar>) \<longlongrightarrow> 0) F"
```
```   607   by (fold real_norm_def) (rule tendsto_norm_zero)
```
```   608
```
```   609 lemma tendsto_rabs_zero_cancel: "((\<lambda>x. \<bar>f x\<bar>) \<longlongrightarrow> (0::real)) F \<Longrightarrow> (f \<longlongrightarrow> 0) F"
```
```   610   by (fold real_norm_def) (rule tendsto_norm_zero_cancel)
```
```   611
```
```   612 lemma tendsto_rabs_zero_iff: "((\<lambda>x. \<bar>f x\<bar>) \<longlongrightarrow> (0::real)) F \<longleftrightarrow> (f \<longlongrightarrow> 0) F"
```
```   613   by (fold real_norm_def) (rule tendsto_norm_zero_iff)
```
```   614
```
```   615
```
```   616 subsection \<open>Topological Monoid\<close>
```
```   617
```
```   618 class topological_monoid_add = topological_space + monoid_add +
```
```   619   assumes tendsto_add_Pair: "LIM x (nhds a \<times>\<^sub>F nhds b). fst x + snd x :> nhds (a + b)"
```
```   620
```
```   621 class topological_comm_monoid_add = topological_monoid_add + comm_monoid_add
```
```   622
```
```   623 lemma tendsto_add [tendsto_intros]:
```
```   624   fixes a b :: "'a::topological_monoid_add"
```
```   625   shows "(f \<longlongrightarrow> a) F \<Longrightarrow> (g \<longlongrightarrow> b) F \<Longrightarrow> ((\<lambda>x. f x + g x) \<longlongrightarrow> a + b) F"
```
```   626   using filterlim_compose[OF tendsto_add_Pair, of "\<lambda>x. (f x, g x)" a b F]
```
```   627   by (simp add: nhds_prod[symmetric] tendsto_Pair)
```
```   628
```
```   629 lemma continuous_add [continuous_intros]:
```
```   630   fixes f g :: "_ \<Rightarrow> 'b::topological_monoid_add"
```
```   631   shows "continuous F f \<Longrightarrow> continuous F g \<Longrightarrow> continuous F (\<lambda>x. f x + g x)"
```
```   632   unfolding continuous_def by (rule tendsto_add)
```
```   633
```
```   634 lemma continuous_on_add [continuous_intros]:
```
```   635   fixes f g :: "_ \<Rightarrow> 'b::topological_monoid_add"
```
```   636   shows "continuous_on s f \<Longrightarrow> continuous_on s g \<Longrightarrow> continuous_on s (\<lambda>x. f x + g x)"
```
```   637   unfolding continuous_on_def by (auto intro: tendsto_add)
```
```   638
```
```   639 lemma tendsto_add_zero:
```
```   640   fixes f g :: "_ \<Rightarrow> 'b::topological_monoid_add"
```
```   641   shows "(f \<longlongrightarrow> 0) F \<Longrightarrow> (g \<longlongrightarrow> 0) F \<Longrightarrow> ((\<lambda>x. f x + g x) \<longlongrightarrow> 0) F"
```
```   642   by (drule (1) tendsto_add) simp
```
```   643
```
```   644 lemma tendsto_sum [tendsto_intros]:
```
```   645   fixes f :: "'a \<Rightarrow> 'b \<Rightarrow> 'c::topological_comm_monoid_add"
```
```   646   shows "(\<And>i. i \<in> I \<Longrightarrow> (f i \<longlongrightarrow> a i) F) \<Longrightarrow> ((\<lambda>x. \<Sum>i\<in>I. f i x) \<longlongrightarrow> (\<Sum>i\<in>I. a i)) F"
```
```   647   by (induct I rule: infinite_finite_induct) (simp_all add: tendsto_add)
```
```   648
```
```   649 lemma continuous_sum [continuous_intros]:
```
```   650   fixes f :: "'a \<Rightarrow> 'b::t2_space \<Rightarrow> 'c::topological_comm_monoid_add"
```
```   651   shows "(\<And>i. i \<in> I \<Longrightarrow> continuous F (f i)) \<Longrightarrow> continuous F (\<lambda>x. \<Sum>i\<in>I. f i x)"
```
```   652   unfolding continuous_def by (rule tendsto_sum)
```
```   653
```
```   654 lemma continuous_on_sum [continuous_intros]:
```
```   655   fixes f :: "'a \<Rightarrow> 'b::topological_space \<Rightarrow> 'c::topological_comm_monoid_add"
```
```   656   shows "(\<And>i. i \<in> I \<Longrightarrow> continuous_on S (f i)) \<Longrightarrow> continuous_on S (\<lambda>x. \<Sum>i\<in>I. f i x)"
```
```   657   unfolding continuous_on_def by (auto intro: tendsto_sum)
```
```   658
```
```   659 instance nat :: topological_comm_monoid_add
```
```   660   by standard
```
```   661     (simp add: nhds_discrete principal_prod_principal filterlim_principal eventually_principal)
```
```   662
```
```   663 instance int :: topological_comm_monoid_add
```
```   664   by standard
```
```   665     (simp add: nhds_discrete principal_prod_principal filterlim_principal eventually_principal)
```
```   666
```
```   667
```
```   668 subsubsection \<open>Topological group\<close>
```
```   669
```
```   670 class topological_group_add = topological_monoid_add + group_add +
```
```   671   assumes tendsto_uminus_nhds: "(uminus \<longlongrightarrow> - a) (nhds a)"
```
```   672 begin
```
```   673
```
```   674 lemma tendsto_minus [tendsto_intros]: "(f \<longlongrightarrow> a) F \<Longrightarrow> ((\<lambda>x. - f x) \<longlongrightarrow> - a) F"
```
```   675   by (rule filterlim_compose[OF tendsto_uminus_nhds])
```
```   676
```
```   677 end
```
```   678
```
```   679 class topological_ab_group_add = topological_group_add + ab_group_add
```
```   680
```
```   681 instance topological_ab_group_add < topological_comm_monoid_add ..
```
```   682
```
```   683 lemma continuous_minus [continuous_intros]: "continuous F f \<Longrightarrow> continuous F (\<lambda>x. - f x)"
```
```   684   for f :: "'a::t2_space \<Rightarrow> 'b::topological_group_add"
```
```   685   unfolding continuous_def by (rule tendsto_minus)
```
```   686
```
```   687 lemma continuous_on_minus [continuous_intros]: "continuous_on s f \<Longrightarrow> continuous_on s (\<lambda>x. - f x)"
```
```   688   for f :: "_ \<Rightarrow> 'b::topological_group_add"
```
```   689   unfolding continuous_on_def by (auto intro: tendsto_minus)
```
```   690
```
```   691 lemma tendsto_minus_cancel: "((\<lambda>x. - f x) \<longlongrightarrow> - a) F \<Longrightarrow> (f \<longlongrightarrow> a) F"
```
```   692   for a :: "'a::topological_group_add"
```
```   693   by (drule tendsto_minus) simp
```
```   694
```
```   695 lemma tendsto_minus_cancel_left:
```
```   696   "(f \<longlongrightarrow> - (y::_::topological_group_add)) F \<longleftrightarrow> ((\<lambda>x. - f x) \<longlongrightarrow> y) F"
```
```   697   using tendsto_minus_cancel[of f "- y" F]  tendsto_minus[of f "- y" F]
```
```   698   by auto
```
```   699
```
```   700 lemma tendsto_diff [tendsto_intros]:
```
```   701   fixes a b :: "'a::topological_group_add"
```
```   702   shows "(f \<longlongrightarrow> a) F \<Longrightarrow> (g \<longlongrightarrow> b) F \<Longrightarrow> ((\<lambda>x. f x - g x) \<longlongrightarrow> a - b) F"
```
```   703   using tendsto_add [of f a F "\<lambda>x. - g x" "- b"] by (simp add: tendsto_minus)
```
```   704
```
```   705 lemma continuous_diff [continuous_intros]:
```
```   706   fixes f g :: "'a::t2_space \<Rightarrow> 'b::topological_group_add"
```
```   707   shows "continuous F f \<Longrightarrow> continuous F g \<Longrightarrow> continuous F (\<lambda>x. f x - g x)"
```
```   708   unfolding continuous_def by (rule tendsto_diff)
```
```   709
```
```   710 lemma continuous_on_diff [continuous_intros]:
```
```   711   fixes f g :: "_ \<Rightarrow> 'b::topological_group_add"
```
```   712   shows "continuous_on s f \<Longrightarrow> continuous_on s g \<Longrightarrow> continuous_on s (\<lambda>x. f x - g x)"
```
```   713   unfolding continuous_on_def by (auto intro: tendsto_diff)
```
```   714
```
```   715 lemma continuous_on_op_minus: "continuous_on (s::'a::topological_group_add set) (op - x)"
```
```   716   by (rule continuous_intros | simp)+
```
```   717
```
```   718 instance real_normed_vector < topological_ab_group_add
```
```   719 proof
```
```   720   fix a b :: 'a
```
```   721   show "((\<lambda>x. fst x + snd x) \<longlongrightarrow> a + b) (nhds a \<times>\<^sub>F nhds b)"
```
```   722     unfolding tendsto_Zfun_iff add_diff_add
```
```   723     using tendsto_fst[OF filterlim_ident, of "(a,b)"] tendsto_snd[OF filterlim_ident, of "(a,b)"]
```
```   724     by (intro Zfun_add)
```
```   725        (auto simp add: tendsto_Zfun_iff[symmetric] nhds_prod[symmetric] intro!: tendsto_fst)
```
```   726   show "(uminus \<longlongrightarrow> - a) (nhds a)"
```
```   727     unfolding tendsto_Zfun_iff minus_diff_minus
```
```   728     using filterlim_ident[of "nhds a"]
```
```   729     by (intro Zfun_minus) (simp add: tendsto_Zfun_iff)
```
```   730 qed
```
```   731
```
```   732 lemmas real_tendsto_sandwich = tendsto_sandwich[where 'a=real]
```
```   733
```
```   734
```
```   735 subsubsection \<open>Linear operators and multiplication\<close>
```
```   736
```
```   737 lemma linear_times: "linear (\<lambda>x. c * x)"
```
```   738   for c :: "'a::real_algebra"
```
```   739   by (auto simp: linearI distrib_left)
```
```   740
```
```   741 lemma (in bounded_linear) tendsto: "(g \<longlongrightarrow> a) F \<Longrightarrow> ((\<lambda>x. f (g x)) \<longlongrightarrow> f a) F"
```
```   742   by (simp only: tendsto_Zfun_iff diff [symmetric] Zfun)
```
```   743
```
```   744 lemma (in bounded_linear) continuous: "continuous F g \<Longrightarrow> continuous F (\<lambda>x. f (g x))"
```
```   745   using tendsto[of g _ F] by (auto simp: continuous_def)
```
```   746
```
```   747 lemma (in bounded_linear) continuous_on: "continuous_on s g \<Longrightarrow> continuous_on s (\<lambda>x. f (g x))"
```
```   748   using tendsto[of g] by (auto simp: continuous_on_def)
```
```   749
```
```   750 lemma (in bounded_linear) tendsto_zero: "(g \<longlongrightarrow> 0) F \<Longrightarrow> ((\<lambda>x. f (g x)) \<longlongrightarrow> 0) F"
```
```   751   by (drule tendsto) (simp only: zero)
```
```   752
```
```   753 lemma (in bounded_bilinear) tendsto:
```
```   754   "(f \<longlongrightarrow> a) F \<Longrightarrow> (g \<longlongrightarrow> b) F \<Longrightarrow> ((\<lambda>x. f x ** g x) \<longlongrightarrow> a ** b) F"
```
```   755   by (simp only: tendsto_Zfun_iff prod_diff_prod Zfun_add Zfun Zfun_left Zfun_right)
```
```   756
```
```   757 lemma (in bounded_bilinear) continuous:
```
```   758   "continuous F f \<Longrightarrow> continuous F g \<Longrightarrow> continuous F (\<lambda>x. f x ** g x)"
```
```   759   using tendsto[of f _ F g] by (auto simp: continuous_def)
```
```   760
```
```   761 lemma (in bounded_bilinear) continuous_on:
```
```   762   "continuous_on s f \<Longrightarrow> continuous_on s g \<Longrightarrow> continuous_on s (\<lambda>x. f x ** g x)"
```
```   763   using tendsto[of f _ _ g] by (auto simp: continuous_on_def)
```
```   764
```
```   765 lemma (in bounded_bilinear) tendsto_zero:
```
```   766   assumes f: "(f \<longlongrightarrow> 0) F"
```
```   767     and g: "(g \<longlongrightarrow> 0) F"
```
```   768   shows "((\<lambda>x. f x ** g x) \<longlongrightarrow> 0) F"
```
```   769   using tendsto [OF f g] by (simp add: zero_left)
```
```   770
```
```   771 lemma (in bounded_bilinear) tendsto_left_zero:
```
```   772   "(f \<longlongrightarrow> 0) F \<Longrightarrow> ((\<lambda>x. f x ** c) \<longlongrightarrow> 0) F"
```
```   773   by (rule bounded_linear.tendsto_zero [OF bounded_linear_left])
```
```   774
```
```   775 lemma (in bounded_bilinear) tendsto_right_zero:
```
```   776   "(f \<longlongrightarrow> 0) F \<Longrightarrow> ((\<lambda>x. c ** f x) \<longlongrightarrow> 0) F"
```
```   777   by (rule bounded_linear.tendsto_zero [OF bounded_linear_right])
```
```   778
```
```   779 lemmas tendsto_of_real [tendsto_intros] =
```
```   780   bounded_linear.tendsto [OF bounded_linear_of_real]
```
```   781
```
```   782 lemmas tendsto_scaleR [tendsto_intros] =
```
```   783   bounded_bilinear.tendsto [OF bounded_bilinear_scaleR]
```
```   784
```
```   785 lemmas tendsto_mult [tendsto_intros] =
```
```   786   bounded_bilinear.tendsto [OF bounded_bilinear_mult]
```
```   787
```
```   788 lemma tendsto_mult_left: "(f \<longlongrightarrow> l) F \<Longrightarrow> ((\<lambda>x. c * (f x)) \<longlongrightarrow> c * l) F"
```
```   789   for c :: "'a::real_normed_algebra"
```
```   790   by (rule tendsto_mult [OF tendsto_const])
```
```   791
```
```   792 lemma tendsto_mult_right: "(f \<longlongrightarrow> l) F \<Longrightarrow> ((\<lambda>x. (f x) * c) \<longlongrightarrow> l * c) F"
```
```   793   for c :: "'a::real_normed_algebra"
```
```   794   by (rule tendsto_mult [OF _ tendsto_const])
```
```   795
```
```   796 lemmas continuous_of_real [continuous_intros] =
```
```   797   bounded_linear.continuous [OF bounded_linear_of_real]
```
```   798
```
```   799 lemmas continuous_scaleR [continuous_intros] =
```
```   800   bounded_bilinear.continuous [OF bounded_bilinear_scaleR]
```
```   801
```
```   802 lemmas continuous_mult [continuous_intros] =
```
```   803   bounded_bilinear.continuous [OF bounded_bilinear_mult]
```
```   804
```
```   805 lemmas continuous_on_of_real [continuous_intros] =
```
```   806   bounded_linear.continuous_on [OF bounded_linear_of_real]
```
```   807
```
```   808 lemmas continuous_on_scaleR [continuous_intros] =
```
```   809   bounded_bilinear.continuous_on [OF bounded_bilinear_scaleR]
```
```   810
```
```   811 lemmas continuous_on_mult [continuous_intros] =
```
```   812   bounded_bilinear.continuous_on [OF bounded_bilinear_mult]
```
```   813
```
```   814 lemmas tendsto_mult_zero =
```
```   815   bounded_bilinear.tendsto_zero [OF bounded_bilinear_mult]
```
```   816
```
```   817 lemmas tendsto_mult_left_zero =
```
```   818   bounded_bilinear.tendsto_left_zero [OF bounded_bilinear_mult]
```
```   819
```
```   820 lemmas tendsto_mult_right_zero =
```
```   821   bounded_bilinear.tendsto_right_zero [OF bounded_bilinear_mult]
```
```   822
```
```   823 lemma tendsto_divide_zero:
```
```   824   fixes c :: "'a::real_normed_field"
```
```   825   shows "(f \<longlongrightarrow> 0) F \<Longrightarrow> ((\<lambda>x. f x / c) \<longlongrightarrow> 0) F"
```
```   826   by (cases "c=0") (simp_all add: divide_inverse tendsto_mult_left_zero)
```
```   827
```
```   828 lemma tendsto_power [tendsto_intros]: "(f \<longlongrightarrow> a) F \<Longrightarrow> ((\<lambda>x. f x ^ n) \<longlongrightarrow> a ^ n) F"
```
```   829   for f :: "'a \<Rightarrow> 'b::{power,real_normed_algebra}"
```
```   830   by (induct n) (simp_all add: tendsto_mult)
```
```   831
```
```   832 lemma tendsto_null_power: "\<lbrakk>(f \<longlongrightarrow> 0) F; 0 < n\<rbrakk> \<Longrightarrow> ((\<lambda>x. f x ^ n) \<longlongrightarrow> 0) F"
```
```   833     for f :: "'a \<Rightarrow> 'b::{power,real_normed_algebra_1}"
```
```   834   using tendsto_power [of f 0 F n] by (simp add: power_0_left)
```
```   835
```
```   836 lemma continuous_power [continuous_intros]: "continuous F f \<Longrightarrow> continuous F (\<lambda>x. (f x)^n)"
```
```   837   for f :: "'a::t2_space \<Rightarrow> 'b::{power,real_normed_algebra}"
```
```   838   unfolding continuous_def by (rule tendsto_power)
```
```   839
```
```   840 lemma continuous_on_power [continuous_intros]:
```
```   841   fixes f :: "_ \<Rightarrow> 'b::{power,real_normed_algebra}"
```
```   842   shows "continuous_on s f \<Longrightarrow> continuous_on s (\<lambda>x. (f x)^n)"
```
```   843   unfolding continuous_on_def by (auto intro: tendsto_power)
```
```   844
```
```   845 lemma tendsto_prod [tendsto_intros]:
```
```   846   fixes f :: "'a \<Rightarrow> 'b \<Rightarrow> 'c::{real_normed_algebra,comm_ring_1}"
```
```   847   shows "(\<And>i. i \<in> S \<Longrightarrow> (f i \<longlongrightarrow> L i) F) \<Longrightarrow> ((\<lambda>x. \<Prod>i\<in>S. f i x) \<longlongrightarrow> (\<Prod>i\<in>S. L i)) F"
```
```   848   by (induct S rule: infinite_finite_induct) (simp_all add: tendsto_mult)
```
```   849
```
```   850 lemma continuous_prod [continuous_intros]:
```
```   851   fixes f :: "'a \<Rightarrow> 'b::t2_space \<Rightarrow> 'c::{real_normed_algebra,comm_ring_1}"
```
```   852   shows "(\<And>i. i \<in> S \<Longrightarrow> continuous F (f i)) \<Longrightarrow> continuous F (\<lambda>x. \<Prod>i\<in>S. f i x)"
```
```   853   unfolding continuous_def by (rule tendsto_prod)
```
```   854
```
```   855 lemma continuous_on_prod [continuous_intros]:
```
```   856   fixes f :: "'a \<Rightarrow> _ \<Rightarrow> 'c::{real_normed_algebra,comm_ring_1}"
```
```   857   shows "(\<And>i. i \<in> S \<Longrightarrow> continuous_on s (f i)) \<Longrightarrow> continuous_on s (\<lambda>x. \<Prod>i\<in>S. f i x)"
```
```   858   unfolding continuous_on_def by (auto intro: tendsto_prod)
```
```   859
```
```   860 lemma tendsto_of_real_iff:
```
```   861   "((\<lambda>x. of_real (f x) :: 'a::real_normed_div_algebra) \<longlongrightarrow> of_real c) F \<longleftrightarrow> (f \<longlongrightarrow> c) F"
```
```   862   unfolding tendsto_iff by simp
```
```   863
```
```   864 lemma tendsto_add_const_iff:
```
```   865   "((\<lambda>x. c + f x :: 'a::real_normed_vector) \<longlongrightarrow> c + d) F \<longleftrightarrow> (f \<longlongrightarrow> d) F"
```
```   866   using tendsto_add[OF tendsto_const[of c], of f d]
```
```   867     and tendsto_add[OF tendsto_const[of "-c"], of "\<lambda>x. c + f x" "c + d"] by auto
```
```   868
```
```   869
```
```   870 subsubsection \<open>Inverse and division\<close>
```
```   871
```
```   872 lemma (in bounded_bilinear) Zfun_prod_Bfun:
```
```   873   assumes f: "Zfun f F"
```
```   874     and g: "Bfun g F"
```
```   875   shows "Zfun (\<lambda>x. f x ** g x) F"
```
```   876 proof -
```
```   877   obtain K where K: "0 \<le> K"
```
```   878     and norm_le: "\<And>x y. norm (x ** y) \<le> norm x * norm y * K"
```
```   879     using nonneg_bounded by blast
```
```   880   obtain B where B: "0 < B"
```
```   881     and norm_g: "eventually (\<lambda>x. norm (g x) \<le> B) F"
```
```   882     using g by (rule BfunE)
```
```   883   have "eventually (\<lambda>x. norm (f x ** g x) \<le> norm (f x) * (B * K)) F"
```
```   884   using norm_g proof eventually_elim
```
```   885     case (elim x)
```
```   886     have "norm (f x ** g x) \<le> norm (f x) * norm (g x) * K"
```
```   887       by (rule norm_le)
```
```   888     also have "\<dots> \<le> norm (f x) * B * K"
```
```   889       by (intro mult_mono' order_refl norm_g norm_ge_zero mult_nonneg_nonneg K elim)
```
```   890     also have "\<dots> = norm (f x) * (B * K)"
```
```   891       by (rule mult.assoc)
```
```   892     finally show "norm (f x ** g x) \<le> norm (f x) * (B * K)" .
```
```   893   qed
```
```   894   with f show ?thesis
```
```   895     by (rule Zfun_imp_Zfun)
```
```   896 qed
```
```   897
```
```   898 lemma (in bounded_bilinear) Bfun_prod_Zfun:
```
```   899   assumes f: "Bfun f F"
```
```   900     and g: "Zfun g F"
```
```   901   shows "Zfun (\<lambda>x. f x ** g x) F"
```
```   902   using flip g f by (rule bounded_bilinear.Zfun_prod_Bfun)
```
```   903
```
```   904 lemma Bfun_inverse_lemma:
```
```   905   fixes x :: "'a::real_normed_div_algebra"
```
```   906   shows "r \<le> norm x \<Longrightarrow> 0 < r \<Longrightarrow> norm (inverse x) \<le> inverse r"
```
```   907   apply (subst nonzero_norm_inverse)
```
```   908   apply clarsimp
```
```   909   apply (erule (1) le_imp_inverse_le)
```
```   910   done
```
```   911
```
```   912 lemma Bfun_inverse:
```
```   913   fixes a :: "'a::real_normed_div_algebra"
```
```   914   assumes f: "(f \<longlongrightarrow> a) F"
```
```   915   assumes a: "a \<noteq> 0"
```
```   916   shows "Bfun (\<lambda>x. inverse (f x)) F"
```
```   917 proof -
```
```   918   from a have "0 < norm a" by simp
```
```   919   then have "\<exists>r>0. r < norm a" by (rule dense)
```
```   920   then obtain r where r1: "0 < r" and r2: "r < norm a"
```
```   921     by blast
```
```   922   have "eventually (\<lambda>x. dist (f x) a < r) F"
```
```   923     using tendstoD [OF f r1] by blast
```
```   924   then have "eventually (\<lambda>x. norm (inverse (f x)) \<le> inverse (norm a - r)) F"
```
```   925   proof eventually_elim
```
```   926     case (elim x)
```
```   927     then have 1: "norm (f x - a) < r"
```
```   928       by (simp add: dist_norm)
```
```   929     then have 2: "f x \<noteq> 0" using r2 by auto
```
```   930     then have "norm (inverse (f x)) = inverse (norm (f x))"
```
```   931       by (rule nonzero_norm_inverse)
```
```   932     also have "\<dots> \<le> inverse (norm a - r)"
```
```   933     proof (rule le_imp_inverse_le)
```
```   934       show "0 < norm a - r"
```
```   935         using r2 by simp
```
```   936       have "norm a - norm (f x) \<le> norm (a - f x)"
```
```   937         by (rule norm_triangle_ineq2)
```
```   938       also have "\<dots> = norm (f x - a)"
```
```   939         by (rule norm_minus_commute)
```
```   940       also have "\<dots> < r" using 1 .
```
```   941       finally show "norm a - r \<le> norm (f x)"
```
```   942         by simp
```
```   943     qed
```
```   944     finally show "norm (inverse (f x)) \<le> inverse (norm a - r)" .
```
```   945   qed
```
```   946   then show ?thesis by (rule BfunI)
```
```   947 qed
```
```   948
```
```   949 lemma tendsto_inverse [tendsto_intros]:
```
```   950   fixes a :: "'a::real_normed_div_algebra"
```
```   951   assumes f: "(f \<longlongrightarrow> a) F"
```
```   952     and a: "a \<noteq> 0"
```
```   953   shows "((\<lambda>x. inverse (f x)) \<longlongrightarrow> inverse a) F"
```
```   954 proof -
```
```   955   from a have "0 < norm a" by simp
```
```   956   with f have "eventually (\<lambda>x. dist (f x) a < norm a) F"
```
```   957     by (rule tendstoD)
```
```   958   then have "eventually (\<lambda>x. f x \<noteq> 0) F"
```
```   959     unfolding dist_norm by (auto elim!: eventually_mono)
```
```   960   with a have "eventually (\<lambda>x. inverse (f x) - inverse a =
```
```   961     - (inverse (f x) * (f x - a) * inverse a)) F"
```
```   962     by (auto elim!: eventually_mono simp: inverse_diff_inverse)
```
```   963   moreover have "Zfun (\<lambda>x. - (inverse (f x) * (f x - a) * inverse a)) F"
```
```   964     by (intro Zfun_minus Zfun_mult_left
```
```   965       bounded_bilinear.Bfun_prod_Zfun [OF bounded_bilinear_mult]
```
```   966       Bfun_inverse [OF f a] f [unfolded tendsto_Zfun_iff])
```
```   967   ultimately show ?thesis
```
```   968     unfolding tendsto_Zfun_iff by (rule Zfun_ssubst)
```
```   969 qed
```
```   970
```
```   971 lemma continuous_inverse:
```
```   972   fixes f :: "'a::t2_space \<Rightarrow> 'b::real_normed_div_algebra"
```
```   973   assumes "continuous F f"
```
```   974     and "f (Lim F (\<lambda>x. x)) \<noteq> 0"
```
```   975   shows "continuous F (\<lambda>x. inverse (f x))"
```
```   976   using assms unfolding continuous_def by (rule tendsto_inverse)
```
```   977
```
```   978 lemma continuous_at_within_inverse[continuous_intros]:
```
```   979   fixes f :: "'a::t2_space \<Rightarrow> 'b::real_normed_div_algebra"
```
```   980   assumes "continuous (at a within s) f"
```
```   981     and "f a \<noteq> 0"
```
```   982   shows "continuous (at a within s) (\<lambda>x. inverse (f x))"
```
```   983   using assms unfolding continuous_within by (rule tendsto_inverse)
```
```   984
```
```   985 lemma isCont_inverse[continuous_intros, simp]:
```
```   986   fixes f :: "'a::t2_space \<Rightarrow> 'b::real_normed_div_algebra"
```
```   987   assumes "isCont f a"
```
```   988     and "f a \<noteq> 0"
```
```   989   shows "isCont (\<lambda>x. inverse (f x)) a"
```
```   990   using assms unfolding continuous_at by (rule tendsto_inverse)
```
```   991
```
```   992 lemma continuous_on_inverse[continuous_intros]:
```
```   993   fixes f :: "'a::topological_space \<Rightarrow> 'b::real_normed_div_algebra"
```
```   994   assumes "continuous_on s f"
```
```   995     and "\<forall>x\<in>s. f x \<noteq> 0"
```
```   996   shows "continuous_on s (\<lambda>x. inverse (f x))"
```
```   997   using assms unfolding continuous_on_def by (blast intro: tendsto_inverse)
```
```   998
```
```   999 lemma tendsto_divide [tendsto_intros]:
```
```  1000   fixes a b :: "'a::real_normed_field"
```
```  1001   shows "(f \<longlongrightarrow> a) F \<Longrightarrow> (g \<longlongrightarrow> b) F \<Longrightarrow> b \<noteq> 0 \<Longrightarrow> ((\<lambda>x. f x / g x) \<longlongrightarrow> a / b) F"
```
```  1002   by (simp add: tendsto_mult tendsto_inverse divide_inverse)
```
```  1003
```
```  1004 lemma continuous_divide:
```
```  1005   fixes f g :: "'a::t2_space \<Rightarrow> 'b::real_normed_field"
```
```  1006   assumes "continuous F f"
```
```  1007     and "continuous F g"
```
```  1008     and "g (Lim F (\<lambda>x. x)) \<noteq> 0"
```
```  1009   shows "continuous F (\<lambda>x. (f x) / (g x))"
```
```  1010   using assms unfolding continuous_def by (rule tendsto_divide)
```
```  1011
```
```  1012 lemma continuous_at_within_divide[continuous_intros]:
```
```  1013   fixes f g :: "'a::t2_space \<Rightarrow> 'b::real_normed_field"
```
```  1014   assumes "continuous (at a within s) f" "continuous (at a within s) g"
```
```  1015     and "g a \<noteq> 0"
```
```  1016   shows "continuous (at a within s) (\<lambda>x. (f x) / (g x))"
```
```  1017   using assms unfolding continuous_within by (rule tendsto_divide)
```
```  1018
```
```  1019 lemma isCont_divide[continuous_intros, simp]:
```
```  1020   fixes f g :: "'a::t2_space \<Rightarrow> 'b::real_normed_field"
```
```  1021   assumes "isCont f a" "isCont g a" "g a \<noteq> 0"
```
```  1022   shows "isCont (\<lambda>x. (f x) / g x) a"
```
```  1023   using assms unfolding continuous_at by (rule tendsto_divide)
```
```  1024
```
```  1025 lemma continuous_on_divide[continuous_intros]:
```
```  1026   fixes f :: "'a::topological_space \<Rightarrow> 'b::real_normed_field"
```
```  1027   assumes "continuous_on s f" "continuous_on s g"
```
```  1028     and "\<forall>x\<in>s. g x \<noteq> 0"
```
```  1029   shows "continuous_on s (\<lambda>x. (f x) / (g x))"
```
```  1030   using assms unfolding continuous_on_def by (blast intro: tendsto_divide)
```
```  1031
```
```  1032 lemma tendsto_sgn [tendsto_intros]: "(f \<longlongrightarrow> l) F \<Longrightarrow> l \<noteq> 0 \<Longrightarrow> ((\<lambda>x. sgn (f x)) \<longlongrightarrow> sgn l) F"
```
```  1033   for l :: "'a::real_normed_vector"
```
```  1034   unfolding sgn_div_norm by (simp add: tendsto_intros)
```
```  1035
```
```  1036 lemma continuous_sgn:
```
```  1037   fixes f :: "'a::t2_space \<Rightarrow> 'b::real_normed_vector"
```
```  1038   assumes "continuous F f"
```
```  1039     and "f (Lim F (\<lambda>x. x)) \<noteq> 0"
```
```  1040   shows "continuous F (\<lambda>x. sgn (f x))"
```
```  1041   using assms unfolding continuous_def by (rule tendsto_sgn)
```
```  1042
```
```  1043 lemma continuous_at_within_sgn[continuous_intros]:
```
```  1044   fixes f :: "'a::t2_space \<Rightarrow> 'b::real_normed_vector"
```
```  1045   assumes "continuous (at a within s) f"
```
```  1046     and "f a \<noteq> 0"
```
```  1047   shows "continuous (at a within s) (\<lambda>x. sgn (f x))"
```
```  1048   using assms unfolding continuous_within by (rule tendsto_sgn)
```
```  1049
```
```  1050 lemma isCont_sgn[continuous_intros]:
```
```  1051   fixes f :: "'a::t2_space \<Rightarrow> 'b::real_normed_vector"
```
```  1052   assumes "isCont f a"
```
```  1053     and "f a \<noteq> 0"
```
```  1054   shows "isCont (\<lambda>x. sgn (f x)) a"
```
```  1055   using assms unfolding continuous_at by (rule tendsto_sgn)
```
```  1056
```
```  1057 lemma continuous_on_sgn[continuous_intros]:
```
```  1058   fixes f :: "'a::topological_space \<Rightarrow> 'b::real_normed_vector"
```
```  1059   assumes "continuous_on s f"
```
```  1060     and "\<forall>x\<in>s. f x \<noteq> 0"
```
```  1061   shows "continuous_on s (\<lambda>x. sgn (f x))"
```
```  1062   using assms unfolding continuous_on_def by (blast intro: tendsto_sgn)
```
```  1063
```
```  1064 lemma filterlim_at_infinity:
```
```  1065   fixes f :: "_ \<Rightarrow> 'a::real_normed_vector"
```
```  1066   assumes "0 \<le> c"
```
```  1067   shows "(LIM x F. f x :> at_infinity) \<longleftrightarrow> (\<forall>r>c. eventually (\<lambda>x. r \<le> norm (f x)) F)"
```
```  1068   unfolding filterlim_iff eventually_at_infinity
```
```  1069 proof safe
```
```  1070   fix P :: "'a \<Rightarrow> bool"
```
```  1071   fix b
```
```  1072   assume *: "\<forall>r>c. eventually (\<lambda>x. r \<le> norm (f x)) F"
```
```  1073   assume P: "\<forall>x. b \<le> norm x \<longrightarrow> P x"
```
```  1074   have "max b (c + 1) > c" by auto
```
```  1075   with * have "eventually (\<lambda>x. max b (c + 1) \<le> norm (f x)) F"
```
```  1076     by auto
```
```  1077   then show "eventually (\<lambda>x. P (f x)) F"
```
```  1078   proof eventually_elim
```
```  1079     case (elim x)
```
```  1080     with P show "P (f x)" by auto
```
```  1081   qed
```
```  1082 qed force
```
```  1083
```
```  1084 lemma not_tendsto_and_filterlim_at_infinity:
```
```  1085   fixes c :: "'a::real_normed_vector"
```
```  1086   assumes "F \<noteq> bot"
```
```  1087     and "(f \<longlongrightarrow> c) F"
```
```  1088     and "filterlim f at_infinity F"
```
```  1089   shows False
```
```  1090 proof -
```
```  1091   from tendstoD[OF assms(2), of "1/2"]
```
```  1092   have "eventually (\<lambda>x. dist (f x) c < 1/2) F"
```
```  1093     by simp
```
```  1094   moreover
```
```  1095   from filterlim_at_infinity[of "norm c" f F] assms(3)
```
```  1096   have "eventually (\<lambda>x. norm (f x) \<ge> norm c + 1) F" by simp
```
```  1097   ultimately have "eventually (\<lambda>x. False) F"
```
```  1098   proof eventually_elim
```
```  1099     fix x
```
```  1100     assume A: "dist (f x) c < 1/2"
```
```  1101     assume "norm (f x) \<ge> norm c + 1"
```
```  1102     also have "norm (f x) = dist (f x) 0" by simp
```
```  1103     also have "\<dots> \<le> dist (f x) c + dist c 0" by (rule dist_triangle)
```
```  1104     finally show False using A by simp
```
```  1105   qed
```
```  1106   with assms show False by simp
```
```  1107 qed
```
```  1108
```
```  1109 lemma filterlim_at_infinity_imp_not_convergent:
```
```  1110   assumes "filterlim f at_infinity sequentially"
```
```  1111   shows "\<not> convergent f"
```
```  1112   by (rule notI, rule not_tendsto_and_filterlim_at_infinity[OF _ _ assms])
```
```  1113      (simp_all add: convergent_LIMSEQ_iff)
```
```  1114
```
```  1115 lemma filterlim_at_infinity_imp_eventually_ne:
```
```  1116   assumes "filterlim f at_infinity F"
```
```  1117   shows "eventually (\<lambda>z. f z \<noteq> c) F"
```
```  1118 proof -
```
```  1119   have "norm c + 1 > 0"
```
```  1120     by (intro add_nonneg_pos) simp_all
```
```  1121   with filterlim_at_infinity[OF order.refl, of f F] assms
```
```  1122   have "eventually (\<lambda>z. norm (f z) \<ge> norm c + 1) F"
```
```  1123     by blast
```
```  1124   then show ?thesis
```
```  1125     by eventually_elim auto
```
```  1126 qed
```
```  1127
```
```  1128 lemma tendsto_of_nat [tendsto_intros]:
```
```  1129   "filterlim (of_nat :: nat \<Rightarrow> 'a::real_normed_algebra_1) at_infinity sequentially"
```
```  1130 proof (subst filterlim_at_infinity[OF order.refl], intro allI impI)
```
```  1131   fix r :: real
```
```  1132   assume r: "r > 0"
```
```  1133   define n where "n = nat \<lceil>r\<rceil>"
```
```  1134   from r have n: "\<forall>m\<ge>n. of_nat m \<ge> r"
```
```  1135     unfolding n_def by linarith
```
```  1136   from eventually_ge_at_top[of n] show "eventually (\<lambda>m. norm (of_nat m :: 'a) \<ge> r) sequentially"
```
```  1137     by eventually_elim (use n in simp_all)
```
```  1138 qed
```
```  1139
```
```  1140
```
```  1141 subsection \<open>Relate @{const at}, @{const at_left} and @{const at_right}\<close>
```
```  1142
```
```  1143 text \<open>
```
```  1144   This lemmas are useful for conversion between @{term "at x"} to @{term "at_left x"} and
```
```  1145   @{term "at_right x"} and also @{term "at_right 0"}.
```
```  1146 \<close>
```
```  1147
```
```  1148 lemmas filterlim_split_at_real = filterlim_split_at[where 'a=real]
```
```  1149
```
```  1150 lemma filtermap_nhds_shift: "filtermap (\<lambda>x. x - d) (nhds a) = nhds (a - d)"
```
```  1151   for a d :: "'a::real_normed_vector"
```
```  1152   by (rule filtermap_fun_inverse[where g="\<lambda>x. x + d"])
```
```  1153     (auto intro!: tendsto_eq_intros filterlim_ident)
```
```  1154
```
```  1155 lemma filtermap_nhds_minus: "filtermap (\<lambda>x. - x) (nhds a) = nhds (- a)"
```
```  1156   for a :: "'a::real_normed_vector"
```
```  1157   by (rule filtermap_fun_inverse[where g=uminus])
```
```  1158     (auto intro!: tendsto_eq_intros filterlim_ident)
```
```  1159
```
```  1160 lemma filtermap_at_shift: "filtermap (\<lambda>x. x - d) (at a) = at (a - d)"
```
```  1161   for a d :: "'a::real_normed_vector"
```
```  1162   by (simp add: filter_eq_iff eventually_filtermap eventually_at_filter filtermap_nhds_shift[symmetric])
```
```  1163
```
```  1164 lemma filtermap_at_right_shift: "filtermap (\<lambda>x. x - d) (at_right a) = at_right (a - d)"
```
```  1165   for a d :: "real"
```
```  1166   by (simp add: filter_eq_iff eventually_filtermap eventually_at_filter filtermap_nhds_shift[symmetric])
```
```  1167
```
```  1168 lemma at_right_to_0: "at_right a = filtermap (\<lambda>x. x + a) (at_right 0)"
```
```  1169   for a :: real
```
```  1170   using filtermap_at_right_shift[of "-a" 0] by simp
```
```  1171
```
```  1172 lemma filterlim_at_right_to_0:
```
```  1173   "filterlim f F (at_right a) \<longleftrightarrow> filterlim (\<lambda>x. f (x + a)) F (at_right 0)"
```
```  1174   for a :: real
```
```  1175   unfolding filterlim_def filtermap_filtermap at_right_to_0[of a] ..
```
```  1176
```
```  1177 lemma eventually_at_right_to_0:
```
```  1178   "eventually P (at_right a) \<longleftrightarrow> eventually (\<lambda>x. P (x + a)) (at_right 0)"
```
```  1179   for a :: real
```
```  1180   unfolding at_right_to_0[of a] by (simp add: eventually_filtermap)
```
```  1181
```
```  1182 lemma filtermap_at_minus: "filtermap (\<lambda>x. - x) (at a) = at (- a)"
```
```  1183   for a :: "'a::real_normed_vector"
```
```  1184   by (simp add: filter_eq_iff eventually_filtermap eventually_at_filter filtermap_nhds_minus[symmetric])
```
```  1185
```
```  1186 lemma at_left_minus: "at_left a = filtermap (\<lambda>x. - x) (at_right (- a))"
```
```  1187   for a :: real
```
```  1188   by (simp add: filter_eq_iff eventually_filtermap eventually_at_filter filtermap_nhds_minus[symmetric])
```
```  1189
```
```  1190 lemma at_right_minus: "at_right a = filtermap (\<lambda>x. - x) (at_left (- a))"
```
```  1191   for a :: real
```
```  1192   by (simp add: filter_eq_iff eventually_filtermap eventually_at_filter filtermap_nhds_minus[symmetric])
```
```  1193
```
```  1194 lemma filterlim_at_left_to_right:
```
```  1195   "filterlim f F (at_left a) \<longleftrightarrow> filterlim (\<lambda>x. f (- x)) F (at_right (-a))"
```
```  1196   for a :: real
```
```  1197   unfolding filterlim_def filtermap_filtermap at_left_minus[of a] ..
```
```  1198
```
```  1199 lemma eventually_at_left_to_right:
```
```  1200   "eventually P (at_left a) \<longleftrightarrow> eventually (\<lambda>x. P (- x)) (at_right (-a))"
```
```  1201   for a :: real
```
```  1202   unfolding at_left_minus[of a] by (simp add: eventually_filtermap)
```
```  1203
```
```  1204 lemma filterlim_uminus_at_top_at_bot: "LIM x at_bot. - x :: real :> at_top"
```
```  1205   unfolding filterlim_at_top eventually_at_bot_dense
```
```  1206   by (metis leI minus_less_iff order_less_asym)
```
```  1207
```
```  1208 lemma filterlim_uminus_at_bot_at_top: "LIM x at_top. - x :: real :> at_bot"
```
```  1209   unfolding filterlim_at_bot eventually_at_top_dense
```
```  1210   by (metis leI less_minus_iff order_less_asym)
```
```  1211
```
```  1212 lemma at_top_mirror: "at_top = filtermap uminus (at_bot :: real filter)"
```
```  1213   by (rule filtermap_fun_inverse[symmetric, of uminus])
```
```  1214      (auto intro: filterlim_uminus_at_bot_at_top filterlim_uminus_at_top_at_bot)
```
```  1215
```
```  1216 lemma at_bot_mirror: "at_bot = filtermap uminus (at_top :: real filter)"
```
```  1217   unfolding at_top_mirror filtermap_filtermap by (simp add: filtermap_ident)
```
```  1218
```
```  1219 lemma filterlim_at_top_mirror: "(LIM x at_top. f x :> F) \<longleftrightarrow> (LIM x at_bot. f (-x::real) :> F)"
```
```  1220   unfolding filterlim_def at_top_mirror filtermap_filtermap ..
```
```  1221
```
```  1222 lemma filterlim_at_bot_mirror: "(LIM x at_bot. f x :> F) \<longleftrightarrow> (LIM x at_top. f (-x::real) :> F)"
```
```  1223   unfolding filterlim_def at_bot_mirror filtermap_filtermap ..
```
```  1224
```
```  1225 lemma filterlim_uminus_at_top: "(LIM x F. f x :> at_top) \<longleftrightarrow> (LIM x F. - (f x) :: real :> at_bot)"
```
```  1226   using filterlim_compose[OF filterlim_uminus_at_bot_at_top, of f F]
```
```  1227     and filterlim_compose[OF filterlim_uminus_at_top_at_bot, of "\<lambda>x. - f x" F]
```
```  1228   by auto
```
```  1229
```
```  1230 lemma filterlim_uminus_at_bot: "(LIM x F. f x :> at_bot) \<longleftrightarrow> (LIM x F. - (f x) :: real :> at_top)"
```
```  1231   unfolding filterlim_uminus_at_top by simp
```
```  1232
```
```  1233 lemma filterlim_inverse_at_top_right: "LIM x at_right (0::real). inverse x :> at_top"
```
```  1234   unfolding filterlim_at_top_gt[where c=0] eventually_at_filter
```
```  1235 proof safe
```
```  1236   fix Z :: real
```
```  1237   assume [arith]: "0 < Z"
```
```  1238   then have "eventually (\<lambda>x. x < inverse Z) (nhds 0)"
```
```  1239     by (auto simp add: eventually_nhds_metric dist_real_def intro!: exI[of _ "\<bar>inverse Z\<bar>"])
```
```  1240   then show "eventually (\<lambda>x. x \<noteq> 0 \<longrightarrow> x \<in> {0<..} \<longrightarrow> Z \<le> inverse x) (nhds 0)"
```
```  1241     by (auto elim!: eventually_mono simp: inverse_eq_divide field_simps)
```
```  1242 qed
```
```  1243
```
```  1244 lemma tendsto_inverse_0:
```
```  1245   fixes x :: "_ \<Rightarrow> 'a::real_normed_div_algebra"
```
```  1246   shows "(inverse \<longlongrightarrow> (0::'a)) at_infinity"
```
```  1247   unfolding tendsto_Zfun_iff diff_0_right Zfun_def eventually_at_infinity
```
```  1248 proof safe
```
```  1249   fix r :: real
```
```  1250   assume "0 < r"
```
```  1251   show "\<exists>b. \<forall>x. b \<le> norm x \<longrightarrow> norm (inverse x :: 'a) < r"
```
```  1252   proof (intro exI[of _ "inverse (r / 2)"] allI impI)
```
```  1253     fix x :: 'a
```
```  1254     from \<open>0 < r\<close> have "0 < inverse (r / 2)" by simp
```
```  1255     also assume *: "inverse (r / 2) \<le> norm x"
```
```  1256     finally show "norm (inverse x) < r"
```
```  1257       using * \<open>0 < r\<close>
```
```  1258       by (subst nonzero_norm_inverse) (simp_all add: inverse_eq_divide field_simps)
```
```  1259   qed
```
```  1260 qed
```
```  1261
```
```  1262 lemma tendsto_add_filterlim_at_infinity:
```
```  1263   fixes c :: "'b::real_normed_vector"
```
```  1264     and F :: "'a filter"
```
```  1265   assumes "(f \<longlongrightarrow> c) F"
```
```  1266     and "filterlim g at_infinity F"
```
```  1267   shows "filterlim (\<lambda>x. f x + g x) at_infinity F"
```
```  1268 proof (subst filterlim_at_infinity[OF order_refl], safe)
```
```  1269   fix r :: real
```
```  1270   assume r: "r > 0"
```
```  1271   from assms(1) have "((\<lambda>x. norm (f x)) \<longlongrightarrow> norm c) F"
```
```  1272     by (rule tendsto_norm)
```
```  1273   then have "eventually (\<lambda>x. norm (f x) < norm c + 1) F"
```
```  1274     by (rule order_tendstoD) simp_all
```
```  1275   moreover from r have "r + norm c + 1 > 0"
```
```  1276     by (intro add_pos_nonneg) simp_all
```
```  1277   with assms(2) have "eventually (\<lambda>x. norm (g x) \<ge> r + norm c + 1) F"
```
```  1278     unfolding filterlim_at_infinity[OF order_refl]
```
```  1279     by (elim allE[of _ "r + norm c + 1"]) simp_all
```
```  1280   ultimately show "eventually (\<lambda>x. norm (f x + g x) \<ge> r) F"
```
```  1281   proof eventually_elim
```
```  1282     fix x :: 'a
```
```  1283     assume A: "norm (f x) < norm c + 1" and B: "r + norm c + 1 \<le> norm (g x)"
```
```  1284     from A B have "r \<le> norm (g x) - norm (f x)"
```
```  1285       by simp
```
```  1286     also have "norm (g x) - norm (f x) \<le> norm (g x + f x)"
```
```  1287       by (rule norm_diff_ineq)
```
```  1288     finally show "r \<le> norm (f x + g x)"
```
```  1289       by (simp add: add_ac)
```
```  1290   qed
```
```  1291 qed
```
```  1292
```
```  1293 lemma tendsto_add_filterlim_at_infinity':
```
```  1294   fixes c :: "'b::real_normed_vector"
```
```  1295     and F :: "'a filter"
```
```  1296   assumes "filterlim f at_infinity F"
```
```  1297     and "(g \<longlongrightarrow> c) F"
```
```  1298   shows "filterlim (\<lambda>x. f x + g x) at_infinity F"
```
```  1299   by (subst add.commute) (rule tendsto_add_filterlim_at_infinity assms)+
```
```  1300
```
```  1301 lemma filterlim_inverse_at_right_top: "LIM x at_top. inverse x :> at_right (0::real)"
```
```  1302   unfolding filterlim_at
```
```  1303   by (auto simp: eventually_at_top_dense)
```
```  1304      (metis tendsto_inverse_0 filterlim_mono at_top_le_at_infinity order_refl)
```
```  1305
```
```  1306 lemma filterlim_inverse_at_top:
```
```  1307   "(f \<longlongrightarrow> (0 :: real)) F \<Longrightarrow> eventually (\<lambda>x. 0 < f x) F \<Longrightarrow> LIM x F. inverse (f x) :> at_top"
```
```  1308   by (intro filterlim_compose[OF filterlim_inverse_at_top_right])
```
```  1309      (simp add: filterlim_def eventually_filtermap eventually_mono at_within_def le_principal)
```
```  1310
```
```  1311 lemma filterlim_inverse_at_bot_neg:
```
```  1312   "LIM x (at_left (0::real)). inverse x :> at_bot"
```
```  1313   by (simp add: filterlim_inverse_at_top_right filterlim_uminus_at_bot filterlim_at_left_to_right)
```
```  1314
```
```  1315 lemma filterlim_inverse_at_bot:
```
```  1316   "(f \<longlongrightarrow> (0 :: real)) F \<Longrightarrow> eventually (\<lambda>x. f x < 0) F \<Longrightarrow> LIM x F. inverse (f x) :> at_bot"
```
```  1317   unfolding filterlim_uminus_at_bot inverse_minus_eq[symmetric]
```
```  1318   by (rule filterlim_inverse_at_top) (simp_all add: tendsto_minus_cancel_left[symmetric])
```
```  1319
```
```  1320 lemma at_right_to_top: "(at_right (0::real)) = filtermap inverse at_top"
```
```  1321   by (intro filtermap_fun_inverse[symmetric, where g=inverse])
```
```  1322      (auto intro: filterlim_inverse_at_top_right filterlim_inverse_at_right_top)
```
```  1323
```
```  1324 lemma eventually_at_right_to_top:
```
```  1325   "eventually P (at_right (0::real)) \<longleftrightarrow> eventually (\<lambda>x. P (inverse x)) at_top"
```
```  1326   unfolding at_right_to_top eventually_filtermap ..
```
```  1327
```
```  1328 lemma filterlim_at_right_to_top:
```
```  1329   "filterlim f F (at_right (0::real)) \<longleftrightarrow> (LIM x at_top. f (inverse x) :> F)"
```
```  1330   unfolding filterlim_def at_right_to_top filtermap_filtermap ..
```
```  1331
```
```  1332 lemma at_top_to_right: "at_top = filtermap inverse (at_right (0::real))"
```
```  1333   unfolding at_right_to_top filtermap_filtermap inverse_inverse_eq filtermap_ident ..
```
```  1334
```
```  1335 lemma eventually_at_top_to_right:
```
```  1336   "eventually P at_top \<longleftrightarrow> eventually (\<lambda>x. P (inverse x)) (at_right (0::real))"
```
```  1337   unfolding at_top_to_right eventually_filtermap ..
```
```  1338
```
```  1339 lemma filterlim_at_top_to_right:
```
```  1340   "filterlim f F at_top \<longleftrightarrow> (LIM x (at_right (0::real)). f (inverse x) :> F)"
```
```  1341   unfolding filterlim_def at_top_to_right filtermap_filtermap ..
```
```  1342
```
```  1343 lemma filterlim_inverse_at_infinity:
```
```  1344   fixes x :: "_ \<Rightarrow> 'a::{real_normed_div_algebra, division_ring}"
```
```  1345   shows "filterlim inverse at_infinity (at (0::'a))"
```
```  1346   unfolding filterlim_at_infinity[OF order_refl]
```
```  1347 proof safe
```
```  1348   fix r :: real
```
```  1349   assume "0 < r"
```
```  1350   then show "eventually (\<lambda>x::'a. r \<le> norm (inverse x)) (at 0)"
```
```  1351     unfolding eventually_at norm_inverse
```
```  1352     by (intro exI[of _ "inverse r"])
```
```  1353        (auto simp: norm_conv_dist[symmetric] field_simps inverse_eq_divide)
```
```  1354 qed
```
```  1355
```
```  1356 lemma filterlim_inverse_at_iff:
```
```  1357   fixes g :: "'a \<Rightarrow> 'b::{real_normed_div_algebra, division_ring}"
```
```  1358   shows "(LIM x F. inverse (g x) :> at 0) \<longleftrightarrow> (LIM x F. g x :> at_infinity)"
```
```  1359   unfolding filterlim_def filtermap_filtermap[symmetric]
```
```  1360 proof
```
```  1361   assume "filtermap g F \<le> at_infinity"
```
```  1362   then have "filtermap inverse (filtermap g F) \<le> filtermap inverse at_infinity"
```
```  1363     by (rule filtermap_mono)
```
```  1364   also have "\<dots> \<le> at 0"
```
```  1365     using tendsto_inverse_0[where 'a='b]
```
```  1366     by (auto intro!: exI[of _ 1]
```
```  1367         simp: le_principal eventually_filtermap filterlim_def at_within_def eventually_at_infinity)
```
```  1368   finally show "filtermap inverse (filtermap g F) \<le> at 0" .
```
```  1369 next
```
```  1370   assume "filtermap inverse (filtermap g F) \<le> at 0"
```
```  1371   then have "filtermap inverse (filtermap inverse (filtermap g F)) \<le> filtermap inverse (at 0)"
```
```  1372     by (rule filtermap_mono)
```
```  1373   with filterlim_inverse_at_infinity show "filtermap g F \<le> at_infinity"
```
```  1374     by (auto intro: order_trans simp: filterlim_def filtermap_filtermap)
```
```  1375 qed
```
```  1376
```
```  1377 lemma tendsto_mult_filterlim_at_infinity:
```
```  1378   fixes c :: "'a::real_normed_field"
```
```  1379   assumes  "(f \<longlongrightarrow> c) F" "c \<noteq> 0"
```
```  1380   assumes "filterlim g at_infinity F"
```
```  1381   shows "filterlim (\<lambda>x. f x * g x) at_infinity F"
```
```  1382 proof -
```
```  1383   have "((\<lambda>x. inverse (f x) * inverse (g x)) \<longlongrightarrow> inverse c * 0) F"
```
```  1384     by (intro tendsto_mult tendsto_inverse assms filterlim_compose[OF tendsto_inverse_0])
```
```  1385   then have "filterlim (\<lambda>x. inverse (f x) * inverse (g x)) (at (inverse c * 0)) F"
```
```  1386     unfolding filterlim_at
```
```  1387     using assms
```
```  1388     by (auto intro: filterlim_at_infinity_imp_eventually_ne tendsto_imp_eventually_ne eventually_conj)
```
```  1389   then show ?thesis
```
```  1390     by (subst filterlim_inverse_at_iff[symmetric]) simp_all
```
```  1391 qed
```
```  1392
```
```  1393 lemma tendsto_inverse_0_at_top: "LIM x F. f x :> at_top \<Longrightarrow> ((\<lambda>x. inverse (f x) :: real) \<longlongrightarrow> 0) F"
```
```  1394  by (metis filterlim_at filterlim_mono[OF _ at_top_le_at_infinity order_refl] filterlim_inverse_at_iff)
```
```  1395
```
```  1396 lemma real_tendsto_divide_at_top:
```
```  1397   fixes c::"real"
```
```  1398   assumes "(f \<longlongrightarrow> c) F"
```
```  1399   assumes "filterlim g at_top F"
```
```  1400   shows "((\<lambda>x. f x / g x) \<longlongrightarrow> 0) F"
```
```  1401   by (auto simp: divide_inverse_commute
```
```  1402       intro!: tendsto_mult[THEN tendsto_eq_rhs] tendsto_inverse_0_at_top assms)
```
```  1403
```
```  1404 lemma mult_nat_left_at_top: "c > 0 \<Longrightarrow> filterlim (\<lambda>x. c * x) at_top sequentially"
```
```  1405   for c :: nat
```
```  1406   by (rule filterlim_subseq) (auto simp: strict_mono_def)
```
```  1407
```
```  1408 lemma mult_nat_right_at_top: "c > 0 \<Longrightarrow> filterlim (\<lambda>x. x * c) at_top sequentially"
```
```  1409   for c :: nat
```
```  1410   by (rule filterlim_subseq) (auto simp: strict_mono_def)
```
```  1411
```
```  1412 lemma at_to_infinity: "(at (0::'a::{real_normed_field,field})) = filtermap inverse at_infinity"
```
```  1413 proof (rule antisym)
```
```  1414   have "(inverse \<longlongrightarrow> (0::'a)) at_infinity"
```
```  1415     by (fact tendsto_inverse_0)
```
```  1416   then show "filtermap inverse at_infinity \<le> at (0::'a)"
```
```  1417     apply (simp add: le_principal eventually_filtermap eventually_at_infinity filterlim_def at_within_def)
```
```  1418     apply (rule_tac x="1" in exI)
```
```  1419     apply auto
```
```  1420     done
```
```  1421 next
```
```  1422   have "filtermap inverse (filtermap inverse (at (0::'a))) \<le> filtermap inverse at_infinity"
```
```  1423     using filterlim_inverse_at_infinity unfolding filterlim_def
```
```  1424     by (rule filtermap_mono)
```
```  1425   then show "at (0::'a) \<le> filtermap inverse at_infinity"
```
```  1426     by (simp add: filtermap_ident filtermap_filtermap)
```
```  1427 qed
```
```  1428
```
```  1429 lemma lim_at_infinity_0:
```
```  1430   fixes l :: "'a::{real_normed_field,field}"
```
```  1431   shows "(f \<longlongrightarrow> l) at_infinity \<longleftrightarrow> ((f \<circ> inverse) \<longlongrightarrow> l) (at (0::'a))"
```
```  1432   by (simp add: tendsto_compose_filtermap at_to_infinity filtermap_filtermap)
```
```  1433
```
```  1434 lemma lim_zero_infinity:
```
```  1435   fixes l :: "'a::{real_normed_field,field}"
```
```  1436   shows "((\<lambda>x. f(1 / x)) \<longlongrightarrow> l) (at (0::'a)) \<Longrightarrow> (f \<longlongrightarrow> l) at_infinity"
```
```  1437   by (simp add: inverse_eq_divide lim_at_infinity_0 comp_def)
```
```  1438
```
```  1439
```
```  1440 text \<open>
```
```  1441   We only show rules for multiplication and addition when the functions are either against a real
```
```  1442   value or against infinity. Further rules are easy to derive by using @{thm
```
```  1443   filterlim_uminus_at_top}.
```
```  1444 \<close>
```
```  1445
```
```  1446 lemma filterlim_tendsto_pos_mult_at_top:
```
```  1447   assumes f: "(f \<longlongrightarrow> c) F"
```
```  1448     and c: "0 < c"
```
```  1449     and g: "LIM x F. g x :> at_top"
```
```  1450   shows "LIM x F. (f x * g x :: real) :> at_top"
```
```  1451   unfolding filterlim_at_top_gt[where c=0]
```
```  1452 proof safe
```
```  1453   fix Z :: real
```
```  1454   assume "0 < Z"
```
```  1455   from f \<open>0 < c\<close> have "eventually (\<lambda>x. c / 2 < f x) F"
```
```  1456     by (auto dest!: tendstoD[where e="c / 2"] elim!: eventually_mono
```
```  1457         simp: dist_real_def abs_real_def split: if_split_asm)
```
```  1458   moreover from g have "eventually (\<lambda>x. (Z / c * 2) \<le> g x) F"
```
```  1459     unfolding filterlim_at_top by auto
```
```  1460   ultimately show "eventually (\<lambda>x. Z \<le> f x * g x) F"
```
```  1461   proof eventually_elim
```
```  1462     case (elim x)
```
```  1463     with \<open>0 < Z\<close> \<open>0 < c\<close> have "c / 2 * (Z / c * 2) \<le> f x * g x"
```
```  1464       by (intro mult_mono) (auto simp: zero_le_divide_iff)
```
```  1465     with \<open>0 < c\<close> show "Z \<le> f x * g x"
```
```  1466        by simp
```
```  1467   qed
```
```  1468 qed
```
```  1469
```
```  1470 lemma filterlim_at_top_mult_at_top:
```
```  1471   assumes f: "LIM x F. f x :> at_top"
```
```  1472     and g: "LIM x F. g x :> at_top"
```
```  1473   shows "LIM x F. (f x * g x :: real) :> at_top"
```
```  1474   unfolding filterlim_at_top_gt[where c=0]
```
```  1475 proof safe
```
```  1476   fix Z :: real
```
```  1477   assume "0 < Z"
```
```  1478   from f have "eventually (\<lambda>x. 1 \<le> f x) F"
```
```  1479     unfolding filterlim_at_top by auto
```
```  1480   moreover from g have "eventually (\<lambda>x. Z \<le> g x) F"
```
```  1481     unfolding filterlim_at_top by auto
```
```  1482   ultimately show "eventually (\<lambda>x. Z \<le> f x * g x) F"
```
```  1483   proof eventually_elim
```
```  1484     case (elim x)
```
```  1485     with \<open>0 < Z\<close> have "1 * Z \<le> f x * g x"
```
```  1486       by (intro mult_mono) (auto simp: zero_le_divide_iff)
```
```  1487     then show "Z \<le> f x * g x"
```
```  1488        by simp
```
```  1489   qed
```
```  1490 qed
```
```  1491
```
```  1492 lemma filterlim_at_top_mult_tendsto_pos:
```
```  1493   assumes f: "(f \<longlongrightarrow> c) F"
```
```  1494     and c: "0 < c"
```
```  1495     and g: "LIM x F. g x :> at_top"
```
```  1496   shows "LIM x F. (g x * f x:: real) :> at_top"
```
```  1497   by (auto simp: mult.commute intro!: filterlim_tendsto_pos_mult_at_top f c g)
```
```  1498
```
```  1499 lemma filterlim_tendsto_pos_mult_at_bot:
```
```  1500   fixes c :: real
```
```  1501   assumes "(f \<longlongrightarrow> c) F" "0 < c" "filterlim g at_bot F"
```
```  1502   shows "LIM x F. f x * g x :> at_bot"
```
```  1503   using filterlim_tendsto_pos_mult_at_top[OF assms(1,2), of "\<lambda>x. - g x"] assms(3)
```
```  1504   unfolding filterlim_uminus_at_bot by simp
```
```  1505
```
```  1506 lemma filterlim_tendsto_neg_mult_at_bot:
```
```  1507   fixes c :: real
```
```  1508   assumes c: "(f \<longlongrightarrow> c) F" "c < 0" and g: "filterlim g at_top F"
```
```  1509   shows "LIM x F. f x * g x :> at_bot"
```
```  1510   using c filterlim_tendsto_pos_mult_at_top[of "\<lambda>x. - f x" "- c" F, OF _ _ g]
```
```  1511   unfolding filterlim_uminus_at_bot tendsto_minus_cancel_left by simp
```
```  1512
```
```  1513 lemma filterlim_pow_at_top:
```
```  1514   fixes f :: "'a \<Rightarrow> real"
```
```  1515   assumes "0 < n"
```
```  1516     and f: "LIM x F. f x :> at_top"
```
```  1517   shows "LIM x F. (f x)^n :: real :> at_top"
```
```  1518   using \<open>0 < n\<close>
```
```  1519 proof (induct n)
```
```  1520   case 0
```
```  1521   then show ?case by simp
```
```  1522 next
```
```  1523   case (Suc n) with f show ?case
```
```  1524     by (cases "n = 0") (auto intro!: filterlim_at_top_mult_at_top)
```
```  1525 qed
```
```  1526
```
```  1527 lemma filterlim_pow_at_bot_even:
```
```  1528   fixes f :: "real \<Rightarrow> real"
```
```  1529   shows "0 < n \<Longrightarrow> LIM x F. f x :> at_bot \<Longrightarrow> even n \<Longrightarrow> LIM x F. (f x)^n :> at_top"
```
```  1530   using filterlim_pow_at_top[of n "\<lambda>x. - f x" F] by (simp add: filterlim_uminus_at_top)
```
```  1531
```
```  1532 lemma filterlim_pow_at_bot_odd:
```
```  1533   fixes f :: "real \<Rightarrow> real"
```
```  1534   shows "0 < n \<Longrightarrow> LIM x F. f x :> at_bot \<Longrightarrow> odd n \<Longrightarrow> LIM x F. (f x)^n :> at_bot"
```
```  1535   using filterlim_pow_at_top[of n "\<lambda>x. - f x" F] by (simp add: filterlim_uminus_at_bot)
```
```  1536
```
```  1537 lemma filterlim_tendsto_add_at_top:
```
```  1538   assumes f: "(f \<longlongrightarrow> c) F"
```
```  1539     and g: "LIM x F. g x :> at_top"
```
```  1540   shows "LIM x F. (f x + g x :: real) :> at_top"
```
```  1541   unfolding filterlim_at_top_gt[where c=0]
```
```  1542 proof safe
```
```  1543   fix Z :: real
```
```  1544   assume "0 < Z"
```
```  1545   from f have "eventually (\<lambda>x. c - 1 < f x) F"
```
```  1546     by (auto dest!: tendstoD[where e=1] elim!: eventually_mono simp: dist_real_def)
```
```  1547   moreover from g have "eventually (\<lambda>x. Z - (c - 1) \<le> g x) F"
```
```  1548     unfolding filterlim_at_top by auto
```
```  1549   ultimately show "eventually (\<lambda>x. Z \<le> f x + g x) F"
```
```  1550     by eventually_elim simp
```
```  1551 qed
```
```  1552
```
```  1553 lemma LIM_at_top_divide:
```
```  1554   fixes f g :: "'a \<Rightarrow> real"
```
```  1555   assumes f: "(f \<longlongrightarrow> a) F" "0 < a"
```
```  1556     and g: "(g \<longlongrightarrow> 0) F" "eventually (\<lambda>x. 0 < g x) F"
```
```  1557   shows "LIM x F. f x / g x :> at_top"
```
```  1558   unfolding divide_inverse
```
```  1559   by (rule filterlim_tendsto_pos_mult_at_top[OF f]) (rule filterlim_inverse_at_top[OF g])
```
```  1560
```
```  1561 lemma filterlim_at_top_add_at_top:
```
```  1562   assumes f: "LIM x F. f x :> at_top"
```
```  1563     and g: "LIM x F. g x :> at_top"
```
```  1564   shows "LIM x F. (f x + g x :: real) :> at_top"
```
```  1565   unfolding filterlim_at_top_gt[where c=0]
```
```  1566 proof safe
```
```  1567   fix Z :: real
```
```  1568   assume "0 < Z"
```
```  1569   from f have "eventually (\<lambda>x. 0 \<le> f x) F"
```
```  1570     unfolding filterlim_at_top by auto
```
```  1571   moreover from g have "eventually (\<lambda>x. Z \<le> g x) F"
```
```  1572     unfolding filterlim_at_top by auto
```
```  1573   ultimately show "eventually (\<lambda>x. Z \<le> f x + g x) F"
```
```  1574     by eventually_elim simp
```
```  1575 qed
```
```  1576
```
```  1577 lemma tendsto_divide_0:
```
```  1578   fixes f :: "_ \<Rightarrow> 'a::{real_normed_div_algebra, division_ring}"
```
```  1579   assumes f: "(f \<longlongrightarrow> c) F"
```
```  1580     and g: "LIM x F. g x :> at_infinity"
```
```  1581   shows "((\<lambda>x. f x / g x) \<longlongrightarrow> 0) F"
```
```  1582   using tendsto_mult[OF f filterlim_compose[OF tendsto_inverse_0 g]]
```
```  1583   by (simp add: divide_inverse)
```
```  1584
```
```  1585 lemma linear_plus_1_le_power:
```
```  1586   fixes x :: real
```
```  1587   assumes x: "0 \<le> x"
```
```  1588   shows "real n * x + 1 \<le> (x + 1) ^ n"
```
```  1589 proof (induct n)
```
```  1590   case 0
```
```  1591   then show ?case by simp
```
```  1592 next
```
```  1593   case (Suc n)
```
```  1594   from x have "real (Suc n) * x + 1 \<le> (x + 1) * (real n * x + 1)"
```
```  1595     by (simp add: field_simps)
```
```  1596   also have "\<dots> \<le> (x + 1)^Suc n"
```
```  1597     using Suc x by (simp add: mult_left_mono)
```
```  1598   finally show ?case .
```
```  1599 qed
```
```  1600
```
```  1601 lemma filterlim_realpow_sequentially_gt1:
```
```  1602   fixes x :: "'a :: real_normed_div_algebra"
```
```  1603   assumes x[arith]: "1 < norm x"
```
```  1604   shows "LIM n sequentially. x ^ n :> at_infinity"
```
```  1605 proof (intro filterlim_at_infinity[THEN iffD2] allI impI)
```
```  1606   fix y :: real
```
```  1607   assume "0 < y"
```
```  1608   have "0 < norm x - 1" by simp
```
```  1609   then obtain N :: nat where "y < real N * (norm x - 1)"
```
```  1610     by (blast dest: reals_Archimedean3)
```
```  1611   also have "\<dots> \<le> real N * (norm x - 1) + 1"
```
```  1612     by simp
```
```  1613   also have "\<dots> \<le> (norm x - 1 + 1) ^ N"
```
```  1614     by (rule linear_plus_1_le_power) simp
```
```  1615   also have "\<dots> = norm x ^ N"
```
```  1616     by simp
```
```  1617   finally have "\<forall>n\<ge>N. y \<le> norm x ^ n"
```
```  1618     by (metis order_less_le_trans power_increasing order_less_imp_le x)
```
```  1619   then show "eventually (\<lambda>n. y \<le> norm (x ^ n)) sequentially"
```
```  1620     unfolding eventually_sequentially
```
```  1621     by (auto simp: norm_power)
```
```  1622 qed simp
```
```  1623
```
```  1624
```
```  1625 lemma filterlim_divide_at_infinity:
```
```  1626   fixes f g :: "'a \<Rightarrow> 'a :: real_normed_field"
```
```  1627   assumes "filterlim f (nhds c) F" "filterlim g (at 0) F" "c \<noteq> 0"
```
```  1628   shows   "filterlim (\<lambda>x. f x / g x) at_infinity F"
```
```  1629 proof -
```
```  1630   have "filterlim (\<lambda>x. f x * inverse (g x)) at_infinity F"
```
```  1631     by (intro tendsto_mult_filterlim_at_infinity[OF assms(1,3)]
```
```  1632           filterlim_compose [OF filterlim_inverse_at_infinity assms(2)])
```
```  1633   thus ?thesis by (simp add: field_simps)
```
```  1634 qed
```
```  1635
```
```  1636 subsection \<open>Floor and Ceiling\<close>
```
```  1637
```
```  1638 lemma eventually_floor_less:
```
```  1639   fixes f :: "'a \<Rightarrow> 'b::{order_topology,floor_ceiling}"
```
```  1640   assumes f: "(f \<longlongrightarrow> l) F"
```
```  1641     and l: "l \<notin> \<int>"
```
```  1642   shows "\<forall>\<^sub>F x in F. of_int (floor l) < f x"
```
```  1643   by (intro order_tendstoD[OF f]) (metis Ints_of_int antisym_conv2 floor_correct l)
```
```  1644
```
```  1645 lemma eventually_less_ceiling:
```
```  1646   fixes f :: "'a \<Rightarrow> 'b::{order_topology,floor_ceiling}"
```
```  1647   assumes f: "(f \<longlongrightarrow> l) F"
```
```  1648     and l: "l \<notin> \<int>"
```
```  1649   shows "\<forall>\<^sub>F x in F. f x < of_int (ceiling l)"
```
```  1650   by (intro order_tendstoD[OF f]) (metis Ints_of_int l le_of_int_ceiling less_le)
```
```  1651
```
```  1652 lemma eventually_floor_eq:
```
```  1653   fixes f::"'a \<Rightarrow> 'b::{order_topology,floor_ceiling}"
```
```  1654   assumes f: "(f \<longlongrightarrow> l) F"
```
```  1655     and l: "l \<notin> \<int>"
```
```  1656   shows "\<forall>\<^sub>F x in F. floor (f x) = floor l"
```
```  1657   using eventually_floor_less[OF assms] eventually_less_ceiling[OF assms]
```
```  1658   by eventually_elim (meson floor_less_iff less_ceiling_iff not_less_iff_gr_or_eq)
```
```  1659
```
```  1660 lemma eventually_ceiling_eq:
```
```  1661   fixes f::"'a \<Rightarrow> 'b::{order_topology,floor_ceiling}"
```
```  1662   assumes f: "(f \<longlongrightarrow> l) F"
```
```  1663     and l: "l \<notin> \<int>"
```
```  1664   shows "\<forall>\<^sub>F x in F. ceiling (f x) = ceiling l"
```
```  1665   using eventually_floor_less[OF assms] eventually_less_ceiling[OF assms]
```
```  1666   by eventually_elim (meson floor_less_iff less_ceiling_iff not_less_iff_gr_or_eq)
```
```  1667
```
```  1668 lemma tendsto_of_int_floor:
```
```  1669   fixes f::"'a \<Rightarrow> 'b::{order_topology,floor_ceiling}"
```
```  1670   assumes "(f \<longlongrightarrow> l) F"
```
```  1671     and "l \<notin> \<int>"
```
```  1672   shows "((\<lambda>x. of_int (floor (f x)) :: 'c::{ring_1,topological_space}) \<longlongrightarrow> of_int (floor l)) F"
```
```  1673   using eventually_floor_eq[OF assms]
```
```  1674   by (simp add: eventually_mono topological_tendstoI)
```
```  1675
```
```  1676 lemma tendsto_of_int_ceiling:
```
```  1677   fixes f::"'a \<Rightarrow> 'b::{order_topology,floor_ceiling}"
```
```  1678   assumes "(f \<longlongrightarrow> l) F"
```
```  1679     and "l \<notin> \<int>"
```
```  1680   shows "((\<lambda>x. of_int (ceiling (f x)):: 'c::{ring_1,topological_space}) \<longlongrightarrow> of_int (ceiling l)) F"
```
```  1681   using eventually_ceiling_eq[OF assms]
```
```  1682   by (simp add: eventually_mono topological_tendstoI)
```
```  1683
```
```  1684 lemma continuous_on_of_int_floor:
```
```  1685   "continuous_on (UNIV - \<int>::'a::{order_topology, floor_ceiling} set)
```
```  1686     (\<lambda>x. of_int (floor x)::'b::{ring_1, topological_space})"
```
```  1687   unfolding continuous_on_def
```
```  1688   by (auto intro!: tendsto_of_int_floor)
```
```  1689
```
```  1690 lemma continuous_on_of_int_ceiling:
```
```  1691   "continuous_on (UNIV - \<int>::'a::{order_topology, floor_ceiling} set)
```
```  1692     (\<lambda>x. of_int (ceiling x)::'b::{ring_1, topological_space})"
```
```  1693   unfolding continuous_on_def
```
```  1694   by (auto intro!: tendsto_of_int_ceiling)
```
```  1695
```
```  1696
```
```  1697 subsection \<open>Limits of Sequences\<close>
```
```  1698
```
```  1699 lemma [trans]: "X = Y \<Longrightarrow> Y \<longlonglongrightarrow> z \<Longrightarrow> X \<longlonglongrightarrow> z"
```
```  1700   by simp
```
```  1701
```
```  1702 lemma LIMSEQ_iff:
```
```  1703   fixes L :: "'a::real_normed_vector"
```
```  1704   shows "(X \<longlonglongrightarrow> L) = (\<forall>r>0. \<exists>no. \<forall>n \<ge> no. norm (X n - L) < r)"
```
```  1705 unfolding lim_sequentially dist_norm ..
```
```  1706
```
```  1707 lemma LIMSEQ_I: "(\<And>r. 0 < r \<Longrightarrow> \<exists>no. \<forall>n\<ge>no. norm (X n - L) < r) \<Longrightarrow> X \<longlonglongrightarrow> L"
```
```  1708   for L :: "'a::real_normed_vector"
```
```  1709   by (simp add: LIMSEQ_iff)
```
```  1710
```
```  1711 lemma LIMSEQ_D: "X \<longlonglongrightarrow> L \<Longrightarrow> 0 < r \<Longrightarrow> \<exists>no. \<forall>n\<ge>no. norm (X n - L) < r"
```
```  1712   for L :: "'a::real_normed_vector"
```
```  1713   by (simp add: LIMSEQ_iff)
```
```  1714
```
```  1715 lemma LIMSEQ_linear: "X \<longlonglongrightarrow> x \<Longrightarrow> l > 0 \<Longrightarrow> (\<lambda> n. X (n * l)) \<longlonglongrightarrow> x"
```
```  1716   unfolding tendsto_def eventually_sequentially
```
```  1717   by (metis div_le_dividend div_mult_self1_is_m le_trans mult.commute)
```
```  1718
```
```  1719 lemma norm_inverse_le_norm: "r \<le> norm x \<Longrightarrow> 0 < r \<Longrightarrow> norm (inverse x) \<le> inverse r"
```
```  1720   for x :: "'a::real_normed_div_algebra"
```
```  1721   apply (subst nonzero_norm_inverse, clarsimp)
```
```  1722   apply (erule (1) le_imp_inverse_le)
```
```  1723   done
```
```  1724
```
```  1725 lemma Bseq_inverse: "X \<longlonglongrightarrow> a \<Longrightarrow> a \<noteq> 0 \<Longrightarrow> Bseq (\<lambda>n. inverse (X n))"
```
```  1726   for a :: "'a::real_normed_div_algebra"
```
```  1727   by (rule Bfun_inverse)
```
```  1728
```
```  1729
```
```  1730 text \<open>Transformation of limit.\<close>
```
```  1731
```
```  1732 lemma Lim_transform: "(g \<longlongrightarrow> a) F \<Longrightarrow> ((\<lambda>x. f x - g x) \<longlongrightarrow> 0) F \<Longrightarrow> (f \<longlongrightarrow> a) F"
```
```  1733   for a b :: "'a::real_normed_vector"
```
```  1734   using tendsto_add [of g a F "\<lambda>x. f x - g x" 0] by simp
```
```  1735
```
```  1736 lemma Lim_transform2: "(f \<longlongrightarrow> a) F \<Longrightarrow> ((\<lambda>x. f x - g x) \<longlongrightarrow> 0) F \<Longrightarrow> (g \<longlongrightarrow> a) F"
```
```  1737   for a b :: "'a::real_normed_vector"
```
```  1738   by (erule Lim_transform) (simp add: tendsto_minus_cancel)
```
```  1739
```
```  1740 proposition Lim_transform_eq: "((\<lambda>x. f x - g x) \<longlongrightarrow> 0) F \<Longrightarrow> (f \<longlongrightarrow> a) F \<longleftrightarrow> (g \<longlongrightarrow> a) F"
```
```  1741   for a :: "'a::real_normed_vector"
```
```  1742   using Lim_transform Lim_transform2 by blast
```
```  1743
```
```  1744 lemma Lim_transform_eventually:
```
```  1745   "eventually (\<lambda>x. f x = g x) net \<Longrightarrow> (f \<longlongrightarrow> l) net \<Longrightarrow> (g \<longlongrightarrow> l) net"
```
```  1746   apply (rule topological_tendstoI)
```
```  1747   apply (drule (2) topological_tendstoD)
```
```  1748   apply (erule (1) eventually_elim2)
```
```  1749   apply simp
```
```  1750   done
```
```  1751
```
```  1752 lemma Lim_transform_within:
```
```  1753   assumes "(f \<longlongrightarrow> l) (at x within S)"
```
```  1754     and "0 < d"
```
```  1755     and "\<And>x'. x'\<in>S \<Longrightarrow> 0 < dist x' x \<Longrightarrow> dist x' x < d \<Longrightarrow> f x' = g x'"
```
```  1756   shows "(g \<longlongrightarrow> l) (at x within S)"
```
```  1757 proof (rule Lim_transform_eventually)
```
```  1758   show "eventually (\<lambda>x. f x = g x) (at x within S)"
```
```  1759     using assms by (auto simp: eventually_at)
```
```  1760   show "(f \<longlongrightarrow> l) (at x within S)"
```
```  1761     by fact
```
```  1762 qed
```
```  1763
```
```  1764 text \<open>Common case assuming being away from some crucial point like 0.\<close>
```
```  1765 lemma Lim_transform_away_within:
```
```  1766   fixes a b :: "'a::t1_space"
```
```  1767   assumes "a \<noteq> b"
```
```  1768     and "\<forall>x\<in>S. x \<noteq> a \<and> x \<noteq> b \<longrightarrow> f x = g x"
```
```  1769     and "(f \<longlongrightarrow> l) (at a within S)"
```
```  1770   shows "(g \<longlongrightarrow> l) (at a within S)"
```
```  1771 proof (rule Lim_transform_eventually)
```
```  1772   show "(f \<longlongrightarrow> l) (at a within S)"
```
```  1773     by fact
```
```  1774   show "eventually (\<lambda>x. f x = g x) (at a within S)"
```
```  1775     unfolding eventually_at_topological
```
```  1776     by (rule exI [where x="- {b}"]) (simp add: open_Compl assms)
```
```  1777 qed
```
```  1778
```
```  1779 lemma Lim_transform_away_at:
```
```  1780   fixes a b :: "'a::t1_space"
```
```  1781   assumes ab: "a \<noteq> b"
```
```  1782     and fg: "\<forall>x. x \<noteq> a \<and> x \<noteq> b \<longrightarrow> f x = g x"
```
```  1783     and fl: "(f \<longlongrightarrow> l) (at a)"
```
```  1784   shows "(g \<longlongrightarrow> l) (at a)"
```
```  1785   using Lim_transform_away_within[OF ab, of UNIV f g l] fg fl by simp
```
```  1786
```
```  1787 text \<open>Alternatively, within an open set.\<close>
```
```  1788 lemma Lim_transform_within_open:
```
```  1789   assumes "(f \<longlongrightarrow> l) (at a within T)"
```
```  1790     and "open s" and "a \<in> s"
```
```  1791     and "\<And>x. x\<in>s \<Longrightarrow> x \<noteq> a \<Longrightarrow> f x = g x"
```
```  1792   shows "(g \<longlongrightarrow> l) (at a within T)"
```
```  1793 proof (rule Lim_transform_eventually)
```
```  1794   show "eventually (\<lambda>x. f x = g x) (at a within T)"
```
```  1795     unfolding eventually_at_topological
```
```  1796     using assms by auto
```
```  1797   show "(f \<longlongrightarrow> l) (at a within T)" by fact
```
```  1798 qed
```
```  1799
```
```  1800
```
```  1801 text \<open>A congruence rule allowing us to transform limits assuming not at point.\<close>
```
```  1802
```
```  1803 (* FIXME: Only one congruence rule for tendsto can be used at a time! *)
```
```  1804
```
```  1805 lemma Lim_cong_within(*[cong add]*):
```
```  1806   assumes "a = b"
```
```  1807     and "x = y"
```
```  1808     and "S = T"
```
```  1809     and "\<And>x. x \<noteq> b \<Longrightarrow> x \<in> T \<Longrightarrow> f x = g x"
```
```  1810   shows "(f \<longlongrightarrow> x) (at a within S) \<longleftrightarrow> (g \<longlongrightarrow> y) (at b within T)"
```
```  1811   unfolding tendsto_def eventually_at_topological
```
```  1812   using assms by simp
```
```  1813
```
```  1814 lemma Lim_cong_at(*[cong add]*):
```
```  1815   assumes "a = b" "x = y"
```
```  1816     and "\<And>x. x \<noteq> a \<Longrightarrow> f x = g x"
```
```  1817   shows "((\<lambda>x. f x) \<longlongrightarrow> x) (at a) \<longleftrightarrow> ((g \<longlongrightarrow> y) (at a))"
```
```  1818   unfolding tendsto_def eventually_at_topological
```
```  1819   using assms by simp
```
```  1820
```
```  1821 text \<open>An unbounded sequence's inverse tends to 0.\<close>
```
```  1822 lemma LIMSEQ_inverse_zero:
```
```  1823   assumes "\<And>r::real. \<exists>N. \<forall>n\<ge>N. r < X n"
```
```  1824   shows "(\<lambda>n. inverse (X n)) \<longlonglongrightarrow> 0"
```
```  1825   apply (rule filterlim_compose[OF tendsto_inverse_0])
```
```  1826   apply (simp add: filterlim_at_infinity[OF order_refl] eventually_sequentially)
```
```  1827   apply (metis assms abs_le_D1 linorder_le_cases linorder_not_le)
```
```  1828   done
```
```  1829
```
```  1830 text \<open>The sequence @{term "1/n"} tends to 0 as @{term n} tends to infinity.\<close>
```
```  1831 lemma LIMSEQ_inverse_real_of_nat: "(\<lambda>n. inverse (real (Suc n))) \<longlonglongrightarrow> 0"
```
```  1832   by (metis filterlim_compose tendsto_inverse_0 filterlim_mono order_refl filterlim_Suc
```
```  1833       filterlim_compose[OF filterlim_real_sequentially] at_top_le_at_infinity)
```
```  1834
```
```  1835 text \<open>
```
```  1836   The sequence @{term "r + 1/n"} tends to @{term r} as @{term n} tends to
```
```  1837   infinity is now easily proved.
```
```  1838 \<close>
```
```  1839
```
```  1840 lemma LIMSEQ_inverse_real_of_nat_add: "(\<lambda>n. r + inverse (real (Suc n))) \<longlonglongrightarrow> r"
```
```  1841   using tendsto_add [OF tendsto_const LIMSEQ_inverse_real_of_nat] by auto
```
```  1842
```
```  1843 lemma LIMSEQ_inverse_real_of_nat_add_minus: "(\<lambda>n. r + -inverse (real (Suc n))) \<longlonglongrightarrow> r"
```
```  1844   using tendsto_add [OF tendsto_const tendsto_minus [OF LIMSEQ_inverse_real_of_nat]]
```
```  1845   by auto
```
```  1846
```
```  1847 lemma LIMSEQ_inverse_real_of_nat_add_minus_mult: "(\<lambda>n. r * (1 + - inverse (real (Suc n)))) \<longlonglongrightarrow> r"
```
```  1848   using tendsto_mult [OF tendsto_const LIMSEQ_inverse_real_of_nat_add_minus [of 1]]
```
```  1849   by auto
```
```  1850
```
```  1851 lemma lim_inverse_n: "((\<lambda>n. inverse(of_nat n)) \<longlongrightarrow> (0::'a::real_normed_field)) sequentially"
```
```  1852   using lim_1_over_n by (simp add: inverse_eq_divide)
```
```  1853
```
```  1854 lemma LIMSEQ_Suc_n_over_n: "(\<lambda>n. of_nat (Suc n) / of_nat n :: 'a :: real_normed_field) \<longlonglongrightarrow> 1"
```
```  1855 proof (rule Lim_transform_eventually)
```
```  1856   show "eventually (\<lambda>n. 1 + inverse (of_nat n :: 'a) = of_nat (Suc n) / of_nat n) sequentially"
```
```  1857     using eventually_gt_at_top[of "0::nat"]
```
```  1858     by eventually_elim (simp add: field_simps)
```
```  1859   have "(\<lambda>n. 1 + inverse (of_nat n) :: 'a) \<longlonglongrightarrow> 1 + 0"
```
```  1860     by (intro tendsto_add tendsto_const lim_inverse_n)
```
```  1861   then show "(\<lambda>n. 1 + inverse (of_nat n) :: 'a) \<longlonglongrightarrow> 1"
```
```  1862     by simp
```
```  1863 qed
```
```  1864
```
```  1865 lemma LIMSEQ_n_over_Suc_n: "(\<lambda>n. of_nat n / of_nat (Suc n) :: 'a :: real_normed_field) \<longlonglongrightarrow> 1"
```
```  1866 proof (rule Lim_transform_eventually)
```
```  1867   show "eventually (\<lambda>n. inverse (of_nat (Suc n) / of_nat n :: 'a) =
```
```  1868       of_nat n / of_nat (Suc n)) sequentially"
```
```  1869     using eventually_gt_at_top[of "0::nat"]
```
```  1870     by eventually_elim (simp add: field_simps del: of_nat_Suc)
```
```  1871   have "(\<lambda>n. inverse (of_nat (Suc n) / of_nat n :: 'a)) \<longlonglongrightarrow> inverse 1"
```
```  1872     by (intro tendsto_inverse LIMSEQ_Suc_n_over_n) simp_all
```
```  1873   then show "(\<lambda>n. inverse (of_nat (Suc n) / of_nat n :: 'a)) \<longlonglongrightarrow> 1"
```
```  1874     by simp
```
```  1875 qed
```
```  1876
```
```  1877
```
```  1878 subsection \<open>Convergence on sequences\<close>
```
```  1879
```
```  1880 lemma convergent_cong:
```
```  1881   assumes "eventually (\<lambda>x. f x = g x) sequentially"
```
```  1882   shows "convergent f \<longleftrightarrow> convergent g"
```
```  1883   unfolding convergent_def
```
```  1884   by (subst filterlim_cong[OF refl refl assms]) (rule refl)
```
```  1885
```
```  1886 lemma convergent_Suc_iff: "convergent (\<lambda>n. f (Suc n)) \<longleftrightarrow> convergent f"
```
```  1887   by (auto simp: convergent_def LIMSEQ_Suc_iff)
```
```  1888
```
```  1889 lemma convergent_ignore_initial_segment: "convergent (\<lambda>n. f (n + m)) = convergent f"
```
```  1890 proof (induct m arbitrary: f)
```
```  1891   case 0
```
```  1892   then show ?case by simp
```
```  1893 next
```
```  1894   case (Suc m)
```
```  1895   have "convergent (\<lambda>n. f (n + Suc m)) \<longleftrightarrow> convergent (\<lambda>n. f (Suc n + m))"
```
```  1896     by simp
```
```  1897   also have "\<dots> \<longleftrightarrow> convergent (\<lambda>n. f (n + m))"
```
```  1898     by (rule convergent_Suc_iff)
```
```  1899   also have "\<dots> \<longleftrightarrow> convergent f"
```
```  1900     by (rule Suc)
```
```  1901   finally show ?case .
```
```  1902 qed
```
```  1903
```
```  1904 lemma convergent_add:
```
```  1905   fixes X Y :: "nat \<Rightarrow> 'a::real_normed_vector"
```
```  1906   assumes "convergent (\<lambda>n. X n)"
```
```  1907     and "convergent (\<lambda>n. Y n)"
```
```  1908   shows "convergent (\<lambda>n. X n + Y n)"
```
```  1909   using assms unfolding convergent_def by (blast intro: tendsto_add)
```
```  1910
```
```  1911 lemma convergent_sum:
```
```  1912   fixes X :: "'a \<Rightarrow> nat \<Rightarrow> 'b::real_normed_vector"
```
```  1913   shows "(\<And>i. i \<in> A \<Longrightarrow> convergent (\<lambda>n. X i n)) \<Longrightarrow> convergent (\<lambda>n. \<Sum>i\<in>A. X i n)"
```
```  1914   by (induct A rule: infinite_finite_induct) (simp_all add: convergent_const convergent_add)
```
```  1915
```
```  1916 lemma (in bounded_linear) convergent:
```
```  1917   assumes "convergent (\<lambda>n. X n)"
```
```  1918   shows "convergent (\<lambda>n. f (X n))"
```
```  1919   using assms unfolding convergent_def by (blast intro: tendsto)
```
```  1920
```
```  1921 lemma (in bounded_bilinear) convergent:
```
```  1922   assumes "convergent (\<lambda>n. X n)"
```
```  1923     and "convergent (\<lambda>n. Y n)"
```
```  1924   shows "convergent (\<lambda>n. X n ** Y n)"
```
```  1925   using assms unfolding convergent_def by (blast intro: tendsto)
```
```  1926
```
```  1927 lemma convergent_minus_iff: "convergent X \<longleftrightarrow> convergent (\<lambda>n. - X n)"
```
```  1928   for X :: "nat \<Rightarrow> 'a::real_normed_vector"
```
```  1929   apply (simp add: convergent_def)
```
```  1930   apply (auto dest: tendsto_minus)
```
```  1931   apply (drule tendsto_minus)
```
```  1932   apply auto
```
```  1933   done
```
```  1934
```
```  1935 lemma convergent_diff:
```
```  1936   fixes X Y :: "nat \<Rightarrow> 'a::real_normed_vector"
```
```  1937   assumes "convergent (\<lambda>n. X n)"
```
```  1938   assumes "convergent (\<lambda>n. Y n)"
```
```  1939   shows "convergent (\<lambda>n. X n - Y n)"
```
```  1940   using assms unfolding convergent_def by (blast intro: tendsto_diff)
```
```  1941
```
```  1942 lemma convergent_norm:
```
```  1943   assumes "convergent f"
```
```  1944   shows "convergent (\<lambda>n. norm (f n))"
```
```  1945 proof -
```
```  1946   from assms have "f \<longlonglongrightarrow> lim f"
```
```  1947     by (simp add: convergent_LIMSEQ_iff)
```
```  1948   then have "(\<lambda>n. norm (f n)) \<longlonglongrightarrow> norm (lim f)"
```
```  1949     by (rule tendsto_norm)
```
```  1950   then show ?thesis
```
```  1951     by (auto simp: convergent_def)
```
```  1952 qed
```
```  1953
```
```  1954 lemma convergent_of_real:
```
```  1955   "convergent f \<Longrightarrow> convergent (\<lambda>n. of_real (f n) :: 'a::real_normed_algebra_1)"
```
```  1956   unfolding convergent_def by (blast intro!: tendsto_of_real)
```
```  1957
```
```  1958 lemma convergent_add_const_iff:
```
```  1959   "convergent (\<lambda>n. c + f n :: 'a::real_normed_vector) \<longleftrightarrow> convergent f"
```
```  1960 proof
```
```  1961   assume "convergent (\<lambda>n. c + f n)"
```
```  1962   from convergent_diff[OF this convergent_const[of c]] show "convergent f"
```
```  1963     by simp
```
```  1964 next
```
```  1965   assume "convergent f"
```
```  1966   from convergent_add[OF convergent_const[of c] this] show "convergent (\<lambda>n. c + f n)"
```
```  1967     by simp
```
```  1968 qed
```
```  1969
```
```  1970 lemma convergent_add_const_right_iff:
```
```  1971   "convergent (\<lambda>n. f n + c :: 'a::real_normed_vector) \<longleftrightarrow> convergent f"
```
```  1972   using convergent_add_const_iff[of c f] by (simp add: add_ac)
```
```  1973
```
```  1974 lemma convergent_diff_const_right_iff:
```
```  1975   "convergent (\<lambda>n. f n - c :: 'a::real_normed_vector) \<longleftrightarrow> convergent f"
```
```  1976   using convergent_add_const_right_iff[of f "-c"] by (simp add: add_ac)
```
```  1977
```
```  1978 lemma convergent_mult:
```
```  1979   fixes X Y :: "nat \<Rightarrow> 'a::real_normed_field"
```
```  1980   assumes "convergent (\<lambda>n. X n)"
```
```  1981     and "convergent (\<lambda>n. Y n)"
```
```  1982   shows "convergent (\<lambda>n. X n * Y n)"
```
```  1983   using assms unfolding convergent_def by (blast intro: tendsto_mult)
```
```  1984
```
```  1985 lemma convergent_mult_const_iff:
```
```  1986   assumes "c \<noteq> 0"
```
```  1987   shows "convergent (\<lambda>n. c * f n :: 'a::real_normed_field) \<longleftrightarrow> convergent f"
```
```  1988 proof
```
```  1989   assume "convergent (\<lambda>n. c * f n)"
```
```  1990   from assms convergent_mult[OF this convergent_const[of "inverse c"]]
```
```  1991     show "convergent f" by (simp add: field_simps)
```
```  1992 next
```
```  1993   assume "convergent f"
```
```  1994   from convergent_mult[OF convergent_const[of c] this] show "convergent (\<lambda>n. c * f n)"
```
```  1995     by simp
```
```  1996 qed
```
```  1997
```
```  1998 lemma convergent_mult_const_right_iff:
```
```  1999   fixes c :: "'a::real_normed_field"
```
```  2000   assumes "c \<noteq> 0"
```
```  2001   shows "convergent (\<lambda>n. f n * c) \<longleftrightarrow> convergent f"
```
```  2002   using convergent_mult_const_iff[OF assms, of f] by (simp add: mult_ac)
```
```  2003
```
```  2004 lemma convergent_imp_Bseq: "convergent f \<Longrightarrow> Bseq f"
```
```  2005   by (simp add: Cauchy_Bseq convergent_Cauchy)
```
```  2006
```
```  2007
```
```  2008 text \<open>A monotone sequence converges to its least upper bound.\<close>
```
```  2009
```
```  2010 lemma LIMSEQ_incseq_SUP:
```
```  2011   fixes X :: "nat \<Rightarrow> 'a::{conditionally_complete_linorder,linorder_topology}"
```
```  2012   assumes u: "bdd_above (range X)"
```
```  2013     and X: "incseq X"
```
```  2014   shows "X \<longlonglongrightarrow> (SUP i. X i)"
```
```  2015   by (rule order_tendstoI)
```
```  2016     (auto simp: eventually_sequentially u less_cSUP_iff
```
```  2017       intro: X[THEN incseqD] less_le_trans cSUP_lessD[OF u])
```
```  2018
```
```  2019 lemma LIMSEQ_decseq_INF:
```
```  2020   fixes X :: "nat \<Rightarrow> 'a::{conditionally_complete_linorder, linorder_topology}"
```
```  2021   assumes u: "bdd_below (range X)"
```
```  2022     and X: "decseq X"
```
```  2023   shows "X \<longlonglongrightarrow> (INF i. X i)"
```
```  2024   by (rule order_tendstoI)
```
```  2025      (auto simp: eventually_sequentially u cINF_less_iff
```
```  2026        intro: X[THEN decseqD] le_less_trans less_cINF_D[OF u])
```
```  2027
```
```  2028 text \<open>Main monotonicity theorem.\<close>
```
```  2029
```
```  2030 lemma Bseq_monoseq_convergent: "Bseq X \<Longrightarrow> monoseq X \<Longrightarrow> convergent X"
```
```  2031   for X :: "nat \<Rightarrow> real"
```
```  2032   by (auto simp: monoseq_iff convergent_def intro: LIMSEQ_decseq_INF LIMSEQ_incseq_SUP
```
```  2033       dest: Bseq_bdd_above Bseq_bdd_below)
```
```  2034
```
```  2035 lemma Bseq_mono_convergent: "Bseq X \<Longrightarrow> (\<forall>m n. m \<le> n \<longrightarrow> X m \<le> X n) \<Longrightarrow> convergent X"
```
```  2036   for X :: "nat \<Rightarrow> real"
```
```  2037   by (auto intro!: Bseq_monoseq_convergent incseq_imp_monoseq simp: incseq_def)
```
```  2038
```
```  2039 lemma monoseq_imp_convergent_iff_Bseq: "monoseq f \<Longrightarrow> convergent f \<longleftrightarrow> Bseq f"
```
```  2040   for f :: "nat \<Rightarrow> real"
```
```  2041   using Bseq_monoseq_convergent[of f] convergent_imp_Bseq[of f] by blast
```
```  2042
```
```  2043 lemma Bseq_monoseq_convergent'_inc:
```
```  2044   fixes f :: "nat \<Rightarrow> real"
```
```  2045   shows "Bseq (\<lambda>n. f (n + M)) \<Longrightarrow> (\<And>m n. M \<le> m \<Longrightarrow> m \<le> n \<Longrightarrow> f m \<le> f n) \<Longrightarrow> convergent f"
```
```  2046   by (subst convergent_ignore_initial_segment [symmetric, of _ M])
```
```  2047      (auto intro!: Bseq_monoseq_convergent simp: monoseq_def)
```
```  2048
```
```  2049 lemma Bseq_monoseq_convergent'_dec:
```
```  2050   fixes f :: "nat \<Rightarrow> real"
```
```  2051   shows "Bseq (\<lambda>n. f (n + M)) \<Longrightarrow> (\<And>m n. M \<le> m \<Longrightarrow> m \<le> n \<Longrightarrow> f m \<ge> f n) \<Longrightarrow> convergent f"
```
```  2052   by (subst convergent_ignore_initial_segment [symmetric, of _ M])
```
```  2053     (auto intro!: Bseq_monoseq_convergent simp: monoseq_def)
```
```  2054
```
```  2055 lemma Cauchy_iff: "Cauchy X \<longleftrightarrow> (\<forall>e>0. \<exists>M. \<forall>m\<ge>M. \<forall>n\<ge>M. norm (X m - X n) < e)"
```
```  2056   for X :: "nat \<Rightarrow> 'a::real_normed_vector"
```
```  2057   unfolding Cauchy_def dist_norm ..
```
```  2058
```
```  2059 lemma CauchyI: "(\<And>e. 0 < e \<Longrightarrow> \<exists>M. \<forall>m\<ge>M. \<forall>n\<ge>M. norm (X m - X n) < e) \<Longrightarrow> Cauchy X"
```
```  2060   for X :: "nat \<Rightarrow> 'a::real_normed_vector"
```
```  2061   by (simp add: Cauchy_iff)
```
```  2062
```
```  2063 lemma CauchyD: "Cauchy X \<Longrightarrow> 0 < e \<Longrightarrow> \<exists>M. \<forall>m\<ge>M. \<forall>n\<ge>M. norm (X m - X n) < e"
```
```  2064   for X :: "nat \<Rightarrow> 'a::real_normed_vector"
```
```  2065   by (simp add: Cauchy_iff)
```
```  2066
```
```  2067 lemma incseq_convergent:
```
```  2068   fixes X :: "nat \<Rightarrow> real"
```
```  2069   assumes "incseq X"
```
```  2070     and "\<forall>i. X i \<le> B"
```
```  2071   obtains L where "X \<longlonglongrightarrow> L" "\<forall>i. X i \<le> L"
```
```  2072 proof atomize_elim
```
```  2073   from incseq_bounded[OF assms] \<open>incseq X\<close> Bseq_monoseq_convergent[of X]
```
```  2074   obtain L where "X \<longlonglongrightarrow> L"
```
```  2075     by (auto simp: convergent_def monoseq_def incseq_def)
```
```  2076   with \<open>incseq X\<close> show "\<exists>L. X \<longlonglongrightarrow> L \<and> (\<forall>i. X i \<le> L)"
```
```  2077     by (auto intro!: exI[of _ L] incseq_le)
```
```  2078 qed
```
```  2079
```
```  2080 lemma decseq_convergent:
```
```  2081   fixes X :: "nat \<Rightarrow> real"
```
```  2082   assumes "decseq X"
```
```  2083     and "\<forall>i. B \<le> X i"
```
```  2084   obtains L where "X \<longlonglongrightarrow> L" "\<forall>i. L \<le> X i"
```
```  2085 proof atomize_elim
```
```  2086   from decseq_bounded[OF assms] \<open>decseq X\<close> Bseq_monoseq_convergent[of X]
```
```  2087   obtain L where "X \<longlonglongrightarrow> L"
```
```  2088     by (auto simp: convergent_def monoseq_def decseq_def)
```
```  2089   with \<open>decseq X\<close> show "\<exists>L. X \<longlonglongrightarrow> L \<and> (\<forall>i. L \<le> X i)"
```
```  2090     by (auto intro!: exI[of _ L] decseq_le)
```
```  2091 qed
```
```  2092
```
```  2093
```
```  2094 subsection \<open>Power Sequences\<close>
```
```  2095
```
```  2096 text \<open>
```
```  2097   The sequence @{term "x^n"} tends to 0 if @{term "0\<le>x"} and @{term
```
```  2098   "x<1"}.  Proof will use (NS) Cauchy equivalence for convergence and
```
```  2099   also fact that bounded and monotonic sequence converges.
```
```  2100 \<close>
```
```  2101
```
```  2102 lemma Bseq_realpow: "0 \<le> x \<Longrightarrow> x \<le> 1 \<Longrightarrow> Bseq (\<lambda>n. x ^ n)"
```
```  2103   for x :: real
```
```  2104   apply (simp add: Bseq_def)
```
```  2105   apply (rule_tac x = 1 in exI)
```
```  2106   apply (simp add: power_abs)
```
```  2107   apply (auto dest: power_mono)
```
```  2108   done
```
```  2109
```
```  2110 lemma monoseq_realpow: "0 \<le> x \<Longrightarrow> x \<le> 1 \<Longrightarrow> monoseq (\<lambda>n. x ^ n)"
```
```  2111   for x :: real
```
```  2112   apply (clarify intro!: mono_SucI2)
```
```  2113   apply (cut_tac n = n and N = "Suc n" and a = x in power_decreasing)
```
```  2114      apply auto
```
```  2115   done
```
```  2116
```
```  2117 lemma convergent_realpow: "0 \<le> x \<Longrightarrow> x \<le> 1 \<Longrightarrow> convergent (\<lambda>n. x ^ n)"
```
```  2118   for x :: real
```
```  2119   by (blast intro!: Bseq_monoseq_convergent Bseq_realpow monoseq_realpow)
```
```  2120
```
```  2121 lemma LIMSEQ_inverse_realpow_zero: "1 < x \<Longrightarrow> (\<lambda>n. inverse (x ^ n)) \<longlonglongrightarrow> 0"
```
```  2122   for x :: real
```
```  2123   by (rule filterlim_compose[OF tendsto_inverse_0 filterlim_realpow_sequentially_gt1]) simp
```
```  2124
```
```  2125 lemma LIMSEQ_realpow_zero:
```
```  2126   fixes x :: real
```
```  2127   assumes "0 \<le> x" "x < 1"
```
```  2128   shows "(\<lambda>n. x ^ n) \<longlonglongrightarrow> 0"
```
```  2129 proof (cases "x = 0")
```
```  2130   case False
```
```  2131   with \<open>0 \<le> x\<close> have x0: "0 < x" by simp
```
```  2132   then have "1 < inverse x"
```
```  2133     using \<open>x < 1\<close> by (rule one_less_inverse)
```
```  2134   then have "(\<lambda>n. inverse (inverse x ^ n)) \<longlonglongrightarrow> 0"
```
```  2135     by (rule LIMSEQ_inverse_realpow_zero)
```
```  2136   then show ?thesis by (simp add: power_inverse)
```
```  2137 next
```
```  2138   case True
```
```  2139   show ?thesis
```
```  2140     by (rule LIMSEQ_imp_Suc) (simp add: True)
```
```  2141 qed
```
```  2142
```
```  2143 lemma LIMSEQ_power_zero: "norm x < 1 \<Longrightarrow> (\<lambda>n. x ^ n) \<longlonglongrightarrow> 0"
```
```  2144   for x :: "'a::real_normed_algebra_1"
```
```  2145   apply (drule LIMSEQ_realpow_zero [OF norm_ge_zero])
```
```  2146   apply (simp only: tendsto_Zfun_iff, erule Zfun_le)
```
```  2147   apply (simp add: power_abs norm_power_ineq)
```
```  2148   done
```
```  2149
```
```  2150 lemma LIMSEQ_divide_realpow_zero: "1 < x \<Longrightarrow> (\<lambda>n. a / (x ^ n) :: real) \<longlonglongrightarrow> 0"
```
```  2151   by (rule tendsto_divide_0 [OF tendsto_const filterlim_realpow_sequentially_gt1]) simp
```
```  2152
```
```  2153 lemma
```
```  2154   tendsto_power_zero:
```
```  2155   fixes x::"'a::real_normed_algebra_1"
```
```  2156   assumes "filterlim f at_top F"
```
```  2157   assumes "norm x < 1"
```
```  2158   shows "((\<lambda>y. x ^ (f y)) \<longlongrightarrow> 0) F"
```
```  2159 proof (rule tendstoI)
```
```  2160   fix e::real assume "0 < e"
```
```  2161   from tendstoD[OF LIMSEQ_power_zero[OF \<open>norm x < 1\<close>] \<open>0 < e\<close>]
```
```  2162   have "\<forall>\<^sub>F xa in sequentially. norm (x ^ xa) < e"
```
```  2163     by simp
```
```  2164   then obtain N where N: "norm (x ^ n) < e" if "n \<ge> N" for n
```
```  2165     by (auto simp: eventually_sequentially)
```
```  2166   have "\<forall>\<^sub>F i in F. f i \<ge> N"
```
```  2167     using \<open>filterlim f sequentially F\<close>
```
```  2168     by (simp add: filterlim_at_top)
```
```  2169   then show "\<forall>\<^sub>F i in F. dist (x ^ f i) 0 < e"
```
```  2170     by (eventually_elim) (auto simp: N)
```
```  2171 qed
```
```  2172
```
```  2173 text \<open>Limit of @{term "c^n"} for @{term"\<bar>c\<bar> < 1"}.\<close>
```
```  2174
```
```  2175 lemma LIMSEQ_rabs_realpow_zero: "\<bar>c\<bar> < 1 \<Longrightarrow> (\<lambda>n. \<bar>c\<bar> ^ n :: real) \<longlonglongrightarrow> 0"
```
```  2176   by (rule LIMSEQ_realpow_zero [OF abs_ge_zero])
```
```  2177
```
```  2178 lemma LIMSEQ_rabs_realpow_zero2: "\<bar>c\<bar> < 1 \<Longrightarrow> (\<lambda>n. c ^ n :: real) \<longlonglongrightarrow> 0"
```
```  2179   by (rule LIMSEQ_power_zero) simp
```
```  2180
```
```  2181
```
```  2182 subsection \<open>Limits of Functions\<close>
```
```  2183
```
```  2184 lemma LIM_eq: "f \<midarrow>a\<rightarrow> L = (\<forall>r>0. \<exists>s>0. \<forall>x. x \<noteq> a \<and> norm (x - a) < s \<longrightarrow> norm (f x - L) < r)"
```
```  2185   for a :: "'a::real_normed_vector" and L :: "'b::real_normed_vector"
```
```  2186   by (simp add: LIM_def dist_norm)
```
```  2187
```
```  2188 lemma LIM_I:
```
```  2189   "(\<And>r. 0 < r \<Longrightarrow> \<exists>s>0. \<forall>x. x \<noteq> a \<and> norm (x - a) < s \<longrightarrow> norm (f x - L) < r) \<Longrightarrow> f \<midarrow>a\<rightarrow> L"
```
```  2190   for a :: "'a::real_normed_vector" and L :: "'b::real_normed_vector"
```
```  2191   by (simp add: LIM_eq)
```
```  2192
```
```  2193 lemma LIM_D: "f \<midarrow>a\<rightarrow> L \<Longrightarrow> 0 < r \<Longrightarrow> \<exists>s>0.\<forall>x. x \<noteq> a \<and> norm (x - a) < s \<longrightarrow> norm (f x - L) < r"
```
```  2194   for a :: "'a::real_normed_vector" and L :: "'b::real_normed_vector"
```
```  2195   by (simp add: LIM_eq)
```
```  2196
```
```  2197 lemma LIM_offset: "f \<midarrow>a\<rightarrow> L \<Longrightarrow> (\<lambda>x. f (x + k)) \<midarrow>(a - k)\<rightarrow> L"
```
```  2198   for a :: "'a::real_normed_vector"
```
```  2199   by (simp add: filtermap_at_shift[symmetric, of a k] filterlim_def filtermap_filtermap)
```
```  2200
```
```  2201 lemma LIM_offset_zero: "f \<midarrow>a\<rightarrow> L \<Longrightarrow> (\<lambda>h. f (a + h)) \<midarrow>0\<rightarrow> L"
```
```  2202   for a :: "'a::real_normed_vector"
```
```  2203   by (drule LIM_offset [where k = a]) (simp add: add.commute)
```
```  2204
```
```  2205 lemma LIM_offset_zero_cancel: "(\<lambda>h. f (a + h)) \<midarrow>0\<rightarrow> L \<Longrightarrow> f \<midarrow>a\<rightarrow> L"
```
```  2206   for a :: "'a::real_normed_vector"
```
```  2207   by (drule LIM_offset [where k = "- a"]) simp
```
```  2208
```
```  2209 lemma LIM_offset_zero_iff: "f \<midarrow>a\<rightarrow> L \<longleftrightarrow> (\<lambda>h. f (a + h)) \<midarrow>0\<rightarrow> L"
```
```  2210   for f :: "'a :: real_normed_vector \<Rightarrow> _"
```
```  2211   using LIM_offset_zero_cancel[of f a L] LIM_offset_zero[of f L a] by auto
```
```  2212
```
```  2213 lemma LIM_zero: "(f \<longlongrightarrow> l) F \<Longrightarrow> ((\<lambda>x. f x - l) \<longlongrightarrow> 0) F"
```
```  2214   for f :: "'a \<Rightarrow> 'b::real_normed_vector"
```
```  2215   unfolding tendsto_iff dist_norm by simp
```
```  2216
```
```  2217 lemma LIM_zero_cancel:
```
```  2218   fixes f :: "'a \<Rightarrow> 'b::real_normed_vector"
```
```  2219   shows "((\<lambda>x. f x - l) \<longlongrightarrow> 0) F \<Longrightarrow> (f \<longlongrightarrow> l) F"
```
```  2220 unfolding tendsto_iff dist_norm by simp
```
```  2221
```
```  2222 lemma LIM_zero_iff: "((\<lambda>x. f x - l) \<longlongrightarrow> 0) F = (f \<longlongrightarrow> l) F"
```
```  2223   for f :: "'a \<Rightarrow> 'b::real_normed_vector"
```
```  2224   unfolding tendsto_iff dist_norm by simp
```
```  2225
```
```  2226 lemma LIM_imp_LIM:
```
```  2227   fixes f :: "'a::topological_space \<Rightarrow> 'b::real_normed_vector"
```
```  2228   fixes g :: "'a::topological_space \<Rightarrow> 'c::real_normed_vector"
```
```  2229   assumes f: "f \<midarrow>a\<rightarrow> l"
```
```  2230     and le: "\<And>x. x \<noteq> a \<Longrightarrow> norm (g x - m) \<le> norm (f x - l)"
```
```  2231   shows "g \<midarrow>a\<rightarrow> m"
```
```  2232   by (rule metric_LIM_imp_LIM [OF f]) (simp add: dist_norm le)
```
```  2233
```
```  2234 lemma LIM_equal2:
```
```  2235   fixes f g :: "'a::real_normed_vector \<Rightarrow> 'b::topological_space"
```
```  2236   assumes "0 < R"
```
```  2237     and "\<And>x. x \<noteq> a \<Longrightarrow> norm (x - a) < R \<Longrightarrow> f x = g x"
```
```  2238   shows "g \<midarrow>a\<rightarrow> l \<Longrightarrow> f \<midarrow>a\<rightarrow> l"
```
```  2239   by (rule metric_LIM_equal2 [OF assms]) (simp_all add: dist_norm)
```
```  2240
```
```  2241 lemma LIM_compose2:
```
```  2242   fixes a :: "'a::real_normed_vector"
```
```  2243   assumes f: "f \<midarrow>a\<rightarrow> b"
```
```  2244     and g: "g \<midarrow>b\<rightarrow> c"
```
```  2245     and inj: "\<exists>d>0. \<forall>x. x \<noteq> a \<and> norm (x - a) < d \<longrightarrow> f x \<noteq> b"
```
```  2246   shows "(\<lambda>x. g (f x)) \<midarrow>a\<rightarrow> c"
```
```  2247   by (rule metric_LIM_compose2 [OF f g inj [folded dist_norm]])
```
```  2248
```
```  2249 lemma real_LIM_sandwich_zero:
```
```  2250   fixes f g :: "'a::topological_space \<Rightarrow> real"
```
```  2251   assumes f: "f \<midarrow>a\<rightarrow> 0"
```
```  2252     and 1: "\<And>x. x \<noteq> a \<Longrightarrow> 0 \<le> g x"
```
```  2253     and 2: "\<And>x. x \<noteq> a \<Longrightarrow> g x \<le> f x"
```
```  2254   shows "g \<midarrow>a\<rightarrow> 0"
```
```  2255 proof (rule LIM_imp_LIM [OF f]) (* FIXME: use tendsto_sandwich *)
```
```  2256   fix x
```
```  2257   assume x: "x \<noteq> a"
```
```  2258   with 1 have "norm (g x - 0) = g x" by simp
```
```  2259   also have "g x \<le> f x" by (rule 2 [OF x])
```
```  2260   also have "f x \<le> \<bar>f x\<bar>" by (rule abs_ge_self)
```
```  2261   also have "\<bar>f x\<bar> = norm (f x - 0)" by simp
```
```  2262   finally show "norm (g x - 0) \<le> norm (f x - 0)" .
```
```  2263 qed
```
```  2264
```
```  2265
```
```  2266 subsection \<open>Continuity\<close>
```
```  2267
```
```  2268 lemma LIM_isCont_iff: "(f \<midarrow>a\<rightarrow> f a) = ((\<lambda>h. f (a + h)) \<midarrow>0\<rightarrow> f a)"
```
```  2269   for f :: "'a::real_normed_vector \<Rightarrow> 'b::topological_space"
```
```  2270   by (rule iffI [OF LIM_offset_zero LIM_offset_zero_cancel])
```
```  2271
```
```  2272 lemma isCont_iff: "isCont f x = (\<lambda>h. f (x + h)) \<midarrow>0\<rightarrow> f x"
```
```  2273   for f :: "'a::real_normed_vector \<Rightarrow> 'b::topological_space"
```
```  2274   by (simp add: isCont_def LIM_isCont_iff)
```
```  2275
```
```  2276 lemma isCont_LIM_compose2:
```
```  2277   fixes a :: "'a::real_normed_vector"
```
```  2278   assumes f [unfolded isCont_def]: "isCont f a"
```
```  2279     and g: "g \<midarrow>f a\<rightarrow> l"
```
```  2280     and inj: "\<exists>d>0. \<forall>x. x \<noteq> a \<and> norm (x - a) < d \<longrightarrow> f x \<noteq> f a"
```
```  2281   shows "(\<lambda>x. g (f x)) \<midarrow>a\<rightarrow> l"
```
```  2282   by (rule LIM_compose2 [OF f g inj])
```
```  2283
```
```  2284 lemma isCont_norm [simp]: "isCont f a \<Longrightarrow> isCont (\<lambda>x. norm (f x)) a"
```
```  2285   for f :: "'a::t2_space \<Rightarrow> 'b::real_normed_vector"
```
```  2286   by (fact continuous_norm)
```
```  2287
```
```  2288 lemma isCont_rabs [simp]: "isCont f a \<Longrightarrow> isCont (\<lambda>x. \<bar>f x\<bar>) a"
```
```  2289   for f :: "'a::t2_space \<Rightarrow> real"
```
```  2290   by (fact continuous_rabs)
```
```  2291
```
```  2292 lemma isCont_add [simp]: "isCont f a \<Longrightarrow> isCont g a \<Longrightarrow> isCont (\<lambda>x. f x + g x) a"
```
```  2293   for f :: "'a::t2_space \<Rightarrow> 'b::topological_monoid_add"
```
```  2294   by (fact continuous_add)
```
```  2295
```
```  2296 lemma isCont_minus [simp]: "isCont f a \<Longrightarrow> isCont (\<lambda>x. - f x) a"
```
```  2297   for f :: "'a::t2_space \<Rightarrow> 'b::real_normed_vector"
```
```  2298   by (fact continuous_minus)
```
```  2299
```
```  2300 lemma isCont_diff [simp]: "isCont f a \<Longrightarrow> isCont g a \<Longrightarrow> isCont (\<lambda>x. f x - g x) a"
```
```  2301   for f :: "'a::t2_space \<Rightarrow> 'b::real_normed_vector"
```
```  2302   by (fact continuous_diff)
```
```  2303
```
```  2304 lemma isCont_mult [simp]: "isCont f a \<Longrightarrow> isCont g a \<Longrightarrow> isCont (\<lambda>x. f x * g x) a"
```
```  2305   for f g :: "'a::t2_space \<Rightarrow> 'b::real_normed_algebra"
```
```  2306   by (fact continuous_mult)
```
```  2307
```
```  2308 lemma (in bounded_linear) isCont: "isCont g a \<Longrightarrow> isCont (\<lambda>x. f (g x)) a"
```
```  2309   by (fact continuous)
```
```  2310
```
```  2311 lemma (in bounded_bilinear) isCont: "isCont f a \<Longrightarrow> isCont g a \<Longrightarrow> isCont (\<lambda>x. f x ** g x) a"
```
```  2312   by (fact continuous)
```
```  2313
```
```  2314 lemmas isCont_scaleR [simp] =
```
```  2315   bounded_bilinear.isCont [OF bounded_bilinear_scaleR]
```
```  2316
```
```  2317 lemmas isCont_of_real [simp] =
```
```  2318   bounded_linear.isCont [OF bounded_linear_of_real]
```
```  2319
```
```  2320 lemma isCont_power [simp]: "isCont f a \<Longrightarrow> isCont (\<lambda>x. f x ^ n) a"
```
```  2321   for f :: "'a::t2_space \<Rightarrow> 'b::{power,real_normed_algebra}"
```
```  2322   by (fact continuous_power)
```
```  2323
```
```  2324 lemma isCont_sum [simp]: "\<forall>i\<in>A. isCont (f i) a \<Longrightarrow> isCont (\<lambda>x. \<Sum>i\<in>A. f i x) a"
```
```  2325   for f :: "'a \<Rightarrow> 'b::t2_space \<Rightarrow> 'c::topological_comm_monoid_add"
```
```  2326   by (auto intro: continuous_sum)
```
```  2327
```
```  2328
```
```  2329 subsection \<open>Uniform Continuity\<close>
```
```  2330
```
```  2331 lemma uniformly_continuous_on_def:
```
```  2332   fixes f :: "'a::metric_space \<Rightarrow> 'b::metric_space"
```
```  2333   shows "uniformly_continuous_on s f \<longleftrightarrow>
```
```  2334     (\<forall>e>0. \<exists>d>0. \<forall>x\<in>s. \<forall>x'\<in>s. dist x' x < d \<longrightarrow> dist (f x') (f x) < e)"
```
```  2335   unfolding uniformly_continuous_on_uniformity
```
```  2336     uniformity_dist filterlim_INF filterlim_principal eventually_inf_principal
```
```  2337   by (force simp: Ball_def uniformity_dist[symmetric] eventually_uniformity_metric)
```
```  2338
```
```  2339 abbreviation isUCont :: "['a::metric_space \<Rightarrow> 'b::metric_space] \<Rightarrow> bool"
```
```  2340   where "isUCont f \<equiv> uniformly_continuous_on UNIV f"
```
```  2341
```
```  2342 lemma isUCont_def: "isUCont f \<longleftrightarrow> (\<forall>r>0. \<exists>s>0. \<forall>x y. dist x y < s \<longrightarrow> dist (f x) (f y) < r)"
```
```  2343   by (auto simp: uniformly_continuous_on_def dist_commute)
```
```  2344
```
```  2345 lemma isUCont_isCont: "isUCont f \<Longrightarrow> isCont f x"
```
```  2346   by (drule uniformly_continuous_imp_continuous) (simp add: continuous_on_eq_continuous_at)
```
```  2347
```
```  2348 lemma uniformly_continuous_on_Cauchy:
```
```  2349   fixes f :: "'a::metric_space \<Rightarrow> 'b::metric_space"
```
```  2350   assumes "uniformly_continuous_on S f" "Cauchy X" "\<And>n. X n \<in> S"
```
```  2351   shows "Cauchy (\<lambda>n. f (X n))"
```
```  2352   using assms
```
```  2353   apply (simp only: uniformly_continuous_on_def)
```
```  2354   apply (rule metric_CauchyI)
```
```  2355   apply (drule_tac x=e in spec)
```
```  2356   apply safe
```
```  2357   apply (drule_tac e=d in metric_CauchyD)
```
```  2358    apply safe
```
```  2359   apply (rule_tac x=M in exI)
```
```  2360   apply simp
```
```  2361   done
```
```  2362
```
```  2363 lemma isUCont_Cauchy: "isUCont f \<Longrightarrow> Cauchy X \<Longrightarrow> Cauchy (\<lambda>n. f (X n))"
```
```  2364   by (rule uniformly_continuous_on_Cauchy[where S=UNIV and f=f]) simp_all
```
```  2365
```
```  2366 lemma uniformly_continuous_imp_Cauchy_continuous:
```
```  2367   fixes f :: "'a::metric_space \<Rightarrow> 'b::metric_space"
```
```  2368   shows "\<lbrakk>uniformly_continuous_on S f; Cauchy \<sigma>; \<And>n. (\<sigma> n) \<in> S\<rbrakk> \<Longrightarrow> Cauchy(f o \<sigma>)"
```
```  2369   by (simp add: uniformly_continuous_on_def Cauchy_def) meson
```
```  2370
```
```  2371 lemma (in bounded_linear) isUCont: "isUCont f"
```
```  2372   unfolding isUCont_def dist_norm
```
```  2373 proof (intro allI impI)
```
```  2374   fix r :: real
```
```  2375   assume r: "0 < r"
```
```  2376   obtain K where K: "0 < K" and norm_le: "norm (f x) \<le> norm x * K" for x
```
```  2377     using pos_bounded by blast
```
```  2378   show "\<exists>s>0. \<forall>x y. norm (x - y) < s \<longrightarrow> norm (f x - f y) < r"
```
```  2379   proof (rule exI, safe)
```
```  2380     from r K show "0 < r / K" by simp
```
```  2381   next
```
```  2382     fix x y :: 'a
```
```  2383     assume xy: "norm (x - y) < r / K"
```
```  2384     have "norm (f x - f y) = norm (f (x - y))" by (simp only: diff)
```
```  2385     also have "\<dots> \<le> norm (x - y) * K" by (rule norm_le)
```
```  2386     also from K xy have "\<dots> < r" by (simp only: pos_less_divide_eq)
```
```  2387     finally show "norm (f x - f y) < r" .
```
```  2388   qed
```
```  2389 qed
```
```  2390
```
```  2391 lemma (in bounded_linear) Cauchy: "Cauchy X \<Longrightarrow> Cauchy (\<lambda>n. f (X n))"
```
```  2392   by (rule isUCont [THEN isUCont_Cauchy])
```
```  2393
```
```  2394 lemma LIM_less_bound:
```
```  2395   fixes f :: "real \<Rightarrow> real"
```
```  2396   assumes ev: "b < x" "\<forall> x' \<in> { b <..< x}. 0 \<le> f x'" and "isCont f x"
```
```  2397   shows "0 \<le> f x"
```
```  2398 proof (rule tendsto_lowerbound)
```
```  2399   show "(f \<longlongrightarrow> f x) (at_left x)"
```
```  2400     using \<open>isCont f x\<close> by (simp add: filterlim_at_split isCont_def)
```
```  2401   show "eventually (\<lambda>x. 0 \<le> f x) (at_left x)"
```
```  2402     using ev by (auto simp: eventually_at dist_real_def intro!: exI[of _ "x - b"])
```
```  2403 qed simp
```
```  2404
```
```  2405
```
```  2406 subsection \<open>Nested Intervals and Bisection -- Needed for Compactness\<close>
```
```  2407
```
```  2408 lemma nested_sequence_unique:
```
```  2409   assumes "\<forall>n. f n \<le> f (Suc n)" "\<forall>n. g (Suc n) \<le> g n" "\<forall>n. f n \<le> g n" "(\<lambda>n. f n - g n) \<longlonglongrightarrow> 0"
```
```  2410   shows "\<exists>l::real. ((\<forall>n. f n \<le> l) \<and> f \<longlonglongrightarrow> l) \<and> ((\<forall>n. l \<le> g n) \<and> g \<longlonglongrightarrow> l)"
```
```  2411 proof -
```
```  2412   have "incseq f" unfolding incseq_Suc_iff by fact
```
```  2413   have "decseq g" unfolding decseq_Suc_iff by fact
```
```  2414   have "f n \<le> g 0" for n
```
```  2415   proof -
```
```  2416     from \<open>decseq g\<close> have "g n \<le> g 0"
```
```  2417       by (rule decseqD) simp
```
```  2418     with \<open>\<forall>n. f n \<le> g n\<close>[THEN spec, of n] show ?thesis
```
```  2419       by auto
```
```  2420   qed
```
```  2421   then obtain u where "f \<longlonglongrightarrow> u" "\<forall>i. f i \<le> u"
```
```  2422     using incseq_convergent[OF \<open>incseq f\<close>] by auto
```
```  2423   moreover have "f 0 \<le> g n" for n
```
```  2424   proof -
```
```  2425     from \<open>incseq f\<close> have "f 0 \<le> f n" by (rule incseqD) simp
```
```  2426     with \<open>\<forall>n. f n \<le> g n\<close>[THEN spec, of n] show ?thesis
```
```  2427       by simp
```
```  2428   qed
```
```  2429   then obtain l where "g \<longlonglongrightarrow> l" "\<forall>i. l \<le> g i"
```
```  2430     using decseq_convergent[OF \<open>decseq g\<close>] by auto
```
```  2431   moreover note LIMSEQ_unique[OF assms(4) tendsto_diff[OF \<open>f \<longlonglongrightarrow> u\<close> \<open>g \<longlonglongrightarrow> l\<close>]]
```
```  2432   ultimately show ?thesis by auto
```
```  2433 qed
```
```  2434
```
```  2435 lemma Bolzano[consumes 1, case_names trans local]:
```
```  2436   fixes P :: "real \<Rightarrow> real \<Rightarrow> bool"
```
```  2437   assumes [arith]: "a \<le> b"
```
```  2438     and trans: "\<And>a b c. P a b \<Longrightarrow> P b c \<Longrightarrow> a \<le> b \<Longrightarrow> b \<le> c \<Longrightarrow> P a c"
```
```  2439     and local: "\<And>x. a \<le> x \<Longrightarrow> x \<le> b \<Longrightarrow> \<exists>d>0. \<forall>a b. a \<le> x \<and> x \<le> b \<and> b - a < d \<longrightarrow> P a b"
```
```  2440   shows "P a b"
```
```  2441 proof -
```
```  2442   define bisect where "bisect =
```
```  2443     rec_nat (a, b) (\<lambda>n (x, y). if P x ((x+y) / 2) then ((x+y)/2, y) else (x, (x+y)/2))"
```
```  2444   define l u where "l n = fst (bisect n)" and "u n = snd (bisect n)" for n
```
```  2445   have l[simp]: "l 0 = a" "\<And>n. l (Suc n) = (if P (l n) ((l n + u n) / 2) then (l n + u n) / 2 else l n)"
```
```  2446     and u[simp]: "u 0 = b" "\<And>n. u (Suc n) = (if P (l n) ((l n + u n) / 2) then u n else (l n + u n) / 2)"
```
```  2447     by (simp_all add: l_def u_def bisect_def split: prod.split)
```
```  2448
```
```  2449   have [simp]: "l n \<le> u n" for n by (induct n) auto
```
```  2450
```
```  2451   have "\<exists>x. ((\<forall>n. l n \<le> x) \<and> l \<longlonglongrightarrow> x) \<and> ((\<forall>n. x \<le> u n) \<and> u \<longlonglongrightarrow> x)"
```
```  2452   proof (safe intro!: nested_sequence_unique)
```
```  2453     show "l n \<le> l (Suc n)" "u (Suc n) \<le> u n" for n
```
```  2454       by (induct n) auto
```
```  2455   next
```
```  2456     have "l n - u n = (a - b) / 2^n" for n
```
```  2457       by (induct n) (auto simp: field_simps)
```
```  2458     then show "(\<lambda>n. l n - u n) \<longlonglongrightarrow> 0"
```
```  2459       by (simp add: LIMSEQ_divide_realpow_zero)
```
```  2460   qed fact
```
```  2461   then obtain x where x: "\<And>n. l n \<le> x" "\<And>n. x \<le> u n" and "l \<longlonglongrightarrow> x" "u \<longlonglongrightarrow> x"
```
```  2462     by auto
```
```  2463   obtain d where "0 < d" and d: "a \<le> x \<Longrightarrow> x \<le> b \<Longrightarrow> b - a < d \<Longrightarrow> P a b" for a b
```
```  2464     using \<open>l 0 \<le> x\<close> \<open>x \<le> u 0\<close> local[of x] by auto
```
```  2465
```
```  2466   show "P a b"
```
```  2467   proof (rule ccontr)
```
```  2468     assume "\<not> P a b"
```
```  2469     have "\<not> P (l n) (u n)" for n
```
```  2470     proof (induct n)
```
```  2471       case 0
```
```  2472       then show ?case
```
```  2473         by (simp add: \<open>\<not> P a b\<close>)
```
```  2474     next
```
```  2475       case (Suc n)
```
```  2476       with trans[of "l n" "(l n + u n) / 2" "u n"] show ?case
```
```  2477         by auto
```
```  2478     qed
```
```  2479     moreover
```
```  2480     {
```
```  2481       have "eventually (\<lambda>n. x - d / 2 < l n) sequentially"
```
```  2482         using \<open>0 < d\<close> \<open>l \<longlonglongrightarrow> x\<close> by (intro order_tendstoD[of _ x]) auto
```
```  2483       moreover have "eventually (\<lambda>n. u n < x + d / 2) sequentially"
```
```  2484         using \<open>0 < d\<close> \<open>u \<longlonglongrightarrow> x\<close> by (intro order_tendstoD[of _ x]) auto
```
```  2485       ultimately have "eventually (\<lambda>n. P (l n) (u n)) sequentially"
```
```  2486       proof eventually_elim
```
```  2487         case (elim n)
```
```  2488         from add_strict_mono[OF this] have "u n - l n < d" by simp
```
```  2489         with x show "P (l n) (u n)" by (rule d)
```
```  2490       qed
```
```  2491     }
```
```  2492     ultimately show False by simp
```
```  2493   qed
```
```  2494 qed
```
```  2495
```
```  2496 lemma compact_Icc[simp, intro]: "compact {a .. b::real}"
```
```  2497 proof (cases "a \<le> b", rule compactI)
```
```  2498   fix C
```
```  2499   assume C: "a \<le> b" "\<forall>t\<in>C. open t" "{a..b} \<subseteq> \<Union>C"
```
```  2500   define T where "T = {a .. b}"
```
```  2501   from C(1,3) show "\<exists>C'\<subseteq>C. finite C' \<and> {a..b} \<subseteq> \<Union>C'"
```
```  2502   proof (induct rule: Bolzano)
```
```  2503     case (trans a b c)
```
```  2504     then have *: "{a..c} = {a..b} \<union> {b..c}"
```
```  2505       by auto
```
```  2506     with trans obtain C1 C2
```
```  2507       where "C1\<subseteq>C" "finite C1" "{a..b} \<subseteq> \<Union>C1" "C2\<subseteq>C" "finite C2" "{b..c} \<subseteq> \<Union>C2"
```
```  2508       by auto
```
```  2509     with trans show ?case
```
```  2510       unfolding * by (intro exI[of _ "C1 \<union> C2"]) auto
```
```  2511   next
```
```  2512     case (local x)
```
```  2513     with C have "x \<in> \<Union>C" by auto
```
```  2514     with C(2) obtain c where "x \<in> c" "open c" "c \<in> C"
```
```  2515       by auto
```
```  2516     then obtain e where "0 < e" "{x - e <..< x + e} \<subseteq> c"
```
```  2517       by (auto simp: open_dist dist_real_def subset_eq Ball_def abs_less_iff)
```
```  2518     with \<open>c \<in> C\<close> show ?case
```
```  2519       by (safe intro!: exI[of _ "e/2"] exI[of _ "{c}"]) auto
```
```  2520   qed
```
```  2521 qed simp
```
```  2522
```
```  2523
```
```  2524 lemma continuous_image_closed_interval:
```
```  2525   fixes a b and f :: "real \<Rightarrow> real"
```
```  2526   defines "S \<equiv> {a..b}"
```
```  2527   assumes "a \<le> b" and f: "continuous_on S f"
```
```  2528   shows "\<exists>c d. f`S = {c..d} \<and> c \<le> d"
```
```  2529 proof -
```
```  2530   have S: "compact S" "S \<noteq> {}"
```
```  2531     using \<open>a \<le> b\<close> by (auto simp: S_def)
```
```  2532   obtain c where "c \<in> S" "\<forall>d\<in>S. f d \<le> f c"
```
```  2533     using continuous_attains_sup[OF S f] by auto
```
```  2534   moreover obtain d where "d \<in> S" "\<forall>c\<in>S. f d \<le> f c"
```
```  2535     using continuous_attains_inf[OF S f] by auto
```
```  2536   moreover have "connected (f`S)"
```
```  2537     using connected_continuous_image[OF f] connected_Icc by (auto simp: S_def)
```
```  2538   ultimately have "f ` S = {f d .. f c} \<and> f d \<le> f c"
```
```  2539     by (auto simp: connected_iff_interval)
```
```  2540   then show ?thesis
```
```  2541     by auto
```
```  2542 qed
```
```  2543
```
```  2544 lemma open_Collect_positive:
```
```  2545   fixes f :: "'a::t2_space \<Rightarrow> real"
```
```  2546   assumes f: "continuous_on s f"
```
```  2547   shows "\<exists>A. open A \<and> A \<inter> s = {x\<in>s. 0 < f x}"
```
```  2548   using continuous_on_open_invariant[THEN iffD1, OF f, rule_format, of "{0 <..}"]
```
```  2549   by (auto simp: Int_def field_simps)
```
```  2550
```
```  2551 lemma open_Collect_less_Int:
```
```  2552   fixes f g :: "'a::t2_space \<Rightarrow> real"
```
```  2553   assumes f: "continuous_on s f"
```
```  2554     and g: "continuous_on s g"
```
```  2555   shows "\<exists>A. open A \<and> A \<inter> s = {x\<in>s. f x < g x}"
```
```  2556   using open_Collect_positive[OF continuous_on_diff[OF g f]] by (simp add: field_simps)
```
```  2557
```
```  2558
```
```  2559 subsection \<open>Boundedness of continuous functions\<close>
```
```  2560
```
```  2561 text\<open>By bisection, function continuous on closed interval is bounded above\<close>
```
```  2562
```
```  2563 lemma isCont_eq_Ub:
```
```  2564   fixes f :: "real \<Rightarrow> 'a::linorder_topology"
```
```  2565   shows "a \<le> b \<Longrightarrow> \<forall>x::real. a \<le> x \<and> x \<le> b \<longrightarrow> isCont f x \<Longrightarrow>
```
```  2566     \<exists>M. (\<forall>x. a \<le> x \<and> x \<le> b \<longrightarrow> f x \<le> M) \<and> (\<exists>x. a \<le> x \<and> x \<le> b \<and> f x = M)"
```
```  2567   using continuous_attains_sup[of "{a..b}" f]
```
```  2568   by (auto simp add: continuous_at_imp_continuous_on Ball_def Bex_def)
```
```  2569
```
```  2570 lemma isCont_eq_Lb:
```
```  2571   fixes f :: "real \<Rightarrow> 'a::linorder_topology"
```
```  2572   shows "a \<le> b \<Longrightarrow> \<forall>x. a \<le> x \<and> x \<le> b \<longrightarrow> isCont f x \<Longrightarrow>
```
```  2573     \<exists>M. (\<forall>x. a \<le> x \<and> x \<le> b \<longrightarrow> M \<le> f x) \<and> (\<exists>x. a \<le> x \<and> x \<le> b \<and> f x = M)"
```
```  2574   using continuous_attains_inf[of "{a..b}" f]
```
```  2575   by (auto simp add: continuous_at_imp_continuous_on Ball_def Bex_def)
```
```  2576
```
```  2577 lemma isCont_bounded:
```
```  2578   fixes f :: "real \<Rightarrow> 'a::linorder_topology"
```
```  2579   shows "a \<le> b \<Longrightarrow> \<forall>x. a \<le> x \<and> x \<le> b \<longrightarrow> isCont f x \<Longrightarrow> \<exists>M. \<forall>x. a \<le> x \<and> x \<le> b \<longrightarrow> f x \<le> M"
```
```  2580   using isCont_eq_Ub[of a b f] by auto
```
```  2581
```
```  2582 lemma isCont_has_Ub:
```
```  2583   fixes f :: "real \<Rightarrow> 'a::linorder_topology"
```
```  2584   shows "a \<le> b \<Longrightarrow> \<forall>x. a \<le> x \<and> x \<le> b \<longrightarrow> isCont f x \<Longrightarrow>
```
```  2585     \<exists>M. (\<forall>x. a \<le> x \<and> x \<le> b \<longrightarrow> f x \<le> M) \<and> (\<forall>N. N < M \<longrightarrow> (\<exists>x. a \<le> x \<and> x \<le> b \<and> N < f x))"
```
```  2586   using isCont_eq_Ub[of a b f] by auto
```
```  2587
```
```  2588 (*HOL style here: object-level formulations*)
```
```  2589 lemma IVT_objl:
```
```  2590   "(f a \<le> y \<and> y \<le> f b \<and> a \<le> b \<and> (\<forall>x. a \<le> x \<and> x \<le> b \<longrightarrow> isCont f x)) \<longrightarrow>
```
```  2591     (\<exists>x. a \<le> x \<and> x \<le> b \<and> f x = y)"
```
```  2592   for a y :: real
```
```  2593   by (blast intro: IVT)
```
```  2594
```
```  2595 lemma IVT2_objl:
```
```  2596   "(f b \<le> y \<and> y \<le> f a \<and> a \<le> b \<and> (\<forall>x. a \<le> x \<and> x \<le> b \<longrightarrow> isCont f x)) \<longrightarrow>
```
```  2597     (\<exists>x. a \<le> x \<and> x \<le> b \<and> f x = y)"
```
```  2598   for b y :: real
```
```  2599   by (blast intro: IVT2)
```
```  2600
```
```  2601 lemma isCont_Lb_Ub:
```
```  2602   fixes f :: "real \<Rightarrow> real"
```
```  2603   assumes "a \<le> b" "\<forall>x. a \<le> x \<and> x \<le> b \<longrightarrow> isCont f x"
```
```  2604   shows "\<exists>L M. (\<forall>x. a \<le> x \<and> x \<le> b \<longrightarrow> L \<le> f x \<and> f x \<le> M) \<and>
```
```  2605     (\<forall>y. L \<le> y \<and> y \<le> M \<longrightarrow> (\<exists>x. a \<le> x \<and> x \<le> b \<and> (f x = y)))"
```
```  2606 proof -
```
```  2607   obtain M where M: "a \<le> M" "M \<le> b" "\<forall>x. a \<le> x \<and> x \<le> b \<longrightarrow> f x \<le> f M"
```
```  2608     using isCont_eq_Ub[OF assms] by auto
```
```  2609   obtain L where L: "a \<le> L" "L \<le> b" "\<forall>x. a \<le> x \<and> x \<le> b \<longrightarrow> f L \<le> f x"
```
```  2610     using isCont_eq_Lb[OF assms] by auto
```
```  2611   show ?thesis
```
```  2612     using IVT[of f L _ M] IVT2[of f L _ M] M L assms
```
```  2613     apply (rule_tac x="f L" in exI)
```
```  2614     apply (rule_tac x="f M" in exI)
```
```  2615     apply (cases "L \<le> M")
```
```  2616      apply simp
```
```  2617      apply (metis order_trans)
```
```  2618     apply simp
```
```  2619     apply (metis order_trans)
```
```  2620     done
```
```  2621 qed
```
```  2622
```
```  2623
```
```  2624 text \<open>Continuity of inverse function.\<close>
```
```  2625
```
```  2626 lemma isCont_inverse_function:
```
```  2627   fixes f g :: "real \<Rightarrow> real"
```
```  2628   assumes d: "0 < d"
```
```  2629     and inj: "\<forall>z. \<bar>z-x\<bar> \<le> d \<longrightarrow> g (f z) = z"
```
```  2630     and cont: "\<forall>z. \<bar>z-x\<bar> \<le> d \<longrightarrow> isCont f z"
```
```  2631   shows "isCont g (f x)"
```
```  2632 proof -
```
```  2633   let ?A = "f (x - d)"
```
```  2634   let ?B = "f (x + d)"
```
```  2635   let ?D = "{x - d..x + d}"
```
```  2636
```
```  2637   have f: "continuous_on ?D f"
```
```  2638     using cont by (intro continuous_at_imp_continuous_on ballI) auto
```
```  2639   then have g: "continuous_on (f`?D) g"
```
```  2640     using inj by (intro continuous_on_inv) auto
```
```  2641
```
```  2642   from d f have "{min ?A ?B <..< max ?A ?B} \<subseteq> f ` ?D"
```
```  2643     by (intro connected_contains_Ioo connected_continuous_image) (auto split: split_min split_max)
```
```  2644   with g have "continuous_on {min ?A ?B <..< max ?A ?B} g"
```
```  2645     by (rule continuous_on_subset)
```
```  2646   moreover
```
```  2647   have "(?A < f x \<and> f x < ?B) \<or> (?B < f x \<and> f x < ?A)"
```
```  2648     using d inj by (intro continuous_inj_imp_mono[OF _ _ f] inj_on_imageI2[of g, OF inj_onI]) auto
```
```  2649   then have "f x \<in> {min ?A ?B <..< max ?A ?B}"
```
```  2650     by auto
```
```  2651   ultimately
```
```  2652   show ?thesis
```
```  2653     by (simp add: continuous_on_eq_continuous_at)
```
```  2654 qed
```
```  2655
```
```  2656 lemma isCont_inverse_function2:
```
```  2657   fixes f g :: "real \<Rightarrow> real"
```
```  2658   shows
```
```  2659     "a < x \<Longrightarrow> x < b \<Longrightarrow>
```
```  2660       \<forall>z. a \<le> z \<and> z \<le> b \<longrightarrow> g (f z) = z \<Longrightarrow>
```
```  2661       \<forall>z. a \<le> z \<and> z \<le> b \<longrightarrow> isCont f z \<Longrightarrow> isCont g (f x)"
```
```  2662   apply (rule isCont_inverse_function [where f=f and d="min (x - a) (b - x)"])
```
```  2663   apply (simp_all add: abs_le_iff)
```
```  2664   done
```
```  2665
```
```  2666 (* need to rename second isCont_inverse *)
```
```  2667 lemma isCont_inv_fun:
```
```  2668   fixes f g :: "real \<Rightarrow> real"
```
```  2669   shows "0 < d \<Longrightarrow> (\<forall>z. \<bar>z - x\<bar> \<le> d \<longrightarrow> g (f z) = z) \<Longrightarrow>
```
```  2670     \<forall>z. \<bar>z - x\<bar> \<le> d \<longrightarrow> isCont f z \<Longrightarrow> isCont g (f x)"
```
```  2671   by (rule isCont_inverse_function)
```
```  2672
```
```  2673 text \<open>Bartle/Sherbert: Introduction to Real Analysis, Theorem 4.2.9, p. 110.\<close>
```
```  2674 lemma LIM_fun_gt_zero: "f \<midarrow>c\<rightarrow> l \<Longrightarrow> 0 < l \<Longrightarrow> \<exists>r. 0 < r \<and> (\<forall>x. x \<noteq> c \<and> \<bar>c - x\<bar> < r \<longrightarrow> 0 < f x)"
```
```  2675   for f :: "real \<Rightarrow> real"
```
```  2676   apply (drule (1) LIM_D)
```
```  2677   apply clarify
```
```  2678   apply (rule_tac x = s in exI)
```
```  2679   apply (simp add: abs_less_iff)
```
```  2680   done
```
```  2681
```
```  2682 lemma LIM_fun_less_zero: "f \<midarrow>c\<rightarrow> l \<Longrightarrow> l < 0 \<Longrightarrow> \<exists>r. 0 < r \<and> (\<forall>x. x \<noteq> c \<and> \<bar>c - x\<bar> < r \<longrightarrow> f x < 0)"
```
```  2683   for f :: "real \<Rightarrow> real"
```
```  2684   apply (drule LIM_D [where r="-l"])
```
```  2685    apply simp
```
```  2686   apply clarify
```
```  2687   apply (rule_tac x = s in exI)
```
```  2688   apply (simp add: abs_less_iff)
```
```  2689   done
```
```  2690
```
```  2691 lemma LIM_fun_not_zero: "f \<midarrow>c\<rightarrow> l \<Longrightarrow> l \<noteq> 0 \<Longrightarrow> \<exists>r. 0 < r \<and> (\<forall>x. x \<noteq> c \<and> \<bar>c - x\<bar> < r \<longrightarrow> f x \<noteq> 0)"
```
```  2692   for f :: "real \<Rightarrow> real"
```
```  2693   using LIM_fun_gt_zero[of f l c] LIM_fun_less_zero[of f l c] by (auto simp add: neq_iff)
```
```  2694
```
```  2695 end
```