src/Pure/display.ML
author wenzelm
Mon Jun 20 22:14:04 2005 +0200 (2005-06-20)
changeset 16490 e10b0d5fa33a
parent 16437 aa87badf7a3c
child 16534 95460b6eb712
permissions -rw-r--r--
tuned;
     1 (*  Title:      Pure/display.ML
     2     ID:         $Id$
     3     Author:     Lawrence C Paulson, Cambridge University Computer Laboratory
     4     Copyright   1993  University of Cambridge
     5 
     6 Printing of theories, theorems, etc.
     7 *)
     8 
     9 signature BASIC_DISPLAY =
    10 sig
    11   val goals_limit: int ref
    12   val show_hyps: bool ref
    13   val show_tags: bool ref
    14   val string_of_thm: thm -> string
    15   val print_thm: thm -> unit
    16   val print_thms: thm list -> unit
    17   val prth: thm -> thm
    18   val prthq: thm Seq.seq -> thm Seq.seq
    19   val prths: thm list -> thm list
    20   val string_of_ctyp: ctyp -> string
    21   val print_ctyp: ctyp -> unit
    22   val string_of_cterm: cterm -> string
    23   val print_cterm: cterm -> unit
    24   val print_syntax: theory -> unit
    25   val show_consts: bool ref
    26 end;
    27 
    28 signature DISPLAY =
    29 sig
    30   include BASIC_DISPLAY
    31   val pretty_flexpair: Pretty.pp -> term * term -> Pretty.T
    32   val pretty_thm_aux: Pretty.pp -> bool -> thm -> Pretty.T
    33   val pretty_thm_no_quote: thm -> Pretty.T
    34   val pretty_thm: thm -> Pretty.T
    35   val pretty_thms: thm list -> Pretty.T
    36   val pretty_thm_sg: theory -> thm -> Pretty.T
    37   val pretty_thms_sg: theory -> thm list -> Pretty.T
    38   val pprint_thm: thm -> pprint_args -> unit
    39   val pretty_ctyp: ctyp -> Pretty.T
    40   val pprint_ctyp: ctyp -> pprint_args -> unit
    41   val pretty_cterm: cterm -> Pretty.T
    42   val pprint_cterm: cterm -> pprint_args -> unit
    43   val pretty_full_theory: theory -> Pretty.T list
    44   val pretty_goals_aux: Pretty.pp -> string -> bool * bool -> int -> thm -> Pretty.T list
    45   val pretty_goals: int -> thm -> Pretty.T list
    46   val print_goals: int -> thm -> unit
    47   val current_goals_markers: (string * string * string) ref
    48   val pretty_current_goals: int -> int -> thm -> Pretty.T list
    49   val print_current_goals_default: int -> int -> thm -> unit
    50   val print_current_goals_fn: (int -> int -> thm -> unit) ref
    51 end;
    52 
    53 structure Display: DISPLAY =
    54 struct
    55 
    56 
    57 (** print thm **)
    58 
    59 val goals_limit = ref 10;       (*max number of goals to print -- set by user*)
    60 val show_hyps = ref false;      (*false: print meta-hypotheses as dots*)
    61 val show_tags = ref false;      (*false: suppress tags*)
    62 
    63 fun pretty_tag (name, args) = Pretty.strs (name :: map Library.quote args);
    64 val pretty_tags = Pretty.list "[" "]" o map pretty_tag;
    65 
    66 fun pretty_flexpair pp (t, u) = Pretty.block
    67   [Pretty.term pp t, Pretty.str " =?=", Pretty.brk 1, Pretty.term pp u];
    68 
    69 fun pretty_thm_aux pp quote th =
    70   let
    71     val {hyps, tpairs, prop, der = (ora, _), ...} = Thm.rep_thm th;
    72     val xshyps = Thm.extra_shyps th;
    73     val (_, tags) = Thm.get_name_tags th;
    74 
    75     val q = if quote then Pretty.quote else I;
    76     val prt_term = q o (Pretty.term pp);
    77 
    78     val hlen = length xshyps + length hyps + length tpairs;
    79     val hsymbs =
    80       if hlen = 0 andalso not ora then []
    81       else if ! show_hyps then
    82         [Pretty.brk 2, Pretty.list "[" "]"
    83           (map (q o pretty_flexpair pp) tpairs @ map prt_term hyps @
    84            map (Pretty.sort pp) xshyps @
    85             (if ora then [Pretty.str "!"] else []))]
    86       else [Pretty.brk 2, Pretty.str ("[" ^ implode (replicate hlen ".") ^
    87         (if ora then "!" else "") ^ "]")];
    88     val tsymbs =
    89       if null tags orelse not (! show_tags) then []
    90       else [Pretty.brk 1, pretty_tags tags];
    91   in Pretty.block (prt_term prop :: (hsymbs @ tsymbs)) end;
    92 
    93 fun gen_pretty_thm quote th =
    94   pretty_thm_aux (Sign.pp (Thm.theory_of_thm th)) quote th;
    95 
    96 val pretty_thm = gen_pretty_thm true;
    97 val pretty_thm_no_quote = gen_pretty_thm false;
    98 
    99 
   100 val string_of_thm = Pretty.string_of o pretty_thm;
   101 val pprint_thm = Pretty.pprint o pretty_thm;
   102 
   103 fun pretty_thms [th] = pretty_thm th
   104   | pretty_thms ths = Pretty.block (Pretty.fbreaks (map pretty_thm ths));
   105 
   106 val pretty_thm_sg = pretty_thm oo Thm.transfer;
   107 val pretty_thms_sg = pretty_thms oo (map o Thm.transfer);
   108 
   109 
   110 (* top-level commands for printing theorems *)
   111 
   112 val print_thm = Pretty.writeln o pretty_thm;
   113 val print_thms = Pretty.writeln o pretty_thms;
   114 
   115 fun prth th = (print_thm th; th);
   116 
   117 (*Print and return a sequence of theorems, separated by blank lines. *)
   118 fun prthq thseq =
   119   (Seq.print (fn _ => print_thm) 100000 thseq; thseq);
   120 
   121 (*Print and return a list of theorems, separated by blank lines. *)
   122 fun prths ths = (List.app (fn th => (print_thm th; writeln "")) ths; ths);
   123 
   124 
   125 (* other printing commands *)
   126 
   127 fun pretty_ctyp cT =
   128   let val {thy, T, ...} = rep_ctyp cT in Sign.pretty_typ thy T end;
   129 
   130 fun pprint_ctyp cT =
   131   let val {thy, T, ...} = rep_ctyp cT in Sign.pprint_typ thy T end;
   132 
   133 fun string_of_ctyp cT =
   134   let val {thy, T, ...} = rep_ctyp cT in Sign.string_of_typ thy T end;
   135 
   136 val print_ctyp = writeln o string_of_ctyp;
   137 
   138 fun pretty_cterm ct =
   139   let val {thy, t, ...} = rep_cterm ct in Sign.pretty_term thy t end;
   140 
   141 fun pprint_cterm ct =
   142   let val {thy, t, ...} = rep_cterm ct in Sign.pprint_term thy t end;
   143 
   144 fun string_of_cterm ct =
   145   let val {thy, t, ...} = rep_cterm ct in Sign.string_of_term thy t end;
   146 
   147 val print_cterm = writeln o string_of_cterm;
   148 
   149 
   150 
   151 (** print theory **)
   152 
   153 val print_syntax = Syntax.print_syntax o Sign.syn_of;
   154 
   155 
   156 (* pretty_full_theory *)
   157 
   158 fun pretty_full_theory thy =
   159   let
   160     fun prt_cls c = Sign.pretty_sort thy [c];
   161     fun prt_sort S = Sign.pretty_sort thy S;
   162     fun prt_arity t (c, Ss) = Sign.pretty_arity thy (t, Ss, [c]);
   163     fun prt_typ ty = Pretty.quote (Sign.pretty_typ thy ty);
   164     val prt_typ_no_tvars = prt_typ o Type.freeze_type;
   165     fun prt_term t = Pretty.quote (Sign.pretty_term thy t);
   166 
   167     fun pretty_classrel (c, []) = prt_cls c
   168       | pretty_classrel (c, cs) = Pretty.block
   169           (prt_cls c :: Pretty.str " <" :: Pretty.brk 1 ::
   170             Pretty.commas (map prt_cls cs));
   171 
   172     fun pretty_default S = Pretty.block
   173       [Pretty.str "default sort:", Pretty.brk 1, prt_sort S];
   174 
   175     fun pretty_witness NONE = Pretty.str "universal non-emptiness witness: -"
   176       | pretty_witness (SOME (T, S)) = Pretty.block
   177           [Pretty.str "universal non-emptiness witness:", Pretty.brk 1,
   178             prt_typ_no_tvars T, Pretty.str " ::", Pretty.brk 1, prt_sort S];
   179 
   180     val tfrees = map (fn v => TFree (v, []));
   181     fun pretty_type syn (t, (Type.LogicalType n, _)) =
   182           if syn then NONE
   183           else SOME (prt_typ (Type (t, tfrees (Term.invent_names [] "'a" n))))
   184       | pretty_type syn (t, (Type.Abbreviation (vs, U, syn'), _)) =
   185           if syn <> syn' then NONE
   186           else SOME (Pretty.block
   187             [prt_typ (Type (t, tfrees vs)), Pretty.str " =", Pretty.brk 1, prt_typ U])
   188       | pretty_type syn (t, (Type.Nonterminal, _)) =
   189           if not syn then NONE
   190           else SOME (prt_typ (Type (t, [])));
   191 
   192     val pretty_arities = List.concat o map (fn (t, ars) => map (prt_arity t) ars);
   193 
   194     fun pretty_const (c, (ty, _)) = Pretty.block
   195       [Pretty.str c, Pretty.str " ::", Pretty.brk 1, prt_typ_no_tvars ty];
   196 
   197     fun pretty_final (c, []) = Pretty.str c
   198       | pretty_final (c, tys) = Pretty.block
   199           (Pretty.str c :: Pretty.str " ::" :: Pretty.brk 1 ::
   200              Pretty.commas (map prt_typ_no_tvars tys));
   201 
   202     fun prt_axm (a, t) = Pretty.block [Pretty.str (a ^ ":"), Pretty.brk 1, prt_term t];
   203 
   204     val {axioms, defs, oracles} = Theory.rep_theory thy;
   205     val {naming, syn = _, tsig, consts} = Sign.rep_sg thy;
   206     val {classes, default, types, arities, log_types = _, witness} = Type.rep_tsig tsig;
   207 
   208     val clsses = NameSpace.extern_table (apsnd (Symtab.make o Graph.dest) classes);
   209     val tdecls = NameSpace.extern_table types;
   210     val cnsts = NameSpace.extern_table consts;
   211     val finals = NameSpace.extern_table (#1 consts, Defs.finals defs);
   212     val axms = NameSpace.extern_table axioms;
   213     val oras = NameSpace.extern_table oracles;
   214   in
   215     [Pretty.strs ("names:" :: Context.names_of thy),
   216       Pretty.strs ("data:" :: Context.theory_data thy),
   217       Pretty.strs ["name prefix:", NameSpace.path_of naming],
   218       Pretty.big_list "classes:" (map pretty_classrel clsses),
   219       pretty_default default,
   220       pretty_witness witness,
   221       Pretty.big_list "syntactic types:" (List.mapPartial (pretty_type true) tdecls),
   222       Pretty.big_list "logical types:" (List.mapPartial (pretty_type false) tdecls),
   223       Pretty.big_list "type arities:" (pretty_arities (Symtab.dest arities)),
   224       Pretty.big_list "consts:" (map pretty_const cnsts),
   225       Pretty.big_list "finals consts:" (map pretty_final finals),
   226       Pretty.big_list "axioms:" (map prt_axm axms),
   227       Pretty.strs ("oracles:" :: (map #1 oras))]
   228   end;
   229 
   230 
   231 
   232 (** print_goals **)
   233 
   234 (* print_goals etc. *)
   235 
   236 (*show consts with types in proof state output?*)
   237 val show_consts = ref false;
   238 
   239 
   240 (*print thm A1,...,An/B in "goal style" -- premises as numbered subgoals*)
   241 
   242 local
   243 
   244 fun ins_entry (x, y) [] = [(x, [y])]
   245   | ins_entry (x, y) ((pair as (x', ys')) :: pairs) =
   246       if x = x' then (x', y ins ys') :: pairs
   247       else pair :: ins_entry (x, y) pairs;
   248 
   249 fun add_consts (Const (c, T), env) = ins_entry (T, (c, T)) env
   250   | add_consts (t $ u, env) = add_consts (u, add_consts (t, env))
   251   | add_consts (Abs (_, _, t), env) = add_consts (t, env)
   252   | add_consts (_, env) = env;
   253 
   254 fun add_vars (Free (x, T), env) = ins_entry (T, (x, ~1)) env
   255   | add_vars (Var (xi, T), env) = ins_entry (T, xi) env
   256   | add_vars (Abs (_, _, t), env) = add_vars (t, env)
   257   | add_vars (t $ u, env) = add_vars (u, add_vars (t, env))
   258   | add_vars (_, env) = env;
   259 
   260 fun add_varsT (Type (_, Ts), env) = foldr add_varsT env Ts
   261   | add_varsT (TFree (x, S), env) = ins_entry (S, (x, ~1)) env
   262   | add_varsT (TVar (xi, S), env) = ins_entry (S, xi) env;
   263 
   264 fun sort_idxs vs = map (apsnd (sort (prod_ord string_ord int_ord))) vs;
   265 fun sort_cnsts cs = map (apsnd (sort_wrt fst)) cs;
   266 
   267 fun consts_of t = sort_cnsts (add_consts (t, []));
   268 fun vars_of t = sort_idxs (add_vars (t, []));
   269 fun varsT_of t = rev (sort_idxs (it_term_types add_varsT (t, [])));
   270 
   271 in
   272 
   273 fun pretty_goals_aux pp begin_goal (msg, main) maxgoals state =
   274   let
   275     fun prt_atoms prt prtT (X, xs) = Pretty.block
   276       [Pretty.block (Pretty.commas (map prt xs)), Pretty.str " ::",
   277         Pretty.brk 1, prtT X];
   278 
   279     fun prt_var (x, ~1) = Pretty.term pp (Syntax.free x)
   280       | prt_var xi = Pretty.term pp (Syntax.var xi);
   281 
   282     fun prt_varT (x, ~1) = Pretty.typ pp (TFree (x, []))
   283       | prt_varT xi = Pretty.typ pp (TVar (xi, []));
   284 
   285     val prt_consts = prt_atoms (Pretty.term pp o Const) (Pretty.typ pp);
   286     val prt_vars = prt_atoms prt_var (Pretty.typ pp);
   287     val prt_varsT = prt_atoms prt_varT (Pretty.sort pp);
   288 
   289 
   290     fun pretty_list _ _ [] = []
   291       | pretty_list name prt lst = [Pretty.big_list name (map prt lst)];
   292 
   293     fun pretty_subgoal (n, A) = Pretty.blk (0,
   294      [Pretty.str (begin_goal ^ " " ^ string_of_int n ^ ". "), Pretty.term pp A]);
   295     fun pretty_subgoals As = map pretty_subgoal (1 upto length As ~~ As);
   296 
   297     val pretty_ffpairs = pretty_list "flex-flex pairs:" (pretty_flexpair pp);
   298 
   299     val pretty_consts = pretty_list "constants:" prt_consts o consts_of;
   300     val pretty_vars = pretty_list "variables:" prt_vars o vars_of;
   301     val pretty_varsT = pretty_list "type variables:" prt_varsT o varsT_of;
   302 
   303 
   304     val {prop, tpairs, ...} = Thm.rep_thm state;
   305     val (As, B) = Logic.strip_horn prop;
   306     val ngoals = length As;
   307 
   308     fun pretty_gs (types, sorts) =
   309       (if main then [Pretty.term pp B] else []) @
   310        (if ngoals = 0 then [Pretty.str "No subgoals!"]
   311         else if ngoals > maxgoals then
   312           pretty_subgoals (Library.take (maxgoals, As)) @
   313           (if msg then [Pretty.str ("A total of " ^ string_of_int ngoals ^ " subgoals...")]
   314            else [])
   315         else pretty_subgoals As) @
   316       pretty_ffpairs tpairs @
   317       (if ! show_consts then pretty_consts prop else []) @
   318       (if types then pretty_vars prop else []) @
   319       (if sorts then pretty_varsT prop else []);
   320   in
   321     setmp show_no_free_types true
   322       (setmp show_types (! show_types orelse ! show_sorts orelse ! show_all_types)
   323         (setmp show_sorts false pretty_gs))
   324    (! show_types orelse ! show_sorts orelse ! show_all_types, ! show_sorts)
   325   end;
   326 
   327 fun pretty_goals_marker bg n th =
   328   pretty_goals_aux (Sign.pp (Thm.theory_of_thm th)) bg (true, true) n th;
   329 
   330 val pretty_goals = pretty_goals_marker "";
   331 val print_goals = (Pretty.writeln o Pretty.chunks) oo pretty_goals_marker "";
   332 
   333 end;
   334 
   335 
   336 (* print_current_goals *)
   337 
   338 val current_goals_markers = ref ("", "", "");
   339 
   340 fun pretty_current_goals n m th =
   341   let
   342     val ref (begin_state, end_state, begin_goal) = current_goals_markers;
   343     val ngoals = nprems_of th;
   344   in
   345     (if begin_state = "" then [] else [Pretty.str begin_state]) @
   346     [Pretty.str ("Level " ^ string_of_int n ^
   347       (if ngoals > 0 then " (" ^ string_of_int ngoals ^ " subgoal" ^
   348         (if ngoals <> 1 then "s" else "") ^ ")"
   349       else ""))] @
   350     pretty_goals_marker begin_goal m th @
   351     (if end_state = "" then [] else [Pretty.str end_state])
   352   end;
   353 
   354 fun print_current_goals_default n m th =
   355   Pretty.writeln (Pretty.chunks (pretty_current_goals n m th));
   356 
   357 val print_current_goals_fn = ref print_current_goals_default;
   358 
   359 end;
   360 
   361 structure BasicDisplay: BASIC_DISPLAY = Display;
   362 open BasicDisplay;