src/HOL/Tools/hologic.ML
author haftmann
Wed May 13 18:41:38 2009 +0200 (2009-05-13)
changeset 31135 e2d777dcf161
parent 31048 ac146fc38b51
child 31183 13effe47174c
permissions -rw-r--r--
added abstract operations for typerep/term_of
     1 (*  Title:      HOL/hologic.ML
     2     Author:     Lawrence C Paulson and Markus Wenzel
     3 
     4 Abstract syntax operations for HOL.
     5 *)
     6 
     7 signature HOLOGIC =
     8 sig
     9   val typeS: sort
    10   val typeT: typ
    11   val boolN: string
    12   val boolT: typ
    13   val Trueprop: term
    14   val mk_Trueprop: term -> term
    15   val dest_Trueprop: term -> term
    16   val true_const: term
    17   val false_const: term
    18   val mk_setT: typ -> typ
    19   val dest_setT: typ -> typ
    20   val Collect_const: typ -> term
    21   val mk_Collect: string * typ * term -> term
    22   val mk_mem: term * term -> term
    23   val dest_mem: term -> term * term
    24   val mk_set: typ -> term list -> term
    25   val dest_set: term -> term list
    26   val mk_UNIV: typ -> term
    27   val conj_intr: thm -> thm -> thm
    28   val conj_elim: thm -> thm * thm
    29   val conj_elims: thm -> thm list
    30   val conj: term
    31   val disj: term
    32   val imp: term
    33   val Not: term
    34   val mk_conj: term * term -> term
    35   val mk_disj: term * term -> term
    36   val mk_imp: term * term -> term
    37   val mk_not: term -> term
    38   val dest_conj: term -> term list
    39   val dest_disj: term -> term list
    40   val disjuncts: term -> term list
    41   val dest_imp: term -> term * term
    42   val dest_not: term -> term
    43   val eq_const: typ -> term
    44   val mk_eq: term * term -> term
    45   val dest_eq: term -> term * term
    46   val all_const: typ -> term
    47   val mk_all: string * typ * term -> term
    48   val list_all: (string * typ) list * term -> term
    49   val exists_const: typ -> term
    50   val mk_exists: string * typ * term -> term
    51   val choice_const: typ -> term
    52   val class_eq: string
    53   val mk_binop: string -> term * term -> term
    54   val mk_binrel: string -> term * term -> term
    55   val dest_bin: string -> typ -> term -> term * term
    56   val unitT: typ
    57   val is_unitT: typ -> bool
    58   val unit: term
    59   val is_unit: term -> bool
    60   val mk_prodT: typ * typ -> typ
    61   val dest_prodT: typ -> typ * typ
    62   val pair_const: typ -> typ -> term
    63   val mk_prod: term * term -> term
    64   val dest_prod: term -> term * term
    65   val mk_fst: term -> term
    66   val mk_snd: term -> term
    67   val split_const: typ * typ * typ -> term
    68   val mk_split: term -> term
    69   val prodT_factors: typ -> typ list
    70   val mk_tuple: typ -> term list -> term
    71   val dest_tuple: term -> term list
    72   val ap_split: typ -> typ -> term -> term
    73   val prod_factors: term -> int list list
    74   val dest_tuple': int list list -> term -> term list
    75   val prodT_factors': int list list -> typ -> typ list
    76   val ap_split': int list list -> typ -> typ -> term -> term
    77   val mk_tuple': int list list -> typ -> term list -> term
    78   val mk_tupleT: int list list -> typ list -> typ
    79   val strip_split: term -> term * typ list * int list list
    80   val natT: typ
    81   val zero: term
    82   val is_zero: term -> bool
    83   val mk_Suc: term -> term
    84   val dest_Suc: term -> term
    85   val Suc_zero: term
    86   val mk_nat: int -> term
    87   val dest_nat: term -> int
    88   val class_size: string
    89   val size_const: typ -> term
    90   val indexT: typ
    91   val intT: typ
    92   val pls_const: term
    93   val min_const: term
    94   val bit0_const: term
    95   val bit1_const: term
    96   val mk_bit: int -> term
    97   val dest_bit: term -> int
    98   val mk_numeral: int -> term
    99   val dest_numeral: term -> int
   100   val number_of_const: typ -> term
   101   val add_numerals: term -> (term * typ) list -> (term * typ) list
   102   val mk_number: typ -> int -> term
   103   val dest_number: term -> typ * int
   104   val realT: typ
   105   val nibbleT: typ
   106   val mk_nibble: int -> term
   107   val dest_nibble: term -> int
   108   val charT: typ
   109   val mk_char: int -> term
   110   val dest_char: term -> int
   111   val listT: typ -> typ
   112   val nil_const: typ -> term
   113   val cons_const: typ -> term
   114   val mk_list: typ -> term list -> term
   115   val dest_list: term -> term list
   116   val stringT: typ
   117   val mk_string: string -> term
   118   val dest_string: term -> string
   119   val message_stringT: typ
   120   val mk_message_string: string -> term
   121   val dest_message_string: term -> string
   122   val mk_typerep: typ -> term
   123   val mk_term_of: typ -> term -> term
   124   val reflect_term: term -> term
   125 end;
   126 
   127 structure HOLogic: HOLOGIC =
   128 struct
   129 
   130 (* HOL syntax *)
   131 
   132 val typeS: sort = ["HOL.type"];
   133 val typeT = TypeInfer.anyT typeS;
   134 
   135 
   136 (* bool and set *)
   137 
   138 val boolN = "bool";
   139 val boolT = Type (boolN, []);
   140 
   141 val true_const =  Const ("True", boolT);
   142 val false_const = Const ("False", boolT);
   143 
   144 fun mk_setT T = T --> boolT;
   145 
   146 fun dest_setT (Type ("fun", [T, Type ("bool", [])])) = T
   147   | dest_setT T = raise TYPE ("dest_setT: set type expected", [T], []);
   148 
   149 fun mk_set T ts =
   150   let
   151     val sT = mk_setT T;
   152     val empty = Const ("Set.empty", sT);
   153     fun insert t u = Const ("insert", T --> sT --> sT) $ t $ u;
   154   in fold_rev insert ts empty end;
   155 
   156 fun mk_UNIV T = Const ("Set.UNIV", mk_setT T);
   157 
   158 fun dest_set (Const ("Orderings.bot", _)) = []
   159   | dest_set (Const ("insert", _) $ t $ u) = t :: dest_set u
   160   | dest_set t = raise TERM ("dest_set", [t]);
   161 
   162 fun Collect_const T = Const ("Collect", (T --> boolT) --> mk_setT T);
   163 fun mk_Collect (a, T, t) = Collect_const T $ absfree (a, T, t);
   164 
   165 fun mk_mem (x, A) =
   166   let val setT = fastype_of A in
   167     Const ("op :", dest_setT setT --> setT --> boolT) $ x $ A
   168   end;
   169 
   170 fun dest_mem (Const ("op :", _) $ x $ A) = (x, A)
   171   | dest_mem t = raise TERM ("dest_mem", [t]);
   172 
   173 
   174 (* logic *)
   175 
   176 val Trueprop = Const ("Trueprop", boolT --> propT);
   177 
   178 fun mk_Trueprop P = Trueprop $ P;
   179 
   180 fun dest_Trueprop (Const ("Trueprop", _) $ P) = P
   181   | dest_Trueprop t = raise TERM ("dest_Trueprop", [t]);
   182 
   183 fun conj_intr thP thQ =
   184   let
   185     val (P, Q) = pairself (ObjectLogic.dest_judgment o Thm.cprop_of) (thP, thQ)
   186       handle CTERM (msg, _) => raise THM (msg, 0, [thP, thQ]);
   187     val inst = Thm.instantiate ([], [(@{cpat "?P::bool"}, P), (@{cpat "?Q::bool"}, Q)]);
   188   in Drule.implies_elim_list (inst @{thm conjI}) [thP, thQ] end;
   189 
   190 fun conj_elim thPQ =
   191   let
   192     val (P, Q) = Thm.dest_binop (ObjectLogic.dest_judgment (Thm.cprop_of thPQ))
   193       handle CTERM (msg, _) => raise THM (msg, 0, [thPQ]);
   194     val inst = Thm.instantiate ([], [(@{cpat "?P::bool"}, P), (@{cpat "?Q::bool"}, Q)]);
   195     val thP = Thm.implies_elim (inst @{thm conjunct1}) thPQ;
   196     val thQ = Thm.implies_elim (inst @{thm conjunct2}) thPQ;
   197   in (thP, thQ) end;
   198 
   199 fun conj_elims th =
   200   let val (th1, th2) = conj_elim th
   201   in conj_elims th1 @ conj_elims th2 end handle THM _ => [th];
   202 
   203 val conj = @{term "op &"}
   204 and disj = @{term "op |"}
   205 and imp = @{term "op -->"}
   206 and Not = @{term "Not"};
   207 
   208 fun mk_conj (t1, t2) = conj $ t1 $ t2
   209 and mk_disj (t1, t2) = disj $ t1 $ t2
   210 and mk_imp (t1, t2) = imp $ t1 $ t2
   211 and mk_not t = Not $ t;
   212 
   213 fun dest_conj (Const ("op &", _) $ t $ t') = t :: dest_conj t'
   214   | dest_conj t = [t];
   215 
   216 fun dest_disj (Const ("op |", _) $ t $ t') = t :: dest_disj t'
   217   | dest_disj t = [t];
   218 
   219 (*Like dest_disj, but flattens disjunctions however nested*)
   220 fun disjuncts_aux (Const ("op |", _) $ t $ t') disjs = disjuncts_aux t (disjuncts_aux t' disjs)
   221   | disjuncts_aux t disjs = t::disjs;
   222 
   223 fun disjuncts t = disjuncts_aux t [];
   224 
   225 fun dest_imp (Const("op -->",_) $ A $ B) = (A, B)
   226   | dest_imp  t = raise TERM ("dest_imp", [t]);
   227 
   228 fun dest_not (Const ("Not", _) $ t) = t
   229   | dest_not t = raise TERM ("dest_not", [t]);
   230 
   231 fun eq_const T = Const ("op =", [T, T] ---> boolT);
   232 fun mk_eq (t, u) = eq_const (fastype_of t) $ t $ u;
   233 
   234 fun dest_eq (Const ("op =", _) $ lhs $ rhs) = (lhs, rhs)
   235   | dest_eq t = raise TERM ("dest_eq", [t])
   236 
   237 fun all_const T = Const ("All", [T --> boolT] ---> boolT);
   238 fun mk_all (x, T, P) = all_const T $ absfree (x, T, P);
   239 fun list_all (xs, t) = fold_rev (fn (x, T) => fn P => all_const T $ Abs (x, T, P)) xs t;
   240 
   241 fun exists_const T = Const ("Ex", [T --> boolT] ---> boolT);
   242 fun mk_exists (x, T, P) = exists_const T $ absfree (x, T, P);
   243 
   244 fun choice_const T = Const("Hilbert_Choice.Eps", (T --> boolT) --> T);
   245 
   246 val class_eq = "HOL.eq";
   247 
   248 
   249 (* binary operations and relations *)
   250 
   251 fun mk_binop c (t, u) =
   252   let val T = fastype_of t in
   253     Const (c, [T, T] ---> T) $ t $ u
   254   end;
   255 
   256 fun mk_binrel c (t, u) =
   257   let val T = fastype_of t in
   258     Const (c, [T, T] ---> boolT) $ t $ u
   259   end;
   260 
   261 (*destruct the application of a binary operator. The dummyT case is a crude
   262   way of handling polymorphic operators.*)
   263 fun dest_bin c T (tm as Const (c', Type ("fun", [T', _])) $ t $ u) =
   264       if c = c' andalso (T=T' orelse T=dummyT) then (t, u)
   265       else raise TERM ("dest_bin " ^ c, [tm])
   266   | dest_bin c _ tm = raise TERM ("dest_bin " ^ c, [tm]);
   267 
   268 
   269 (* unit *)
   270 
   271 val unitT = Type ("Product_Type.unit", []);
   272 
   273 fun is_unitT (Type ("Product_Type.unit", [])) = true
   274   | is_unitT _ = false;
   275 
   276 val unit = Const ("Product_Type.Unity", unitT);
   277 
   278 fun is_unit (Const ("Product_Type.Unity", _)) = true
   279   | is_unit _ = false;
   280 
   281 
   282 (* prod *)
   283 
   284 fun mk_prodT (T1, T2) = Type ("*", [T1, T2]);
   285 
   286 fun dest_prodT (Type ("*", [T1, T2])) = (T1, T2)
   287   | dest_prodT T = raise TYPE ("dest_prodT", [T], []);
   288 
   289 fun pair_const T1 T2 = Const ("Pair", [T1, T2] ---> mk_prodT (T1, T2));
   290 
   291 fun mk_prod (t1, t2) =
   292   let val T1 = fastype_of t1 and T2 = fastype_of t2 in
   293     pair_const T1 T2 $ t1 $ t2
   294   end;
   295 
   296 fun dest_prod (Const ("Pair", _) $ t1 $ t2) = (t1, t2)
   297   | dest_prod t = raise TERM ("dest_prod", [t]);
   298 
   299 fun mk_fst p =
   300   let val pT = fastype_of p in
   301     Const ("fst", pT --> fst (dest_prodT pT)) $ p
   302   end;
   303 
   304 fun mk_snd p =
   305   let val pT = fastype_of p in
   306     Const ("snd", pT --> snd (dest_prodT pT)) $ p
   307   end;
   308 
   309 fun split_const (A, B, C) =
   310   Const ("split", (A --> B --> C) --> mk_prodT (A, B) --> C);
   311 
   312 fun mk_split t =
   313   (case Term.fastype_of t of
   314     T as (Type ("fun", [A, Type ("fun", [B, C])])) =>
   315       Const ("split", T --> mk_prodT (A, B) --> C) $ t
   316   | _ => raise TERM ("mk_split: bad body type", [t]));
   317 
   318 (*Maps the type T1 * ... * Tn to [T1, ..., Tn], however nested*)
   319 fun prodT_factors (Type ("*", [T1, T2])) = prodT_factors T1 @ prodT_factors T2
   320   | prodT_factors T = [T];
   321 
   322 (*Makes a nested tuple from a list, following the product type structure*)
   323 fun mk_tuple (Type ("*", [T1, T2])) tms =
   324         mk_prod (mk_tuple T1 tms,
   325                  mk_tuple T2 (Library.drop (length (prodT_factors T1), tms)))
   326   | mk_tuple T (t::_) = t;
   327 
   328 fun dest_tuple (Const ("Pair", _) $ t $ u) = dest_tuple t @ dest_tuple u
   329   | dest_tuple t = [t];
   330 
   331 (*In ap_split S T u, term u expects separate arguments for the factors of S,
   332   with result type T.  The call creates a new term expecting one argument
   333   of type S.*)
   334 fun ap_split T T3 u =
   335   let
   336     fun ap (T :: Ts) =
   337           (case T of
   338              Type ("*", [T1, T2]) =>
   339                split_const (T1, T2, Ts ---> T3) $ ap (T1 :: T2 :: Ts)
   340            | _ => Abs ("x", T, ap Ts))
   341       | ap [] =
   342           let val k = length (prodT_factors T)
   343           in list_comb (incr_boundvars k u, map Bound (k - 1 downto 0)) end
   344   in ap [T] end;
   345 
   346 
   347 (* operations on tuples with specific arities *)
   348 (*
   349   an "arity" of a tuple is a list of lists of integers
   350   ("factors"), denoting paths to subterms that are pairs
   351 *)
   352 
   353 fun prod_err s = raise TERM (s ^ ": inconsistent use of products", []);
   354 
   355 fun prod_factors t =
   356   let
   357     fun factors p (Const ("Pair", _) $ t $ u) =
   358           p :: factors (1::p) t @ factors (2::p) u
   359       | factors p _ = []
   360   in factors [] t end;
   361 
   362 fun dest_tuple' ps =
   363   let
   364     fun dest p t = if p mem ps then (case t of
   365         Const ("Pair", _) $ t $ u =>
   366           dest (1::p) t @ dest (2::p) u
   367       | _ => prod_err "dest_tuple'") else [t]
   368   in dest [] end;
   369 
   370 fun prodT_factors' ps =
   371   let
   372     fun factors p T = if p mem ps then (case T of
   373         Type ("*", [T1, T2]) =>
   374           factors (1::p) T1 @ factors (2::p) T2
   375       | _ => prod_err "prodT_factors'") else [T]
   376   in factors [] end;
   377 
   378 (*In ap_split' ps S T u, term u expects separate arguments for the factors of S,
   379   with result type T.  The call creates a new term expecting one argument
   380   of type S.*)
   381 fun ap_split' ps T T3 u =
   382   let
   383     fun ap ((p, T) :: pTs) =
   384           if p mem ps then (case T of
   385               Type ("*", [T1, T2]) =>
   386                 split_const (T1, T2, map snd pTs ---> T3) $
   387                   ap ((1::p, T1) :: (2::p, T2) :: pTs)
   388             | _ => prod_err "ap_split'")
   389           else Abs ("x", T, ap pTs)
   390       | ap [] =
   391           let val k = length ps
   392           in list_comb (incr_boundvars (k + 1) u, map Bound (k downto 0)) end
   393   in ap [([], T)] end;
   394 
   395 fun mk_tuple' ps =
   396   let
   397     fun mk p T ts =
   398       if p mem ps then (case T of
   399           Type ("*", [T1, T2]) =>
   400             let
   401               val (t, ts') = mk (1::p) T1 ts;
   402               val (u, ts'') = mk (2::p) T2 ts'
   403             in (pair_const T1 T2 $ t $ u, ts'') end
   404         | _ => prod_err "mk_tuple'")
   405       else (hd ts, tl ts)
   406   in fst oo mk [] end;
   407 
   408 fun mk_tupleT ps =
   409   let
   410     fun mk p Ts =
   411       if p mem ps then
   412         let
   413           val (T, Ts') = mk (1::p) Ts;
   414           val (U, Ts'') = mk (2::p) Ts'
   415         in (mk_prodT (T, U), Ts'') end
   416       else (hd Ts, tl Ts)
   417   in fst o mk [] end;
   418 
   419 fun strip_split t =
   420   let
   421     fun strip [] qs Ts t = (t, Ts, qs)
   422       | strip (p :: ps) qs Ts (Const ("split", _) $ t) =
   423           strip ((1 :: p) :: (2 :: p) :: ps) (p :: qs) Ts t
   424       | strip (p :: ps) qs Ts (Abs (s, T, t)) = strip ps qs (T :: Ts) t
   425       | strip (p :: ps) qs Ts t = strip ps qs
   426           (hd (binder_types (fastype_of1 (Ts, t))) :: Ts)
   427           (incr_boundvars 1 t $ Bound 0)
   428   in strip [[]] [] [] t end;
   429 
   430 
   431 (* nat *)
   432 
   433 val natT = Type ("nat", []);
   434 
   435 val zero = Const ("HOL.zero_class.zero", natT);
   436 
   437 fun is_zero (Const ("HOL.zero_class.zero", _)) = true
   438   | is_zero _ = false;
   439 
   440 fun mk_Suc t = Const ("Suc", natT --> natT) $ t;
   441 
   442 fun dest_Suc (Const ("Suc", _) $ t) = t
   443   | dest_Suc t = raise TERM ("dest_Suc", [t]);
   444 
   445 val Suc_zero = mk_Suc zero;
   446 
   447 fun mk_nat n =
   448   let
   449     fun mk 0 = zero
   450       | mk n = mk_Suc (mk (n - 1));
   451   in if n < 0 then raise TERM ("mk_nat: negative number", []) else mk n end;
   452 
   453 fun dest_nat (Const ("HOL.zero_class.zero", _)) = 0
   454   | dest_nat (Const ("Suc", _) $ t) = dest_nat t + 1
   455   | dest_nat t = raise TERM ("dest_nat", [t]);
   456 
   457 val class_size = "Nat.size";
   458 
   459 fun size_const T = Const ("Nat.size_class.size", T --> natT);
   460 
   461 
   462 (* index *)
   463 
   464 val indexT = Type ("Code_Index.index", []);
   465 
   466 
   467 (* binary numerals and int -- non-unique representation due to leading zeros/ones! *)
   468 
   469 val intT = Type ("Int.int", []);
   470 
   471 val pls_const = Const ("Int.Pls", intT)
   472 and min_const = Const ("Int.Min", intT)
   473 and bit0_const = Const ("Int.Bit0", intT --> intT)
   474 and bit1_const = Const ("Int.Bit1", intT --> intT);
   475 
   476 fun mk_bit 0 = bit0_const
   477   | mk_bit 1 = bit1_const
   478   | mk_bit _ = raise TERM ("mk_bit", []);
   479 
   480 fun dest_bit (Const ("Int.Bit0", _)) = 0
   481   | dest_bit (Const ("Int.Bit1", _)) = 1
   482   | dest_bit t = raise TERM ("dest_bit", [t]);
   483 
   484 fun mk_numeral 0 = pls_const
   485   | mk_numeral ~1 = min_const
   486   | mk_numeral i =
   487       let val (q, r) = Integer.div_mod i 2;
   488       in mk_bit r $ mk_numeral q end;
   489 
   490 fun dest_numeral (Const ("Int.Pls", _)) = 0
   491   | dest_numeral (Const ("Int.Min", _)) = ~1
   492   | dest_numeral (Const ("Int.Bit0", _) $ bs) = 2 * dest_numeral bs
   493   | dest_numeral (Const ("Int.Bit1", _) $ bs) = 2 * dest_numeral bs + 1
   494   | dest_numeral t = raise TERM ("dest_numeral", [t]);
   495 
   496 fun number_of_const T = Const ("Int.number_class.number_of", intT --> T);
   497 
   498 fun add_numerals (Const ("Int.number_class.number_of", Type (_, [_, T])) $ t) = cons (t, T)
   499   | add_numerals (t $ u) = add_numerals t #> add_numerals u
   500   | add_numerals (Abs (_, _, t)) = add_numerals t
   501   | add_numerals _ = I;
   502 
   503 fun mk_number T 0 = Const ("HOL.zero_class.zero", T)
   504   | mk_number T 1 = Const ("HOL.one_class.one", T)
   505   | mk_number T i = number_of_const T $ mk_numeral i;
   506 
   507 fun dest_number (Const ("HOL.zero_class.zero", T)) = (T, 0)
   508   | dest_number (Const ("HOL.one_class.one", T)) = (T, 1)
   509   | dest_number (Const ("Int.number_class.number_of", Type ("fun", [_, T])) $ t) =
   510       (T, dest_numeral t)
   511   | dest_number t = raise TERM ("dest_number", [t]);
   512 
   513 
   514 (* real *)
   515 
   516 val realT = Type ("RealDef.real", []);
   517 
   518 
   519 (* list *)
   520 
   521 fun listT T = Type ("List.list", [T]);
   522 
   523 fun nil_const T = Const ("List.list.Nil", listT T);
   524 
   525 fun cons_const T =
   526   let val lT = listT T
   527   in Const ("List.list.Cons", T --> lT --> lT) end;
   528 
   529 fun mk_list T ts =
   530   let
   531     val lT = listT T;
   532     val Nil = Const ("List.list.Nil", lT);
   533     fun Cons t u = Const ("List.list.Cons", T --> lT --> lT) $ t $ u;
   534   in fold_rev Cons ts Nil end;
   535 
   536 fun dest_list (Const ("List.list.Nil", _)) = []
   537   | dest_list (Const ("List.list.Cons", _) $ t $ u) = t :: dest_list u
   538   | dest_list t = raise TERM ("dest_list", [t]);
   539 
   540 
   541 (* nibble *)
   542 
   543 val nibbleT = Type ("String.nibble", []);
   544 
   545 fun mk_nibble n =
   546   let val s =
   547     if 0 <= n andalso n <= 9 then chr (n + ord "0")
   548     else if 10 <= n andalso n <= 15 then chr (n + ord "A" - 10)
   549     else raise TERM ("mk_nibble", [])
   550   in Const ("String.nibble.Nibble" ^ s, nibbleT) end;
   551 
   552 fun dest_nibble t =
   553   let fun err () = raise TERM ("dest_nibble", [t]) in
   554     (case try (unprefix "String.nibble.Nibble" o fst o Term.dest_Const) t of
   555       NONE => err ()
   556     | SOME c =>
   557         if size c <> 1 then err ()
   558         else if "0" <= c andalso c <= "9" then ord c - ord "0"
   559         else if "A" <= c andalso c <= "F" then ord c - ord "A" + 10
   560         else err ())
   561   end;
   562 
   563 
   564 (* char *)
   565 
   566 val charT = Type ("String.char", []);
   567 
   568 fun mk_char n =
   569   if 0 <= n andalso n <= 255 then
   570     Const ("String.char.Char", nibbleT --> nibbleT --> charT) $
   571       mk_nibble (n div 16) $ mk_nibble (n mod 16)
   572   else raise TERM ("mk_char", []);
   573 
   574 fun dest_char (Const ("String.char.Char", _) $ t $ u) =
   575       dest_nibble t * 16 + dest_nibble u
   576   | dest_char t = raise TERM ("dest_char", [t]);
   577 
   578 
   579 (* string *)
   580 
   581 val stringT = Type ("String.string", []);
   582 
   583 val mk_string = mk_list charT o map (mk_char o ord) o explode;
   584 val dest_string = implode o map (chr o dest_char) o dest_list;
   585 
   586 
   587 (* message_string *)
   588 
   589 val message_stringT = Type ("String.message_string", []);
   590 
   591 fun mk_message_string s = Const ("String.message_string.STR", stringT --> message_stringT)
   592       $ mk_string s;
   593 fun dest_message_string (Const ("String.message_string.STR", _) $ t) =
   594       dest_string t
   595   | dest_message_string t = raise TERM ("dest_message_string", [t]);
   596 
   597 
   598 (* typerep and term *)
   599 
   600 val typerepT = Type ("Typerep.typerep", []);
   601 
   602 fun mk_typerep T = Const ("Typerep.typerep_class.typerep",
   603   Term.itselfT T --> typerepT) $ Logic.mk_type T;
   604 
   605 val termT = Type ("Code_Eval.term", []);
   606 
   607 fun mk_term_of T t = Const ("Code_Eval.term_of_class.term_of", T --> termT) $ t;
   608 
   609 fun reflect_term (Const (c, T)) =
   610       Const ("Code_Eval.Const", message_stringT --> typerepT --> termT)
   611         $ mk_message_string c $ mk_typerep T
   612   | reflect_term (t1 $ t2) =
   613       Const ("Code_Eval.App", termT --> termT --> termT)
   614         $ reflect_term t1 $ reflect_term t2
   615   | reflect_term (t as Free _) = t
   616   | reflect_term (t as Bound _) = t
   617   | reflect_term (Abs (v, _, t)) = Abs (v, termT, reflect_term t);
   618 
   619 end;