src/HOL/HOL.thy
 author paulson Tue Apr 25 16:39:54 2017 +0100 (2017-04-25) changeset 65578 e4997c181cce parent 63912 9f8325206465 child 66109 e034a563ed7d permissions -rw-r--r--
New material from PNT proof, as well as more default [simp] declarations. Also removed duplicate theorems about geometric series
1 (*  Title:      HOL/HOL.thy
2     Author:     Tobias Nipkow, Markus Wenzel, and Larry Paulson
3 *)
5 section \<open>The basis of Higher-Order Logic\<close>
7 theory HOL
8 imports Pure "~~/src/Tools/Code_Generator"
9 keywords
10   "try" "solve_direct" "quickcheck" "print_coercions" "print_claset"
11     "print_induct_rules" :: diag and
12   "quickcheck_params" :: thy_decl
13 begin
15 ML_file "~~/src/Tools/misc_legacy.ML"
16 ML_file "~~/src/Tools/try.ML"
17 ML_file "~~/src/Tools/quickcheck.ML"
18 ML_file "~~/src/Tools/solve_direct.ML"
19 ML_file "~~/src/Tools/IsaPlanner/zipper.ML"
20 ML_file "~~/src/Tools/IsaPlanner/isand.ML"
21 ML_file "~~/src/Tools/IsaPlanner/rw_inst.ML"
22 ML_file "~~/src/Provers/hypsubst.ML"
23 ML_file "~~/src/Provers/splitter.ML"
24 ML_file "~~/src/Provers/classical.ML"
25 ML_file "~~/src/Provers/blast.ML"
26 ML_file "~~/src/Provers/clasimp.ML"
27 ML_file "~~/src/Tools/eqsubst.ML"
28 ML_file "~~/src/Provers/quantifier1.ML"
29 ML_file "~~/src/Tools/atomize_elim.ML"
30 ML_file "~~/src/Tools/cong_tac.ML"
31 ML_file "~~/src/Tools/intuitionistic.ML" setup \<open>Intuitionistic.method_setup @{binding iprover}\<close>
32 ML_file "~~/src/Tools/project_rule.ML"
33 ML_file "~~/src/Tools/subtyping.ML"
34 ML_file "~~/src/Tools/case_product.ML"
37 ML \<open>Plugin_Name.declare_setup @{binding extraction}\<close>
39 ML \<open>
40   Plugin_Name.declare_setup @{binding quickcheck_random};
41   Plugin_Name.declare_setup @{binding quickcheck_exhaustive};
42   Plugin_Name.declare_setup @{binding quickcheck_bounded_forall};
43   Plugin_Name.declare_setup @{binding quickcheck_full_exhaustive};
44   Plugin_Name.declare_setup @{binding quickcheck_narrowing};
45 \<close>
46 ML \<open>
47   Plugin_Name.define_setup @{binding quickcheck}
48    [@{plugin quickcheck_exhaustive},
49     @{plugin quickcheck_random},
50     @{plugin quickcheck_bounded_forall},
51     @{plugin quickcheck_full_exhaustive},
52     @{plugin quickcheck_narrowing}]
53 \<close>
56 subsection \<open>Primitive logic\<close>
58 subsubsection \<open>Core syntax\<close>
60 setup \<open>Axclass.class_axiomatization (@{binding type}, [])\<close>
61 default_sort type
62 setup \<open>Object_Logic.add_base_sort @{sort type}\<close>
64 axiomatization where fun_arity: "OFCLASS('a \<Rightarrow> 'b, type_class)"
65 instance "fun" :: (type, type) type by (rule fun_arity)
67 axiomatization where itself_arity: "OFCLASS('a itself, type_class)"
68 instance itself :: (type) type by (rule itself_arity)
70 typedecl bool
72 judgment Trueprop :: "bool \<Rightarrow> prop"  ("(_)" 5)
74 axiomatization implies :: "[bool, bool] \<Rightarrow> bool"  (infixr "\<longrightarrow>" 25)
75   and eq :: "['a, 'a] \<Rightarrow> bool"  (infixl "=" 50)
76   and The :: "('a \<Rightarrow> bool) \<Rightarrow> 'a"
79 subsubsection \<open>Defined connectives and quantifiers\<close>
81 definition True :: bool
82   where "True \<equiv> ((\<lambda>x::bool. x) = (\<lambda>x. x))"
84 definition All :: "('a \<Rightarrow> bool) \<Rightarrow> bool"  (binder "\<forall>" 10)
85   where "All P \<equiv> (P = (\<lambda>x. True))"
87 definition Ex :: "('a \<Rightarrow> bool) \<Rightarrow> bool"  (binder "\<exists>" 10)
88   where "Ex P \<equiv> \<forall>Q. (\<forall>x. P x \<longrightarrow> Q) \<longrightarrow> Q"
90 definition False :: bool
91   where "False \<equiv> (\<forall>P. P)"
93 definition Not :: "bool \<Rightarrow> bool"  ("\<not> _"  40)
94   where not_def: "\<not> P \<equiv> P \<longrightarrow> False"
96 definition conj :: "[bool, bool] \<Rightarrow> bool"  (infixr "\<and>" 35)
97   where and_def: "P \<and> Q \<equiv> \<forall>R. (P \<longrightarrow> Q \<longrightarrow> R) \<longrightarrow> R"
99 definition disj :: "[bool, bool] \<Rightarrow> bool"  (infixr "\<or>" 30)
100   where or_def: "P \<or> Q \<equiv> \<forall>R. (P \<longrightarrow> R) \<longrightarrow> (Q \<longrightarrow> R) \<longrightarrow> R"
102 definition Ex1 :: "('a \<Rightarrow> bool) \<Rightarrow> bool"
103   where "Ex1 P \<equiv> \<exists>x. P x \<and> (\<forall>y. P y \<longrightarrow> y = x)"
106 subsubsection \<open>Additional concrete syntax\<close>
108 syntax (ASCII)
109   "_Ex1" :: "pttrn \<Rightarrow> bool \<Rightarrow> bool"  ("(3EX! _./ _)" [0, 10] 10)
110 syntax (input)
111   "_Ex1" :: "pttrn \<Rightarrow> bool \<Rightarrow> bool"  ("(3?! _./ _)" [0, 10] 10)
112 syntax "_Ex1" :: "pttrn \<Rightarrow> bool \<Rightarrow> bool"  ("(3\<exists>!_./ _)" [0, 10] 10)
113 translations "\<exists>!x. P" \<rightleftharpoons> "CONST Ex1 (\<lambda>x. P)"
115 print_translation \<open>
116  [Syntax_Trans.preserve_binder_abs_tr' @{const_syntax Ex1} @{syntax_const "_Ex1"}]
117 \<close> \<comment> \<open>to avoid eta-contraction of body\<close>
120 syntax
121   "_Not_Ex" :: "idts \<Rightarrow> bool \<Rightarrow> bool"  ("(3\<nexists>_./ _)" [0, 10] 10)
122   "_Not_Ex1" :: "pttrn \<Rightarrow> bool \<Rightarrow> bool"  ("(3\<nexists>!_./ _)" [0, 10] 10)
123 translations
124   "\<nexists>x. P" \<rightleftharpoons> "\<not> (\<exists>x. P)"
125   "\<nexists>!x. P" \<rightleftharpoons> "\<not> (\<exists>!x. P)"
128 abbreviation not_equal :: "['a, 'a] \<Rightarrow> bool"  (infixl "\<noteq>" 50)
129   where "x \<noteq> y \<equiv> \<not> (x = y)"
131 notation (output)
132   eq  (infix "=" 50) and
133   not_equal  (infix "\<noteq>" 50)
135 notation (ASCII output)
136   not_equal  (infix "~=" 50)
138 notation (ASCII)
139   Not  ("~ _"  40) and
140   conj  (infixr "&" 35) and
141   disj  (infixr "|" 30) and
142   implies  (infixr "-->" 25) and
143   not_equal  (infixl "~=" 50)
145 abbreviation (iff)
146   iff :: "[bool, bool] \<Rightarrow> bool"  (infixr "\<longleftrightarrow>" 25)
147   where "A \<longleftrightarrow> B \<equiv> A = B"
149 syntax "_The" :: "[pttrn, bool] \<Rightarrow> 'a"  ("(3THE _./ _)" [0, 10] 10)
150 translations "THE x. P" \<rightleftharpoons> "CONST The (\<lambda>x. P)"
151 print_translation \<open>
152   [(@{const_syntax The}, fn _ => fn [Abs abs] =>
153       let val (x, t) = Syntax_Trans.atomic_abs_tr' abs
154       in Syntax.const @{syntax_const "_The"} \$ x \$ t end)]
155 \<close>  \<comment> \<open>To avoid eta-contraction of body\<close>
157 nonterminal letbinds and letbind
158 syntax
159   "_bind"       :: "[pttrn, 'a] \<Rightarrow> letbind"              ("(2_ =/ _)" 10)
160   ""            :: "letbind \<Rightarrow> letbinds"                 ("_")
161   "_binds"      :: "[letbind, letbinds] \<Rightarrow> letbinds"     ("_;/ _")
162   "_Let"        :: "[letbinds, 'a] \<Rightarrow> 'a"                ("(let (_)/ in (_))" [0, 10] 10)
164 nonterminal case_syn and cases_syn
165 syntax
166   "_case_syntax" :: "['a, cases_syn] \<Rightarrow> 'b"  ("(case _ of/ _)" 10)
167   "_case1" :: "['a, 'b] \<Rightarrow> case_syn"  ("(2_ \<Rightarrow>/ _)" 10)
168   "" :: "case_syn \<Rightarrow> cases_syn"  ("_")
169   "_case2" :: "[case_syn, cases_syn] \<Rightarrow> cases_syn"  ("_/ | _")
170 syntax (ASCII)
171   "_case1" :: "['a, 'b] \<Rightarrow> case_syn"  ("(2_ =>/ _)" 10)
173 notation (ASCII)
174   All  (binder "ALL " 10) and
175   Ex  (binder "EX " 10)
177 notation (input)
178   All  (binder "! " 10) and
179   Ex  (binder "? " 10)
182 subsubsection \<open>Axioms and basic definitions\<close>
184 axiomatization where
185   refl: "t = (t::'a)" and
186   subst: "s = t \<Longrightarrow> P s \<Longrightarrow> P t" and
187   ext: "(\<And>x::'a. (f x ::'b) = g x) \<Longrightarrow> (\<lambda>x. f x) = (\<lambda>x. g x)"
188     \<comment> \<open>Extensionality is built into the meta-logic, and this rule expresses
189          a related property.  It is an eta-expanded version of the traditional
190          rule, and similar to the ABS rule of HOL\<close> and
192   the_eq_trivial: "(THE x. x = a) = (a::'a)"
194 axiomatization where
195   impI: "(P \<Longrightarrow> Q) \<Longrightarrow> P \<longrightarrow> Q" and
196   mp: "\<lbrakk>P \<longrightarrow> Q; P\<rbrakk> \<Longrightarrow> Q" and
198   iff: "(P \<longrightarrow> Q) \<longrightarrow> (Q \<longrightarrow> P) \<longrightarrow> (P = Q)" and
199   True_or_False: "(P = True) \<or> (P = False)"
201 definition If :: "bool \<Rightarrow> 'a \<Rightarrow> 'a \<Rightarrow> 'a" ("(if (_)/ then (_)/ else (_))" [0, 0, 10] 10)
202   where "If P x y \<equiv> (THE z::'a. (P = True \<longrightarrow> z = x) \<and> (P = False \<longrightarrow> z = y))"
204 definition Let :: "'a \<Rightarrow> ('a \<Rightarrow> 'b) \<Rightarrow> 'b"
205   where "Let s f \<equiv> f s"
207 translations
208   "_Let (_binds b bs) e"  \<rightleftharpoons> "_Let b (_Let bs e)"
209   "let x = a in e"        \<rightleftharpoons> "CONST Let a (\<lambda>x. e)"
211 axiomatization undefined :: 'a
213 class default = fixes default :: 'a
216 subsection \<open>Fundamental rules\<close>
218 subsubsection \<open>Equality\<close>
220 lemma sym: "s = t \<Longrightarrow> t = s"
221   by (erule subst) (rule refl)
223 lemma ssubst: "t = s \<Longrightarrow> P s \<Longrightarrow> P t"
224   by (drule sym) (erule subst)
226 lemma trans: "\<lbrakk>r = s; s = t\<rbrakk> \<Longrightarrow> r = t"
227   by (erule subst)
229 lemma trans_sym [Pure.elim?]: "r = s \<Longrightarrow> t = s \<Longrightarrow> r = t"
230   by (rule trans [OF _ sym])
232 lemma meta_eq_to_obj_eq:
233   assumes "A \<equiv> B"
234   shows "A = B"
235   unfolding assms by (rule refl)
237 text \<open>Useful with \<open>erule\<close> for proving equalities from known equalities.\<close>
238      (* a = b
239         |   |
240         c = d   *)
241 lemma box_equals: "\<lbrakk>a = b; a = c; b = d\<rbrakk> \<Longrightarrow> c = d"
242   apply (rule trans)
243    apply (rule trans)
244     apply (rule sym)
245     apply assumption+
246   done
248 text \<open>For calculational reasoning:\<close>
250 lemma forw_subst: "a = b \<Longrightarrow> P b \<Longrightarrow> P a"
251   by (rule ssubst)
253 lemma back_subst: "P a \<Longrightarrow> a = b \<Longrightarrow> P b"
254   by (rule subst)
257 subsubsection \<open>Congruence rules for application\<close>
259 text \<open>Similar to \<open>AP_THM\<close> in Gordon's HOL.\<close>
260 lemma fun_cong: "(f :: 'a \<Rightarrow> 'b) = g \<Longrightarrow> f x = g x"
261   apply (erule subst)
262   apply (rule refl)
263   done
265 text \<open>Similar to \<open>AP_TERM\<close> in Gordon's HOL and FOL's \<open>subst_context\<close>.\<close>
266 lemma arg_cong: "x = y \<Longrightarrow> f x = f y"
267   apply (erule subst)
268   apply (rule refl)
269   done
271 lemma arg_cong2: "\<lbrakk>a = b; c = d\<rbrakk> \<Longrightarrow> f a c = f b d"
272   apply (erule ssubst)+
273   apply (rule refl)
274   done
276 lemma cong: "\<lbrakk>f = g; (x::'a) = y\<rbrakk> \<Longrightarrow> f x = g y"
277   apply (erule subst)+
278   apply (rule refl)
279   done
281 ML \<open>fun cong_tac ctxt = Cong_Tac.cong_tac ctxt @{thm cong}\<close>
284 subsubsection \<open>Equality of booleans -- iff\<close>
286 lemma iffI: assumes "P \<Longrightarrow> Q" and "Q \<Longrightarrow> P" shows "P = Q"
287   by (iprover intro: iff [THEN mp, THEN mp] impI assms)
289 lemma iffD2: "\<lbrakk>P = Q; Q\<rbrakk> \<Longrightarrow> P"
290   by (erule ssubst)
292 lemma rev_iffD2: "\<lbrakk>Q; P = Q\<rbrakk> \<Longrightarrow> P"
293   by (erule iffD2)
295 lemma iffD1: "Q = P \<Longrightarrow> Q \<Longrightarrow> P"
296   by (drule sym) (rule iffD2)
298 lemma rev_iffD1: "Q \<Longrightarrow> Q = P \<Longrightarrow> P"
299   by (drule sym) (rule rev_iffD2)
301 lemma iffE:
302   assumes major: "P = Q"
303     and minor: "\<lbrakk>P \<longrightarrow> Q; Q \<longrightarrow> P\<rbrakk> \<Longrightarrow> R"
304   shows R
305   by (iprover intro: minor impI major [THEN iffD2] major [THEN iffD1])
308 subsubsection \<open>True\<close>
310 lemma TrueI: True
311   unfolding True_def by (rule refl)
313 lemma eqTrueI: "P \<Longrightarrow> P = True"
314   by (iprover intro: iffI TrueI)
316 lemma eqTrueE: "P = True \<Longrightarrow> P"
317   by (erule iffD2) (rule TrueI)
320 subsubsection \<open>Universal quantifier\<close>
322 lemma allI:
323   assumes "\<And>x::'a. P x"
324   shows "\<forall>x. P x"
325   unfolding All_def by (iprover intro: ext eqTrueI assms)
327 lemma spec: "\<forall>x::'a. P x \<Longrightarrow> P x"
328   apply (unfold All_def)
329   apply (rule eqTrueE)
330   apply (erule fun_cong)
331   done
333 lemma allE:
334   assumes major: "\<forall>x. P x"
335     and minor: "P x \<Longrightarrow> R"
336   shows R
337   by (iprover intro: minor major [THEN spec])
339 lemma all_dupE:
340   assumes major: "\<forall>x. P x"
341     and minor: "\<lbrakk>P x; \<forall>x. P x\<rbrakk> \<Longrightarrow> R"
342   shows R
343   by (iprover intro: minor major major [THEN spec])
346 subsubsection \<open>False\<close>
348 text \<open>
349   Depends upon \<open>spec\<close>; it is impossible to do propositional
350   logic before quantifiers!
351 \<close>
353 lemma FalseE: "False \<Longrightarrow> P"
354   apply (unfold False_def)
355   apply (erule spec)
356   done
358 lemma False_neq_True: "False = True \<Longrightarrow> P"
359   by (erule eqTrueE [THEN FalseE])
362 subsubsection \<open>Negation\<close>
364 lemma notI:
365   assumes "P \<Longrightarrow> False"
366   shows "\<not> P"
367   apply (unfold not_def)
368   apply (iprover intro: impI assms)
369   done
371 lemma False_not_True: "False \<noteq> True"
372   apply (rule notI)
373   apply (erule False_neq_True)
374   done
376 lemma True_not_False: "True \<noteq> False"
377   apply (rule notI)
378   apply (drule sym)
379   apply (erule False_neq_True)
380   done
382 lemma notE: "\<lbrakk>\<not> P; P\<rbrakk> \<Longrightarrow> R"
383   apply (unfold not_def)
384   apply (erule mp [THEN FalseE])
385   apply assumption
386   done
388 lemma notI2: "(P \<Longrightarrow> \<not> Pa) \<Longrightarrow> (P \<Longrightarrow> Pa) \<Longrightarrow> \<not> P"
389   by (erule notE [THEN notI]) (erule meta_mp)
392 subsubsection \<open>Implication\<close>
394 lemma impE:
395   assumes "P \<longrightarrow> Q" P "Q \<Longrightarrow> R"
396   shows R
397   by (iprover intro: assms mp)
399 text \<open>Reduces \<open>Q\<close> to \<open>P \<longrightarrow> Q\<close>, allowing substitution in \<open>P\<close>.\<close>
400 lemma rev_mp: "\<lbrakk>P; P \<longrightarrow> Q\<rbrakk> \<Longrightarrow> Q"
401   by (iprover intro: mp)
403 lemma contrapos_nn:
404   assumes major: "\<not> Q"
405     and minor: "P \<Longrightarrow> Q"
406   shows "\<not> P"
407   by (iprover intro: notI minor major [THEN notE])
409 text \<open>Not used at all, but we already have the other 3 combinations.\<close>
410 lemma contrapos_pn:
411   assumes major: "Q"
412     and minor: "P \<Longrightarrow> \<not> Q"
413   shows "\<not> P"
414   by (iprover intro: notI minor major notE)
416 lemma not_sym: "t \<noteq> s \<Longrightarrow> s \<noteq> t"
417   by (erule contrapos_nn) (erule sym)
419 lemma eq_neq_eq_imp_neq: "\<lbrakk>x = a; a \<noteq> b; b = y\<rbrakk> \<Longrightarrow> x \<noteq> y"
420   by (erule subst, erule ssubst, assumption)
423 subsubsection \<open>Existential quantifier\<close>
425 lemma exI: "P x \<Longrightarrow> \<exists>x::'a. P x"
426   unfolding Ex_def by (iprover intro: allI allE impI mp)
428 lemma exE:
429   assumes major: "\<exists>x::'a. P x"
430     and minor: "\<And>x. P x \<Longrightarrow> Q"
431   shows "Q"
432   by (rule major [unfolded Ex_def, THEN spec, THEN mp]) (iprover intro: impI [THEN allI] minor)
435 subsubsection \<open>Conjunction\<close>
437 lemma conjI: "\<lbrakk>P; Q\<rbrakk> \<Longrightarrow> P \<and> Q"
438   unfolding and_def by (iprover intro: impI [THEN allI] mp)
440 lemma conjunct1: "\<lbrakk>P \<and> Q\<rbrakk> \<Longrightarrow> P"
441   unfolding and_def by (iprover intro: impI dest: spec mp)
443 lemma conjunct2: "\<lbrakk>P \<and> Q\<rbrakk> \<Longrightarrow> Q"
444   unfolding and_def by (iprover intro: impI dest: spec mp)
446 lemma conjE:
447   assumes major: "P \<and> Q"
448     and minor: "\<lbrakk>P; Q\<rbrakk> \<Longrightarrow> R"
449   shows R
450   apply (rule minor)
451    apply (rule major [THEN conjunct1])
452   apply (rule major [THEN conjunct2])
453   done
455 lemma context_conjI:
456   assumes P "P \<Longrightarrow> Q"
457   shows "P \<and> Q"
458   by (iprover intro: conjI assms)
461 subsubsection \<open>Disjunction\<close>
463 lemma disjI1: "P \<Longrightarrow> P \<or> Q"
464   unfolding or_def by (iprover intro: allI impI mp)
466 lemma disjI2: "Q \<Longrightarrow> P \<or> Q"
467   unfolding or_def by (iprover intro: allI impI mp)
469 lemma disjE:
470   assumes major: "P \<or> Q"
471     and minorP: "P \<Longrightarrow> R"
472     and minorQ: "Q \<Longrightarrow> R"
473   shows R
474   by (iprover intro: minorP minorQ impI
475       major [unfolded or_def, THEN spec, THEN mp, THEN mp])
478 subsubsection \<open>Classical logic\<close>
480 lemma classical:
481   assumes prem: "\<not> P \<Longrightarrow> P"
482   shows P
483   apply (rule True_or_False [THEN disjE, THEN eqTrueE])
484    apply assumption
485   apply (rule notI [THEN prem, THEN eqTrueI])
486   apply (erule subst)
487   apply assumption
488   done
490 lemmas ccontr = FalseE [THEN classical]
492 text \<open>\<open>notE\<close> with premises exchanged; it discharges \<open>\<not> R\<close> so that it can be used to
493   make elimination rules.\<close>
494 lemma rev_notE:
495   assumes premp: P
496     and premnot: "\<not> R \<Longrightarrow> \<not> P"
497   shows R
498   apply (rule ccontr)
499   apply (erule notE [OF premnot premp])
500   done
502 text \<open>Double negation law.\<close>
503 lemma notnotD: "\<not>\<not> P \<Longrightarrow> P"
504   apply (rule classical)
505   apply (erule notE)
506   apply assumption
507   done
509 lemma contrapos_pp:
510   assumes p1: Q
511     and p2: "\<not> P \<Longrightarrow> \<not> Q"
512   shows P
513   by (iprover intro: classical p1 p2 notE)
516 subsubsection \<open>Unique existence\<close>
518 lemma ex1I:
519   assumes "P a" "\<And>x. P x \<Longrightarrow> x = a"
520   shows "\<exists>!x. P x"
521   unfolding Ex1_def by (iprover intro: assms exI conjI allI impI)
523 text \<open>Sometimes easier to use: the premises have no shared variables. Safe!\<close>
524 lemma ex_ex1I:
525   assumes ex_prem: "\<exists>x. P x"
526     and eq: "\<And>x y. \<lbrakk>P x; P y\<rbrakk> \<Longrightarrow> x = y"
527   shows "\<exists>!x. P x"
528   by (iprover intro: ex_prem [THEN exE] ex1I eq)
530 lemma ex1E:
531   assumes major: "\<exists>!x. P x"
532     and minor: "\<And>x. \<lbrakk>P x; \<forall>y. P y \<longrightarrow> y = x\<rbrakk> \<Longrightarrow> R"
533   shows R
534   apply (rule major [unfolded Ex1_def, THEN exE])
535   apply (erule conjE)
536   apply (iprover intro: minor)
537   done
539 lemma ex1_implies_ex: "\<exists>!x. P x \<Longrightarrow> \<exists>x. P x"
540   apply (erule ex1E)
541   apply (rule exI)
542   apply assumption
543   done
546 subsubsection \<open>Classical intro rules for disjunction and existential quantifiers\<close>
548 lemma disjCI:
549   assumes "\<not> Q \<Longrightarrow> P"
550   shows "P \<or> Q"
551   by (rule classical) (iprover intro: assms disjI1 disjI2 notI elim: notE)
553 lemma excluded_middle: "\<not> P \<or> P"
554   by (iprover intro: disjCI)
556 text \<open>
557   case distinction as a natural deduction rule.
558   Note that \<open>\<not> P\<close> is the second case, not the first.
559 \<close>
560 lemma case_split [case_names True False]:
561   assumes prem1: "P \<Longrightarrow> Q"
562     and prem2: "\<not> P \<Longrightarrow> Q"
563   shows Q
564   apply (rule excluded_middle [THEN disjE])
565    apply (erule prem2)
566   apply (erule prem1)
567   done
569 text \<open>Classical implies (\<open>\<longrightarrow>\<close>) elimination.\<close>
570 lemma impCE:
571   assumes major: "P \<longrightarrow> Q"
572     and minor: "\<not> P \<Longrightarrow> R" "Q \<Longrightarrow> R"
573   shows R
574   apply (rule excluded_middle [of P, THEN disjE])
575    apply (iprover intro: minor major [THEN mp])+
576   done
578 text \<open>
579   This version of \<open>\<longrightarrow>\<close> elimination works on \<open>Q\<close> before \<open>P\<close>.  It works best for
580   those cases in which \<open>P\<close> holds "almost everywhere".  Can't install as
581   default: would break old proofs.
582 \<close>
583 lemma impCE':
584   assumes major: "P \<longrightarrow> Q"
585     and minor: "Q \<Longrightarrow> R" "\<not> P \<Longrightarrow> R"
586   shows R
587   apply (rule excluded_middle [of P, THEN disjE])
588    apply (iprover intro: minor major [THEN mp])+
589   done
591 text \<open>Classical \<open>\<longleftrightarrow>\<close> elimination.\<close>
592 lemma iffCE:
593   assumes major: "P = Q"
594     and minor: "\<lbrakk>P; Q\<rbrakk> \<Longrightarrow> R" "\<lbrakk>\<not> P; \<not> Q\<rbrakk> \<Longrightarrow> R"
595   shows R
596   by (rule major [THEN iffE]) (iprover intro: minor elim: impCE notE)
598 lemma exCI:
599   assumes "\<forall>x. \<not> P x \<Longrightarrow> P a"
600   shows "\<exists>x. P x"
601   by (rule ccontr) (iprover intro: assms exI allI notI notE [of "\<exists>x. P x"])
604 subsubsection \<open>Intuitionistic Reasoning\<close>
606 lemma impE':
607   assumes 1: "P \<longrightarrow> Q"
608     and 2: "Q \<Longrightarrow> R"
609     and 3: "P \<longrightarrow> Q \<Longrightarrow> P"
610   shows R
611 proof -
612   from 3 and 1 have P .
613   with 1 have Q by (rule impE)
614   with 2 show R .
615 qed
617 lemma allE':
618   assumes 1: "\<forall>x. P x"
619     and 2: "P x \<Longrightarrow> \<forall>x. P x \<Longrightarrow> Q"
620   shows Q
621 proof -
622   from 1 have "P x" by (rule spec)
623   from this and 1 show Q by (rule 2)
624 qed
626 lemma notE':
627   assumes 1: "\<not> P"
628     and 2: "\<not> P \<Longrightarrow> P"
629   shows R
630 proof -
631   from 2 and 1 have P .
632   with 1 show R by (rule notE)
633 qed
635 lemma TrueE: "True \<Longrightarrow> P \<Longrightarrow> P" .
636 lemma notFalseE: "\<not> False \<Longrightarrow> P \<Longrightarrow> P" .
638 lemmas [Pure.elim!] = disjE iffE FalseE conjE exE TrueE notFalseE
639   and [Pure.intro!] = iffI conjI impI TrueI notI allI refl
640   and [Pure.elim 2] = allE notE' impE'
641   and [Pure.intro] = exI disjI2 disjI1
643 lemmas [trans] = trans
644   and [sym] = sym not_sym
645   and [Pure.elim?] = iffD1 iffD2 impE
648 subsubsection \<open>Atomizing meta-level connectives\<close>
650 axiomatization where
651   eq_reflection: "x = y \<Longrightarrow> x \<equiv> y"  \<comment> \<open>admissible axiom\<close>
653 lemma atomize_all [atomize]: "(\<And>x. P x) \<equiv> Trueprop (\<forall>x. P x)"
654 proof
655   assume "\<And>x. P x"
656   then show "\<forall>x. P x" ..
657 next
658   assume "\<forall>x. P x"
659   then show "\<And>x. P x" by (rule allE)
660 qed
662 lemma atomize_imp [atomize]: "(A \<Longrightarrow> B) \<equiv> Trueprop (A \<longrightarrow> B)"
663 proof
664   assume r: "A \<Longrightarrow> B"
665   show "A \<longrightarrow> B" by (rule impI) (rule r)
666 next
667   assume "A \<longrightarrow> B" and A
668   then show B by (rule mp)
669 qed
671 lemma atomize_not: "(A \<Longrightarrow> False) \<equiv> Trueprop (\<not> A)"
672 proof
673   assume r: "A \<Longrightarrow> False"
674   show "\<not> A" by (rule notI) (rule r)
675 next
676   assume "\<not> A" and A
677   then show False by (rule notE)
678 qed
680 lemma atomize_eq [atomize, code]: "(x \<equiv> y) \<equiv> Trueprop (x = y)"
681 proof
682   assume "x \<equiv> y"
683   show "x = y" by (unfold \<open>x \<equiv> y\<close>) (rule refl)
684 next
685   assume "x = y"
686   then show "x \<equiv> y" by (rule eq_reflection)
687 qed
689 lemma atomize_conj [atomize]: "(A &&& B) \<equiv> Trueprop (A \<and> B)"
690 proof
691   assume conj: "A &&& B"
692   show "A \<and> B"
693   proof (rule conjI)
694     from conj show A by (rule conjunctionD1)
695     from conj show B by (rule conjunctionD2)
696   qed
697 next
698   assume conj: "A \<and> B"
699   show "A &&& B"
700   proof -
701     from conj show A ..
702     from conj show B ..
703   qed
704 qed
706 lemmas [symmetric, rulify] = atomize_all atomize_imp
707   and [symmetric, defn] = atomize_all atomize_imp atomize_eq
710 subsubsection \<open>Atomizing elimination rules\<close>
712 lemma atomize_exL[atomize_elim]: "(\<And>x. P x \<Longrightarrow> Q) \<equiv> ((\<exists>x. P x) \<Longrightarrow> Q)"
713   by rule iprover+
715 lemma atomize_conjL[atomize_elim]: "(A \<Longrightarrow> B \<Longrightarrow> C) \<equiv> (A \<and> B \<Longrightarrow> C)"
716   by rule iprover+
718 lemma atomize_disjL[atomize_elim]: "((A \<Longrightarrow> C) \<Longrightarrow> (B \<Longrightarrow> C) \<Longrightarrow> C) \<equiv> ((A \<or> B \<Longrightarrow> C) \<Longrightarrow> C)"
719   by rule iprover+
721 lemma atomize_elimL[atomize_elim]: "(\<And>B. (A \<Longrightarrow> B) \<Longrightarrow> B) \<equiv> Trueprop A" ..
724 subsection \<open>Package setup\<close>
726 ML_file "Tools/hologic.ML"
729 subsubsection \<open>Sledgehammer setup\<close>
731 text \<open>
732   Theorems blacklisted to Sledgehammer. These theorems typically produce clauses
733   that are prolific (match too many equality or membership literals) and relate to
734   seldom-used facts. Some duplicate other rules.
735 \<close>
737 named_theorems no_atp "theorems that should be filtered out by Sledgehammer"
740 subsubsection \<open>Classical Reasoner setup\<close>
742 lemma imp_elim: "P \<longrightarrow> Q \<Longrightarrow> (\<not> R \<Longrightarrow> P) \<Longrightarrow> (Q \<Longrightarrow> R) \<Longrightarrow> R"
743   by (rule classical) iprover
745 lemma swap: "\<not> P \<Longrightarrow> (\<not> R \<Longrightarrow> P) \<Longrightarrow> R"
746   by (rule classical) iprover
748 lemma thin_refl: "\<lbrakk>x = x; PROP W\<rbrakk> \<Longrightarrow> PROP W" .
750 ML \<open>
751 structure Hypsubst = Hypsubst
752 (
753   val dest_eq = HOLogic.dest_eq
754   val dest_Trueprop = HOLogic.dest_Trueprop
755   val dest_imp = HOLogic.dest_imp
756   val eq_reflection = @{thm eq_reflection}
757   val rev_eq_reflection = @{thm meta_eq_to_obj_eq}
758   val imp_intr = @{thm impI}
759   val rev_mp = @{thm rev_mp}
760   val subst = @{thm subst}
761   val sym = @{thm sym}
762   val thin_refl = @{thm thin_refl};
763 );
764 open Hypsubst;
766 structure Classical = Classical
767 (
768   val imp_elim = @{thm imp_elim}
769   val not_elim = @{thm notE}
770   val swap = @{thm swap}
771   val classical = @{thm classical}
772   val sizef = Drule.size_of_thm
773   val hyp_subst_tacs = [Hypsubst.hyp_subst_tac]
774 );
776 structure Basic_Classical: BASIC_CLASSICAL = Classical;
777 open Basic_Classical;
778 \<close>
780 setup \<open>
781   (*prevent substitution on bool*)
782   let
783     fun non_bool_eq (@{const_name HOL.eq}, Type (_, [T, _])) = T <> @{typ bool}
784       | non_bool_eq _ = false;
785     fun hyp_subst_tac' ctxt =
786       SUBGOAL (fn (goal, i) =>
787         if Term.exists_Const non_bool_eq goal
788         then Hypsubst.hyp_subst_tac ctxt i
789         else no_tac);
790   in
791     Context_Rules.addSWrapper (fn ctxt => fn tac => hyp_subst_tac' ctxt ORELSE' tac)
792   end
793 \<close>
795 declare iffI [intro!]
796   and notI [intro!]
797   and impI [intro!]
798   and disjCI [intro!]
799   and conjI [intro!]
800   and TrueI [intro!]
801   and refl [intro!]
803 declare iffCE [elim!]
804   and FalseE [elim!]
805   and impCE [elim!]
806   and disjE [elim!]
807   and conjE [elim!]
809 declare ex_ex1I [intro!]
810   and allI [intro!]
811   and exI [intro]
813 declare exE [elim!]
814   allE [elim]
816 ML \<open>val HOL_cs = claset_of @{context}\<close>
818 lemma contrapos_np: "\<not> Q \<Longrightarrow> (\<not> P \<Longrightarrow> Q) \<Longrightarrow> P"
819   apply (erule swap)
820   apply (erule (1) meta_mp)
821   done
823 declare ex_ex1I [rule del, intro! 2]
824   and ex1I [intro]
826 declare ext [intro]
828 lemmas [intro?] = ext
829   and [elim?] = ex1_implies_ex
831 text \<open>Better than \<open>ex1E\<close> for classical reasoner: needs no quantifier duplication!\<close>
832 lemma alt_ex1E [elim!]:
833   assumes major: "\<exists>!x. P x"
834     and prem: "\<And>x. \<lbrakk>P x; \<forall>y y'. P y \<and> P y' \<longrightarrow> y = y'\<rbrakk> \<Longrightarrow> R"
835   shows R
836   apply (rule ex1E [OF major])
837   apply (rule prem)
838    apply assumption
839   apply (rule allI)+
840   apply (tactic \<open>eresolve_tac @{context} [Classical.dup_elim @{context} @{thm allE}] 1\<close>)
841   apply iprover
842   done
844 ML \<open>
845   structure Blast = Blast
846   (
847     structure Classical = Classical
848     val Trueprop_const = dest_Const @{const Trueprop}
849     val equality_name = @{const_name HOL.eq}
850     val not_name = @{const_name Not}
851     val notE = @{thm notE}
852     val ccontr = @{thm ccontr}
853     val hyp_subst_tac = Hypsubst.blast_hyp_subst_tac
854   );
855   val blast_tac = Blast.blast_tac;
856 \<close>
859 subsubsection \<open>THE: definite description operator\<close>
861 lemma the_equality [intro]:
862   assumes "P a"
863     and "\<And>x. P x \<Longrightarrow> x = a"
864   shows "(THE x. P x) = a"
865   by (blast intro: assms trans [OF arg_cong [where f=The] the_eq_trivial])
867 lemma theI:
868   assumes "P a"
869     and "\<And>x. P x \<Longrightarrow> x = a"
870   shows "P (THE x. P x)"
871   by (iprover intro: assms the_equality [THEN ssubst])
873 lemma theI': "\<exists>!x. P x \<Longrightarrow> P (THE x. P x)"
874   by (blast intro: theI)
876 text \<open>Easier to apply than \<open>theI\<close>: only one occurrence of \<open>P\<close>.\<close>
877 lemma theI2:
878   assumes "P a" "\<And>x. P x \<Longrightarrow> x = a" "\<And>x. P x \<Longrightarrow> Q x"
879   shows "Q (THE x. P x)"
880   by (iprover intro: assms theI)
882 lemma the1I2:
883   assumes "\<exists>!x. P x" "\<And>x. P x \<Longrightarrow> Q x"
884   shows "Q (THE x. P x)"
885   by (iprover intro: assms(2) theI2[where P=P and Q=Q] ex1E[OF assms(1)] elim: allE impE)
887 lemma the1_equality [elim?]: "\<lbrakk>\<exists>!x. P x; P a\<rbrakk> \<Longrightarrow> (THE x. P x) = a"
888   by blast
890 lemma the_sym_eq_trivial: "(THE y. x = y) = x"
891   by blast
894 subsubsection \<open>Simplifier\<close>
896 lemma eta_contract_eq: "(\<lambda>s. f s) = f" ..
898 lemma simp_thms:
899   shows not_not: "(\<not> \<not> P) = P"
900   and Not_eq_iff: "((\<not> P) = (\<not> Q)) = (P = Q)"
901   and
902     "(P \<noteq> Q) = (P = (\<not> Q))"
903     "(P \<or> \<not>P) = True"    "(\<not> P \<or> P) = True"
904     "(x = x) = True"
905   and not_True_eq_False [code]: "(\<not> True) = False"
906   and not_False_eq_True [code]: "(\<not> False) = True"
907   and
908     "(\<not> P) \<noteq> P"  "P \<noteq> (\<not> P)"
909     "(True = P) = P"
910   and eq_True: "(P = True) = P"
911   and "(False = P) = (\<not> P)"
912   and eq_False: "(P = False) = (\<not> P)"
913   and
914     "(True \<longrightarrow> P) = P"  "(False \<longrightarrow> P) = True"
915     "(P \<longrightarrow> True) = True"  "(P \<longrightarrow> P) = True"
916     "(P \<longrightarrow> False) = (\<not> P)"  "(P \<longrightarrow> \<not> P) = (\<not> P)"
917     "(P \<and> True) = P"  "(True \<and> P) = P"
918     "(P \<and> False) = False"  "(False \<and> P) = False"
919     "(P \<and> P) = P"  "(P \<and> (P \<and> Q)) = (P \<and> Q)"
920     "(P \<and> \<not> P) = False"    "(\<not> P \<and> P) = False"
921     "(P \<or> True) = True"  "(True \<or> P) = True"
922     "(P \<or> False) = P"  "(False \<or> P) = P"
923     "(P \<or> P) = P"  "(P \<or> (P \<or> Q)) = (P \<or> Q)" and
924     "(\<forall>x. P) = P"  "(\<exists>x. P) = P"  "\<exists>x. x = t"  "\<exists>x. t = x"
925   and
926     "\<And>P. (\<exists>x. x = t \<and> P x) = P t"
927     "\<And>P. (\<exists>x. t = x \<and> P x) = P t"
928     "\<And>P. (\<forall>x. x = t \<longrightarrow> P x) = P t"
929     "\<And>P. (\<forall>x. t = x \<longrightarrow> P x) = P t"
930   by (blast, blast, blast, blast, blast, iprover+)
932 lemma disj_absorb: "A \<or> A \<longleftrightarrow> A"
933   by blast
935 lemma disj_left_absorb: "A \<or> (A \<or> B) \<longleftrightarrow> A \<or> B"
936   by blast
938 lemma conj_absorb: "A \<and> A \<longleftrightarrow> A"
939   by blast
941 lemma conj_left_absorb: "A \<and> (A \<and> B) \<longleftrightarrow> A \<and> B"
942   by blast
944 lemma eq_ac:
945   shows eq_commute: "a = b \<longleftrightarrow> b = a"
946     and iff_left_commute: "(P \<longleftrightarrow> (Q \<longleftrightarrow> R)) \<longleftrightarrow> (Q \<longleftrightarrow> (P \<longleftrightarrow> R))"
947     and iff_assoc: "((P \<longleftrightarrow> Q) \<longleftrightarrow> R) \<longleftrightarrow> (P \<longleftrightarrow> (Q \<longleftrightarrow> R))"
948   by (iprover, blast+)
950 lemma neq_commute: "a \<noteq> b \<longleftrightarrow> b \<noteq> a" by iprover
952 lemma conj_comms:
953   shows conj_commute: "P \<and> Q \<longleftrightarrow> Q \<and> P"
954     and conj_left_commute: "P \<and> (Q \<and> R) \<longleftrightarrow> Q \<and> (P \<and> R)" by iprover+
955 lemma conj_assoc: "(P \<and> Q) \<and> R \<longleftrightarrow> P \<and> (Q \<and> R)" by iprover
957 lemmas conj_ac = conj_commute conj_left_commute conj_assoc
959 lemma disj_comms:
960   shows disj_commute: "P \<or> Q \<longleftrightarrow> Q \<or> P"
961     and disj_left_commute: "P \<or> (Q \<or> R) \<longleftrightarrow> Q \<or> (P \<or> R)" by iprover+
962 lemma disj_assoc: "(P \<or> Q) \<or> R \<longleftrightarrow> P \<or> (Q \<or> R)" by iprover
964 lemmas disj_ac = disj_commute disj_left_commute disj_assoc
966 lemma conj_disj_distribL: "P \<and> (Q \<or> R) \<longleftrightarrow> P \<and> Q \<or> P \<and> R" by iprover
967 lemma conj_disj_distribR: "(P \<or> Q) \<and> R \<longleftrightarrow> P \<and> R \<or> Q \<and> R" by iprover
969 lemma disj_conj_distribL: "P \<or> (Q \<and> R) \<longleftrightarrow> (P \<or> Q) \<and> (P \<or> R)" by iprover
970 lemma disj_conj_distribR: "(P \<and> Q) \<or> R \<longleftrightarrow> (P \<or> R) \<and> (Q \<or> R)" by iprover
972 lemma imp_conjR: "(P \<longrightarrow> (Q \<and> R)) = ((P \<longrightarrow> Q) \<and> (P \<longrightarrow> R))" by iprover
973 lemma imp_conjL: "((P \<and> Q) \<longrightarrow> R) = (P \<longrightarrow> (Q \<longrightarrow> R))" by iprover
974 lemma imp_disjL: "((P \<or> Q) \<longrightarrow> R) = ((P \<longrightarrow> R) \<and> (Q \<longrightarrow> R))" by iprover
976 text \<open>These two are specialized, but \<open>imp_disj_not1\<close> is useful in \<open>Auth/Yahalom\<close>.\<close>
977 lemma imp_disj_not1: "(P \<longrightarrow> Q \<or> R) \<longleftrightarrow> (\<not> Q \<longrightarrow> P \<longrightarrow> R)" by blast
978 lemma imp_disj_not2: "(P \<longrightarrow> Q \<or> R) \<longleftrightarrow> (\<not> R \<longrightarrow> P \<longrightarrow> Q)" by blast
980 lemma imp_disj1: "((P \<longrightarrow> Q) \<or> R) \<longleftrightarrow> (P \<longrightarrow> Q \<or> R)" by blast
981 lemma imp_disj2: "(Q \<or> (P \<longrightarrow> R)) \<longleftrightarrow> (P \<longrightarrow> Q \<or> R)" by blast
983 lemma imp_cong: "(P = P') \<Longrightarrow> (P' \<Longrightarrow> (Q = Q')) \<Longrightarrow> ((P \<longrightarrow> Q) \<longleftrightarrow> (P' \<longrightarrow> Q'))"
984   by iprover
986 lemma de_Morgan_disj: "\<not> (P \<or> Q) \<longleftrightarrow> \<not> P \<and> \<not> Q" by iprover
987 lemma de_Morgan_conj: "\<not> (P \<and> Q) \<longleftrightarrow> \<not> P \<or> \<not> Q" by blast
988 lemma not_imp: "\<not> (P \<longrightarrow> Q) \<longleftrightarrow> P \<and> \<not> Q" by blast
989 lemma not_iff: "P \<noteq> Q \<longleftrightarrow> (P \<longleftrightarrow> \<not> Q)" by blast
990 lemma disj_not1: "\<not> P \<or> Q \<longleftrightarrow> (P \<longrightarrow> Q)" by blast
991 lemma disj_not2: "P \<or> \<not> Q \<longleftrightarrow> (Q \<longrightarrow> P)" by blast  \<comment> \<open>changes orientation :-(\<close>
992 lemma imp_conv_disj: "(P \<longrightarrow> Q) \<longleftrightarrow> (\<not> P) \<or> Q" by blast
993 lemma disj_imp: "P \<or> Q \<longleftrightarrow> \<not> P \<longrightarrow> Q" by blast
995 lemma iff_conv_conj_imp: "(P \<longleftrightarrow> Q) \<longleftrightarrow> (P \<longrightarrow> Q) \<and> (Q \<longrightarrow> P)" by iprover
998 lemma cases_simp: "(P \<longrightarrow> Q) \<and> (\<not> P \<longrightarrow> Q) \<longleftrightarrow> Q"
999   \<comment> \<open>Avoids duplication of subgoals after \<open>if_split\<close>, when the true and false\<close>
1000   \<comment> \<open>cases boil down to the same thing.\<close>
1001   by blast
1003 lemma not_all: "\<not> (\<forall>x. P x) \<longleftrightarrow> (\<exists>x. \<not> P x)" by blast
1004 lemma imp_all: "((\<forall>x. P x) \<longrightarrow> Q) \<longleftrightarrow> (\<exists>x. P x \<longrightarrow> Q)" by blast
1005 lemma not_ex: "\<not> (\<exists>x. P x) \<longleftrightarrow> (\<forall>x. \<not> P x)" by iprover
1006 lemma imp_ex: "((\<exists>x. P x) \<longrightarrow> Q) \<longleftrightarrow> (\<forall>x. P x \<longrightarrow> Q)" by iprover
1007 lemma all_not_ex: "(\<forall>x. P x) \<longleftrightarrow> \<not> (\<exists>x. \<not> P x)" by blast
1009 declare All_def [no_atp]
1011 lemma ex_disj_distrib: "(\<exists>x. P x \<or> Q x) \<longleftrightarrow> (\<exists>x. P x) \<or> (\<exists>x. Q x)" by iprover
1012 lemma all_conj_distrib: "(\<forall>x. P x \<and> Q x) \<longleftrightarrow> (\<forall>x. P x) \<and> (\<forall>x. Q x)" by iprover
1014 text \<open>
1015   \<^medskip> The \<open>\<and>\<close> congruence rule: not included by default!
1016   May slow rewrite proofs down by as much as 50\%\<close>
1018 lemma conj_cong: "P = P' \<Longrightarrow> (P' \<Longrightarrow> Q = Q') \<Longrightarrow> (P \<and> Q) = (P' \<and> Q')"
1019   by iprover
1021 lemma rev_conj_cong: "Q = Q' \<Longrightarrow> (Q' \<Longrightarrow> P = P') \<Longrightarrow> (P \<and> Q) = (P' \<and> Q')"
1022   by iprover
1024 text \<open>The \<open>|\<close> congruence rule: not included by default!\<close>
1026 lemma disj_cong: "P = P' \<Longrightarrow> (\<not> P' \<Longrightarrow> Q = Q') \<Longrightarrow> (P \<or> Q) = (P' \<or> Q')"
1027   by blast
1030 text \<open>\<^medskip> if-then-else rules\<close>
1032 lemma if_True [code]: "(if True then x else y) = x"
1033   unfolding If_def by blast
1035 lemma if_False [code]: "(if False then x else y) = y"
1036   unfolding If_def by blast
1038 lemma if_P: "P \<Longrightarrow> (if P then x else y) = x"
1039   unfolding If_def by blast
1041 lemma if_not_P: "\<not> P \<Longrightarrow> (if P then x else y) = y"
1042   unfolding If_def by blast
1044 lemma if_split: "P (if Q then x else y) = ((Q \<longrightarrow> P x) \<and> (\<not> Q \<longrightarrow> P y))"
1045   apply (rule case_split [of Q])
1046    apply (simplesubst if_P)
1047     prefer 3
1048     apply (simplesubst if_not_P)
1049      apply blast+
1050   done
1052 lemma if_split_asm: "P (if Q then x else y) = (\<not> ((Q \<and> \<not> P x) \<or> (\<not> Q \<and> \<not> P y)))"
1053   by (simplesubst if_split) blast
1055 lemmas if_splits [no_atp] = if_split if_split_asm
1057 lemma if_cancel: "(if c then x else x) = x"
1058   by (simplesubst if_split) blast
1060 lemma if_eq_cancel: "(if x = y then y else x) = x"
1061   by (simplesubst if_split) blast
1063 lemma if_bool_eq_conj: "(if P then Q else R) = ((P \<longrightarrow> Q) \<and> (\<not> P \<longrightarrow> R))"
1064   \<comment> \<open>This form is useful for expanding \<open>if\<close>s on the RIGHT of the \<open>\<Longrightarrow>\<close> symbol.\<close>
1065   by (rule if_split)
1067 lemma if_bool_eq_disj: "(if P then Q else R) = ((P \<and> Q) \<or> (\<not> P \<and> R))"
1068   \<comment> \<open>And this form is useful for expanding \<open>if\<close>s on the LEFT.\<close>
1069   by (simplesubst if_split) blast
1071 lemma Eq_TrueI: "P \<Longrightarrow> P \<equiv> True" unfolding atomize_eq by iprover
1072 lemma Eq_FalseI: "\<not> P \<Longrightarrow> P \<equiv> False" unfolding atomize_eq by iprover
1074 text \<open>\<^medskip> let rules for simproc\<close>
1076 lemma Let_folded: "f x \<equiv> g x \<Longrightarrow> Let x f \<equiv> Let x g"
1077   by (unfold Let_def)
1079 lemma Let_unfold: "f x \<equiv> g \<Longrightarrow> Let x f \<equiv> g"
1080   by (unfold Let_def)
1082 text \<open>
1083   The following copy of the implication operator is useful for
1084   fine-tuning congruence rules.  It instructs the simplifier to simplify
1085   its premise.
1086 \<close>
1088 definition simp_implies :: "prop \<Rightarrow> prop \<Rightarrow> prop"  (infixr "=simp=>" 1)
1089   where "simp_implies \<equiv> op \<Longrightarrow>"
1091 lemma simp_impliesI:
1092   assumes PQ: "(PROP P \<Longrightarrow> PROP Q)"
1093   shows "PROP P =simp=> PROP Q"
1094   apply (unfold simp_implies_def)
1095   apply (rule PQ)
1096   apply assumption
1097   done
1099 lemma simp_impliesE:
1100   assumes PQ: "PROP P =simp=> PROP Q"
1101     and P: "PROP P"
1102     and QR: "PROP Q \<Longrightarrow> PROP R"
1103   shows "PROP R"
1104   apply (rule QR)
1105   apply (rule PQ [unfolded simp_implies_def])
1106   apply (rule P)
1107   done
1109 lemma simp_implies_cong:
1110   assumes PP' :"PROP P \<equiv> PROP P'"
1111     and P'QQ': "PROP P' \<Longrightarrow> (PROP Q \<equiv> PROP Q')"
1112   shows "(PROP P =simp=> PROP Q) \<equiv> (PROP P' =simp=> PROP Q')"
1113   unfolding simp_implies_def
1114 proof (rule equal_intr_rule)
1115   assume PQ: "PROP P \<Longrightarrow> PROP Q"
1116     and P': "PROP P'"
1117   from PP' [symmetric] and P' have "PROP P"
1118     by (rule equal_elim_rule1)
1119   then have "PROP Q" by (rule PQ)
1120   with P'QQ' [OF P'] show "PROP Q'" by (rule equal_elim_rule1)
1121 next
1122   assume P'Q': "PROP P' \<Longrightarrow> PROP Q'"
1123     and P: "PROP P"
1124   from PP' and P have P': "PROP P'" by (rule equal_elim_rule1)
1125   then have "PROP Q'" by (rule P'Q')
1126   with P'QQ' [OF P', symmetric] show "PROP Q"
1127     by (rule equal_elim_rule1)
1128 qed
1130 lemma uncurry:
1131   assumes "P \<longrightarrow> Q \<longrightarrow> R"
1132   shows "P \<and> Q \<longrightarrow> R"
1133   using assms by blast
1135 lemma iff_allI:
1136   assumes "\<And>x. P x = Q x"
1137   shows "(\<forall>x. P x) = (\<forall>x. Q x)"
1138   using assms by blast
1140 lemma iff_exI:
1141   assumes "\<And>x. P x = Q x"
1142   shows "(\<exists>x. P x) = (\<exists>x. Q x)"
1143   using assms by blast
1145 lemma all_comm: "(\<forall>x y. P x y) = (\<forall>y x. P x y)"
1146   by blast
1148 lemma ex_comm: "(\<exists>x y. P x y) = (\<exists>y x. P x y)"
1149   by blast
1151 ML_file "Tools/simpdata.ML"
1152 ML \<open>open Simpdata\<close>
1154 setup \<open>
1155   map_theory_simpset (put_simpset HOL_basic_ss) #>
1156   Simplifier.method_setup Splitter.split_modifiers
1157 \<close>
1159 simproc_setup defined_Ex ("\<exists>x. P x") = \<open>fn _ => Quantifier1.rearrange_ex\<close>
1160 simproc_setup defined_All ("\<forall>x. P x") = \<open>fn _ => Quantifier1.rearrange_all\<close>
1162 text \<open>Simproc for proving \<open>(y = x) \<equiv> False\<close> from premise \<open>\<not> (x = y)\<close>:\<close>
1164 simproc_setup neq ("x = y") = \<open>fn _ =>
1165   let
1166     val neq_to_EQ_False = @{thm not_sym} RS @{thm Eq_FalseI};
1167     fun is_neq eq lhs rhs thm =
1168       (case Thm.prop_of thm of
1169         _ \$ (Not \$ (eq' \$ l' \$ r')) =>
1170           Not = HOLogic.Not andalso eq' = eq andalso
1171           r' aconv lhs andalso l' aconv rhs
1172       | _ => false);
1173     fun proc ss ct =
1174       (case Thm.term_of ct of
1175         eq \$ lhs \$ rhs =>
1176           (case find_first (is_neq eq lhs rhs) (Simplifier.prems_of ss) of
1177             SOME thm => SOME (thm RS neq_to_EQ_False)
1178           | NONE => NONE)
1179        | _ => NONE);
1180   in proc end;
1181 \<close>
1183 simproc_setup let_simp ("Let x f") = \<open>
1184   let
1185     fun count_loose (Bound i) k = if i >= k then 1 else 0
1186       | count_loose (s \$ t) k = count_loose s k + count_loose t k
1187       | count_loose (Abs (_, _, t)) k = count_loose  t (k + 1)
1188       | count_loose _ _ = 0;
1189     fun is_trivial_let (Const (@{const_name Let}, _) \$ x \$ t) =
1190       (case t of
1191         Abs (_, _, t') => count_loose t' 0 <= 1
1192       | _ => true);
1193   in
1194     fn _ => fn ctxt => fn ct =>
1195       if is_trivial_let (Thm.term_of ct)
1196       then SOME @{thm Let_def} (*no or one ocurrence of bound variable*)
1197       else
1198         let (*Norbert Schirmer's case*)
1199           val t = Thm.term_of ct;
1200           val ([t'], ctxt') = Variable.import_terms false [t] ctxt;
1201         in
1202           Option.map (hd o Variable.export ctxt' ctxt o single)
1203             (case t' of Const (@{const_name Let},_) \$ x \$ f => (* x and f are already in normal form *)
1204               if is_Free x orelse is_Bound x orelse is_Const x
1205               then SOME @{thm Let_def}
1206               else
1207                 let
1208                   val n = case f of (Abs (x, _, _)) => x | _ => "x";
1209                   val cx = Thm.cterm_of ctxt x;
1210                   val xT = Thm.typ_of_cterm cx;
1211                   val cf = Thm.cterm_of ctxt f;
1212                   val fx_g = Simplifier.rewrite ctxt (Thm.apply cf cx);
1213                   val (_ \$ _ \$ g) = Thm.prop_of fx_g;
1214                   val g' = abstract_over (x, g);
1215                   val abs_g'= Abs (n, xT, g');
1216                 in
1217                   if g aconv g' then
1218                     let
1219                       val rl =
1220                         infer_instantiate ctxt [(("f", 0), cf), (("x", 0), cx)] @{thm Let_unfold};
1221                     in SOME (rl OF [fx_g]) end
1222                   else if (Envir.beta_eta_contract f) aconv (Envir.beta_eta_contract abs_g')
1223                   then NONE (*avoid identity conversion*)
1224                   else
1225                     let
1226                       val g'x = abs_g' \$ x;
1227                       val g_g'x = Thm.symmetric (Thm.beta_conversion false (Thm.cterm_of ctxt g'x));
1228                       val rl =
1229                         @{thm Let_folded} |> infer_instantiate ctxt
1230                           [(("f", 0), Thm.cterm_of ctxt f),
1231                            (("x", 0), cx),
1232                            (("g", 0), Thm.cterm_of ctxt abs_g')];
1233                     in SOME (rl OF [Thm.transitive fx_g g_g'x]) end
1234                 end
1235             | _ => NONE)
1236         end
1237   end
1238 \<close>
1240 lemma True_implies_equals: "(True \<Longrightarrow> PROP P) \<equiv> PROP P"
1241 proof
1242   assume "True \<Longrightarrow> PROP P"
1243   from this [OF TrueI] show "PROP P" .
1244 next
1245   assume "PROP P"
1246   then show "PROP P" .
1247 qed
1249 lemma implies_True_equals: "(PROP P \<Longrightarrow> True) \<equiv> Trueprop True"
1250   by standard (intro TrueI)
1252 lemma False_implies_equals: "(False \<Longrightarrow> P) \<equiv> Trueprop True"
1253   by standard simp_all
1255 (* This is not made a simp rule because it does not improve any proofs
1256    but slows some AFP entries down by 5% (cpu time). May 2015 *)
1257 lemma implies_False_swap:
1258   "NO_MATCH (Trueprop False) P \<Longrightarrow>
1259     (False \<Longrightarrow> PROP P \<Longrightarrow> PROP Q) \<equiv> (PROP P \<Longrightarrow> False \<Longrightarrow> PROP Q)"
1260   by (rule swap_prems_eq)
1262 lemma ex_simps:
1263   "\<And>P Q. (\<exists>x. P x \<and> Q)   = ((\<exists>x. P x) \<and> Q)"
1264   "\<And>P Q. (\<exists>x. P \<and> Q x)   = (P \<and> (\<exists>x. Q x))"
1265   "\<And>P Q. (\<exists>x. P x \<or> Q)   = ((\<exists>x. P x) \<or> Q)"
1266   "\<And>P Q. (\<exists>x. P \<or> Q x)   = (P \<or> (\<exists>x. Q x))"
1267   "\<And>P Q. (\<exists>x. P x \<longrightarrow> Q) = ((\<forall>x. P x) \<longrightarrow> Q)"
1268   "\<And>P Q. (\<exists>x. P \<longrightarrow> Q x) = (P \<longrightarrow> (\<exists>x. Q x))"
1269   \<comment> \<open>Miniscoping: pushing in existential quantifiers.\<close>
1270   by (iprover | blast)+
1272 lemma all_simps:
1273   "\<And>P Q. (\<forall>x. P x \<and> Q)   = ((\<forall>x. P x) \<and> Q)"
1274   "\<And>P Q. (\<forall>x. P \<and> Q x)   = (P \<and> (\<forall>x. Q x))"
1275   "\<And>P Q. (\<forall>x. P x \<or> Q)   = ((\<forall>x. P x) \<or> Q)"
1276   "\<And>P Q. (\<forall>x. P \<or> Q x)   = (P \<or> (\<forall>x. Q x))"
1277   "\<And>P Q. (\<forall>x. P x \<longrightarrow> Q) = ((\<exists>x. P x) \<longrightarrow> Q)"
1278   "\<And>P Q. (\<forall>x. P \<longrightarrow> Q x) = (P \<longrightarrow> (\<forall>x. Q x))"
1279   \<comment> \<open>Miniscoping: pushing in universal quantifiers.\<close>
1280   by (iprover | blast)+
1282 lemmas [simp] =
1283   triv_forall_equality  \<comment> \<open>prunes params\<close>
1284   True_implies_equals implies_True_equals  \<comment> \<open>prune \<open>True\<close> in asms\<close>
1285   False_implies_equals  \<comment> \<open>prune \<open>False\<close> in asms\<close>
1286   if_True
1287   if_False
1288   if_cancel
1289   if_eq_cancel
1290   imp_disjL \<comment>
1291    \<open>In general it seems wrong to add distributive laws by default: they
1292     might cause exponential blow-up.  But \<open>imp_disjL\<close> has been in for a while
1293     and cannot be removed without affecting existing proofs.  Moreover,
1294     rewriting by \<open>(P \<or> Q \<longrightarrow> R) = ((P \<longrightarrow> R) \<and> (Q \<longrightarrow> R))\<close> might be justified on the
1295     grounds that it allows simplification of \<open>R\<close> in the two cases.\<close>
1296   conj_assoc
1297   disj_assoc
1298   de_Morgan_conj
1299   de_Morgan_disj
1300   imp_disj1
1301   imp_disj2
1302   not_imp
1303   disj_not1
1304   not_all
1305   not_ex
1306   cases_simp
1307   the_eq_trivial
1308   the_sym_eq_trivial
1309   ex_simps
1310   all_simps
1311   simp_thms
1313 lemmas [cong] = imp_cong simp_implies_cong
1314 lemmas [split] = if_split
1316 ML \<open>val HOL_ss = simpset_of @{context}\<close>
1318 text \<open>Simplifies \<open>x\<close> assuming \<open>c\<close> and \<open>y\<close> assuming \<open>\<not> c\<close>.\<close>
1319 lemma if_cong:
1320   assumes "b = c"
1321     and "c \<Longrightarrow> x = u"
1322     and "\<not> c \<Longrightarrow> y = v"
1323   shows "(if b then x else y) = (if c then u else v)"
1324   using assms by simp
1326 text \<open>Prevents simplification of \<open>x\<close> and \<open>y\<close>:
1327   faster and allows the execution of functional programs.\<close>
1328 lemma if_weak_cong [cong]:
1329   assumes "b = c"
1330   shows "(if b then x else y) = (if c then x else y)"
1331   using assms by (rule arg_cong)
1333 text \<open>Prevents simplification of t: much faster\<close>
1334 lemma let_weak_cong:
1335   assumes "a = b"
1336   shows "(let x = a in t x) = (let x = b in t x)"
1337   using assms by (rule arg_cong)
1339 text \<open>To tidy up the result of a simproc.  Only the RHS will be simplified.\<close>
1340 lemma eq_cong2:
1341   assumes "u = u'"
1342   shows "(t \<equiv> u) \<equiv> (t \<equiv> u')"
1343   using assms by simp
1345 lemma if_distrib: "f (if c then x else y) = (if c then f x else f y)"
1346   by simp
1348 text \<open>As a simplification rule, it replaces all function equalities by
1349   first-order equalities.\<close>
1350 lemma fun_eq_iff: "f = g \<longleftrightarrow> (\<forall>x. f x = g x)"
1351   by auto
1354 subsubsection \<open>Generic cases and induction\<close>
1356 text \<open>Rule projections:\<close>
1357 ML \<open>
1358 structure Project_Rule = Project_Rule
1359 (
1360   val conjunct1 = @{thm conjunct1}
1361   val conjunct2 = @{thm conjunct2}
1362   val mp = @{thm mp}
1363 );
1364 \<close>
1366 context
1367 begin
1369 qualified definition "induct_forall P \<equiv> \<forall>x. P x"
1370 qualified definition "induct_implies A B \<equiv> A \<longrightarrow> B"
1371 qualified definition "induct_equal x y \<equiv> x = y"
1372 qualified definition "induct_conj A B \<equiv> A \<and> B"
1373 qualified definition "induct_true \<equiv> True"
1374 qualified definition "induct_false \<equiv> False"
1376 lemma induct_forall_eq: "(\<And>x. P x) \<equiv> Trueprop (induct_forall (\<lambda>x. P x))"
1377   by (unfold atomize_all induct_forall_def)
1379 lemma induct_implies_eq: "(A \<Longrightarrow> B) \<equiv> Trueprop (induct_implies A B)"
1380   by (unfold atomize_imp induct_implies_def)
1382 lemma induct_equal_eq: "(x \<equiv> y) \<equiv> Trueprop (induct_equal x y)"
1383   by (unfold atomize_eq induct_equal_def)
1385 lemma induct_conj_eq: "(A &&& B) \<equiv> Trueprop (induct_conj A B)"
1386   by (unfold atomize_conj induct_conj_def)
1388 lemmas induct_atomize' = induct_forall_eq induct_implies_eq induct_conj_eq
1389 lemmas induct_atomize = induct_atomize' induct_equal_eq
1390 lemmas induct_rulify' [symmetric] = induct_atomize'
1391 lemmas induct_rulify [symmetric] = induct_atomize
1392 lemmas induct_rulify_fallback =
1393   induct_forall_def induct_implies_def induct_equal_def induct_conj_def
1394   induct_true_def induct_false_def
1396 lemma induct_forall_conj: "induct_forall (\<lambda>x. induct_conj (A x) (B x)) =
1397     induct_conj (induct_forall A) (induct_forall B)"
1398   by (unfold induct_forall_def induct_conj_def) iprover
1400 lemma induct_implies_conj: "induct_implies C (induct_conj A B) =
1401     induct_conj (induct_implies C A) (induct_implies C B)"
1402   by (unfold induct_implies_def induct_conj_def) iprover
1404 lemma induct_conj_curry: "(induct_conj A B \<Longrightarrow> PROP C) \<equiv> (A \<Longrightarrow> B \<Longrightarrow> PROP C)"
1405 proof
1406   assume r: "induct_conj A B \<Longrightarrow> PROP C"
1407   assume ab: A B
1408   show "PROP C" by (rule r) (simp add: induct_conj_def ab)
1409 next
1410   assume r: "A \<Longrightarrow> B \<Longrightarrow> PROP C"
1411   assume ab: "induct_conj A B"
1412   show "PROP C" by (rule r) (simp_all add: ab [unfolded induct_conj_def])
1413 qed
1415 lemmas induct_conj = induct_forall_conj induct_implies_conj induct_conj_curry
1417 lemma induct_trueI: "induct_true"
1418   by (simp add: induct_true_def)
1420 text \<open>Method setup.\<close>
1422 ML_file "~~/src/Tools/induct.ML"
1423 ML \<open>
1424 structure Induct = Induct
1425 (
1426   val cases_default = @{thm case_split}
1427   val atomize = @{thms induct_atomize}
1428   val rulify = @{thms induct_rulify'}
1429   val rulify_fallback = @{thms induct_rulify_fallback}
1430   val equal_def = @{thm induct_equal_def}
1431   fun dest_def (Const (@{const_name induct_equal}, _) \$ t \$ u) = SOME (t, u)
1432     | dest_def _ = NONE
1433   fun trivial_tac ctxt = match_tac ctxt @{thms induct_trueI}
1434 )
1435 \<close>
1437 ML_file "~~/src/Tools/induction.ML"
1439 declaration \<open>
1440   fn _ => Induct.map_simpset (fn ss => ss
1442       [Simplifier.make_simproc @{context} "swap_induct_false"
1443         {lhss = [@{term "induct_false \<Longrightarrow> PROP P \<Longrightarrow> PROP Q"}],
1444          proc = fn _ => fn _ => fn ct =>
1445           (case Thm.term_of ct of
1446             _ \$ (P as _ \$ @{const induct_false}) \$ (_ \$ Q \$ _) =>
1447               if P <> Q then SOME Drule.swap_prems_eq else NONE
1448           | _ => NONE)},
1449        Simplifier.make_simproc @{context} "induct_equal_conj_curry"
1450         {lhss = [@{term "induct_conj P Q \<Longrightarrow> PROP R"}],
1451          proc = fn _ => fn _ => fn ct =>
1452           (case Thm.term_of ct of
1453             _ \$ (_ \$ P) \$ _ =>
1454               let
1455                 fun is_conj (@{const induct_conj} \$ P \$ Q) =
1456                       is_conj P andalso is_conj Q
1457                   | is_conj (Const (@{const_name induct_equal}, _) \$ _ \$ _) = true
1458                   | is_conj @{const induct_true} = true
1459                   | is_conj @{const induct_false} = true
1460                   | is_conj _ = false
1461               in if is_conj P then SOME @{thm induct_conj_curry} else NONE end
1462             | _ => NONE)}]
1463     |> Simplifier.set_mksimps (fn ctxt =>
1464         Simpdata.mksimps Simpdata.mksimps_pairs ctxt #>
1465         map (rewrite_rule ctxt (map Thm.symmetric @{thms induct_rulify_fallback}))))
1466 \<close>
1468 text \<open>Pre-simplification of induction and cases rules\<close>
1470 lemma [induct_simp]: "(\<And>x. induct_equal x t \<Longrightarrow> PROP P x) \<equiv> PROP P t"
1471   unfolding induct_equal_def
1472 proof
1473   assume r: "\<And>x. x = t \<Longrightarrow> PROP P x"
1474   show "PROP P t" by (rule r [OF refl])
1475 next
1476   fix x
1477   assume "PROP P t" "x = t"
1478   then show "PROP P x" by simp
1479 qed
1481 lemma [induct_simp]: "(\<And>x. induct_equal t x \<Longrightarrow> PROP P x) \<equiv> PROP P t"
1482   unfolding induct_equal_def
1483 proof
1484   assume r: "\<And>x. t = x \<Longrightarrow> PROP P x"
1485   show "PROP P t" by (rule r [OF refl])
1486 next
1487   fix x
1488   assume "PROP P t" "t = x"
1489   then show "PROP P x" by simp
1490 qed
1492 lemma [induct_simp]: "(induct_false \<Longrightarrow> P) \<equiv> Trueprop induct_true"
1493   unfolding induct_false_def induct_true_def
1494   by (iprover intro: equal_intr_rule)
1496 lemma [induct_simp]: "(induct_true \<Longrightarrow> PROP P) \<equiv> PROP P"
1497   unfolding induct_true_def
1498 proof
1499   assume "True \<Longrightarrow> PROP P"
1500   then show "PROP P" using TrueI .
1501 next
1502   assume "PROP P"
1503   then show "PROP P" .
1504 qed
1506 lemma [induct_simp]: "(PROP P \<Longrightarrow> induct_true) \<equiv> Trueprop induct_true"
1507   unfolding induct_true_def
1508   by (iprover intro: equal_intr_rule)
1510 lemma [induct_simp]: "(\<And>x::'a::{}. induct_true) \<equiv> Trueprop induct_true"
1511   unfolding induct_true_def
1512   by (iprover intro: equal_intr_rule)
1514 lemma [induct_simp]: "induct_implies induct_true P \<equiv> P"
1515   by (simp add: induct_implies_def induct_true_def)
1517 lemma [induct_simp]: "x = x \<longleftrightarrow> True"
1518   by (rule simp_thms)
1520 end
1522 ML_file "~~/src/Tools/induct_tacs.ML"
1525 subsubsection \<open>Coherent logic\<close>
1527 ML_file "~~/src/Tools/coherent.ML"
1528 ML \<open>
1529 structure Coherent = Coherent
1530 (
1531   val atomize_elimL = @{thm atomize_elimL};
1532   val atomize_exL = @{thm atomize_exL};
1533   val atomize_conjL = @{thm atomize_conjL};
1534   val atomize_disjL = @{thm atomize_disjL};
1535   val operator_names = [@{const_name HOL.disj}, @{const_name HOL.conj}, @{const_name Ex}];
1536 );
1537 \<close>
1540 subsubsection \<open>Reorienting equalities\<close>
1542 ML \<open>
1543 signature REORIENT_PROC =
1544 sig
1545   val add : (term -> bool) -> theory -> theory
1546   val proc : morphism -> Proof.context -> cterm -> thm option
1547 end;
1549 structure Reorient_Proc : REORIENT_PROC =
1550 struct
1551   structure Data = Theory_Data
1552   (
1553     type T = ((term -> bool) * stamp) list;
1554     val empty = [];
1555     val extend = I;
1556     fun merge data : T = Library.merge (eq_snd op =) data;
1557   );
1558   fun add m = Data.map (cons (m, stamp ()));
1559   fun matches thy t = exists (fn (m, _) => m t) (Data.get thy);
1561   val meta_reorient = @{thm eq_commute [THEN eq_reflection]};
1562   fun proc phi ctxt ct =
1563     let
1564       val thy = Proof_Context.theory_of ctxt;
1565     in
1566       case Thm.term_of ct of
1567         (_ \$ t \$ u) => if matches thy u then NONE else SOME meta_reorient
1568       | _ => NONE
1569     end;
1570 end;
1571 \<close>
1574 subsection \<open>Other simple lemmas and lemma duplicates\<close>
1576 lemma ex1_eq [iff]: "\<exists>!x. x = t" "\<exists>!x. t = x"
1577   by blast+
1579 lemma choice_eq: "(\<forall>x. \<exists>!y. P x y) = (\<exists>!f. \<forall>x. P x (f x))"
1580   apply (rule iffI)
1581    apply (rule_tac a = "\<lambda>x. THE y. P x y" in ex1I)
1582     apply (fast dest!: theI')
1583    apply (fast intro: the1_equality [symmetric])
1584   apply (erule ex1E)
1585   apply (rule allI)
1586   apply (rule ex1I)
1587    apply (erule spec)
1588   apply (erule_tac x = "\<lambda>z. if z = x then y else f z" in allE)
1589   apply (erule impE)
1590    apply (rule allI)
1591    apply (case_tac "xa = x")
1592     apply (drule_tac  x = x in fun_cong)
1593     apply simp_all
1594   done
1596 lemmas eq_sym_conv = eq_commute
1598 lemma nnf_simps:
1599   "(\<not> (P \<and> Q)) = (\<not> P \<or> \<not> Q)"
1600   "(\<not> (P \<or> Q)) = (\<not> P \<and> \<not> Q)"
1601   "(P \<longrightarrow> Q) = (\<not> P \<or> Q)"
1602   "(P = Q) = ((P \<and> Q) \<or> (\<not> P \<and> \<not> Q))"
1603   "(\<not> (P = Q)) = ((P \<and> \<not> Q) \<or> (\<not> P \<and> Q))"
1604   "(\<not> \<not> P) = P"
1605   by blast+
1608 subsection \<open>Basic ML bindings\<close>
1610 ML \<open>
1611 val FalseE = @{thm FalseE}
1612 val Let_def = @{thm Let_def}
1613 val TrueI = @{thm TrueI}
1614 val allE = @{thm allE}
1615 val allI = @{thm allI}
1616 val all_dupE = @{thm all_dupE}
1617 val arg_cong = @{thm arg_cong}
1618 val box_equals = @{thm box_equals}
1619 val ccontr = @{thm ccontr}
1620 val classical = @{thm classical}
1621 val conjE = @{thm conjE}
1622 val conjI = @{thm conjI}
1623 val conjunct1 = @{thm conjunct1}
1624 val conjunct2 = @{thm conjunct2}
1625 val disjCI = @{thm disjCI}
1626 val disjE = @{thm disjE}
1627 val disjI1 = @{thm disjI1}
1628 val disjI2 = @{thm disjI2}
1629 val eq_reflection = @{thm eq_reflection}
1630 val ex1E = @{thm ex1E}
1631 val ex1I = @{thm ex1I}
1632 val ex1_implies_ex = @{thm ex1_implies_ex}
1633 val exE = @{thm exE}
1634 val exI = @{thm exI}
1635 val excluded_middle = @{thm excluded_middle}
1636 val ext = @{thm ext}
1637 val fun_cong = @{thm fun_cong}
1638 val iffD1 = @{thm iffD1}
1639 val iffD2 = @{thm iffD2}
1640 val iffI = @{thm iffI}
1641 val impE = @{thm impE}
1642 val impI = @{thm impI}
1643 val meta_eq_to_obj_eq = @{thm meta_eq_to_obj_eq}
1644 val mp = @{thm mp}
1645 val notE = @{thm notE}
1646 val notI = @{thm notI}
1647 val not_all = @{thm not_all}
1648 val not_ex = @{thm not_ex}
1649 val not_iff = @{thm not_iff}
1650 val not_not = @{thm not_not}
1651 val not_sym = @{thm not_sym}
1652 val refl = @{thm refl}
1653 val rev_mp = @{thm rev_mp}
1654 val spec = @{thm spec}
1655 val ssubst = @{thm ssubst}
1656 val subst = @{thm subst}
1657 val sym = @{thm sym}
1658 val trans = @{thm trans}
1659 \<close>
1661 ML_file "Tools/cnf.ML"
1664 section \<open>\<open>NO_MATCH\<close> simproc\<close>
1666 text \<open>
1667   The simplification procedure can be used to avoid simplification of terms
1668   of a certain form.
1669 \<close>
1671 definition NO_MATCH :: "'a \<Rightarrow> 'b \<Rightarrow> bool"
1672   where "NO_MATCH pat val \<equiv> True"
1674 lemma NO_MATCH_cong[cong]: "NO_MATCH pat val = NO_MATCH pat val"
1675   by (rule refl)
1677 declare [[coercion_args NO_MATCH - -]]
1679 simproc_setup NO_MATCH ("NO_MATCH pat val") = \<open>fn _ => fn ctxt => fn ct =>
1680   let
1681     val thy = Proof_Context.theory_of ctxt
1682     val dest_binop = Term.dest_comb #> apfst (Term.dest_comb #> snd)
1683     val m = Pattern.matches thy (dest_binop (Thm.term_of ct))
1684   in if m then NONE else SOME @{thm NO_MATCH_def} end
1685 \<close>
1687 text \<open>
1688   This setup ensures that a rewrite rule of the form @{term "NO_MATCH pat val \<Longrightarrow> t"}
1689   is only applied, if the pattern \<open>pat\<close> does not match the value \<open>val\<close>.
1690 \<close>
1693 text\<open>
1694   Tagging a premise of a simp rule with ASSUMPTION forces the simplifier
1695   not to simplify the argument and to solve it by an assumption.
1696 \<close>
1698 definition ASSUMPTION :: "bool \<Rightarrow> bool"
1699   where "ASSUMPTION A \<equiv> A"
1701 lemma ASSUMPTION_cong[cong]: "ASSUMPTION A = ASSUMPTION A"
1702   by (rule refl)
1704 lemma ASSUMPTION_I: "A \<Longrightarrow> ASSUMPTION A"
1705   by (simp add: ASSUMPTION_def)
1707 lemma ASSUMPTION_D: "ASSUMPTION A \<Longrightarrow> A"
1708   by (simp add: ASSUMPTION_def)
1710 setup \<open>
1711 let
1712   val asm_sol = mk_solver "ASSUMPTION" (fn ctxt =>
1713     resolve_tac ctxt [@{thm ASSUMPTION_I}] THEN'
1714     resolve_tac ctxt (Simplifier.prems_of ctxt))
1715 in
1716   map_theory_simpset (fn ctxt => Simplifier.addSolver (ctxt,asm_sol))
1717 end
1718 \<close>
1721 subsection \<open>Code generator setup\<close>
1723 subsubsection \<open>Generic code generator preprocessor setup\<close>
1725 lemma conj_left_cong: "P \<longleftrightarrow> Q \<Longrightarrow> P \<and> R \<longleftrightarrow> Q \<and> R"
1726   by (fact arg_cong)
1728 lemma disj_left_cong: "P \<longleftrightarrow> Q \<Longrightarrow> P \<or> R \<longleftrightarrow> Q \<or> R"
1729   by (fact arg_cong)
1731 setup \<open>
1732   Code_Preproc.map_pre (put_simpset HOL_basic_ss) #>
1733   Code_Preproc.map_post (put_simpset HOL_basic_ss) #>
1734   Code_Simp.map_ss (put_simpset HOL_basic_ss #>
1735   Simplifier.add_cong @{thm conj_left_cong} #>
1736   Simplifier.add_cong @{thm disj_left_cong})
1737 \<close>
1740 subsubsection \<open>Equality\<close>
1742 class equal =
1743   fixes equal :: "'a \<Rightarrow> 'a \<Rightarrow> bool"
1744   assumes equal_eq: "equal x y \<longleftrightarrow> x = y"
1745 begin
1747 lemma equal: "equal = (op =)"
1748   by (rule ext equal_eq)+
1750 lemma equal_refl: "equal x x \<longleftrightarrow> True"
1751   unfolding equal by rule+
1753 lemma eq_equal: "(op =) \<equiv> equal"
1754   by (rule eq_reflection) (rule ext, rule ext, rule sym, rule equal_eq)
1756 end
1758 declare eq_equal [symmetric, code_post]
1759 declare eq_equal [code]
1761 setup \<open>
1762   Code_Preproc.map_pre (fn ctxt =>
1764       [Simplifier.make_simproc @{context} "equal"
1765         {lhss = [@{term HOL.eq}],
1766          proc = fn _ => fn _ => fn ct =>
1767           (case Thm.term_of ct of
1768             Const (_, Type (@{type_name fun}, [Type _, _])) => SOME @{thm eq_equal}
1769           | _ => NONE)}])
1770 \<close>
1773 subsubsection \<open>Generic code generator foundation\<close>
1775 text \<open>Datatype @{typ bool}\<close>
1777 code_datatype True False
1779 lemma [code]:
1780   shows "False \<and> P \<longleftrightarrow> False"
1781     and "True \<and> P \<longleftrightarrow> P"
1782     and "P \<and> False \<longleftrightarrow> False"
1783     and "P \<and> True \<longleftrightarrow> P"
1784   by simp_all
1786 lemma [code]:
1787   shows "False \<or> P \<longleftrightarrow> P"
1788     and "True \<or> P \<longleftrightarrow> True"
1789     and "P \<or> False \<longleftrightarrow> P"
1790     and "P \<or> True \<longleftrightarrow> True"
1791   by simp_all
1793 lemma [code]:
1794   shows "(False \<longrightarrow> P) \<longleftrightarrow> True"
1795     and "(True \<longrightarrow> P) \<longleftrightarrow> P"
1796     and "(P \<longrightarrow> False) \<longleftrightarrow> \<not> P"
1797     and "(P \<longrightarrow> True) \<longleftrightarrow> True"
1798   by simp_all
1800 text \<open>More about @{typ prop}\<close>
1802 lemma [code nbe]:
1803   shows "(True \<Longrightarrow> PROP Q) \<equiv> PROP Q"
1804     and "(PROP Q \<Longrightarrow> True) \<equiv> Trueprop True"
1805     and "(P \<Longrightarrow> R) \<equiv> Trueprop (P \<longrightarrow> R)"
1806   by (auto intro!: equal_intr_rule)
1808 lemma Trueprop_code [code]: "Trueprop True \<equiv> Code_Generator.holds"
1809   by (auto intro!: equal_intr_rule holds)
1811 declare Trueprop_code [symmetric, code_post]
1813 text \<open>Equality\<close>
1815 declare simp_thms(6) [code nbe]
1817 instantiation itself :: (type) equal
1818 begin
1820 definition equal_itself :: "'a itself \<Rightarrow> 'a itself \<Rightarrow> bool"
1821   where "equal_itself x y \<longleftrightarrow> x = y"
1823 instance
1824   by standard (fact equal_itself_def)
1826 end
1828 lemma equal_itself_code [code]: "equal TYPE('a) TYPE('a) \<longleftrightarrow> True"
1829   by (simp add: equal)
1831 setup \<open>Sign.add_const_constraint (@{const_name equal}, SOME @{typ "'a::type \<Rightarrow> 'a \<Rightarrow> bool"})\<close>
1833 lemma equal_alias_cert: "OFCLASS('a, equal_class) \<equiv> ((op = :: 'a \<Rightarrow> 'a \<Rightarrow> bool) \<equiv> equal)"
1834   (is "?ofclass \<equiv> ?equal")
1835 proof
1836   assume "PROP ?ofclass"
1837   show "PROP ?equal"
1838     by (tactic \<open>ALLGOALS (resolve_tac @{context} [Thm.unconstrainT @{thm eq_equal}])\<close>)
1839       (fact \<open>PROP ?ofclass\<close>)
1840 next
1841   assume "PROP ?equal"
1842   show "PROP ?ofclass" proof
1843   qed (simp add: \<open>PROP ?equal\<close>)
1844 qed
1846 setup \<open>Sign.add_const_constraint (@{const_name equal}, SOME @{typ "'a::equal \<Rightarrow> 'a \<Rightarrow> bool"})\<close>
1848 setup \<open>Nbe.add_const_alias @{thm equal_alias_cert}\<close>
1850 text \<open>Cases\<close>
1852 lemma Let_case_cert:
1853   assumes "CASE \<equiv> (\<lambda>x. Let x f)"
1854   shows "CASE x \<equiv> f x"
1855   using assms by simp_all
1857 setup \<open>
1858   Code.add_case @{thm Let_case_cert} #>
1859   Code.add_undefined @{const_name undefined}
1860 \<close>
1862 declare [[code abort: undefined]]
1865 subsubsection \<open>Generic code generator target languages\<close>
1867 text \<open>type @{typ bool}\<close>
1869 code_printing
1870   type_constructor bool \<rightharpoonup>
1871     (SML) "bool" and (OCaml) "bool" and (Haskell) "Bool" and (Scala) "Boolean"
1872 | constant True \<rightharpoonup>
1873     (SML) "true" and (OCaml) "true" and (Haskell) "True" and (Scala) "true"
1874 | constant False \<rightharpoonup>
1875     (SML) "false" and (OCaml) "false" and (Haskell) "False" and (Scala) "false"
1877 code_reserved SML
1878   bool true false
1880 code_reserved OCaml
1881   bool
1883 code_reserved Scala
1884   Boolean
1886 code_printing
1887   constant Not \<rightharpoonup>
1888     (SML) "not" and (OCaml) "not" and (Haskell) "not" and (Scala) "'! _"
1889 | constant HOL.conj \<rightharpoonup>
1890     (SML) infixl 1 "andalso" and (OCaml) infixl 3 "&&" and (Haskell) infixr 3 "&&" and (Scala) infixl 3 "&&"
1891 | constant HOL.disj \<rightharpoonup>
1892     (SML) infixl 0 "orelse" and (OCaml) infixl 2 "||" and (Haskell) infixl 2 "||" and (Scala) infixl 1 "||"
1893 | constant HOL.implies \<rightharpoonup>
1894     (SML) "!(if (_)/ then (_)/ else true)"
1895     and (OCaml) "!(if (_)/ then (_)/ else true)"
1896     and (Haskell) "!(if (_)/ then (_)/ else True)"
1897     and (Scala) "!(if ((_))/ (_)/ else true)"
1898 | constant If \<rightharpoonup>
1899     (SML) "!(if (_)/ then (_)/ else (_))"
1900     and (OCaml) "!(if (_)/ then (_)/ else (_))"
1901     and (Haskell) "!(if (_)/ then (_)/ else (_))"
1902     and (Scala) "!(if ((_))/ (_)/ else (_))"
1904 code_reserved SML
1905   not
1907 code_reserved OCaml
1908   not
1910 code_identifier
1911   code_module Pure \<rightharpoonup>
1912     (SML) HOL and (OCaml) HOL and (Haskell) HOL and (Scala) HOL
1914 text \<open>Using built-in Haskell equality.\<close>
1915 code_printing
1916   type_class equal \<rightharpoonup> (Haskell) "Eq"
1917 | constant HOL.equal \<rightharpoonup> (Haskell) infix 4 "=="
1918 | constant HOL.eq \<rightharpoonup> (Haskell) infix 4 "=="
1920 text \<open>\<open>undefined\<close>\<close>
1921 code_printing
1922   constant undefined \<rightharpoonup>
1923     (SML) "!(raise/ Fail/ \"undefined\")"
1924     and (OCaml) "failwith/ \"undefined\""
1925     and (Haskell) "error/ \"undefined\""
1926     and (Scala) "!sys.error(\"undefined\")"
1929 subsubsection \<open>Evaluation and normalization by evaluation\<close>
1931 method_setup eval = \<open>
1932   let
1933     fun eval_tac ctxt =
1934       let val conv = Code_Runtime.dynamic_holds_conv ctxt
1935       in
1936         CONVERSION (Conv.params_conv ~1 (K (Conv.concl_conv ~1 conv)) ctxt) THEN'
1937         resolve_tac ctxt [TrueI]
1938       end
1939   in
1940     Scan.succeed (SIMPLE_METHOD' o eval_tac)
1941   end
1942 \<close> "solve goal by evaluation"
1944 method_setup normalization = \<open>
1945   Scan.succeed (fn ctxt =>
1946     SIMPLE_METHOD'
1947       (CHANGED_PROP o
1948         (CONVERSION (Nbe.dynamic_conv ctxt)
1949           THEN_ALL_NEW (TRY o resolve_tac ctxt [TrueI]))))
1950 \<close> "solve goal by normalization"
1953 subsection \<open>Counterexample Search Units\<close>
1955 subsubsection \<open>Quickcheck\<close>
1957 quickcheck_params [size = 5, iterations = 50]
1960 subsubsection \<open>Nitpick setup\<close>
1962 named_theorems nitpick_unfold "alternative definitions of constants as needed by Nitpick"
1963   and nitpick_simp "equational specification of constants as needed by Nitpick"
1964   and nitpick_psimp "partial equational specification of constants as needed by Nitpick"
1965   and nitpick_choice_spec "choice specification of constants as needed by Nitpick"
1967 declare if_bool_eq_conj [nitpick_unfold, no_atp]
1968   and if_bool_eq_disj [no_atp]
1971 subsection \<open>Preprocessing for the predicate compiler\<close>
1973 named_theorems code_pred_def "alternative definitions of constants for the Predicate Compiler"
1974   and code_pred_inline "inlining definitions for the Predicate Compiler"
1975   and code_pred_simp "simplification rules for the optimisations in the Predicate Compiler"
1978 subsection \<open>Legacy tactics and ML bindings\<close>
1980 ML \<open>
1981   (* combination of (spec RS spec RS ...(j times) ... spec RS mp) *)
1982   local
1983     fun wrong_prem (Const (@{const_name All}, _) \$ Abs (_, _, t)) = wrong_prem t
1984       | wrong_prem (Bound _) = true
1985       | wrong_prem _ = false;
1986     val filter_right = filter (not o wrong_prem o HOLogic.dest_Trueprop o hd o Thm.prems_of);
1987     fun smp i = funpow i (fn m => filter_right ([spec] RL m)) [mp];
1988   in
1989     fun smp_tac ctxt j = EVERY' [dresolve_tac ctxt (smp j), assume_tac ctxt];
1990   end;
1992   local
1993     val nnf_ss =
1994       simpset_of (put_simpset HOL_basic_ss @{context} addsimps @{thms simp_thms nnf_simps});
1995   in
1996     fun nnf_conv ctxt = Simplifier.rewrite (put_simpset nnf_ss ctxt);
1997   end
1998 \<close>
2000 hide_const (open) eq equal
2002 end