src/HOL/Auth/OtwayRees_AN.thy
author paulson
Tue Mar 25 10:43:01 1997 +0100 (1997-03-25)
changeset 2837 dee1c7f1f576
parent 2516 4d68fbe6378b
child 3465 e85c24717cad
permissions -rw-r--r--
Trivial renamings (for consistency with CSFW papers)
     1 (*  Title:      HOL/Auth/OtwayRees
     2     ID:         $Id$
     3     Author:     Lawrence C Paulson, Cambridge University Computer Laboratory
     4     Copyright   1996  University of Cambridge
     5 
     6 Inductive relation "otway" for the Otway-Rees protocol.
     7 
     8 Simplified version with minimal encryption but explicit messages
     9 
    10 Note that the formalization does not even assume that nonces are fresh.
    11 This is because the protocol does not rely on uniqueness of nonces for
    12 security, only for freshness, and the proof script does not prove freshness
    13 properties.
    14 
    15 From page 11 of
    16   Abadi and Needham.  Prudent Engineering Practice for Cryptographic Protocols.
    17   IEEE Trans. SE 22 (1), 1996
    18 *)
    19 
    20 OtwayRees_AN = Shared + 
    21 
    22 consts  otway   :: agent set => event list set
    23 inductive "otway lost"
    24   intrs 
    25          (*Initial trace is empty*)
    26     Nil  "[]: otway lost"
    27 
    28          (*The spy MAY say anything he CAN say.  We do not expect him to
    29            invent new nonces here, but he can also use NS1.  Common to
    30            all similar protocols.*)
    31     Fake "[| evs: otway lost;  B ~= Spy;  
    32              X: synth (analz (sees lost Spy evs)) |]
    33           ==> Says Spy B X  # evs : otway lost"
    34 
    35          (*Alice initiates a protocol run*)
    36     OR1  "[| evs: otway lost;  A ~= B;  B ~= Server |]
    37           ==> Says A B {|Agent A, Agent B, Nonce NA|} # evs : otway lost"
    38 
    39          (*Bob's response to Alice's message.  Bob doesn't know who 
    40 	   the sender is, hence the A' in the sender field.*)
    41     OR2  "[| evs: otway lost;  B ~= Server;
    42              Says A' B {|Agent A, Agent B, Nonce NA|} : set_of_list evs |]
    43           ==> Says B Server {|Agent A, Agent B, Nonce NA, Nonce NB|}
    44                  # evs : otway lost"
    45 
    46          (*The Server receives Bob's message.  Then he sends a new
    47            session key to Bob with a packet for forwarding to Alice.*)
    48     OR3  "[| evs: otway lost;  B ~= Server;  A ~= B;  Key KAB ~: used evs;
    49              Says B' Server {|Agent A, Agent B, Nonce NA, Nonce NB|}
    50                : set_of_list evs |]
    51           ==> Says Server B 
    52                {|Crypt (shrK A) {|Nonce NA, Agent A, Agent B, Key KAB|},
    53                  Crypt (shrK B) {|Nonce NB, Agent A, Agent B, Key KAB|}|}
    54               # evs : otway lost"
    55 
    56          (*Bob receives the Server's (?) message and compares the Nonces with
    57 	   those in the message he previously sent the Server.*)
    58     OR4  "[| evs: otway lost;  A ~= B;
    59              Says B Server {|Agent A, Agent B, Nonce NA, Nonce NB|}
    60                : set_of_list evs;
    61              Says S' B {|X, Crypt(shrK B){|Nonce NB,Agent A,Agent B,Key K|}|}
    62                : set_of_list evs |]
    63           ==> Says B A X # evs : otway lost"
    64 
    65          (*This message models possible leaks of session keys.  The nonces
    66            identify the protocol run.  B is not assumed to know shrK A.*)
    67     Oops "[| evs: otway lost;  B ~= Spy;
    68              Says Server B 
    69                       {|Crypt (shrK A) {|Nonce NA, Agent A, Agent B, Key K|}, 
    70                         Crypt (shrK B) {|Nonce NB, Agent A, Agent B, Key K|}|}
    71                : set_of_list evs |]
    72           ==> Says B Spy {|Nonce NA, Nonce NB, Key K|} # evs : otway lost"
    73 
    74 end