src/HOL/HOL.thy
author haftmann
Wed Sep 26 20:27:55 2007 +0200 (2007-09-26)
changeset 24728 e2b3a1065676
parent 24633 0a3a02066244
child 24748 ee0a0eb6b738
permissions -rw-r--r--
moved Finite_Set before Datatype
     1 (*  Title:      HOL/HOL.thy
     2     ID:         $Id$
     3     Author:     Tobias Nipkow, Markus Wenzel, and Larry Paulson
     4 *)
     5 
     6 header {* The basis of Higher-Order Logic *}
     7 
     8 theory HOL
     9 imports CPure
    10 uses
    11   ("hologic.ML")
    12   "~~/src/Tools/IsaPlanner/zipper.ML"
    13   "~~/src/Tools/IsaPlanner/isand.ML"
    14   "~~/src/Tools/IsaPlanner/rw_tools.ML"
    15   "~~/src/Tools/IsaPlanner/rw_inst.ML"
    16   "~~/src/Provers/project_rule.ML"
    17   "~~/src/Provers/induct_method.ML"
    18   "~~/src/Provers/hypsubst.ML"
    19   "~~/src/Provers/splitter.ML"
    20   "~~/src/Provers/classical.ML"
    21   "~~/src/Provers/blast.ML"
    22   "~~/src/Provers/clasimp.ML"
    23   "~~/src/Provers/eqsubst.ML"
    24   "~~/src/Provers/quantifier1.ML"
    25   ("simpdata.ML")
    26   "~~/src/Tools/code/code_name.ML"
    27   "~~/src/Tools/code/code_funcgr.ML"
    28   "~~/src/Tools/code/code_thingol.ML"
    29   "~~/src/Tools/code/code_target.ML"
    30   "~~/src/Tools/code/code_package.ML"
    31   "~~/src/Tools/nbe.ML"
    32 begin
    33 
    34 subsection {* Primitive logic *}
    35 
    36 subsubsection {* Core syntax *}
    37 
    38 classes type
    39 defaultsort type
    40 
    41 global
    42 
    43 typedecl bool
    44 
    45 arities
    46   bool :: type
    47   "fun" :: (type, type) type
    48 
    49 judgment
    50   Trueprop      :: "bool => prop"                   ("(_)" 5)
    51 
    52 consts
    53   Not           :: "bool => bool"                   ("~ _" [40] 40)
    54   True          :: bool
    55   False         :: bool
    56   arbitrary     :: 'a
    57 
    58   The           :: "('a => bool) => 'a"
    59   All           :: "('a => bool) => bool"           (binder "ALL " 10)
    60   Ex            :: "('a => bool) => bool"           (binder "EX " 10)
    61   Ex1           :: "('a => bool) => bool"           (binder "EX! " 10)
    62   Let           :: "['a, 'a => 'b] => 'b"
    63 
    64   "op ="        :: "['a, 'a] => bool"               (infixl "=" 50)
    65   "op &"        :: "[bool, bool] => bool"           (infixr "&" 35)
    66   "op |"        :: "[bool, bool] => bool"           (infixr "|" 30)
    67   "op -->"      :: "[bool, bool] => bool"           (infixr "-->" 25)
    68 
    69 local
    70 
    71 consts
    72   If            :: "[bool, 'a, 'a] => 'a"           ("(if (_)/ then (_)/ else (_))" 10)
    73 
    74 
    75 subsubsection {* Additional concrete syntax *}
    76 
    77 notation (output)
    78   "op ="  (infix "=" 50)
    79 
    80 abbreviation
    81   not_equal :: "['a, 'a] => bool"  (infixl "~=" 50) where
    82   "x ~= y == ~ (x = y)"
    83 
    84 notation (output)
    85   not_equal  (infix "~=" 50)
    86 
    87 notation (xsymbols)
    88   Not  ("\<not> _" [40] 40) and
    89   "op &"  (infixr "\<and>" 35) and
    90   "op |"  (infixr "\<or>" 30) and
    91   "op -->"  (infixr "\<longrightarrow>" 25) and
    92   not_equal  (infix "\<noteq>" 50)
    93 
    94 notation (HTML output)
    95   Not  ("\<not> _" [40] 40) and
    96   "op &"  (infixr "\<and>" 35) and
    97   "op |"  (infixr "\<or>" 30) and
    98   not_equal  (infix "\<noteq>" 50)
    99 
   100 abbreviation (iff)
   101   iff :: "[bool, bool] => bool"  (infixr "<->" 25) where
   102   "A <-> B == A = B"
   103 
   104 notation (xsymbols)
   105   iff  (infixr "\<longleftrightarrow>" 25)
   106 
   107 
   108 nonterminals
   109   letbinds  letbind
   110   case_syn  cases_syn
   111 
   112 syntax
   113   "_The"        :: "[pttrn, bool] => 'a"                 ("(3THE _./ _)" [0, 10] 10)
   114 
   115   "_bind"       :: "[pttrn, 'a] => letbind"              ("(2_ =/ _)" 10)
   116   ""            :: "letbind => letbinds"                 ("_")
   117   "_binds"      :: "[letbind, letbinds] => letbinds"     ("_;/ _")
   118   "_Let"        :: "[letbinds, 'a] => 'a"                ("(let (_)/ in (_))" 10)
   119 
   120   "_case_syntax":: "['a, cases_syn] => 'b"               ("(case _ of/ _)" 10)
   121   "_case1"      :: "['a, 'b] => case_syn"                ("(2_ =>/ _)" 10)
   122   ""            :: "case_syn => cases_syn"               ("_")
   123   "_case2"      :: "[case_syn, cases_syn] => cases_syn"  ("_/ | _")
   124 
   125 translations
   126   "THE x. P"              == "The (%x. P)"
   127   "_Let (_binds b bs) e"  == "_Let b (_Let bs e)"
   128   "let x = a in e"        == "Let a (%x. e)"
   129 
   130 print_translation {*
   131 (* To avoid eta-contraction of body: *)
   132 [("The", fn [Abs abs] =>
   133      let val (x,t) = atomic_abs_tr' abs
   134      in Syntax.const "_The" $ x $ t end)]
   135 *}
   136 
   137 syntax (xsymbols)
   138   "_case1"      :: "['a, 'b] => case_syn"                ("(2_ \<Rightarrow>/ _)" 10)
   139 
   140 notation (xsymbols)
   141   All  (binder "\<forall>" 10) and
   142   Ex  (binder "\<exists>" 10) and
   143   Ex1  (binder "\<exists>!" 10)
   144 
   145 notation (HTML output)
   146   All  (binder "\<forall>" 10) and
   147   Ex  (binder "\<exists>" 10) and
   148   Ex1  (binder "\<exists>!" 10)
   149 
   150 notation (HOL)
   151   All  (binder "! " 10) and
   152   Ex  (binder "? " 10) and
   153   Ex1  (binder "?! " 10)
   154 
   155 
   156 subsubsection {* Axioms and basic definitions *}
   157 
   158 axioms
   159   eq_reflection:  "(x=y) ==> (x==y)"
   160 
   161   refl:           "t = (t::'a)"
   162 
   163   ext:            "(!!x::'a. (f x ::'b) = g x) ==> (%x. f x) = (%x. g x)"
   164     -- {*Extensionality is built into the meta-logic, and this rule expresses
   165          a related property.  It is an eta-expanded version of the traditional
   166          rule, and similar to the ABS rule of HOL*}
   167 
   168   the_eq_trivial: "(THE x. x = a) = (a::'a)"
   169 
   170   impI:           "(P ==> Q) ==> P-->Q"
   171   mp:             "[| P-->Q;  P |] ==> Q"
   172 
   173 
   174 defs
   175   True_def:     "True      == ((%x::bool. x) = (%x. x))"
   176   All_def:      "All(P)    == (P = (%x. True))"
   177   Ex_def:       "Ex(P)     == !Q. (!x. P x --> Q) --> Q"
   178   False_def:    "False     == (!P. P)"
   179   not_def:      "~ P       == P-->False"
   180   and_def:      "P & Q     == !R. (P-->Q-->R) --> R"
   181   or_def:       "P | Q     == !R. (P-->R) --> (Q-->R) --> R"
   182   Ex1_def:      "Ex1(P)    == ? x. P(x) & (! y. P(y) --> y=x)"
   183 
   184 axioms
   185   iff:          "(P-->Q) --> (Q-->P) --> (P=Q)"
   186   True_or_False:  "(P=True) | (P=False)"
   187 
   188 defs
   189   Let_def:      "Let s f == f(s)"
   190   if_def:       "If P x y == THE z::'a. (P=True --> z=x) & (P=False --> z=y)"
   191 
   192 finalconsts
   193   "op ="
   194   "op -->"
   195   The
   196   arbitrary
   197 
   198 axiomatization
   199   undefined :: 'a
   200 
   201 axiomatization where
   202   undefined_fun: "undefined x = undefined"
   203 
   204 
   205 subsubsection {* Generic classes and algebraic operations *}
   206 
   207 class default = type +
   208   fixes default :: "'a"
   209 
   210 class zero = type + 
   211   fixes zero :: "'a"  ("\<^loc>0")
   212 
   213 class one = type +
   214   fixes one  :: "'a"  ("\<^loc>1")
   215 
   216 hide (open) const zero one
   217 
   218 class plus = type +
   219   fixes plus :: "'a \<Rightarrow> 'a \<Rightarrow> 'a"  (infixl "\<^loc>+" 65)
   220 
   221 class minus = type +
   222   fixes uminus :: "'a \<Rightarrow> 'a" 
   223     and minus :: "'a \<Rightarrow> 'a \<Rightarrow> 'a"  (infixl "\<^loc>-" 65)
   224 
   225 class times = type +
   226   fixes times :: "'a \<Rightarrow> 'a \<Rightarrow> 'a"  (infixl "\<^loc>*" 70)
   227 
   228 class inverse = type +
   229   fixes inverse :: "'a \<Rightarrow> 'a"
   230     and divide :: "'a \<Rightarrow> 'a \<Rightarrow> 'a"  (infixl "\<^loc>'/" 70)
   231 
   232 class abs = type +
   233   fixes abs :: "'a \<Rightarrow> 'a"
   234 
   235 class sgn = type +
   236   fixes sgn :: "'a \<Rightarrow> 'a"
   237 
   238 notation
   239   uminus  ("- _" [81] 80)
   240 
   241 notation (xsymbols)
   242   abs  ("\<bar>_\<bar>")
   243 notation (HTML output)
   244   abs  ("\<bar>_\<bar>")
   245 
   246 class ord = type +
   247   fixes less_eq :: "'a \<Rightarrow> 'a \<Rightarrow> bool"  (infix "\<sqsubseteq>" 50)
   248     and less :: "'a \<Rightarrow> 'a \<Rightarrow> bool"  (infix "\<sqsubset>" 50)
   249 begin
   250 
   251 notation
   252   less_eq  ("op \<^loc><=") and
   253   less_eq  ("(_/ \<^loc><= _)" [51, 51] 50) and
   254   less  ("op \<^loc><") and
   255   less  ("(_/ \<^loc>< _)"  [51, 51] 50)
   256   
   257 notation (xsymbols)
   258   less_eq  ("op \<^loc>\<le>") and
   259   less_eq  ("(_/ \<^loc>\<le> _)"  [51, 51] 50)
   260 
   261 notation (HTML output)
   262   less_eq  ("op \<^loc>\<le>") and
   263   less_eq  ("(_/ \<^loc>\<le> _)"  [51, 51] 50)
   264 
   265 abbreviation (input)
   266   greater  (infix "\<^loc>>" 50) where
   267   "x \<^loc>> y \<equiv> y \<^loc>< x"
   268 
   269 abbreviation (input)
   270   greater_eq  (infix "\<^loc>>=" 50) where
   271   "x \<^loc>>= y \<equiv> y \<^loc><= x"
   272 
   273 notation (input)
   274   greater_eq  (infix "\<^loc>\<ge>" 50)
   275 
   276 definition
   277   Least :: "('a \<Rightarrow> bool) \<Rightarrow> 'a" (binder "\<^loc>LEAST " 10)
   278 where
   279   "Least P == (THE x. P x \<and> (\<forall>y. P y \<longrightarrow> x \<^loc>\<le> y))"
   280 
   281 end
   282 
   283 notation
   284   less_eq  ("op <=") and
   285   less_eq  ("(_/ <= _)" [51, 51] 50) and
   286   less  ("op <") and
   287   less  ("(_/ < _)"  [51, 51] 50)
   288   
   289 notation (xsymbols)
   290   less_eq  ("op \<le>") and
   291   less_eq  ("(_/ \<le> _)"  [51, 51] 50)
   292 
   293 notation (HTML output)
   294   less_eq  ("op \<le>") and
   295   less_eq  ("(_/ \<le> _)"  [51, 51] 50)
   296 
   297 abbreviation (input)
   298   greater  (infix ">" 50) where
   299   "x > y \<equiv> y < x"
   300 
   301 abbreviation (input)
   302   greater_eq  (infix ">=" 50) where
   303   "x >= y \<equiv> y <= x"
   304 
   305 notation (input)
   306   greater_eq  (infix "\<ge>" 50)
   307 
   308 syntax
   309   "_index1"  :: index    ("\<^sub>1")
   310 translations
   311   (index) "\<^sub>1" => (index) "\<^bsub>\<struct>\<^esub>"
   312 
   313 typed_print_translation {*
   314 let
   315   fun tr' c = (c, fn show_sorts => fn T => fn ts =>
   316     if T = dummyT orelse not (! show_types) andalso can Term.dest_Type T then raise Match
   317     else Syntax.const Syntax.constrainC $ Syntax.const c $ Syntax.term_of_typ show_sorts T);
   318 in map tr' [@{const_syntax HOL.one}, @{const_syntax HOL.zero}] end;
   319 *} -- {* show types that are presumably too general *}
   320 
   321 
   322 subsection {* Fundamental rules *}
   323 
   324 subsubsection {* Equality *}
   325 
   326 text {* Thanks to Stephan Merz *}
   327 lemma subst:
   328   assumes eq: "s = t" and p: "P s"
   329   shows "P t"
   330 proof -
   331   from eq have meta: "s \<equiv> t"
   332     by (rule eq_reflection)
   333   from p show ?thesis
   334     by (unfold meta)
   335 qed
   336 
   337 lemma sym: "s = t ==> t = s"
   338   by (erule subst) (rule refl)
   339 
   340 lemma ssubst: "t = s ==> P s ==> P t"
   341   by (drule sym) (erule subst)
   342 
   343 lemma trans: "[| r=s; s=t |] ==> r=t"
   344   by (erule subst)
   345 
   346 lemma meta_eq_to_obj_eq: 
   347   assumes meq: "A == B"
   348   shows "A = B"
   349   by (unfold meq) (rule refl)
   350 
   351 text {* Useful with @{text erule} for proving equalities from known equalities. *}
   352      (* a = b
   353         |   |
   354         c = d   *)
   355 lemma box_equals: "[| a=b;  a=c;  b=d |] ==> c=d"
   356 apply (rule trans)
   357 apply (rule trans)
   358 apply (rule sym)
   359 apply assumption+
   360 done
   361 
   362 text {* For calculational reasoning: *}
   363 
   364 lemma forw_subst: "a = b ==> P b ==> P a"
   365   by (rule ssubst)
   366 
   367 lemma back_subst: "P a ==> a = b ==> P b"
   368   by (rule subst)
   369 
   370 
   371 subsubsection {*Congruence rules for application*}
   372 
   373 (*similar to AP_THM in Gordon's HOL*)
   374 lemma fun_cong: "(f::'a=>'b) = g ==> f(x)=g(x)"
   375 apply (erule subst)
   376 apply (rule refl)
   377 done
   378 
   379 (*similar to AP_TERM in Gordon's HOL and FOL's subst_context*)
   380 lemma arg_cong: "x=y ==> f(x)=f(y)"
   381 apply (erule subst)
   382 apply (rule refl)
   383 done
   384 
   385 lemma arg_cong2: "\<lbrakk> a = b; c = d \<rbrakk> \<Longrightarrow> f a c = f b d"
   386 apply (erule ssubst)+
   387 apply (rule refl)
   388 done
   389 
   390 lemma cong: "[| f = g; (x::'a) = y |] ==> f(x) = g(y)"
   391 apply (erule subst)+
   392 apply (rule refl)
   393 done
   394 
   395 
   396 subsubsection {*Equality of booleans -- iff*}
   397 
   398 lemma iffI: assumes "P ==> Q" and "Q ==> P" shows "P=Q"
   399   by (iprover intro: iff [THEN mp, THEN mp] impI assms)
   400 
   401 lemma iffD2: "[| P=Q; Q |] ==> P"
   402   by (erule ssubst)
   403 
   404 lemma rev_iffD2: "[| Q; P=Q |] ==> P"
   405   by (erule iffD2)
   406 
   407 lemma iffD1: "Q = P \<Longrightarrow> Q \<Longrightarrow> P"
   408   by (drule sym) (rule iffD2)
   409 
   410 lemma rev_iffD1: "Q \<Longrightarrow> Q = P \<Longrightarrow> P"
   411   by (drule sym) (rule rev_iffD2)
   412 
   413 lemma iffE:
   414   assumes major: "P=Q"
   415     and minor: "[| P --> Q; Q --> P |] ==> R"
   416   shows R
   417   by (iprover intro: minor impI major [THEN iffD2] major [THEN iffD1])
   418 
   419 
   420 subsubsection {*True*}
   421 
   422 lemma TrueI: "True"
   423   unfolding True_def by (rule refl)
   424 
   425 lemma eqTrueI: "P ==> P = True"
   426   by (iprover intro: iffI TrueI)
   427 
   428 lemma eqTrueE: "P = True ==> P"
   429   by (erule iffD2) (rule TrueI)
   430 
   431 
   432 subsubsection {*Universal quantifier*}
   433 
   434 lemma allI: assumes "!!x::'a. P(x)" shows "ALL x. P(x)"
   435   unfolding All_def by (iprover intro: ext eqTrueI assms)
   436 
   437 lemma spec: "ALL x::'a. P(x) ==> P(x)"
   438 apply (unfold All_def)
   439 apply (rule eqTrueE)
   440 apply (erule fun_cong)
   441 done
   442 
   443 lemma allE:
   444   assumes major: "ALL x. P(x)"
   445     and minor: "P(x) ==> R"
   446   shows R
   447   by (iprover intro: minor major [THEN spec])
   448 
   449 lemma all_dupE:
   450   assumes major: "ALL x. P(x)"
   451     and minor: "[| P(x); ALL x. P(x) |] ==> R"
   452   shows R
   453   by (iprover intro: minor major major [THEN spec])
   454 
   455 
   456 subsubsection {* False *}
   457 
   458 text {*
   459   Depends upon @{text spec}; it is impossible to do propositional
   460   logic before quantifiers!
   461 *}
   462 
   463 lemma FalseE: "False ==> P"
   464   apply (unfold False_def)
   465   apply (erule spec)
   466   done
   467 
   468 lemma False_neq_True: "False = True ==> P"
   469   by (erule eqTrueE [THEN FalseE])
   470 
   471 
   472 subsubsection {* Negation *}
   473 
   474 lemma notI:
   475   assumes "P ==> False"
   476   shows "~P"
   477   apply (unfold not_def)
   478   apply (iprover intro: impI assms)
   479   done
   480 
   481 lemma False_not_True: "False ~= True"
   482   apply (rule notI)
   483   apply (erule False_neq_True)
   484   done
   485 
   486 lemma True_not_False: "True ~= False"
   487   apply (rule notI)
   488   apply (drule sym)
   489   apply (erule False_neq_True)
   490   done
   491 
   492 lemma notE: "[| ~P;  P |] ==> R"
   493   apply (unfold not_def)
   494   apply (erule mp [THEN FalseE])
   495   apply assumption
   496   done
   497 
   498 lemma notI2: "(P \<Longrightarrow> \<not> Pa) \<Longrightarrow> (P \<Longrightarrow> Pa) \<Longrightarrow> \<not> P"
   499   by (erule notE [THEN notI]) (erule meta_mp)
   500 
   501 
   502 subsubsection {*Implication*}
   503 
   504 lemma impE:
   505   assumes "P-->Q" "P" "Q ==> R"
   506   shows "R"
   507 by (iprover intro: assms mp)
   508 
   509 (* Reduces Q to P-->Q, allowing substitution in P. *)
   510 lemma rev_mp: "[| P;  P --> Q |] ==> Q"
   511 by (iprover intro: mp)
   512 
   513 lemma contrapos_nn:
   514   assumes major: "~Q"
   515       and minor: "P==>Q"
   516   shows "~P"
   517 by (iprover intro: notI minor major [THEN notE])
   518 
   519 (*not used at all, but we already have the other 3 combinations *)
   520 lemma contrapos_pn:
   521   assumes major: "Q"
   522       and minor: "P ==> ~Q"
   523   shows "~P"
   524 by (iprover intro: notI minor major notE)
   525 
   526 lemma not_sym: "t ~= s ==> s ~= t"
   527   by (erule contrapos_nn) (erule sym)
   528 
   529 lemma eq_neq_eq_imp_neq: "[| x = a ; a ~= b; b = y |] ==> x ~= y"
   530   by (erule subst, erule ssubst, assumption)
   531 
   532 (*still used in HOLCF*)
   533 lemma rev_contrapos:
   534   assumes pq: "P ==> Q"
   535       and nq: "~Q"
   536   shows "~P"
   537 apply (rule nq [THEN contrapos_nn])
   538 apply (erule pq)
   539 done
   540 
   541 subsubsection {*Existential quantifier*}
   542 
   543 lemma exI: "P x ==> EX x::'a. P x"
   544 apply (unfold Ex_def)
   545 apply (iprover intro: allI allE impI mp)
   546 done
   547 
   548 lemma exE:
   549   assumes major: "EX x::'a. P(x)"
   550       and minor: "!!x. P(x) ==> Q"
   551   shows "Q"
   552 apply (rule major [unfolded Ex_def, THEN spec, THEN mp])
   553 apply (iprover intro: impI [THEN allI] minor)
   554 done
   555 
   556 
   557 subsubsection {*Conjunction*}
   558 
   559 lemma conjI: "[| P; Q |] ==> P&Q"
   560 apply (unfold and_def)
   561 apply (iprover intro: impI [THEN allI] mp)
   562 done
   563 
   564 lemma conjunct1: "[| P & Q |] ==> P"
   565 apply (unfold and_def)
   566 apply (iprover intro: impI dest: spec mp)
   567 done
   568 
   569 lemma conjunct2: "[| P & Q |] ==> Q"
   570 apply (unfold and_def)
   571 apply (iprover intro: impI dest: spec mp)
   572 done
   573 
   574 lemma conjE:
   575   assumes major: "P&Q"
   576       and minor: "[| P; Q |] ==> R"
   577   shows "R"
   578 apply (rule minor)
   579 apply (rule major [THEN conjunct1])
   580 apply (rule major [THEN conjunct2])
   581 done
   582 
   583 lemma context_conjI:
   584   assumes "P" "P ==> Q" shows "P & Q"
   585 by (iprover intro: conjI assms)
   586 
   587 
   588 subsubsection {*Disjunction*}
   589 
   590 lemma disjI1: "P ==> P|Q"
   591 apply (unfold or_def)
   592 apply (iprover intro: allI impI mp)
   593 done
   594 
   595 lemma disjI2: "Q ==> P|Q"
   596 apply (unfold or_def)
   597 apply (iprover intro: allI impI mp)
   598 done
   599 
   600 lemma disjE:
   601   assumes major: "P|Q"
   602       and minorP: "P ==> R"
   603       and minorQ: "Q ==> R"
   604   shows "R"
   605 by (iprover intro: minorP minorQ impI
   606                  major [unfolded or_def, THEN spec, THEN mp, THEN mp])
   607 
   608 
   609 subsubsection {*Classical logic*}
   610 
   611 lemma classical:
   612   assumes prem: "~P ==> P"
   613   shows "P"
   614 apply (rule True_or_False [THEN disjE, THEN eqTrueE])
   615 apply assumption
   616 apply (rule notI [THEN prem, THEN eqTrueI])
   617 apply (erule subst)
   618 apply assumption
   619 done
   620 
   621 lemmas ccontr = FalseE [THEN classical, standard]
   622 
   623 (*notE with premises exchanged; it discharges ~R so that it can be used to
   624   make elimination rules*)
   625 lemma rev_notE:
   626   assumes premp: "P"
   627       and premnot: "~R ==> ~P"
   628   shows "R"
   629 apply (rule ccontr)
   630 apply (erule notE [OF premnot premp])
   631 done
   632 
   633 (*Double negation law*)
   634 lemma notnotD: "~~P ==> P"
   635 apply (rule classical)
   636 apply (erule notE)
   637 apply assumption
   638 done
   639 
   640 lemma contrapos_pp:
   641   assumes p1: "Q"
   642       and p2: "~P ==> ~Q"
   643   shows "P"
   644 by (iprover intro: classical p1 p2 notE)
   645 
   646 
   647 subsubsection {*Unique existence*}
   648 
   649 lemma ex1I:
   650   assumes "P a" "!!x. P(x) ==> x=a"
   651   shows "EX! x. P(x)"
   652 by (unfold Ex1_def, iprover intro: assms exI conjI allI impI)
   653 
   654 text{*Sometimes easier to use: the premises have no shared variables.  Safe!*}
   655 lemma ex_ex1I:
   656   assumes ex_prem: "EX x. P(x)"
   657       and eq: "!!x y. [| P(x); P(y) |] ==> x=y"
   658   shows "EX! x. P(x)"
   659 by (iprover intro: ex_prem [THEN exE] ex1I eq)
   660 
   661 lemma ex1E:
   662   assumes major: "EX! x. P(x)"
   663       and minor: "!!x. [| P(x);  ALL y. P(y) --> y=x |] ==> R"
   664   shows "R"
   665 apply (rule major [unfolded Ex1_def, THEN exE])
   666 apply (erule conjE)
   667 apply (iprover intro: minor)
   668 done
   669 
   670 lemma ex1_implies_ex: "EX! x. P x ==> EX x. P x"
   671 apply (erule ex1E)
   672 apply (rule exI)
   673 apply assumption
   674 done
   675 
   676 
   677 subsubsection {*THE: definite description operator*}
   678 
   679 lemma the_equality:
   680   assumes prema: "P a"
   681       and premx: "!!x. P x ==> x=a"
   682   shows "(THE x. P x) = a"
   683 apply (rule trans [OF _ the_eq_trivial])
   684 apply (rule_tac f = "The" in arg_cong)
   685 apply (rule ext)
   686 apply (rule iffI)
   687  apply (erule premx)
   688 apply (erule ssubst, rule prema)
   689 done
   690 
   691 lemma theI:
   692   assumes "P a" and "!!x. P x ==> x=a"
   693   shows "P (THE x. P x)"
   694 by (iprover intro: assms the_equality [THEN ssubst])
   695 
   696 lemma theI': "EX! x. P x ==> P (THE x. P x)"
   697 apply (erule ex1E)
   698 apply (erule theI)
   699 apply (erule allE)
   700 apply (erule mp)
   701 apply assumption
   702 done
   703 
   704 (*Easier to apply than theI: only one occurrence of P*)
   705 lemma theI2:
   706   assumes "P a" "!!x. P x ==> x=a" "!!x. P x ==> Q x"
   707   shows "Q (THE x. P x)"
   708 by (iprover intro: assms theI)
   709 
   710 lemma the1I2: assumes "EX! x. P x" "\<And>x. P x \<Longrightarrow> Q x" shows "Q (THE x. P x)"
   711 by(iprover intro:assms(2) theI2[where P=P and Q=Q] ex1E[OF assms(1)]
   712            elim:allE impE)
   713 
   714 lemma the1_equality [elim?]: "[| EX!x. P x; P a |] ==> (THE x. P x) = a"
   715 apply (rule the_equality)
   716 apply  assumption
   717 apply (erule ex1E)
   718 apply (erule all_dupE)
   719 apply (drule mp)
   720 apply  assumption
   721 apply (erule ssubst)
   722 apply (erule allE)
   723 apply (erule mp)
   724 apply assumption
   725 done
   726 
   727 lemma the_sym_eq_trivial: "(THE y. x=y) = x"
   728 apply (rule the_equality)
   729 apply (rule refl)
   730 apply (erule sym)
   731 done
   732 
   733 
   734 subsubsection {*Classical intro rules for disjunction and existential quantifiers*}
   735 
   736 lemma disjCI:
   737   assumes "~Q ==> P" shows "P|Q"
   738 apply (rule classical)
   739 apply (iprover intro: assms disjI1 disjI2 notI elim: notE)
   740 done
   741 
   742 lemma excluded_middle: "~P | P"
   743 by (iprover intro: disjCI)
   744 
   745 text {*
   746   case distinction as a natural deduction rule.
   747   Note that @{term "~P"} is the second case, not the first
   748 *}
   749 lemma case_split_thm:
   750   assumes prem1: "P ==> Q"
   751       and prem2: "~P ==> Q"
   752   shows "Q"
   753 apply (rule excluded_middle [THEN disjE])
   754 apply (erule prem2)
   755 apply (erule prem1)
   756 done
   757 lemmas case_split = case_split_thm [case_names True False]
   758 
   759 (*Classical implies (-->) elimination. *)
   760 lemma impCE:
   761   assumes major: "P-->Q"
   762       and minor: "~P ==> R" "Q ==> R"
   763   shows "R"
   764 apply (rule excluded_middle [of P, THEN disjE])
   765 apply (iprover intro: minor major [THEN mp])+
   766 done
   767 
   768 (*This version of --> elimination works on Q before P.  It works best for
   769   those cases in which P holds "almost everywhere".  Can't install as
   770   default: would break old proofs.*)
   771 lemma impCE':
   772   assumes major: "P-->Q"
   773       and minor: "Q ==> R" "~P ==> R"
   774   shows "R"
   775 apply (rule excluded_middle [of P, THEN disjE])
   776 apply (iprover intro: minor major [THEN mp])+
   777 done
   778 
   779 (*Classical <-> elimination. *)
   780 lemma iffCE:
   781   assumes major: "P=Q"
   782       and minor: "[| P; Q |] ==> R"  "[| ~P; ~Q |] ==> R"
   783   shows "R"
   784 apply (rule major [THEN iffE])
   785 apply (iprover intro: minor elim: impCE notE)
   786 done
   787 
   788 lemma exCI:
   789   assumes "ALL x. ~P(x) ==> P(a)"
   790   shows "EX x. P(x)"
   791 apply (rule ccontr)
   792 apply (iprover intro: assms exI allI notI notE [of "\<exists>x. P x"])
   793 done
   794 
   795 
   796 subsubsection {* Intuitionistic Reasoning *}
   797 
   798 lemma impE':
   799   assumes 1: "P --> Q"
   800     and 2: "Q ==> R"
   801     and 3: "P --> Q ==> P"
   802   shows R
   803 proof -
   804   from 3 and 1 have P .
   805   with 1 have Q by (rule impE)
   806   with 2 show R .
   807 qed
   808 
   809 lemma allE':
   810   assumes 1: "ALL x. P x"
   811     and 2: "P x ==> ALL x. P x ==> Q"
   812   shows Q
   813 proof -
   814   from 1 have "P x" by (rule spec)
   815   from this and 1 show Q by (rule 2)
   816 qed
   817 
   818 lemma notE':
   819   assumes 1: "~ P"
   820     and 2: "~ P ==> P"
   821   shows R
   822 proof -
   823   from 2 and 1 have P .
   824   with 1 show R by (rule notE)
   825 qed
   826 
   827 lemma TrueE: "True ==> P ==> P" .
   828 lemma notFalseE: "~ False ==> P ==> P" .
   829 
   830 lemmas [Pure.elim!] = disjE iffE FalseE conjE exE TrueE notFalseE
   831   and [Pure.intro!] = iffI conjI impI TrueI notI allI refl
   832   and [Pure.elim 2] = allE notE' impE'
   833   and [Pure.intro] = exI disjI2 disjI1
   834 
   835 lemmas [trans] = trans
   836   and [sym] = sym not_sym
   837   and [Pure.elim?] = iffD1 iffD2 impE
   838 
   839 use "hologic.ML"
   840 
   841 
   842 subsubsection {* Atomizing meta-level connectives *}
   843 
   844 lemma atomize_all [atomize]: "(!!x. P x) == Trueprop (ALL x. P x)"
   845 proof
   846   assume "!!x. P x"
   847   then show "ALL x. P x" ..
   848 next
   849   assume "ALL x. P x"
   850   then show "!!x. P x" by (rule allE)
   851 qed
   852 
   853 lemma atomize_imp [atomize]: "(A ==> B) == Trueprop (A --> B)"
   854 proof
   855   assume r: "A ==> B"
   856   show "A --> B" by (rule impI) (rule r)
   857 next
   858   assume "A --> B" and A
   859   then show B by (rule mp)
   860 qed
   861 
   862 lemma atomize_not: "(A ==> False) == Trueprop (~A)"
   863 proof
   864   assume r: "A ==> False"
   865   show "~A" by (rule notI) (rule r)
   866 next
   867   assume "~A" and A
   868   then show False by (rule notE)
   869 qed
   870 
   871 lemma atomize_eq [atomize]: "(x == y) == Trueprop (x = y)"
   872 proof
   873   assume "x == y"
   874   show "x = y" by (unfold `x == y`) (rule refl)
   875 next
   876   assume "x = y"
   877   then show "x == y" by (rule eq_reflection)
   878 qed
   879 
   880 lemma atomize_conj [atomize]:
   881   includes meta_conjunction_syntax
   882   shows "(A && B) == Trueprop (A & B)"
   883 proof
   884   assume conj: "A && B"
   885   show "A & B"
   886   proof (rule conjI)
   887     from conj show A by (rule conjunctionD1)
   888     from conj show B by (rule conjunctionD2)
   889   qed
   890 next
   891   assume conj: "A & B"
   892   show "A && B"
   893   proof -
   894     from conj show A ..
   895     from conj show B ..
   896   qed
   897 qed
   898 
   899 lemmas [symmetric, rulify] = atomize_all atomize_imp
   900   and [symmetric, defn] = atomize_all atomize_imp atomize_eq
   901 
   902 
   903 subsection {* Package setup *}
   904 
   905 subsubsection {* Classical Reasoner setup *}
   906 
   907 lemma thin_refl:
   908   "\<And>X. \<lbrakk> x=x; PROP W \<rbrakk> \<Longrightarrow> PROP W" .
   909 
   910 ML {*
   911 structure Hypsubst = HypsubstFun(
   912 struct
   913   structure Simplifier = Simplifier
   914   val dest_eq = HOLogic.dest_eq
   915   val dest_Trueprop = HOLogic.dest_Trueprop
   916   val dest_imp = HOLogic.dest_imp
   917   val eq_reflection = @{thm HOL.eq_reflection}
   918   val rev_eq_reflection = @{thm HOL.meta_eq_to_obj_eq}
   919   val imp_intr = @{thm HOL.impI}
   920   val rev_mp = @{thm HOL.rev_mp}
   921   val subst = @{thm HOL.subst}
   922   val sym = @{thm HOL.sym}
   923   val thin_refl = @{thm thin_refl};
   924 end);
   925 open Hypsubst;
   926 
   927 structure Classical = ClassicalFun(
   928 struct
   929   val mp = @{thm HOL.mp}
   930   val not_elim = @{thm HOL.notE}
   931   val classical = @{thm HOL.classical}
   932   val sizef = Drule.size_of_thm
   933   val hyp_subst_tacs = [Hypsubst.hyp_subst_tac]
   934 end);
   935 
   936 structure BasicClassical: BASIC_CLASSICAL = Classical; 
   937 open BasicClassical;
   938 
   939 ML_Context.value_antiq "claset"
   940   (Scan.succeed ("claset", "Classical.local_claset_of (ML_Context.the_local_context ())"));
   941 
   942 structure ResAtpset = NamedThmsFun(val name = "atp" val description = "ATP rules");
   943 
   944 structure ResBlacklist = NamedThmsFun(val name = "noatp" val description = "Theorems blacklisted for ATP");
   945 *}
   946 
   947 (*ResBlacklist holds theorems blacklisted to sledgehammer. 
   948   These theorems typically produce clauses that are prolific (match too many equality or
   949   membership literals) and relate to seldom-used facts. Some duplicate other rules.*)
   950 
   951 setup {*
   952 let
   953   (*prevent substitution on bool*)
   954   fun hyp_subst_tac' i thm = if i <= Thm.nprems_of thm andalso
   955     Term.exists_Const (fn ("op =", Type (_, [T, _])) => T <> Type ("bool", []) | _ => false)
   956       (nth (Thm.prems_of thm) (i - 1)) then Hypsubst.hyp_subst_tac i thm else no_tac thm;
   957 in
   958   Hypsubst.hypsubst_setup
   959   #> ContextRules.addSWrapper (fn tac => hyp_subst_tac' ORELSE' tac)
   960   #> Classical.setup
   961   #> ResAtpset.setup
   962   #> ResBlacklist.setup
   963 end
   964 *}
   965 
   966 declare iffI [intro!]
   967   and notI [intro!]
   968   and impI [intro!]
   969   and disjCI [intro!]
   970   and conjI [intro!]
   971   and TrueI [intro!]
   972   and refl [intro!]
   973 
   974 declare iffCE [elim!]
   975   and FalseE [elim!]
   976   and impCE [elim!]
   977   and disjE [elim!]
   978   and conjE [elim!]
   979   and conjE [elim!]
   980 
   981 declare ex_ex1I [intro!]
   982   and allI [intro!]
   983   and the_equality [intro]
   984   and exI [intro]
   985 
   986 declare exE [elim!]
   987   allE [elim]
   988 
   989 ML {* val HOL_cs = @{claset} *}
   990 
   991 lemma contrapos_np: "~ Q ==> (~ P ==> Q) ==> P"
   992   apply (erule swap)
   993   apply (erule (1) meta_mp)
   994   done
   995 
   996 declare ex_ex1I [rule del, intro! 2]
   997   and ex1I [intro]
   998 
   999 lemmas [intro?] = ext
  1000   and [elim?] = ex1_implies_ex
  1001 
  1002 (*Better then ex1E for classical reasoner: needs no quantifier duplication!*)
  1003 lemma alt_ex1E [elim!]:
  1004   assumes major: "\<exists>!x. P x"
  1005       and prem: "\<And>x. \<lbrakk> P x; \<forall>y y'. P y \<and> P y' \<longrightarrow> y = y' \<rbrakk> \<Longrightarrow> R"
  1006   shows R
  1007 apply (rule ex1E [OF major])
  1008 apply (rule prem)
  1009 apply (tactic {* ares_tac @{thms allI} 1 *})+
  1010 apply (tactic {* etac (Classical.dup_elim @{thm allE}) 1 *})
  1011 apply iprover
  1012 done
  1013 
  1014 ML {*
  1015 structure Blast = BlastFun(
  1016 struct
  1017   type claset = Classical.claset
  1018   val equality_name = @{const_name "op ="}
  1019   val not_name = @{const_name Not}
  1020   val notE = @{thm HOL.notE}
  1021   val ccontr = @{thm HOL.ccontr}
  1022   val contr_tac = Classical.contr_tac
  1023   val dup_intr = Classical.dup_intr
  1024   val hyp_subst_tac = Hypsubst.blast_hyp_subst_tac
  1025   val claset = Classical.claset
  1026   val rep_cs = Classical.rep_cs
  1027   val cla_modifiers = Classical.cla_modifiers
  1028   val cla_meth' = Classical.cla_meth'
  1029 end);
  1030 val Blast_tac = Blast.Blast_tac;
  1031 val blast_tac = Blast.blast_tac;
  1032 *}
  1033 
  1034 setup Blast.setup
  1035 
  1036 
  1037 subsubsection {* Simplifier *}
  1038 
  1039 lemma eta_contract_eq: "(%s. f s) = f" ..
  1040 
  1041 lemma simp_thms:
  1042   shows not_not: "(~ ~ P) = P"
  1043   and Not_eq_iff: "((~P) = (~Q)) = (P = Q)"
  1044   and
  1045     "(P ~= Q) = (P = (~Q))"
  1046     "(P | ~P) = True"    "(~P | P) = True"
  1047     "(x = x) = True"
  1048   and not_True_eq_False: "(\<not> True) = False"
  1049   and not_False_eq_True: "(\<not> False) = True"
  1050   and
  1051     "(~P) ~= P"  "P ~= (~P)"
  1052     "(True=P) = P"
  1053   and eq_True: "(P = True) = P"
  1054   and "(False=P) = (~P)"
  1055   and eq_False: "(P = False) = (\<not> P)"
  1056   and
  1057     "(True --> P) = P"  "(False --> P) = True"
  1058     "(P --> True) = True"  "(P --> P) = True"
  1059     "(P --> False) = (~P)"  "(P --> ~P) = (~P)"
  1060     "(P & True) = P"  "(True & P) = P"
  1061     "(P & False) = False"  "(False & P) = False"
  1062     "(P & P) = P"  "(P & (P & Q)) = (P & Q)"
  1063     "(P & ~P) = False"    "(~P & P) = False"
  1064     "(P | True) = True"  "(True | P) = True"
  1065     "(P | False) = P"  "(False | P) = P"
  1066     "(P | P) = P"  "(P | (P | Q)) = (P | Q)" and
  1067     "(ALL x. P) = P"  "(EX x. P) = P"  "EX x. x=t"  "EX x. t=x"
  1068     -- {* needed for the one-point-rule quantifier simplification procs *}
  1069     -- {* essential for termination!! *} and
  1070     "!!P. (EX x. x=t & P(x)) = P(t)"
  1071     "!!P. (EX x. t=x & P(x)) = P(t)"
  1072     "!!P. (ALL x. x=t --> P(x)) = P(t)"
  1073     "!!P. (ALL x. t=x --> P(x)) = P(t)"
  1074   by (blast, blast, blast, blast, blast, iprover+)
  1075 
  1076 lemma disj_absorb: "(A | A) = A"
  1077   by blast
  1078 
  1079 lemma disj_left_absorb: "(A | (A | B)) = (A | B)"
  1080   by blast
  1081 
  1082 lemma conj_absorb: "(A & A) = A"
  1083   by blast
  1084 
  1085 lemma conj_left_absorb: "(A & (A & B)) = (A & B)"
  1086   by blast
  1087 
  1088 lemma eq_ac:
  1089   shows eq_commute: "(a=b) = (b=a)"
  1090     and eq_left_commute: "(P=(Q=R)) = (Q=(P=R))"
  1091     and eq_assoc: "((P=Q)=R) = (P=(Q=R))" by (iprover, blast+)
  1092 lemma neq_commute: "(a~=b) = (b~=a)" by iprover
  1093 
  1094 lemma conj_comms:
  1095   shows conj_commute: "(P&Q) = (Q&P)"
  1096     and conj_left_commute: "(P&(Q&R)) = (Q&(P&R))" by iprover+
  1097 lemma conj_assoc: "((P&Q)&R) = (P&(Q&R))" by iprover
  1098 
  1099 lemmas conj_ac = conj_commute conj_left_commute conj_assoc
  1100 
  1101 lemma disj_comms:
  1102   shows disj_commute: "(P|Q) = (Q|P)"
  1103     and disj_left_commute: "(P|(Q|R)) = (Q|(P|R))" by iprover+
  1104 lemma disj_assoc: "((P|Q)|R) = (P|(Q|R))" by iprover
  1105 
  1106 lemmas disj_ac = disj_commute disj_left_commute disj_assoc
  1107 
  1108 lemma conj_disj_distribL: "(P&(Q|R)) = (P&Q | P&R)" by iprover
  1109 lemma conj_disj_distribR: "((P|Q)&R) = (P&R | Q&R)" by iprover
  1110 
  1111 lemma disj_conj_distribL: "(P|(Q&R)) = ((P|Q) & (P|R))" by iprover
  1112 lemma disj_conj_distribR: "((P&Q)|R) = ((P|R) & (Q|R))" by iprover
  1113 
  1114 lemma imp_conjR: "(P --> (Q&R)) = ((P-->Q) & (P-->R))" by iprover
  1115 lemma imp_conjL: "((P&Q) -->R)  = (P --> (Q --> R))" by iprover
  1116 lemma imp_disjL: "((P|Q) --> R) = ((P-->R)&(Q-->R))" by iprover
  1117 
  1118 text {* These two are specialized, but @{text imp_disj_not1} is useful in @{text "Auth/Yahalom"}. *}
  1119 lemma imp_disj_not1: "(P --> Q | R) = (~Q --> P --> R)" by blast
  1120 lemma imp_disj_not2: "(P --> Q | R) = (~R --> P --> Q)" by blast
  1121 
  1122 lemma imp_disj1: "((P-->Q)|R) = (P--> Q|R)" by blast
  1123 lemma imp_disj2: "(Q|(P-->R)) = (P--> Q|R)" by blast
  1124 
  1125 lemma imp_cong: "(P = P') ==> (P' ==> (Q = Q')) ==> ((P --> Q) = (P' --> Q'))"
  1126   by iprover
  1127 
  1128 lemma de_Morgan_disj: "(~(P | Q)) = (~P & ~Q)" by iprover
  1129 lemma de_Morgan_conj: "(~(P & Q)) = (~P | ~Q)" by blast
  1130 lemma not_imp: "(~(P --> Q)) = (P & ~Q)" by blast
  1131 lemma not_iff: "(P~=Q) = (P = (~Q))" by blast
  1132 lemma disj_not1: "(~P | Q) = (P --> Q)" by blast
  1133 lemma disj_not2: "(P | ~Q) = (Q --> P)"  -- {* changes orientation :-( *}
  1134   by blast
  1135 lemma imp_conv_disj: "(P --> Q) = ((~P) | Q)" by blast
  1136 
  1137 lemma iff_conv_conj_imp: "(P = Q) = ((P --> Q) & (Q --> P))" by iprover
  1138 
  1139 
  1140 lemma cases_simp: "((P --> Q) & (~P --> Q)) = Q"
  1141   -- {* Avoids duplication of subgoals after @{text split_if}, when the true and false *}
  1142   -- {* cases boil down to the same thing. *}
  1143   by blast
  1144 
  1145 lemma not_all: "(~ (! x. P(x))) = (? x.~P(x))" by blast
  1146 lemma imp_all: "((! x. P x) --> Q) = (? x. P x --> Q)" by blast
  1147 lemma not_ex: "(~ (? x. P(x))) = (! x.~P(x))" by iprover
  1148 lemma imp_ex: "((? x. P x) --> Q) = (! x. P x --> Q)" by iprover
  1149 lemma all_not_ex: "(ALL x. P x) = (~ (EX x. ~ P x ))" by blast
  1150 
  1151 declare All_def [noatp]
  1152 
  1153 lemma ex_disj_distrib: "(? x. P(x) | Q(x)) = ((? x. P(x)) | (? x. Q(x)))" by iprover
  1154 lemma all_conj_distrib: "(!x. P(x) & Q(x)) = ((! x. P(x)) & (! x. Q(x)))" by iprover
  1155 
  1156 text {*
  1157   \medskip The @{text "&"} congruence rule: not included by default!
  1158   May slow rewrite proofs down by as much as 50\% *}
  1159 
  1160 lemma conj_cong:
  1161     "(P = P') ==> (P' ==> (Q = Q')) ==> ((P & Q) = (P' & Q'))"
  1162   by iprover
  1163 
  1164 lemma rev_conj_cong:
  1165     "(Q = Q') ==> (Q' ==> (P = P')) ==> ((P & Q) = (P' & Q'))"
  1166   by iprover
  1167 
  1168 text {* The @{text "|"} congruence rule: not included by default! *}
  1169 
  1170 lemma disj_cong:
  1171     "(P = P') ==> (~P' ==> (Q = Q')) ==> ((P | Q) = (P' | Q'))"
  1172   by blast
  1173 
  1174 
  1175 text {* \medskip if-then-else rules *}
  1176 
  1177 lemma if_True: "(if True then x else y) = x"
  1178   by (unfold if_def) blast
  1179 
  1180 lemma if_False: "(if False then x else y) = y"
  1181   by (unfold if_def) blast
  1182 
  1183 lemma if_P: "P ==> (if P then x else y) = x"
  1184   by (unfold if_def) blast
  1185 
  1186 lemma if_not_P: "~P ==> (if P then x else y) = y"
  1187   by (unfold if_def) blast
  1188 
  1189 lemma split_if: "P (if Q then x else y) = ((Q --> P(x)) & (~Q --> P(y)))"
  1190   apply (rule case_split [of Q])
  1191    apply (simplesubst if_P)
  1192     prefer 3 apply (simplesubst if_not_P, blast+)
  1193   done
  1194 
  1195 lemma split_if_asm: "P (if Q then x else y) = (~((Q & ~P x) | (~Q & ~P y)))"
  1196 by (simplesubst split_if, blast)
  1197 
  1198 lemmas if_splits [noatp] = split_if split_if_asm
  1199 
  1200 lemma if_cancel: "(if c then x else x) = x"
  1201 by (simplesubst split_if, blast)
  1202 
  1203 lemma if_eq_cancel: "(if x = y then y else x) = x"
  1204 by (simplesubst split_if, blast)
  1205 
  1206 lemma if_bool_eq_conj: "(if P then Q else R) = ((P-->Q) & (~P-->R))"
  1207   -- {* This form is useful for expanding @{text "if"}s on the RIGHT of the @{text "==>"} symbol. *}
  1208   by (rule split_if)
  1209 
  1210 lemma if_bool_eq_disj: "(if P then Q else R) = ((P&Q) | (~P&R))"
  1211   -- {* And this form is useful for expanding @{text "if"}s on the LEFT. *}
  1212   apply (simplesubst split_if, blast)
  1213   done
  1214 
  1215 lemma Eq_TrueI: "P ==> P == True" by (unfold atomize_eq) iprover
  1216 lemma Eq_FalseI: "~P ==> P == False" by (unfold atomize_eq) iprover
  1217 
  1218 text {* \medskip let rules for simproc *}
  1219 
  1220 lemma Let_folded: "f x \<equiv> g x \<Longrightarrow>  Let x f \<equiv> Let x g"
  1221   by (unfold Let_def)
  1222 
  1223 lemma Let_unfold: "f x \<equiv> g \<Longrightarrow>  Let x f \<equiv> g"
  1224   by (unfold Let_def)
  1225 
  1226 text {*
  1227   The following copy of the implication operator is useful for
  1228   fine-tuning congruence rules.  It instructs the simplifier to simplify
  1229   its premise.
  1230 *}
  1231 
  1232 constdefs
  1233   simp_implies :: "[prop, prop] => prop"  (infixr "=simp=>" 1)
  1234   "simp_implies \<equiv> op ==>"
  1235 
  1236 lemma simp_impliesI:
  1237   assumes PQ: "(PROP P \<Longrightarrow> PROP Q)"
  1238   shows "PROP P =simp=> PROP Q"
  1239   apply (unfold simp_implies_def)
  1240   apply (rule PQ)
  1241   apply assumption
  1242   done
  1243 
  1244 lemma simp_impliesE:
  1245   assumes PQ:"PROP P =simp=> PROP Q"
  1246   and P: "PROP P"
  1247   and QR: "PROP Q \<Longrightarrow> PROP R"
  1248   shows "PROP R"
  1249   apply (rule QR)
  1250   apply (rule PQ [unfolded simp_implies_def])
  1251   apply (rule P)
  1252   done
  1253 
  1254 lemma simp_implies_cong:
  1255   assumes PP' :"PROP P == PROP P'"
  1256   and P'QQ': "PROP P' ==> (PROP Q == PROP Q')"
  1257   shows "(PROP P =simp=> PROP Q) == (PROP P' =simp=> PROP Q')"
  1258 proof (unfold simp_implies_def, rule equal_intr_rule)
  1259   assume PQ: "PROP P \<Longrightarrow> PROP Q"
  1260   and P': "PROP P'"
  1261   from PP' [symmetric] and P' have "PROP P"
  1262     by (rule equal_elim_rule1)
  1263   then have "PROP Q" by (rule PQ)
  1264   with P'QQ' [OF P'] show "PROP Q'" by (rule equal_elim_rule1)
  1265 next
  1266   assume P'Q': "PROP P' \<Longrightarrow> PROP Q'"
  1267   and P: "PROP P"
  1268   from PP' and P have P': "PROP P'" by (rule equal_elim_rule1)
  1269   then have "PROP Q'" by (rule P'Q')
  1270   with P'QQ' [OF P', symmetric] show "PROP Q"
  1271     by (rule equal_elim_rule1)
  1272 qed
  1273 
  1274 lemma uncurry:
  1275   assumes "P \<longrightarrow> Q \<longrightarrow> R"
  1276   shows "P \<and> Q \<longrightarrow> R"
  1277   using assms by blast
  1278 
  1279 lemma iff_allI:
  1280   assumes "\<And>x. P x = Q x"
  1281   shows "(\<forall>x. P x) = (\<forall>x. Q x)"
  1282   using assms by blast
  1283 
  1284 lemma iff_exI:
  1285   assumes "\<And>x. P x = Q x"
  1286   shows "(\<exists>x. P x) = (\<exists>x. Q x)"
  1287   using assms by blast
  1288 
  1289 lemma all_comm:
  1290   "(\<forall>x y. P x y) = (\<forall>y x. P x y)"
  1291   by blast
  1292 
  1293 lemma ex_comm:
  1294   "(\<exists>x y. P x y) = (\<exists>y x. P x y)"
  1295   by blast
  1296 
  1297 use "simpdata.ML"
  1298 ML {* open Simpdata *}
  1299 
  1300 setup {*
  1301   Simplifier.method_setup Splitter.split_modifiers
  1302   #> (fn thy => (change_simpset_of thy (fn _ => Simpdata.simpset_simprocs); thy))
  1303   #> Splitter.setup
  1304   #> Clasimp.setup
  1305   #> EqSubst.setup
  1306 *}
  1307 
  1308 text {* Simproc for proving @{text "(y = x) == False"} from premise @{text "~(x = y)"}: *}
  1309 
  1310 simproc_setup neq ("x = y") = {* fn _ =>
  1311 let
  1312   val neq_to_EQ_False = @{thm not_sym} RS @{thm Eq_FalseI};
  1313   fun is_neq eq lhs rhs thm =
  1314     (case Thm.prop_of thm of
  1315       _ $ (Not $ (eq' $ l' $ r')) =>
  1316         Not = HOLogic.Not andalso eq' = eq andalso
  1317         r' aconv lhs andalso l' aconv rhs
  1318     | _ => false);
  1319   fun proc ss ct =
  1320     (case Thm.term_of ct of
  1321       eq $ lhs $ rhs =>
  1322         (case find_first (is_neq eq lhs rhs) (Simplifier.prems_of_ss ss) of
  1323           SOME thm => SOME (thm RS neq_to_EQ_False)
  1324         | NONE => NONE)
  1325      | _ => NONE);
  1326 in proc end;
  1327 *}
  1328 
  1329 simproc_setup let_simp ("Let x f") = {*
  1330 let
  1331   val (f_Let_unfold, x_Let_unfold) =
  1332     let val [(_$(f$x)$_)] = prems_of @{thm Let_unfold}
  1333     in (cterm_of @{theory} f, cterm_of @{theory} x) end
  1334   val (f_Let_folded, x_Let_folded) =
  1335     let val [(_$(f$x)$_)] = prems_of @{thm Let_folded}
  1336     in (cterm_of @{theory} f, cterm_of @{theory} x) end;
  1337   val g_Let_folded =
  1338     let val [(_$_$(g$_))] = prems_of @{thm Let_folded} in cterm_of @{theory} g end;
  1339 
  1340   fun proc _ ss ct =
  1341     let
  1342       val ctxt = Simplifier.the_context ss;
  1343       val thy = ProofContext.theory_of ctxt;
  1344       val t = Thm.term_of ct;
  1345       val ([t'], ctxt') = Variable.import_terms false [t] ctxt;
  1346     in Option.map (hd o Variable.export ctxt' ctxt o single)
  1347       (case t' of Const ("Let",_) $ x $ f => (* x and f are already in normal form *)
  1348         if is_Free x orelse is_Bound x orelse is_Const x
  1349         then SOME @{thm Let_def}
  1350         else
  1351           let
  1352             val n = case f of (Abs (x,_,_)) => x | _ => "x";
  1353             val cx = cterm_of thy x;
  1354             val {T=xT,...} = rep_cterm cx;
  1355             val cf = cterm_of thy f;
  1356             val fx_g = Simplifier.rewrite ss (Thm.capply cf cx);
  1357             val (_$_$g) = prop_of fx_g;
  1358             val g' = abstract_over (x,g);
  1359           in (if (g aconv g')
  1360                then
  1361                   let
  1362                     val rl =
  1363                       cterm_instantiate [(f_Let_unfold,cf),(x_Let_unfold,cx)] @{thm Let_unfold};
  1364                   in SOME (rl OF [fx_g]) end
  1365                else if Term.betapply (f,x) aconv g then NONE (*avoid identity conversion*)
  1366                else let
  1367                      val abs_g'= Abs (n,xT,g');
  1368                      val g'x = abs_g'$x;
  1369                      val g_g'x = symmetric (beta_conversion false (cterm_of thy g'x));
  1370                      val rl = cterm_instantiate
  1371                                [(f_Let_folded,cterm_of thy f),(x_Let_folded,cx),
  1372                                 (g_Let_folded,cterm_of thy abs_g')]
  1373                                @{thm Let_folded};
  1374                    in SOME (rl OF [transitive fx_g g_g'x])
  1375                    end)
  1376           end
  1377       | _ => NONE)
  1378     end
  1379 in proc end *}
  1380 
  1381 
  1382 lemma True_implies_equals: "(True \<Longrightarrow> PROP P) \<equiv> PROP P"
  1383 proof
  1384   assume "True \<Longrightarrow> PROP P"
  1385   from this [OF TrueI] show "PROP P" .
  1386 next
  1387   assume "PROP P"
  1388   then show "PROP P" .
  1389 qed
  1390 
  1391 lemma ex_simps:
  1392   "!!P Q. (EX x. P x & Q)   = ((EX x. P x) & Q)"
  1393   "!!P Q. (EX x. P & Q x)   = (P & (EX x. Q x))"
  1394   "!!P Q. (EX x. P x | Q)   = ((EX x. P x) | Q)"
  1395   "!!P Q. (EX x. P | Q x)   = (P | (EX x. Q x))"
  1396   "!!P Q. (EX x. P x --> Q) = ((ALL x. P x) --> Q)"
  1397   "!!P Q. (EX x. P --> Q x) = (P --> (EX x. Q x))"
  1398   -- {* Miniscoping: pushing in existential quantifiers. *}
  1399   by (iprover | blast)+
  1400 
  1401 lemma all_simps:
  1402   "!!P Q. (ALL x. P x & Q)   = ((ALL x. P x) & Q)"
  1403   "!!P Q. (ALL x. P & Q x)   = (P & (ALL x. Q x))"
  1404   "!!P Q. (ALL x. P x | Q)   = ((ALL x. P x) | Q)"
  1405   "!!P Q. (ALL x. P | Q x)   = (P | (ALL x. Q x))"
  1406   "!!P Q. (ALL x. P x --> Q) = ((EX x. P x) --> Q)"
  1407   "!!P Q. (ALL x. P --> Q x) = (P --> (ALL x. Q x))"
  1408   -- {* Miniscoping: pushing in universal quantifiers. *}
  1409   by (iprover | blast)+
  1410 
  1411 lemmas [simp] =
  1412   triv_forall_equality (*prunes params*)
  1413   True_implies_equals  (*prune asms `True'*)
  1414   if_True
  1415   if_False
  1416   if_cancel
  1417   if_eq_cancel
  1418   imp_disjL
  1419   (*In general it seems wrong to add distributive laws by default: they
  1420     might cause exponential blow-up.  But imp_disjL has been in for a while
  1421     and cannot be removed without affecting existing proofs.  Moreover,
  1422     rewriting by "(P|Q --> R) = ((P-->R)&(Q-->R))" might be justified on the
  1423     grounds that it allows simplification of R in the two cases.*)
  1424   conj_assoc
  1425   disj_assoc
  1426   de_Morgan_conj
  1427   de_Morgan_disj
  1428   imp_disj1
  1429   imp_disj2
  1430   not_imp
  1431   disj_not1
  1432   not_all
  1433   not_ex
  1434   cases_simp
  1435   the_eq_trivial
  1436   the_sym_eq_trivial
  1437   ex_simps
  1438   all_simps
  1439   simp_thms
  1440 
  1441 lemmas [cong] = imp_cong simp_implies_cong
  1442 lemmas [split] = split_if
  1443 
  1444 ML {* val HOL_ss = @{simpset} *}
  1445 
  1446 text {* Simplifies x assuming c and y assuming ~c *}
  1447 lemma if_cong:
  1448   assumes "b = c"
  1449       and "c \<Longrightarrow> x = u"
  1450       and "\<not> c \<Longrightarrow> y = v"
  1451   shows "(if b then x else y) = (if c then u else v)"
  1452   unfolding if_def using assms by simp
  1453 
  1454 text {* Prevents simplification of x and y:
  1455   faster and allows the execution of functional programs. *}
  1456 lemma if_weak_cong [cong]:
  1457   assumes "b = c"
  1458   shows "(if b then x else y) = (if c then x else y)"
  1459   using assms by (rule arg_cong)
  1460 
  1461 text {* Prevents simplification of t: much faster *}
  1462 lemma let_weak_cong:
  1463   assumes "a = b"
  1464   shows "(let x = a in t x) = (let x = b in t x)"
  1465   using assms by (rule arg_cong)
  1466 
  1467 text {* To tidy up the result of a simproc.  Only the RHS will be simplified. *}
  1468 lemma eq_cong2:
  1469   assumes "u = u'"
  1470   shows "(t \<equiv> u) \<equiv> (t \<equiv> u')"
  1471   using assms by simp
  1472 
  1473 lemma if_distrib:
  1474   "f (if c then x else y) = (if c then f x else f y)"
  1475   by simp
  1476 
  1477 text {* This lemma restricts the effect of the rewrite rule u=v to the left-hand
  1478   side of an equality.  Used in @{text "{Integ,Real}/simproc.ML"} *}
  1479 lemma restrict_to_left:
  1480   assumes "x = y"
  1481   shows "(x = z) = (y = z)"
  1482   using assms by simp
  1483 
  1484 
  1485 subsubsection {* Generic cases and induction *}
  1486 
  1487 text {* Rule projections: *}
  1488 
  1489 ML {*
  1490 structure ProjectRule = ProjectRuleFun
  1491 (struct
  1492   val conjunct1 = @{thm conjunct1};
  1493   val conjunct2 = @{thm conjunct2};
  1494   val mp = @{thm mp};
  1495 end)
  1496 *}
  1497 
  1498 constdefs
  1499   induct_forall where "induct_forall P == \<forall>x. P x"
  1500   induct_implies where "induct_implies A B == A \<longrightarrow> B"
  1501   induct_equal where "induct_equal x y == x = y"
  1502   induct_conj where "induct_conj A B == A \<and> B"
  1503 
  1504 lemma induct_forall_eq: "(!!x. P x) == Trueprop (induct_forall (\<lambda>x. P x))"
  1505   by (unfold atomize_all induct_forall_def)
  1506 
  1507 lemma induct_implies_eq: "(A ==> B) == Trueprop (induct_implies A B)"
  1508   by (unfold atomize_imp induct_implies_def)
  1509 
  1510 lemma induct_equal_eq: "(x == y) == Trueprop (induct_equal x y)"
  1511   by (unfold atomize_eq induct_equal_def)
  1512 
  1513 lemma induct_conj_eq:
  1514   includes meta_conjunction_syntax
  1515   shows "(A && B) == Trueprop (induct_conj A B)"
  1516   by (unfold atomize_conj induct_conj_def)
  1517 
  1518 lemmas induct_atomize = induct_forall_eq induct_implies_eq induct_equal_eq induct_conj_eq
  1519 lemmas induct_rulify [symmetric, standard] = induct_atomize
  1520 lemmas induct_rulify_fallback =
  1521   induct_forall_def induct_implies_def induct_equal_def induct_conj_def
  1522 
  1523 
  1524 lemma induct_forall_conj: "induct_forall (\<lambda>x. induct_conj (A x) (B x)) =
  1525     induct_conj (induct_forall A) (induct_forall B)"
  1526   by (unfold induct_forall_def induct_conj_def) iprover
  1527 
  1528 lemma induct_implies_conj: "induct_implies C (induct_conj A B) =
  1529     induct_conj (induct_implies C A) (induct_implies C B)"
  1530   by (unfold induct_implies_def induct_conj_def) iprover
  1531 
  1532 lemma induct_conj_curry: "(induct_conj A B ==> PROP C) == (A ==> B ==> PROP C)"
  1533 proof
  1534   assume r: "induct_conj A B ==> PROP C" and A B
  1535   show "PROP C" by (rule r) (simp add: induct_conj_def `A` `B`)
  1536 next
  1537   assume r: "A ==> B ==> PROP C" and "induct_conj A B"
  1538   show "PROP C" by (rule r) (simp_all add: `induct_conj A B` [unfolded induct_conj_def])
  1539 qed
  1540 
  1541 lemmas induct_conj = induct_forall_conj induct_implies_conj induct_conj_curry
  1542 
  1543 hide const induct_forall induct_implies induct_equal induct_conj
  1544 
  1545 text {* Method setup. *}
  1546 
  1547 ML {*
  1548   structure InductMethod = InductMethodFun
  1549   (struct
  1550     val cases_default = @{thm case_split}
  1551     val atomize = @{thms induct_atomize}
  1552     val rulify = @{thms induct_rulify}
  1553     val rulify_fallback = @{thms induct_rulify_fallback}
  1554   end);
  1555 *}
  1556 
  1557 setup InductMethod.setup
  1558 
  1559 
  1560 
  1561 subsection {* Other simple lemmas and lemma duplicates *}
  1562 
  1563 lemma Let_0 [simp]: "Let 0 f = f 0"
  1564   unfolding Let_def ..
  1565 
  1566 lemma Let_1 [simp]: "Let 1 f = f 1"
  1567   unfolding Let_def ..
  1568 
  1569 lemma ex1_eq [iff]: "EX! x. x = t" "EX! x. t = x"
  1570   by blast+
  1571 
  1572 lemma choice_eq: "(ALL x. EX! y. P x y) = (EX! f. ALL x. P x (f x))"
  1573   apply (rule iffI)
  1574   apply (rule_tac a = "%x. THE y. P x y" in ex1I)
  1575   apply (fast dest!: theI')
  1576   apply (fast intro: ext the1_equality [symmetric])
  1577   apply (erule ex1E)
  1578   apply (rule allI)
  1579   apply (rule ex1I)
  1580   apply (erule spec)
  1581   apply (erule_tac x = "%z. if z = x then y else f z" in allE)
  1582   apply (erule impE)
  1583   apply (rule allI)
  1584   apply (rule_tac P = "xa = x" in case_split_thm)
  1585   apply (drule_tac [3] x = x in fun_cong, simp_all)
  1586   done
  1587 
  1588 lemma mk_left_commute:
  1589   fixes f (infix "\<otimes>" 60)
  1590   assumes a: "\<And>x y z. (x \<otimes> y) \<otimes> z = x \<otimes> (y \<otimes> z)" and
  1591           c: "\<And>x y. x \<otimes> y = y \<otimes> x"
  1592   shows "x \<otimes> (y \<otimes> z) = y \<otimes> (x \<otimes> z)"
  1593   by (rule trans [OF trans [OF c a] arg_cong [OF c, of "f y"]])
  1594 
  1595 lemmas eq_sym_conv = eq_commute
  1596 
  1597 lemma nnf_simps:
  1598   "(\<not>(P \<and> Q)) = (\<not> P \<or> \<not> Q)" "(\<not> (P \<or> Q)) = (\<not> P \<and> \<not>Q)" "(P \<longrightarrow> Q) = (\<not>P \<or> Q)" 
  1599   "(P = Q) = ((P \<and> Q) \<or> (\<not>P \<and> \<not> Q))" "(\<not>(P = Q)) = ((P \<and> \<not> Q) \<or> (\<not>P \<and> Q))" 
  1600   "(\<not> \<not>(P)) = P"
  1601 by blast+
  1602 
  1603 
  1604 subsection {* Basic ML bindings *}
  1605 
  1606 ML {*
  1607 val FalseE = @{thm FalseE}
  1608 val Let_def = @{thm Let_def}
  1609 val TrueI = @{thm TrueI}
  1610 val allE = @{thm allE}
  1611 val allI = @{thm allI}
  1612 val all_dupE = @{thm all_dupE}
  1613 val arg_cong = @{thm arg_cong}
  1614 val box_equals = @{thm box_equals}
  1615 val ccontr = @{thm ccontr}
  1616 val classical = @{thm classical}
  1617 val conjE = @{thm conjE}
  1618 val conjI = @{thm conjI}
  1619 val conjunct1 = @{thm conjunct1}
  1620 val conjunct2 = @{thm conjunct2}
  1621 val disjCI = @{thm disjCI}
  1622 val disjE = @{thm disjE}
  1623 val disjI1 = @{thm disjI1}
  1624 val disjI2 = @{thm disjI2}
  1625 val eq_reflection = @{thm eq_reflection}
  1626 val ex1E = @{thm ex1E}
  1627 val ex1I = @{thm ex1I}
  1628 val ex1_implies_ex = @{thm ex1_implies_ex}
  1629 val exE = @{thm exE}
  1630 val exI = @{thm exI}
  1631 val excluded_middle = @{thm excluded_middle}
  1632 val ext = @{thm ext}
  1633 val fun_cong = @{thm fun_cong}
  1634 val iffD1 = @{thm iffD1}
  1635 val iffD2 = @{thm iffD2}
  1636 val iffI = @{thm iffI}
  1637 val impE = @{thm impE}
  1638 val impI = @{thm impI}
  1639 val meta_eq_to_obj_eq = @{thm meta_eq_to_obj_eq}
  1640 val mp = @{thm mp}
  1641 val notE = @{thm notE}
  1642 val notI = @{thm notI}
  1643 val not_all = @{thm not_all}
  1644 val not_ex = @{thm not_ex}
  1645 val not_iff = @{thm not_iff}
  1646 val not_not = @{thm not_not}
  1647 val not_sym = @{thm not_sym}
  1648 val refl = @{thm refl}
  1649 val rev_mp = @{thm rev_mp}
  1650 val spec = @{thm spec}
  1651 val ssubst = @{thm ssubst}
  1652 val subst = @{thm subst}
  1653 val sym = @{thm sym}
  1654 val trans = @{thm trans}
  1655 *}
  1656 
  1657 
  1658 subsection {* Code generator basic setup -- see further @{text Code_Setup.thy} *}
  1659 
  1660 setup "CodeName.setup #> CodeTarget.setup #> Nbe.setup"
  1661 
  1662 class eq (attach "op =") = type
  1663 
  1664 code_datatype True False
  1665 
  1666 lemma [code func]:
  1667   shows "False \<and> x \<longleftrightarrow> False"
  1668     and "True \<and> x \<longleftrightarrow> x"
  1669     and "x \<and> False \<longleftrightarrow> False"
  1670     and "x \<and> True \<longleftrightarrow> x" by simp_all
  1671 
  1672 lemma [code func]:
  1673   shows "False \<or> x \<longleftrightarrow> x"
  1674     and "True \<or> x \<longleftrightarrow> True"
  1675     and "x \<or> False \<longleftrightarrow> x"
  1676     and "x \<or> True \<longleftrightarrow> True" by simp_all
  1677 
  1678 lemma [code func]:
  1679   shows "\<not> True \<longleftrightarrow> False"
  1680     and "\<not> False \<longleftrightarrow> True" by (rule HOL.simp_thms)+
  1681 
  1682 instance bool :: eq ..
  1683 
  1684 lemma [code func]:
  1685   shows "False = P \<longleftrightarrow> \<not> P"
  1686     and "True = P \<longleftrightarrow> P" 
  1687     and "P = False \<longleftrightarrow> \<not> P" 
  1688     and "P = True \<longleftrightarrow> P" by simp_all
  1689 
  1690 code_datatype Trueprop "prop"
  1691 
  1692 code_datatype "TYPE('a)"
  1693 
  1694 
  1695 subsection {* Legacy tactics and ML bindings *}
  1696 
  1697 ML {*
  1698 fun strip_tac i = REPEAT (resolve_tac [impI, allI] i);
  1699 
  1700 (* combination of (spec RS spec RS ...(j times) ... spec RS mp) *)
  1701 local
  1702   fun wrong_prem (Const ("All", _) $ (Abs (_, _, t))) = wrong_prem t
  1703     | wrong_prem (Bound _) = true
  1704     | wrong_prem _ = false;
  1705   val filter_right = filter (not o wrong_prem o HOLogic.dest_Trueprop o hd o Thm.prems_of);
  1706 in
  1707   fun smp i = funpow i (fn m => filter_right ([spec] RL m)) ([mp]);
  1708   fun smp_tac j = EVERY'[dresolve_tac (smp j), atac];
  1709 end;
  1710 
  1711 val all_conj_distrib = thm "all_conj_distrib";
  1712 val all_simps = thms "all_simps";
  1713 val atomize_not = thm "atomize_not";
  1714 val case_split = thm "case_split_thm";
  1715 val case_split_thm = thm "case_split_thm"
  1716 val cases_simp = thm "cases_simp";
  1717 val choice_eq = thm "choice_eq"
  1718 val cong = thm "cong"
  1719 val conj_comms = thms "conj_comms";
  1720 val conj_cong = thm "conj_cong";
  1721 val de_Morgan_conj = thm "de_Morgan_conj";
  1722 val de_Morgan_disj = thm "de_Morgan_disj";
  1723 val disj_assoc = thm "disj_assoc";
  1724 val disj_comms = thms "disj_comms";
  1725 val disj_cong = thm "disj_cong";
  1726 val eq_ac = thms "eq_ac";
  1727 val eq_cong2 = thm "eq_cong2"
  1728 val Eq_FalseI = thm "Eq_FalseI";
  1729 val Eq_TrueI = thm "Eq_TrueI";
  1730 val Ex1_def = thm "Ex1_def"
  1731 val ex_disj_distrib = thm "ex_disj_distrib";
  1732 val ex_simps = thms "ex_simps";
  1733 val if_cancel = thm "if_cancel";
  1734 val if_eq_cancel = thm "if_eq_cancel";
  1735 val if_False = thm "if_False";
  1736 val iff_conv_conj_imp = thm "iff_conv_conj_imp";
  1737 val iff = thm "iff"
  1738 val if_splits = thms "if_splits";
  1739 val if_True = thm "if_True";
  1740 val if_weak_cong = thm "if_weak_cong"
  1741 val imp_all = thm "imp_all";
  1742 val imp_cong = thm "imp_cong";
  1743 val imp_conjL = thm "imp_conjL";
  1744 val imp_conjR = thm "imp_conjR";
  1745 val imp_conv_disj = thm "imp_conv_disj";
  1746 val simp_implies_def = thm "simp_implies_def";
  1747 val simp_thms = thms "simp_thms";
  1748 val split_if = thm "split_if";
  1749 val the1_equality = thm "the1_equality"
  1750 val theI = thm "theI"
  1751 val theI' = thm "theI'"
  1752 val True_implies_equals = thm "True_implies_equals";
  1753 val nnf_conv = Simplifier.rewrite (HOL_basic_ss addsimps simp_thms @ @{thms "nnf_simps"})
  1754 
  1755 *}
  1756 
  1757 end