src/Pure/library.ML
author berghofe
Mon Dec 17 18:39:18 2007 +0100 (2007-12-17)
changeset 25681 ded611be9604
parent 25549 7040555f20c7
child 25702 a61554b1e7a9
permissions -rw-r--r--
Added foldl1.
     1 (*  Title:      Pure/library.ML
     2     ID:         $Id$
     3     Author:     Lawrence C Paulson, Cambridge University Computer Laboratory
     4     Author:     Markus Wenzel, TU Muenchen
     5 
     6 Basic library: functions, options, pairs, booleans, lists, integers,
     7 strings, lists as sets, orders, current directory, misc.
     8 
     9 See also General/basics.ML for the most fundamental concepts.
    10 *)
    11 
    12 infix 1 |>>>
    13 infix 2 ?
    14 infix 3 o oo ooo oooo
    15 infix 4 ~~ upto downto
    16 infix orf andf \ \\ mem mem_int mem_string union union_int
    17   union_string inter inter_int inter_string subset subset_int subset_string
    18 
    19 signature BASIC_LIBRARY =
    20 sig
    21   (*functions*)
    22   val undefined: 'a -> 'b
    23   val I: 'a -> 'a
    24   val K: 'a -> 'b -> 'a
    25   val curry: ('a * 'b -> 'c) -> 'a -> 'b -> 'c
    26   val uncurry: ('a -> 'b -> 'c) -> 'a * 'b -> 'c
    27   val |>>> : ('a * 'c) * ('a -> 'b * 'd) -> 'b * ('c * 'd)
    28   val ? : bool * ('a -> 'a) -> 'a -> 'a
    29   val oo: ('a -> 'b) * ('c -> 'd -> 'a) -> 'c -> 'd -> 'b
    30   val ooo: ('a -> 'b) * ('c -> 'd -> 'e -> 'a) -> 'c -> 'd -> 'e -> 'b
    31   val oooo: ('a -> 'b) * ('c -> 'd -> 'e -> 'f -> 'a) -> 'c -> 'd -> 'e -> 'f -> 'b
    32   val funpow: int -> ('a -> 'a) -> 'a -> 'a
    33 
    34   (*errors*)
    35   exception SYS_ERROR of string
    36   val sys_error: string -> 'a
    37   exception ERROR of string
    38   val error: string -> 'a
    39   val cat_error: string -> string -> 'a
    40   val assert_all: ('a -> bool) -> 'a list -> ('a -> string) -> unit
    41 
    42   (*pairs*)
    43   val pair: 'a -> 'b -> 'a * 'b
    44   val rpair: 'a -> 'b -> 'b * 'a
    45   val fst: 'a * 'b -> 'a
    46   val snd: 'a * 'b -> 'b
    47   val eq_fst: ('a * 'c -> bool) -> ('a * 'b) * ('c * 'd) -> bool
    48   val eq_snd: ('b * 'd -> bool) -> ('a * 'b) * ('c * 'd) -> bool
    49   val eq_pair: ('a * 'c -> bool) -> ('b * 'd -> bool) -> ('a * 'b) * ('c * 'd) -> bool
    50   val swap: 'a * 'b -> 'b * 'a
    51   val apfst: ('a -> 'b) -> 'a * 'c -> 'b * 'c
    52   val apsnd: ('a -> 'b) -> 'c * 'a -> 'c * 'b
    53   val pairself: ('a -> 'b) -> 'a * 'a -> 'b * 'b
    54 
    55   (*booleans*)
    56   val equal: ''a -> ''a -> bool
    57   val not_equal: ''a -> ''a -> bool
    58   val orf: ('a -> bool) * ('a -> bool) -> 'a -> bool
    59   val andf: ('a -> bool) * ('a -> bool) -> 'a -> bool
    60   val exists: ('a -> bool) -> 'a list -> bool
    61   val forall: ('a -> bool) -> 'a list -> bool
    62   val set: bool ref -> bool
    63   val reset: bool ref -> bool
    64   val toggle: bool ref -> bool
    65   val change: 'a ref -> ('a -> 'a) -> unit
    66   val setmp_noncritical: 'a ref -> 'a -> ('b -> 'c) -> 'b -> 'c
    67   val setmp: 'a ref -> 'a -> ('b -> 'c) -> 'b -> 'c
    68 
    69   (*lists*)
    70   exception UnequalLengths
    71   val single: 'a -> 'a list
    72   val the_single: 'a list -> 'a
    73   val singleton: ('a list -> 'b list) -> 'a -> 'b
    74   val yield_singleton: ('a list -> 'c -> 'b list * 'c) -> 'a -> 'c -> 'b * 'c
    75   val apply: ('a -> 'a) list -> 'a -> 'a
    76   val perhaps_apply: ('a -> 'a option) list -> 'a -> 'a option
    77   val perhaps_loop: ('a -> 'a option) -> 'a -> 'a option
    78   val foldl1: ('a * 'a -> 'a) -> 'a list -> 'a
    79   val foldr1: ('a * 'a -> 'a) -> 'a list -> 'a
    80   val foldl_map: ('a * 'b -> 'a * 'c) -> 'a * 'b list -> 'a * 'c list
    81   val flat: 'a list list -> 'a list
    82   val unflat: 'a list list -> 'b list -> 'b list list
    83   val burrow: ('a list -> 'b list) -> 'a list list -> 'b list list
    84   val burrow_options: ('a list -> 'b list) -> 'a option list -> 'b option list
    85   val fold_burrow: ('a list -> 'c -> 'b list * 'd) -> 'a list list -> 'c -> 'b list list * 'd
    86   val maps: ('a -> 'b list) -> 'a list -> 'b list
    87   val filter: ('a -> bool) -> 'a list -> 'a list
    88   val filter_out: ('a -> bool) -> 'a list -> 'a list
    89   val map_filter: ('a -> 'b option) -> 'a list -> 'b list
    90   val chop: int -> 'a list -> 'a list * 'a list
    91   val dropwhile: ('a -> bool) -> 'a list -> 'a list
    92   val nth: 'a list -> int -> 'a
    93   val nth_map: int -> ('a -> 'a) -> 'a list -> 'a list
    94   val nth_drop: int -> 'a list -> 'a list
    95   val nth_list: 'a list list -> int -> 'a list
    96   val map_index: (int * 'a -> 'b) -> 'a list -> 'b list
    97   val fold_index: (int * 'a -> 'b -> 'b) -> 'a list -> 'b -> 'b
    98   val split_last: 'a list -> 'a list * 'a
    99   val find_index: ('a -> bool) -> 'a list -> int
   100   val find_index_eq: ''a -> ''a list -> int
   101   val find_first: ('a -> bool) -> 'a list -> 'a option
   102   val get_index: ('a -> 'b option) -> 'a list -> (int * 'b) option
   103   val get_first: ('a -> 'b option) -> 'a list -> 'b option
   104   val eq_list: ('a * 'b -> bool) -> 'a list * 'b list -> bool
   105   val map2: ('a -> 'b -> 'c) -> 'a list -> 'b list -> 'c list
   106   val fold2: ('a -> 'b -> 'c -> 'c) -> 'a list -> 'b list -> 'c -> 'c
   107   val zip_options: 'a list -> 'b option list -> ('a * 'b) list
   108   val ~~ : 'a list * 'b list -> ('a * 'b) list
   109   val split_list: ('a * 'b) list -> 'a list * 'b list
   110   val separate: 'a -> 'a list -> 'a list
   111   val replicate: int -> 'a -> 'a list
   112   val is_prefix: ('a * 'a -> bool) -> 'a list -> 'a list -> bool
   113   val take_prefix: ('a -> bool) -> 'a list -> 'a list * 'a list
   114   val chop_prefix: ('a * 'b -> bool) -> 'a list * 'b list -> 'a list * ('a list * 'b list)
   115   val take_suffix: ('a -> bool) -> 'a list -> 'a list * 'a list
   116   val prefixes1: 'a list -> 'a list list
   117   val prefixes: 'a list -> 'a list list
   118   val suffixes1: 'a list -> 'a list list
   119   val suffixes: 'a list -> 'a list list
   120 
   121   (*integers*)
   122   val inc: int ref -> int
   123   val dec: int ref -> int
   124   val upto: int * int -> int list
   125   val downto: int * int -> int list
   126   val radixpand: int * int -> int list
   127   val radixstring: int * string * int -> string
   128   val string_of_int: int -> string
   129   val signed_string_of_int: int -> string
   130   val string_of_indexname: string * int -> string
   131   val read_radix_int: int -> string list -> int * string list
   132   val read_int: string list -> int * string list
   133   val oct_char: string -> string
   134 
   135   (*strings*)
   136   val nth_string: string -> int -> string
   137   val fold_string: (string -> 'a -> 'a) -> string -> 'a -> 'a
   138   val exists_string: (string -> bool) -> string -> bool
   139   val forall_string: (string -> bool) -> string -> bool
   140   val enclose: string -> string -> string -> string
   141   val unenclose: string -> string
   142   val quote: string -> string
   143   val space_implode: string -> string list -> string
   144   val commas: string list -> string
   145   val commas_quote: string list -> string
   146   val cat_lines: string list -> string
   147   val space_explode: string -> string -> string list
   148   val split_lines: string -> string list
   149   val prefix_lines: string -> string -> string
   150   val untabify: string list -> string list
   151   val prefix: string -> string -> string
   152   val suffix: string -> string -> string
   153   val unprefix: string -> string -> string
   154   val unsuffix: string -> string -> string
   155   val replicate_string: int -> string -> string
   156   val translate_string: (string -> string) -> string -> string
   157   val multiply: 'a list -> 'a list list -> 'a list list
   158   val map_product: ('a -> 'b -> 'c) -> 'a list -> 'b list -> 'c list
   159   val fold_product: ('a -> 'b -> 'c -> 'c) -> 'a list -> 'b list -> 'c -> 'c
   160 
   161   (*lists as sets -- see also Pure/General/ord_list.ML*)
   162   val member: ('b * 'a -> bool) -> 'a list -> 'b -> bool
   163   val insert: ('a * 'a -> bool) -> 'a -> 'a list -> 'a list
   164   val remove: ('b * 'a -> bool) -> 'b -> 'a list -> 'a list
   165   val update: ('a * 'a -> bool) -> 'a -> 'a list -> 'a list
   166   val subtract: ('b * 'a -> bool) -> 'b list -> 'a list -> 'a list
   167   val merge: ('a * 'a -> bool) -> 'a list * 'a list -> 'a list
   168   val mem: ''a * ''a list -> bool
   169   val mem_int: int * int list -> bool
   170   val mem_string: string * string list -> bool
   171   val union: ''a list * ''a list -> ''a list
   172   val union_int: int list * int list -> int list
   173   val union_string: string list * string list -> string list
   174   val gen_union: ('a * 'a -> bool) -> 'a list * 'a list -> 'a list
   175   val gen_inter: ('a * 'b -> bool) -> 'a list * 'b list -> 'a list
   176   val inter: ''a list * ''a list -> ''a list
   177   val inter_int: int list * int list -> int list
   178   val inter_string: string list * string list -> string list
   179   val subset: ''a list * ''a list -> bool
   180   val subset_int: int list * int list -> bool
   181   val subset_string: string list * string list -> bool
   182   val eq_set: ''a list * ''a list -> bool
   183   val eq_set_string: string list * string list -> bool
   184   val gen_subset: ('a * 'b -> bool) -> 'a list * 'b list -> bool
   185   val gen_eq_set: ('a * 'b -> bool) -> 'a list * 'b list -> bool
   186   val \ : ''a list * ''a -> ''a list
   187   val \\ : ''a list * ''a list -> ''a list
   188   val distinct: ('a * 'a -> bool) -> 'a list -> 'a list
   189   val duplicates: ('a * 'a -> bool) -> 'a list -> 'a list
   190   val has_duplicates: ('a * 'a -> bool) -> 'a list -> bool
   191 
   192   (*lists as multisets*)
   193   val remove1: ('b * 'a -> bool) -> 'b -> 'a list -> 'a list
   194   val submultiset: ('a * 'b -> bool) -> 'a list * 'b list -> bool
   195 
   196   (*orders*)
   197   val is_equal: order -> bool
   198   val rev_order: order -> order
   199   val make_ord: ('a * 'a -> bool) -> 'a * 'a -> order
   200   val bool_ord: bool * bool -> order
   201   val int_ord: int * int -> order
   202   val string_ord: string * string -> order
   203   val fast_string_ord: string * string -> order
   204   val option_ord: ('a * 'b -> order) -> 'a option * 'b option -> order
   205   val prod_ord: ('a * 'b -> order) -> ('c * 'd -> order) -> ('a * 'c) * ('b * 'd) -> order
   206   val dict_ord: ('a * 'b -> order) -> 'a list * 'b list -> order
   207   val list_ord: ('a * 'b -> order) -> 'a list * 'b list -> order
   208   val sort: ('a * 'a -> order) -> 'a list -> 'a list
   209   val sort_distinct: ('a * 'a -> order) -> 'a list -> 'a list
   210   val sort_strings: string list -> string list
   211   val sort_wrt: ('a -> string) -> 'a list -> 'a list
   212 
   213   (*random numbers*)
   214   exception RANDOM
   215   val random: unit -> real
   216   val random_range: int -> int -> int
   217   val one_of: 'a list -> 'a
   218   val frequency: (int * 'a) list -> 'a
   219 
   220   (*misc*)
   221   val divide_and_conquer: ('a -> 'a list * ('b list -> 'b)) -> 'a -> 'b
   222   val partition_eq: ('a * 'a -> bool) -> 'a list -> 'a list list
   223   val partition_list: (int -> 'a -> bool) -> int -> int -> 'a list -> 'a list list
   224   val gensym: string -> string
   225   type stamp
   226   val stamp: unit -> stamp
   227   type serial
   228   val serial: unit -> serial
   229   val serial_string: unit -> string
   230   structure Object: sig type T end
   231 end;
   232 
   233 signature LIBRARY =
   234 sig
   235   include BASIC_LIBRARY
   236   val foldl: ('a * 'b -> 'a) -> 'a * 'b list -> 'a
   237   val foldr: ('a * 'b -> 'b) -> 'a list * 'b -> 'b
   238   val take: int * 'a list -> 'a list
   239   val drop: int * 'a list -> 'a list
   240   val last_elem: 'a list -> 'a
   241 end;
   242 
   243 structure Library: LIBRARY =
   244 struct
   245 
   246 (* functions *)
   247 
   248 fun undefined _ = raise Match;
   249 
   250 fun I x = x;
   251 fun K x = fn _ => x;
   252 fun curry f x y = f (x, y);
   253 fun uncurry f (x, y) = f x y;
   254 
   255 (*application and structured results -- old version*)
   256 fun (x, y) |>>> f = let val (x', z) = f x in (x', (y, z)) end;
   257 
   258 (*conditional application*)
   259 fun b ? f = fn x => if b then f x else x;
   260 
   261 (*composition with multiple args*)
   262 fun (f oo g) x y = f (g x y);
   263 fun (f ooo g) x y z = f (g x y z);
   264 fun (f oooo g) x y z w = f (g x y z w);
   265 
   266 (*function exponentiation: f(...(f x)...) with n applications of f*)
   267 fun funpow (0: int) _ x = x
   268   | funpow n f x = funpow (n - 1) f (f x);
   269 
   270 
   271 (* errors *)
   272 
   273 exception SYS_ERROR of string;
   274 fun sys_error msg = raise SYS_ERROR msg;
   275 
   276 exception ERROR of string;
   277 fun error msg = raise ERROR msg;
   278 
   279 fun cat_error "" msg = error msg
   280   | cat_error msg1 msg2 = error (msg1 ^ "\n" ^ msg2);
   281 
   282 fun assert_all pred list msg =
   283   let
   284     fun ass [] = ()
   285       | ass (x :: xs) = if pred x then ass xs else error (msg x);
   286   in ass list end;
   287 
   288 
   289 (* pairs *)
   290 
   291 fun pair x y = (x, y);
   292 fun rpair x y = (y, x);
   293 
   294 fun fst (x, y) = x;
   295 fun snd (x, y) = y;
   296 
   297 fun eq_fst eq ((x1, _), (x2, _)) = eq (x1, x2);
   298 fun eq_snd eq ((_, y1), (_, y2)) = eq (y1, y2);
   299 fun eq_pair eqx eqy ((x1, y1), (x2, y2)) = eqx (x1, x2) andalso eqy (y1, y2);
   300 
   301 fun swap (x, y) = (y, x);
   302 
   303 fun apfst f (x, y) = (f x, y);
   304 fun apsnd f (x, y) = (x, f y);
   305 fun pairself f (x, y) = (f x, f y);
   306 
   307 
   308 (* booleans *)
   309 
   310 (*polymorphic equality*)
   311 fun equal x y = x = y;
   312 fun not_equal x y = x <> y;
   313 
   314 (*combining predicates*)
   315 fun p orf q = fn x => p x orelse q x;
   316 fun p andf q = fn x => p x andalso q x;
   317 
   318 (*exists pred [x1, ..., xn] ===> pred x1 orelse ... orelse pred xn*)
   319 fun exists (pred: 'a -> bool) : 'a list -> bool =
   320   let fun boolf [] = false
   321         | boolf (x :: xs) = pred x orelse boolf xs
   322   in boolf end;
   323 
   324 (*forall pred [x1, ..., xn] ===> pred x1 andalso ... andalso pred xn*)
   325 fun forall (pred: 'a -> bool) : 'a list -> bool =
   326   let fun boolf [] = true
   327         | boolf (x :: xs) = pred x andalso boolf xs
   328   in boolf end;
   329 
   330 
   331 (* flags *)
   332 
   333 fun set flag = (flag := true; true);
   334 fun reset flag = (flag := false; false);
   335 fun toggle flag = (flag := not (! flag); ! flag);
   336 
   337 fun change r f = r := f (! r);
   338 
   339 (*temporarily set flag during execution*)
   340 fun setmp_noncritical flag value f x =
   341   let
   342     val orig_value = ! flag;
   343     val _ = flag := value;
   344     val result = Exn.capture f x;
   345     val _ = flag := orig_value;
   346   in Exn.release result end;
   347 
   348 fun setmp flag value f x = NAMED_CRITICAL "setmp" (fn () => setmp_noncritical flag value f x);
   349 
   350 
   351 
   352 (** lists **)
   353 
   354 exception UnequalLengths;
   355 
   356 fun single x = [x];
   357 
   358 fun the_single [x] = x
   359   | the_single _ = raise Empty;
   360 
   361 fun singleton f x = the_single (f [x]);
   362 
   363 fun yield_singleton f x = f [x] #>> the_single;
   364 
   365 fun apply [] x = x
   366   | apply (f :: fs) x = apply fs (f x);
   367 
   368 fun perhaps_apply funs arg =
   369   let
   370     fun app [] res = res
   371       | app (f :: fs) (changed, x) =
   372           (case f x of
   373             NONE => app fs (changed, x)
   374           | SOME x' => app fs (true, x'));
   375   in (case app funs (false, arg) of (false, _) => NONE | (true, arg') => SOME arg') end;
   376 
   377 fun perhaps_loop f arg =
   378   let
   379     fun loop (changed, x) =
   380       (case f x of
   381         NONE => (changed, x)
   382       | SOME x' => loop (true, x'));
   383   in (case loop (false, arg) of (false, _) => NONE | (true, arg') => SOME arg') end;
   384 
   385 
   386 (* fold -- old versions *)
   387 
   388 (*the following versions of fold are designed to fit nicely with infixes*)
   389 
   390 (*  (op @) (e, [x1, ..., xn])  ===>  ((e @ x1) @ x2) ... @ xn
   391     for operators that associate to the left (TAIL RECURSIVE)*)
   392 fun foldl (f: 'a * 'b -> 'a) : 'a * 'b list -> 'a =
   393   let fun itl (e, [])  = e
   394         | itl (e, a::l) = itl (f(e, a), l)
   395   in  itl end;
   396 
   397 (*  (op @) ([x1, ..., xn], e)  ===>   x1 @ (x2 ... @ (xn @ e))
   398     for operators that associate to the right (not tail recursive)*)
   399 fun foldr f (l, e) =
   400   let fun itr [] = e
   401         | itr (a::l) = f(a, itr l)
   402   in  itr l  end;
   403 
   404 (*  (op @) [x1, ..., xn]  ===>  ((x1 @ x2) @ x3) ... @ xn
   405     for operators that associate to the left (TAIL RECURSIVE)*)
   406 fun foldl1 f [] = raise Empty
   407   | foldl1 f (x :: xs) = foldl f (x, xs);
   408 
   409 (*  (op @) [x1, ..., xn]  ===>   x1 @ (x2 ... @ (x[n-1] @ xn))
   410     for n > 0, operators that associate to the right (not tail recursive)*)
   411 fun foldr1 f [] = raise Empty
   412   | foldr1 f l =
   413       let fun itr [x] = x
   414             | itr (x::l) = f(x, itr l)
   415       in  itr l  end;
   416 
   417 fun foldl_map f =
   418   let
   419     fun fold_aux (x, []) = (x, [])
   420       | fold_aux (x, y :: ys) =
   421           let
   422             val (x', y') = f (x, y);
   423             val (x'', ys') = fold_aux (x', ys);
   424           in (x'', y' :: ys') end;
   425   in fold_aux end;
   426 
   427 
   428 (* basic list functions *)
   429 
   430 fun eq_list eq (list1, list2) =
   431   let
   432     fun eq_lst (x :: xs, y :: ys) = eq (x, y) andalso eq_lst (xs, ys)
   433       | eq_lst _ = true;
   434   in length list1 = length list2 andalso eq_lst (list1, list2) end;
   435 
   436 fun maps f [] = []
   437   | maps f (x :: xs) = f x @ maps f xs;
   438 
   439 val filter = List.filter;
   440 fun filter_out f = filter (not o f);
   441 val map_filter = List.mapPartial;
   442 
   443 fun chop (0: int) xs = ([], xs)
   444   | chop _ [] = ([], [])
   445   | chop n (x :: xs) = chop (n - 1) xs |>> cons x;
   446 
   447 (*take the first n elements from a list*)
   448 fun take (n: int, []) = []
   449   | take (n, x :: xs) =
   450       if n > 0 then x :: take (n - 1, xs) else [];
   451 
   452 (*drop the first n elements from a list*)
   453 fun drop (n: int, []) = []
   454   | drop (n, x :: xs) =
   455       if n > 0 then drop (n - 1, xs) else x :: xs;
   456 
   457 fun dropwhile P [] = []
   458   | dropwhile P (ys as x::xs) = if P x then dropwhile P xs else ys;
   459 
   460 (*return nth element of a list, where 0 designates the first element;
   461   raise Subscript if list too short*)
   462 fun nth xs i = List.nth (xs, i);
   463 
   464 fun nth_list xss i = nth xss i handle Subscript => [];
   465 
   466 fun nth_map 0 f (x :: xs) = f x :: xs
   467   | nth_map n f (x :: xs) = x :: nth_map (n - 1) f xs
   468   | nth_map (_: int) _ [] = raise Subscript;
   469 
   470 fun nth_drop n xs =
   471   List.take (xs, n) @ List.drop (xs, n + 1);
   472 
   473 fun map_index f =
   474   let
   475     fun mapp (_: int) [] = []
   476       | mapp i (x :: xs) = f (i, x) :: mapp (i + 1) xs
   477   in mapp 0 end;
   478 
   479 fun fold_index f =
   480   let
   481     fun fold_aux (_: int) [] y = y
   482       | fold_aux i (x :: xs) y = fold_aux (i + 1) xs (f (i, x) y);
   483   in fold_aux 0 end;
   484 
   485 val last_elem = List.last;
   486 
   487 (*rear decomposition*)
   488 fun split_last [] = raise Empty
   489   | split_last [x] = ([], x)
   490   | split_last (x :: xs) = apfst (cons x) (split_last xs);
   491 
   492 (*find the position of an element in a list*)
   493 fun find_index pred =
   494   let fun find (_: int) [] = ~1
   495         | find n (x :: xs) = if pred x then n else find (n + 1) xs;
   496   in find 0 end;
   497 
   498 fun find_index_eq x = find_index (equal x);
   499 
   500 (*find first element satisfying predicate*)
   501 val find_first = List.find;
   502 
   503 (*get first element by lookup function*)
   504 fun get_first _ [] = NONE
   505   | get_first f (x :: xs) =
   506       (case f x of
   507         NONE => get_first f xs
   508       | some => some);
   509 
   510 fun get_index f =
   511   let
   512     fun get (_: int) [] = NONE
   513       | get i (x :: xs) =
   514           case f x
   515            of NONE => get (i + 1) xs
   516             | SOME y => SOME (i, y)
   517   in get 0 end;
   518 
   519 val flat = List.concat;
   520 
   521 fun unflat (xs :: xss) ys =
   522       let val (ps, qs) = chop (length xs) ys
   523       in ps :: unflat xss qs end
   524   | unflat [] [] = []
   525   | unflat _ _ = raise UnequalLengths;
   526 
   527 fun burrow f xss = unflat xss (f (flat xss));
   528 
   529 fun burrow_options f os = map (try hd) (burrow f (map the_list os));
   530 
   531 fun fold_burrow f xss s =
   532   apfst (unflat xss) (f (flat xss) s);
   533 
   534 (*separate s [x1, x2, ..., xn]  ===>  [x1, s, x2, s, ..., s, xn]*)
   535 fun separate s (x :: (xs as _ :: _)) = x :: s :: separate s xs
   536   | separate _ xs = xs;
   537 
   538 (*make the list [x, x, ..., x] of length n*)
   539 fun replicate (n: int) x =
   540   let fun rep (0, xs) = xs
   541         | rep (n, xs) = rep (n - 1, x :: xs)
   542   in
   543     if n < 0 then raise Subscript
   544     else rep (n, [])
   545   end;
   546 
   547 fun translate_string f = String.translate (f o String.str);
   548 
   549 (*multiply [a, b, c, ...] * [xs, ys, zs, ...]*)
   550 fun multiply [] _ = []
   551   | multiply (x :: xs) yss = map (cons x) yss @ multiply xs yss;
   552 
   553 
   554 (* direct product *)
   555 
   556 fun map_product f _ [] = []
   557   | map_product f [] _ = []
   558   | map_product f (x :: xs) ys = map (f x) ys @ map_product f xs ys;
   559 
   560 fun fold_product f _ [] z = z
   561   | fold_product f [] _ z = z
   562   | fold_product f (x :: xs) ys z = z |> fold (f x) ys |> fold_product f xs ys;
   563 
   564 
   565 (* lists of pairs *)
   566 
   567 exception UnequalLengths;
   568 
   569 fun map2 _ [] [] = []
   570   | map2 f (x :: xs) (y :: ys) = f x y :: map2 f xs ys
   571   | map2 _ _ _ = raise UnequalLengths;
   572 
   573 fun fold2 f [] [] z = z
   574   | fold2 f (x :: xs) (y :: ys) z = fold2 f xs ys (f x y z)
   575   | fold2 f _ _ _ = raise UnequalLengths;
   576 
   577 fun zip_options (x :: xs) (SOME y :: ys) = (x, y) :: zip_options xs ys
   578   | zip_options (_ :: xs) (NONE :: ys) = zip_options xs ys
   579   | zip_options _ [] = []
   580   | zip_options [] _ = raise UnequalLengths;
   581 
   582 (*combine two lists forming a list of pairs:
   583   [x1, ..., xn] ~~ [y1, ..., yn]  ===>  [(x1, y1), ..., (xn, yn)]*)
   584 fun [] ~~ [] = []
   585   | (x :: xs) ~~ (y :: ys) = (x, y) :: (xs ~~ ys)
   586   | _ ~~ _ = raise UnequalLengths;
   587 
   588 (*inverse of ~~; the old 'split':
   589   [(x1, y1), ..., (xn, yn)]  ===>  ([x1, ..., xn], [y1, ..., yn])*)
   590 val split_list = ListPair.unzip;
   591 
   592 
   593 (* prefixes, suffixes *)
   594 
   595 fun is_prefix _ [] _ = true
   596   | is_prefix eq (x :: xs) (y :: ys) = eq (x, y) andalso is_prefix eq xs ys
   597   | is_prefix eq _ _ = false;
   598 
   599 (* [x1, ..., xi, ..., xn]  --->  ([x1, ..., x(i-1)], [xi, ..., xn])
   600    where xi is the first element that does not satisfy the predicate*)
   601 fun take_prefix (pred : 'a -> bool)  (xs: 'a list) : 'a list * 'a list =
   602   let fun take (rxs, []) = (rev rxs, [])
   603         | take (rxs, x :: xs) =
   604             if  pred x  then  take(x :: rxs, xs)  else  (rev rxs, x :: xs)
   605   in  take([], xs)  end;
   606 
   607 fun chop_prefix eq ([], ys) = ([], ([], ys))
   608   | chop_prefix eq (xs, []) = ([], (xs, []))
   609   | chop_prefix eq (xs as x :: xs', ys as y :: ys') =
   610       if eq (x, y) then
   611         let val (ps', xys'') = chop_prefix eq (xs', ys')
   612         in (x :: ps', xys'') end
   613       else ([], (xs, ys));
   614 
   615 (* [x1, ..., xi, ..., xn]  --->  ([x1, ..., xi], [x(i+1), ..., xn])
   616    where xi is the last element that does not satisfy the predicate*)
   617 fun take_suffix _ [] = ([], [])
   618   | take_suffix pred (x :: xs) =
   619       (case take_suffix pred xs of
   620         ([], sffx) => if pred x then ([], x :: sffx) else ([x], sffx)
   621       | (prfx, sffx) => (x :: prfx, sffx));
   622 
   623 fun prefixes1 [] = []
   624   | prefixes1 (x :: xs) = map (cons x) ([] :: prefixes1 xs);
   625 
   626 fun prefixes xs = [] :: prefixes1 xs;
   627 
   628 fun suffixes1 xs = map rev (prefixes1 (rev xs));
   629 fun suffixes xs = [] :: suffixes1 xs;
   630 
   631 
   632 
   633 (** integers **)
   634 
   635 fun inc i = (i := ! i + (1: int); ! i);
   636 fun dec i = (i := ! i - (1: int); ! i);
   637 
   638 
   639 (* lists of integers *)
   640 
   641 (*make the list [from, from + 1, ..., to]*)
   642 fun ((i: int) upto j) =
   643   if i > j then [] else i :: (i + 1 upto j);
   644 
   645 (*make the list [from, from - 1, ..., to]*)
   646 fun ((i: int) downto j) =
   647   if i < j then [] else i :: (i - 1 downto j);
   648 
   649 
   650 (* convert integers to strings *)
   651 
   652 (*expand the number in the given base;
   653   example: radixpand (2, 8) gives [1, 0, 0, 0]*)
   654 fun radixpand (base, num) : int list =
   655   let
   656     fun radix (n, tail) =
   657       if n < base then n :: tail
   658       else radix (n div base, (n mod base) :: tail)
   659   in radix (num, []) end;
   660 
   661 (*expands a number into a string of characters starting from "zerochar";
   662   example: radixstring (2, "0", 8) gives "1000"*)
   663 fun radixstring (base, zerochar, num) =
   664   let val offset = ord zerochar;
   665       fun chrof n = chr (offset + n)
   666   in implode (map chrof (radixpand (base, num))) end;
   667 
   668 
   669 val string_of_int = Int.toString;
   670 
   671 fun signed_string_of_int i =
   672   if i < 0 then "-" ^ string_of_int (~ i) else string_of_int i;
   673 
   674 fun string_of_indexname (a, 0) = a
   675   | string_of_indexname (a, i) = a ^ "_" ^ string_of_int i;
   676 
   677 
   678 (* read integers *)
   679 
   680 fun read_radix_int radix cs =
   681   let
   682     val zero = ord "0";
   683     val limit = zero + radix;
   684     fun scan (num, []) = (num, [])
   685       | scan (num, c :: cs) =
   686         if zero <= ord c andalso ord c < limit then
   687           scan (radix * num + (ord c - zero), cs)
   688         else (num, c :: cs);
   689   in scan (0, cs) end;
   690 
   691 val read_int = read_radix_int 10;
   692 
   693 fun oct_char s = chr (#1 (read_radix_int 8 (explode s)));
   694 
   695 
   696 
   697 (** strings **)
   698 
   699 (* functions tuned for strings, avoiding explode *)
   700 
   701 fun nth_string str i =
   702   (case try String.substring (str, i, 1) of
   703     SOME s => s
   704   | NONE => raise Subscript);
   705 
   706 fun fold_string f str x0 =
   707   let
   708     val n = size str;
   709     fun iter (x, i) =
   710       if i < n then iter (f (String.substring (str, i, 1)) x, i + 1) else x;
   711   in iter (x0, 0) end;
   712 
   713 fun exists_string pred str =
   714   let
   715     val n = size str;
   716     fun ex i = i < n andalso (pred (String.substring (str, i, 1)) orelse ex (i + 1));
   717   in ex 0 end;
   718 
   719 fun forall_string pred = not o exists_string (not o pred);
   720 
   721 (*enclose in brackets*)
   722 fun enclose lpar rpar str = lpar ^ str ^ rpar;
   723 fun unenclose str = String.substring (str, 1, size str - 2);
   724 
   725 (*simple quoting (does not escape special chars)*)
   726 val quote = enclose "\"" "\"";
   727 
   728 (*space_implode "..." (explode "hello") = "h...e...l...l...o"*)
   729 fun space_implode a bs = implode (separate a bs);
   730 
   731 val commas = space_implode ", ";
   732 val commas_quote = commas o map quote;
   733 
   734 (*concatenate messages, one per line, into a string*)
   735 val cat_lines = space_implode "\n";
   736 
   737 (*space_explode "." "h.e..l.lo" = ["h", "e", "", "l", "lo"]*)
   738 fun space_explode _ "" = []
   739   | space_explode sep s = String.fields (fn c => str c = sep) s;
   740 
   741 val split_lines = space_explode "\n";
   742 
   743 fun prefix_lines "" txt = txt
   744   | prefix_lines prfx txt = txt |> split_lines |> map (fn s => prfx ^ s) |> cat_lines;
   745 
   746 fun untabify chs =
   747   let
   748     val tab_width = 8;
   749 
   750     fun untab pos [] ys = rev ys
   751       | untab pos ("\n" :: xs) ys = untab 0 xs ("\n" :: ys)
   752       | untab pos ("\t" :: xs) ys =
   753           let val d = tab_width - (pos mod tab_width)
   754           in untab (pos + d) xs (funpow d (cons " ") ys) end
   755       | untab pos (c :: xs) ys = untab (pos + 1) xs (c :: ys);
   756   in
   757     if not (exists (fn c => c = "\t") chs) then chs
   758     else untab 0 chs []
   759   end;
   760 
   761 fun prefix prfx s = prfx ^ s;
   762 fun suffix sffx s = s ^ sffx;
   763 
   764 fun unprefix prfx s =
   765   if String.isPrefix prfx s then String.substring (s, size prfx, size s - size prfx)
   766   else raise Fail "unprefix";
   767 
   768 fun unsuffix sffx s =
   769   if String.isSuffix sffx s then String.substring (s, 0, size s - size sffx)
   770   else raise Fail "unsuffix";
   771 
   772 fun replicate_string (0: int) _ = ""
   773   | replicate_string 1 a = a
   774   | replicate_string k a =
   775       if k mod 2 = 0 then replicate_string (k div 2) (a ^ a)
   776       else replicate_string (k div 2) (a ^ a) ^ a;
   777 
   778 
   779 
   780 (** lists as sets -- see also Pure/General/ord_list.ML **)
   781 
   782 (*canonical member, insert, remove*)
   783 fun member eq list x =
   784   let
   785     fun memb [] = false
   786       | memb (y :: ys) = eq (x, y) orelse memb ys;
   787   in memb list end;
   788 
   789 fun insert eq x xs = if member eq xs x then xs else x :: xs;
   790 fun remove eq x xs = if member eq xs x then filter_out (fn y => eq (x, y)) xs else xs;
   791 fun update eq x xs = cons x (remove eq x xs);
   792 
   793 fun subtract eq = fold (remove eq);
   794 
   795 fun merge _ ([], ys) = ys
   796   | merge eq (xs, ys) = fold_rev (insert eq) ys xs;
   797 
   798 (*old-style infixes*)
   799 fun x mem xs = member (op =) xs x;
   800 fun (x: int) mem_int xs = member (op =) xs x;
   801 fun (x: string) mem_string xs = member (op =) xs x;
   802 
   803 
   804 (*union of sets represented as lists: no repetitions*)
   805 fun xs union [] = xs
   806   | [] union ys = ys
   807   | (x :: xs) union ys = xs union (insert (op =) x ys);
   808 
   809 (*union of sets, optimized version for ints*)
   810 fun (xs:int list) union_int [] = xs
   811   | [] union_int ys = ys
   812   | (x :: xs) union_int ys = xs union_int (insert (op =) x ys);
   813 
   814 (*union of sets, optimized version for strings*)
   815 fun (xs:string list) union_string [] = xs
   816   | [] union_string ys = ys
   817   | (x :: xs) union_string ys = xs union_string (insert (op =) x ys);
   818 
   819 (*generalized union*)
   820 fun gen_union eq (xs, []) = xs
   821   | gen_union eq ([], ys) = ys
   822   | gen_union eq (x :: xs, ys) = gen_union eq (xs, insert eq x ys);
   823 
   824 
   825 (*intersection*)
   826 fun [] inter ys = []
   827   | (x :: xs) inter ys =
   828       if x mem ys then x :: (xs inter ys) else xs inter ys;
   829 
   830 (*intersection, optimized version for ints*)
   831 fun ([]:int list) inter_int ys = []
   832   | (x :: xs) inter_int ys =
   833       if x mem_int ys then x :: (xs inter_int ys) else xs inter_int ys;
   834 
   835 (*intersection, optimized version for strings *)
   836 fun ([]:string list) inter_string ys = []
   837   | (x :: xs) inter_string ys =
   838       if x mem_string ys then x :: (xs inter_string ys) else xs inter_string ys;
   839 
   840 (*generalized intersection*)
   841 fun gen_inter eq ([], ys) = []
   842   | gen_inter eq (x::xs, ys) =
   843       if member eq ys x then x :: gen_inter eq (xs, ys)
   844       else gen_inter eq (xs, ys);
   845 
   846 
   847 (*subset*)
   848 fun [] subset ys = true
   849   | (x :: xs) subset ys = x mem ys andalso xs subset ys;
   850 
   851 (*subset, optimized version for ints*)
   852 fun ([]: int list) subset_int ys = true
   853   | (x :: xs) subset_int ys = x mem_int ys andalso xs subset_int ys;
   854 
   855 (*subset, optimized version for strings*)
   856 fun ([]: string list) subset_string ys = true
   857   | (x :: xs) subset_string ys = x mem_string ys andalso xs subset_string ys;
   858 
   859 (*set equality*)
   860 fun eq_set (xs, ys) =
   861   xs = ys orelse (xs subset ys andalso ys subset xs);
   862 
   863 (*set equality for strings*)
   864 fun eq_set_string ((xs: string list), ys) =
   865   xs = ys orelse (xs subset_string ys andalso ys subset_string xs);
   866 
   867 fun gen_subset eq (xs, ys) = forall (member eq ys) xs;
   868 
   869 fun gen_eq_set eq (xs, ys) =
   870   eq_list eq (xs, ys) orelse
   871     (gen_subset eq (xs, ys) andalso gen_subset (eq o swap) (ys, xs));
   872 
   873 
   874 (*removing an element from a list WITHOUT duplicates*)
   875 fun (y :: ys) \ x = if x = y then ys else y :: (ys \ x)
   876   | [] \ x = [];
   877 fun ys \\ xs = foldl (op \) (ys,xs);
   878 
   879 
   880 (*makes a list of the distinct members of the input; preserves order, takes
   881   first of equal elements*)
   882 fun distinct eq lst =
   883   let
   884     fun dist (rev_seen, []) = rev rev_seen
   885       | dist (rev_seen, x :: xs) =
   886           if member eq rev_seen x then dist (rev_seen, xs)
   887           else dist (x :: rev_seen, xs);
   888   in dist ([], lst) end;
   889 
   890 (*returns a list containing all repeated elements exactly once; preserves
   891   order, takes first of equal elements*)
   892 fun duplicates eq lst =
   893   let
   894     fun dups (rev_dups, []) = rev rev_dups
   895       | dups (rev_dups, x :: xs) =
   896           if member eq rev_dups x orelse not (member eq xs x) then
   897             dups (rev_dups, xs)
   898           else dups (x :: rev_dups, xs);
   899   in dups ([], lst) end;
   900 
   901 fun has_duplicates eq =
   902   let
   903     fun dups [] = false
   904       | dups (x :: xs) = member eq xs x orelse dups xs;
   905   in dups end;
   906 
   907 
   908 
   909 (** lists as multisets **)
   910 
   911 fun remove1 _ _ [] = raise Empty
   912   | remove1 eq y (x::xs) = if eq (y, x) then xs else x :: remove1 eq y xs;
   913 
   914 fun submultiset _ ([], _)  = true
   915   | submultiset eq (x :: xs, ys) = member eq ys x andalso submultiset eq (xs, remove1 eq x ys);
   916 
   917 
   918 
   919 (** orders **)
   920 
   921 fun is_equal EQUAL = true
   922   | is_equal _ = false;
   923 
   924 fun rev_order LESS = GREATER
   925   | rev_order EQUAL = EQUAL
   926   | rev_order GREATER = LESS;
   927 
   928 (*assume rel is a linear strict order*)
   929 fun make_ord rel (x, y) =
   930   if rel (x, y) then LESS
   931   else if rel (y, x) then GREATER
   932   else EQUAL;
   933 
   934 fun bool_ord (false, true) = LESS
   935   | bool_ord (true, false) = GREATER
   936   | bool_ord _ = EQUAL;
   937 
   938 val int_ord = Int.compare;
   939 val string_ord = String.compare;
   940 
   941 fun fast_string_ord (s1, s2) =
   942   (case int_ord (size s1, size s2) of EQUAL => string_ord (s1, s2) | ord => ord);
   943 
   944 fun option_ord ord (SOME x, SOME y) = ord (x, y)
   945   | option_ord _ (NONE, NONE) = EQUAL
   946   | option_ord _ (NONE, SOME _) = LESS
   947   | option_ord _ (SOME _, NONE) = GREATER;
   948 
   949 (*lexicographic product*)
   950 fun prod_ord a_ord b_ord ((x, y), (x', y')) =
   951   (case a_ord (x, x') of EQUAL => b_ord (y, y') | ord => ord);
   952 
   953 (*dictionary order -- in general NOT well-founded!*)
   954 fun dict_ord elem_ord (x :: xs, y :: ys) =
   955       (case elem_ord (x, y) of EQUAL => dict_ord elem_ord (xs, ys) | ord => ord)
   956   | dict_ord _ ([], []) = EQUAL
   957   | dict_ord _ ([], _ :: _) = LESS
   958   | dict_ord _ (_ :: _, []) = GREATER;
   959 
   960 (*lexicographic product of lists*)
   961 fun list_ord elem_ord (xs, ys) =
   962   (case int_ord (length xs, length ys) of EQUAL => dict_ord elem_ord (xs, ys) | ord => ord);
   963 
   964 
   965 (* sorting *)
   966 
   967 (*quicksort -- stable, i.e. does not reorder equal elements*)
   968 fun quicksort unique ord =
   969   let
   970     fun qsort [] = []
   971       | qsort (xs as [_]) = xs
   972       | qsort (xs as [x, y]) =
   973           (case ord (x, y) of
   974             LESS => xs
   975           | EQUAL => if unique then [x] else xs
   976           | GREATER => [y, x])
   977       | qsort xs =
   978           let val (lts, eqs, gts) = part (nth xs (length xs div 2)) xs
   979           in qsort lts @ eqs @ qsort gts end
   980     and part _ [] = ([], [], [])
   981       | part pivot (x :: xs) = add (ord (x, pivot)) x (part pivot xs)
   982     and add LESS x (lts, eqs, gts) = (x :: lts, eqs, gts)
   983       | add EQUAL x (lts, [], gts) = (lts, [x], gts)
   984       | add EQUAL x (res as (lts, eqs, gts)) = if unique then res else (lts, x :: eqs, gts)
   985       | add GREATER x (lts, eqs, gts) = (lts, eqs, x :: gts);
   986   in qsort end;
   987 
   988 fun sort ord = quicksort false ord;
   989 fun sort_distinct ord = quicksort true ord;
   990 
   991 val sort_strings = sort string_ord;
   992 fun sort_wrt sel xs = sort (string_ord o pairself sel) xs;
   993 
   994 
   995 
   996 (** random numbers **)
   997 
   998 exception RANDOM;
   999 
  1000 fun rmod x y = x - y * Real.realFloor (x / y);
  1001 
  1002 local
  1003   val a = 16807.0;
  1004   val m = 2147483647.0;
  1005   val random_seed = ref 1.0;
  1006 in
  1007 
  1008 fun random () = CRITICAL (fn () =>
  1009   let val r = rmod (a * ! random_seed) m
  1010   in (random_seed := r; r) end);
  1011 
  1012 end;
  1013 
  1014 fun random_range l h =
  1015   if h < l orelse l < 0 then raise RANDOM
  1016   else l + Real.floor (rmod (random ()) (real (h - l + 1)));
  1017 
  1018 fun one_of xs = nth xs (random_range 0 (length xs - 1));
  1019 
  1020 fun frequency xs =
  1021   let
  1022     val sum = foldl op + (0, map fst xs);
  1023     fun pick n ((k: int, x) :: xs) =
  1024       if n <= k then x else pick (n - k) xs
  1025   in pick (random_range 1 sum) xs end;
  1026 
  1027 
  1028 
  1029 (** misc **)
  1030 
  1031 fun divide_and_conquer decomp x =
  1032   let val (ys, recomb) = decomp x
  1033   in recomb (map (divide_and_conquer decomp) ys) end;
  1034 
  1035 
  1036 (*Partition a list into buckets  [ bi, b(i+1), ..., bj ]
  1037    putting x in bk if p(k)(x) holds.  Preserve order of elements if possible.*)
  1038 fun partition_list p i j =
  1039   let fun part k xs =
  1040             if k>j then
  1041               (case xs of [] => []
  1042                          | _ => raise Fail "partition_list")
  1043             else
  1044             let val (ns, rest) = List.partition (p k) xs;
  1045             in  ns :: part(k+1)rest  end
  1046   in  part (i: int) end;
  1047 
  1048 fun partition_eq (eq:'a * 'a -> bool) =
  1049   let
  1050     fun part [] = []
  1051       | part (x :: ys) =
  1052           let val (xs, xs') = List.partition (fn y => eq (x, y)) ys
  1053           in (x::xs)::(part xs') end
  1054   in part end;
  1055 
  1056 
  1057 
  1058 (* generating identifiers *)
  1059 
  1060 (** Freshly generated identifiers; supplied prefix MUST start with a letter **)
  1061 local
  1062 (*Maps 0-61 to A-Z, a-z, 0-9; exclude _ or ' to avoid clash with internal/unusual indentifiers*)
  1063 fun gensym_char i =
  1064   if i<26 then chr (ord "A" + i)
  1065   else if i<52 then chr (ord "a" + i - 26)
  1066   else chr (ord "0" + i - 52);
  1067 
  1068 val char_vec = Vector.tabulate (62, gensym_char);
  1069 fun newid n = implode (map (fn i => Vector.sub (char_vec, i)) (radixpand (62, n)));
  1070 
  1071 val gensym_seed = ref (0: int);
  1072 
  1073 in
  1074   fun gensym pre = pre ^ newid (NAMED_CRITICAL "gensym" (fn () => inc gensym_seed));
  1075 end;
  1076 
  1077 
  1078 (* stamps and serial numbers *)
  1079 
  1080 type stamp = unit ref;
  1081 val stamp: unit -> stamp = ref;
  1082 
  1083 type serial = int;
  1084 local val count = ref (0: int)
  1085 in fun serial () = NAMED_CRITICAL "serial" (fn () => inc count) end;
  1086 
  1087 val serial_string = string_of_int o serial;
  1088 
  1089 
  1090 (* generic objects *)
  1091 
  1092 (*note that the builtin exception datatype may be extended by new
  1093   constructors at any time*)
  1094 structure Object = struct type T = exn end;
  1095 
  1096 end;
  1097 
  1098 structure BasicLibrary: BASIC_LIBRARY = Library;
  1099 open BasicLibrary;