src/HOL/Product_Type.thy
author bulwahn
Wed Oct 19 08:37:22 2011 +0200 (2011-10-19)
changeset 45176 df4cbfc5ca4f
parent 45175 ae8411edd939
child 45205 2825ce94fd4d
permissions -rw-r--r--
removing old code generator setup of inductive predicates
     1 (*  Title:      HOL/Product_Type.thy
     2     Author:     Lawrence C Paulson, Cambridge University Computer Laboratory
     3     Copyright   1992  University of Cambridge
     4 *)
     5 
     6 header {* Cartesian products *}
     7 
     8 theory Product_Type
     9 imports Typedef Inductive Fun
    10 uses
    11   ("Tools/split_rule.ML")
    12   ("Tools/inductive_set.ML")
    13 begin
    14 
    15 subsection {* @{typ bool} is a datatype *}
    16 
    17 rep_datatype True False by (auto intro: bool_induct)
    18 
    19 declare case_split [cases type: bool]
    20   -- "prefer plain propositional version"
    21 
    22 lemma
    23   shows [code]: "HOL.equal False P \<longleftrightarrow> \<not> P"
    24     and [code]: "HOL.equal True P \<longleftrightarrow> P" 
    25     and [code]: "HOL.equal P False \<longleftrightarrow> \<not> P" 
    26     and [code]: "HOL.equal P True \<longleftrightarrow> P"
    27     and [code nbe]: "HOL.equal P P \<longleftrightarrow> True"
    28   by (simp_all add: equal)
    29 
    30 lemma If_case_cert:
    31   assumes "CASE \<equiv> (\<lambda>b. If b f g)"
    32   shows "(CASE True \<equiv> f) &&& (CASE False \<equiv> g)"
    33   using assms by simp_all
    34 
    35 setup {*
    36   Code.add_case @{thm If_case_cert}
    37 *}
    38 
    39 code_const "HOL.equal \<Colon> bool \<Rightarrow> bool \<Rightarrow> bool"
    40   (Haskell infix 4 "==")
    41 
    42 code_instance bool :: equal
    43   (Haskell -)
    44 
    45 
    46 subsection {* The @{text unit} type *}
    47 
    48 typedef (open) unit = "{True}"
    49 proof
    50   show "True : ?unit" ..
    51 qed
    52 
    53 definition
    54   Unity :: unit    ("'(')")
    55 where
    56   "() = Abs_unit True"
    57 
    58 lemma unit_eq [no_atp]: "u = ()"
    59   by (induct u) (simp add: Unity_def)
    60 
    61 text {*
    62   Simplification procedure for @{thm [source] unit_eq}.  Cannot use
    63   this rule directly --- it loops!
    64 *}
    65 
    66 simproc_setup unit_eq ("x::unit") = {*
    67   fn _ => fn _ => fn ct =>
    68     if HOLogic.is_unit (term_of ct) then NONE
    69     else SOME (mk_meta_eq @{thm unit_eq})
    70 *}
    71 
    72 rep_datatype "()" by simp
    73 
    74 lemma unit_all_eq1: "(!!x::unit. PROP P x) == PROP P ()"
    75   by simp
    76 
    77 lemma unit_all_eq2: "(!!x::unit. PROP P) == PROP P"
    78   by (rule triv_forall_equality)
    79 
    80 text {*
    81   This rewrite counters the effect of simproc @{text unit_eq} on @{term
    82   [source] "%u::unit. f u"}, replacing it by @{term [source]
    83   f} rather than by @{term [source] "%u. f ()"}.
    84 *}
    85 
    86 lemma unit_abs_eta_conv [simp, no_atp]: "(%u::unit. f ()) = f"
    87   by (rule ext) simp
    88 
    89 lemma UNIV_unit [no_atp]:
    90   "UNIV = {()}" by auto
    91 
    92 instantiation unit :: default
    93 begin
    94 
    95 definition "default = ()"
    96 
    97 instance ..
    98 
    99 end
   100 
   101 lemma [code]:
   102   "HOL.equal (u\<Colon>unit) v \<longleftrightarrow> True" unfolding equal unit_eq [of u] unit_eq [of v] by rule+
   103 
   104 code_type unit
   105   (SML "unit")
   106   (OCaml "unit")
   107   (Haskell "()")
   108   (Scala "Unit")
   109 
   110 code_const Unity
   111   (SML "()")
   112   (OCaml "()")
   113   (Haskell "()")
   114   (Scala "()")
   115 
   116 code_instance unit :: equal
   117   (Haskell -)
   118 
   119 code_const "HOL.equal \<Colon> unit \<Rightarrow> unit \<Rightarrow> bool"
   120   (Haskell infix 4 "==")
   121 
   122 code_reserved SML
   123   unit
   124 
   125 code_reserved OCaml
   126   unit
   127 
   128 code_reserved Scala
   129   Unit
   130 
   131 
   132 subsection {* The product type *}
   133 
   134 subsubsection {* Type definition *}
   135 
   136 definition Pair_Rep :: "'a \<Rightarrow> 'b \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> bool" where
   137   "Pair_Rep a b = (\<lambda>x y. x = a \<and> y = b)"
   138 
   139 typedef ('a, 'b) prod (infixr "*" 20)
   140   = "{f. \<exists>a b. f = Pair_Rep (a\<Colon>'a) (b\<Colon>'b)}"
   141 proof
   142   fix a b show "Pair_Rep a b \<in> ?prod"
   143     by rule+
   144 qed
   145 
   146 type_notation (xsymbols)
   147   "prod"  ("(_ \<times>/ _)" [21, 20] 20)
   148 type_notation (HTML output)
   149   "prod"  ("(_ \<times>/ _)" [21, 20] 20)
   150 
   151 definition Pair :: "'a \<Rightarrow> 'b \<Rightarrow> 'a \<times> 'b" where
   152   "Pair a b = Abs_prod (Pair_Rep a b)"
   153 
   154 rep_datatype Pair proof -
   155   fix P :: "'a \<times> 'b \<Rightarrow> bool" and p
   156   assume "\<And>a b. P (Pair a b)"
   157   then show "P p" by (cases p) (auto simp add: prod_def Pair_def Pair_Rep_def)
   158 next
   159   fix a c :: 'a and b d :: 'b
   160   have "Pair_Rep a b = Pair_Rep c d \<longleftrightarrow> a = c \<and> b = d"
   161     by (auto simp add: Pair_Rep_def fun_eq_iff)
   162   moreover have "Pair_Rep a b \<in> prod" and "Pair_Rep c d \<in> prod"
   163     by (auto simp add: prod_def)
   164   ultimately show "Pair a b = Pair c d \<longleftrightarrow> a = c \<and> b = d"
   165     by (simp add: Pair_def Abs_prod_inject)
   166 qed
   167 
   168 declare prod.simps(2) [nitpick_simp del]
   169 
   170 declare prod.weak_case_cong [cong del]
   171 
   172 
   173 subsubsection {* Tuple syntax *}
   174 
   175 abbreviation (input) split :: "('a \<Rightarrow> 'b \<Rightarrow> 'c) \<Rightarrow> 'a \<times> 'b \<Rightarrow> 'c" where
   176   "split \<equiv> prod_case"
   177 
   178 text {*
   179   Patterns -- extends pre-defined type @{typ pttrn} used in
   180   abstractions.
   181 *}
   182 
   183 nonterminal tuple_args and patterns
   184 
   185 syntax
   186   "_tuple"      :: "'a => tuple_args => 'a * 'b"        ("(1'(_,/ _'))")
   187   "_tuple_arg"  :: "'a => tuple_args"                   ("_")
   188   "_tuple_args" :: "'a => tuple_args => tuple_args"     ("_,/ _")
   189   "_pattern"    :: "[pttrn, patterns] => pttrn"         ("'(_,/ _')")
   190   ""            :: "pttrn => patterns"                  ("_")
   191   "_patterns"   :: "[pttrn, patterns] => patterns"      ("_,/ _")
   192 
   193 translations
   194   "(x, y)" == "CONST Pair x y"
   195   "_tuple x (_tuple_args y z)" == "_tuple x (_tuple_arg (_tuple y z))"
   196   "%(x, y, zs). b" == "CONST prod_case (%x (y, zs). b)"
   197   "%(x, y). b" == "CONST prod_case (%x y. b)"
   198   "_abs (CONST Pair x y) t" => "%(x, y). t"
   199   -- {* The last rule accommodates tuples in `case C ... (x,y) ... => ...'
   200      The (x,y) is parsed as `Pair x y' because it is logic, not pttrn *}
   201 
   202 (*reconstruct pattern from (nested) splits, avoiding eta-contraction of body;
   203   works best with enclosing "let", if "let" does not avoid eta-contraction*)
   204 print_translation {*
   205 let
   206   fun split_tr' [Abs (x, T, t as (Abs abs))] =
   207         (* split (%x y. t) => %(x,y) t *)
   208         let
   209           val (y, t') = Syntax_Trans.atomic_abs_tr' abs;
   210           val (x', t'') = Syntax_Trans.atomic_abs_tr' (x, T, t');
   211         in
   212           Syntax.const @{syntax_const "_abs"} $
   213             (Syntax.const @{syntax_const "_pattern"} $ x' $ y) $ t''
   214         end
   215     | split_tr' [Abs (x, T, (s as Const (@{const_syntax prod_case}, _) $ t))] =
   216         (* split (%x. (split (%y z. t))) => %(x,y,z). t *)
   217         let
   218           val Const (@{syntax_const "_abs"}, _) $
   219             (Const (@{syntax_const "_pattern"}, _) $ y $ z) $ t' = split_tr' [t];
   220           val (x', t'') = Syntax_Trans.atomic_abs_tr' (x, T, t');
   221         in
   222           Syntax.const @{syntax_const "_abs"} $
   223             (Syntax.const @{syntax_const "_pattern"} $ x' $
   224               (Syntax.const @{syntax_const "_patterns"} $ y $ z)) $ t''
   225         end
   226     | split_tr' [Const (@{const_syntax prod_case}, _) $ t] =
   227         (* split (split (%x y z. t)) => %((x, y), z). t *)
   228         split_tr' [(split_tr' [t])] (* inner split_tr' creates next pattern *)
   229     | split_tr' [Const (@{syntax_const "_abs"}, _) $ x_y $ Abs abs] =
   230         (* split (%pttrn z. t) => %(pttrn,z). t *)
   231         let val (z, t) = Syntax_Trans.atomic_abs_tr' abs in
   232           Syntax.const @{syntax_const "_abs"} $
   233             (Syntax.const @{syntax_const "_pattern"} $ x_y $ z) $ t
   234         end
   235     | split_tr' _ = raise Match;
   236 in [(@{const_syntax prod_case}, split_tr')] end
   237 *}
   238 
   239 (* print "split f" as "\<lambda>(x,y). f x y" and "split (\<lambda>x. f x)" as "\<lambda>(x,y). f x y" *) 
   240 typed_print_translation {*
   241 let
   242   fun split_guess_names_tr' T [Abs (x, _, Abs _)] = raise Match
   243     | split_guess_names_tr' T [Abs (x, xT, t)] =
   244         (case (head_of t) of
   245           Const (@{const_syntax prod_case}, _) => raise Match
   246         | _ =>
   247           let 
   248             val (_ :: yT :: _) = binder_types (domain_type T) handle Bind => raise Match;
   249             val (y, t') = Syntax_Trans.atomic_abs_tr' ("y", yT, incr_boundvars 1 t $ Bound 0);
   250             val (x', t'') = Syntax_Trans.atomic_abs_tr' (x, xT, t');
   251           in
   252             Syntax.const @{syntax_const "_abs"} $
   253               (Syntax.const @{syntax_const "_pattern"} $ x' $ y) $ t''
   254           end)
   255     | split_guess_names_tr' T [t] =
   256         (case head_of t of
   257           Const (@{const_syntax prod_case}, _) => raise Match
   258         | _ =>
   259           let
   260             val (xT :: yT :: _) = binder_types (domain_type T) handle Bind => raise Match;
   261             val (y, t') =
   262               Syntax_Trans.atomic_abs_tr' ("y", yT, incr_boundvars 2 t $ Bound 1 $ Bound 0);
   263             val (x', t'') = Syntax_Trans.atomic_abs_tr' ("x", xT, t');
   264           in
   265             Syntax.const @{syntax_const "_abs"} $
   266               (Syntax.const @{syntax_const "_pattern"} $ x' $ y) $ t''
   267           end)
   268     | split_guess_names_tr' _ _ = raise Match;
   269 in [(@{const_syntax prod_case}, split_guess_names_tr')] end
   270 *}
   271 
   272 (* Force eta-contraction for terms of the form "Q A (%p. prod_case P p)"
   273    where Q is some bounded quantifier or set operator.
   274    Reason: the above prints as "Q p : A. case p of (x,y) \<Rightarrow> P x y"
   275    whereas we want "Q (x,y):A. P x y".
   276    Otherwise prevent eta-contraction.
   277 *)
   278 print_translation {*
   279 let
   280   fun contract Q f ts =
   281     case ts of
   282       [A, Abs(_, _, (s as Const (@{const_syntax prod_case},_) $ t) $ Bound 0)]
   283       => if Term.is_dependent t then f ts else Syntax.const Q $ A $ s
   284     | _ => f ts;
   285   fun contract2 (Q,f) = (Q, contract Q f);
   286   val pairs =
   287     [Syntax_Trans.preserve_binder_abs2_tr' @{const_syntax Ball} @{syntax_const "_Ball"},
   288      Syntax_Trans.preserve_binder_abs2_tr' @{const_syntax Bex} @{syntax_const "_Bex"},
   289      Syntax_Trans.preserve_binder_abs2_tr' @{const_syntax INFI} @{syntax_const "_INF"},
   290      Syntax_Trans.preserve_binder_abs2_tr' @{const_syntax SUPR} @{syntax_const "_SUP"}]
   291 in map contract2 pairs end
   292 *}
   293 
   294 subsubsection {* Code generator setup *}
   295 
   296 code_type prod
   297   (SML infix 2 "*")
   298   (OCaml infix 2 "*")
   299   (Haskell "!((_),/ (_))")
   300   (Scala "((_),/ (_))")
   301 
   302 code_const Pair
   303   (SML "!((_),/ (_))")
   304   (OCaml "!((_),/ (_))")
   305   (Haskell "!((_),/ (_))")
   306   (Scala "!((_),/ (_))")
   307 
   308 code_instance prod :: equal
   309   (Haskell -)
   310 
   311 code_const "HOL.equal \<Colon> 'a \<times> 'b \<Rightarrow> 'a \<times> 'b \<Rightarrow> bool"
   312   (Haskell infix 4 "==")
   313 
   314 
   315 subsubsection {* Fundamental operations and properties *}
   316 
   317 lemma surj_pair [simp]: "EX x y. p = (x, y)"
   318   by (cases p) simp
   319 
   320 definition fst :: "'a \<times> 'b \<Rightarrow> 'a" where
   321   "fst p = (case p of (a, b) \<Rightarrow> a)"
   322 
   323 definition snd :: "'a \<times> 'b \<Rightarrow> 'b" where
   324   "snd p = (case p of (a, b) \<Rightarrow> b)"
   325 
   326 lemma fst_conv [simp, code]: "fst (a, b) = a"
   327   unfolding fst_def by simp
   328 
   329 lemma snd_conv [simp, code]: "snd (a, b) = b"
   330   unfolding snd_def by simp
   331 
   332 code_const fst and snd
   333   (Haskell "fst" and "snd")
   334 
   335 lemma prod_case_unfold [nitpick_unfold]: "prod_case = (%c p. c (fst p) (snd p))"
   336   by (simp add: fun_eq_iff split: prod.split)
   337 
   338 lemma fst_eqD: "fst (x, y) = a ==> x = a"
   339   by simp
   340 
   341 lemma snd_eqD: "snd (x, y) = a ==> y = a"
   342   by simp
   343 
   344 lemma pair_collapse [simp]: "(fst p, snd p) = p"
   345   by (cases p) simp
   346 
   347 lemmas surjective_pairing = pair_collapse [symmetric]
   348 
   349 lemma prod_eq_iff: "s = t \<longleftrightarrow> fst s = fst t \<and> snd s = snd t"
   350   by (cases s, cases t) simp
   351 
   352 lemma prod_eqI [intro?]: "fst p = fst q \<Longrightarrow> snd p = snd q \<Longrightarrow> p = q"
   353   by (simp add: prod_eq_iff)
   354 
   355 lemma split_conv [simp, code]: "split f (a, b) = f a b"
   356   by (fact prod.cases)
   357 
   358 lemma splitI: "f a b \<Longrightarrow> split f (a, b)"
   359   by (rule split_conv [THEN iffD2])
   360 
   361 lemma splitD: "split f (a, b) \<Longrightarrow> f a b"
   362   by (rule split_conv [THEN iffD1])
   363 
   364 lemma split_Pair [simp]: "(\<lambda>(x, y). (x, y)) = id"
   365   by (simp add: fun_eq_iff split: prod.split)
   366 
   367 lemma split_eta: "(\<lambda>(x, y). f (x, y)) = f"
   368   -- {* Subsumes the old @{text split_Pair} when @{term f} is the identity function. *}
   369   by (simp add: fun_eq_iff split: prod.split)
   370 
   371 lemma split_comp: "split (f \<circ> g) x = f (g (fst x)) (snd x)"
   372   by (cases x) simp
   373 
   374 lemma split_twice: "split f (split g p) = split (\<lambda>x y. split f (g x y)) p"
   375   by (cases p) simp
   376 
   377 lemma The_split: "The (split P) = (THE xy. P (fst xy) (snd xy))"
   378   by (simp add: prod_case_unfold)
   379 
   380 lemma split_weak_cong: "p = q \<Longrightarrow> split c p = split c q"
   381   -- {* Prevents simplification of @{term c}: much faster *}
   382   by (fact prod.weak_case_cong)
   383 
   384 lemma cond_split_eta: "(!!x y. f x y = g (x, y)) ==> (%(x, y). f x y) = g"
   385   by (simp add: split_eta)
   386 
   387 lemma split_paired_all: "(!!x. PROP P x) == (!!a b. PROP P (a, b))"
   388 proof
   389   fix a b
   390   assume "!!x. PROP P x"
   391   then show "PROP P (a, b)" .
   392 next
   393   fix x
   394   assume "!!a b. PROP P (a, b)"
   395   from `PROP P (fst x, snd x)` show "PROP P x" by simp
   396 qed
   397 
   398 text {*
   399   The rule @{thm [source] split_paired_all} does not work with the
   400   Simplifier because it also affects premises in congrence rules,
   401   where this can lead to premises of the form @{text "!!a b. ... =
   402   ?P(a, b)"} which cannot be solved by reflexivity.
   403 *}
   404 
   405 lemmas split_tupled_all = split_paired_all unit_all_eq2
   406 
   407 ML {*
   408   (* replace parameters of product type by individual component parameters *)
   409   val safe_full_simp_tac = generic_simp_tac true (true, false, false);
   410   local (* filtering with exists_paired_all is an essential optimization *)
   411     fun exists_paired_all (Const ("all", _) $ Abs (_, T, t)) =
   412           can HOLogic.dest_prodT T orelse exists_paired_all t
   413       | exists_paired_all (t $ u) = exists_paired_all t orelse exists_paired_all u
   414       | exists_paired_all (Abs (_, _, t)) = exists_paired_all t
   415       | exists_paired_all _ = false;
   416     val ss = HOL_basic_ss
   417       addsimps [@{thm split_paired_all}, @{thm unit_all_eq2}, @{thm unit_abs_eta_conv}]
   418       addsimprocs [@{simproc unit_eq}];
   419   in
   420     val split_all_tac = SUBGOAL (fn (t, i) =>
   421       if exists_paired_all t then safe_full_simp_tac ss i else no_tac);
   422     val unsafe_split_all_tac = SUBGOAL (fn (t, i) =>
   423       if exists_paired_all t then full_simp_tac ss i else no_tac);
   424     fun split_all th =
   425    if exists_paired_all (Thm.prop_of th) then full_simplify ss th else th;
   426   end;
   427 *}
   428 
   429 declaration {* fn _ =>
   430   Classical.map_cs (fn cs => cs addSbefore ("split_all_tac", split_all_tac))
   431 *}
   432 
   433 lemma split_paired_All [simp]: "(ALL x. P x) = (ALL a b. P (a, b))"
   434   -- {* @{text "[iff]"} is not a good idea because it makes @{text blast} loop *}
   435   by fast
   436 
   437 lemma split_paired_Ex [simp]: "(EX x. P x) = (EX a b. P (a, b))"
   438   by fast
   439 
   440 lemma split_paired_The: "(THE x. P x) = (THE (a, b). P (a, b))"
   441   -- {* Can't be added to simpset: loops! *}
   442   by (simp add: split_eta)
   443 
   444 text {*
   445   Simplification procedure for @{thm [source] cond_split_eta}.  Using
   446   @{thm [source] split_eta} as a rewrite rule is not general enough,
   447   and using @{thm [source] cond_split_eta} directly would render some
   448   existing proofs very inefficient; similarly for @{text
   449   split_beta}.
   450 *}
   451 
   452 ML {*
   453 local
   454   val cond_split_eta_ss = HOL_basic_ss addsimps @{thms cond_split_eta};
   455   fun Pair_pat k 0 (Bound m) = (m = k)
   456     | Pair_pat k i (Const (@{const_name Pair},  _) $ Bound m $ t) =
   457         i > 0 andalso m = k + i andalso Pair_pat k (i - 1) t
   458     | Pair_pat _ _ _ = false;
   459   fun no_args k i (Abs (_, _, t)) = no_args (k + 1) i t
   460     | no_args k i (t $ u) = no_args k i t andalso no_args k i u
   461     | no_args k i (Bound m) = m < k orelse m > k + i
   462     | no_args _ _ _ = true;
   463   fun split_pat tp i (Abs  (_, _, t)) = if tp 0 i t then SOME (i, t) else NONE
   464     | split_pat tp i (Const (@{const_name prod_case}, _) $ Abs (_, _, t)) = split_pat tp (i + 1) t
   465     | split_pat tp i _ = NONE;
   466   fun metaeq ss lhs rhs = mk_meta_eq (Goal.prove (Simplifier.the_context ss) [] []
   467         (HOLogic.mk_Trueprop (HOLogic.mk_eq (lhs, rhs)))
   468         (K (simp_tac (Simplifier.inherit_context ss cond_split_eta_ss) 1)));
   469 
   470   fun beta_term_pat k i (Abs (_, _, t)) = beta_term_pat (k + 1) i t
   471     | beta_term_pat k i (t $ u) =
   472         Pair_pat k i (t $ u) orelse (beta_term_pat k i t andalso beta_term_pat k i u)
   473     | beta_term_pat k i t = no_args k i t;
   474   fun eta_term_pat k i (f $ arg) = no_args k i f andalso Pair_pat k i arg
   475     | eta_term_pat _ _ _ = false;
   476   fun subst arg k i (Abs (x, T, t)) = Abs (x, T, subst arg (k+1) i t)
   477     | subst arg k i (t $ u) =
   478         if Pair_pat k i (t $ u) then incr_boundvars k arg
   479         else (subst arg k i t $ subst arg k i u)
   480     | subst arg k i t = t;
   481 in
   482   fun beta_proc ss (s as Const (@{const_name prod_case}, _) $ Abs (_, _, t) $ arg) =
   483         (case split_pat beta_term_pat 1 t of
   484           SOME (i, f) => SOME (metaeq ss s (subst arg 0 i f))
   485         | NONE => NONE)
   486     | beta_proc _ _ = NONE;
   487   fun eta_proc ss (s as Const (@{const_name prod_case}, _) $ Abs (_, _, t)) =
   488         (case split_pat eta_term_pat 1 t of
   489           SOME (_, ft) => SOME (metaeq ss s (let val (f $ arg) = ft in f end))
   490         | NONE => NONE)
   491     | eta_proc _ _ = NONE;
   492 end;
   493 *}
   494 simproc_setup split_beta ("split f z") = {* fn _ => fn ss => fn ct => beta_proc ss (term_of ct) *}
   495 simproc_setup split_eta ("split f") = {* fn _ => fn ss => fn ct => eta_proc ss (term_of ct) *}
   496 
   497 lemma split_beta [mono]: "(%(x, y). P x y) z = P (fst z) (snd z)"
   498   by (subst surjective_pairing, rule split_conv)
   499 
   500 lemma split_split [no_atp]: "R(split c p) = (ALL x y. p = (x, y) --> R(c x y))"
   501   -- {* For use with @{text split} and the Simplifier. *}
   502   by (insert surj_pair [of p], clarify, simp)
   503 
   504 text {*
   505   @{thm [source] split_split} could be declared as @{text "[split]"}
   506   done after the Splitter has been speeded up significantly;
   507   precompute the constants involved and don't do anything unless the
   508   current goal contains one of those constants.
   509 *}
   510 
   511 lemma split_split_asm [no_atp]: "R (split c p) = (~(EX x y. p = (x, y) & (~R (c x y))))"
   512 by (subst split_split, simp)
   513 
   514 text {*
   515   \medskip @{term split} used as a logical connective or set former.
   516 
   517   \medskip These rules are for use with @{text blast}; could instead
   518   call @{text simp} using @{thm [source] prod.split} as rewrite. *}
   519 
   520 lemma splitI2: "!!p. [| !!a b. p = (a, b) ==> c a b |] ==> split c p"
   521   apply (simp only: split_tupled_all)
   522   apply (simp (no_asm_simp))
   523   done
   524 
   525 lemma splitI2': "!!p. [| !!a b. (a, b) = p ==> c a b x |] ==> split c p x"
   526   apply (simp only: split_tupled_all)
   527   apply (simp (no_asm_simp))
   528   done
   529 
   530 lemma splitE: "split c p ==> (!!x y. p = (x, y) ==> c x y ==> Q) ==> Q"
   531   by (induct p) auto
   532 
   533 lemma splitE': "split c p z ==> (!!x y. p = (x, y) ==> c x y z ==> Q) ==> Q"
   534   by (induct p) auto
   535 
   536 lemma splitE2:
   537   "[| Q (split P z);  !!x y. [|z = (x, y); Q (P x y)|] ==> R |] ==> R"
   538 proof -
   539   assume q: "Q (split P z)"
   540   assume r: "!!x y. [|z = (x, y); Q (P x y)|] ==> R"
   541   show R
   542     apply (rule r surjective_pairing)+
   543     apply (rule split_beta [THEN subst], rule q)
   544     done
   545 qed
   546 
   547 lemma splitD': "split R (a,b) c ==> R a b c"
   548   by simp
   549 
   550 lemma mem_splitI: "z: c a b ==> z: split c (a, b)"
   551   by simp
   552 
   553 lemma mem_splitI2: "!!p. [| !!a b. p = (a, b) ==> z: c a b |] ==> z: split c p"
   554 by (simp only: split_tupled_all, simp)
   555 
   556 lemma mem_splitE:
   557   assumes major: "z \<in> split c p"
   558     and cases: "\<And>x y. p = (x, y) \<Longrightarrow> z \<in> c x y \<Longrightarrow> Q"
   559   shows Q
   560   by (rule major [unfolded prod_case_unfold] cases surjective_pairing)+
   561 
   562 declare mem_splitI2 [intro!] mem_splitI [intro!] splitI2' [intro!] splitI2 [intro!] splitI [intro!]
   563 declare mem_splitE [elim!] splitE' [elim!] splitE [elim!]
   564 
   565 ML {*
   566 local (* filtering with exists_p_split is an essential optimization *)
   567   fun exists_p_split (Const (@{const_name prod_case},_) $ _ $ (Const (@{const_name Pair},_)$_$_)) = true
   568     | exists_p_split (t $ u) = exists_p_split t orelse exists_p_split u
   569     | exists_p_split (Abs (_, _, t)) = exists_p_split t
   570     | exists_p_split _ = false;
   571   val ss = HOL_basic_ss addsimps @{thms split_conv};
   572 in
   573 val split_conv_tac = SUBGOAL (fn (t, i) =>
   574     if exists_p_split t then safe_full_simp_tac ss i else no_tac);
   575 end;
   576 *}
   577 
   578 (* This prevents applications of splitE for already splitted arguments leading
   579    to quite time-consuming computations (in particular for nested tuples) *)
   580 declaration {* fn _ =>
   581   Classical.map_cs (fn cs => cs addSbefore ("split_conv_tac", split_conv_tac))
   582 *}
   583 
   584 lemma split_eta_SetCompr [simp,no_atp]: "(%u. EX x y. u = (x, y) & P (x, y)) = P"
   585   by (rule ext) fast
   586 
   587 lemma split_eta_SetCompr2 [simp,no_atp]: "(%u. EX x y. u = (x, y) & P x y) = split P"
   588   by (rule ext) fast
   589 
   590 lemma split_part [simp]: "(%(a,b). P & Q a b) = (%ab. P & split Q ab)"
   591   -- {* Allows simplifications of nested splits in case of independent predicates. *}
   592   by (rule ext) blast
   593 
   594 (* Do NOT make this a simp rule as it
   595    a) only helps in special situations
   596    b) can lead to nontermination in the presence of split_def
   597 *)
   598 lemma split_comp_eq: 
   599   fixes f :: "'a => 'b => 'c" and g :: "'d => 'a"
   600   shows "(%u. f (g (fst u)) (snd u)) = (split (%x. f (g x)))"
   601   by (rule ext) auto
   602 
   603 lemma pair_imageI [intro]: "(a, b) : A ==> f a b : (%(a, b). f a b) ` A"
   604   apply (rule_tac x = "(a, b)" in image_eqI)
   605    apply auto
   606   done
   607 
   608 lemma The_split_eq [simp]: "(THE (x',y'). x = x' & y = y') = (x, y)"
   609   by blast
   610 
   611 (*
   612 the following  would be slightly more general,
   613 but cannot be used as rewrite rule:
   614 ### Cannot add premise as rewrite rule because it contains (type) unknowns:
   615 ### ?y = .x
   616 Goal "[| P y; !!x. P x ==> x = y |] ==> (@(x',y). x = x' & P y) = (x,y)"
   617 by (rtac some_equality 1)
   618 by ( Simp_tac 1)
   619 by (split_all_tac 1)
   620 by (Asm_full_simp_tac 1)
   621 qed "The_split_eq";
   622 *)
   623 
   624 text {*
   625   Setup of internal @{text split_rule}.
   626 *}
   627 
   628 lemmas prod_caseI = prod.cases [THEN iffD2, standard]
   629 
   630 lemma prod_caseI2: "!!p. [| !!a b. p = (a, b) ==> c a b |] ==> prod_case c p"
   631   by (fact splitI2)
   632 
   633 lemma prod_caseI2': "!!p. [| !!a b. (a, b) = p ==> c a b x |] ==> prod_case c p x"
   634   by (fact splitI2')
   635 
   636 lemma prod_caseE: "prod_case c p ==> (!!x y. p = (x, y) ==> c x y ==> Q) ==> Q"
   637   by (fact splitE)
   638 
   639 lemma prod_caseE': "prod_case c p z ==> (!!x y. p = (x, y) ==> c x y z ==> Q) ==> Q"
   640   by (fact splitE')
   641 
   642 declare prod_caseI [intro!]
   643 
   644 lemma prod_case_beta:
   645   "prod_case f p = f (fst p) (snd p)"
   646   by (fact split_beta)
   647 
   648 lemma prod_cases3 [cases type]:
   649   obtains (fields) a b c where "y = (a, b, c)"
   650   by (cases y, case_tac b) blast
   651 
   652 lemma prod_induct3 [case_names fields, induct type]:
   653     "(!!a b c. P (a, b, c)) ==> P x"
   654   by (cases x) blast
   655 
   656 lemma prod_cases4 [cases type]:
   657   obtains (fields) a b c d where "y = (a, b, c, d)"
   658   by (cases y, case_tac c) blast
   659 
   660 lemma prod_induct4 [case_names fields, induct type]:
   661     "(!!a b c d. P (a, b, c, d)) ==> P x"
   662   by (cases x) blast
   663 
   664 lemma prod_cases5 [cases type]:
   665   obtains (fields) a b c d e where "y = (a, b, c, d, e)"
   666   by (cases y, case_tac d) blast
   667 
   668 lemma prod_induct5 [case_names fields, induct type]:
   669     "(!!a b c d e. P (a, b, c, d, e)) ==> P x"
   670   by (cases x) blast
   671 
   672 lemma prod_cases6 [cases type]:
   673   obtains (fields) a b c d e f where "y = (a, b, c, d, e, f)"
   674   by (cases y, case_tac e) blast
   675 
   676 lemma prod_induct6 [case_names fields, induct type]:
   677     "(!!a b c d e f. P (a, b, c, d, e, f)) ==> P x"
   678   by (cases x) blast
   679 
   680 lemma prod_cases7 [cases type]:
   681   obtains (fields) a b c d e f g where "y = (a, b, c, d, e, f, g)"
   682   by (cases y, case_tac f) blast
   683 
   684 lemma prod_induct7 [case_names fields, induct type]:
   685     "(!!a b c d e f g. P (a, b, c, d, e, f, g)) ==> P x"
   686   by (cases x) blast
   687 
   688 lemma split_def:
   689   "split = (\<lambda>c p. c (fst p) (snd p))"
   690   by (fact prod_case_unfold)
   691 
   692 definition internal_split :: "('a \<Rightarrow> 'b \<Rightarrow> 'c) \<Rightarrow> 'a \<times> 'b \<Rightarrow> 'c" where
   693   "internal_split == split"
   694 
   695 lemma internal_split_conv: "internal_split c (a, b) = c a b"
   696   by (simp only: internal_split_def split_conv)
   697 
   698 use "Tools/split_rule.ML"
   699 setup Split_Rule.setup
   700 
   701 hide_const internal_split
   702 
   703 
   704 subsubsection {* Derived operations *}
   705 
   706 definition curry    :: "('a \<times> 'b \<Rightarrow> 'c) \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'c" where
   707   "curry = (\<lambda>c x y. c (x, y))"
   708 
   709 lemma curry_conv [simp, code]: "curry f a b = f (a, b)"
   710   by (simp add: curry_def)
   711 
   712 lemma curryI [intro!]: "f (a, b) \<Longrightarrow> curry f a b"
   713   by (simp add: curry_def)
   714 
   715 lemma curryD [dest!]: "curry f a b \<Longrightarrow> f (a, b)"
   716   by (simp add: curry_def)
   717 
   718 lemma curryE: "curry f a b \<Longrightarrow> (f (a, b) \<Longrightarrow> Q) \<Longrightarrow> Q"
   719   by (simp add: curry_def)
   720 
   721 lemma curry_split [simp]: "curry (split f) = f"
   722   by (simp add: curry_def split_def)
   723 
   724 lemma split_curry [simp]: "split (curry f) = f"
   725   by (simp add: curry_def split_def)
   726 
   727 text {*
   728   The composition-uncurry combinator.
   729 *}
   730 
   731 notation fcomp (infixl "\<circ>>" 60)
   732 
   733 definition scomp :: "('a \<Rightarrow> 'b \<times> 'c) \<Rightarrow> ('b \<Rightarrow> 'c \<Rightarrow> 'd) \<Rightarrow> 'a \<Rightarrow> 'd" (infixl "\<circ>\<rightarrow>" 60) where
   734   "f \<circ>\<rightarrow> g = (\<lambda>x. prod_case g (f x))"
   735 
   736 lemma scomp_unfold: "scomp = (\<lambda>f g x. g (fst (f x)) (snd (f x)))"
   737   by (simp add: fun_eq_iff scomp_def prod_case_unfold)
   738 
   739 lemma scomp_apply [simp]: "(f \<circ>\<rightarrow> g) x = prod_case g (f x)"
   740   by (simp add: scomp_unfold prod_case_unfold)
   741 
   742 lemma Pair_scomp: "Pair x \<circ>\<rightarrow> f = f x"
   743   by (simp add: fun_eq_iff)
   744 
   745 lemma scomp_Pair: "x \<circ>\<rightarrow> Pair = x"
   746   by (simp add: fun_eq_iff)
   747 
   748 lemma scomp_scomp: "(f \<circ>\<rightarrow> g) \<circ>\<rightarrow> h = f \<circ>\<rightarrow> (\<lambda>x. g x \<circ>\<rightarrow> h)"
   749   by (simp add: fun_eq_iff scomp_unfold)
   750 
   751 lemma scomp_fcomp: "(f \<circ>\<rightarrow> g) \<circ>> h = f \<circ>\<rightarrow> (\<lambda>x. g x \<circ>> h)"
   752   by (simp add: fun_eq_iff scomp_unfold fcomp_def)
   753 
   754 lemma fcomp_scomp: "(f \<circ>> g) \<circ>\<rightarrow> h = f \<circ>> (g \<circ>\<rightarrow> h)"
   755   by (simp add: fun_eq_iff scomp_unfold)
   756 
   757 code_const scomp
   758   (Eval infixl 3 "#->")
   759 
   760 no_notation fcomp (infixl "\<circ>>" 60)
   761 no_notation scomp (infixl "\<circ>\<rightarrow>" 60)
   762 
   763 text {*
   764   @{term map_pair} --- action of the product functor upon
   765   functions.
   766 *}
   767 
   768 definition map_pair :: "('a \<Rightarrow> 'c) \<Rightarrow> ('b \<Rightarrow> 'd) \<Rightarrow> 'a \<times> 'b \<Rightarrow> 'c \<times> 'd" where
   769   "map_pair f g = (\<lambda>(x, y). (f x, g y))"
   770 
   771 lemma map_pair_simp [simp, code]:
   772   "map_pair f g (a, b) = (f a, g b)"
   773   by (simp add: map_pair_def)
   774 
   775 enriched_type map_pair: map_pair
   776   by (auto simp add: split_paired_all)
   777 
   778 lemma fst_map_pair [simp]:
   779   "fst (map_pair f g x) = f (fst x)"
   780   by (cases x) simp_all
   781 
   782 lemma snd_prod_fun [simp]:
   783   "snd (map_pair f g x) = g (snd x)"
   784   by (cases x) simp_all
   785 
   786 lemma fst_comp_map_pair [simp]:
   787   "fst \<circ> map_pair f g = f \<circ> fst"
   788   by (rule ext) simp_all
   789 
   790 lemma snd_comp_map_pair [simp]:
   791   "snd \<circ> map_pair f g = g \<circ> snd"
   792   by (rule ext) simp_all
   793 
   794 lemma map_pair_compose:
   795   "map_pair (f1 o f2) (g1 o g2) = (map_pair f1 g1 o map_pair f2 g2)"
   796   by (rule ext) (simp add: map_pair.compositionality comp_def)
   797 
   798 lemma map_pair_ident [simp]:
   799   "map_pair (%x. x) (%y. y) = (%z. z)"
   800   by (rule ext) (simp add: map_pair.identity)
   801 
   802 lemma map_pair_imageI [intro]:
   803   "(a, b) \<in> R \<Longrightarrow> (f a, g b) \<in> map_pair f g ` R"
   804   by (rule image_eqI) simp_all
   805 
   806 lemma prod_fun_imageE [elim!]:
   807   assumes major: "c \<in> map_pair f g ` R"
   808     and cases: "\<And>x y. c = (f x, g y) \<Longrightarrow> (x, y) \<in> R \<Longrightarrow> P"
   809   shows P
   810   apply (rule major [THEN imageE])
   811   apply (case_tac x)
   812   apply (rule cases)
   813   apply simp_all
   814   done
   815 
   816 definition apfst :: "('a \<Rightarrow> 'c) \<Rightarrow> 'a \<times> 'b \<Rightarrow> 'c \<times> 'b" where
   817   "apfst f = map_pair f id"
   818 
   819 definition apsnd :: "('b \<Rightarrow> 'c) \<Rightarrow> 'a \<times> 'b \<Rightarrow> 'a \<times> 'c" where
   820   "apsnd f = map_pair id f"
   821 
   822 lemma apfst_conv [simp, code]:
   823   "apfst f (x, y) = (f x, y)" 
   824   by (simp add: apfst_def)
   825 
   826 lemma apsnd_conv [simp, code]:
   827   "apsnd f (x, y) = (x, f y)" 
   828   by (simp add: apsnd_def)
   829 
   830 lemma fst_apfst [simp]:
   831   "fst (apfst f x) = f (fst x)"
   832   by (cases x) simp
   833 
   834 lemma fst_apsnd [simp]:
   835   "fst (apsnd f x) = fst x"
   836   by (cases x) simp
   837 
   838 lemma snd_apfst [simp]:
   839   "snd (apfst f x) = snd x"
   840   by (cases x) simp
   841 
   842 lemma snd_apsnd [simp]:
   843   "snd (apsnd f x) = f (snd x)"
   844   by (cases x) simp
   845 
   846 lemma apfst_compose:
   847   "apfst f (apfst g x) = apfst (f \<circ> g) x"
   848   by (cases x) simp
   849 
   850 lemma apsnd_compose:
   851   "apsnd f (apsnd g x) = apsnd (f \<circ> g) x"
   852   by (cases x) simp
   853 
   854 lemma apfst_apsnd [simp]:
   855   "apfst f (apsnd g x) = (f (fst x), g (snd x))"
   856   by (cases x) simp
   857 
   858 lemma apsnd_apfst [simp]:
   859   "apsnd f (apfst g x) = (g (fst x), f (snd x))"
   860   by (cases x) simp
   861 
   862 lemma apfst_id [simp] :
   863   "apfst id = id"
   864   by (simp add: fun_eq_iff)
   865 
   866 lemma apsnd_id [simp] :
   867   "apsnd id = id"
   868   by (simp add: fun_eq_iff)
   869 
   870 lemma apfst_eq_conv [simp]:
   871   "apfst f x = apfst g x \<longleftrightarrow> f (fst x) = g (fst x)"
   872   by (cases x) simp
   873 
   874 lemma apsnd_eq_conv [simp]:
   875   "apsnd f x = apsnd g x \<longleftrightarrow> f (snd x) = g (snd x)"
   876   by (cases x) simp
   877 
   878 lemma apsnd_apfst_commute:
   879   "apsnd f (apfst g p) = apfst g (apsnd f p)"
   880   by simp
   881 
   882 text {*
   883   Disjoint union of a family of sets -- Sigma.
   884 *}
   885 
   886 definition Sigma :: "['a set, 'a => 'b set] => ('a \<times> 'b) set" where
   887   Sigma_def: "Sigma A B == UN x:A. UN y:B x. {Pair x y}"
   888 
   889 abbreviation
   890   Times :: "['a set, 'b set] => ('a * 'b) set"
   891     (infixr "<*>" 80) where
   892   "A <*> B == Sigma A (%_. B)"
   893 
   894 notation (xsymbols)
   895   Times  (infixr "\<times>" 80)
   896 
   897 notation (HTML output)
   898   Times  (infixr "\<times>" 80)
   899 
   900 syntax
   901   "_Sigma" :: "[pttrn, 'a set, 'b set] => ('a * 'b) set"  ("(3SIGMA _:_./ _)" [0, 0, 10] 10)
   902 translations
   903   "SIGMA x:A. B" == "CONST Sigma A (%x. B)"
   904 
   905 lemma SigmaI [intro!]: "[| a:A;  b:B(a) |] ==> (a,b) : Sigma A B"
   906   by (unfold Sigma_def) blast
   907 
   908 lemma SigmaE [elim!]:
   909     "[| c: Sigma A B;
   910         !!x y.[| x:A;  y:B(x);  c=(x,y) |] ==> P
   911      |] ==> P"
   912   -- {* The general elimination rule. *}
   913   by (unfold Sigma_def) blast
   914 
   915 text {*
   916   Elimination of @{term "(a, b) : A \<times> B"} -- introduces no
   917   eigenvariables.
   918 *}
   919 
   920 lemma SigmaD1: "(a, b) : Sigma A B ==> a : A"
   921   by blast
   922 
   923 lemma SigmaD2: "(a, b) : Sigma A B ==> b : B a"
   924   by blast
   925 
   926 lemma SigmaE2:
   927     "[| (a, b) : Sigma A B;
   928         [| a:A;  b:B(a) |] ==> P
   929      |] ==> P"
   930   by blast
   931 
   932 lemma Sigma_cong:
   933      "\<lbrakk>A = B; !!x. x \<in> B \<Longrightarrow> C x = D x\<rbrakk>
   934       \<Longrightarrow> (SIGMA x: A. C x) = (SIGMA x: B. D x)"
   935   by auto
   936 
   937 lemma Sigma_mono: "[| A <= C; !!x. x:A ==> B x <= D x |] ==> Sigma A B <= Sigma C D"
   938   by blast
   939 
   940 lemma Sigma_empty1 [simp]: "Sigma {} B = {}"
   941   by blast
   942 
   943 lemma Sigma_empty2 [simp]: "A <*> {} = {}"
   944   by blast
   945 
   946 lemma UNIV_Times_UNIV [simp]: "UNIV <*> UNIV = UNIV"
   947   by auto
   948 
   949 lemma Compl_Times_UNIV1 [simp]: "- (UNIV <*> A) = UNIV <*> (-A)"
   950   by auto
   951 
   952 lemma Compl_Times_UNIV2 [simp]: "- (A <*> UNIV) = (-A) <*> UNIV"
   953   by auto
   954 
   955 lemma mem_Sigma_iff [iff]: "((a,b): Sigma A B) = (a:A & b:B(a))"
   956   by blast
   957 
   958 lemma Times_subset_cancel2: "x:C ==> (A <*> C <= B <*> C) = (A <= B)"
   959   by blast
   960 
   961 lemma Times_eq_cancel2: "x:C ==> (A <*> C = B <*> C) = (A = B)"
   962   by (blast elim: equalityE)
   963 
   964 lemma SetCompr_Sigma_eq:
   965     "Collect (split (%x y. P x & Q x y)) = (SIGMA x:Collect P. Collect (Q x))"
   966   by blast
   967 
   968 lemma Collect_split [simp]: "{(a,b). P a & Q b} = Collect P <*> Collect Q"
   969   by blast
   970 
   971 lemma UN_Times_distrib:
   972   "(UN (a,b):(A <*> B). E a <*> F b) = (UNION A E) <*> (UNION B F)"
   973   -- {* Suggested by Pierre Chartier *}
   974   by blast
   975 
   976 lemma split_paired_Ball_Sigma [simp,no_atp]:
   977     "(ALL z: Sigma A B. P z) = (ALL x:A. ALL y: B x. P(x,y))"
   978   by blast
   979 
   980 lemma split_paired_Bex_Sigma [simp,no_atp]:
   981     "(EX z: Sigma A B. P z) = (EX x:A. EX y: B x. P(x,y))"
   982   by blast
   983 
   984 lemma Sigma_Un_distrib1: "(SIGMA i:I Un J. C(i)) = (SIGMA i:I. C(i)) Un (SIGMA j:J. C(j))"
   985   by blast
   986 
   987 lemma Sigma_Un_distrib2: "(SIGMA i:I. A(i) Un B(i)) = (SIGMA i:I. A(i)) Un (SIGMA i:I. B(i))"
   988   by blast
   989 
   990 lemma Sigma_Int_distrib1: "(SIGMA i:I Int J. C(i)) = (SIGMA i:I. C(i)) Int (SIGMA j:J. C(j))"
   991   by blast
   992 
   993 lemma Sigma_Int_distrib2: "(SIGMA i:I. A(i) Int B(i)) = (SIGMA i:I. A(i)) Int (SIGMA i:I. B(i))"
   994   by blast
   995 
   996 lemma Sigma_Diff_distrib1: "(SIGMA i:I - J. C(i)) = (SIGMA i:I. C(i)) - (SIGMA j:J. C(j))"
   997   by blast
   998 
   999 lemma Sigma_Diff_distrib2: "(SIGMA i:I. A(i) - B(i)) = (SIGMA i:I. A(i)) - (SIGMA i:I. B(i))"
  1000   by blast
  1001 
  1002 lemma Sigma_Union: "Sigma (Union X) B = (UN A:X. Sigma A B)"
  1003   by blast
  1004 
  1005 text {*
  1006   Non-dependent versions are needed to avoid the need for higher-order
  1007   matching, especially when the rules are re-oriented.
  1008 *}
  1009 
  1010 lemma Times_Un_distrib1: "(A Un B) <*> C = (A <*> C) Un (B <*> C)"
  1011 by blast
  1012 
  1013 lemma Times_Int_distrib1: "(A Int B) <*> C = (A <*> C) Int (B <*> C)"
  1014 by blast
  1015 
  1016 lemma Times_Diff_distrib1: "(A - B) <*> C = (A <*> C) - (B <*> C)"
  1017 by blast
  1018 
  1019 lemma Times_empty[simp]: "A \<times> B = {} \<longleftrightarrow> A = {} \<or> B = {}"
  1020   by auto
  1021 
  1022 lemma fst_image_times[simp]: "fst ` (A \<times> B) = (if B = {} then {} else A)"
  1023   by force
  1024 
  1025 lemma snd_image_times[simp]: "snd ` (A \<times> B) = (if A = {} then {} else B)"
  1026   by force
  1027 
  1028 lemma insert_times_insert[simp]:
  1029   "insert a A \<times> insert b B =
  1030    insert (a,b) (A \<times> insert b B \<union> insert a A \<times> B)"
  1031 by blast
  1032 
  1033 lemma vimage_Times: "f -` (A \<times> B) = ((fst \<circ> f) -` A) \<inter> ((snd \<circ> f) -` B)"
  1034   by (auto, case_tac "f x", auto)
  1035 
  1036 lemma swap_inj_on:
  1037   "inj_on (\<lambda>(i, j). (j, i)) A"
  1038   by (auto intro!: inj_onI)
  1039 
  1040 lemma swap_product:
  1041   "(%(i, j). (j, i)) ` (A \<times> B) = B \<times> A"
  1042   by (simp add: split_def image_def) blast
  1043 
  1044 lemma image_split_eq_Sigma:
  1045   "(\<lambda>x. (f x, g x)) ` A = Sigma (f ` A) (\<lambda>x. g ` (f -` {x} \<inter> A))"
  1046 proof (safe intro!: imageI vimageI)
  1047   fix a b assume *: "a \<in> A" "b \<in> A" and eq: "f a = f b"
  1048   show "(f b, g a) \<in> (\<lambda>x. (f x, g x)) ` A"
  1049     using * eq[symmetric] by auto
  1050 qed simp_all
  1051 
  1052 text {* The following @{const map_pair} lemmas are due to Joachim Breitner: *}
  1053 
  1054 lemma map_pair_inj_on:
  1055   assumes "inj_on f A" and "inj_on g B"
  1056   shows "inj_on (map_pair f g) (A \<times> B)"
  1057 proof (rule inj_onI)
  1058   fix x :: "'a \<times> 'c" and y :: "'a \<times> 'c"
  1059   assume "x \<in> A \<times> B" hence "fst x \<in> A" and "snd x \<in> B" by auto
  1060   assume "y \<in> A \<times> B" hence "fst y \<in> A" and "snd y \<in> B" by auto
  1061   assume "map_pair f g x = map_pair f g y"
  1062   hence "fst (map_pair f g x) = fst (map_pair f g y)" by (auto)
  1063   hence "f (fst x) = f (fst y)" by (cases x,cases y,auto)
  1064   with `inj_on f A` and `fst x \<in> A` and `fst y \<in> A`
  1065   have "fst x = fst y" by (auto dest:dest:inj_onD)
  1066   moreover from `map_pair f g x = map_pair f g y`
  1067   have "snd (map_pair f g x) = snd (map_pair f g y)" by (auto)
  1068   hence "g (snd x) = g (snd y)" by (cases x,cases y,auto)
  1069   with `inj_on g B` and `snd x \<in> B` and `snd y \<in> B`
  1070   have "snd x = snd y" by (auto dest:dest:inj_onD)
  1071   ultimately show "x = y" by(rule prod_eqI)
  1072 qed
  1073 
  1074 lemma map_pair_surj:
  1075   fixes f :: "'a \<Rightarrow> 'b" and g :: "'c \<Rightarrow> 'd"
  1076   assumes "surj f" and "surj g"
  1077   shows "surj (map_pair f g)"
  1078 unfolding surj_def
  1079 proof
  1080   fix y :: "'b \<times> 'd"
  1081   from `surj f` obtain a where "fst y = f a" by (auto elim:surjE)
  1082   moreover
  1083   from `surj g` obtain b where "snd y = g b" by (auto elim:surjE)
  1084   ultimately have "(fst y, snd y) = map_pair f g (a,b)" by auto
  1085   thus "\<exists>x. y = map_pair f g x" by auto
  1086 qed
  1087 
  1088 lemma map_pair_surj_on:
  1089   assumes "f ` A = A'" and "g ` B = B'"
  1090   shows "map_pair f g ` (A \<times> B) = A' \<times> B'"
  1091 unfolding image_def
  1092 proof(rule set_eqI,rule iffI)
  1093   fix x :: "'a \<times> 'c"
  1094   assume "x \<in> {y\<Colon>'a \<times> 'c. \<exists>x\<Colon>'b \<times> 'd\<in>A \<times> B. y = map_pair f g x}"
  1095   then obtain y where "y \<in> A \<times> B" and "x = map_pair f g y" by blast
  1096   from `image f A = A'` and `y \<in> A \<times> B` have "f (fst y) \<in> A'" by auto
  1097   moreover from `image g B = B'` and `y \<in> A \<times> B` have "g (snd y) \<in> B'" by auto
  1098   ultimately have "(f (fst y), g (snd y)) \<in> (A' \<times> B')" by auto
  1099   with `x = map_pair f g y` show "x \<in> A' \<times> B'" by (cases y, auto)
  1100 next
  1101   fix x :: "'a \<times> 'c"
  1102   assume "x \<in> A' \<times> B'" hence "fst x \<in> A'" and "snd x \<in> B'" by auto
  1103   from `image f A = A'` and `fst x \<in> A'` have "fst x \<in> image f A" by auto
  1104   then obtain a where "a \<in> A" and "fst x = f a" by (rule imageE)
  1105   moreover from `image g B = B'` and `snd x \<in> B'`
  1106   obtain b where "b \<in> B" and "snd x = g b" by auto
  1107   ultimately have "(fst x, snd x) = map_pair f g (a,b)" by auto
  1108   moreover from `a \<in> A` and  `b \<in> B` have "(a , b) \<in> A \<times> B" by auto
  1109   ultimately have "\<exists>y \<in> A \<times> B. x = map_pair f g y" by auto
  1110   thus "x \<in> {x. \<exists>y \<in> A \<times> B. x = map_pair f g y}" by auto
  1111 qed
  1112 
  1113 
  1114 subsection {* Inductively defined sets *}
  1115 
  1116 use "Tools/inductive_set.ML"
  1117 setup Inductive_Set.setup
  1118 
  1119 
  1120 subsection {* Legacy theorem bindings and duplicates *}
  1121 
  1122 lemma PairE:
  1123   obtains x y where "p = (x, y)"
  1124   by (fact prod.exhaust)
  1125 
  1126 lemma Pair_inject:
  1127   assumes "(a, b) = (a', b')"
  1128     and "a = a' ==> b = b' ==> R"
  1129   shows R
  1130   using assms by simp
  1131 
  1132 lemmas Pair_eq = prod.inject
  1133 
  1134 lemmas split = split_conv  -- {* for backwards compatibility *}
  1135 
  1136 lemmas Pair_fst_snd_eq = prod_eq_iff
  1137 
  1138 end