src/HOL/Lifting_Set.thy
 author paulson Tue Apr 25 16:39:54 2017 +0100 (2017-04-25) changeset 65578 e4997c181cce parent 64272 f76b6dda2e56 child 67399 eab6ce8368fa permissions -rw-r--r--
New material from PNT proof, as well as more default [simp] declarations. Also removed duplicate theorems about geometric series
1 (*  Title:      HOL/Lifting_Set.thy
2     Author:     Brian Huffman and Ondrej Kuncar
3 *)
5 section \<open>Setup for Lifting/Transfer for the set type\<close>
7 theory Lifting_Set
8 imports Lifting
9 begin
11 subsection \<open>Relator and predicator properties\<close>
13 lemma rel_setD1: "\<lbrakk> rel_set R A B; x \<in> A \<rbrakk> \<Longrightarrow> \<exists>y \<in> B. R x y"
14   and rel_setD2: "\<lbrakk> rel_set R A B; y \<in> B \<rbrakk> \<Longrightarrow> \<exists>x \<in> A. R x y"
15   by (simp_all add: rel_set_def)
17 lemma rel_set_conversep [simp]: "rel_set A\<inverse>\<inverse> = (rel_set A)\<inverse>\<inverse>"
18   unfolding rel_set_def by auto
20 lemma rel_set_eq [relator_eq]: "rel_set (op =) = (op =)"
21   unfolding rel_set_def fun_eq_iff by auto
23 lemma rel_set_mono[relator_mono]:
24   assumes "A \<le> B"
25   shows "rel_set A \<le> rel_set B"
26   using assms unfolding rel_set_def by blast
28 lemma rel_set_OO[relator_distr]: "rel_set R OO rel_set S = rel_set (R OO S)"
29   apply (rule sym)
30   apply (intro ext)
31   subgoal for X Z
32     apply (rule iffI)
33     apply (rule relcomppI [where b="{y. (\<exists>x\<in>X. R x y) \<and> (\<exists>z\<in>Z. S y z)}"])
34     apply (simp add: rel_set_def, fast)+
35     done
36   done
38 lemma Domainp_set[relator_domain]:
39   "Domainp (rel_set T) = (\<lambda>A. Ball A (Domainp T))"
40   unfolding rel_set_def Domainp_iff[abs_def]
41   apply (intro ext)
42   apply (rule iffI)
43   apply blast
44   subgoal for A by (rule exI [where x="{y. \<exists>x\<in>A. T x y}"]) fast
45   done
47 lemma left_total_rel_set[transfer_rule]:
48   "left_total A \<Longrightarrow> left_total (rel_set A)"
49   unfolding left_total_def rel_set_def
50   apply safe
51   subgoal for X by (rule exI [where x="{y. \<exists>x\<in>X. A x y}"]) fast
52   done
54 lemma left_unique_rel_set[transfer_rule]:
55   "left_unique A \<Longrightarrow> left_unique (rel_set A)"
56   unfolding left_unique_def rel_set_def
57   by fast
59 lemma right_total_rel_set [transfer_rule]:
60   "right_total A \<Longrightarrow> right_total (rel_set A)"
61   using left_total_rel_set[of "A\<inverse>\<inverse>"] by simp
63 lemma right_unique_rel_set [transfer_rule]:
64   "right_unique A \<Longrightarrow> right_unique (rel_set A)"
65   unfolding right_unique_def rel_set_def by fast
67 lemma bi_total_rel_set [transfer_rule]:
68   "bi_total A \<Longrightarrow> bi_total (rel_set A)"
69   by(simp add: bi_total_alt_def left_total_rel_set right_total_rel_set)
71 lemma bi_unique_rel_set [transfer_rule]:
72   "bi_unique A \<Longrightarrow> bi_unique (rel_set A)"
73   unfolding bi_unique_def rel_set_def by fast
75 lemma set_relator_eq_onp [relator_eq_onp]:
76   "rel_set (eq_onp P) = eq_onp (\<lambda>A. Ball A P)"
77   unfolding fun_eq_iff rel_set_def eq_onp_def Ball_def by fast
79 lemma bi_unique_rel_set_lemma:
80   assumes "bi_unique R" and "rel_set R X Y"
81   obtains f where "Y = image f X" and "inj_on f X" and "\<forall>x\<in>X. R x (f x)"
82 proof
83   define f where "f x = (THE y. R x y)" for x
84   { fix x assume "x \<in> X"
85     with \<open>rel_set R X Y\<close> \<open>bi_unique R\<close> have "R x (f x)"
86       by (simp add: bi_unique_def rel_set_def f_def) (metis theI)
87     with assms \<open>x \<in> X\<close>
88     have  "R x (f x)" "\<forall>x'\<in>X. R x' (f x) \<longrightarrow> x = x'" "\<forall>y\<in>Y. R x y \<longrightarrow> y = f x" "f x \<in> Y"
89       by (fastforce simp add: bi_unique_def rel_set_def)+ }
90   note * = this
91   moreover
92   { fix y assume "y \<in> Y"
93     with \<open>rel_set R X Y\<close> *(3) \<open>y \<in> Y\<close> have "\<exists>x\<in>X. y = f x"
94       by (fastforce simp: rel_set_def) }
95   ultimately show "\<forall>x\<in>X. R x (f x)" "Y = image f X" "inj_on f X"
96     by (auto simp: inj_on_def image_iff)
97 qed
99 subsection \<open>Quotient theorem for the Lifting package\<close>
101 lemma Quotient_set[quot_map]:
102   assumes "Quotient R Abs Rep T"
103   shows "Quotient (rel_set R) (image Abs) (image Rep) (rel_set T)"
104   using assms unfolding Quotient_alt_def4
105   apply (simp add: rel_set_OO[symmetric])
106   apply (simp add: rel_set_def)
107   apply fast
108   done
111 subsection \<open>Transfer rules for the Transfer package\<close>
113 subsubsection \<open>Unconditional transfer rules\<close>
115 context includes lifting_syntax
116 begin
118 lemma empty_transfer [transfer_rule]: "(rel_set A) {} {}"
119   unfolding rel_set_def by simp
121 lemma insert_transfer [transfer_rule]:
122   "(A ===> rel_set A ===> rel_set A) insert insert"
123   unfolding rel_fun_def rel_set_def by auto
125 lemma union_transfer [transfer_rule]:
126   "(rel_set A ===> rel_set A ===> rel_set A) union union"
127   unfolding rel_fun_def rel_set_def by auto
129 lemma Union_transfer [transfer_rule]:
130   "(rel_set (rel_set A) ===> rel_set A) Union Union"
131   unfolding rel_fun_def rel_set_def by simp fast
133 lemma image_transfer [transfer_rule]:
134   "((A ===> B) ===> rel_set A ===> rel_set B) image image"
135   unfolding rel_fun_def rel_set_def by simp fast
137 lemma UNION_transfer [transfer_rule]:
138   "(rel_set A ===> (A ===> rel_set B) ===> rel_set B) UNION UNION"
139   by transfer_prover
141 lemma Ball_transfer [transfer_rule]:
142   "(rel_set A ===> (A ===> op =) ===> op =) Ball Ball"
143   unfolding rel_set_def rel_fun_def by fast
145 lemma Bex_transfer [transfer_rule]:
146   "(rel_set A ===> (A ===> op =) ===> op =) Bex Bex"
147   unfolding rel_set_def rel_fun_def by fast
149 lemma Pow_transfer [transfer_rule]:
150   "(rel_set A ===> rel_set (rel_set A)) Pow Pow"
151   apply (rule rel_funI)
152   apply (rule rel_setI)
153   subgoal for X Y X'
154     apply (rule rev_bexI [where x="{y\<in>Y. \<exists>x\<in>X'. A x y}"])
155     apply clarsimp
156     apply (simp add: rel_set_def)
157     apply fast
158     done
159   subgoal for X Y Y'
160     apply (rule rev_bexI [where x="{x\<in>X. \<exists>y\<in>Y'. A x y}"])
161     apply clarsimp
162     apply (simp add: rel_set_def)
163     apply fast
164     done
165   done
167 lemma rel_set_transfer [transfer_rule]:
168   "((A ===> B ===> op =) ===> rel_set A ===> rel_set B ===> op =) rel_set rel_set"
169   unfolding rel_fun_def rel_set_def by fast
171 lemma bind_transfer [transfer_rule]:
172   "(rel_set A ===> (A ===> rel_set B) ===> rel_set B) Set.bind Set.bind"
173   unfolding bind_UNION [abs_def] by transfer_prover
175 lemma INF_parametric [transfer_rule]:
176   "(rel_set A ===> (A ===> HOL.eq) ===> HOL.eq) INFIMUM INFIMUM"
177   by transfer_prover
179 lemma SUP_parametric [transfer_rule]:
180   "(rel_set R ===> (R ===> HOL.eq) ===> HOL.eq) SUPREMUM SUPREMUM"
181   by transfer_prover
184 subsubsection \<open>Rules requiring bi-unique, bi-total or right-total relations\<close>
186 lemma member_transfer [transfer_rule]:
187   assumes "bi_unique A"
188   shows "(A ===> rel_set A ===> op =) (op \<in>) (op \<in>)"
189   using assms unfolding rel_fun_def rel_set_def bi_unique_def by fast
191 lemma right_total_Collect_transfer[transfer_rule]:
192   assumes "right_total A"
193   shows "((A ===> op =) ===> rel_set A) (\<lambda>P. Collect (\<lambda>x. P x \<and> Domainp A x)) Collect"
194   using assms unfolding right_total_def rel_set_def rel_fun_def Domainp_iff by fast
196 lemma Collect_transfer [transfer_rule]:
197   assumes "bi_total A"
198   shows "((A ===> op =) ===> rel_set A) Collect Collect"
199   using assms unfolding rel_fun_def rel_set_def bi_total_def by fast
201 lemma inter_transfer [transfer_rule]:
202   assumes "bi_unique A"
203   shows "(rel_set A ===> rel_set A ===> rel_set A) inter inter"
204   using assms unfolding rel_fun_def rel_set_def bi_unique_def by fast
206 lemma Diff_transfer [transfer_rule]:
207   assumes "bi_unique A"
208   shows "(rel_set A ===> rel_set A ===> rel_set A) (op -) (op -)"
209   using assms unfolding rel_fun_def rel_set_def bi_unique_def
210   unfolding Ball_def Bex_def Diff_eq
211   by (safe, simp, metis, simp, metis)
213 lemma subset_transfer [transfer_rule]:
214   assumes [transfer_rule]: "bi_unique A"
215   shows "(rel_set A ===> rel_set A ===> op =) (op \<subseteq>) (op \<subseteq>)"
216   unfolding subset_eq [abs_def] by transfer_prover
218 declare right_total_UNIV_transfer[transfer_rule]
220 lemma UNIV_transfer [transfer_rule]:
221   assumes "bi_total A"
222   shows "(rel_set A) UNIV UNIV"
223   using assms unfolding rel_set_def bi_total_def by simp
225 lemma right_total_Compl_transfer [transfer_rule]:
226   assumes [transfer_rule]: "bi_unique A" and [transfer_rule]: "right_total A"
227   shows "(rel_set A ===> rel_set A) (\<lambda>S. uminus S \<inter> Collect (Domainp A)) uminus"
228   unfolding Compl_eq [abs_def]
229   by (subst Collect_conj_eq[symmetric]) transfer_prover
231 lemma Compl_transfer [transfer_rule]:
232   assumes [transfer_rule]: "bi_unique A" and [transfer_rule]: "bi_total A"
233   shows "(rel_set A ===> rel_set A) uminus uminus"
234   unfolding Compl_eq [abs_def] by transfer_prover
236 lemma right_total_Inter_transfer [transfer_rule]:
237   assumes [transfer_rule]: "bi_unique A" and [transfer_rule]: "right_total A"
238   shows "(rel_set (rel_set A) ===> rel_set A) (\<lambda>S. \<Inter>S \<inter> Collect (Domainp A)) Inter"
239   unfolding Inter_eq[abs_def]
240   by (subst Collect_conj_eq[symmetric]) transfer_prover
242 lemma Inter_transfer [transfer_rule]:
243   assumes [transfer_rule]: "bi_unique A" and [transfer_rule]: "bi_total A"
244   shows "(rel_set (rel_set A) ===> rel_set A) Inter Inter"
245   unfolding Inter_eq [abs_def] by transfer_prover
247 lemma filter_transfer [transfer_rule]:
248   assumes [transfer_rule]: "bi_unique A"
249   shows "((A ===> op=) ===> rel_set A ===> rel_set A) Set.filter Set.filter"
250   unfolding Set.filter_def[abs_def] rel_fun_def rel_set_def by blast
252 lemma finite_transfer [transfer_rule]:
253   "bi_unique A \<Longrightarrow> (rel_set A ===> op =) finite finite"
254   by (rule rel_funI, erule (1) bi_unique_rel_set_lemma)
255      (auto dest: finite_imageD)
257 lemma card_transfer [transfer_rule]:
258   "bi_unique A \<Longrightarrow> (rel_set A ===> op =) card card"
259   by (rule rel_funI, erule (1) bi_unique_rel_set_lemma)
260      (simp add: card_image)
262 lemma vimage_parametric [transfer_rule]:
263   assumes [transfer_rule]: "bi_total A" "bi_unique B"
264   shows "((A ===> B) ===> rel_set B ===> rel_set A) vimage vimage"
265   unfolding vimage_def[abs_def] by transfer_prover
267 lemma Image_parametric [transfer_rule]:
268   assumes "bi_unique A"
269   shows "(rel_set (rel_prod A B) ===> rel_set A ===> rel_set B) op `` op ``"
270   by (intro rel_funI rel_setI)
271     (force dest: rel_setD1 bi_uniqueDr[OF assms], force dest: rel_setD2 bi_uniqueDl[OF assms])
273 end
275 lemma (in comm_monoid_set) F_parametric [transfer_rule]:
276   fixes A :: "'b \<Rightarrow> 'c \<Rightarrow> bool"
277   assumes "bi_unique A"
278   shows "rel_fun (rel_fun A (op =)) (rel_fun (rel_set A) (op =)) F F"
279 proof (rule rel_funI)+
280   fix f :: "'b \<Rightarrow> 'a" and g S T
281   assume "rel_fun A (op =) f g" "rel_set A S T"
282   with \<open>bi_unique A\<close> obtain i where "bij_betw i S T" "\<And>x. x \<in> S \<Longrightarrow> f x = g (i x)"
283     by (auto elim: bi_unique_rel_set_lemma simp: rel_fun_def bij_betw_def)
284   then show "F f S = F g T"
285     by (simp add: reindex_bij_betw)
286 qed
288 lemmas sum_parametric = sum.F_parametric
289 lemmas prod_parametric = prod.F_parametric
291 lemma rel_set_UNION:
292   assumes [transfer_rule]: "rel_set Q A B" "rel_fun Q (rel_set R) f g"
293   shows "rel_set R (UNION A f) (UNION B g)"
294   by transfer_prover
296 end