src/HOL/Library/FuncSet.thy
author chaieb
Mon Jun 11 11:06:04 2007 +0200 (2007-06-11)
changeset 23315 df3a7e9ebadb
parent 21404 eb85850d3eb7
child 26106 be52145f482d
permissions -rw-r--r--
tuned Proof
     1 (*  Title:      HOL/Library/FuncSet.thy
     2     ID:         $Id$
     3     Author:     Florian Kammueller and Lawrence C Paulson
     4 *)
     5 
     6 header {* Pi and Function Sets *}
     7 
     8 theory FuncSet
     9 imports Main
    10 begin
    11 
    12 definition
    13   Pi :: "['a set, 'a => 'b set] => ('a => 'b) set" where
    14   "Pi A B = {f. \<forall>x. x \<in> A --> f x \<in> B x}"
    15 
    16 definition
    17   extensional :: "'a set => ('a => 'b) set" where
    18   "extensional A = {f. \<forall>x. x~:A --> f x = arbitrary}"
    19 
    20 definition
    21   "restrict" :: "['a => 'b, 'a set] => ('a => 'b)" where
    22   "restrict f A = (%x. if x \<in> A then f x else arbitrary)"
    23 
    24 abbreviation
    25   funcset :: "['a set, 'b set] => ('a => 'b) set"
    26     (infixr "->" 60) where
    27   "A -> B == Pi A (%_. B)"
    28 
    29 notation (xsymbols)
    30   funcset  (infixr "\<rightarrow>" 60)
    31 
    32 syntax
    33   "_Pi"  :: "[pttrn, 'a set, 'b set] => ('a => 'b) set"  ("(3PI _:_./ _)" 10)
    34   "_lam" :: "[pttrn, 'a set, 'a => 'b] => ('a=>'b)"  ("(3%_:_./ _)" [0,0,3] 3)
    35 
    36 syntax (xsymbols)
    37   "_Pi" :: "[pttrn, 'a set, 'b set] => ('a => 'b) set"  ("(3\<Pi> _\<in>_./ _)"   10)
    38   "_lam" :: "[pttrn, 'a set, 'a => 'b] => ('a=>'b)"  ("(3\<lambda>_\<in>_./ _)" [0,0,3] 3)
    39 
    40 syntax (HTML output)
    41   "_Pi" :: "[pttrn, 'a set, 'b set] => ('a => 'b) set"  ("(3\<Pi> _\<in>_./ _)"   10)
    42   "_lam" :: "[pttrn, 'a set, 'a => 'b] => ('a=>'b)"  ("(3\<lambda>_\<in>_./ _)" [0,0,3] 3)
    43 
    44 translations
    45   "PI x:A. B" == "CONST Pi A (%x. B)"
    46   "%x:A. f" == "CONST restrict (%x. f) A"
    47 
    48 definition
    49   "compose" :: "['a set, 'b => 'c, 'a => 'b] => ('a => 'c)" where
    50   "compose A g f = (\<lambda>x\<in>A. g (f x))"
    51 
    52 
    53 subsection{*Basic Properties of @{term Pi}*}
    54 
    55 lemma Pi_I: "(!!x. x \<in> A ==> f x \<in> B x) ==> f \<in> Pi A B"
    56   by (simp add: Pi_def)
    57 
    58 lemma funcsetI: "(!!x. x \<in> A ==> f x \<in> B) ==> f \<in> A -> B"
    59   by (simp add: Pi_def)
    60 
    61 lemma Pi_mem: "[|f: Pi A B; x \<in> A|] ==> f x \<in> B x"
    62   by (simp add: Pi_def)
    63 
    64 lemma funcset_mem: "[|f \<in> A -> B; x \<in> A|] ==> f x \<in> B"
    65   by (simp add: Pi_def)
    66 
    67 lemma funcset_image: "f \<in> A\<rightarrow>B ==> f ` A \<subseteq> B"
    68   by (auto simp add: Pi_def)
    69 
    70 lemma Pi_eq_empty: "((PI x: A. B x) = {}) = (\<exists>x\<in>A. B(x) = {})"
    71 apply (simp add: Pi_def, auto)
    72 txt{*Converse direction requires Axiom of Choice to exhibit a function
    73 picking an element from each non-empty @{term "B x"}*}
    74 apply (drule_tac x = "%u. SOME y. y \<in> B u" in spec, auto)
    75 apply (cut_tac P= "%y. y \<in> B x" in some_eq_ex, auto)
    76 done
    77 
    78 lemma Pi_empty [simp]: "Pi {} B = UNIV"
    79   by (simp add: Pi_def)
    80 
    81 lemma Pi_UNIV [simp]: "A -> UNIV = UNIV"
    82   by (simp add: Pi_def)
    83 
    84 text{*Covariance of Pi-sets in their second argument*}
    85 lemma Pi_mono: "(!!x. x \<in> A ==> B x <= C x) ==> Pi A B <= Pi A C"
    86   by (simp add: Pi_def, blast)
    87 
    88 text{*Contravariance of Pi-sets in their first argument*}
    89 lemma Pi_anti_mono: "A' <= A ==> Pi A B <= Pi A' B"
    90   by (simp add: Pi_def, blast)
    91 
    92 
    93 subsection{*Composition With a Restricted Domain: @{term compose}*}
    94 
    95 lemma funcset_compose:
    96     "[| f \<in> A -> B; g \<in> B -> C |]==> compose A g f \<in> A -> C"
    97   by (simp add: Pi_def compose_def restrict_def)
    98 
    99 lemma compose_assoc:
   100     "[| f \<in> A -> B; g \<in> B -> C; h \<in> C -> D |]
   101       ==> compose A h (compose A g f) = compose A (compose B h g) f"
   102   by (simp add: expand_fun_eq Pi_def compose_def restrict_def)
   103 
   104 lemma compose_eq: "x \<in> A ==> compose A g f x = g(f(x))"
   105   by (simp add: compose_def restrict_def)
   106 
   107 lemma surj_compose: "[| f ` A = B; g ` B = C |] ==> compose A g f ` A = C"
   108   by (auto simp add: image_def compose_eq)
   109 
   110 
   111 subsection{*Bounded Abstraction: @{term restrict}*}
   112 
   113 lemma restrict_in_funcset: "(!!x. x \<in> A ==> f x \<in> B) ==> (\<lambda>x\<in>A. f x) \<in> A -> B"
   114   by (simp add: Pi_def restrict_def)
   115 
   116 lemma restrictI: "(!!x. x \<in> A ==> f x \<in> B x) ==> (\<lambda>x\<in>A. f x) \<in> Pi A B"
   117   by (simp add: Pi_def restrict_def)
   118 
   119 lemma restrict_apply [simp]:
   120     "(\<lambda>y\<in>A. f y) x = (if x \<in> A then f x else arbitrary)"
   121   by (simp add: restrict_def)
   122 
   123 lemma restrict_ext:
   124     "(!!x. x \<in> A ==> f x = g x) ==> (\<lambda>x\<in>A. f x) = (\<lambda>x\<in>A. g x)"
   125   by (simp add: expand_fun_eq Pi_def Pi_def restrict_def)
   126 
   127 lemma inj_on_restrict_eq [simp]: "inj_on (restrict f A) A = inj_on f A"
   128   by (simp add: inj_on_def restrict_def)
   129 
   130 lemma Id_compose:
   131     "[|f \<in> A -> B;  f \<in> extensional A|] ==> compose A (\<lambda>y\<in>B. y) f = f"
   132   by (auto simp add: expand_fun_eq compose_def extensional_def Pi_def)
   133 
   134 lemma compose_Id:
   135     "[|g \<in> A -> B;  g \<in> extensional A|] ==> compose A g (\<lambda>x\<in>A. x) = g"
   136   by (auto simp add: expand_fun_eq compose_def extensional_def Pi_def)
   137 
   138 lemma image_restrict_eq [simp]: "(restrict f A) ` A = f ` A"
   139   by (auto simp add: restrict_def)
   140 
   141 
   142 subsection{*Bijections Between Sets*}
   143 
   144 text{*The basic definition could be moved to @{text "Fun.thy"}, but most of
   145 the theorems belong here, or need at least @{term Hilbert_Choice}.*}
   146 
   147 definition
   148   bij_betw :: "['a => 'b, 'a set, 'b set] => bool" where -- {* bijective *}
   149   "bij_betw f A B = (inj_on f A & f ` A = B)"
   150 
   151 lemma bij_betw_imp_inj_on: "bij_betw f A B \<Longrightarrow> inj_on f A"
   152   by (simp add: bij_betw_def)
   153 
   154 lemma bij_betw_imp_funcset: "bij_betw f A B \<Longrightarrow> f \<in> A \<rightarrow> B"
   155   by (auto simp add: bij_betw_def inj_on_Inv Pi_def)
   156 
   157 lemma bij_betw_Inv: "bij_betw f A B \<Longrightarrow> bij_betw (Inv A f) B A"
   158   apply (auto simp add: bij_betw_def inj_on_Inv Inv_mem)
   159   apply (simp add: image_compose [symmetric] o_def)
   160   apply (simp add: image_def Inv_f_f)
   161   done
   162 
   163 lemma inj_on_compose:
   164     "[| bij_betw f A B; inj_on g B |] ==> inj_on (compose A g f) A"
   165   by (auto simp add: bij_betw_def inj_on_def compose_eq)
   166 
   167 lemma bij_betw_compose:
   168     "[| bij_betw f A B; bij_betw g B C |] ==> bij_betw (compose A g f) A C"
   169   apply (simp add: bij_betw_def compose_eq inj_on_compose)
   170   apply (auto simp add: compose_def image_def)
   171   done
   172 
   173 lemma bij_betw_restrict_eq [simp]:
   174      "bij_betw (restrict f A) A B = bij_betw f A B"
   175   by (simp add: bij_betw_def)
   176 
   177 
   178 subsection{*Extensionality*}
   179 
   180 lemma extensional_arb: "[|f \<in> extensional A; x\<notin> A|] ==> f x = arbitrary"
   181   by (simp add: extensional_def)
   182 
   183 lemma restrict_extensional [simp]: "restrict f A \<in> extensional A"
   184   by (simp add: restrict_def extensional_def)
   185 
   186 lemma compose_extensional [simp]: "compose A f g \<in> extensional A"
   187   by (simp add: compose_def)
   188 
   189 lemma extensionalityI:
   190     "[| f \<in> extensional A; g \<in> extensional A;
   191       !!x. x\<in>A ==> f x = g x |] ==> f = g"
   192   by (force simp add: expand_fun_eq extensional_def)
   193 
   194 lemma Inv_funcset: "f ` A = B ==> (\<lambda>x\<in>B. Inv A f x) : B -> A"
   195   by (unfold Inv_def) (fast intro: restrict_in_funcset someI2)
   196 
   197 lemma compose_Inv_id:
   198     "bij_betw f A B ==> compose A (\<lambda>y\<in>B. Inv A f y) f = (\<lambda>x\<in>A. x)"
   199   apply (simp add: bij_betw_def compose_def)
   200   apply (rule restrict_ext, auto)
   201   apply (erule subst)
   202   apply (simp add: Inv_f_f)
   203   done
   204 
   205 lemma compose_id_Inv:
   206     "f ` A = B ==> compose B f (\<lambda>y\<in>B. Inv A f y) = (\<lambda>x\<in>B. x)"
   207   apply (simp add: compose_def)
   208   apply (rule restrict_ext)
   209   apply (simp add: f_Inv_f)
   210   done
   211 
   212 
   213 subsection{*Cardinality*}
   214 
   215 lemma card_inj: "[|f \<in> A\<rightarrow>B; inj_on f A; finite B|] ==> card(A) \<le> card(B)"
   216   apply (rule card_inj_on_le)
   217     apply (auto simp add: Pi_def)
   218   done
   219 
   220 lemma card_bij:
   221      "[|f \<in> A\<rightarrow>B; inj_on f A;
   222         g \<in> B\<rightarrow>A; inj_on g B; finite A; finite B|] ==> card(A) = card(B)"
   223   by (blast intro: card_inj order_antisym)
   224 
   225 
   226 (*The following declarations generate polymorphic Skolem functions for 
   227   these theorems. Eventually they should become redundant, once this 
   228   is done automatically.*)
   229 
   230 declare FuncSet.Pi_I [skolem]
   231 declare FuncSet.Pi_mono [skolem]
   232 declare FuncSet.extensionalityI [skolem]
   233 declare FuncSet.funcsetI [skolem]
   234 declare FuncSet.restrictI [skolem]
   235 declare FuncSet.restrict_in_funcset [skolem]
   236 
   237 end