src/HOL/OrderedGroup.thy
author haftmann
Wed Sep 26 20:27:55 2007 +0200 (2007-09-26)
changeset 24728 e2b3a1065676
parent 24380 c215e256beca
child 24748 ee0a0eb6b738
permissions -rw-r--r--
moved Finite_Set before Datatype
     1 (*  Title:   HOL/OrderedGroup.thy
     2     ID:      $Id$
     3     Author:  Gertrud Bauer, Steven Obua, Lawrence C Paulson, and Markus Wenzel,
     4              with contributions by Jeremy Avigad
     5 *)
     6 
     7 header {* Ordered Groups *}
     8 
     9 theory OrderedGroup
    10 imports Lattices
    11 uses "~~/src/Provers/Arith/abel_cancel.ML"
    12 begin
    13 
    14 text {*
    15   The theory of partially ordered groups is taken from the books:
    16   \begin{itemize}
    17   \item \emph{Lattice Theory} by Garret Birkhoff, American Mathematical Society 1979 
    18   \item \emph{Partially Ordered Algebraic Systems}, Pergamon Press 1963
    19   \end{itemize}
    20   Most of the used notions can also be looked up in 
    21   \begin{itemize}
    22   \item \url{http://www.mathworld.com} by Eric Weisstein et. al.
    23   \item \emph{Algebra I} by van der Waerden, Springer.
    24   \end{itemize}
    25 *}
    26 
    27 subsection {* Semigroups and Monoids *}
    28 
    29 class semigroup_add = plus +
    30   assumes add_assoc: "(a \<^loc>+ b) \<^loc>+ c = a \<^loc>+ (b \<^loc>+ c)"
    31 
    32 class ab_semigroup_add = semigroup_add +
    33   assumes add_commute: "a \<^loc>+ b = b \<^loc>+ a"
    34 
    35 lemma add_left_commute: "a + (b + c) = b + (a + (c::'a::ab_semigroup_add))"
    36   by (rule mk_left_commute [of "op +", OF add_assoc add_commute])
    37 
    38 theorems add_ac = add_assoc add_commute add_left_commute
    39 
    40 class semigroup_mult = times +
    41   assumes mult_assoc: "(a \<^loc>* b) \<^loc>* c = a \<^loc>* (b \<^loc>* c)"
    42 
    43 class ab_semigroup_mult = semigroup_mult +
    44   assumes mult_commute: "a \<^loc>* b = b \<^loc>* a"
    45 begin
    46 
    47 lemma mult_left_commute: "a \<^loc>* (b \<^loc>* c) = b \<^loc>* (a \<^loc>* c)"
    48   by (rule mk_left_commute [of "op \<^loc>*", OF mult_assoc mult_commute])
    49 
    50 end
    51 
    52 theorems mult_ac = mult_assoc mult_commute mult_left_commute
    53 
    54 class monoid_add = zero + semigroup_add +
    55   assumes add_0_left [simp]: "\<^loc>0 \<^loc>+ a = a" and add_0_right [simp]: "a \<^loc>+ \<^loc>0 = a"
    56 
    57 class comm_monoid_add = zero + ab_semigroup_add +
    58   assumes add_0: "\<^loc>0 \<^loc>+ a = a"
    59 
    60 instance comm_monoid_add < monoid_add
    61 by intro_classes (insert comm_monoid_add_class.zero_plus.add_0, simp_all add: add_commute, auto)
    62 
    63 class monoid_mult = one + semigroup_mult +
    64   assumes mult_1_left [simp]: "\<^loc>1 \<^loc>* a  = a"
    65   assumes mult_1_right [simp]: "a \<^loc>* \<^loc>1 = a"
    66 
    67 class comm_monoid_mult = one + ab_semigroup_mult +
    68   assumes mult_1: "\<^loc>1 \<^loc>* a = a"
    69 
    70 instance comm_monoid_mult \<subseteq> monoid_mult
    71   by intro_classes (insert mult_1, simp_all add: mult_commute, auto)
    72 
    73 class cancel_semigroup_add = semigroup_add +
    74   assumes add_left_imp_eq: "a \<^loc>+ b = a \<^loc>+ c \<Longrightarrow> b = c"
    75   assumes add_right_imp_eq: "b \<^loc>+ a = c \<^loc>+ a \<Longrightarrow> b = c"
    76 
    77 class cancel_ab_semigroup_add = ab_semigroup_add +
    78   assumes add_imp_eq: "a \<^loc>+ b = a \<^loc>+ c \<Longrightarrow> b = c"
    79 
    80 instance cancel_ab_semigroup_add \<subseteq> cancel_semigroup_add
    81 proof intro_classes
    82   fix a b c :: 'a
    83   assume "a + b = a + c" 
    84   then show "b = c" by (rule add_imp_eq)
    85 next
    86   fix a b c :: 'a
    87   assume "b + a = c + a"
    88   then have "a + b = a + c" by (simp only: add_commute)
    89   then show "b = c" by (rule add_imp_eq)
    90 qed
    91 
    92 lemma add_left_cancel [simp]:
    93   "a + b = a + c \<longleftrightarrow> b = (c \<Colon> 'a\<Colon>cancel_semigroup_add)"
    94   by (blast dest: add_left_imp_eq)
    95 
    96 lemma add_right_cancel [simp]:
    97   "b + a = c + a \<longleftrightarrow> b = (c \<Colon> 'a\<Colon>cancel_semigroup_add)"
    98   by (blast dest: add_right_imp_eq)
    99 
   100 subsection {* Groups *}
   101 
   102 class ab_group_add = minus + comm_monoid_add +
   103   assumes ab_left_minus: "uminus a \<^loc>+ a = \<^loc>0"
   104   assumes ab_diff_minus: "a \<^loc>- b = a \<^loc>+ (uminus b)"
   105 
   106 class group_add = minus + monoid_add +
   107   assumes left_minus [simp]: "uminus a \<^loc>+ a = \<^loc>0"
   108   assumes diff_minus: "a \<^loc>- b = a \<^loc>+ (uminus b)"
   109 
   110 instance ab_group_add < group_add
   111 by intro_classes (simp_all add: ab_left_minus ab_diff_minus)
   112 
   113 instance ab_group_add \<subseteq> cancel_ab_semigroup_add
   114 proof intro_classes
   115   fix a b c :: 'a
   116   assume "a + b = a + c"
   117   then have "uminus a + a + b = uminus a + a + c" unfolding add_assoc by simp
   118   then show "b = c" by simp
   119 qed
   120 
   121 lemma minus_add_cancel: "-(a::'a::group_add) + (a+b) = b"
   122 by(simp add:add_assoc[symmetric])
   123 
   124 lemma minus_zero[simp]: "-(0::'a::group_add) = 0"
   125 proof -
   126   have "-(0::'a::group_add) = - 0 + (0+0)" by(simp only: add_0_right)
   127   also have "\<dots> = 0" by(rule minus_add_cancel)
   128   finally show ?thesis .
   129 qed
   130 
   131 lemma minus_minus[simp]: "- (-(a::'a::group_add)) = a"
   132 proof -
   133   have "-(-a) = -(-a) + (-a + a)" by simp
   134   also have "\<dots> = a" by(rule minus_add_cancel)
   135   finally show ?thesis .
   136 qed
   137 
   138 lemma right_minus[simp]: "a + - a = (0::'a::group_add)"
   139 proof -
   140   have "a + -a = -(-a) + -a" by simp
   141   also have "\<dots> = 0" thm group_add.left_minus by(rule left_minus)
   142   finally show ?thesis .
   143 qed
   144 
   145 lemma right_minus_eq: "(a - b = 0) = (a = (b::'a::group_add))"
   146 proof
   147   assume "a - b = 0"
   148   have "a = (a - b) + b" by (simp add:diff_minus add_assoc)
   149   also have "\<dots> = b" using `a - b = 0` by simp
   150   finally show "a = b" .
   151 next
   152   assume "a = b" thus "a - b = 0" by (simp add: diff_minus)
   153 qed
   154 
   155 lemma equals_zero_I: assumes "a+b = 0" shows "-a = (b::'a::group_add)"
   156 proof -
   157   have "- a = -a + (a+b)" using assms by simp
   158   also have "\<dots> = b" by(simp add:add_assoc[symmetric])
   159   finally show ?thesis .
   160 qed
   161 
   162 lemma diff_self[simp]: "(a::'a::group_add) - a = 0"
   163 by(simp add: diff_minus)
   164 
   165 lemma diff_0 [simp]: "(0::'a::group_add) - a = -a"
   166 by (simp add: diff_minus)
   167 
   168 lemma diff_0_right [simp]: "a - (0::'a::group_add) = a" 
   169 by (simp add: diff_minus)
   170 
   171 lemma diff_minus_eq_add [simp]: "a - - b = a + (b::'a::group_add)"
   172 by (simp add: diff_minus)
   173 
   174 lemma uminus_add_conv_diff: "-a + b = b - (a::'a::ab_group_add)"
   175 by(simp add:diff_minus add_commute)
   176 
   177 lemma neg_equal_iff_equal [simp]: "(-a = -b) = (a = (b::'a::group_add))" 
   178 proof 
   179   assume "- a = - b"
   180   hence "- (- a) = - (- b)"
   181     by simp
   182   thus "a=b" by simp
   183 next
   184   assume "a=b"
   185   thus "-a = -b" by simp
   186 qed
   187 
   188 lemma neg_equal_0_iff_equal [simp]: "(-a = 0) = (a = (0::'a::group_add))"
   189 by (subst neg_equal_iff_equal [symmetric], simp)
   190 
   191 lemma neg_0_equal_iff_equal [simp]: "(0 = -a) = (0 = (a::'a::group_add))"
   192 by (subst neg_equal_iff_equal [symmetric], simp)
   193 
   194 text{*The next two equations can make the simplifier loop!*}
   195 
   196 lemma equation_minus_iff: "(a = - b) = (b = - (a::'a::group_add))"
   197 proof -
   198   have "(- (-a) = - b) = (- a = b)" by (rule neg_equal_iff_equal)
   199   thus ?thesis by (simp add: eq_commute)
   200 qed
   201 
   202 lemma minus_equation_iff: "(- a = b) = (- (b::'a::group_add) = a)"
   203 proof -
   204   have "(- a = - (-b)) = (a = -b)" by (rule neg_equal_iff_equal)
   205   thus ?thesis by (simp add: eq_commute)
   206 qed
   207 
   208 lemma minus_add_distrib [simp]: "- (a + b) = -a + -(b::'a::ab_group_add)"
   209 apply (rule equals_zero_I)
   210 apply (simp add: add_ac)
   211 done
   212 
   213 lemma minus_diff_eq [simp]: "- (a - b) = b - (a::'a::ab_group_add)"
   214 by (simp add: diff_minus add_commute)
   215 
   216 subsection {* (Partially) Ordered Groups *} 
   217 
   218 class pordered_ab_semigroup_add = order + ab_semigroup_add +
   219   assumes add_left_mono: "a \<sqsubseteq> b \<Longrightarrow> c \<^loc>+ a \<sqsubseteq> c \<^loc>+ b"
   220 
   221 class pordered_cancel_ab_semigroup_add =
   222   pordered_ab_semigroup_add + cancel_ab_semigroup_add
   223 
   224 class pordered_ab_semigroup_add_imp_le = pordered_cancel_ab_semigroup_add +
   225   assumes add_le_imp_le_left: "c \<^loc>+ a \<sqsubseteq> c \<^loc>+ b \<Longrightarrow> a \<sqsubseteq> b"
   226 
   227 class pordered_ab_group_add = ab_group_add + pordered_ab_semigroup_add
   228 
   229 instance pordered_ab_group_add \<subseteq> pordered_ab_semigroup_add_imp_le
   230 proof
   231   fix a b c :: 'a
   232   assume "c + a \<le> c + b"
   233   hence "(-c) + (c + a) \<le> (-c) + (c + b)" by (rule add_left_mono)
   234   hence "((-c) + c) + a \<le> ((-c) + c) + b" by (simp only: add_assoc)
   235   thus "a \<le> b" by simp
   236 qed
   237 
   238 class ordered_ab_semigroup_add =
   239   linorder + pordered_ab_semigroup_add
   240 
   241 class ordered_cancel_ab_semigroup_add =
   242   linorder + pordered_cancel_ab_semigroup_add
   243 
   244 instance ordered_cancel_ab_semigroup_add \<subseteq> ordered_ab_semigroup_add ..
   245 
   246 instance ordered_cancel_ab_semigroup_add \<subseteq> pordered_ab_semigroup_add_imp_le
   247 proof
   248   fix a b c :: 'a
   249   assume le: "c + a <= c + b"  
   250   show "a <= b"
   251   proof (rule ccontr)
   252     assume w: "~ a \<le> b"
   253     hence "b <= a" by (simp add: linorder_not_le)
   254     hence le2: "c+b <= c+a" by (rule add_left_mono)
   255     have "a = b" 
   256       apply (insert le)
   257       apply (insert le2)
   258       apply (drule order_antisym, simp_all)
   259       done
   260     with w  show False 
   261       by (simp add: linorder_not_le [symmetric])
   262   qed
   263 qed
   264 
   265 lemma add_right_mono: "a \<le> (b::'a::pordered_ab_semigroup_add) ==> a + c \<le> b + c"
   266   by (simp add: add_commute [of _ c] add_left_mono)
   267 
   268 text {* non-strict, in both arguments *}
   269 lemma add_mono:
   270      "[|a \<le> b;  c \<le> d|] ==> a + c \<le> b + (d::'a::pordered_ab_semigroup_add)"
   271   apply (erule add_right_mono [THEN order_trans])
   272   apply (simp add: add_commute add_left_mono)
   273   done
   274 
   275 lemma add_strict_left_mono:
   276      "a < b ==> c + a < c + (b::'a::pordered_cancel_ab_semigroup_add)"
   277  by (simp add: order_less_le add_left_mono) 
   278 
   279 lemma add_strict_right_mono:
   280      "a < b ==> a + c < b + (c::'a::pordered_cancel_ab_semigroup_add)"
   281  by (simp add: add_commute [of _ c] add_strict_left_mono)
   282 
   283 text{*Strict monotonicity in both arguments*}
   284 lemma add_strict_mono: "[|a<b; c<d|] ==> a + c < b + (d::'a::pordered_cancel_ab_semigroup_add)"
   285 apply (erule add_strict_right_mono [THEN order_less_trans])
   286 apply (erule add_strict_left_mono)
   287 done
   288 
   289 lemma add_less_le_mono:
   290      "[| a<b; c\<le>d |] ==> a + c < b + (d::'a::pordered_cancel_ab_semigroup_add)"
   291 apply (erule add_strict_right_mono [THEN order_less_le_trans])
   292 apply (erule add_left_mono) 
   293 done
   294 
   295 lemma add_le_less_mono:
   296      "[| a\<le>b; c<d |] ==> a + c < b + (d::'a::pordered_cancel_ab_semigroup_add)"
   297 apply (erule add_right_mono [THEN order_le_less_trans])
   298 apply (erule add_strict_left_mono) 
   299 done
   300 
   301 lemma add_less_imp_less_left:
   302       assumes less: "c + a < c + b"  shows "a < (b::'a::pordered_ab_semigroup_add_imp_le)"
   303 proof -
   304   from less have le: "c + a <= c + b" by (simp add: order_le_less)
   305   have "a <= b" 
   306     apply (insert le)
   307     apply (drule add_le_imp_le_left)
   308     by (insert le, drule add_le_imp_le_left, assumption)
   309   moreover have "a \<noteq> b"
   310   proof (rule ccontr)
   311     assume "~(a \<noteq> b)"
   312     then have "a = b" by simp
   313     then have "c + a = c + b" by simp
   314     with less show "False"by simp
   315   qed
   316   ultimately show "a < b" by (simp add: order_le_less)
   317 qed
   318 
   319 lemma add_less_imp_less_right:
   320       "a + c < b + c ==> a < (b::'a::pordered_ab_semigroup_add_imp_le)"
   321 apply (rule add_less_imp_less_left [of c])
   322 apply (simp add: add_commute)  
   323 done
   324 
   325 lemma add_less_cancel_left [simp]:
   326     "(c+a < c+b) = (a < (b::'a::pordered_ab_semigroup_add_imp_le))"
   327 by (blast intro: add_less_imp_less_left add_strict_left_mono) 
   328 
   329 lemma add_less_cancel_right [simp]:
   330     "(a+c < b+c) = (a < (b::'a::pordered_ab_semigroup_add_imp_le))"
   331 by (blast intro: add_less_imp_less_right add_strict_right_mono)
   332 
   333 lemma add_le_cancel_left [simp]:
   334     "(c+a \<le> c+b) = (a \<le> (b::'a::pordered_ab_semigroup_add_imp_le))"
   335 by (auto, drule add_le_imp_le_left, simp_all add: add_left_mono) 
   336 
   337 lemma add_le_cancel_right [simp]:
   338     "(a+c \<le> b+c) = (a \<le> (b::'a::pordered_ab_semigroup_add_imp_le))"
   339 by (simp add: add_commute[of a c] add_commute[of b c])
   340 
   341 lemma add_le_imp_le_right:
   342       "a + c \<le> b + c ==> a \<le> (b::'a::pordered_ab_semigroup_add_imp_le)"
   343 by simp
   344 
   345 lemma add_increasing:
   346   fixes c :: "'a::{pordered_ab_semigroup_add_imp_le, comm_monoid_add}"
   347   shows  "[|0\<le>a; b\<le>c|] ==> b \<le> a + c"
   348 by (insert add_mono [of 0 a b c], simp)
   349 
   350 lemma add_increasing2:
   351   fixes c :: "'a::{pordered_ab_semigroup_add_imp_le, comm_monoid_add}"
   352   shows  "[|0\<le>c; b\<le>a|] ==> b \<le> a + c"
   353 by (simp add:add_increasing add_commute[of a])
   354 
   355 lemma add_strict_increasing:
   356   fixes c :: "'a::{pordered_ab_semigroup_add_imp_le, comm_monoid_add}"
   357   shows "[|0<a; b\<le>c|] ==> b < a + c"
   358 by (insert add_less_le_mono [of 0 a b c], simp)
   359 
   360 lemma add_strict_increasing2:
   361   fixes c :: "'a::{pordered_ab_semigroup_add_imp_le, comm_monoid_add}"
   362   shows "[|0\<le>a; b<c|] ==> b < a + c"
   363 by (insert add_le_less_mono [of 0 a b c], simp)
   364 
   365 lemma max_add_distrib_left:
   366   fixes z :: "'a::pordered_ab_semigroup_add_imp_le"
   367   shows  "(max x y) + z = max (x+z) (y+z)"
   368 by (rule max_of_mono [THEN sym], rule add_le_cancel_right)
   369 
   370 lemma min_add_distrib_left:
   371   fixes z :: "'a::pordered_ab_semigroup_add_imp_le"
   372   shows  "(min x y) + z = min (x+z) (y+z)"
   373 by (rule min_of_mono [THEN sym], rule add_le_cancel_right)
   374 
   375 lemma max_diff_distrib_left:
   376   fixes z :: "'a::pordered_ab_group_add"
   377   shows  "(max x y) - z = max (x-z) (y-z)"
   378 by (simp add: diff_minus, rule max_add_distrib_left) 
   379 
   380 lemma min_diff_distrib_left:
   381   fixes z :: "'a::pordered_ab_group_add"
   382   shows  "(min x y) - z = min (x-z) (y-z)"
   383 by (simp add: diff_minus, rule min_add_distrib_left) 
   384 
   385 
   386 subsection {* Ordering Rules for Unary Minus *}
   387 
   388 lemma le_imp_neg_le:
   389   assumes "a \<le> (b::'a::{pordered_ab_semigroup_add_imp_le, ab_group_add})" shows "-b \<le> -a"
   390 proof -
   391   have "-a+a \<le> -a+b"
   392     using `a \<le> b` by (rule add_left_mono) 
   393   hence "0 \<le> -a+b"
   394     by simp
   395   hence "0 + (-b) \<le> (-a + b) + (-b)"
   396     by (rule add_right_mono) 
   397   thus ?thesis
   398     by (simp add: add_assoc)
   399 qed
   400 
   401 lemma neg_le_iff_le [simp]: "(-b \<le> -a) = (a \<le> (b::'a::pordered_ab_group_add))"
   402 proof 
   403   assume "- b \<le> - a"
   404   hence "- (- a) \<le> - (- b)"
   405     by (rule le_imp_neg_le)
   406   thus "a\<le>b" by simp
   407 next
   408   assume "a\<le>b"
   409   thus "-b \<le> -a" by (rule le_imp_neg_le)
   410 qed
   411 
   412 lemma neg_le_0_iff_le [simp]: "(-a \<le> 0) = (0 \<le> (a::'a::pordered_ab_group_add))"
   413 by (subst neg_le_iff_le [symmetric], simp)
   414 
   415 lemma neg_0_le_iff_le [simp]: "(0 \<le> -a) = (a \<le> (0::'a::pordered_ab_group_add))"
   416 by (subst neg_le_iff_le [symmetric], simp)
   417 
   418 lemma neg_less_iff_less [simp]: "(-b < -a) = (a < (b::'a::pordered_ab_group_add))"
   419 by (force simp add: order_less_le) 
   420 
   421 lemma neg_less_0_iff_less [simp]: "(-a < 0) = (0 < (a::'a::pordered_ab_group_add))"
   422 by (subst neg_less_iff_less [symmetric], simp)
   423 
   424 lemma neg_0_less_iff_less [simp]: "(0 < -a) = (a < (0::'a::pordered_ab_group_add))"
   425 by (subst neg_less_iff_less [symmetric], simp)
   426 
   427 text{*The next several equations can make the simplifier loop!*}
   428 
   429 lemma less_minus_iff: "(a < - b) = (b < - (a::'a::pordered_ab_group_add))"
   430 proof -
   431   have "(- (-a) < - b) = (b < - a)" by (rule neg_less_iff_less)
   432   thus ?thesis by simp
   433 qed
   434 
   435 lemma minus_less_iff: "(- a < b) = (- b < (a::'a::pordered_ab_group_add))"
   436 proof -
   437   have "(- a < - (-b)) = (- b < a)" by (rule neg_less_iff_less)
   438   thus ?thesis by simp
   439 qed
   440 
   441 lemma le_minus_iff: "(a \<le> - b) = (b \<le> - (a::'a::pordered_ab_group_add))"
   442 proof -
   443   have mm: "!! a (b::'a). (-(-a)) < -b \<Longrightarrow> -(-b) < -a" by (simp only: minus_less_iff)
   444   have "(- (- a) <= -b) = (b <= - a)" 
   445     apply (auto simp only: order_le_less)
   446     apply (drule mm)
   447     apply (simp_all)
   448     apply (drule mm[simplified], assumption)
   449     done
   450   then show ?thesis by simp
   451 qed
   452 
   453 lemma minus_le_iff: "(- a \<le> b) = (- b \<le> (a::'a::pordered_ab_group_add))"
   454 by (auto simp add: order_le_less minus_less_iff)
   455 
   456 lemma add_diff_eq: "a + (b - c) = (a + b) - (c::'a::ab_group_add)"
   457 by (simp add: diff_minus add_ac)
   458 
   459 lemma diff_add_eq: "(a - b) + c = (a + c) - (b::'a::ab_group_add)"
   460 by (simp add: diff_minus add_ac)
   461 
   462 lemma diff_eq_eq: "(a-b = c) = (a = c + (b::'a::ab_group_add))"
   463 by (auto simp add: diff_minus add_assoc)
   464 
   465 lemma eq_diff_eq: "(a = c-b) = (a + (b::'a::ab_group_add) = c)"
   466 by (auto simp add: diff_minus add_assoc)
   467 
   468 lemma diff_diff_eq: "(a - b) - c = a - (b + (c::'a::ab_group_add))"
   469 by (simp add: diff_minus add_ac)
   470 
   471 lemma diff_diff_eq2: "a - (b - c) = (a + c) - (b::'a::ab_group_add)"
   472 by (simp add: diff_minus add_ac)
   473 
   474 lemma diff_add_cancel: "a - b + b = (a::'a::ab_group_add)"
   475 by (simp add: diff_minus add_ac)
   476 
   477 lemma add_diff_cancel: "a + b - b = (a::'a::ab_group_add)"
   478 by (simp add: diff_minus add_ac)
   479 
   480 text{*Further subtraction laws*}
   481 
   482 lemma less_iff_diff_less_0: "(a < b) = (a - b < (0::'a::pordered_ab_group_add))"
   483 proof -
   484   have  "(a < b) = (a + (- b) < b + (-b))"  
   485     by (simp only: add_less_cancel_right)
   486   also have "... =  (a - b < 0)" by (simp add: diff_minus)
   487   finally show ?thesis .
   488 qed
   489 
   490 lemma diff_less_eq: "(a-b < c) = (a < c + (b::'a::pordered_ab_group_add))"
   491 apply (subst less_iff_diff_less_0 [of a])
   492 apply (rule less_iff_diff_less_0 [of _ c, THEN ssubst])
   493 apply (simp add: diff_minus add_ac)
   494 done
   495 
   496 lemma less_diff_eq: "(a < c-b) = (a + (b::'a::pordered_ab_group_add) < c)"
   497 apply (subst less_iff_diff_less_0 [of "a+b"])
   498 apply (subst less_iff_diff_less_0 [of a])
   499 apply (simp add: diff_minus add_ac)
   500 done
   501 
   502 lemma diff_le_eq: "(a-b \<le> c) = (a \<le> c + (b::'a::pordered_ab_group_add))"
   503 by (auto simp add: order_le_less diff_less_eq diff_add_cancel add_diff_cancel)
   504 
   505 lemma le_diff_eq: "(a \<le> c-b) = (a + (b::'a::pordered_ab_group_add) \<le> c)"
   506 by (auto simp add: order_le_less less_diff_eq diff_add_cancel add_diff_cancel)
   507 
   508 text{*This list of rewrites simplifies (in)equalities by bringing subtractions
   509   to the top and then moving negative terms to the other side.
   510   Use with @{text add_ac}*}
   511 lemmas compare_rls =
   512        diff_minus [symmetric]
   513        add_diff_eq diff_add_eq diff_diff_eq diff_diff_eq2
   514        diff_less_eq less_diff_eq diff_le_eq le_diff_eq
   515        diff_eq_eq eq_diff_eq
   516 
   517 subsection {* Support for reasoning about signs *}
   518 
   519 lemma add_pos_pos: "0 < 
   520     (x::'a::{comm_monoid_add,pordered_cancel_ab_semigroup_add}) 
   521       ==> 0 < y ==> 0 < x + y"
   522 apply (subgoal_tac "0 + 0 < x + y")
   523 apply simp
   524 apply (erule add_less_le_mono)
   525 apply (erule order_less_imp_le)
   526 done
   527 
   528 lemma add_pos_nonneg: "0 < 
   529     (x::'a::{comm_monoid_add,pordered_cancel_ab_semigroup_add}) 
   530       ==> 0 <= y ==> 0 < x + y"
   531 apply (subgoal_tac "0 + 0 < x + y")
   532 apply simp
   533 apply (erule add_less_le_mono, assumption)
   534 done
   535 
   536 lemma add_nonneg_pos: "0 <= 
   537     (x::'a::{comm_monoid_add,pordered_cancel_ab_semigroup_add}) 
   538       ==> 0 < y ==> 0 < x + y"
   539 apply (subgoal_tac "0 + 0 < x + y")
   540 apply simp
   541 apply (erule add_le_less_mono, assumption)
   542 done
   543 
   544 lemma add_nonneg_nonneg: "0 <= 
   545     (x::'a::{comm_monoid_add,pordered_cancel_ab_semigroup_add}) 
   546       ==> 0 <= y ==> 0 <= x + y"
   547 apply (subgoal_tac "0 + 0 <= x + y")
   548 apply simp
   549 apply (erule add_mono, assumption)
   550 done
   551 
   552 lemma add_neg_neg: "(x::'a::{comm_monoid_add,pordered_cancel_ab_semigroup_add})
   553     < 0 ==> y < 0 ==> x + y < 0"
   554 apply (subgoal_tac "x + y < 0 + 0")
   555 apply simp
   556 apply (erule add_less_le_mono)
   557 apply (erule order_less_imp_le)
   558 done
   559 
   560 lemma add_neg_nonpos: 
   561     "(x::'a::{comm_monoid_add,pordered_cancel_ab_semigroup_add}) < 0 
   562       ==> y <= 0 ==> x + y < 0"
   563 apply (subgoal_tac "x + y < 0 + 0")
   564 apply simp
   565 apply (erule add_less_le_mono, assumption)
   566 done
   567 
   568 lemma add_nonpos_neg: 
   569     "(x::'a::{comm_monoid_add,pordered_cancel_ab_semigroup_add}) <= 0 
   570       ==> y < 0 ==> x + y < 0"
   571 apply (subgoal_tac "x + y < 0 + 0")
   572 apply simp
   573 apply (erule add_le_less_mono, assumption)
   574 done
   575 
   576 lemma add_nonpos_nonpos: 
   577     "(x::'a::{comm_monoid_add,pordered_cancel_ab_semigroup_add}) <= 0 
   578       ==> y <= 0 ==> x + y <= 0"
   579 apply (subgoal_tac "x + y <= 0 + 0")
   580 apply simp
   581 apply (erule add_mono, assumption)
   582 done
   583 
   584 subsection{*Lemmas for the @{text cancel_numerals} simproc*}
   585 
   586 lemma eq_iff_diff_eq_0: "(a = b) = (a-b = (0::'a::ab_group_add))"
   587 by (simp add: compare_rls)
   588 
   589 lemma le_iff_diff_le_0: "(a \<le> b) = (a-b \<le> (0::'a::pordered_ab_group_add))"
   590 by (simp add: compare_rls)
   591 
   592 
   593 subsection {* Lattice Ordered (Abelian) Groups *}
   594 
   595 class lordered_ab_group_meet = pordered_ab_group_add + lower_semilattice
   596 
   597 class lordered_ab_group_join = pordered_ab_group_add + upper_semilattice
   598 
   599 class lordered_ab_group = pordered_ab_group_add + lattice
   600 
   601 instance lordered_ab_group \<subseteq> lordered_ab_group_meet by default
   602 instance lordered_ab_group \<subseteq> lordered_ab_group_join by default
   603 
   604 lemma add_inf_distrib_left: "a + inf b c = inf (a + b) (a + (c::'a::{pordered_ab_group_add, lower_semilattice}))"
   605 apply (rule order_antisym)
   606 apply (simp_all add: le_infI)
   607 apply (rule add_le_imp_le_left [of "-a"])
   608 apply (simp only: add_assoc[symmetric], simp)
   609 apply rule
   610 apply (rule add_le_imp_le_left[of "a"], simp only: add_assoc[symmetric], simp)+
   611 done
   612 
   613 lemma add_sup_distrib_left: "a + sup b c = sup (a + b) (a+ (c::'a::{pordered_ab_group_add, upper_semilattice}))" 
   614 apply (rule order_antisym)
   615 apply (rule add_le_imp_le_left [of "-a"])
   616 apply (simp only: add_assoc[symmetric], simp)
   617 apply rule
   618 apply (rule add_le_imp_le_left [of "a"], simp only: add_assoc[symmetric], simp)+
   619 apply (rule le_supI)
   620 apply (simp_all)
   621 done
   622 
   623 lemma add_inf_distrib_right: "inf a b + (c::'a::lordered_ab_group) = inf (a+c) (b+c)"
   624 proof -
   625   have "c + inf a b = inf (c+a) (c+b)" by (simp add: add_inf_distrib_left)
   626   thus ?thesis by (simp add: add_commute)
   627 qed
   628 
   629 lemma add_sup_distrib_right: "sup a b + (c::'a::lordered_ab_group) = sup (a+c) (b+c)"
   630 proof -
   631   have "c + sup a b = sup (c+a) (c+b)" by (simp add: add_sup_distrib_left)
   632   thus ?thesis by (simp add: add_commute)
   633 qed
   634 
   635 lemmas add_sup_inf_distribs = add_inf_distrib_right add_inf_distrib_left add_sup_distrib_right add_sup_distrib_left
   636 
   637 lemma inf_eq_neg_sup: "inf a (b\<Colon>'a\<Colon>lordered_ab_group) = - sup (-a) (-b)"
   638 proof (rule inf_unique)
   639   fix a b :: 'a
   640   show "- sup (-a) (-b) \<le> a" by (rule add_le_imp_le_right [of _ "sup (-a) (-b)"])
   641     (simp, simp add: add_sup_distrib_left)
   642 next
   643   fix a b :: 'a
   644   show "- sup (-a) (-b) \<le> b" by (rule add_le_imp_le_right [of _ "sup (-a) (-b)"])
   645     (simp, simp add: add_sup_distrib_left)
   646 next
   647   fix a b c :: 'a
   648   assume "a \<le> b" "a \<le> c"
   649   then show "a \<le> - sup (-b) (-c)" by (subst neg_le_iff_le [symmetric])
   650     (simp add: le_supI)
   651 qed
   652   
   653 lemma sup_eq_neg_inf: "sup a (b\<Colon>'a\<Colon>lordered_ab_group) = - inf (-a) (-b)"
   654 proof (rule sup_unique)
   655   fix a b :: 'a
   656   show "a \<le> - inf (-a) (-b)" by (rule add_le_imp_le_right [of _ "inf (-a) (-b)"])
   657     (simp, simp add: add_inf_distrib_left)
   658 next
   659   fix a b :: 'a
   660   show "b \<le> - inf (-a) (-b)" by (rule add_le_imp_le_right [of _ "inf (-a) (-b)"])
   661     (simp, simp add: add_inf_distrib_left)
   662 next
   663   fix a b c :: 'a
   664   assume "a \<le> c" "b \<le> c"
   665   then show "- inf (-a) (-b) \<le> c" by (subst neg_le_iff_le [symmetric])
   666     (simp add: le_infI)
   667 qed
   668 
   669 lemma add_eq_inf_sup: "a + b = sup a b + inf a (b\<Colon>'a\<Colon>lordered_ab_group)"
   670 proof -
   671   have "0 = - inf 0 (a-b) + inf (a-b) 0" by (simp add: inf_commute)
   672   hence "0 = sup 0 (b-a) + inf (a-b) 0" by (simp add: inf_eq_neg_sup)
   673   hence "0 = (-a + sup a b) + (inf a b + (-b))"
   674     apply (simp add: add_sup_distrib_left add_inf_distrib_right)
   675     by (simp add: diff_minus add_commute)
   676   thus ?thesis
   677     apply (simp add: compare_rls)
   678     apply (subst add_left_cancel[symmetric, of "a+b" "sup a b + inf a b" "-a"])
   679     apply (simp only: add_assoc, simp add: add_assoc[symmetric])
   680     done
   681 qed
   682 
   683 subsection {* Positive Part, Negative Part, Absolute Value *}
   684 
   685 definition
   686   nprt :: "'a \<Rightarrow> ('a::lordered_ab_group)" where
   687   "nprt x = inf x 0"
   688 
   689 definition
   690   pprt :: "'a \<Rightarrow> ('a::lordered_ab_group)" where
   691   "pprt x = sup x 0"
   692 
   693 lemma prts: "a = pprt a + nprt a"
   694 by (simp add: pprt_def nprt_def add_eq_inf_sup[symmetric])
   695 
   696 lemma zero_le_pprt[simp]: "0 \<le> pprt a"
   697 by (simp add: pprt_def)
   698 
   699 lemma nprt_le_zero[simp]: "nprt a \<le> 0"
   700 by (simp add: nprt_def)
   701 
   702 lemma le_eq_neg: "(a \<le> -b) = (a + b \<le> (0::_::lordered_ab_group))" (is "?l = ?r")
   703 proof -
   704   have a: "?l \<longrightarrow> ?r"
   705     apply (auto)
   706     apply (rule add_le_imp_le_right[of _ "-b" _])
   707     apply (simp add: add_assoc)
   708     done
   709   have b: "?r \<longrightarrow> ?l"
   710     apply (auto)
   711     apply (rule add_le_imp_le_right[of _ "b" _])
   712     apply (simp)
   713     done
   714   from a b show ?thesis by blast
   715 qed
   716 
   717 lemma pprt_0[simp]: "pprt 0 = 0" by (simp add: pprt_def)
   718 lemma nprt_0[simp]: "nprt 0 = 0" by (simp add: nprt_def)
   719 
   720 lemma pprt_eq_id[simp,noatp]: "0 <= x \<Longrightarrow> pprt x = x"
   721   by (simp add: pprt_def le_iff_sup sup_aci)
   722 
   723 lemma nprt_eq_id[simp,noatp]: "x <= 0 \<Longrightarrow> nprt x = x"
   724   by (simp add: nprt_def le_iff_inf inf_aci)
   725 
   726 lemma pprt_eq_0[simp,noatp]: "x <= 0 \<Longrightarrow> pprt x = 0"
   727   by (simp add: pprt_def le_iff_sup sup_aci)
   728 
   729 lemma nprt_eq_0[simp,noatp]: "0 <= x \<Longrightarrow> nprt x = 0"
   730   by (simp add: nprt_def le_iff_inf inf_aci)
   731 
   732 lemma sup_0_imp_0: "sup a (-a) = 0 \<Longrightarrow> a = (0::'a::lordered_ab_group)"
   733 proof -
   734   {
   735     fix a::'a
   736     assume hyp: "sup a (-a) = 0"
   737     hence "sup a (-a) + a = a" by (simp)
   738     hence "sup (a+a) 0 = a" by (simp add: add_sup_distrib_right) 
   739     hence "sup (a+a) 0 <= a" by (simp)
   740     hence "0 <= a" by (blast intro: order_trans inf_sup_ord)
   741   }
   742   note p = this
   743   assume hyp:"sup a (-a) = 0"
   744   hence hyp2:"sup (-a) (-(-a)) = 0" by (simp add: sup_commute)
   745   from p[OF hyp] p[OF hyp2] show "a = 0" by simp
   746 qed
   747 
   748 lemma inf_0_imp_0: "inf a (-a) = 0 \<Longrightarrow> a = (0::'a::lordered_ab_group)"
   749 apply (simp add: inf_eq_neg_sup)
   750 apply (simp add: sup_commute)
   751 apply (erule sup_0_imp_0)
   752 done
   753 
   754 lemma inf_0_eq_0[simp,noatp]: "(inf a (-a) = 0) = (a = (0::'a::lordered_ab_group))"
   755 by (auto, erule inf_0_imp_0)
   756 
   757 lemma sup_0_eq_0[simp,noatp]: "(sup a (-a) = 0) = (a = (0::'a::lordered_ab_group))"
   758 by (auto, erule sup_0_imp_0)
   759 
   760 lemma zero_le_double_add_iff_zero_le_single_add[simp]: "(0 \<le> a + a) = (0 \<le> (a::'a::lordered_ab_group))"
   761 proof
   762   assume "0 <= a + a"
   763   hence a:"inf (a+a) 0 = 0" by (simp add: le_iff_inf inf_commute)
   764   have "(inf a 0)+(inf a 0) = inf (inf (a+a) 0) a" (is "?l=_") by (simp add: add_sup_inf_distribs inf_aci)
   765   hence "?l = 0 + inf a 0" by (simp add: a, simp add: inf_commute)
   766   hence "inf a 0 = 0" by (simp only: add_right_cancel)
   767   then show "0 <= a" by (simp add: le_iff_inf inf_commute)    
   768 next  
   769   assume a: "0 <= a"
   770   show "0 <= a + a" by (simp add: add_mono[OF a a, simplified])
   771 qed
   772 
   773 lemma double_add_le_zero_iff_single_add_le_zero[simp]: "(a + a <= 0) = ((a::'a::lordered_ab_group) <= 0)" 
   774 proof -
   775   have "(a + a <= 0) = (0 <= -(a+a))" by (subst le_minus_iff, simp)
   776   moreover have "\<dots> = (a <= 0)" by (simp add: zero_le_double_add_iff_zero_le_single_add)
   777   ultimately show ?thesis by blast
   778 qed
   779 
   780 lemma double_add_less_zero_iff_single_less_zero[simp]: "(a+a<0) = ((a::'a::{pordered_ab_group_add,linorder}) < 0)" (is ?s)
   781 proof cases
   782   assume a: "a < 0"
   783   thus ?s by (simp add:  add_strict_mono[OF a a, simplified])
   784 next
   785   assume "~(a < 0)" 
   786   hence a:"0 <= a" by (simp)
   787   hence "0 <= a+a" by (simp add: add_mono[OF a a, simplified])
   788   hence "~(a+a < 0)" by simp
   789   with a show ?thesis by simp 
   790 qed
   791 
   792 class lordered_ab_group_abs = lordered_ab_group + abs +
   793   assumes abs_lattice: "abs x = sup x (uminus x)"
   794 
   795 lemma abs_zero[simp]: "abs 0 = (0::'a::lordered_ab_group_abs)"
   796 by (simp add: abs_lattice)
   797 
   798 lemma abs_eq_0[simp]: "(abs a = 0) = (a = (0::'a::lordered_ab_group_abs))"
   799 by (simp add: abs_lattice)
   800 
   801 lemma abs_0_eq[simp]: "(0 = abs a) = (a = (0::'a::lordered_ab_group_abs))"
   802 proof -
   803   have "(0 = abs a) = (abs a = 0)" by (simp only: eq_ac)
   804   thus ?thesis by simp
   805 qed
   806 
   807 declare abs_0_eq [noatp] (*essentially the same as the other one*)
   808 
   809 lemma neg_inf_eq_sup[simp]: "- inf a (b::_::lordered_ab_group) = sup (-a) (-b)"
   810 by (simp add: inf_eq_neg_sup)
   811 
   812 lemma neg_sup_eq_inf[simp]: "- sup a (b::_::lordered_ab_group) = inf (-a) (-b)"
   813 by (simp del: neg_inf_eq_sup add: sup_eq_neg_inf)
   814 
   815 lemma sup_eq_if: "sup a (-a) = (if a < 0 then -a else (a::'a::{lordered_ab_group, linorder}))"
   816 proof -
   817   note b = add_le_cancel_right[of a a "-a",symmetric,simplified]
   818   have c: "a + a = 0 \<Longrightarrow> -a = a" by (rule add_right_imp_eq[of _ a], simp)
   819   show ?thesis by (auto simp add: max_def b linorder_not_less sup_max)
   820 qed
   821 
   822 lemma abs_if_lattice: "\<bar>a\<bar> = (if a < 0 then -a else (a::'a::{lordered_ab_group_abs, linorder}))"
   823 proof -
   824   show ?thesis by (simp add: abs_lattice sup_eq_if)
   825 qed
   826 
   827 lemma abs_ge_zero[simp]: "0 \<le> abs (a::'a::lordered_ab_group_abs)"
   828 proof -
   829   have a:"a <= abs a" and b:"-a <= abs a" by (auto simp add: abs_lattice)
   830   show ?thesis by (rule add_mono[OF a b, simplified])
   831 qed
   832   
   833 lemma abs_le_zero_iff [simp]: "(abs a \<le> (0::'a::lordered_ab_group_abs)) = (a = 0)" 
   834 proof
   835   assume "abs a <= 0"
   836   hence "abs a = 0" by (auto dest: order_antisym)
   837   thus "a = 0" by simp
   838 next
   839   assume "a = 0"
   840   thus "abs a <= 0" by simp
   841 qed
   842 
   843 lemma zero_less_abs_iff [simp]: "(0 < abs a) = (a \<noteq> (0::'a::lordered_ab_group_abs))"
   844 by (simp add: order_less_le)
   845 
   846 lemma abs_not_less_zero [simp]: "~ abs a < (0::'a::lordered_ab_group_abs)"
   847 proof -
   848   have a:"!! x (y::_::order). x <= y \<Longrightarrow> ~(y < x)" by auto
   849   show ?thesis by (simp add: a)
   850 qed
   851 
   852 lemma abs_ge_self: "a \<le> abs (a::'a::lordered_ab_group_abs)"
   853 by (simp add: abs_lattice)
   854 
   855 lemma abs_ge_minus_self: "-a \<le> abs (a::'a::lordered_ab_group_abs)"
   856 by (simp add: abs_lattice)
   857 
   858 lemma abs_prts: "abs (a::_::lordered_ab_group_abs) = pprt a - nprt a"
   859 apply (simp add: pprt_def nprt_def diff_minus)
   860 apply (simp add: add_sup_inf_distribs sup_aci abs_lattice[symmetric])
   861 apply (subst sup_absorb2, auto)
   862 done
   863 
   864 lemma abs_minus_cancel [simp]: "abs (-a) = abs(a::'a::lordered_ab_group_abs)"
   865 by (simp add: abs_lattice sup_commute)
   866 
   867 lemma abs_idempotent [simp]: "abs (abs a) = abs (a::'a::lordered_ab_group_abs)"
   868 apply (simp add: abs_lattice[of "abs a"])
   869 apply (subst sup_absorb1)
   870 apply (rule order_trans[of _ 0])
   871 by auto
   872 
   873 lemma abs_minus_commute: 
   874   fixes a :: "'a::lordered_ab_group_abs"
   875   shows "abs (a-b) = abs(b-a)"
   876 proof -
   877   have "abs (a-b) = abs (- (a-b))" by (simp only: abs_minus_cancel)
   878   also have "... = abs(b-a)" by simp
   879   finally show ?thesis .
   880 qed
   881 
   882 lemma zero_le_iff_zero_nprt: "(0 \<le> a) = (nprt a = 0)"
   883 by (simp add: le_iff_inf nprt_def inf_commute)
   884 
   885 lemma le_zero_iff_zero_pprt: "(a \<le> 0) = (pprt a = 0)"
   886 by (simp add: le_iff_sup pprt_def sup_commute)
   887 
   888 lemma le_zero_iff_pprt_id: "(0 \<le> a) = (pprt a = a)"
   889 by (simp add: le_iff_sup pprt_def sup_commute)
   890 
   891 lemma zero_le_iff_nprt_id: "(a \<le> 0) = (nprt a = a)"
   892 by (simp add: le_iff_inf nprt_def inf_commute)
   893 
   894 lemma pprt_mono[simp,noatp]: "(a::_::lordered_ab_group) <= b \<Longrightarrow> pprt a <= pprt b"
   895   by (simp add: le_iff_sup pprt_def sup_aci)
   896 
   897 lemma nprt_mono[simp,noatp]: "(a::_::lordered_ab_group) <= b \<Longrightarrow> nprt a <= nprt b"
   898   by (simp add: le_iff_inf nprt_def inf_aci)
   899 
   900 lemma pprt_neg: "pprt (-x) = - nprt x"
   901   by (simp add: pprt_def nprt_def)
   902 
   903 lemma nprt_neg: "nprt (-x) = - pprt x"
   904   by (simp add: pprt_def nprt_def)
   905 
   906 lemma iff2imp: "(A=B) \<Longrightarrow> (A \<Longrightarrow> B)"
   907 by (simp)
   908 
   909 lemma abs_of_nonneg [simp]: "0 \<le> a \<Longrightarrow> abs a = (a::'a::lordered_ab_group_abs)"
   910 by (simp add: iff2imp[OF zero_le_iff_zero_nprt] iff2imp[OF le_zero_iff_pprt_id] abs_prts)
   911 
   912 lemma abs_of_pos: "0 < (x::'a::lordered_ab_group_abs) ==> abs x = x";
   913 by (rule abs_of_nonneg, rule order_less_imp_le);
   914 
   915 lemma abs_of_nonpos [simp]: "a \<le> 0 \<Longrightarrow> abs a = -(a::'a::lordered_ab_group_abs)"
   916 by (simp add: iff2imp[OF le_zero_iff_zero_pprt] iff2imp[OF zero_le_iff_nprt_id] abs_prts)
   917 
   918 lemma abs_of_neg: "(x::'a::lordered_ab_group_abs) <  0 ==> 
   919   abs x = - x"
   920 by (rule abs_of_nonpos, rule order_less_imp_le)
   921 
   922 lemma abs_leI: "[|a \<le> b; -a \<le> b|] ==> abs a \<le> (b::'a::lordered_ab_group_abs)"
   923 by (simp add: abs_lattice le_supI)
   924 
   925 lemma le_minus_self_iff: "(a \<le> -a) = (a \<le> (0::'a::lordered_ab_group))"
   926 proof -
   927   from add_le_cancel_left[of "-a" "a+a" "0"] have "(a <= -a) = (a+a <= 0)" 
   928     by (simp add: add_assoc[symmetric])
   929   thus ?thesis by simp
   930 qed
   931 
   932 lemma minus_le_self_iff: "(-a \<le> a) = (0 \<le> (a::'a::lordered_ab_group))"
   933 proof -
   934   from add_le_cancel_left[of "-a" "0" "a+a"] have "(-a <= a) = (0 <= a+a)" 
   935     by (simp add: add_assoc[symmetric])
   936   thus ?thesis by simp
   937 qed
   938 
   939 lemma abs_le_D1: "abs a \<le> b ==> a \<le> (b::'a::lordered_ab_group_abs)"
   940 by (insert abs_ge_self, blast intro: order_trans)
   941 
   942 lemma abs_le_D2: "abs a \<le> b ==> -a \<le> (b::'a::lordered_ab_group_abs)"
   943 by (insert abs_le_D1 [of "-a"], simp)
   944 
   945 lemma abs_le_iff: "(abs a \<le> b) = (a \<le> b & -a \<le> (b::'a::lordered_ab_group_abs))"
   946 by (blast intro: abs_leI dest: abs_le_D1 abs_le_D2)
   947 
   948 lemma abs_triangle_ineq: "abs(a+b) \<le> abs a + abs(b::'a::lordered_ab_group_abs)"
   949 proof -
   950   have g:"abs a + abs b = sup (a+b) (sup (-a-b) (sup (-a+b) (a + (-b))))" (is "_=sup ?m ?n")
   951     by (simp add: abs_lattice add_sup_inf_distribs sup_aci diff_minus)
   952   have a:"a+b <= sup ?m ?n" by (simp)
   953   have b:"-a-b <= ?n" by (simp) 
   954   have c:"?n <= sup ?m ?n" by (simp)
   955   from b c have d: "-a-b <= sup ?m ?n" by(rule order_trans)
   956   have e:"-a-b = -(a+b)" by (simp add: diff_minus)
   957   from a d e have "abs(a+b) <= sup ?m ?n" 
   958     by (drule_tac abs_leI, auto)
   959   with g[symmetric] show ?thesis by simp
   960 qed
   961 
   962 lemma abs_triangle_ineq2: "abs (a::'a::lordered_ab_group_abs) - 
   963     abs b <= abs (a - b)"
   964   apply (simp add: compare_rls)
   965   apply (subgoal_tac "abs a = abs (a - b + b)")
   966   apply (erule ssubst)
   967   apply (rule abs_triangle_ineq)
   968   apply (rule arg_cong);back;
   969   apply (simp add: compare_rls)
   970 done
   971 
   972 lemma abs_triangle_ineq3: 
   973     "abs(abs (a::'a::lordered_ab_group_abs) - abs b) <= abs (a - b)"
   974   apply (subst abs_le_iff)
   975   apply auto
   976   apply (rule abs_triangle_ineq2)
   977   apply (subst abs_minus_commute)
   978   apply (rule abs_triangle_ineq2)
   979 done
   980 
   981 lemma abs_triangle_ineq4: "abs ((a::'a::lordered_ab_group_abs) - b) <= 
   982     abs a + abs b"
   983 proof -;
   984   have "abs(a - b) = abs(a + - b)"
   985     by (subst diff_minus, rule refl)
   986   also have "... <= abs a + abs (- b)"
   987     by (rule abs_triangle_ineq)
   988   finally show ?thesis
   989     by simp
   990 qed
   991 
   992 lemma abs_diff_triangle_ineq:
   993      "\<bar>(a::'a::lordered_ab_group_abs) + b - (c+d)\<bar> \<le> \<bar>a-c\<bar> + \<bar>b-d\<bar>"
   994 proof -
   995   have "\<bar>a + b - (c+d)\<bar> = \<bar>(a-c) + (b-d)\<bar>" by (simp add: diff_minus add_ac)
   996   also have "... \<le> \<bar>a-c\<bar> + \<bar>b-d\<bar>" by (rule abs_triangle_ineq)
   997   finally show ?thesis .
   998 qed
   999 
  1000 lemma abs_add_abs[simp]:
  1001 fixes a:: "'a::{lordered_ab_group_abs}"
  1002 shows "abs(abs a + abs b) = abs a + abs b" (is "?L = ?R")
  1003 proof (rule order_antisym)
  1004   show "?L \<ge> ?R" by(rule abs_ge_self)
  1005 next
  1006   have "?L \<le> \<bar>\<bar>a\<bar>\<bar> + \<bar>\<bar>b\<bar>\<bar>" by(rule abs_triangle_ineq)
  1007   also have "\<dots> = ?R" by simp
  1008   finally show "?L \<le> ?R" .
  1009 qed
  1010 
  1011 text {* Needed for abelian cancellation simprocs: *}
  1012 
  1013 lemma add_cancel_21: "((x::'a::ab_group_add) + (y + z) = y + u) = (x + z = u)"
  1014 apply (subst add_left_commute)
  1015 apply (subst add_left_cancel)
  1016 apply simp
  1017 done
  1018 
  1019 lemma add_cancel_end: "(x + (y + z) = y) = (x = - (z::'a::ab_group_add))"
  1020 apply (subst add_cancel_21[of _ _ _ 0, simplified])
  1021 apply (simp add: add_right_cancel[symmetric, of "x" "-z" "z", simplified])
  1022 done
  1023 
  1024 lemma less_eqI: "(x::'a::pordered_ab_group_add) - y = x' - y' \<Longrightarrow> (x < y) = (x' < y')"
  1025 by (simp add: less_iff_diff_less_0[of x y] less_iff_diff_less_0[of x' y'])
  1026 
  1027 lemma le_eqI: "(x::'a::pordered_ab_group_add) - y = x' - y' \<Longrightarrow> (y <= x) = (y' <= x')"
  1028 apply (simp add: le_iff_diff_le_0[of y x] le_iff_diff_le_0[of  y' x'])
  1029 apply (simp add: neg_le_iff_le[symmetric, of "y-x" 0] neg_le_iff_le[symmetric, of "y'-x'" 0])
  1030 done
  1031 
  1032 lemma eq_eqI: "(x::'a::ab_group_add) - y = x' - y' \<Longrightarrow> (x = y) = (x' = y')"
  1033 by (simp add: eq_iff_diff_eq_0[of x y] eq_iff_diff_eq_0[of x' y'])
  1034 
  1035 lemma diff_def: "(x::'a::ab_group_add) - y == x + (-y)"
  1036 by (simp add: diff_minus)
  1037 
  1038 lemma add_minus_cancel: "(a::'a::ab_group_add) + (-a + b) = b"
  1039 by (simp add: add_assoc[symmetric])
  1040 
  1041 lemma  le_add_right_mono: 
  1042   assumes 
  1043   "a <= b + (c::'a::pordered_ab_group_add)"
  1044   "c <= d"    
  1045   shows "a <= b + d"
  1046   apply (rule_tac order_trans[where y = "b+c"])
  1047   apply (simp_all add: prems)
  1048   done
  1049 
  1050 lemmas group_simps =
  1051   mult_ac
  1052   add_ac
  1053   add_diff_eq diff_add_eq diff_diff_eq diff_diff_eq2
  1054   diff_eq_eq eq_diff_eq  diff_minus[symmetric] uminus_add_conv_diff
  1055   diff_less_eq less_diff_eq diff_le_eq le_diff_eq
  1056 
  1057 lemma estimate_by_abs:
  1058   "a + b <= (c::'a::lordered_ab_group_abs) \<Longrightarrow> a <= c + abs b" 
  1059 proof -
  1060   assume "a+b <= c"
  1061   hence 2: "a <= c+(-b)" by (simp add: group_simps)
  1062   have 3: "(-b) <= abs b" by (rule abs_ge_minus_self)
  1063   show ?thesis by (rule le_add_right_mono[OF 2 3])
  1064 qed
  1065 
  1066 
  1067 subsection {* Tools setup *}
  1068 
  1069 text{*Simplification of @{term "x-y < 0"}, etc.*}
  1070 lemmas diff_less_0_iff_less [simp] = less_iff_diff_less_0 [symmetric]
  1071 lemmas diff_eq_0_iff_eq [simp, noatp] = eq_iff_diff_eq_0 [symmetric]
  1072 lemmas diff_le_0_iff_le [simp] = le_iff_diff_le_0 [symmetric]
  1073 
  1074 ML {*
  1075 structure ab_group_add_cancel = Abel_Cancel(
  1076 struct
  1077 
  1078 (* term order for abelian groups *)
  1079 
  1080 fun agrp_ord (Const (a, _)) = find_index (fn a' => a = a')
  1081       [@{const_name HOL.zero}, @{const_name HOL.plus},
  1082         @{const_name HOL.uminus}, @{const_name HOL.minus}]
  1083   | agrp_ord _ = ~1;
  1084 
  1085 fun termless_agrp (a, b) = (Term.term_lpo agrp_ord (a, b) = LESS);
  1086 
  1087 local
  1088   val ac1 = mk_meta_eq @{thm add_assoc};
  1089   val ac2 = mk_meta_eq @{thm add_commute};
  1090   val ac3 = mk_meta_eq @{thm add_left_commute};
  1091   fun solve_add_ac thy _ (_ $ (Const (@{const_name HOL.plus},_) $ _ $ _) $ _) =
  1092         SOME ac1
  1093     | solve_add_ac thy _ (_ $ x $ (Const (@{const_name HOL.plus},_) $ y $ z)) =
  1094         if termless_agrp (y, x) then SOME ac3 else NONE
  1095     | solve_add_ac thy _ (_ $ x $ y) =
  1096         if termless_agrp (y, x) then SOME ac2 else NONE
  1097     | solve_add_ac thy _ _ = NONE
  1098 in
  1099   val add_ac_proc = Simplifier.simproc @{theory}
  1100     "add_ac_proc" ["x + y::'a::ab_semigroup_add"] solve_add_ac;
  1101 end;
  1102 
  1103 val cancel_ss = HOL_basic_ss settermless termless_agrp
  1104   addsimprocs [add_ac_proc] addsimps
  1105   [@{thm add_0_left}, @{thm add_0_right}, @{thm diff_def},
  1106    @{thm minus_add_distrib}, @{thm minus_minus}, @{thm minus_zero},
  1107    @{thm right_minus}, @{thm left_minus}, @{thm add_minus_cancel},
  1108    @{thm minus_add_cancel}];
  1109   
  1110 val eq_reflection = @{thm eq_reflection};
  1111   
  1112 val thy_ref = Theory.check_thy @{theory};
  1113 
  1114 val T = TFree("'a", ["OrderedGroup.ab_group_add"]);
  1115 
  1116 val eqI_rules = [@{thm less_eqI}, @{thm le_eqI}, @{thm eq_eqI}];
  1117 
  1118 val dest_eqI = 
  1119   fst o HOLogic.dest_bin "op =" HOLogic.boolT o HOLogic.dest_Trueprop o concl_of;
  1120 
  1121 end);
  1122 *}
  1123 
  1124 ML_setup {*
  1125   Addsimprocs [ab_group_add_cancel.sum_conv, ab_group_add_cancel.rel_conv];
  1126 *}
  1127 
  1128 end