src/Pure/drule.ML
author wenzelm
Sun Nov 11 21:30:10 2001 +0100 (2001-11-11)
changeset 12135 e370e5d469c2
parent 12126 34f72eb7d2db
child 12221 cc31140bba16
permissions -rw-r--r--
added conj_elim_precise, conj_intr_thm;
     1 (*  Title:      Pure/drule.ML
     2     ID:         $Id$
     3     Author:     Lawrence C Paulson, Cambridge University Computer Laboratory
     4     Copyright   1993  University of Cambridge
     5 
     6 Derived rules and other operations on theorems.
     7 *)
     8 
     9 infix 0 RS RSN RL RLN MRS MRL OF COMP;
    10 
    11 signature BASIC_DRULE =
    12 sig
    13   val mk_implies        : cterm * cterm -> cterm
    14   val list_implies      : cterm list * cterm -> cterm
    15   val dest_implies      : cterm -> cterm * cterm
    16   val dest_equals       : cterm -> cterm * cterm
    17   val skip_flexpairs    : cterm -> cterm
    18   val strip_imp_prems   : cterm -> cterm list
    19   val strip_imp_concl   : cterm -> cterm
    20   val cprems_of         : thm -> cterm list
    21   val read_insts        :
    22           Sign.sg -> (indexname -> typ option) * (indexname -> sort option)
    23                   -> (indexname -> typ option) * (indexname -> sort option)
    24                   -> string list -> (string*string)list
    25                   -> (indexname*ctyp)list * (cterm*cterm)list
    26   val types_sorts: thm -> (indexname-> typ option) * (indexname-> sort option)
    27   val strip_shyps_warning : thm -> thm
    28   val forall_intr_list  : cterm list -> thm -> thm
    29   val forall_intr_frees : thm -> thm
    30   val forall_intr_vars  : thm -> thm
    31   val forall_elim_list  : cterm list -> thm -> thm
    32   val forall_elim_var   : int -> thm -> thm
    33   val forall_elim_vars  : int -> thm -> thm
    34   val forall_elim_vars_safe  : thm -> thm
    35   val freeze_thaw       : thm -> thm * (thm -> thm)
    36   val implies_elim_list : thm -> thm list -> thm
    37   val implies_intr_list : cterm list -> thm -> thm
    38   val instantiate       :
    39     (indexname * ctyp) list * (cterm * cterm) list -> thm -> thm
    40   val zero_var_indexes  : thm -> thm
    41   val standard          : thm -> thm
    42   val standard'         : thm -> thm
    43   val rotate_prems      : int -> thm -> thm
    44   val rearrange_prems   : int list -> thm -> thm
    45   val assume_ax         : theory -> string -> thm
    46   val RSN               : thm * (int * thm) -> thm
    47   val RS                : thm * thm -> thm
    48   val RLN               : thm list * (int * thm list) -> thm list
    49   val RL                : thm list * thm list -> thm list
    50   val MRS               : thm list * thm -> thm
    51   val MRL               : thm list list * thm list -> thm list
    52   val OF                : thm * thm list -> thm
    53   val compose           : thm * int * thm -> thm list
    54   val COMP              : thm * thm -> thm
    55   val read_instantiate_sg: Sign.sg -> (string*string)list -> thm -> thm
    56   val read_instantiate  : (string*string)list -> thm -> thm
    57   val cterm_instantiate : (cterm*cterm)list -> thm -> thm
    58   val weak_eq_thm       : thm * thm -> bool
    59   val eq_thm_sg         : thm * thm -> bool
    60   val size_of_thm       : thm -> int
    61   val reflexive_thm     : thm
    62   val symmetric_thm     : thm
    63   val transitive_thm    : thm
    64   val refl_implies      : thm
    65   val symmetric_fun     : thm -> thm
    66   val extensional       : thm -> thm
    67   val imp_cong          : thm
    68   val swap_prems_eq     : thm
    69   val equal_abs_elim    : cterm  -> thm -> thm
    70   val equal_abs_elim_list: cterm list -> thm -> thm
    71   val flexpair_abs_elim_list: cterm list -> thm -> thm
    72   val asm_rl            : thm
    73   val cut_rl            : thm
    74   val revcut_rl         : thm
    75   val thin_rl           : thm
    76   val triv_forall_equality: thm
    77   val swap_prems_rl     : thm
    78   val equal_intr_rule   : thm
    79   val inst              : string -> string -> thm -> thm
    80   val instantiate'      : ctyp option list -> cterm option list -> thm -> thm
    81   val incr_indexes_wrt  : int list -> ctyp list -> cterm list -> thm list -> thm -> thm
    82 end;
    83 
    84 signature DRULE =
    85 sig
    86   include BASIC_DRULE
    87   val rule_attribute: ('a -> thm -> thm) -> 'a attribute
    88   val tag_rule: tag -> thm -> thm
    89   val untag_rule: string -> thm -> thm
    90   val tag: tag -> 'a attribute
    91   val untag: string -> 'a attribute
    92   val get_kind: thm -> string
    93   val kind: string -> 'a attribute
    94   val theoremK: string
    95   val lemmaK: string
    96   val corollaryK: string
    97   val internalK: string
    98   val kind_internal: 'a attribute
    99   val has_internal: tag list -> bool
   100   val impose_hyps: cterm list -> thm -> thm
   101   val close_derivation: thm -> thm
   102   val local_standard: thm -> thm
   103   val compose_single: thm * int * thm -> thm
   104   val add_rules: thm list -> thm list -> thm list
   105   val del_rules: thm list -> thm list -> thm list
   106   val merge_rules: thm list * thm list -> thm list
   107   val norm_hhf_eq: thm
   108   val triv_goal: thm
   109   val rev_triv_goal: thm
   110   val implies_intr_goals: cterm list -> thm -> thm
   111   val freeze_all: thm -> thm
   112   val mk_triv_goal: cterm -> thm
   113   val add_tvarsT: (indexname * sort) list * typ -> (indexname * sort) list
   114   val add_tvars: (indexname * sort) list * term -> (indexname * sort) list
   115   val add_vars: (indexname * typ) list * term -> (indexname * typ) list
   116   val add_frees: (string * typ) list * term -> (string * typ) list
   117   val tvars_of_terms: term list -> (indexname * sort) list
   118   val vars_of_terms: term list -> (indexname * typ) list
   119   val tvars_of: thm -> (indexname * sort) list
   120   val vars_of: thm -> (indexname * typ) list
   121   val unvarifyT: thm -> thm
   122   val unvarify: thm -> thm
   123   val tvars_intr_list: string list -> thm -> thm
   124   val conj_intr: thm -> thm -> thm
   125   val conj_intr_list: thm list -> thm
   126   val conj_elim: thm -> thm * thm
   127   val conj_elim_list: thm -> thm list
   128   val conj_elim_precise: int -> thm -> thm list
   129   val conj_intr_thm: thm
   130 end;
   131 
   132 structure Drule: DRULE =
   133 struct
   134 
   135 
   136 (** some cterm->cterm operations: much faster than calling cterm_of! **)
   137 
   138 (** SAME NAMES as in structure Logic: use compound identifiers! **)
   139 
   140 (*dest_implies for cterms. Note T=prop below*)
   141 fun dest_implies ct =
   142     case term_of ct of
   143         (Const("==>", _) $ _ $ _) =>
   144             let val (ct1,ct2) = Thm.dest_comb ct
   145             in  (#2 (Thm.dest_comb ct1), ct2)  end
   146       | _ => raise TERM ("dest_implies", [term_of ct]) ;
   147 
   148 fun dest_equals ct =
   149     case term_of ct of
   150         (Const("==", _) $ _ $ _) =>
   151             let val (ct1,ct2) = Thm.dest_comb ct
   152             in  (#2 (Thm.dest_comb ct1), ct2)  end
   153       | _ => raise TERM ("dest_equals", [term_of ct]) ;
   154 
   155 
   156 (*Discard flexflex pairs; return a cterm*)
   157 fun skip_flexpairs ct =
   158     case term_of ct of
   159         (Const("==>", _) $ (Const("=?=",_)$_$_) $ _) =>
   160             skip_flexpairs (#2 (dest_implies ct))
   161       | _ => ct;
   162 
   163 (* A1==>...An==>B  goes to  [A1,...,An], where B is not an implication *)
   164 fun strip_imp_prems ct =
   165     let val (cA,cB) = dest_implies ct
   166     in  cA :: strip_imp_prems cB  end
   167     handle TERM _ => [];
   168 
   169 (* A1==>...An==>B  goes to B, where B is not an implication *)
   170 fun strip_imp_concl ct =
   171     case term_of ct of (Const("==>", _) $ _ $ _) =>
   172         strip_imp_concl (#2 (Thm.dest_comb ct))
   173   | _ => ct;
   174 
   175 (*The premises of a theorem, as a cterm list*)
   176 val cprems_of = strip_imp_prems o skip_flexpairs o cprop_of;
   177 
   178 val proto_sign = Theory.sign_of ProtoPure.thy;
   179 
   180 val implies = cterm_of proto_sign Term.implies;
   181 
   182 (*cterm version of mk_implies*)
   183 fun mk_implies(A,B) = Thm.capply (Thm.capply implies A) B;
   184 
   185 (*cterm version of list_implies: [A1,...,An], B  goes to [|A1;==>;An|]==>B *)
   186 fun list_implies([], B) = B
   187   | list_implies(A::AS, B) = mk_implies (A, list_implies(AS,B));
   188 
   189 
   190 (** reading of instantiations **)
   191 
   192 fun absent ixn =
   193   error("No such variable in term: " ^ Syntax.string_of_vname ixn);
   194 
   195 fun inst_failure ixn =
   196   error("Instantiation of " ^ Syntax.string_of_vname ixn ^ " fails");
   197 
   198 fun read_insts sign (rtypes,rsorts) (types,sorts) used insts =
   199 let
   200     fun split([],tvs,vs) = (tvs,vs)
   201       | split((sv,st)::l,tvs,vs) = (case Symbol.explode sv of
   202                   "'"::cs => split(l,(Syntax.indexname cs,st)::tvs,vs)
   203                 | cs => split(l,tvs,(Syntax.indexname cs,st)::vs));
   204     val (tvs,vs) = split(insts,[],[]);
   205     fun readT((a,i),st) =
   206         let val ixn = ("'" ^ a,i);
   207             val S = case rsorts ixn of Some S => S | None => absent ixn;
   208             val T = Sign.read_typ (sign,sorts) st;
   209         in if Sign.typ_instance sign (T, TVar(ixn,S)) then (ixn,T)
   210            else inst_failure ixn
   211         end
   212     val tye = map readT tvs;
   213     fun mkty(ixn,st) = (case rtypes ixn of
   214                           Some T => (ixn,(st,typ_subst_TVars tye T))
   215                         | None => absent ixn);
   216     val ixnsTs = map mkty vs;
   217     val ixns = map fst ixnsTs
   218     and sTs  = map snd ixnsTs
   219     val (cts,tye2) = read_def_cterms(sign,types,sorts) used false sTs;
   220     fun mkcVar(ixn,T) =
   221         let val U = typ_subst_TVars tye2 T
   222         in cterm_of sign (Var(ixn,U)) end
   223     val ixnTs = ListPair.zip(ixns, map snd sTs)
   224 in (map (fn (ixn,T) => (ixn,ctyp_of sign T)) (tye2 @ tye),
   225     ListPair.zip(map mkcVar ixnTs,cts))
   226 end;
   227 
   228 
   229 (*** Find the type (sort) associated with a (T)Var or (T)Free in a term
   230      Used for establishing default types (of variables) and sorts (of
   231      type variables) when reading another term.
   232      Index -1 indicates that a (T)Free rather than a (T)Var is wanted.
   233 ***)
   234 
   235 fun types_sorts thm =
   236     let val {prop,hyps,...} = rep_thm thm;
   237         val big = list_comb(prop,hyps); (* bogus term! *)
   238         val vars = map dest_Var (term_vars big);
   239         val frees = map dest_Free (term_frees big);
   240         val tvars = term_tvars big;
   241         val tfrees = term_tfrees big;
   242         fun typ(a,i) = if i<0 then assoc(frees,a) else assoc(vars,(a,i));
   243         fun sort(a,i) = if i<0 then assoc(tfrees,a) else assoc(tvars,(a,i));
   244     in (typ,sort) end;
   245 
   246 
   247 
   248 (** basic attributes **)
   249 
   250 (* dependent rules *)
   251 
   252 fun rule_attribute f (x, thm) = (x, (f x thm));
   253 
   254 
   255 (* add / delete tags *)
   256 
   257 fun map_tags f thm =
   258   Thm.put_name_tags (Thm.name_of_thm thm, f (#2 (Thm.get_name_tags thm))) thm;
   259 
   260 fun tag_rule tg = map_tags (fn tgs => if tg mem tgs then tgs else tgs @ [tg]);
   261 fun untag_rule s = map_tags (filter_out (equal s o #1));
   262 
   263 fun tag tg x = rule_attribute (K (tag_rule tg)) x;
   264 fun untag s x = rule_attribute (K (untag_rule s)) x;
   265 
   266 fun simple_tag name x = tag (name, []) x;
   267 
   268 
   269 (* theorem kinds *)
   270 
   271 val theoremK = "theorem";
   272 val lemmaK = "lemma";
   273 val corollaryK = "corollary";
   274 val internalK = "internal";
   275 
   276 fun get_kind thm =
   277   (case Library.assoc (#2 (Thm.get_name_tags thm), "kind") of
   278     Some (k :: _) => k
   279   | _ => "unknown");
   280 
   281 fun kind_rule k = tag_rule ("kind", [k]) o untag_rule "kind";
   282 fun kind k x = rule_attribute (K (kind_rule k)) x;
   283 fun kind_internal x = kind internalK x;
   284 fun has_internal tags = exists (equal internalK o fst) tags;
   285 
   286 
   287 
   288 (** Standardization of rules **)
   289 
   290 (*Strip extraneous shyps as far as possible*)
   291 fun strip_shyps_warning thm =
   292   let
   293     val str_of_sort = Sign.str_of_sort (Thm.sign_of_thm thm);
   294     val thm' = Thm.strip_shyps thm;
   295     val xshyps = Thm.extra_shyps thm';
   296   in
   297     if null xshyps then ()
   298     else warning ("Pending sort hypotheses: " ^ commas (map str_of_sort xshyps));
   299     thm'
   300   end;
   301 
   302 (*Generalization over a list of variables, IGNORING bad ones*)
   303 fun forall_intr_list [] th = th
   304   | forall_intr_list (y::ys) th =
   305         let val gth = forall_intr_list ys th
   306         in  forall_intr y gth   handle THM _ =>  gth  end;
   307 
   308 (*Generalization over all suitable Free variables*)
   309 fun forall_intr_frees th =
   310     let val {prop,sign,...} = rep_thm th
   311     in  forall_intr_list
   312          (map (cterm_of sign) (sort (make_ord atless) (term_frees prop)))
   313          th
   314     end;
   315 
   316 val forall_elim_var = PureThy.forall_elim_var;
   317 val forall_elim_vars = PureThy.forall_elim_vars;
   318 
   319 fun forall_elim_vars_safe th =
   320   forall_elim_vars_safe (forall_elim_var (#maxidx (Thm.rep_thm th) + 1) th)
   321     handle THM _ => th;
   322 
   323 
   324 (*Specialization over a list of cterms*)
   325 fun forall_elim_list cts th = foldr (uncurry forall_elim) (rev cts, th);
   326 
   327 (* maps A1,...,An |- B   to   [| A1;...;An |] ==> B  *)
   328 fun implies_intr_list cAs th = foldr (uncurry implies_intr) (cAs,th);
   329 
   330 (* maps [| A1;...;An |] ==> B and [A1,...,An]   to   B *)
   331 fun implies_elim_list impth ths = foldl (uncurry implies_elim) (impth,ths);
   332 
   333 (* maps |- B to A1,...,An |- B *)
   334 fun impose_hyps chyps th =
   335   let val chyps' = gen_rems (op aconv o apfst Thm.term_of) (chyps, #hyps (Thm.rep_thm th))
   336   in implies_elim_list (implies_intr_list chyps' th) (map Thm.assume chyps') end;
   337 
   338 (*Reset Var indexes to zero, renaming to preserve distinctness*)
   339 fun zero_var_indexes th =
   340     let val {prop,sign,...} = rep_thm th;
   341         val vars = term_vars prop
   342         val bs = foldl add_new_id ([], map (fn Var((a,_),_)=>a) vars)
   343         val inrs = add_term_tvars(prop,[]);
   344         val nms' = rev(foldl add_new_id ([], map (#1 o #1) inrs));
   345         val tye = ListPair.map (fn ((v,rs),a) => (v, TVar((a,0),rs)))
   346                      (inrs, nms')
   347         val ctye = map (fn (v,T) => (v,ctyp_of sign T)) tye;
   348         fun varpairs([],[]) = []
   349           | varpairs((var as Var(v,T)) :: vars, b::bs) =
   350                 let val T' = typ_subst_TVars tye T
   351                 in (cterm_of sign (Var(v,T')),
   352                     cterm_of sign (Var((b,0),T'))) :: varpairs(vars,bs)
   353                 end
   354           | varpairs _ = raise TERM("varpairs", []);
   355     in Thm.instantiate (ctye, varpairs(vars,rev bs)) th end;
   356 
   357 
   358 (*Standard form of object-rule: no hypotheses, Frees, or outer quantifiers;
   359     all generality expressed by Vars having index 0.*)
   360 
   361 fun close_derivation thm =
   362   if Thm.get_name_tags thm = ("", []) then Thm.name_thm ("", thm)
   363   else thm;
   364 
   365 fun standard' th =
   366   let val {maxidx,...} = rep_thm th in
   367     th
   368     |> implies_intr_hyps
   369     |> forall_intr_frees |> forall_elim_vars (maxidx + 1)
   370     |> strip_shyps_warning
   371     |> zero_var_indexes |> Thm.varifyT |> Thm.compress
   372   end;
   373 
   374 val standard = close_derivation o standard';
   375 
   376 fun local_standard th =
   377   th |> strip_shyps_warning |> zero_var_indexes
   378   |> Thm.compress |> close_derivation;
   379 
   380 
   381 (*Convert all Vars in a theorem to Frees.  Also return a function for
   382   reversing that operation.  DOES NOT WORK FOR TYPE VARIABLES.
   383   Similar code in type/freeze_thaw*)
   384 fun freeze_thaw th =
   385  let val fth = freezeT th
   386      val {prop,sign,...} = rep_thm fth
   387  in
   388    case term_vars prop of
   389        [] => (fth, fn x => x)
   390      | vars =>
   391          let fun newName (Var(ix,_), (pairs,used)) =
   392                    let val v = variant used (string_of_indexname ix)
   393                    in  ((ix,v)::pairs, v::used)  end;
   394              val (alist, _) = foldr newName
   395                                 (vars, ([], add_term_names (prop, [])))
   396              fun mk_inst (Var(v,T)) =
   397                  (cterm_of sign (Var(v,T)),
   398                   cterm_of sign (Free(the (assoc(alist,v)), T)))
   399              val insts = map mk_inst vars
   400              fun thaw th' =
   401                  th' |> forall_intr_list (map #2 insts)
   402                      |> forall_elim_list (map #1 insts)
   403          in  (Thm.instantiate ([],insts) fth, thaw)  end
   404  end;
   405 
   406 
   407 (*Rotates a rule's premises to the left by k*)
   408 val rotate_prems = permute_prems 0;
   409 
   410 (* permute prems, where the i-th position in the argument list (counting from 0)
   411    gives the position within the original thm to be transferred to position i.
   412    Any remaining trailing positions are left unchanged. *)
   413 val rearrange_prems = let
   414   fun rearr new []      thm = thm
   415   |   rearr new (p::ps) thm = rearr (new+1)
   416      (map (fn q => if new<=q andalso q<p then q+1 else q) ps)
   417      (permute_prems (new+1) (new-p) (permute_prems new (p-new) thm))
   418   in rearr 0 end;
   419 
   420 (*Assume a new formula, read following the same conventions as axioms.
   421   Generalizes over Free variables,
   422   creates the assumption, and then strips quantifiers.
   423   Example is [| ALL x:?A. ?P(x) |] ==> [| ?P(?a) |]
   424              [ !(A,P,a)[| ALL x:A. P(x) |] ==> [| P(a) |] ]    *)
   425 fun assume_ax thy sP =
   426     let val sign = Theory.sign_of thy
   427         val prop = Logic.close_form (term_of (read_cterm sign (sP, propT)))
   428     in forall_elim_vars 0 (assume (cterm_of sign prop))  end;
   429 
   430 (*Resolution: exactly one resolvent must be produced.*)
   431 fun tha RSN (i,thb) =
   432   case Seq.chop (2, biresolution false [(false,tha)] i thb) of
   433       ([th],_) => th
   434     | ([],_)   => raise THM("RSN: no unifiers", i, [tha,thb])
   435     |      _   => raise THM("RSN: multiple unifiers", i, [tha,thb]);
   436 
   437 (*resolution: P==>Q, Q==>R gives P==>R. *)
   438 fun tha RS thb = tha RSN (1,thb);
   439 
   440 (*For joining lists of rules*)
   441 fun thas RLN (i,thbs) =
   442   let val resolve = biresolution false (map (pair false) thas) i
   443       fun resb thb = Seq.list_of (resolve thb) handle THM _ => []
   444   in  List.concat (map resb thbs)  end;
   445 
   446 fun thas RL thbs = thas RLN (1,thbs);
   447 
   448 (*Resolve a list of rules against bottom_rl from right to left;
   449   makes proof trees*)
   450 fun rls MRS bottom_rl =
   451   let fun rs_aux i [] = bottom_rl
   452         | rs_aux i (rl::rls) = rl RSN (i, rs_aux (i+1) rls)
   453   in  rs_aux 1 rls  end;
   454 
   455 (*As above, but for rule lists*)
   456 fun rlss MRL bottom_rls =
   457   let fun rs_aux i [] = bottom_rls
   458         | rs_aux i (rls::rlss) = rls RLN (i, rs_aux (i+1) rlss)
   459   in  rs_aux 1 rlss  end;
   460 
   461 (*A version of MRS with more appropriate argument order*)
   462 fun bottom_rl OF rls = rls MRS bottom_rl;
   463 
   464 (*compose Q and [...,Qi,Q(i+1),...]==>R to [...,Q(i+1),...]==>R
   465   with no lifting or renaming!  Q may contain ==> or meta-quants
   466   ALWAYS deletes premise i *)
   467 fun compose(tha,i,thb) =
   468     Seq.list_of (bicompose false (false,tha,0) i thb);
   469 
   470 fun compose_single (tha,i,thb) =
   471   (case compose (tha,i,thb) of
   472     [th] => th
   473   | _ => raise THM ("compose: unique result expected", i, [tha,thb]));
   474 
   475 (*compose Q and [Q1,Q2,...,Qk]==>R to [Q2,...,Qk]==>R getting unique result*)
   476 fun tha COMP thb =
   477     case compose(tha,1,thb) of
   478         [th] => th
   479       | _ =>   raise THM("COMP", 1, [tha,thb]);
   480 
   481 (** theorem equality **)
   482 
   483 (*Do the two theorems have the same signature?*)
   484 fun eq_thm_sg (th1,th2) = Sign.eq_sg(#sign(rep_thm th1), #sign(rep_thm th2));
   485 
   486 (*Useful "distance" function for BEST_FIRST*)
   487 val size_of_thm = size_of_term o #prop o rep_thm;
   488 
   489 (*maintain lists of theorems --- preserving canonical order*)
   490 fun del_rules rs rules = Library.gen_rems Thm.eq_thm (rules, rs);
   491 fun add_rules rs rules = rs @ del_rules rs rules;
   492 fun merge_rules (rules1, rules2) = Library.generic_merge Thm.eq_thm I I rules1 rules2;
   493 
   494 
   495 (** Mark Staples's weaker version of eq_thm: ignores variable renaming and
   496     (some) type variable renaming **)
   497 
   498  (* Can't use term_vars, because it sorts the resulting list of variable names.
   499     We instead need the unique list noramlised by the order of appearance
   500     in the term. *)
   501 fun term_vars' (t as Var(v,T)) = [t]
   502   | term_vars' (Abs(_,_,b)) = term_vars' b
   503   | term_vars' (f$a) = (term_vars' f) @ (term_vars' a)
   504   | term_vars' _ = [];
   505 
   506 fun forall_intr_vars th =
   507   let val {prop,sign,...} = rep_thm th;
   508       val vars = distinct (term_vars' prop);
   509   in forall_intr_list (map (cterm_of sign) vars) th end;
   510 
   511 fun weak_eq_thm (tha,thb) =
   512     eq_thm(forall_intr_vars (freezeT tha), forall_intr_vars (freezeT thb));
   513 
   514 
   515 
   516 (*** Meta-Rewriting Rules ***)
   517 
   518 fun read_prop s = read_cterm proto_sign (s, propT);
   519 
   520 fun store_thm name thm = hd (PureThy.smart_store_thms (name, [thm]));
   521 fun store_standard_thm name thm = store_thm name (standard thm);
   522 fun store_thm_open name thm = hd (PureThy.smart_store_thms_open (name, [thm]));
   523 fun store_standard_thm_open name thm = store_thm_open name (standard' thm);
   524 
   525 val reflexive_thm =
   526   let val cx = cterm_of proto_sign (Var(("x",0),TVar(("'a",0),logicS)))
   527   in store_standard_thm_open "reflexive" (Thm.reflexive cx) end;
   528 
   529 val symmetric_thm =
   530   let val xy = read_prop "x::'a::logic == y"
   531   in store_standard_thm_open "symmetric" (Thm.implies_intr_hyps (Thm.symmetric (Thm.assume xy))) end;
   532 
   533 val transitive_thm =
   534   let val xy = read_prop "x::'a::logic == y"
   535       val yz = read_prop "y::'a::logic == z"
   536       val xythm = Thm.assume xy and yzthm = Thm.assume yz
   537   in store_standard_thm_open "transitive" (Thm.implies_intr yz (Thm.transitive xythm yzthm)) end;
   538 
   539 fun symmetric_fun thm = thm RS symmetric_thm;
   540 
   541 fun extensional eq =
   542   let val eq' =
   543     abstract_rule "x" (snd (Thm.dest_comb (fst (dest_equals (cprop_of eq))))) eq
   544   in equal_elim (eta_conversion (cprop_of eq')) eq' end;
   545 
   546 val imp_cong =
   547   let
   548     val ABC = read_prop "PROP A ==> PROP B == PROP C"
   549     val AB = read_prop "PROP A ==> PROP B"
   550     val AC = read_prop "PROP A ==> PROP C"
   551     val A = read_prop "PROP A"
   552   in
   553     store_standard_thm_open "imp_cong" (implies_intr ABC (equal_intr
   554       (implies_intr AB (implies_intr A
   555         (equal_elim (implies_elim (assume ABC) (assume A))
   556           (implies_elim (assume AB) (assume A)))))
   557       (implies_intr AC (implies_intr A
   558         (equal_elim (symmetric (implies_elim (assume ABC) (assume A)))
   559           (implies_elim (assume AC) (assume A)))))))
   560   end;
   561 
   562 val swap_prems_eq =
   563   let
   564     val ABC = read_prop "PROP A ==> PROP B ==> PROP C"
   565     val BAC = read_prop "PROP B ==> PROP A ==> PROP C"
   566     val A = read_prop "PROP A"
   567     val B = read_prop "PROP B"
   568   in
   569     store_standard_thm_open "swap_prems_eq" (equal_intr
   570       (implies_intr ABC (implies_intr B (implies_intr A
   571         (implies_elim (implies_elim (assume ABC) (assume A)) (assume B)))))
   572       (implies_intr BAC (implies_intr A (implies_intr B
   573         (implies_elim (implies_elim (assume BAC) (assume B)) (assume A))))))
   574   end;
   575 
   576 val refl_implies = reflexive implies;
   577 
   578 
   579 (*** Some useful meta-theorems ***)
   580 
   581 (*The rule V/V, obtains assumption solving for eresolve_tac*)
   582 val asm_rl = store_standard_thm_open "asm_rl" (Thm.trivial (read_prop "PROP ?psi"));
   583 val _ = store_thm "_" asm_rl;
   584 
   585 (*Meta-level cut rule: [| V==>W; V |] ==> W *)
   586 val cut_rl =
   587   store_standard_thm_open "cut_rl"
   588     (Thm.trivial (read_prop "PROP ?psi ==> PROP ?theta"));
   589 
   590 (*Generalized elim rule for one conclusion; cut_rl with reversed premises:
   591      [| PROP V;  PROP V ==> PROP W |] ==> PROP W *)
   592 val revcut_rl =
   593   let val V = read_prop "PROP V"
   594       and VW = read_prop "PROP V ==> PROP W";
   595   in
   596     store_standard_thm_open "revcut_rl"
   597       (implies_intr V (implies_intr VW (implies_elim (assume VW) (assume V))))
   598   end;
   599 
   600 (*for deleting an unwanted assumption*)
   601 val thin_rl =
   602   let val V = read_prop "PROP V"
   603       and W = read_prop "PROP W";
   604   in store_standard_thm_open "thin_rl" (implies_intr V (implies_intr W (assume W))) end;
   605 
   606 (* (!!x. PROP ?V) == PROP ?V       Allows removal of redundant parameters*)
   607 val triv_forall_equality =
   608   let val V  = read_prop "PROP V"
   609       and QV = read_prop "!!x::'a. PROP V"
   610       and x  = read_cterm proto_sign ("x", TypeInfer.logicT);
   611   in
   612     store_standard_thm_open "triv_forall_equality"
   613       (equal_intr (implies_intr QV (forall_elim x (assume QV)))
   614         (implies_intr V  (forall_intr x (assume V))))
   615   end;
   616 
   617 (* (PROP ?PhiA ==> PROP ?PhiB ==> PROP ?Psi) ==>
   618    (PROP ?PhiB ==> PROP ?PhiA ==> PROP ?Psi)
   619    `thm COMP swap_prems_rl' swaps the first two premises of `thm'
   620 *)
   621 val swap_prems_rl =
   622   let val cmajor = read_prop "PROP PhiA ==> PROP PhiB ==> PROP Psi";
   623       val major = assume cmajor;
   624       val cminor1 = read_prop "PROP PhiA";
   625       val minor1 = assume cminor1;
   626       val cminor2 = read_prop "PROP PhiB";
   627       val minor2 = assume cminor2;
   628   in store_standard_thm_open "swap_prems_rl"
   629        (implies_intr cmajor (implies_intr cminor2 (implies_intr cminor1
   630          (implies_elim (implies_elim major minor1) minor2))))
   631   end;
   632 
   633 (* [| PROP ?phi ==> PROP ?psi; PROP ?psi ==> PROP ?phi |]
   634    ==> PROP ?phi == PROP ?psi
   635    Introduction rule for == as a meta-theorem.
   636 *)
   637 val equal_intr_rule =
   638   let val PQ = read_prop "PROP phi ==> PROP psi"
   639       and QP = read_prop "PROP psi ==> PROP phi"
   640   in
   641     store_standard_thm_open "equal_intr_rule"
   642       (implies_intr PQ (implies_intr QP (equal_intr (assume PQ) (assume QP))))
   643   end;
   644 
   645 
   646 (*(PROP ?phi ==> (!!x. PROP ?psi(x))) == (!!x. PROP ?phi ==> PROP ?psi(x))
   647   Rewrite rule for HHF normalization.
   648 *)
   649 
   650 val norm_hhf_eq =
   651   let
   652     val cert = Thm.cterm_of proto_sign;
   653     val aT = TFree ("'a", Term.logicS);
   654     val all = Term.all aT;
   655     val x = Free ("x", aT);
   656     val phi = Free ("phi", propT);
   657     val psi = Free ("psi", aT --> propT);
   658 
   659     val cx = cert x;
   660     val cphi = cert phi;
   661     val lhs = cert (Logic.mk_implies (phi, all $ Abs ("x", aT, psi $ Bound 0)));
   662     val rhs = cert (all $ Abs ("x", aT, Logic.mk_implies (phi, psi $ Bound 0)));
   663   in
   664     Thm.equal_intr
   665       (Thm.implies_elim (Thm.assume lhs) (Thm.assume cphi)
   666         |> Thm.forall_elim cx
   667         |> Thm.implies_intr cphi
   668         |> Thm.forall_intr cx
   669         |> Thm.implies_intr lhs)
   670       (Thm.implies_elim
   671           (Thm.assume rhs |> Thm.forall_elim cx) (Thm.assume cphi)
   672         |> Thm.forall_intr cx
   673         |> Thm.implies_intr cphi
   674         |> Thm.implies_intr rhs)
   675     |> store_standard_thm_open "norm_hhf_eq"
   676   end;
   677 
   678 
   679 (*** Instantiate theorem th, reading instantiations under signature sg ****)
   680 
   681 (*Version that normalizes the result: Thm.instantiate no longer does that*)
   682 fun instantiate instpair th = Thm.instantiate instpair th  COMP   asm_rl;
   683 
   684 fun read_instantiate_sg sg sinsts th =
   685     let val ts = types_sorts th;
   686         val used = add_term_tvarnames(#prop(rep_thm th),[]);
   687     in  instantiate (read_insts sg ts ts used sinsts) th  end;
   688 
   689 (*Instantiate theorem th, reading instantiations under theory of th*)
   690 fun read_instantiate sinsts th =
   691     read_instantiate_sg (#sign (rep_thm th)) sinsts th;
   692 
   693 
   694 (*Left-to-right replacements: tpairs = [...,(vi,ti),...].
   695   Instantiates distinct Vars by terms, inferring type instantiations. *)
   696 local
   697   fun add_types ((ct,cu), (sign,tye,maxidx)) =
   698     let val {sign=signt, t=t, T= T, maxidx=maxt,...} = rep_cterm ct
   699         and {sign=signu, t=u, T= U, maxidx=maxu,...} = rep_cterm cu;
   700         val maxi = Int.max(maxidx, Int.max(maxt, maxu));
   701         val sign' = Sign.merge(sign, Sign.merge(signt, signu))
   702         val (tye',maxi') = Type.unify (#tsig(Sign.rep_sg sign')) maxi tye (T,U)
   703           handle Type.TUNIFY => raise TYPE("Ill-typed instantiation", [T,U], [t,u])
   704     in  (sign', tye', maxi')  end;
   705 in
   706 fun cterm_instantiate ctpairs0 th =
   707   let val (sign,tye,_) = foldr add_types (ctpairs0, (#sign(rep_thm th), Vartab.empty, 0))
   708       fun instT(ct,cu) = let val inst = subst_TVars_Vartab tye
   709                          in (cterm_fun inst ct, cterm_fun inst cu) end
   710       fun ctyp2 (ix,T) = (ix, ctyp_of sign T)
   711   in  instantiate (map ctyp2 (Vartab.dest tye), map instT ctpairs0) th  end
   712   handle TERM _ =>
   713            raise THM("cterm_instantiate: incompatible signatures",0,[th])
   714        | TYPE (msg, _, _) => raise THM(msg, 0, [th])
   715 end;
   716 
   717 
   718 (** Derived rules mainly for METAHYPS **)
   719 
   720 (*Given the term "a", takes (%x.t)==(%x.u) to t[a/x]==u[a/x]*)
   721 fun equal_abs_elim ca eqth =
   722   let val {sign=signa, t=a, ...} = rep_cterm ca
   723       and combth = combination eqth (reflexive ca)
   724       val {sign,prop,...} = rep_thm eqth
   725       val (abst,absu) = Logic.dest_equals prop
   726       val cterm = cterm_of (Sign.merge (sign,signa))
   727   in  transitive (symmetric (beta_conversion false (cterm (abst$a))))
   728            (transitive combth (beta_conversion false (cterm (absu$a))))
   729   end
   730   handle THM _ => raise THM("equal_abs_elim", 0, [eqth]);
   731 
   732 (*Calling equal_abs_elim with multiple terms*)
   733 fun equal_abs_elim_list cts th = foldr (uncurry equal_abs_elim) (rev cts, th);
   734 
   735 local
   736   val alpha = TVar(("'a",0), [])     (*  type ?'a::{}  *)
   737   fun err th = raise THM("flexpair_inst: ", 0, [th])
   738   fun flexpair_inst def th =
   739     let val {prop = Const _ $ t $ u,  sign,...} = rep_thm th
   740         val cterm = cterm_of sign
   741         fun cvar a = cterm(Var((a,0),alpha))
   742         val def' = cterm_instantiate [(cvar"t", cterm t), (cvar"u", cterm u)]
   743                    def
   744     in  equal_elim def' th
   745     end
   746     handle THM _ => err th | Bind => err th
   747 in
   748 val flexpair_intr = flexpair_inst (symmetric ProtoPure.flexpair_def)
   749 and flexpair_elim = flexpair_inst ProtoPure.flexpair_def
   750 end;
   751 
   752 (*Version for flexflex pairs -- this supports lifting.*)
   753 fun flexpair_abs_elim_list cts =
   754     flexpair_intr o equal_abs_elim_list cts o flexpair_elim;
   755 
   756 
   757 (*** Goal (PROP A) <==> PROP A ***)
   758 
   759 local
   760   val cert = Thm.cterm_of proto_sign;
   761   val A = Free ("A", propT);
   762   val G = Logic.mk_goal A;
   763   val (G_def, _) = freeze_thaw ProtoPure.Goal_def;
   764 in
   765   val triv_goal = store_thm "triv_goal" (kind_rule internalK (standard
   766       (Thm.equal_elim (Thm.symmetric G_def) (Thm.assume (cert A)))));
   767   val rev_triv_goal = store_thm "rev_triv_goal" (kind_rule internalK (standard
   768       (Thm.equal_elim G_def (Thm.assume (cert G)))));
   769 end;
   770 
   771 val mk_cgoal = Thm.capply (Thm.cterm_of proto_sign Logic.goal_const);
   772 fun assume_goal ct = Thm.assume (mk_cgoal ct) RS rev_triv_goal;
   773 
   774 fun implies_intr_goals cprops thm =
   775   implies_elim_list (implies_intr_list cprops thm) (map assume_goal cprops)
   776   |> implies_intr_list (map mk_cgoal cprops);
   777 
   778 
   779 
   780 (** variations on instantiate **)
   781 
   782 (*shorthand for instantiating just one variable in the current theory*)
   783 fun inst x t = read_instantiate_sg (sign_of (the_context())) [(x,t)];
   784 
   785 
   786 (* collect vars *)
   787 
   788 val add_tvarsT = foldl_atyps (fn (vs, TVar v) => v ins vs | (vs, _) => vs);
   789 val add_tvars = foldl_types add_tvarsT;
   790 val add_vars = foldl_aterms (fn (vs, Var v) => v ins vs | (vs, _) => vs);
   791 val add_frees = foldl_aterms (fn (vs, Free v) => v ins vs | (vs, _) => vs);
   792 
   793 fun tvars_of_terms ts = rev (foldl add_tvars ([], ts));
   794 fun vars_of_terms ts = rev (foldl add_vars ([], ts));
   795 
   796 fun tvars_of thm = tvars_of_terms [#prop (Thm.rep_thm thm)];
   797 fun vars_of thm = vars_of_terms [#prop (Thm.rep_thm thm)];
   798 
   799 
   800 (* instantiate by left-to-right occurrence of variables *)
   801 
   802 fun instantiate' cTs cts thm =
   803   let
   804     fun err msg =
   805       raise TYPE ("instantiate': " ^ msg,
   806         mapfilter (apsome Thm.typ_of) cTs,
   807         mapfilter (apsome Thm.term_of) cts);
   808 
   809     fun inst_of (v, ct) =
   810       (Thm.cterm_of (#sign (Thm.rep_cterm ct)) (Var v), ct)
   811         handle TYPE (msg, _, _) => err msg;
   812 
   813     fun zip_vars _ [] = []
   814       | zip_vars (_ :: vs) (None :: opt_ts) = zip_vars vs opt_ts
   815       | zip_vars (v :: vs) (Some t :: opt_ts) = (v, t) :: zip_vars vs opt_ts
   816       | zip_vars [] _ = err "more instantiations than variables in thm";
   817 
   818     (*instantiate types first!*)
   819     val thm' =
   820       if forall is_none cTs then thm
   821       else Thm.instantiate (zip_vars (map fst (tvars_of thm)) cTs, []) thm;
   822     in
   823       if forall is_none cts then thm'
   824       else Thm.instantiate ([], map inst_of (zip_vars (vars_of thm') cts)) thm'
   825     end;
   826 
   827 
   828 (* unvarify(T) *)
   829 
   830 (*assume thm in standard form, i.e. no frees, 0 var indexes*)
   831 
   832 fun unvarifyT thm =
   833   let
   834     val cT = Thm.ctyp_of (Thm.sign_of_thm thm);
   835     val tfrees = map (fn ((x, _), S) => Some (cT (TFree (x, S)))) (tvars_of thm);
   836   in instantiate' tfrees [] thm end;
   837 
   838 fun unvarify raw_thm =
   839   let
   840     val thm = unvarifyT raw_thm;
   841     val ct = Thm.cterm_of (Thm.sign_of_thm thm);
   842     val frees = map (fn ((x, _), T) => Some (ct (Free (x, T)))) (vars_of thm);
   843   in instantiate' [] frees thm end;
   844 
   845 
   846 (* tvars_intr_list *)
   847 
   848 fun tfrees_of thm =
   849   let val {hyps, prop, ...} = Thm.rep_thm thm
   850   in foldr Term.add_term_tfree_names (prop :: hyps, []) end;
   851 
   852 fun tvars_intr_list tfrees thm =
   853   Thm.varifyT' (tfrees_of thm \\ tfrees) thm;
   854 
   855 
   856 (* increment var indexes *)
   857 
   858 fun incr_indexes_wrt is cTs cts thms =
   859   let
   860     val maxidx =
   861       foldl Int.max (~1, is @
   862         map (maxidx_of_typ o #T o Thm.rep_ctyp) cTs @
   863         map (#maxidx o Thm.rep_cterm) cts @
   864         map (#maxidx o Thm.rep_thm) thms);
   865   in Thm.incr_indexes (maxidx + 1) end;
   866 
   867 
   868 (* freeze_all *)
   869 
   870 (*freeze all (T)Vars; assumes thm in standard form*)
   871 
   872 fun freeze_all_TVars thm =
   873   (case tvars_of thm of
   874     [] => thm
   875   | tvars =>
   876       let val cert = Thm.ctyp_of (Thm.sign_of_thm thm)
   877       in instantiate' (map (fn ((x, _), S) => Some (cert (TFree (x, S)))) tvars) [] thm end);
   878 
   879 fun freeze_all_Vars thm =
   880   (case vars_of thm of
   881     [] => thm
   882   | vars =>
   883       let val cert = Thm.cterm_of (Thm.sign_of_thm thm)
   884       in instantiate' [] (map (fn ((x, _), T) => Some (cert (Free (x, T)))) vars) thm end);
   885 
   886 val freeze_all = freeze_all_Vars o freeze_all_TVars;
   887 
   888 
   889 (* mk_triv_goal *)
   890 
   891 (*make an initial proof state, "PROP A ==> (PROP A)" *)
   892 fun mk_triv_goal ct = instantiate' [] [Some ct] triv_goal;
   893 
   894 
   895 
   896 (** meta-level conjunction **)
   897 
   898 local
   899   val A = read_prop "PROP A";
   900   val B = read_prop "PROP B";
   901   val C = read_prop "PROP C";
   902   val ABC = read_prop "PROP A ==> PROP B ==> PROP C";
   903 
   904   val proj1 =
   905     forall_intr_list [A, B] (implies_intr_list [A, B] (Thm.assume A))
   906     |> forall_elim_vars 0;
   907 
   908   val proj2 =
   909     forall_intr_list [A, B] (implies_intr_list [A, B] (Thm.assume B))
   910     |> forall_elim_vars 0;
   911 
   912   val conj_intr_rule =
   913     forall_intr_list [A, B] (implies_intr_list [A, B]
   914       (Thm.forall_intr C (Thm.implies_intr ABC
   915         (implies_elim_list (Thm.assume ABC) [Thm.assume A, Thm.assume B]))))
   916     |> forall_elim_vars 0;
   917 
   918   val incr = incr_indexes_wrt [] [] [];
   919 in
   920 
   921 fun conj_intr tha thb = thb COMP (tha COMP incr [tha, thb] conj_intr_rule);
   922 val conj_intr_list = foldr1 (uncurry conj_intr);
   923 
   924 fun conj_elim th =
   925   let val th' = forall_elim_var (#maxidx (Thm.rep_thm th) + 1) th
   926   in (incr [th'] proj1 COMP th', incr [th'] proj2 COMP th') end;
   927 
   928 fun conj_elim_list th =
   929   let val (th1, th2) = conj_elim th
   930   in conj_elim_list th1 @ conj_elim_list th2 end handle THM _ => [th];
   931 
   932 fun conj_elim_precise 1 th = [th]
   933   | conj_elim_precise n th =
   934       let val (th1, th2) = conj_elim th
   935       in th1 :: conj_elim_precise (n - 1) th2 end;
   936 
   937 val conj_intr_thm = store_standard_thm_open "conjunctionI"
   938   (implies_intr_list [A, B] (conj_intr (Thm.assume A) (Thm.assume B)));
   939 
   940 end;
   941 
   942 end;
   943 
   944 structure BasicDrule: BASIC_DRULE = Drule;
   945 open BasicDrule;