src/ZF/Constructible/Datatype_absolute.thy
author ballarin
Thu Dec 11 18:30:26 2008 +0100 (2008-12-11)
changeset 29223 e09c53289830
parent 22710 f44439cdce77
child 32960 69916a850301
permissions -rw-r--r--
Conversion of HOL-Main and ZF to new locales.
     1 (*  Title:      ZF/Constructible/Datatype_absolute.thy
     2     ID: $Id$
     3     Author:     Lawrence C Paulson, Cambridge University Computer Laboratory
     4 *)
     5 
     6 header {*Absoluteness Properties for Recursive Datatypes*}
     7 
     8 theory Datatype_absolute imports Formula WF_absolute begin
     9 
    10 
    11 subsection{*The lfp of a continuous function can be expressed as a union*}
    12 
    13 definition
    14   directed :: "i=>o" where
    15    "directed(A) == A\<noteq>0 & (\<forall>x\<in>A. \<forall>y\<in>A. x \<union> y \<in> A)"
    16 
    17 definition
    18   contin :: "(i=>i) => o" where
    19    "contin(h) == (\<forall>A. directed(A) --> h(\<Union>A) = (\<Union>X\<in>A. h(X)))"
    20 
    21 lemma bnd_mono_iterates_subset: "[|bnd_mono(D, h); n \<in> nat|] ==> h^n (0) <= D"
    22 apply (induct_tac n) 
    23  apply (simp_all add: bnd_mono_def, blast) 
    24 done
    25 
    26 lemma bnd_mono_increasing [rule_format]:
    27      "[|i \<in> nat; j \<in> nat; bnd_mono(D,h)|] ==> i \<le> j --> h^i(0) \<subseteq> h^j(0)"
    28 apply (rule_tac m=i and n=j in diff_induct, simp_all)
    29 apply (blast del: subsetI
    30 	     intro: bnd_mono_iterates_subset bnd_monoD2 [of concl: h]) 
    31 done
    32 
    33 lemma directed_iterates: "bnd_mono(D,h) ==> directed({h^n (0). n\<in>nat})"
    34 apply (simp add: directed_def, clarify) 
    35 apply (rename_tac i j)
    36 apply (rule_tac x="i \<union> j" in bexI) 
    37 apply (rule_tac i = i and j = j in Ord_linear_le)
    38 apply (simp_all add: subset_Un_iff [THEN iffD1] le_imp_subset
    39                      subset_Un_iff2 [THEN iffD1])
    40 apply (simp_all add: subset_Un_iff [THEN iff_sym] bnd_mono_increasing
    41                      subset_Un_iff2 [THEN iff_sym])
    42 done
    43 
    44 
    45 lemma contin_iterates_eq: 
    46     "[|bnd_mono(D, h); contin(h)|] 
    47      ==> h(\<Union>n\<in>nat. h^n (0)) = (\<Union>n\<in>nat. h^n (0))"
    48 apply (simp add: contin_def directed_iterates) 
    49 apply (rule trans) 
    50 apply (rule equalityI) 
    51  apply (simp_all add: UN_subset_iff)
    52  apply safe
    53  apply (erule_tac [2] natE) 
    54   apply (rule_tac a="succ(x)" in UN_I) 
    55    apply simp_all 
    56 apply blast 
    57 done
    58 
    59 lemma lfp_subset_Union:
    60      "[|bnd_mono(D, h); contin(h)|] ==> lfp(D,h) <= (\<Union>n\<in>nat. h^n(0))"
    61 apply (rule lfp_lowerbound) 
    62  apply (simp add: contin_iterates_eq) 
    63 apply (simp add: contin_def bnd_mono_iterates_subset UN_subset_iff) 
    64 done
    65 
    66 lemma Union_subset_lfp:
    67      "bnd_mono(D,h) ==> (\<Union>n\<in>nat. h^n(0)) <= lfp(D,h)"
    68 apply (simp add: UN_subset_iff)
    69 apply (rule ballI)  
    70 apply (induct_tac n, simp_all) 
    71 apply (rule subset_trans [of _ "h(lfp(D,h))"])
    72  apply (blast dest: bnd_monoD2 [OF _ _ lfp_subset])  
    73 apply (erule lfp_lemma2) 
    74 done
    75 
    76 lemma lfp_eq_Union:
    77      "[|bnd_mono(D, h); contin(h)|] ==> lfp(D,h) = (\<Union>n\<in>nat. h^n(0))"
    78 by (blast del: subsetI 
    79           intro: lfp_subset_Union Union_subset_lfp)
    80 
    81 
    82 subsubsection{*Some Standard Datatype Constructions Preserve Continuity*}
    83 
    84 lemma contin_imp_mono: "[|X\<subseteq>Y; contin(F)|] ==> F(X) \<subseteq> F(Y)"
    85 apply (simp add: contin_def) 
    86 apply (drule_tac x="{X,Y}" in spec) 
    87 apply (simp add: directed_def subset_Un_iff2 Un_commute) 
    88 done
    89 
    90 lemma sum_contin: "[|contin(F); contin(G)|] ==> contin(\<lambda>X. F(X) + G(X))"
    91 by (simp add: contin_def, blast)
    92 
    93 lemma prod_contin: "[|contin(F); contin(G)|] ==> contin(\<lambda>X. F(X) * G(X))" 
    94 apply (subgoal_tac "\<forall>B C. F(B) \<subseteq> F(B \<union> C)")
    95  prefer 2 apply (simp add: Un_upper1 contin_imp_mono) 
    96 apply (subgoal_tac "\<forall>B C. G(C) \<subseteq> G(B \<union> C)")
    97  prefer 2 apply (simp add: Un_upper2 contin_imp_mono) 
    98 apply (simp add: contin_def, clarify) 
    99 apply (rule equalityI) 
   100  prefer 2 apply blast 
   101 apply clarify 
   102 apply (rename_tac B C) 
   103 apply (rule_tac a="B \<union> C" in UN_I) 
   104  apply (simp add: directed_def, blast)  
   105 done
   106 
   107 lemma const_contin: "contin(\<lambda>X. A)"
   108 by (simp add: contin_def directed_def)
   109 
   110 lemma id_contin: "contin(\<lambda>X. X)"
   111 by (simp add: contin_def)
   112 
   113 
   114 
   115 subsection {*Absoluteness for "Iterates"*}
   116 
   117 definition
   118   iterates_MH :: "[i=>o, [i,i]=>o, i, i, i, i] => o" where
   119    "iterates_MH(M,isF,v,n,g,z) ==
   120         is_nat_case(M, v, \<lambda>m u. \<exists>gm[M]. fun_apply(M,g,m,gm) & isF(gm,u),
   121                     n, z)"
   122 
   123 definition
   124   is_iterates :: "[i=>o, [i,i]=>o, i, i, i] => o" where
   125     "is_iterates(M,isF,v,n,Z) == 
   126       \<exists>sn[M]. \<exists>msn[M]. successor(M,n,sn) & membership(M,sn,msn) &
   127                        is_wfrec(M, iterates_MH(M,isF,v), msn, n, Z)"
   128 
   129 definition
   130   iterates_replacement :: "[i=>o, [i,i]=>o, i] => o" where
   131    "iterates_replacement(M,isF,v) ==
   132       \<forall>n[M]. n\<in>nat --> 
   133          wfrec_replacement(M, iterates_MH(M,isF,v), Memrel(succ(n)))"
   134 
   135 lemma (in M_basic) iterates_MH_abs:
   136   "[| relation1(M,isF,F); M(n); M(g); M(z) |] 
   137    ==> iterates_MH(M,isF,v,n,g,z) <-> z = nat_case(v, \<lambda>m. F(g`m), n)"
   138 by (simp add: nat_case_abs [of _ "\<lambda>m. F(g ` m)"]
   139               relation1_def iterates_MH_def)  
   140 
   141 lemma (in M_basic) iterates_imp_wfrec_replacement:
   142   "[|relation1(M,isF,F); n \<in> nat; iterates_replacement(M,isF,v)|] 
   143    ==> wfrec_replacement(M, \<lambda>n f z. z = nat_case(v, \<lambda>m. F(f`m), n), 
   144                        Memrel(succ(n)))" 
   145 by (simp add: iterates_replacement_def iterates_MH_abs)
   146 
   147 theorem (in M_trancl) iterates_abs:
   148   "[| iterates_replacement(M,isF,v); relation1(M,isF,F);
   149       n \<in> nat; M(v); M(z); \<forall>x[M]. M(F(x)) |] 
   150    ==> is_iterates(M,isF,v,n,z) <-> z = iterates(F,n,v)" 
   151 apply (frule iterates_imp_wfrec_replacement, assumption+)
   152 apply (simp add: wf_Memrel trans_Memrel relation_Memrel nat_into_M
   153                  is_iterates_def relation2_def iterates_MH_abs 
   154                  iterates_nat_def recursor_def transrec_def 
   155                  eclose_sing_Ord_eq nat_into_M
   156          trans_wfrec_abs [of _ _ _ _ "\<lambda>n g. nat_case(v, \<lambda>m. F(g`m), n)"])
   157 done
   158 
   159 
   160 lemma (in M_trancl) iterates_closed [intro,simp]:
   161   "[| iterates_replacement(M,isF,v); relation1(M,isF,F);
   162       n \<in> nat; M(v); \<forall>x[M]. M(F(x)) |] 
   163    ==> M(iterates(F,n,v))"
   164 apply (frule iterates_imp_wfrec_replacement, assumption+)
   165 apply (simp add: wf_Memrel trans_Memrel relation_Memrel nat_into_M
   166                  relation2_def iterates_MH_abs 
   167                  iterates_nat_def recursor_def transrec_def 
   168                  eclose_sing_Ord_eq nat_into_M
   169          trans_wfrec_closed [of _ _ _ "\<lambda>n g. nat_case(v, \<lambda>m. F(g`m), n)"])
   170 done
   171 
   172 
   173 subsection {*lists without univ*}
   174 
   175 lemmas datatype_univs = Inl_in_univ Inr_in_univ 
   176                         Pair_in_univ nat_into_univ A_into_univ 
   177 
   178 lemma list_fun_bnd_mono: "bnd_mono(univ(A), \<lambda>X. {0} + A*X)"
   179 apply (rule bnd_monoI)
   180  apply (intro subset_refl zero_subset_univ A_subset_univ 
   181 	      sum_subset_univ Sigma_subset_univ) 
   182 apply (rule subset_refl sum_mono Sigma_mono | assumption)+
   183 done
   184 
   185 lemma list_fun_contin: "contin(\<lambda>X. {0} + A*X)"
   186 by (intro sum_contin prod_contin id_contin const_contin) 
   187 
   188 text{*Re-expresses lists using sum and product*}
   189 lemma list_eq_lfp2: "list(A) = lfp(univ(A), \<lambda>X. {0} + A*X)"
   190 apply (simp add: list_def) 
   191 apply (rule equalityI) 
   192  apply (rule lfp_lowerbound) 
   193   prefer 2 apply (rule lfp_subset)
   194  apply (clarify, subst lfp_unfold [OF list_fun_bnd_mono])
   195  apply (simp add: Nil_def Cons_def)
   196  apply blast 
   197 txt{*Opposite inclusion*}
   198 apply (rule lfp_lowerbound) 
   199  prefer 2 apply (rule lfp_subset) 
   200 apply (clarify, subst lfp_unfold [OF list.bnd_mono]) 
   201 apply (simp add: Nil_def Cons_def)
   202 apply (blast intro: datatype_univs
   203              dest: lfp_subset [THEN subsetD])
   204 done
   205 
   206 text{*Re-expresses lists using "iterates", no univ.*}
   207 lemma list_eq_Union:
   208      "list(A) = (\<Union>n\<in>nat. (\<lambda>X. {0} + A*X) ^ n (0))"
   209 by (simp add: list_eq_lfp2 lfp_eq_Union list_fun_bnd_mono list_fun_contin)
   210 
   211 
   212 definition
   213   is_list_functor :: "[i=>o,i,i,i] => o" where
   214     "is_list_functor(M,A,X,Z) == 
   215         \<exists>n1[M]. \<exists>AX[M]. 
   216          number1(M,n1) & cartprod(M,A,X,AX) & is_sum(M,n1,AX,Z)"
   217 
   218 lemma (in M_basic) list_functor_abs [simp]: 
   219      "[| M(A); M(X); M(Z) |] ==> is_list_functor(M,A,X,Z) <-> (Z = {0} + A*X)"
   220 by (simp add: is_list_functor_def singleton_0 nat_into_M)
   221 
   222 
   223 subsection {*formulas without univ*}
   224 
   225 lemma formula_fun_bnd_mono:
   226      "bnd_mono(univ(0), \<lambda>X. ((nat*nat) + (nat*nat)) + (X*X + X))"
   227 apply (rule bnd_monoI)
   228  apply (intro subset_refl zero_subset_univ A_subset_univ 
   229 	      sum_subset_univ Sigma_subset_univ nat_subset_univ) 
   230 apply (rule subset_refl sum_mono Sigma_mono | assumption)+
   231 done
   232 
   233 lemma formula_fun_contin:
   234      "contin(\<lambda>X. ((nat*nat) + (nat*nat)) + (X*X + X))"
   235 by (intro sum_contin prod_contin id_contin const_contin) 
   236 
   237 
   238 text{*Re-expresses formulas using sum and product*}
   239 lemma formula_eq_lfp2:
   240     "formula = lfp(univ(0), \<lambda>X. ((nat*nat) + (nat*nat)) + (X*X + X))"
   241 apply (simp add: formula_def) 
   242 apply (rule equalityI) 
   243  apply (rule lfp_lowerbound) 
   244   prefer 2 apply (rule lfp_subset)
   245  apply (clarify, subst lfp_unfold [OF formula_fun_bnd_mono])
   246  apply (simp add: Member_def Equal_def Nand_def Forall_def)
   247  apply blast 
   248 txt{*Opposite inclusion*}
   249 apply (rule lfp_lowerbound) 
   250  prefer 2 apply (rule lfp_subset, clarify) 
   251 apply (subst lfp_unfold [OF formula.bnd_mono, simplified]) 
   252 apply (simp add: Member_def Equal_def Nand_def Forall_def)  
   253 apply (elim sumE SigmaE, simp_all) 
   254 apply (blast intro: datatype_univs dest: lfp_subset [THEN subsetD])+  
   255 done
   256 
   257 text{*Re-expresses formulas using "iterates", no univ.*}
   258 lemma formula_eq_Union:
   259      "formula = 
   260       (\<Union>n\<in>nat. (\<lambda>X. ((nat*nat) + (nat*nat)) + (X*X + X)) ^ n (0))"
   261 by (simp add: formula_eq_lfp2 lfp_eq_Union formula_fun_bnd_mono 
   262               formula_fun_contin)
   263 
   264 
   265 definition
   266   is_formula_functor :: "[i=>o,i,i] => o" where
   267     "is_formula_functor(M,X,Z) == 
   268         \<exists>nat'[M]. \<exists>natnat[M]. \<exists>natnatsum[M]. \<exists>XX[M]. \<exists>X3[M]. 
   269           omega(M,nat') & cartprod(M,nat',nat',natnat) & 
   270           is_sum(M,natnat,natnat,natnatsum) &
   271           cartprod(M,X,X,XX) & is_sum(M,XX,X,X3) & 
   272           is_sum(M,natnatsum,X3,Z)"
   273 
   274 lemma (in M_basic) formula_functor_abs [simp]: 
   275      "[| M(X); M(Z) |] 
   276       ==> is_formula_functor(M,X,Z) <-> 
   277           Z = ((nat*nat) + (nat*nat)) + (X*X + X)"
   278 by (simp add: is_formula_functor_def) 
   279 
   280 
   281 subsection{*@{term M} Contains the List and Formula Datatypes*}
   282 
   283 definition
   284   list_N :: "[i,i] => i" where
   285     "list_N(A,n) == (\<lambda>X. {0} + A * X)^n (0)"
   286 
   287 lemma Nil_in_list_N [simp]: "[] \<in> list_N(A,succ(n))"
   288 by (simp add: list_N_def Nil_def)
   289 
   290 lemma Cons_in_list_N [simp]:
   291      "Cons(a,l) \<in> list_N(A,succ(n)) <-> a\<in>A & l \<in> list_N(A,n)"
   292 by (simp add: list_N_def Cons_def) 
   293 
   294 text{*These two aren't simprules because they reveal the underlying
   295 list representation.*}
   296 lemma list_N_0: "list_N(A,0) = 0"
   297 by (simp add: list_N_def)
   298 
   299 lemma list_N_succ: "list_N(A,succ(n)) = {0} + A * (list_N(A,n))"
   300 by (simp add: list_N_def)
   301 
   302 lemma list_N_imp_list:
   303   "[| l \<in> list_N(A,n); n \<in> nat |] ==> l \<in> list(A)"
   304 by (force simp add: list_eq_Union list_N_def)
   305 
   306 lemma list_N_imp_length_lt [rule_format]:
   307      "n \<in> nat ==> \<forall>l \<in> list_N(A,n). length(l) < n"
   308 apply (induct_tac n)  
   309 apply (auto simp add: list_N_0 list_N_succ 
   310                       Nil_def [symmetric] Cons_def [symmetric]) 
   311 done
   312 
   313 lemma list_imp_list_N [rule_format]:
   314      "l \<in> list(A) ==> \<forall>n\<in>nat. length(l) < n --> l \<in> list_N(A, n)"
   315 apply (induct_tac l)
   316 apply (force elim: natE)+
   317 done
   318 
   319 lemma list_N_imp_eq_length:
   320       "[|n \<in> nat; l \<notin> list_N(A, n); l \<in> list_N(A, succ(n))|] 
   321        ==> n = length(l)"
   322 apply (rule le_anti_sym) 
   323  prefer 2 apply (simp add: list_N_imp_length_lt) 
   324 apply (frule list_N_imp_list, simp)
   325 apply (simp add: not_lt_iff_le [symmetric]) 
   326 apply (blast intro: list_imp_list_N) 
   327 done
   328   
   329 text{*Express @{term list_rec} without using @{term rank} or @{term Vset},
   330 neither of which is absolute.*}
   331 lemma (in M_trivial) list_rec_eq:
   332   "l \<in> list(A) ==>
   333    list_rec(a,g,l) = 
   334    transrec (succ(length(l)),
   335       \<lambda>x h. Lambda (list(A),
   336                     list_case' (a, 
   337                            \<lambda>a l. g(a, l, h ` succ(length(l)) ` l)))) ` l"
   338 apply (induct_tac l) 
   339 apply (subst transrec, simp) 
   340 apply (subst transrec) 
   341 apply (simp add: list_imp_list_N) 
   342 done
   343 
   344 definition
   345   is_list_N :: "[i=>o,i,i,i] => o" where
   346     "is_list_N(M,A,n,Z) == 
   347       \<exists>zero[M]. empty(M,zero) & 
   348                 is_iterates(M, is_list_functor(M,A), zero, n, Z)"
   349 
   350 definition  
   351   mem_list :: "[i=>o,i,i] => o" where
   352     "mem_list(M,A,l) == 
   353       \<exists>n[M]. \<exists>listn[M]. 
   354        finite_ordinal(M,n) & is_list_N(M,A,n,listn) & l \<in> listn"
   355 
   356 definition
   357   is_list :: "[i=>o,i,i] => o" where
   358     "is_list(M,A,Z) == \<forall>l[M]. l \<in> Z <-> mem_list(M,A,l)"
   359 
   360 subsubsection{*Towards Absoluteness of @{term formula_rec}*}
   361 
   362 consts   depth :: "i=>i"
   363 primrec
   364   "depth(Member(x,y)) = 0"
   365   "depth(Equal(x,y))  = 0"
   366   "depth(Nand(p,q)) = succ(depth(p) \<union> depth(q))"
   367   "depth(Forall(p)) = succ(depth(p))"
   368 
   369 lemma depth_type [TC]: "p \<in> formula ==> depth(p) \<in> nat"
   370 by (induct_tac p, simp_all) 
   371 
   372 
   373 definition
   374   formula_N :: "i => i" where
   375     "formula_N(n) == (\<lambda>X. ((nat*nat) + (nat*nat)) + (X*X + X)) ^ n (0)"
   376 
   377 lemma Member_in_formula_N [simp]:
   378      "Member(x,y) \<in> formula_N(succ(n)) <-> x \<in> nat & y \<in> nat"
   379 by (simp add: formula_N_def Member_def) 
   380 
   381 lemma Equal_in_formula_N [simp]:
   382      "Equal(x,y) \<in> formula_N(succ(n)) <-> x \<in> nat & y \<in> nat"
   383 by (simp add: formula_N_def Equal_def) 
   384 
   385 lemma Nand_in_formula_N [simp]:
   386      "Nand(x,y) \<in> formula_N(succ(n)) <-> x \<in> formula_N(n) & y \<in> formula_N(n)"
   387 by (simp add: formula_N_def Nand_def) 
   388 
   389 lemma Forall_in_formula_N [simp]:
   390      "Forall(x) \<in> formula_N(succ(n)) <-> x \<in> formula_N(n)"
   391 by (simp add: formula_N_def Forall_def) 
   392 
   393 text{*These two aren't simprules because they reveal the underlying
   394 formula representation.*}
   395 lemma formula_N_0: "formula_N(0) = 0"
   396 by (simp add: formula_N_def)
   397 
   398 lemma formula_N_succ:
   399      "formula_N(succ(n)) = 
   400       ((nat*nat) + (nat*nat)) + (formula_N(n) * formula_N(n) + formula_N(n))"
   401 by (simp add: formula_N_def)
   402 
   403 lemma formula_N_imp_formula:
   404   "[| p \<in> formula_N(n); n \<in> nat |] ==> p \<in> formula"
   405 by (force simp add: formula_eq_Union formula_N_def)
   406 
   407 lemma formula_N_imp_depth_lt [rule_format]:
   408      "n \<in> nat ==> \<forall>p \<in> formula_N(n). depth(p) < n"
   409 apply (induct_tac n)  
   410 apply (auto simp add: formula_N_0 formula_N_succ 
   411                       depth_type formula_N_imp_formula Un_least_lt_iff
   412                       Member_def [symmetric] Equal_def [symmetric]
   413                       Nand_def [symmetric] Forall_def [symmetric]) 
   414 done
   415 
   416 lemma formula_imp_formula_N [rule_format]:
   417      "p \<in> formula ==> \<forall>n\<in>nat. depth(p) < n --> p \<in> formula_N(n)"
   418 apply (induct_tac p)
   419 apply (simp_all add: succ_Un_distrib Un_least_lt_iff) 
   420 apply (force elim: natE)+
   421 done
   422 
   423 lemma formula_N_imp_eq_depth:
   424       "[|n \<in> nat; p \<notin> formula_N(n); p \<in> formula_N(succ(n))|] 
   425        ==> n = depth(p)"
   426 apply (rule le_anti_sym) 
   427  prefer 2 apply (simp add: formula_N_imp_depth_lt) 
   428 apply (frule formula_N_imp_formula, simp)
   429 apply (simp add: not_lt_iff_le [symmetric]) 
   430 apply (blast intro: formula_imp_formula_N) 
   431 done
   432 
   433 
   434 text{*This result and the next are unused.*}
   435 lemma formula_N_mono [rule_format]:
   436   "[| m \<in> nat; n \<in> nat |] ==> m\<le>n --> formula_N(m) \<subseteq> formula_N(n)"
   437 apply (rule_tac m = m and n = n in diff_induct)
   438 apply (simp_all add: formula_N_0 formula_N_succ, blast) 
   439 done
   440 
   441 lemma formula_N_distrib:
   442   "[| m \<in> nat; n \<in> nat |] ==> formula_N(m \<union> n) = formula_N(m) \<union> formula_N(n)"
   443 apply (rule_tac i = m and j = n in Ord_linear_le, auto) 
   444 apply (simp_all add: subset_Un_iff [THEN iffD1] subset_Un_iff2 [THEN iffD1] 
   445                      le_imp_subset formula_N_mono)
   446 done
   447 
   448 definition
   449   is_formula_N :: "[i=>o,i,i] => o" where
   450     "is_formula_N(M,n,Z) == 
   451       \<exists>zero[M]. empty(M,zero) & 
   452                 is_iterates(M, is_formula_functor(M), zero, n, Z)"
   453 
   454 
   455 definition  
   456   mem_formula :: "[i=>o,i] => o" where
   457     "mem_formula(M,p) == 
   458       \<exists>n[M]. \<exists>formn[M]. 
   459        finite_ordinal(M,n) & is_formula_N(M,n,formn) & p \<in> formn"
   460 
   461 definition
   462   is_formula :: "[i=>o,i] => o" where
   463     "is_formula(M,Z) == \<forall>p[M]. p \<in> Z <-> mem_formula(M,p)"
   464 
   465 locale M_datatypes = M_trancl +
   466  assumes list_replacement1:
   467    "M(A) ==> iterates_replacement(M, is_list_functor(M,A), 0)"
   468   and list_replacement2:
   469    "M(A) ==> strong_replacement(M,
   470          \<lambda>n y. n\<in>nat & is_iterates(M, is_list_functor(M,A), 0, n, y))"
   471   and formula_replacement1:
   472    "iterates_replacement(M, is_formula_functor(M), 0)"
   473   and formula_replacement2:
   474    "strong_replacement(M,
   475          \<lambda>n y. n\<in>nat & is_iterates(M, is_formula_functor(M), 0, n, y))"
   476   and nth_replacement:
   477    "M(l) ==> iterates_replacement(M, %l t. is_tl(M,l,t), l)"
   478 
   479 
   480 subsubsection{*Absoluteness of the List Construction*}
   481 
   482 lemma (in M_datatypes) list_replacement2':
   483   "M(A) ==> strong_replacement(M, \<lambda>n y. n\<in>nat & y = (\<lambda>X. {0} + A * X)^n (0))"
   484 apply (insert list_replacement2 [of A])
   485 apply (rule strong_replacement_cong [THEN iffD1])
   486 apply (rule conj_cong [OF iff_refl iterates_abs [of "is_list_functor(M,A)"]])
   487 apply (simp_all add: list_replacement1 relation1_def)
   488 done
   489 
   490 lemma (in M_datatypes) list_closed [intro,simp]:
   491      "M(A) ==> M(list(A))"
   492 apply (insert list_replacement1)
   493 by  (simp add: RepFun_closed2 list_eq_Union
   494                list_replacement2' relation1_def
   495                iterates_closed [of "is_list_functor(M,A)"])
   496 
   497 text{*WARNING: use only with @{text "dest:"} or with variables fixed!*}
   498 lemmas (in M_datatypes) list_into_M = transM [OF _ list_closed]
   499 
   500 lemma (in M_datatypes) list_N_abs [simp]:
   501      "[|M(A); n\<in>nat; M(Z)|]
   502       ==> is_list_N(M,A,n,Z) <-> Z = list_N(A,n)"
   503 apply (insert list_replacement1)
   504 apply (simp add: is_list_N_def list_N_def relation1_def nat_into_M
   505                  iterates_abs [of "is_list_functor(M,A)" _ "\<lambda>X. {0} + A*X"])
   506 done
   507 
   508 lemma (in M_datatypes) list_N_closed [intro,simp]:
   509      "[|M(A); n\<in>nat|] ==> M(list_N(A,n))"
   510 apply (insert list_replacement1)
   511 apply (simp add: is_list_N_def list_N_def relation1_def nat_into_M
   512                  iterates_closed [of "is_list_functor(M,A)"])
   513 done
   514 
   515 lemma (in M_datatypes) mem_list_abs [simp]:
   516      "M(A) ==> mem_list(M,A,l) <-> l \<in> list(A)"
   517 apply (insert list_replacement1)
   518 apply (simp add: mem_list_def list_N_def relation1_def list_eq_Union
   519                  iterates_closed [of "is_list_functor(M,A)"])
   520 done
   521 
   522 lemma (in M_datatypes) list_abs [simp]:
   523      "[|M(A); M(Z)|] ==> is_list(M,A,Z) <-> Z = list(A)"
   524 apply (simp add: is_list_def, safe)
   525 apply (rule M_equalityI, simp_all)
   526 done
   527 
   528 subsubsection{*Absoluteness of Formulas*}
   529 
   530 lemma (in M_datatypes) formula_replacement2':
   531   "strong_replacement(M, \<lambda>n y. n\<in>nat & y = (\<lambda>X. ((nat*nat) + (nat*nat)) + (X*X + X))^n (0))"
   532 apply (insert formula_replacement2)
   533 apply (rule strong_replacement_cong [THEN iffD1])
   534 apply (rule conj_cong [OF iff_refl iterates_abs [of "is_formula_functor(M)"]])
   535 apply (simp_all add: formula_replacement1 relation1_def)
   536 done
   537 
   538 lemma (in M_datatypes) formula_closed [intro,simp]:
   539      "M(formula)"
   540 apply (insert formula_replacement1)
   541 apply  (simp add: RepFun_closed2 formula_eq_Union
   542                   formula_replacement2' relation1_def
   543                   iterates_closed [of "is_formula_functor(M)"])
   544 done
   545 
   546 lemmas (in M_datatypes) formula_into_M = transM [OF _ formula_closed]
   547 
   548 lemma (in M_datatypes) formula_N_abs [simp]:
   549      "[|n\<in>nat; M(Z)|]
   550       ==> is_formula_N(M,n,Z) <-> Z = formula_N(n)"
   551 apply (insert formula_replacement1)
   552 apply (simp add: is_formula_N_def formula_N_def relation1_def nat_into_M
   553                  iterates_abs [of "is_formula_functor(M)" _
   554                                   "\<lambda>X. ((nat*nat) + (nat*nat)) + (X*X + X)"])
   555 done
   556 
   557 lemma (in M_datatypes) formula_N_closed [intro,simp]:
   558      "n\<in>nat ==> M(formula_N(n))"
   559 apply (insert formula_replacement1)
   560 apply (simp add: is_formula_N_def formula_N_def relation1_def nat_into_M
   561                  iterates_closed [of "is_formula_functor(M)"])
   562 done
   563 
   564 lemma (in M_datatypes) mem_formula_abs [simp]:
   565      "mem_formula(M,l) <-> l \<in> formula"
   566 apply (insert formula_replacement1)
   567 apply (simp add: mem_formula_def relation1_def formula_eq_Union formula_N_def
   568                  iterates_closed [of "is_formula_functor(M)"])
   569 done
   570 
   571 lemma (in M_datatypes) formula_abs [simp]:
   572      "[|M(Z)|] ==> is_formula(M,Z) <-> Z = formula"
   573 apply (simp add: is_formula_def, safe)
   574 apply (rule M_equalityI, simp_all)
   575 done
   576 
   577 
   578 subsection{*Absoluteness for @{text \<epsilon>}-Closure: the @{term eclose} Operator*}
   579 
   580 text{*Re-expresses eclose using "iterates"*}
   581 lemma eclose_eq_Union:
   582      "eclose(A) = (\<Union>n\<in>nat. Union^n (A))"
   583 apply (simp add: eclose_def)
   584 apply (rule UN_cong)
   585 apply (rule refl)
   586 apply (induct_tac n)
   587 apply (simp add: nat_rec_0)
   588 apply (simp add: nat_rec_succ)
   589 done
   590 
   591 definition
   592   is_eclose_n :: "[i=>o,i,i,i] => o" where
   593     "is_eclose_n(M,A,n,Z) == is_iterates(M, big_union(M), A, n, Z)"
   594 
   595 definition
   596   mem_eclose :: "[i=>o,i,i] => o" where
   597     "mem_eclose(M,A,l) ==
   598       \<exists>n[M]. \<exists>eclosen[M].
   599        finite_ordinal(M,n) & is_eclose_n(M,A,n,eclosen) & l \<in> eclosen"
   600 
   601 definition
   602   is_eclose :: "[i=>o,i,i] => o" where
   603     "is_eclose(M,A,Z) == \<forall>u[M]. u \<in> Z <-> mem_eclose(M,A,u)"
   604 
   605 
   606 locale M_eclose = M_datatypes +
   607  assumes eclose_replacement1:
   608    "M(A) ==> iterates_replacement(M, big_union(M), A)"
   609   and eclose_replacement2:
   610    "M(A) ==> strong_replacement(M,
   611          \<lambda>n y. n\<in>nat & is_iterates(M, big_union(M), A, n, y))"
   612 
   613 lemma (in M_eclose) eclose_replacement2':
   614   "M(A) ==> strong_replacement(M, \<lambda>n y. n\<in>nat & y = Union^n (A))"
   615 apply (insert eclose_replacement2 [of A])
   616 apply (rule strong_replacement_cong [THEN iffD1])
   617 apply (rule conj_cong [OF iff_refl iterates_abs [of "big_union(M)"]])
   618 apply (simp_all add: eclose_replacement1 relation1_def)
   619 done
   620 
   621 lemma (in M_eclose) eclose_closed [intro,simp]:
   622      "M(A) ==> M(eclose(A))"
   623 apply (insert eclose_replacement1)
   624 by  (simp add: RepFun_closed2 eclose_eq_Union
   625                eclose_replacement2' relation1_def
   626                iterates_closed [of "big_union(M)"])
   627 
   628 lemma (in M_eclose) is_eclose_n_abs [simp]:
   629      "[|M(A); n\<in>nat; M(Z)|] ==> is_eclose_n(M,A,n,Z) <-> Z = Union^n (A)"
   630 apply (insert eclose_replacement1)
   631 apply (simp add: is_eclose_n_def relation1_def nat_into_M
   632                  iterates_abs [of "big_union(M)" _ "Union"])
   633 done
   634 
   635 lemma (in M_eclose) mem_eclose_abs [simp]:
   636      "M(A) ==> mem_eclose(M,A,l) <-> l \<in> eclose(A)"
   637 apply (insert eclose_replacement1)
   638 apply (simp add: mem_eclose_def relation1_def eclose_eq_Union
   639                  iterates_closed [of "big_union(M)"])
   640 done
   641 
   642 lemma (in M_eclose) eclose_abs [simp]:
   643      "[|M(A); M(Z)|] ==> is_eclose(M,A,Z) <-> Z = eclose(A)"
   644 apply (simp add: is_eclose_def, safe)
   645 apply (rule M_equalityI, simp_all)
   646 done
   647 
   648 
   649 subsection {*Absoluteness for @{term transrec}*}
   650 
   651 text{* @{prop "transrec(a,H) \<equiv> wfrec(Memrel(eclose({a})), a, H)"} *}
   652 
   653 definition
   654   is_transrec :: "[i=>o, [i,i,i]=>o, i, i] => o" where
   655    "is_transrec(M,MH,a,z) ==
   656       \<exists>sa[M]. \<exists>esa[M]. \<exists>mesa[M].
   657        upair(M,a,a,sa) & is_eclose(M,sa,esa) & membership(M,esa,mesa) &
   658        is_wfrec(M,MH,mesa,a,z)"
   659 
   660 definition
   661   transrec_replacement :: "[i=>o, [i,i,i]=>o, i] => o" where
   662    "transrec_replacement(M,MH,a) ==
   663       \<exists>sa[M]. \<exists>esa[M]. \<exists>mesa[M].
   664        upair(M,a,a,sa) & is_eclose(M,sa,esa) & membership(M,esa,mesa) &
   665        wfrec_replacement(M,MH,mesa)"
   666 
   667 text{*The condition @{term "Ord(i)"} lets us use the simpler
   668   @{text "trans_wfrec_abs"} rather than @{text "trans_wfrec_abs"},
   669   which I haven't even proved yet. *}
   670 theorem (in M_eclose) transrec_abs:
   671   "[|transrec_replacement(M,MH,i);  relation2(M,MH,H);
   672      Ord(i);  M(i);  M(z);
   673      \<forall>x[M]. \<forall>g[M]. function(g) --> M(H(x,g))|]
   674    ==> is_transrec(M,MH,i,z) <-> z = transrec(i,H)"
   675 by (simp add: trans_wfrec_abs transrec_replacement_def is_transrec_def
   676        transrec_def eclose_sing_Ord_eq wf_Memrel trans_Memrel relation_Memrel)
   677 
   678 
   679 theorem (in M_eclose) transrec_closed:
   680      "[|transrec_replacement(M,MH,i);  relation2(M,MH,H);
   681 	Ord(i);  M(i);
   682 	\<forall>x[M]. \<forall>g[M]. function(g) --> M(H(x,g))|]
   683       ==> M(transrec(i,H))"
   684 by (simp add: trans_wfrec_closed transrec_replacement_def is_transrec_def
   685         transrec_def eclose_sing_Ord_eq wf_Memrel trans_Memrel relation_Memrel)
   686 
   687 
   688 text{*Helps to prove instances of @{term transrec_replacement}*}
   689 lemma (in M_eclose) transrec_replacementI:
   690    "[|M(a);
   691       strong_replacement (M,
   692                   \<lambda>x z. \<exists>y[M]. pair(M, x, y, z) &
   693                                is_wfrec(M,MH,Memrel(eclose({a})),x,y))|]
   694     ==> transrec_replacement(M,MH,a)"
   695 by (simp add: transrec_replacement_def wfrec_replacement_def)
   696 
   697 
   698 subsection{*Absoluteness for the List Operator @{term length}*}
   699 text{*But it is never used.*}
   700 
   701 definition
   702   is_length :: "[i=>o,i,i,i] => o" where
   703     "is_length(M,A,l,n) ==
   704        \<exists>sn[M]. \<exists>list_n[M]. \<exists>list_sn[M].
   705         is_list_N(M,A,n,list_n) & l \<notin> list_n &
   706         successor(M,n,sn) & is_list_N(M,A,sn,list_sn) & l \<in> list_sn"
   707 
   708 
   709 lemma (in M_datatypes) length_abs [simp]:
   710      "[|M(A); l \<in> list(A); n \<in> nat|] ==> is_length(M,A,l,n) <-> n = length(l)"
   711 apply (subgoal_tac "M(l) & M(n)")
   712  prefer 2 apply (blast dest: transM)
   713 apply (simp add: is_length_def)
   714 apply (blast intro: list_imp_list_N nat_into_Ord list_N_imp_eq_length
   715              dest: list_N_imp_length_lt)
   716 done
   717 
   718 text{*Proof is trivial since @{term length} returns natural numbers.*}
   719 lemma (in M_trivial) length_closed [intro,simp]:
   720      "l \<in> list(A) ==> M(length(l))"
   721 by (simp add: nat_into_M)
   722 
   723 
   724 subsection {*Absoluteness for the List Operator @{term nth}*}
   725 
   726 lemma nth_eq_hd_iterates_tl [rule_format]:
   727      "xs \<in> list(A) ==> \<forall>n \<in> nat. nth(n,xs) = hd' (tl'^n (xs))"
   728 apply (induct_tac xs)
   729 apply (simp add: iterates_tl_Nil hd'_Nil, clarify)
   730 apply (erule natE)
   731 apply (simp add: hd'_Cons)
   732 apply (simp add: tl'_Cons iterates_commute)
   733 done
   734 
   735 lemma (in M_basic) iterates_tl'_closed:
   736      "[|n \<in> nat; M(x)|] ==> M(tl'^n (x))"
   737 apply (induct_tac n, simp)
   738 apply (simp add: tl'_Cons tl'_closed)
   739 done
   740 
   741 text{*Immediate by type-checking*}
   742 lemma (in M_datatypes) nth_closed [intro,simp]:
   743      "[|xs \<in> list(A); n \<in> nat; M(A)|] ==> M(nth(n,xs))"
   744 apply (case_tac "n < length(xs)")
   745  apply (blast intro: nth_type transM)
   746 apply (simp add: not_lt_iff_le nth_eq_0)
   747 done
   748 
   749 definition
   750   is_nth :: "[i=>o,i,i,i] => o" where
   751     "is_nth(M,n,l,Z) ==
   752       \<exists>X[M]. is_iterates(M, is_tl(M), l, n, X) & is_hd(M,X,Z)"
   753 
   754 lemma (in M_datatypes) nth_abs [simp]:
   755      "[|M(A); n \<in> nat; l \<in> list(A); M(Z)|]
   756       ==> is_nth(M,n,l,Z) <-> Z = nth(n,l)"
   757 apply (subgoal_tac "M(l)")
   758  prefer 2 apply (blast intro: transM)
   759 apply (simp add: is_nth_def nth_eq_hd_iterates_tl nat_into_M
   760                  tl'_closed iterates_tl'_closed
   761                  iterates_abs [OF _ relation1_tl] nth_replacement)
   762 done
   763 
   764 
   765 subsection{*Relativization and Absoluteness for the @{term formula} Constructors*}
   766 
   767 definition
   768   is_Member :: "[i=>o,i,i,i] => o" where
   769      --{* because @{term "Member(x,y) \<equiv> Inl(Inl(\<langle>x,y\<rangle>))"}*}
   770     "is_Member(M,x,y,Z) ==
   771 	\<exists>p[M]. \<exists>u[M]. pair(M,x,y,p) & is_Inl(M,p,u) & is_Inl(M,u,Z)"
   772 
   773 lemma (in M_trivial) Member_abs [simp]:
   774      "[|M(x); M(y); M(Z)|] ==> is_Member(M,x,y,Z) <-> (Z = Member(x,y))"
   775 by (simp add: is_Member_def Member_def)
   776 
   777 lemma (in M_trivial) Member_in_M_iff [iff]:
   778      "M(Member(x,y)) <-> M(x) & M(y)"
   779 by (simp add: Member_def)
   780 
   781 definition
   782   is_Equal :: "[i=>o,i,i,i] => o" where
   783      --{* because @{term "Equal(x,y) \<equiv> Inl(Inr(\<langle>x,y\<rangle>))"}*}
   784     "is_Equal(M,x,y,Z) ==
   785 	\<exists>p[M]. \<exists>u[M]. pair(M,x,y,p) & is_Inr(M,p,u) & is_Inl(M,u,Z)"
   786 
   787 lemma (in M_trivial) Equal_abs [simp]:
   788      "[|M(x); M(y); M(Z)|] ==> is_Equal(M,x,y,Z) <-> (Z = Equal(x,y))"
   789 by (simp add: is_Equal_def Equal_def)
   790 
   791 lemma (in M_trivial) Equal_in_M_iff [iff]: "M(Equal(x,y)) <-> M(x) & M(y)"
   792 by (simp add: Equal_def)
   793 
   794 definition
   795   is_Nand :: "[i=>o,i,i,i] => o" where
   796      --{* because @{term "Nand(x,y) \<equiv> Inr(Inl(\<langle>x,y\<rangle>))"}*}
   797     "is_Nand(M,x,y,Z) ==
   798 	\<exists>p[M]. \<exists>u[M]. pair(M,x,y,p) & is_Inl(M,p,u) & is_Inr(M,u,Z)"
   799 
   800 lemma (in M_trivial) Nand_abs [simp]:
   801      "[|M(x); M(y); M(Z)|] ==> is_Nand(M,x,y,Z) <-> (Z = Nand(x,y))"
   802 by (simp add: is_Nand_def Nand_def)
   803 
   804 lemma (in M_trivial) Nand_in_M_iff [iff]: "M(Nand(x,y)) <-> M(x) & M(y)"
   805 by (simp add: Nand_def)
   806 
   807 definition
   808   is_Forall :: "[i=>o,i,i] => o" where
   809      --{* because @{term "Forall(x) \<equiv> Inr(Inr(p))"}*}
   810     "is_Forall(M,p,Z) == \<exists>u[M]. is_Inr(M,p,u) & is_Inr(M,u,Z)"
   811 
   812 lemma (in M_trivial) Forall_abs [simp]:
   813      "[|M(x); M(Z)|] ==> is_Forall(M,x,Z) <-> (Z = Forall(x))"
   814 by (simp add: is_Forall_def Forall_def)
   815 
   816 lemma (in M_trivial) Forall_in_M_iff [iff]: "M(Forall(x)) <-> M(x)"
   817 by (simp add: Forall_def)
   818 
   819 
   820 
   821 subsection {*Absoluteness for @{term formula_rec}*}
   822 
   823 definition
   824   formula_rec_case :: "[[i,i]=>i, [i,i]=>i, [i,i,i,i]=>i, [i,i]=>i, i, i] => i" where
   825     --{* the instance of @{term formula_case} in @{term formula_rec}*}
   826    "formula_rec_case(a,b,c,d,h) ==
   827         formula_case (a, b,
   828                 \<lambda>u v. c(u, v, h ` succ(depth(u)) ` u,
   829                               h ` succ(depth(v)) ` v),
   830                 \<lambda>u. d(u, h ` succ(depth(u)) ` u))"
   831 
   832 text{*Unfold @{term formula_rec} to @{term formula_rec_case}.
   833      Express @{term formula_rec} without using @{term rank} or @{term Vset},
   834 neither of which is absolute.*}
   835 lemma (in M_trivial) formula_rec_eq:
   836   "p \<in> formula ==>
   837    formula_rec(a,b,c,d,p) =
   838    transrec (succ(depth(p)),
   839              \<lambda>x h. Lambda (formula, formula_rec_case(a,b,c,d,h))) ` p"
   840 apply (simp add: formula_rec_case_def)
   841 apply (induct_tac p)
   842    txt{*Base case for @{term Member}*}
   843    apply (subst transrec, simp add: formula.intros)
   844   txt{*Base case for @{term Equal}*}
   845   apply (subst transrec, simp add: formula.intros)
   846  txt{*Inductive step for @{term Nand}*}
   847  apply (subst transrec)
   848  apply (simp add: succ_Un_distrib formula.intros)
   849 txt{*Inductive step for @{term Forall}*}
   850 apply (subst transrec)
   851 apply (simp add: formula_imp_formula_N formula.intros)
   852 done
   853 
   854 
   855 subsubsection{*Absoluteness for the Formula Operator @{term depth}*}
   856 
   857 definition
   858   is_depth :: "[i=>o,i,i] => o" where
   859     "is_depth(M,p,n) ==
   860        \<exists>sn[M]. \<exists>formula_n[M]. \<exists>formula_sn[M].
   861         is_formula_N(M,n,formula_n) & p \<notin> formula_n &
   862         successor(M,n,sn) & is_formula_N(M,sn,formula_sn) & p \<in> formula_sn"
   863 
   864 
   865 lemma (in M_datatypes) depth_abs [simp]:
   866      "[|p \<in> formula; n \<in> nat|] ==> is_depth(M,p,n) <-> n = depth(p)"
   867 apply (subgoal_tac "M(p) & M(n)")
   868  prefer 2 apply (blast dest: transM)
   869 apply (simp add: is_depth_def)
   870 apply (blast intro: formula_imp_formula_N nat_into_Ord formula_N_imp_eq_depth
   871              dest: formula_N_imp_depth_lt)
   872 done
   873 
   874 text{*Proof is trivial since @{term depth} returns natural numbers.*}
   875 lemma (in M_trivial) depth_closed [intro,simp]:
   876      "p \<in> formula ==> M(depth(p))"
   877 by (simp add: nat_into_M)
   878 
   879 
   880 subsubsection{*@{term is_formula_case}: relativization of @{term formula_case}*}
   881 
   882 definition
   883  is_formula_case ::
   884     "[i=>o, [i,i,i]=>o, [i,i,i]=>o, [i,i,i]=>o, [i,i]=>o, i, i] => o" where
   885   --{*no constraint on non-formulas*}
   886   "is_formula_case(M, is_a, is_b, is_c, is_d, p, z) ==
   887       (\<forall>x[M]. \<forall>y[M]. finite_ordinal(M,x) --> finite_ordinal(M,y) -->
   888                       is_Member(M,x,y,p) --> is_a(x,y,z)) &
   889       (\<forall>x[M]. \<forall>y[M]. finite_ordinal(M,x) --> finite_ordinal(M,y) -->
   890                       is_Equal(M,x,y,p) --> is_b(x,y,z)) &
   891       (\<forall>x[M]. \<forall>y[M]. mem_formula(M,x) --> mem_formula(M,y) -->
   892                      is_Nand(M,x,y,p) --> is_c(x,y,z)) &
   893       (\<forall>x[M]. mem_formula(M,x) --> is_Forall(M,x,p) --> is_d(x,z))"
   894 
   895 lemma (in M_datatypes) formula_case_abs [simp]:
   896      "[| Relation2(M,nat,nat,is_a,a); Relation2(M,nat,nat,is_b,b);
   897          Relation2(M,formula,formula,is_c,c); Relation1(M,formula,is_d,d);
   898          p \<in> formula; M(z) |]
   899       ==> is_formula_case(M,is_a,is_b,is_c,is_d,p,z) <->
   900           z = formula_case(a,b,c,d,p)"
   901 apply (simp add: formula_into_M is_formula_case_def)
   902 apply (erule formula.cases)
   903    apply (simp_all add: Relation1_def Relation2_def)
   904 done
   905 
   906 lemma (in M_datatypes) formula_case_closed [intro,simp]:
   907   "[|p \<in> formula;
   908      \<forall>x[M]. \<forall>y[M]. x\<in>nat --> y\<in>nat --> M(a(x,y));
   909      \<forall>x[M]. \<forall>y[M]. x\<in>nat --> y\<in>nat --> M(b(x,y));
   910      \<forall>x[M]. \<forall>y[M]. x\<in>formula --> y\<in>formula --> M(c(x,y));
   911      \<forall>x[M]. x\<in>formula --> M(d(x))|] ==> M(formula_case(a,b,c,d,p))"
   912 by (erule formula.cases, simp_all)
   913 
   914 
   915 subsubsection {*Absoluteness for @{term formula_rec}: Final Results*}
   916 
   917 definition
   918   is_formula_rec :: "[i=>o, [i,i,i]=>o, i, i] => o" where
   919     --{* predicate to relativize the functional @{term formula_rec}*}
   920    "is_formula_rec(M,MH,p,z)  ==
   921       \<exists>dp[M]. \<exists>i[M]. \<exists>f[M]. finite_ordinal(M,dp) & is_depth(M,p,dp) &
   922              successor(M,dp,i) & fun_apply(M,f,p,z) & is_transrec(M,MH,i,f)"
   923 
   924 
   925 text{*Sufficient conditions to relativize the instance of @{term formula_case}
   926       in @{term formula_rec}*}
   927 lemma (in M_datatypes) Relation1_formula_rec_case:
   928      "[|Relation2(M, nat, nat, is_a, a);
   929         Relation2(M, nat, nat, is_b, b);
   930         Relation2 (M, formula, formula,
   931            is_c, \<lambda>u v. c(u, v, h`succ(depth(u))`u, h`succ(depth(v))`v));
   932         Relation1(M, formula,
   933            is_d, \<lambda>u. d(u, h ` succ(depth(u)) ` u));
   934  	M(h) |]
   935       ==> Relation1(M, formula,
   936                          is_formula_case (M, is_a, is_b, is_c, is_d),
   937                          formula_rec_case(a, b, c, d, h))"
   938 apply (simp (no_asm) add: formula_rec_case_def Relation1_def)
   939 apply (simp add: formula_case_abs)
   940 done
   941 
   942 
   943 text{*This locale packages the premises of the following theorems,
   944       which is the normal purpose of locales.  It doesn't accumulate
   945       constraints on the class @{term M}, as in most of this deveopment.*}
   946 locale Formula_Rec = M_eclose +
   947   fixes a and is_a and b and is_b and c and is_c and d and is_d and MH
   948   defines
   949       "MH(u::i,f,z) ==
   950 	\<forall>fml[M]. is_formula(M,fml) -->
   951              is_lambda
   952 	 (M, fml, is_formula_case (M, is_a, is_b, is_c(f), is_d(f)), z)"
   953 
   954   assumes a_closed: "[|x\<in>nat; y\<in>nat|] ==> M(a(x,y))"
   955       and a_rel:    "Relation2(M, nat, nat, is_a, a)"
   956       and b_closed: "[|x\<in>nat; y\<in>nat|] ==> M(b(x,y))"
   957       and b_rel:    "Relation2(M, nat, nat, is_b, b)"
   958       and c_closed: "[|x \<in> formula; y \<in> formula; M(gx); M(gy)|]
   959                      ==> M(c(x, y, gx, gy))"
   960       and c_rel:
   961          "M(f) ==>
   962           Relation2 (M, formula, formula, is_c(f),
   963              \<lambda>u v. c(u, v, f ` succ(depth(u)) ` u, f ` succ(depth(v)) ` v))"
   964       and d_closed: "[|x \<in> formula; M(gx)|] ==> M(d(x, gx))"
   965       and d_rel:
   966          "M(f) ==>
   967           Relation1(M, formula, is_d(f), \<lambda>u. d(u, f ` succ(depth(u)) ` u))"
   968       and fr_replace: "n \<in> nat ==> transrec_replacement(M,MH,n)"
   969       and fr_lam_replace:
   970            "M(g) ==>
   971             strong_replacement
   972 	      (M, \<lambda>x y. x \<in> formula &
   973 		  y = \<langle>x, formula_rec_case(a,b,c,d,g,x)\<rangle>)";
   974 
   975 lemma (in Formula_Rec) formula_rec_case_closed:
   976     "[|M(g); p \<in> formula|] ==> M(formula_rec_case(a, b, c, d, g, p))"
   977 by (simp add: formula_rec_case_def a_closed b_closed c_closed d_closed)
   978 
   979 lemma (in Formula_Rec) formula_rec_lam_closed:
   980     "M(g) ==> M(Lambda (formula, formula_rec_case(a,b,c,d,g)))"
   981 by (simp add: lam_closed2 fr_lam_replace formula_rec_case_closed)
   982 
   983 lemma (in Formula_Rec) MH_rel2:
   984      "relation2 (M, MH,
   985              \<lambda>x h. Lambda (formula, formula_rec_case(a,b,c,d,h)))"
   986 apply (simp add: relation2_def MH_def, clarify)
   987 apply (rule lambda_abs2)
   988 apply (rule Relation1_formula_rec_case)
   989 apply (simp_all add: a_rel b_rel c_rel d_rel formula_rec_case_closed)
   990 done
   991 
   992 lemma (in Formula_Rec) fr_transrec_closed:
   993     "n \<in> nat
   994      ==> M(transrec
   995           (n, \<lambda>x h. Lambda(formula, formula_rec_case(a, b, c, d, h))))"
   996 by (simp add: transrec_closed [OF fr_replace MH_rel2]
   997               nat_into_M formula_rec_lam_closed)
   998 
   999 text{*The main two results: @{term formula_rec} is absolute for @{term M}.*}
  1000 theorem (in Formula_Rec) formula_rec_closed:
  1001     "p \<in> formula ==> M(formula_rec(a,b,c,d,p))"
  1002 by (simp add: formula_rec_eq fr_transrec_closed
  1003               transM [OF _ formula_closed])
  1004 
  1005 theorem (in Formula_Rec) formula_rec_abs:
  1006   "[| p \<in> formula; M(z)|]
  1007    ==> is_formula_rec(M,MH,p,z) <-> z = formula_rec(a,b,c,d,p)"
  1008 by (simp add: is_formula_rec_def formula_rec_eq transM [OF _ formula_closed]
  1009               transrec_abs [OF fr_replace MH_rel2] depth_type
  1010               fr_transrec_closed formula_rec_lam_closed eq_commute)
  1011 
  1012 
  1013 end