src/Pure/context.ML
author wenzelm
Thu Sep 15 17:16:56 2005 +0200 (2005-09-15)
changeset 17412 e26cb20ef0cc
parent 17340 11f959f0fe6c
child 17756 d4a35f82fbb4
permissions -rw-r--r--
TableFun/Symtab: curried lookup and update;
     1 (*  Title:      Pure/context.ML
     2     ID:         $Id$
     3     Author:     Markus Wenzel, TU Muenchen
     4 
     5 Generic theory contexts with unique identity, arbitrarily typed data,
     6 development graph and history support.  Implicit theory contexts in ML.
     7 Generic proof contexts with arbitrarily typed data.
     8 *)
     9 
    10 signature BASIC_CONTEXT =
    11 sig
    12   type theory
    13   type theory_ref
    14   exception THEORY of string * theory list
    15   val context: theory -> unit
    16   val the_context: unit -> theory
    17 end;
    18 
    19 signature CONTEXT =
    20 sig
    21   include BASIC_CONTEXT
    22   (*theory context*)
    23   val theory_name: theory -> string
    24   val parents_of: theory -> theory list
    25   val ancestors_of: theory -> theory list
    26   val is_stale: theory -> bool
    27   val ProtoPureN: string
    28   val PureN: string
    29   val CPureN: string
    30   val draftN: string
    31   val exists_name: string -> theory -> bool
    32   val names_of: theory -> string list
    33   val pretty_thy: theory -> Pretty.T
    34   val string_of_thy: theory -> string
    35   val pprint_thy: theory -> pprint_args -> unit
    36   val pretty_abbrev_thy: theory -> Pretty.T
    37   val str_of_thy: theory -> string
    38   val check_thy: theory -> theory
    39   val eq_thy: theory * theory -> bool
    40   val subthy: theory * theory -> bool
    41   val joinable: theory * theory -> bool
    42   val merge: theory * theory -> theory                     (*exception TERM*)
    43   val merge_refs: theory_ref * theory_ref -> theory_ref    (*exception TERM*)
    44   val self_ref: theory -> theory_ref
    45   val deref: theory_ref -> theory
    46   val copy_thy: theory -> theory
    47   val checkpoint_thy: theory -> theory
    48   val finish_thy: theory -> theory
    49   val theory_data_of: theory -> string list
    50   val pre_pure_thy: theory
    51   val begin_thy: (theory -> Pretty.pp) -> string -> theory list -> theory
    52   (*ML theory context*)
    53   val get_context: unit -> theory option
    54   val set_context: theory option -> unit
    55   val reset_context: unit -> unit
    56   val setmp: theory option -> ('a -> 'b) -> 'a -> 'b
    57   val pass: theory option -> ('a -> 'b) -> 'a -> 'b * theory option
    58   val pass_theory: theory -> ('a -> 'b) -> 'a -> 'b * theory
    59   val save: ('a -> 'b) -> 'a -> 'b
    60   val >> : (theory -> theory) -> unit
    61   val ml_output: (string -> unit) * (string -> unit)
    62   val use_mltext: string -> bool -> theory option -> unit
    63   val use_mltext_theory: string -> bool -> theory -> theory
    64   val use_let: string -> string -> string -> theory -> theory
    65   val add_setup: (theory -> theory) list -> unit
    66   val setup: unit -> (theory -> theory) list
    67   (*proof context*)
    68   type proof
    69   exception PROOF of string * proof
    70   val theory_of_proof: proof -> theory
    71   val transfer_proof: theory -> proof -> proof
    72   val init_proof: theory -> proof
    73   val proof_data_of: theory -> string list
    74   (*generic context*)
    75   datatype context = Theory of theory | Proof of proof
    76   val theory_of: context -> theory
    77   val proof_of: context -> proof
    78 end;
    79 
    80 signature PRIVATE_CONTEXT =
    81 sig
    82   include CONTEXT
    83   structure TheoryData:
    84   sig
    85     val declare: string -> Object.T -> (Object.T -> Object.T) -> (Object.T -> Object.T) ->
    86       (Pretty.pp -> Object.T * Object.T -> Object.T) -> serial
    87     val init: serial -> theory -> theory
    88     val get: serial -> (Object.T -> 'a) -> theory -> 'a
    89     val put: serial -> ('a -> Object.T) -> 'a -> theory -> theory
    90   end
    91   structure ProofData:
    92   sig
    93     val declare: string -> (theory -> Object.T) -> serial
    94     val init: serial -> theory -> theory
    95     val get: serial -> (Object.T -> 'a) -> proof -> 'a
    96     val put: serial -> ('a -> Object.T) -> 'a -> proof -> proof
    97   end
    98 end;
    99 
   100 structure Context: PRIVATE_CONTEXT =
   101 struct
   102 
   103 (*** theory context ***)
   104 
   105 (** theory data **)
   106 
   107 (* data kinds and access methods *)
   108 
   109 local
   110 
   111 type kind =
   112  {name: string,
   113   empty: Object.T,
   114   copy: Object.T -> Object.T,
   115   extend: Object.T -> Object.T,
   116   merge: Pretty.pp -> Object.T * Object.T -> Object.T};
   117 
   118 val kinds = ref (Inttab.empty: kind Inttab.table);
   119 
   120 fun invoke meth_name meth_fn k =
   121   (case Inttab.lookup (! kinds) k of
   122     SOME kind => meth_fn kind |> transform_failure (fn exn =>
   123       EXCEPTION (exn, "Theory data method " ^ #name kind ^ "." ^ meth_name ^ " failed"))
   124   | NONE => sys_error ("Invalid theory data identifier " ^ string_of_int k));
   125 
   126 in
   127 
   128 fun invoke_name k    = invoke "name" (K o #name) k ();
   129 fun invoke_empty k   = invoke "empty" (K o #empty) k ();
   130 val invoke_copy      = invoke "copy" #copy;
   131 val invoke_extend    = invoke "extend" #extend;
   132 fun invoke_merge pp  = invoke "merge" (fn kind => #merge kind pp);
   133 
   134 fun declare_theory_data name empty copy extend merge =
   135   let
   136     val k = serial ();
   137     val kind = {name = name, empty = empty, copy = copy, extend = extend, merge = merge};
   138     val _ = conditional (Inttab.exists (equal name o #name o #2) (! kinds)) (fn () =>
   139       warning ("Duplicate declaration of theory data " ^ quote name));
   140     val _ = change kinds (Inttab.update (k, kind));
   141   in k end;
   142 
   143 val copy_data = Inttab.map' invoke_copy;
   144 val extend_data = Inttab.map' invoke_extend;
   145 fun merge_data pp = Inttab.join (SOME oo invoke_merge pp) o pairself extend_data;
   146 
   147 end;
   148 
   149 
   150 
   151 (** datatype theory **)
   152 
   153 datatype theory =
   154   Theory of
   155    (*identity*)
   156    {self: theory ref option,            (*dynamic self reference -- follows theory changes*)
   157     id: serial * string,                (*identifier of this theory*)
   158     ids: string Inttab.table,           (*identifiers of ancestors*)
   159     iids: string Inttab.table} *        (*identifiers of intermediate checkpoints*)
   160    (*data*)
   161    {theory: Object.T Inttab.table,      (*theory data record*)
   162     proof: unit Inttab.table} *         (*proof data kinds*)
   163    (*ancestry*)
   164    {parents: theory list,               (*immediate predecessors*)
   165     ancestors: theory list} *           (*all predecessors*)
   166    (*history*)
   167    {name: string,                       (*prospective name of finished theory*)
   168     version: int,                       (*checkpoint counter*)
   169     intermediates: theory list};        (*intermediate checkpoints*)
   170 
   171 exception THEORY of string * theory list;
   172 
   173 fun rep_theory (Theory args) = args;
   174 
   175 val identity_of = #1 o rep_theory;
   176 val data_of     = #2 o rep_theory;
   177 val ancestry_of = #3 o rep_theory;
   178 val history_of  = #4 o rep_theory;
   179 
   180 fun make_identity self id ids iids = {self = self, id = id, ids = ids, iids = iids};
   181 fun make_data theory proof = {theory = theory, proof = proof};
   182 fun make_ancestry parents ancestors = {parents = parents, ancestors = ancestors};
   183 fun make_history name vers ints = {name = name, version = vers, intermediates = ints};
   184 
   185 fun map_theory f {theory, proof} = make_data (f theory) proof;
   186 fun map_proof f {theory, proof} = make_data theory (f proof);
   187 
   188 val the_self = the o #self o identity_of;
   189 val parents_of = #parents o ancestry_of;
   190 val ancestors_of = #ancestors o ancestry_of;
   191 val theory_name = #name o history_of;
   192 
   193 
   194 (* staleness *)
   195 
   196 fun eq_id ((i: int, _), (j, _)) = (i = j);
   197 
   198 fun is_stale
   199     (Theory ({self = SOME (ref (Theory ({id = id', ...}, _, _, _))), id, ...}, _, _, _)) =
   200       not (eq_id (id, id'))
   201   | is_stale (Theory ({self = NONE, ...}, _, _, _)) = true;
   202 
   203 fun vitalize (thy as Theory ({self = SOME r, ...}, _, _, _)) = (r := thy; thy)
   204   | vitalize (thy as Theory ({self = NONE, id, ids, iids}, data, ancestry, history)) =
   205       let
   206         val r = ref thy;
   207         val thy' = Theory (make_identity (SOME r) id ids iids, data, ancestry, history);
   208       in r := thy'; thy' end;
   209 
   210 
   211 (* names *)
   212 
   213 val ProtoPureN = "ProtoPure";
   214 val PureN = "Pure";
   215 val CPureN = "CPure";
   216 
   217 val draftN = "#";
   218 fun draft_id (_, name) = (name = draftN);
   219 val is_draft = draft_id o #id o identity_of;
   220 
   221 fun exists_name name (Theory ({id, ids, iids, ...}, _, _, _)) =
   222   name = #2 id orelse
   223   Inttab.exists (equal name o #2) ids orelse
   224   Inttab.exists (equal name o #2) iids;
   225 
   226 fun names_of (Theory ({id, ids, iids, ...}, _, _, _)) =
   227   rev (#2 id :: Inttab.fold (cons o #2) iids (Inttab.fold (cons o #2) ids []));
   228 
   229 fun pretty_thy thy =
   230   Pretty.str_list "{" "}" (names_of thy @ (if is_stale thy then ["!"] else []));
   231 
   232 val string_of_thy = Pretty.string_of o pretty_thy;
   233 val pprint_thy = Pretty.pprint o pretty_thy;
   234 
   235 fun pretty_abbrev_thy thy =
   236   let
   237     val names = names_of thy;
   238     val n = length names;
   239     val abbrev = if n > 5 then "..." :: List.drop (names, n - 5) else names;
   240   in Pretty.str_list "{" "}" abbrev end;
   241 
   242 val str_of_thy = Pretty.str_of o pretty_abbrev_thy;
   243 
   244 
   245 (* consistency *)    (*exception TERM*)
   246 
   247 fun check_thy thy =
   248   if is_stale thy then
   249     raise TERM ("Stale theory encountered:\n" ^ string_of_thy thy, [])
   250   else thy;
   251 
   252 fun check_ins id ids =
   253   if draft_id id orelse Inttab.defined ids (#1 id) then ids
   254   else if Inttab.exists (equal (#2 id) o #2) ids then
   255     raise TERM ("Different versions of theory component " ^ quote (#2 id), [])
   256   else Inttab.update id ids;
   257 
   258 fun check_insert intermediate id (ids, iids) =
   259   let val ids' = check_ins id ids and iids' = check_ins id iids
   260   in if intermediate then (ids, iids') else (ids', iids) end;
   261 
   262 fun check_merge
   263     (Theory ({id = id1, ids = ids1, iids = iids1, ...}, _, _, history1))
   264     (Theory ({id = id2, ids = ids2, iids = iids2, ...}, _, _, history2)) =
   265   (Inttab.fold check_ins ids2 ids1, Inttab.fold check_ins iids2 iids1)
   266   |> check_insert (#version history1 > 0) id1
   267   |> check_insert (#version history2 > 0) id2;
   268 
   269 
   270 (* equality and inclusion *)
   271 
   272 val eq_thy = eq_id o pairself (#id o identity_of o check_thy);
   273 
   274 fun proper_subthy
   275     (Theory ({id = (i, _), ...}, _, _, _), Theory ({ids, iids, ...}, _, _, _)) =
   276   Inttab.defined ids i orelse Inttab.defined iids i;
   277 
   278 fun subthy thys = eq_thy thys orelse proper_subthy thys;
   279 
   280 fun joinable (thy1, thy2) = subthy (thy1, thy2) orelse subthy (thy2, thy1);
   281 
   282 
   283 (* theory references *)
   284 
   285 (*theory_ref provides a safe way to store dynamic references to a
   286   theory in external data structures -- a plain theory value would
   287   become stale as the self reference moves on*)
   288 
   289 datatype theory_ref = TheoryRef of theory ref;
   290 
   291 val self_ref = TheoryRef o the_self o check_thy;
   292 fun deref (TheoryRef (ref thy)) = thy;
   293 
   294 
   295 (* trivial merge *)    (*exception TERM*)
   296 
   297 fun merge (thy1, thy2) =
   298   if eq_thy (thy1, thy2) then thy1
   299   else if proper_subthy (thy2, thy1) then thy1
   300   else if proper_subthy (thy1, thy2) then thy2
   301   else (check_merge thy1 thy2;
   302     raise TERM (cat_lines ["Attempt to perform non-trivial merge of theories:",
   303       str_of_thy thy1, str_of_thy thy2], []));
   304 
   305 fun merge_refs (ref1, ref2) =
   306   if ref1 = ref2 then ref1
   307   else self_ref (merge (deref ref1, deref ref2));
   308 
   309 
   310 
   311 (** build theories **)
   312 
   313 (* primitives *)
   314 
   315 fun create_thy name self id ids iids data ancestry history =
   316   let
   317     val intermediate = #version history > 0;
   318     val (ids', iids') = check_insert intermediate id (ids, iids);
   319     val id' = (serial (), name);
   320     val _ = check_insert intermediate id' (ids', iids');
   321     val identity' = make_identity self id' ids' iids';
   322   in vitalize (Theory (identity', data, ancestry, history)) end;
   323 
   324 fun change_thy name f (thy as Theory ({self, id, ids, iids}, data, ancestry, history)) =
   325   let
   326     val _ = check_thy thy;
   327     val (self', data', ancestry') =
   328       if is_draft thy then (self, data, ancestry)    (*destructive change!*)
   329       else if #version history > 0
   330       then (NONE, map_theory copy_data data, ancestry)
   331       else (NONE, map_theory extend_data data, make_ancestry [thy] (thy :: #ancestors ancestry));
   332     val data'' = f data';
   333   in create_thy name self' id ids iids data'' ancestry' history end;
   334 
   335 fun name_thy name = change_thy name I;
   336 val modify_thy = change_thy draftN;
   337 val extend_thy = modify_thy I;
   338 
   339 fun copy_thy (thy as Theory ({id, ids, iids, ...}, data, ancestry, history)) =
   340   (check_thy thy;
   341     create_thy draftN NONE id ids iids (map_theory copy_data data) ancestry history);
   342 
   343 val pre_pure_thy = create_thy draftN NONE (serial (), draftN) Inttab.empty Inttab.empty
   344   (make_data Inttab.empty Inttab.empty) (make_ancestry [] []) (make_history ProtoPureN 0 []);
   345 
   346 
   347 (* named theory nodes *)
   348 
   349 fun merge_thys pp (thy1, thy2) =
   350   if exists_name CPureN thy1 <> exists_name CPureN thy2 then
   351     error "Cannot merge Pure and CPure developments"
   352   else
   353     let
   354       val (ids, iids) = check_merge thy1 thy2;
   355       val data1 = data_of thy1 and data2 = data_of thy2;
   356       val data = make_data
   357         (merge_data (pp thy1) (#theory data1, #theory data2))
   358         (Inttab.merge (K true) (#proof data1, #proof data2));
   359       val ancestry = make_ancestry [] [];
   360       val history = make_history "" 0 [];
   361     in create_thy draftN NONE (serial (), draftN) ids iids data ancestry history end;
   362 
   363 fun maximal_thys thys =
   364   thys |> filter (fn thy => not (exists (fn thy' => proper_subthy (thy, thy')) thys));
   365 
   366 fun begin_thy pp name imports =
   367   if name = draftN then error ("Illegal theory name: " ^ quote draftN)
   368   else
   369     let
   370       val parents =
   371         maximal_thys (gen_distinct eq_thy (map check_thy imports));
   372       val ancestors = gen_distinct eq_thy (parents @ List.concat (map ancestors_of parents));
   373       val Theory ({id, ids, iids, ...}, data, _, _) =
   374         (case parents of
   375           [] => error "No parent theories"
   376         | [thy] => extend_thy thy
   377         | thy :: thys => Library.foldl (merge_thys pp) (thy, thys));
   378       val ancestry = make_ancestry parents ancestors;
   379       val history = make_history name 0 [];
   380     in create_thy draftN NONE id ids iids data ancestry history end;
   381 
   382 
   383 (* undoable checkpoints *)
   384 
   385 fun checkpoint_thy thy =
   386   if not (is_draft thy) then thy
   387   else
   388     let
   389       val {name, version, intermediates} = history_of thy;
   390       val thy' as Theory (identity', data', ancestry', _) =
   391         name_thy (name ^ ":" ^ string_of_int version) thy;
   392       val history' = make_history name (version + 1) (thy' :: intermediates);
   393     in vitalize (Theory (identity', data', ancestry', history')) end;
   394 
   395 fun finish_thy thy =
   396   let
   397     val {name, version, intermediates} = history_of thy;
   398     val rs = map (the_self o check_thy) intermediates;
   399     val thy' as Theory ({self, id, ids, ...}, data', ancestry', _) = name_thy name thy;
   400     val identity' = make_identity self id ids Inttab.empty;
   401     val history' = make_history name 0 [];
   402     val thy'' = vitalize (Theory (identity', data', ancestry', history'));
   403     val _ = List.app (fn r => r := thy'') rs;
   404   in thy'' end;
   405 
   406 
   407 (* theory data *)
   408 
   409 fun dest_data name_of tab =
   410   map name_of (Inttab.keys tab)
   411   |> map (rpair ()) |> Symtab.make_multi |> Symtab.dest
   412   |> map (apsnd length)
   413   |> map (fn (name, 1) => name | (name, n) => name ^ enclose "[" "]" (string_of_int n));
   414 
   415 val theory_data_of = dest_data invoke_name o #theory o data_of;
   416 
   417 structure TheoryData =
   418 struct
   419 
   420 val declare = declare_theory_data;
   421 
   422 fun get k dest thy =
   423   (case Inttab.lookup (#theory (data_of thy)) k of
   424     SOME x => (dest x handle Match =>
   425       error ("Failed to access theory data " ^ quote (invoke_name k)))
   426   | NONE => error ("Uninitialized theory data " ^ quote (invoke_name k)));
   427 
   428 fun put k mk x = modify_thy (map_theory (Inttab.update (k, mk x)));
   429 fun init k = put k I (invoke_empty k);
   430 
   431 end;
   432 
   433 
   434 
   435 (*** ML theory context ***)
   436 
   437 local
   438   val current_theory = ref (NONE: theory option);
   439 in
   440   fun get_context () = ! current_theory;
   441   fun set_context opt_thy = current_theory := opt_thy;
   442   fun setmp opt_thy f x = Library.setmp current_theory opt_thy f x;
   443 end;
   444 
   445 fun the_context () =
   446   (case get_context () of
   447     SOME thy => thy
   448   | _ => error "Unknown theory context");
   449 
   450 fun context thy = set_context (SOME thy);
   451 fun reset_context () = set_context NONE;
   452 
   453 fun pass opt_thy f x =
   454   setmp opt_thy (fn x => let val y = f x in (y, get_context ()) end) x;
   455 
   456 fun pass_theory thy f x =
   457   (case pass (SOME thy) f x of
   458     (y, SOME thy') => (y, thy')
   459   | (_, NONE) => error "Lost theory context in ML");
   460 
   461 fun save f x = setmp (get_context ()) f x;
   462 
   463 
   464 (* map context *)
   465 
   466 nonfix >>;
   467 fun >> f = set_context (SOME (f (the_context ())));
   468 
   469 
   470 (* use ML text *)
   471 
   472 val ml_output = (writeln, error_msg);
   473 
   474 fun use_output verbose txt = use_text ml_output verbose (Symbol.escape txt);
   475 
   476 fun use_mltext txt verbose opt_thy = setmp opt_thy (fn () => use_output verbose txt) ();
   477 fun use_mltext_theory txt verbose thy = #2 (pass_theory thy (use_output verbose) txt);
   478 
   479 fun use_context txt = use_mltext_theory ("Context.>> (" ^ txt ^ ");") false;
   480 
   481 fun use_let bind body txt =
   482   use_context ("let " ^ bind ^ " = " ^ txt ^ " in\n" ^ body ^ " end");
   483 
   484 
   485 (* delayed theory setup *)
   486 
   487 local
   488   val setup_fns = ref ([]: (theory -> theory) list);
   489 in
   490   fun add_setup fns = setup_fns := ! setup_fns @ fns;
   491   fun setup () = let val fns = ! setup_fns in setup_fns := []; fns end;
   492 end;
   493 
   494 
   495 
   496 (*** proof context ***)
   497 
   498 (* datatype proof *)
   499 
   500 datatype proof = Proof of theory_ref * Object.T Inttab.table;
   501 
   502 exception PROOF of string * proof;
   503 
   504 fun theory_of_proof (Proof (thy_ref, _)) = deref thy_ref;
   505 fun data_of_proof (Proof (_, data)) = data;
   506 fun map_prf f (Proof (thy_ref, data)) = Proof (thy_ref, f data);
   507 
   508 fun transfer_proof thy' (prf as Proof (thy_ref, data)) =
   509   if not (subthy (deref thy_ref, thy')) then
   510     raise PROOF ("transfer proof context: no a super theory", prf)
   511   else Proof (self_ref thy', data);
   512 
   513 
   514 (* proof data kinds *)
   515 
   516 local
   517 
   518 type kind =
   519  {name: string,
   520   init: theory -> Object.T};
   521 
   522 val kinds = ref (Inttab.empty: kind Inttab.table);
   523 
   524 fun invoke meth_name meth_fn k =
   525   (case Inttab.lookup (! kinds) k of
   526     SOME kind => meth_fn kind |> transform_failure (fn exn =>
   527       EXCEPTION (exn, "Proof data method " ^ #name kind ^ "." ^ meth_name ^ " failed"))
   528   | NONE => sys_error ("Invalid proof data identifier " ^ string_of_int k));
   529 
   530 fun invoke_name k = invoke "name" (K o #name) k ();
   531 val invoke_init   = invoke "init" #init;
   532 
   533 in
   534 
   535 val proof_data_of = dest_data invoke_name o #proof o data_of;
   536 
   537 fun init_proof thy =
   538   Proof (self_ref thy, Inttab.map' (fn k => fn _ => invoke_init k thy) (#proof (data_of thy)));
   539 
   540 structure ProofData =
   541 struct
   542 
   543 fun declare name init =
   544   let
   545     val k = serial ();
   546     val kind = {name = name, init = init};
   547     val _ = conditional (Inttab.exists (equal name o #name o #2) (! kinds)) (fn () =>
   548       warning ("Duplicate declaration of proof data " ^ quote name));
   549     val _ = change kinds (Inttab.update (k, kind));
   550   in k end;
   551 
   552 fun init k = modify_thy (map_proof (Inttab.update (k, ())));
   553 
   554 fun get k dest prf =
   555   (case Inttab.lookup (data_of_proof prf) k of
   556     SOME x => (dest x handle Match =>
   557       error ("Failed to access proof data " ^ quote (invoke_name k)))
   558   | NONE => error ("Uninitialized proof data " ^ quote (invoke_name k)));
   559 
   560 fun put k mk x = map_prf (Inttab.update (k, mk x));
   561 
   562 end;
   563 
   564 end;
   565 
   566 
   567 (*** generic context ***)
   568 
   569 datatype context = Theory of theory | Proof of proof;
   570 
   571 fun theory_of (Theory thy) = thy
   572   | theory_of (Proof prf) = theory_of_proof prf;
   573 
   574 fun proof_of (Theory thy) = init_proof thy
   575   | proof_of (Proof prf) = prf;
   576 
   577 end;
   578 
   579 structure BasicContext: BASIC_CONTEXT = Context;
   580 open BasicContext;
   581 
   582 
   583 
   584 (*** type-safe interfaces for data declarations ***)
   585 
   586 (** theory data **)
   587 
   588 signature THEORY_DATA_ARGS =
   589 sig
   590   val name: string
   591   type T
   592   val empty: T
   593   val copy: T -> T
   594   val extend: T -> T
   595   val merge: Pretty.pp -> T * T -> T
   596   val print: theory -> T -> unit
   597 end;
   598 
   599 signature THEORY_DATA =
   600 sig
   601   type T
   602   val init: theory -> theory
   603   val print: theory -> unit
   604   val get: theory -> T
   605   val get_sg: theory -> T    (*obsolete*)
   606   val put: T -> theory -> theory
   607   val map: (T -> T) -> theory -> theory
   608 end;
   609 
   610 functor TheoryDataFun(Data: THEORY_DATA_ARGS): THEORY_DATA =
   611 struct
   612 
   613 structure TheoryData = Context.TheoryData;
   614 
   615 type T = Data.T;
   616 exception Data of T;
   617 
   618 val kind = TheoryData.declare Data.name
   619   (Data Data.empty)
   620   (fn Data x => Data (Data.copy x))
   621   (fn Data x => Data (Data.extend x))
   622   (fn pp => fn (Data x1, Data x2) => Data (Data.merge pp (x1, x2)));
   623 
   624 val init = TheoryData.init kind;
   625 val get = TheoryData.get kind (fn Data x => x);
   626 val get_sg = get;
   627 fun print thy = Data.print thy (get thy);
   628 val put = TheoryData.put kind Data;
   629 fun map f thy = put (f (get thy)) thy;
   630 
   631 end;
   632 
   633 
   634 
   635 (** proof data **)
   636 
   637 signature PROOF_DATA_ARGS =
   638 sig
   639   val name: string
   640   type T
   641   val init: theory -> T
   642   val print: Context.proof -> T -> unit
   643 end;
   644 
   645 signature PROOF_DATA =
   646 sig
   647   type T
   648   val init: theory -> theory
   649   val print: Context.proof -> unit
   650   val get: Context.proof -> T
   651   val put: T -> Context.proof -> Context.proof
   652   val map: (T -> T) -> Context.proof -> Context.proof
   653 end;
   654 
   655 functor ProofDataFun(Data: PROOF_DATA_ARGS): PROOF_DATA =
   656 struct
   657 
   658 structure ProofData = Context.ProofData;
   659 
   660 type T = Data.T;
   661 exception Data of T;
   662 
   663 val kind = ProofData.declare Data.name (Data o Data.init);
   664 
   665 val init = ProofData.init kind;
   666 val get = ProofData.get kind (fn Data x => x);
   667 fun print prf = Data.print prf (get prf);
   668 val put = ProofData.put kind Data;
   669 fun map f prf = put (f (get prf)) prf;
   670 
   671 end;
   672 
   673 (*hide private interface*)
   674 structure Context: CONTEXT = Context;