src/Pure/sign.ML
author wenzelm
Thu Sep 15 17:16:56 2005 +0200 (2005-09-15)
changeset 17412 e26cb20ef0cc
parent 17405 e4dc583a2d79
child 17496 26535df536ae
permissions -rw-r--r--
TableFun/Symtab: curried lookup and update;
     1 (*  Title:      Pure/sign.ML
     2     ID:         $Id$
     3     Author:     Lawrence C Paulson and Markus Wenzel
     4 
     5 Logical signature content: naming conventions, concrete syntax, type
     6 signature, constant declarations.
     7 *)
     8 
     9 signature SIGN_THEORY =
    10 sig
    11   val add_defsort: string -> theory -> theory
    12   val add_defsort_i: sort -> theory -> theory
    13   val add_types: (bstring * int * mixfix) list -> theory -> theory
    14   val add_typedecls: (bstring * string list * mixfix) list -> theory -> theory
    15   val add_nonterminals: bstring list -> theory -> theory
    16   val add_tyabbrs: (bstring * string list * string * mixfix) list -> theory -> theory
    17   val add_tyabbrs_i: (bstring * string list * typ * mixfix) list -> theory -> theory
    18   val add_arities: (xstring * string list * string) list -> theory -> theory
    19   val add_arities_i: (string * sort list * sort) list -> theory -> theory
    20   val add_syntax: (bstring * string * mixfix) list -> theory -> theory
    21   val add_syntax_i: (bstring * typ * mixfix) list -> theory -> theory
    22   val add_modesyntax: (string * bool) -> (bstring * string * mixfix) list -> theory -> theory
    23   val add_modesyntax_i: (string * bool) -> (bstring * typ * mixfix) list -> theory -> theory
    24   val del_modesyntax: (string * bool) -> (bstring * string * mixfix) list -> theory -> theory
    25   val del_modesyntax_i: (string * bool) -> (bstring * typ * mixfix) list -> theory -> theory
    26   val add_consts: (bstring * string * mixfix) list -> theory -> theory
    27   val add_consts_i: (bstring * typ * mixfix) list -> theory -> theory
    28   val add_const_constraint: xstring * string -> theory -> theory
    29   val add_const_constraint_i: string * typ -> theory -> theory
    30   val add_classes: (bstring * xstring list) list -> theory -> theory
    31   val add_classes_i: (bstring * class list) list -> theory -> theory
    32   val add_classrel: (xstring * xstring) list -> theory -> theory
    33   val add_classrel_i: (class * class) list -> theory -> theory
    34   val add_trfuns:
    35     (string * (ast list -> ast)) list *
    36     (string * (term list -> term)) list *
    37     (string * (term list -> term)) list *
    38     (string * (ast list -> ast)) list -> theory -> theory
    39   val add_trfunsT:
    40     (string * (bool -> typ -> term list -> term)) list -> theory -> theory
    41   val add_advanced_trfuns:
    42     (string * (theory -> ast list -> ast)) list *
    43     (string * (theory -> term list -> term)) list *
    44     (string * (theory -> term list -> term)) list *
    45     (string * (theory -> ast list -> ast)) list -> theory -> theory
    46   val add_advanced_trfunsT:
    47     (string * (theory -> bool -> typ -> term list -> term)) list -> theory -> theory
    48   val add_tokentrfuns:
    49     (string * string * (string -> string * real)) list -> theory -> theory
    50   val add_mode_tokentrfuns: string -> (string * (string -> string * real)) list
    51     -> theory -> theory
    52   val parse_ast_translation: bool * string -> theory -> theory
    53   val parse_translation: bool * string -> theory -> theory
    54   val print_translation: bool * string -> theory -> theory
    55   val typed_print_translation: bool * string -> theory -> theory
    56   val print_ast_translation: bool * string -> theory -> theory
    57   val token_translation: string -> theory -> theory
    58   val add_trrules: (xstring * string) Syntax.trrule list -> theory -> theory
    59   val add_trrules_i: ast Syntax.trrule list -> theory -> theory
    60   val add_path: string -> theory -> theory
    61   val parent_path: theory -> theory
    62   val root_path: theory -> theory
    63   val absolute_path: theory -> theory
    64   val local_path: theory -> theory
    65   val qualified_names: theory -> theory
    66   val no_base_names: theory -> theory
    67   val custom_accesses: (string list -> string list list) -> theory -> theory
    68   val set_policy: (string -> bstring -> string) * (string list -> string list list) ->
    69     theory -> theory
    70   val restore_naming: theory -> theory -> theory
    71   val hide_classes: bool -> xstring list -> theory -> theory
    72   val hide_classes_i: bool -> string list -> theory -> theory
    73   val hide_types: bool -> xstring list -> theory -> theory
    74   val hide_types_i: bool -> string list -> theory -> theory
    75   val hide_consts: bool -> xstring list -> theory -> theory
    76   val hide_consts_i: bool -> string list -> theory -> theory
    77   val hide_names: bool -> string * xstring list -> theory -> theory
    78   val hide_names_i: bool -> string * string list -> theory -> theory
    79 end
    80 
    81 signature SIGN =
    82 sig
    83   type sg    (*obsolete*)
    84   val init_data: theory -> theory
    85   val rep_sg: theory ->
    86    {naming: NameSpace.naming,
    87     syn: Syntax.syntax,
    88     tsig: Type.tsig,
    89     consts: (typ * stamp) NameSpace.table * typ Symtab.table}
    90   val naming_of: theory -> NameSpace.naming
    91   val base_name: string -> bstring
    92   val full_name: theory -> bstring -> string
    93   val full_name_path: theory -> string -> bstring -> string
    94   val declare_name: theory -> string -> NameSpace.T -> NameSpace.T
    95   val syn_of: theory -> Syntax.syntax
    96   val tsig_of: theory -> Type.tsig
    97   val classes_of: theory -> Sorts.classes
    98   val classes_arities_of: theory -> Sorts.classes * Sorts.arities
    99   val classes: theory -> class list
   100   val defaultS: theory -> sort
   101   val subsort: theory -> sort * sort -> bool
   102   val of_sort: theory -> typ * sort -> bool
   103   val witness_sorts: theory -> sort list -> sort list -> (typ * sort) list
   104   val universal_witness: theory -> (typ * sort) option
   105   val all_sorts_nonempty: theory -> bool
   106   val typ_instance: theory -> typ * typ -> bool
   107   val typ_match: theory -> typ * typ -> Type.tyenv -> Type.tyenv
   108   val typ_unify: theory -> typ * typ -> Type.tyenv * int -> Type.tyenv * int
   109   val is_logtype: theory -> string -> bool
   110   val const_constraint: theory -> string -> typ option
   111   val the_const_constraint: theory -> string -> typ
   112   val const_type: theory -> string -> typ option
   113   val the_const_type: theory -> string -> typ
   114   val declared_tyname: theory -> string -> bool
   115   val declared_const: theory -> string -> bool
   116   val class_space: theory -> NameSpace.T
   117   val type_space: theory -> NameSpace.T
   118   val const_space: theory -> NameSpace.T
   119   val intern_class: theory -> xstring -> string
   120   val extern_class: theory -> string -> xstring
   121   val intern_type: theory -> xstring -> string
   122   val extern_type: theory -> string -> xstring
   123   val intern_const: theory -> xstring -> string
   124   val extern_const: theory -> string -> xstring
   125   val intern_sort: theory -> sort -> sort
   126   val extern_sort: theory -> sort -> sort
   127   val intern_typ: theory -> typ -> typ
   128   val extern_typ: theory -> typ -> typ
   129   val intern_term: theory -> term -> term
   130   val extern_term: theory -> term -> term
   131   val intern_tycons: theory -> typ -> typ
   132   val pretty_term': Syntax.syntax -> theory -> term -> Pretty.T
   133   val pretty_term: theory -> term -> Pretty.T
   134   val pretty_typ: theory -> typ -> Pretty.T
   135   val pretty_sort: theory -> sort -> Pretty.T
   136   val pretty_classrel: theory -> class list -> Pretty.T
   137   val pretty_arity: theory -> arity -> Pretty.T
   138   val string_of_term: theory -> term -> string
   139   val string_of_typ: theory -> typ -> string
   140   val string_of_sort: theory -> sort -> string
   141   val string_of_classrel: theory -> class list -> string
   142   val string_of_arity: theory -> arity -> string
   143   val pprint_term: theory -> term -> pprint_args -> unit
   144   val pprint_typ: theory -> typ -> pprint_args -> unit
   145   val pp: theory -> Pretty.pp
   146   val certify_class: theory -> class -> class
   147   val certify_sort: theory -> sort -> sort
   148   val certify_typ: theory -> typ -> typ
   149   val certify_typ_syntax: theory -> typ -> typ
   150   val certify_typ_abbrev: theory -> typ -> typ
   151   val certify_term: Pretty.pp -> theory -> term -> term * typ * int
   152   val certify_prop: Pretty.pp -> theory -> term -> term * typ * int
   153   val cert_term: theory -> term -> term
   154   val cert_prop: theory -> term -> term
   155   val read_sort': Syntax.syntax -> theory -> string -> sort
   156   val read_sort: theory -> string -> sort
   157   val read_typ': Syntax.syntax -> theory * (indexname -> sort option) -> string -> typ
   158   val read_typ_syntax': Syntax.syntax -> theory * (indexname -> sort option) -> string -> typ
   159   val read_typ_abbrev': Syntax.syntax -> theory * (indexname -> sort option) -> string -> typ
   160   val read_typ: theory * (indexname -> sort option) -> string -> typ
   161   val read_typ_syntax: theory * (indexname -> sort option) -> string -> typ
   162   val read_typ_abbrev: theory * (indexname -> sort option) -> string -> typ
   163   val read_tyname: theory -> string -> typ
   164   val read_const: theory -> string -> term
   165   val infer_types_simult: Pretty.pp -> theory -> (indexname -> typ option) ->
   166     (indexname -> sort option) -> string list -> bool
   167     -> (term list * typ) list -> term list * (indexname * typ) list
   168   val infer_types: Pretty.pp -> theory -> (indexname -> typ option) ->
   169     (indexname -> sort option) -> string list -> bool
   170     -> term list * typ -> term * (indexname * typ) list
   171   val read_def_terms': Pretty.pp -> (string -> bool) -> Syntax.syntax ->
   172     theory * (indexname -> typ option) * (indexname -> sort option) ->
   173     string list -> bool -> (string * typ) list -> term list * (indexname * typ) list
   174   val read_def_terms:
   175     theory * (indexname -> typ option) * (indexname -> sort option) ->
   176     string list -> bool -> (string * typ) list -> term list * (indexname * typ) list
   177   val simple_read_term: theory -> typ -> string -> term
   178   val read_term: theory -> string -> term
   179   val read_prop: theory -> string -> term
   180   val const_of_class: class -> string
   181   val class_of_const: string -> class
   182   include SIGN_THEORY
   183 end
   184 
   185 structure Sign: SIGN =
   186 struct
   187 
   188 type sg = theory;
   189 
   190 
   191 (** datatype sign **)
   192 
   193 datatype sign = Sign of
   194  {naming: NameSpace.naming,                 (*common naming conventions*)
   195   syn: Syntax.syntax,                       (*concrete syntax for terms, types, sorts*)
   196   tsig: Type.tsig,                          (*order-sorted signature of types*)
   197   consts:
   198     (typ * stamp) NameSpace.table *         (*type schemes of declared term constants*)
   199     typ Symtab.table};                      (*type constraints for constants*)
   200 
   201 
   202 fun make_sign (naming, syn, tsig, consts) =
   203   Sign {naming = naming, syn = syn, tsig = tsig, consts = consts};
   204 
   205 fun err_dup_consts cs =
   206   error ("Duplicate declaration of constant(s) " ^ commas_quote cs);
   207 
   208 fun err_inconsistent_constraints cs =
   209   error ("Inconsistent type constraints for constant(s) " ^ commas_quote cs);
   210 
   211 structure SignData = TheoryDataFun
   212 (struct
   213   val name = "Pure/sign";
   214   type T = sign;
   215   val copy = I;
   216   fun extend (Sign {syn, tsig, consts, ...}) =
   217     make_sign (NameSpace.default_naming, syn, tsig, consts);
   218 
   219   val empty = make_sign (NameSpace.default_naming, Syntax.pure_syn, Type.empty_tsig,
   220     (NameSpace.empty_table, Symtab.empty));
   221 
   222   fun merge pp (sign1, sign2) =
   223     let
   224       val Sign {naming = _, syn = syn1, tsig = tsig1, consts = (consts1, constraints1)} = sign1;
   225       val Sign {naming = _, syn = syn2, tsig = tsig2, consts = (consts2, constraints2)} = sign2;
   226 
   227       val naming = NameSpace.default_naming;
   228       val syn = Syntax.merge_syntaxes syn1 syn2;
   229       val tsig = Type.merge_tsigs pp (tsig1, tsig2);
   230       val consts = NameSpace.merge_tables eq_snd (consts1, consts2)
   231         handle Symtab.DUPS cs => err_dup_consts cs;
   232       val constraints = Symtab.merge (op =) (constraints1, constraints2)
   233         handle Symtab.DUPS cs => err_inconsistent_constraints cs;
   234     in make_sign (naming, syn, tsig, (consts, constraints)) end;
   235 
   236   fun print _ _ = ();
   237 end);
   238 
   239 val init_data = SignData.init;
   240 
   241 fun rep_sg thy = SignData.get thy |> (fn Sign args => args);
   242 
   243 fun map_sign f = SignData.map (fn Sign {naming, syn, tsig, consts} =>
   244   make_sign (f (naming, syn, tsig, consts)));
   245 
   246 fun map_naming f = map_sign (fn (naming, syn, tsig, consts) => (f naming, syn, tsig, consts));
   247 fun map_syn f = map_sign (fn (naming, syn, tsig, consts) => (naming, f syn, tsig, consts));
   248 fun map_tsig f = map_sign (fn (naming, syn, tsig, consts) => (naming, syn, f tsig, consts));
   249 fun map_consts f = map_sign (fn (naming, syn, tsig, consts) => (naming, syn, tsig, f consts));
   250 
   251 
   252 (* naming *)
   253 
   254 val naming_of = #naming o rep_sg;
   255 val base_name = NameSpace.base;
   256 val full_name = NameSpace.full o naming_of;
   257 fun full_name_path thy elems = NameSpace.full (NameSpace.add_path elems (naming_of thy));
   258 val declare_name = NameSpace.declare o naming_of;
   259 
   260 
   261 (* syntax *)
   262 
   263 val syn_of = #syn o rep_sg;
   264 
   265 
   266 (* type signature *)
   267 
   268 val tsig_of = #tsig o rep_sg;
   269 val classes_of = snd o #classes o Type.rep_tsig o tsig_of;
   270 fun classes_arities_of thy = (classes_of thy, #arities (Type.rep_tsig (tsig_of thy)));
   271 val classes = Type.classes o tsig_of;
   272 val defaultS = Type.defaultS o tsig_of;
   273 val subsort = Type.subsort o tsig_of;
   274 val of_sort = Type.of_sort o tsig_of;
   275 val witness_sorts = Type.witness_sorts o tsig_of;
   276 val universal_witness = Type.universal_witness o tsig_of;
   277 val all_sorts_nonempty = is_some o universal_witness;
   278 val typ_instance = Type.typ_instance o tsig_of;
   279 val typ_match = Type.typ_match o tsig_of;
   280 val typ_unify = Type.unify o tsig_of;
   281 fun is_logtype thy c = c mem_string Type.logical_types (tsig_of thy);
   282 
   283 
   284 (* consts signature *)
   285 
   286 fun const_constraint thy c =
   287   let val ((_, consts), constraints) = #consts (rep_sg thy) in
   288     (case Symtab.lookup constraints c of
   289       NONE => Option.map #1 (Symtab.lookup consts c)
   290     | some => some)
   291   end;
   292 
   293 fun the_const_constraint thy c =
   294   (case const_constraint thy c of SOME T => T
   295   | NONE => raise TYPE ("Undeclared constant " ^ quote c, [], []));
   296 
   297 val const_type = Option.map #1 oo (Symtab.lookup o #2 o #1 o #consts o rep_sg);
   298 
   299 fun the_const_type thy c =
   300   (case const_type thy c of SOME T => T
   301   | NONE => raise TYPE ("Undeclared constant " ^ quote c, [], []));
   302 
   303 val declared_tyname = Symtab.defined o #2 o #types o Type.rep_tsig o tsig_of;
   304 val declared_const = is_some oo const_type;
   305 
   306 
   307 
   308 (** intern / extern names **)
   309 
   310 val class_space = #1 o #classes o Type.rep_tsig o tsig_of;
   311 val type_space = #1 o #types o Type.rep_tsig o tsig_of;
   312 val const_space = #1 o #1 o #consts o rep_sg
   313 
   314 val intern_class = NameSpace.intern o class_space;
   315 val extern_class = NameSpace.extern o class_space;
   316 val intern_type = NameSpace.intern o type_space;
   317 val extern_type = NameSpace.extern o type_space;
   318 val intern_const = NameSpace.intern o const_space;
   319 val extern_const = NameSpace.extern o const_space;
   320 
   321 val intern_sort = map o intern_class;
   322 val extern_sort = map o extern_class;
   323 
   324 local
   325 
   326 fun mapping add_names f t =
   327   let
   328     fun f' x = let val y = f x in if x = y then NONE else SOME (x, y) end;
   329     val tab = List.mapPartial f' (add_names (t, []));
   330     fun get x = if_none (AList.lookup (op =) tab x) x;
   331   in get end;
   332 
   333 fun typ_mapping f g thy T =
   334   T |> Term.map_typ
   335     (mapping add_typ_classes (f thy) T)
   336     (mapping add_typ_tycons (g thy) T);
   337 
   338 fun term_mapping f g h thy t =
   339   t |> Term.map_term
   340     (mapping add_term_classes (f thy) t)
   341     (mapping add_term_tycons (g thy) t)
   342     (mapping add_term_consts (h thy) t);
   343 
   344 in
   345 
   346 val intern_typ = typ_mapping intern_class intern_type;
   347 val extern_typ = typ_mapping extern_class extern_type;
   348 val intern_term = term_mapping intern_class intern_type intern_const;
   349 val extern_term = term_mapping extern_class extern_type extern_const;
   350 val intern_tycons = typ_mapping (K I) intern_type;
   351 
   352 end;
   353 
   354 
   355 
   356 (** pretty printing of terms, types etc. **)
   357 
   358 fun pretty_term' syn thy t =
   359   Syntax.pretty_term thy syn (Context.exists_name Context.CPureN thy) (extern_term thy t);
   360 fun pretty_term thy t = pretty_term' (syn_of thy) thy t;
   361 fun pretty_typ thy T = Syntax.pretty_typ thy (syn_of thy) (extern_typ thy T);
   362 fun pretty_sort thy S = Syntax.pretty_sort thy (syn_of thy) (extern_sort thy S);
   363 
   364 fun pretty_classrel thy cs = Pretty.block (List.concat
   365   (separate [Pretty.str " <", Pretty.brk 1] (map (single o pretty_sort thy o single) cs)));
   366 
   367 fun pretty_arity thy (a, Ss, S) =
   368   let
   369     val a' = extern_type thy a;
   370     val dom =
   371       if null Ss then []
   372       else [Pretty.list "(" ")" (map (pretty_sort thy) Ss), Pretty.brk 1];
   373   in Pretty.block ([Pretty.str (a' ^ " ::"), Pretty.brk 1] @ dom @ [pretty_sort thy S]) end;
   374 
   375 val string_of_term = Pretty.string_of oo pretty_term;
   376 val string_of_typ = Pretty.string_of oo pretty_typ;
   377 val string_of_sort = Pretty.string_of oo pretty_sort;
   378 val string_of_classrel = Pretty.string_of oo pretty_classrel;
   379 val string_of_arity = Pretty.string_of oo pretty_arity;
   380 
   381 val pprint_term = (Pretty.pprint o Pretty.quote) oo pretty_term;
   382 val pprint_typ = (Pretty.pprint o Pretty.quote) oo pretty_typ;
   383 
   384 fun pp thy = Pretty.pp (pretty_term thy, pretty_typ thy, pretty_sort thy,
   385   pretty_classrel thy, pretty_arity thy);
   386 
   387 
   388 
   389 (** certify entities **)    (*exception TYPE*)
   390 
   391 (* certify wrt. type signature *)
   392 
   393 fun certify cert = cert o tsig_of o Context.check_thy;
   394 
   395 val certify_class      = certify Type.cert_class;
   396 val certify_sort       = certify Type.cert_sort;
   397 val certify_typ        = certify Type.cert_typ;
   398 val certify_typ_syntax = certify Type.cert_typ_syntax;
   399 val certify_typ_abbrev = certify Type.cert_typ_abbrev;
   400 
   401 
   402 (* certify_term *)
   403 
   404 local
   405 
   406 (*determine and check the type of a term*)
   407 fun type_check pp tm =
   408   let
   409     fun err_appl why bs t T u U =
   410       let
   411         val xs = map Free bs;           (*we do not rename here*)
   412         val t' = subst_bounds (xs, t);
   413         val u' = subst_bounds (xs, u);
   414         val msg = cat_lines
   415           (TypeInfer.appl_error (Syntax.pp_show_brackets pp) why t' T u' U);
   416       in raise TYPE (msg, [T, U], [t', u']) end;
   417 
   418     fun typ_of (_, Const (_, T)) = T
   419       | typ_of (_, Free  (_, T)) = T
   420       | typ_of (_, Var (_, T)) = T
   421       | typ_of (bs, Bound i) = snd (List.nth (bs, i) handle Subscript =>
   422           raise TYPE ("Loose bound variable: B." ^ string_of_int i, [], [Bound i]))
   423       | typ_of (bs, Abs (x, T, body)) = T --> typ_of ((x, T) :: bs, body)
   424       | typ_of (bs, t $ u) =
   425           let val T = typ_of (bs, t) and U = typ_of (bs, u) in
   426             (case T of
   427               Type ("fun", [T1, T2]) =>
   428                 if T1 = U then T2 else err_appl "Incompatible operand type" bs t T u U
   429             | _ => err_appl "Operator not of function type" bs t T u U)
   430           end;
   431 
   432   in typ_of ([], tm) end;
   433 
   434 in
   435 
   436 fun certify_term pp thy tm =
   437   let
   438     val _ = Context.check_thy thy;
   439 
   440     val tm' = map_term_types (certify_typ thy) tm;
   441     val tm' = if tm = tm' then tm else tm';  (*avoid copying of already normal term*)
   442 
   443     fun err msg = raise TYPE (msg, [], [tm']);
   444 
   445     fun show_const a T = quote a ^ " :: " ^ Pretty.string_of_typ pp T;
   446 
   447     fun check_atoms (t $ u) = (check_atoms t; check_atoms u)
   448       | check_atoms (Abs (_, _, t)) = check_atoms t
   449       | check_atoms (Const (a, T)) =
   450           (case const_type thy a of
   451             NONE => err ("Undeclared constant " ^ show_const a T)
   452           | SOME U =>
   453               if typ_instance thy (T, U) then ()
   454               else err ("Illegal type for constant " ^ show_const a T))
   455       | check_atoms (Var ((x, i), _)) =
   456           if i < 0 then err ("Malformed variable: " ^ quote x) else ()
   457       | check_atoms _ = ();
   458   in
   459     check_atoms tm';
   460     (tm', type_check pp tm', maxidx_of_term tm')
   461   end;
   462 
   463 end;
   464 
   465 fun certify_prop pp thy tm =
   466   let val res as (tm', T, _) = certify_term pp thy tm
   467   in if T <> propT then raise TYPE ("Term not of type prop", [T], [tm']) else res end;
   468 
   469 fun cert_term thy tm = #1 (certify_term (pp thy) thy tm);
   470 fun cert_prop thy tm = #1 (certify_prop (pp thy) thy tm);
   471 
   472 
   473 
   474 (** read and certify entities **)    (*exception ERROR*)
   475 
   476 (* sorts *)
   477 
   478 fun read_sort' syn thy str =
   479   let
   480     val _ = Context.check_thy thy;
   481     val S = intern_sort thy (Syntax.read_sort thy syn str);
   482   in certify_sort thy S handle TYPE (msg, _, _) => error msg end;
   483 
   484 fun read_sort thy str = read_sort' (syn_of thy) thy str;
   485 
   486 
   487 (* types *)
   488 
   489 local
   490 
   491 fun gen_read_typ' cert syn (thy, def_sort) str =
   492   let
   493     val _ = Context.check_thy thy;
   494     val get_sort = TypeInfer.get_sort (tsig_of thy) def_sort (intern_sort thy);
   495     val T = intern_tycons thy (Syntax.read_typ thy syn get_sort (intern_sort thy) str);
   496   in cert thy T handle TYPE (msg, _, _) => error msg end
   497   handle ERROR => error ("The error(s) above occurred in type " ^ quote str);
   498 
   499 fun gen_read_typ cert (thy, def_sort) str =
   500   gen_read_typ' cert (syn_of thy) (thy, def_sort) str;
   501 
   502 in
   503 
   504 fun no_def_sort thy = (thy: theory, K NONE);
   505 
   506 val read_typ'        = gen_read_typ' certify_typ;
   507 val read_typ_syntax' = gen_read_typ' certify_typ_syntax;
   508 val read_typ_abbrev' = gen_read_typ' certify_typ_abbrev;
   509 val read_typ         = gen_read_typ certify_typ;
   510 val read_typ_syntax  = gen_read_typ certify_typ_syntax;
   511 val read_typ_abbrev  = gen_read_typ certify_typ_abbrev;
   512 
   513 end;
   514 
   515 
   516 (* type and constant names *)
   517 
   518 fun read_tyname thy raw_c =
   519   let val c = intern_type thy raw_c in
   520     (case Symtab.lookup (#2 (#types (Type.rep_tsig (tsig_of thy)))) c of
   521       SOME (Type.LogicalType n, _) => Type (c, replicate n dummyT)
   522     | _ => error ("Undeclared type constructor: " ^ quote c))
   523   end;
   524 
   525 fun read_const thy raw_c =
   526   let
   527     val c = intern_const thy raw_c;
   528     val _ = the_const_type thy c handle TYPE (msg, _, _) => error msg;
   529   in Const (c, dummyT) end;
   530 
   531 
   532 
   533 (** infer_types **)         (*exception ERROR*)
   534 
   535 (*
   536   def_type: partial map from indexnames to types (constrains Frees and Vars)
   537   def_sort: partial map from indexnames to sorts (constrains TFrees and TVars)
   538   used: list of already used type variables
   539   freeze: if true then generated parameters are turned into TFrees, else TVars
   540 
   541   termss: lists of alternative parses (only one combination should be type-correct)
   542   typs: expected types
   543 *)
   544 
   545 fun infer_types_simult pp thy def_type def_sort used freeze args =
   546   let
   547     val termss = foldr multiply [[]] (map fst args);
   548     val typs =
   549       map (fn (_, T) => certify_typ thy T handle TYPE (msg, _, _) => error msg) args;
   550 
   551     fun infer ts = OK (TypeInfer.infer_types (Syntax.pp_show_brackets pp) (tsig_of thy)
   552         (const_constraint thy) def_type def_sort (intern_const thy) (intern_tycons thy)
   553         (intern_sort thy) used freeze typs ts)
   554       handle TYPE (msg, _, _) => Error msg;
   555 
   556     val err_results = map infer termss;
   557     val errs = List.mapPartial get_error err_results;
   558     val results = List.mapPartial get_ok err_results;
   559 
   560     val ambiguity = length termss;
   561 
   562     fun ambig_msg () =
   563       if ambiguity > 1 andalso ambiguity <= ! Syntax.ambiguity_level
   564       then
   565         error_msg "Got more than one parse tree.\n\
   566           \Retry with smaller Syntax.ambiguity_level for more information."
   567       else ();
   568   in
   569     if null results then (ambig_msg (); error (cat_lines errs))
   570     else if length results = 1 then
   571       (if ambiguity > ! Syntax.ambiguity_level then
   572         warning "Fortunately, only one parse tree is type correct.\n\
   573           \You may still want to disambiguate your grammar or your input."
   574       else (); hd results)
   575     else (ambig_msg (); error ("More than one term is type correct:\n" ^
   576       cat_lines (map (Pretty.string_of_term pp) (List.concat (map fst results)))))
   577   end;
   578 
   579 fun infer_types pp thy def_type def_sort used freeze tsT =
   580   apfst hd (infer_types_simult pp thy def_type def_sort used freeze [tsT]);
   581 
   582 
   583 (* read_def_terms -- read terms and infer types *)    (*exception ERROR*)
   584 
   585 fun read_def_terms' pp is_logtype syn (thy, types, sorts) used freeze sTs =
   586   let
   587     fun read (s, T) =
   588       let val T' = certify_typ thy T handle TYPE (msg, _, _) => error msg
   589       in (Syntax.read thy is_logtype syn T' s, T') end;
   590   in infer_types_simult pp thy types sorts used freeze (map read sTs) end;
   591 
   592 fun read_def_terms (thy, types, sorts) =
   593   read_def_terms' (pp thy) (is_logtype thy) (syn_of thy) (thy, types, sorts);
   594 
   595 fun simple_read_term thy T s =
   596   let val ([t], _) = read_def_terms (thy, K NONE, K NONE) [] true [(s, T)]
   597   in t end
   598   handle ERROR => error ("The error(s) above occurred for term " ^ s);
   599 
   600 fun read_term thy = simple_read_term thy TypeInfer.logicT;
   601 fun read_prop thy = simple_read_term thy propT;
   602 
   603 
   604 
   605 (** signature extension functions **)  (*exception ERROR/TYPE*)
   606 
   607 (* add default sort *)
   608 
   609 fun gen_add_defsort prep_sort s thy =
   610   thy |> map_tsig (Type.set_defsort (prep_sort thy s));
   611 
   612 val add_defsort = gen_add_defsort read_sort;
   613 val add_defsort_i = gen_add_defsort certify_sort;
   614 
   615 
   616 (* add type constructors *)
   617 
   618 fun add_types types thy = thy |> map_sign (fn (naming, syn, tsig, consts) =>
   619   let
   620     val syn' = Syntax.extend_type_gram types syn;
   621     val decls = map (fn (a, n, mx) => (Syntax.type_name a mx, n)) types;
   622     val tsig' = Type.add_types naming decls tsig;
   623   in (naming, syn', tsig', consts) end);
   624 
   625 fun add_typedecls decls thy =
   626   let
   627     fun type_of (a, vs, mx) =
   628       if null (duplicates vs) then (a, length vs, mx)
   629       else error ("Duplicate parameters in type declaration: " ^ quote a);
   630   in add_types (map type_of decls) thy end;
   631 
   632 
   633 (* add nonterminals *)
   634 
   635 fun add_nonterminals ns thy = thy |> map_sign (fn (naming, syn, tsig, consts) =>
   636   let
   637     val syn' = Syntax.extend_consts ns syn;
   638     val tsig' = Type.add_nonterminals naming ns tsig;
   639   in (naming, syn', tsig', consts) end);
   640 
   641 
   642 (* add type abbreviations *)
   643 
   644 fun gen_add_tyabbr prep_typ (a, vs, rhs, mx) thy =
   645   thy |> map_sign (fn (naming, syn, tsig, consts) =>
   646     let
   647       val syn' = Syntax.extend_type_gram [(a, length vs, mx)] syn;
   648       val a' = Syntax.type_name a mx;
   649       val abbr = (a', vs, prep_typ thy rhs)
   650         handle ERROR => error ("in type abbreviation " ^ quote a');
   651       val tsig' = Type.add_abbrevs naming [abbr] tsig;
   652     in (naming, syn', tsig', consts) end);
   653 
   654 val add_tyabbrs = fold (gen_add_tyabbr (read_typ_syntax o no_def_sort));
   655 val add_tyabbrs_i = fold (gen_add_tyabbr certify_typ_syntax);
   656 
   657 
   658 (* add type arities *)
   659 
   660 fun gen_add_arities int_type prep_sort arities thy = thy |> map_tsig (fn tsig =>
   661   let
   662     fun prep_arity (a, Ss, S) = (int_type thy a, map (prep_sort thy) Ss, prep_sort thy S)
   663       handle ERROR => error ("in arity for type " ^ quote a);
   664     val tsig' = Type.add_arities (pp thy) (map prep_arity arities) tsig;
   665   in tsig' end);
   666 
   667 val add_arities = gen_add_arities intern_type read_sort;
   668 val add_arities_i = gen_add_arities (K I) certify_sort;
   669 
   670 
   671 (* modify syntax *)
   672 
   673 fun gen_syntax change_gram prep_typ prmode args thy =
   674   let
   675     fun prep (c, T, mx) = (c, prep_typ thy T, mx)
   676       handle ERROR => error ("in syntax declaration " ^ quote (Syntax.const_name c mx));
   677   in thy |> map_syn (change_gram (is_logtype thy) prmode (map prep args)) end;
   678 
   679 fun gen_add_syntax x = gen_syntax Syntax.extend_const_gram x;
   680 
   681 val add_modesyntax = gen_add_syntax (read_typ_syntax o no_def_sort);
   682 val add_modesyntax_i = gen_add_syntax certify_typ_syntax;
   683 val add_syntax = add_modesyntax Syntax.default_mode;
   684 val add_syntax_i = add_modesyntax_i Syntax.default_mode;
   685 val del_modesyntax = gen_syntax Syntax.remove_const_gram (read_typ_syntax o no_def_sort);
   686 val del_modesyntax_i = gen_syntax Syntax.remove_const_gram certify_typ_syntax;
   687 
   688 
   689 (* add constants *)
   690 
   691 fun gen_add_consts prep_typ raw_args thy =
   692   let
   693     val prepT = Compress.typ thy o Type.varifyT o Type.no_tvars o Term.no_dummyT o prep_typ thy;
   694     fun prep (c, T, mx) = ((c, prepT T, mx) handle TYPE (msg, _, _) => error msg)
   695       handle ERROR => error ("in declaration of constant " ^ quote (Syntax.const_name c mx));
   696     val args = map prep raw_args;
   697     val decls = args |> map (fn (c, T, mx) => (Syntax.const_name c mx, (T, stamp ())));
   698 
   699     fun extend_consts consts = NameSpace.extend_table (naming_of thy) (consts, decls)
   700       handle Symtab.DUPS cs => err_dup_consts cs;
   701   in
   702     thy
   703     |> map_consts (apfst extend_consts)
   704     |> add_syntax_i args
   705   end;
   706 
   707 val add_consts = gen_add_consts (read_typ o no_def_sort);
   708 val add_consts_i = gen_add_consts certify_typ;
   709 
   710 
   711 (* add constraints *)
   712 
   713 fun gen_add_constraint int_const prep_typ (raw_c, raw_T) thy =
   714   let
   715     val c = int_const thy raw_c;
   716     val T = Term.zero_var_indexesT (Term.no_dummyT (prep_typ thy raw_T))
   717       handle TYPE (msg, _, _) => error msg;
   718     val _ = cert_term thy (Const (c, T))
   719       handle TYPE (msg, _, _) => error msg;
   720   in thy |> map_consts (apsnd (Symtab.update (c, T))) end;
   721 
   722 val add_const_constraint = gen_add_constraint intern_const (read_typ o no_def_sort);
   723 val add_const_constraint_i = gen_add_constraint (K I) certify_typ;
   724 
   725 
   726 (* add type classes *)
   727 
   728 val classN = "_class";
   729 
   730 val const_of_class = suffix classN;
   731 fun class_of_const c = unsuffix classN c
   732   handle Fail _ => raise TERM ("class_of_const: bad name " ^ quote c, []);
   733 
   734 fun gen_add_class int_class (bclass, raw_classes) thy =
   735   thy |> map_sign (fn (naming, syn, tsig, consts) =>
   736     let
   737       val classes = map (int_class thy) raw_classes;
   738       val syn' = Syntax.extend_consts [bclass] syn;
   739       val tsig' = Type.add_classes (pp thy) naming [(bclass, classes)] tsig;
   740     in (naming, syn', tsig', consts) end)
   741   |> add_consts_i [(const_of_class bclass, a_itselfT --> propT, Syntax.NoSyn)];
   742 
   743 val add_classes = fold (gen_add_class intern_class);
   744 val add_classes_i = fold (gen_add_class (K I));
   745 
   746 
   747 (* add to classrel *)
   748 
   749 fun gen_add_classrel int_class raw_pairs thy = thy |> map_tsig (fn tsig =>
   750   let
   751     val pairs = map (pairself (int_class thy)) raw_pairs;
   752     val tsig' = Type.add_classrel (pp thy) pairs tsig;
   753   in tsig' end);
   754 
   755 val add_classrel = gen_add_classrel intern_class;
   756 val add_classrel_i = gen_add_classrel (K I);
   757 
   758 
   759 (* add translation functions *)
   760 
   761 local
   762 
   763 fun mk trs = map Syntax.mk_trfun trs;
   764 
   765 fun gen_add_trfuns ext non_typed (atrs, trs, tr's, atr's) =
   766   map_syn (ext (mk atrs, mk trs, mk (map (apsnd non_typed) tr's), mk atr's));
   767 
   768 fun gen_add_trfunsT ext tr's = map_syn (ext ([], [], mk tr's, []));
   769 
   770 in
   771 
   772 val add_trfuns = gen_add_trfuns Syntax.extend_trfuns Syntax.non_typed_tr';
   773 val add_trfunsT = gen_add_trfunsT Syntax.extend_trfuns;
   774 val add_advanced_trfuns = gen_add_trfuns Syntax.extend_advanced_trfuns Syntax.non_typed_tr'';
   775 val add_advanced_trfunsT = gen_add_trfunsT Syntax.extend_advanced_trfuns;
   776 
   777 end;
   778 
   779 val add_tokentrfuns = map_syn o Syntax.extend_tokentrfuns;
   780 fun add_mode_tokentrfuns m = add_tokentrfuns o map (fn (s, f) => (m, s, f));
   781 
   782 
   783 (* compile translation functions *)
   784 
   785 local
   786 
   787 fun advancedT false = ""
   788   | advancedT true = "theory -> ";
   789 
   790 fun advancedN false = ""
   791   | advancedN true = "advanced_";
   792 
   793 in
   794 
   795 fun parse_ast_translation (a, txt) =
   796   txt |> Context.use_let ("val parse_ast_translation: (string * (" ^ advancedT a ^
   797       "Syntax.ast list -> Syntax.ast)) list")
   798     ("Sign.add_" ^ advancedN a ^ "trfuns (parse_ast_translation, [], [], [])");
   799 
   800 fun parse_translation (a, txt) =
   801   txt |> Context.use_let ("val parse_translation: (string * (" ^ advancedT a ^
   802       "term list -> term)) list")
   803     ("Sign.add_" ^ advancedN a ^ "trfuns ([], parse_translation, [], [])");
   804 
   805 fun print_translation (a, txt) =
   806   txt |> Context.use_let ("val print_translation: (string * (" ^ advancedT a ^
   807       "term list -> term)) list")
   808     ("Sign.add_" ^ advancedN a ^ "trfuns ([], [], print_translation, [])");
   809 
   810 fun print_ast_translation (a, txt) =
   811   txt |> Context.use_let ("val print_ast_translation: (string * (" ^ advancedT a ^
   812       "Syntax.ast list -> Syntax.ast)) list")
   813     ("Sign.add_" ^ advancedN a ^ "trfuns ([], [], [], print_ast_translation)");
   814 
   815 fun typed_print_translation (a, txt) =
   816   txt |> Context.use_let ("val typed_print_translation: (string * (" ^ advancedT a ^
   817       "bool -> typ -> term list -> term)) list")
   818     ("Sign.add_" ^ advancedN a ^ "trfunsT typed_print_translation");
   819 
   820 val token_translation =
   821   Context.use_let "val token_translation: (string * string * (string -> string * real)) list"
   822     "Sign.add_tokentrfuns token_translation";
   823 
   824 end;
   825 
   826 
   827 (* add translation rules *)
   828 
   829 fun add_trrules args thy = thy |> map_syn (fn syn =>
   830   let val rules = map (Syntax.map_trrule (apfst (intern_type thy))) args
   831   in Syntax.extend_trrules thy (is_logtype thy) syn rules syn end);
   832 
   833 val add_trrules_i = map_syn o Syntax.extend_trrules_i;
   834 
   835 
   836 (* modify naming *)
   837 
   838 val add_path        = map_naming o NameSpace.add_path;
   839 val qualified_names = map_naming NameSpace.qualified_names;
   840 val no_base_names   = map_naming NameSpace.no_base_names;
   841 val custom_accesses = map_naming o NameSpace.custom_accesses;
   842 val set_policy      = map_naming o NameSpace.set_policy;
   843 val restore_naming  = map_naming o K o naming_of;
   844 
   845 val parent_path     = add_path "..";
   846 val root_path       = add_path "/";
   847 val absolute_path   = add_path "//";
   848 
   849 fun local_path thy = thy |> root_path |> add_path (Context.theory_name thy);
   850 
   851 
   852 (* hide names *)
   853 
   854 fun hide_classes b xs thy = thy |> map_tsig (Type.hide_classes b (map (intern_class thy) xs));
   855 val hide_classes_i = map_tsig oo Type.hide_classes;
   856 fun hide_types b xs thy = thy |> map_tsig (Type.hide_types b (map (intern_type thy) xs));
   857 val hide_types_i = map_tsig oo Type.hide_types;
   858 fun hide_consts b xs thy =
   859   thy |> map_consts (apfst (apfst (fold (NameSpace.hide b o intern_const thy) xs)));
   860 val hide_consts_i = (map_consts o apfst o apfst) oo (fold o NameSpace.hide);
   861 
   862 local
   863 
   864 val kinds =
   865  [("class", (intern_class, can o certify_class, hide_classes_i)),
   866   ("type", (intern_type, declared_tyname, hide_types_i)),
   867   ("const", (intern_const, declared_const, hide_consts_i))];
   868 
   869 fun gen_hide int b (kind, xnames) thy =
   870   (case AList.lookup (op =) kinds kind of
   871     SOME (intern, check, hide) =>
   872       let
   873         val names = if int then map (intern thy) xnames else xnames;
   874         val bads = filter_out (check thy) names;
   875       in
   876         if null bads then hide b names thy
   877         else error ("Attempt to hide undeclared item(s): " ^ commas_quote bads)
   878       end
   879   | NONE => error ("Bad name space specification: " ^ quote kind));
   880 
   881 in
   882 
   883 val hide_names = gen_hide true;
   884 val hide_names_i = gen_hide false;
   885 
   886 end;
   887 
   888 end;