src/HOL/Library/Formal_Power_Series.thy
author avigad
Tue Jul 14 20:58:53 2009 -0400 (2009-07-14)
changeset 32042 df28ead1cf19
parent 31968 0314441a53a6
child 32047 c141f139ce26
permissions -rw-r--r--
Repairs regarding new Fact.thy.
     1 (*  Title:      Formal_Power_Series.thy
     2     Author:     Amine Chaieb, University of Cambridge
     3 *)
     4 
     5 header{* A formalization of formal power series *}
     6 
     7 theory Formal_Power_Series
     8 imports Complex_Main
     9 begin
    10 
    11 
    12 subsection {* The type of formal power series*}
    13 
    14 typedef (open) 'a fps = "{f :: nat \<Rightarrow> 'a. True}"
    15   morphisms fps_nth Abs_fps
    16   by simp
    17 
    18 notation fps_nth (infixl "$" 75)
    19 
    20 lemma expand_fps_eq: "p = q \<longleftrightarrow> (\<forall>n. p $ n = q $ n)"
    21   by (simp add: fps_nth_inject [symmetric] expand_fun_eq)
    22 
    23 lemma fps_ext: "(\<And>n. p $ n = q $ n) \<Longrightarrow> p = q"
    24   by (simp add: expand_fps_eq)
    25 
    26 lemma fps_nth_Abs_fps [simp]: "Abs_fps f $ n = f n"
    27   by (simp add: Abs_fps_inverse)
    28 
    29 text{* Definition of the basic elements 0 and 1 and the basic operations of addition, negation and multiplication *}
    30 
    31 instantiation fps :: (zero)  zero
    32 begin
    33 
    34 definition fps_zero_def:
    35   "0 = Abs_fps (\<lambda>n. 0)"
    36 
    37 instance ..
    38 end
    39 
    40 lemma fps_zero_nth [simp]: "0 $ n = 0"
    41   unfolding fps_zero_def by simp
    42 
    43 instantiation fps :: ("{one,zero}")  one
    44 begin
    45 
    46 definition fps_one_def:
    47   "1 = Abs_fps (\<lambda>n. if n = 0 then 1 else 0)"
    48 
    49 instance ..
    50 end
    51 
    52 lemma fps_one_nth [simp]: "1 $ n = (if n = 0 then 1 else 0)"
    53   unfolding fps_one_def by simp
    54 
    55 instantiation fps :: (plus)  plus
    56 begin
    57 
    58 definition fps_plus_def:
    59   "op + = (\<lambda>f g. Abs_fps (\<lambda>n. f $ n + g $ n))"
    60 
    61 instance ..
    62 end
    63 
    64 lemma fps_add_nth [simp]: "(f + g) $ n = f $ n + g $ n"
    65   unfolding fps_plus_def by simp
    66 
    67 instantiation fps :: (minus) minus
    68 begin
    69 
    70 definition fps_minus_def:
    71   "op - = (\<lambda>f g. Abs_fps (\<lambda>n. f $ n - g $ n))"
    72 
    73 instance ..
    74 end
    75 
    76 lemma fps_sub_nth [simp]: "(f - g) $ n = f $ n - g $ n"
    77   unfolding fps_minus_def by simp
    78 
    79 instantiation fps :: (uminus) uminus
    80 begin
    81 
    82 definition fps_uminus_def:
    83   "uminus = (\<lambda>f. Abs_fps (\<lambda>n. - (f $ n)))"
    84 
    85 instance ..
    86 end
    87 
    88 lemma fps_neg_nth [simp]: "(- f) $ n = - (f $ n)"
    89   unfolding fps_uminus_def by simp
    90 
    91 instantiation fps :: ("{comm_monoid_add, times}")  times
    92 begin
    93 
    94 definition fps_times_def:
    95   "op * = (\<lambda>f g. Abs_fps (\<lambda>n. \<Sum>i=0..n. f $ i * g $ (n - i)))"
    96 
    97 instance ..
    98 end
    99 
   100 lemma fps_mult_nth: "(f * g) $ n = (\<Sum>i=0..n. f$i * g$(n - i))"
   101   unfolding fps_times_def by simp
   102 
   103 declare atLeastAtMost_iff[presburger]
   104 declare Bex_def[presburger]
   105 declare Ball_def[presburger]
   106 
   107 lemma mult_delta_left:
   108   fixes x y :: "'a::mult_zero"
   109   shows "(if b then x else 0) * y = (if b then x * y else 0)"
   110   by simp
   111 
   112 lemma mult_delta_right:
   113   fixes x y :: "'a::mult_zero"
   114   shows "x * (if b then y else 0) = (if b then x * y else 0)"
   115   by simp
   116 
   117 lemma cond_value_iff: "f (if b then x else y) = (if b then f x else f y)"
   118   by auto
   119 lemma cond_application_beta: "(if b then f else g) x = (if b then f x else g x)"
   120   by auto
   121 
   122 subsection{* Formal power series form a commutative ring with unity, if the range of sequences
   123   they represent is a commutative ring with unity*}
   124 
   125 instance fps :: (semigroup_add) semigroup_add
   126 proof
   127   fix a b c :: "'a fps" show "a + b + c = a + (b + c)"
   128     by (simp add: fps_ext add_assoc)
   129 qed
   130 
   131 instance fps :: (ab_semigroup_add) ab_semigroup_add
   132 proof
   133   fix a b :: "'a fps" show "a + b = b + a"
   134     by (simp add: fps_ext add_commute)
   135 qed
   136 
   137 lemma fps_mult_assoc_lemma:
   138   fixes k :: nat and f :: "nat \<Rightarrow> nat \<Rightarrow> nat \<Rightarrow> 'a::comm_monoid_add"
   139   shows "(\<Sum>j=0..k. \<Sum>i=0..j. f i (j - i) (n - j)) =
   140          (\<Sum>j=0..k. \<Sum>i=0..k - j. f j i (n - j - i))"
   141 proof (induct k)
   142   case 0 show ?case by simp
   143 next
   144   case (Suc k) thus ?case
   145     by (simp add: Suc_diff_le setsum_addf add_assoc
   146              cong: strong_setsum_cong)
   147 qed
   148 
   149 instance fps :: (semiring_0) semigroup_mult
   150 proof
   151   fix a b c :: "'a fps"
   152   show "(a * b) * c = a * (b * c)"
   153   proof (rule fps_ext)
   154     fix n :: nat
   155     have "(\<Sum>j=0..n. \<Sum>i=0..j. a$i * b$(j - i) * c$(n - j)) =
   156           (\<Sum>j=0..n. \<Sum>i=0..n - j. a$j * b$i * c$(n - j - i))"
   157       by (rule fps_mult_assoc_lemma)
   158     thus "((a * b) * c) $ n = (a * (b * c)) $ n"
   159       by (simp add: fps_mult_nth setsum_right_distrib
   160                     setsum_left_distrib mult_assoc)
   161   qed
   162 qed
   163 
   164 lemma fps_mult_commute_lemma:
   165   fixes n :: nat and f :: "nat \<Rightarrow> nat \<Rightarrow> 'a::comm_monoid_add"
   166   shows "(\<Sum>i=0..n. f i (n - i)) = (\<Sum>i=0..n. f (n - i) i)"
   167 proof (rule setsum_reindex_cong)
   168   show "inj_on (\<lambda>i. n - i) {0..n}"
   169     by (rule inj_onI) simp
   170   show "{0..n} = (\<lambda>i. n - i) ` {0..n}"
   171     by (auto, rule_tac x="n - x" in image_eqI, simp_all)
   172 next
   173   fix i assume "i \<in> {0..n}"
   174   hence "n - (n - i) = i" by simp
   175   thus "f (n - i) i = f (n - i) (n - (n - i))" by simp
   176 qed
   177 
   178 instance fps :: (comm_semiring_0) ab_semigroup_mult
   179 proof
   180   fix a b :: "'a fps"
   181   show "a * b = b * a"
   182   proof (rule fps_ext)
   183     fix n :: nat
   184     have "(\<Sum>i=0..n. a$i * b$(n - i)) = (\<Sum>i=0..n. a$(n - i) * b$i)"
   185       by (rule fps_mult_commute_lemma)
   186     thus "(a * b) $ n = (b * a) $ n"
   187       by (simp add: fps_mult_nth mult_commute)
   188   qed
   189 qed
   190 
   191 instance fps :: (monoid_add) monoid_add
   192 proof
   193   fix a :: "'a fps" show "0 + a = a "
   194     by (simp add: fps_ext)
   195 next
   196   fix a :: "'a fps" show "a + 0 = a "
   197     by (simp add: fps_ext)
   198 qed
   199 
   200 instance fps :: (comm_monoid_add) comm_monoid_add
   201 proof
   202   fix a :: "'a fps" show "0 + a = a "
   203     by (simp add: fps_ext)
   204 qed
   205 
   206 instance fps :: (semiring_1) monoid_mult
   207 proof
   208   fix a :: "'a fps" show "1 * a = a"
   209     by (simp add: fps_ext fps_mult_nth mult_delta_left setsum_delta)
   210 next
   211   fix a :: "'a fps" show "a * 1 = a"
   212     by (simp add: fps_ext fps_mult_nth mult_delta_right setsum_delta')
   213 qed
   214 
   215 instance fps :: (cancel_semigroup_add) cancel_semigroup_add
   216 proof
   217   fix a b c :: "'a fps"
   218   assume "a + b = a + c" then show "b = c"
   219     by (simp add: expand_fps_eq)
   220 next
   221   fix a b c :: "'a fps"
   222   assume "b + a = c + a" then show "b = c"
   223     by (simp add: expand_fps_eq)
   224 qed
   225 
   226 instance fps :: (cancel_ab_semigroup_add) cancel_ab_semigroup_add
   227 proof
   228   fix a b c :: "'a fps"
   229   assume "a + b = a + c" then show "b = c"
   230     by (simp add: expand_fps_eq)
   231 qed
   232 
   233 instance fps :: (cancel_comm_monoid_add) cancel_comm_monoid_add ..
   234 
   235 instance fps :: (group_add) group_add
   236 proof
   237   fix a :: "'a fps" show "- a + a = 0"
   238     by (simp add: fps_ext)
   239 next
   240   fix a b :: "'a fps" show "a - b = a + - b"
   241     by (simp add: fps_ext diff_minus)
   242 qed
   243 
   244 instance fps :: (ab_group_add) ab_group_add
   245 proof
   246   fix a :: "'a fps"
   247   show "- a + a = 0"
   248     by (simp add: fps_ext)
   249 next
   250   fix a b :: "'a fps"
   251   show "a - b = a + - b"
   252     by (simp add: fps_ext)
   253 qed
   254 
   255 instance fps :: (zero_neq_one) zero_neq_one
   256   by default (simp add: expand_fps_eq)
   257 
   258 instance fps :: (semiring_0) semiring
   259 proof
   260   fix a b c :: "'a fps"
   261   show "(a + b) * c = a * c + b * c"
   262     by (simp add: expand_fps_eq fps_mult_nth left_distrib setsum_addf)
   263 next
   264   fix a b c :: "'a fps"
   265   show "a * (b + c) = a * b + a * c"
   266     by (simp add: expand_fps_eq fps_mult_nth right_distrib setsum_addf)
   267 qed
   268 
   269 instance fps :: (semiring_0) semiring_0
   270 proof
   271   fix a:: "'a fps" show "0 * a = 0"
   272     by (simp add: fps_ext fps_mult_nth)
   273 next
   274   fix a:: "'a fps" show "a * 0 = 0"
   275     by (simp add: fps_ext fps_mult_nth)
   276 qed
   277 
   278 instance fps :: (semiring_0_cancel) semiring_0_cancel ..
   279 
   280 subsection {* Selection of the nth power of the implicit variable in the infinite sum*}
   281 
   282 lemma fps_nonzero_nth: "f \<noteq> 0 \<longleftrightarrow> (\<exists> n. f $n \<noteq> 0)"
   283   by (simp add: expand_fps_eq)
   284 
   285 lemma fps_nonzero_nth_minimal:
   286   "f \<noteq> 0 \<longleftrightarrow> (\<exists>n. f $ n \<noteq> 0 \<and> (\<forall>m<n. f $ m = 0))"
   287 proof
   288   let ?n = "LEAST n. f $ n \<noteq> 0"
   289   assume "f \<noteq> 0"
   290   then have "\<exists>n. f $ n \<noteq> 0"
   291     by (simp add: fps_nonzero_nth)
   292   then have "f $ ?n \<noteq> 0"
   293     by (rule LeastI_ex)
   294   moreover have "\<forall>m<?n. f $ m = 0"
   295     by (auto dest: not_less_Least)
   296   ultimately have "f $ ?n \<noteq> 0 \<and> (\<forall>m<?n. f $ m = 0)" ..
   297   then show "\<exists>n. f $ n \<noteq> 0 \<and> (\<forall>m<n. f $ m = 0)" ..
   298 next
   299   assume "\<exists>n. f $ n \<noteq> 0 \<and> (\<forall>m<n. f $ m = 0)"
   300   then show "f \<noteq> 0" by (auto simp add: expand_fps_eq)
   301 qed
   302 
   303 lemma fps_eq_iff: "f = g \<longleftrightarrow> (\<forall>n. f $ n = g $n)"
   304   by (rule expand_fps_eq)
   305 
   306 lemma fps_setsum_nth: "(setsum f S) $ n = setsum (\<lambda>k. (f k) $ n) S"
   307 proof (cases "finite S")
   308   assume "\<not> finite S" then show ?thesis by simp
   309 next
   310   assume "finite S"
   311   then show ?thesis by (induct set: finite) auto
   312 qed
   313 
   314 subsection{* Injection of the basic ring elements and multiplication by scalars *}
   315 
   316 definition
   317   "fps_const c = Abs_fps (\<lambda>n. if n = 0 then c else 0)"
   318 
   319 lemma fps_nth_fps_const [simp]: "fps_const c $ n = (if n = 0 then c else 0)"
   320   unfolding fps_const_def by simp
   321 
   322 lemma fps_const_0_eq_0 [simp]: "fps_const 0 = 0"
   323   by (simp add: fps_ext)
   324 
   325 lemma fps_const_1_eq_1 [simp]: "fps_const 1 = 1"
   326   by (simp add: fps_ext)
   327 
   328 lemma fps_const_neg [simp]: "- (fps_const (c::'a::ring)) = fps_const (- c)"
   329   by (simp add: fps_ext)
   330 
   331 lemma fps_const_add [simp]: "fps_const (c::'a\<Colon>monoid_add) + fps_const d = fps_const (c + d)"
   332   by (simp add: fps_ext)
   333 lemma fps_const_sub [simp]: "fps_const (c::'a\<Colon>group_add) - fps_const d = fps_const (c - d)"
   334   by (simp add: fps_ext)
   335 lemma fps_const_mult[simp]: "fps_const (c::'a\<Colon>ring) * fps_const d = fps_const (c * d)"
   336   by (simp add: fps_eq_iff fps_mult_nth setsum_0')
   337 
   338 lemma fps_const_add_left: "fps_const (c::'a\<Colon>monoid_add) + f = Abs_fps (\<lambda>n. if n = 0 then c + f$0 else f$n)"
   339   by (simp add: fps_ext)
   340 
   341 lemma fps_const_add_right: "f + fps_const (c::'a\<Colon>monoid_add) = Abs_fps (\<lambda>n. if n = 0 then f$0 + c else f$n)"
   342   by (simp add: fps_ext)
   343 
   344 lemma fps_const_mult_left: "fps_const (c::'a\<Colon>semiring_0) * f = Abs_fps (\<lambda>n. c * f$n)"
   345   unfolding fps_eq_iff fps_mult_nth
   346   by (simp add: fps_const_def mult_delta_left setsum_delta)
   347 
   348 lemma fps_const_mult_right: "f * fps_const (c::'a\<Colon>semiring_0) = Abs_fps (\<lambda>n. f$n * c)"
   349   unfolding fps_eq_iff fps_mult_nth
   350   by (simp add: fps_const_def mult_delta_right setsum_delta')
   351 
   352 lemma fps_mult_left_const_nth [simp]: "(fps_const (c::'a::semiring_1) * f)$n = c* f$n"
   353   by (simp add: fps_mult_nth mult_delta_left setsum_delta)
   354 
   355 lemma fps_mult_right_const_nth [simp]: "(f * fps_const (c::'a::semiring_1))$n = f$n * c"
   356   by (simp add: fps_mult_nth mult_delta_right setsum_delta')
   357 
   358 subsection {* Formal power series form an integral domain*}
   359 
   360 instance fps :: (ring) ring ..
   361 
   362 instance fps :: (ring_1) ring_1
   363   by (intro_classes, auto simp add: diff_minus left_distrib)
   364 
   365 instance fps :: (comm_ring_1) comm_ring_1
   366   by (intro_classes, auto simp add: diff_minus left_distrib)
   367 
   368 instance fps :: (ring_no_zero_divisors) ring_no_zero_divisors
   369 proof
   370   fix a b :: "'a fps"
   371   assume a0: "a \<noteq> 0" and b0: "b \<noteq> 0"
   372   then obtain i j where i: "a$i\<noteq>0" "\<forall>k<i. a$k=0"
   373     and j: "b$j \<noteq>0" "\<forall>k<j. b$k =0" unfolding fps_nonzero_nth_minimal
   374     by blast+
   375   have "(a * b) $ (i+j) = (\<Sum>k=0..i+j. a$k * b$(i+j-k))"
   376     by (rule fps_mult_nth)
   377   also have "\<dots> = (a$i * b$(i+j-i)) + (\<Sum>k\<in>{0..i+j}-{i}. a$k * b$(i+j-k))"
   378     by (rule setsum_diff1') simp_all
   379   also have "(\<Sum>k\<in>{0..i+j}-{i}. a$k * b$(i+j-k)) = 0"
   380     proof (rule setsum_0' [rule_format])
   381       fix k assume "k \<in> {0..i+j} - {i}"
   382       then have "k < i \<or> i+j-k < j" by auto
   383       then show "a$k * b$(i+j-k) = 0" using i j by auto
   384     qed
   385   also have "a$i * b$(i+j-i) + 0 = a$i * b$j" by simp
   386   also have "a$i * b$j \<noteq> 0" using i j by simp
   387   finally have "(a*b) $ (i+j) \<noteq> 0" .
   388   then show "a*b \<noteq> 0" unfolding fps_nonzero_nth by blast
   389 qed
   390 
   391 instance fps :: (idom) idom ..
   392 
   393 instantiation fps :: (comm_ring_1) number_ring
   394 begin
   395 definition number_of_fps_def: "(number_of k::'a fps) = of_int k"
   396 
   397 instance proof
   398 qed (rule number_of_fps_def)
   399 end
   400 
   401 lemma number_of_fps_const: "(number_of k::('a::comm_ring_1) fps) = fps_const (of_int k)"
   402   
   403 proof(induct k rule: int_induct[where k=0])
   404   case base thus ?case unfolding number_of_fps_def of_int_0 by simp
   405 next
   406   case (step1 i) thus ?case unfolding number_of_fps_def 
   407     by (simp add: fps_const_add[symmetric] del: fps_const_add)
   408 next
   409   case (step2 i) thus ?case unfolding number_of_fps_def 
   410     by (simp add: fps_const_sub[symmetric] del: fps_const_sub)
   411 qed
   412 subsection{* The eXtractor series X*}
   413 
   414 lemma minus_one_power_iff: "(- (1::'a :: {comm_ring_1})) ^ n = (if even n then 1 else - 1)"
   415   by (induct n, auto)
   416 
   417 definition "X = Abs_fps (\<lambda>n. if n = 1 then 1 else 0)"
   418 lemma X_mult_nth[simp]: "(X * (f :: ('a::semiring_1) fps)) $n = (if n = 0 then 0 else f $ (n - 1))"
   419 proof-
   420   {assume n: "n \<noteq> 0"
   421     have fN: "finite {0 .. n}" by simp
   422     have "(X * f) $n = (\<Sum>i = 0..n. X $ i * f $ (n - i))" by (simp add: fps_mult_nth)
   423     also have "\<dots> = f $ (n - 1)"
   424       using n by (simp add: X_def mult_delta_left setsum_delta [OF fN])
   425   finally have ?thesis using n by simp }
   426   moreover
   427   {assume n: "n=0" hence ?thesis by (simp add: fps_mult_nth X_def)}
   428   ultimately show ?thesis by blast
   429 qed
   430 
   431 lemma X_mult_right_nth[simp]: "((f :: ('a::comm_semiring_1) fps) * X) $n = (if n = 0 then 0 else f $ (n - 1))"
   432   by (metis X_mult_nth mult_commute)
   433 
   434 lemma X_power_iff: "X^k = Abs_fps (\<lambda>n. if n = k then (1::'a::comm_ring_1) else 0)"
   435 proof(induct k)
   436   case 0 thus ?case by (simp add: X_def fps_eq_iff)
   437 next
   438   case (Suc k)
   439   {fix m
   440     have "(X^Suc k) $ m = (if m = 0 then (0::'a) else (X^k) $ (m - 1))"
   441       by (simp add: power_Suc del: One_nat_def)
   442     then     have "(X^Suc k) $ m = (if m = Suc k then (1::'a) else 0)"
   443       using Suc.hyps by (auto cong del: if_weak_cong)}
   444   then show ?case by (simp add: fps_eq_iff)
   445 qed
   446 
   447 lemma X_power_mult_nth: "(X^k * (f :: ('a::comm_ring_1) fps)) $n = (if n < k then 0 else f $ (n - k))"
   448   apply (induct k arbitrary: n)
   449   apply (simp)
   450   unfolding power_Suc mult_assoc
   451   by (case_tac n, auto)
   452 
   453 lemma X_power_mult_right_nth: "((f :: ('a::comm_ring_1) fps) * X^k) $n = (if n < k then 0 else f $ (n - k))"
   454   by (metis X_power_mult_nth mult_commute)
   455 
   456 
   457 
   458   
   459 subsection{* Formal Power series form a metric space *}
   460 
   461 definition (in dist) ball_def: "ball x r = {y. dist y x < r}"
   462 instantiation fps :: (comm_ring_1) dist
   463 begin
   464 
   465 definition dist_fps_def: "dist (a::'a fps) b = (if (\<exists>n. a$n \<noteq> b$n) then inverse (2 ^ The (leastP (\<lambda>n. a$n \<noteq> b$n))) else 0)"
   466 
   467 lemma dist_fps_ge0: "dist (a::'a fps) b \<ge> 0"
   468   by (simp add: dist_fps_def)
   469 
   470 lemma dist_fps_sym: "dist (a::'a fps) b = dist b a"
   471   apply (auto simp add: dist_fps_def)
   472   thm cong[OF refl]
   473   apply (rule cong[OF refl, where x="(\<lambda>n\<Colon>nat. a $ n \<noteq> b $ n)"])
   474   apply (rule ext)
   475   by auto
   476 instance ..
   477 end
   478 
   479 lemma fps_nonzero_least_unique: assumes a0: "a \<noteq> 0"
   480   shows "\<exists>! n. leastP (\<lambda>n. a$n \<noteq> 0) n"
   481 proof-
   482   from fps_nonzero_nth_minimal[of a] a0
   483   obtain n where n: "a$n \<noteq> 0" "\<forall>m < n. a$m = 0" by blast
   484   from n have ln: "leastP (\<lambda>n. a$n \<noteq> 0) n" 
   485     by (auto simp add: leastP_def setge_def not_le[symmetric])
   486   moreover
   487   {fix m assume "leastP (\<lambda>n. a$n \<noteq> 0) m"
   488     then have "m = n" using ln
   489       apply (auto simp add: leastP_def setge_def)
   490       apply (erule allE[where x=n])
   491       apply (erule allE[where x=m])
   492       by simp}
   493   ultimately show ?thesis by blast
   494 qed
   495 
   496 lemma fps_eq_least_unique: assumes ab: "(a::('a::ab_group_add) fps) \<noteq> b"
   497   shows "\<exists>! n. leastP (\<lambda>n. a$n \<noteq> b$n) n"
   498 using fps_nonzero_least_unique[of "a - b"] ab
   499 by auto
   500 
   501 instantiation fps :: (comm_ring_1) metric_space
   502 begin
   503 
   504 definition open_fps_def: "open (S :: 'a fps set) = (\<forall>a \<in> S. \<exists>r. r >0 \<and> ball a r \<subseteq> S)"
   505 
   506 instance
   507 proof
   508   fix S :: "'a fps set" 
   509   show "open S = (\<forall>x\<in>S. \<exists>e>0. \<forall>y. dist y x < e \<longrightarrow> y \<in> S)"
   510     by (auto simp add: open_fps_def ball_def subset_eq)
   511 next
   512 {  fix a b :: "'a fps"
   513   {assume ab: "a = b"
   514    then have "\<not> (\<exists>n. a$n \<noteq> b$n)" by simp
   515    then have "dist a b = 0" by (simp add: dist_fps_def)}
   516  moreover
   517  {assume d: "dist a b = 0"
   518    then have "\<forall>n. a$n = b$n" 
   519      by - (rule ccontr, simp add: dist_fps_def)
   520    then have "a = b" by (simp add: fps_eq_iff)}
   521  ultimately show "dist a b =0 \<longleftrightarrow> a = b" by blast}
   522 note th = this
   523 from th have th'[simp]: "\<And>a::'a fps. dist a a = 0" by simp
   524   fix a b c :: "'a fps"
   525   {assume ab: "a = b" then have d0: "dist a b = 0"  unfolding th .
   526     then have "dist a b \<le> dist a c + dist b c" 
   527       using dist_fps_ge0[of a c] dist_fps_ge0[of b c] by simp}
   528   moreover
   529   {assume c: "c = a \<or> c = b" then have "dist a b \<le> dist a c + dist b c"
   530       by (cases "c=a", simp_all add: th dist_fps_sym) }
   531   moreover
   532   {assume ab: "a \<noteq> b" and ac: "a \<noteq> c" and bc: "b \<noteq> c"
   533     let ?P = "\<lambda>a b n. a$n \<noteq> b$n"
   534     from fps_eq_least_unique[OF ab] fps_eq_least_unique[OF ac] 
   535       fps_eq_least_unique[OF bc]
   536     obtain nab nac nbc where nab: "leastP (?P a b) nab" 
   537       and nac: "leastP (?P a c) nac" 
   538       and nbc: "leastP (?P b c) nbc" by blast
   539     from nab have nab': "\<And>m. m < nab \<Longrightarrow> a$m = b$m" "a$nab \<noteq> b$nab"
   540       by (auto simp add: leastP_def setge_def)
   541     from nac have nac': "\<And>m. m < nac \<Longrightarrow> a$m = c$m" "a$nac \<noteq> c$nac"
   542       by (auto simp add: leastP_def setge_def)
   543     from nbc have nbc': "\<And>m. m < nbc \<Longrightarrow> b$m = c$m" "b$nbc \<noteq> c$nbc"
   544       by (auto simp add: leastP_def setge_def)
   545 
   546     have th0: "\<And>(a::'a fps) b. a \<noteq> b \<longleftrightarrow> (\<exists>n. a$n \<noteq> b$n)"
   547       by (simp add: fps_eq_iff)
   548     from ab ac bc nab nac nbc 
   549     have dab: "dist a b = inverse (2 ^ nab)" 
   550       and dac: "dist a c = inverse (2 ^ nac)" 
   551       and dbc: "dist b c = inverse (2 ^ nbc)"
   552       unfolding th0
   553       apply (simp_all add: dist_fps_def)
   554       apply (erule the1_equality[OF fps_eq_least_unique[OF ab]])
   555       apply (erule the1_equality[OF fps_eq_least_unique[OF ac]])
   556       by (erule the1_equality[OF fps_eq_least_unique[OF bc]])
   557     from ab ac bc have nz: "dist a b \<noteq> 0" "dist a c \<noteq> 0" "dist b c \<noteq> 0"
   558       unfolding th by simp_all
   559     from nz have pos: "dist a b > 0" "dist a c > 0" "dist b c > 0"
   560       using dist_fps_ge0[of a b] dist_fps_ge0[of a c] dist_fps_ge0[of b c] 
   561       by auto
   562     have th1: "\<And>n. (2::real)^n >0" by auto
   563     {assume h: "dist a b > dist a c + dist b c"
   564       then have gt: "dist a b > dist a c" "dist a b > dist b c"
   565 	using pos by auto
   566       from gt have gtn: "nab < nbc" "nab < nac"
   567 	unfolding dab dbc dac by (auto simp add: th1)
   568       from nac'(1)[OF gtn(2)] nbc'(1)[OF gtn(1)]
   569       have "a$nab = b$nab" by simp
   570       with nab'(2) have False  by simp}
   571     then have "dist a b \<le> dist a c + dist b c"
   572       by (auto simp add: not_le[symmetric]) }
   573   ultimately show "dist a b \<le> dist a c + dist b c" by blast
   574 qed
   575   
   576 end
   577 
   578 text{* The infinite sums and justification of the notation in textbooks*}
   579 
   580 lemma reals_power_lt_ex: assumes xp: "x > 0" and y1: "(y::real) > 1"
   581   shows "\<exists>k>0. (1/y)^k < x"
   582 proof-
   583   have yp: "y > 0" using y1 by simp
   584   from reals_Archimedean2[of "max 0 (- log y x) + 1"]
   585   obtain k::nat where k: "real k > max 0 (- log y x) + 1" by blast
   586   from k have kp: "k > 0" by simp
   587   from k have "real k > - log y x" by simp
   588   then have "ln y * real k > - ln x" unfolding log_def
   589     using ln_gt_zero_iff[OF yp] y1
   590     by (simp add: minus_divide_left field_simps del:minus_divide_left[symmetric] )
   591   then have "ln y * real k + ln x > 0" by simp
   592   then have "exp (real k * ln y + ln x) > exp 0"
   593     by (simp add: mult_ac)
   594   then have "y ^ k * x > 1"
   595     unfolding exp_zero exp_add exp_real_of_nat_mult
   596     exp_ln[OF xp] exp_ln[OF yp] by simp
   597   then have "x > (1/y)^k" using yp 
   598     by (simp add: field_simps nonzero_power_divide )
   599   then show ?thesis using kp by blast
   600 qed
   601 lemma X_nth[simp]: "X$n = (if n = 1 then 1 else 0)" by (simp add: X_def)
   602 lemma X_power_nth[simp]: "(X^k) $n = (if n = k then 1 else (0::'a::comm_ring_1))"
   603   by (simp add: X_power_iff)
   604  
   605 
   606 lemma fps_sum_rep_nth: "(setsum (%i. fps_const(a$i)*X^i) {0..m})$n = (if n \<le> m then a$n else (0::'a::comm_ring_1))"
   607   apply (auto simp add: fps_eq_iff fps_setsum_nth X_power_nth cond_application_beta cond_value_iff  cong del: if_weak_cong)
   608   by (simp add: setsum_delta')
   609   
   610 lemma fps_notation: 
   611   "(%n. setsum (%i. fps_const(a$i) * X^i) {0..n}) ----> a" (is "?s ----> a")
   612 proof-
   613     {fix r:: real
   614       assume rp: "r > 0"
   615       have th0: "(2::real) > 1" by simp
   616       from reals_power_lt_ex[OF rp th0] 
   617       obtain n0 where n0: "(1/2)^n0 < r" "n0 > 0" by blast
   618       {fix n::nat
   619 	assume nn0: "n \<ge> n0"
   620 	then have thnn0: "(1/2)^n <= (1/2 :: real)^n0"
   621 	  by (auto intro: power_decreasing)
   622 	{assume "?s n = a" then have "dist (?s n) a < r" 
   623 	    unfolding dist_eq_0_iff[of "?s n" a, symmetric]
   624 	    using rp by (simp del: dist_eq_0_iff)}
   625 	moreover
   626 	{assume neq: "?s n \<noteq> a"
   627 	  from fps_eq_least_unique[OF neq] 
   628 	  obtain k where k: "leastP (\<lambda>i. ?s n $ i \<noteq> a$i) k" by blast
   629 	  have th0: "\<And>(a::'a fps) b. a \<noteq> b \<longleftrightarrow> (\<exists>n. a$n \<noteq> b$n)"
   630 	    by (simp add: fps_eq_iff)
   631 	  from neq have dth: "dist (?s n) a = (1/2)^k"
   632 	    unfolding th0 dist_fps_def
   633 	    unfolding the1_equality[OF fps_eq_least_unique[OF neq], OF k]
   634 	    by (auto simp add: inverse_eq_divide power_divide)
   635 
   636 	  from k have kn: "k > n"
   637 	    apply (simp add: leastP_def setge_def fps_sum_rep_nth)
   638 	    by (cases "k \<le> n", auto)
   639 	  then have "dist (?s n) a < (1/2)^n" unfolding dth
   640 	    by (auto intro: power_strict_decreasing)
   641 	  also have "\<dots> <= (1/2)^n0" using nn0
   642 	    by (auto intro: power_decreasing)
   643 	  also have "\<dots> < r" using n0 by simp
   644 	  finally have "dist (?s n) a < r" .}
   645 	ultimately have "dist (?s n) a < r" by blast}
   646       then have "\<exists>n0. \<forall> n \<ge> n0. dist (?s n) a < r " by blast}
   647     then show ?thesis  unfolding  LIMSEQ_def by blast
   648   qed
   649 
   650 subsection{* Inverses of formal power series *}
   651 
   652 declare setsum_cong[fundef_cong]
   653 
   654 
   655 instantiation fps :: ("{comm_monoid_add,inverse, times, uminus}") inverse
   656 begin
   657 
   658 fun natfun_inverse:: "'a fps \<Rightarrow> nat \<Rightarrow> 'a" where
   659   "natfun_inverse f 0 = inverse (f$0)"
   660 | "natfun_inverse f n = - inverse (f$0) * setsum (\<lambda>i. f$i * natfun_inverse f (n - i)) {1..n}"
   661 
   662 definition fps_inverse_def:
   663   "inverse f = (if f$0 = 0 then 0 else Abs_fps (natfun_inverse f))"
   664 definition fps_divide_def: "divide = (\<lambda>(f::'a fps) g. f * inverse g)"
   665 instance ..
   666 end
   667 
   668 lemma fps_inverse_zero[simp]:
   669   "inverse (0 :: 'a::{comm_monoid_add,inverse, times, uminus} fps) = 0"
   670   by (simp add: fps_ext fps_inverse_def)
   671 
   672 lemma fps_inverse_one[simp]: "inverse (1 :: 'a::{division_ring,zero_neq_one} fps) = 1"
   673   apply (auto simp add: expand_fps_eq fps_inverse_def)
   674   by (case_tac n, auto)
   675 
   676 instance fps :: ("{comm_monoid_add,inverse, times, uminus}")  division_by_zero
   677   by default (rule fps_inverse_zero)
   678 
   679 lemma inverse_mult_eq_1[intro]: assumes f0: "f$0 \<noteq> (0::'a::field)"
   680   shows "inverse f * f = 1"
   681 proof-
   682   have c: "inverse f * f = f * inverse f" by (simp add: mult_commute)
   683   from f0 have ifn: "\<And>n. inverse f $ n = natfun_inverse f n"
   684     by (simp add: fps_inverse_def)
   685   from f0 have th0: "(inverse f * f) $ 0 = 1"
   686     by (simp add: fps_mult_nth fps_inverse_def)
   687   {fix n::nat assume np: "n >0 "
   688     from np have eq: "{0..n} = {0} \<union> {1 .. n}" by auto
   689     have d: "{0} \<inter> {1 .. n} = {}" by auto
   690     have f: "finite {0::nat}" "finite {1..n}" by auto
   691     from f0 np have th0: "- (inverse f$n) =
   692       (setsum (\<lambda>i. f$i * natfun_inverse f (n - i)) {1..n}) / (f$0)"
   693       by (cases n, simp, simp add: divide_inverse fps_inverse_def)
   694     from th0[symmetric, unfolded nonzero_divide_eq_eq[OF f0]]
   695     have th1: "setsum (\<lambda>i. f$i * natfun_inverse f (n - i)) {1..n} =
   696       - (f$0) * (inverse f)$n"
   697       by (simp add: ring_simps)
   698     have "(f * inverse f) $ n = (\<Sum>i = 0..n. f $i * natfun_inverse f (n - i))"
   699       unfolding fps_mult_nth ifn ..
   700     also have "\<dots> = f$0 * natfun_inverse f n
   701       + (\<Sum>i = 1..n. f$i * natfun_inverse f (n-i))"
   702       unfolding setsum_Un_disjoint[OF f d, unfolded eq[symmetric]]
   703       by simp
   704     also have "\<dots> = 0" unfolding th1 ifn by simp
   705     finally have "(inverse f * f)$n = 0" unfolding c . }
   706   with th0 show ?thesis by (simp add: fps_eq_iff)
   707 qed
   708 
   709 lemma fps_inverse_0_iff[simp]: "(inverse f)$0 = (0::'a::division_ring) \<longleftrightarrow> f$0 = 0"
   710   by (simp add: fps_inverse_def nonzero_imp_inverse_nonzero)
   711 
   712 lemma fps_inverse_eq_0_iff[simp]: "inverse f = (0:: ('a::field) fps) \<longleftrightarrow> f $0 = 0"
   713 proof-
   714   {assume "f$0 = 0" hence "inverse f = 0" by (simp add: fps_inverse_def)}
   715   moreover
   716   {assume h: "inverse f = 0" and c: "f $0 \<noteq> 0"
   717     from inverse_mult_eq_1[OF c] h have False by simp}
   718   ultimately show ?thesis by blast
   719 qed
   720 
   721 lemma fps_inverse_idempotent[intro]: assumes f0: "f$0 \<noteq> (0::'a::field)"
   722   shows "inverse (inverse f) = f"
   723 proof-
   724   from f0 have if0: "inverse f $ 0 \<noteq> 0" by simp
   725   from inverse_mult_eq_1[OF f0] inverse_mult_eq_1[OF if0]
   726   have th0: "inverse f * f = inverse f * inverse (inverse f)"   by (simp add: mult_ac)
   727   then show ?thesis using f0 unfolding mult_cancel_left by simp
   728 qed
   729 
   730 lemma fps_inverse_unique: assumes f0: "f$0 \<noteq> (0::'a::field)" and fg: "f*g = 1"
   731   shows "inverse f = g"
   732 proof-
   733   from inverse_mult_eq_1[OF f0] fg
   734   have th0: "inverse f * f = g * f" by (simp add: mult_ac)
   735   then show ?thesis using f0  unfolding mult_cancel_right
   736     by (auto simp add: expand_fps_eq)
   737 qed
   738 
   739 lemma fps_inverse_gp: "inverse (Abs_fps(\<lambda>n. (1::'a::field)))
   740   = Abs_fps (\<lambda>n. if n= 0 then 1 else if n=1 then - 1 else 0)"
   741   apply (rule fps_inverse_unique)
   742   apply simp
   743   apply (simp add: fps_eq_iff fps_mult_nth)
   744 proof(clarsimp)
   745   fix n::nat assume n: "n > 0"
   746   let ?f = "\<lambda>i. if n = i then (1\<Colon>'a) else if n - i = 1 then - 1 else 0"
   747   let ?g = "\<lambda>i. if i = n then 1 else if i=n - 1 then - 1 else 0"
   748   let ?h = "\<lambda>i. if i=n - 1 then - 1 else 0"
   749   have th1: "setsum ?f {0..n} = setsum ?g {0..n}"
   750     by (rule setsum_cong2) auto
   751   have th2: "setsum ?g {0..n - 1} = setsum ?h {0..n - 1}"
   752     using n apply - by (rule setsum_cong2) auto
   753   have eq: "{0 .. n} = {0.. n - 1} \<union> {n}" by auto
   754   from n have d: "{0.. n - 1} \<inter> {n} = {}" by auto
   755   have f: "finite {0.. n - 1}" "finite {n}" by auto
   756   show "setsum ?f {0..n} = 0"
   757     unfolding th1
   758     apply (simp add: setsum_Un_disjoint[OF f d, unfolded eq[symmetric]] del: One_nat_def)
   759     unfolding th2
   760     by(simp add: setsum_delta)
   761 qed
   762 
   763 subsection{* Formal Derivatives, and the MacLaurin theorem around 0*}
   764 
   765 definition "fps_deriv f = Abs_fps (\<lambda>n. of_nat (n + 1) * f $ (n + 1))"
   766 
   767 lemma fps_deriv_nth[simp]: "fps_deriv f $ n = of_nat (n +1) * f $ (n+1)" by (simp add: fps_deriv_def)
   768 
   769 lemma fps_deriv_linear[simp]: "fps_deriv (fps_const (a::'a::comm_semiring_1) * f + fps_const b * g) = fps_const a * fps_deriv f + fps_const b * fps_deriv g"
   770   unfolding fps_eq_iff fps_add_nth  fps_const_mult_left fps_deriv_nth by (simp add: ring_simps)
   771 
   772 lemma fps_deriv_mult[simp]:
   773   fixes f :: "('a :: comm_ring_1) fps"
   774   shows "fps_deriv (f * g) = f * fps_deriv g + fps_deriv f * g"
   775 proof-
   776   let ?D = "fps_deriv"
   777   {fix n::nat
   778     let ?Zn = "{0 ..n}"
   779     let ?Zn1 = "{0 .. n + 1}"
   780     let ?f = "\<lambda>i. i + 1"
   781     have fi: "inj_on ?f {0..n}" by (simp add: inj_on_def)
   782     have eq: "{1.. n+1} = ?f ` {0..n}" by auto
   783     let ?g = "\<lambda>i. of_nat (i+1) * g $ (i+1) * f $ (n - i) +
   784         of_nat (i+1)* f $ (i+1) * g $ (n - i)"
   785     let ?h = "\<lambda>i. of_nat i * g $ i * f $ ((n+1) - i) +
   786         of_nat i* f $ i * g $ ((n + 1) - i)"
   787     {fix k assume k: "k \<in> {0..n}"
   788       have "?h (k + 1) = ?g k" using k by auto}
   789     note th0 = this
   790     have eq': "{0..n +1}- {1 .. n+1} = {0}" by auto
   791     have s0: "setsum (\<lambda>i. of_nat i * f $ i * g $ (n + 1 - i)) ?Zn1 = setsum (\<lambda>i. of_nat (n + 1 - i) * f $ (n + 1 - i) * g $ i) ?Zn1"
   792       apply (rule setsum_reindex_cong[where f="\<lambda>i. n + 1 - i"])
   793       apply (simp add: inj_on_def Ball_def)
   794       apply presburger
   795       apply (rule set_ext)
   796       apply (presburger add: image_iff)
   797       by simp
   798     have s1: "setsum (\<lambda>i. f $ i * g $ (n + 1 - i)) ?Zn1 = setsum (\<lambda>i. f $ (n + 1 - i) * g $ i) ?Zn1"
   799       apply (rule setsum_reindex_cong[where f="\<lambda>i. n + 1 - i"])
   800       apply (simp add: inj_on_def Ball_def)
   801       apply presburger
   802       apply (rule set_ext)
   803       apply (presburger add: image_iff)
   804       by simp
   805     have "(f * ?D g + ?D f * g)$n = (?D g * f + ?D f * g)$n" by (simp only: mult_commute)
   806     also have "\<dots> = (\<Sum>i = 0..n. ?g i)"
   807       by (simp add: fps_mult_nth setsum_addf[symmetric])
   808     also have "\<dots> = setsum ?h {1..n+1}"
   809       using th0 setsum_reindex_cong[OF fi eq, of "?g" "?h"] by auto
   810     also have "\<dots> = setsum ?h {0..n+1}"
   811       apply (rule setsum_mono_zero_left)
   812       apply simp
   813       apply (simp add: subset_eq)
   814       unfolding eq'
   815       by simp
   816     also have "\<dots> = (fps_deriv (f * g)) $ n"
   817       apply (simp only: fps_deriv_nth fps_mult_nth setsum_addf)
   818       unfolding s0 s1
   819       unfolding setsum_addf[symmetric] setsum_right_distrib
   820       apply (rule setsum_cong2)
   821       by (auto simp add: of_nat_diff ring_simps)
   822     finally have "(f * ?D g + ?D f * g) $ n = ?D (f*g) $ n" .}
   823   then show ?thesis unfolding fps_eq_iff by auto
   824 qed
   825 
   826 lemma fps_deriv_X[simp]: "fps_deriv X = 1"
   827   by (simp add: fps_deriv_def X_def fps_eq_iff)
   828 
   829 lemma fps_deriv_neg[simp]: "fps_deriv (- (f:: ('a:: comm_ring_1) fps)) = - (fps_deriv f)"
   830   by (simp add: fps_eq_iff fps_deriv_def)
   831 lemma fps_deriv_add[simp]: "fps_deriv ((f:: ('a::comm_ring_1) fps) + g) = fps_deriv f + fps_deriv g"
   832   using fps_deriv_linear[of 1 f 1 g] by simp
   833 
   834 lemma fps_deriv_sub[simp]: "fps_deriv ((f:: ('a::comm_ring_1) fps) - g) = fps_deriv f - fps_deriv g"
   835   unfolding diff_minus by simp
   836 
   837 lemma fps_deriv_const[simp]: "fps_deriv (fps_const c) = 0"
   838   by (simp add: fps_ext fps_deriv_def fps_const_def)
   839 
   840 lemma fps_deriv_mult_const_left[simp]: "fps_deriv (fps_const (c::'a::comm_ring_1) * f) = fps_const c * fps_deriv f"
   841   by simp
   842 
   843 lemma fps_deriv_0[simp]: "fps_deriv 0 = 0"
   844   by (simp add: fps_deriv_def fps_eq_iff)
   845 
   846 lemma fps_deriv_1[simp]: "fps_deriv 1 = 0"
   847   by (simp add: fps_deriv_def fps_eq_iff )
   848 
   849 lemma fps_deriv_mult_const_right[simp]: "fps_deriv (f * fps_const (c::'a::comm_ring_1)) = fps_deriv f * fps_const c"
   850   by simp
   851 
   852 lemma fps_deriv_setsum: "fps_deriv (setsum f S) = setsum (\<lambda>i. fps_deriv (f i :: ('a::comm_ring_1) fps)) S"
   853 proof-
   854   {assume "\<not> finite S" hence ?thesis by simp}
   855   moreover
   856   {assume fS: "finite S"
   857     have ?thesis  by (induct rule: finite_induct[OF fS], simp_all)}
   858   ultimately show ?thesis by blast
   859 qed
   860 
   861 lemma fps_deriv_eq_0_iff[simp]: "fps_deriv f = 0 \<longleftrightarrow> (f = fps_const (f$0 :: 'a::{idom,semiring_char_0}))"
   862 proof-
   863   {assume "f= fps_const (f$0)" hence "fps_deriv f = fps_deriv (fps_const (f$0))" by simp
   864     hence "fps_deriv f = 0" by simp }
   865   moreover
   866   {assume z: "fps_deriv f = 0"
   867     hence "\<forall>n. (fps_deriv f)$n = 0" by simp
   868     hence "\<forall>n. f$(n+1) = 0" by (simp del: of_nat_Suc of_nat_add One_nat_def)
   869     hence "f = fps_const (f$0)"
   870       apply (clarsimp simp add: fps_eq_iff fps_const_def)
   871       apply (erule_tac x="n - 1" in allE)
   872       by simp}
   873   ultimately show ?thesis by blast
   874 qed
   875 
   876 lemma fps_deriv_eq_iff:
   877   fixes f:: "('a::{idom,semiring_char_0}) fps"
   878   shows "fps_deriv f = fps_deriv g \<longleftrightarrow> (f = fps_const(f$0 - g$0) + g)"
   879 proof-
   880   have "fps_deriv f = fps_deriv g \<longleftrightarrow> fps_deriv (f - g) = 0" by simp
   881   also have "\<dots> \<longleftrightarrow> f - g = fps_const ((f-g)$0)" unfolding fps_deriv_eq_0_iff ..
   882   finally show ?thesis by (simp add: ring_simps)
   883 qed
   884 
   885 lemma fps_deriv_eq_iff_ex: "(fps_deriv f = fps_deriv g) \<longleftrightarrow> (\<exists>(c::'a::{idom,semiring_char_0}). f = fps_const c + g)"
   886   apply auto unfolding fps_deriv_eq_iff by blast
   887 
   888 
   889 fun fps_nth_deriv :: "nat \<Rightarrow> ('a::semiring_1) fps \<Rightarrow> 'a fps" where
   890   "fps_nth_deriv 0 f = f"
   891 | "fps_nth_deriv (Suc n) f = fps_nth_deriv n (fps_deriv f)"
   892 
   893 lemma fps_nth_deriv_commute: "fps_nth_deriv (Suc n) f = fps_deriv (fps_nth_deriv n f)"
   894   by (induct n arbitrary: f, auto)
   895 
   896 lemma fps_nth_deriv_linear[simp]: "fps_nth_deriv n (fps_const (a::'a::comm_semiring_1) * f + fps_const b * g) = fps_const a * fps_nth_deriv n f + fps_const b * fps_nth_deriv n g"
   897   by (induct n arbitrary: f g, auto simp add: fps_nth_deriv_commute)
   898 
   899 lemma fps_nth_deriv_neg[simp]: "fps_nth_deriv n (- (f:: ('a:: comm_ring_1) fps)) = - (fps_nth_deriv n f)"
   900   by (induct n arbitrary: f, simp_all)
   901 
   902 lemma fps_nth_deriv_add[simp]: "fps_nth_deriv n ((f:: ('a::comm_ring_1) fps) + g) = fps_nth_deriv n f + fps_nth_deriv n g"
   903   using fps_nth_deriv_linear[of n 1 f 1 g] by simp
   904 
   905 lemma fps_nth_deriv_sub[simp]: "fps_nth_deriv n ((f:: ('a::comm_ring_1) fps) - g) = fps_nth_deriv n f - fps_nth_deriv n g"
   906   unfolding diff_minus fps_nth_deriv_add by simp
   907 
   908 lemma fps_nth_deriv_0[simp]: "fps_nth_deriv n 0 = 0"
   909   by (induct n, simp_all )
   910 
   911 lemma fps_nth_deriv_1[simp]: "fps_nth_deriv n 1 = (if n = 0 then 1 else 0)"
   912   by (induct n, simp_all )
   913 
   914 lemma fps_nth_deriv_const[simp]: "fps_nth_deriv n (fps_const c) = (if n = 0 then fps_const c else 0)"
   915   by (cases n, simp_all)
   916 
   917 lemma fps_nth_deriv_mult_const_left[simp]: "fps_nth_deriv n (fps_const (c::'a::comm_ring_1) * f) = fps_const c * fps_nth_deriv n f"
   918   using fps_nth_deriv_linear[of n "c" f 0 0 ] by simp
   919 
   920 lemma fps_nth_deriv_mult_const_right[simp]: "fps_nth_deriv n (f * fps_const (c::'a::comm_ring_1)) = fps_nth_deriv n f * fps_const c"
   921   using fps_nth_deriv_linear[of n "c" f 0 0] by (simp add: mult_commute)
   922 
   923 lemma fps_nth_deriv_setsum: "fps_nth_deriv n (setsum f S) = setsum (\<lambda>i. fps_nth_deriv n (f i :: ('a::comm_ring_1) fps)) S"
   924 proof-
   925   {assume "\<not> finite S" hence ?thesis by simp}
   926   moreover
   927   {assume fS: "finite S"
   928     have ?thesis  by (induct rule: finite_induct[OF fS], simp_all)}
   929   ultimately show ?thesis by blast
   930 qed
   931 
   932 lemma fps_deriv_maclauren_0: "(fps_nth_deriv k (f:: ('a::comm_semiring_1) fps)) $ 0 = of_nat (fact k) * f$(k)"
   933   by (induct k arbitrary: f) (auto simp add: ring_simps of_nat_mult)
   934 
   935 subsection {* Powers*}
   936 
   937 lemma fps_power_zeroth_eq_one: "a$0 =1 \<Longrightarrow> a^n $ 0 = (1::'a::semiring_1)"
   938   by (induct n, auto simp add: expand_fps_eq fps_mult_nth)
   939 
   940 lemma fps_power_first_eq: "(a:: 'a::comm_ring_1 fps)$0 =1 \<Longrightarrow> a^n $ 1 = of_nat n * a$1"
   941 proof(induct n)
   942   case 0 thus ?case by simp
   943 next
   944   case (Suc n)
   945   note h = Suc.hyps[OF `a$0 = 1`]
   946   show ?case unfolding power_Suc fps_mult_nth
   947     using h `a$0 = 1`  fps_power_zeroth_eq_one[OF `a$0=1`] by (simp add: ring_simps)
   948 qed
   949 
   950 lemma startsby_one_power:"a $ 0 = (1::'a::comm_ring_1) \<Longrightarrow> a^n $ 0 = 1"
   951   by (induct n, auto simp add: fps_mult_nth)
   952 
   953 lemma startsby_zero_power:"a $0 = (0::'a::comm_ring_1) \<Longrightarrow> n > 0 \<Longrightarrow> a^n $0 = 0"
   954   by (induct n, auto simp add: fps_mult_nth)
   955 
   956 lemma startsby_power:"a $0 = (v::'a::{comm_ring_1}) \<Longrightarrow> a^n $0 = v^n"
   957   by (induct n, auto simp add: fps_mult_nth power_Suc)
   958 
   959 lemma startsby_zero_power_iff[simp]:
   960   "a^n $0 = (0::'a::{idom}) \<longleftrightarrow> (n \<noteq> 0 \<and> a$0 = 0)"
   961 apply (rule iffI)
   962 apply (induct n, auto simp add: power_Suc fps_mult_nth)
   963 by (rule startsby_zero_power, simp_all)
   964 
   965 lemma startsby_zero_power_prefix:
   966   assumes a0: "a $0 = (0::'a::idom)"
   967   shows "\<forall>n < k. a ^ k $ n = 0"
   968   using a0
   969 proof(induct k rule: nat_less_induct)
   970   fix k assume H: "\<forall>m<k. a $0 =  0 \<longrightarrow> (\<forall>n<m. a ^ m $ n = 0)" and a0: "a $0 = (0\<Colon>'a)"
   971   let ?ths = "\<forall>m<k. a ^ k $ m = 0"
   972   {assume "k = 0" then have ?ths by simp}
   973   moreover
   974   {fix l assume k: "k = Suc l"
   975     {fix m assume mk: "m < k"
   976       {assume "m=0" hence "a^k $ m = 0" using startsby_zero_power[of a k] k a0
   977 	  by simp}
   978       moreover
   979       {assume m0: "m \<noteq> 0"
   980 	have "a ^k $ m = (a^l * a) $m" by (simp add: k power_Suc mult_commute)
   981 	also have "\<dots> = (\<Sum>i = 0..m. a ^ l $ i * a $ (m - i))" by (simp add: fps_mult_nth)
   982 	also have "\<dots> = 0" apply (rule setsum_0')
   983 	  apply auto
   984 	  apply (case_tac "aa = m")
   985 	  using a0
   986 	  apply simp
   987 	  apply (rule H[rule_format])
   988 	  using a0 k mk by auto
   989 	finally have "a^k $ m = 0" .}
   990     ultimately have "a^k $ m = 0" by blast}
   991     hence ?ths by blast}
   992   ultimately show ?ths by (cases k, auto)
   993 qed
   994 
   995 lemma startsby_zero_setsum_depends:
   996   assumes a0: "a $0 = (0::'a::idom)" and kn: "n \<ge> k"
   997   shows "setsum (\<lambda>i. (a ^ i)$k) {0 .. n} = setsum (\<lambda>i. (a ^ i)$k) {0 .. k}"
   998   apply (rule setsum_mono_zero_right)
   999   using kn apply auto
  1000   apply (rule startsby_zero_power_prefix[rule_format, OF a0])
  1001   by arith
  1002 
  1003 lemma startsby_zero_power_nth_same: assumes a0: "a$0 = (0::'a::{idom})"
  1004   shows "a^n $ n = (a$1) ^ n"
  1005 proof(induct n)
  1006   case 0 thus ?case by (simp add: power_0)
  1007 next
  1008   case (Suc n)
  1009   have "a ^ Suc n $ (Suc n) = (a^n * a)$(Suc n)" by (simp add: ring_simps power_Suc)
  1010   also have "\<dots> = setsum (\<lambda>i. a^n$i * a $ (Suc n - i)) {0.. Suc n}" by (simp add: fps_mult_nth)
  1011   also have "\<dots> = setsum (\<lambda>i. a^n$i * a $ (Suc n - i)) {n .. Suc n}"
  1012     apply (rule setsum_mono_zero_right)
  1013     apply simp
  1014     apply clarsimp
  1015     apply clarsimp
  1016     apply (rule startsby_zero_power_prefix[rule_format, OF a0])
  1017     apply arith
  1018     done
  1019   also have "\<dots> = a^n $ n * a$1" using a0 by simp
  1020   finally show ?case using Suc.hyps by (simp add: power_Suc)
  1021 qed
  1022 
  1023 lemma fps_inverse_power:
  1024   fixes a :: "('a::{field}) fps"
  1025   shows "inverse (a^n) = inverse a ^ n"
  1026 proof-
  1027   {assume a0: "a$0 = 0"
  1028     hence eq: "inverse a = 0" by (simp add: fps_inverse_def)
  1029     {assume "n = 0" hence ?thesis by simp}
  1030     moreover
  1031     {assume n: "n > 0"
  1032       from startsby_zero_power[OF a0 n] eq a0 n have ?thesis
  1033 	by (simp add: fps_inverse_def)}
  1034     ultimately have ?thesis by blast}
  1035   moreover
  1036   {assume a0: "a$0 \<noteq> 0"
  1037     have ?thesis
  1038       apply (rule fps_inverse_unique)
  1039       apply (simp add: a0)
  1040       unfolding power_mult_distrib[symmetric]
  1041       apply (rule ssubst[where t = "a * inverse a" and s= 1])
  1042       apply simp_all
  1043       apply (subst mult_commute)
  1044       by (rule inverse_mult_eq_1[OF a0])}
  1045   ultimately show ?thesis by blast
  1046 qed
  1047 
  1048 lemma fps_deriv_power: "fps_deriv (a ^ n) = fps_const (of_nat n :: 'a:: comm_ring_1) * fps_deriv a * a ^ (n - 1)"
  1049   apply (induct n, auto simp add: power_Suc ring_simps fps_const_add[symmetric] simp del: fps_const_add)
  1050   by (case_tac n, auto simp add: power_Suc ring_simps)
  1051 
  1052 lemma fps_inverse_deriv:
  1053   fixes a:: "('a :: field) fps"
  1054   assumes a0: "a$0 \<noteq> 0"
  1055   shows "fps_deriv (inverse a) = - fps_deriv a * inverse a ^ 2"
  1056 proof-
  1057   from inverse_mult_eq_1[OF a0]
  1058   have "fps_deriv (inverse a * a) = 0" by simp
  1059   hence "inverse a * fps_deriv a + fps_deriv (inverse a) * a = 0" by simp
  1060   hence "inverse a * (inverse a * fps_deriv a + fps_deriv (inverse a) * a) = 0"  by simp
  1061   with inverse_mult_eq_1[OF a0]
  1062   have "inverse a ^ 2 * fps_deriv a + fps_deriv (inverse a) = 0"
  1063     unfolding power2_eq_square
  1064     apply (simp add: ring_simps)
  1065     by (simp add: mult_assoc[symmetric])
  1066   hence "inverse a ^ 2 * fps_deriv a + fps_deriv (inverse a) - fps_deriv a * inverse a ^ 2 = 0 - fps_deriv a * inverse a ^ 2"
  1067     by simp
  1068   then show "fps_deriv (inverse a) = - fps_deriv a * inverse a ^ 2" by (simp add: ring_simps)
  1069 qed
  1070 
  1071 lemma fps_inverse_mult:
  1072   fixes a::"('a :: field) fps"
  1073   shows "inverse (a * b) = inverse a * inverse b"
  1074 proof-
  1075   {assume a0: "a$0 = 0" hence ab0: "(a*b)$0 = 0" by (simp add: fps_mult_nth)
  1076     from a0 ab0 have th: "inverse a = 0" "inverse (a*b) = 0" by simp_all
  1077     have ?thesis unfolding th by simp}
  1078   moreover
  1079   {assume b0: "b$0 = 0" hence ab0: "(a*b)$0 = 0" by (simp add: fps_mult_nth)
  1080     from b0 ab0 have th: "inverse b = 0" "inverse (a*b) = 0" by simp_all
  1081     have ?thesis unfolding th by simp}
  1082   moreover
  1083   {assume a0: "a$0 \<noteq> 0" and b0: "b$0 \<noteq> 0"
  1084     from a0 b0 have ab0:"(a*b) $ 0 \<noteq> 0" by (simp  add: fps_mult_nth)
  1085     from inverse_mult_eq_1[OF ab0]
  1086     have "inverse (a*b) * (a*b) * inverse a * inverse b = 1 * inverse a * inverse b" by simp
  1087     then have "inverse (a*b) * (inverse a * a) * (inverse b * b) = inverse a * inverse b"
  1088       by (simp add: ring_simps)
  1089     then have ?thesis using inverse_mult_eq_1[OF a0] inverse_mult_eq_1[OF b0] by simp}
  1090 ultimately show ?thesis by blast
  1091 qed
  1092 
  1093 lemma fps_inverse_deriv':
  1094   fixes a:: "('a :: field) fps"
  1095   assumes a0: "a$0 \<noteq> 0"
  1096   shows "fps_deriv (inverse a) = - fps_deriv a / a ^ 2"
  1097   using fps_inverse_deriv[OF a0]
  1098   unfolding power2_eq_square fps_divide_def
  1099     fps_inverse_mult by simp
  1100 
  1101 lemma inverse_mult_eq_1': assumes f0: "f$0 \<noteq> (0::'a::field)"
  1102   shows "f * inverse f= 1"
  1103   by (metis mult_commute inverse_mult_eq_1 f0)
  1104 
  1105 lemma fps_divide_deriv:   fixes a:: "('a :: field) fps"
  1106   assumes a0: "b$0 \<noteq> 0"
  1107   shows "fps_deriv (a / b) = (fps_deriv a * b - a * fps_deriv b) / b ^ 2"
  1108   using fps_inverse_deriv[OF a0]
  1109   by (simp add: fps_divide_def ring_simps power2_eq_square fps_inverse_mult inverse_mult_eq_1'[OF a0])
  1110 
  1111 
  1112 lemma fps_inverse_gp': "inverse (Abs_fps(\<lambda>n. (1::'a::field)))
  1113   = 1 - X"
  1114   by (simp add: fps_inverse_gp fps_eq_iff X_def)
  1115 
  1116 lemma fps_nth_deriv_X[simp]: "fps_nth_deriv n X = (if n = 0 then X else if n=1 then 1 else 0)"
  1117   by (cases "n", simp_all)
  1118 
  1119 
  1120 lemma fps_inverse_X_plus1:
  1121   "inverse (1 + X) = Abs_fps (\<lambda>n. (- (1::'a::{field})) ^ n)" (is "_ = ?r")
  1122 proof-
  1123   have eq: "(1 + X) * ?r = 1"
  1124     unfolding minus_one_power_iff
  1125     by (auto simp add: ring_simps fps_eq_iff)
  1126   show ?thesis by (auto simp add: eq intro: fps_inverse_unique)
  1127 qed
  1128 
  1129 
  1130 subsection{* Integration *}
  1131 
  1132 definition
  1133   fps_integral :: "'a::field_char_0 fps \<Rightarrow> 'a \<Rightarrow> 'a fps" where
  1134   "fps_integral a a0 = Abs_fps (\<lambda>n. if n = 0 then a0 else (a$(n - 1) / of_nat n))"
  1135 
  1136 lemma fps_deriv_fps_integral: "fps_deriv (fps_integral a a0) = a"
  1137   unfolding fps_integral_def fps_deriv_def
  1138   by (simp add: fps_eq_iff del: of_nat_Suc)
  1139 
  1140 lemma fps_integral_linear:
  1141   "fps_integral (fps_const a * f + fps_const b * g) (a*a0 + b*b0) =
  1142     fps_const a * fps_integral f a0 + fps_const b * fps_integral g b0"
  1143   (is "?l = ?r")
  1144 proof-
  1145   have "fps_deriv ?l = fps_deriv ?r" by (simp add: fps_deriv_fps_integral)
  1146   moreover have "?l$0 = ?r$0" by (simp add: fps_integral_def)
  1147   ultimately show ?thesis
  1148     unfolding fps_deriv_eq_iff by auto
  1149 qed
  1150 
  1151 subsection {* Composition of FPSs *}
  1152 definition fps_compose :: "('a::semiring_1) fps \<Rightarrow> 'a fps \<Rightarrow> 'a fps" (infixl "oo" 55) where
  1153   fps_compose_def: "a oo b = Abs_fps (\<lambda>n. setsum (\<lambda>i. a$i * (b^i$n)) {0..n})"
  1154 
  1155 lemma fps_compose_nth: "(a oo b)$n = setsum (\<lambda>i. a$i * (b^i$n)) {0..n}" by (simp add: fps_compose_def)
  1156 
  1157 lemma fps_compose_X[simp]: "a oo X = (a :: ('a :: comm_ring_1) fps)"
  1158   by (simp add: fps_ext fps_compose_def mult_delta_right setsum_delta')
  1159 
  1160 lemma fps_const_compose[simp]:
  1161   "fps_const (a::'a::{comm_ring_1}) oo b = fps_const (a)"
  1162   by (simp add: fps_eq_iff fps_compose_nth mult_delta_left setsum_delta)
  1163 
  1164 lemma number_of_compose[simp]: "(number_of k::('a::{comm_ring_1}) fps) oo b = number_of k"
  1165   unfolding number_of_fps_const by simp
  1166 
  1167 lemma X_fps_compose_startby0[simp]: "a$0 = 0 \<Longrightarrow> X oo a = (a :: ('a :: comm_ring_1) fps)"
  1168   by (simp add: fps_eq_iff fps_compose_def mult_delta_left setsum_delta
  1169                 power_Suc not_le)
  1170 
  1171 
  1172 subsection {* Rules from Herbert Wilf's Generatingfunctionology*}
  1173 
  1174 subsubsection {* Rule 1 *}
  1175   (* {a_{n+k}}_0^infty Corresponds to (f - setsum (\<lambda>i. a_i * x^i))/x^h, for h>0*)
  1176 
  1177 lemma fps_power_mult_eq_shift:
  1178   "X^Suc k * Abs_fps (\<lambda>n. a (n + Suc k)) = Abs_fps a - setsum (\<lambda>i. fps_const (a i :: 'a:: comm_ring_1) * X^i) {0 .. k}" (is "?lhs = ?rhs")
  1179 proof-
  1180   {fix n:: nat
  1181     have "?lhs $ n = (if n < Suc k then 0 else a n)"
  1182       unfolding X_power_mult_nth by auto
  1183     also have "\<dots> = ?rhs $ n"
  1184     proof(induct k)
  1185       case 0 thus ?case by (simp add: fps_setsum_nth power_Suc)
  1186     next
  1187       case (Suc k)
  1188       note th = Suc.hyps[symmetric]
  1189       have "(Abs_fps a - setsum (\<lambda>i. fps_const (a i :: 'a) * X^i) {0 .. Suc k})$n = (Abs_fps a - setsum (\<lambda>i. fps_const (a i :: 'a) * X^i) {0 .. k} - fps_const (a (Suc k)) * X^ Suc k) $ n" by (simp add: ring_simps)
  1190       also  have "\<dots> = (if n < Suc k then 0 else a n) - (fps_const (a (Suc k)) * X^ Suc k)$n"
  1191 	using th
  1192 	unfolding fps_sub_nth by simp
  1193       also have "\<dots> = (if n < Suc (Suc k) then 0 else a n)"
  1194 	unfolding X_power_mult_right_nth
  1195 	apply (auto simp add: not_less fps_const_def)
  1196 	apply (rule cong[of a a, OF refl])
  1197 	by arith
  1198       finally show ?case by simp
  1199     qed
  1200     finally have "?lhs $ n = ?rhs $ n"  .}
  1201   then show ?thesis by (simp add: fps_eq_iff)
  1202 qed
  1203 
  1204 subsubsection{* Rule 2*}
  1205 
  1206   (* We can not reach the form of Wilf, but still near to it using rewrite rules*)
  1207   (* If f reprents {a_n} and P is a polynomial, then
  1208         P(xD) f represents {P(n) a_n}*)
  1209 
  1210 definition "XD = op * X o fps_deriv"
  1211 
  1212 lemma XD_add[simp]:"XD (a + b) = XD a + XD (b :: ('a::comm_ring_1) fps)"
  1213   by (simp add: XD_def ring_simps)
  1214 
  1215 lemma XD_mult_const[simp]:"XD (fps_const (c::'a::comm_ring_1) * a) = fps_const c * XD a"
  1216   by (simp add: XD_def ring_simps)
  1217 
  1218 lemma XD_linear[simp]: "XD (fps_const c * a + fps_const d * b) = fps_const c * XD a + fps_const d * XD (b :: ('a::comm_ring_1) fps)"
  1219   by simp
  1220 
  1221 lemma XDN_linear:
  1222   "(XD ^^ n) (fps_const c * a + fps_const d * b) = fps_const c * (XD ^^ n) a + fps_const d * (XD ^^ n) (b :: ('a::comm_ring_1) fps)"
  1223   by (induct n, simp_all)
  1224 
  1225 lemma fps_mult_X_deriv_shift: "X* fps_deriv a = Abs_fps (\<lambda>n. of_nat n* a$n)" by (simp add: fps_eq_iff)
  1226 
  1227 
  1228 lemma fps_mult_XD_shift:
  1229   "(XD ^^ k) (a:: ('a::{comm_ring_1}) fps) = Abs_fps (\<lambda>n. (of_nat n ^ k) * a$n)"
  1230   by (induct k arbitrary: a) (simp_all add: power_Suc XD_def fps_eq_iff ring_simps del: One_nat_def)
  1231 
  1232 subsubsection{* Rule 3 is trivial and is given by @{text fps_times_def}*}
  1233 subsubsection{* Rule 5 --- summation and "division" by (1 - X)*}
  1234 
  1235 lemma fps_divide_X_minus1_setsum_lemma:
  1236   "a = ((1::('a::comm_ring_1) fps) - X) * Abs_fps (\<lambda>n. setsum (\<lambda>i. a $ i) {0..n})"
  1237 proof-
  1238   let ?X = "X::('a::comm_ring_1) fps"
  1239   let ?sa = "Abs_fps (\<lambda>n. setsum (\<lambda>i. a $ i) {0..n})"
  1240   have th0: "\<And>i. (1 - (X::'a fps)) $ i = (if i = 0 then 1 else if i = 1 then - 1 else 0)" by simp
  1241   {fix n:: nat
  1242     {assume "n=0" hence "a$n = ((1 - ?X) * ?sa) $ n"
  1243 	by (simp add: fps_mult_nth)}
  1244     moreover
  1245     {assume n0: "n \<noteq> 0"
  1246       then have u: "{0} \<union> ({1} \<union> {2..n}) = {0..n}" "{1}\<union>{2..n} = {1..n}"
  1247 	"{0..n - 1}\<union>{n} = {0..n}"
  1248 	apply (simp_all add: expand_set_eq) by presburger+
  1249       have d: "{0} \<inter> ({1} \<union> {2..n}) = {}" "{1} \<inter> {2..n} = {}"
  1250 	"{0..n - 1}\<inter>{n} ={}" using n0
  1251 	by (simp_all add: expand_set_eq, presburger+)
  1252       have f: "finite {0}" "finite {1}" "finite {2 .. n}"
  1253 	"finite {0 .. n - 1}" "finite {n}" by simp_all
  1254     have "((1 - ?X) * ?sa) $ n = setsum (\<lambda>i. (1 - ?X)$ i * ?sa $ (n - i)) {0 .. n}"
  1255       by (simp add: fps_mult_nth)
  1256     also have "\<dots> = a$n" unfolding th0
  1257       unfolding setsum_Un_disjoint[OF f(1) finite_UnI[OF f(2,3)] d(1), unfolded u(1)]
  1258       unfolding setsum_Un_disjoint[OF f(2) f(3) d(2)]
  1259       apply (simp)
  1260       unfolding setsum_Un_disjoint[OF f(4,5) d(3), unfolded u(3)]
  1261       by simp
  1262     finally have "a$n = ((1 - ?X) * ?sa) $ n" by simp}
  1263   ultimately have "a$n = ((1 - ?X) * ?sa) $ n" by blast}
  1264 then show ?thesis
  1265   unfolding fps_eq_iff by blast
  1266 qed
  1267 
  1268 lemma fps_divide_X_minus1_setsum:
  1269   "a /((1::('a::field) fps) - X)  = Abs_fps (\<lambda>n. setsum (\<lambda>i. a $ i) {0..n})"
  1270 proof-
  1271   let ?X = "1 - (X::('a::field) fps)"
  1272   have th0: "?X $ 0 \<noteq> 0" by simp
  1273   have "a /?X = ?X *  Abs_fps (\<lambda>n\<Colon>nat. setsum (op $ a) {0..n}) * inverse ?X"
  1274     using fps_divide_X_minus1_setsum_lemma[of a, symmetric] th0
  1275     by (simp add: fps_divide_def mult_assoc)
  1276   also have "\<dots> = (inverse ?X * ?X) * Abs_fps (\<lambda>n\<Colon>nat. setsum (op $ a) {0..n}) "
  1277     by (simp add: mult_ac)
  1278   finally show ?thesis by (simp add: inverse_mult_eq_1[OF th0])
  1279 qed
  1280 
  1281 subsubsection{* Rule 4 in its more general form: generalizes Rule 3 for an arbitrary
  1282   finite product of FPS, also the relvant instance of powers of a FPS*}
  1283 
  1284 definition "natpermute n k = {l:: nat list. length l = k \<and> foldl op + 0 l = n}"
  1285 
  1286 lemma natlist_trivial_1: "natpermute n 1 = {[n]}"
  1287   apply (auto simp add: natpermute_def)
  1288   apply (case_tac x, auto)
  1289   done
  1290 
  1291 lemma foldl_add_start0:
  1292   "foldl op + x xs = x + foldl op + (0::nat) xs"
  1293   apply (induct xs arbitrary: x)
  1294   apply simp
  1295   unfolding foldl.simps
  1296   apply atomize
  1297   apply (subgoal_tac "\<forall>x\<Colon>nat. foldl op + x xs = x + foldl op + (0\<Colon>nat) xs")
  1298   apply (erule_tac x="x + a" in allE)
  1299   apply (erule_tac x="a" in allE)
  1300   apply simp
  1301   apply assumption
  1302   done
  1303 
  1304 lemma foldl_add_append: "foldl op + (x::nat) (xs@ys) = foldl op + x xs + foldl op + 0 ys"
  1305   apply (induct ys arbitrary: x xs)
  1306   apply auto
  1307   apply (subst (2) foldl_add_start0)
  1308   apply simp
  1309   apply (subst (2) foldl_add_start0)
  1310   by simp
  1311 
  1312 lemma foldl_add_setsum: "foldl op + (x::nat) xs = x + setsum (nth xs) {0..<length xs}"
  1313 proof(induct xs arbitrary: x)
  1314   case Nil thus ?case by simp
  1315 next
  1316   case (Cons a as x)
  1317   have eq: "setsum (op ! (a#as)) {1..<length (a#as)} = setsum (op ! as) {0..<length as}"
  1318     apply (rule setsum_reindex_cong [where f=Suc])
  1319     by (simp_all add: inj_on_def)
  1320   have f: "finite {0}" "finite {1 ..< length (a#as)}" by simp_all
  1321   have d: "{0} \<inter> {1..<length (a#as)} = {}" by simp
  1322   have seq: "{0} \<union> {1..<length(a#as)} = {0 ..<length (a#as)}" by auto
  1323   have "foldl op + x (a#as) = x + foldl op + a as "
  1324     apply (subst foldl_add_start0)    by simp
  1325   also have "\<dots> = x + a + setsum (op ! as) {0..<length as}" unfolding Cons.hyps by simp
  1326   also have "\<dots> = x + setsum (op ! (a#as)) {0..<length (a#as)}"
  1327     unfolding eq[symmetric]
  1328     unfolding setsum_Un_disjoint[OF f d, unfolded seq]
  1329     by simp
  1330   finally show ?case  .
  1331 qed
  1332 
  1333 
  1334 lemma append_natpermute_less_eq:
  1335   assumes h: "xs@ys \<in> natpermute n k" shows "foldl op + 0 xs \<le> n" and "foldl op + 0 ys \<le> n"
  1336 proof-
  1337   {from h have "foldl op + 0 (xs@ ys) = n" by (simp add: natpermute_def)
  1338     hence "foldl op + 0 xs + foldl op + 0 ys = n" unfolding foldl_add_append .}
  1339   note th = this
  1340   {from th show "foldl op + 0 xs \<le> n" by simp}
  1341   {from th show "foldl op + 0 ys \<le> n" by simp}
  1342 qed
  1343 
  1344 lemma natpermute_split:
  1345   assumes mn: "h \<le> k"
  1346   shows "natpermute n k = (\<Union>m \<in>{0..n}. {l1 @ l2 |l1 l2. l1 \<in> natpermute m h \<and> l2 \<in> natpermute (n - m) (k - h)})" (is "?L = ?R" is "?L = (\<Union>m \<in>{0..n}. ?S m)")
  1347 proof-
  1348   {fix l assume l: "l \<in> ?R"
  1349     from l obtain m xs ys where h: "m \<in> {0..n}" and xs: "xs \<in> natpermute m h" and ys: "ys \<in> natpermute (n - m) (k - h)"  and leq: "l = xs@ys" by blast
  1350     from xs have xs': "foldl op + 0 xs = m" by (simp add: natpermute_def)
  1351     from ys have ys': "foldl op + 0 ys = n - m" by (simp add: natpermute_def)
  1352     have "l \<in> ?L" using leq xs ys h
  1353       apply simp
  1354       apply (clarsimp simp add: natpermute_def simp del: foldl_append)
  1355       apply (simp add: foldl_add_append[unfolded foldl_append])
  1356       unfolding xs' ys'
  1357       using mn xs ys
  1358       unfolding natpermute_def by simp}
  1359   moreover
  1360   {fix l assume l: "l \<in> natpermute n k"
  1361     let ?xs = "take h l"
  1362     let ?ys = "drop h l"
  1363     let ?m = "foldl op + 0 ?xs"
  1364     from l have ls: "foldl op + 0 (?xs @ ?ys) = n" by (simp add: natpermute_def)
  1365     have xs: "?xs \<in> natpermute ?m h" using l mn by (simp add: natpermute_def)
  1366     have ys: "?ys \<in> natpermute (n - ?m) (k - h)" using l mn ls[unfolded foldl_add_append]
  1367       by (simp add: natpermute_def)
  1368     from ls have m: "?m \<in> {0..n}"  unfolding foldl_add_append by simp
  1369     from xs ys ls have "l \<in> ?R"
  1370       apply auto
  1371       apply (rule bexI[where x = "?m"])
  1372       apply (rule exI[where x = "?xs"])
  1373       apply (rule exI[where x = "?ys"])
  1374       using ls l unfolding foldl_add_append
  1375       by (auto simp add: natpermute_def)}
  1376   ultimately show ?thesis by blast
  1377 qed
  1378 
  1379 lemma natpermute_0: "natpermute n 0 = (if n = 0 then {[]} else {})"
  1380   by (auto simp add: natpermute_def)
  1381 lemma natpermute_0'[simp]: "natpermute 0 k = (if k = 0 then {[]} else {replicate k 0})"
  1382   apply (auto simp add: set_replicate_conv_if natpermute_def)
  1383   apply (rule nth_equalityI)
  1384   by simp_all
  1385 
  1386 lemma natpermute_finite: "finite (natpermute n k)"
  1387 proof(induct k arbitrary: n)
  1388   case 0 thus ?case
  1389     apply (subst natpermute_split[of 0 0, simplified])
  1390     by (simp add: natpermute_0)
  1391 next
  1392   case (Suc k)
  1393   then show ?case unfolding natpermute_split[of k "Suc k", simplified]
  1394     apply -
  1395     apply (rule finite_UN_I)
  1396     apply simp
  1397     unfolding One_nat_def[symmetric] natlist_trivial_1
  1398     apply simp
  1399     done
  1400 qed
  1401 
  1402 lemma natpermute_contain_maximal:
  1403   "{xs \<in> natpermute n (k+1). n \<in> set xs} = UNION {0 .. k} (\<lambda>i. {(replicate (k+1) 0) [i:=n]})"
  1404   (is "?A = ?B")
  1405 proof-
  1406   {fix xs assume H: "xs \<in> natpermute n (k+1)" and n: "n \<in> set xs"
  1407     from n obtain i where i: "i \<in> {0.. k}" "xs!i = n" using H
  1408       unfolding in_set_conv_nth by (auto simp add: less_Suc_eq_le natpermute_def)
  1409     have eqs: "({0..k} - {i}) \<union> {i} = {0..k}" using i by auto
  1410     have f: "finite({0..k} - {i})" "finite {i}" by auto
  1411     have d: "({0..k} - {i}) \<inter> {i} = {}" using i by auto
  1412     from H have "n = setsum (nth xs) {0..k}" apply (simp add: natpermute_def)
  1413       unfolding foldl_add_setsum by (auto simp add: atLeastLessThanSuc_atLeastAtMost)
  1414     also have "\<dots> = n + setsum (nth xs) ({0..k} - {i})"
  1415       unfolding setsum_Un_disjoint[OF f d, unfolded eqs] using i by simp
  1416     finally have zxs: "\<forall> j\<in> {0..k} - {i}. xs!j = 0" by auto
  1417     from H have xsl: "length xs = k+1" by (simp add: natpermute_def)
  1418     from i have i': "i < length (replicate (k+1) 0)"   "i < k+1"
  1419       unfolding length_replicate  by arith+
  1420     have "xs = replicate (k+1) 0 [i := n]"
  1421       apply (rule nth_equalityI)
  1422       unfolding xsl length_list_update length_replicate
  1423       apply simp
  1424       apply clarify
  1425       unfolding nth_list_update[OF i'(1)]
  1426       using i zxs
  1427       by (case_tac "ia=i", auto simp del: replicate.simps)
  1428     then have "xs \<in> ?B" using i by blast}
  1429   moreover
  1430   {fix i assume i: "i \<in> {0..k}"
  1431     let ?xs = "replicate (k+1) 0 [i:=n]"
  1432     have nxs: "n \<in> set ?xs"
  1433       apply (rule set_update_memI) using i by simp
  1434     have xsl: "length ?xs = k+1" by (simp only: length_replicate length_list_update)
  1435     have "foldl op + 0 ?xs = setsum (nth ?xs) {0..<k+1}"
  1436       unfolding foldl_add_setsum add_0 length_replicate length_list_update ..
  1437     also have "\<dots> = setsum (\<lambda>j. if j = i then n else 0) {0..< k+1}"
  1438       apply (rule setsum_cong2) by (simp del: replicate.simps)
  1439     also have "\<dots> = n" using i by (simp add: setsum_delta)
  1440     finally
  1441     have "?xs \<in> natpermute n (k+1)" using xsl unfolding natpermute_def Collect_def mem_def
  1442       by blast
  1443     then have "?xs \<in> ?A"  using nxs  by blast}
  1444   ultimately show ?thesis by auto
  1445 qed
  1446 
  1447     (* The general form *)
  1448 lemma fps_setprod_nth:
  1449   fixes m :: nat and a :: "nat \<Rightarrow> ('a::comm_ring_1) fps"
  1450   shows "(setprod a {0 .. m})$n = setsum (\<lambda>v. setprod (\<lambda>j. (a j) $ (v!j)) {0..m}) (natpermute n (m+1))"
  1451   (is "?P m n")
  1452 proof(induct m arbitrary: n rule: nat_less_induct)
  1453   fix m n assume H: "\<forall>m' < m. \<forall>n. ?P m' n"
  1454   {assume m0: "m = 0"
  1455     hence "?P m n" apply simp
  1456       unfolding natlist_trivial_1[where n = n, unfolded One_nat_def] by simp}
  1457   moreover
  1458   {fix k assume k: "m = Suc k"
  1459     have km: "k < m" using k by arith
  1460     have u0: "{0 .. k} \<union> {m} = {0..m}" using k apply (simp add: expand_set_eq) by presburger
  1461     have f0: "finite {0 .. k}" "finite {m}" by auto
  1462     have d0: "{0 .. k} \<inter> {m} = {}" using k by auto
  1463     have "(setprod a {0 .. m}) $ n = (setprod a {0 .. k} * a m) $ n"
  1464       unfolding setprod_Un_disjoint[OF f0 d0, unfolded u0] by simp
  1465     also have "\<dots> = (\<Sum>i = 0..n. (\<Sum>v\<in>natpermute i (k + 1). \<Prod>j\<in>{0..k}. a j $ v ! j) * a m $ (n - i))"
  1466       unfolding fps_mult_nth H[rule_format, OF km] ..
  1467     also have "\<dots> = (\<Sum>v\<in>natpermute n (m + 1). \<Prod>j\<in>{0..m}. a j $ v ! j)"
  1468       apply (simp add: k)
  1469       unfolding natpermute_split[of m "m + 1", simplified, of n, unfolded natlist_trivial_1[unfolded One_nat_def] k]
  1470       apply (subst setsum_UN_disjoint)
  1471       apply simp
  1472       apply simp
  1473       unfolding image_Collect[symmetric]
  1474       apply clarsimp
  1475       apply (rule finite_imageI)
  1476       apply (rule natpermute_finite)
  1477       apply (clarsimp simp add: expand_set_eq)
  1478       apply auto
  1479       apply (rule setsum_cong2)
  1480       unfolding setsum_left_distrib
  1481       apply (rule sym)
  1482       apply (rule_tac f="\<lambda>xs. xs @[n - x]" in  setsum_reindex_cong)
  1483       apply (simp add: inj_on_def)
  1484       apply auto
  1485       unfolding setprod_Un_disjoint[OF f0 d0, unfolded u0, unfolded k]
  1486       apply (clarsimp simp add: natpermute_def nth_append)
  1487       done
  1488     finally have "?P m n" .}
  1489   ultimately show "?P m n " by (cases m, auto)
  1490 qed
  1491 
  1492 text{* The special form for powers *}
  1493 lemma fps_power_nth_Suc:
  1494   fixes m :: nat and a :: "('a::comm_ring_1) fps"
  1495   shows "(a ^ Suc m)$n = setsum (\<lambda>v. setprod (\<lambda>j. a $ (v!j)) {0..m}) (natpermute n (m+1))"
  1496 proof-
  1497   have f: "finite {0 ..m}" by simp
  1498   have th0: "a^Suc m = setprod (\<lambda>i. a) {0..m}" unfolding setprod_constant[OF f, of a] by simp
  1499   show ?thesis unfolding th0 fps_setprod_nth ..
  1500 qed
  1501 lemma fps_power_nth:
  1502   fixes m :: nat and a :: "('a::comm_ring_1) fps"
  1503   shows "(a ^m)$n = (if m=0 then 1$n else setsum (\<lambda>v. setprod (\<lambda>j. a $ (v!j)) {0..m - 1}) (natpermute n m))"
  1504   by (cases m, simp_all add: fps_power_nth_Suc del: power_Suc)
  1505 
  1506 lemma fps_nth_power_0:
  1507   fixes m :: nat and a :: "('a::{comm_ring_1}) fps"
  1508   shows "(a ^m)$0 = (a$0) ^ m"
  1509 proof-
  1510   {assume "m=0" hence ?thesis by simp}
  1511   moreover
  1512   {fix n assume m: "m = Suc n"
  1513     have c: "m = card {0..n}" using m by simp
  1514    have "(a ^m)$0 = setprod (\<lambda>i. a$0) {0..n}"
  1515      by (simp add: m fps_power_nth del: replicate.simps power_Suc)
  1516    also have "\<dots> = (a$0) ^ m"
  1517      unfolding c by (rule setprod_constant, simp)
  1518    finally have ?thesis .}
  1519  ultimately show ?thesis by (cases m, auto)
  1520 qed
  1521 
  1522 lemma fps_compose_inj_right:
  1523   assumes a0: "a$0 = (0::'a::{idom})"
  1524   and a1: "a$1 \<noteq> 0"
  1525   shows "(b oo a = c oo a) \<longleftrightarrow> b = c" (is "?lhs \<longleftrightarrow>?rhs")
  1526 proof-
  1527   {assume ?rhs then have "?lhs" by simp}
  1528   moreover
  1529   {assume h: ?lhs
  1530     {fix n have "b$n = c$n"
  1531       proof(induct n rule: nat_less_induct)
  1532 	fix n assume H: "\<forall>m<n. b$m = c$m"
  1533 	{assume n0: "n=0"
  1534 	  from h have "(b oo a)$n = (c oo a)$n" by simp
  1535 	  hence "b$n = c$n" using n0 by (simp add: fps_compose_nth)}
  1536 	moreover
  1537 	{fix n1 assume n1: "n = Suc n1"
  1538 	  have f: "finite {0 .. n1}" "finite {n}" by simp_all
  1539 	  have eq: "{0 .. n1} \<union> {n} = {0 .. n}" using n1 by auto
  1540 	  have d: "{0 .. n1} \<inter> {n} = {}" using n1 by auto
  1541 	  have seq: "(\<Sum>i = 0..n1. b $ i * a ^ i $ n) = (\<Sum>i = 0..n1. c $ i * a ^ i $ n)"
  1542 	    apply (rule setsum_cong2)
  1543 	    using H n1 by auto
  1544 	  have th0: "(b oo a) $n = (\<Sum>i = 0..n1. c $ i * a ^ i $ n) + b$n * (a$1)^n"
  1545 	    unfolding fps_compose_nth setsum_Un_disjoint[OF f d, unfolded eq] seq
  1546 	    using startsby_zero_power_nth_same[OF a0]
  1547 	    by simp
  1548 	  have th1: "(c oo a) $n = (\<Sum>i = 0..n1. c $ i * a ^ i $ n) + c$n * (a$1)^n"
  1549 	    unfolding fps_compose_nth setsum_Un_disjoint[OF f d, unfolded eq]
  1550 	    using startsby_zero_power_nth_same[OF a0]
  1551 	    by simp
  1552 	  from h[unfolded fps_eq_iff, rule_format, of n] th0 th1 a1
  1553 	  have "b$n = c$n" by auto}
  1554 	ultimately show "b$n = c$n" by (cases n, auto)
  1555       qed}
  1556     then have ?rhs by (simp add: fps_eq_iff)}
  1557   ultimately show ?thesis by blast
  1558 qed
  1559 
  1560 
  1561 subsection {* Radicals *}
  1562 
  1563 declare setprod_cong[fundef_cong]
  1564 function radical :: "(nat \<Rightarrow> 'a \<Rightarrow> 'a) \<Rightarrow> nat \<Rightarrow> ('a::{field}) fps \<Rightarrow> nat \<Rightarrow> 'a" where
  1565   "radical r 0 a 0 = 1"
  1566 | "radical r 0 a (Suc n) = 0"
  1567 | "radical r (Suc k) a 0 = r (Suc k) (a$0)"
  1568 | "radical r (Suc k) a (Suc n) = (a$ Suc n - setsum (\<lambda>xs. setprod (\<lambda>j. radical r (Suc k) a (xs ! j)) {0..k}) {xs. xs \<in> natpermute (Suc n) (Suc k) \<and> Suc n \<notin> set xs}) / (of_nat (Suc k) * (radical r (Suc k) a 0)^k)"
  1569 by pat_completeness auto
  1570 
  1571 termination radical
  1572 proof
  1573   let ?R = "measure (\<lambda>(r, k, a, n). n)"
  1574   {
  1575     show "wf ?R" by auto}
  1576   {fix r k a n xs i
  1577     assume xs: "xs \<in> {xs \<in> natpermute (Suc n) (Suc k). Suc n \<notin> set xs}" and i: "i \<in> {0..k}"
  1578     {assume c: "Suc n \<le> xs ! i"
  1579       from xs i have "xs !i \<noteq> Suc n" by (auto simp add: in_set_conv_nth natpermute_def)
  1580       with c have c': "Suc n < xs!i" by arith
  1581       have fths: "finite {0 ..< i}" "finite {i}" "finite {i+1..<Suc k}" by simp_all
  1582       have d: "{0 ..< i} \<inter> ({i} \<union> {i+1 ..< Suc k}) = {}" "{i} \<inter> {i+1..< Suc k} = {}" by auto
  1583       have eqs: "{0..<Suc k} = {0 ..< i} \<union> ({i} \<union> {i+1 ..< Suc k})" using i by auto
  1584       from xs have "Suc n = foldl op + 0 xs" by (simp add: natpermute_def)
  1585       also have "\<dots> = setsum (nth xs) {0..<Suc k}" unfolding foldl_add_setsum using xs
  1586 	by (simp add: natpermute_def)
  1587       also have "\<dots> = xs!i + setsum (nth xs) {0..<i} + setsum (nth xs) {i+1..<Suc k}"
  1588 	unfolding eqs  setsum_Un_disjoint[OF fths(1) finite_UnI[OF fths(2,3)] d(1)]
  1589 	unfolding setsum_Un_disjoint[OF fths(2) fths(3) d(2)]
  1590 	by simp
  1591       finally have False using c' by simp}
  1592     then show "((r,Suc k,a,xs!i), r, Suc k, a, Suc n) \<in> ?R"
  1593       apply auto by (metis not_less)}
  1594   {fix r k a n
  1595     show "((r,Suc k, a, 0),r, Suc k, a, Suc n) \<in> ?R" by simp}
  1596 qed
  1597 
  1598 definition "fps_radical r n a = Abs_fps (radical r n a)"
  1599 
  1600 lemma fps_radical0[simp]: "fps_radical r 0 a = 1"
  1601   apply (auto simp add: fps_eq_iff fps_radical_def)  by (case_tac n, auto)
  1602 
  1603 lemma fps_radical_nth_0[simp]: "fps_radical r n a $ 0 = (if n=0 then 1 else r n (a$0))"
  1604   by (cases n, simp_all add: fps_radical_def)
  1605 
  1606 lemma fps_radical_power_nth[simp]:
  1607   assumes r: "(r k (a$0)) ^ k = a$0"
  1608   shows "fps_radical r k a ^ k $ 0 = (if k = 0 then 1 else a$0)"
  1609 proof-
  1610   {assume "k=0" hence ?thesis by simp }
  1611   moreover
  1612   {fix h assume h: "k = Suc h"
  1613     have fh: "finite {0..h}" by simp
  1614     have eq1: "fps_radical r k a ^ k $ 0 = (\<Prod>j\<in>{0..h}. fps_radical r k a $ (replicate k 0) ! j)"
  1615       unfolding fps_power_nth h by simp
  1616     also have "\<dots> = (\<Prod>j\<in>{0..h}. r k (a$0))"
  1617       apply (rule setprod_cong)
  1618       apply simp
  1619       using h
  1620       apply (subgoal_tac "replicate k (0::nat) ! x = 0")
  1621       by (auto intro: nth_replicate simp del: replicate.simps)
  1622     also have "\<dots> = a$0"
  1623       unfolding setprod_constant[OF fh] using r by (simp add: h)
  1624     finally have ?thesis using h by simp}
  1625   ultimately show ?thesis by (cases k, auto)
  1626 qed
  1627 
  1628 lemma natpermute_max_card: assumes n0: "n\<noteq>0"
  1629   shows "card {xs \<in> natpermute n (k+1). n \<in> set xs} = k+1"
  1630   unfolding natpermute_contain_maximal
  1631 proof-
  1632   let ?A= "\<lambda>i. {replicate (k + 1) 0[i := n]}"
  1633   let ?K = "{0 ..k}"
  1634   have fK: "finite ?K" by simp
  1635   have fAK: "\<forall>i\<in>?K. finite (?A i)" by auto
  1636   have d: "\<forall>i\<in> ?K. \<forall>j\<in> ?K. i \<noteq> j \<longrightarrow> {replicate (k + 1) 0[i := n]} \<inter> {replicate (k + 1) 0[j := n]} = {}"
  1637   proof(clarify)
  1638     fix i j assume i: "i \<in> ?K" and j: "j\<in> ?K" and ij: "i\<noteq>j"
  1639     {assume eq: "replicate (k+1) 0 [i:=n] = replicate (k+1) 0 [j:= n]"
  1640       have "(replicate (k+1) 0 [i:=n] ! i) = n" using i by (simp del: replicate.simps)
  1641       moreover
  1642       have "(replicate (k+1) 0 [j:=n] ! i) = 0" using i ij by (simp del: replicate.simps)
  1643       ultimately have False using eq n0 by (simp del: replicate.simps)}
  1644     then show "{replicate (k + 1) 0[i := n]} \<inter> {replicate (k + 1) 0[j := n]} = {}"
  1645       by auto
  1646   qed
  1647   from card_UN_disjoint[OF fK fAK d]
  1648   show "card (\<Union>i\<in>{0..k}. {replicate (k + 1) 0[i := n]}) = k+1" by simp
  1649 qed
  1650 
  1651 lemma power_radical:
  1652   fixes a:: "'a::field_char_0 fps"
  1653   assumes a0: "a$0 \<noteq> 0"
  1654   shows "(r (Suc k) (a$0)) ^ Suc k = a$0 \<longleftrightarrow> (fps_radical r (Suc k) a) ^ (Suc k) = a"
  1655 proof-
  1656   let ?r = "fps_radical r (Suc k) a"
  1657   {assume r0: "(r (Suc k) (a$0)) ^ Suc k = a$0"
  1658     from a0 r0 have r00: "r (Suc k) (a$0) \<noteq> 0" by auto
  1659     {fix z have "?r ^ Suc k $ z = a$z"
  1660       proof(induct z rule: nat_less_induct)
  1661 	fix n assume H: "\<forall>m<n. ?r ^ Suc k $ m = a$m"
  1662 	{assume "n = 0" hence "?r ^ Suc k $ n = a $n"
  1663 	    using fps_radical_power_nth[of r "Suc k" a, OF r0] by simp}
  1664 	moreover
  1665 	{fix n1 assume n1: "n = Suc n1"
  1666 	  have fK: "finite {0..k}" by simp
  1667 	  have nz: "n \<noteq> 0" using n1 by arith
  1668 	  let ?Pnk = "natpermute n (k + 1)"
  1669 	  let ?Pnkn = "{xs \<in> ?Pnk. n \<in> set xs}"
  1670 	  let ?Pnknn = "{xs \<in> ?Pnk. n \<notin> set xs}"
  1671 	  have eq: "?Pnkn \<union> ?Pnknn = ?Pnk" by blast
  1672 	  have d: "?Pnkn \<inter> ?Pnknn = {}" by blast
  1673 	  have f: "finite ?Pnkn" "finite ?Pnknn"
  1674 	    using finite_Un[of ?Pnkn ?Pnknn, unfolded eq]
  1675 	    by (metis natpermute_finite)+
  1676 	  let ?f = "\<lambda>v. \<Prod>j\<in>{0..k}. ?r $ v ! j"
  1677 	  have "setsum ?f ?Pnkn = setsum (\<lambda>v. ?r $ n * r (Suc k) (a $ 0) ^ k) ?Pnkn"
  1678 	  proof(rule setsum_cong2)
  1679 	    fix v assume v: "v \<in> {xs \<in> natpermute n (k + 1). n \<in> set xs}"
  1680 	    let ?ths = "(\<Prod>j\<in>{0..k}. fps_radical r (Suc k) a $ v ! j) = fps_radical r (Suc k) a $ n * r (Suc k) (a $ 0) ^ k"
  1681 	  from v obtain i where i: "i \<in> {0..k}" "v = replicate (k+1) 0 [i:= n]"
  1682 	    unfolding natpermute_contain_maximal by auto
  1683 	  have "(\<Prod>j\<in>{0..k}. fps_radical r (Suc k) a $ v ! j) = (\<Prod>j\<in>{0..k}. if j = i then fps_radical r (Suc k) a $ n else r (Suc k) (a$0))"
  1684 	    apply (rule setprod_cong, simp)
  1685 	    using i r0 by (simp del: replicate.simps)
  1686 	  also have "\<dots> = (fps_radical r (Suc k) a $ n) * r (Suc k) (a$0) ^ k"
  1687 	    unfolding setprod_gen_delta[OF fK] using i r0 by simp
  1688 	  finally show ?ths .
  1689 	qed
  1690 	then have "setsum ?f ?Pnkn = of_nat (k+1) * ?r $ n * r (Suc k) (a $ 0) ^ k"
  1691 	  by (simp add: natpermute_max_card[OF nz, simplified])
  1692 	also have "\<dots> = a$n - setsum ?f ?Pnknn"
  1693 	  unfolding n1 using r00 a0 by (simp add: field_simps fps_radical_def del: of_nat_Suc )
  1694 	finally have fn: "setsum ?f ?Pnkn = a$n - setsum ?f ?Pnknn" .
  1695 	have "(?r ^ Suc k)$n = setsum ?f ?Pnkn + setsum ?f ?Pnknn"
  1696 	  unfolding fps_power_nth_Suc setsum_Un_disjoint[OF f d, unfolded eq] ..
  1697 	also have "\<dots> = a$n" unfolding fn by simp
  1698 	finally have "?r ^ Suc k $ n = a $n" .}
  1699       ultimately  show "?r ^ Suc k $ n = a $n" by (cases n, auto)
  1700     qed }
  1701   then have ?thesis using r0 by (simp add: fps_eq_iff)}
  1702 moreover 
  1703 { assume h: "(fps_radical r (Suc k) a) ^ (Suc k) = a"
  1704   hence "((fps_radical r (Suc k) a) ^ (Suc k))$0 = a$0" by simp
  1705   then have "(r (Suc k) (a$0)) ^ Suc k = a$0"
  1706     unfolding fps_power_nth_Suc
  1707     by (simp add: setprod_constant del: replicate.simps)}
  1708 ultimately show ?thesis by blast
  1709 qed
  1710 
  1711 (*
  1712 lemma power_radical:
  1713   fixes a:: "'a::field_char_0 fps"
  1714   assumes r0: "(r (Suc k) (a$0)) ^ Suc k = a$0" and a0: "a$0 \<noteq> 0"
  1715   shows "(fps_radical r (Suc k) a) ^ (Suc k) = a"
  1716 proof-
  1717   let ?r = "fps_radical r (Suc k) a"
  1718   from a0 r0 have r00: "r (Suc k) (a$0) \<noteq> 0" by auto
  1719   {fix z have "?r ^ Suc k $ z = a$z"
  1720     proof(induct z rule: nat_less_induct)
  1721       fix n assume H: "\<forall>m<n. ?r ^ Suc k $ m = a$m"
  1722       {assume "n = 0" hence "?r ^ Suc k $ n = a $n"
  1723 	  using fps_radical_power_nth[of r "Suc k" a, OF r0] by simp}
  1724       moreover
  1725       {fix n1 assume n1: "n = Suc n1"
  1726 	have fK: "finite {0..k}" by simp
  1727 	have nz: "n \<noteq> 0" using n1 by arith
  1728 	let ?Pnk = "natpermute n (k + 1)"
  1729 	let ?Pnkn = "{xs \<in> ?Pnk. n \<in> set xs}"
  1730 	let ?Pnknn = "{xs \<in> ?Pnk. n \<notin> set xs}"
  1731 	have eq: "?Pnkn \<union> ?Pnknn = ?Pnk" by blast
  1732 	have d: "?Pnkn \<inter> ?Pnknn = {}" by blast
  1733 	have f: "finite ?Pnkn" "finite ?Pnknn"
  1734 	  using finite_Un[of ?Pnkn ?Pnknn, unfolded eq]
  1735 	  by (metis natpermute_finite)+
  1736 	let ?f = "\<lambda>v. \<Prod>j\<in>{0..k}. ?r $ v ! j"
  1737 	have "setsum ?f ?Pnkn = setsum (\<lambda>v. ?r $ n * r (Suc k) (a $ 0) ^ k) ?Pnkn"
  1738 	proof(rule setsum_cong2)
  1739 	  fix v assume v: "v \<in> {xs \<in> natpermute n (k + 1). n \<in> set xs}"
  1740 	  let ?ths = "(\<Prod>j\<in>{0..k}. fps_radical r (Suc k) a $ v ! j) = fps_radical r (Suc k) a $ n * r (Suc k) (a $ 0) ^ k"
  1741 	  from v obtain i where i: "i \<in> {0..k}" "v = replicate (k+1) 0 [i:= n]"
  1742 	    unfolding natpermute_contain_maximal by auto
  1743 	  have "(\<Prod>j\<in>{0..k}. fps_radical r (Suc k) a $ v ! j) = (\<Prod>j\<in>{0..k}. if j = i then fps_radical r (Suc k) a $ n else r (Suc k) (a$0))"
  1744 	    apply (rule setprod_cong, simp)
  1745 	    using i r0 by (simp del: replicate.simps)
  1746 	  also have "\<dots> = (fps_radical r (Suc k) a $ n) * r (Suc k) (a$0) ^ k"
  1747 	    unfolding setprod_gen_delta[OF fK] using i r0 by simp
  1748 	  finally show ?ths .
  1749 	qed
  1750 	then have "setsum ?f ?Pnkn = of_nat (k+1) * ?r $ n * r (Suc k) (a $ 0) ^ k"
  1751 	  by (simp add: natpermute_max_card[OF nz, simplified])
  1752 	also have "\<dots> = a$n - setsum ?f ?Pnknn"
  1753 	  unfolding n1 using r00 a0 by (simp add: field_simps fps_radical_def del: of_nat_Suc )
  1754 	finally have fn: "setsum ?f ?Pnkn = a$n - setsum ?f ?Pnknn" .
  1755 	have "(?r ^ Suc k)$n = setsum ?f ?Pnkn + setsum ?f ?Pnknn"
  1756 	  unfolding fps_power_nth_Suc setsum_Un_disjoint[OF f d, unfolded eq] ..
  1757 	also have "\<dots> = a$n" unfolding fn by simp
  1758 	finally have "?r ^ Suc k $ n = a $n" .}
  1759       ultimately  show "?r ^ Suc k $ n = a $n" by (cases n, auto)
  1760   qed }
  1761   then show ?thesis by (simp add: fps_eq_iff)
  1762 qed
  1763 
  1764 *)
  1765 lemma eq_divide_imp': assumes c0: "(c::'a::field) ~= 0" and eq: "a * c = b"
  1766   shows "a = b / c"
  1767 proof-
  1768   from eq have "a * c * inverse c = b * inverse c" by simp
  1769   hence "a * (inverse c * c) = b/c" by (simp only: field_simps divide_inverse)
  1770   then show "a = b/c" unfolding  field_inverse[OF c0] by simp
  1771 qed
  1772 
  1773 lemma radical_unique:
  1774   assumes r0: "(r (Suc k) (b$0)) ^ Suc k = b$0"
  1775   and a0: "r (Suc k) (b$0 ::'a::field_char_0) = a$0" and b0: "b$0 \<noteq> 0"
  1776   shows "a^(Suc k) = b \<longleftrightarrow> a = fps_radical r (Suc k) b"
  1777 proof-
  1778   let ?r = "fps_radical r (Suc k) b"
  1779   have r00: "r (Suc k) (b$0) \<noteq> 0" using b0 r0 by auto
  1780   {assume H: "a = ?r"
  1781     from H have "a^Suc k = b" using power_radical[OF b0, of r k, unfolded r0] by simp}
  1782   moreover
  1783   {assume H: "a^Suc k = b"
  1784     have ceq: "card {0..k} = Suc k" by simp
  1785     have fk: "finite {0..k}" by simp
  1786     from a0 have a0r0: "a$0 = ?r$0" by simp
  1787     {fix n have "a $ n = ?r $ n"
  1788       proof(induct n rule: nat_less_induct)
  1789 	fix n assume h: "\<forall>m<n. a$m = ?r $m"
  1790 	{assume "n = 0" hence "a$n = ?r $n" using a0 by simp }
  1791 	moreover
  1792 	{fix n1 assume n1: "n = Suc n1"
  1793 	  have fK: "finite {0..k}" by simp
  1794 	have nz: "n \<noteq> 0" using n1 by arith
  1795 	let ?Pnk = "natpermute n (Suc k)"
  1796 	let ?Pnkn = "{xs \<in> ?Pnk. n \<in> set xs}"
  1797 	let ?Pnknn = "{xs \<in> ?Pnk. n \<notin> set xs}"
  1798 	have eq: "?Pnkn \<union> ?Pnknn = ?Pnk" by blast
  1799 	have d: "?Pnkn \<inter> ?Pnknn = {}" by blast
  1800 	have f: "finite ?Pnkn" "finite ?Pnknn"
  1801 	  using finite_Un[of ?Pnkn ?Pnknn, unfolded eq]
  1802 	  by (metis natpermute_finite)+
  1803 	let ?f = "\<lambda>v. \<Prod>j\<in>{0..k}. ?r $ v ! j"
  1804 	let ?g = "\<lambda>v. \<Prod>j\<in>{0..k}. a $ v ! j"
  1805 	have "setsum ?g ?Pnkn = setsum (\<lambda>v. a $ n * (?r$0)^k) ?Pnkn"
  1806 	proof(rule setsum_cong2)
  1807 	  fix v assume v: "v \<in> {xs \<in> natpermute n (Suc k). n \<in> set xs}"
  1808 	  let ?ths = "(\<Prod>j\<in>{0..k}. a $ v ! j) = a $ n * (?r$0)^k"
  1809 	  from v obtain i where i: "i \<in> {0..k}" "v = replicate (k+1) 0 [i:= n]"
  1810 	    unfolding Suc_eq_plus1 natpermute_contain_maximal by (auto simp del: replicate.simps)
  1811 	  have "(\<Prod>j\<in>{0..k}. a $ v ! j) = (\<Prod>j\<in>{0..k}. if j = i then a $ n else r (Suc k) (b$0))"
  1812 	    apply (rule setprod_cong, simp)
  1813 	    using i a0 by (simp del: replicate.simps)
  1814 	  also have "\<dots> = a $ n * (?r $ 0)^k"
  1815 	    unfolding  setprod_gen_delta[OF fK] using i by simp
  1816 	  finally show ?ths .
  1817 	qed
  1818 	then have th0: "setsum ?g ?Pnkn = of_nat (k+1) * a $ n * (?r $ 0)^k"
  1819 	  by (simp add: natpermute_max_card[OF nz, simplified])
  1820 	have th1: "setsum ?g ?Pnknn = setsum ?f ?Pnknn"
  1821 	proof (rule setsum_cong2, rule setprod_cong, simp)
  1822 	  fix xs i assume xs: "xs \<in> ?Pnknn" and i: "i \<in> {0..k}"
  1823 	  {assume c: "n \<le> xs ! i"
  1824 	    from xs i have "xs !i \<noteq> n" by (auto simp add: in_set_conv_nth natpermute_def)
  1825 	    with c have c': "n < xs!i" by arith
  1826 	    have fths: "finite {0 ..< i}" "finite {i}" "finite {i+1..<Suc k}" by simp_all
  1827 	    have d: "{0 ..< i} \<inter> ({i} \<union> {i+1 ..< Suc k}) = {}" "{i} \<inter> {i+1..< Suc k} = {}" by auto
  1828 	    have eqs: "{0..<Suc k} = {0 ..< i} \<union> ({i} \<union> {i+1 ..< Suc k})" using i by auto
  1829 	    from xs have "n = foldl op + 0 xs" by (simp add: natpermute_def)
  1830 	    also have "\<dots> = setsum (nth xs) {0..<Suc k}" unfolding foldl_add_setsum using xs
  1831 	      by (simp add: natpermute_def)
  1832 	    also have "\<dots> = xs!i + setsum (nth xs) {0..<i} + setsum (nth xs) {i+1..<Suc k}"
  1833 	      unfolding eqs  setsum_Un_disjoint[OF fths(1) finite_UnI[OF fths(2,3)] d(1)]
  1834 	      unfolding setsum_Un_disjoint[OF fths(2) fths(3) d(2)]
  1835 	      by simp
  1836 	    finally have False using c' by simp}
  1837 	  then have thn: "xs!i < n" by arith
  1838 	  from h[rule_format, OF thn]
  1839 	  show "a$(xs !i) = ?r$(xs!i)" .
  1840 	qed
  1841 	have th00: "\<And>(x::'a). of_nat (Suc k) * (x * inverse (of_nat (Suc k))) = x"
  1842 	  by (simp add: field_simps del: of_nat_Suc)
  1843 	from H have "b$n = a^Suc k $ n" by (simp add: fps_eq_iff)
  1844 	also have "a ^ Suc k$n = setsum ?g ?Pnkn + setsum ?g ?Pnknn"
  1845 	  unfolding fps_power_nth_Suc
  1846 	  using setsum_Un_disjoint[OF f d, unfolded Suc_eq_plus1[symmetric],
  1847 	    unfolded eq, of ?g] by simp
  1848 	also have "\<dots> = of_nat (k+1) * a $ n * (?r $ 0)^k + setsum ?f ?Pnknn" unfolding th0 th1 ..
  1849 	finally have "of_nat (k+1) * a $ n * (?r $ 0)^k = b$n - setsum ?f ?Pnknn" by simp
  1850 	then have "a$n = (b$n - setsum ?f ?Pnknn) / (of_nat (k+1) * (?r $ 0)^k)"
  1851 	  apply -
  1852 	  apply (rule eq_divide_imp')
  1853 	  using r00
  1854 	  apply (simp del: of_nat_Suc)
  1855 	  by (simp add: mult_ac)
  1856 	then have "a$n = ?r $n"
  1857 	  apply (simp del: of_nat_Suc)
  1858 	  unfolding fps_radical_def n1
  1859 	  by (simp add: field_simps n1 th00 del: of_nat_Suc)}
  1860 	ultimately show "a$n = ?r $ n" by (cases n, auto)
  1861       qed}
  1862     then have "a = ?r" by (simp add: fps_eq_iff)}
  1863   ultimately show ?thesis by blast
  1864 qed
  1865 
  1866 
  1867 lemma radical_power:
  1868   assumes r0: "r (Suc k) ((a$0) ^ Suc k) = a$0"
  1869   and a0: "(a$0 ::'a::field_char_0) \<noteq> 0"
  1870   shows "(fps_radical r (Suc k) (a ^ Suc k)) = a"
  1871 proof-
  1872   let ?ak = "a^ Suc k"
  1873   have ak0: "?ak $ 0 = (a$0) ^ Suc k" by (simp add: fps_nth_power_0 del: power_Suc)
  1874   from r0 have th0: "r (Suc k) (a ^ Suc k $ 0) ^ Suc k = a ^ Suc k $ 0" using ak0 by auto
  1875   from r0 ak0 have th1: "r (Suc k) (a ^ Suc k $ 0) = a $ 0" by auto
  1876   from ak0 a0 have ak00: "?ak $ 0 \<noteq>0 " by auto
  1877   from radical_unique[of r k ?ak a, OF th0 th1 ak00] show ?thesis by metis
  1878 qed
  1879 
  1880 lemma fps_deriv_radical:
  1881   fixes a:: "'a::field_char_0 fps"
  1882   assumes r0: "(r (Suc k) (a$0)) ^ Suc k = a$0" and a0: "a$0 \<noteq> 0"
  1883   shows "fps_deriv (fps_radical r (Suc k) a) = fps_deriv a / (fps_const (of_nat (Suc k)) * (fps_radical r (Suc k) a) ^ k)"
  1884 proof-
  1885   let ?r= "fps_radical r (Suc k) a"
  1886   let ?w = "(fps_const (of_nat (Suc k)) * ?r ^ k)"
  1887   from a0 r0 have r0': "r (Suc k) (a$0) \<noteq> 0" by auto
  1888   from r0' have w0: "?w $ 0 \<noteq> 0" by (simp del: of_nat_Suc)
  1889   note th0 = inverse_mult_eq_1[OF w0]
  1890   let ?iw = "inverse ?w"
  1891   from iffD1[OF power_radical[of a r], OF a0 r0]
  1892   have "fps_deriv (?r ^ Suc k) = fps_deriv a" by simp
  1893   hence "fps_deriv ?r * ?w = fps_deriv a"
  1894     by (simp add: fps_deriv_power mult_ac del: power_Suc)
  1895   hence "?iw * fps_deriv ?r * ?w = ?iw * fps_deriv a" by simp
  1896   hence "fps_deriv ?r * (?iw * ?w) = fps_deriv a / ?w"
  1897     by (simp add: fps_divide_def)
  1898   then show ?thesis unfolding th0 by simp
  1899 qed
  1900 
  1901 lemma radical_mult_distrib:
  1902   fixes a:: "'a::field_char_0 fps"
  1903   assumes
  1904   k: "k > 0"
  1905   and ra0: "r k (a $ 0) ^ k = a $ 0"
  1906   and rb0: "r k (b $ 0) ^ k = b $ 0"
  1907   and a0: "a$0 \<noteq> 0"
  1908   and b0: "b$0 \<noteq> 0"
  1909   shows "r k ((a * b) $ 0) = r k (a $ 0) * r k (b $ 0) \<longleftrightarrow> fps_radical r (k) (a*b) = fps_radical r (k) a * fps_radical r (k) (b)"
  1910 proof-
  1911   {assume  r0': "r k ((a * b) $ 0) = r k (a $ 0) * r k (b $ 0)"
  1912   from r0' have r0: "(r (k) ((a*b)$0)) ^ k = (a*b)$0"
  1913     by (simp add: fps_mult_nth ra0 rb0 power_mult_distrib)
  1914   {assume "k=0" hence ?thesis using r0' by simp}
  1915   moreover
  1916   {fix h assume k: "k = Suc h"
  1917   let ?ra = "fps_radical r (Suc h) a"
  1918   let ?rb = "fps_radical r (Suc h) b"
  1919   have th0: "r (Suc h) ((a * b) $ 0) = (fps_radical r (Suc h) a * fps_radical r (Suc h) b) $ 0"
  1920     using r0' k by (simp add: fps_mult_nth)
  1921   have ab0: "(a*b) $ 0 \<noteq> 0" using a0 b0 by (simp add: fps_mult_nth)
  1922   from radical_unique[of r h "a*b" "fps_radical r (Suc h) a * fps_radical r (Suc h) b", OF r0[unfolded k] th0 ab0, symmetric]
  1923     iffD1[OF power_radical[of _ r], OF a0 ra0[unfolded k]] iffD1[OF power_radical[of _ r], OF b0 rb0[unfolded k]] k r0'
  1924   have ?thesis by (auto simp add: power_mult_distrib simp del: power_Suc)}
  1925 ultimately have ?thesis by (cases k, auto)}
  1926 moreover
  1927 {assume h: "fps_radical r k (a*b) = fps_radical r k a * fps_radical r k b"
  1928   hence "(fps_radical r k (a*b))$0 = (fps_radical r k a * fps_radical r k b)$0" by simp
  1929   then have "r k ((a * b) $ 0) = r k (a $ 0) * r k (b $ 0)"
  1930     using k by (simp add: fps_mult_nth)}
  1931 ultimately show ?thesis by blast
  1932 qed
  1933 
  1934 (*
  1935 lemma radical_mult_distrib:
  1936   fixes a:: "'a::field_char_0 fps"
  1937   assumes
  1938   ra0: "r k (a $ 0) ^ k = a $ 0"
  1939   and rb0: "r k (b $ 0) ^ k = b $ 0"
  1940   and r0': "r k ((a * b) $ 0) = r k (a $ 0) * r k (b $ 0)"
  1941   and a0: "a$0 \<noteq> 0"
  1942   and b0: "b$0 \<noteq> 0"
  1943   shows "fps_radical r (k) (a*b) = fps_radical r (k) a * fps_radical r (k) (b)"
  1944 proof-
  1945   from r0' have r0: "(r (k) ((a*b)$0)) ^ k = (a*b)$0"
  1946     by (simp add: fps_mult_nth ra0 rb0 power_mult_distrib)
  1947   {assume "k=0" hence ?thesis by simp}
  1948   moreover
  1949   {fix h assume k: "k = Suc h"
  1950   let ?ra = "fps_radical r (Suc h) a"
  1951   let ?rb = "fps_radical r (Suc h) b"
  1952   have th0: "r (Suc h) ((a * b) $ 0) = (fps_radical r (Suc h) a * fps_radical r (Suc h) b) $ 0"
  1953     using r0' k by (simp add: fps_mult_nth)
  1954   have ab0: "(a*b) $ 0 \<noteq> 0" using a0 b0 by (simp add: fps_mult_nth)
  1955   from radical_unique[of r h "a*b" "fps_radical r (Suc h) a * fps_radical r (Suc h) b", OF r0[unfolded k] th0 ab0, symmetric]
  1956     power_radical[of r, OF ra0[unfolded k] a0] power_radical[of r, OF rb0[unfolded k] b0] k
  1957   have ?thesis by (auto simp add: power_mult_distrib simp del: power_Suc)}
  1958 ultimately show ?thesis by (cases k, auto)
  1959 qed
  1960 *)
  1961 
  1962 lemma fps_divide_1[simp]: "(a:: ('a::field) fps) / 1 = a"
  1963   by (simp add: fps_divide_def)
  1964 
  1965 lemma radical_divide:
  1966   fixes a :: "'a::field_char_0 fps"
  1967   assumes
  1968   kp: "k>0"
  1969   and ra0: "(r k (a $ 0)) ^ k = a $ 0"
  1970   and rb0: "(r k (b $ 0)) ^ k = b $ 0"
  1971   and a0: "a$0 \<noteq> 0"
  1972   and b0: "b$0 \<noteq> 0"
  1973   shows "r k ((a $ 0) / (b$0)) = r k (a$0) / r k (b $ 0) \<longleftrightarrow> fps_radical r k (a/b) = fps_radical r k a / fps_radical r k b" (is "?lhs = ?rhs")
  1974 proof-
  1975   let ?r = "fps_radical r k"
  1976   from kp obtain h where k: "k = Suc h" by (cases k, auto)
  1977   have ra0': "r k (a$0) \<noteq> 0" using a0 ra0 k by auto
  1978   have rb0': "r k (b$0) \<noteq> 0" using b0 rb0 k by auto
  1979 
  1980   {assume ?rhs
  1981     then have "?r (a/b) $ 0 = (?r a / ?r b)$0" by simp
  1982     then have ?lhs using k a0 b0 rb0' 
  1983       by (simp add: fps_divide_def fps_mult_nth fps_inverse_def divide_inverse) }
  1984   moreover
  1985   {assume h: ?lhs
  1986     from a0 b0 have ab0[simp]: "(a/b)$0 = a$0 / b$0" 
  1987       by (simp add: fps_divide_def fps_mult_nth divide_inverse fps_inverse_def)
  1988     have th0: "r k ((a/b)$0) ^ k = (a/b)$0"
  1989       by (simp add: h nonzero_power_divide[OF rb0'] ra0 rb0 del: k)
  1990     from a0 b0 ra0' rb0' kp h 
  1991     have th1: "r k ((a / b) $ 0) = (fps_radical r k a / fps_radical r k b) $ 0"
  1992       by (simp add: fps_divide_def fps_mult_nth fps_inverse_def divide_inverse del: k)
  1993     from a0 b0 ra0' rb0' kp have ab0': "(a / b) $ 0 \<noteq> 0"
  1994       by (simp add: fps_divide_def fps_mult_nth fps_inverse_def nonzero_imp_inverse_nonzero)
  1995     note tha[simp] = iffD1[OF power_radical[where r=r and k=h], OF a0 ra0[unfolded k], unfolded k[symmetric]]
  1996     note thb[simp] = iffD1[OF power_radical[where r=r and k=h], OF b0 rb0[unfolded k], unfolded k[symmetric]]
  1997     have th2: "(?r a / ?r b)^k = a/b"
  1998       by (simp add: fps_divide_def power_mult_distrib fps_inverse_power[symmetric])
  1999     from iffD1[OF radical_unique[where r=r and a="?r a / ?r b" and b="a/b" and k=h], symmetric, unfolded k[symmetric], OF th0 th1 ab0' th2] have ?rhs .}
  2000   ultimately show ?thesis by blast
  2001 qed
  2002 
  2003 lemma radical_inverse:
  2004   fixes a :: "'a::field_char_0 fps"
  2005   assumes
  2006   k: "k>0"
  2007   and ra0: "r k (a $ 0) ^ k = a $ 0"
  2008   and r1: "(r k 1)^k = 1"
  2009   and a0: "a$0 \<noteq> 0"
  2010   shows "r k (inverse (a $ 0)) = r k 1 / (r k (a $ 0)) \<longleftrightarrow> fps_radical r k (inverse a) = fps_radical r k 1 / fps_radical r k a"
  2011   using radical_divide[where k=k and r=r and a=1 and b=a, OF k ] ra0 r1 a0
  2012   by (simp add: divide_inverse fps_divide_def)
  2013 
  2014 subsection{* Derivative of composition *}
  2015 
  2016 lemma fps_compose_deriv:
  2017   fixes a:: "('a::idom) fps"
  2018   assumes b0: "b$0 = 0"
  2019   shows "fps_deriv (a oo b) = ((fps_deriv a) oo b) * (fps_deriv b)"
  2020 proof-
  2021   {fix n
  2022     have "(fps_deriv (a oo b))$n = setsum (\<lambda>i. a $ i * (fps_deriv (b^i))$n) {0.. Suc n}"
  2023       by (simp add: fps_compose_def ring_simps setsum_right_distrib del: of_nat_Suc)
  2024     also have "\<dots> = setsum (\<lambda>i. a$i * ((fps_const (of_nat i)) * (fps_deriv b * (b^(i - 1))))$n) {0.. Suc n}"
  2025       by (simp add: ring_simps fps_deriv_power del: fps_mult_left_const_nth of_nat_Suc)
  2026   also have "\<dots> = setsum (\<lambda>i. of_nat i * a$i * (((b^(i - 1)) * fps_deriv b))$n) {0.. Suc n}"
  2027     unfolding fps_mult_left_const_nth  by (simp add: ring_simps)
  2028   also have "\<dots> = setsum (\<lambda>i. of_nat i * a$i * (setsum (\<lambda>j. (b^ (i - 1))$j * (fps_deriv b)$(n - j)) {0..n})) {0.. Suc n}"
  2029     unfolding fps_mult_nth ..
  2030   also have "\<dots> = setsum (\<lambda>i. of_nat i * a$i * (setsum (\<lambda>j. (b^ (i - 1))$j * (fps_deriv b)$(n - j)) {0..n})) {1.. Suc n}"
  2031     apply (rule setsum_mono_zero_right)
  2032     apply (auto simp add: mult_delta_left setsum_delta not_le)
  2033     done
  2034   also have "\<dots> = setsum (\<lambda>i. of_nat (i + 1) * a$(i+1) * (setsum (\<lambda>j. (b^ i)$j * of_nat (n - j + 1) * b$(n - j + 1)) {0..n})) {0.. n}"
  2035     unfolding fps_deriv_nth
  2036     apply (rule setsum_reindex_cong[where f="Suc"])
  2037     by (auto simp add: mult_assoc)
  2038   finally have th0: "(fps_deriv (a oo b))$n = setsum (\<lambda>i. of_nat (i + 1) * a$(i+1) * (setsum (\<lambda>j. (b^ i)$j * of_nat (n - j + 1) * b$(n - j + 1)) {0..n})) {0.. n}" .
  2039 
  2040   have "(((fps_deriv a) oo b) * (fps_deriv b))$n = setsum (\<lambda>i. (fps_deriv b)$ (n - i) * ((fps_deriv a) oo b)$i) {0..n}"
  2041     unfolding fps_mult_nth by (simp add: mult_ac)
  2042   also have "\<dots> = setsum (\<lambda>i. setsum (\<lambda>j. of_nat (n - i +1) * b$(n - i + 1) * of_nat (j + 1) * a$(j+1) * (b^j)$i) {0..n}) {0..n}"
  2043     unfolding fps_deriv_nth fps_compose_nth setsum_right_distrib mult_assoc
  2044     apply (rule setsum_cong2)
  2045     apply (rule setsum_mono_zero_left)
  2046     apply (simp_all add: subset_eq)
  2047     apply clarify
  2048     apply (subgoal_tac "b^i$x = 0")
  2049     apply simp
  2050     apply (rule startsby_zero_power_prefix[OF b0, rule_format])
  2051     by simp
  2052   also have "\<dots> = setsum (\<lambda>i. of_nat (i + 1) * a$(i+1) * (setsum (\<lambda>j. (b^ i)$j * of_nat (n - j + 1) * b$(n - j + 1)) {0..n})) {0.. n}"
  2053     unfolding setsum_right_distrib
  2054     apply (subst setsum_commute)
  2055     by ((rule setsum_cong2)+) simp
  2056   finally have "(fps_deriv (a oo b))$n = (((fps_deriv a) oo b) * (fps_deriv b)) $n"
  2057     unfolding th0 by simp}
  2058 then show ?thesis by (simp add: fps_eq_iff)
  2059 qed
  2060 
  2061 lemma fps_mult_X_plus_1_nth:
  2062   "((1+X)*a) $n = (if n = 0 then (a$n :: 'a::comm_ring_1) else a$n + a$(n - 1))"
  2063 proof-
  2064   {assume "n = 0" hence ?thesis by (simp add: fps_mult_nth )}
  2065   moreover
  2066   {fix m assume m: "n = Suc m"
  2067     have "((1+X)*a) $n = setsum (\<lambda>i. (1+X)$i * a$(n-i)) {0..n}"
  2068       by (simp add: fps_mult_nth)
  2069     also have "\<dots> = setsum (\<lambda>i. (1+X)$i * a$(n-i)) {0.. 1}"
  2070       unfolding m
  2071       apply (rule setsum_mono_zero_right)
  2072       by (auto simp add: )
  2073     also have "\<dots> = (if n = 0 then (a$n :: 'a::comm_ring_1) else a$n + a$(n - 1))"
  2074       unfolding m
  2075       by (simp add: )
  2076     finally have ?thesis .}
  2077   ultimately show ?thesis by (cases n, auto)
  2078 qed
  2079 
  2080 subsection{* Finite FPS (i.e. polynomials) and X *}
  2081 lemma fps_poly_sum_X:
  2082   assumes z: "\<forall>i > n. a$i = (0::'a::comm_ring_1)"
  2083   shows "a = setsum (\<lambda>i. fps_const (a$i) * X^i) {0..n}" (is "a = ?r")
  2084 proof-
  2085   {fix i
  2086     have "a$i = ?r$i"
  2087       unfolding fps_setsum_nth fps_mult_left_const_nth X_power_nth
  2088       by (simp add: mult_delta_right setsum_delta' z)
  2089   }
  2090   then show ?thesis unfolding fps_eq_iff by blast
  2091 qed
  2092 
  2093 subsection{* Compositional inverses *}
  2094 
  2095 
  2096 fun compinv :: "'a fps \<Rightarrow> nat \<Rightarrow> 'a::{field}" where
  2097   "compinv a 0 = X$0"
  2098 | "compinv a (Suc n) = (X$ Suc n - setsum (\<lambda>i. (compinv a i) * (a^i)$Suc n) {0 .. n}) / (a$1) ^ Suc n"
  2099 
  2100 definition "fps_inv a = Abs_fps (compinv a)"
  2101 
  2102 lemma fps_inv: assumes a0: "a$0 = 0" and a1: "a$1 \<noteq> 0"
  2103   shows "fps_inv a oo a = X"
  2104 proof-
  2105   let ?i = "fps_inv a oo a"
  2106   {fix n
  2107     have "?i $n = X$n"
  2108     proof(induct n rule: nat_less_induct)
  2109       fix n assume h: "\<forall>m<n. ?i$m = X$m"
  2110       {assume "n=0" hence "?i $n = X$n" using a0
  2111 	  by (simp add: fps_compose_nth fps_inv_def)}
  2112       moreover
  2113       {fix n1 assume n1: "n = Suc n1"
  2114 	have "?i $ n = setsum (\<lambda>i. (fps_inv a $ i) * (a^i)$n) {0 .. n1} + fps_inv a $ Suc n1 * (a $ 1)^ Suc n1"
  2115 	  by (simp add: fps_compose_nth n1 startsby_zero_power_nth_same[OF a0]
  2116                    del: power_Suc)
  2117 	also have "\<dots> = setsum (\<lambda>i. (fps_inv a $ i) * (a^i)$n) {0 .. n1} + (X$ Suc n1 - setsum (\<lambda>i. (fps_inv a $ i) * (a^i)$n) {0 .. n1})"
  2118 	  using a0 a1 n1 by (simp add: fps_inv_def)
  2119 	also have "\<dots> = X$n" using n1 by simp
  2120 	finally have "?i $ n = X$n" .}
  2121       ultimately show "?i $ n = X$n" by (cases n, auto)
  2122     qed}
  2123   then show ?thesis by (simp add: fps_eq_iff)
  2124 qed
  2125 
  2126 
  2127 fun gcompinv :: "'a fps \<Rightarrow> 'a fps \<Rightarrow> nat \<Rightarrow> 'a::{field}" where
  2128   "gcompinv b a 0 = b$0"
  2129 | "gcompinv b a (Suc n) = (b$ Suc n - setsum (\<lambda>i. (gcompinv b a i) * (a^i)$Suc n) {0 .. n}) / (a$1) ^ Suc n"
  2130 
  2131 definition "fps_ginv b a = Abs_fps (gcompinv b a)"
  2132 
  2133 lemma fps_ginv: assumes a0: "a$0 = 0" and a1: "a$1 \<noteq> 0"
  2134   shows "fps_ginv b a oo a = b"
  2135 proof-
  2136   let ?i = "fps_ginv b a oo a"
  2137   {fix n
  2138     have "?i $n = b$n"
  2139     proof(induct n rule: nat_less_induct)
  2140       fix n assume h: "\<forall>m<n. ?i$m = b$m"
  2141       {assume "n=0" hence "?i $n = b$n" using a0
  2142 	  by (simp add: fps_compose_nth fps_ginv_def)}
  2143       moreover
  2144       {fix n1 assume n1: "n = Suc n1"
  2145 	have "?i $ n = setsum (\<lambda>i. (fps_ginv b a $ i) * (a^i)$n) {0 .. n1} + fps_ginv b a $ Suc n1 * (a $ 1)^ Suc n1"
  2146 	  by (simp add: fps_compose_nth n1 startsby_zero_power_nth_same[OF a0]
  2147                    del: power_Suc)
  2148 	also have "\<dots> = setsum (\<lambda>i. (fps_ginv b a $ i) * (a^i)$n) {0 .. n1} + (b$ Suc n1 - setsum (\<lambda>i. (fps_ginv b a $ i) * (a^i)$n) {0 .. n1})"
  2149 	  using a0 a1 n1 by (simp add: fps_ginv_def)
  2150 	also have "\<dots> = b$n" using n1 by simp
  2151 	finally have "?i $ n = b$n" .}
  2152       ultimately show "?i $ n = b$n" by (cases n, auto)
  2153     qed}
  2154   then show ?thesis by (simp add: fps_eq_iff)
  2155 qed
  2156 
  2157 lemma fps_inv_ginv: "fps_inv = fps_ginv X"
  2158   apply (auto simp add: expand_fun_eq fps_eq_iff fps_inv_def fps_ginv_def)
  2159   apply (induct_tac n rule: nat_less_induct, auto)
  2160   apply (case_tac na)
  2161   apply simp
  2162   apply simp
  2163   done
  2164 
  2165 lemma fps_compose_1[simp]: "1 oo a = 1"
  2166   by (simp add: fps_eq_iff fps_compose_nth mult_delta_left setsum_delta)
  2167 
  2168 lemma fps_compose_0[simp]: "0 oo a = 0"
  2169   by (simp add: fps_eq_iff fps_compose_nth)
  2170 
  2171 lemma fps_compose_0_right[simp]: "a oo 0 = fps_const (a$0)"
  2172   by (auto simp add: fps_eq_iff fps_compose_nth power_0_left setsum_0')
  2173 
  2174 lemma fps_compose_add_distrib: "(a + b) oo c = (a oo c) + (b oo c)"
  2175   by (simp add: fps_eq_iff fps_compose_nth ring_simps setsum_addf)
  2176 
  2177 lemma fps_compose_setsum_distrib: "(setsum f S) oo a = setsum (\<lambda>i. f i oo a) S"
  2178 proof-
  2179   {assume "\<not> finite S" hence ?thesis by simp}
  2180   moreover
  2181   {assume fS: "finite S"
  2182     have ?thesis
  2183     proof(rule finite_induct[OF fS])
  2184       show "setsum f {} oo a = (\<Sum>i\<in>{}. f i oo a)" by simp
  2185     next
  2186       fix x F assume fF: "finite F" and xF: "x \<notin> F" and h: "setsum f F oo a = setsum (\<lambda>i. f i oo a) F"
  2187       show "setsum f (insert x F) oo a  = setsum (\<lambda>i. f i oo a) (insert x F)"
  2188 	using fF xF h by (simp add: fps_compose_add_distrib)
  2189     qed}
  2190   ultimately show ?thesis by blast
  2191 qed
  2192 
  2193 lemma convolution_eq:
  2194   "setsum (%i. a (i :: nat) * b (n - i)) {0 .. n} = setsum (%(i,j). a i * b j) {(i,j). i <= n \<and> j \<le> n \<and> i + j = n}"
  2195   apply (rule setsum_reindex_cong[where f=fst])
  2196   apply (clarsimp simp add: inj_on_def)
  2197   apply (auto simp add: expand_set_eq image_iff)
  2198   apply (rule_tac x= "x" in exI)
  2199   apply clarsimp
  2200   apply (rule_tac x="n - x" in exI)
  2201   apply arith
  2202   done
  2203 
  2204 lemma product_composition_lemma:
  2205   assumes c0: "c$0 = (0::'a::idom)" and d0: "d$0 = 0"
  2206   shows "((a oo c) * (b oo d))$n = setsum (%(k,m). a$k * b$m * (c^k * d^m) $ n) {(k,m). k + m \<le> n}" (is "?l = ?r")
  2207 proof-
  2208   let ?S = "{(k\<Colon>nat, m\<Colon>nat). k + m \<le> n}"
  2209   have s: "?S \<subseteq> {0..n} <*> {0..n}" by (auto simp add: subset_eq)
  2210   have f: "finite {(k\<Colon>nat, m\<Colon>nat). k + m \<le> n}"
  2211     apply (rule finite_subset[OF s])
  2212     by auto
  2213   have "?r =  setsum (%i. setsum (%(k,m). a$k * (c^k)$i * b$m * (d^m) $ (n - i)) {(k,m). k + m \<le> n}) {0..n}"
  2214     apply (simp add: fps_mult_nth setsum_right_distrib)
  2215     apply (subst setsum_commute)
  2216     apply (rule setsum_cong2)
  2217     by (auto simp add: ring_simps)
  2218   also have "\<dots> = ?l"
  2219     apply (simp add: fps_mult_nth fps_compose_nth setsum_product)
  2220     apply (rule setsum_cong2)
  2221     apply (simp add: setsum_cartesian_product mult_assoc)
  2222     apply (rule setsum_mono_zero_right[OF f])
  2223     apply (simp add: subset_eq) apply presburger
  2224     apply clarsimp
  2225     apply (rule ccontr)
  2226     apply (clarsimp simp add: not_le)
  2227     apply (case_tac "x < aa")
  2228     apply simp
  2229     apply (frule_tac startsby_zero_power_prefix[rule_format, OF c0])
  2230     apply blast
  2231     apply simp
  2232     apply (frule_tac startsby_zero_power_prefix[rule_format, OF d0])
  2233     apply blast
  2234     done
  2235   finally show ?thesis by simp
  2236 qed
  2237 
  2238 lemma product_composition_lemma':
  2239   assumes c0: "c$0 = (0::'a::idom)" and d0: "d$0 = 0"
  2240   shows "((a oo c) * (b oo d))$n = setsum (%k. setsum (%m. a$k * b$m * (c^k * d^m) $ n) {0..n}) {0..n}" (is "?l = ?r")
  2241   unfolding product_composition_lemma[OF c0 d0]
  2242   unfolding setsum_cartesian_product
  2243   apply (rule setsum_mono_zero_left)
  2244   apply simp
  2245   apply (clarsimp simp add: subset_eq)
  2246   apply clarsimp
  2247   apply (rule ccontr)
  2248   apply (subgoal_tac "(c^aa * d^ba) $ n = 0")
  2249   apply simp
  2250   unfolding fps_mult_nth
  2251   apply (rule setsum_0')
  2252   apply (clarsimp simp add: not_le)
  2253   apply (case_tac "aaa < aa")
  2254   apply (rule startsby_zero_power_prefix[OF c0, rule_format])
  2255   apply simp
  2256   apply (subgoal_tac "n - aaa < ba")
  2257   apply (frule_tac k = "ba" in startsby_zero_power_prefix[OF d0, rule_format])
  2258   apply simp
  2259   apply arith
  2260   done
  2261 
  2262 
  2263 lemma setsum_pair_less_iff:
  2264   "setsum (%((k::nat),m). a k * b m * c (k + m)) {(k,m). k + m \<le> n} = setsum (%s. setsum (%i. a i * b (s - i) * c s) {0..s}) {0..n}" (is "?l = ?r")
  2265 proof-
  2266   let ?KM=  "{(k,m). k + m \<le> n}"
  2267   let ?f = "%s. UNION {(0::nat)..s} (%i. {(i,s - i)})"
  2268   have th0: "?KM = UNION {0..n} ?f"
  2269     apply (simp add: expand_set_eq)
  2270     apply arith (* FIXME: VERY slow! *)
  2271     done
  2272   show "?l = ?r "
  2273     unfolding th0
  2274     apply (subst setsum_UN_disjoint)
  2275     apply auto
  2276     apply (subst setsum_UN_disjoint)
  2277     apply auto
  2278     done
  2279 qed
  2280 
  2281 lemma fps_compose_mult_distrib_lemma:
  2282   assumes c0: "c$0 = (0::'a::idom)"
  2283   shows "((a oo c) * (b oo c))$n = setsum (%s. setsum (%i. a$i * b$(s - i) * (c^s) $ n) {0..s}) {0..n}" (is "?l = ?r")
  2284   unfolding product_composition_lemma[OF c0 c0] power_add[symmetric]
  2285   unfolding setsum_pair_less_iff[where a = "%k. a$k" and b="%m. b$m" and c="%s. (c ^ s)$n" and n = n] ..
  2286 
  2287 
  2288 lemma fps_compose_mult_distrib:
  2289   assumes c0: "c$0 = (0::'a::idom)"
  2290   shows "(a * b) oo c = (a oo c) * (b oo c)" (is "?l = ?r")
  2291   apply (simp add: fps_eq_iff fps_compose_mult_distrib_lemma[OF c0])
  2292   by (simp add: fps_compose_nth fps_mult_nth setsum_left_distrib)
  2293 lemma fps_compose_setprod_distrib:
  2294   assumes c0: "c$0 = (0::'a::idom)"
  2295   shows "(setprod a S) oo c = setprod (%k. a k oo c) S" (is "?l = ?r")
  2296   apply (cases "finite S")
  2297   apply simp_all
  2298   apply (induct S rule: finite_induct)
  2299   apply simp
  2300   apply (simp add: fps_compose_mult_distrib[OF c0])
  2301   done
  2302 
  2303 lemma fps_compose_power:   assumes c0: "c$0 = (0::'a::idom)"
  2304   shows "(a oo c)^n = a^n oo c" (is "?l = ?r")
  2305 proof-
  2306   {assume "n=0" then have ?thesis by simp}
  2307   moreover
  2308   {fix m assume m: "n = Suc m"
  2309     have th0: "a^n = setprod (%k. a) {0..m}" "(a oo c) ^ n = setprod (%k. a oo c) {0..m}"
  2310       by (simp_all add: setprod_constant m)
  2311     then have ?thesis
  2312       by (simp add: fps_compose_setprod_distrib[OF c0])}
  2313   ultimately show ?thesis by (cases n, auto)
  2314 qed
  2315 
  2316 lemma fps_compose_uminus: "- (a::'a::ring_1 fps) oo c = - (a oo c)"
  2317   by (simp add: fps_eq_iff fps_compose_nth ring_simps setsum_negf[symmetric])
  2318 
  2319 lemma fps_compose_sub_distrib:
  2320   shows "(a - b) oo (c::'a::ring_1 fps) = (a oo c) - (b oo c)"
  2321   unfolding diff_minus fps_compose_uminus fps_compose_add_distrib ..
  2322 
  2323 lemma X_fps_compose:"X oo a = Abs_fps (\<lambda>n. if n = 0 then (0::'a::comm_ring_1) else a$n)"
  2324   by (simp add: fps_eq_iff fps_compose_nth mult_delta_left setsum_delta power_Suc)
  2325 
  2326 lemma fps_inverse_compose:
  2327   assumes b0: "(b$0 :: 'a::field) = 0" and a0: "a$0 \<noteq> 0"
  2328   shows "inverse a oo b = inverse (a oo b)"
  2329 proof-
  2330   let ?ia = "inverse a"
  2331   let ?ab = "a oo b"
  2332   let ?iab = "inverse ?ab"
  2333 
  2334 from a0 have ia0: "?ia $ 0 \<noteq> 0" by (simp )
  2335 from a0 have ab0: "?ab $ 0 \<noteq> 0" by (simp add: fps_compose_def)
  2336 thm inverse_mult_eq_1[OF ab0]
  2337 have "(?ia oo b) *  (a oo b) = 1"
  2338 unfolding fps_compose_mult_distrib[OF b0, symmetric]
  2339 unfolding inverse_mult_eq_1[OF a0]
  2340 fps_compose_1 ..
  2341 
  2342 then have "(?ia oo b) *  (a oo b) * ?iab  = 1 * ?iab" by simp
  2343 then have "(?ia oo b) *  (?iab * (a oo b))  = ?iab" by simp
  2344 then show ?thesis 
  2345   unfolding inverse_mult_eq_1[OF ab0] by simp
  2346 qed
  2347 
  2348 lemma fps_divide_compose:
  2349   assumes c0: "(c$0 :: 'a::field) = 0" and b0: "b$0 \<noteq> 0"
  2350   shows "(a/b) oo c = (a oo c) / (b oo c)"
  2351     unfolding fps_divide_def fps_compose_mult_distrib[OF c0]
  2352     fps_inverse_compose[OF c0 b0] ..
  2353 
  2354 lemma gp: assumes a0: "a$0 = (0::'a::field)"
  2355   shows "(Abs_fps (\<lambda>n. 1)) oo a = 1/(1 - a)" (is "?one oo a = _")
  2356 proof-
  2357   have o0: "?one $ 0 \<noteq> 0" by simp
  2358   have th0: "(1 - X) $ 0 \<noteq> (0::'a)" by simp  
  2359   from fps_inverse_gp[where ?'a = 'a]
  2360   have "inverse ?one = 1 - X" by (simp add: fps_eq_iff)
  2361   hence "inverse (inverse ?one) = inverse (1 - X)" by simp
  2362   hence th: "?one = 1/(1 - X)" unfolding fps_inverse_idempotent[OF o0] 
  2363     by (simp add: fps_divide_def)
  2364   show ?thesis unfolding th
  2365     unfolding fps_divide_compose[OF a0 th0]
  2366     fps_compose_1 fps_compose_sub_distrib X_fps_compose_startby0[OF a0] ..
  2367 qed
  2368 
  2369 lemma fps_const_power[simp]: "fps_const (c::'a::ring_1) ^ n = fps_const (c^n)"
  2370 by (induct n, auto)
  2371 
  2372 lemma fps_compose_radical:
  2373   assumes b0: "b$0 = (0::'a::field_char_0)"
  2374   and ra0: "r (Suc k) (a$0) ^ Suc k = a$0"
  2375   and a0: "a$0 \<noteq> 0"
  2376   shows "fps_radical r (Suc k)  a oo b = fps_radical r (Suc k) (a oo b)"
  2377 proof-
  2378   let ?r = "fps_radical r (Suc k)"
  2379   let ?ab = "a oo b"
  2380   have ab0: "?ab $ 0 = a$0" by (simp add: fps_compose_def)
  2381   from ab0 a0 ra0 have rab0: "?ab $ 0 \<noteq> 0" "r (Suc k) (?ab $ 0) ^ Suc k = ?ab $ 0" by simp_all
  2382   have th00: "r (Suc k) ((a oo b) $ 0) = (fps_radical r (Suc k) a oo b) $ 0"
  2383     by (simp add: ab0 fps_compose_def)
  2384   have th0: "(?r a oo b) ^ (Suc k) = a  oo b"
  2385     unfolding fps_compose_power[OF b0]
  2386     unfolding iffD1[OF power_radical[of a r k], OF a0 ra0]  .. 
  2387   from iffD1[OF radical_unique[where r=r and k=k and b= ?ab and a = "?r a oo b", OF rab0(2) th00 rab0(1)], OF th0] show ?thesis  . 
  2388 qed
  2389 
  2390 lemma fps_const_mult_apply_left:
  2391   "fps_const c * (a oo b) = (fps_const c * a) oo b"
  2392   by (simp add: fps_eq_iff fps_compose_nth setsum_right_distrib mult_assoc)
  2393 
  2394 lemma fps_const_mult_apply_right:
  2395   "(a oo b) * fps_const (c::'a::comm_semiring_1) = (fps_const c * a) oo b"
  2396   by (auto simp add: fps_const_mult_apply_left mult_commute)
  2397 
  2398 lemma fps_compose_assoc:
  2399   assumes c0: "c$0 = (0::'a::idom)" and b0: "b$0 = 0"
  2400   shows "a oo (b oo c) = a oo b oo c" (is "?l = ?r")
  2401 proof-
  2402   {fix n
  2403     have "?l$n = (setsum (\<lambda>i. (fps_const (a$i) * b^i) oo c) {0..n})$n"
  2404       by (simp add: fps_compose_nth fps_compose_power[OF c0] fps_const_mult_apply_left setsum_right_distrib mult_assoc fps_setsum_nth)
  2405     also have "\<dots> = ((setsum (\<lambda>i. fps_const (a$i) * b^i) {0..n}) oo c)$n"
  2406       by (simp add: fps_compose_setsum_distrib)
  2407     also have "\<dots> = ?r$n"
  2408       apply (simp add: fps_compose_nth fps_setsum_nth setsum_left_distrib mult_assoc)
  2409       apply (rule setsum_cong2)
  2410       apply (rule setsum_mono_zero_right)
  2411       apply (auto simp add: not_le)
  2412       by (erule startsby_zero_power_prefix[OF b0, rule_format])
  2413     finally have "?l$n = ?r$n" .}
  2414   then show ?thesis by (simp add: fps_eq_iff)
  2415 qed
  2416 
  2417 
  2418 lemma fps_X_power_compose:
  2419   assumes a0: "a$0=0" shows "X^k oo a = (a::('a::idom fps))^k" (is "?l = ?r")
  2420 proof-
  2421   {assume "k=0" hence ?thesis by simp}
  2422   moreover
  2423   {fix h assume h: "k = Suc h"
  2424     {fix n
  2425       {assume kn: "k>n" hence "?l $ n = ?r $n" using a0 startsby_zero_power_prefix[OF a0] h
  2426 	  by (simp add: fps_compose_nth del: power_Suc)}
  2427       moreover
  2428       {assume kn: "k \<le> n"
  2429 	hence "?l$n = ?r$n"
  2430           by (simp add: fps_compose_nth mult_delta_left setsum_delta)}
  2431       moreover have "k >n \<or> k\<le> n"  by arith
  2432       ultimately have "?l$n = ?r$n"  by blast}
  2433     then have ?thesis unfolding fps_eq_iff by blast}
  2434   ultimately show ?thesis by (cases k, auto)
  2435 qed
  2436 
  2437 lemma fps_inv_right: assumes a0: "a$0 = 0" and a1: "a$1 \<noteq> 0"
  2438   shows "a oo fps_inv a = X"
  2439 proof-
  2440   let ?ia = "fps_inv a"
  2441   let ?iaa = "a oo fps_inv a"
  2442   have th0: "?ia $ 0 = 0" by (simp add: fps_inv_def)
  2443   have th1: "?iaa $ 0 = 0" using a0 a1
  2444     by (simp add: fps_inv_def fps_compose_nth)
  2445   have th2: "X$0 = 0" by simp
  2446   from fps_inv[OF a0 a1] have "a oo (fps_inv a oo a) = a oo X" by simp
  2447   then have "(a oo fps_inv a) oo a = X oo a"
  2448     by (simp add: fps_compose_assoc[OF a0 th0] X_fps_compose_startby0[OF a0])
  2449   with fps_compose_inj_right[OF a0 a1]
  2450   show ?thesis by simp
  2451 qed
  2452 
  2453 lemma fps_inv_deriv:
  2454   assumes a0:"a$0 = (0::'a::{field})" and a1: "a$1 \<noteq> 0"
  2455   shows "fps_deriv (fps_inv a) = inverse (fps_deriv a oo fps_inv a)"
  2456 proof-
  2457   let ?ia = "fps_inv a"
  2458   let ?d = "fps_deriv a oo ?ia"
  2459   let ?dia = "fps_deriv ?ia"
  2460   have ia0: "?ia$0 = 0" by (simp add: fps_inv_def)
  2461   have th0: "?d$0 \<noteq> 0" using a1 by (simp add: fps_compose_nth fps_deriv_nth)
  2462   from fps_inv_right[OF a0 a1] have "?d * ?dia = 1"
  2463     by (simp add: fps_compose_deriv[OF ia0, of a, symmetric] )
  2464   hence "inverse ?d * ?d * ?dia = inverse ?d * 1" by simp
  2465   with inverse_mult_eq_1[OF th0]
  2466   show "?dia = inverse ?d" by simp
  2467 qed
  2468 
  2469 lemma fps_inv_idempotent: 
  2470   assumes a0: "a$0 = 0" and a1: "a$1 \<noteq> 0"
  2471   shows "fps_inv (fps_inv a) = a"
  2472 proof-
  2473   let ?r = "fps_inv"
  2474   have ra0: "?r a $ 0 = 0" by (simp add: fps_inv_def)
  2475   from a1 have ra1: "?r a $ 1 \<noteq> 0" by (simp add: fps_inv_def field_simps)
  2476   have X0: "X$0 = 0" by simp
  2477   from fps_inv[OF ra0 ra1] have "?r (?r a) oo ?r a = X" .
  2478   then have "?r (?r a) oo ?r a oo a = X oo a" by simp
  2479   then have "?r (?r a) oo (?r a oo a) = a" 
  2480     unfolding X_fps_compose_startby0[OF a0]
  2481     unfolding fps_compose_assoc[OF a0 ra0, symmetric] .
  2482   then show ?thesis unfolding fps_inv[OF a0 a1] by simp
  2483 qed
  2484 
  2485 lemma fps_ginv_ginv:
  2486   assumes a0: "a$0 = 0" and a1: "a$1 \<noteq> 0"
  2487   and c0: "c$0 = 0" and  c1: "c$1 \<noteq> 0"
  2488   shows "fps_ginv b (fps_ginv c a) = b oo a oo fps_inv c"
  2489 proof-
  2490   let ?r = "fps_ginv"
  2491   from c0 have rca0: "?r c a $0 = 0" by (simp add: fps_ginv_def)
  2492   from a1 c1 have rca1: "?r c a $ 1 \<noteq> 0" by (simp add: fps_ginv_def field_simps)
  2493   from fps_ginv[OF rca0 rca1] 
  2494   have "?r b (?r c a) oo ?r c a = b" .
  2495   then have "?r b (?r c a) oo ?r c a oo a = b oo a" by simp
  2496   then have "?r b (?r c a) oo (?r c a oo a) = b oo a"
  2497     apply (subst fps_compose_assoc)
  2498     using a0 c0 by (auto simp add: fps_ginv_def)
  2499   then have "?r b (?r c a) oo c = b oo a"
  2500     unfolding fps_ginv[OF a0 a1] .
  2501   then have "?r b (?r c a) oo c oo fps_inv c= b oo a oo fps_inv c" by simp
  2502   then have "?r b (?r c a) oo (c oo fps_inv c) = b oo a oo fps_inv c"
  2503     apply (subst fps_compose_assoc)
  2504     using a0 c0 by (auto simp add: fps_inv_def)
  2505   then show ?thesis unfolding fps_inv_right[OF c0 c1] by simp
  2506 qed
  2507 
  2508 subsection{* Elementary series *}
  2509 
  2510 subsubsection{* Exponential series *}
  2511 definition "E x = Abs_fps (\<lambda>n. x^n / of_nat (fact n))"
  2512 
  2513 lemma E_deriv[simp]: "fps_deriv (E a) = fps_const (a::'a::field_char_0) * E a" (is "?l = ?r")
  2514 proof-
  2515   {fix n
  2516     have "?l$n = ?r $ n"
  2517   apply (auto simp add: E_def field_simps power_Suc[symmetric]simp del: fact_Suc_nat of_nat_Suc power_Suc)
  2518   by (simp add: of_nat_mult ring_simps)}
  2519 then show ?thesis by (simp add: fps_eq_iff)
  2520 qed
  2521 
  2522 lemma E_unique_ODE:
  2523   "fps_deriv a = fps_const c * a \<longleftrightarrow> a = fps_const (a$0) * E (c :: 'a::field_char_0)"
  2524   (is "?lhs \<longleftrightarrow> ?rhs")
  2525 proof-
  2526   {assume d: ?lhs
  2527   from d have th: "\<And>n. a $ Suc n = c * a$n / of_nat (Suc n)"
  2528     by (simp add: fps_deriv_def fps_eq_iff field_simps del: of_nat_Suc)
  2529   {fix n have "a$n = a$0 * c ^ n/ (of_nat (fact n))"
  2530       apply (induct n)
  2531       apply simp
  2532       unfolding th
  2533       using fact_gt_zero_nat
  2534       apply (simp add: field_simps del: of_nat_Suc fact_Suc_nat)
  2535       apply (drule sym)
  2536       by (simp add: ring_simps of_nat_mult power_Suc)}
  2537   note th' = this
  2538   have ?rhs
  2539     by (auto simp add: fps_eq_iff fps_const_mult_left E_def intro : th')}
  2540 moreover
  2541 {assume h: ?rhs
  2542   have ?lhs
  2543     apply (subst h)
  2544     apply simp
  2545     apply (simp only: h[symmetric])
  2546   by simp}
  2547 ultimately show ?thesis by blast
  2548 qed
  2549 
  2550 lemma E_add_mult: "E (a + b) = E (a::'a::field_char_0) * E b" (is "?l = ?r")
  2551 proof-
  2552   have "fps_deriv (?r) = fps_const (a+b) * ?r"
  2553     by (simp add: fps_const_add[symmetric] ring_simps del: fps_const_add)
  2554   then have "?r = ?l" apply (simp only: E_unique_ODE)
  2555     by (simp add: fps_mult_nth E_def)
  2556   then show ?thesis ..
  2557 qed
  2558 
  2559 lemma E_nth[simp]: "E a $ n = a^n / of_nat (fact n)"
  2560   by (simp add: E_def)
  2561 
  2562 lemma E0[simp]: "E (0::'a::{field}) = 1"
  2563   by (simp add: fps_eq_iff power_0_left)
  2564 
  2565 lemma E_neg: "E (- a) = inverse (E (a::'a::field_char_0))"
  2566 proof-
  2567   from E_add_mult[of a "- a"] have th0: "E a * E (- a) = 1"
  2568     by (simp )
  2569   have th1: "E a $ 0 \<noteq> 0" by simp
  2570   from fps_inverse_unique[OF th1 th0] show ?thesis by simp
  2571 qed
  2572 
  2573 lemma E_nth_deriv[simp]: "fps_nth_deriv n (E (a::'a::field_char_0)) = (fps_const a)^n * (E a)"
  2574   by (induct n, auto simp add: power_Suc)
  2575 
  2576 lemma X_compose_E[simp]: "X oo E (a::'a::{field}) = E a - 1"
  2577   by (simp add: fps_eq_iff X_fps_compose)
  2578 
  2579 lemma LE_compose:
  2580   assumes a: "a\<noteq>0"
  2581   shows "fps_inv (E a - 1) oo (E a - 1) = X"
  2582   and "(E a - 1) oo fps_inv (E a - 1) = X"
  2583 proof-
  2584   let ?b = "E a - 1"
  2585   have b0: "?b $ 0 = 0" by simp
  2586   have b1: "?b $ 1 \<noteq> 0" by (simp add: a)
  2587   from fps_inv[OF b0 b1] show "fps_inv (E a - 1) oo (E a - 1) = X" .
  2588   from fps_inv_right[OF b0 b1] show "(E a - 1) oo fps_inv (E a - 1) = X" .
  2589 qed
  2590 
  2591 
  2592 lemma fps_const_inverse:
  2593   "a \<noteq> 0 \<Longrightarrow> inverse (fps_const (a::'a::field)) = fps_const (inverse a)"
  2594   apply (auto simp add: fps_eq_iff fps_inverse_def) by (case_tac "n", auto)
  2595 
  2596 lemma inverse_one_plus_X:
  2597   "inverse (1 + X) = Abs_fps (\<lambda>n. (- 1 ::'a::{field})^n)"
  2598   (is "inverse ?l = ?r")
  2599 proof-
  2600   have th: "?l * ?r = 1"
  2601     by (auto simp add: ring_simps fps_eq_iff minus_one_power_iff)
  2602   have th': "?l $ 0 \<noteq> 0" by (simp add: )
  2603   from fps_inverse_unique[OF th' th] show ?thesis .
  2604 qed
  2605 
  2606 lemma E_power_mult: "(E (c::'a::field_char_0))^n = E (of_nat n * c)"
  2607   by (induct n, auto simp add: ring_simps E_add_mult power_Suc)
  2608 
  2609 lemma assumes r: "r (Suc k) 1 = 1" 
  2610   shows "fps_radical r (Suc k) (E (c::'a::{field_char_0})) = E (c / of_nat (Suc k))"
  2611 proof-
  2612   let ?ck = "(c / of_nat (Suc k))"
  2613   let ?r = "fps_radical r (Suc k)"
  2614   have eq0[simp]: "?ck * of_nat (Suc k) = c" "of_nat (Suc k) * ?ck = c"
  2615     by (simp_all del: of_nat_Suc)
  2616   have th0: "E ?ck ^ (Suc k) = E c" unfolding E_power_mult eq0 ..
  2617   have th: "r (Suc k) (E c $0) ^ Suc k = E c $ 0"
  2618     "r (Suc k) (E c $ 0) = E ?ck $ 0" "E c $ 0 \<noteq> 0" using r by simp_all
  2619   from th0 radical_unique[where r=r and k=k, OF th]
  2620   show ?thesis by auto 
  2621 qed
  2622 
  2623 lemma Ec_E1_eq: 
  2624   "E (1::'a::{field_char_0}) oo (fps_const c * X) = E c"
  2625   apply (auto simp add: fps_eq_iff E_def fps_compose_def power_mult_distrib)
  2626   by (simp add: cond_value_iff cond_application_beta setsum_delta' cong del: if_weak_cong)
  2627 
  2628 subsubsection{* Logarithmic series *}
  2629 
  2630 lemma Abs_fps_if_0: 
  2631   "Abs_fps(%n. if n=0 then (v::'a::ring_1) else f n) = fps_const v + X * Abs_fps (%n. f (Suc n))"
  2632   by (auto simp add: fps_eq_iff)
  2633 
  2634 definition L:: "'a::{field_char_0} \<Rightarrow> 'a fps" where 
  2635   "L c \<equiv> fps_const (1/c) * Abs_fps (\<lambda>n. if n = 0 then 0 else (- 1) ^ (n - 1) / of_nat n)"
  2636 
  2637 lemma fps_deriv_L: "fps_deriv (L c) = fps_const (1/c) * inverse (1 + X)"
  2638   unfolding inverse_one_plus_X
  2639   by (simp add: L_def fps_eq_iff del: of_nat_Suc)
  2640 
  2641 lemma L_nth: "L c $ n = (if n=0 then 0 else 1/c * ((- 1) ^ (n - 1) / of_nat n))"
  2642   by (simp add: L_def field_simps)
  2643 
  2644 lemma L_0[simp]: "L c $ 0 = 0" by (simp add: L_def)
  2645 lemma L_E_inv:
  2646   assumes a: "a\<noteq> (0::'a::{field_char_0})"
  2647   shows "L a = fps_inv (E a - 1)" (is "?l = ?r")
  2648 proof-
  2649   let ?b = "E a - 1"
  2650   have b0: "?b $ 0 = 0" by simp
  2651   have b1: "?b $ 1 \<noteq> 0" by (simp add: a)
  2652   have "fps_deriv (E a - 1) oo fps_inv (E a - 1) = (fps_const a * (E a - 1) + fps_const a) oo fps_inv (E a - 1)"
  2653     by (simp add: ring_simps)
  2654   also have "\<dots> = fps_const a * (X + 1)" apply (simp add: fps_compose_add_distrib fps_const_mult_apply_left[symmetric] fps_inv_right[OF b0 b1])
  2655     by (simp add: ring_simps)
  2656   finally have eq: "fps_deriv (E a - 1) oo fps_inv (E a - 1) = fps_const a * (X + 1)" .
  2657   from fps_inv_deriv[OF b0 b1, unfolded eq]
  2658   have "fps_deriv (fps_inv ?b) = fps_const (inverse a) / (X + 1)"
  2659     using a 
  2660     by (simp add: fps_const_inverse eq fps_divide_def fps_inverse_mult)
  2661   hence "fps_deriv ?l = fps_deriv ?r"
  2662     by (simp add: fps_deriv_L add_commute fps_divide_def divide_inverse)
  2663   then show ?thesis unfolding fps_deriv_eq_iff
  2664     by (simp add: L_nth fps_inv_def)
  2665 qed
  2666 
  2667 lemma L_mult_add: 
  2668   assumes c0: "c\<noteq>0" and d0: "d\<noteq>0"
  2669   shows "L c + L d = fps_const (c+d) * L (c*d)"
  2670   (is "?r = ?l")
  2671 proof-
  2672   from c0 d0 have eq: "1/c + 1/d = (c+d)/(c*d)" by (simp add: field_simps)
  2673   have "fps_deriv ?r = fps_const (1/c + 1/d) * inverse (1 + X)"
  2674     by (simp add: fps_deriv_L fps_const_add[symmetric] algebra_simps del: fps_const_add)
  2675   also have "\<dots> = fps_deriv ?l"
  2676     apply (simp add: fps_deriv_L)
  2677     by (simp add: fps_eq_iff eq)
  2678   finally show ?thesis
  2679     unfolding fps_deriv_eq_iff by simp
  2680 qed
  2681 
  2682 subsubsection{* Formal trigonometric functions  *}
  2683 
  2684 definition "fps_sin (c::'a::field_char_0) =
  2685   Abs_fps (\<lambda>n. if even n then 0 else (- 1) ^((n - 1) div 2) * c^n /(of_nat (fact n)))"
  2686 
  2687 definition "fps_cos (c::'a::field_char_0) =
  2688   Abs_fps (\<lambda>n. if even n then (- 1) ^ (n div 2) * c^n / (of_nat (fact n)) else 0)"
  2689 
  2690 lemma fps_sin_deriv:
  2691   "fps_deriv (fps_sin c) = fps_const c * fps_cos c"
  2692   (is "?lhs = ?rhs")
  2693 proof (rule fps_ext)
  2694   fix n::nat
  2695     {assume en: "even n"
  2696       have "?lhs$n = of_nat (n+1) * (fps_sin c $ (n+1))" by simp
  2697       also have "\<dots> = of_nat (n+1) * ((- 1)^(n div 2) * c^Suc n / of_nat (fact (Suc n)))"
  2698 	using en by (simp add: fps_sin_def)
  2699       also have "\<dots> = (- 1)^(n div 2) * c^Suc n * (of_nat (n+1) / (of_nat (Suc n) * of_nat (fact n)))"
  2700 	unfolding fact_Suc_nat of_nat_mult
  2701 	by (simp add: field_simps del: of_nat_add of_nat_Suc)
  2702       also have "\<dots> = (- 1)^(n div 2) *c^Suc n / of_nat (fact n)"
  2703 	by (simp add: field_simps del: of_nat_add of_nat_Suc)
  2704       finally have "?lhs $n = ?rhs$n" using en
  2705 	by (simp add: fps_cos_def ring_simps power_Suc )}
  2706     then show "?lhs $ n = ?rhs $ n"
  2707       by (cases "even n", simp_all add: fps_deriv_def fps_sin_def fps_cos_def)
  2708 qed
  2709 
  2710 lemma fps_cos_deriv:
  2711   "fps_deriv (fps_cos c) = fps_const (- c)* (fps_sin c)"
  2712   (is "?lhs = ?rhs")
  2713 proof (rule fps_ext)
  2714   have th0: "\<And>n. - ((- 1::'a) ^ n) = (- 1)^Suc n" by (simp add: power_Suc)
  2715   have th1: "\<And>n. odd n \<Longrightarrow> Suc ((n - 1) div 2) = Suc n div 2"
  2716     by (case_tac n, simp_all)
  2717   fix n::nat
  2718     {assume en: "odd n"
  2719       from en have n0: "n \<noteq>0 " by presburger
  2720       have "?lhs$n = of_nat (n+1) * (fps_cos c $ (n+1))" by simp
  2721       also have "\<dots> = of_nat (n+1) * ((- 1)^((n + 1) div 2) * c^Suc n / of_nat (fact (Suc n)))"
  2722 	using en by (simp add: fps_cos_def)
  2723       also have "\<dots> = (- 1)^((n + 1) div 2)*c^Suc n * (of_nat (n+1) / (of_nat (Suc n) * of_nat (fact n)))"
  2724 	unfolding fact_Suc_nat of_nat_mult
  2725 	by (simp add: field_simps del: of_nat_add of_nat_Suc)
  2726       also have "\<dots> = (- 1)^((n + 1) div 2) * c^Suc n / of_nat (fact n)"
  2727 	by (simp add: field_simps del: of_nat_add of_nat_Suc)
  2728       also have "\<dots> = (- ((- 1)^((n - 1) div 2))) * c^Suc n / of_nat (fact n)"
  2729 	unfolding th0 unfolding th1[OF en] by simp
  2730       finally have "?lhs $n = ?rhs$n" using en
  2731 	by (simp add: fps_sin_def ring_simps power_Suc)}
  2732     then show "?lhs $ n = ?rhs $ n"
  2733       by (cases "even n", simp_all add: fps_deriv_def fps_sin_def
  2734 	fps_cos_def)
  2735 qed
  2736 
  2737 lemma fps_sin_cos_sum_of_squares:
  2738   "fps_cos c ^ 2 + fps_sin c ^ 2 = 1" (is "?lhs = 1")
  2739 proof-
  2740   have "fps_deriv ?lhs = 0"
  2741     apply (simp add:  fps_deriv_power fps_sin_deriv fps_cos_deriv power_Suc)
  2742     by (simp add: ring_simps fps_const_neg[symmetric] del: fps_const_neg)
  2743   then have "?lhs = fps_const (?lhs $ 0)"
  2744     unfolding fps_deriv_eq_0_iff .
  2745   also have "\<dots> = 1"
  2746     by (auto simp add: fps_eq_iff numeral_2_eq_2 fps_mult_nth fps_cos_def fps_sin_def)
  2747   finally show ?thesis .
  2748 qed
  2749 
  2750 lemma divide_eq_iff: "a \<noteq> (0::'a::field) \<Longrightarrow> x / a = y \<longleftrightarrow> x = y * a"
  2751 by auto
  2752 
  2753 lemma eq_divide_iff: "a \<noteq> (0::'a::field) \<Longrightarrow> x = y / a \<longleftrightarrow> x * a = y"
  2754 by auto
  2755 
  2756 lemma fps_sin_nth_0 [simp]: "fps_sin c $ 0 = 0"
  2757 unfolding fps_sin_def by simp
  2758 
  2759 lemma fps_sin_nth_1 [simp]: "fps_sin c $ 1 = c"
  2760 unfolding fps_sin_def by simp
  2761 
  2762 lemma fps_sin_nth_add_2:
  2763   "fps_sin c $ (n + 2) = - (c * c * fps_sin c $ n / (of_nat(n+1) * of_nat(n+2)))"
  2764 unfolding fps_sin_def
  2765 apply (cases n, simp)
  2766 apply (simp add: divide_eq_iff eq_divide_iff del: of_nat_Suc fact_Suc_nat)
  2767 apply (simp add: of_nat_mult del: of_nat_Suc mult_Suc)
  2768 done
  2769 
  2770 lemma fps_cos_nth_0 [simp]: "fps_cos c $ 0 = 1"
  2771 unfolding fps_cos_def by simp
  2772 
  2773 lemma fps_cos_nth_1 [simp]: "fps_cos c $ 1 = 0"
  2774 unfolding fps_cos_def by simp
  2775 
  2776 lemma fps_cos_nth_add_2:
  2777   "fps_cos c $ (n + 2) = - (c * c * fps_cos c $ n / (of_nat(n+1) * of_nat(n+2)))"
  2778 unfolding fps_cos_def
  2779 apply (simp add: divide_eq_iff eq_divide_iff del: of_nat_Suc fact_Suc_nat)
  2780 apply (simp add: of_nat_mult del: of_nat_Suc mult_Suc)
  2781 done
  2782 
  2783 lemma nat_induct2:
  2784   "\<lbrakk>P 0; P 1; \<And>n. P n \<Longrightarrow> P (n + 2)\<rbrakk> \<Longrightarrow> P (n::nat)"
  2785 unfolding One_nat_def numeral_2_eq_2
  2786 apply (induct n rule: nat_less_induct)
  2787 apply (case_tac n, simp)
  2788 apply (rename_tac m, case_tac m, simp)
  2789 apply (rename_tac k, case_tac k, simp_all)
  2790 done
  2791 
  2792 lemma nat_add_1_add_1: "(n::nat) + 1 + 1 = n + 2"
  2793 by simp
  2794 
  2795 lemma eq_fps_sin:
  2796   assumes 0: "a $ 0 = 0" and 1: "a $ 1 = c"
  2797   and 2: "fps_deriv (fps_deriv a) = - (fps_const c * fps_const c * a)"
  2798   shows "a = fps_sin c"
  2799 apply (rule fps_ext)
  2800 apply (induct_tac n rule: nat_induct2)
  2801 apply (simp add: fps_sin_nth_0 0)
  2802 apply (simp add: fps_sin_nth_1 1 del: One_nat_def)
  2803 apply (rename_tac m, cut_tac f="\<lambda>a. a $ m" in arg_cong [OF 2])
  2804 apply (simp add: nat_add_1_add_1 fps_sin_nth_add_2
  2805             del: One_nat_def of_nat_Suc of_nat_add add_2_eq_Suc')
  2806 apply (subst minus_divide_left)
  2807 apply (subst eq_divide_iff)
  2808 apply (simp del: of_nat_add of_nat_Suc)
  2809 apply (simp only: mult_ac)
  2810 done
  2811 
  2812 lemma eq_fps_cos:
  2813   assumes 0: "a $ 0 = 1" and 1: "a $ 1 = 0"
  2814   and 2: "fps_deriv (fps_deriv a) = - (fps_const c * fps_const c * a)"
  2815   shows "a = fps_cos c"
  2816 apply (rule fps_ext)
  2817 apply (induct_tac n rule: nat_induct2)
  2818 apply (simp add: fps_cos_nth_0 0)
  2819 apply (simp add: fps_cos_nth_1 1 del: One_nat_def)
  2820 apply (rename_tac m, cut_tac f="\<lambda>a. a $ m" in arg_cong [OF 2])
  2821 apply (simp add: nat_add_1_add_1 fps_cos_nth_add_2
  2822             del: One_nat_def of_nat_Suc of_nat_add add_2_eq_Suc')
  2823 apply (subst minus_divide_left)
  2824 apply (subst eq_divide_iff)
  2825 apply (simp del: of_nat_add of_nat_Suc)
  2826 apply (simp only: mult_ac)
  2827 done
  2828 
  2829 lemma mult_nth_0 [simp]: "(a * b) $ 0 = a $ 0 * b $ 0"
  2830 by (simp add: fps_mult_nth)
  2831 
  2832 lemma mult_nth_1 [simp]: "(a * b) $ 1 = a $ 0 * b $ 1 + a $ 1 * b $ 0"
  2833 by (simp add: fps_mult_nth)
  2834 
  2835 lemma fps_sin_add:
  2836   "fps_sin (a + b) = fps_sin a * fps_cos b + fps_cos a * fps_sin b"
  2837 apply (rule eq_fps_sin [symmetric], simp, simp del: One_nat_def)
  2838 apply (simp del: fps_const_neg fps_const_add fps_const_mult
  2839             add: fps_const_add [symmetric] fps_const_neg [symmetric]
  2840                  fps_sin_deriv fps_cos_deriv algebra_simps)
  2841 done
  2842 
  2843 lemma fps_cos_add:
  2844   "fps_cos (a + b) = fps_cos a * fps_cos b - fps_sin a * fps_sin b"
  2845 apply (rule eq_fps_cos [symmetric], simp, simp del: One_nat_def)
  2846 apply (simp del: fps_const_neg fps_const_add fps_const_mult
  2847             add: fps_const_add [symmetric] fps_const_neg [symmetric]
  2848                  fps_sin_deriv fps_cos_deriv algebra_simps)
  2849 done
  2850 
  2851 lemma fps_sin_even: "fps_sin (- c) = - fps_sin c"
  2852   by (auto simp add: fps_eq_iff fps_sin_def)
  2853 
  2854 lemma fps_cos_odd: "fps_cos (- c) = fps_cos c"
  2855   by (auto simp add: fps_eq_iff fps_cos_def)
  2856 
  2857 definition "fps_tan c = fps_sin c / fps_cos c"
  2858 
  2859 lemma fps_tan_deriv: "fps_deriv(fps_tan c) = fps_const c/ (fps_cos c ^ 2)"
  2860 proof-
  2861   have th0: "fps_cos c $ 0 \<noteq> 0" by (simp add: fps_cos_def)
  2862   show ?thesis
  2863     using fps_sin_cos_sum_of_squares[of c]
  2864     apply (simp add: fps_tan_def fps_divide_deriv[OF th0] fps_sin_deriv fps_cos_deriv add: fps_const_neg[symmetric] ring_simps power2_eq_square del: fps_const_neg)
  2865     unfolding right_distrib[symmetric]
  2866     by simp
  2867 qed
  2868 
  2869 end