src/HOL/Series.thy
author hoelzl
Wed Apr 25 19:26:00 2012 +0200 (2012-04-25)
changeset 47761 dfe747e72fa8
parent 47108 2a1953f0d20d
child 50331 4b6dc5077e98
permissions -rw-r--r--
moved lemmas to appropriate places
     1 (*  Title       : Series.thy
     2     Author      : Jacques D. Fleuriot
     3     Copyright   : 1998  University of Cambridge
     4 
     5 Converted to Isar and polished by lcp
     6 Converted to setsum and polished yet more by TNN
     7 Additional contributions by Jeremy Avigad
     8 *)
     9 
    10 header{*Finite Summation and Infinite Series*}
    11 
    12 theory Series
    13 imports SEQ Deriv
    14 begin
    15 
    16 definition
    17    sums  :: "(nat \<Rightarrow> 'a::{topological_space, comm_monoid_add}) \<Rightarrow> 'a \<Rightarrow> bool"
    18      (infixr "sums" 80) where
    19    "f sums s = (%n. setsum f {0..<n}) ----> s"
    20 
    21 definition
    22    summable :: "(nat \<Rightarrow> 'a::{topological_space, comm_monoid_add}) \<Rightarrow> bool" where
    23    "summable f = (\<exists>s. f sums s)"
    24 
    25 definition
    26    suminf   :: "(nat \<Rightarrow> 'a::{topological_space, comm_monoid_add}) \<Rightarrow> 'a" where
    27    "suminf f = (THE s. f sums s)"
    28 
    29 notation suminf (binder "\<Sum>" 10)
    30 
    31 
    32 lemma [trans]: "f=g ==> g sums z ==> f sums z"
    33   by simp
    34 
    35 lemma sumr_diff_mult_const:
    36  "setsum f {0..<n} - (real n*r) = setsum (%i. f i - r) {0..<n::nat}"
    37 by (simp add: diff_minus setsum_addf real_of_nat_def)
    38 
    39 lemma real_setsum_nat_ivl_bounded:
    40      "(!!p. p < n \<Longrightarrow> f(p) \<le> K)
    41       \<Longrightarrow> setsum f {0..<n::nat} \<le> real n * K"
    42 using setsum_bounded[where A = "{0..<n}"]
    43 by (auto simp:real_of_nat_def)
    44 
    45 (* Generalize from real to some algebraic structure? *)
    46 lemma sumr_minus_one_realpow_zero [simp]:
    47   "(\<Sum>i=0..<2*n. (-1) ^ Suc i) = (0::real)"
    48 by (induct "n", auto)
    49 
    50 (* FIXME this is an awful lemma! *)
    51 lemma sumr_one_lb_realpow_zero [simp]:
    52   "(\<Sum>n=Suc 0..<n. f(n) * (0::real) ^ n) = 0"
    53 by (rule setsum_0', simp)
    54 
    55 lemma sumr_group:
    56      "(\<Sum>m=0..<n::nat. setsum f {m * k ..< m*k + k}) = setsum f {0 ..< n * k}"
    57 apply (subgoal_tac "k = 0 | 0 < k", auto)
    58 apply (induct "n")
    59 apply (simp_all add: setsum_add_nat_ivl add_commute)
    60 done
    61 
    62 lemma sumr_offset3:
    63   "setsum f {0::nat..<n+k} = (\<Sum>m=0..<n. f (m+k)) + setsum f {0..<k}"
    64 apply (subst setsum_shift_bounds_nat_ivl [symmetric])
    65 apply (simp add: setsum_add_nat_ivl add_commute)
    66 done
    67 
    68 lemma sumr_offset:
    69   fixes f :: "nat \<Rightarrow> 'a::ab_group_add"
    70   shows "(\<Sum>m=0..<n. f(m+k)) = setsum f {0..<n+k} - setsum f {0..<k}"
    71 by (simp add: sumr_offset3)
    72 
    73 lemma sumr_offset2:
    74  "\<forall>f. (\<Sum>m=0..<n::nat. f(m+k)::real) = setsum f {0..<n+k} - setsum f {0..<k}"
    75 by (simp add: sumr_offset)
    76 
    77 lemma sumr_offset4:
    78   "\<forall>n f. setsum f {0::nat..<n+k} = (\<Sum>m=0..<n. f (m+k)::real) + setsum f {0..<k}"
    79 by (clarify, rule sumr_offset3)
    80 
    81 subsection{* Infinite Sums, by the Properties of Limits*}
    82 
    83 (*----------------------
    84    suminf is the sum
    85  ---------------------*)
    86 lemma sums_summable: "f sums l ==> summable f"
    87   by (simp add: sums_def summable_def, blast)
    88 
    89 lemma summable_sums:
    90   fixes f :: "nat \<Rightarrow> 'a::{t2_space, comm_monoid_add}"
    91   assumes "summable f"
    92   shows "f sums (suminf f)"
    93 proof -
    94   from assms obtain s where s: "(\<lambda>n. setsum f {0..<n}) ----> s"
    95     unfolding summable_def sums_def [abs_def] ..
    96   then show ?thesis unfolding sums_def [abs_def] suminf_def
    97     by (rule theI, auto intro!: tendsto_unique[OF trivial_limit_sequentially])
    98 qed
    99 
   100 lemma summable_sumr_LIMSEQ_suminf:
   101   fixes f :: "nat \<Rightarrow> 'a::{t2_space, comm_monoid_add}"
   102   shows "summable f \<Longrightarrow> (\<lambda>n. setsum f {0..<n}) ----> suminf f"
   103 by (rule summable_sums [unfolded sums_def])
   104 
   105 lemma suminf_eq_lim: "suminf f = lim (%n. setsum f {0..<n})"
   106   by (simp add: suminf_def sums_def lim_def)
   107 
   108 (*-------------------
   109     sum is unique
   110  ------------------*)
   111 lemma sums_unique:
   112   fixes f :: "nat \<Rightarrow> 'a::{t2_space, comm_monoid_add}"
   113   shows "f sums s \<Longrightarrow> (s = suminf f)"
   114 apply (frule sums_summable[THEN summable_sums])
   115 apply (auto intro!: tendsto_unique[OF trivial_limit_sequentially] simp add: sums_def)
   116 done
   117 
   118 lemma sums_iff:
   119   fixes f :: "nat \<Rightarrow> 'a::{t2_space, comm_monoid_add}"
   120   shows "f sums x \<longleftrightarrow> summable f \<and> (suminf f = x)"
   121   by (metis summable_sums sums_summable sums_unique)
   122 
   123 lemma sums_finite:
   124   assumes [simp]: "finite N"
   125   assumes f: "\<And>n. n \<notin> N \<Longrightarrow> f n = 0"
   126   shows "f sums (\<Sum>n\<in>N. f n)"
   127 proof -
   128   { fix n
   129     have "setsum f {..<n + Suc (Max N)} = setsum f N"
   130     proof cases
   131       assume "N = {}"
   132       with f have "f = (\<lambda>x. 0)" by auto
   133       then show ?thesis by simp
   134     next
   135       assume [simp]: "N \<noteq> {}"
   136       show ?thesis
   137       proof (safe intro!: setsum_mono_zero_right f)
   138         fix i assume "i \<in> N"
   139         then have "i \<le> Max N" by simp
   140         then show "i < n + Suc (Max N)" by simp
   141       qed
   142     qed }
   143   note eq = this
   144   show ?thesis unfolding sums_def
   145     by (rule LIMSEQ_offset[of _ "Suc (Max N)"])
   146        (simp add: eq atLeast0LessThan tendsto_const del: add_Suc_right)
   147 qed
   148 
   149 lemma suminf_finite:
   150   fixes f :: "nat \<Rightarrow> 'a::{comm_monoid_add,t2_space}"
   151   assumes N: "finite N" and f: "\<And>n. n \<notin> N \<Longrightarrow> f n = 0"
   152   shows "suminf f = (\<Sum>n\<in>N. f n)"
   153   using sums_finite[OF assms, THEN sums_unique] by simp
   154 
   155 lemma sums_If_finite_set:
   156   "finite A \<Longrightarrow> (\<lambda>r. if r \<in> A then f r else 0 :: 'a::{comm_monoid_add,t2_space}) sums (\<Sum>r\<in>A. f r)"
   157   using sums_finite[of A "(\<lambda>r. if r \<in> A then f r else 0)"] by simp
   158 
   159 lemma sums_If_finite:
   160   "finite {r. P r} \<Longrightarrow> (\<lambda>r. if P r then f r else 0 :: 'a::{comm_monoid_add,t2_space}) sums (\<Sum>r | P r. f r)"
   161   using sums_If_finite_set[of "{r. P r}" f] by simp
   162 
   163 lemma sums_single:
   164   "(\<lambda>r. if r = i then f r else 0::'a::{comm_monoid_add,t2_space}) sums f i"
   165   using sums_If_finite[of "\<lambda>r. r = i" f] by simp
   166 
   167 lemma sums_split_initial_segment:
   168   fixes f :: "nat \<Rightarrow> 'a::real_normed_vector"
   169   shows "f sums s ==> (\<lambda>n. f(n + k)) sums (s - (SUM i = 0..< k. f i))"
   170   apply (unfold sums_def)
   171   apply (simp add: sumr_offset)
   172   apply (rule tendsto_diff [OF _ tendsto_const])
   173   apply (rule LIMSEQ_ignore_initial_segment)
   174   apply assumption
   175 done
   176 
   177 lemma summable_ignore_initial_segment:
   178   fixes f :: "nat \<Rightarrow> 'a::real_normed_vector"
   179   shows "summable f ==> summable (%n. f(n + k))"
   180   apply (unfold summable_def)
   181   apply (auto intro: sums_split_initial_segment)
   182 done
   183 
   184 lemma suminf_minus_initial_segment:
   185   fixes f :: "nat \<Rightarrow> 'a::real_normed_vector"
   186   shows "summable f ==>
   187     suminf f = s ==> suminf (%n. f(n + k)) = s - (SUM i = 0..< k. f i)"
   188   apply (frule summable_ignore_initial_segment)
   189   apply (rule sums_unique [THEN sym])
   190   apply (frule summable_sums)
   191   apply (rule sums_split_initial_segment)
   192   apply auto
   193 done
   194 
   195 lemma suminf_split_initial_segment:
   196   fixes f :: "nat \<Rightarrow> 'a::real_normed_vector"
   197   shows "summable f ==>
   198     suminf f = (SUM i = 0..< k. f i) + (\<Sum>n. f(n + k))"
   199 by (auto simp add: suminf_minus_initial_segment)
   200 
   201 lemma suminf_exist_split: fixes r :: real assumes "0 < r" and "summable a"
   202   shows "\<exists> N. \<forall> n \<ge> N. \<bar> \<Sum> i. a (i + n) \<bar> < r"
   203 proof -
   204   from LIMSEQ_D[OF summable_sumr_LIMSEQ_suminf[OF `summable a`] `0 < r`]
   205   obtain N :: nat where "\<forall> n \<ge> N. norm (setsum a {0..<n} - suminf a) < r" by auto
   206   thus ?thesis unfolding suminf_minus_initial_segment[OF `summable a` refl] abs_minus_commute real_norm_def
   207     by auto
   208 qed
   209 
   210 lemma sums_Suc:
   211   fixes f :: "nat \<Rightarrow> 'a::real_normed_vector"
   212   assumes sumSuc: "(\<lambda> n. f (Suc n)) sums l" shows "f sums (l + f 0)"
   213 proof -
   214   from sumSuc[unfolded sums_def]
   215   have "(\<lambda>i. \<Sum>n = Suc 0..<Suc i. f n) ----> l" unfolding setsum_reindex[OF inj_Suc] image_Suc_atLeastLessThan[symmetric] comp_def .
   216   from tendsto_add[OF this tendsto_const, where b="f 0"]
   217   have "(\<lambda>i. \<Sum>n = 0..<Suc i. f n) ----> l + f 0" unfolding add_commute setsum_head_upt_Suc[OF zero_less_Suc] .
   218   thus ?thesis unfolding sums_def by (rule LIMSEQ_imp_Suc)
   219 qed
   220 
   221 lemma series_zero:
   222   fixes f :: "nat \<Rightarrow> 'a::{t2_space, comm_monoid_add}"
   223   assumes "\<forall>m. n \<le> m \<longrightarrow> f m = 0"
   224   shows "f sums (setsum f {0..<n})"
   225 proof -
   226   { fix k :: nat have "setsum f {0..<k + n} = setsum f {0..<n}"
   227       using assms by (induct k) auto }
   228   note setsum_const = this
   229   show ?thesis
   230     unfolding sums_def
   231     apply (rule LIMSEQ_offset[of _ n])
   232     unfolding setsum_const
   233     apply (rule tendsto_const)
   234     done
   235 qed
   236 
   237 lemma sums_zero[simp, intro]: "(\<lambda>n. 0) sums 0"
   238   unfolding sums_def by (simp add: tendsto_const)
   239 
   240 lemma summable_zero[simp, intro]: "summable (\<lambda>n. 0)"
   241 by (rule sums_zero [THEN sums_summable])
   242 
   243 lemma suminf_zero[simp]: "suminf (\<lambda>n. 0::'a::{t2_space, comm_monoid_add}) = 0"
   244 by (rule sums_zero [THEN sums_unique, symmetric])
   245 
   246 lemma (in bounded_linear) sums:
   247   "(\<lambda>n. X n) sums a \<Longrightarrow> (\<lambda>n. f (X n)) sums (f a)"
   248   unfolding sums_def by (drule tendsto, simp only: setsum)
   249 
   250 lemma (in bounded_linear) summable:
   251   "summable (\<lambda>n. X n) \<Longrightarrow> summable (\<lambda>n. f (X n))"
   252 unfolding summable_def by (auto intro: sums)
   253 
   254 lemma (in bounded_linear) suminf:
   255   "summable (\<lambda>n. X n) \<Longrightarrow> f (\<Sum>n. X n) = (\<Sum>n. f (X n))"
   256 by (intro sums_unique sums summable_sums)
   257 
   258 lemmas sums_of_real = bounded_linear.sums [OF bounded_linear_of_real]
   259 lemmas summable_of_real = bounded_linear.summable [OF bounded_linear_of_real]
   260 lemmas suminf_of_real = bounded_linear.suminf [OF bounded_linear_of_real]
   261 
   262 lemma sums_mult:
   263   fixes c :: "'a::real_normed_algebra"
   264   shows "f sums a \<Longrightarrow> (\<lambda>n. c * f n) sums (c * a)"
   265   by (rule bounded_linear.sums [OF bounded_linear_mult_right])
   266 
   267 lemma summable_mult:
   268   fixes c :: "'a::real_normed_algebra"
   269   shows "summable f \<Longrightarrow> summable (%n. c * f n)"
   270   by (rule bounded_linear.summable [OF bounded_linear_mult_right])
   271 
   272 lemma suminf_mult:
   273   fixes c :: "'a::real_normed_algebra"
   274   shows "summable f \<Longrightarrow> suminf (\<lambda>n. c * f n) = c * suminf f"
   275   by (rule bounded_linear.suminf [OF bounded_linear_mult_right, symmetric])
   276 
   277 lemma sums_mult2:
   278   fixes c :: "'a::real_normed_algebra"
   279   shows "f sums a \<Longrightarrow> (\<lambda>n. f n * c) sums (a * c)"
   280   by (rule bounded_linear.sums [OF bounded_linear_mult_left])
   281 
   282 lemma summable_mult2:
   283   fixes c :: "'a::real_normed_algebra"
   284   shows "summable f \<Longrightarrow> summable (\<lambda>n. f n * c)"
   285   by (rule bounded_linear.summable [OF bounded_linear_mult_left])
   286 
   287 lemma suminf_mult2:
   288   fixes c :: "'a::real_normed_algebra"
   289   shows "summable f \<Longrightarrow> suminf f * c = (\<Sum>n. f n * c)"
   290   by (rule bounded_linear.suminf [OF bounded_linear_mult_left])
   291 
   292 lemma sums_divide:
   293   fixes c :: "'a::real_normed_field"
   294   shows "f sums a \<Longrightarrow> (\<lambda>n. f n / c) sums (a / c)"
   295   by (rule bounded_linear.sums [OF bounded_linear_divide])
   296 
   297 lemma summable_divide:
   298   fixes c :: "'a::real_normed_field"
   299   shows "summable f \<Longrightarrow> summable (\<lambda>n. f n / c)"
   300   by (rule bounded_linear.summable [OF bounded_linear_divide])
   301 
   302 lemma suminf_divide:
   303   fixes c :: "'a::real_normed_field"
   304   shows "summable f \<Longrightarrow> suminf (\<lambda>n. f n / c) = suminf f / c"
   305   by (rule bounded_linear.suminf [OF bounded_linear_divide, symmetric])
   306 
   307 lemma sums_add:
   308   fixes a b :: "'a::real_normed_field"
   309   shows "\<lbrakk>X sums a; Y sums b\<rbrakk> \<Longrightarrow> (\<lambda>n. X n + Y n) sums (a + b)"
   310   unfolding sums_def by (simp add: setsum_addf tendsto_add)
   311 
   312 lemma summable_add:
   313   fixes X Y :: "nat \<Rightarrow> 'a::real_normed_field"
   314   shows "\<lbrakk>summable X; summable Y\<rbrakk> \<Longrightarrow> summable (\<lambda>n. X n + Y n)"
   315 unfolding summable_def by (auto intro: sums_add)
   316 
   317 lemma suminf_add:
   318   fixes X Y :: "nat \<Rightarrow> 'a::real_normed_field"
   319   shows "\<lbrakk>summable X; summable Y\<rbrakk> \<Longrightarrow> suminf X + suminf Y = (\<Sum>n. X n + Y n)"
   320 by (intro sums_unique sums_add summable_sums)
   321 
   322 lemma sums_diff:
   323   fixes X Y :: "nat \<Rightarrow> 'a::real_normed_field"
   324   shows "\<lbrakk>X sums a; Y sums b\<rbrakk> \<Longrightarrow> (\<lambda>n. X n - Y n) sums (a - b)"
   325   unfolding sums_def by (simp add: setsum_subtractf tendsto_diff)
   326 
   327 lemma summable_diff:
   328   fixes X Y :: "nat \<Rightarrow> 'a::real_normed_field"
   329   shows "\<lbrakk>summable X; summable Y\<rbrakk> \<Longrightarrow> summable (\<lambda>n. X n - Y n)"
   330 unfolding summable_def by (auto intro: sums_diff)
   331 
   332 lemma suminf_diff:
   333   fixes X Y :: "nat \<Rightarrow> 'a::real_normed_field"
   334   shows "\<lbrakk>summable X; summable Y\<rbrakk> \<Longrightarrow> suminf X - suminf Y = (\<Sum>n. X n - Y n)"
   335 by (intro sums_unique sums_diff summable_sums)
   336 
   337 lemma sums_minus:
   338   fixes X :: "nat \<Rightarrow> 'a::real_normed_field"
   339   shows "X sums a ==> (\<lambda>n. - X n) sums (- a)"
   340   unfolding sums_def by (simp add: setsum_negf tendsto_minus)
   341 
   342 lemma summable_minus:
   343   fixes X :: "nat \<Rightarrow> 'a::real_normed_field"
   344   shows "summable X \<Longrightarrow> summable (\<lambda>n. - X n)"
   345 unfolding summable_def by (auto intro: sums_minus)
   346 
   347 lemma suminf_minus:
   348   fixes X :: "nat \<Rightarrow> 'a::real_normed_field"
   349   shows "summable X \<Longrightarrow> (\<Sum>n. - X n) = - (\<Sum>n. X n)"
   350 by (intro sums_unique [symmetric] sums_minus summable_sums)
   351 
   352 lemma sums_group:
   353   fixes f :: "nat \<Rightarrow> 'a::real_normed_field"
   354   shows "\<lbrakk>f sums s; 0 < k\<rbrakk> \<Longrightarrow> (\<lambda>n. setsum f {n*k..<n*k+k}) sums s"
   355 apply (simp only: sums_def sumr_group)
   356 apply (unfold LIMSEQ_iff, safe)
   357 apply (drule_tac x="r" in spec, safe)
   358 apply (rule_tac x="no" in exI, safe)
   359 apply (drule_tac x="n*k" in spec)
   360 apply (erule mp)
   361 apply (erule order_trans)
   362 apply simp
   363 done
   364 
   365 text{*A summable series of positive terms has limit that is at least as
   366 great as any partial sum.*}
   367 
   368 lemma pos_summable:
   369   fixes f:: "nat \<Rightarrow> real"
   370   assumes pos: "!!n. 0 \<le> f n" and le: "!!n. setsum f {0..<n} \<le> x"
   371   shows "summable f"
   372 proof -
   373   have "convergent (\<lambda>n. setsum f {0..<n})"
   374     proof (rule Bseq_mono_convergent)
   375       show "Bseq (\<lambda>n. setsum f {0..<n})"
   376         by (rule f_inc_g_dec_Beq_f [of "(\<lambda>n. setsum f {0..<n})" "\<lambda>n. x"])
   377            (auto simp add: le pos)
   378     next
   379       show "\<forall>m n. m \<le> n \<longrightarrow> setsum f {0..<m} \<le> setsum f {0..<n}"
   380         by (auto intro: setsum_mono2 pos)
   381     qed
   382   then obtain L where "(%n. setsum f {0..<n}) ----> L"
   383     by (blast dest: convergentD)
   384   thus ?thesis
   385     by (force simp add: summable_def sums_def)
   386 qed
   387 
   388 lemma series_pos_le:
   389   fixes f :: "nat \<Rightarrow> real"
   390   shows "\<lbrakk>summable f; \<forall>m\<ge>n. 0 \<le> f m\<rbrakk> \<Longrightarrow> setsum f {0..<n} \<le> suminf f"
   391 apply (drule summable_sums)
   392 apply (simp add: sums_def)
   393 apply (cut_tac k = "setsum f {0..<n}" in tendsto_const)
   394 apply (erule LIMSEQ_le, blast)
   395 apply (rule_tac x="n" in exI, clarify)
   396 apply (rule setsum_mono2)
   397 apply auto
   398 done
   399 
   400 lemma series_pos_less:
   401   fixes f :: "nat \<Rightarrow> real"
   402   shows "\<lbrakk>summable f; \<forall>m\<ge>n. 0 < f m\<rbrakk> \<Longrightarrow> setsum f {0..<n} < suminf f"
   403 apply (rule_tac y="setsum f {0..<Suc n}" in order_less_le_trans)
   404 apply simp
   405 apply (erule series_pos_le)
   406 apply (simp add: order_less_imp_le)
   407 done
   408 
   409 lemma suminf_gt_zero:
   410   fixes f :: "nat \<Rightarrow> real"
   411   shows "\<lbrakk>summable f; \<forall>n. 0 < f n\<rbrakk> \<Longrightarrow> 0 < suminf f"
   412 by (drule_tac n="0" in series_pos_less, simp_all)
   413 
   414 lemma suminf_ge_zero:
   415   fixes f :: "nat \<Rightarrow> real"
   416   shows "\<lbrakk>summable f; \<forall>n. 0 \<le> f n\<rbrakk> \<Longrightarrow> 0 \<le> suminf f"
   417 by (drule_tac n="0" in series_pos_le, simp_all)
   418 
   419 lemma sumr_pos_lt_pair:
   420   fixes f :: "nat \<Rightarrow> real"
   421   shows "\<lbrakk>summable f;
   422         \<forall>d. 0 < f (k + (Suc(Suc 0) * d)) + f (k + ((Suc(Suc 0) * d) + 1))\<rbrakk>
   423       \<Longrightarrow> setsum f {0..<k} < suminf f"
   424 unfolding One_nat_def
   425 apply (subst suminf_split_initial_segment [where k="k"])
   426 apply assumption
   427 apply simp
   428 apply (drule_tac k="k" in summable_ignore_initial_segment)
   429 apply (drule_tac k="Suc (Suc 0)" in sums_group [OF summable_sums], simp)
   430 apply simp
   431 apply (frule sums_unique)
   432 apply (drule sums_summable)
   433 apply simp
   434 apply (erule suminf_gt_zero)
   435 apply (simp add: add_ac)
   436 done
   437 
   438 text{*Sum of a geometric progression.*}
   439 
   440 lemmas sumr_geometric = geometric_sum [where 'a = real]
   441 
   442 lemma geometric_sums:
   443   fixes x :: "'a::{real_normed_field}"
   444   shows "norm x < 1 \<Longrightarrow> (\<lambda>n. x ^ n) sums (1 / (1 - x))"
   445 proof -
   446   assume less_1: "norm x < 1"
   447   hence neq_1: "x \<noteq> 1" by auto
   448   hence neq_0: "x - 1 \<noteq> 0" by simp
   449   from less_1 have lim_0: "(\<lambda>n. x ^ n) ----> 0"
   450     by (rule LIMSEQ_power_zero)
   451   hence "(\<lambda>n. x ^ n / (x - 1) - 1 / (x - 1)) ----> 0 / (x - 1) - 1 / (x - 1)"
   452     using neq_0 by (intro tendsto_intros)
   453   hence "(\<lambda>n. (x ^ n - 1) / (x - 1)) ----> 1 / (1 - x)"
   454     by (simp add: nonzero_minus_divide_right [OF neq_0] diff_divide_distrib)
   455   thus "(\<lambda>n. x ^ n) sums (1 / (1 - x))"
   456     by (simp add: sums_def geometric_sum neq_1)
   457 qed
   458 
   459 lemma summable_geometric:
   460   fixes x :: "'a::{real_normed_field}"
   461   shows "norm x < 1 \<Longrightarrow> summable (\<lambda>n. x ^ n)"
   462 by (rule geometric_sums [THEN sums_summable])
   463 
   464 lemma half: "0 < 1 / (2::'a::linordered_field)"
   465   by simp
   466 
   467 lemma power_half_series: "(\<lambda>n. (1/2::real)^Suc n) sums 1"
   468 proof -
   469   have 2: "(\<lambda>n. (1/2::real)^n) sums 2" using geometric_sums [of "1/2::real"]
   470     by auto
   471   have "(\<lambda>n. (1/2::real)^Suc n) = (\<lambda>n. (1 / 2) ^ n / 2)"
   472     by simp
   473   thus ?thesis using sums_divide [OF 2, of 2]
   474     by simp
   475 qed
   476 
   477 text{*Cauchy-type criterion for convergence of series (c.f. Harrison)*}
   478 
   479 lemma summable_convergent_sumr_iff:
   480  "summable f = convergent (%n. setsum f {0..<n})"
   481 by (simp add: summable_def sums_def convergent_def)
   482 
   483 lemma summable_LIMSEQ_zero:
   484   fixes f :: "nat \<Rightarrow> 'a::real_normed_vector"
   485   shows "summable f \<Longrightarrow> f ----> 0"
   486 apply (drule summable_convergent_sumr_iff [THEN iffD1])
   487 apply (drule convergent_Cauchy)
   488 apply (simp only: Cauchy_iff LIMSEQ_iff, safe)
   489 apply (drule_tac x="r" in spec, safe)
   490 apply (rule_tac x="M" in exI, safe)
   491 apply (drule_tac x="Suc n" in spec, simp)
   492 apply (drule_tac x="n" in spec, simp)
   493 done
   494 
   495 lemma suminf_le:
   496   fixes x :: real
   497   shows "summable f \<Longrightarrow> (!!n. setsum f {0..<n} \<le> x) \<Longrightarrow> suminf f \<le> x"
   498   by (simp add: summable_convergent_sumr_iff suminf_eq_lim lim_le)
   499 
   500 lemma summable_Cauchy:
   501      "summable (f::nat \<Rightarrow> 'a::banach) =
   502       (\<forall>e > 0. \<exists>N. \<forall>m \<ge> N. \<forall>n. norm (setsum f {m..<n}) < e)"
   503 apply (simp only: summable_convergent_sumr_iff Cauchy_convergent_iff [symmetric] Cauchy_iff, safe)
   504 apply (drule spec, drule (1) mp)
   505 apply (erule exE, rule_tac x="M" in exI, clarify)
   506 apply (rule_tac x="m" and y="n" in linorder_le_cases)
   507 apply (frule (1) order_trans)
   508 apply (drule_tac x="n" in spec, drule (1) mp)
   509 apply (drule_tac x="m" in spec, drule (1) mp)
   510 apply (simp add: setsum_diff [symmetric])
   511 apply simp
   512 apply (drule spec, drule (1) mp)
   513 apply (erule exE, rule_tac x="N" in exI, clarify)
   514 apply (rule_tac x="m" and y="n" in linorder_le_cases)
   515 apply (subst norm_minus_commute)
   516 apply (simp add: setsum_diff [symmetric])
   517 apply (simp add: setsum_diff [symmetric])
   518 done
   519 
   520 text{*Comparison test*}
   521 
   522 lemma norm_setsum:
   523   fixes f :: "'a \<Rightarrow> 'b::real_normed_vector"
   524   shows "norm (setsum f A) \<le> (\<Sum>i\<in>A. norm (f i))"
   525 apply (case_tac "finite A")
   526 apply (erule finite_induct)
   527 apply simp
   528 apply simp
   529 apply (erule order_trans [OF norm_triangle_ineq add_left_mono])
   530 apply simp
   531 done
   532 
   533 lemma summable_comparison_test:
   534   fixes f :: "nat \<Rightarrow> 'a::banach"
   535   shows "\<lbrakk>\<exists>N. \<forall>n\<ge>N. norm (f n) \<le> g n; summable g\<rbrakk> \<Longrightarrow> summable f"
   536 apply (simp add: summable_Cauchy, safe)
   537 apply (drule_tac x="e" in spec, safe)
   538 apply (rule_tac x = "N + Na" in exI, safe)
   539 apply (rotate_tac 2)
   540 apply (drule_tac x = m in spec)
   541 apply (auto, rotate_tac 2, drule_tac x = n in spec)
   542 apply (rule_tac y = "\<Sum>k=m..<n. norm (f k)" in order_le_less_trans)
   543 apply (rule norm_setsum)
   544 apply (rule_tac y = "setsum g {m..<n}" in order_le_less_trans)
   545 apply (auto intro: setsum_mono simp add: abs_less_iff)
   546 done
   547 
   548 lemma summable_norm_comparison_test:
   549   fixes f :: "nat \<Rightarrow> 'a::banach"
   550   shows "\<lbrakk>\<exists>N. \<forall>n\<ge>N. norm (f n) \<le> g n; summable g\<rbrakk>
   551          \<Longrightarrow> summable (\<lambda>n. norm (f n))"
   552 apply (rule summable_comparison_test)
   553 apply (auto)
   554 done
   555 
   556 lemma summable_rabs_comparison_test:
   557   fixes f :: "nat \<Rightarrow> real"
   558   shows "\<lbrakk>\<exists>N. \<forall>n\<ge>N. \<bar>f n\<bar> \<le> g n; summable g\<rbrakk> \<Longrightarrow> summable (\<lambda>n. \<bar>f n\<bar>)"
   559 apply (rule summable_comparison_test)
   560 apply (auto)
   561 done
   562 
   563 text{*Summability of geometric series for real algebras*}
   564 
   565 lemma complete_algebra_summable_geometric:
   566   fixes x :: "'a::{real_normed_algebra_1,banach}"
   567   shows "norm x < 1 \<Longrightarrow> summable (\<lambda>n. x ^ n)"
   568 proof (rule summable_comparison_test)
   569   show "\<exists>N. \<forall>n\<ge>N. norm (x ^ n) \<le> norm x ^ n"
   570     by (simp add: norm_power_ineq)
   571   show "norm x < 1 \<Longrightarrow> summable (\<lambda>n. norm x ^ n)"
   572     by (simp add: summable_geometric)
   573 qed
   574 
   575 text{*Limit comparison property for series (c.f. jrh)*}
   576 
   577 lemma summable_le:
   578   fixes f g :: "nat \<Rightarrow> real"
   579   shows "\<lbrakk>\<forall>n. f n \<le> g n; summable f; summable g\<rbrakk> \<Longrightarrow> suminf f \<le> suminf g"
   580 apply (drule summable_sums)+
   581 apply (simp only: sums_def, erule (1) LIMSEQ_le)
   582 apply (rule exI)
   583 apply (auto intro!: setsum_mono)
   584 done
   585 
   586 lemma summable_le2:
   587   fixes f g :: "nat \<Rightarrow> real"
   588   shows "\<lbrakk>\<forall>n. \<bar>f n\<bar> \<le> g n; summable g\<rbrakk> \<Longrightarrow> summable f \<and> suminf f \<le> suminf g"
   589 apply (subgoal_tac "summable f")
   590 apply (auto intro!: summable_le)
   591 apply (simp add: abs_le_iff)
   592 apply (rule_tac g="g" in summable_comparison_test, simp_all)
   593 done
   594 
   595 (* specialisation for the common 0 case *)
   596 lemma suminf_0_le:
   597   fixes f::"nat\<Rightarrow>real"
   598   assumes gt0: "\<forall>n. 0 \<le> f n" and sm: "summable f"
   599   shows "0 \<le> suminf f"
   600 proof -
   601   let ?g = "(\<lambda>n. (0::real))"
   602   from gt0 have "\<forall>n. ?g n \<le> f n" by simp
   603   moreover have "summable ?g" by (rule summable_zero)
   604   moreover from sm have "summable f" .
   605   ultimately have "suminf ?g \<le> suminf f" by (rule summable_le)
   606   then show "0 \<le> suminf f" by simp
   607 qed
   608 
   609 
   610 text{*Absolute convergence imples normal convergence*}
   611 lemma summable_norm_cancel:
   612   fixes f :: "nat \<Rightarrow> 'a::banach"
   613   shows "summable (\<lambda>n. norm (f n)) \<Longrightarrow> summable f"
   614 apply (simp only: summable_Cauchy, safe)
   615 apply (drule_tac x="e" in spec, safe)
   616 apply (rule_tac x="N" in exI, safe)
   617 apply (drule_tac x="m" in spec, safe)
   618 apply (rule order_le_less_trans [OF norm_setsum])
   619 apply (rule order_le_less_trans [OF abs_ge_self])
   620 apply simp
   621 done
   622 
   623 lemma summable_rabs_cancel:
   624   fixes f :: "nat \<Rightarrow> real"
   625   shows "summable (\<lambda>n. \<bar>f n\<bar>) \<Longrightarrow> summable f"
   626 by (rule summable_norm_cancel, simp)
   627 
   628 text{*Absolute convergence of series*}
   629 lemma summable_norm:
   630   fixes f :: "nat \<Rightarrow> 'a::banach"
   631   shows "summable (\<lambda>n. norm (f n)) \<Longrightarrow> norm (suminf f) \<le> (\<Sum>n. norm (f n))"
   632   by (auto intro: LIMSEQ_le tendsto_norm summable_norm_cancel
   633                 summable_sumr_LIMSEQ_suminf norm_setsum)
   634 
   635 lemma summable_rabs:
   636   fixes f :: "nat \<Rightarrow> real"
   637   shows "summable (\<lambda>n. \<bar>f n\<bar>) \<Longrightarrow> \<bar>suminf f\<bar> \<le> (\<Sum>n. \<bar>f n\<bar>)"
   638 by (fold real_norm_def, rule summable_norm)
   639 
   640 subsection{* The Ratio Test*}
   641 
   642 lemma norm_ratiotest_lemma:
   643   fixes x y :: "'a::real_normed_vector"
   644   shows "\<lbrakk>c \<le> 0; norm x \<le> c * norm y\<rbrakk> \<Longrightarrow> x = 0"
   645 apply (subgoal_tac "norm x \<le> 0", simp)
   646 apply (erule order_trans)
   647 apply (simp add: mult_le_0_iff)
   648 done
   649 
   650 lemma rabs_ratiotest_lemma: "[| c \<le> 0; abs x \<le> c * abs y |] ==> x = (0::real)"
   651 by (erule norm_ratiotest_lemma, simp)
   652 
   653 lemma le_Suc_ex: "(k::nat) \<le> l ==> (\<exists>n. l = k + n)"
   654 apply (drule le_imp_less_or_eq)
   655 apply (auto dest: less_imp_Suc_add)
   656 done
   657 
   658 lemma le_Suc_ex_iff: "((k::nat) \<le> l) = (\<exists>n. l = k + n)"
   659 by (auto simp add: le_Suc_ex)
   660 
   661 (*All this trouble just to get 0<c *)
   662 lemma ratio_test_lemma2:
   663   fixes f :: "nat \<Rightarrow> 'a::banach"
   664   shows "\<lbrakk>\<forall>n\<ge>N. norm (f (Suc n)) \<le> c * norm (f n)\<rbrakk> \<Longrightarrow> 0 < c \<or> summable f"
   665 apply (simp (no_asm) add: linorder_not_le [symmetric])
   666 apply (simp add: summable_Cauchy)
   667 apply (safe, subgoal_tac "\<forall>n. N < n --> f (n) = 0")
   668  prefer 2
   669  apply clarify
   670  apply(erule_tac x = "n - Suc 0" in allE)
   671  apply (simp add:diff_Suc split:nat.splits)
   672  apply (blast intro: norm_ratiotest_lemma)
   673 apply (rule_tac x = "Suc N" in exI, clarify)
   674 apply(simp cong del: setsum_cong cong: setsum_ivl_cong)
   675 done
   676 
   677 lemma ratio_test:
   678   fixes f :: "nat \<Rightarrow> 'a::banach"
   679   shows "\<lbrakk>c < 1; \<forall>n\<ge>N. norm (f (Suc n)) \<le> c * norm (f n)\<rbrakk> \<Longrightarrow> summable f"
   680 apply (frule ratio_test_lemma2, auto)
   681 apply (rule_tac g = "%n. (norm (f N) / (c ^ N))*c ^ n"
   682        in summable_comparison_test)
   683 apply (rule_tac x = N in exI, safe)
   684 apply (drule le_Suc_ex_iff [THEN iffD1])
   685 apply (auto simp add: power_add field_power_not_zero)
   686 apply (induct_tac "na", auto)
   687 apply (rule_tac y = "c * norm (f (N + n))" in order_trans)
   688 apply (auto intro: mult_right_mono simp add: summable_def)
   689 apply (rule_tac x = "norm (f N) * (1/ (1 - c)) / (c ^ N)" in exI)
   690 apply (rule sums_divide)
   691 apply (rule sums_mult)
   692 apply (auto intro!: geometric_sums)
   693 done
   694 
   695 subsection {* Cauchy Product Formula *}
   696 
   697 (* Proof based on Analysis WebNotes: Chapter 07, Class 41
   698 http://www.math.unl.edu/~webnotes/classes/class41/prp77.htm *)
   699 
   700 lemma setsum_triangle_reindex:
   701   fixes n :: nat
   702   shows "(\<Sum>(i,j)\<in>{(i,j). i+j < n}. f i j) = (\<Sum>k=0..<n. \<Sum>i=0..k. f i (k - i))"
   703 proof -
   704   have "(\<Sum>(i, j)\<in>{(i, j). i + j < n}. f i j) =
   705     (\<Sum>(k, i)\<in>(SIGMA k:{0..<n}. {0..k}). f i (k - i))"
   706   proof (rule setsum_reindex_cong)
   707     show "inj_on (\<lambda>(k,i). (i, k - i)) (SIGMA k:{0..<n}. {0..k})"
   708       by (rule inj_on_inverseI [where g="\<lambda>(i,j). (i+j, i)"], auto)
   709     show "{(i,j). i + j < n} = (\<lambda>(k,i). (i, k - i)) ` (SIGMA k:{0..<n}. {0..k})"
   710       by (safe, rule_tac x="(a+b,a)" in image_eqI, auto)
   711     show "\<And>a. (\<lambda>(k, i). f i (k - i)) a = split f ((\<lambda>(k, i). (i, k - i)) a)"
   712       by clarify
   713   qed
   714   thus ?thesis by (simp add: setsum_Sigma)
   715 qed
   716 
   717 lemma Cauchy_product_sums:
   718   fixes a b :: "nat \<Rightarrow> 'a::{real_normed_algebra,banach}"
   719   assumes a: "summable (\<lambda>k. norm (a k))"
   720   assumes b: "summable (\<lambda>k. norm (b k))"
   721   shows "(\<lambda>k. \<Sum>i=0..k. a i * b (k - i)) sums ((\<Sum>k. a k) * (\<Sum>k. b k))"
   722 proof -
   723   let ?S1 = "\<lambda>n::nat. {0..<n} \<times> {0..<n}"
   724   let ?S2 = "\<lambda>n::nat. {(i,j). i + j < n}"
   725   have S1_mono: "\<And>m n. m \<le> n \<Longrightarrow> ?S1 m \<subseteq> ?S1 n" by auto
   726   have S2_le_S1: "\<And>n. ?S2 n \<subseteq> ?S1 n" by auto
   727   have S1_le_S2: "\<And>n. ?S1 (n div 2) \<subseteq> ?S2 n" by auto
   728   have finite_S1: "\<And>n. finite (?S1 n)" by simp
   729   with S2_le_S1 have finite_S2: "\<And>n. finite (?S2 n)" by (rule finite_subset)
   730 
   731   let ?g = "\<lambda>(i,j). a i * b j"
   732   let ?f = "\<lambda>(i,j). norm (a i) * norm (b j)"
   733   have f_nonneg: "\<And>x. 0 \<le> ?f x"
   734     by (auto simp add: mult_nonneg_nonneg)
   735   hence norm_setsum_f: "\<And>A. norm (setsum ?f A) = setsum ?f A"
   736     unfolding real_norm_def
   737     by (simp only: abs_of_nonneg setsum_nonneg [rule_format])
   738 
   739   have "(\<lambda>n. (\<Sum>k=0..<n. a k) * (\<Sum>k=0..<n. b k))
   740            ----> (\<Sum>k. a k) * (\<Sum>k. b k)"
   741     by (intro tendsto_mult summable_sumr_LIMSEQ_suminf
   742         summable_norm_cancel [OF a] summable_norm_cancel [OF b])
   743   hence 1: "(\<lambda>n. setsum ?g (?S1 n)) ----> (\<Sum>k. a k) * (\<Sum>k. b k)"
   744     by (simp only: setsum_product setsum_Sigma [rule_format]
   745                    finite_atLeastLessThan)
   746 
   747   have "(\<lambda>n. (\<Sum>k=0..<n. norm (a k)) * (\<Sum>k=0..<n. norm (b k)))
   748        ----> (\<Sum>k. norm (a k)) * (\<Sum>k. norm (b k))"
   749     using a b by (intro tendsto_mult summable_sumr_LIMSEQ_suminf)
   750   hence "(\<lambda>n. setsum ?f (?S1 n)) ----> (\<Sum>k. norm (a k)) * (\<Sum>k. norm (b k))"
   751     by (simp only: setsum_product setsum_Sigma [rule_format]
   752                    finite_atLeastLessThan)
   753   hence "convergent (\<lambda>n. setsum ?f (?S1 n))"
   754     by (rule convergentI)
   755   hence Cauchy: "Cauchy (\<lambda>n. setsum ?f (?S1 n))"
   756     by (rule convergent_Cauchy)
   757   have "Zfun (\<lambda>n. setsum ?f (?S1 n - ?S2 n)) sequentially"
   758   proof (rule ZfunI, simp only: eventually_sequentially norm_setsum_f)
   759     fix r :: real
   760     assume r: "0 < r"
   761     from CauchyD [OF Cauchy r] obtain N
   762     where "\<forall>m\<ge>N. \<forall>n\<ge>N. norm (setsum ?f (?S1 m) - setsum ?f (?S1 n)) < r" ..
   763     hence "\<And>m n. \<lbrakk>N \<le> n; n \<le> m\<rbrakk> \<Longrightarrow> norm (setsum ?f (?S1 m - ?S1 n)) < r"
   764       by (simp only: setsum_diff finite_S1 S1_mono)
   765     hence N: "\<And>m n. \<lbrakk>N \<le> n; n \<le> m\<rbrakk> \<Longrightarrow> setsum ?f (?S1 m - ?S1 n) < r"
   766       by (simp only: norm_setsum_f)
   767     show "\<exists>N. \<forall>n\<ge>N. setsum ?f (?S1 n - ?S2 n) < r"
   768     proof (intro exI allI impI)
   769       fix n assume "2 * N \<le> n"
   770       hence n: "N \<le> n div 2" by simp
   771       have "setsum ?f (?S1 n - ?S2 n) \<le> setsum ?f (?S1 n - ?S1 (n div 2))"
   772         by (intro setsum_mono2 finite_Diff finite_S1 f_nonneg
   773                   Diff_mono subset_refl S1_le_S2)
   774       also have "\<dots> < r"
   775         using n div_le_dividend by (rule N)
   776       finally show "setsum ?f (?S1 n - ?S2 n) < r" .
   777     qed
   778   qed
   779   hence "Zfun (\<lambda>n. setsum ?g (?S1 n - ?S2 n)) sequentially"
   780     apply (rule Zfun_le [rule_format])
   781     apply (simp only: norm_setsum_f)
   782     apply (rule order_trans [OF norm_setsum setsum_mono])
   783     apply (auto simp add: norm_mult_ineq)
   784     done
   785   hence 2: "(\<lambda>n. setsum ?g (?S1 n) - setsum ?g (?S2 n)) ----> 0"
   786     unfolding tendsto_Zfun_iff diff_0_right
   787     by (simp only: setsum_diff finite_S1 S2_le_S1)
   788 
   789   with 1 have "(\<lambda>n. setsum ?g (?S2 n)) ----> (\<Sum>k. a k) * (\<Sum>k. b k)"
   790     by (rule LIMSEQ_diff_approach_zero2)
   791   thus ?thesis by (simp only: sums_def setsum_triangle_reindex)
   792 qed
   793 
   794 lemma Cauchy_product:
   795   fixes a b :: "nat \<Rightarrow> 'a::{real_normed_algebra,banach}"
   796   assumes a: "summable (\<lambda>k. norm (a k))"
   797   assumes b: "summable (\<lambda>k. norm (b k))"
   798   shows "(\<Sum>k. a k) * (\<Sum>k. b k) = (\<Sum>k. \<Sum>i=0..k. a i * b (k - i))"
   799 using a b
   800 by (rule Cauchy_product_sums [THEN sums_unique])
   801 
   802 end