src/Pure/library.ML
author haftmann
Tue Jul 05 13:57:23 2005 +0200 (2005-07-05)
changeset 16688 e3de7ea24c23
parent 16676 671bd433b9eb
child 16691 539b9cc282fa
permissions -rw-r--r--
added ST combinator '|->'
     1 (*  Title:      Pure/library.ML
     2     ID:         $Id$
     3     Author:     Lawrence C Paulson, Cambridge University Computer Laboratory
     4     Author:     Markus Wenzel, TU Muenchen
     5 
     6 Basic library: functions, options, pairs, booleans, lists, integers,
     7 rational numbers, strings, lists as sets, association lists, generic
     8 tables, balanced trees, orders, current directory, misc.
     9 *)
    10 
    11 infix |> |-> |>> |>>> ~~ \ \\ ins ins_string ins_int orf andf prefix upto downto
    12   mem mem_int mem_string union union_int union_string inter inter_int
    13   inter_string subset subset_int subset_string;
    14 
    15 infix 3 oo ooo oooo;
    16 
    17 signature BASIC_LIBRARY =
    18 sig
    19   (*functions*)
    20   val curry: ('a * 'b -> 'c) -> 'a -> 'b -> 'c
    21   val uncurry: ('a -> 'b -> 'c) -> 'a * 'b -> 'c
    22   val I: 'a -> 'a
    23   val K: 'a -> 'b -> 'a
    24   val |> : 'a * ('a -> 'b) -> 'b
    25   val |-> : ('a * 'c) * ('c -> 'a -> 'b) -> 'b
    26   val |>> : ('a * 'b) * ('a -> 'c) -> 'c * 'b
    27   val |>>> : ('a * 'b) * ('a -> 'c * 'd) -> 'c * ('b * 'd)
    28   val apl: 'a * ('a * 'b -> 'c) -> 'b -> 'c
    29   val apr: ('a * 'b -> 'c) * 'b -> 'a -> 'c
    30   val funpow: int -> ('a -> 'a) -> 'a -> 'a
    31   val oo: ('a -> 'b) * ('c -> 'd -> 'a) -> 'c -> 'd -> 'b
    32   val ooo: ('a -> 'b) * ('c -> 'd -> 'e -> 'a) -> 'c -> 'd -> 'e -> 'b
    33   val oooo: ('a -> 'b) * ('c -> 'd -> 'e -> 'f -> 'a) -> 'c -> 'd -> 'e -> 'f -> 'b
    34 
    35   (*old options -- invalidated*)
    36   datatype invalid = None of invalid
    37   exception OPTION of invalid
    38 
    39   (*options*)
    40   val the: 'a option -> 'a
    41   val if_none: 'a option -> 'a -> 'a
    42   val is_some: 'a option -> bool
    43   val is_none: 'a option -> bool
    44 
    45   exception ERROR
    46   val try: ('a -> 'b) -> 'a -> 'b option
    47   val can: ('a -> 'b) -> 'a -> bool
    48   datatype 'a result = Result of 'a | Exn of exn
    49   val capture: ('a -> 'b) -> 'a -> 'b result
    50   val release: 'a result -> 'a
    51   val get_result: 'a result -> 'a option
    52   val get_exn: 'a result -> exn option
    53 
    54   (*pairs*)
    55   val pair: 'a -> 'b -> 'a * 'b
    56   val rpair: 'a -> 'b -> 'b * 'a
    57   val fst: 'a * 'b -> 'a
    58   val snd: 'a * 'b -> 'b
    59   val eq_fst: (''a * 'b) * (''a * 'c) -> bool
    60   val eq_snd: ('a * ''b) * ('c * ''b) -> bool
    61   val swap: 'a * 'b -> 'b * 'a
    62   val apfst: ('a -> 'b) -> 'a * 'c -> 'b * 'c
    63   val apsnd: ('a -> 'b) -> 'c * 'a -> 'c * 'b
    64   val pairself: ('a -> 'b) -> 'a * 'a -> 'b * 'b
    65 
    66   (*booleans*)
    67   val equal: ''a -> ''a -> bool
    68   val not_equal: ''a -> ''a -> bool
    69   val orf: ('a -> bool) * ('a -> bool) -> 'a -> bool
    70   val andf: ('a -> bool) * ('a -> bool) -> 'a -> bool
    71   val exists: ('a -> bool) -> 'a list -> bool
    72   val forall: ('a -> bool) -> 'a list -> bool
    73   val set: bool ref -> bool
    74   val reset: bool ref -> bool
    75   val toggle: bool ref -> bool
    76   val change: 'a ref -> ('a -> 'a) -> unit
    77   val setmp: 'a ref -> 'a -> ('b -> 'c) -> 'b -> 'c
    78   val conditional: bool -> (unit -> unit) -> unit
    79 
    80   (*lists*)
    81   exception UnequalLengths
    82   val cons: 'a -> 'a list -> 'a list
    83   val single: 'a -> 'a list
    84   val append: 'a list -> 'a list -> 'a list
    85   val apply: ('a -> 'a) list -> 'a -> 'a
    86   val fold: ('a -> 'b -> 'b) -> 'a list -> 'b -> 'b
    87   val fold_rev: ('a -> 'b -> 'b) -> 'a list -> 'b -> 'b
    88   val foldl_map: ('a * 'b -> 'a * 'c) -> 'a * 'b list -> 'a * 'c list
    89   val foldr1: ('a * 'a -> 'a) -> 'a list -> 'a
    90   val foldln: ('a * int -> 'b -> 'b) -> 'a list -> 'b -> 'b
    91   val unflat: 'a list list -> 'b list -> 'b list list
    92   val splitAt: int * 'a list -> 'a list * 'a list
    93   val dropwhile: ('a -> bool) -> 'a list -> 'a list
    94   val map_nth_elem: int -> ('a -> 'a) -> 'a list -> 'a list
    95   val split_last: 'a list -> 'a list * 'a
    96   val nth_update: 'a -> int * 'a list -> 'a list
    97   val find_index: ('a -> bool) -> 'a list -> int
    98   val find_index_eq: ''a -> ''a list -> int
    99   val find_first: ('a -> bool) -> 'a list -> 'a option
   100   val get_first: ('a -> 'b option) -> 'a list -> 'b option
   101   val separate: 'a -> 'a list -> 'a list
   102   val replicate: int -> 'a -> 'a list
   103   val multiply: 'a list * 'a list list -> 'a list list
   104   val product: 'a list -> 'b list -> ('a * 'b) list
   105   val filter: ('a -> bool) -> 'a list -> 'a list
   106   val filter_out: ('a -> bool) -> 'a list -> 'a list
   107   val map2: ('a * 'b -> 'c) -> 'a list * 'b list -> 'c list
   108   val exists2: ('a * 'b -> bool) -> 'a list * 'b list -> bool
   109   val forall2: ('a * 'b -> bool) -> 'a list * 'b list -> bool
   110   val seq2: ('a * 'b -> unit) -> 'a list * 'b list -> unit
   111   val ~~ : 'a list * 'b list -> ('a * 'b) list
   112   val split_list: ('a * 'b) list -> 'a list * 'b list
   113   val equal_lists: ('a * 'b -> bool) -> 'a list * 'b list -> bool
   114   val prefix: ''a list * ''a list -> bool
   115   val take_prefix: ('a -> bool) -> 'a list -> 'a list * 'a list
   116   val take_suffix: ('a -> bool) -> 'a list -> 'a list * 'a list
   117   val prefixes1: 'a list -> 'a list list
   118   val suffixes1: 'a list -> 'a list list
   119 
   120   (*integers*)
   121   val gcd: IntInf.int * IntInf.int -> IntInf.int
   122   val lcm: IntInf.int * IntInf.int -> IntInf.int
   123   val inc: int ref -> int
   124   val dec: int ref -> int
   125   val upto: int * int -> int list
   126   val downto: int * int -> int list
   127   val downto0: int list * int -> bool
   128   val radixpand: int * int -> int list
   129   val radixstring: int * string * int -> string
   130   val string_of_int: int -> string
   131   val string_of_indexname: string * int -> string
   132   val read_radixint: int * string list -> int * string list
   133   val read_int: string list -> int * string list
   134   val oct_char: string -> string
   135 
   136   (*rational numbers*)
   137   type rat
   138   exception RAT of string
   139   val rep_rat: rat -> IntInf.int * IntInf.int
   140   val ratadd: rat * rat -> rat
   141   val ratmul: rat * rat -> rat
   142   val ratinv: rat -> rat
   143   val int_ratdiv: IntInf.int * IntInf.int -> rat
   144   val ratneg: rat -> rat
   145   val rat_of_int: int -> rat
   146   val rat_of_intinf: IntInf.int -> rat
   147 
   148   (*strings*)
   149   val nth_elem_string: int * string -> string
   150   val fold_string: (string -> 'a -> 'a) -> string -> 'a -> 'a
   151   val exists_string: (string -> bool) -> string -> bool
   152   val forall_string: (string -> bool) -> string -> bool
   153   val enclose: string -> string -> string -> string
   154   val unenclose: string -> string
   155   val quote: string -> string
   156   val space_implode: string -> string list -> string
   157   val commas: string list -> string
   158   val commas_quote: string list -> string
   159   val cat_lines: string list -> string
   160   val space_explode: string -> string -> string list
   161   val split_lines: string -> string list
   162   val prefix_lines: string -> string -> string
   163   val untabify: string list -> string list
   164   val suffix: string -> string -> string
   165   val unsuffix: string -> string -> string
   166   val unprefix: string -> string -> string
   167   val replicate_string: int -> string -> string
   168   val translate_string: (string -> string) -> string -> string
   169 
   170   (*lists as sets -- see also Pure/General/ord_list.ML*)
   171   val mem: ''a * ''a list -> bool
   172   val mem_int: int * int list -> bool
   173   val mem_string: string * string list -> bool
   174   val gen_mem: ('a * 'b -> bool) -> 'a * 'b list -> bool
   175   val ins: ''a * ''a list -> ''a list
   176   val ins_int: int * int list -> int list
   177   val ins_string: string * string list -> string list
   178   val gen_ins: ('a * 'a -> bool) -> 'a * 'a list -> 'a list
   179   val member: ('b * 'a -> bool) -> 'a list -> 'b -> bool
   180   val insert: ('a * 'a -> bool) -> 'a -> 'a list -> 'a list
   181   val remove: ('b * 'a -> bool) -> 'b -> 'a list -> 'a list
   182   val union: ''a list * ''a list -> ''a list
   183   val union_int: int list * int list -> int list
   184   val union_string: string list * string list -> string list
   185   val gen_union: ('a * 'a -> bool) -> 'a list * 'a list -> 'a list
   186   val gen_inter: ('a * 'b -> bool) -> 'a list * 'b list -> 'a list
   187   val inter: ''a list * ''a list -> ''a list
   188   val inter_int: int list * int list -> int list
   189   val inter_string: string list * string list -> string list
   190   val subset: ''a list * ''a list -> bool
   191   val subset_int: int list * int list -> bool
   192   val subset_string: string list * string list -> bool
   193   val eq_set: ''a list * ''a list -> bool
   194   val eq_set_string: string list * string list -> bool
   195   val gen_subset: ('a * 'b -> bool) -> 'a list * 'b list -> bool
   196   val \ : ''a list * ''a -> ''a list
   197   val \\ : ''a list * ''a list -> ''a list
   198   val gen_rem: ('a * 'b -> bool) -> 'a list * 'b -> 'a list
   199   val gen_rems: ('a * 'b -> bool) -> 'a list * 'b list -> 'a list
   200   val gen_distinct: ('a * 'a -> bool) -> 'a list -> 'a list
   201   val distinct: ''a list -> ''a list
   202   val findrep: ''a list -> ''a list
   203   val gen_duplicates: ('a * 'a -> bool) -> 'a list -> 'a list
   204   val duplicates: ''a list -> ''a list
   205 
   206   (*association lists*)
   207   val assoc: (''a * 'b) list * ''a -> 'b option
   208   val assoc_int: (int * 'a) list * int -> 'a option
   209   val assoc_string: (string * 'a) list * string -> 'a option
   210   val assoc_string_int: ((string * int) * 'a) list * (string * int) -> 'a option
   211   val assocs: (''a * 'b list) list -> ''a -> 'b list
   212   val assoc2: (''a * (''b * 'c) list) list * (''a * ''b) -> 'c option
   213   val gen_assoc: ('a * 'b -> bool) -> ('b * 'c) list * 'a -> 'c option
   214   val overwrite: (''a * 'b) list * (''a * 'b) -> (''a * 'b) list
   215   val gen_overwrite: ('a * 'a -> bool) -> ('a * 'b) list * ('a * 'b) -> ('a * 'b) list
   216 
   217   (*lists as tables*)
   218   val gen_merge_lists: ('a * 'a -> bool) -> 'a list -> 'a list -> 'a list
   219   val gen_merge_lists': ('a * 'a -> bool) -> 'a list -> 'a list -> 'a list
   220   val merge_lists: ''a list -> ''a list -> ''a list
   221   val merge_lists': ''a list -> ''a list -> ''a list
   222   val merge_alists: (''a * 'b) list -> (''a * 'b) list -> (''a * 'b) list
   223   val merge_alists': (''a * 'b) list -> (''a * 'b) list -> (''a * 'b) list
   224 
   225   (*balanced trees*)
   226   exception Balance
   227   val fold_bal: ('a * 'a -> 'a) -> 'a list -> 'a
   228   val access_bal: ('a -> 'a) * ('a -> 'a) * 'a -> int -> int -> 'a
   229   val accesses_bal: ('a -> 'a) * ('a -> 'a) * 'a -> int -> 'a list
   230 
   231   (*orders*)
   232   val rev_order: order -> order
   233   val make_ord: ('a * 'a -> bool) -> 'a * 'a -> order
   234   val int_ord: int * int -> order
   235   val string_ord: string * string -> order
   236   val fast_string_ord: string * string -> order
   237   val option_ord: ('a * 'b -> order) -> 'a option * 'b option -> order
   238   val prod_ord: ('a * 'b -> order) -> ('c * 'd -> order) -> ('a * 'c) * ('b * 'd) -> order
   239   val dict_ord: ('a * 'b -> order) -> 'a list * 'b list -> order
   240   val list_ord: ('a * 'b -> order) -> 'a list * 'b list -> order
   241   val sort: ('a * 'a -> order) -> 'a list -> 'a list
   242   val sort_strings: string list -> string list
   243   val sort_wrt: ('a -> string) -> 'a list -> 'a list
   244   val unique_strings: string list -> string list
   245 
   246   (*random numbers*)
   247   exception RANDOM
   248   val random: unit -> real
   249   val random_range: int -> int -> int
   250   val one_of: 'a list -> 'a
   251   val frequency: (int * 'a) list -> 'a
   252 
   253   (*current directory*)
   254   val cd: string -> unit
   255   val pwd: unit -> string
   256 
   257   (*misc*)
   258   val make_keylist: ('a -> 'b) -> 'a list -> ('a * 'b) list
   259   val keyfilter: ('a * ''b) list -> ''b -> 'a list
   260   val partition_eq: ('a * 'a -> bool) -> 'a list -> 'a list list
   261   val partition_list: (int -> 'a -> bool) -> int -> int -> 'a list -> 'a list list
   262   val gensym: string -> string
   263   val scanwords: (string -> bool) -> string list -> string list
   264   type stamp
   265   val stamp: unit -> stamp
   266   type serial
   267   val serial: unit -> serial
   268   structure Object: sig type T end
   269 end;
   270 
   271 signature LIBRARY =
   272 sig
   273   include BASIC_LIBRARY
   274   val foldl: ('a * 'b -> 'a) -> 'a * 'b list -> 'a
   275   val foldr: ('a * 'b -> 'b) -> 'a list * 'b -> 'b
   276   val take: int * 'a list -> 'a list
   277   val drop: int * 'a list -> 'a list
   278   val nth_elem: int * 'a list -> 'a
   279   val last_elem: 'a list -> 'a
   280   val flat: 'a list list -> 'a list
   281   val seq: ('a -> unit) -> 'a list -> unit
   282   val partition: ('a -> bool) -> 'a list -> 'a list * 'a list
   283   val mapfilter: ('a -> 'b option) -> 'a list -> 'b list
   284 end;
   285 
   286 structure Library: LIBRARY =
   287 struct
   288 
   289 
   290 (** functions **)
   291 
   292 (*handy combinators*)
   293 fun curry f x y = f (x, y);
   294 fun uncurry f (x, y) = f x y;
   295 fun I x = x;
   296 fun K x y = x;
   297 
   298 (*reverse apply*)
   299 fun (x |> f) = f x;
   300 fun ((x, v) |-> f) = f v x;
   301 fun ((x, y) |>> f) = (f x, y);
   302 fun ((x, y) |>>> f) = let val (x', z) = f x in (x', (y, z)) end;
   303 
   304 (*application of (infix) operator to its left or right argument*)
   305 fun apl (x, f) y = f (x, y);
   306 fun apr (f, y) x = f (x, y);
   307 
   308 (*function exponentiation: f(...(f x)...) with n applications of f*)
   309 fun funpow n f x =
   310   let fun rep (0, x) = x
   311         | rep (n, x) = rep (n - 1, f x)
   312   in rep (n, x) end;
   313 
   314 (*concatenation: 2 and 3 args*)
   315 fun (f oo g) x y = f (g x y);
   316 fun (f ooo g) x y z = f (g x y z);
   317 fun (f oooo g) x y z w = f (g x y z w);
   318 
   319 
   320 
   321 (** options **)
   322 
   323 (*invalidate former constructors to prevent accidental use as match-all patterns!*)
   324 datatype invalid = None of invalid;
   325 exception OPTION of invalid;
   326 
   327 val the = Option.valOf;
   328 
   329 (*strict!*)
   330 fun if_none NONE y = y
   331   | if_none (SOME x) _ = x;
   332 
   333 fun is_some (SOME _) = true
   334   | is_some NONE = false;
   335 
   336 fun is_none (SOME _) = false
   337   | is_none NONE = true;
   338 
   339 
   340 (* exception handling *)
   341 
   342 exception ERROR;
   343 
   344 fun try f x = SOME (f x)
   345   handle Interrupt => raise Interrupt | ERROR => raise ERROR | _ => NONE;
   346 
   347 fun can f x = is_some (try f x);
   348 
   349 
   350 datatype 'a result =
   351   Result of 'a |
   352   Exn of exn;
   353 
   354 fun capture f x = Result (f x) handle e => Exn e;
   355 
   356 fun release (Result y) = y
   357   | release (Exn e) = raise e;
   358 
   359 fun get_result (Result x) = SOME x
   360   | get_result _ = NONE;
   361 
   362 fun get_exn (Exn exn) = SOME exn
   363   | get_exn _ = NONE;
   364 
   365 
   366 
   367 (** pairs **)
   368 
   369 fun pair x y = (x, y);
   370 fun rpair x y = (y, x);
   371 
   372 fun fst (x, y) = x;
   373 fun snd (x, y) = y;
   374 
   375 fun eq_fst ((x1, _), (x2, _)) = x1 = x2;
   376 fun eq_snd ((_, y1), (_, y2)) = y1 = y2;
   377 
   378 fun swap (x, y) = (y, x);
   379 
   380 (*apply function to components*)
   381 fun apfst f (x, y) = (f x, y);
   382 fun apsnd f (x, y) = (x, f y);
   383 fun pairself f (x, y) = (f x, f y);
   384 
   385 
   386 
   387 (** booleans **)
   388 
   389 (* equality *)
   390 
   391 fun equal x y = x = y;
   392 fun not_equal x y = x <> y;
   393 
   394 
   395 (* operators for combining predicates *)
   396 
   397 fun (p orf q) = fn x => p x orelse q x;
   398 fun (p andf q) = fn x => p x andalso q x;
   399 
   400 
   401 (* predicates on lists *)
   402 
   403 (*exists pred [x1, ..., xn] ===> pred x1 orelse ... orelse pred xn*)
   404 fun exists (pred: 'a -> bool) : 'a list -> bool =
   405   let fun boolf [] = false
   406         | boolf (x :: xs) = pred x orelse boolf xs
   407   in boolf end;
   408 
   409 (*forall pred [x1, ..., xn] ===> pred x1 andalso ... andalso pred xn*)
   410 fun forall (pred: 'a -> bool) : 'a list -> bool =
   411   let fun boolf [] = true
   412         | boolf (x :: xs) = pred x andalso boolf xs
   413   in boolf end;
   414 
   415 
   416 (* flags *)
   417 
   418 fun set flag = (flag := true; true);
   419 fun reset flag = (flag := false; false);
   420 fun toggle flag = (flag := not (! flag); ! flag);
   421 
   422 fun change r f = r := f (! r);
   423 
   424 (*temporarily set flag, handling exceptions*)
   425 fun setmp flag value f x =
   426   let
   427     val orig_value = ! flag;
   428     fun return y = (flag := orig_value; y);
   429   in
   430     flag := value;
   431     return (f x handle exn => (return (); raise exn))
   432   end;
   433 
   434 
   435 (* conditional execution *)
   436 
   437 fun conditional b f = if b then f () else ();
   438 
   439 
   440 
   441 (** lists **)
   442 
   443 exception UnequalLengths;
   444 
   445 fun cons x xs = x :: xs;
   446 fun single x = [x];
   447 
   448 fun append xs ys = xs @ ys;
   449 
   450 fun apply [] x = x
   451   | apply (f :: fs) x = apply fs (f x);
   452 
   453 
   454 (* fold *)
   455 
   456 fun fold f =
   457   let
   458     fun fold_aux [] y = y
   459       | fold_aux (x :: xs) y = fold_aux xs (f x y);
   460   in fold_aux end;
   461 
   462 fun fold_rev f =
   463   let
   464     fun fold_aux [] y = y
   465       | fold_aux (x :: xs) y = f x (fold_aux xs y);
   466   in fold_aux end;
   467 
   468 fun foldl_map f =
   469   let
   470     fun fold_aux (x, []) = (x, [])
   471       | fold_aux (x, y :: ys) =
   472           let
   473             val (x', y') = f (x, y);
   474             val (x'', ys') = fold_aux (x', ys);
   475           in (x'', y' :: ys') end;
   476   in fold_aux end;
   477 
   478 (*the following versions of fold are designed to fit nicely with infixes*)
   479 
   480 (*  (op @) (e, [x1, ..., xn])  ===>  ((e @ x1) @ x2) ... @ xn
   481     for operators that associate to the left (TAIL RECURSIVE)*)
   482 fun foldl (f: 'a * 'b -> 'a) : 'a * 'b list -> 'a =
   483   let fun itl (e, [])  = e
   484         | itl (e, a::l) = itl (f(e, a), l)
   485   in  itl end;
   486 
   487 (*  (op @) ([x1, ..., xn], e)  ===>   x1 @ (x2 ... @ (xn @ e))
   488     for operators that associate to the right (not tail recursive)*)
   489 fun foldr f (l, e) =
   490   let fun itr [] = e
   491         | itr (a::l) = f(a, itr l)
   492   in  itr l  end;
   493 
   494 (*  (op @) [x1, ..., xn]  ===>   x1 @ (x2 ... @ (x[n-1] @ xn))
   495     for n > 0, operators that associate to the right (not tail recursive)*)
   496 fun foldr1 f l =
   497   let fun itr [x] = x
   498         | itr (x::l) = f(x, itr l)
   499   in  itr l  end;
   500 
   501 fun foldln f xs e = fst (foldl (fn ((e,i), x) => (f (x,i) e, i+1)) ((e,1),xs));
   502 
   503 
   504 (* basic list functions *)
   505 
   506 (*take the first n elements from a list*)
   507 fun take (n, []) = []
   508   | take (n, x :: xs) =
   509       if n > 0 then x :: take (n - 1, xs) else [];
   510 
   511 (*drop the first n elements from a list*)
   512 fun drop (n, []) = []
   513   | drop (n, x :: xs) =
   514       if n > 0 then drop (n - 1, xs) else x :: xs;
   515 
   516 fun splitAt(n,[]) = ([],[])
   517   | splitAt(n,xs as x::ys) =
   518       if n>0 then let val (ps,qs) = splitAt(n-1,ys) in (x::ps,qs) end
   519       else ([],xs)
   520 
   521 fun dropwhile P [] = []
   522   | dropwhile P (ys as x::xs) = if P x then dropwhile P xs else ys;
   523 
   524 (*return nth element of a list, where 0 designates the first element;
   525   raise EXCEPTION if list too short*)
   526 fun nth_elem (i,xs) = List.nth(xs,i);
   527 
   528 fun map_nth_elem 0 f (x :: xs) = f x :: xs
   529   | map_nth_elem n f (x :: xs) = x :: map_nth_elem (n - 1) f xs
   530   | map_nth_elem _ _ [] = raise Subscript;
   531 
   532 (*last element of a list*)
   533 val last_elem = List.last;
   534 
   535 (*rear decomposition*)
   536 fun split_last [] = raise Empty
   537   | split_last [x] = ([], x)
   538   | split_last (x :: xs) = apfst (cons x) (split_last xs);
   539 
   540 (*update nth element*)
   541 fun nth_update x n_xs =
   542     (case splitAt n_xs of
   543       (_,[]) => raise Subscript
   544     | (prfx, _ :: sffx') => prfx @ (x :: sffx'))
   545 
   546 (*find the position of an element in a list*)
   547 fun find_index pred =
   548   let fun find _ [] = ~1
   549         | find n (x :: xs) = if pred x then n else find (n + 1) xs;
   550   in find 0 end;
   551 
   552 fun find_index_eq x = find_index (equal x);
   553 
   554 (*find first element satisfying predicate*)
   555 fun find_first _ [] = NONE
   556   | find_first pred (x :: xs) =
   557       if pred x then SOME x else find_first pred xs;
   558 
   559 (*get first element by lookup function*)
   560 fun get_first _ [] = NONE
   561   | get_first f (x :: xs) =
   562       (case f x of
   563         NONE => get_first f xs
   564       | some => some);
   565 
   566 (*flatten a list of lists to a list*)
   567 val flat = List.concat;
   568 
   569 fun unflat (xs :: xss) ys =
   570       let val (ps,qs) = splitAt(length xs,ys)
   571       in ps :: unflat xss qs end
   572   | unflat [] [] = []
   573   | unflat _ _ = raise UnequalLengths;
   574 
   575 (*like Lisp's MAPC -- seq proc [x1, ..., xn] evaluates
   576   (proc x1; ...; proc xn) for side effects*)
   577 val seq = List.app;
   578 
   579 (*separate s [x1, x2, ..., xn]  ===>  [x1, s, x2, s, ..., s, xn]*)
   580 fun separate s (x :: (xs as _ :: _)) = x :: s :: separate s xs
   581   | separate _ xs = xs;
   582 
   583 (*make the list [x, x, ..., x] of length n*)
   584 fun replicate n (x: 'a) : 'a list =
   585   let fun rep (0, xs) = xs
   586         | rep (n, xs) = rep (n - 1, x :: xs)
   587   in
   588     if n < 0 then raise Subscript
   589     else rep (n, [])
   590   end;
   591 
   592 fun translate_string f = String.translate (f o String.str);
   593 
   594 (*multiply [a, b, c, ...] * [xs, ys, zs, ...]*)
   595 fun multiply ([], _) = []
   596   | multiply (x :: xs, yss) = map (cons x) yss @ multiply (xs, yss);
   597 
   598 (*direct product*)
   599 fun product _ [] = []
   600   | product [] _ = []
   601   | product (x :: xs) ys = map (pair x) ys @ product xs ys;
   602 
   603 
   604 (* filter *)
   605 
   606 (*copy the list preserving elements that satisfy the predicate*)
   607 val filter = List.filter;
   608 fun filter_out f = filter (not o f);
   609 val mapfilter = List.mapPartial;
   610 
   611 
   612 (* lists of pairs *)
   613 
   614 exception UnequalLengths;
   615 
   616 fun map2 _ ([], []) = []
   617   | map2 f (x :: xs, y :: ys) = (f (x, y) :: map2 f (xs, ys))
   618   | map2 _ _ = raise UnequalLengths;
   619 
   620 fun exists2 _ ([], []) = false
   621   | exists2 pred (x :: xs, y :: ys) = pred (x, y) orelse exists2 pred (xs, ys)
   622   | exists2 _ _ = raise UnequalLengths;
   623 
   624 fun forall2 _ ([], []) = true
   625   | forall2 pred (x :: xs, y :: ys) = pred (x, y) andalso forall2 pred (xs, ys)
   626   | forall2 _ _ = raise UnequalLengths;
   627 
   628 fun seq2 _ ([], []) = ()
   629   | seq2 f (x :: xs, y :: ys) = (f (x, y); seq2 f (xs, ys))
   630   | seq2 _ _ = raise UnequalLengths;
   631 
   632 (*combine two lists forming a list of pairs:
   633   [x1, ..., xn] ~~ [y1, ..., yn]  ===>  [(x1, y1), ..., (xn, yn)]*)
   634 fun [] ~~ [] = []
   635   | (x :: xs) ~~ (y :: ys) = (x, y) :: (xs ~~ ys)
   636   | _ ~~ _ = raise UnequalLengths;
   637 
   638 (*inverse of ~~; the old 'split':
   639   [(x1, y1), ..., (xn, yn)]  ===>  ([x1, ..., xn], [y1, ..., yn])*)
   640 val split_list = ListPair.unzip;
   641 
   642 fun equal_lists eq (xs, ys) = length xs = length ys andalso forall2 eq (xs, ys);
   643 
   644 
   645 (* prefixes, suffixes *)
   646 
   647 fun [] prefix _ = true
   648   | (x :: xs) prefix (y :: ys) = x = y andalso (xs prefix ys)
   649   | _ prefix _ = false;
   650 
   651 (* [x1, ..., xi, ..., xn]  --->  ([x1, ..., x(i-1)], [xi, ..., xn])
   652    where xi is the first element that does not satisfy the predicate*)
   653 fun take_prefix (pred : 'a -> bool)  (xs: 'a list) : 'a list * 'a list =
   654   let fun take (rxs, []) = (rev rxs, [])
   655         | take (rxs, x :: xs) =
   656             if  pred x  then  take(x :: rxs, xs)  else  (rev rxs, x :: xs)
   657   in  take([], xs)  end;
   658 
   659 (* [x1, ..., xi, ..., xn]  --->  ([x1, ..., xi], [x(i+1), ..., xn])
   660    where xi is the last element that does not satisfy the predicate*)
   661 fun take_suffix _ [] = ([], [])
   662   | take_suffix pred (x :: xs) =
   663       (case take_suffix pred xs of
   664         ([], sffx) => if pred x then ([], x :: sffx) else ([x], sffx)
   665       | (prfx, sffx) => (x :: prfx, sffx));
   666 
   667 fun prefixes1 [] = []
   668   | prefixes1 (x :: xs) = map (cons x) ([] :: prefixes1 xs);
   669 
   670 fun suffixes1 xs = map rev (prefixes1 (rev xs));
   671 
   672 
   673 
   674 (** integers **)
   675 
   676 fun gcd (x, y) =
   677   let fun gxd x y : IntInf.int =
   678     if y = 0 then x else gxd y (x mod y)
   679   in if x < y then gxd y x else gxd x y end;
   680 
   681 fun lcm (x, y) = (x * y) div gcd (x, y);
   682 
   683 fun inc i = (i := ! i + 1; ! i);
   684 fun dec i = (i := ! i - 1; ! i);
   685 
   686 
   687 (* lists of integers *)
   688 
   689 (*make the list [from, from + 1, ..., to]*)
   690 fun (from upto to) =
   691   if from > to then [] else from :: ((from + 1) upto to);
   692 
   693 (*make the list [from, from - 1, ..., to]*)
   694 fun (from downto to) =
   695   if from < to then [] else from :: ((from - 1) downto to);
   696 
   697 (*predicate: downto0 (is, n) <=> is = [n, n - 1, ..., 0]*)
   698 fun downto0 (i :: is, n) = i = n andalso downto0 (is, n - 1)
   699   | downto0 ([], n) = n = ~1;
   700 
   701 
   702 (* convert integers to strings *)
   703 
   704 (*expand the number in the given base;
   705   example: radixpand (2, 8) gives [1, 0, 0, 0]*)
   706 fun radixpand (base, num) : int list =
   707   let
   708     fun radix (n, tail) =
   709       if n < base then n :: tail
   710       else radix (n div base, (n mod base) :: tail)
   711   in radix (num, []) end;
   712 
   713 (*expands a number into a string of characters starting from "zerochar";
   714   example: radixstring (2, "0", 8) gives "1000"*)
   715 fun radixstring (base, zerochar, num) =
   716   let val offset = ord zerochar;
   717       fun chrof n = chr (offset + n)
   718   in implode (map chrof (radixpand (base, num))) end;
   719 
   720 
   721 val string_of_int = Int.toString;
   722 
   723 fun string_of_indexname (a,0) = a
   724   | string_of_indexname (a,i) = a ^ "_" ^ Int.toString i;
   725 
   726 
   727 (* read integers *)
   728 
   729 fun read_radixint (radix: int, cs) : int * string list =
   730   let val zero = ord"0"
   731       val limit = zero+radix
   732       fun scan (num,[]) = (num,[])
   733         | scan (num, c::cs) =
   734               if  zero <= ord c  andalso  ord c < limit
   735               then scan(radix*num + ord c - zero, cs)
   736               else (num, c::cs)
   737   in  scan(0,cs)  end;
   738 
   739 fun read_int cs = read_radixint (10, cs);
   740 
   741 fun oct_char s = chr (#1 (read_radixint (8, explode s)));
   742 
   743 
   744 
   745 (** strings **)
   746 
   747 (* functions tuned for strings, avoiding explode *)
   748 
   749 fun nth_elem_string (i, str) =
   750   (case try String.substring (str, i, 1) of
   751     SOME s => s
   752   | NONE => raise Subscript);
   753 
   754 fun fold_string f str x0 =
   755   let
   756     val n = size str;
   757     fun iter (x, i) =
   758       if i < n then iter (f (String.substring (str, i, 1)) x, i + 1) else x;
   759   in iter (x0, 0) end;
   760 
   761 fun exists_string pred str =
   762   let
   763     val n = size str;
   764     fun ex i = i < n andalso (pred (String.substring (str, i, 1)) orelse ex (i + 1));
   765   in ex 0 end;
   766 
   767 fun forall_string pred = not o exists_string (not o pred);
   768 
   769 (*enclose in brackets*)
   770 fun enclose lpar rpar str = lpar ^ str ^ rpar;
   771 fun unenclose str = String.substring (str, 1, size str - 2);
   772 
   773 (*simple quoting (does not escape special chars)*)
   774 val quote = enclose "\"" "\"";
   775 
   776 (*space_implode "..." (explode "hello") = "h...e...l...l...o"*)
   777 fun space_implode a bs = implode (separate a bs);
   778 
   779 val commas = space_implode ", ";
   780 val commas_quote = commas o map quote;
   781 
   782 (*concatenate messages, one per line, into a string*)
   783 val cat_lines = space_implode "\n";
   784 
   785 (*space_explode "." "h.e..l.lo" = ["h", "e", "", "l", "lo"]*)
   786 fun space_explode _ "" = []
   787   | space_explode sep str =
   788       let
   789         fun expl chs =
   790           (case take_prefix (not_equal sep) chs of
   791             (cs, []) => [implode cs]
   792           | (cs, _ :: cs') => implode cs :: expl cs');
   793       in expl (explode str) end;
   794 
   795 val split_lines = space_explode "\n";
   796 
   797 fun prefix_lines "" txt = txt
   798   | prefix_lines prfx txt = txt |> split_lines |> map (fn s => prfx ^ s) |> cat_lines;
   799 
   800 fun untabify chs =
   801   let
   802     val tab_width = 8;
   803 
   804     fun untab (_, "\n") = (0, ["\n"])
   805       | untab (pos, "\t") =
   806           let val d = tab_width - (pos mod tab_width) in (pos + d, replicate d " ") end
   807       | untab (pos, c) = (pos + 1, [c]);
   808   in
   809     if not (exists (equal "\t") chs) then chs
   810     else flat (#2 (foldl_map untab (0, chs)))
   811   end;
   812 
   813 fun suffix sffx s = s ^ sffx;
   814 
   815 fun unsuffix sffx s =
   816   let val m = size sffx; val n = size s - m in
   817     if n >= 0 andalso String.substring (s, n, m) = sffx then String.substring (s, 0, n)
   818     else raise Fail "unsuffix"
   819   end;
   820 
   821 fun unprefix prfx s =
   822   let val m = size prfx; val n = size s - m in
   823     if String.isPrefix prfx s then String.substring (s, m, n)
   824     else raise Fail "unprefix"
   825   end;
   826 
   827 fun replicate_string 0 _ = ""
   828   | replicate_string 1 a = a
   829   | replicate_string k a =
   830       if k mod 2 = 0 then replicate_string (k div 2) (a ^ a)
   831       else replicate_string (k div 2) (a ^ a) ^ a;
   832 
   833 
   834 
   835 (** lists as sets -- see also Pure/General/ord_list.ML **)
   836 
   837 (*membership in a list*)
   838 fun x mem [] = false
   839   | x mem (y :: ys) = x = y orelse x mem ys;
   840 
   841 (*membership in a list, optimized version for ints*)
   842 fun (x:int) mem_int [] = false
   843   | x mem_int (y :: ys) = x = y orelse x mem_int ys;
   844 
   845 (*membership in a list, optimized version for strings*)
   846 fun (x:string) mem_string [] = false
   847   | x mem_string (y :: ys) = x = y orelse x mem_string ys;
   848 
   849 (*generalized membership test*)
   850 fun gen_mem eq (x, []) = false
   851   | gen_mem eq (x, y :: ys) = eq (x, y) orelse gen_mem eq (x, ys);
   852 
   853 (*member, insert, and remove -- with canonical argument order*)
   854 fun member eq xs x = gen_mem eq (x, xs);
   855 fun insert eq x xs = if gen_mem eq (x, xs) then xs else x :: xs;
   856 fun remove eq x xs = if gen_mem eq (x, xs) then filter_out (fn y => eq (x, y)) xs else xs;
   857 
   858 (*insertion into list if not already there*)
   859 fun (x ins xs) = if x mem xs then xs else x :: xs;
   860 
   861 (*insertion into list, optimized version for ints*)
   862 fun (x ins_int xs) = if x mem_int xs then xs else x :: xs;
   863 
   864 (*insertion into list, optimized version for strings*)
   865 fun (x ins_string xs) = if x mem_string xs then xs else x :: xs;
   866 
   867 (*generalized insertion*)
   868 fun gen_ins eq (x, xs) = insert eq x xs;
   869 
   870 (*union of sets represented as lists: no repetitions*)
   871 fun xs union [] = xs
   872   | [] union ys = ys
   873   | (x :: xs) union ys = xs union (x ins ys);
   874 
   875 (*union of sets, optimized version for ints*)
   876 fun (xs:int list) union_int [] = xs
   877   | [] union_int ys = ys
   878   | (x :: xs) union_int ys = xs union_int (x ins_int ys);
   879 
   880 (*union of sets, optimized version for strings*)
   881 fun (xs:string list) union_string [] = xs
   882   | [] union_string ys = ys
   883   | (x :: xs) union_string ys = xs union_string (x ins_string ys);
   884 
   885 (*generalized union*)
   886 fun gen_union eq (xs, []) = xs
   887   | gen_union eq ([], ys) = ys
   888   | gen_union eq (x :: xs, ys) = gen_union eq (xs, gen_ins eq (x, ys));
   889 
   890 
   891 (*intersection*)
   892 fun [] inter ys = []
   893   | (x :: xs) inter ys =
   894       if x mem ys then x :: (xs inter ys) else xs inter ys;
   895 
   896 (*intersection, optimized version for ints*)
   897 fun ([]:int list) inter_int ys = []
   898   | (x :: xs) inter_int ys =
   899       if x mem_int ys then x :: (xs inter_int ys) else xs inter_int ys;
   900 
   901 (*intersection, optimized version for strings *)
   902 fun ([]:string list) inter_string ys = []
   903   | (x :: xs) inter_string ys =
   904       if x mem_string ys then x :: (xs inter_string ys) else xs inter_string ys;
   905 
   906 (*generalized intersection*)
   907 fun gen_inter eq ([], ys) = []
   908   | gen_inter eq (x::xs, ys) =
   909       if gen_mem eq (x,ys) then x :: gen_inter eq (xs, ys)
   910                            else      gen_inter eq (xs, ys);
   911 
   912 
   913 (*subset*)
   914 fun [] subset ys = true
   915   | (x :: xs) subset ys = x mem ys andalso xs subset ys;
   916 
   917 (*subset, optimized version for ints*)
   918 fun ([]: int list) subset_int ys = true
   919   | (x :: xs) subset_int ys = x mem_int ys andalso xs subset_int ys;
   920 
   921 (*subset, optimized version for strings*)
   922 fun ([]: string list) subset_string ys = true
   923   | (x :: xs) subset_string ys = x mem_string ys andalso xs subset_string ys;
   924 
   925 (*set equality*)
   926 fun eq_set (xs, ys) =
   927   xs = ys orelse (xs subset ys andalso ys subset xs);
   928 
   929 (*set equality for strings*)
   930 fun eq_set_string ((xs: string list), ys) =
   931   xs = ys orelse (xs subset_string ys andalso ys subset_string xs);
   932 
   933 fun gen_subset eq (xs, ys) = forall (fn x => gen_mem eq (x, ys)) xs;
   934 
   935 
   936 (*removing an element from a list WITHOUT duplicates*)
   937 fun (y :: ys) \ x = if x = y then ys else y :: (ys \ x)
   938   | [] \ x = [];
   939 
   940 fun ys \\ xs = foldl (op \) (ys,xs);
   941 
   942 (*removing an element from a list -- possibly WITH duplicates*)
   943 fun gen_rem eq (xs, y) = filter_out (fn x => eq (x, y)) xs;
   944 fun gen_rems eq (xs, ys) = filter_out (fn x => gen_mem eq (x, ys)) xs;
   945 
   946 (*makes a list of the distinct members of the input; preserves order, takes
   947   first of equal elements*)
   948 fun gen_distinct eq lst =
   949   let
   950     val memb = gen_mem eq;
   951 
   952     fun dist (rev_seen, []) = rev rev_seen
   953       | dist (rev_seen, x :: xs) =
   954           if memb (x, rev_seen) then dist (rev_seen, xs)
   955           else dist (x :: rev_seen, xs);
   956   in
   957     dist ([], lst)
   958   end;
   959 
   960 fun distinct l = gen_distinct (op =) l;
   961 
   962 
   963 (*returns the tail beginning with the first repeated element, or []*)
   964 fun findrep [] = []
   965   | findrep (x :: xs) = if x mem xs then x :: xs else findrep xs;
   966 
   967 
   968 (*returns a list containing all repeated elements exactly once; preserves
   969   order, takes first of equal elements*)
   970 fun gen_duplicates eq lst =
   971   let
   972     val memb = gen_mem eq;
   973 
   974     fun dups (rev_dups, []) = rev rev_dups
   975       | dups (rev_dups, x :: xs) =
   976           if memb (x, rev_dups) orelse not (memb (x, xs)) then
   977             dups (rev_dups, xs)
   978           else dups (x :: rev_dups, xs);
   979   in
   980     dups ([], lst)
   981   end;
   982 
   983 fun duplicates l = gen_duplicates (op =) l;
   984 
   985 
   986 
   987 (** association lists **)
   988 
   989 (*association list lookup*)
   990 fun assoc ([], key) = NONE
   991   | assoc ((keyi, xi) :: pairs, key) =
   992       if key = keyi then SOME xi else assoc (pairs, key);
   993 
   994 (*association list lookup, optimized version for ints*)
   995 fun assoc_int ([], (key:int)) = NONE
   996   | assoc_int ((keyi, xi) :: pairs, key) =
   997       if key = keyi then SOME xi else assoc_int (pairs, key);
   998 
   999 (*association list lookup, optimized version for strings*)
  1000 fun assoc_string ([], (key:string)) = NONE
  1001   | assoc_string ((keyi, xi) :: pairs, key) =
  1002       if key = keyi then SOME xi else assoc_string (pairs, key);
  1003 
  1004 (*association list lookup, optimized version for string*ints*)
  1005 fun assoc_string_int ([], (key:string*int)) = NONE
  1006   | assoc_string_int ((keyi, xi) :: pairs, key) =
  1007       if key = keyi then SOME xi else assoc_string_int (pairs, key);
  1008 
  1009 fun assocs ps x =
  1010   (case assoc (ps, x) of
  1011     NONE => []
  1012   | SOME ys => ys);
  1013 
  1014 (*two-fold association list lookup*)
  1015 fun assoc2 (aal, (key1, key2)) =
  1016   (case assoc (aal, key1) of
  1017     SOME al => assoc (al, key2)
  1018   | NONE => NONE);
  1019 
  1020 (*generalized association list lookup*)
  1021 fun gen_assoc eq ([], key) = NONE
  1022   | gen_assoc eq ((keyi, xi) :: pairs, key) =
  1023       if eq (key, keyi) then SOME xi else gen_assoc eq (pairs, key);
  1024 
  1025 (*association list update*)
  1026 fun overwrite (al, p as (key, _)) =
  1027   let fun over ((q as (keyi, _)) :: pairs) =
  1028             if keyi = key then p :: pairs else q :: (over pairs)
  1029         | over [] = [p]
  1030   in over al end;
  1031 
  1032 fun gen_overwrite eq (al, p as (key, _)) =
  1033   let fun over ((q as (keyi, _)) :: pairs) =
  1034             if eq (keyi, key) then p :: pairs else q :: (over pairs)
  1035         | over [] = [p]
  1036   in over al end;
  1037 
  1038 
  1039 (* lists as tables *)
  1040 
  1041 fun gen_merge_lists _ xs [] = xs
  1042   | gen_merge_lists _ [] ys = ys
  1043   | gen_merge_lists eq xs ys = xs @ gen_rems eq (ys, xs);
  1044 
  1045 fun gen_merge_lists' _ xs [] = xs
  1046   | gen_merge_lists' _ [] ys = ys
  1047   | gen_merge_lists' eq xs ys = gen_rems eq (ys, xs) @ xs;
  1048 
  1049 fun merge_lists xs ys = gen_merge_lists (op =) xs ys;
  1050 fun merge_lists' xs ys = gen_merge_lists' (op =) xs ys;
  1051 fun merge_alists al = gen_merge_lists eq_fst al;
  1052 fun merge_alists' al = gen_merge_lists' eq_fst al;
  1053 
  1054 
  1055 
  1056 (** balanced trees **)
  1057 
  1058 exception Balance;      (*indicates non-positive argument to balancing fun*)
  1059 
  1060 (*balanced folding; avoids deep nesting*)
  1061 fun fold_bal f [x] = x
  1062   | fold_bal f [] = raise Balance
  1063   | fold_bal f xs =
  1064       let val (ps,qs) = splitAt(length xs div 2, xs)
  1065       in  f (fold_bal f ps, fold_bal f qs)  end;
  1066 
  1067 (*construct something of the form f(...g(...(x)...)) for balanced access*)
  1068 fun access_bal (f, g, x) n i =
  1069   let fun acc n i =     (*1<=i<=n*)
  1070           if n=1 then x else
  1071           let val n2 = n div 2
  1072           in  if i<=n2 then f (acc n2 i)
  1073                        else g (acc (n-n2) (i-n2))
  1074           end
  1075   in  if 1<=i andalso i<=n then acc n i else raise Balance  end;
  1076 
  1077 (*construct ALL such accesses; could try harder to share recursive calls!*)
  1078 fun accesses_bal (f, g, x) n =
  1079   let fun acc n =
  1080           if n=1 then [x] else
  1081           let val n2 = n div 2
  1082               val acc2 = acc n2
  1083           in  if n-n2=n2 then map f acc2 @ map g acc2
  1084                          else map f acc2 @ map g (acc (n-n2)) end
  1085   in  if 1<=n then acc n else raise Balance  end;
  1086 
  1087 
  1088 
  1089 (** orders **)
  1090 
  1091 fun rev_order LESS = GREATER
  1092   | rev_order EQUAL = EQUAL
  1093   | rev_order GREATER = LESS;
  1094 
  1095 (*assume rel is a linear strict order*)
  1096 fun make_ord rel (x, y) =
  1097   if rel (x, y) then LESS
  1098   else if rel (y, x) then GREATER
  1099   else EQUAL;
  1100 
  1101 val int_ord = Int.compare;
  1102 val string_ord = String.compare;
  1103 
  1104 fun fast_string_ord (s1, s2) =
  1105   (case int_ord (size s1, size s2) of EQUAL => string_ord (s1, s2) | ord => ord);
  1106 
  1107 fun option_ord ord (SOME x, SOME y) = ord (x, y)
  1108   | option_ord _ (NONE, NONE) = EQUAL
  1109   | option_ord _ (NONE, SOME _) = LESS
  1110   | option_ord _ (SOME _, NONE) = GREATER;
  1111 
  1112 (*lexicographic product*)
  1113 fun prod_ord a_ord b_ord ((x, y), (x', y')) =
  1114   (case a_ord (x, x') of EQUAL => b_ord (y, y') | ord => ord);
  1115 
  1116 (*dictionary order -- in general NOT well-founded!*)
  1117 fun dict_ord _ ([], []) = EQUAL
  1118   | dict_ord _ ([], _ :: _) = LESS
  1119   | dict_ord _ (_ :: _, []) = GREATER
  1120   | dict_ord elem_ord (x :: xs, y :: ys) =
  1121       (case elem_ord (x, y) of EQUAL => dict_ord elem_ord (xs, ys) | ord => ord);
  1122 
  1123 (*lexicographic product of lists*)
  1124 fun list_ord elem_ord (xs, ys) =
  1125   (case int_ord (length xs, length ys) of EQUAL => dict_ord elem_ord (xs, ys) | ord => ord);
  1126 
  1127 
  1128 (* sorting *)
  1129 
  1130 (*quicksort (stable, i.e. does not reorder equal elements)*)
  1131 fun sort ord =
  1132   let
  1133     fun qsort xs =
  1134       let val len = length xs in
  1135         if len <= 1 then xs
  1136         else
  1137           let val (lts, eqs, gts) = part (nth_elem (len div 2, xs)) xs in
  1138             qsort lts @ eqs @ qsort gts
  1139           end
  1140       end
  1141     and part _ [] = ([], [], [])
  1142       | part pivot (x :: xs) = add (ord (x, pivot)) x (part pivot xs)
  1143     and add LESS x (lts, eqs, gts) = (x :: lts, eqs, gts)
  1144       | add EQUAL x (lts, eqs, gts) = (lts, x :: eqs, gts)
  1145       | add GREATER x (lts, eqs, gts) = (lts, eqs, x :: gts);
  1146   in qsort end;
  1147 
  1148 (*sort strings*)
  1149 val sort_strings = sort string_ord;
  1150 fun sort_wrt sel xs = sort (string_ord o pairself sel) xs;
  1151 
  1152 fun unique_strings ([]: string list) = []
  1153   | unique_strings [x] = [x]
  1154   | unique_strings (x :: y :: ys) =
  1155       if x = y then unique_strings (y :: ys)
  1156       else x :: unique_strings (y :: ys);
  1157 
  1158 
  1159 (** random numbers **)
  1160 
  1161 exception RANDOM;
  1162 
  1163 fun rmod x y = x - y * Real.realFloor (x / y);
  1164 
  1165 local
  1166   val a = 16807.0;
  1167   val m = 2147483647.0;
  1168   val random_seed = ref 1.0;
  1169 in
  1170 
  1171 fun random () =
  1172   let val r = rmod (a * !random_seed) m
  1173   in (random_seed := r; r) end;
  1174 
  1175 end;
  1176 
  1177 fun random_range l h =
  1178   if h < l orelse l < 0 then raise RANDOM
  1179   else l + Real.floor (rmod (random ()) (real (h - l + 1)));
  1180 
  1181 fun one_of xs = nth_elem (random_range 0 (length xs - 1), xs);
  1182 
  1183 fun frequency xs =
  1184   let
  1185     val sum = foldl op + (0, map fst xs);
  1186     fun pick n ((k, x) :: xs) =
  1187       if n <= k then x else pick (n - k) xs
  1188   in pick (random_range 1 sum) xs end;
  1189 
  1190 
  1191 (** current directory **)
  1192 
  1193 val cd = OS.FileSys.chDir;
  1194 val pwd = OS.FileSys.getDir;
  1195 
  1196 
  1197 
  1198 (** rational numbers **)
  1199 
  1200 datatype rat = Rat of bool * IntInf.int * IntInf.int
  1201 
  1202 exception RAT of string;
  1203 
  1204 fun rep_rat(Rat(a,p,q)) = (if a then p else ~p,q)
  1205 
  1206 fun ratnorm(a,p,q) = if p=0 then Rat(a,0,1) else
  1207   let val absp = abs p
  1208       val m = gcd(absp,q)
  1209   in Rat(a = (0 <= p), absp div m, q div m) end;
  1210 
  1211 fun ratadd(Rat(a,p,q),Rat(b,r,s)) =
  1212   let val den = lcm(q,s)
  1213       val p = p*(den div q) and r = r*(den div s)
  1214       val num = (if a then p else ~p) + (if b then r else ~r)
  1215   in ratnorm(true,num,den) end;
  1216 
  1217 fun ratmul(Rat(a,p,q),Rat(b,r,s)) = ratnorm(a=b,p*r,q*s)
  1218 
  1219 fun ratinv(Rat(a,p,q)) = if p=0 then raise RAT "ratinv" else Rat(a,q,p)
  1220 
  1221 fun int_ratdiv(p,q) =
  1222   if q=0 then raise RAT "int_ratdiv" else ratnorm(0<=q, p, abs q)
  1223 
  1224 fun ratneg(Rat(b,p,q)) = Rat(not b,p,q);
  1225 
  1226 fun rat_of_intinf i = if i < 0 then Rat(false,abs i,1) else Rat(true,i,1);
  1227 
  1228 fun rat_of_int i = rat_of_intinf (IntInf.fromInt i);
  1229 
  1230 
  1231 (** misc **)
  1232 
  1233 (*use the keyfun to make a list of (x, key) pairs*)
  1234 fun make_keylist (keyfun: 'a->'b) : 'a list -> ('a * 'b) list =
  1235   let fun keypair x = (x, keyfun x)
  1236   in map keypair end;
  1237 
  1238 (*given a list of (x, key) pairs and a searchkey
  1239   return the list of xs from each pair whose key equals searchkey*)
  1240 fun keyfilter [] searchkey = []
  1241   | keyfilter ((x, key) :: pairs) searchkey =
  1242       if key = searchkey then x :: keyfilter pairs searchkey
  1243       else keyfilter pairs searchkey;
  1244 
  1245 
  1246 (*Partition list into elements that satisfy predicate and those that don't.
  1247   Preserves order of elements in both lists.*)
  1248 val partition = List.partition;
  1249 
  1250 
  1251 fun partition_eq (eq:'a * 'a -> bool) =
  1252     let fun part [] = []
  1253           | part (x::ys) = let val (xs, xs') = partition (apl(x, eq)) ys
  1254                            in (x::xs)::(part xs') end
  1255     in part end;
  1256 
  1257 
  1258 (*Partition a list into buckets  [ bi, b(i+1), ..., bj ]
  1259    putting x in bk if p(k)(x) holds.  Preserve order of elements if possible.*)
  1260 fun partition_list p i j =
  1261   let fun part k xs =
  1262             if k>j then
  1263               (case xs of [] => []
  1264                          | _ => raise Fail "partition_list")
  1265             else
  1266             let val (ns, rest) = partition (p k) xs;
  1267             in  ns :: part(k+1)rest  end
  1268   in  part i end;
  1269 
  1270 
  1271 (* generating identifiers *)
  1272 
  1273 (** Freshly generated identifiers; supplied prefix MUST start with a letter **)
  1274 local
  1275 (*Maps 0-63 to A-Z, a-z, 0-9 or _ or ' for generating random identifiers*)
  1276 fun char i =      if i<26 then chr (ord "A" + i)
  1277              else if i<52 then chr (ord "a" + i - 26)
  1278              else if i<62 then chr (ord"0" + i - 52)
  1279              else if i=62 then "_"
  1280              else  (*i=63*)    "'";
  1281 
  1282 val charVec = Vector.tabulate (64, char);
  1283 
  1284 fun newid n =
  1285   let
  1286   in  implode (map (fn i => Vector.sub(charVec,i)) (radixpand (64,n)))  end;
  1287 
  1288 val seedr = ref 0;
  1289 
  1290 in
  1291 
  1292 fun gensym pre = pre ^ (#1(newid (!seedr), inc seedr));
  1293 
  1294 end;
  1295 
  1296 
  1297 (* lexical scanning *)
  1298 
  1299 (*scan a list of characters into "words" composed of "letters" (recognized by
  1300   is_let) and separated by any number of non-"letters"*)
  1301 fun scanwords is_let cs =
  1302   let fun scan1 [] = []
  1303         | scan1 cs =
  1304             let val (lets, rest) = take_prefix is_let cs
  1305             in implode lets :: scanwords is_let rest end;
  1306   in scan1 (#2 (take_prefix (not o is_let) cs)) end;
  1307 
  1308 
  1309 (* stamps and serial numbers *)
  1310 
  1311 type stamp = unit ref;
  1312 val stamp: unit -> stamp = ref;
  1313 
  1314 type serial = int;
  1315 local val count = ref 0
  1316 in fun serial () = inc count end;
  1317 
  1318 
  1319 (* generic objects *)
  1320 
  1321 (*note that the builtin exception datatype may be extended by new
  1322   constructors at any time*)
  1323 structure Object = struct type T = exn end;
  1324 
  1325 end;
  1326 
  1327 structure BasicLibrary: BASIC_LIBRARY = Library;
  1328 open BasicLibrary;