src/HOL/Tools/ATP_Manager/atp_problem.ML
author blanchet
Tue Jul 27 17:43:11 2010 +0200 (2010-07-27)
changeset 38019 e207a64e1e0b
parent 38018 ee6c11ae8077
child 38024 e4a95eb5530e
permissions -rw-r--r--
complete renaming of "Sledgehammer_TPTP_Format" to "ATP_Problem"
     1 (*  Title:      HOL/Tools/ATP_Manager/atp_problem.ML
     2     Author:     Jia Meng, NICTA
     3     Author:     Jasmin Blanchette, TU Muenchen
     4 
     5 TPTP syntax.
     6 *)
     7 
     8 signature ATP_PROBLEM =
     9 sig
    10   type kind = Metis_Clauses.kind
    11 
    12   datatype 'a fo_term = ATerm of 'a * 'a fo_term list
    13   datatype quantifier = AForall | AExists
    14   datatype connective = ANot | AAnd | AOr | AImplies | AIf | AIff | ANotIff
    15   datatype ('a, 'b) formula =
    16     AQuant of quantifier * 'a list * ('a, 'b) formula |
    17     AConn of connective * ('a, 'b) formula list |
    18     APred of 'b
    19 
    20   datatype 'a problem_line = Fof of string * kind * ('a, 'a fo_term) formula
    21   type 'a problem = (string * 'a problem_line list) list
    22 
    23   val timestamp : unit -> string
    24   val is_tptp_variable : string -> bool
    25   val strings_for_tptp_problem :
    26     (string * string problem_line list) list -> string list
    27   val nice_tptp_problem :
    28     bool -> ('a * (string * string) problem_line list) list
    29     -> ('a * string problem_line list) list
    30        * (string Symtab.table * string Symtab.table) option
    31 end;
    32 
    33 structure ATP_Problem : ATP_PROBLEM =
    34 struct
    35 
    36 open Sledgehammer_Util
    37 
    38 type kind = Metis_Clauses.kind
    39 
    40 (** ATP problem **)
    41 
    42 datatype 'a fo_term = ATerm of 'a * 'a fo_term list
    43 datatype quantifier = AForall | AExists
    44 datatype connective = ANot | AAnd | AOr | AImplies | AIf | AIff | ANotIff
    45 datatype ('a, 'b) formula =
    46   AQuant of quantifier * 'a list * ('a, 'b) formula |
    47   AConn of connective * ('a, 'b) formula list |
    48   APred of 'b
    49 
    50 datatype 'a problem_line = Fof of string * kind * ('a, 'a fo_term) formula
    51 type 'a problem = (string * 'a problem_line list) list
    52 
    53 val timestamp = Date.fmt "%Y-%m-%d %H:%M:%S" o Date.fromTimeLocal o Time.now
    54 
    55 fun string_for_term (ATerm (s, [])) = s
    56   | string_for_term (ATerm (s, ts)) =
    57     if s = "equal" then space_implode " = " (map string_for_term ts)
    58     else s ^ "(" ^ commas (map string_for_term ts) ^ ")"
    59 fun string_for_quantifier AForall = "!"
    60   | string_for_quantifier AExists = "?"
    61 fun string_for_connective ANot = "~"
    62   | string_for_connective AAnd = "&"
    63   | string_for_connective AOr = "|"
    64   | string_for_connective AImplies = "=>"
    65   | string_for_connective AIf = "<="
    66   | string_for_connective AIff = "<=>"
    67   | string_for_connective ANotIff = "<~>"
    68 fun string_for_formula (AQuant (q, xs, phi)) =
    69     string_for_quantifier q ^ "[" ^ commas xs ^ "] : " ^
    70     string_for_formula phi
    71   | string_for_formula (AConn (ANot, [APred (ATerm ("equal", ts))])) =
    72     space_implode " != " (map string_for_term ts)
    73   | string_for_formula (AConn (c, [phi])) =
    74     string_for_connective c ^ " " ^ string_for_formula phi
    75   | string_for_formula (AConn (c, phis)) =
    76     "(" ^ space_implode (" " ^ string_for_connective c ^ " ")
    77                         (map string_for_formula phis) ^ ")"
    78   | string_for_formula (APred tm) = string_for_term tm
    79 
    80 fun string_for_problem_line (Fof (ident, kind, phi)) =
    81   "fof(" ^ ident ^ ", " ^
    82   (case kind of Axiom => "axiom" | Conjecture => "conjecture") ^ ",\n" ^
    83   "    (" ^ string_for_formula phi ^ ")).\n"
    84 fun strings_for_tptp_problem problem =
    85   "% This file was generated by Isabelle (most likely Sledgehammer)\n\
    86   \% " ^ timestamp () ^ "\n" ::
    87   maps (fn (_, []) => []
    88          | (heading, lines) =>
    89            "\n% " ^ heading ^ " (" ^ Int.toString (length lines) ^ ")\n" ::
    90            map string_for_problem_line lines) problem
    91 
    92 fun is_tptp_variable s = Char.isUpper (String.sub (s, 0))
    93 
    94 
    95 (** Nice names **)
    96 
    97 fun empty_name_pool readable_names =
    98   if readable_names then SOME (Symtab.empty, Symtab.empty) else NONE
    99 
   100 fun pool_fold f xs z = pair z #> fold_rev (fn x => uncurry (f x)) xs
   101 fun pool_map f xs =
   102   pool_fold (fn x => fn ys => fn pool => f x pool |>> (fn y => y :: ys)) xs []
   103 
   104 (* "equal" is reserved by some ATPs. "op" is also reserved, to avoid the
   105    unreadable "op_1", "op_2", etc., in the problem files. *)
   106 val reserved_nice_names = ["equal", "op"]
   107 fun readable_name full_name s =
   108   if s = full_name then
   109     s
   110   else
   111     let
   112       val s = s |> Long_Name.base_name
   113                 |> Name.desymbolize (Char.isUpper (String.sub (full_name, 0)))
   114     in if member (op =) reserved_nice_names s then full_name else s end
   115 
   116 fun nice_name (full_name, _) NONE = (full_name, NONE)
   117   | nice_name (full_name, desired_name) (SOME the_pool) =
   118     case Symtab.lookup (fst the_pool) full_name of
   119       SOME nice_name => (nice_name, SOME the_pool)
   120     | NONE =>
   121       let
   122         val nice_prefix = readable_name full_name desired_name
   123         fun add j =
   124           let
   125             val nice_name = nice_prefix ^
   126                             (if j = 0 then "" else "_" ^ Int.toString j)
   127           in
   128             case Symtab.lookup (snd the_pool) nice_name of
   129               SOME full_name' =>
   130               if full_name = full_name' then (nice_name, the_pool)
   131               else add (j + 1)
   132             | NONE =>
   133               (nice_name,
   134                (Symtab.update_new (full_name, nice_name) (fst the_pool),
   135                 Symtab.update_new (nice_name, full_name) (snd the_pool)))
   136           end
   137       in add 0 |> apsnd SOME end
   138 
   139 
   140 fun nice_term (ATerm (name, ts)) =
   141   nice_name name ##>> pool_map nice_term ts #>> ATerm
   142 fun nice_formula (AQuant (q, xs, phi)) =
   143     pool_map nice_name xs ##>> nice_formula phi
   144     #>> (fn (xs, phi) => AQuant (q, xs, phi))
   145   | nice_formula (AConn (c, phis)) =
   146     pool_map nice_formula phis #>> curry AConn c
   147   | nice_formula (APred tm) = nice_term tm #>> APred
   148 fun nice_problem_line (Fof (ident, kind, phi)) =
   149   nice_formula phi #>> (fn phi => Fof (ident, kind, phi))
   150 fun nice_problem problem =
   151   pool_map (fn (heading, lines) =>
   152                pool_map nice_problem_line lines #>> pair heading) problem
   153 fun nice_tptp_problem readable_names problem =
   154   nice_problem problem (empty_name_pool readable_names)
   155 
   156 end;