src/HOL/Library/Binomial.thy
author huffman
Thu Jun 11 09:03:24 2009 -0700 (2009-06-11)
changeset 31563 ded2364d14d4
parent 31287 6c593b431f04
child 32042 df28ead1cf19
child 32158 4dc119d4fc8b
permissions -rw-r--r--
cleaned up some proofs
     1 (*  Title:      HOL/Binomial.thy
     2     Author:     Lawrence C Paulson, Amine Chaieb
     3     Copyright   1997  University of Cambridge
     4 *)
     5 
     6 header {* Binomial Coefficients *}
     7 
     8 theory Binomial
     9 imports Fact SetInterval Presburger Main Rational
    10 begin
    11 
    12 text {* This development is based on the work of Andy Gordon and
    13   Florian Kammueller. *}
    14 
    15 primrec binomial :: "nat \<Rightarrow> nat \<Rightarrow> nat" (infixl "choose" 65) where
    16   binomial_0: "(0 choose k) = (if k = 0 then 1 else 0)"
    17   | binomial_Suc: "(Suc n choose k) =
    18                  (if k = 0 then 1 else (n choose (k - 1)) + (n choose k))"
    19 
    20 lemma binomial_n_0 [simp]: "(n choose 0) = 1"
    21 by (cases n) simp_all
    22 
    23 lemma binomial_0_Suc [simp]: "(0 choose Suc k) = 0"
    24 by simp
    25 
    26 lemma binomial_Suc_Suc [simp]:
    27   "(Suc n choose Suc k) = (n choose k) + (n choose Suc k)"
    28 by simp
    29 
    30 lemma binomial_eq_0: "!!k. n < k ==> (n choose k) = 0"
    31 by (induct n) auto
    32 
    33 declare binomial_0 [simp del] binomial_Suc [simp del]
    34 
    35 lemma binomial_n_n [simp]: "(n choose n) = 1"
    36 by (induct n) (simp_all add: binomial_eq_0)
    37 
    38 lemma binomial_Suc_n [simp]: "(Suc n choose n) = Suc n"
    39 by (induct n) simp_all
    40 
    41 lemma binomial_1 [simp]: "(n choose Suc 0) = n"
    42 by (induct n) simp_all
    43 
    44 lemma zero_less_binomial: "k \<le> n ==> (n choose k) > 0"
    45 by (induct n k rule: diff_induct) simp_all
    46 
    47 lemma binomial_eq_0_iff: "(n choose k = 0) = (n<k)"
    48 apply (safe intro!: binomial_eq_0)
    49 apply (erule contrapos_pp)
    50 apply (simp add: zero_less_binomial)
    51 done
    52 
    53 lemma zero_less_binomial_iff: "(n choose k > 0) = (k\<le>n)"
    54 by(simp add: linorder_not_less binomial_eq_0_iff neq0_conv[symmetric]
    55         del:neq0_conv)
    56 
    57 (*Might be more useful if re-oriented*)
    58 lemma Suc_times_binomial_eq:
    59   "!!k. k \<le> n ==> Suc n * (n choose k) = (Suc n choose Suc k) * Suc k"
    60 apply (induct n)
    61 apply (simp add: binomial_0)
    62 apply (case_tac k)
    63 apply (auto simp add: add_mult_distrib add_mult_distrib2 le_Suc_eq
    64     binomial_eq_0)
    65 done
    66 
    67 text{*This is the well-known version, but it's harder to use because of the
    68   need to reason about division.*}
    69 lemma binomial_Suc_Suc_eq_times:
    70     "k \<le> n ==> (Suc n choose Suc k) = (Suc n * (n choose k)) div Suc k"
    71   by (simp add: Suc_times_binomial_eq div_mult_self_is_m zero_less_Suc
    72     del: mult_Suc mult_Suc_right)
    73 
    74 text{*Another version, with -1 instead of Suc.*}
    75 lemma times_binomial_minus1_eq:
    76     "[|k \<le> n;  0<k|] ==> (n choose k) * k = n * ((n - 1) choose (k - 1))"
    77   apply (cut_tac n = "n - 1" and k = "k - 1" in Suc_times_binomial_eq)
    78   apply (simp split add: nat_diff_split, auto)
    79   done
    80 
    81 
    82 subsection {* Theorems about @{text "choose"} *}
    83 
    84 text {*
    85   \medskip Basic theorem about @{text "choose"}.  By Florian
    86   Kamm\"uller, tidied by LCP.
    87 *}
    88 
    89 lemma card_s_0_eq_empty:
    90     "finite A ==> card {B. B \<subseteq> A & card B = 0} = 1"
    91 by (simp cong add: conj_cong add: finite_subset [THEN card_0_eq])
    92 
    93 lemma choose_deconstruct: "finite M ==> x \<notin> M
    94   ==> {s. s <= insert x M & card(s) = Suc k}
    95        = {s. s <= M & card(s) = Suc k} Un
    96          {s. EX t. t <= M & card(t) = k & s = insert x t}"
    97   apply safe
    98    apply (auto intro: finite_subset [THEN card_insert_disjoint])
    99   apply (drule_tac x = "xa - {x}" in spec)
   100   apply (subgoal_tac "x \<notin> xa", auto)
   101   apply (erule rev_mp, subst card_Diff_singleton)
   102   apply (auto intro: finite_subset)
   103   done
   104 (*
   105 lemma "finite(UN y. {x. P x y})"
   106 apply simp
   107 lemma Collect_ex_eq
   108 
   109 lemma "{x. EX y. P x y} = (UN y. {x. P x y})"
   110 apply blast
   111 *)
   112 
   113 lemma finite_bex_subset[simp]:
   114   "finite B \<Longrightarrow> (!!A. A<=B \<Longrightarrow> finite{x. P x A}) \<Longrightarrow> finite{x. EX A<=B. P x A}"
   115 apply(subgoal_tac "{x. EX A<=B. P x A} = (UN A:Pow B. {x. P x A})")
   116  apply simp
   117 apply blast
   118 done
   119 
   120 text{*There are as many subsets of @{term A} having cardinality @{term k}
   121  as there are sets obtained from the former by inserting a fixed element
   122  @{term x} into each.*}
   123 lemma constr_bij:
   124    "[|finite A; x \<notin> A|] ==>
   125     card {B. EX C. C <= A & card(C) = k & B = insert x C} =
   126     card {B. B <= A & card(B) = k}"
   127 apply (rule_tac f = "%s. s - {x}" and g = "insert x" in card_bij_eq)
   128      apply (auto elim!: equalityE simp add: inj_on_def)
   129 apply (subst Diff_insert0, auto)
   130 done
   131 
   132 text {*
   133   Main theorem: combinatorial statement about number of subsets of a set.
   134 *}
   135 
   136 lemma n_sub_lemma:
   137     "!!A. finite A ==> card {B. B <= A & card B = k} = (card A choose k)"
   138   apply (induct k)
   139    apply (simp add: card_s_0_eq_empty, atomize)
   140   apply (rotate_tac -1, erule finite_induct)
   141    apply (simp_all (no_asm_simp) cong add: conj_cong
   142      add: card_s_0_eq_empty choose_deconstruct)
   143   apply (subst card_Un_disjoint)
   144      prefer 4 apply (force simp add: constr_bij)
   145     prefer 3 apply force
   146    prefer 2 apply (blast intro: finite_Pow_iff [THEN iffD2]
   147      finite_subset [of _ "Pow (insert x F)", standard])
   148   apply (blast intro: finite_Pow_iff [THEN iffD2, THEN [2] finite_subset])
   149   done
   150 
   151 theorem n_subsets:
   152     "finite A ==> card {B. B <= A & card B = k} = (card A choose k)"
   153   by (simp add: n_sub_lemma)
   154 
   155 
   156 text{* The binomial theorem (courtesy of Tobias Nipkow): *}
   157 
   158 theorem binomial: "(a+b::nat)^n = (\<Sum>k=0..n. (n choose k) * a^k * b^(n-k))"
   159 proof (induct n)
   160   case 0 thus ?case by simp
   161 next
   162   case (Suc n)
   163   have decomp: "{0..n+1} = {0} \<union> {n+1} \<union> {1..n}"
   164     by (auto simp add:atLeastAtMost_def atLeast_def atMost_def)
   165   have decomp2: "{0..n} = {0} \<union> {1..n}"
   166     by (auto simp add:atLeastAtMost_def atLeast_def atMost_def)
   167   have "(a+b::nat)^(n+1) = (a+b) * (\<Sum>k=0..n. (n choose k) * a^k * b^(n-k))"
   168     using Suc by simp
   169   also have "\<dots> =  a*(\<Sum>k=0..n. (n choose k) * a^k * b^(n-k)) +
   170                    b*(\<Sum>k=0..n. (n choose k) * a^k * b^(n-k))"
   171     by (rule nat_distrib)
   172   also have "\<dots> = (\<Sum>k=0..n. (n choose k) * a^(k+1) * b^(n-k)) +
   173                   (\<Sum>k=0..n. (n choose k) * a^k * b^(n-k+1))"
   174     by (simp add: setsum_right_distrib mult_ac)
   175   also have "\<dots> = (\<Sum>k=0..n. (n choose k) * a^k * b^(n+1-k)) +
   176                   (\<Sum>k=1..n+1. (n choose (k - 1)) * a^k * b^(n+1-k))"
   177     by (simp add:setsum_shift_bounds_cl_Suc_ivl Suc_diff_le
   178              del:setsum_cl_ivl_Suc)
   179   also have "\<dots> = a^(n+1) + b^(n+1) +
   180                   (\<Sum>k=1..n. (n choose (k - 1)) * a^k * b^(n+1-k)) +
   181                   (\<Sum>k=1..n. (n choose k) * a^k * b^(n+1-k))"
   182     by (simp add: decomp2)
   183   also have
   184       "\<dots> = a^(n+1) + b^(n+1) + (\<Sum>k=1..n. (n+1 choose k) * a^k * b^(n+1-k))"
   185     by (simp add: nat_distrib setsum_addf binomial.simps)
   186   also have "\<dots> = (\<Sum>k=0..n+1. (n+1 choose k) * a^k * b^(n+1-k))"
   187     using decomp by simp
   188   finally show ?case by simp
   189 qed
   190 
   191 subsection{* Pochhammer's symbol : generalized raising factorial*}
   192 
   193 definition "pochhammer (a::'a::comm_semiring_1) n = (if n = 0 then 1 else setprod (\<lambda>n. a + of_nat n) {0 .. n - 1})"
   194 
   195 lemma pochhammer_0[simp]: "pochhammer a 0 = 1" 
   196   by (simp add: pochhammer_def)
   197 
   198 lemma pochhammer_1[simp]: "pochhammer a 1 = a" by (simp add: pochhammer_def)
   199 lemma pochhammer_Suc0[simp]: "pochhammer a (Suc 0) = a" 
   200   by (simp add: pochhammer_def)
   201 
   202 lemma pochhammer_Suc_setprod: "pochhammer a (Suc n) = setprod (\<lambda>n. a + of_nat n) {0 .. n}"
   203   by (simp add: pochhammer_def)
   204 
   205 lemma setprod_nat_ivl_Suc: "setprod f {0 .. Suc n} = setprod f {0..n} * f (Suc n)"
   206 proof-
   207   have th: "finite {0..n}" "finite {Suc n}" "{0..n} \<inter> {Suc n} = {}" by auto
   208   have eq: "{0..Suc n} = {0..n} \<union> {Suc n}" by auto
   209   show ?thesis unfolding eq setprod_Un_disjoint[OF th] by simp
   210 qed
   211 
   212 lemma setprod_nat_ivl_1_Suc: "setprod f {0 .. Suc n} = f 0 * setprod f {1.. Suc n}"
   213 proof-
   214   have th: "finite {0}" "finite {1..Suc n}" "{0} \<inter> {1.. Suc n} = {}" by auto
   215   have eq: "{0..Suc n} = {0} \<union> {1 .. Suc n}" by auto
   216   show ?thesis unfolding eq setprod_Un_disjoint[OF th] by simp
   217 qed
   218 
   219 
   220 lemma pochhammer_Suc: "pochhammer a (Suc n) = pochhammer a n * (a + of_nat n)"
   221 proof-
   222   {assume "n=0" then have ?thesis by simp}
   223   moreover
   224   {fix m assume m: "n = Suc m"
   225     have ?thesis  unfolding m pochhammer_Suc_setprod setprod_nat_ivl_Suc ..}
   226   ultimately show ?thesis by (cases n, auto)
   227 qed 
   228 
   229 lemma pochhammer_rec: "pochhammer a (Suc n) = a * pochhammer (a + 1) n"
   230 proof-
   231   {assume "n=0" then have ?thesis by (simp add: pochhammer_Suc_setprod)}
   232   moreover
   233   {assume n0: "n \<noteq> 0"
   234     have th0: "finite {1 .. n}" "0 \<notin> {1 .. n}" by auto
   235     have eq: "insert 0 {1 .. n} = {0..n}" by auto
   236     have th1: "(\<Prod>n\<in>{1\<Colon>nat..n}. a + of_nat n) =
   237       (\<Prod>n\<in>{0\<Colon>nat..n - 1}. a + 1 + of_nat n)"
   238       apply (rule setprod_reindex_cong[where f = "Suc"])
   239       using n0 by (auto simp add: expand_fun_eq ring_simps)
   240     have ?thesis apply (simp add: pochhammer_def)
   241     unfolding setprod_insert[OF th0, unfolded eq]
   242     using th1 by (simp add: ring_simps)}
   243 ultimately show ?thesis by blast
   244 qed
   245 
   246 lemma fact_setprod: "fact n = setprod id {1 .. n}"
   247   apply (induct n, simp)
   248   apply (simp only: fact_Suc atLeastAtMostSuc_conv)
   249   apply (subst setprod_insert)
   250   by simp_all
   251 
   252 lemma pochhammer_fact: "of_nat (fact n) = pochhammer 1 n"
   253   unfolding fact_setprod
   254   
   255   apply (cases n, simp_all add: of_nat_setprod pochhammer_Suc_setprod)
   256   apply (rule setprod_reindex_cong[where f=Suc])
   257   by (auto simp add: expand_fun_eq)
   258 
   259 lemma pochhammer_of_nat_eq_0_lemma: assumes kn: "k > n"
   260   shows "pochhammer (- (of_nat n :: 'a:: idom)) k = 0"
   261 proof-
   262   from kn obtain h where h: "k = Suc h" by (cases k, auto)
   263   {assume n0: "n=0" then have ?thesis using kn 
   264       by (cases k, simp_all add: pochhammer_rec del: pochhammer_Suc)}
   265   moreover
   266   {assume n0: "n \<noteq> 0"
   267     then have ?thesis apply (simp add: h pochhammer_Suc_setprod)
   268   apply (rule_tac x="n" in bexI)
   269   using h kn by auto}
   270 ultimately show ?thesis by blast
   271 qed
   272 
   273 lemma pochhammer_of_nat_eq_0_lemma': assumes kn: "k \<le> n"
   274   shows "pochhammer (- (of_nat n :: 'a:: {idom, ring_char_0})) k \<noteq> 0"
   275 proof-
   276   {assume "k=0" then have ?thesis by simp}
   277   moreover
   278   {fix h assume h: "k = Suc h"
   279     then have ?thesis apply (simp add: pochhammer_Suc_setprod)
   280       using h kn by (auto simp add: algebra_simps)}
   281   ultimately show ?thesis by (cases k, auto)
   282 qed
   283 
   284 lemma pochhammer_of_nat_eq_0_iff: 
   285   shows "pochhammer (- (of_nat n :: 'a:: {idom, ring_char_0})) k = 0 \<longleftrightarrow> k > n"
   286   (is "?l = ?r")
   287   using pochhammer_of_nat_eq_0_lemma[of n k, where ?'a='a] 
   288     pochhammer_of_nat_eq_0_lemma'[of k n, where ?'a = 'a]
   289   by (auto simp add: not_le[symmetric])
   290 
   291 subsection{* Generalized binomial coefficients *}
   292 
   293 definition gbinomial :: "'a::field_char_0 \<Rightarrow> nat \<Rightarrow> 'a" (infixl "gchoose" 65)
   294   where "a gchoose n = (if n = 0 then 1 else (setprod (\<lambda>i. a - of_nat i) {0 .. n - 1}) / of_nat (fact n))"
   295 
   296 lemma gbinomial_0[simp]: "a gchoose 0 = 1" "0 gchoose (Suc n) = 0"
   297 apply (simp_all add: gbinomial_def)
   298 apply (subgoal_tac "(\<Prod>i\<Colon>nat\<in>{0\<Colon>nat..n}. - of_nat i) = (0::'b)")
   299  apply (simp del:setprod_zero_iff)
   300 apply simp
   301 done
   302 
   303 lemma gbinomial_pochhammer: "a gchoose n = (- 1) ^ n * pochhammer (- a) n / of_nat (fact n)"
   304 proof-
   305   {assume "n=0" then have ?thesis by simp}
   306   moreover
   307   {assume n0: "n\<noteq>0"
   308     from n0 setprod_constant[of "{0 .. n - 1}" "- (1:: 'a)"]
   309     have eq: "(- (1\<Colon>'a)) ^ n = setprod (\<lambda>i. - 1) {0 .. n - 1}"
   310       by auto
   311     from n0 have ?thesis 
   312       by (simp add: pochhammer_def gbinomial_def field_simps eq setprod_timesf[symmetric])}
   313   ultimately show ?thesis by blast
   314 qed
   315 
   316 lemma binomial_fact_lemma:
   317   "k \<le> n \<Longrightarrow> fact k * fact (n - k) * (n choose k) = fact n"
   318 proof(induct n arbitrary: k rule: nat_less_induct)
   319   fix n k assume H: "\<forall>m<n. \<forall>x\<le>m. fact x * fact (m - x) * (m choose x) =
   320                       fact m" and kn: "k \<le> n"
   321     let ?ths = "fact k * fact (n - k) * (n choose k) = fact n"
   322   {assume "n=0" then have ?ths using kn by simp}
   323   moreover
   324   {assume "k=0" then have ?ths using kn by simp}
   325   moreover
   326   {assume nk: "n=k" then have ?ths by simp}
   327   moreover
   328   {fix m h assume n: "n = Suc m" and h: "k = Suc h" and hm: "h < m"
   329     from n have mn: "m < n" by arith
   330     from hm have hm': "h \<le> m" by arith
   331     from hm h n kn have km: "k \<le> m" by arith
   332     have "m - h = Suc (m - Suc h)" using  h km hm by arith 
   333     with km h have th0: "fact (m - h) = (m - h) * fact (m - k)"
   334       by simp
   335     from n h th0 
   336     have "fact k * fact (n - k) * (n choose k) = k * (fact h * fact (m - h) * (m choose h)) +  (m - h) * (fact k * fact (m - k) * (m choose k))"
   337       by (simp add: ring_simps)
   338     also have "\<dots> = (k + (m - h)) * fact m"
   339       using H[rule_format, OF mn hm'] H[rule_format, OF mn km]
   340       by (simp add: ring_simps)
   341     finally have ?ths using h n km by simp}
   342   moreover have "n=0 \<or> k = 0 \<or> k = n \<or> (EX m h. n=Suc m \<and> k = Suc h \<and> h < m)" using kn by presburger
   343   ultimately show ?ths by blast
   344 qed
   345   
   346 lemma binomial_fact: 
   347   assumes kn: "k \<le> n" 
   348   shows "(of_nat (n choose k) :: 'a::field_char_0) = of_nat (fact n) / (of_nat (fact k) * of_nat (fact (n - k)))"
   349   using binomial_fact_lemma[OF kn]
   350   by (simp add: field_simps fact_not_eq_zero of_nat_mult[symmetric])
   351 
   352 lemma binomial_gbinomial: "of_nat (n choose k) = of_nat n gchoose k"
   353 proof-
   354   {assume kn: "k > n" 
   355     from kn binomial_eq_0[OF kn] have ?thesis 
   356       by (simp add: gbinomial_pochhammer field_simps
   357 	pochhammer_of_nat_eq_0_iff)}
   358   moreover
   359   {assume "k=0" then have ?thesis by simp}
   360   moreover
   361   {assume kn: "k \<le> n" and k0: "k\<noteq> 0"
   362     from k0 obtain h where h: "k = Suc h" by (cases k, auto)
   363     from h
   364     have eq:"(- 1 :: 'a) ^ k = setprod (\<lambda>i. - 1) {0..h}"
   365       by (subst setprod_constant, auto)
   366     have eq': "(\<Prod>i\<in>{0..h}. of_nat n + - (of_nat i :: 'a)) = (\<Prod>i\<in>{n - h..n}. of_nat i)"
   367       apply (rule strong_setprod_reindex_cong[where f="op - n"])
   368       using h kn 
   369       apply (simp_all add: inj_on_def image_iff Bex_def expand_set_eq)
   370       apply clarsimp
   371       apply (presburger)
   372       apply presburger
   373       by (simp add: expand_fun_eq ring_simps of_nat_add[symmetric] del: of_nat_add)
   374     have th0: "finite {1..n - Suc h}" "finite {n - h .. n}" 
   375 "{1..n - Suc h} \<inter> {n - h .. n} = {}" and eq3: "{1..n - Suc h} \<union> {n - h .. n} = {1..n}" using h kn by auto
   376     from eq[symmetric]
   377     have ?thesis using kn
   378       apply (simp add: binomial_fact[OF kn, where ?'a = 'a] 
   379 	gbinomial_pochhammer field_simps pochhammer_Suc_setprod)
   380       apply (simp add: pochhammer_Suc_setprod fact_setprod h of_nat_setprod setprod_timesf[symmetric] eq' del: One_nat_def power_Suc)
   381       unfolding setprod_Un_disjoint[OF th0, unfolded eq3, of "of_nat:: nat \<Rightarrow> 'a"] eq[unfolded h]
   382       unfolding mult_assoc[symmetric] 
   383       unfolding setprod_timesf[symmetric]
   384       apply simp
   385       apply (rule strong_setprod_reindex_cong[where f= "op - n"])
   386       apply (auto simp add: inj_on_def image_iff Bex_def)
   387       apply presburger
   388       apply (subgoal_tac "(of_nat (n - x) :: 'a) = of_nat n - of_nat x")
   389       apply simp
   390       by (rule of_nat_diff, simp)
   391   }
   392   moreover
   393   have "k > n \<or> k = 0 \<or> (k \<le> n \<and> k \<noteq> 0)" by arith
   394   ultimately show ?thesis by blast
   395 qed
   396 
   397 lemma gbinomial_1[simp]: "a gchoose 1 = a"
   398   by (simp add: gbinomial_def)
   399 
   400 lemma gbinomial_Suc0[simp]: "a gchoose (Suc 0) = a"
   401   by (simp add: gbinomial_def)
   402 
   403 lemma gbinomial_mult_1: "a * (a gchoose n) = of_nat n * (a gchoose n) + of_nat (Suc n) * (a gchoose (Suc n))" (is "?l = ?r")
   404 proof-
   405   have "?r = ((- 1) ^n * pochhammer (- a) n / of_nat (fact n)) * (of_nat n - (- a + of_nat n))"
   406     unfolding gbinomial_pochhammer
   407     pochhammer_Suc fact_Suc of_nat_mult right_diff_distrib power_Suc
   408     by (simp add:  field_simps del: of_nat_Suc)
   409   also have "\<dots> = ?l" unfolding gbinomial_pochhammer
   410     by (simp add: ring_simps)
   411   finally show ?thesis ..
   412 qed
   413 
   414 lemma gbinomial_mult_1': "(a gchoose n) * a = of_nat n * (a gchoose n) + of_nat (Suc n) * (a gchoose (Suc n))"
   415   by (simp add: mult_commute gbinomial_mult_1)
   416 
   417 lemma gbinomial_Suc: "a gchoose (Suc k) = (setprod (\<lambda>i. a - of_nat i) {0 .. k}) / of_nat (fact (Suc k))"
   418   by (simp add: gbinomial_def)
   419  
   420 lemma gbinomial_mult_fact:
   421   "(of_nat (fact (Suc k)) :: 'a) * ((a::'a::field_char_0) gchoose (Suc k)) = (setprod (\<lambda>i. a - of_nat i) {0 .. k})"
   422   unfolding gbinomial_Suc
   423   by (simp_all add: field_simps del: fact_Suc)
   424 
   425 lemma gbinomial_mult_fact':
   426   "((a::'a::field_char_0) gchoose (Suc k)) * (of_nat (fact (Suc k)) :: 'a) = (setprod (\<lambda>i. a - of_nat i) {0 .. k})"
   427   using gbinomial_mult_fact[of k a]
   428   apply (subst mult_commute) .
   429 
   430 lemma gbinomial_Suc_Suc: "((a::'a::field_char_0) + 1) gchoose (Suc k) = a gchoose k + (a gchoose (Suc k))"
   431 proof-
   432   {assume "k = 0" then have ?thesis by simp}
   433   moreover
   434   {fix h assume h: "k = Suc h"
   435    have eq0: "(\<Prod>i\<in>{1..k}. (a + 1) - of_nat i) = (\<Prod>i\<in>{0..h}. a - of_nat i)"
   436      apply (rule strong_setprod_reindex_cong[where f = Suc])
   437      using h by auto
   438 
   439     have "of_nat (fact (Suc k)) * (a gchoose k + (a gchoose (Suc k))) = ((a gchoose Suc h) * of_nat (fact (Suc h)) * of_nat (Suc k)) + (\<Prod>i\<in>{0\<Colon>nat..Suc h}. a - of_nat i)" 
   440       unfolding h
   441       apply (simp add: ring_simps del: fact_Suc)
   442       unfolding gbinomial_mult_fact'
   443       apply (subst fact_Suc)
   444       unfolding of_nat_mult 
   445       apply (subst mult_commute)
   446       unfolding mult_assoc
   447       unfolding gbinomial_mult_fact
   448       by (simp add: ring_simps)
   449     also have "\<dots> = (\<Prod>i\<in>{0..h}. a - of_nat i) * (a + 1)"
   450       unfolding gbinomial_mult_fact' setprod_nat_ivl_Suc
   451       by (simp add: ring_simps h)
   452     also have "\<dots> = (\<Prod>i\<in>{0..k}. (a + 1) - of_nat i)"
   453       using eq0
   454       unfolding h  setprod_nat_ivl_1_Suc
   455       by simp
   456     also have "\<dots> = of_nat (fact (Suc k)) * ((a + 1) gchoose (Suc k))"
   457       unfolding gbinomial_mult_fact ..
   458     finally have ?thesis by (simp del: fact_Suc) }
   459   ultimately show ?thesis by (cases k, auto)
   460 qed
   461 
   462 end