src/Pure/sign.ML
author wenzelm
Tue Mar 31 22:31:05 2015 +0200 (2015-03-31)
changeset 59886 e0dc738eb08c
parent 59880 30687c3f2b10
child 59896 e563b0ee0331
permissions -rw-r--r--
support for explicit scope of private entries;
     1 (*  Title:      Pure/sign.ML
     2     Author:     Lawrence C Paulson and Markus Wenzel
     3 
     4 Logical signature content: naming conventions, concrete syntax, type
     5 signature, polymorphic constants.
     6 *)
     7 
     8 signature SIGN =
     9 sig
    10   val change_begin: theory -> theory
    11   val change_end: theory -> theory
    12   val change_end_local: Proof.context -> Proof.context
    13   val change_check: theory -> theory
    14   val syn_of: theory -> Syntax.syntax
    15   val tsig_of: theory -> Type.tsig
    16   val classes_of: theory -> Sorts.algebra
    17   val all_classes: theory -> class list
    18   val super_classes: theory -> class -> class list
    19   val minimize_sort: theory -> sort -> sort
    20   val complete_sort: theory -> sort -> sort
    21   val set_defsort: sort -> theory -> theory
    22   val defaultS: theory -> sort
    23   val subsort: theory -> sort * sort -> bool
    24   val of_sort: theory -> typ * sort -> bool
    25   val inter_sort: theory -> sort * sort -> sort
    26   val witness_sorts: theory -> (typ * sort) list -> sort list -> (typ * sort) list
    27   val logical_types: theory -> string list
    28   val typ_instance: theory -> typ * typ -> bool
    29   val typ_equiv: theory -> typ * typ -> bool
    30   val typ_match: theory -> typ * typ -> Type.tyenv -> Type.tyenv
    31   val typ_unify: theory -> typ * typ -> Type.tyenv * int -> Type.tyenv * int
    32   val consts_of: theory -> Consts.T
    33   val the_const_constraint: theory -> string -> typ
    34   val const_type: theory -> string -> typ option
    35   val the_const_type: theory -> string -> typ
    36   val declared_tyname: theory -> string -> bool
    37   val declared_const: theory -> string -> bool
    38   val naming_of: theory -> Name_Space.naming
    39   val map_naming: (Name_Space.naming -> Name_Space.naming) -> theory -> theory
    40   val restore_naming: theory -> theory -> theory
    41   val inherit_naming: theory -> Proof.context -> Context.generic
    42   val full_name: theory -> binding -> string
    43   val full_name_path: theory -> string -> binding -> string
    44   val full_bname: theory -> bstring -> string
    45   val full_bname_path: theory -> string -> bstring -> string
    46   val const_monomorphic: theory -> string -> bool
    47   val const_typargs: theory -> string * typ -> typ list
    48   val const_instance: theory -> string * typ list -> typ
    49   val mk_const: theory -> string * typ list -> term
    50   val class_space: theory -> Name_Space.T
    51   val type_space: theory -> Name_Space.T
    52   val const_space: theory -> Name_Space.T
    53   val intern_class: theory -> xstring -> string
    54   val intern_type: theory -> xstring -> string
    55   val intern_const: theory -> xstring -> string
    56   val class_alias: binding -> class -> theory -> theory
    57   val type_alias: binding -> string -> theory -> theory
    58   val const_alias: binding -> string -> theory -> theory
    59   val arity_number: theory -> string -> int
    60   val arity_sorts: theory -> string -> sort -> sort list
    61   val certify_class: theory -> class -> class
    62   val certify_sort: theory -> sort -> sort
    63   val certify_typ: theory -> typ -> typ
    64   val certify_typ_mode: Type.mode -> theory -> typ -> typ
    65   val certify': bool -> Context.pretty -> bool -> Consts.T -> theory -> term -> term * typ * int
    66   val certify_term: theory -> term -> term * typ * int
    67   val cert_term: theory -> term -> term
    68   val cert_prop: theory -> term -> term
    69   val no_frees: Proof.context -> term -> term
    70   val no_vars: Proof.context -> term -> term
    71   val add_type: Proof.context -> binding * int * mixfix -> theory -> theory
    72   val add_types_global: (binding * int * mixfix) list -> theory -> theory
    73   val add_nonterminals: Proof.context -> binding list -> theory -> theory
    74   val add_nonterminals_global: binding list -> theory -> theory
    75   val add_type_abbrev: Proof.context -> binding * string list * typ -> theory -> theory
    76   val add_syntax: Syntax.mode -> (string * typ * mixfix) list -> theory -> theory
    77   val add_syntax_cmd: Syntax.mode -> (string * string * mixfix) list -> theory -> theory
    78   val del_syntax: Syntax.mode -> (string * typ * mixfix) list -> theory -> theory
    79   val del_syntax_cmd: Syntax.mode -> (string * string * mixfix) list -> theory -> theory
    80   val type_notation: bool -> Syntax.mode -> (typ * mixfix) list -> theory -> theory
    81   val notation: bool -> Syntax.mode -> (term * mixfix) list -> theory -> theory
    82   val declare_const: Proof.context -> (binding * typ) * mixfix -> theory -> term * theory
    83   val declare_const_global: (binding * typ) * mixfix -> theory -> term * theory
    84   val add_consts: (binding * typ * mixfix) list -> theory -> theory
    85   val add_consts_cmd: (binding * string * mixfix) list -> theory -> theory
    86   val add_abbrev: string -> binding * term -> theory -> (term * term) * theory
    87   val revert_abbrev: string -> string -> theory -> theory
    88   val add_const_constraint: string * typ option -> theory -> theory
    89   val primitive_class: binding * class list -> theory -> theory
    90   val primitive_classrel: class * class -> theory -> theory
    91   val primitive_arity: arity -> theory -> theory
    92   val parse_ast_translation:
    93     (string * (Proof.context -> Ast.ast list -> Ast.ast)) list -> theory -> theory
    94   val parse_translation:
    95     (string * (Proof.context -> term list -> term)) list -> theory -> theory
    96   val print_translation:
    97     (string * (Proof.context -> term list -> term)) list -> theory -> theory
    98   val typed_print_translation:
    99     (string * (Proof.context -> typ -> term list -> term)) list -> theory -> theory
   100   val print_ast_translation:
   101     (string * (Proof.context -> Ast.ast list -> Ast.ast)) list -> theory -> theory
   102   val add_trrules: Ast.ast Syntax.trrule list -> theory -> theory
   103   val del_trrules: Ast.ast Syntax.trrule list -> theory -> theory
   104   val get_scope: theory -> Binding.scope option
   105   val new_scope: theory -> Binding.scope * theory
   106   val new_group: theory -> theory
   107   val reset_group: theory -> theory
   108   val add_path: string -> theory -> theory
   109   val root_path: theory -> theory
   110   val parent_path: theory -> theory
   111   val mandatory_path: string -> theory -> theory
   112   val qualified_path: bool -> binding -> theory -> theory
   113   val local_path: theory -> theory
   114   val concealed: theory -> theory
   115   val hide_class: bool -> string -> theory -> theory
   116   val hide_type: bool -> string -> theory -> theory
   117   val hide_const: bool -> string -> theory -> theory
   118 end
   119 
   120 structure Sign: SIGN =
   121 struct
   122 
   123 (** datatype sign **)
   124 
   125 datatype sign = Sign of
   126  {syn: Syntax.syntax,           (*concrete syntax for terms, types, sorts*)
   127   tsig: Type.tsig,              (*order-sorted signature of types*)
   128   consts: Consts.T};            (*polymorphic constants*)
   129 
   130 fun make_sign (syn, tsig, consts) = Sign {syn = syn, tsig = tsig, consts = consts};
   131 
   132 structure Data = Theory_Data_PP
   133 (
   134   type T = sign;
   135   fun extend (Sign {syn, tsig, consts, ...}) = make_sign (syn, tsig, consts);
   136 
   137   val empty = make_sign (Syntax.empty_syntax, Type.empty_tsig, Consts.empty);
   138 
   139   fun merge pp (sign1, sign2) =
   140     let
   141       val Sign {syn = syn1, tsig = tsig1, consts = consts1} = sign1;
   142       val Sign {syn = syn2, tsig = tsig2, consts = consts2} = sign2;
   143 
   144       val syn = Syntax.merge_syntax (syn1, syn2);
   145       val tsig = Type.merge_tsig pp (tsig1, tsig2);
   146       val consts = Consts.merge (consts1, consts2);
   147     in make_sign (syn, tsig, consts) end;
   148 );
   149 
   150 fun rep_sg thy = Data.get thy |> (fn Sign args => args);
   151 
   152 fun map_sign f = Data.map (fn Sign {syn, tsig, consts} => make_sign (f (syn, tsig, consts)));
   153 
   154 fun map_syn f = map_sign (fn (syn, tsig, consts) => (f syn, tsig, consts));
   155 fun map_tsig f = map_sign (fn (syn, tsig, consts) => (syn, f tsig, consts));
   156 fun map_consts f = map_sign (fn (syn, tsig, consts) => (syn, tsig, f consts));
   157 
   158 
   159 (* linear change discipline *)
   160 
   161 fun change_base begin = map_sign (fn (syn, tsig, consts) =>
   162   (syn, Type.change_base begin tsig, Consts.change_base begin consts));
   163 
   164 val change_begin = change_base true;
   165 val change_end = change_base false;
   166 
   167 fun change_end_local ctxt =
   168   Context.raw_transfer (change_end (Proof_Context.theory_of ctxt)) ctxt;
   169 
   170 fun change_check thy =
   171   if can change_end thy
   172   then raise Fail "Unfinished linear change of theory content" else thy;
   173 
   174 
   175 (* syntax *)
   176 
   177 val syn_of = #syn o rep_sg;
   178 
   179 
   180 (* type signature *)
   181 
   182 val tsig_of = #tsig o rep_sg;
   183 
   184 val classes_of = #2 o #classes o Type.rep_tsig o tsig_of;
   185 val all_classes = Sorts.all_classes o classes_of;
   186 val super_classes = Sorts.super_classes o classes_of;
   187 val minimize_sort = Sorts.minimize_sort o classes_of;
   188 val complete_sort = Sorts.complete_sort o classes_of;
   189 
   190 val set_defsort = map_tsig o Type.set_defsort;
   191 val defaultS = Type.defaultS o tsig_of;
   192 val subsort = Type.subsort o tsig_of;
   193 val of_sort = Type.of_sort o tsig_of;
   194 val inter_sort = Type.inter_sort o tsig_of;
   195 val witness_sorts = Type.witness_sorts o tsig_of;
   196 val logical_types = Type.logical_types o tsig_of;
   197 
   198 val typ_instance = Type.typ_instance o tsig_of;
   199 fun typ_equiv thy (T, U) = typ_instance thy (T, U) andalso typ_instance thy (U, T);
   200 val typ_match = Type.typ_match o tsig_of;
   201 val typ_unify = Type.unify o tsig_of;
   202 
   203 
   204 (* polymorphic constants *)
   205 
   206 val consts_of = #consts o rep_sg;
   207 val the_const_constraint = Consts.the_constraint o consts_of;
   208 val the_const_type = #2 oo (Consts.the_const o consts_of);
   209 val const_type = try o the_const_type;
   210 val const_monomorphic = Consts.is_monomorphic o consts_of;
   211 val const_typargs = Consts.typargs o consts_of;
   212 val const_instance = Consts.instance o consts_of;
   213 
   214 fun mk_const thy (c, Ts) = Const (c, const_instance thy (c, Ts));
   215 
   216 fun declared_tyname ctxt c = can (Type.the_decl (tsig_of ctxt)) (c, Position.none);
   217 val declared_const = can o the_const_constraint;
   218 
   219 
   220 (* naming *)
   221 
   222 val naming_of = Name_Space.naming_of o Context.Theory;
   223 val map_naming = Context.theory_map o Name_Space.map_naming;
   224 val restore_naming = map_naming o K o naming_of;
   225 fun inherit_naming thy = Name_Space.map_naming (K (naming_of thy)) o Context.Proof;
   226 
   227 val full_name = Name_Space.full_name o naming_of;
   228 fun full_name_path thy path = Name_Space.full_name (Name_Space.add_path path (naming_of thy));
   229 
   230 fun full_bname thy = Name_Space.full_name (naming_of thy) o Binding.name;
   231 fun full_bname_path thy path = full_name_path thy path o Binding.name;
   232 
   233 
   234 
   235 (** name spaces **)
   236 
   237 val class_space = Type.class_space o tsig_of;
   238 val type_space = Type.type_space o tsig_of;
   239 val const_space = Consts.space_of o consts_of;
   240 
   241 val intern_class = Name_Space.intern o class_space;
   242 val intern_type = Name_Space.intern o type_space;
   243 val intern_const = Name_Space.intern o const_space;
   244 
   245 fun class_alias b c thy = map_tsig (Type.class_alias (naming_of thy) b c) thy;
   246 fun type_alias b c thy = map_tsig (Type.type_alias (naming_of thy) b c) thy;
   247 fun const_alias b c thy = map_consts (Consts.alias (naming_of thy) b c) thy;
   248 
   249 
   250 
   251 (** certify entities **)    (*exception TYPE*)
   252 
   253 (* certify wrt. type signature *)
   254 
   255 val arity_number = Type.arity_number o tsig_of;
   256 fun arity_sorts thy = Type.arity_sorts (Context.pretty_global thy) (tsig_of thy);
   257 
   258 val certify_class = Type.cert_class o tsig_of;
   259 val certify_sort = Type.cert_sort o tsig_of;
   260 val certify_typ = Type.cert_typ o tsig_of;
   261 fun certify_typ_mode mode = Type.cert_typ_mode mode o tsig_of;
   262 
   263 
   264 (* certify term/prop *)
   265 
   266 local
   267 
   268 fun type_check pp tm =
   269   let
   270     fun err_appl bs t T u U =
   271       let
   272         val xs = map Free bs;           (*we do not rename here*)
   273         val t' = subst_bounds (xs, t);
   274         val u' = subst_bounds (xs, u);
   275         val msg = Type.appl_error (Syntax.init_pretty pp) t' T u' U;
   276       in raise TYPE (msg, [T, U], [t', u']) end;
   277 
   278     fun typ_of (_, Const (_, T)) = T
   279       | typ_of (_, Free  (_, T)) = T
   280       | typ_of (_, Var (_, T)) = T
   281       | typ_of (bs, Bound i) = snd (nth bs i handle General.Subscript =>
   282           raise TYPE ("Loose bound variable: B." ^ string_of_int i, [], [Bound i]))
   283       | typ_of (bs, Abs (x, T, body)) = T --> typ_of ((x, T) :: bs, body)
   284       | typ_of (bs, t $ u) =
   285           let val T = typ_of (bs, t) and U = typ_of (bs, u) in
   286             (case T of
   287               Type ("fun", [T1, T2]) =>
   288                 if T1 = U then T2 else err_appl bs t T u U
   289             | _ => err_appl bs t T u U)
   290           end;
   291   in typ_of ([], tm) end;
   292 
   293 fun err msg = raise TYPE (msg, [], []);
   294 
   295 fun check_vars (t $ u) = (check_vars t; check_vars u)
   296   | check_vars (Abs (_, _, t)) = check_vars t
   297   | check_vars (Free (x, _)) =
   298       if Long_Name.is_qualified x then err ("Malformed variable: " ^ quote x) else ()
   299   | check_vars (Var (xi as (_, i), _)) =
   300       if i < 0 then err ("Malformed variable: " ^ quote (Term.string_of_vname xi)) else ()
   301   | check_vars _ = ();
   302 
   303 in
   304 
   305 fun certify' prop pp do_expand consts thy tm =
   306   let
   307     val _ = check_vars tm;
   308     val tm' = Term.map_types (certify_typ thy) tm;
   309     val T = type_check pp tm';
   310     val _ = if prop andalso T <> propT then err "Term not of type prop" else ();
   311     val tm'' = Consts.certify pp (tsig_of thy) do_expand consts tm';
   312   in (if tm = tm'' then tm else tm'', T, Term.maxidx_of_term tm'') end;
   313 
   314 fun certify_term thy = certify' false (Context.pretty_global thy) true (consts_of thy) thy;
   315 fun cert_term_abbrev thy =
   316   #1 o certify' false (Context.pretty_global thy) false (consts_of thy) thy;
   317 val cert_term = #1 oo certify_term;
   318 fun cert_prop thy = #1 o certify' true (Context.pretty_global thy) true (consts_of thy) thy;
   319 
   320 end;
   321 
   322 
   323 (* specifications *)
   324 
   325 fun no_variables kind add addT mk mkT ctxt tm =
   326   (case (add tm [], addT tm []) of
   327     ([], []) => tm
   328   | (frees, tfrees) => error (Pretty.string_of (Pretty.block
   329       (Pretty.str ("Illegal " ^ kind ^ " variable(s) in term:") :: Pretty.brk 1 ::
   330        Pretty.commas
   331         (map (Syntax.pretty_term ctxt o mk) frees @ map (Syntax.pretty_typ ctxt o mkT) tfrees)))));
   332 
   333 val no_frees = no_variables "free" Term.add_frees Term.add_tfrees Free TFree;
   334 val no_vars = no_variables "schematic" Term.add_vars Term.add_tvars Var TVar;
   335 
   336 
   337 
   338 (** signature extension functions **)  (*exception ERROR/TYPE*)
   339 
   340 (* add type constructors *)
   341 
   342 fun add_type ctxt (b, n, mx) thy = thy |> map_sign (fn (syn, tsig, consts) =>
   343   let
   344     val type_syntax = (Lexicon.mark_type (full_name thy b), Mixfix.make_type n, mx);
   345     val syn' = Syntax.update_type_gram true Syntax.mode_default [type_syntax] syn;
   346     val tsig' = Type.add_type (inherit_naming thy ctxt) (b, n) tsig;
   347   in (syn', tsig', consts) end);
   348 
   349 fun add_types_global types thy =
   350   fold (add_type (Syntax.init_pretty_global thy)) types thy;
   351 
   352 
   353 (* add nonterminals *)
   354 
   355 fun add_nonterminals ctxt ns thy = thy |> map_sign (fn (syn, tsig, consts) =>
   356   (syn, fold (Type.add_nonterminal (inherit_naming thy ctxt)) ns tsig, consts));
   357 
   358 fun add_nonterminals_global ns thy =
   359   add_nonterminals (Syntax.init_pretty_global thy) ns thy;
   360 
   361 
   362 (* add type abbreviations *)
   363 
   364 fun add_type_abbrev ctxt abbr thy = thy |> map_sign (fn (syn, tsig, consts) =>
   365   (syn, Type.add_abbrev (inherit_naming thy ctxt) abbr tsig, consts));
   366 
   367 
   368 (* modify syntax *)
   369 
   370 fun gen_syntax change_gram parse_typ mode args thy =
   371   let
   372     val ctxt = Type.set_mode Type.mode_syntax (Proof_Context.init_global thy);
   373     fun prep (c, T, mx) = (c, certify_typ_mode Type.mode_syntax thy (parse_typ ctxt T), mx)
   374       handle ERROR msg => cat_error msg ("in syntax declaration " ^ quote c);
   375   in thy |> map_syn (change_gram (logical_types thy) mode (map prep args)) end;
   376 
   377 fun gen_add_syntax x = gen_syntax (Syntax.update_const_gram true) x;
   378 
   379 val add_syntax = gen_add_syntax (K I);
   380 val add_syntax_cmd = gen_add_syntax Syntax.read_typ;
   381 val del_syntax = gen_syntax (Syntax.update_const_gram false) (K I);
   382 val del_syntax_cmd = gen_syntax (Syntax.update_const_gram false) Syntax.read_typ;
   383 
   384 fun type_notation add mode args =
   385   let
   386     fun type_syntax (Type (c, args), mx) =
   387           SOME (Lexicon.mark_type c, Mixfix.make_type (length args), mx)
   388       | type_syntax _ = NONE;
   389   in map_syn (Syntax.update_type_gram add mode (map_filter type_syntax args)) end;
   390 
   391 fun notation add mode args thy =
   392   let
   393     fun const_syntax (Const (c, _), mx) =
   394           (case try (Consts.type_scheme (consts_of thy)) c of
   395             SOME T => SOME (Lexicon.mark_const c, T, mx)
   396           | NONE => NONE)
   397       | const_syntax _ = NONE;
   398   in gen_syntax (Syntax.update_const_gram add) (K I) mode (map_filter const_syntax args) thy end;
   399 
   400 
   401 (* add constants *)
   402 
   403 local
   404 
   405 fun gen_add_consts prep_typ ctxt raw_args thy =
   406   let
   407     val prepT = Type.no_tvars o Term.no_dummyT o certify_typ thy o prep_typ ctxt;
   408     fun prep (b, raw_T, mx) =
   409       let
   410         val c = full_name thy b;
   411         val T = (prepT raw_T handle TYPE (msg, _, _) => error msg) handle ERROR msg =>
   412           cat_error msg ("in declaration of constant " ^ Binding.print b);
   413         val T' = Logic.varifyT_global T;
   414       in ((b, T'), (Lexicon.mark_const c, T', mx), Const (c, T)) end;
   415     val args = map prep raw_args;
   416   in
   417     thy
   418     |> map_consts (fold (Consts.declare (inherit_naming thy ctxt) o #1) args)
   419     |> add_syntax Syntax.mode_default (map #2 args)
   420     |> pair (map #3 args)
   421   end;
   422 
   423 in
   424 
   425 fun add_consts args thy =
   426   #2 (gen_add_consts (K I) (Proof_Context.init_global thy) args thy);
   427 
   428 fun add_consts_cmd args thy =
   429   #2 (gen_add_consts Syntax.read_typ (Proof_Context.init_global thy) args thy);
   430 
   431 fun declare_const ctxt ((b, T), mx) = yield_singleton (gen_add_consts (K I) ctxt) (b, T, mx);
   432 fun declare_const_global arg thy = declare_const (Proof_Context.init_global thy) arg thy;
   433 
   434 end;
   435 
   436 
   437 (* abbreviations *)
   438 
   439 fun add_abbrev mode (b, raw_t) thy =  (* FIXME proper ctxt (?) *)
   440   let
   441     val ctxt = Syntax.init_pretty_global thy;
   442     val prep_tm = no_frees ctxt o Term.no_dummy_patterns o cert_term_abbrev thy;
   443     val t = (prep_tm raw_t handle TYPE (msg, _, _) => error msg | TERM (msg, _) => error msg)
   444       handle ERROR msg => cat_error msg ("in constant abbreviation " ^ Binding.print b);
   445     val (res, consts') = consts_of thy
   446       |> Consts.abbreviate (inherit_naming thy ctxt) (tsig_of thy) mode (b, t);
   447   in (res, thy |> map_consts (K consts')) end;
   448 
   449 fun revert_abbrev mode c = map_consts (Consts.revert_abbrev mode c);
   450 
   451 
   452 (* add constraints *)
   453 
   454 fun add_const_constraint (c, opt_T) thy =
   455   let
   456     fun prepT raw_T =
   457       let val T = Logic.varifyT_global (Type.no_tvars (Term.no_dummyT (certify_typ thy raw_T)))
   458       in cert_term thy (Const (c, T)); T end
   459       handle TYPE (msg, _, _) => error msg;
   460   in thy |> map_consts (Consts.constrain (c, Option.map prepT opt_T)) end;
   461 
   462 
   463 (* primitive classes and arities *)
   464 
   465 fun primitive_class (bclass, classes) thy =
   466   thy
   467   |> map_sign (fn (syn, tsig, consts) =>
   468       let val tsig' = Type.add_class (Context.Theory thy) (bclass, classes) tsig;
   469       in (syn, tsig', consts) end)
   470   |> add_consts [(Binding.map_name Logic.const_of_class bclass, Term.a_itselfT --> propT, NoSyn)];
   471 
   472 fun primitive_classrel arg thy =
   473   thy |> map_tsig (Type.add_classrel (Context.pretty_global thy) arg);
   474 
   475 fun primitive_arity arg thy =
   476   thy |> map_tsig (Type.add_arity (Context.pretty_global thy) arg);
   477 
   478 
   479 (* add translation functions *)
   480 
   481 local
   482 
   483 fun mk trs = map Syntax_Ext.mk_trfun trs;
   484 
   485 in
   486 
   487 fun parse_ast_translation atrs = map_syn (Syntax.update_trfuns (mk atrs, [], [], []));
   488 fun parse_translation trs = map_syn (Syntax.update_trfuns ([], mk trs, [], []));
   489 fun print_translation tr's =
   490   map_syn (Syntax.update_trfuns ([], [], mk (map (apsnd Syntax_Trans.non_typed_tr') tr's), []));
   491 fun typed_print_translation tr's = map_syn (Syntax.update_trfuns ([], [], mk tr's, []));
   492 fun print_ast_translation atr's = map_syn (Syntax.update_trfuns ([], [], [], mk atr's));
   493 
   494 end;
   495 
   496 
   497 (* translation rules *)
   498 
   499 val add_trrules = map_syn o Syntax.update_trrules;
   500 val del_trrules = map_syn o Syntax.remove_trrules;
   501 
   502 
   503 (* naming *)
   504 
   505 val get_scope = Name_Space.get_scope o naming_of;
   506 
   507 fun new_scope thy =
   508   let
   509     val (scope, naming') = Name_Space.new_scope (naming_of thy);
   510     val thy' = map_naming (K naming') thy;
   511   in (scope, thy') end;
   512 
   513 val new_group = map_naming Name_Space.new_group;
   514 val reset_group = map_naming Name_Space.reset_group;
   515 
   516 val add_path = map_naming o Name_Space.add_path;
   517 val root_path = map_naming Name_Space.root_path;
   518 val parent_path = map_naming Name_Space.parent_path;
   519 val mandatory_path = map_naming o Name_Space.mandatory_path;
   520 val qualified_path = map_naming oo Name_Space.qualified_path;
   521 
   522 fun local_path thy = thy |> root_path |> add_path (Context.theory_name thy);
   523 
   524 val concealed = map_naming Name_Space.concealed;
   525 
   526 
   527 (* hide names *)
   528 
   529 val hide_class = map_tsig oo Type.hide_class;
   530 val hide_type = map_tsig oo Type.hide_type;
   531 val hide_const = map_consts oo Consts.hide;
   532 
   533 end;