src/HOL/Probability/Finite_Product_Measure.thy
author hoelzl
Fri Nov 02 14:00:39 2012 +0100 (2012-11-02)
changeset 49999 dfb63b9b8908
parent 49784 5e5b2da42a69
child 50003 8c213922ed49
permissions -rw-r--r--
for the product measure it is enough if only one measure is sigma-finite
     1 (*  Title:      HOL/Probability/Finite_Product_Measure.thy
     2     Author:     Johannes Hölzl, TU München
     3 *)
     4 
     5 header {*Finite product measures*}
     6 
     7 theory Finite_Product_Measure
     8 imports Binary_Product_Measure
     9 begin
    10 
    11 lemma split_const: "(\<lambda>(i, j). c) = (\<lambda>_. c)"
    12   by auto
    13 
    14 abbreviation
    15   "Pi\<^isub>E A B \<equiv> Pi A B \<inter> extensional A"
    16 
    17 syntax
    18   "_PiE"  :: "[pttrn, 'a set, 'b set] => ('a => 'b) set"  ("(3PIE _:_./ _)" 10)
    19 
    20 syntax (xsymbols)
    21   "_PiE" :: "[pttrn, 'a set, 'b set] => ('a => 'b) set"  ("(3\<Pi>\<^isub>E _\<in>_./ _)"   10)
    22 
    23 syntax (HTML output)
    24   "_PiE" :: "[pttrn, 'a set, 'b set] => ('a => 'b) set"  ("(3\<Pi>\<^isub>E _\<in>_./ _)"   10)
    25 
    26 translations
    27   "PIE x:A. B" == "CONST Pi\<^isub>E A (%x. B)"
    28 
    29 abbreviation
    30   funcset_extensional :: "['a set, 'b set] => ('a => 'b) set"
    31     (infixr "->\<^isub>E" 60) where
    32   "A ->\<^isub>E B \<equiv> Pi\<^isub>E A (%_. B)"
    33 
    34 notation (xsymbols)
    35   funcset_extensional  (infixr "\<rightarrow>\<^isub>E" 60)
    36 
    37 lemma extensional_insert[intro, simp]:
    38   assumes "a \<in> extensional (insert i I)"
    39   shows "a(i := b) \<in> extensional (insert i I)"
    40   using assms unfolding extensional_def by auto
    41 
    42 lemma extensional_Int[simp]:
    43   "extensional I \<inter> extensional I' = extensional (I \<inter> I')"
    44   unfolding extensional_def by auto
    45 
    46 definition
    47   "merge I J = (\<lambda>(x, y) i. if i \<in> I then x i else if i \<in> J then y i else undefined)"
    48 
    49 lemma merge_apply[simp]:
    50   "I \<inter> J = {} \<Longrightarrow> i \<in> I \<Longrightarrow> merge I J (x, y) i = x i"
    51   "I \<inter> J = {} \<Longrightarrow> i \<in> J \<Longrightarrow> merge I J (x, y) i = y i"
    52   "J \<inter> I = {} \<Longrightarrow> i \<in> I \<Longrightarrow> merge I J (x, y) i = x i"
    53   "J \<inter> I = {} \<Longrightarrow> i \<in> J \<Longrightarrow> merge I J (x, y) i = y i"
    54   "i \<notin> I \<Longrightarrow> i \<notin> J \<Longrightarrow> merge I J (x, y) i = undefined"
    55   unfolding merge_def by auto
    56 
    57 lemma merge_commute:
    58   "I \<inter> J = {} \<Longrightarrow> merge I J (x, y) = merge J I (y, x)"
    59   by (auto simp: merge_def intro!: ext)
    60 
    61 lemma Pi_cancel_merge_range[simp]:
    62   "I \<inter> J = {} \<Longrightarrow> x \<in> Pi I (merge I J (A, B)) \<longleftrightarrow> x \<in> Pi I A"
    63   "I \<inter> J = {} \<Longrightarrow> x \<in> Pi I (merge J I (B, A)) \<longleftrightarrow> x \<in> Pi I A"
    64   "J \<inter> I = {} \<Longrightarrow> x \<in> Pi I (merge I J (A, B)) \<longleftrightarrow> x \<in> Pi I A"
    65   "J \<inter> I = {} \<Longrightarrow> x \<in> Pi I (merge J I (B, A)) \<longleftrightarrow> x \<in> Pi I A"
    66   by (auto simp: Pi_def)
    67 
    68 lemma Pi_cancel_merge[simp]:
    69   "I \<inter> J = {} \<Longrightarrow> merge I J (x, y) \<in> Pi I B \<longleftrightarrow> x \<in> Pi I B"
    70   "J \<inter> I = {} \<Longrightarrow> merge I J (x, y) \<in> Pi I B \<longleftrightarrow> x \<in> Pi I B"
    71   "I \<inter> J = {} \<Longrightarrow> merge I J (x, y) \<in> Pi J B \<longleftrightarrow> y \<in> Pi J B"
    72   "J \<inter> I = {} \<Longrightarrow> merge I J (x, y) \<in> Pi J B \<longleftrightarrow> y \<in> Pi J B"
    73   by (auto simp: Pi_def)
    74 
    75 lemma extensional_merge[simp]: "merge I J (x, y) \<in> extensional (I \<union> J)"
    76   by (auto simp: extensional_def)
    77 
    78 lemma restrict_Pi_cancel: "restrict x I \<in> Pi I A \<longleftrightarrow> x \<in> Pi I A"
    79   by (auto simp: restrict_def Pi_def)
    80 
    81 lemma restrict_merge[simp]:
    82   "I \<inter> J = {} \<Longrightarrow> restrict (merge I J (x, y)) I = restrict x I"
    83   "I \<inter> J = {} \<Longrightarrow> restrict (merge I J (x, y)) J = restrict y J"
    84   "J \<inter> I = {} \<Longrightarrow> restrict (merge I J (x, y)) I = restrict x I"
    85   "J \<inter> I = {} \<Longrightarrow> restrict (merge I J (x, y)) J = restrict y J"
    86   by (auto simp: restrict_def)
    87 
    88 lemma extensional_insert_undefined[intro, simp]:
    89   assumes "a \<in> extensional (insert i I)"
    90   shows "a(i := undefined) \<in> extensional I"
    91   using assms unfolding extensional_def by auto
    92 
    93 lemma extensional_insert_cancel[intro, simp]:
    94   assumes "a \<in> extensional I"
    95   shows "a \<in> extensional (insert i I)"
    96   using assms unfolding extensional_def by auto
    97 
    98 lemma merge_singleton[simp]: "i \<notin> I \<Longrightarrow> merge I {i} (x,y) = restrict (x(i := y i)) (insert i I)"
    99   unfolding merge_def by (auto simp: fun_eq_iff)
   100 
   101 lemma Pi_Int: "Pi I E \<inter> Pi I F = (\<Pi> i\<in>I. E i \<inter> F i)"
   102   by auto
   103 
   104 lemma PiE_Int: "(Pi\<^isub>E I A) \<inter> (Pi\<^isub>E I B) = Pi\<^isub>E I (\<lambda>x. A x \<inter> B x)"
   105   by auto
   106 
   107 lemma Pi_cancel_fupd_range[simp]: "i \<notin> I \<Longrightarrow> x \<in> Pi I (B(i := b)) \<longleftrightarrow> x \<in> Pi I B"
   108   by (auto simp: Pi_def)
   109 
   110 lemma Pi_split_insert_domain[simp]: "x \<in> Pi (insert i I) X \<longleftrightarrow> x \<in> Pi I X \<and> x i \<in> X i"
   111   by (auto simp: Pi_def)
   112 
   113 lemma Pi_split_domain[simp]: "x \<in> Pi (I \<union> J) X \<longleftrightarrow> x \<in> Pi I X \<and> x \<in> Pi J X"
   114   by (auto simp: Pi_def)
   115 
   116 lemma Pi_cancel_fupd[simp]: "i \<notin> I \<Longrightarrow> x(i := a) \<in> Pi I B \<longleftrightarrow> x \<in> Pi I B"
   117   by (auto simp: Pi_def)
   118 
   119 lemma restrict_vimage:
   120   assumes "I \<inter> J = {}"
   121   shows "(\<lambda>x. (restrict x I, restrict x J)) -` (Pi\<^isub>E I E \<times> Pi\<^isub>E J F) = Pi (I \<union> J) (merge I J (E, F))"
   122   using assms by (auto simp: restrict_Pi_cancel)
   123 
   124 lemma merge_vimage:
   125   assumes "I \<inter> J = {}"
   126   shows "merge I J -` Pi\<^isub>E (I \<union> J) E = Pi I E \<times> Pi J E"
   127   using assms by (auto simp: restrict_Pi_cancel)
   128 
   129 lemma restrict_fupd[simp]: "i \<notin> I \<Longrightarrow> restrict (f (i := x)) I = restrict f I"
   130   by (auto simp: restrict_def)
   131 
   132 lemma merge_restrict[simp]:
   133   "merge I J (restrict x I, y) = merge I J (x, y)"
   134   "merge I J (x, restrict y J) = merge I J (x, y)"
   135   unfolding merge_def by auto
   136 
   137 lemma merge_x_x_eq_restrict[simp]:
   138   "merge I J (x, x) = restrict x (I \<union> J)"
   139   unfolding merge_def by auto
   140 
   141 lemma Pi_fupd_iff: "i \<in> I \<Longrightarrow> f \<in> Pi I (B(i := A)) \<longleftrightarrow> f \<in> Pi (I - {i}) B \<and> f i \<in> A"
   142   apply auto
   143   apply (drule_tac x=x in Pi_mem)
   144   apply (simp_all split: split_if_asm)
   145   apply (drule_tac x=i in Pi_mem)
   146   apply (auto dest!: Pi_mem)
   147   done
   148 
   149 lemma Pi_UN:
   150   fixes A :: "nat \<Rightarrow> 'i \<Rightarrow> 'a set"
   151   assumes "finite I" and mono: "\<And>i n m. i \<in> I \<Longrightarrow> n \<le> m \<Longrightarrow> A n i \<subseteq> A m i"
   152   shows "(\<Union>n. Pi I (A n)) = (\<Pi> i\<in>I. \<Union>n. A n i)"
   153 proof (intro set_eqI iffI)
   154   fix f assume "f \<in> (\<Pi> i\<in>I. \<Union>n. A n i)"
   155   then have "\<forall>i\<in>I. \<exists>n. f i \<in> A n i" by auto
   156   from bchoice[OF this] obtain n where n: "\<And>i. i \<in> I \<Longrightarrow> f i \<in> (A (n i) i)" by auto
   157   obtain k where k: "\<And>i. i \<in> I \<Longrightarrow> n i \<le> k"
   158     using `finite I` finite_nat_set_iff_bounded_le[of "n`I"] by auto
   159   have "f \<in> Pi I (A k)"
   160   proof (intro Pi_I)
   161     fix i assume "i \<in> I"
   162     from mono[OF this, of "n i" k] k[OF this] n[OF this]
   163     show "f i \<in> A k i" by auto
   164   qed
   165   then show "f \<in> (\<Union>n. Pi I (A n))" by auto
   166 qed auto
   167 
   168 lemma PiE_cong:
   169   assumes "\<And>i. i\<in>I \<Longrightarrow> A i = B i"
   170   shows "Pi\<^isub>E I A = Pi\<^isub>E I B"
   171   using assms by (auto intro!: Pi_cong)
   172 
   173 lemma restrict_upd[simp]:
   174   "i \<notin> I \<Longrightarrow> (restrict f I)(i := y) = restrict (f(i := y)) (insert i I)"
   175   by (auto simp: fun_eq_iff)
   176 
   177 lemma Pi_eq_subset:
   178   assumes ne: "\<And>i. i \<in> I \<Longrightarrow> F i \<noteq> {}" "\<And>i. i \<in> I \<Longrightarrow> F' i \<noteq> {}"
   179   assumes eq: "Pi\<^isub>E I F = Pi\<^isub>E I F'" and "i \<in> I"
   180   shows "F i \<subseteq> F' i"
   181 proof
   182   fix x assume "x \<in> F i"
   183   with ne have "\<forall>j. \<exists>y. ((j \<in> I \<longrightarrow> y \<in> F j \<and> (i = j \<longrightarrow> x = y)) \<and> (j \<notin> I \<longrightarrow> y = undefined))" by auto
   184   from choice[OF this] guess f .. note f = this
   185   then have "f \<in> Pi\<^isub>E I F" by (auto simp: extensional_def)
   186   then have "f \<in> Pi\<^isub>E I F'" using assms by simp
   187   then show "x \<in> F' i" using f `i \<in> I` by auto
   188 qed
   189 
   190 lemma Pi_eq_iff_not_empty:
   191   assumes ne: "\<And>i. i \<in> I \<Longrightarrow> F i \<noteq> {}" "\<And>i. i \<in> I \<Longrightarrow> F' i \<noteq> {}"
   192   shows "Pi\<^isub>E I F = Pi\<^isub>E I F' \<longleftrightarrow> (\<forall>i\<in>I. F i = F' i)"
   193 proof (intro iffI ballI)
   194   fix i assume eq: "Pi\<^isub>E I F = Pi\<^isub>E I F'" and i: "i \<in> I"
   195   show "F i = F' i"
   196     using Pi_eq_subset[of I F F', OF ne eq i]
   197     using Pi_eq_subset[of I F' F, OF ne(2,1) eq[symmetric] i]
   198     by auto
   199 qed auto
   200 
   201 lemma Pi_eq_empty_iff:
   202   "Pi\<^isub>E I F = {} \<longleftrightarrow> (\<exists>i\<in>I. F i = {})"
   203 proof
   204   assume "Pi\<^isub>E I F = {}"
   205   show "\<exists>i\<in>I. F i = {}"
   206   proof (rule ccontr)
   207     assume "\<not> ?thesis"
   208     then have "\<forall>i. \<exists>y. (i \<in> I \<longrightarrow> y \<in> F i) \<and> (i \<notin> I \<longrightarrow> y = undefined)" by auto
   209     from choice[OF this] guess f ..
   210     then have "f \<in> Pi\<^isub>E I F" by (auto simp: extensional_def)
   211     with `Pi\<^isub>E I F = {}` show False by auto
   212   qed
   213 qed auto
   214 
   215 lemma Pi_eq_iff:
   216   "Pi\<^isub>E I F = Pi\<^isub>E I F' \<longleftrightarrow> (\<forall>i\<in>I. F i = F' i) \<or> ((\<exists>i\<in>I. F i = {}) \<and> (\<exists>i\<in>I. F' i = {}))"
   217 proof (intro iffI disjCI)
   218   assume eq[simp]: "Pi\<^isub>E I F = Pi\<^isub>E I F'"
   219   assume "\<not> ((\<exists>i\<in>I. F i = {}) \<and> (\<exists>i\<in>I. F' i = {}))"
   220   then have "(\<forall>i\<in>I. F i \<noteq> {}) \<and> (\<forall>i\<in>I. F' i \<noteq> {})"
   221     using Pi_eq_empty_iff[of I F] Pi_eq_empty_iff[of I F'] by auto
   222   with Pi_eq_iff_not_empty[of I F F'] show "\<forall>i\<in>I. F i = F' i" by auto
   223 next
   224   assume "(\<forall>i\<in>I. F i = F' i) \<or> (\<exists>i\<in>I. F i = {}) \<and> (\<exists>i\<in>I. F' i = {})"
   225   then show "Pi\<^isub>E I F = Pi\<^isub>E I F'"
   226     using Pi_eq_empty_iff[of I F] Pi_eq_empty_iff[of I F'] by auto
   227 qed
   228 
   229 section "Finite product spaces"
   230 
   231 section "Products"
   232 
   233 definition prod_emb where
   234   "prod_emb I M K X = (\<lambda>x. restrict x K) -` X \<inter> (PIE i:I. space (M i))"
   235 
   236 lemma prod_emb_iff: 
   237   "f \<in> prod_emb I M K X \<longleftrightarrow> f \<in> extensional I \<and> (restrict f K \<in> X) \<and> (\<forall>i\<in>I. f i \<in> space (M i))"
   238   unfolding prod_emb_def by auto
   239 
   240 lemma
   241   shows prod_emb_empty[simp]: "prod_emb M L K {} = {}"
   242     and prod_emb_Un[simp]: "prod_emb M L K (A \<union> B) = prod_emb M L K A \<union> prod_emb M L K B"
   243     and prod_emb_Int: "prod_emb M L K (A \<inter> B) = prod_emb M L K A \<inter> prod_emb M L K B"
   244     and prod_emb_UN[simp]: "prod_emb M L K (\<Union>i\<in>I. F i) = (\<Union>i\<in>I. prod_emb M L K (F i))"
   245     and prod_emb_INT[simp]: "I \<noteq> {} \<Longrightarrow> prod_emb M L K (\<Inter>i\<in>I. F i) = (\<Inter>i\<in>I. prod_emb M L K (F i))"
   246     and prod_emb_Diff[simp]: "prod_emb M L K (A - B) = prod_emb M L K A - prod_emb M L K B"
   247   by (auto simp: prod_emb_def)
   248 
   249 lemma prod_emb_PiE: "J \<subseteq> I \<Longrightarrow> (\<And>i. i \<in> J \<Longrightarrow> E i \<subseteq> space (M i)) \<Longrightarrow>
   250     prod_emb I M J (\<Pi>\<^isub>E i\<in>J. E i) = (\<Pi>\<^isub>E i\<in>I. if i \<in> J then E i else space (M i))"
   251   by (force simp: prod_emb_def Pi_iff split_if_mem2)
   252 
   253 lemma prod_emb_PiE_same_index[simp]: "(\<And>i. i \<in> I \<Longrightarrow> E i \<subseteq> space (M i)) \<Longrightarrow> prod_emb I M I (Pi\<^isub>E I E) = Pi\<^isub>E I E"
   254   by (auto simp: prod_emb_def Pi_iff)
   255 
   256 definition PiM :: "'i set \<Rightarrow> ('i \<Rightarrow> 'a measure) \<Rightarrow> ('i \<Rightarrow> 'a) measure" where
   257   "PiM I M = extend_measure (\<Pi>\<^isub>E i\<in>I. space (M i))
   258     {(J, X). (J \<noteq> {} \<or> I = {}) \<and> finite J \<and> J \<subseteq> I \<and> X \<in> (\<Pi> j\<in>J. sets (M j))}
   259     (\<lambda>(J, X). prod_emb I M J (\<Pi>\<^isub>E j\<in>J. X j))
   260     (\<lambda>(J, X). \<Prod>j\<in>J \<union> {i\<in>I. emeasure (M i) (space (M i)) \<noteq> 1}. if j \<in> J then emeasure (M j) (X j) else emeasure (M j) (space (M j)))"
   261 
   262 definition prod_algebra :: "'i set \<Rightarrow> ('i \<Rightarrow> 'a measure) \<Rightarrow> ('i \<Rightarrow> 'a) set set" where
   263   "prod_algebra I M = (\<lambda>(J, X). prod_emb I M J (\<Pi>\<^isub>E j\<in>J. X j)) `
   264     {(J, X). (J \<noteq> {} \<or> I = {}) \<and> finite J \<and> J \<subseteq> I \<and> X \<in> (\<Pi> j\<in>J. sets (M j))}"
   265 
   266 abbreviation
   267   "Pi\<^isub>M I M \<equiv> PiM I M"
   268 
   269 syntax
   270   "_PiM" :: "pttrn \<Rightarrow> 'i set \<Rightarrow> 'a measure \<Rightarrow> ('i => 'a) measure"  ("(3PIM _:_./ _)" 10)
   271 
   272 syntax (xsymbols)
   273   "_PiM" :: "pttrn \<Rightarrow> 'i set \<Rightarrow> 'a measure \<Rightarrow> ('i => 'a) measure"  ("(3\<Pi>\<^isub>M _\<in>_./ _)"  10)
   274 
   275 syntax (HTML output)
   276   "_PiM" :: "pttrn \<Rightarrow> 'i set \<Rightarrow> 'a measure \<Rightarrow> ('i => 'a) measure"  ("(3\<Pi>\<^isub>M _\<in>_./ _)"  10)
   277 
   278 translations
   279   "PIM x:I. M" == "CONST PiM I (%x. M)"
   280 
   281 lemma prod_algebra_sets_into_space:
   282   "prod_algebra I M \<subseteq> Pow (\<Pi>\<^isub>E i\<in>I. space (M i))"
   283   using assms by (auto simp: prod_emb_def prod_algebra_def)
   284 
   285 lemma prod_algebra_eq_finite:
   286   assumes I: "finite I"
   287   shows "prod_algebra I M = {(\<Pi>\<^isub>E i\<in>I. X i) |X. X \<in> (\<Pi> j\<in>I. sets (M j))}" (is "?L = ?R")
   288 proof (intro iffI set_eqI)
   289   fix A assume "A \<in> ?L"
   290   then obtain J E where J: "J \<noteq> {} \<or> I = {}" "finite J" "J \<subseteq> I" "\<forall>i\<in>J. E i \<in> sets (M i)"
   291     and A: "A = prod_emb I M J (PIE j:J. E j)"
   292     by (auto simp: prod_algebra_def)
   293   let ?A = "\<Pi>\<^isub>E i\<in>I. if i \<in> J then E i else space (M i)"
   294   have A: "A = ?A"
   295     unfolding A using J by (intro prod_emb_PiE sets_into_space) auto
   296   show "A \<in> ?R" unfolding A using J top
   297     by (intro CollectI exI[of _ "\<lambda>i. if i \<in> J then E i else space (M i)"]) simp
   298 next
   299   fix A assume "A \<in> ?R"
   300   then obtain X where "A = (\<Pi>\<^isub>E i\<in>I. X i)" and X: "X \<in> (\<Pi> j\<in>I. sets (M j))" by auto
   301   then have A: "A = prod_emb I M I (\<Pi>\<^isub>E i\<in>I. X i)"
   302     using sets_into_space by (force simp: prod_emb_def Pi_iff)
   303   from X I show "A \<in> ?L" unfolding A
   304     by (auto simp: prod_algebra_def)
   305 qed
   306 
   307 lemma prod_algebraI:
   308   "finite J \<Longrightarrow> (J \<noteq> {} \<or> I = {}) \<Longrightarrow> J \<subseteq> I \<Longrightarrow> (\<And>i. i \<in> J \<Longrightarrow> E i \<in> sets (M i))
   309     \<Longrightarrow> prod_emb I M J (PIE j:J. E j) \<in> prod_algebra I M"
   310   by (auto simp: prod_algebra_def Pi_iff)
   311 
   312 lemma prod_algebraE:
   313   assumes A: "A \<in> prod_algebra I M"
   314   obtains J E where "A = prod_emb I M J (PIE j:J. E j)"
   315     "finite J" "J \<noteq> {} \<or> I = {}" "J \<subseteq> I" "\<And>i. i \<in> J \<Longrightarrow> E i \<in> sets (M i)" 
   316   using A by (auto simp: prod_algebra_def)
   317 
   318 lemma prod_algebraE_all:
   319   assumes A: "A \<in> prod_algebra I M"
   320   obtains E where "A = Pi\<^isub>E I E" "E \<in> (\<Pi> i\<in>I. sets (M i))"
   321 proof -
   322   from A obtain E J where A: "A = prod_emb I M J (Pi\<^isub>E J E)"
   323     and J: "J \<subseteq> I" and E: "E \<in> (\<Pi> i\<in>J. sets (M i))"
   324     by (auto simp: prod_algebra_def)
   325   from E have "\<And>i. i \<in> J \<Longrightarrow> E i \<subseteq> space (M i)"
   326     using sets_into_space by auto
   327   then have "A = (\<Pi>\<^isub>E i\<in>I. if i\<in>J then E i else space (M i))"
   328     using A J by (auto simp: prod_emb_PiE)
   329   moreover then have "(\<lambda>i. if i\<in>J then E i else space (M i)) \<in> (\<Pi> i\<in>I. sets (M i))"
   330     using top E by auto
   331   ultimately show ?thesis using that by auto
   332 qed
   333 
   334 lemma Int_stable_prod_algebra: "Int_stable (prod_algebra I M)"
   335 proof (unfold Int_stable_def, safe)
   336   fix A assume "A \<in> prod_algebra I M"
   337   from prod_algebraE[OF this] guess J E . note A = this
   338   fix B assume "B \<in> prod_algebra I M"
   339   from prod_algebraE[OF this] guess K F . note B = this
   340   have "A \<inter> B = prod_emb I M (J \<union> K) (\<Pi>\<^isub>E i\<in>J \<union> K. (if i \<in> J then E i else space (M i)) \<inter> 
   341       (if i \<in> K then F i else space (M i)))"
   342     unfolding A B using A(2,3,4) A(5)[THEN sets_into_space] B(2,3,4) B(5)[THEN sets_into_space]
   343     apply (subst (1 2 3) prod_emb_PiE)
   344     apply (simp_all add: subset_eq PiE_Int)
   345     apply blast
   346     apply (intro PiE_cong)
   347     apply auto
   348     done
   349   also have "\<dots> \<in> prod_algebra I M"
   350     using A B by (auto intro!: prod_algebraI)
   351   finally show "A \<inter> B \<in> prod_algebra I M" .
   352 qed
   353 
   354 lemma prod_algebra_mono:
   355   assumes space: "\<And>i. i \<in> I \<Longrightarrow> space (E i) = space (F i)"
   356   assumes sets: "\<And>i. i \<in> I \<Longrightarrow> sets (E i) \<subseteq> sets (F i)"
   357   shows "prod_algebra I E \<subseteq> prod_algebra I F"
   358 proof
   359   fix A assume "A \<in> prod_algebra I E"
   360   then obtain J G where J: "J \<noteq> {} \<or> I = {}" "finite J" "J \<subseteq> I"
   361     and A: "A = prod_emb I E J (\<Pi>\<^isub>E i\<in>J. G i)"
   362     and G: "\<And>i. i \<in> J \<Longrightarrow> G i \<in> sets (E i)"
   363     by (auto simp: prod_algebra_def)
   364   moreover
   365   from space have "(\<Pi>\<^isub>E i\<in>I. space (E i)) = (\<Pi>\<^isub>E i\<in>I. space (F i))"
   366     by (rule PiE_cong)
   367   with A have "A = prod_emb I F J (\<Pi>\<^isub>E i\<in>J. G i)"
   368     by (simp add: prod_emb_def)
   369   moreover
   370   from sets G J have "\<And>i. i \<in> J \<Longrightarrow> G i \<in> sets (F i)"
   371     by auto
   372   ultimately show "A \<in> prod_algebra I F"
   373     apply (simp add: prod_algebra_def image_iff)
   374     apply (intro exI[of _ J] exI[of _ G] conjI)
   375     apply auto
   376     done
   377 qed
   378 
   379 lemma space_PiM: "space (\<Pi>\<^isub>M i\<in>I. M i) = (\<Pi>\<^isub>E i\<in>I. space (M i))"
   380   using prod_algebra_sets_into_space unfolding PiM_def prod_algebra_def by (intro space_extend_measure) simp
   381 
   382 lemma sets_PiM: "sets (\<Pi>\<^isub>M i\<in>I. M i) = sigma_sets (\<Pi>\<^isub>E i\<in>I. space (M i)) (prod_algebra I M)"
   383   using prod_algebra_sets_into_space unfolding PiM_def prod_algebra_def by (intro sets_extend_measure) simp
   384 
   385 lemma sets_PiM_single: "sets (PiM I M) =
   386     sigma_sets (\<Pi>\<^isub>E i\<in>I. space (M i)) {{f\<in>\<Pi>\<^isub>E i\<in>I. space (M i). f i \<in> A} | i A. i \<in> I \<and> A \<in> sets (M i)}"
   387     (is "_ = sigma_sets ?\<Omega> ?R")
   388   unfolding sets_PiM
   389 proof (rule sigma_sets_eqI)
   390   interpret R: sigma_algebra ?\<Omega> "sigma_sets ?\<Omega> ?R" by (rule sigma_algebra_sigma_sets) auto
   391   fix A assume "A \<in> prod_algebra I M"
   392   from prod_algebraE[OF this] guess J X . note X = this
   393   show "A \<in> sigma_sets ?\<Omega> ?R"
   394   proof cases
   395     assume "I = {}"
   396     with X have "A = {\<lambda>x. undefined}" by (auto simp: prod_emb_def)
   397     with `I = {}` show ?thesis by (auto intro!: sigma_sets_top)
   398   next
   399     assume "I \<noteq> {}"
   400     with X have "A = (\<Inter>j\<in>J. {f\<in>(\<Pi>\<^isub>E i\<in>I. space (M i)). f j \<in> X j})"
   401       using sets_into_space[OF X(5)]
   402       by (auto simp: prod_emb_PiE[OF _ sets_into_space] Pi_iff split: split_if_asm) blast
   403     also have "\<dots> \<in> sigma_sets ?\<Omega> ?R"
   404       using X `I \<noteq> {}` by (intro R.finite_INT sigma_sets.Basic) auto
   405     finally show "A \<in> sigma_sets ?\<Omega> ?R" .
   406   qed
   407 next
   408   fix A assume "A \<in> ?R"
   409   then obtain i B where A: "A = {f\<in>\<Pi>\<^isub>E i\<in>I. space (M i). f i \<in> B}" "i \<in> I" "B \<in> sets (M i)" 
   410     by auto
   411   then have "A = prod_emb I M {i} (\<Pi>\<^isub>E i\<in>{i}. B)"
   412     using sets_into_space[OF A(3)]
   413     apply (subst prod_emb_PiE)
   414     apply (auto simp: Pi_iff split: split_if_asm)
   415     apply blast
   416     done
   417   also have "\<dots> \<in> sigma_sets ?\<Omega> (prod_algebra I M)"
   418     using A by (intro sigma_sets.Basic prod_algebraI) auto
   419   finally show "A \<in> sigma_sets ?\<Omega> (prod_algebra I M)" .
   420 qed
   421 
   422 lemma sets_PiM_I:
   423   assumes "finite J" "J \<subseteq> I" "\<forall>i\<in>J. E i \<in> sets (M i)"
   424   shows "prod_emb I M J (PIE j:J. E j) \<in> sets (PIM i:I. M i)"
   425 proof cases
   426   assume "J = {}"
   427   then have "prod_emb I M J (PIE j:J. E j) = (PIE j:I. space (M j))"
   428     by (auto simp: prod_emb_def)
   429   then show ?thesis
   430     by (auto simp add: sets_PiM intro!: sigma_sets_top)
   431 next
   432   assume "J \<noteq> {}" with assms show ?thesis
   433     by (auto simp add: sets_PiM prod_algebra_def intro!: sigma_sets.Basic)
   434 qed
   435 
   436 lemma measurable_PiM:
   437   assumes space: "f \<in> space N \<rightarrow> (\<Pi>\<^isub>E i\<in>I. space (M i))"
   438   assumes sets: "\<And>X J. J \<noteq> {} \<or> I = {} \<Longrightarrow> finite J \<Longrightarrow> J \<subseteq> I \<Longrightarrow> (\<And>i. i \<in> J \<Longrightarrow> X i \<in> sets (M i)) \<Longrightarrow>
   439     f -` prod_emb I M J (Pi\<^isub>E J X) \<inter> space N \<in> sets N" 
   440   shows "f \<in> measurable N (PiM I M)"
   441   using sets_PiM prod_algebra_sets_into_space space
   442 proof (rule measurable_sigma_sets)
   443   fix A assume "A \<in> prod_algebra I M"
   444   from prod_algebraE[OF this] guess J X .
   445   with sets[of J X] show "f -` A \<inter> space N \<in> sets N" by auto
   446 qed
   447 
   448 lemma measurable_PiM_Collect:
   449   assumes space: "f \<in> space N \<rightarrow> (\<Pi>\<^isub>E i\<in>I. space (M i))"
   450   assumes sets: "\<And>X J. J \<noteq> {} \<or> I = {} \<Longrightarrow> finite J \<Longrightarrow> J \<subseteq> I \<Longrightarrow> (\<And>i. i \<in> J \<Longrightarrow> X i \<in> sets (M i)) \<Longrightarrow>
   451     {\<omega>\<in>space N. \<forall>i\<in>J. f \<omega> i \<in> X i} \<in> sets N" 
   452   shows "f \<in> measurable N (PiM I M)"
   453   using sets_PiM prod_algebra_sets_into_space space
   454 proof (rule measurable_sigma_sets)
   455   fix A assume "A \<in> prod_algebra I M"
   456   from prod_algebraE[OF this] guess J X . note X = this
   457   have "f -` A \<inter> space N = {\<omega> \<in> space N. \<forall>i\<in>J. f \<omega> i \<in> X i}"
   458     using sets_into_space[OF X(5)] X(2-) space unfolding X(1)
   459     by (subst prod_emb_PiE) (auto simp: Pi_iff split: split_if_asm)
   460   also have "\<dots> \<in> sets N" using X(3,2,4,5) by (rule sets)
   461   finally show "f -` A \<inter> space N \<in> sets N" .
   462 qed
   463 
   464 lemma measurable_PiM_single:
   465   assumes space: "f \<in> space N \<rightarrow> (\<Pi>\<^isub>E i\<in>I. space (M i))"
   466   assumes sets: "\<And>A i. i \<in> I \<Longrightarrow> A \<in> sets (M i) \<Longrightarrow> {\<omega> \<in> space N. f \<omega> i \<in> A} \<in> sets N" 
   467   shows "f \<in> measurable N (PiM I M)"
   468   using sets_PiM_single
   469 proof (rule measurable_sigma_sets)
   470   fix A assume "A \<in> {{f \<in> \<Pi>\<^isub>E i\<in>I. space (M i). f i \<in> A} |i A. i \<in> I \<and> A \<in> sets (M i)}"
   471   then obtain B i where "A = {f \<in> \<Pi>\<^isub>E i\<in>I. space (M i). f i \<in> B}" and B: "i \<in> I" "B \<in> sets (M i)"
   472     by auto
   473   with space have "f -` A \<inter> space N = {\<omega> \<in> space N. f \<omega> i \<in> B}" by auto
   474   also have "\<dots> \<in> sets N" using B by (rule sets)
   475   finally show "f -` A \<inter> space N \<in> sets N" .
   476 qed (auto simp: space)
   477 
   478 lemma sets_PiM_I_finite[simp, intro]:
   479   assumes "finite I" and sets: "(\<And>i. i \<in> I \<Longrightarrow> E i \<in> sets (M i))"
   480   shows "(PIE j:I. E j) \<in> sets (PIM i:I. M i)"
   481   using sets_PiM_I[of I I E M] sets_into_space[OF sets] `finite I` sets by auto
   482 
   483 lemma measurable_component_update:
   484   assumes "x \<in> space (Pi\<^isub>M I M)" and "i \<notin> I"
   485   shows "(\<lambda>v. x(i := v)) \<in> measurable (M i) (Pi\<^isub>M (insert i I) M)" (is "?f \<in> _")
   486 proof (intro measurable_PiM_single)
   487   fix j A assume "j \<in> insert i I" "A \<in> sets (M j)"
   488   moreover have "{\<omega> \<in> space (M i). (x(i := \<omega>)) j \<in> A} =
   489     (if i = j then space (M i) \<inter> A else if x j \<in> A then space (M i) else {})"
   490     by auto
   491   ultimately show "{\<omega> \<in> space (M i). (x(i := \<omega>)) j \<in> A} \<in> sets (M i)"
   492     by auto
   493 qed (insert sets_into_space assms, auto simp: space_PiM)
   494 
   495 lemma measurable_component_singleton:
   496   assumes "i \<in> I" shows "(\<lambda>x. x i) \<in> measurable (Pi\<^isub>M I M) (M i)"
   497 proof (unfold measurable_def, intro CollectI conjI ballI)
   498   fix A assume "A \<in> sets (M i)"
   499   then have "(\<lambda>x. x i) -` A \<inter> space (Pi\<^isub>M I M) = prod_emb I M {i} (\<Pi>\<^isub>E j\<in>{i}. A)"
   500     using sets_into_space `i \<in> I`
   501     by (fastforce dest: Pi_mem simp: prod_emb_def space_PiM split: split_if_asm)
   502   then show "(\<lambda>x. x i) -` A \<inter> space (Pi\<^isub>M I M) \<in> sets (Pi\<^isub>M I M)"
   503     using `A \<in> sets (M i)` `i \<in> I` by (auto intro!: sets_PiM_I)
   504 qed (insert `i \<in> I`, auto simp: space_PiM)
   505 
   506 lemma measurable_add_dim:
   507   "(\<lambda>(f, y). f(i := y)) \<in> measurable (Pi\<^isub>M I M \<Otimes>\<^isub>M M i) (Pi\<^isub>M (insert i I) M)"
   508     (is "?f \<in> measurable ?P ?I")
   509 proof (rule measurable_PiM_single)
   510   fix j A assume j: "j \<in> insert i I" and A: "A \<in> sets (M j)"
   511   have "{\<omega> \<in> space ?P. (\<lambda>(f, x). fun_upd f i x) \<omega> j \<in> A} =
   512     (if j = i then space (Pi\<^isub>M I M) \<times> A else ((\<lambda>x. x j) \<circ> fst) -` A \<inter> space ?P)"
   513     using sets_into_space[OF A] by (auto simp add: space_pair_measure space_PiM)
   514   also have "\<dots> \<in> sets ?P"
   515     using A j
   516     by (auto intro!: measurable_sets[OF measurable_comp, OF _ measurable_component_singleton])
   517   finally show "{\<omega> \<in> space ?P. prod_case (\<lambda>f. fun_upd f i) \<omega> j \<in> A} \<in> sets ?P" .
   518 qed (auto simp: space_pair_measure space_PiM)
   519 
   520 lemma measurable_merge:
   521   "merge I J \<in> measurable (Pi\<^isub>M I M \<Otimes>\<^isub>M Pi\<^isub>M J M) (Pi\<^isub>M (I \<union> J) M)"
   522     (is "?f \<in> measurable ?P ?U")
   523 proof (rule measurable_PiM_single)
   524   fix i A assume A: "A \<in> sets (M i)" "i \<in> I \<union> J"
   525   then have "{\<omega> \<in> space ?P. merge I J \<omega> i \<in> A} =
   526     (if i \<in> I then ((\<lambda>x. x i) \<circ> fst) -` A \<inter> space ?P else ((\<lambda>x. x i) \<circ> snd) -` A \<inter> space ?P)"
   527     by (auto simp: merge_def)
   528   also have "\<dots> \<in> sets ?P"
   529     using A
   530     by (auto intro!: measurable_sets[OF measurable_comp, OF _ measurable_component_singleton])
   531   finally show "{\<omega> \<in> space ?P. merge I J \<omega> i \<in> A} \<in> sets ?P" .
   532 qed (auto simp: space_pair_measure space_PiM Pi_iff merge_def extensional_def)
   533 
   534 lemma measurable_restrict:
   535   assumes X: "\<And>i. i \<in> I \<Longrightarrow> X i \<in> measurable N (M i)"
   536   shows "(\<lambda>x. \<lambda>i\<in>I. X i x) \<in> measurable N (Pi\<^isub>M I M)"
   537 proof (rule measurable_PiM_single)
   538   fix A i assume A: "i \<in> I" "A \<in> sets (M i)"
   539   then have "{\<omega> \<in> space N. (\<lambda>i\<in>I. X i \<omega>) i \<in> A} = X i -` A \<inter> space N"
   540     by auto
   541   then show "{\<omega> \<in> space N. (\<lambda>i\<in>I. X i \<omega>) i \<in> A} \<in> sets N"
   542     using A X by (auto intro!: measurable_sets)
   543 qed (insert X, auto dest: measurable_space)
   544 
   545 locale product_sigma_finite =
   546   fixes M :: "'i \<Rightarrow> 'a measure"
   547   assumes sigma_finite_measures: "\<And>i. sigma_finite_measure (M i)"
   548 
   549 sublocale product_sigma_finite \<subseteq> M: sigma_finite_measure "M i" for i
   550   by (rule sigma_finite_measures)
   551 
   552 locale finite_product_sigma_finite = product_sigma_finite M for M :: "'i \<Rightarrow> 'a measure" +
   553   fixes I :: "'i set"
   554   assumes finite_index: "finite I"
   555 
   556 lemma (in finite_product_sigma_finite) sigma_finite_pairs:
   557   "\<exists>F::'i \<Rightarrow> nat \<Rightarrow> 'a set.
   558     (\<forall>i\<in>I. range (F i) \<subseteq> sets (M i)) \<and>
   559     (\<forall>k. \<forall>i\<in>I. emeasure (M i) (F i k) \<noteq> \<infinity>) \<and> incseq (\<lambda>k. \<Pi>\<^isub>E i\<in>I. F i k) \<and>
   560     (\<Union>k. \<Pi>\<^isub>E i\<in>I. F i k) = space (PiM I M)"
   561 proof -
   562   have "\<forall>i::'i. \<exists>F::nat \<Rightarrow> 'a set. range F \<subseteq> sets (M i) \<and> incseq F \<and> (\<Union>i. F i) = space (M i) \<and> (\<forall>k. emeasure (M i) (F k) \<noteq> \<infinity>)"
   563     using M.sigma_finite_incseq by metis
   564   from choice[OF this] guess F :: "'i \<Rightarrow> nat \<Rightarrow> 'a set" ..
   565   then have F: "\<And>i. range (F i) \<subseteq> sets (M i)" "\<And>i. incseq (F i)" "\<And>i. (\<Union>j. F i j) = space (M i)" "\<And>i k. emeasure (M i) (F i k) \<noteq> \<infinity>"
   566     by auto
   567   let ?F = "\<lambda>k. \<Pi>\<^isub>E i\<in>I. F i k"
   568   note space_PiM[simp]
   569   show ?thesis
   570   proof (intro exI[of _ F] conjI allI incseq_SucI set_eqI iffI ballI)
   571     fix i show "range (F i) \<subseteq> sets (M i)" by fact
   572   next
   573     fix i k show "emeasure (M i) (F i k) \<noteq> \<infinity>" by fact
   574   next
   575     fix A assume "A \<in> (\<Union>i. ?F i)" then show "A \<in> space (PiM I M)"
   576       using `\<And>i. range (F i) \<subseteq> sets (M i)` sets_into_space
   577       by auto blast
   578   next
   579     fix f assume "f \<in> space (PiM I M)"
   580     with Pi_UN[OF finite_index, of "\<lambda>k i. F i k"] F
   581     show "f \<in> (\<Union>i. ?F i)" by (auto simp: incseq_def)
   582   next
   583     fix i show "?F i \<subseteq> ?F (Suc i)"
   584       using `\<And>i. incseq (F i)`[THEN incseq_SucD] by auto
   585   qed
   586 qed
   587 
   588 lemma
   589   shows space_PiM_empty: "space (Pi\<^isub>M {} M) = {\<lambda>k. undefined}"
   590     and sets_PiM_empty: "sets (Pi\<^isub>M {} M) = { {}, {\<lambda>k. undefined} }"
   591   by (simp_all add: space_PiM sets_PiM_single image_constant sigma_sets_empty_eq)
   592 
   593 lemma emeasure_PiM_empty[simp]: "emeasure (PiM {} M) {\<lambda>_. undefined} = 1"
   594 proof -
   595   let ?\<mu> = "\<lambda>A. if A = {} then 0 else (1::ereal)"
   596   have "emeasure (Pi\<^isub>M {} M) (prod_emb {} M {} (\<Pi>\<^isub>E i\<in>{}. {})) = 1"
   597   proof (subst emeasure_extend_measure_Pair[OF PiM_def])
   598     show "positive (PiM {} M) ?\<mu>"
   599       by (auto simp: positive_def)
   600     show "countably_additive (PiM {} M) ?\<mu>"
   601       by (rule countably_additiveI_finite)
   602          (auto simp: additive_def positive_def sets_PiM_empty space_PiM_empty intro!: )
   603   qed (auto simp: prod_emb_def)
   604   also have "(prod_emb {} M {} (\<Pi>\<^isub>E i\<in>{}. {})) = {\<lambda>_. undefined}"
   605     by (auto simp: prod_emb_def)
   606   finally show ?thesis
   607     by simp
   608 qed
   609 
   610 lemma PiM_empty: "PiM {} M = count_space {\<lambda>_. undefined}"
   611   by (rule measure_eqI) (auto simp add: sets_PiM_empty one_ereal_def)
   612 
   613 lemma (in product_sigma_finite) emeasure_PiM:
   614   "finite I \<Longrightarrow> (\<And>i. i\<in>I \<Longrightarrow> A i \<in> sets (M i)) \<Longrightarrow> emeasure (PiM I M) (Pi\<^isub>E I A) = (\<Prod>i\<in>I. emeasure (M i) (A i))"
   615 proof (induct I arbitrary: A rule: finite_induct)
   616   case (insert i I)
   617   interpret finite_product_sigma_finite M I by default fact
   618   have "finite (insert i I)" using `finite I` by auto
   619   interpret I': finite_product_sigma_finite M "insert i I" by default fact
   620   let ?h = "(\<lambda>(f, y). f(i := y))"
   621 
   622   let ?P = "distr (Pi\<^isub>M I M \<Otimes>\<^isub>M M i) (Pi\<^isub>M (insert i I) M) ?h"
   623   let ?\<mu> = "emeasure ?P"
   624   let ?I = "{j \<in> insert i I. emeasure (M j) (space (M j)) \<noteq> 1}"
   625   let ?f = "\<lambda>J E j. if j \<in> J then emeasure (M j) (E j) else emeasure (M j) (space (M j))"
   626 
   627   have "emeasure (Pi\<^isub>M (insert i I) M) (prod_emb (insert i I) M (insert i I) (Pi\<^isub>E (insert i I) A)) =
   628     (\<Prod>i\<in>insert i I. emeasure (M i) (A i))"
   629   proof (subst emeasure_extend_measure_Pair[OF PiM_def])
   630     fix J E assume "(J \<noteq> {} \<or> insert i I = {}) \<and> finite J \<and> J \<subseteq> insert i I \<and> E \<in> (\<Pi> j\<in>J. sets (M j))"
   631     then have J: "J \<noteq> {}" "finite J" "J \<subseteq> insert i I" and E: "\<forall>j\<in>J. E j \<in> sets (M j)" by auto
   632     let ?p = "prod_emb (insert i I) M J (Pi\<^isub>E J E)"
   633     let ?p' = "prod_emb I M (J - {i}) (\<Pi>\<^isub>E j\<in>J-{i}. E j)"
   634     have "?\<mu> ?p =
   635       emeasure (Pi\<^isub>M I M \<Otimes>\<^isub>M (M i)) (?h -` ?p \<inter> space (Pi\<^isub>M I M \<Otimes>\<^isub>M M i))"
   636       by (intro emeasure_distr measurable_add_dim sets_PiM_I) fact+
   637     also have "?h -` ?p \<inter> space (Pi\<^isub>M I M \<Otimes>\<^isub>M M i) = ?p' \<times> (if i \<in> J then E i else space (M i))"
   638       using J E[rule_format, THEN sets_into_space]
   639       by (force simp: space_pair_measure space_PiM Pi_iff prod_emb_iff split: split_if_asm)
   640     also have "emeasure (Pi\<^isub>M I M \<Otimes>\<^isub>M (M i)) (?p' \<times> (if i \<in> J then E i else space (M i))) =
   641       emeasure (Pi\<^isub>M I M) ?p' * emeasure (M i) (if i \<in> J then (E i) else space (M i))"
   642       using J E by (intro M.emeasure_pair_measure_Times sets_PiM_I) auto
   643     also have "?p' = (\<Pi>\<^isub>E j\<in>I. if j \<in> J-{i} then E j else space (M j))"
   644       using J E[rule_format, THEN sets_into_space]
   645       by (auto simp: prod_emb_iff Pi_iff split: split_if_asm) blast+
   646     also have "emeasure (Pi\<^isub>M I M) (\<Pi>\<^isub>E j\<in>I. if j \<in> J-{i} then E j else space (M j)) =
   647       (\<Prod> j\<in>I. if j \<in> J-{i} then emeasure (M j) (E j) else emeasure (M j) (space (M j)))"
   648       using E by (subst insert) (auto intro!: setprod_cong)
   649     also have "(\<Prod>j\<in>I. if j \<in> J - {i} then emeasure (M j) (E j) else emeasure (M j) (space (M j))) *
   650        emeasure (M i) (if i \<in> J then E i else space (M i)) = (\<Prod>j\<in>insert i I. ?f J E j)"
   651       using insert by (auto simp: mult_commute intro!: arg_cong2[where f="op *"] setprod_cong)
   652     also have "\<dots> = (\<Prod>j\<in>J \<union> ?I. ?f J E j)"
   653       using insert(1,2) J E by (intro setprod_mono_one_right) auto
   654     finally show "?\<mu> ?p = \<dots>" .
   655 
   656     show "prod_emb (insert i I) M J (Pi\<^isub>E J E) \<in> Pow (\<Pi>\<^isub>E i\<in>insert i I. space (M i))"
   657       using J E[rule_format, THEN sets_into_space] by (auto simp: prod_emb_iff)
   658   next
   659     show "positive (sets (Pi\<^isub>M (insert i I) M)) ?\<mu>" "countably_additive (sets (Pi\<^isub>M (insert i I) M)) ?\<mu>"
   660       using emeasure_positive[of ?P] emeasure_countably_additive[of ?P] by simp_all
   661   next
   662     show "(insert i I \<noteq> {} \<or> insert i I = {}) \<and> finite (insert i I) \<and>
   663       insert i I \<subseteq> insert i I \<and> A \<in> (\<Pi> j\<in>insert i I. sets (M j))"
   664       using insert by auto
   665   qed (auto intro!: setprod_cong)
   666   with insert show ?case
   667     by (subst (asm) prod_emb_PiE_same_index) (auto intro!: sets_into_space)
   668 qed (simp add: emeasure_PiM_empty)
   669 
   670 lemma (in product_sigma_finite) sigma_finite: 
   671   assumes "finite I"
   672   shows "sigma_finite_measure (PiM I M)"
   673 proof -
   674   interpret finite_product_sigma_finite M I by default fact
   675 
   676   from sigma_finite_pairs guess F :: "'i \<Rightarrow> nat \<Rightarrow> 'a set" ..
   677   then have F: "\<And>j. j \<in> I \<Longrightarrow> range (F j) \<subseteq> sets (M j)"
   678     "incseq (\<lambda>k. \<Pi>\<^isub>E j \<in> I. F j k)"
   679     "(\<Union>k. \<Pi>\<^isub>E j \<in> I. F j k) = space (Pi\<^isub>M I M)"
   680     "\<And>k. \<And>j. j \<in> I \<Longrightarrow> emeasure (M j) (F j k) \<noteq> \<infinity>"
   681     by blast+
   682   let ?F = "\<lambda>k. \<Pi>\<^isub>E j \<in> I. F j k"
   683 
   684   show ?thesis
   685   proof (unfold_locales, intro exI[of _ ?F] conjI allI)
   686     show "range ?F \<subseteq> sets (Pi\<^isub>M I M)" using F(1) `finite I` by auto
   687   next
   688     from F(3) show "(\<Union>i. ?F i) = space (Pi\<^isub>M I M)" by simp
   689   next
   690     fix j
   691     from F `finite I` setprod_PInf[of I, OF emeasure_nonneg, of M]
   692     show "emeasure (\<Pi>\<^isub>M i\<in>I. M i) (?F j) \<noteq> \<infinity>"
   693       by (subst emeasure_PiM) auto
   694   qed
   695 qed
   696 
   697 sublocale finite_product_sigma_finite \<subseteq> sigma_finite_measure "Pi\<^isub>M I M"
   698   using sigma_finite[OF finite_index] .
   699 
   700 lemma (in finite_product_sigma_finite) measure_times:
   701   "(\<And>i. i \<in> I \<Longrightarrow> A i \<in> sets (M i)) \<Longrightarrow> emeasure (Pi\<^isub>M I M) (Pi\<^isub>E I A) = (\<Prod>i\<in>I. emeasure (M i) (A i))"
   702   using emeasure_PiM[OF finite_index] by auto
   703 
   704 lemma (in product_sigma_finite) positive_integral_empty:
   705   assumes pos: "0 \<le> f (\<lambda>k. undefined)"
   706   shows "integral\<^isup>P (Pi\<^isub>M {} M) f = f (\<lambda>k. undefined)"
   707 proof -
   708   interpret finite_product_sigma_finite M "{}" by default (fact finite.emptyI)
   709   have "\<And>A. emeasure (Pi\<^isub>M {} M) (Pi\<^isub>E {} A) = 1"
   710     using assms by (subst measure_times) auto
   711   then show ?thesis
   712     unfolding positive_integral_def simple_function_def simple_integral_def[abs_def]
   713   proof (simp add: space_PiM_empty sets_PiM_empty, intro antisym)
   714     show "f (\<lambda>k. undefined) \<le> (SUP f:{g. g \<le> max 0 \<circ> f}. f (\<lambda>k. undefined))"
   715       by (intro SUP_upper) (auto simp: le_fun_def split: split_max)
   716     show "(SUP f:{g. g \<le> max 0 \<circ> f}. f (\<lambda>k. undefined)) \<le> f (\<lambda>k. undefined)" using pos
   717       by (intro SUP_least) (auto simp: le_fun_def simp: max_def split: split_if_asm)
   718   qed
   719 qed
   720 
   721 lemma (in product_sigma_finite) distr_merge:
   722   assumes IJ[simp]: "I \<inter> J = {}" and fin: "finite I" "finite J"
   723   shows "distr (Pi\<^isub>M I M \<Otimes>\<^isub>M Pi\<^isub>M J M) (Pi\<^isub>M (I \<union> J) M) (merge I J) = Pi\<^isub>M (I \<union> J) M"
   724    (is "?D = ?P")
   725 proof -
   726   interpret I: finite_product_sigma_finite M I by default fact
   727   interpret J: finite_product_sigma_finite M J by default fact
   728   have "finite (I \<union> J)" using fin by auto
   729   interpret IJ: finite_product_sigma_finite M "I \<union> J" by default fact
   730   interpret P: pair_sigma_finite "Pi\<^isub>M I M" "Pi\<^isub>M J M" by default
   731   let ?g = "merge I J"
   732 
   733   from IJ.sigma_finite_pairs obtain F where
   734     F: "\<And>i. i\<in> I \<union> J \<Longrightarrow> range (F i) \<subseteq> sets (M i)"
   735        "incseq (\<lambda>k. \<Pi>\<^isub>E i\<in>I \<union> J. F i k)"
   736        "(\<Union>k. \<Pi>\<^isub>E i\<in>I \<union> J. F i k) = space ?P"
   737        "\<And>k. \<forall>i\<in>I\<union>J. emeasure (M i) (F i k) \<noteq> \<infinity>"
   738     by auto
   739   let ?F = "\<lambda>k. \<Pi>\<^isub>E i\<in>I \<union> J. F i k"
   740   
   741   show ?thesis
   742   proof (rule measure_eqI_generator_eq[symmetric])
   743     show "Int_stable (prod_algebra (I \<union> J) M)"
   744       by (rule Int_stable_prod_algebra)
   745     show "prod_algebra (I \<union> J) M \<subseteq> Pow (\<Pi>\<^isub>E i \<in> I \<union> J. space (M i))"
   746       by (rule prod_algebra_sets_into_space)
   747     show "sets ?P = sigma_sets (\<Pi>\<^isub>E i\<in>I \<union> J. space (M i)) (prod_algebra (I \<union> J) M)"
   748       by (rule sets_PiM)
   749     then show "sets ?D = sigma_sets (\<Pi>\<^isub>E i\<in>I \<union> J. space (M i)) (prod_algebra (I \<union> J) M)"
   750       by simp
   751 
   752     show "range ?F \<subseteq> prod_algebra (I \<union> J) M" using F
   753       using fin by (auto simp: prod_algebra_eq_finite)
   754     show "(\<Union>i. \<Pi>\<^isub>E ia\<in>I \<union> J. F ia i) = (\<Pi>\<^isub>E i\<in>I \<union> J. space (M i))"
   755       using F(3) by (simp add: space_PiM)
   756   next
   757     fix k
   758     from F `finite I` setprod_PInf[of "I \<union> J", OF emeasure_nonneg, of M]
   759     show "emeasure ?P (?F k) \<noteq> \<infinity>" by (subst IJ.measure_times) auto
   760   next
   761     fix A assume A: "A \<in> prod_algebra (I \<union> J) M"
   762     with fin obtain F where A_eq: "A = (Pi\<^isub>E (I \<union> J) F)" and F: "\<forall>i\<in>I \<union> J. F i \<in> sets (M i)"
   763       by (auto simp add: prod_algebra_eq_finite)
   764     let ?B = "Pi\<^isub>M I M \<Otimes>\<^isub>M Pi\<^isub>M J M"
   765     let ?X = "?g -` A \<inter> space ?B"
   766     have "Pi\<^isub>E I F \<subseteq> space (Pi\<^isub>M I M)" "Pi\<^isub>E J F \<subseteq> space (Pi\<^isub>M J M)"
   767       using F[rule_format, THEN sets_into_space] by (auto simp: space_PiM)
   768     then have X: "?X = (Pi\<^isub>E I F \<times> Pi\<^isub>E J F)"
   769       unfolding A_eq by (subst merge_vimage) (auto simp: space_pair_measure space_PiM)
   770     have "emeasure ?D A = emeasure ?B ?X"
   771       using A by (intro emeasure_distr measurable_merge) (auto simp: sets_PiM)
   772     also have "emeasure ?B ?X = (\<Prod>i\<in>I. emeasure (M i) (F i)) * (\<Prod>i\<in>J. emeasure (M i) (F i))"
   773       using `finite J` `finite I` F X
   774       by (simp add: J.emeasure_pair_measure_Times I.measure_times J.measure_times Pi_iff)
   775     also have "\<dots> = (\<Prod>i\<in>I \<union> J. emeasure (M i) (F i))"
   776       using `finite J` `finite I` `I \<inter> J = {}`  by (simp add: setprod_Un_one)
   777     also have "\<dots> = emeasure ?P (Pi\<^isub>E (I \<union> J) F)"
   778       using `finite J` `finite I` F unfolding A
   779       by (intro IJ.measure_times[symmetric]) auto
   780     finally show "emeasure ?P A = emeasure ?D A" using A_eq by simp
   781   qed
   782 qed
   783 
   784 lemma (in product_sigma_finite) product_positive_integral_fold:
   785   assumes IJ: "I \<inter> J = {}" "finite I" "finite J"
   786   and f: "f \<in> borel_measurable (Pi\<^isub>M (I \<union> J) M)"
   787   shows "integral\<^isup>P (Pi\<^isub>M (I \<union> J) M) f =
   788     (\<integral>\<^isup>+ x. (\<integral>\<^isup>+ y. f (merge I J (x, y)) \<partial>(Pi\<^isub>M J M)) \<partial>(Pi\<^isub>M I M))"
   789 proof -
   790   interpret I: finite_product_sigma_finite M I by default fact
   791   interpret J: finite_product_sigma_finite M J by default fact
   792   interpret P: pair_sigma_finite "Pi\<^isub>M I M" "Pi\<^isub>M J M" by default
   793   have P_borel: "(\<lambda>x. f (merge I J x)) \<in> borel_measurable (Pi\<^isub>M I M \<Otimes>\<^isub>M Pi\<^isub>M J M)"
   794     using measurable_comp[OF measurable_merge f] by (simp add: comp_def)
   795   show ?thesis
   796     apply (subst distr_merge[OF IJ, symmetric])
   797     apply (subst positive_integral_distr[OF measurable_merge f])
   798     apply (subst J.positive_integral_fst_measurable(2)[symmetric, OF P_borel])
   799     apply simp
   800     done
   801 qed
   802 
   803 lemma (in product_sigma_finite) distr_singleton:
   804   "distr (Pi\<^isub>M {i} M) (M i) (\<lambda>x. x i) = M i" (is "?D = _")
   805 proof (intro measure_eqI[symmetric])
   806   interpret I: finite_product_sigma_finite M "{i}" by default simp
   807   fix A assume A: "A \<in> sets (M i)"
   808   moreover then have "(\<lambda>x. x i) -` A \<inter> space (Pi\<^isub>M {i} M) = (\<Pi>\<^isub>E i\<in>{i}. A)"
   809     using sets_into_space by (auto simp: space_PiM)
   810   ultimately show "emeasure (M i) A = emeasure ?D A"
   811     using A I.measure_times[of "\<lambda>_. A"]
   812     by (simp add: emeasure_distr measurable_component_singleton)
   813 qed simp
   814 
   815 lemma (in product_sigma_finite) product_positive_integral_singleton:
   816   assumes f: "f \<in> borel_measurable (M i)"
   817   shows "integral\<^isup>P (Pi\<^isub>M {i} M) (\<lambda>x. f (x i)) = integral\<^isup>P (M i) f"
   818 proof -
   819   interpret I: finite_product_sigma_finite M "{i}" by default simp
   820   from f show ?thesis
   821     apply (subst distr_singleton[symmetric])
   822     apply (subst positive_integral_distr[OF measurable_component_singleton])
   823     apply simp_all
   824     done
   825 qed
   826 
   827 lemma (in product_sigma_finite) product_positive_integral_insert:
   828   assumes I[simp]: "finite I" "i \<notin> I"
   829     and f: "f \<in> borel_measurable (Pi\<^isub>M (insert i I) M)"
   830   shows "integral\<^isup>P (Pi\<^isub>M (insert i I) M) f = (\<integral>\<^isup>+ x. (\<integral>\<^isup>+ y. f (x(i := y)) \<partial>(M i)) \<partial>(Pi\<^isub>M I M))"
   831 proof -
   832   interpret I: finite_product_sigma_finite M I by default auto
   833   interpret i: finite_product_sigma_finite M "{i}" by default auto
   834   have IJ: "I \<inter> {i} = {}" and insert: "I \<union> {i} = insert i I"
   835     using f by auto
   836   show ?thesis
   837     unfolding product_positive_integral_fold[OF IJ, unfolded insert, OF I(1) i.finite_index f]
   838   proof (rule positive_integral_cong, subst product_positive_integral_singleton[symmetric])
   839     fix x assume x: "x \<in> space (Pi\<^isub>M I M)"
   840     let ?f = "\<lambda>y. f (x(i := y))"
   841     show "?f \<in> borel_measurable (M i)"
   842       using measurable_comp[OF measurable_component_update f, OF x `i \<notin> I`]
   843       unfolding comp_def .
   844     show "(\<integral>\<^isup>+ y. f (merge I {i} (x, y)) \<partial>Pi\<^isub>M {i} M) = (\<integral>\<^isup>+ y. f (x(i := y i)) \<partial>Pi\<^isub>M {i} M)"
   845       using x
   846       by (auto intro!: positive_integral_cong arg_cong[where f=f]
   847                simp add: space_PiM extensional_def)
   848   qed
   849 qed
   850 
   851 lemma (in product_sigma_finite) product_positive_integral_setprod:
   852   fixes f :: "'i \<Rightarrow> 'a \<Rightarrow> ereal"
   853   assumes "finite I" and borel: "\<And>i. i \<in> I \<Longrightarrow> f i \<in> borel_measurable (M i)"
   854   and pos: "\<And>i x. i \<in> I \<Longrightarrow> 0 \<le> f i x"
   855   shows "(\<integral>\<^isup>+ x. (\<Prod>i\<in>I. f i (x i)) \<partial>Pi\<^isub>M I M) = (\<Prod>i\<in>I. integral\<^isup>P (M i) (f i))"
   856 using assms proof induct
   857   case (insert i I)
   858   note `finite I`[intro, simp]
   859   interpret I: finite_product_sigma_finite M I by default auto
   860   have *: "\<And>x y. (\<Prod>j\<in>I. f j (if j = i then y else x j)) = (\<Prod>j\<in>I. f j (x j))"
   861     using insert by (auto intro!: setprod_cong)
   862   have prod: "\<And>J. J \<subseteq> insert i I \<Longrightarrow> (\<lambda>x. (\<Prod>i\<in>J. f i (x i))) \<in> borel_measurable (Pi\<^isub>M J M)"
   863     using sets_into_space insert
   864     by (intro borel_measurable_ereal_setprod
   865               measurable_comp[OF measurable_component_singleton, unfolded comp_def])
   866        auto
   867   then show ?case
   868     apply (simp add: product_positive_integral_insert[OF insert(1,2) prod])
   869     apply (simp add: insert(2-) * pos borel setprod_ereal_pos positive_integral_multc)
   870     apply (subst positive_integral_cmult)
   871     apply (auto simp add: pos borel insert(2-) setprod_ereal_pos positive_integral_positive)
   872     done
   873 qed (simp add: space_PiM)
   874 
   875 lemma (in product_sigma_finite) product_integral_singleton:
   876   assumes f: "f \<in> borel_measurable (M i)"
   877   shows "(\<integral>x. f (x i) \<partial>Pi\<^isub>M {i} M) = integral\<^isup>L (M i) f"
   878 proof -
   879   interpret I: finite_product_sigma_finite M "{i}" by default simp
   880   have *: "(\<lambda>x. ereal (f x)) \<in> borel_measurable (M i)"
   881     "(\<lambda>x. ereal (- f x)) \<in> borel_measurable (M i)"
   882     using assms by auto
   883   show ?thesis
   884     unfolding lebesgue_integral_def *[THEN product_positive_integral_singleton] ..
   885 qed
   886 
   887 lemma (in product_sigma_finite) product_integral_fold:
   888   assumes IJ[simp]: "I \<inter> J = {}" and fin: "finite I" "finite J"
   889   and f: "integrable (Pi\<^isub>M (I \<union> J) M) f"
   890   shows "integral\<^isup>L (Pi\<^isub>M (I \<union> J) M) f = (\<integral>x. (\<integral>y. f (merge I J (x, y)) \<partial>Pi\<^isub>M J M) \<partial>Pi\<^isub>M I M)"
   891 proof -
   892   interpret I: finite_product_sigma_finite M I by default fact
   893   interpret J: finite_product_sigma_finite M J by default fact
   894   have "finite (I \<union> J)" using fin by auto
   895   interpret IJ: finite_product_sigma_finite M "I \<union> J" by default fact
   896   interpret P: pair_sigma_finite "Pi\<^isub>M I M" "Pi\<^isub>M J M" by default
   897   let ?M = "merge I J"
   898   let ?f = "\<lambda>x. f (?M x)"
   899   from f have f_borel: "f \<in> borel_measurable (Pi\<^isub>M (I \<union> J) M)"
   900     by auto
   901   have P_borel: "(\<lambda>x. f (merge I J x)) \<in> borel_measurable (Pi\<^isub>M I M \<Otimes>\<^isub>M Pi\<^isub>M J M)"
   902     using measurable_comp[OF measurable_merge f_borel] by (simp add: comp_def)
   903   have f_int: "integrable (Pi\<^isub>M I M \<Otimes>\<^isub>M Pi\<^isub>M J M) ?f"
   904     by (rule integrable_distr[OF measurable_merge]) (simp add: distr_merge[OF IJ fin] f)
   905   show ?thesis
   906     apply (subst distr_merge[symmetric, OF IJ fin])
   907     apply (subst integral_distr[OF measurable_merge f_borel])
   908     apply (subst P.integrable_fst_measurable(2)[symmetric, OF f_int])
   909     apply simp
   910     done
   911 qed
   912 
   913 lemma (in product_sigma_finite)
   914   assumes IJ: "I \<inter> J = {}" "finite I" "finite J" and A: "A \<in> sets (Pi\<^isub>M (I \<union> J) M)"
   915   shows emeasure_fold_integral:
   916     "emeasure (Pi\<^isub>M (I \<union> J) M) A = (\<integral>\<^isup>+x. emeasure (Pi\<^isub>M J M) ((\<lambda>y. merge I J (x, y)) -` A \<inter> space (Pi\<^isub>M J M)) \<partial>Pi\<^isub>M I M)" (is ?I)
   917     and emeasure_fold_measurable:
   918     "(\<lambda>x. emeasure (Pi\<^isub>M J M) ((\<lambda>y. merge I J (x, y)) -` A \<inter> space (Pi\<^isub>M J M))) \<in> borel_measurable (Pi\<^isub>M I M)" (is ?B)
   919 proof -
   920   interpret I: finite_product_sigma_finite M I by default fact
   921   interpret J: finite_product_sigma_finite M J by default fact
   922   interpret IJ: pair_sigma_finite "Pi\<^isub>M I M" "Pi\<^isub>M J M" ..
   923   have merge: "merge I J -` A \<inter> space (Pi\<^isub>M I M \<Otimes>\<^isub>M Pi\<^isub>M J M) \<in> sets (Pi\<^isub>M I M \<Otimes>\<^isub>M Pi\<^isub>M J M)"
   924     by (intro measurable_sets[OF _ A] measurable_merge assms)
   925 
   926   show ?I
   927     apply (subst distr_merge[symmetric, OF IJ])
   928     apply (subst emeasure_distr[OF measurable_merge A])
   929     apply (subst J.emeasure_pair_measure_alt[OF merge])
   930     apply (auto intro!: positive_integral_cong arg_cong2[where f=emeasure] simp: space_pair_measure)
   931     done
   932 
   933   show ?B
   934     using IJ.measurable_emeasure_Pair1[OF merge]
   935     by (simp add: vimage_compose[symmetric] comp_def space_pair_measure cong: measurable_cong)
   936 qed
   937 
   938 lemma (in product_sigma_finite) product_integral_insert:
   939   assumes I: "finite I" "i \<notin> I"
   940     and f: "integrable (Pi\<^isub>M (insert i I) M) f"
   941   shows "integral\<^isup>L (Pi\<^isub>M (insert i I) M) f = (\<integral>x. (\<integral>y. f (x(i:=y)) \<partial>M i) \<partial>Pi\<^isub>M I M)"
   942 proof -
   943   have "integral\<^isup>L (Pi\<^isub>M (insert i I) M) f = integral\<^isup>L (Pi\<^isub>M (I \<union> {i}) M) f"
   944     by simp
   945   also have "\<dots> = (\<integral>x. (\<integral>y. f (merge I {i} (x,y)) \<partial>Pi\<^isub>M {i} M) \<partial>Pi\<^isub>M I M)"
   946     using f I by (intro product_integral_fold) auto
   947   also have "\<dots> = (\<integral>x. (\<integral>y. f (x(i := y)) \<partial>M i) \<partial>Pi\<^isub>M I M)"
   948   proof (rule integral_cong, subst product_integral_singleton[symmetric])
   949     fix x assume x: "x \<in> space (Pi\<^isub>M I M)"
   950     have f_borel: "f \<in> borel_measurable (Pi\<^isub>M (insert i I) M)"
   951       using f by auto
   952     show "(\<lambda>y. f (x(i := y))) \<in> borel_measurable (M i)"
   953       using measurable_comp[OF measurable_component_update f_borel, OF x `i \<notin> I`]
   954       unfolding comp_def .
   955     from x I show "(\<integral> y. f (merge I {i} (x,y)) \<partial>Pi\<^isub>M {i} M) = (\<integral> xa. f (x(i := xa i)) \<partial>Pi\<^isub>M {i} M)"
   956       by (auto intro!: integral_cong arg_cong[where f=f] simp: merge_def space_PiM extensional_def)
   957   qed
   958   finally show ?thesis .
   959 qed
   960 
   961 lemma (in product_sigma_finite) product_integrable_setprod:
   962   fixes f :: "'i \<Rightarrow> 'a \<Rightarrow> real"
   963   assumes [simp]: "finite I" and integrable: "\<And>i. i \<in> I \<Longrightarrow> integrable (M i) (f i)"
   964   shows "integrable (Pi\<^isub>M I M) (\<lambda>x. (\<Prod>i\<in>I. f i (x i)))" (is "integrable _ ?f")
   965 proof -
   966   interpret finite_product_sigma_finite M I by default fact
   967   have f: "\<And>i. i \<in> I \<Longrightarrow> f i \<in> borel_measurable (M i)"
   968     using integrable unfolding integrable_def by auto
   969   have borel: "?f \<in> borel_measurable (Pi\<^isub>M I M)"
   970     using measurable_comp[OF measurable_component_singleton[of _ I M] f] by (auto simp: comp_def)
   971   moreover have "integrable (Pi\<^isub>M I M) (\<lambda>x. \<bar>\<Prod>i\<in>I. f i (x i)\<bar>)"
   972   proof (unfold integrable_def, intro conjI)
   973     show "(\<lambda>x. abs (?f x)) \<in> borel_measurable (Pi\<^isub>M I M)"
   974       using borel by auto
   975     have "(\<integral>\<^isup>+x. ereal (abs (?f x)) \<partial>Pi\<^isub>M I M) = (\<integral>\<^isup>+x. (\<Prod>i\<in>I. ereal (abs (f i (x i)))) \<partial>Pi\<^isub>M I M)"
   976       by (simp add: setprod_ereal abs_setprod)
   977     also have "\<dots> = (\<Prod>i\<in>I. (\<integral>\<^isup>+x. ereal (abs (f i x)) \<partial>M i))"
   978       using f by (subst product_positive_integral_setprod) auto
   979     also have "\<dots> < \<infinity>"
   980       using integrable[THEN integrable_abs]
   981       by (simp add: setprod_PInf integrable_def positive_integral_positive)
   982     finally show "(\<integral>\<^isup>+x. ereal (abs (?f x)) \<partial>(Pi\<^isub>M I M)) \<noteq> \<infinity>" by auto
   983     have "(\<integral>\<^isup>+x. ereal (- abs (?f x)) \<partial>(Pi\<^isub>M I M)) = (\<integral>\<^isup>+x. 0 \<partial>(Pi\<^isub>M I M))"
   984       by (intro positive_integral_cong_pos) auto
   985     then show "(\<integral>\<^isup>+x. ereal (- abs (?f x)) \<partial>(Pi\<^isub>M I M)) \<noteq> \<infinity>" by simp
   986   qed
   987   ultimately show ?thesis
   988     by (rule integrable_abs_iff[THEN iffD1])
   989 qed
   990 
   991 lemma (in product_sigma_finite) product_integral_setprod:
   992   fixes f :: "'i \<Rightarrow> 'a \<Rightarrow> real"
   993   assumes "finite I" and integrable: "\<And>i. i \<in> I \<Longrightarrow> integrable (M i) (f i)"
   994   shows "(\<integral>x. (\<Prod>i\<in>I. f i (x i)) \<partial>Pi\<^isub>M I M) = (\<Prod>i\<in>I. integral\<^isup>L (M i) (f i))"
   995 using assms proof induct
   996   case empty
   997   interpret finite_measure "Pi\<^isub>M {} M"
   998     by rule (simp add: space_PiM)
   999   show ?case by (simp add: space_PiM measure_def)
  1000 next
  1001   case (insert i I)
  1002   then have iI: "finite (insert i I)" by auto
  1003   then have prod: "\<And>J. J \<subseteq> insert i I \<Longrightarrow>
  1004     integrable (Pi\<^isub>M J M) (\<lambda>x. (\<Prod>i\<in>J. f i (x i)))"
  1005     by (intro product_integrable_setprod insert(4)) (auto intro: finite_subset)
  1006   interpret I: finite_product_sigma_finite M I by default fact
  1007   have *: "\<And>x y. (\<Prod>j\<in>I. f j (if j = i then y else x j)) = (\<Prod>j\<in>I. f j (x j))"
  1008     using `i \<notin> I` by (auto intro!: setprod_cong)
  1009   show ?case
  1010     unfolding product_integral_insert[OF insert(1,2) prod[OF subset_refl]]
  1011     by (simp add: * insert integral_multc integral_cmult[OF prod] subset_insertI)
  1012 qed
  1013 
  1014 lemma sets_Collect_single:
  1015   "i \<in> I \<Longrightarrow> A \<in> sets (M i) \<Longrightarrow> { x \<in> space (Pi\<^isub>M I M). x i \<in> A } \<in> sets (Pi\<^isub>M I M)"
  1016   unfolding sets_PiM_single
  1017   by (auto intro!: sigma_sets.Basic exI[of _ i] exI[of _ A]) (auto simp: space_PiM)
  1018 
  1019 lemma sigma_prod_algebra_sigma_eq_infinite:
  1020   fixes E :: "'i \<Rightarrow> 'a set set"
  1021   assumes S_union: "\<And>i. i \<in> I \<Longrightarrow> (\<Union>j. S i j) = space (M i)"
  1022     and S_in_E: "\<And>i. i \<in> I \<Longrightarrow> range (S i) \<subseteq> E i"
  1023   assumes E_closed: "\<And>i. i \<in> I \<Longrightarrow> E i \<subseteq> Pow (space (M i))"
  1024     and E_generates: "\<And>i. i \<in> I \<Longrightarrow> sets (M i) = sigma_sets (space (M i)) (E i)"
  1025   defines "P == {{f\<in>\<Pi>\<^isub>E i\<in>I. space (M i). f i \<in> A} | i A. i \<in> I \<and> A \<in> E i}"
  1026   shows "sets (PiM I M) = sigma_sets (space (PiM I M)) P"
  1027 proof
  1028   let ?P = "sigma (space (Pi\<^isub>M I M)) P"
  1029   have P_closed: "P \<subseteq> Pow (space (Pi\<^isub>M I M))"
  1030     using E_closed by (auto simp: space_PiM P_def Pi_iff subset_eq)
  1031   then have space_P: "space ?P = (\<Pi>\<^isub>E i\<in>I. space (M i))"
  1032     by (simp add: space_PiM)
  1033   have "sets (PiM I M) =
  1034       sigma_sets (space ?P) {{f \<in> \<Pi>\<^isub>E i\<in>I. space (M i). f i \<in> A} |i A. i \<in> I \<and> A \<in> sets (M i)}"
  1035     using sets_PiM_single[of I M] by (simp add: space_P)
  1036   also have "\<dots> \<subseteq> sets (sigma (space (PiM I M)) P)"
  1037   proof (safe intro!: sigma_sets_subset)
  1038     fix i A assume "i \<in> I" and A: "A \<in> sets (M i)"
  1039     then have "(\<lambda>x. x i) \<in> measurable ?P (sigma (space (M i)) (E i))"
  1040       apply (subst measurable_iff_measure_of)
  1041       apply (simp_all add: P_closed)
  1042       using E_closed
  1043       apply (force simp: subset_eq space_PiM)
  1044       apply (force simp: subset_eq space_PiM)
  1045       apply (auto simp: P_def intro!: sigma_sets.Basic exI[of _ i])
  1046       apply (rule_tac x=Aa in exI)
  1047       apply (auto simp: space_PiM)
  1048       done
  1049     from measurable_sets[OF this, of A] A `i \<in> I` E_closed
  1050     have "(\<lambda>x. x i) -` A \<inter> space ?P \<in> sets ?P"
  1051       by (simp add: E_generates)
  1052     also have "(\<lambda>x. x i) -` A \<inter> space ?P = {f \<in> \<Pi>\<^isub>E i\<in>I. space (M i). f i \<in> A}"
  1053       using P_closed by (auto simp: space_PiM)
  1054     finally show "\<dots> \<in> sets ?P" .
  1055   qed
  1056   finally show "sets (PiM I M) \<subseteq> sigma_sets (space (PiM I M)) P"
  1057     by (simp add: P_closed)
  1058   show "sigma_sets (space (PiM I M)) P \<subseteq> sets (PiM I M)"
  1059     unfolding P_def space_PiM[symmetric]
  1060     by (intro sigma_sets_subset) (auto simp: E_generates sets_Collect_single)
  1061 qed
  1062 
  1063 lemma bchoice_iff: "(\<forall>a\<in>A. \<exists>b. P a b) \<longleftrightarrow> (\<exists>f. \<forall>a\<in>A. P a (f a))"
  1064   by metis
  1065 
  1066 lemma sigma_prod_algebra_sigma_eq:
  1067   fixes E :: "'i \<Rightarrow> 'a set set" and S :: "'i \<Rightarrow> nat \<Rightarrow> 'a set"
  1068   assumes "finite I"
  1069   assumes S_union: "\<And>i. i \<in> I \<Longrightarrow> (\<Union>j. S i j) = space (M i)"
  1070     and S_in_E: "\<And>i. i \<in> I \<Longrightarrow> range (S i) \<subseteq> E i"
  1071   assumes E_closed: "\<And>i. i \<in> I \<Longrightarrow> E i \<subseteq> Pow (space (M i))"
  1072     and E_generates: "\<And>i. i \<in> I \<Longrightarrow> sets (M i) = sigma_sets (space (M i)) (E i)"
  1073   defines "P == { Pi\<^isub>E I F | F. \<forall>i\<in>I. F i \<in> E i }"
  1074   shows "sets (PiM I M) = sigma_sets (space (PiM I M)) P"
  1075 proof
  1076   let ?P = "sigma (space (Pi\<^isub>M I M)) P"
  1077   from `finite I`[THEN ex_bij_betw_finite_nat] guess T ..
  1078   then have T: "\<And>i. i \<in> I \<Longrightarrow> T i < card I" "\<And>i. i\<in>I \<Longrightarrow> the_inv_into I T (T i) = i"
  1079     by (auto simp add: bij_betw_def set_eq_iff image_iff the_inv_into_f_f)
  1080   have P_closed: "P \<subseteq> Pow (space (Pi\<^isub>M I M))"
  1081     using E_closed by (auto simp: space_PiM P_def Pi_iff subset_eq)
  1082   then have space_P: "space ?P = (\<Pi>\<^isub>E i\<in>I. space (M i))"
  1083     by (simp add: space_PiM)
  1084   have "sets (PiM I M) =
  1085       sigma_sets (space ?P) {{f \<in> \<Pi>\<^isub>E i\<in>I. space (M i). f i \<in> A} |i A. i \<in> I \<and> A \<in> sets (M i)}"
  1086     using sets_PiM_single[of I M] by (simp add: space_P)
  1087   also have "\<dots> \<subseteq> sets (sigma (space (PiM I M)) P)"
  1088   proof (safe intro!: sigma_sets_subset)
  1089     fix i A assume "i \<in> I" and A: "A \<in> sets (M i)"
  1090     have "(\<lambda>x. x i) \<in> measurable ?P (sigma (space (M i)) (E i))"
  1091     proof (subst measurable_iff_measure_of)
  1092       show "E i \<subseteq> Pow (space (M i))" using `i \<in> I` by fact
  1093       from space_P `i \<in> I` show "(\<lambda>x. x i) \<in> space ?P \<rightarrow> space (M i)"
  1094         by (auto simp: Pi_iff)
  1095       show "\<forall>A\<in>E i. (\<lambda>x. x i) -` A \<inter> space ?P \<in> sets ?P"
  1096       proof
  1097         fix A assume A: "A \<in> E i"
  1098         then have "(\<lambda>x. x i) -` A \<inter> space ?P = (\<Pi>\<^isub>E j\<in>I. if i = j then A else space (M j))"
  1099           using E_closed `i \<in> I` by (auto simp: space_P Pi_iff subset_eq split: split_if_asm)
  1100         also have "\<dots> = (\<Pi>\<^isub>E j\<in>I. \<Union>n. if i = j then A else S j n)"
  1101           by (intro PiE_cong) (simp add: S_union)
  1102         also have "\<dots> = (\<Union>xs\<in>{xs. length xs = card I}. \<Pi>\<^isub>E j\<in>I. if i = j then A else S j (xs ! T j))"
  1103           using T
  1104           apply (auto simp: Pi_iff bchoice_iff)
  1105           apply (rule_tac x="map (\<lambda>n. f (the_inv_into I T n)) [0..<card I]" in exI)
  1106           apply (auto simp: bij_betw_def)
  1107           done
  1108         also have "\<dots> \<in> sets ?P"
  1109         proof (safe intro!: countable_UN)
  1110           fix xs show "(\<Pi>\<^isub>E j\<in>I. if i = j then A else S j (xs ! T j)) \<in> sets ?P"
  1111             using A S_in_E
  1112             by (simp add: P_closed)
  1113                (auto simp: P_def subset_eq intro!: exI[of _ "\<lambda>j. if i = j then A else S j (xs ! T j)"])
  1114         qed
  1115         finally show "(\<lambda>x. x i) -` A \<inter> space ?P \<in> sets ?P"
  1116           using P_closed by simp
  1117       qed
  1118     qed
  1119     from measurable_sets[OF this, of A] A `i \<in> I` E_closed
  1120     have "(\<lambda>x. x i) -` A \<inter> space ?P \<in> sets ?P"
  1121       by (simp add: E_generates)
  1122     also have "(\<lambda>x. x i) -` A \<inter> space ?P = {f \<in> \<Pi>\<^isub>E i\<in>I. space (M i). f i \<in> A}"
  1123       using P_closed by (auto simp: space_PiM)
  1124     finally show "\<dots> \<in> sets ?P" .
  1125   qed
  1126   finally show "sets (PiM I M) \<subseteq> sigma_sets (space (PiM I M)) P"
  1127     by (simp add: P_closed)
  1128   show "sigma_sets (space (PiM I M)) P \<subseteq> sets (PiM I M)"
  1129     using `finite I`
  1130     by (auto intro!: sigma_sets_subset simp: E_generates P_def)
  1131 qed
  1132 
  1133 end