src/HOL/Real/RComplete.thy
author wenzelm
Fri Jun 02 23:22:29 2006 +0200 (2006-06-02)
changeset 19765 dfe940911617
parent 16893 0cc94e6f6ae5
child 19850 29c125556d86
permissions -rw-r--r--
misc cleanup;
     1 (*  Title       : HOL/Real/RComplete.thy
     2     ID          : $Id$
     3     Author      : Jacques D. Fleuriot, University of Edinburgh
     4     Author      : Larry Paulson, University of Cambridge
     5     Author      : Jeremy Avigad, Carnegie Mellon University
     6     Author      : Florian Zuleger, Johannes Hoelzl, and Simon Funke, TU Muenchen
     7 *)
     8 
     9 header {* Completeness of the Reals; Floor and Ceiling Functions *}
    10 
    11 theory RComplete
    12 imports Lubs RealDef
    13 begin
    14 
    15 lemma real_sum_of_halves: "x/2 + x/2 = (x::real)"
    16   by simp
    17 
    18 
    19 subsection {* Completeness of Positive Reals *}
    20 
    21 text {*
    22   Supremum property for the set of positive reals
    23 
    24   Let @{text "P"} be a non-empty set of positive reals, with an upper
    25   bound @{text "y"}.  Then @{text "P"} has a least upper bound
    26   (written @{text "S"}).
    27 
    28   FIXME: Can the premise be weakened to @{text "\<forall>x \<in> P. x\<le> y"}?
    29 *}
    30 
    31 lemma posreal_complete:
    32   assumes positive_P: "\<forall>x \<in> P. (0::real) < x"
    33     and not_empty_P: "\<exists>x. x \<in> P"
    34     and upper_bound_Ex: "\<exists>y. \<forall>x \<in> P. x<y"
    35   shows "\<exists>S. \<forall>y. (\<exists>x \<in> P. y < x) = (y < S)"
    36 proof (rule exI, rule allI)
    37   fix y
    38   let ?pP = "{w. real_of_preal w \<in> P}"
    39 
    40   show "(\<exists>x\<in>P. y < x) = (y < real_of_preal (psup ?pP))"
    41   proof (cases "0 < y")
    42     assume neg_y: "\<not> 0 < y"
    43     show ?thesis
    44     proof
    45       assume "\<exists>x\<in>P. y < x"
    46       have "\<forall>x. y < real_of_preal x"
    47         using neg_y by (rule real_less_all_real2)
    48       thus "y < real_of_preal (psup ?pP)" ..
    49     next
    50       assume "y < real_of_preal (psup ?pP)"
    51       obtain "x" where x_in_P: "x \<in> P" using not_empty_P ..
    52       hence "0 < x" using positive_P by simp
    53       hence "y < x" using neg_y by simp
    54       thus "\<exists>x \<in> P. y < x" using x_in_P ..
    55     qed
    56   next
    57     assume pos_y: "0 < y"
    58 
    59     then obtain py where y_is_py: "y = real_of_preal py"
    60       by (auto simp add: real_gt_zero_preal_Ex)
    61 
    62     obtain a where a_in_P: "a \<in> P" using not_empty_P ..
    63     have a_pos: "0 < a" using positive_P ..
    64     then obtain pa where "a = real_of_preal pa"
    65       by (auto simp add: real_gt_zero_preal_Ex)
    66     hence "pa \<in> ?pP" using a_in_P by auto
    67     hence pP_not_empty: "?pP \<noteq> {}" by auto
    68 
    69     obtain sup where sup: "\<forall>x \<in> P. x < sup"
    70       using upper_bound_Ex ..
    71     hence  "a < sup" ..
    72     hence "0 < sup" using a_pos by arith
    73     then obtain possup where "sup = real_of_preal possup"
    74       by (auto simp add: real_gt_zero_preal_Ex)
    75     hence "\<forall>X \<in> ?pP. X \<le> possup"
    76       using sup by (auto simp add: real_of_preal_lessI)
    77     with pP_not_empty have psup: "\<And>Z. (\<exists>X \<in> ?pP. Z < X) = (Z < psup ?pP)"
    78       by (rule preal_complete)
    79 
    80     show ?thesis
    81     proof
    82       assume "\<exists>x \<in> P. y < x"
    83       then obtain x where x_in_P: "x \<in> P" and y_less_x: "y < x" ..
    84       hence "0 < x" using pos_y by arith
    85       then obtain px where x_is_px: "x = real_of_preal px"
    86         by (auto simp add: real_gt_zero_preal_Ex)
    87 
    88       have py_less_X: "\<exists>X \<in> ?pP. py < X"
    89       proof
    90         show "py < px" using y_is_py and x_is_px and y_less_x
    91           by (simp add: real_of_preal_lessI)
    92         show "px \<in> ?pP" using x_in_P and x_is_px by simp
    93       qed
    94 
    95       have "(\<exists>X \<in> ?pP. py < X) ==> (py < psup ?pP)"
    96         using psup by simp
    97       hence "py < psup ?pP" using py_less_X by simp
    98       thus "y < real_of_preal (psup {w. real_of_preal w \<in> P})"
    99         using y_is_py and pos_y by (simp add: real_of_preal_lessI)
   100     next
   101       assume y_less_psup: "y < real_of_preal (psup ?pP)"
   102 
   103       hence "py < psup ?pP" using y_is_py
   104         by (simp add: real_of_preal_lessI)
   105       then obtain "X" where py_less_X: "py < X" and X_in_pP: "X \<in> ?pP"
   106         using psup by auto
   107       then obtain x where x_is_X: "x = real_of_preal X"
   108         by (simp add: real_gt_zero_preal_Ex)
   109       hence "y < x" using py_less_X and y_is_py
   110         by (simp add: real_of_preal_lessI)
   111 
   112       moreover have "x \<in> P" using x_is_X and X_in_pP by simp
   113 
   114       ultimately show "\<exists> x \<in> P. y < x" ..
   115     qed
   116   qed
   117 qed
   118 
   119 text {*
   120   \medskip Completeness properties using @{text "isUb"}, @{text "isLub"} etc.
   121 *}
   122 
   123 lemma real_isLub_unique: "[| isLub R S x; isLub R S y |] ==> x = (y::real)"
   124   apply (frule isLub_isUb)
   125   apply (frule_tac x = y in isLub_isUb)
   126   apply (blast intro!: order_antisym dest!: isLub_le_isUb)
   127   done
   128 
   129 
   130 text {*
   131   \medskip Completeness theorem for the positive reals (again).
   132 *}
   133 
   134 lemma posreals_complete:
   135   assumes positive_S: "\<forall>x \<in> S. 0 < x"
   136     and not_empty_S: "\<exists>x. x \<in> S"
   137     and upper_bound_Ex: "\<exists>u. isUb (UNIV::real set) S u"
   138   shows "\<exists>t. isLub (UNIV::real set) S t"
   139 proof
   140   let ?pS = "{w. real_of_preal w \<in> S}"
   141 
   142   obtain u where "isUb UNIV S u" using upper_bound_Ex ..
   143   hence sup: "\<forall>x \<in> S. x \<le> u" by (simp add: isUb_def setle_def)
   144 
   145   obtain x where x_in_S: "x \<in> S" using not_empty_S ..
   146   hence x_gt_zero: "0 < x" using positive_S by simp
   147   have  "x \<le> u" using sup and x_in_S ..
   148   hence "0 < u" using x_gt_zero by arith
   149 
   150   then obtain pu where u_is_pu: "u = real_of_preal pu"
   151     by (auto simp add: real_gt_zero_preal_Ex)
   152 
   153   have pS_less_pu: "\<forall>pa \<in> ?pS. pa \<le> pu"
   154   proof
   155     fix pa
   156     assume "pa \<in> ?pS"
   157     then obtain a where "a \<in> S" and "a = real_of_preal pa"
   158       by simp
   159     moreover hence "a \<le> u" using sup by simp
   160     ultimately show "pa \<le> pu"
   161       using sup and u_is_pu by (simp add: real_of_preal_le_iff)
   162   qed
   163 
   164   have "\<forall>y \<in> S. y \<le> real_of_preal (psup ?pS)"
   165   proof
   166     fix y
   167     assume y_in_S: "y \<in> S"
   168     hence "0 < y" using positive_S by simp
   169     then obtain py where y_is_py: "y = real_of_preal py"
   170       by (auto simp add: real_gt_zero_preal_Ex)
   171     hence py_in_pS: "py \<in> ?pS" using y_in_S by simp
   172     with pS_less_pu have "py \<le> psup ?pS"
   173       by (rule preal_psup_le)
   174     thus "y \<le> real_of_preal (psup ?pS)"
   175       using y_is_py by (simp add: real_of_preal_le_iff)
   176   qed
   177 
   178   moreover {
   179     fix x
   180     assume x_ub_S: "\<forall>y\<in>S. y \<le> x"
   181     have "real_of_preal (psup ?pS) \<le> x"
   182     proof -
   183       obtain "s" where s_in_S: "s \<in> S" using not_empty_S ..
   184       hence s_pos: "0 < s" using positive_S by simp
   185 
   186       hence "\<exists> ps. s = real_of_preal ps" by (simp add: real_gt_zero_preal_Ex)
   187       then obtain "ps" where s_is_ps: "s = real_of_preal ps" ..
   188       hence ps_in_pS: "ps \<in> {w. real_of_preal w \<in> S}" using s_in_S by simp
   189 
   190       from x_ub_S have "s \<le> x" using s_in_S ..
   191       hence "0 < x" using s_pos by simp
   192       hence "\<exists> px. x = real_of_preal px" by (simp add: real_gt_zero_preal_Ex)
   193       then obtain "px" where x_is_px: "x = real_of_preal px" ..
   194 
   195       have "\<forall>pe \<in> ?pS. pe \<le> px"
   196       proof
   197 	fix pe
   198 	assume "pe \<in> ?pS"
   199 	hence "real_of_preal pe \<in> S" by simp
   200 	hence "real_of_preal pe \<le> x" using x_ub_S by simp
   201 	thus "pe \<le> px" using x_is_px by (simp add: real_of_preal_le_iff)
   202       qed
   203 
   204       moreover have "?pS \<noteq> {}" using ps_in_pS by auto
   205       ultimately have "(psup ?pS) \<le> px" by (simp add: psup_le_ub)
   206       thus "real_of_preal (psup ?pS) \<le> x" using x_is_px by (simp add: real_of_preal_le_iff)
   207     qed
   208   }
   209   ultimately show "isLub UNIV S (real_of_preal (psup ?pS))"
   210     by (simp add: isLub_def leastP_def isUb_def setle_def setge_def)
   211 qed
   212 
   213 text {*
   214   \medskip reals Completeness (again!)
   215 *}
   216 
   217 lemma reals_complete:
   218   assumes notempty_S: "\<exists>X. X \<in> S"
   219     and exists_Ub: "\<exists>Y. isUb (UNIV::real set) S Y"
   220   shows "\<exists>t. isLub (UNIV :: real set) S t"
   221 proof -
   222   obtain X where X_in_S: "X \<in> S" using notempty_S ..
   223   obtain Y where Y_isUb: "isUb (UNIV::real set) S Y"
   224     using exists_Ub ..
   225   let ?SHIFT = "{z. \<exists>x \<in>S. z = x + (-X) + 1} \<inter> {x. 0 < x}"
   226 
   227   {
   228     fix x
   229     assume "isUb (UNIV::real set) S x"
   230     hence S_le_x: "\<forall> y \<in> S. y <= x"
   231       by (simp add: isUb_def setle_def)
   232     {
   233       fix s
   234       assume "s \<in> {z. \<exists>x\<in>S. z = x + - X + 1}"
   235       hence "\<exists> x \<in> S. s = x + -X + 1" ..
   236       then obtain x1 where "x1 \<in> S" and "s = x1 + (-X) + 1" ..
   237       moreover hence "x1 \<le> x" using S_le_x by simp
   238       ultimately have "s \<le> x + - X + 1" by arith
   239     }
   240     then have "isUb (UNIV::real set) ?SHIFT (x + (-X) + 1)"
   241       by (auto simp add: isUb_def setle_def)
   242   } note S_Ub_is_SHIFT_Ub = this
   243 
   244   hence "isUb UNIV ?SHIFT (Y + (-X) + 1)" using Y_isUb by simp
   245   hence "\<exists>Z. isUb UNIV ?SHIFT Z" ..
   246   moreover have "\<forall>y \<in> ?SHIFT. 0 < y" by auto
   247   moreover have shifted_not_empty: "\<exists>u. u \<in> ?SHIFT"
   248     using X_in_S and Y_isUb by auto
   249   ultimately obtain t where t_is_Lub: "isLub UNIV ?SHIFT t"
   250     using posreals_complete [of ?SHIFT] by blast
   251 
   252   show ?thesis
   253   proof
   254     show "isLub UNIV S (t + X + (-1))"
   255     proof (rule isLubI2)
   256       {
   257         fix x
   258         assume "isUb (UNIV::real set) S x"
   259         hence "isUb (UNIV::real set) (?SHIFT) (x + (-X) + 1)"
   260 	  using S_Ub_is_SHIFT_Ub by simp
   261         hence "t \<le> (x + (-X) + 1)"
   262 	  using t_is_Lub by (simp add: isLub_le_isUb)
   263         hence "t + X + -1 \<le> x" by arith
   264       }
   265       then show "(t + X + -1) <=* Collect (isUb UNIV S)"
   266 	by (simp add: setgeI)
   267     next
   268       show "isUb UNIV S (t + X + -1)"
   269       proof -
   270         {
   271           fix y
   272           assume y_in_S: "y \<in> S"
   273           have "y \<le> t + X + -1"
   274           proof -
   275             obtain "u" where u_in_shift: "u \<in> ?SHIFT" using shifted_not_empty ..
   276             hence "\<exists> x \<in> S. u = x + - X + 1" by simp
   277             then obtain "x" where x_and_u: "u = x + - X + 1" ..
   278             have u_le_t: "u \<le> t" using u_in_shift and t_is_Lub by (simp add: isLubD2)
   279 
   280             show ?thesis
   281             proof cases
   282               assume "y \<le> x"
   283               moreover have "x = u + X + - 1" using x_and_u by arith
   284               moreover have "u + X + - 1  \<le> t + X + -1" using u_le_t by arith
   285               ultimately show "y  \<le> t + X + -1" by arith
   286             next
   287               assume "~(y \<le> x)"
   288               hence x_less_y: "x < y" by arith
   289 
   290               have "x + (-X) + 1 \<in> ?SHIFT" using x_and_u and u_in_shift by simp
   291               hence "0 < x + (-X) + 1" by simp
   292               hence "0 < y + (-X) + 1" using x_less_y by arith
   293               hence "y + (-X) + 1 \<in> ?SHIFT" using y_in_S by simp
   294               hence "y + (-X) + 1 \<le> t" using t_is_Lub  by (simp add: isLubD2)
   295               thus ?thesis by simp
   296             qed
   297           qed
   298         }
   299         then show ?thesis by (simp add: isUb_def setle_def)
   300       qed
   301     qed
   302   qed
   303 qed
   304 
   305 
   306 subsection {* The Archimedean Property of the Reals *}
   307 
   308 theorem reals_Archimedean:
   309   assumes x_pos: "0 < x"
   310   shows "\<exists>n. inverse (real (Suc n)) < x"
   311 proof (rule ccontr)
   312   assume contr: "\<not> ?thesis"
   313   have "\<forall>n. x * real (Suc n) <= 1"
   314   proof
   315     fix n
   316     from contr have "x \<le> inverse (real (Suc n))"
   317       by (simp add: linorder_not_less)
   318     hence "x \<le> (1 / (real (Suc n)))"
   319       by (simp add: inverse_eq_divide)
   320     moreover have "0 \<le> real (Suc n)"
   321       by (rule real_of_nat_ge_zero)
   322     ultimately have "x * real (Suc n) \<le> (1 / real (Suc n)) * real (Suc n)"
   323       by (rule mult_right_mono)
   324     thus "x * real (Suc n) \<le> 1" by simp
   325   qed
   326   hence "{z. \<exists>n. z = x * (real (Suc n))} *<= 1"
   327     by (simp add: setle_def, safe, rule spec)
   328   hence "isUb (UNIV::real set) {z. \<exists>n. z = x * (real (Suc n))} 1"
   329     by (simp add: isUbI)
   330   hence "\<exists>Y. isUb (UNIV::real set) {z. \<exists>n. z = x* (real (Suc n))} Y" ..
   331   moreover have "\<exists>X. X \<in> {z. \<exists>n. z = x* (real (Suc n))}" by auto
   332   ultimately have "\<exists>t. isLub UNIV {z. \<exists>n. z = x * real (Suc n)} t"
   333     by (simp add: reals_complete)
   334   then obtain "t" where
   335     t_is_Lub: "isLub UNIV {z. \<exists>n. z = x * real (Suc n)} t" ..
   336 
   337   have "\<forall>n::nat. x * real n \<le> t + - x"
   338   proof
   339     fix n
   340     from t_is_Lub have "x * real (Suc n) \<le> t"
   341       by (simp add: isLubD2)
   342     hence  "x * (real n) + x \<le> t"
   343       by (simp add: right_distrib real_of_nat_Suc)
   344     thus  "x * (real n) \<le> t + - x" by arith
   345   qed
   346 
   347   hence "\<forall>m. x * real (Suc m) \<le> t + - x" by simp
   348   hence "{z. \<exists>n. z = x * (real (Suc n))}  *<= (t + - x)"
   349     by (auto simp add: setle_def)
   350   hence "isUb (UNIV::real set) {z. \<exists>n. z = x * (real (Suc n))} (t + (-x))"
   351     by (simp add: isUbI)
   352   hence "t \<le> t + - x"
   353     using t_is_Lub by (simp add: isLub_le_isUb)
   354   thus False using x_pos by arith
   355 qed
   356 
   357 text {*
   358   There must be other proofs, e.g. @{text "Suc"} of the largest
   359   integer in the cut representing @{text "x"}.
   360 *}
   361 
   362 lemma reals_Archimedean2: "\<exists>n. (x::real) < real (n::nat)"
   363 proof cases
   364   assume "x \<le> 0"
   365   hence "x < real (1::nat)" by simp
   366   thus ?thesis ..
   367 next
   368   assume "\<not> x \<le> 0"
   369   hence x_greater_zero: "0 < x" by simp
   370   hence "0 < inverse x" by simp
   371   then obtain n where "inverse (real (Suc n)) < inverse x"
   372     using reals_Archimedean by blast
   373   hence "inverse (real (Suc n)) * x < inverse x * x"
   374     using x_greater_zero by (rule mult_strict_right_mono)
   375   hence "inverse (real (Suc n)) * x < 1"
   376     using x_greater_zero by (simp add: real_mult_inverse_left mult_commute)
   377   hence "real (Suc n) * (inverse (real (Suc n)) * x) < real (Suc n) * 1"
   378     by (rule mult_strict_left_mono) simp
   379   hence "x < real (Suc n)"
   380     by (simp add: mult_commute ring_eq_simps real_mult_inverse_left)
   381   thus "\<exists>(n::nat). x < real n" ..
   382 qed
   383 
   384 lemma reals_Archimedean3:
   385   assumes x_greater_zero: "0 < x"
   386   shows "\<forall>(y::real). \<exists>(n::nat). y < real n * x"
   387 proof
   388   fix y
   389   have x_not_zero: "x \<noteq> 0" using x_greater_zero by simp
   390   obtain n where "y * inverse x < real (n::nat)"
   391     using reals_Archimedean2 ..
   392   hence "y * inverse x * x < real n * x"
   393     using x_greater_zero by (simp add: mult_strict_right_mono)
   394   hence "x * inverse x * y < x * real n"
   395     by (simp add: mult_commute ring_eq_simps)
   396   hence "y < real (n::nat) * x"
   397     using x_not_zero by (simp add: real_mult_inverse_left ring_eq_simps)
   398   thus "\<exists>(n::nat). y < real n * x" ..
   399 qed
   400 
   401 lemma reals_Archimedean6:
   402      "0 \<le> r ==> \<exists>(n::nat). real (n - 1) \<le> r & r < real (n)"
   403 apply (insert reals_Archimedean2 [of r], safe)
   404 apply (frule_tac P = "%k. r < real k" and k = n and m = "%x. x"
   405        in ex_has_least_nat, auto)
   406 apply (rule_tac x = x in exI)
   407 apply (case_tac x, simp)
   408 apply (rename_tac x')
   409 apply (drule_tac x = x' in spec, simp)
   410 done
   411 
   412 lemma reals_Archimedean6a: "0 \<le> r ==> \<exists>n. real (n) \<le> r & r < real (Suc n)"
   413   by (drule reals_Archimedean6) auto
   414 
   415 lemma reals_Archimedean_6b_int:
   416      "0 \<le> r ==> \<exists>n::int. real n \<le> r & r < real (n+1)"
   417 apply (drule reals_Archimedean6a, auto)
   418 apply (rule_tac x = "int n" in exI)
   419 apply (simp add: real_of_int_real_of_nat real_of_nat_Suc)
   420 done
   421 
   422 lemma reals_Archimedean_6c_int:
   423      "r < 0 ==> \<exists>n::int. real n \<le> r & r < real (n+1)"
   424 apply (rule reals_Archimedean_6b_int [of "-r", THEN exE], simp, auto)
   425 apply (rename_tac n)
   426 apply (drule real_le_imp_less_or_eq, auto)
   427 apply (rule_tac x = "- n - 1" in exI)
   428 apply (rule_tac [2] x = "- n" in exI, auto)
   429 done
   430 
   431 
   432 subsection{*Floor and Ceiling Functions from the Reals to the Integers*}
   433 
   434 definition
   435   floor :: "real => int"
   436   "floor r = (LEAST n::int. r < real (n+1))"
   437 
   438   ceiling :: "real => int"
   439   "ceiling r = - floor (- r)"
   440 
   441 const_syntax (xsymbols)
   442   floor  ("\<lfloor>_\<rfloor>")
   443   ceiling  ("\<lceil>_\<rceil>")
   444 
   445 const_syntax (HTML output)
   446   floor  ("\<lfloor>_\<rfloor>")
   447   ceiling  ("\<lceil>_\<rceil>")
   448 
   449 
   450 lemma number_of_less_real_of_int_iff [simp]:
   451      "((number_of n) < real (m::int)) = (number_of n < m)"
   452 apply auto
   453 apply (rule real_of_int_less_iff [THEN iffD1])
   454 apply (drule_tac [2] real_of_int_less_iff [THEN iffD2], auto)
   455 done
   456 
   457 lemma number_of_less_real_of_int_iff2 [simp]:
   458      "(real (m::int) < (number_of n)) = (m < number_of n)"
   459 apply auto
   460 apply (rule real_of_int_less_iff [THEN iffD1])
   461 apply (drule_tac [2] real_of_int_less_iff [THEN iffD2], auto)
   462 done
   463 
   464 lemma number_of_le_real_of_int_iff [simp]:
   465      "((number_of n) \<le> real (m::int)) = (number_of n \<le> m)"
   466 by (simp add: linorder_not_less [symmetric])
   467 
   468 lemma number_of_le_real_of_int_iff2 [simp]:
   469      "(real (m::int) \<le> (number_of n)) = (m \<le> number_of n)"
   470 by (simp add: linorder_not_less [symmetric])
   471 
   472 lemma floor_zero [simp]: "floor 0 = 0"
   473 apply (simp add: floor_def del: real_of_int_add)
   474 apply (rule Least_equality)
   475 apply simp_all
   476 done
   477 
   478 lemma floor_real_of_nat_zero [simp]: "floor (real (0::nat)) = 0"
   479 by auto
   480 
   481 lemma floor_real_of_nat [simp]: "floor (real (n::nat)) = int n"
   482 apply (simp only: floor_def)
   483 apply (rule Least_equality)
   484 apply (drule_tac [2] real_of_int_real_of_nat [THEN ssubst])
   485 apply (drule_tac [2] real_of_int_less_iff [THEN iffD1])
   486 apply (simp_all add: real_of_int_real_of_nat)
   487 done
   488 
   489 lemma floor_minus_real_of_nat [simp]: "floor (- real (n::nat)) = - int n"
   490 apply (simp only: floor_def)
   491 apply (rule Least_equality)
   492 apply (drule_tac [2] real_of_int_real_of_nat [THEN ssubst])
   493 apply (drule_tac [2] real_of_int_minus [THEN sym, THEN subst])
   494 apply (drule_tac [2] real_of_int_less_iff [THEN iffD1])
   495 apply (simp_all add: real_of_int_real_of_nat)
   496 done
   497 
   498 lemma floor_real_of_int [simp]: "floor (real (n::int)) = n"
   499 apply (simp only: floor_def)
   500 apply (rule Least_equality)
   501 apply (drule_tac [2] real_of_int_real_of_nat [THEN ssubst])
   502 apply (drule_tac [2] real_of_int_less_iff [THEN iffD1], auto)
   503 done
   504 
   505 lemma floor_minus_real_of_int [simp]: "floor (- real (n::int)) = - n"
   506 apply (simp only: floor_def)
   507 apply (rule Least_equality)
   508 apply (drule_tac [2] real_of_int_minus [THEN sym, THEN subst])
   509 apply (drule_tac [2] real_of_int_real_of_nat [THEN ssubst])
   510 apply (drule_tac [2] real_of_int_less_iff [THEN iffD1], auto)
   511 done
   512 
   513 lemma real_lb_ub_int: " \<exists>n::int. real n \<le> r & r < real (n+1)"
   514 apply (case_tac "r < 0")
   515 apply (blast intro: reals_Archimedean_6c_int)
   516 apply (simp only: linorder_not_less)
   517 apply (blast intro: reals_Archimedean_6b_int reals_Archimedean_6c_int)
   518 done
   519 
   520 lemma lemma_floor:
   521   assumes a1: "real m \<le> r" and a2: "r < real n + 1"
   522   shows "m \<le> (n::int)"
   523 proof -
   524   have "real m < real n + 1" by (rule order_le_less_trans)
   525   also have "... = real(n+1)" by simp
   526   finally have "m < n+1" by (simp only: real_of_int_less_iff)
   527   thus ?thesis by arith
   528 qed
   529 
   530 lemma real_of_int_floor_le [simp]: "real (floor r) \<le> r"
   531 apply (simp add: floor_def Least_def)
   532 apply (insert real_lb_ub_int [of r], safe)
   533 apply (rule theI2)
   534 apply auto
   535 done
   536 
   537 lemma floor_mono: "x < y ==> floor x \<le> floor y"
   538 apply (simp add: floor_def Least_def)
   539 apply (insert real_lb_ub_int [of x])
   540 apply (insert real_lb_ub_int [of y], safe)
   541 apply (rule theI2)
   542 apply (rule_tac [3] theI2)
   543 apply simp
   544 apply (erule conjI)
   545 apply (auto simp add: order_eq_iff int_le_real_less)
   546 done
   547 
   548 lemma floor_mono2: "x \<le> y ==> floor x \<le> floor y"
   549 by (auto dest: real_le_imp_less_or_eq simp add: floor_mono)
   550 
   551 lemma lemma_floor2: "real n < real (x::int) + 1 ==> n \<le> x"
   552 by (auto intro: lemma_floor)
   553 
   554 lemma real_of_int_floor_cancel [simp]:
   555     "(real (floor x) = x) = (\<exists>n::int. x = real n)"
   556 apply (simp add: floor_def Least_def)
   557 apply (insert real_lb_ub_int [of x], erule exE)
   558 apply (rule theI2)
   559 apply (auto intro: lemma_floor)
   560 done
   561 
   562 lemma floor_eq: "[| real n < x; x < real n + 1 |] ==> floor x = n"
   563 apply (simp add: floor_def)
   564 apply (rule Least_equality)
   565 apply (auto intro: lemma_floor)
   566 done
   567 
   568 lemma floor_eq2: "[| real n \<le> x; x < real n + 1 |] ==> floor x = n"
   569 apply (simp add: floor_def)
   570 apply (rule Least_equality)
   571 apply (auto intro: lemma_floor)
   572 done
   573 
   574 lemma floor_eq3: "[| real n < x; x < real (Suc n) |] ==> nat(floor x) = n"
   575 apply (rule inj_int [THEN injD])
   576 apply (simp add: real_of_nat_Suc)
   577 apply (simp add: real_of_nat_Suc floor_eq floor_eq [where n = "int n"])
   578 done
   579 
   580 lemma floor_eq4: "[| real n \<le> x; x < real (Suc n) |] ==> nat(floor x) = n"
   581 apply (drule order_le_imp_less_or_eq)
   582 apply (auto intro: floor_eq3)
   583 done
   584 
   585 lemma floor_number_of_eq [simp]:
   586      "floor(number_of n :: real) = (number_of n :: int)"
   587 apply (subst real_number_of [symmetric])
   588 apply (rule floor_real_of_int)
   589 done
   590 
   591 lemma floor_one [simp]: "floor 1 = 1"
   592   apply (rule trans)
   593   prefer 2
   594   apply (rule floor_real_of_int)
   595   apply simp
   596 done
   597 
   598 lemma real_of_int_floor_ge_diff_one [simp]: "r - 1 \<le> real(floor r)"
   599 apply (simp add: floor_def Least_def)
   600 apply (insert real_lb_ub_int [of r], safe)
   601 apply (rule theI2)
   602 apply (auto intro: lemma_floor)
   603 done
   604 
   605 lemma real_of_int_floor_gt_diff_one [simp]: "r - 1 < real(floor r)"
   606 apply (simp add: floor_def Least_def)
   607 apply (insert real_lb_ub_int [of r], safe)
   608 apply (rule theI2)
   609 apply (auto intro: lemma_floor)
   610 done
   611 
   612 lemma real_of_int_floor_add_one_ge [simp]: "r \<le> real(floor r) + 1"
   613 apply (insert real_of_int_floor_ge_diff_one [of r])
   614 apply (auto simp del: real_of_int_floor_ge_diff_one)
   615 done
   616 
   617 lemma real_of_int_floor_add_one_gt [simp]: "r < real(floor r) + 1"
   618 apply (insert real_of_int_floor_gt_diff_one [of r])
   619 apply (auto simp del: real_of_int_floor_gt_diff_one)
   620 done
   621 
   622 lemma le_floor: "real a <= x ==> a <= floor x"
   623   apply (subgoal_tac "a < floor x + 1")
   624   apply arith
   625   apply (subst real_of_int_less_iff [THEN sym])
   626   apply simp
   627   apply (insert real_of_int_floor_add_one_gt [of x])
   628   apply arith
   629 done
   630 
   631 lemma real_le_floor: "a <= floor x ==> real a <= x"
   632   apply (rule order_trans)
   633   prefer 2
   634   apply (rule real_of_int_floor_le)
   635   apply (subst real_of_int_le_iff)
   636   apply assumption
   637 done
   638 
   639 lemma le_floor_eq: "(a <= floor x) = (real a <= x)"
   640   apply (rule iffI)
   641   apply (erule real_le_floor)
   642   apply (erule le_floor)
   643 done
   644 
   645 lemma le_floor_eq_number_of [simp]:
   646     "(number_of n <= floor x) = (number_of n <= x)"
   647 by (simp add: le_floor_eq)
   648 
   649 lemma le_floor_eq_zero [simp]: "(0 <= floor x) = (0 <= x)"
   650 by (simp add: le_floor_eq)
   651 
   652 lemma le_floor_eq_one [simp]: "(1 <= floor x) = (1 <= x)"
   653 by (simp add: le_floor_eq)
   654 
   655 lemma floor_less_eq: "(floor x < a) = (x < real a)"
   656   apply (subst linorder_not_le [THEN sym])+
   657   apply simp
   658   apply (rule le_floor_eq)
   659 done
   660 
   661 lemma floor_less_eq_number_of [simp]:
   662     "(floor x < number_of n) = (x < number_of n)"
   663 by (simp add: floor_less_eq)
   664 
   665 lemma floor_less_eq_zero [simp]: "(floor x < 0) = (x < 0)"
   666 by (simp add: floor_less_eq)
   667 
   668 lemma floor_less_eq_one [simp]: "(floor x < 1) = (x < 1)"
   669 by (simp add: floor_less_eq)
   670 
   671 lemma less_floor_eq: "(a < floor x) = (real a + 1 <= x)"
   672   apply (insert le_floor_eq [of "a + 1" x])
   673   apply auto
   674 done
   675 
   676 lemma less_floor_eq_number_of [simp]:
   677     "(number_of n < floor x) = (number_of n + 1 <= x)"
   678 by (simp add: less_floor_eq)
   679 
   680 lemma less_floor_eq_zero [simp]: "(0 < floor x) = (1 <= x)"
   681 by (simp add: less_floor_eq)
   682 
   683 lemma less_floor_eq_one [simp]: "(1 < floor x) = (2 <= x)"
   684 by (simp add: less_floor_eq)
   685 
   686 lemma floor_le_eq: "(floor x <= a) = (x < real a + 1)"
   687   apply (insert floor_less_eq [of x "a + 1"])
   688   apply auto
   689 done
   690 
   691 lemma floor_le_eq_number_of [simp]:
   692     "(floor x <= number_of n) = (x < number_of n + 1)"
   693 by (simp add: floor_le_eq)
   694 
   695 lemma floor_le_eq_zero [simp]: "(floor x <= 0) = (x < 1)"
   696 by (simp add: floor_le_eq)
   697 
   698 lemma floor_le_eq_one [simp]: "(floor x <= 1) = (x < 2)"
   699 by (simp add: floor_le_eq)
   700 
   701 lemma floor_add [simp]: "floor (x + real a) = floor x + a"
   702   apply (subst order_eq_iff)
   703   apply (rule conjI)
   704   prefer 2
   705   apply (subgoal_tac "floor x + a < floor (x + real a) + 1")
   706   apply arith
   707   apply (subst real_of_int_less_iff [THEN sym])
   708   apply simp
   709   apply (subgoal_tac "x + real a < real(floor(x + real a)) + 1")
   710   apply (subgoal_tac "real (floor x) <= x")
   711   apply arith
   712   apply (rule real_of_int_floor_le)
   713   apply (rule real_of_int_floor_add_one_gt)
   714   apply (subgoal_tac "floor (x + real a) < floor x + a + 1")
   715   apply arith
   716   apply (subst real_of_int_less_iff [THEN sym])
   717   apply simp
   718   apply (subgoal_tac "real(floor(x + real a)) <= x + real a")
   719   apply (subgoal_tac "x < real(floor x) + 1")
   720   apply arith
   721   apply (rule real_of_int_floor_add_one_gt)
   722   apply (rule real_of_int_floor_le)
   723 done
   724 
   725 lemma floor_add_number_of [simp]:
   726     "floor (x + number_of n) = floor x + number_of n"
   727   apply (subst floor_add [THEN sym])
   728   apply simp
   729 done
   730 
   731 lemma floor_add_one [simp]: "floor (x + 1) = floor x + 1"
   732   apply (subst floor_add [THEN sym])
   733   apply simp
   734 done
   735 
   736 lemma floor_subtract [simp]: "floor (x - real a) = floor x - a"
   737   apply (subst diff_minus)+
   738   apply (subst real_of_int_minus [THEN sym])
   739   apply (rule floor_add)
   740 done
   741 
   742 lemma floor_subtract_number_of [simp]: "floor (x - number_of n) =
   743     floor x - number_of n"
   744   apply (subst floor_subtract [THEN sym])
   745   apply simp
   746 done
   747 
   748 lemma floor_subtract_one [simp]: "floor (x - 1) = floor x - 1"
   749   apply (subst floor_subtract [THEN sym])
   750   apply simp
   751 done
   752 
   753 lemma ceiling_zero [simp]: "ceiling 0 = 0"
   754 by (simp add: ceiling_def)
   755 
   756 lemma ceiling_real_of_nat [simp]: "ceiling (real (n::nat)) = int n"
   757 by (simp add: ceiling_def)
   758 
   759 lemma ceiling_real_of_nat_zero [simp]: "ceiling (real (0::nat)) = 0"
   760 by auto
   761 
   762 lemma ceiling_floor [simp]: "ceiling (real (floor r)) = floor r"
   763 by (simp add: ceiling_def)
   764 
   765 lemma floor_ceiling [simp]: "floor (real (ceiling r)) = ceiling r"
   766 by (simp add: ceiling_def)
   767 
   768 lemma real_of_int_ceiling_ge [simp]: "r \<le> real (ceiling r)"
   769 apply (simp add: ceiling_def)
   770 apply (subst le_minus_iff, simp)
   771 done
   772 
   773 lemma ceiling_mono: "x < y ==> ceiling x \<le> ceiling y"
   774 by (simp add: floor_mono ceiling_def)
   775 
   776 lemma ceiling_mono2: "x \<le> y ==> ceiling x \<le> ceiling y"
   777 by (simp add: floor_mono2 ceiling_def)
   778 
   779 lemma real_of_int_ceiling_cancel [simp]:
   780      "(real (ceiling x) = x) = (\<exists>n::int. x = real n)"
   781 apply (auto simp add: ceiling_def)
   782 apply (drule arg_cong [where f = uminus], auto)
   783 apply (rule_tac x = "-n" in exI, auto)
   784 done
   785 
   786 lemma ceiling_eq: "[| real n < x; x < real n + 1 |] ==> ceiling x = n + 1"
   787 apply (simp add: ceiling_def)
   788 apply (rule minus_equation_iff [THEN iffD1])
   789 apply (simp add: floor_eq [where n = "-(n+1)"])
   790 done
   791 
   792 lemma ceiling_eq2: "[| real n < x; x \<le> real n + 1 |] ==> ceiling x = n + 1"
   793 by (simp add: ceiling_def floor_eq2 [where n = "-(n+1)"])
   794 
   795 lemma ceiling_eq3: "[| real n - 1 < x; x \<le> real n  |] ==> ceiling x = n"
   796 by (simp add: ceiling_def floor_eq2 [where n = "-n"])
   797 
   798 lemma ceiling_real_of_int [simp]: "ceiling (real (n::int)) = n"
   799 by (simp add: ceiling_def)
   800 
   801 lemma ceiling_number_of_eq [simp]:
   802      "ceiling (number_of n :: real) = (number_of n)"
   803 apply (subst real_number_of [symmetric])
   804 apply (rule ceiling_real_of_int)
   805 done
   806 
   807 lemma ceiling_one [simp]: "ceiling 1 = 1"
   808   by (unfold ceiling_def, simp)
   809 
   810 lemma real_of_int_ceiling_diff_one_le [simp]: "real (ceiling r) - 1 \<le> r"
   811 apply (rule neg_le_iff_le [THEN iffD1])
   812 apply (simp add: ceiling_def diff_minus)
   813 done
   814 
   815 lemma real_of_int_ceiling_le_add_one [simp]: "real (ceiling r) \<le> r + 1"
   816 apply (insert real_of_int_ceiling_diff_one_le [of r])
   817 apply (simp del: real_of_int_ceiling_diff_one_le)
   818 done
   819 
   820 lemma ceiling_le: "x <= real a ==> ceiling x <= a"
   821   apply (unfold ceiling_def)
   822   apply (subgoal_tac "-a <= floor(- x)")
   823   apply simp
   824   apply (rule le_floor)
   825   apply simp
   826 done
   827 
   828 lemma ceiling_le_real: "ceiling x <= a ==> x <= real a"
   829   apply (unfold ceiling_def)
   830   apply (subgoal_tac "real(- a) <= - x")
   831   apply simp
   832   apply (rule real_le_floor)
   833   apply simp
   834 done
   835 
   836 lemma ceiling_le_eq: "(ceiling x <= a) = (x <= real a)"
   837   apply (rule iffI)
   838   apply (erule ceiling_le_real)
   839   apply (erule ceiling_le)
   840 done
   841 
   842 lemma ceiling_le_eq_number_of [simp]:
   843     "(ceiling x <= number_of n) = (x <= number_of n)"
   844 by (simp add: ceiling_le_eq)
   845 
   846 lemma ceiling_le_zero_eq [simp]: "(ceiling x <= 0) = (x <= 0)"
   847 by (simp add: ceiling_le_eq)
   848 
   849 lemma ceiling_le_eq_one [simp]: "(ceiling x <= 1) = (x <= 1)"
   850 by (simp add: ceiling_le_eq)
   851 
   852 lemma less_ceiling_eq: "(a < ceiling x) = (real a < x)"
   853   apply (subst linorder_not_le [THEN sym])+
   854   apply simp
   855   apply (rule ceiling_le_eq)
   856 done
   857 
   858 lemma less_ceiling_eq_number_of [simp]:
   859     "(number_of n < ceiling x) = (number_of n < x)"
   860 by (simp add: less_ceiling_eq)
   861 
   862 lemma less_ceiling_eq_zero [simp]: "(0 < ceiling x) = (0 < x)"
   863 by (simp add: less_ceiling_eq)
   864 
   865 lemma less_ceiling_eq_one [simp]: "(1 < ceiling x) = (1 < x)"
   866 by (simp add: less_ceiling_eq)
   867 
   868 lemma ceiling_less_eq: "(ceiling x < a) = (x <= real a - 1)"
   869   apply (insert ceiling_le_eq [of x "a - 1"])
   870   apply auto
   871 done
   872 
   873 lemma ceiling_less_eq_number_of [simp]:
   874     "(ceiling x < number_of n) = (x <= number_of n - 1)"
   875 by (simp add: ceiling_less_eq)
   876 
   877 lemma ceiling_less_eq_zero [simp]: "(ceiling x < 0) = (x <= -1)"
   878 by (simp add: ceiling_less_eq)
   879 
   880 lemma ceiling_less_eq_one [simp]: "(ceiling x < 1) = (x <= 0)"
   881 by (simp add: ceiling_less_eq)
   882 
   883 lemma le_ceiling_eq: "(a <= ceiling x) = (real a - 1 < x)"
   884   apply (insert less_ceiling_eq [of "a - 1" x])
   885   apply auto
   886 done
   887 
   888 lemma le_ceiling_eq_number_of [simp]:
   889     "(number_of n <= ceiling x) = (number_of n - 1 < x)"
   890 by (simp add: le_ceiling_eq)
   891 
   892 lemma le_ceiling_eq_zero [simp]: "(0 <= ceiling x) = (-1 < x)"
   893 by (simp add: le_ceiling_eq)
   894 
   895 lemma le_ceiling_eq_one [simp]: "(1 <= ceiling x) = (0 < x)"
   896 by (simp add: le_ceiling_eq)
   897 
   898 lemma ceiling_add [simp]: "ceiling (x + real a) = ceiling x + a"
   899   apply (unfold ceiling_def, simp)
   900   apply (subst real_of_int_minus [THEN sym])
   901   apply (subst floor_add)
   902   apply simp
   903 done
   904 
   905 lemma ceiling_add_number_of [simp]: "ceiling (x + number_of n) =
   906     ceiling x + number_of n"
   907   apply (subst ceiling_add [THEN sym])
   908   apply simp
   909 done
   910 
   911 lemma ceiling_add_one [simp]: "ceiling (x + 1) = ceiling x + 1"
   912   apply (subst ceiling_add [THEN sym])
   913   apply simp
   914 done
   915 
   916 lemma ceiling_subtract [simp]: "ceiling (x - real a) = ceiling x - a"
   917   apply (subst diff_minus)+
   918   apply (subst real_of_int_minus [THEN sym])
   919   apply (rule ceiling_add)
   920 done
   921 
   922 lemma ceiling_subtract_number_of [simp]: "ceiling (x - number_of n) =
   923     ceiling x - number_of n"
   924   apply (subst ceiling_subtract [THEN sym])
   925   apply simp
   926 done
   927 
   928 lemma ceiling_subtract_one [simp]: "ceiling (x - 1) = ceiling x - 1"
   929   apply (subst ceiling_subtract [THEN sym])
   930   apply simp
   931 done
   932 
   933 subsection {* Versions for the natural numbers *}
   934 
   935 definition
   936   natfloor :: "real => nat"
   937   "natfloor x = nat(floor x)"
   938   natceiling :: "real => nat"
   939   "natceiling x = nat(ceiling x)"
   940 
   941 lemma natfloor_zero [simp]: "natfloor 0 = 0"
   942   by (unfold natfloor_def, simp)
   943 
   944 lemma natfloor_one [simp]: "natfloor 1 = 1"
   945   by (unfold natfloor_def, simp)
   946 
   947 lemma zero_le_natfloor [simp]: "0 <= natfloor x"
   948   by (unfold natfloor_def, simp)
   949 
   950 lemma natfloor_number_of_eq [simp]: "natfloor (number_of n) = number_of n"
   951   by (unfold natfloor_def, simp)
   952 
   953 lemma natfloor_real_of_nat [simp]: "natfloor(real n) = n"
   954   by (unfold natfloor_def, simp)
   955 
   956 lemma real_natfloor_le: "0 <= x ==> real(natfloor x) <= x"
   957   by (unfold natfloor_def, simp)
   958 
   959 lemma natfloor_neg: "x <= 0 ==> natfloor x = 0"
   960   apply (unfold natfloor_def)
   961   apply (subgoal_tac "floor x <= floor 0")
   962   apply simp
   963   apply (erule floor_mono2)
   964 done
   965 
   966 lemma natfloor_mono: "x <= y ==> natfloor x <= natfloor y"
   967   apply (case_tac "0 <= x")
   968   apply (subst natfloor_def)+
   969   apply (subst nat_le_eq_zle)
   970   apply force
   971   apply (erule floor_mono2)
   972   apply (subst natfloor_neg)
   973   apply simp
   974   apply simp
   975 done
   976 
   977 lemma le_natfloor: "real x <= a ==> x <= natfloor a"
   978   apply (unfold natfloor_def)
   979   apply (subst nat_int [THEN sym])
   980   apply (subst nat_le_eq_zle)
   981   apply simp
   982   apply (rule le_floor)
   983   apply simp
   984 done
   985 
   986 lemma le_natfloor_eq: "0 <= x ==> (a <= natfloor x) = (real a <= x)"
   987   apply (rule iffI)
   988   apply (rule order_trans)
   989   prefer 2
   990   apply (erule real_natfloor_le)
   991   apply (subst real_of_nat_le_iff)
   992   apply assumption
   993   apply (erule le_natfloor)
   994 done
   995 
   996 lemma le_natfloor_eq_number_of [simp]:
   997     "~ neg((number_of n)::int) ==> 0 <= x ==>
   998       (number_of n <= natfloor x) = (number_of n <= x)"
   999   apply (subst le_natfloor_eq, assumption)
  1000   apply simp
  1001 done
  1002 
  1003 lemma le_natfloor_eq_one [simp]: "(1 <= natfloor x) = (1 <= x)"
  1004   apply (case_tac "0 <= x")
  1005   apply (subst le_natfloor_eq, assumption, simp)
  1006   apply (rule iffI)
  1007   apply (subgoal_tac "natfloor x <= natfloor 0")
  1008   apply simp
  1009   apply (rule natfloor_mono)
  1010   apply simp
  1011   apply simp
  1012 done
  1013 
  1014 lemma natfloor_eq: "real n <= x ==> x < real n + 1 ==> natfloor x = n"
  1015   apply (unfold natfloor_def)
  1016   apply (subst nat_int [THEN sym]);back;
  1017   apply (subst eq_nat_nat_iff)
  1018   apply simp
  1019   apply simp
  1020   apply (rule floor_eq2)
  1021   apply auto
  1022 done
  1023 
  1024 lemma real_natfloor_add_one_gt: "x < real(natfloor x) + 1"
  1025   apply (case_tac "0 <= x")
  1026   apply (unfold natfloor_def)
  1027   apply simp
  1028   apply simp_all
  1029 done
  1030 
  1031 lemma real_natfloor_gt_diff_one: "x - 1 < real(natfloor x)"
  1032   apply (simp add: compare_rls)
  1033   apply (rule real_natfloor_add_one_gt)
  1034 done
  1035 
  1036 lemma ge_natfloor_plus_one_imp_gt: "natfloor z + 1 <= n ==> z < real n"
  1037   apply (subgoal_tac "z < real(natfloor z) + 1")
  1038   apply arith
  1039   apply (rule real_natfloor_add_one_gt)
  1040 done
  1041 
  1042 lemma natfloor_add [simp]: "0 <= x ==> natfloor (x + real a) = natfloor x + a"
  1043   apply (unfold natfloor_def)
  1044   apply (subgoal_tac "real a = real (int a)")
  1045   apply (erule ssubst)
  1046   apply (simp add: nat_add_distrib)
  1047   apply simp
  1048 done
  1049 
  1050 lemma natfloor_add_number_of [simp]:
  1051     "~neg ((number_of n)::int) ==> 0 <= x ==>
  1052       natfloor (x + number_of n) = natfloor x + number_of n"
  1053   apply (subst natfloor_add [THEN sym])
  1054   apply simp_all
  1055 done
  1056 
  1057 lemma natfloor_add_one: "0 <= x ==> natfloor(x + 1) = natfloor x + 1"
  1058   apply (subst natfloor_add [THEN sym])
  1059   apply assumption
  1060   apply simp
  1061 done
  1062 
  1063 lemma natfloor_subtract [simp]: "real a <= x ==>
  1064     natfloor(x - real a) = natfloor x - a"
  1065   apply (unfold natfloor_def)
  1066   apply (subgoal_tac "real a = real (int a)")
  1067   apply (erule ssubst)
  1068   apply simp
  1069   apply (subst nat_diff_distrib)
  1070   apply simp
  1071   apply (rule le_floor)
  1072   apply simp_all
  1073 done
  1074 
  1075 lemma natceiling_zero [simp]: "natceiling 0 = 0"
  1076   by (unfold natceiling_def, simp)
  1077 
  1078 lemma natceiling_one [simp]: "natceiling 1 = 1"
  1079   by (unfold natceiling_def, simp)
  1080 
  1081 lemma zero_le_natceiling [simp]: "0 <= natceiling x"
  1082   by (unfold natceiling_def, simp)
  1083 
  1084 lemma natceiling_number_of_eq [simp]: "natceiling (number_of n) = number_of n"
  1085   by (unfold natceiling_def, simp)
  1086 
  1087 lemma natceiling_real_of_nat [simp]: "natceiling(real n) = n"
  1088   by (unfold natceiling_def, simp)
  1089 
  1090 lemma real_natceiling_ge: "x <= real(natceiling x)"
  1091   apply (unfold natceiling_def)
  1092   apply (case_tac "x < 0")
  1093   apply simp
  1094   apply (subst real_nat_eq_real)
  1095   apply (subgoal_tac "ceiling 0 <= ceiling x")
  1096   apply simp
  1097   apply (rule ceiling_mono2)
  1098   apply simp
  1099   apply simp
  1100 done
  1101 
  1102 lemma natceiling_neg: "x <= 0 ==> natceiling x = 0"
  1103   apply (unfold natceiling_def)
  1104   apply simp
  1105 done
  1106 
  1107 lemma natceiling_mono: "x <= y ==> natceiling x <= natceiling y"
  1108   apply (case_tac "0 <= x")
  1109   apply (subst natceiling_def)+
  1110   apply (subst nat_le_eq_zle)
  1111   apply (rule disjI2)
  1112   apply (subgoal_tac "real (0::int) <= real(ceiling y)")
  1113   apply simp
  1114   apply (rule order_trans)
  1115   apply simp
  1116   apply (erule order_trans)
  1117   apply simp
  1118   apply (erule ceiling_mono2)
  1119   apply (subst natceiling_neg)
  1120   apply simp_all
  1121 done
  1122 
  1123 lemma natceiling_le: "x <= real a ==> natceiling x <= a"
  1124   apply (unfold natceiling_def)
  1125   apply (case_tac "x < 0")
  1126   apply simp
  1127   apply (subst nat_int [THEN sym]);back;
  1128   apply (subst nat_le_eq_zle)
  1129   apply simp
  1130   apply (rule ceiling_le)
  1131   apply simp
  1132 done
  1133 
  1134 lemma natceiling_le_eq: "0 <= x ==> (natceiling x <= a) = (x <= real a)"
  1135   apply (rule iffI)
  1136   apply (rule order_trans)
  1137   apply (rule real_natceiling_ge)
  1138   apply (subst real_of_nat_le_iff)
  1139   apply assumption
  1140   apply (erule natceiling_le)
  1141 done
  1142 
  1143 lemma natceiling_le_eq_number_of [simp]:
  1144     "~ neg((number_of n)::int) ==> 0 <= x ==>
  1145       (natceiling x <= number_of n) = (x <= number_of n)"
  1146   apply (subst natceiling_le_eq, assumption)
  1147   apply simp
  1148 done
  1149 
  1150 lemma natceiling_le_eq_one: "(natceiling x <= 1) = (x <= 1)"
  1151   apply (case_tac "0 <= x")
  1152   apply (subst natceiling_le_eq)
  1153   apply assumption
  1154   apply simp
  1155   apply (subst natceiling_neg)
  1156   apply simp
  1157   apply simp
  1158 done
  1159 
  1160 lemma natceiling_eq: "real n < x ==> x <= real n + 1 ==> natceiling x = n + 1"
  1161   apply (unfold natceiling_def)
  1162   apply (subst nat_int [THEN sym]);back;
  1163   apply (subgoal_tac "nat(int n) + 1 = nat(int n + 1)")
  1164   apply (erule ssubst)
  1165   apply (subst eq_nat_nat_iff)
  1166   apply (subgoal_tac "ceiling 0 <= ceiling x")
  1167   apply simp
  1168   apply (rule ceiling_mono2)
  1169   apply force
  1170   apply force
  1171   apply (rule ceiling_eq2)
  1172   apply (simp, simp)
  1173   apply (subst nat_add_distrib)
  1174   apply auto
  1175 done
  1176 
  1177 lemma natceiling_add [simp]: "0 <= x ==>
  1178     natceiling (x + real a) = natceiling x + a"
  1179   apply (unfold natceiling_def)
  1180   apply (subgoal_tac "real a = real (int a)")
  1181   apply (erule ssubst)
  1182   apply simp
  1183   apply (subst nat_add_distrib)
  1184   apply (subgoal_tac "0 = ceiling 0")
  1185   apply (erule ssubst)
  1186   apply (erule ceiling_mono2)
  1187   apply simp_all
  1188 done
  1189 
  1190 lemma natceiling_add_number_of [simp]:
  1191     "~ neg ((number_of n)::int) ==> 0 <= x ==>
  1192       natceiling (x + number_of n) = natceiling x + number_of n"
  1193   apply (subst natceiling_add [THEN sym])
  1194   apply simp_all
  1195 done
  1196 
  1197 lemma natceiling_add_one: "0 <= x ==> natceiling(x + 1) = natceiling x + 1"
  1198   apply (subst natceiling_add [THEN sym])
  1199   apply assumption
  1200   apply simp
  1201 done
  1202 
  1203 lemma natceiling_subtract [simp]: "real a <= x ==>
  1204     natceiling(x - real a) = natceiling x - a"
  1205   apply (unfold natceiling_def)
  1206   apply (subgoal_tac "real a = real (int a)")
  1207   apply (erule ssubst)
  1208   apply simp
  1209   apply (subst nat_diff_distrib)
  1210   apply simp
  1211   apply (rule order_trans)
  1212   prefer 2
  1213   apply (rule ceiling_mono2)
  1214   apply assumption
  1215   apply simp_all
  1216 done
  1217 
  1218 lemma natfloor_div_nat: "1 <= x ==> 0 < y ==>
  1219   natfloor (x / real y) = natfloor x div y"
  1220 proof -
  1221   assume "1 <= (x::real)" and "0 < (y::nat)"
  1222   have "natfloor x = (natfloor x) div y * y + (natfloor x) mod y"
  1223     by simp
  1224   then have a: "real(natfloor x) = real ((natfloor x) div y) * real y +
  1225     real((natfloor x) mod y)"
  1226     by (simp only: real_of_nat_add [THEN sym] real_of_nat_mult [THEN sym])
  1227   have "x = real(natfloor x) + (x - real(natfloor x))"
  1228     by simp
  1229   then have "x = real ((natfloor x) div y) * real y +
  1230       real((natfloor x) mod y) + (x - real(natfloor x))"
  1231     by (simp add: a)
  1232   then have "x / real y = ... / real y"
  1233     by simp
  1234   also have "... = real((natfloor x) div y) + real((natfloor x) mod y) /
  1235     real y + (x - real(natfloor x)) / real y"
  1236     by (auto simp add: ring_distrib ring_eq_simps add_divide_distrib
  1237       diff_divide_distrib prems)
  1238   finally have "natfloor (x / real y) = natfloor(...)" by simp
  1239   also have "... = natfloor(real((natfloor x) mod y) /
  1240     real y + (x - real(natfloor x)) / real y + real((natfloor x) div y))"
  1241     by (simp add: add_ac)
  1242   also have "... = natfloor(real((natfloor x) mod y) /
  1243     real y + (x - real(natfloor x)) / real y) + (natfloor x) div y"
  1244     apply (rule natfloor_add)
  1245     apply (rule add_nonneg_nonneg)
  1246     apply (rule divide_nonneg_pos)
  1247     apply simp
  1248     apply (simp add: prems)
  1249     apply (rule divide_nonneg_pos)
  1250     apply (simp add: compare_rls)
  1251     apply (rule real_natfloor_le)
  1252     apply (insert prems, auto)
  1253     done
  1254   also have "natfloor(real((natfloor x) mod y) /
  1255     real y + (x - real(natfloor x)) / real y) = 0"
  1256     apply (rule natfloor_eq)
  1257     apply simp
  1258     apply (rule add_nonneg_nonneg)
  1259     apply (rule divide_nonneg_pos)
  1260     apply force
  1261     apply (force simp add: prems)
  1262     apply (rule divide_nonneg_pos)
  1263     apply (simp add: compare_rls)
  1264     apply (rule real_natfloor_le)
  1265     apply (auto simp add: prems)
  1266     apply (insert prems, arith)
  1267     apply (simp add: add_divide_distrib [THEN sym])
  1268     apply (subgoal_tac "real y = real y - 1 + 1")
  1269     apply (erule ssubst)
  1270     apply (rule add_le_less_mono)
  1271     apply (simp add: compare_rls)
  1272     apply (subgoal_tac "real(natfloor x mod y) + 1 =
  1273       real(natfloor x mod y + 1)")
  1274     apply (erule ssubst)
  1275     apply (subst real_of_nat_le_iff)
  1276     apply (subgoal_tac "natfloor x mod y < y")
  1277     apply arith
  1278     apply (rule mod_less_divisor)
  1279     apply assumption
  1280     apply auto
  1281     apply (simp add: compare_rls)
  1282     apply (subst add_commute)
  1283     apply (rule real_natfloor_add_one_gt)
  1284     done
  1285   finally show ?thesis
  1286     by simp
  1287 qed
  1288 
  1289 end