src/Pure/General/symbol_pos.ML
author wenzelm
Wed Jan 20 14:32:56 2016 +0100 (2016-01-20)
changeset 62210 e068ea693678
parent 61707 d5ddd022a451
child 62239 6ee95b93fbed
permissions -rw-r--r--
tuned signature (according to Scala version);
     1 (*  Title:      Pure/General/symbol_pos.ML
     2     Author:     Makarius
     3 
     4 Symbols with explicit position information.
     5 *)
     6 
     7 signature SYMBOL_POS =
     8 sig
     9   type T = Symbol.symbol * Position.T
    10   val symbol: T -> Symbol.symbol
    11   val $$ : Symbol.symbol -> T list -> T * T list
    12   val ~$$ : Symbol.symbol -> T list -> T * T list
    13   val $$$ : Symbol.symbol -> T list -> T list * T list
    14   val ~$$$ : Symbol.symbol -> T list -> T list * T list
    15   val content: T list -> string
    16   val range: T list -> Position.range
    17   val split_lines: T list -> T list list
    18   val trim_blanks: T list -> T list
    19   val trim_lines: T list -> T list
    20   val is_eof: T -> bool
    21   val stopper: T Scan.stopper
    22   val !!! : Scan.message -> (T list -> 'a) -> T list -> 'a
    23   val scan_pos: T list -> Position.T * T list
    24   val scan_string_q: string -> T list -> (Position.T * (T list * Position.T)) * T list
    25   val scan_string_qq: string -> T list -> (Position.T * (T list * Position.T)) * T list
    26   val scan_string_bq: string -> T list -> (Position.T * (T list * Position.T)) * T list
    27   val recover_string_q: T list -> T list * T list
    28   val recover_string_qq: T list -> T list * T list
    29   val recover_string_bq: T list -> T list * T list
    30   val quote_string_q: string -> string
    31   val quote_string_qq: string -> string
    32   val quote_string_bq: string -> string
    33   val scan_cartouche: string -> T list -> T list * T list
    34   val recover_cartouche: T list -> T list * T list
    35   val cartouche_content: T list -> T list
    36   val scan_comment: string -> T list -> T list * T list
    37   val scan_comment_body: string -> T list -> T list * T list
    38   val recover_comment: T list -> T list * T list
    39   val source: Position.T -> (Symbol.symbol, 'a) Source.source ->
    40     (T, Position.T * (Symbol.symbol, 'a) Source.source) Source.source
    41   type text = string
    42   val implode: T list -> text
    43   val implode_range: Position.range -> T list -> text * Position.range
    44   val explode: text * Position.T -> T list
    45   val scan_ident: T list -> T list * T list
    46   val is_identifier: string -> bool
    47 end;
    48 
    49 structure Symbol_Pos: SYMBOL_POS =
    50 struct
    51 
    52 (* type T *)
    53 
    54 type T = Symbol.symbol * Position.T;
    55 
    56 fun symbol ((s, _): T) = s;
    57 
    58 val content = implode o map symbol;
    59 
    60 fun range (syms as (_, pos) :: _) =
    61       let val pos' = List.last syms |-> Position.advance
    62       in Position.range pos pos' end
    63   | range [] = Position.no_range;
    64 
    65 
    66 (* lines and blanks *)
    67 
    68 fun split_lines [] = []
    69   | split_lines (list: T list) =
    70       let
    71         fun split syms =
    72           (case take_prefix (fn (s, _) => s <> "\n") syms of
    73             (line, []) => [line]
    74           | (line, nl :: rest) => line :: split rest);
    75       in split list end;
    76 
    77 val trim_blanks = trim (Symbol.is_blank o symbol);
    78 
    79 val trim_lines =
    80   split_lines #> map trim_blanks #> separate [(Symbol.space, Position.none)] #> flat;
    81 
    82 
    83 (* stopper *)
    84 
    85 fun mk_eof pos = (Symbol.eof, pos);
    86 val eof = mk_eof Position.none;
    87 
    88 val is_eof = Symbol.is_eof o symbol;
    89 
    90 val stopper =
    91   Scan.stopper (fn [] => eof | inp => mk_eof (List.last inp |-> Position.advance)) is_eof;
    92 
    93 
    94 (* basic scanners *)
    95 
    96 fun !!! text scan =
    97   let
    98     fun get_pos [] = " (end-of-input)"
    99       | get_pos ((_, pos) :: _) = Position.here pos;
   100 
   101     fun err (syms, msg) = fn () =>
   102       text () ^ get_pos syms ^
   103       Markup.markup Markup.no_report (" at " ^ Symbol.beginning 10 (map symbol syms)) ^
   104       (case msg of NONE => "" | SOME m => "\n" ^ m ());
   105   in Scan.!! err scan end;
   106 
   107 fun $$ s = Scan.one (fn x => symbol x = s);
   108 fun ~$$ s = Scan.one (fn x => symbol x <> s);
   109 
   110 fun $$$ s = Scan.one (fn x => symbol x = s) >> single;
   111 fun ~$$$ s = Scan.one (fn x => symbol x <> s) >> single;
   112 
   113 val scan_pos = Scan.ahead (Scan.one (K true)) >> (fn (_, pos): T => pos);
   114 
   115 
   116 (* scan string literals *)
   117 
   118 local
   119 
   120 val char_code =
   121   Scan.one (Symbol.is_ascii_digit o symbol) --
   122   Scan.one (Symbol.is_ascii_digit o symbol) --
   123   Scan.one (Symbol.is_ascii_digit o symbol) :|--
   124   (fn (((a, pos), (b, _)), (c, _)) =>
   125     let val (n, _) = Library.read_int [a, b, c]
   126     in if n <= 255 then Scan.succeed [(chr n, pos)] else Scan.fail end);
   127 
   128 fun scan_str q err_prefix =
   129   $$$ "\\" |-- !!! (fn () => err_prefix ^ "bad escape character in string")
   130     ($$$ q || $$$ "\\" || char_code) ||
   131   Scan.one (fn (s, _) => s <> q andalso s <> "\\" andalso Symbol.not_eof s) >> single;
   132 
   133 fun scan_strs q err_prefix =
   134   Scan.ahead ($$ q) |--
   135     !!! (fn () => err_prefix ^ "unclosed string literal")
   136       ((scan_pos --| $$$ q) -- (Scan.repeats (scan_str q err_prefix) -- ($$$ q |-- scan_pos)));
   137 
   138 fun recover_strs q =
   139   $$$ q @@@ Scan.repeats (Scan.permissive (scan_str q ""));
   140 
   141 in
   142 
   143 val scan_string_q = scan_strs "'";
   144 val scan_string_qq = scan_strs "\"";
   145 val scan_string_bq = scan_strs "`";
   146 
   147 val recover_string_q = recover_strs "'";
   148 val recover_string_qq = recover_strs "\"";
   149 val recover_string_bq = recover_strs "`";
   150 
   151 end;
   152 
   153 
   154 (* quote string literals *)
   155 
   156 local
   157 
   158 fun char_code i =
   159   (if i < 10 then "00" else if i < 100 then "0" else "") ^ string_of_int i;
   160 
   161 fun quote_str q s =
   162   if Symbol.is_ascii_control s then "\\" ^ char_code (ord s)
   163   else if s = q orelse s = "\\" then "\\" ^ s
   164   else s;
   165 
   166 fun quote_string q = enclose q q o implode o map (quote_str q) o Symbol.explode;
   167 
   168 in
   169 
   170 val quote_string_q = quote_string "'";
   171 val quote_string_qq = quote_string "\"";
   172 val quote_string_bq = quote_string "`";
   173 
   174 end;
   175 
   176 
   177 (* nested text cartouches *)
   178 
   179 val scan_cartouche_depth =
   180   Scan.repeat1 (Scan.depend (fn (depth: int option) =>
   181     (case depth of
   182       SOME d =>
   183         $$ Symbol.open_ >> pair (SOME (d + 1)) ||
   184           (if d > 0 then
   185             Scan.one (fn (s, _) => s <> Symbol.close andalso Symbol.not_eof s) >> pair depth ||
   186             $$ Symbol.close >> pair (if d = 1 then NONE else SOME (d - 1))
   187           else Scan.fail)
   188     | NONE => Scan.fail)));
   189 
   190 fun scan_cartouche err_prefix =
   191   Scan.ahead ($$ Symbol.open_) |--
   192     !!! (fn () => err_prefix ^ "unclosed text cartouche")
   193       (Scan.provide is_none (SOME 0) scan_cartouche_depth);
   194 
   195 val recover_cartouche = Scan.pass (SOME 0) scan_cartouche_depth;
   196 
   197 fun cartouche_content syms =
   198   let
   199     fun err () =
   200       error ("Malformed text cartouche: "
   201         ^ quote (content syms) ^ Position.here (#1 (range syms)));
   202   in
   203     (case syms of
   204       ("\\<open>", _) :: rest =>
   205         (case rev rest of
   206           ("\\<close>", _) :: rrest => rev rrest
   207         | _ => err ())
   208     | _ => err ())
   209   end;
   210 
   211 
   212 (* ML-style comments *)
   213 
   214 local
   215 
   216 val scan_cmt =
   217   Scan.depend (fn (d: int) => $$$ "(" @@@ $$$ "*" >> pair (d + 1)) ||
   218   Scan.depend (fn 0 => Scan.fail | d => $$$ "*" @@@ $$$ ")" >> pair (d - 1)) ||
   219   Scan.lift ($$$ "*" --| Scan.ahead (~$$$ ")")) ||
   220   Scan.lift (Scan.one (fn (s, _) => s <> "*" andalso Symbol.not_eof s)) >> single;
   221 
   222 val scan_cmts = Scan.pass 0 (Scan.repeats scan_cmt);
   223 
   224 in
   225 
   226 fun scan_comment err_prefix =
   227   Scan.ahead ($$ "(" -- $$ "*") |--
   228     !!! (fn () => err_prefix ^ "unclosed comment")
   229       ($$$ "(" @@@ $$$ "*" @@@ scan_cmts @@@ $$$ "*" @@@ $$$ ")");
   230 
   231 fun scan_comment_body err_prefix =
   232   Scan.ahead ($$ "(" -- $$ "*") |--
   233     !!! (fn () => err_prefix ^ "unclosed comment")
   234       ($$ "(" |-- $$ "*" |-- scan_cmts --| $$ "*" --| $$ ")");
   235 
   236 val recover_comment =
   237   $$$ "(" @@@ $$$ "*" @@@ scan_cmts;
   238 
   239 end;
   240 
   241 
   242 (* source *)
   243 
   244 fun source pos =
   245   Source.source' pos Symbol.stopper (Scan.bulk (Scan.depend (fn pos =>
   246     Scan.one Symbol.not_eof >> (fn s => (Position.advance s pos, (s, pos))))));
   247 
   248 
   249 (* compact representation -- with Symbol.DEL padding *)
   250 
   251 type text = string;
   252 
   253 fun pad [] = []
   254   | pad [(s, _)] = [s]
   255   | pad ((s1, pos1) :: (rest as (_, pos2) :: _)) =
   256       let
   257         val end_pos1 = Position.advance s1 pos1;
   258         val d = Int.max (0, Position.distance_of end_pos1 pos2);
   259       in s1 :: replicate d Symbol.DEL @ pad rest end;
   260 
   261 val implode = implode o pad;
   262 
   263 fun implode_range (pos1, pos2) syms =
   264   let val syms' = (("", pos1) :: syms @ [("", pos2)])
   265   in (implode syms', range syms') end;
   266 
   267 fun explode (str, pos) =
   268   let
   269     val (res, _) =
   270       fold (fn s => fn (res, p) => ((s, p) :: res, Position.advance s p))
   271         (Symbol.explode str) ([], Position.reset_range pos);
   272   in fold (fn (s, p) => if s = Symbol.DEL then I else cons (s, p)) res [] end;
   273 
   274 
   275 (* identifiers *)
   276 
   277 local
   278 
   279 val letter = Scan.one (symbol #> Symbol.is_letter);
   280 val letdigs1 = Scan.many1 (symbol #> Symbol.is_letdig);
   281 
   282 val sub = Scan.one (symbol #> (fn s => s = "\\<^sub>"));
   283 
   284 in
   285 
   286 val scan_ident = letter ::: Scan.repeats (letdigs1 || sub ::: letdigs1);
   287 
   288 end;
   289 
   290 fun is_identifier s =
   291   Symbol.is_ascii_identifier s orelse
   292     (case try (Scan.finite stopper scan_ident) (explode (s, Position.none)) of
   293       SOME (_, []) => true
   294     | _ => false);
   295 
   296 end;
   297 
   298 structure Basic_Symbol_Pos =   (*not open by default*)
   299 struct
   300   val $$ = Symbol_Pos.$$;
   301   val ~$$ = Symbol_Pos.~$$;
   302   val $$$ = Symbol_Pos.$$$;
   303   val ~$$$ = Symbol_Pos.~$$$;
   304 end;
   305