src/HOL/Limits.thy
author paulson <lp15@cam.ac.uk>
Tue Apr 25 16:39:54 2017 +0100 (2017-04-25)
changeset 65578 e4997c181cce
parent 65204 d23eded35a33
child 65680 378a2f11bec9
permissions -rw-r--r--
New material from PNT proof, as well as more default [simp] declarations. Also removed duplicate theorems about geometric series
     1 (*  Title:      HOL/Limits.thy
     2     Author:     Brian Huffman
     3     Author:     Jacques D. Fleuriot, University of Cambridge
     4     Author:     Lawrence C Paulson
     5     Author:     Jeremy Avigad
     6 *)
     7 
     8 section \<open>Limits on Real Vector Spaces\<close>
     9 
    10 theory Limits
    11   imports Real_Vector_Spaces
    12 begin
    13 
    14 subsection \<open>Filter going to infinity norm\<close>
    15 
    16 definition at_infinity :: "'a::real_normed_vector filter"
    17   where "at_infinity = (INF r. principal {x. r \<le> norm x})"
    18 
    19 lemma eventually_at_infinity: "eventually P at_infinity \<longleftrightarrow> (\<exists>b. \<forall>x. b \<le> norm x \<longrightarrow> P x)"
    20   unfolding at_infinity_def
    21   by (subst eventually_INF_base)
    22      (auto simp: subset_eq eventually_principal intro!: exI[of _ "max a b" for a b])
    23 
    24 corollary eventually_at_infinity_pos:
    25   "eventually p at_infinity \<longleftrightarrow> (\<exists>b. 0 < b \<and> (\<forall>x. norm x \<ge> b \<longrightarrow> p x))"
    26   apply (simp add: eventually_at_infinity)
    27   apply auto
    28   apply (case_tac "b \<le> 0")
    29   using norm_ge_zero order_trans zero_less_one apply blast
    30   apply force
    31   done
    32 
    33 lemma at_infinity_eq_at_top_bot: "(at_infinity :: real filter) = sup at_top at_bot"
    34   apply (simp add: filter_eq_iff eventually_sup eventually_at_infinity
    35       eventually_at_top_linorder eventually_at_bot_linorder)
    36   apply safe
    37     apply (rule_tac x="b" in exI)
    38     apply simp
    39    apply (rule_tac x="- b" in exI)
    40    apply simp
    41   apply (rule_tac x="max (- Na) N" in exI)
    42   apply (auto simp: abs_real_def)
    43   done
    44 
    45 lemma at_top_le_at_infinity: "at_top \<le> (at_infinity :: real filter)"
    46   unfolding at_infinity_eq_at_top_bot by simp
    47 
    48 lemma at_bot_le_at_infinity: "at_bot \<le> (at_infinity :: real filter)"
    49   unfolding at_infinity_eq_at_top_bot by simp
    50 
    51 lemma filterlim_at_top_imp_at_infinity: "filterlim f at_top F \<Longrightarrow> filterlim f at_infinity F"
    52   for f :: "_ \<Rightarrow> real"
    53   by (rule filterlim_mono[OF _ at_top_le_at_infinity order_refl])
    54 
    55 lemma lim_infinity_imp_sequentially: "(f \<longlongrightarrow> l) at_infinity \<Longrightarrow> ((\<lambda>n. f(n)) \<longlongrightarrow> l) sequentially"
    56   by (simp add: filterlim_at_top_imp_at_infinity filterlim_compose filterlim_real_sequentially)
    57 
    58 
    59 subsubsection \<open>Boundedness\<close>
    60 
    61 definition Bfun :: "('a \<Rightarrow> 'b::metric_space) \<Rightarrow> 'a filter \<Rightarrow> bool"
    62   where Bfun_metric_def: "Bfun f F = (\<exists>y. \<exists>K>0. eventually (\<lambda>x. dist (f x) y \<le> K) F)"
    63 
    64 abbreviation Bseq :: "(nat \<Rightarrow> 'a::metric_space) \<Rightarrow> bool"
    65   where "Bseq X \<equiv> Bfun X sequentially"
    66 
    67 lemma Bseq_conv_Bfun: "Bseq X \<longleftrightarrow> Bfun X sequentially" ..
    68 
    69 lemma Bseq_ignore_initial_segment: "Bseq X \<Longrightarrow> Bseq (\<lambda>n. X (n + k))"
    70   unfolding Bfun_metric_def by (subst eventually_sequentially_seg)
    71 
    72 lemma Bseq_offset: "Bseq (\<lambda>n. X (n + k)) \<Longrightarrow> Bseq X"
    73   unfolding Bfun_metric_def by (subst (asm) eventually_sequentially_seg)
    74 
    75 lemma Bfun_def: "Bfun f F \<longleftrightarrow> (\<exists>K>0. eventually (\<lambda>x. norm (f x) \<le> K) F)"
    76   unfolding Bfun_metric_def norm_conv_dist
    77 proof safe
    78   fix y K
    79   assume K: "0 < K" and *: "eventually (\<lambda>x. dist (f x) y \<le> K) F"
    80   moreover have "eventually (\<lambda>x. dist (f x) 0 \<le> dist (f x) y + dist 0 y) F"
    81     by (intro always_eventually) (metis dist_commute dist_triangle)
    82   with * have "eventually (\<lambda>x. dist (f x) 0 \<le> K + dist 0 y) F"
    83     by eventually_elim auto
    84   with \<open>0 < K\<close> show "\<exists>K>0. eventually (\<lambda>x. dist (f x) 0 \<le> K) F"
    85     by (intro exI[of _ "K + dist 0 y"] add_pos_nonneg conjI zero_le_dist) auto
    86 qed (force simp del: norm_conv_dist [symmetric])
    87 
    88 lemma BfunI:
    89   assumes K: "eventually (\<lambda>x. norm (f x) \<le> K) F"
    90   shows "Bfun f F"
    91   unfolding Bfun_def
    92 proof (intro exI conjI allI)
    93   show "0 < max K 1" by simp
    94   show "eventually (\<lambda>x. norm (f x) \<le> max K 1) F"
    95     using K by (rule eventually_mono) simp
    96 qed
    97 
    98 lemma BfunE:
    99   assumes "Bfun f F"
   100   obtains B where "0 < B" and "eventually (\<lambda>x. norm (f x) \<le> B) F"
   101   using assms unfolding Bfun_def by blast
   102 
   103 lemma Cauchy_Bseq: "Cauchy X \<Longrightarrow> Bseq X"
   104   unfolding Cauchy_def Bfun_metric_def eventually_sequentially
   105   apply (erule_tac x=1 in allE)
   106   apply simp
   107   apply safe
   108   apply (rule_tac x="X M" in exI)
   109   apply (rule_tac x=1 in exI)
   110   apply (erule_tac x=M in allE)
   111   apply simp
   112   apply (rule_tac x=M in exI)
   113   apply (auto simp: dist_commute)
   114   done
   115 
   116 
   117 subsubsection \<open>Bounded Sequences\<close>
   118 
   119 lemma BseqI': "(\<And>n. norm (X n) \<le> K) \<Longrightarrow> Bseq X"
   120   by (intro BfunI) (auto simp: eventually_sequentially)
   121 
   122 lemma BseqI2': "\<forall>n\<ge>N. norm (X n) \<le> K \<Longrightarrow> Bseq X"
   123   by (intro BfunI) (auto simp: eventually_sequentially)
   124 
   125 lemma Bseq_def: "Bseq X \<longleftrightarrow> (\<exists>K>0. \<forall>n. norm (X n) \<le> K)"
   126   unfolding Bfun_def eventually_sequentially
   127 proof safe
   128   fix N K
   129   assume "0 < K" "\<forall>n\<ge>N. norm (X n) \<le> K"
   130   then show "\<exists>K>0. \<forall>n. norm (X n) \<le> K"
   131     by (intro exI[of _ "max (Max (norm ` X ` {..N})) K"] max.strict_coboundedI2)
   132        (auto intro!: imageI not_less[where 'a=nat, THEN iffD1] Max_ge simp: le_max_iff_disj)
   133 qed auto
   134 
   135 lemma BseqE: "Bseq X \<Longrightarrow> (\<And>K. 0 < K \<Longrightarrow> \<forall>n. norm (X n) \<le> K \<Longrightarrow> Q) \<Longrightarrow> Q"
   136   unfolding Bseq_def by auto
   137 
   138 lemma BseqD: "Bseq X \<Longrightarrow> \<exists>K. 0 < K \<and> (\<forall>n. norm (X n) \<le> K)"
   139   by (simp add: Bseq_def)
   140 
   141 lemma BseqI: "0 < K \<Longrightarrow> \<forall>n. norm (X n) \<le> K \<Longrightarrow> Bseq X"
   142   by (auto simp add: Bseq_def)
   143 
   144 lemma Bseq_bdd_above: "Bseq X \<Longrightarrow> bdd_above (range X)"
   145   for X :: "nat \<Rightarrow> real"
   146 proof (elim BseqE, intro bdd_aboveI2)
   147   fix K n
   148   assume "0 < K" "\<forall>n. norm (X n) \<le> K"
   149   then show "X n \<le> K"
   150     by (auto elim!: allE[of _ n])
   151 qed
   152 
   153 lemma Bseq_bdd_above': "Bseq X \<Longrightarrow> bdd_above (range (\<lambda>n. norm (X n)))"
   154   for X :: "nat \<Rightarrow> 'a :: real_normed_vector"
   155 proof (elim BseqE, intro bdd_aboveI2)
   156   fix K n
   157   assume "0 < K" "\<forall>n. norm (X n) \<le> K"
   158   then show "norm (X n) \<le> K"
   159     by (auto elim!: allE[of _ n])
   160 qed
   161 
   162 lemma Bseq_bdd_below: "Bseq X \<Longrightarrow> bdd_below (range X)"
   163   for X :: "nat \<Rightarrow> real"
   164 proof (elim BseqE, intro bdd_belowI2)
   165   fix K n
   166   assume "0 < K" "\<forall>n. norm (X n) \<le> K"
   167   then show "- K \<le> X n"
   168     by (auto elim!: allE[of _ n])
   169 qed
   170 
   171 lemma Bseq_eventually_mono:
   172   assumes "eventually (\<lambda>n. norm (f n) \<le> norm (g n)) sequentially" "Bseq g"
   173   shows "Bseq f"
   174 proof -
   175   from assms(1) obtain N where N: "\<And>n. n \<ge> N \<Longrightarrow> norm (f n) \<le> norm (g n)"
   176     by (auto simp: eventually_at_top_linorder)
   177   moreover from assms(2) obtain K where K: "\<And>n. norm (g n) \<le> K"
   178     by (blast elim!: BseqE)
   179   ultimately have "norm (f n) \<le> max K (Max {norm (f n) |n. n < N})" for n
   180     apply (cases "n < N")
   181     subgoal by (rule max.coboundedI2, rule Max.coboundedI) auto
   182     subgoal by (rule max.coboundedI1) (force intro: order.trans[OF N K])
   183     done
   184   then show ?thesis by (blast intro: BseqI')
   185 qed
   186 
   187 lemma lemma_NBseq_def: "(\<exists>K > 0. \<forall>n. norm (X n) \<le> K) \<longleftrightarrow> (\<exists>N. \<forall>n. norm (X n) \<le> real(Suc N))"
   188 proof safe
   189   fix K :: real
   190   from reals_Archimedean2 obtain n :: nat where "K < real n" ..
   191   then have "K \<le> real (Suc n)" by auto
   192   moreover assume "\<forall>m. norm (X m) \<le> K"
   193   ultimately have "\<forall>m. norm (X m) \<le> real (Suc n)"
   194     by (blast intro: order_trans)
   195   then show "\<exists>N. \<forall>n. norm (X n) \<le> real (Suc N)" ..
   196 next
   197   show "\<And>N. \<forall>n. norm (X n) \<le> real (Suc N) \<Longrightarrow> \<exists>K>0. \<forall>n. norm (X n) \<le> K"
   198     using of_nat_0_less_iff by blast
   199 qed
   200 
   201 text \<open>Alternative definition for \<open>Bseq\<close>.\<close>
   202 lemma Bseq_iff: "Bseq X \<longleftrightarrow> (\<exists>N. \<forall>n. norm (X n) \<le> real(Suc N))"
   203   by (simp add: Bseq_def) (simp add: lemma_NBseq_def)
   204 
   205 lemma lemma_NBseq_def2: "(\<exists>K > 0. \<forall>n. norm (X n) \<le> K) = (\<exists>N. \<forall>n. norm (X n) < real(Suc N))"
   206   apply (subst lemma_NBseq_def)
   207   apply auto
   208    apply (rule_tac x = "Suc N" in exI)
   209    apply (rule_tac [2] x = N in exI)
   210    apply auto
   211    prefer 2 apply (blast intro: order_less_imp_le)
   212   apply (drule_tac x = n in spec)
   213   apply simp
   214   done
   215 
   216 text \<open>Yet another definition for Bseq.\<close>
   217 lemma Bseq_iff1a: "Bseq X \<longleftrightarrow> (\<exists>N. \<forall>n. norm (X n) < real (Suc N))"
   218   by (simp add: Bseq_def lemma_NBseq_def2)
   219 
   220 subsubsection \<open>A Few More Equivalence Theorems for Boundedness\<close>
   221 
   222 text \<open>Alternative formulation for boundedness.\<close>
   223 lemma Bseq_iff2: "Bseq X \<longleftrightarrow> (\<exists>k > 0. \<exists>x. \<forall>n. norm (X n + - x) \<le> k)"
   224   apply (unfold Bseq_def)
   225   apply safe
   226    apply (rule_tac [2] x = "k + norm x" in exI)
   227    apply (rule_tac x = K in exI)
   228    apply simp
   229    apply (rule exI [where x = 0])
   230    apply auto
   231    apply (erule order_less_le_trans)
   232    apply simp
   233   apply (drule_tac x=n in spec)
   234   apply (drule order_trans [OF norm_triangle_ineq2])
   235   apply simp
   236   done
   237 
   238 text \<open>Alternative formulation for boundedness.\<close>
   239 lemma Bseq_iff3: "Bseq X \<longleftrightarrow> (\<exists>k>0. \<exists>N. \<forall>n. norm (X n + - X N) \<le> k)"
   240   (is "?P \<longleftrightarrow> ?Q")
   241 proof
   242   assume ?P
   243   then obtain K where *: "0 < K" and **: "\<And>n. norm (X n) \<le> K"
   244     by (auto simp add: Bseq_def)
   245   from * have "0 < K + norm (X 0)" by (rule order_less_le_trans) simp
   246   from ** have "\<forall>n. norm (X n - X 0) \<le> K + norm (X 0)"
   247     by (auto intro: order_trans norm_triangle_ineq4)
   248   then have "\<forall>n. norm (X n + - X 0) \<le> K + norm (X 0)"
   249     by simp
   250   with \<open>0 < K + norm (X 0)\<close> show ?Q by blast
   251 next
   252   assume ?Q
   253   then show ?P by (auto simp add: Bseq_iff2)
   254 qed
   255 
   256 lemma BseqI2: "\<forall>n. k \<le> f n \<and> f n \<le> K \<Longrightarrow> Bseq f"
   257   for k K :: real
   258   apply (simp add: Bseq_def)
   259   apply (rule_tac x = "(\<bar>k\<bar> + \<bar>K\<bar>) + 1" in exI)
   260   apply auto
   261   apply (drule_tac x = n in spec)
   262   apply arith
   263   done
   264 
   265 
   266 subsubsection \<open>Upper Bounds and Lubs of Bounded Sequences\<close>
   267 
   268 lemma Bseq_minus_iff: "Bseq (\<lambda>n. - (X n) :: 'a::real_normed_vector) \<longleftrightarrow> Bseq X"
   269   by (simp add: Bseq_def)
   270 
   271 lemma Bseq_add:
   272   fixes f :: "nat \<Rightarrow> 'a::real_normed_vector"
   273   assumes "Bseq f"
   274   shows "Bseq (\<lambda>x. f x + c)"
   275 proof -
   276   from assms obtain K where K: "\<And>x. norm (f x) \<le> K"
   277     unfolding Bseq_def by blast
   278   {
   279     fix x :: nat
   280     have "norm (f x + c) \<le> norm (f x) + norm c" by (rule norm_triangle_ineq)
   281     also have "norm (f x) \<le> K" by (rule K)
   282     finally have "norm (f x + c) \<le> K + norm c" by simp
   283   }
   284   then show ?thesis by (rule BseqI')
   285 qed
   286 
   287 lemma Bseq_add_iff: "Bseq (\<lambda>x. f x + c) \<longleftrightarrow> Bseq f"
   288   for f :: "nat \<Rightarrow> 'a::real_normed_vector"
   289   using Bseq_add[of f c] Bseq_add[of "\<lambda>x. f x + c" "-c"] by auto
   290 
   291 lemma Bseq_mult:
   292   fixes f g :: "nat \<Rightarrow> 'a::real_normed_field"
   293   assumes "Bseq f" and "Bseq g"
   294   shows "Bseq (\<lambda>x. f x * g x)"
   295 proof -
   296   from assms obtain K1 K2 where K: "norm (f x) \<le> K1" "K1 > 0" "norm (g x) \<le> K2" "K2 > 0"
   297     for x
   298     unfolding Bseq_def by blast
   299   then have "norm (f x * g x) \<le> K1 * K2" for x
   300     by (auto simp: norm_mult intro!: mult_mono)
   301   then show ?thesis by (rule BseqI')
   302 qed
   303 
   304 lemma Bfun_const [simp]: "Bfun (\<lambda>_. c) F"
   305   unfolding Bfun_metric_def by (auto intro!: exI[of _ c] exI[of _ "1::real"])
   306 
   307 lemma Bseq_cmult_iff:
   308   fixes c :: "'a::real_normed_field"
   309   assumes "c \<noteq> 0"
   310   shows "Bseq (\<lambda>x. c * f x) \<longleftrightarrow> Bseq f"
   311 proof
   312   assume "Bseq (\<lambda>x. c * f x)"
   313   with Bfun_const have "Bseq (\<lambda>x. inverse c * (c * f x))"
   314     by (rule Bseq_mult)
   315   with \<open>c \<noteq> 0\<close> show "Bseq f"
   316     by (simp add: divide_simps)
   317 qed (intro Bseq_mult Bfun_const)
   318 
   319 lemma Bseq_subseq: "Bseq f \<Longrightarrow> Bseq (\<lambda>x. f (g x))"
   320   for f :: "nat \<Rightarrow> 'a::real_normed_vector"
   321   unfolding Bseq_def by auto
   322 
   323 lemma Bseq_Suc_iff: "Bseq (\<lambda>n. f (Suc n)) \<longleftrightarrow> Bseq f"
   324   for f :: "nat \<Rightarrow> 'a::real_normed_vector"
   325   using Bseq_offset[of f 1] by (auto intro: Bseq_subseq)
   326 
   327 lemma increasing_Bseq_subseq_iff:
   328   assumes "\<And>x y. x \<le> y \<Longrightarrow> norm (f x :: 'a::real_normed_vector) \<le> norm (f y)" "subseq g"
   329   shows "Bseq (\<lambda>x. f (g x)) \<longleftrightarrow> Bseq f"
   330 proof
   331   assume "Bseq (\<lambda>x. f (g x))"
   332   then obtain K where K: "\<And>x. norm (f (g x)) \<le> K"
   333     unfolding Bseq_def by auto
   334   {
   335     fix x :: nat
   336     from filterlim_subseq[OF assms(2)] obtain y where "g y \<ge> x"
   337       by (auto simp: filterlim_at_top eventually_at_top_linorder)
   338     then have "norm (f x) \<le> norm (f (g y))"
   339       using assms(1) by blast
   340     also have "norm (f (g y)) \<le> K" by (rule K)
   341     finally have "norm (f x) \<le> K" .
   342   }
   343   then show "Bseq f" by (rule BseqI')
   344 qed (use Bseq_subseq[of f g] in simp_all)
   345 
   346 lemma nonneg_incseq_Bseq_subseq_iff:
   347   fixes f :: "nat \<Rightarrow> real"
   348     and g :: "nat \<Rightarrow> nat"
   349   assumes "\<And>x. f x \<ge> 0" "incseq f" "subseq g"
   350   shows "Bseq (\<lambda>x. f (g x)) \<longleftrightarrow> Bseq f"
   351   using assms by (intro increasing_Bseq_subseq_iff) (auto simp: incseq_def)
   352 
   353 lemma Bseq_eq_bounded: "range f \<subseteq> {a..b} \<Longrightarrow> Bseq f"
   354   for a b :: real
   355   apply (simp add: subset_eq)
   356   apply (rule BseqI'[where K="max (norm a) (norm b)"])
   357   apply (erule_tac x=n in allE)
   358   apply auto
   359   done
   360 
   361 lemma incseq_bounded: "incseq X \<Longrightarrow> \<forall>i. X i \<le> B \<Longrightarrow> Bseq X"
   362   for B :: real
   363   by (intro Bseq_eq_bounded[of X "X 0" B]) (auto simp: incseq_def)
   364 
   365 lemma decseq_bounded: "decseq X \<Longrightarrow> \<forall>i. B \<le> X i \<Longrightarrow> Bseq X"
   366   for B :: real
   367   by (intro Bseq_eq_bounded[of X B "X 0"]) (auto simp: decseq_def)
   368 
   369 
   370 subsection \<open>Bounded Monotonic Sequences\<close>
   371 
   372 subsubsection \<open>A Bounded and Monotonic Sequence Converges\<close>
   373 
   374 (* TODO: delete *)
   375 (* FIXME: one use in NSA/HSEQ.thy *)
   376 lemma Bmonoseq_LIMSEQ: "\<forall>n. m \<le> n \<longrightarrow> X n = X m \<Longrightarrow> \<exists>L. X \<longlonglongrightarrow> L"
   377   apply (rule_tac x="X m" in exI)
   378   apply (rule filterlim_cong[THEN iffD2, OF refl refl _ tendsto_const])
   379   unfolding eventually_sequentially
   380   apply blast
   381   done
   382 
   383 
   384 subsection \<open>Convergence to Zero\<close>
   385 
   386 definition Zfun :: "('a \<Rightarrow> 'b::real_normed_vector) \<Rightarrow> 'a filter \<Rightarrow> bool"
   387   where "Zfun f F = (\<forall>r>0. eventually (\<lambda>x. norm (f x) < r) F)"
   388 
   389 lemma ZfunI: "(\<And>r. 0 < r \<Longrightarrow> eventually (\<lambda>x. norm (f x) < r) F) \<Longrightarrow> Zfun f F"
   390   by (simp add: Zfun_def)
   391 
   392 lemma ZfunD: "Zfun f F \<Longrightarrow> 0 < r \<Longrightarrow> eventually (\<lambda>x. norm (f x) < r) F"
   393   by (simp add: Zfun_def)
   394 
   395 lemma Zfun_ssubst: "eventually (\<lambda>x. f x = g x) F \<Longrightarrow> Zfun g F \<Longrightarrow> Zfun f F"
   396   unfolding Zfun_def by (auto elim!: eventually_rev_mp)
   397 
   398 lemma Zfun_zero: "Zfun (\<lambda>x. 0) F"
   399   unfolding Zfun_def by simp
   400 
   401 lemma Zfun_norm_iff: "Zfun (\<lambda>x. norm (f x)) F = Zfun (\<lambda>x. f x) F"
   402   unfolding Zfun_def by simp
   403 
   404 lemma Zfun_imp_Zfun:
   405   assumes f: "Zfun f F"
   406     and g: "eventually (\<lambda>x. norm (g x) \<le> norm (f x) * K) F"
   407   shows "Zfun (\<lambda>x. g x) F"
   408 proof (cases "0 < K")
   409   case K: True
   410   show ?thesis
   411   proof (rule ZfunI)
   412     fix r :: real
   413     assume "0 < r"
   414     then have "0 < r / K" using K by simp
   415     then have "eventually (\<lambda>x. norm (f x) < r / K) F"
   416       using ZfunD [OF f] by blast
   417     with g show "eventually (\<lambda>x. norm (g x) < r) F"
   418     proof eventually_elim
   419       case (elim x)
   420       then have "norm (f x) * K < r"
   421         by (simp add: pos_less_divide_eq K)
   422       then show ?case
   423         by (simp add: order_le_less_trans [OF elim(1)])
   424     qed
   425   qed
   426 next
   427   case False
   428   then have K: "K \<le> 0" by (simp only: not_less)
   429   show ?thesis
   430   proof (rule ZfunI)
   431     fix r :: real
   432     assume "0 < r"
   433     from g show "eventually (\<lambda>x. norm (g x) < r) F"
   434     proof eventually_elim
   435       case (elim x)
   436       also have "norm (f x) * K \<le> norm (f x) * 0"
   437         using K norm_ge_zero by (rule mult_left_mono)
   438       finally show ?case
   439         using \<open>0 < r\<close> by simp
   440     qed
   441   qed
   442 qed
   443 
   444 lemma Zfun_le: "Zfun g F \<Longrightarrow> \<forall>x. norm (f x) \<le> norm (g x) \<Longrightarrow> Zfun f F"
   445   by (erule Zfun_imp_Zfun [where K = 1]) simp
   446 
   447 lemma Zfun_add:
   448   assumes f: "Zfun f F"
   449     and g: "Zfun g F"
   450   shows "Zfun (\<lambda>x. f x + g x) F"
   451 proof (rule ZfunI)
   452   fix r :: real
   453   assume "0 < r"
   454   then have r: "0 < r / 2" by simp
   455   have "eventually (\<lambda>x. norm (f x) < r/2) F"
   456     using f r by (rule ZfunD)
   457   moreover
   458   have "eventually (\<lambda>x. norm (g x) < r/2) F"
   459     using g r by (rule ZfunD)
   460   ultimately
   461   show "eventually (\<lambda>x. norm (f x + g x) < r) F"
   462   proof eventually_elim
   463     case (elim x)
   464     have "norm (f x + g x) \<le> norm (f x) + norm (g x)"
   465       by (rule norm_triangle_ineq)
   466     also have "\<dots> < r/2 + r/2"
   467       using elim by (rule add_strict_mono)
   468     finally show ?case
   469       by simp
   470   qed
   471 qed
   472 
   473 lemma Zfun_minus: "Zfun f F \<Longrightarrow> Zfun (\<lambda>x. - f x) F"
   474   unfolding Zfun_def by simp
   475 
   476 lemma Zfun_diff: "Zfun f F \<Longrightarrow> Zfun g F \<Longrightarrow> Zfun (\<lambda>x. f x - g x) F"
   477   using Zfun_add [of f F "\<lambda>x. - g x"] by (simp add: Zfun_minus)
   478 
   479 lemma (in bounded_linear) Zfun:
   480   assumes g: "Zfun g F"
   481   shows "Zfun (\<lambda>x. f (g x)) F"
   482 proof -
   483   obtain K where "norm (f x) \<le> norm x * K" for x
   484     using bounded by blast
   485   then have "eventually (\<lambda>x. norm (f (g x)) \<le> norm (g x) * K) F"
   486     by simp
   487   with g show ?thesis
   488     by (rule Zfun_imp_Zfun)
   489 qed
   490 
   491 lemma (in bounded_bilinear) Zfun:
   492   assumes f: "Zfun f F"
   493     and g: "Zfun g F"
   494   shows "Zfun (\<lambda>x. f x ** g x) F"
   495 proof (rule ZfunI)
   496   fix r :: real
   497   assume r: "0 < r"
   498   obtain K where K: "0 < K"
   499     and norm_le: "norm (x ** y) \<le> norm x * norm y * K" for x y
   500     using pos_bounded by blast
   501   from K have K': "0 < inverse K"
   502     by (rule positive_imp_inverse_positive)
   503   have "eventually (\<lambda>x. norm (f x) < r) F"
   504     using f r by (rule ZfunD)
   505   moreover
   506   have "eventually (\<lambda>x. norm (g x) < inverse K) F"
   507     using g K' by (rule ZfunD)
   508   ultimately
   509   show "eventually (\<lambda>x. norm (f x ** g x) < r) F"
   510   proof eventually_elim
   511     case (elim x)
   512     have "norm (f x ** g x) \<le> norm (f x) * norm (g x) * K"
   513       by (rule norm_le)
   514     also have "norm (f x) * norm (g x) * K < r * inverse K * K"
   515       by (intro mult_strict_right_mono mult_strict_mono' norm_ge_zero elim K)
   516     also from K have "r * inverse K * K = r"
   517       by simp
   518     finally show ?case .
   519   qed
   520 qed
   521 
   522 lemma (in bounded_bilinear) Zfun_left: "Zfun f F \<Longrightarrow> Zfun (\<lambda>x. f x ** a) F"
   523   by (rule bounded_linear_left [THEN bounded_linear.Zfun])
   524 
   525 lemma (in bounded_bilinear) Zfun_right: "Zfun f F \<Longrightarrow> Zfun (\<lambda>x. a ** f x) F"
   526   by (rule bounded_linear_right [THEN bounded_linear.Zfun])
   527 
   528 lemmas Zfun_mult = bounded_bilinear.Zfun [OF bounded_bilinear_mult]
   529 lemmas Zfun_mult_right = bounded_bilinear.Zfun_right [OF bounded_bilinear_mult]
   530 lemmas Zfun_mult_left = bounded_bilinear.Zfun_left [OF bounded_bilinear_mult]
   531 
   532 lemma tendsto_Zfun_iff: "(f \<longlongrightarrow> a) F = Zfun (\<lambda>x. f x - a) F"
   533   by (simp only: tendsto_iff Zfun_def dist_norm)
   534 
   535 lemma tendsto_0_le:
   536   "(f \<longlongrightarrow> 0) F \<Longrightarrow> eventually (\<lambda>x. norm (g x) \<le> norm (f x) * K) F \<Longrightarrow> (g \<longlongrightarrow> 0) F"
   537   by (simp add: Zfun_imp_Zfun tendsto_Zfun_iff)
   538 
   539 
   540 subsubsection \<open>Distance and norms\<close>
   541 
   542 lemma tendsto_dist [tendsto_intros]:
   543   fixes l m :: "'a::metric_space"
   544   assumes f: "(f \<longlongrightarrow> l) F"
   545     and g: "(g \<longlongrightarrow> m) F"
   546   shows "((\<lambda>x. dist (f x) (g x)) \<longlongrightarrow> dist l m) F"
   547 proof (rule tendstoI)
   548   fix e :: real
   549   assume "0 < e"
   550   then have e2: "0 < e/2" by simp
   551   from tendstoD [OF f e2] tendstoD [OF g e2]
   552   show "eventually (\<lambda>x. dist (dist (f x) (g x)) (dist l m) < e) F"
   553   proof (eventually_elim)
   554     case (elim x)
   555     then show "dist (dist (f x) (g x)) (dist l m) < e"
   556       unfolding dist_real_def
   557       using dist_triangle2 [of "f x" "g x" "l"]
   558         and dist_triangle2 [of "g x" "l" "m"]
   559         and dist_triangle3 [of "l" "m" "f x"]
   560         and dist_triangle [of "f x" "m" "g x"]
   561       by arith
   562   qed
   563 qed
   564 
   565 lemma continuous_dist[continuous_intros]:
   566   fixes f g :: "_ \<Rightarrow> 'a :: metric_space"
   567   shows "continuous F f \<Longrightarrow> continuous F g \<Longrightarrow> continuous F (\<lambda>x. dist (f x) (g x))"
   568   unfolding continuous_def by (rule tendsto_dist)
   569 
   570 lemma continuous_on_dist[continuous_intros]:
   571   fixes f g :: "_ \<Rightarrow> 'a :: metric_space"
   572   shows "continuous_on s f \<Longrightarrow> continuous_on s g \<Longrightarrow> continuous_on s (\<lambda>x. dist (f x) (g x))"
   573   unfolding continuous_on_def by (auto intro: tendsto_dist)
   574 
   575 lemma tendsto_norm [tendsto_intros]: "(f \<longlongrightarrow> a) F \<Longrightarrow> ((\<lambda>x. norm (f x)) \<longlongrightarrow> norm a) F"
   576   unfolding norm_conv_dist by (intro tendsto_intros)
   577 
   578 lemma continuous_norm [continuous_intros]: "continuous F f \<Longrightarrow> continuous F (\<lambda>x. norm (f x))"
   579   unfolding continuous_def by (rule tendsto_norm)
   580 
   581 lemma continuous_on_norm [continuous_intros]:
   582   "continuous_on s f \<Longrightarrow> continuous_on s (\<lambda>x. norm (f x))"
   583   unfolding continuous_on_def by (auto intro: tendsto_norm)
   584 
   585 lemma tendsto_norm_zero: "(f \<longlongrightarrow> 0) F \<Longrightarrow> ((\<lambda>x. norm (f x)) \<longlongrightarrow> 0) F"
   586   by (drule tendsto_norm) simp
   587 
   588 lemma tendsto_norm_zero_cancel: "((\<lambda>x. norm (f x)) \<longlongrightarrow> 0) F \<Longrightarrow> (f \<longlongrightarrow> 0) F"
   589   unfolding tendsto_iff dist_norm by simp
   590 
   591 lemma tendsto_norm_zero_iff: "((\<lambda>x. norm (f x)) \<longlongrightarrow> 0) F \<longleftrightarrow> (f \<longlongrightarrow> 0) F"
   592   unfolding tendsto_iff dist_norm by simp
   593 
   594 lemma tendsto_rabs [tendsto_intros]: "(f \<longlongrightarrow> l) F \<Longrightarrow> ((\<lambda>x. \<bar>f x\<bar>) \<longlongrightarrow> \<bar>l\<bar>) F"
   595   for l :: real
   596   by (fold real_norm_def) (rule tendsto_norm)
   597 
   598 lemma continuous_rabs [continuous_intros]:
   599   "continuous F f \<Longrightarrow> continuous F (\<lambda>x. \<bar>f x :: real\<bar>)"
   600   unfolding real_norm_def[symmetric] by (rule continuous_norm)
   601 
   602 lemma continuous_on_rabs [continuous_intros]:
   603   "continuous_on s f \<Longrightarrow> continuous_on s (\<lambda>x. \<bar>f x :: real\<bar>)"
   604   unfolding real_norm_def[symmetric] by (rule continuous_on_norm)
   605 
   606 lemma tendsto_rabs_zero: "(f \<longlongrightarrow> (0::real)) F \<Longrightarrow> ((\<lambda>x. \<bar>f x\<bar>) \<longlongrightarrow> 0) F"
   607   by (fold real_norm_def) (rule tendsto_norm_zero)
   608 
   609 lemma tendsto_rabs_zero_cancel: "((\<lambda>x. \<bar>f x\<bar>) \<longlongrightarrow> (0::real)) F \<Longrightarrow> (f \<longlongrightarrow> 0) F"
   610   by (fold real_norm_def) (rule tendsto_norm_zero_cancel)
   611 
   612 lemma tendsto_rabs_zero_iff: "((\<lambda>x. \<bar>f x\<bar>) \<longlongrightarrow> (0::real)) F \<longleftrightarrow> (f \<longlongrightarrow> 0) F"
   613   by (fold real_norm_def) (rule tendsto_norm_zero_iff)
   614 
   615 
   616 subsection \<open>Topological Monoid\<close>
   617 
   618 class topological_monoid_add = topological_space + monoid_add +
   619   assumes tendsto_add_Pair: "LIM x (nhds a \<times>\<^sub>F nhds b). fst x + snd x :> nhds (a + b)"
   620 
   621 class topological_comm_monoid_add = topological_monoid_add + comm_monoid_add
   622 
   623 lemma tendsto_add [tendsto_intros]:
   624   fixes a b :: "'a::topological_monoid_add"
   625   shows "(f \<longlongrightarrow> a) F \<Longrightarrow> (g \<longlongrightarrow> b) F \<Longrightarrow> ((\<lambda>x. f x + g x) \<longlongrightarrow> a + b) F"
   626   using filterlim_compose[OF tendsto_add_Pair, of "\<lambda>x. (f x, g x)" a b F]
   627   by (simp add: nhds_prod[symmetric] tendsto_Pair)
   628 
   629 lemma continuous_add [continuous_intros]:
   630   fixes f g :: "_ \<Rightarrow> 'b::topological_monoid_add"
   631   shows "continuous F f \<Longrightarrow> continuous F g \<Longrightarrow> continuous F (\<lambda>x. f x + g x)"
   632   unfolding continuous_def by (rule tendsto_add)
   633 
   634 lemma continuous_on_add [continuous_intros]:
   635   fixes f g :: "_ \<Rightarrow> 'b::topological_monoid_add"
   636   shows "continuous_on s f \<Longrightarrow> continuous_on s g \<Longrightarrow> continuous_on s (\<lambda>x. f x + g x)"
   637   unfolding continuous_on_def by (auto intro: tendsto_add)
   638 
   639 lemma tendsto_add_zero:
   640   fixes f g :: "_ \<Rightarrow> 'b::topological_monoid_add"
   641   shows "(f \<longlongrightarrow> 0) F \<Longrightarrow> (g \<longlongrightarrow> 0) F \<Longrightarrow> ((\<lambda>x. f x + g x) \<longlongrightarrow> 0) F"
   642   by (drule (1) tendsto_add) simp
   643 
   644 lemma tendsto_sum [tendsto_intros]:
   645   fixes f :: "'a \<Rightarrow> 'b \<Rightarrow> 'c::topological_comm_monoid_add"
   646   shows "(\<And>i. i \<in> I \<Longrightarrow> (f i \<longlongrightarrow> a i) F) \<Longrightarrow> ((\<lambda>x. \<Sum>i\<in>I. f i x) \<longlongrightarrow> (\<Sum>i\<in>I. a i)) F"
   647   by (induct I rule: infinite_finite_induct) (simp_all add: tendsto_add)
   648 
   649 lemma continuous_sum [continuous_intros]:
   650   fixes f :: "'a \<Rightarrow> 'b::t2_space \<Rightarrow> 'c::topological_comm_monoid_add"
   651   shows "(\<And>i. i \<in> I \<Longrightarrow> continuous F (f i)) \<Longrightarrow> continuous F (\<lambda>x. \<Sum>i\<in>I. f i x)"
   652   unfolding continuous_def by (rule tendsto_sum)
   653 
   654 lemma continuous_on_sum [continuous_intros]:
   655   fixes f :: "'a \<Rightarrow> 'b::topological_space \<Rightarrow> 'c::topological_comm_monoid_add"
   656   shows "(\<And>i. i \<in> I \<Longrightarrow> continuous_on S (f i)) \<Longrightarrow> continuous_on S (\<lambda>x. \<Sum>i\<in>I. f i x)"
   657   unfolding continuous_on_def by (auto intro: tendsto_sum)
   658 
   659 instance nat :: topological_comm_monoid_add
   660   by standard
   661     (simp add: nhds_discrete principal_prod_principal filterlim_principal eventually_principal)
   662 
   663 instance int :: topological_comm_monoid_add
   664   by standard
   665     (simp add: nhds_discrete principal_prod_principal filterlim_principal eventually_principal)
   666 
   667 
   668 subsubsection \<open>Topological group\<close>
   669 
   670 class topological_group_add = topological_monoid_add + group_add +
   671   assumes tendsto_uminus_nhds: "(uminus \<longlongrightarrow> - a) (nhds a)"
   672 begin
   673 
   674 lemma tendsto_minus [tendsto_intros]: "(f \<longlongrightarrow> a) F \<Longrightarrow> ((\<lambda>x. - f x) \<longlongrightarrow> - a) F"
   675   by (rule filterlim_compose[OF tendsto_uminus_nhds])
   676 
   677 end
   678 
   679 class topological_ab_group_add = topological_group_add + ab_group_add
   680 
   681 instance topological_ab_group_add < topological_comm_monoid_add ..
   682 
   683 lemma continuous_minus [continuous_intros]: "continuous F f \<Longrightarrow> continuous F (\<lambda>x. - f x)"
   684   for f :: "'a::t2_space \<Rightarrow> 'b::topological_group_add"
   685   unfolding continuous_def by (rule tendsto_minus)
   686 
   687 lemma continuous_on_minus [continuous_intros]: "continuous_on s f \<Longrightarrow> continuous_on s (\<lambda>x. - f x)"
   688   for f :: "_ \<Rightarrow> 'b::topological_group_add"
   689   unfolding continuous_on_def by (auto intro: tendsto_minus)
   690 
   691 lemma tendsto_minus_cancel: "((\<lambda>x. - f x) \<longlongrightarrow> - a) F \<Longrightarrow> (f \<longlongrightarrow> a) F"
   692   for a :: "'a::topological_group_add"
   693   by (drule tendsto_minus) simp
   694 
   695 lemma tendsto_minus_cancel_left:
   696   "(f \<longlongrightarrow> - (y::_::topological_group_add)) F \<longleftrightarrow> ((\<lambda>x. - f x) \<longlongrightarrow> y) F"
   697   using tendsto_minus_cancel[of f "- y" F]  tendsto_minus[of f "- y" F]
   698   by auto
   699 
   700 lemma tendsto_diff [tendsto_intros]:
   701   fixes a b :: "'a::topological_group_add"
   702   shows "(f \<longlongrightarrow> a) F \<Longrightarrow> (g \<longlongrightarrow> b) F \<Longrightarrow> ((\<lambda>x. f x - g x) \<longlongrightarrow> a - b) F"
   703   using tendsto_add [of f a F "\<lambda>x. - g x" "- b"] by (simp add: tendsto_minus)
   704 
   705 lemma continuous_diff [continuous_intros]:
   706   fixes f g :: "'a::t2_space \<Rightarrow> 'b::topological_group_add"
   707   shows "continuous F f \<Longrightarrow> continuous F g \<Longrightarrow> continuous F (\<lambda>x. f x - g x)"
   708   unfolding continuous_def by (rule tendsto_diff)
   709 
   710 lemma continuous_on_diff [continuous_intros]:
   711   fixes f g :: "_ \<Rightarrow> 'b::topological_group_add"
   712   shows "continuous_on s f \<Longrightarrow> continuous_on s g \<Longrightarrow> continuous_on s (\<lambda>x. f x - g x)"
   713   unfolding continuous_on_def by (auto intro: tendsto_diff)
   714 
   715 lemma continuous_on_op_minus: "continuous_on (s::'a::topological_group_add set) (op - x)"
   716   by (rule continuous_intros | simp)+
   717 
   718 instance real_normed_vector < topological_ab_group_add
   719 proof
   720   fix a b :: 'a
   721   show "((\<lambda>x. fst x + snd x) \<longlongrightarrow> a + b) (nhds a \<times>\<^sub>F nhds b)"
   722     unfolding tendsto_Zfun_iff add_diff_add
   723     using tendsto_fst[OF filterlim_ident, of "(a,b)"] tendsto_snd[OF filterlim_ident, of "(a,b)"]
   724     by (intro Zfun_add)
   725        (auto simp add: tendsto_Zfun_iff[symmetric] nhds_prod[symmetric] intro!: tendsto_fst)
   726   show "(uminus \<longlongrightarrow> - a) (nhds a)"
   727     unfolding tendsto_Zfun_iff minus_diff_minus
   728     using filterlim_ident[of "nhds a"]
   729     by (intro Zfun_minus) (simp add: tendsto_Zfun_iff)
   730 qed
   731 
   732 lemmas real_tendsto_sandwich = tendsto_sandwich[where 'a=real]
   733 
   734 
   735 subsubsection \<open>Linear operators and multiplication\<close>
   736 
   737 lemma linear_times: "linear (\<lambda>x. c * x)"
   738   for c :: "'a::real_algebra"
   739   by (auto simp: linearI distrib_left)
   740 
   741 lemma (in bounded_linear) tendsto: "(g \<longlongrightarrow> a) F \<Longrightarrow> ((\<lambda>x. f (g x)) \<longlongrightarrow> f a) F"
   742   by (simp only: tendsto_Zfun_iff diff [symmetric] Zfun)
   743 
   744 lemma (in bounded_linear) continuous: "continuous F g \<Longrightarrow> continuous F (\<lambda>x. f (g x))"
   745   using tendsto[of g _ F] by (auto simp: continuous_def)
   746 
   747 lemma (in bounded_linear) continuous_on: "continuous_on s g \<Longrightarrow> continuous_on s (\<lambda>x. f (g x))"
   748   using tendsto[of g] by (auto simp: continuous_on_def)
   749 
   750 lemma (in bounded_linear) tendsto_zero: "(g \<longlongrightarrow> 0) F \<Longrightarrow> ((\<lambda>x. f (g x)) \<longlongrightarrow> 0) F"
   751   by (drule tendsto) (simp only: zero)
   752 
   753 lemma (in bounded_bilinear) tendsto:
   754   "(f \<longlongrightarrow> a) F \<Longrightarrow> (g \<longlongrightarrow> b) F \<Longrightarrow> ((\<lambda>x. f x ** g x) \<longlongrightarrow> a ** b) F"
   755   by (simp only: tendsto_Zfun_iff prod_diff_prod Zfun_add Zfun Zfun_left Zfun_right)
   756 
   757 lemma (in bounded_bilinear) continuous:
   758   "continuous F f \<Longrightarrow> continuous F g \<Longrightarrow> continuous F (\<lambda>x. f x ** g x)"
   759   using tendsto[of f _ F g] by (auto simp: continuous_def)
   760 
   761 lemma (in bounded_bilinear) continuous_on:
   762   "continuous_on s f \<Longrightarrow> continuous_on s g \<Longrightarrow> continuous_on s (\<lambda>x. f x ** g x)"
   763   using tendsto[of f _ _ g] by (auto simp: continuous_on_def)
   764 
   765 lemma (in bounded_bilinear) tendsto_zero:
   766   assumes f: "(f \<longlongrightarrow> 0) F"
   767     and g: "(g \<longlongrightarrow> 0) F"
   768   shows "((\<lambda>x. f x ** g x) \<longlongrightarrow> 0) F"
   769   using tendsto [OF f g] by (simp add: zero_left)
   770 
   771 lemma (in bounded_bilinear) tendsto_left_zero:
   772   "(f \<longlongrightarrow> 0) F \<Longrightarrow> ((\<lambda>x. f x ** c) \<longlongrightarrow> 0) F"
   773   by (rule bounded_linear.tendsto_zero [OF bounded_linear_left])
   774 
   775 lemma (in bounded_bilinear) tendsto_right_zero:
   776   "(f \<longlongrightarrow> 0) F \<Longrightarrow> ((\<lambda>x. c ** f x) \<longlongrightarrow> 0) F"
   777   by (rule bounded_linear.tendsto_zero [OF bounded_linear_right])
   778 
   779 lemmas tendsto_of_real [tendsto_intros] =
   780   bounded_linear.tendsto [OF bounded_linear_of_real]
   781 
   782 lemmas tendsto_scaleR [tendsto_intros] =
   783   bounded_bilinear.tendsto [OF bounded_bilinear_scaleR]
   784 
   785 lemmas tendsto_mult [tendsto_intros] =
   786   bounded_bilinear.tendsto [OF bounded_bilinear_mult]
   787 
   788 lemma tendsto_mult_left: "(f \<longlongrightarrow> l) F \<Longrightarrow> ((\<lambda>x. c * (f x)) \<longlongrightarrow> c * l) F"
   789   for c :: "'a::real_normed_algebra"
   790   by (rule tendsto_mult [OF tendsto_const])
   791 
   792 lemma tendsto_mult_right: "(f \<longlongrightarrow> l) F \<Longrightarrow> ((\<lambda>x. (f x) * c) \<longlongrightarrow> l * c) F"
   793   for c :: "'a::real_normed_algebra"
   794   by (rule tendsto_mult [OF _ tendsto_const])
   795 
   796 lemmas continuous_of_real [continuous_intros] =
   797   bounded_linear.continuous [OF bounded_linear_of_real]
   798 
   799 lemmas continuous_scaleR [continuous_intros] =
   800   bounded_bilinear.continuous [OF bounded_bilinear_scaleR]
   801 
   802 lemmas continuous_mult [continuous_intros] =
   803   bounded_bilinear.continuous [OF bounded_bilinear_mult]
   804 
   805 lemmas continuous_on_of_real [continuous_intros] =
   806   bounded_linear.continuous_on [OF bounded_linear_of_real]
   807 
   808 lemmas continuous_on_scaleR [continuous_intros] =
   809   bounded_bilinear.continuous_on [OF bounded_bilinear_scaleR]
   810 
   811 lemmas continuous_on_mult [continuous_intros] =
   812   bounded_bilinear.continuous_on [OF bounded_bilinear_mult]
   813 
   814 lemmas tendsto_mult_zero =
   815   bounded_bilinear.tendsto_zero [OF bounded_bilinear_mult]
   816 
   817 lemmas tendsto_mult_left_zero =
   818   bounded_bilinear.tendsto_left_zero [OF bounded_bilinear_mult]
   819 
   820 lemmas tendsto_mult_right_zero =
   821   bounded_bilinear.tendsto_right_zero [OF bounded_bilinear_mult]
   822 
   823 lemma tendsto_power [tendsto_intros]: "(f \<longlongrightarrow> a) F \<Longrightarrow> ((\<lambda>x. f x ^ n) \<longlongrightarrow> a ^ n) F"
   824   for f :: "'a \<Rightarrow> 'b::{power,real_normed_algebra}"
   825   by (induct n) (simp_all add: tendsto_mult)
   826 
   827 lemma continuous_power [continuous_intros]: "continuous F f \<Longrightarrow> continuous F (\<lambda>x. (f x)^n)"
   828   for f :: "'a::t2_space \<Rightarrow> 'b::{power,real_normed_algebra}"
   829   unfolding continuous_def by (rule tendsto_power)
   830 
   831 lemma continuous_on_power [continuous_intros]:
   832   fixes f :: "_ \<Rightarrow> 'b::{power,real_normed_algebra}"
   833   shows "continuous_on s f \<Longrightarrow> continuous_on s (\<lambda>x. (f x)^n)"
   834   unfolding continuous_on_def by (auto intro: tendsto_power)
   835 
   836 lemma tendsto_prod [tendsto_intros]:
   837   fixes f :: "'a \<Rightarrow> 'b \<Rightarrow> 'c::{real_normed_algebra,comm_ring_1}"
   838   shows "(\<And>i. i \<in> S \<Longrightarrow> (f i \<longlongrightarrow> L i) F) \<Longrightarrow> ((\<lambda>x. \<Prod>i\<in>S. f i x) \<longlongrightarrow> (\<Prod>i\<in>S. L i)) F"
   839   by (induct S rule: infinite_finite_induct) (simp_all add: tendsto_mult)
   840 
   841 lemma continuous_prod [continuous_intros]:
   842   fixes f :: "'a \<Rightarrow> 'b::t2_space \<Rightarrow> 'c::{real_normed_algebra,comm_ring_1}"
   843   shows "(\<And>i. i \<in> S \<Longrightarrow> continuous F (f i)) \<Longrightarrow> continuous F (\<lambda>x. \<Prod>i\<in>S. f i x)"
   844   unfolding continuous_def by (rule tendsto_prod)
   845 
   846 lemma continuous_on_prod [continuous_intros]:
   847   fixes f :: "'a \<Rightarrow> _ \<Rightarrow> 'c::{real_normed_algebra,comm_ring_1}"
   848   shows "(\<And>i. i \<in> S \<Longrightarrow> continuous_on s (f i)) \<Longrightarrow> continuous_on s (\<lambda>x. \<Prod>i\<in>S. f i x)"
   849   unfolding continuous_on_def by (auto intro: tendsto_prod)
   850 
   851 lemma tendsto_of_real_iff:
   852   "((\<lambda>x. of_real (f x) :: 'a::real_normed_div_algebra) \<longlongrightarrow> of_real c) F \<longleftrightarrow> (f \<longlongrightarrow> c) F"
   853   unfolding tendsto_iff by simp
   854 
   855 lemma tendsto_add_const_iff:
   856   "((\<lambda>x. c + f x :: 'a::real_normed_vector) \<longlongrightarrow> c + d) F \<longleftrightarrow> (f \<longlongrightarrow> d) F"
   857   using tendsto_add[OF tendsto_const[of c], of f d]
   858     and tendsto_add[OF tendsto_const[of "-c"], of "\<lambda>x. c + f x" "c + d"] by auto
   859 
   860 
   861 subsubsection \<open>Inverse and division\<close>
   862 
   863 lemma (in bounded_bilinear) Zfun_prod_Bfun:
   864   assumes f: "Zfun f F"
   865     and g: "Bfun g F"
   866   shows "Zfun (\<lambda>x. f x ** g x) F"
   867 proof -
   868   obtain K where K: "0 \<le> K"
   869     and norm_le: "\<And>x y. norm (x ** y) \<le> norm x * norm y * K"
   870     using nonneg_bounded by blast
   871   obtain B where B: "0 < B"
   872     and norm_g: "eventually (\<lambda>x. norm (g x) \<le> B) F"
   873     using g by (rule BfunE)
   874   have "eventually (\<lambda>x. norm (f x ** g x) \<le> norm (f x) * (B * K)) F"
   875   using norm_g proof eventually_elim
   876     case (elim x)
   877     have "norm (f x ** g x) \<le> norm (f x) * norm (g x) * K"
   878       by (rule norm_le)
   879     also have "\<dots> \<le> norm (f x) * B * K"
   880       by (intro mult_mono' order_refl norm_g norm_ge_zero mult_nonneg_nonneg K elim)
   881     also have "\<dots> = norm (f x) * (B * K)"
   882       by (rule mult.assoc)
   883     finally show "norm (f x ** g x) \<le> norm (f x) * (B * K)" .
   884   qed
   885   with f show ?thesis
   886     by (rule Zfun_imp_Zfun)
   887 qed
   888 
   889 lemma (in bounded_bilinear) Bfun_prod_Zfun:
   890   assumes f: "Bfun f F"
   891     and g: "Zfun g F"
   892   shows "Zfun (\<lambda>x. f x ** g x) F"
   893   using flip g f by (rule bounded_bilinear.Zfun_prod_Bfun)
   894 
   895 lemma Bfun_inverse_lemma:
   896   fixes x :: "'a::real_normed_div_algebra"
   897   shows "r \<le> norm x \<Longrightarrow> 0 < r \<Longrightarrow> norm (inverse x) \<le> inverse r"
   898   apply (subst nonzero_norm_inverse)
   899   apply clarsimp
   900   apply (erule (1) le_imp_inverse_le)
   901   done
   902 
   903 lemma Bfun_inverse:
   904   fixes a :: "'a::real_normed_div_algebra"
   905   assumes f: "(f \<longlongrightarrow> a) F"
   906   assumes a: "a \<noteq> 0"
   907   shows "Bfun (\<lambda>x. inverse (f x)) F"
   908 proof -
   909   from a have "0 < norm a" by simp
   910   then have "\<exists>r>0. r < norm a" by (rule dense)
   911   then obtain r where r1: "0 < r" and r2: "r < norm a"
   912     by blast
   913   have "eventually (\<lambda>x. dist (f x) a < r) F"
   914     using tendstoD [OF f r1] by blast
   915   then have "eventually (\<lambda>x. norm (inverse (f x)) \<le> inverse (norm a - r)) F"
   916   proof eventually_elim
   917     case (elim x)
   918     then have 1: "norm (f x - a) < r"
   919       by (simp add: dist_norm)
   920     then have 2: "f x \<noteq> 0" using r2 by auto
   921     then have "norm (inverse (f x)) = inverse (norm (f x))"
   922       by (rule nonzero_norm_inverse)
   923     also have "\<dots> \<le> inverse (norm a - r)"
   924     proof (rule le_imp_inverse_le)
   925       show "0 < norm a - r"
   926         using r2 by simp
   927       have "norm a - norm (f x) \<le> norm (a - f x)"
   928         by (rule norm_triangle_ineq2)
   929       also have "\<dots> = norm (f x - a)"
   930         by (rule norm_minus_commute)
   931       also have "\<dots> < r" using 1 .
   932       finally show "norm a - r \<le> norm (f x)"
   933         by simp
   934     qed
   935     finally show "norm (inverse (f x)) \<le> inverse (norm a - r)" .
   936   qed
   937   then show ?thesis by (rule BfunI)
   938 qed
   939 
   940 lemma tendsto_inverse [tendsto_intros]:
   941   fixes a :: "'a::real_normed_div_algebra"
   942   assumes f: "(f \<longlongrightarrow> a) F"
   943     and a: "a \<noteq> 0"
   944   shows "((\<lambda>x. inverse (f x)) \<longlongrightarrow> inverse a) F"
   945 proof -
   946   from a have "0 < norm a" by simp
   947   with f have "eventually (\<lambda>x. dist (f x) a < norm a) F"
   948     by (rule tendstoD)
   949   then have "eventually (\<lambda>x. f x \<noteq> 0) F"
   950     unfolding dist_norm by (auto elim!: eventually_mono)
   951   with a have "eventually (\<lambda>x. inverse (f x) - inverse a =
   952     - (inverse (f x) * (f x - a) * inverse a)) F"
   953     by (auto elim!: eventually_mono simp: inverse_diff_inverse)
   954   moreover have "Zfun (\<lambda>x. - (inverse (f x) * (f x - a) * inverse a)) F"
   955     by (intro Zfun_minus Zfun_mult_left
   956       bounded_bilinear.Bfun_prod_Zfun [OF bounded_bilinear_mult]
   957       Bfun_inverse [OF f a] f [unfolded tendsto_Zfun_iff])
   958   ultimately show ?thesis
   959     unfolding tendsto_Zfun_iff by (rule Zfun_ssubst)
   960 qed
   961 
   962 lemma continuous_inverse:
   963   fixes f :: "'a::t2_space \<Rightarrow> 'b::real_normed_div_algebra"
   964   assumes "continuous F f"
   965     and "f (Lim F (\<lambda>x. x)) \<noteq> 0"
   966   shows "continuous F (\<lambda>x. inverse (f x))"
   967   using assms unfolding continuous_def by (rule tendsto_inverse)
   968 
   969 lemma continuous_at_within_inverse[continuous_intros]:
   970   fixes f :: "'a::t2_space \<Rightarrow> 'b::real_normed_div_algebra"
   971   assumes "continuous (at a within s) f"
   972     and "f a \<noteq> 0"
   973   shows "continuous (at a within s) (\<lambda>x. inverse (f x))"
   974   using assms unfolding continuous_within by (rule tendsto_inverse)
   975 
   976 lemma isCont_inverse[continuous_intros, simp]:
   977   fixes f :: "'a::t2_space \<Rightarrow> 'b::real_normed_div_algebra"
   978   assumes "isCont f a"
   979     and "f a \<noteq> 0"
   980   shows "isCont (\<lambda>x. inverse (f x)) a"
   981   using assms unfolding continuous_at by (rule tendsto_inverse)
   982 
   983 lemma continuous_on_inverse[continuous_intros]:
   984   fixes f :: "'a::topological_space \<Rightarrow> 'b::real_normed_div_algebra"
   985   assumes "continuous_on s f"
   986     and "\<forall>x\<in>s. f x \<noteq> 0"
   987   shows "continuous_on s (\<lambda>x. inverse (f x))"
   988   using assms unfolding continuous_on_def by (blast intro: tendsto_inverse)
   989 
   990 lemma tendsto_divide [tendsto_intros]:
   991   fixes a b :: "'a::real_normed_field"
   992   shows "(f \<longlongrightarrow> a) F \<Longrightarrow> (g \<longlongrightarrow> b) F \<Longrightarrow> b \<noteq> 0 \<Longrightarrow> ((\<lambda>x. f x / g x) \<longlongrightarrow> a / b) F"
   993   by (simp add: tendsto_mult tendsto_inverse divide_inverse)
   994 
   995 lemma continuous_divide:
   996   fixes f g :: "'a::t2_space \<Rightarrow> 'b::real_normed_field"
   997   assumes "continuous F f"
   998     and "continuous F g"
   999     and "g (Lim F (\<lambda>x. x)) \<noteq> 0"
  1000   shows "continuous F (\<lambda>x. (f x) / (g x))"
  1001   using assms unfolding continuous_def by (rule tendsto_divide)
  1002 
  1003 lemma continuous_at_within_divide[continuous_intros]:
  1004   fixes f g :: "'a::t2_space \<Rightarrow> 'b::real_normed_field"
  1005   assumes "continuous (at a within s) f" "continuous (at a within s) g"
  1006     and "g a \<noteq> 0"
  1007   shows "continuous (at a within s) (\<lambda>x. (f x) / (g x))"
  1008   using assms unfolding continuous_within by (rule tendsto_divide)
  1009 
  1010 lemma isCont_divide[continuous_intros, simp]:
  1011   fixes f g :: "'a::t2_space \<Rightarrow> 'b::real_normed_field"
  1012   assumes "isCont f a" "isCont g a" "g a \<noteq> 0"
  1013   shows "isCont (\<lambda>x. (f x) / g x) a"
  1014   using assms unfolding continuous_at by (rule tendsto_divide)
  1015 
  1016 lemma continuous_on_divide[continuous_intros]:
  1017   fixes f :: "'a::topological_space \<Rightarrow> 'b::real_normed_field"
  1018   assumes "continuous_on s f" "continuous_on s g"
  1019     and "\<forall>x\<in>s. g x \<noteq> 0"
  1020   shows "continuous_on s (\<lambda>x. (f x) / (g x))"
  1021   using assms unfolding continuous_on_def by (blast intro: tendsto_divide)
  1022 
  1023 lemma tendsto_sgn [tendsto_intros]: "(f \<longlongrightarrow> l) F \<Longrightarrow> l \<noteq> 0 \<Longrightarrow> ((\<lambda>x. sgn (f x)) \<longlongrightarrow> sgn l) F"
  1024   for l :: "'a::real_normed_vector"
  1025   unfolding sgn_div_norm by (simp add: tendsto_intros)
  1026 
  1027 lemma continuous_sgn:
  1028   fixes f :: "'a::t2_space \<Rightarrow> 'b::real_normed_vector"
  1029   assumes "continuous F f"
  1030     and "f (Lim F (\<lambda>x. x)) \<noteq> 0"
  1031   shows "continuous F (\<lambda>x. sgn (f x))"
  1032   using assms unfolding continuous_def by (rule tendsto_sgn)
  1033 
  1034 lemma continuous_at_within_sgn[continuous_intros]:
  1035   fixes f :: "'a::t2_space \<Rightarrow> 'b::real_normed_vector"
  1036   assumes "continuous (at a within s) f"
  1037     and "f a \<noteq> 0"
  1038   shows "continuous (at a within s) (\<lambda>x. sgn (f x))"
  1039   using assms unfolding continuous_within by (rule tendsto_sgn)
  1040 
  1041 lemma isCont_sgn[continuous_intros]:
  1042   fixes f :: "'a::t2_space \<Rightarrow> 'b::real_normed_vector"
  1043   assumes "isCont f a"
  1044     and "f a \<noteq> 0"
  1045   shows "isCont (\<lambda>x. sgn (f x)) a"
  1046   using assms unfolding continuous_at by (rule tendsto_sgn)
  1047 
  1048 lemma continuous_on_sgn[continuous_intros]:
  1049   fixes f :: "'a::topological_space \<Rightarrow> 'b::real_normed_vector"
  1050   assumes "continuous_on s f"
  1051     and "\<forall>x\<in>s. f x \<noteq> 0"
  1052   shows "continuous_on s (\<lambda>x. sgn (f x))"
  1053   using assms unfolding continuous_on_def by (blast intro: tendsto_sgn)
  1054 
  1055 lemma filterlim_at_infinity:
  1056   fixes f :: "_ \<Rightarrow> 'a::real_normed_vector"
  1057   assumes "0 \<le> c"
  1058   shows "(LIM x F. f x :> at_infinity) \<longleftrightarrow> (\<forall>r>c. eventually (\<lambda>x. r \<le> norm (f x)) F)"
  1059   unfolding filterlim_iff eventually_at_infinity
  1060 proof safe
  1061   fix P :: "'a \<Rightarrow> bool"
  1062   fix b
  1063   assume *: "\<forall>r>c. eventually (\<lambda>x. r \<le> norm (f x)) F"
  1064   assume P: "\<forall>x. b \<le> norm x \<longrightarrow> P x"
  1065   have "max b (c + 1) > c" by auto
  1066   with * have "eventually (\<lambda>x. max b (c + 1) \<le> norm (f x)) F"
  1067     by auto
  1068   then show "eventually (\<lambda>x. P (f x)) F"
  1069   proof eventually_elim
  1070     case (elim x)
  1071     with P show "P (f x)" by auto
  1072   qed
  1073 qed force
  1074 
  1075 lemma not_tendsto_and_filterlim_at_infinity:
  1076   fixes c :: "'a::real_normed_vector"
  1077   assumes "F \<noteq> bot"
  1078     and "(f \<longlongrightarrow> c) F"
  1079     and "filterlim f at_infinity F"
  1080   shows False
  1081 proof -
  1082   from tendstoD[OF assms(2), of "1/2"]
  1083   have "eventually (\<lambda>x. dist (f x) c < 1/2) F"
  1084     by simp
  1085   moreover
  1086   from filterlim_at_infinity[of "norm c" f F] assms(3)
  1087   have "eventually (\<lambda>x. norm (f x) \<ge> norm c + 1) F" by simp
  1088   ultimately have "eventually (\<lambda>x. False) F"
  1089   proof eventually_elim
  1090     fix x
  1091     assume A: "dist (f x) c < 1/2"
  1092     assume "norm (f x) \<ge> norm c + 1"
  1093     also have "norm (f x) = dist (f x) 0" by simp
  1094     also have "\<dots> \<le> dist (f x) c + dist c 0" by (rule dist_triangle)
  1095     finally show False using A by simp
  1096   qed
  1097   with assms show False by simp
  1098 qed
  1099 
  1100 lemma filterlim_at_infinity_imp_not_convergent:
  1101   assumes "filterlim f at_infinity sequentially"
  1102   shows "\<not> convergent f"
  1103   by (rule notI, rule not_tendsto_and_filterlim_at_infinity[OF _ _ assms])
  1104      (simp_all add: convergent_LIMSEQ_iff)
  1105 
  1106 lemma filterlim_at_infinity_imp_eventually_ne:
  1107   assumes "filterlim f at_infinity F"
  1108   shows "eventually (\<lambda>z. f z \<noteq> c) F"
  1109 proof -
  1110   have "norm c + 1 > 0"
  1111     by (intro add_nonneg_pos) simp_all
  1112   with filterlim_at_infinity[OF order.refl, of f F] assms
  1113   have "eventually (\<lambda>z. norm (f z) \<ge> norm c + 1) F"
  1114     by blast
  1115   then show ?thesis
  1116     by eventually_elim auto
  1117 qed
  1118 
  1119 lemma tendsto_of_nat [tendsto_intros]:
  1120   "filterlim (of_nat :: nat \<Rightarrow> 'a::real_normed_algebra_1) at_infinity sequentially"
  1121 proof (subst filterlim_at_infinity[OF order.refl], intro allI impI)
  1122   fix r :: real
  1123   assume r: "r > 0"
  1124   define n where "n = nat \<lceil>r\<rceil>"
  1125   from r have n: "\<forall>m\<ge>n. of_nat m \<ge> r"
  1126     unfolding n_def by linarith
  1127   from eventually_ge_at_top[of n] show "eventually (\<lambda>m. norm (of_nat m :: 'a) \<ge> r) sequentially"
  1128     by eventually_elim (use n in simp_all)
  1129 qed
  1130 
  1131 
  1132 subsection \<open>Relate @{const at}, @{const at_left} and @{const at_right}\<close>
  1133 
  1134 text \<open>
  1135   This lemmas are useful for conversion between @{term "at x"} to @{term "at_left x"} and
  1136   @{term "at_right x"} and also @{term "at_right 0"}.
  1137 \<close>
  1138 
  1139 lemmas filterlim_split_at_real = filterlim_split_at[where 'a=real]
  1140 
  1141 lemma filtermap_nhds_shift: "filtermap (\<lambda>x. x - d) (nhds a) = nhds (a - d)"
  1142   for a d :: "'a::real_normed_vector"
  1143   by (rule filtermap_fun_inverse[where g="\<lambda>x. x + d"])
  1144     (auto intro!: tendsto_eq_intros filterlim_ident)
  1145 
  1146 lemma filtermap_nhds_minus: "filtermap (\<lambda>x. - x) (nhds a) = nhds (- a)"
  1147   for a :: "'a::real_normed_vector"
  1148   by (rule filtermap_fun_inverse[where g=uminus])
  1149     (auto intro!: tendsto_eq_intros filterlim_ident)
  1150 
  1151 lemma filtermap_at_shift: "filtermap (\<lambda>x. x - d) (at a) = at (a - d)"
  1152   for a d :: "'a::real_normed_vector"
  1153   by (simp add: filter_eq_iff eventually_filtermap eventually_at_filter filtermap_nhds_shift[symmetric])
  1154 
  1155 lemma filtermap_at_right_shift: "filtermap (\<lambda>x. x - d) (at_right a) = at_right (a - d)"
  1156   for a d :: "real"
  1157   by (simp add: filter_eq_iff eventually_filtermap eventually_at_filter filtermap_nhds_shift[symmetric])
  1158 
  1159 lemma at_right_to_0: "at_right a = filtermap (\<lambda>x. x + a) (at_right 0)"
  1160   for a :: real
  1161   using filtermap_at_right_shift[of "-a" 0] by simp
  1162 
  1163 lemma filterlim_at_right_to_0:
  1164   "filterlim f F (at_right a) \<longleftrightarrow> filterlim (\<lambda>x. f (x + a)) F (at_right 0)"
  1165   for a :: real
  1166   unfolding filterlim_def filtermap_filtermap at_right_to_0[of a] ..
  1167 
  1168 lemma eventually_at_right_to_0:
  1169   "eventually P (at_right a) \<longleftrightarrow> eventually (\<lambda>x. P (x + a)) (at_right 0)"
  1170   for a :: real
  1171   unfolding at_right_to_0[of a] by (simp add: eventually_filtermap)
  1172 
  1173 lemma filtermap_at_minus: "filtermap (\<lambda>x. - x) (at a) = at (- a)"
  1174   for a :: "'a::real_normed_vector"
  1175   by (simp add: filter_eq_iff eventually_filtermap eventually_at_filter filtermap_nhds_minus[symmetric])
  1176 
  1177 lemma at_left_minus: "at_left a = filtermap (\<lambda>x. - x) (at_right (- a))"
  1178   for a :: real
  1179   by (simp add: filter_eq_iff eventually_filtermap eventually_at_filter filtermap_nhds_minus[symmetric])
  1180 
  1181 lemma at_right_minus: "at_right a = filtermap (\<lambda>x. - x) (at_left (- a))"
  1182   for a :: real
  1183   by (simp add: filter_eq_iff eventually_filtermap eventually_at_filter filtermap_nhds_minus[symmetric])
  1184 
  1185 lemma filterlim_at_left_to_right:
  1186   "filterlim f F (at_left a) \<longleftrightarrow> filterlim (\<lambda>x. f (- x)) F (at_right (-a))"
  1187   for a :: real
  1188   unfolding filterlim_def filtermap_filtermap at_left_minus[of a] ..
  1189 
  1190 lemma eventually_at_left_to_right:
  1191   "eventually P (at_left a) \<longleftrightarrow> eventually (\<lambda>x. P (- x)) (at_right (-a))"
  1192   for a :: real
  1193   unfolding at_left_minus[of a] by (simp add: eventually_filtermap)
  1194 
  1195 lemma filterlim_uminus_at_top_at_bot: "LIM x at_bot. - x :: real :> at_top"
  1196   unfolding filterlim_at_top eventually_at_bot_dense
  1197   by (metis leI minus_less_iff order_less_asym)
  1198 
  1199 lemma filterlim_uminus_at_bot_at_top: "LIM x at_top. - x :: real :> at_bot"
  1200   unfolding filterlim_at_bot eventually_at_top_dense
  1201   by (metis leI less_minus_iff order_less_asym)
  1202 
  1203 lemma at_top_mirror: "at_top = filtermap uminus (at_bot :: real filter)"
  1204   by (rule filtermap_fun_inverse[symmetric, of uminus])
  1205      (auto intro: filterlim_uminus_at_bot_at_top filterlim_uminus_at_top_at_bot)
  1206 
  1207 lemma at_bot_mirror: "at_bot = filtermap uminus (at_top :: real filter)"
  1208   unfolding at_top_mirror filtermap_filtermap by (simp add: filtermap_ident)
  1209 
  1210 lemma filterlim_at_top_mirror: "(LIM x at_top. f x :> F) \<longleftrightarrow> (LIM x at_bot. f (-x::real) :> F)"
  1211   unfolding filterlim_def at_top_mirror filtermap_filtermap ..
  1212 
  1213 lemma filterlim_at_bot_mirror: "(LIM x at_bot. f x :> F) \<longleftrightarrow> (LIM x at_top. f (-x::real) :> F)"
  1214   unfolding filterlim_def at_bot_mirror filtermap_filtermap ..
  1215 
  1216 lemma filterlim_uminus_at_top: "(LIM x F. f x :> at_top) \<longleftrightarrow> (LIM x F. - (f x) :: real :> at_bot)"
  1217   using filterlim_compose[OF filterlim_uminus_at_bot_at_top, of f F]
  1218     and filterlim_compose[OF filterlim_uminus_at_top_at_bot, of "\<lambda>x. - f x" F]
  1219   by auto
  1220 
  1221 lemma filterlim_uminus_at_bot: "(LIM x F. f x :> at_bot) \<longleftrightarrow> (LIM x F. - (f x) :: real :> at_top)"
  1222   unfolding filterlim_uminus_at_top by simp
  1223 
  1224 lemma filterlim_inverse_at_top_right: "LIM x at_right (0::real). inverse x :> at_top"
  1225   unfolding filterlim_at_top_gt[where c=0] eventually_at_filter
  1226 proof safe
  1227   fix Z :: real
  1228   assume [arith]: "0 < Z"
  1229   then have "eventually (\<lambda>x. x < inverse Z) (nhds 0)"
  1230     by (auto simp add: eventually_nhds_metric dist_real_def intro!: exI[of _ "\<bar>inverse Z\<bar>"])
  1231   then show "eventually (\<lambda>x. x \<noteq> 0 \<longrightarrow> x \<in> {0<..} \<longrightarrow> Z \<le> inverse x) (nhds 0)"
  1232     by (auto elim!: eventually_mono simp: inverse_eq_divide field_simps)
  1233 qed
  1234 
  1235 lemma tendsto_inverse_0:
  1236   fixes x :: "_ \<Rightarrow> 'a::real_normed_div_algebra"
  1237   shows "(inverse \<longlongrightarrow> (0::'a)) at_infinity"
  1238   unfolding tendsto_Zfun_iff diff_0_right Zfun_def eventually_at_infinity
  1239 proof safe
  1240   fix r :: real
  1241   assume "0 < r"
  1242   show "\<exists>b. \<forall>x. b \<le> norm x \<longrightarrow> norm (inverse x :: 'a) < r"
  1243   proof (intro exI[of _ "inverse (r / 2)"] allI impI)
  1244     fix x :: 'a
  1245     from \<open>0 < r\<close> have "0 < inverse (r / 2)" by simp
  1246     also assume *: "inverse (r / 2) \<le> norm x"
  1247     finally show "norm (inverse x) < r"
  1248       using * \<open>0 < r\<close>
  1249       by (subst nonzero_norm_inverse) (simp_all add: inverse_eq_divide field_simps)
  1250   qed
  1251 qed
  1252 
  1253 lemma tendsto_add_filterlim_at_infinity:
  1254   fixes c :: "'b::real_normed_vector"
  1255     and F :: "'a filter"
  1256   assumes "(f \<longlongrightarrow> c) F"
  1257     and "filterlim g at_infinity F"
  1258   shows "filterlim (\<lambda>x. f x + g x) at_infinity F"
  1259 proof (subst filterlim_at_infinity[OF order_refl], safe)
  1260   fix r :: real
  1261   assume r: "r > 0"
  1262   from assms(1) have "((\<lambda>x. norm (f x)) \<longlongrightarrow> norm c) F"
  1263     by (rule tendsto_norm)
  1264   then have "eventually (\<lambda>x. norm (f x) < norm c + 1) F"
  1265     by (rule order_tendstoD) simp_all
  1266   moreover from r have "r + norm c + 1 > 0"
  1267     by (intro add_pos_nonneg) simp_all
  1268   with assms(2) have "eventually (\<lambda>x. norm (g x) \<ge> r + norm c + 1) F"
  1269     unfolding filterlim_at_infinity[OF order_refl]
  1270     by (elim allE[of _ "r + norm c + 1"]) simp_all
  1271   ultimately show "eventually (\<lambda>x. norm (f x + g x) \<ge> r) F"
  1272   proof eventually_elim
  1273     fix x :: 'a
  1274     assume A: "norm (f x) < norm c + 1" and B: "r + norm c + 1 \<le> norm (g x)"
  1275     from A B have "r \<le> norm (g x) - norm (f x)"
  1276       by simp
  1277     also have "norm (g x) - norm (f x) \<le> norm (g x + f x)"
  1278       by (rule norm_diff_ineq)
  1279     finally show "r \<le> norm (f x + g x)"
  1280       by (simp add: add_ac)
  1281   qed
  1282 qed
  1283 
  1284 lemma tendsto_add_filterlim_at_infinity':
  1285   fixes c :: "'b::real_normed_vector"
  1286     and F :: "'a filter"
  1287   assumes "filterlim f at_infinity F"
  1288     and "(g \<longlongrightarrow> c) F"
  1289   shows "filterlim (\<lambda>x. f x + g x) at_infinity F"
  1290   by (subst add.commute) (rule tendsto_add_filterlim_at_infinity assms)+
  1291 
  1292 lemma filterlim_inverse_at_right_top: "LIM x at_top. inverse x :> at_right (0::real)"
  1293   unfolding filterlim_at
  1294   by (auto simp: eventually_at_top_dense)
  1295      (metis tendsto_inverse_0 filterlim_mono at_top_le_at_infinity order_refl)
  1296 
  1297 lemma filterlim_inverse_at_top:
  1298   "(f \<longlongrightarrow> (0 :: real)) F \<Longrightarrow> eventually (\<lambda>x. 0 < f x) F \<Longrightarrow> LIM x F. inverse (f x) :> at_top"
  1299   by (intro filterlim_compose[OF filterlim_inverse_at_top_right])
  1300      (simp add: filterlim_def eventually_filtermap eventually_mono at_within_def le_principal)
  1301 
  1302 lemma filterlim_inverse_at_bot_neg:
  1303   "LIM x (at_left (0::real)). inverse x :> at_bot"
  1304   by (simp add: filterlim_inverse_at_top_right filterlim_uminus_at_bot filterlim_at_left_to_right)
  1305 
  1306 lemma filterlim_inverse_at_bot:
  1307   "(f \<longlongrightarrow> (0 :: real)) F \<Longrightarrow> eventually (\<lambda>x. f x < 0) F \<Longrightarrow> LIM x F. inverse (f x) :> at_bot"
  1308   unfolding filterlim_uminus_at_bot inverse_minus_eq[symmetric]
  1309   by (rule filterlim_inverse_at_top) (simp_all add: tendsto_minus_cancel_left[symmetric])
  1310 
  1311 lemma at_right_to_top: "(at_right (0::real)) = filtermap inverse at_top"
  1312   by (intro filtermap_fun_inverse[symmetric, where g=inverse])
  1313      (auto intro: filterlim_inverse_at_top_right filterlim_inverse_at_right_top)
  1314 
  1315 lemma eventually_at_right_to_top:
  1316   "eventually P (at_right (0::real)) \<longleftrightarrow> eventually (\<lambda>x. P (inverse x)) at_top"
  1317   unfolding at_right_to_top eventually_filtermap ..
  1318 
  1319 lemma filterlim_at_right_to_top:
  1320   "filterlim f F (at_right (0::real)) \<longleftrightarrow> (LIM x at_top. f (inverse x) :> F)"
  1321   unfolding filterlim_def at_right_to_top filtermap_filtermap ..
  1322 
  1323 lemma at_top_to_right: "at_top = filtermap inverse (at_right (0::real))"
  1324   unfolding at_right_to_top filtermap_filtermap inverse_inverse_eq filtermap_ident ..
  1325 
  1326 lemma eventually_at_top_to_right:
  1327   "eventually P at_top \<longleftrightarrow> eventually (\<lambda>x. P (inverse x)) (at_right (0::real))"
  1328   unfolding at_top_to_right eventually_filtermap ..
  1329 
  1330 lemma filterlim_at_top_to_right:
  1331   "filterlim f F at_top \<longleftrightarrow> (LIM x (at_right (0::real)). f (inverse x) :> F)"
  1332   unfolding filterlim_def at_top_to_right filtermap_filtermap ..
  1333 
  1334 lemma filterlim_inverse_at_infinity:
  1335   fixes x :: "_ \<Rightarrow> 'a::{real_normed_div_algebra, division_ring}"
  1336   shows "filterlim inverse at_infinity (at (0::'a))"
  1337   unfolding filterlim_at_infinity[OF order_refl]
  1338 proof safe
  1339   fix r :: real
  1340   assume "0 < r"
  1341   then show "eventually (\<lambda>x::'a. r \<le> norm (inverse x)) (at 0)"
  1342     unfolding eventually_at norm_inverse
  1343     by (intro exI[of _ "inverse r"])
  1344        (auto simp: norm_conv_dist[symmetric] field_simps inverse_eq_divide)
  1345 qed
  1346 
  1347 lemma filterlim_inverse_at_iff:
  1348   fixes g :: "'a \<Rightarrow> 'b::{real_normed_div_algebra, division_ring}"
  1349   shows "(LIM x F. inverse (g x) :> at 0) \<longleftrightarrow> (LIM x F. g x :> at_infinity)"
  1350   unfolding filterlim_def filtermap_filtermap[symmetric]
  1351 proof
  1352   assume "filtermap g F \<le> at_infinity"
  1353   then have "filtermap inverse (filtermap g F) \<le> filtermap inverse at_infinity"
  1354     by (rule filtermap_mono)
  1355   also have "\<dots> \<le> at 0"
  1356     using tendsto_inverse_0[where 'a='b]
  1357     by (auto intro!: exI[of _ 1]
  1358         simp: le_principal eventually_filtermap filterlim_def at_within_def eventually_at_infinity)
  1359   finally show "filtermap inverse (filtermap g F) \<le> at 0" .
  1360 next
  1361   assume "filtermap inverse (filtermap g F) \<le> at 0"
  1362   then have "filtermap inverse (filtermap inverse (filtermap g F)) \<le> filtermap inverse (at 0)"
  1363     by (rule filtermap_mono)
  1364   with filterlim_inverse_at_infinity show "filtermap g F \<le> at_infinity"
  1365     by (auto intro: order_trans simp: filterlim_def filtermap_filtermap)
  1366 qed
  1367 
  1368 lemma tendsto_mult_filterlim_at_infinity:
  1369   fixes c :: "'a::real_normed_field"
  1370   assumes  "(f \<longlongrightarrow> c) F" "c \<noteq> 0"
  1371   assumes "filterlim g at_infinity F"
  1372   shows "filterlim (\<lambda>x. f x * g x) at_infinity F"
  1373 proof -
  1374   have "((\<lambda>x. inverse (f x) * inverse (g x)) \<longlongrightarrow> inverse c * 0) F"
  1375     by (intro tendsto_mult tendsto_inverse assms filterlim_compose[OF tendsto_inverse_0])
  1376   then have "filterlim (\<lambda>x. inverse (f x) * inverse (g x)) (at (inverse c * 0)) F"
  1377     unfolding filterlim_at
  1378     using assms
  1379     by (auto intro: filterlim_at_infinity_imp_eventually_ne tendsto_imp_eventually_ne eventually_conj)
  1380   then show ?thesis
  1381     by (subst filterlim_inverse_at_iff[symmetric]) simp_all
  1382 qed  
  1383 
  1384 lemma tendsto_inverse_0_at_top: "LIM x F. f x :> at_top \<Longrightarrow> ((\<lambda>x. inverse (f x) :: real) \<longlongrightarrow> 0) F"
  1385  by (metis filterlim_at filterlim_mono[OF _ at_top_le_at_infinity order_refl] filterlim_inverse_at_iff)
  1386 
  1387 lemma real_tendsto_divide_at_top:
  1388   fixes c::"real"
  1389   assumes "(f \<longlongrightarrow> c) F"
  1390   assumes "filterlim g at_top F"
  1391   shows "((\<lambda>x. f x / g x) \<longlongrightarrow> 0) F"
  1392   by (auto simp: divide_inverse_commute
  1393       intro!: tendsto_mult[THEN tendsto_eq_rhs] tendsto_inverse_0_at_top assms)
  1394 
  1395 lemma mult_nat_left_at_top: "c > 0 \<Longrightarrow> filterlim (\<lambda>x. c * x) at_top sequentially"
  1396   for c :: nat
  1397   by (rule filterlim_subseq) (auto simp: subseq_def)
  1398 
  1399 lemma mult_nat_right_at_top: "c > 0 \<Longrightarrow> filterlim (\<lambda>x. x * c) at_top sequentially"
  1400   for c :: nat
  1401   by (rule filterlim_subseq) (auto simp: subseq_def)
  1402 
  1403 lemma at_to_infinity: "(at (0::'a::{real_normed_field,field})) = filtermap inverse at_infinity"
  1404 proof (rule antisym)
  1405   have "(inverse \<longlongrightarrow> (0::'a)) at_infinity"
  1406     by (fact tendsto_inverse_0)
  1407   then show "filtermap inverse at_infinity \<le> at (0::'a)"
  1408     apply (simp add: le_principal eventually_filtermap eventually_at_infinity filterlim_def at_within_def)
  1409     apply (rule_tac x="1" in exI)
  1410     apply auto
  1411     done
  1412 next
  1413   have "filtermap inverse (filtermap inverse (at (0::'a))) \<le> filtermap inverse at_infinity"
  1414     using filterlim_inverse_at_infinity unfolding filterlim_def
  1415     by (rule filtermap_mono)
  1416   then show "at (0::'a) \<le> filtermap inverse at_infinity"
  1417     by (simp add: filtermap_ident filtermap_filtermap)
  1418 qed
  1419 
  1420 lemma lim_at_infinity_0:
  1421   fixes l :: "'a::{real_normed_field,field}"
  1422   shows "(f \<longlongrightarrow> l) at_infinity \<longleftrightarrow> ((f \<circ> inverse) \<longlongrightarrow> l) (at (0::'a))"
  1423   by (simp add: tendsto_compose_filtermap at_to_infinity filtermap_filtermap)
  1424 
  1425 lemma lim_zero_infinity:
  1426   fixes l :: "'a::{real_normed_field,field}"
  1427   shows "((\<lambda>x. f(1 / x)) \<longlongrightarrow> l) (at (0::'a)) \<Longrightarrow> (f \<longlongrightarrow> l) at_infinity"
  1428   by (simp add: inverse_eq_divide lim_at_infinity_0 comp_def)
  1429 
  1430 
  1431 text \<open>
  1432   We only show rules for multiplication and addition when the functions are either against a real
  1433   value or against infinity. Further rules are easy to derive by using @{thm
  1434   filterlim_uminus_at_top}.
  1435 \<close>
  1436 
  1437 lemma filterlim_tendsto_pos_mult_at_top:
  1438   assumes f: "(f \<longlongrightarrow> c) F"
  1439     and c: "0 < c"
  1440     and g: "LIM x F. g x :> at_top"
  1441   shows "LIM x F. (f x * g x :: real) :> at_top"
  1442   unfolding filterlim_at_top_gt[where c=0]
  1443 proof safe
  1444   fix Z :: real
  1445   assume "0 < Z"
  1446   from f \<open>0 < c\<close> have "eventually (\<lambda>x. c / 2 < f x) F"
  1447     by (auto dest!: tendstoD[where e="c / 2"] elim!: eventually_mono
  1448         simp: dist_real_def abs_real_def split: if_split_asm)
  1449   moreover from g have "eventually (\<lambda>x. (Z / c * 2) \<le> g x) F"
  1450     unfolding filterlim_at_top by auto
  1451   ultimately show "eventually (\<lambda>x. Z \<le> f x * g x) F"
  1452   proof eventually_elim
  1453     case (elim x)
  1454     with \<open>0 < Z\<close> \<open>0 < c\<close> have "c / 2 * (Z / c * 2) \<le> f x * g x"
  1455       by (intro mult_mono) (auto simp: zero_le_divide_iff)
  1456     with \<open>0 < c\<close> show "Z \<le> f x * g x"
  1457        by simp
  1458   qed
  1459 qed
  1460 
  1461 lemma filterlim_at_top_mult_at_top:
  1462   assumes f: "LIM x F. f x :> at_top"
  1463     and g: "LIM x F. g x :> at_top"
  1464   shows "LIM x F. (f x * g x :: real) :> at_top"
  1465   unfolding filterlim_at_top_gt[where c=0]
  1466 proof safe
  1467   fix Z :: real
  1468   assume "0 < Z"
  1469   from f have "eventually (\<lambda>x. 1 \<le> f x) F"
  1470     unfolding filterlim_at_top by auto
  1471   moreover from g have "eventually (\<lambda>x. Z \<le> g x) F"
  1472     unfolding filterlim_at_top by auto
  1473   ultimately show "eventually (\<lambda>x. Z \<le> f x * g x) F"
  1474   proof eventually_elim
  1475     case (elim x)
  1476     with \<open>0 < Z\<close> have "1 * Z \<le> f x * g x"
  1477       by (intro mult_mono) (auto simp: zero_le_divide_iff)
  1478     then show "Z \<le> f x * g x"
  1479        by simp
  1480   qed
  1481 qed
  1482 
  1483 lemma filterlim_at_top_mult_tendsto_pos:
  1484   assumes f: "(f \<longlongrightarrow> c) F"
  1485     and c: "0 < c"
  1486     and g: "LIM x F. g x :> at_top"
  1487   shows "LIM x F. (g x * f x:: real) :> at_top"
  1488   by (auto simp: mult.commute intro!: filterlim_tendsto_pos_mult_at_top f c g)
  1489 
  1490 lemma filterlim_tendsto_pos_mult_at_bot:
  1491   fixes c :: real
  1492   assumes "(f \<longlongrightarrow> c) F" "0 < c" "filterlim g at_bot F"
  1493   shows "LIM x F. f x * g x :> at_bot"
  1494   using filterlim_tendsto_pos_mult_at_top[OF assms(1,2), of "\<lambda>x. - g x"] assms(3)
  1495   unfolding filterlim_uminus_at_bot by simp
  1496 
  1497 lemma filterlim_tendsto_neg_mult_at_bot:
  1498   fixes c :: real
  1499   assumes c: "(f \<longlongrightarrow> c) F" "c < 0" and g: "filterlim g at_top F"
  1500   shows "LIM x F. f x * g x :> at_bot"
  1501   using c filterlim_tendsto_pos_mult_at_top[of "\<lambda>x. - f x" "- c" F, OF _ _ g]
  1502   unfolding filterlim_uminus_at_bot tendsto_minus_cancel_left by simp
  1503 
  1504 lemma filterlim_pow_at_top:
  1505   fixes f :: "'a \<Rightarrow> real"
  1506   assumes "0 < n"
  1507     and f: "LIM x F. f x :> at_top"
  1508   shows "LIM x F. (f x)^n :: real :> at_top"
  1509   using \<open>0 < n\<close>
  1510 proof (induct n)
  1511   case 0
  1512   then show ?case by simp
  1513 next
  1514   case (Suc n) with f show ?case
  1515     by (cases "n = 0") (auto intro!: filterlim_at_top_mult_at_top)
  1516 qed
  1517 
  1518 lemma filterlim_pow_at_bot_even:
  1519   fixes f :: "real \<Rightarrow> real"
  1520   shows "0 < n \<Longrightarrow> LIM x F. f x :> at_bot \<Longrightarrow> even n \<Longrightarrow> LIM x F. (f x)^n :> at_top"
  1521   using filterlim_pow_at_top[of n "\<lambda>x. - f x" F] by (simp add: filterlim_uminus_at_top)
  1522 
  1523 lemma filterlim_pow_at_bot_odd:
  1524   fixes f :: "real \<Rightarrow> real"
  1525   shows "0 < n \<Longrightarrow> LIM x F. f x :> at_bot \<Longrightarrow> odd n \<Longrightarrow> LIM x F. (f x)^n :> at_bot"
  1526   using filterlim_pow_at_top[of n "\<lambda>x. - f x" F] by (simp add: filterlim_uminus_at_bot)
  1527 
  1528 lemma filterlim_tendsto_add_at_top:
  1529   assumes f: "(f \<longlongrightarrow> c) F"
  1530     and g: "LIM x F. g x :> at_top"
  1531   shows "LIM x F. (f x + g x :: real) :> at_top"
  1532   unfolding filterlim_at_top_gt[where c=0]
  1533 proof safe
  1534   fix Z :: real
  1535   assume "0 < Z"
  1536   from f have "eventually (\<lambda>x. c - 1 < f x) F"
  1537     by (auto dest!: tendstoD[where e=1] elim!: eventually_mono simp: dist_real_def)
  1538   moreover from g have "eventually (\<lambda>x. Z - (c - 1) \<le> g x) F"
  1539     unfolding filterlim_at_top by auto
  1540   ultimately show "eventually (\<lambda>x. Z \<le> f x + g x) F"
  1541     by eventually_elim simp
  1542 qed
  1543 
  1544 lemma LIM_at_top_divide:
  1545   fixes f g :: "'a \<Rightarrow> real"
  1546   assumes f: "(f \<longlongrightarrow> a) F" "0 < a"
  1547     and g: "(g \<longlongrightarrow> 0) F" "eventually (\<lambda>x. 0 < g x) F"
  1548   shows "LIM x F. f x / g x :> at_top"
  1549   unfolding divide_inverse
  1550   by (rule filterlim_tendsto_pos_mult_at_top[OF f]) (rule filterlim_inverse_at_top[OF g])
  1551 
  1552 lemma filterlim_at_top_add_at_top:
  1553   assumes f: "LIM x F. f x :> at_top"
  1554     and g: "LIM x F. g x :> at_top"
  1555   shows "LIM x F. (f x + g x :: real) :> at_top"
  1556   unfolding filterlim_at_top_gt[where c=0]
  1557 proof safe
  1558   fix Z :: real
  1559   assume "0 < Z"
  1560   from f have "eventually (\<lambda>x. 0 \<le> f x) F"
  1561     unfolding filterlim_at_top by auto
  1562   moreover from g have "eventually (\<lambda>x. Z \<le> g x) F"
  1563     unfolding filterlim_at_top by auto
  1564   ultimately show "eventually (\<lambda>x. Z \<le> f x + g x) F"
  1565     by eventually_elim simp
  1566 qed
  1567 
  1568 lemma tendsto_divide_0:
  1569   fixes f :: "_ \<Rightarrow> 'a::{real_normed_div_algebra, division_ring}"
  1570   assumes f: "(f \<longlongrightarrow> c) F"
  1571     and g: "LIM x F. g x :> at_infinity"
  1572   shows "((\<lambda>x. f x / g x) \<longlongrightarrow> 0) F"
  1573   using tendsto_mult[OF f filterlim_compose[OF tendsto_inverse_0 g]]
  1574   by (simp add: divide_inverse)
  1575 
  1576 lemma linear_plus_1_le_power:
  1577   fixes x :: real
  1578   assumes x: "0 \<le> x"
  1579   shows "real n * x + 1 \<le> (x + 1) ^ n"
  1580 proof (induct n)
  1581   case 0
  1582   then show ?case by simp
  1583 next
  1584   case (Suc n)
  1585   from x have "real (Suc n) * x + 1 \<le> (x + 1) * (real n * x + 1)"
  1586     by (simp add: field_simps)
  1587   also have "\<dots> \<le> (x + 1)^Suc n"
  1588     using Suc x by (simp add: mult_left_mono)
  1589   finally show ?case .
  1590 qed
  1591 
  1592 lemma filterlim_realpow_sequentially_gt1:
  1593   fixes x :: "'a :: real_normed_div_algebra"
  1594   assumes x[arith]: "1 < norm x"
  1595   shows "LIM n sequentially. x ^ n :> at_infinity"
  1596 proof (intro filterlim_at_infinity[THEN iffD2] allI impI)
  1597   fix y :: real
  1598   assume "0 < y"
  1599   have "0 < norm x - 1" by simp
  1600   then obtain N :: nat where "y < real N * (norm x - 1)"
  1601     by (blast dest: reals_Archimedean3)
  1602   also have "\<dots> \<le> real N * (norm x - 1) + 1"
  1603     by simp
  1604   also have "\<dots> \<le> (norm x - 1 + 1) ^ N"
  1605     by (rule linear_plus_1_le_power) simp
  1606   also have "\<dots> = norm x ^ N"
  1607     by simp
  1608   finally have "\<forall>n\<ge>N. y \<le> norm x ^ n"
  1609     by (metis order_less_le_trans power_increasing order_less_imp_le x)
  1610   then show "eventually (\<lambda>n. y \<le> norm (x ^ n)) sequentially"
  1611     unfolding eventually_sequentially
  1612     by (auto simp: norm_power)
  1613 qed simp
  1614 
  1615 
  1616 subsection \<open>Floor and Ceiling\<close>
  1617 
  1618 lemma eventually_floor_less:
  1619   fixes f :: "'a \<Rightarrow> 'b::{order_topology,floor_ceiling}"
  1620   assumes f: "(f \<longlongrightarrow> l) F"
  1621     and l: "l \<notin> \<int>"
  1622   shows "\<forall>\<^sub>F x in F. of_int (floor l) < f x"
  1623   by (intro order_tendstoD[OF f]) (metis Ints_of_int antisym_conv2 floor_correct l)
  1624 
  1625 lemma eventually_less_ceiling:
  1626   fixes f :: "'a \<Rightarrow> 'b::{order_topology,floor_ceiling}"
  1627   assumes f: "(f \<longlongrightarrow> l) F"
  1628     and l: "l \<notin> \<int>"
  1629   shows "\<forall>\<^sub>F x in F. f x < of_int (ceiling l)"
  1630   by (intro order_tendstoD[OF f]) (metis Ints_of_int l le_of_int_ceiling less_le)
  1631 
  1632 lemma eventually_floor_eq:
  1633   fixes f::"'a \<Rightarrow> 'b::{order_topology,floor_ceiling}"
  1634   assumes f: "(f \<longlongrightarrow> l) F"
  1635     and l: "l \<notin> \<int>"
  1636   shows "\<forall>\<^sub>F x in F. floor (f x) = floor l"
  1637   using eventually_floor_less[OF assms] eventually_less_ceiling[OF assms]
  1638   by eventually_elim (meson floor_less_iff less_ceiling_iff not_less_iff_gr_or_eq)
  1639 
  1640 lemma eventually_ceiling_eq:
  1641   fixes f::"'a \<Rightarrow> 'b::{order_topology,floor_ceiling}"
  1642   assumes f: "(f \<longlongrightarrow> l) F"
  1643     and l: "l \<notin> \<int>"
  1644   shows "\<forall>\<^sub>F x in F. ceiling (f x) = ceiling l"
  1645   using eventually_floor_less[OF assms] eventually_less_ceiling[OF assms]
  1646   by eventually_elim (meson floor_less_iff less_ceiling_iff not_less_iff_gr_or_eq)
  1647 
  1648 lemma tendsto_of_int_floor:
  1649   fixes f::"'a \<Rightarrow> 'b::{order_topology,floor_ceiling}"
  1650   assumes "(f \<longlongrightarrow> l) F"
  1651     and "l \<notin> \<int>"
  1652   shows "((\<lambda>x. of_int (floor (f x)) :: 'c::{ring_1,topological_space}) \<longlongrightarrow> of_int (floor l)) F"
  1653   using eventually_floor_eq[OF assms]
  1654   by (simp add: eventually_mono topological_tendstoI)
  1655 
  1656 lemma tendsto_of_int_ceiling:
  1657   fixes f::"'a \<Rightarrow> 'b::{order_topology,floor_ceiling}"
  1658   assumes "(f \<longlongrightarrow> l) F"
  1659     and "l \<notin> \<int>"
  1660   shows "((\<lambda>x. of_int (ceiling (f x)):: 'c::{ring_1,topological_space}) \<longlongrightarrow> of_int (ceiling l)) F"
  1661   using eventually_ceiling_eq[OF assms]
  1662   by (simp add: eventually_mono topological_tendstoI)
  1663 
  1664 lemma continuous_on_of_int_floor:
  1665   "continuous_on (UNIV - \<int>::'a::{order_topology, floor_ceiling} set)
  1666     (\<lambda>x. of_int (floor x)::'b::{ring_1, topological_space})"
  1667   unfolding continuous_on_def
  1668   by (auto intro!: tendsto_of_int_floor)
  1669 
  1670 lemma continuous_on_of_int_ceiling:
  1671   "continuous_on (UNIV - \<int>::'a::{order_topology, floor_ceiling} set)
  1672     (\<lambda>x. of_int (ceiling x)::'b::{ring_1, topological_space})"
  1673   unfolding continuous_on_def
  1674   by (auto intro!: tendsto_of_int_ceiling)
  1675 
  1676 
  1677 subsection \<open>Limits of Sequences\<close>
  1678 
  1679 lemma [trans]: "X = Y \<Longrightarrow> Y \<longlonglongrightarrow> z \<Longrightarrow> X \<longlonglongrightarrow> z"
  1680   by simp
  1681 
  1682 lemma LIMSEQ_iff:
  1683   fixes L :: "'a::real_normed_vector"
  1684   shows "(X \<longlonglongrightarrow> L) = (\<forall>r>0. \<exists>no. \<forall>n \<ge> no. norm (X n - L) < r)"
  1685 unfolding lim_sequentially dist_norm ..
  1686 
  1687 lemma LIMSEQ_I: "(\<And>r. 0 < r \<Longrightarrow> \<exists>no. \<forall>n\<ge>no. norm (X n - L) < r) \<Longrightarrow> X \<longlonglongrightarrow> L"
  1688   for L :: "'a::real_normed_vector"
  1689   by (simp add: LIMSEQ_iff)
  1690 
  1691 lemma LIMSEQ_D: "X \<longlonglongrightarrow> L \<Longrightarrow> 0 < r \<Longrightarrow> \<exists>no. \<forall>n\<ge>no. norm (X n - L) < r"
  1692   for L :: "'a::real_normed_vector"
  1693   by (simp add: LIMSEQ_iff)
  1694 
  1695 lemma LIMSEQ_linear: "X \<longlonglongrightarrow> x \<Longrightarrow> l > 0 \<Longrightarrow> (\<lambda> n. X (n * l)) \<longlonglongrightarrow> x"
  1696   unfolding tendsto_def eventually_sequentially
  1697   by (metis div_le_dividend div_mult_self1_is_m le_trans mult.commute)
  1698 
  1699 lemma norm_inverse_le_norm: "r \<le> norm x \<Longrightarrow> 0 < r \<Longrightarrow> norm (inverse x) \<le> inverse r"
  1700   for x :: "'a::real_normed_div_algebra"
  1701   apply (subst nonzero_norm_inverse, clarsimp)
  1702   apply (erule (1) le_imp_inverse_le)
  1703   done
  1704 
  1705 lemma Bseq_inverse: "X \<longlonglongrightarrow> a \<Longrightarrow> a \<noteq> 0 \<Longrightarrow> Bseq (\<lambda>n. inverse (X n))"
  1706   for a :: "'a::real_normed_div_algebra"
  1707   by (rule Bfun_inverse)
  1708 
  1709 
  1710 text \<open>Transformation of limit.\<close>
  1711 
  1712 lemma Lim_transform: "(g \<longlongrightarrow> a) F \<Longrightarrow> ((\<lambda>x. f x - g x) \<longlongrightarrow> 0) F \<Longrightarrow> (f \<longlongrightarrow> a) F"
  1713   for a b :: "'a::real_normed_vector"
  1714   using tendsto_add [of g a F "\<lambda>x. f x - g x" 0] by simp
  1715 
  1716 lemma Lim_transform2: "(f \<longlongrightarrow> a) F \<Longrightarrow> ((\<lambda>x. f x - g x) \<longlongrightarrow> 0) F \<Longrightarrow> (g \<longlongrightarrow> a) F"
  1717   for a b :: "'a::real_normed_vector"
  1718   by (erule Lim_transform) (simp add: tendsto_minus_cancel)
  1719 
  1720 proposition Lim_transform_eq: "((\<lambda>x. f x - g x) \<longlongrightarrow> 0) F \<Longrightarrow> (f \<longlongrightarrow> a) F \<longleftrightarrow> (g \<longlongrightarrow> a) F"
  1721   for a :: "'a::real_normed_vector"
  1722   using Lim_transform Lim_transform2 by blast
  1723 
  1724 lemma Lim_transform_eventually:
  1725   "eventually (\<lambda>x. f x = g x) net \<Longrightarrow> (f \<longlongrightarrow> l) net \<Longrightarrow> (g \<longlongrightarrow> l) net"
  1726   apply (rule topological_tendstoI)
  1727   apply (drule (2) topological_tendstoD)
  1728   apply (erule (1) eventually_elim2)
  1729   apply simp
  1730   done
  1731 
  1732 lemma Lim_transform_within:
  1733   assumes "(f \<longlongrightarrow> l) (at x within S)"
  1734     and "0 < d"
  1735     and "\<And>x'. x'\<in>S \<Longrightarrow> 0 < dist x' x \<Longrightarrow> dist x' x < d \<Longrightarrow> f x' = g x'"
  1736   shows "(g \<longlongrightarrow> l) (at x within S)"
  1737 proof (rule Lim_transform_eventually)
  1738   show "eventually (\<lambda>x. f x = g x) (at x within S)"
  1739     using assms by (auto simp: eventually_at)
  1740   show "(f \<longlongrightarrow> l) (at x within S)"
  1741     by fact
  1742 qed
  1743 
  1744 text \<open>Common case assuming being away from some crucial point like 0.\<close>
  1745 lemma Lim_transform_away_within:
  1746   fixes a b :: "'a::t1_space"
  1747   assumes "a \<noteq> b"
  1748     and "\<forall>x\<in>S. x \<noteq> a \<and> x \<noteq> b \<longrightarrow> f x = g x"
  1749     and "(f \<longlongrightarrow> l) (at a within S)"
  1750   shows "(g \<longlongrightarrow> l) (at a within S)"
  1751 proof (rule Lim_transform_eventually)
  1752   show "(f \<longlongrightarrow> l) (at a within S)"
  1753     by fact
  1754   show "eventually (\<lambda>x. f x = g x) (at a within S)"
  1755     unfolding eventually_at_topological
  1756     by (rule exI [where x="- {b}"]) (simp add: open_Compl assms)
  1757 qed
  1758 
  1759 lemma Lim_transform_away_at:
  1760   fixes a b :: "'a::t1_space"
  1761   assumes ab: "a \<noteq> b"
  1762     and fg: "\<forall>x. x \<noteq> a \<and> x \<noteq> b \<longrightarrow> f x = g x"
  1763     and fl: "(f \<longlongrightarrow> l) (at a)"
  1764   shows "(g \<longlongrightarrow> l) (at a)"
  1765   using Lim_transform_away_within[OF ab, of UNIV f g l] fg fl by simp
  1766 
  1767 text \<open>Alternatively, within an open set.\<close>
  1768 lemma Lim_transform_within_open:
  1769   assumes "(f \<longlongrightarrow> l) (at a within T)"
  1770     and "open s" and "a \<in> s"
  1771     and "\<And>x. x\<in>s \<Longrightarrow> x \<noteq> a \<Longrightarrow> f x = g x"
  1772   shows "(g \<longlongrightarrow> l) (at a within T)"
  1773 proof (rule Lim_transform_eventually)
  1774   show "eventually (\<lambda>x. f x = g x) (at a within T)"
  1775     unfolding eventually_at_topological
  1776     using assms by auto
  1777   show "(f \<longlongrightarrow> l) (at a within T)" by fact
  1778 qed
  1779 
  1780 
  1781 text \<open>A congruence rule allowing us to transform limits assuming not at point.\<close>
  1782 
  1783 (* FIXME: Only one congruence rule for tendsto can be used at a time! *)
  1784 
  1785 lemma Lim_cong_within(*[cong add]*):
  1786   assumes "a = b"
  1787     and "x = y"
  1788     and "S = T"
  1789     and "\<And>x. x \<noteq> b \<Longrightarrow> x \<in> T \<Longrightarrow> f x = g x"
  1790   shows "(f \<longlongrightarrow> x) (at a within S) \<longleftrightarrow> (g \<longlongrightarrow> y) (at b within T)"
  1791   unfolding tendsto_def eventually_at_topological
  1792   using assms by simp
  1793 
  1794 lemma Lim_cong_at(*[cong add]*):
  1795   assumes "a = b" "x = y"
  1796     and "\<And>x. x \<noteq> a \<Longrightarrow> f x = g x"
  1797   shows "((\<lambda>x. f x) \<longlongrightarrow> x) (at a) \<longleftrightarrow> ((g \<longlongrightarrow> y) (at a))"
  1798   unfolding tendsto_def eventually_at_topological
  1799   using assms by simp
  1800 
  1801 text \<open>An unbounded sequence's inverse tends to 0.\<close>
  1802 lemma LIMSEQ_inverse_zero:
  1803   assumes "\<And>r::real. \<exists>N. \<forall>n\<ge>N. r < X n"
  1804   shows "(\<lambda>n. inverse (X n)) \<longlonglongrightarrow> 0"
  1805   apply (rule filterlim_compose[OF tendsto_inverse_0])
  1806   apply (simp add: filterlim_at_infinity[OF order_refl] eventually_sequentially)
  1807   apply (metis assms abs_le_D1 linorder_le_cases linorder_not_le)
  1808   done
  1809 
  1810 text \<open>The sequence @{term "1/n"} tends to 0 as @{term n} tends to infinity.\<close>
  1811 lemma LIMSEQ_inverse_real_of_nat: "(\<lambda>n. inverse (real (Suc n))) \<longlonglongrightarrow> 0"
  1812   by (metis filterlim_compose tendsto_inverse_0 filterlim_mono order_refl filterlim_Suc
  1813       filterlim_compose[OF filterlim_real_sequentially] at_top_le_at_infinity)
  1814 
  1815 text \<open>
  1816   The sequence @{term "r + 1/n"} tends to @{term r} as @{term n} tends to
  1817   infinity is now easily proved.
  1818 \<close>
  1819 
  1820 lemma LIMSEQ_inverse_real_of_nat_add: "(\<lambda>n. r + inverse (real (Suc n))) \<longlonglongrightarrow> r"
  1821   using tendsto_add [OF tendsto_const LIMSEQ_inverse_real_of_nat] by auto
  1822 
  1823 lemma LIMSEQ_inverse_real_of_nat_add_minus: "(\<lambda>n. r + -inverse (real (Suc n))) \<longlonglongrightarrow> r"
  1824   using tendsto_add [OF tendsto_const tendsto_minus [OF LIMSEQ_inverse_real_of_nat]]
  1825   by auto
  1826 
  1827 lemma LIMSEQ_inverse_real_of_nat_add_minus_mult: "(\<lambda>n. r * (1 + - inverse (real (Suc n)))) \<longlonglongrightarrow> r"
  1828   using tendsto_mult [OF tendsto_const LIMSEQ_inverse_real_of_nat_add_minus [of 1]]
  1829   by auto
  1830 
  1831 lemma lim_inverse_n: "((\<lambda>n. inverse(of_nat n)) \<longlongrightarrow> (0::'a::real_normed_field)) sequentially"
  1832   using lim_1_over_n by (simp add: inverse_eq_divide)
  1833 
  1834 lemma LIMSEQ_Suc_n_over_n: "(\<lambda>n. of_nat (Suc n) / of_nat n :: 'a :: real_normed_field) \<longlonglongrightarrow> 1"
  1835 proof (rule Lim_transform_eventually)
  1836   show "eventually (\<lambda>n. 1 + inverse (of_nat n :: 'a) = of_nat (Suc n) / of_nat n) sequentially"
  1837     using eventually_gt_at_top[of "0::nat"]
  1838     by eventually_elim (simp add: field_simps)
  1839   have "(\<lambda>n. 1 + inverse (of_nat n) :: 'a) \<longlonglongrightarrow> 1 + 0"
  1840     by (intro tendsto_add tendsto_const lim_inverse_n)
  1841   then show "(\<lambda>n. 1 + inverse (of_nat n) :: 'a) \<longlonglongrightarrow> 1"
  1842     by simp
  1843 qed
  1844 
  1845 lemma LIMSEQ_n_over_Suc_n: "(\<lambda>n. of_nat n / of_nat (Suc n) :: 'a :: real_normed_field) \<longlonglongrightarrow> 1"
  1846 proof (rule Lim_transform_eventually)
  1847   show "eventually (\<lambda>n. inverse (of_nat (Suc n) / of_nat n :: 'a) =
  1848       of_nat n / of_nat (Suc n)) sequentially"
  1849     using eventually_gt_at_top[of "0::nat"]
  1850     by eventually_elim (simp add: field_simps del: of_nat_Suc)
  1851   have "(\<lambda>n. inverse (of_nat (Suc n) / of_nat n :: 'a)) \<longlonglongrightarrow> inverse 1"
  1852     by (intro tendsto_inverse LIMSEQ_Suc_n_over_n) simp_all
  1853   then show "(\<lambda>n. inverse (of_nat (Suc n) / of_nat n :: 'a)) \<longlonglongrightarrow> 1"
  1854     by simp
  1855 qed
  1856 
  1857 
  1858 subsection \<open>Convergence on sequences\<close>
  1859 
  1860 lemma convergent_cong:
  1861   assumes "eventually (\<lambda>x. f x = g x) sequentially"
  1862   shows "convergent f \<longleftrightarrow> convergent g"
  1863   unfolding convergent_def
  1864   by (subst filterlim_cong[OF refl refl assms]) (rule refl)
  1865 
  1866 lemma convergent_Suc_iff: "convergent (\<lambda>n. f (Suc n)) \<longleftrightarrow> convergent f"
  1867   by (auto simp: convergent_def LIMSEQ_Suc_iff)
  1868 
  1869 lemma convergent_ignore_initial_segment: "convergent (\<lambda>n. f (n + m)) = convergent f"
  1870 proof (induct m arbitrary: f)
  1871   case 0
  1872   then show ?case by simp
  1873 next
  1874   case (Suc m)
  1875   have "convergent (\<lambda>n. f (n + Suc m)) \<longleftrightarrow> convergent (\<lambda>n. f (Suc n + m))"
  1876     by simp
  1877   also have "\<dots> \<longleftrightarrow> convergent (\<lambda>n. f (n + m))"
  1878     by (rule convergent_Suc_iff)
  1879   also have "\<dots> \<longleftrightarrow> convergent f"
  1880     by (rule Suc)
  1881   finally show ?case .
  1882 qed
  1883 
  1884 lemma convergent_add:
  1885   fixes X Y :: "nat \<Rightarrow> 'a::real_normed_vector"
  1886   assumes "convergent (\<lambda>n. X n)"
  1887     and "convergent (\<lambda>n. Y n)"
  1888   shows "convergent (\<lambda>n. X n + Y n)"
  1889   using assms unfolding convergent_def by (blast intro: tendsto_add)
  1890 
  1891 lemma convergent_sum:
  1892   fixes X :: "'a \<Rightarrow> nat \<Rightarrow> 'b::real_normed_vector"
  1893   shows "(\<And>i. i \<in> A \<Longrightarrow> convergent (\<lambda>n. X i n)) \<Longrightarrow> convergent (\<lambda>n. \<Sum>i\<in>A. X i n)"
  1894   by (induct A rule: infinite_finite_induct) (simp_all add: convergent_const convergent_add)
  1895 
  1896 lemma (in bounded_linear) convergent:
  1897   assumes "convergent (\<lambda>n. X n)"
  1898   shows "convergent (\<lambda>n. f (X n))"
  1899   using assms unfolding convergent_def by (blast intro: tendsto)
  1900 
  1901 lemma (in bounded_bilinear) convergent:
  1902   assumes "convergent (\<lambda>n. X n)"
  1903     and "convergent (\<lambda>n. Y n)"
  1904   shows "convergent (\<lambda>n. X n ** Y n)"
  1905   using assms unfolding convergent_def by (blast intro: tendsto)
  1906 
  1907 lemma convergent_minus_iff: "convergent X \<longleftrightarrow> convergent (\<lambda>n. - X n)"
  1908   for X :: "nat \<Rightarrow> 'a::real_normed_vector"
  1909   apply (simp add: convergent_def)
  1910   apply (auto dest: tendsto_minus)
  1911   apply (drule tendsto_minus)
  1912   apply auto
  1913   done
  1914 
  1915 lemma convergent_diff:
  1916   fixes X Y :: "nat \<Rightarrow> 'a::real_normed_vector"
  1917   assumes "convergent (\<lambda>n. X n)"
  1918   assumes "convergent (\<lambda>n. Y n)"
  1919   shows "convergent (\<lambda>n. X n - Y n)"
  1920   using assms unfolding convergent_def by (blast intro: tendsto_diff)
  1921 
  1922 lemma convergent_norm:
  1923   assumes "convergent f"
  1924   shows "convergent (\<lambda>n. norm (f n))"
  1925 proof -
  1926   from assms have "f \<longlonglongrightarrow> lim f"
  1927     by (simp add: convergent_LIMSEQ_iff)
  1928   then have "(\<lambda>n. norm (f n)) \<longlonglongrightarrow> norm (lim f)"
  1929     by (rule tendsto_norm)
  1930   then show ?thesis
  1931     by (auto simp: convergent_def)
  1932 qed
  1933 
  1934 lemma convergent_of_real:
  1935   "convergent f \<Longrightarrow> convergent (\<lambda>n. of_real (f n) :: 'a::real_normed_algebra_1)"
  1936   unfolding convergent_def by (blast intro!: tendsto_of_real)
  1937 
  1938 lemma convergent_add_const_iff:
  1939   "convergent (\<lambda>n. c + f n :: 'a::real_normed_vector) \<longleftrightarrow> convergent f"
  1940 proof
  1941   assume "convergent (\<lambda>n. c + f n)"
  1942   from convergent_diff[OF this convergent_const[of c]] show "convergent f"
  1943     by simp
  1944 next
  1945   assume "convergent f"
  1946   from convergent_add[OF convergent_const[of c] this] show "convergent (\<lambda>n. c + f n)"
  1947     by simp
  1948 qed
  1949 
  1950 lemma convergent_add_const_right_iff:
  1951   "convergent (\<lambda>n. f n + c :: 'a::real_normed_vector) \<longleftrightarrow> convergent f"
  1952   using convergent_add_const_iff[of c f] by (simp add: add_ac)
  1953 
  1954 lemma convergent_diff_const_right_iff:
  1955   "convergent (\<lambda>n. f n - c :: 'a::real_normed_vector) \<longleftrightarrow> convergent f"
  1956   using convergent_add_const_right_iff[of f "-c"] by (simp add: add_ac)
  1957 
  1958 lemma convergent_mult:
  1959   fixes X Y :: "nat \<Rightarrow> 'a::real_normed_field"
  1960   assumes "convergent (\<lambda>n. X n)"
  1961     and "convergent (\<lambda>n. Y n)"
  1962   shows "convergent (\<lambda>n. X n * Y n)"
  1963   using assms unfolding convergent_def by (blast intro: tendsto_mult)
  1964 
  1965 lemma convergent_mult_const_iff:
  1966   assumes "c \<noteq> 0"
  1967   shows "convergent (\<lambda>n. c * f n :: 'a::real_normed_field) \<longleftrightarrow> convergent f"
  1968 proof
  1969   assume "convergent (\<lambda>n. c * f n)"
  1970   from assms convergent_mult[OF this convergent_const[of "inverse c"]]
  1971     show "convergent f" by (simp add: field_simps)
  1972 next
  1973   assume "convergent f"
  1974   from convergent_mult[OF convergent_const[of c] this] show "convergent (\<lambda>n. c * f n)"
  1975     by simp
  1976 qed
  1977 
  1978 lemma convergent_mult_const_right_iff:
  1979   fixes c :: "'a::real_normed_field"
  1980   assumes "c \<noteq> 0"
  1981   shows "convergent (\<lambda>n. f n * c) \<longleftrightarrow> convergent f"
  1982   using convergent_mult_const_iff[OF assms, of f] by (simp add: mult_ac)
  1983 
  1984 lemma convergent_imp_Bseq: "convergent f \<Longrightarrow> Bseq f"
  1985   by (simp add: Cauchy_Bseq convergent_Cauchy)
  1986 
  1987 
  1988 text \<open>A monotone sequence converges to its least upper bound.\<close>
  1989 
  1990 lemma LIMSEQ_incseq_SUP:
  1991   fixes X :: "nat \<Rightarrow> 'a::{conditionally_complete_linorder,linorder_topology}"
  1992   assumes u: "bdd_above (range X)"
  1993     and X: "incseq X"
  1994   shows "X \<longlonglongrightarrow> (SUP i. X i)"
  1995   by (rule order_tendstoI)
  1996     (auto simp: eventually_sequentially u less_cSUP_iff
  1997       intro: X[THEN incseqD] less_le_trans cSUP_lessD[OF u])
  1998 
  1999 lemma LIMSEQ_decseq_INF:
  2000   fixes X :: "nat \<Rightarrow> 'a::{conditionally_complete_linorder, linorder_topology}"
  2001   assumes u: "bdd_below (range X)"
  2002     and X: "decseq X"
  2003   shows "X \<longlonglongrightarrow> (INF i. X i)"
  2004   by (rule order_tendstoI)
  2005      (auto simp: eventually_sequentially u cINF_less_iff
  2006        intro: X[THEN decseqD] le_less_trans less_cINF_D[OF u])
  2007 
  2008 text \<open>Main monotonicity theorem.\<close>
  2009 
  2010 lemma Bseq_monoseq_convergent: "Bseq X \<Longrightarrow> monoseq X \<Longrightarrow> convergent X"
  2011   for X :: "nat \<Rightarrow> real"
  2012   by (auto simp: monoseq_iff convergent_def intro: LIMSEQ_decseq_INF LIMSEQ_incseq_SUP
  2013       dest: Bseq_bdd_above Bseq_bdd_below)
  2014 
  2015 lemma Bseq_mono_convergent: "Bseq X \<Longrightarrow> (\<forall>m n. m \<le> n \<longrightarrow> X m \<le> X n) \<Longrightarrow> convergent X"
  2016   for X :: "nat \<Rightarrow> real"
  2017   by (auto intro!: Bseq_monoseq_convergent incseq_imp_monoseq simp: incseq_def)
  2018 
  2019 lemma monoseq_imp_convergent_iff_Bseq: "monoseq f \<Longrightarrow> convergent f \<longleftrightarrow> Bseq f"
  2020   for f :: "nat \<Rightarrow> real"
  2021   using Bseq_monoseq_convergent[of f] convergent_imp_Bseq[of f] by blast
  2022 
  2023 lemma Bseq_monoseq_convergent'_inc:
  2024   fixes f :: "nat \<Rightarrow> real"
  2025   shows "Bseq (\<lambda>n. f (n + M)) \<Longrightarrow> (\<And>m n. M \<le> m \<Longrightarrow> m \<le> n \<Longrightarrow> f m \<le> f n) \<Longrightarrow> convergent f"
  2026   by (subst convergent_ignore_initial_segment [symmetric, of _ M])
  2027      (auto intro!: Bseq_monoseq_convergent simp: monoseq_def)
  2028 
  2029 lemma Bseq_monoseq_convergent'_dec:
  2030   fixes f :: "nat \<Rightarrow> real"
  2031   shows "Bseq (\<lambda>n. f (n + M)) \<Longrightarrow> (\<And>m n. M \<le> m \<Longrightarrow> m \<le> n \<Longrightarrow> f m \<ge> f n) \<Longrightarrow> convergent f"
  2032   by (subst convergent_ignore_initial_segment [symmetric, of _ M])
  2033     (auto intro!: Bseq_monoseq_convergent simp: monoseq_def)
  2034 
  2035 lemma Cauchy_iff: "Cauchy X \<longleftrightarrow> (\<forall>e>0. \<exists>M. \<forall>m\<ge>M. \<forall>n\<ge>M. norm (X m - X n) < e)"
  2036   for X :: "nat \<Rightarrow> 'a::real_normed_vector"
  2037   unfolding Cauchy_def dist_norm ..
  2038 
  2039 lemma CauchyI: "(\<And>e. 0 < e \<Longrightarrow> \<exists>M. \<forall>m\<ge>M. \<forall>n\<ge>M. norm (X m - X n) < e) \<Longrightarrow> Cauchy X"
  2040   for X :: "nat \<Rightarrow> 'a::real_normed_vector"
  2041   by (simp add: Cauchy_iff)
  2042 
  2043 lemma CauchyD: "Cauchy X \<Longrightarrow> 0 < e \<Longrightarrow> \<exists>M. \<forall>m\<ge>M. \<forall>n\<ge>M. norm (X m - X n) < e"
  2044   for X :: "nat \<Rightarrow> 'a::real_normed_vector"
  2045   by (simp add: Cauchy_iff)
  2046 
  2047 lemma incseq_convergent:
  2048   fixes X :: "nat \<Rightarrow> real"
  2049   assumes "incseq X"
  2050     and "\<forall>i. X i \<le> B"
  2051   obtains L where "X \<longlonglongrightarrow> L" "\<forall>i. X i \<le> L"
  2052 proof atomize_elim
  2053   from incseq_bounded[OF assms] \<open>incseq X\<close> Bseq_monoseq_convergent[of X]
  2054   obtain L where "X \<longlonglongrightarrow> L"
  2055     by (auto simp: convergent_def monoseq_def incseq_def)
  2056   with \<open>incseq X\<close> show "\<exists>L. X \<longlonglongrightarrow> L \<and> (\<forall>i. X i \<le> L)"
  2057     by (auto intro!: exI[of _ L] incseq_le)
  2058 qed
  2059 
  2060 lemma decseq_convergent:
  2061   fixes X :: "nat \<Rightarrow> real"
  2062   assumes "decseq X"
  2063     and "\<forall>i. B \<le> X i"
  2064   obtains L where "X \<longlonglongrightarrow> L" "\<forall>i. L \<le> X i"
  2065 proof atomize_elim
  2066   from decseq_bounded[OF assms] \<open>decseq X\<close> Bseq_monoseq_convergent[of X]
  2067   obtain L where "X \<longlonglongrightarrow> L"
  2068     by (auto simp: convergent_def monoseq_def decseq_def)
  2069   with \<open>decseq X\<close> show "\<exists>L. X \<longlonglongrightarrow> L \<and> (\<forall>i. L \<le> X i)"
  2070     by (auto intro!: exI[of _ L] decseq_le)
  2071 qed
  2072 
  2073 
  2074 subsection \<open>Power Sequences\<close>
  2075 
  2076 text \<open>
  2077   The sequence @{term "x^n"} tends to 0 if @{term "0\<le>x"} and @{term
  2078   "x<1"}.  Proof will use (NS) Cauchy equivalence for convergence and
  2079   also fact that bounded and monotonic sequence converges.
  2080 \<close>
  2081 
  2082 lemma Bseq_realpow: "0 \<le> x \<Longrightarrow> x \<le> 1 \<Longrightarrow> Bseq (\<lambda>n. x ^ n)"
  2083   for x :: real
  2084   apply (simp add: Bseq_def)
  2085   apply (rule_tac x = 1 in exI)
  2086   apply (simp add: power_abs)
  2087   apply (auto dest: power_mono)
  2088   done
  2089 
  2090 lemma monoseq_realpow: "0 \<le> x \<Longrightarrow> x \<le> 1 \<Longrightarrow> monoseq (\<lambda>n. x ^ n)"
  2091   for x :: real
  2092   apply (clarify intro!: mono_SucI2)
  2093   apply (cut_tac n = n and N = "Suc n" and a = x in power_decreasing)
  2094      apply auto
  2095   done
  2096 
  2097 lemma convergent_realpow: "0 \<le> x \<Longrightarrow> x \<le> 1 \<Longrightarrow> convergent (\<lambda>n. x ^ n)"
  2098   for x :: real
  2099   by (blast intro!: Bseq_monoseq_convergent Bseq_realpow monoseq_realpow)
  2100 
  2101 lemma LIMSEQ_inverse_realpow_zero: "1 < x \<Longrightarrow> (\<lambda>n. inverse (x ^ n)) \<longlonglongrightarrow> 0"
  2102   for x :: real
  2103   by (rule filterlim_compose[OF tendsto_inverse_0 filterlim_realpow_sequentially_gt1]) simp
  2104 
  2105 lemma LIMSEQ_realpow_zero:
  2106   fixes x :: real
  2107   assumes "0 \<le> x" "x < 1"
  2108   shows "(\<lambda>n. x ^ n) \<longlonglongrightarrow> 0"
  2109 proof (cases "x = 0")
  2110   case False
  2111   with \<open>0 \<le> x\<close> have x0: "0 < x" by simp
  2112   then have "1 < inverse x"
  2113     using \<open>x < 1\<close> by (rule one_less_inverse)
  2114   then have "(\<lambda>n. inverse (inverse x ^ n)) \<longlonglongrightarrow> 0"
  2115     by (rule LIMSEQ_inverse_realpow_zero)
  2116   then show ?thesis by (simp add: power_inverse)
  2117 next
  2118   case True
  2119   show ?thesis
  2120     by (rule LIMSEQ_imp_Suc) (simp add: True)
  2121 qed
  2122 
  2123 lemma LIMSEQ_power_zero: "norm x < 1 \<Longrightarrow> (\<lambda>n. x ^ n) \<longlonglongrightarrow> 0"
  2124   for x :: "'a::real_normed_algebra_1"
  2125   apply (drule LIMSEQ_realpow_zero [OF norm_ge_zero])
  2126   apply (simp only: tendsto_Zfun_iff, erule Zfun_le)
  2127   apply (simp add: power_abs norm_power_ineq)
  2128   done
  2129 
  2130 lemma LIMSEQ_divide_realpow_zero: "1 < x \<Longrightarrow> (\<lambda>n. a / (x ^ n) :: real) \<longlonglongrightarrow> 0"
  2131   by (rule tendsto_divide_0 [OF tendsto_const filterlim_realpow_sequentially_gt1]) simp
  2132 
  2133 lemma
  2134   tendsto_power_zero:
  2135   fixes x::"'a::real_normed_algebra_1"
  2136   assumes "filterlim f at_top F"
  2137   assumes "norm x < 1"
  2138   shows "((\<lambda>y. x ^ (f y)) \<longlongrightarrow> 0) F"
  2139 proof (rule tendstoI)
  2140   fix e::real assume "0 < e"
  2141   from tendstoD[OF LIMSEQ_power_zero[OF \<open>norm x < 1\<close>] \<open>0 < e\<close>]
  2142   have "\<forall>\<^sub>F xa in sequentially. norm (x ^ xa) < e"
  2143     by simp
  2144   then obtain N where N: "norm (x ^ n) < e" if "n \<ge> N" for n
  2145     by (auto simp: eventually_sequentially)
  2146   have "\<forall>\<^sub>F i in F. f i \<ge> N"
  2147     using \<open>filterlim f sequentially F\<close>
  2148     by (simp add: filterlim_at_top)
  2149   then show "\<forall>\<^sub>F i in F. dist (x ^ f i) 0 < e"
  2150     by (eventually_elim) (auto simp: N)
  2151 qed
  2152 
  2153 text \<open>Limit of @{term "c^n"} for @{term"\<bar>c\<bar> < 1"}.\<close>
  2154 
  2155 lemma LIMSEQ_rabs_realpow_zero: "\<bar>c\<bar> < 1 \<Longrightarrow> (\<lambda>n. \<bar>c\<bar> ^ n :: real) \<longlonglongrightarrow> 0"
  2156   by (rule LIMSEQ_realpow_zero [OF abs_ge_zero])
  2157 
  2158 lemma LIMSEQ_rabs_realpow_zero2: "\<bar>c\<bar> < 1 \<Longrightarrow> (\<lambda>n. c ^ n :: real) \<longlonglongrightarrow> 0"
  2159   by (rule LIMSEQ_power_zero) simp
  2160 
  2161 
  2162 subsection \<open>Limits of Functions\<close>
  2163 
  2164 lemma LIM_eq: "f \<midarrow>a\<rightarrow> L = (\<forall>r>0. \<exists>s>0. \<forall>x. x \<noteq> a \<and> norm (x - a) < s \<longrightarrow> norm (f x - L) < r)"
  2165   for a :: "'a::real_normed_vector" and L :: "'b::real_normed_vector"
  2166   by (simp add: LIM_def dist_norm)
  2167 
  2168 lemma LIM_I:
  2169   "(\<And>r. 0 < r \<Longrightarrow> \<exists>s>0. \<forall>x. x \<noteq> a \<and> norm (x - a) < s \<longrightarrow> norm (f x - L) < r) \<Longrightarrow> f \<midarrow>a\<rightarrow> L"
  2170   for a :: "'a::real_normed_vector" and L :: "'b::real_normed_vector"
  2171   by (simp add: LIM_eq)
  2172 
  2173 lemma LIM_D: "f \<midarrow>a\<rightarrow> L \<Longrightarrow> 0 < r \<Longrightarrow> \<exists>s>0.\<forall>x. x \<noteq> a \<and> norm (x - a) < s \<longrightarrow> norm (f x - L) < r"
  2174   for a :: "'a::real_normed_vector" and L :: "'b::real_normed_vector"
  2175   by (simp add: LIM_eq)
  2176 
  2177 lemma LIM_offset: "f \<midarrow>a\<rightarrow> L \<Longrightarrow> (\<lambda>x. f (x + k)) \<midarrow>(a - k)\<rightarrow> L"
  2178   for a :: "'a::real_normed_vector"
  2179   by (simp add: filtermap_at_shift[symmetric, of a k] filterlim_def filtermap_filtermap)
  2180 
  2181 lemma LIM_offset_zero: "f \<midarrow>a\<rightarrow> L \<Longrightarrow> (\<lambda>h. f (a + h)) \<midarrow>0\<rightarrow> L"
  2182   for a :: "'a::real_normed_vector"
  2183   by (drule LIM_offset [where k = a]) (simp add: add.commute)
  2184 
  2185 lemma LIM_offset_zero_cancel: "(\<lambda>h. f (a + h)) \<midarrow>0\<rightarrow> L \<Longrightarrow> f \<midarrow>a\<rightarrow> L"
  2186   for a :: "'a::real_normed_vector"
  2187   by (drule LIM_offset [where k = "- a"]) simp
  2188 
  2189 lemma LIM_offset_zero_iff: "f \<midarrow>a\<rightarrow> L \<longleftrightarrow> (\<lambda>h. f (a + h)) \<midarrow>0\<rightarrow> L"
  2190   for f :: "'a :: real_normed_vector \<Rightarrow> _"
  2191   using LIM_offset_zero_cancel[of f a L] LIM_offset_zero[of f L a] by auto
  2192 
  2193 lemma LIM_zero: "(f \<longlongrightarrow> l) F \<Longrightarrow> ((\<lambda>x. f x - l) \<longlongrightarrow> 0) F"
  2194   for f :: "'a \<Rightarrow> 'b::real_normed_vector"
  2195   unfolding tendsto_iff dist_norm by simp
  2196 
  2197 lemma LIM_zero_cancel:
  2198   fixes f :: "'a \<Rightarrow> 'b::real_normed_vector"
  2199   shows "((\<lambda>x. f x - l) \<longlongrightarrow> 0) F \<Longrightarrow> (f \<longlongrightarrow> l) F"
  2200 unfolding tendsto_iff dist_norm by simp
  2201 
  2202 lemma LIM_zero_iff: "((\<lambda>x. f x - l) \<longlongrightarrow> 0) F = (f \<longlongrightarrow> l) F"
  2203   for f :: "'a \<Rightarrow> 'b::real_normed_vector"
  2204   unfolding tendsto_iff dist_norm by simp
  2205 
  2206 lemma LIM_imp_LIM:
  2207   fixes f :: "'a::topological_space \<Rightarrow> 'b::real_normed_vector"
  2208   fixes g :: "'a::topological_space \<Rightarrow> 'c::real_normed_vector"
  2209   assumes f: "f \<midarrow>a\<rightarrow> l"
  2210     and le: "\<And>x. x \<noteq> a \<Longrightarrow> norm (g x - m) \<le> norm (f x - l)"
  2211   shows "g \<midarrow>a\<rightarrow> m"
  2212   by (rule metric_LIM_imp_LIM [OF f]) (simp add: dist_norm le)
  2213 
  2214 lemma LIM_equal2:
  2215   fixes f g :: "'a::real_normed_vector \<Rightarrow> 'b::topological_space"
  2216   assumes "0 < R"
  2217     and "\<And>x. x \<noteq> a \<Longrightarrow> norm (x - a) < R \<Longrightarrow> f x = g x"
  2218   shows "g \<midarrow>a\<rightarrow> l \<Longrightarrow> f \<midarrow>a\<rightarrow> l"
  2219   by (rule metric_LIM_equal2 [OF assms]) (simp_all add: dist_norm)
  2220 
  2221 lemma LIM_compose2:
  2222   fixes a :: "'a::real_normed_vector"
  2223   assumes f: "f \<midarrow>a\<rightarrow> b"
  2224     and g: "g \<midarrow>b\<rightarrow> c"
  2225     and inj: "\<exists>d>0. \<forall>x. x \<noteq> a \<and> norm (x - a) < d \<longrightarrow> f x \<noteq> b"
  2226   shows "(\<lambda>x. g (f x)) \<midarrow>a\<rightarrow> c"
  2227   by (rule metric_LIM_compose2 [OF f g inj [folded dist_norm]])
  2228 
  2229 lemma real_LIM_sandwich_zero:
  2230   fixes f g :: "'a::topological_space \<Rightarrow> real"
  2231   assumes f: "f \<midarrow>a\<rightarrow> 0"
  2232     and 1: "\<And>x. x \<noteq> a \<Longrightarrow> 0 \<le> g x"
  2233     and 2: "\<And>x. x \<noteq> a \<Longrightarrow> g x \<le> f x"
  2234   shows "g \<midarrow>a\<rightarrow> 0"
  2235 proof (rule LIM_imp_LIM [OF f]) (* FIXME: use tendsto_sandwich *)
  2236   fix x
  2237   assume x: "x \<noteq> a"
  2238   with 1 have "norm (g x - 0) = g x" by simp
  2239   also have "g x \<le> f x" by (rule 2 [OF x])
  2240   also have "f x \<le> \<bar>f x\<bar>" by (rule abs_ge_self)
  2241   also have "\<bar>f x\<bar> = norm (f x - 0)" by simp
  2242   finally show "norm (g x - 0) \<le> norm (f x - 0)" .
  2243 qed
  2244 
  2245 
  2246 subsection \<open>Continuity\<close>
  2247 
  2248 lemma LIM_isCont_iff: "(f \<midarrow>a\<rightarrow> f a) = ((\<lambda>h. f (a + h)) \<midarrow>0\<rightarrow> f a)"
  2249   for f :: "'a::real_normed_vector \<Rightarrow> 'b::topological_space"
  2250   by (rule iffI [OF LIM_offset_zero LIM_offset_zero_cancel])
  2251 
  2252 lemma isCont_iff: "isCont f x = (\<lambda>h. f (x + h)) \<midarrow>0\<rightarrow> f x"
  2253   for f :: "'a::real_normed_vector \<Rightarrow> 'b::topological_space"
  2254   by (simp add: isCont_def LIM_isCont_iff)
  2255 
  2256 lemma isCont_LIM_compose2:
  2257   fixes a :: "'a::real_normed_vector"
  2258   assumes f [unfolded isCont_def]: "isCont f a"
  2259     and g: "g \<midarrow>f a\<rightarrow> l"
  2260     and inj: "\<exists>d>0. \<forall>x. x \<noteq> a \<and> norm (x - a) < d \<longrightarrow> f x \<noteq> f a"
  2261   shows "(\<lambda>x. g (f x)) \<midarrow>a\<rightarrow> l"
  2262   by (rule LIM_compose2 [OF f g inj])
  2263 
  2264 lemma isCont_norm [simp]: "isCont f a \<Longrightarrow> isCont (\<lambda>x. norm (f x)) a"
  2265   for f :: "'a::t2_space \<Rightarrow> 'b::real_normed_vector"
  2266   by (fact continuous_norm)
  2267 
  2268 lemma isCont_rabs [simp]: "isCont f a \<Longrightarrow> isCont (\<lambda>x. \<bar>f x\<bar>) a"
  2269   for f :: "'a::t2_space \<Rightarrow> real"
  2270   by (fact continuous_rabs)
  2271 
  2272 lemma isCont_add [simp]: "isCont f a \<Longrightarrow> isCont g a \<Longrightarrow> isCont (\<lambda>x. f x + g x) a"
  2273   for f :: "'a::t2_space \<Rightarrow> 'b::topological_monoid_add"
  2274   by (fact continuous_add)
  2275 
  2276 lemma isCont_minus [simp]: "isCont f a \<Longrightarrow> isCont (\<lambda>x. - f x) a"
  2277   for f :: "'a::t2_space \<Rightarrow> 'b::real_normed_vector"
  2278   by (fact continuous_minus)
  2279 
  2280 lemma isCont_diff [simp]: "isCont f a \<Longrightarrow> isCont g a \<Longrightarrow> isCont (\<lambda>x. f x - g x) a"
  2281   for f :: "'a::t2_space \<Rightarrow> 'b::real_normed_vector"
  2282   by (fact continuous_diff)
  2283 
  2284 lemma isCont_mult [simp]: "isCont f a \<Longrightarrow> isCont g a \<Longrightarrow> isCont (\<lambda>x. f x * g x) a"
  2285   for f g :: "'a::t2_space \<Rightarrow> 'b::real_normed_algebra"
  2286   by (fact continuous_mult)
  2287 
  2288 lemma (in bounded_linear) isCont: "isCont g a \<Longrightarrow> isCont (\<lambda>x. f (g x)) a"
  2289   by (fact continuous)
  2290 
  2291 lemma (in bounded_bilinear) isCont: "isCont f a \<Longrightarrow> isCont g a \<Longrightarrow> isCont (\<lambda>x. f x ** g x) a"
  2292   by (fact continuous)
  2293 
  2294 lemmas isCont_scaleR [simp] =
  2295   bounded_bilinear.isCont [OF bounded_bilinear_scaleR]
  2296 
  2297 lemmas isCont_of_real [simp] =
  2298   bounded_linear.isCont [OF bounded_linear_of_real]
  2299 
  2300 lemma isCont_power [simp]: "isCont f a \<Longrightarrow> isCont (\<lambda>x. f x ^ n) a"
  2301   for f :: "'a::t2_space \<Rightarrow> 'b::{power,real_normed_algebra}"
  2302   by (fact continuous_power)
  2303 
  2304 lemma isCont_sum [simp]: "\<forall>i\<in>A. isCont (f i) a \<Longrightarrow> isCont (\<lambda>x. \<Sum>i\<in>A. f i x) a"
  2305   for f :: "'a \<Rightarrow> 'b::t2_space \<Rightarrow> 'c::topological_comm_monoid_add"
  2306   by (auto intro: continuous_sum)
  2307 
  2308 
  2309 subsection \<open>Uniform Continuity\<close>
  2310 
  2311 lemma uniformly_continuous_on_def:
  2312   fixes f :: "'a::metric_space \<Rightarrow> 'b::metric_space"
  2313   shows "uniformly_continuous_on s f \<longleftrightarrow>
  2314     (\<forall>e>0. \<exists>d>0. \<forall>x\<in>s. \<forall>x'\<in>s. dist x' x < d \<longrightarrow> dist (f x') (f x) < e)"
  2315   unfolding uniformly_continuous_on_uniformity
  2316     uniformity_dist filterlim_INF filterlim_principal eventually_inf_principal
  2317   by (force simp: Ball_def uniformity_dist[symmetric] eventually_uniformity_metric)
  2318 
  2319 abbreviation isUCont :: "['a::metric_space \<Rightarrow> 'b::metric_space] \<Rightarrow> bool"
  2320   where "isUCont f \<equiv> uniformly_continuous_on UNIV f"
  2321 
  2322 lemma isUCont_def: "isUCont f \<longleftrightarrow> (\<forall>r>0. \<exists>s>0. \<forall>x y. dist x y < s \<longrightarrow> dist (f x) (f y) < r)"
  2323   by (auto simp: uniformly_continuous_on_def dist_commute)
  2324 
  2325 lemma isUCont_isCont: "isUCont f \<Longrightarrow> isCont f x"
  2326   by (drule uniformly_continuous_imp_continuous) (simp add: continuous_on_eq_continuous_at)
  2327 
  2328 lemma uniformly_continuous_on_Cauchy:
  2329   fixes f :: "'a::metric_space \<Rightarrow> 'b::metric_space"
  2330   assumes "uniformly_continuous_on S f" "Cauchy X" "\<And>n. X n \<in> S"
  2331   shows "Cauchy (\<lambda>n. f (X n))"
  2332   using assms
  2333   apply (simp only: uniformly_continuous_on_def)
  2334   apply (rule metric_CauchyI)
  2335   apply (drule_tac x=e in spec)
  2336   apply safe
  2337   apply (drule_tac e=d in metric_CauchyD)
  2338    apply safe
  2339   apply (rule_tac x=M in exI)
  2340   apply simp
  2341   done
  2342 
  2343 lemma isUCont_Cauchy: "isUCont f \<Longrightarrow> Cauchy X \<Longrightarrow> Cauchy (\<lambda>n. f (X n))"
  2344   by (rule uniformly_continuous_on_Cauchy[where S=UNIV and f=f]) simp_all
  2345   
  2346 lemma uniformly_continuous_imp_Cauchy_continuous:
  2347   fixes f :: "'a::metric_space \<Rightarrow> 'b::metric_space"
  2348   shows "\<lbrakk>uniformly_continuous_on S f; Cauchy \<sigma>; \<And>n. (\<sigma> n) \<in> S\<rbrakk> \<Longrightarrow> Cauchy(f o \<sigma>)"
  2349   by (simp add: uniformly_continuous_on_def Cauchy_def) meson
  2350 
  2351 lemma (in bounded_linear) isUCont: "isUCont f"
  2352   unfolding isUCont_def dist_norm
  2353 proof (intro allI impI)
  2354   fix r :: real
  2355   assume r: "0 < r"
  2356   obtain K where K: "0 < K" and norm_le: "norm (f x) \<le> norm x * K" for x
  2357     using pos_bounded by blast
  2358   show "\<exists>s>0. \<forall>x y. norm (x - y) < s \<longrightarrow> norm (f x - f y) < r"
  2359   proof (rule exI, safe)
  2360     from r K show "0 < r / K" by simp
  2361   next
  2362     fix x y :: 'a
  2363     assume xy: "norm (x - y) < r / K"
  2364     have "norm (f x - f y) = norm (f (x - y))" by (simp only: diff)
  2365     also have "\<dots> \<le> norm (x - y) * K" by (rule norm_le)
  2366     also from K xy have "\<dots> < r" by (simp only: pos_less_divide_eq)
  2367     finally show "norm (f x - f y) < r" .
  2368   qed
  2369 qed
  2370 
  2371 lemma (in bounded_linear) Cauchy: "Cauchy X \<Longrightarrow> Cauchy (\<lambda>n. f (X n))"
  2372   by (rule isUCont [THEN isUCont_Cauchy])
  2373 
  2374 lemma LIM_less_bound:
  2375   fixes f :: "real \<Rightarrow> real"
  2376   assumes ev: "b < x" "\<forall> x' \<in> { b <..< x}. 0 \<le> f x'" and "isCont f x"
  2377   shows "0 \<le> f x"
  2378 proof (rule tendsto_lowerbound)
  2379   show "(f \<longlongrightarrow> f x) (at_left x)"
  2380     using \<open>isCont f x\<close> by (simp add: filterlim_at_split isCont_def)
  2381   show "eventually (\<lambda>x. 0 \<le> f x) (at_left x)"
  2382     using ev by (auto simp: eventually_at dist_real_def intro!: exI[of _ "x - b"])
  2383 qed simp
  2384 
  2385 
  2386 subsection \<open>Nested Intervals and Bisection -- Needed for Compactness\<close>
  2387 
  2388 lemma nested_sequence_unique:
  2389   assumes "\<forall>n. f n \<le> f (Suc n)" "\<forall>n. g (Suc n) \<le> g n" "\<forall>n. f n \<le> g n" "(\<lambda>n. f n - g n) \<longlonglongrightarrow> 0"
  2390   shows "\<exists>l::real. ((\<forall>n. f n \<le> l) \<and> f \<longlonglongrightarrow> l) \<and> ((\<forall>n. l \<le> g n) \<and> g \<longlonglongrightarrow> l)"
  2391 proof -
  2392   have "incseq f" unfolding incseq_Suc_iff by fact
  2393   have "decseq g" unfolding decseq_Suc_iff by fact
  2394   have "f n \<le> g 0" for n
  2395   proof -
  2396     from \<open>decseq g\<close> have "g n \<le> g 0"
  2397       by (rule decseqD) simp
  2398     with \<open>\<forall>n. f n \<le> g n\<close>[THEN spec, of n] show ?thesis
  2399       by auto
  2400   qed
  2401   then obtain u where "f \<longlonglongrightarrow> u" "\<forall>i. f i \<le> u"
  2402     using incseq_convergent[OF \<open>incseq f\<close>] by auto
  2403   moreover have "f 0 \<le> g n" for n
  2404   proof -
  2405     from \<open>incseq f\<close> have "f 0 \<le> f n" by (rule incseqD) simp
  2406     with \<open>\<forall>n. f n \<le> g n\<close>[THEN spec, of n] show ?thesis
  2407       by simp
  2408   qed
  2409   then obtain l where "g \<longlonglongrightarrow> l" "\<forall>i. l \<le> g i"
  2410     using decseq_convergent[OF \<open>decseq g\<close>] by auto
  2411   moreover note LIMSEQ_unique[OF assms(4) tendsto_diff[OF \<open>f \<longlonglongrightarrow> u\<close> \<open>g \<longlonglongrightarrow> l\<close>]]
  2412   ultimately show ?thesis by auto
  2413 qed
  2414 
  2415 lemma Bolzano[consumes 1, case_names trans local]:
  2416   fixes P :: "real \<Rightarrow> real \<Rightarrow> bool"
  2417   assumes [arith]: "a \<le> b"
  2418     and trans: "\<And>a b c. P a b \<Longrightarrow> P b c \<Longrightarrow> a \<le> b \<Longrightarrow> b \<le> c \<Longrightarrow> P a c"
  2419     and local: "\<And>x. a \<le> x \<Longrightarrow> x \<le> b \<Longrightarrow> \<exists>d>0. \<forall>a b. a \<le> x \<and> x \<le> b \<and> b - a < d \<longrightarrow> P a b"
  2420   shows "P a b"
  2421 proof -
  2422   define bisect where "bisect =
  2423     rec_nat (a, b) (\<lambda>n (x, y). if P x ((x+y) / 2) then ((x+y)/2, y) else (x, (x+y)/2))"
  2424   define l u where "l n = fst (bisect n)" and "u n = snd (bisect n)" for n
  2425   have l[simp]: "l 0 = a" "\<And>n. l (Suc n) = (if P (l n) ((l n + u n) / 2) then (l n + u n) / 2 else l n)"
  2426     and u[simp]: "u 0 = b" "\<And>n. u (Suc n) = (if P (l n) ((l n + u n) / 2) then u n else (l n + u n) / 2)"
  2427     by (simp_all add: l_def u_def bisect_def split: prod.split)
  2428 
  2429   have [simp]: "l n \<le> u n" for n by (induct n) auto
  2430 
  2431   have "\<exists>x. ((\<forall>n. l n \<le> x) \<and> l \<longlonglongrightarrow> x) \<and> ((\<forall>n. x \<le> u n) \<and> u \<longlonglongrightarrow> x)"
  2432   proof (safe intro!: nested_sequence_unique)
  2433     show "l n \<le> l (Suc n)" "u (Suc n) \<le> u n" for n
  2434       by (induct n) auto
  2435   next
  2436     have "l n - u n = (a - b) / 2^n" for n
  2437       by (induct n) (auto simp: field_simps)
  2438     then show "(\<lambda>n. l n - u n) \<longlonglongrightarrow> 0"
  2439       by (simp add: LIMSEQ_divide_realpow_zero)
  2440   qed fact
  2441   then obtain x where x: "\<And>n. l n \<le> x" "\<And>n. x \<le> u n" and "l \<longlonglongrightarrow> x" "u \<longlonglongrightarrow> x"
  2442     by auto
  2443   obtain d where "0 < d" and d: "a \<le> x \<Longrightarrow> x \<le> b \<Longrightarrow> b - a < d \<Longrightarrow> P a b" for a b
  2444     using \<open>l 0 \<le> x\<close> \<open>x \<le> u 0\<close> local[of x] by auto
  2445 
  2446   show "P a b"
  2447   proof (rule ccontr)
  2448     assume "\<not> P a b"
  2449     have "\<not> P (l n) (u n)" for n
  2450     proof (induct n)
  2451       case 0
  2452       then show ?case
  2453         by (simp add: \<open>\<not> P a b\<close>)
  2454     next
  2455       case (Suc n)
  2456       with trans[of "l n" "(l n + u n) / 2" "u n"] show ?case
  2457         by auto
  2458     qed
  2459     moreover
  2460     {
  2461       have "eventually (\<lambda>n. x - d / 2 < l n) sequentially"
  2462         using \<open>0 < d\<close> \<open>l \<longlonglongrightarrow> x\<close> by (intro order_tendstoD[of _ x]) auto
  2463       moreover have "eventually (\<lambda>n. u n < x + d / 2) sequentially"
  2464         using \<open>0 < d\<close> \<open>u \<longlonglongrightarrow> x\<close> by (intro order_tendstoD[of _ x]) auto
  2465       ultimately have "eventually (\<lambda>n. P (l n) (u n)) sequentially"
  2466       proof eventually_elim
  2467         case (elim n)
  2468         from add_strict_mono[OF this] have "u n - l n < d" by simp
  2469         with x show "P (l n) (u n)" by (rule d)
  2470       qed
  2471     }
  2472     ultimately show False by simp
  2473   qed
  2474 qed
  2475 
  2476 lemma compact_Icc[simp, intro]: "compact {a .. b::real}"
  2477 proof (cases "a \<le> b", rule compactI)
  2478   fix C
  2479   assume C: "a \<le> b" "\<forall>t\<in>C. open t" "{a..b} \<subseteq> \<Union>C"
  2480   define T where "T = {a .. b}"
  2481   from C(1,3) show "\<exists>C'\<subseteq>C. finite C' \<and> {a..b} \<subseteq> \<Union>C'"
  2482   proof (induct rule: Bolzano)
  2483     case (trans a b c)
  2484     then have *: "{a..c} = {a..b} \<union> {b..c}"
  2485       by auto
  2486     with trans obtain C1 C2
  2487       where "C1\<subseteq>C" "finite C1" "{a..b} \<subseteq> \<Union>C1" "C2\<subseteq>C" "finite C2" "{b..c} \<subseteq> \<Union>C2"
  2488       by auto
  2489     with trans show ?case
  2490       unfolding * by (intro exI[of _ "C1 \<union> C2"]) auto
  2491   next
  2492     case (local x)
  2493     with C have "x \<in> \<Union>C" by auto
  2494     with C(2) obtain c where "x \<in> c" "open c" "c \<in> C"
  2495       by auto
  2496     then obtain e where "0 < e" "{x - e <..< x + e} \<subseteq> c"
  2497       by (auto simp: open_dist dist_real_def subset_eq Ball_def abs_less_iff)
  2498     with \<open>c \<in> C\<close> show ?case
  2499       by (safe intro!: exI[of _ "e/2"] exI[of _ "{c}"]) auto
  2500   qed
  2501 qed simp
  2502 
  2503 
  2504 lemma continuous_image_closed_interval:
  2505   fixes a b and f :: "real \<Rightarrow> real"
  2506   defines "S \<equiv> {a..b}"
  2507   assumes "a \<le> b" and f: "continuous_on S f"
  2508   shows "\<exists>c d. f`S = {c..d} \<and> c \<le> d"
  2509 proof -
  2510   have S: "compact S" "S \<noteq> {}"
  2511     using \<open>a \<le> b\<close> by (auto simp: S_def)
  2512   obtain c where "c \<in> S" "\<forall>d\<in>S. f d \<le> f c"
  2513     using continuous_attains_sup[OF S f] by auto
  2514   moreover obtain d where "d \<in> S" "\<forall>c\<in>S. f d \<le> f c"
  2515     using continuous_attains_inf[OF S f] by auto
  2516   moreover have "connected (f`S)"
  2517     using connected_continuous_image[OF f] connected_Icc by (auto simp: S_def)
  2518   ultimately have "f ` S = {f d .. f c} \<and> f d \<le> f c"
  2519     by (auto simp: connected_iff_interval)
  2520   then show ?thesis
  2521     by auto
  2522 qed
  2523 
  2524 lemma open_Collect_positive:
  2525   fixes f :: "'a::t2_space \<Rightarrow> real"
  2526   assumes f: "continuous_on s f"
  2527   shows "\<exists>A. open A \<and> A \<inter> s = {x\<in>s. 0 < f x}"
  2528   using continuous_on_open_invariant[THEN iffD1, OF f, rule_format, of "{0 <..}"]
  2529   by (auto simp: Int_def field_simps)
  2530 
  2531 lemma open_Collect_less_Int:
  2532   fixes f g :: "'a::t2_space \<Rightarrow> real"
  2533   assumes f: "continuous_on s f"
  2534     and g: "continuous_on s g"
  2535   shows "\<exists>A. open A \<and> A \<inter> s = {x\<in>s. f x < g x}"
  2536   using open_Collect_positive[OF continuous_on_diff[OF g f]] by (simp add: field_simps)
  2537 
  2538 
  2539 subsection \<open>Boundedness of continuous functions\<close>
  2540 
  2541 text\<open>By bisection, function continuous on closed interval is bounded above\<close>
  2542 
  2543 lemma isCont_eq_Ub:
  2544   fixes f :: "real \<Rightarrow> 'a::linorder_topology"
  2545   shows "a \<le> b \<Longrightarrow> \<forall>x::real. a \<le> x \<and> x \<le> b \<longrightarrow> isCont f x \<Longrightarrow>
  2546     \<exists>M. (\<forall>x. a \<le> x \<and> x \<le> b \<longrightarrow> f x \<le> M) \<and> (\<exists>x. a \<le> x \<and> x \<le> b \<and> f x = M)"
  2547   using continuous_attains_sup[of "{a..b}" f]
  2548   by (auto simp add: continuous_at_imp_continuous_on Ball_def Bex_def)
  2549 
  2550 lemma isCont_eq_Lb:
  2551   fixes f :: "real \<Rightarrow> 'a::linorder_topology"
  2552   shows "a \<le> b \<Longrightarrow> \<forall>x. a \<le> x \<and> x \<le> b \<longrightarrow> isCont f x \<Longrightarrow>
  2553     \<exists>M. (\<forall>x. a \<le> x \<and> x \<le> b \<longrightarrow> M \<le> f x) \<and> (\<exists>x. a \<le> x \<and> x \<le> b \<and> f x = M)"
  2554   using continuous_attains_inf[of "{a..b}" f]
  2555   by (auto simp add: continuous_at_imp_continuous_on Ball_def Bex_def)
  2556 
  2557 lemma isCont_bounded:
  2558   fixes f :: "real \<Rightarrow> 'a::linorder_topology"
  2559   shows "a \<le> b \<Longrightarrow> \<forall>x. a \<le> x \<and> x \<le> b \<longrightarrow> isCont f x \<Longrightarrow> \<exists>M. \<forall>x. a \<le> x \<and> x \<le> b \<longrightarrow> f x \<le> M"
  2560   using isCont_eq_Ub[of a b f] by auto
  2561 
  2562 lemma isCont_has_Ub:
  2563   fixes f :: "real \<Rightarrow> 'a::linorder_topology"
  2564   shows "a \<le> b \<Longrightarrow> \<forall>x. a \<le> x \<and> x \<le> b \<longrightarrow> isCont f x \<Longrightarrow>
  2565     \<exists>M. (\<forall>x. a \<le> x \<and> x \<le> b \<longrightarrow> f x \<le> M) \<and> (\<forall>N. N < M \<longrightarrow> (\<exists>x. a \<le> x \<and> x \<le> b \<and> N < f x))"
  2566   using isCont_eq_Ub[of a b f] by auto
  2567 
  2568 (*HOL style here: object-level formulations*)
  2569 lemma IVT_objl:
  2570   "(f a \<le> y \<and> y \<le> f b \<and> a \<le> b \<and> (\<forall>x. a \<le> x \<and> x \<le> b \<longrightarrow> isCont f x)) \<longrightarrow>
  2571     (\<exists>x. a \<le> x \<and> x \<le> b \<and> f x = y)"
  2572   for a y :: real
  2573   by (blast intro: IVT)
  2574 
  2575 lemma IVT2_objl:
  2576   "(f b \<le> y \<and> y \<le> f a \<and> a \<le> b \<and> (\<forall>x. a \<le> x \<and> x \<le> b \<longrightarrow> isCont f x)) \<longrightarrow>
  2577     (\<exists>x. a \<le> x \<and> x \<le> b \<and> f x = y)"
  2578   for b y :: real
  2579   by (blast intro: IVT2)
  2580 
  2581 lemma isCont_Lb_Ub:
  2582   fixes f :: "real \<Rightarrow> real"
  2583   assumes "a \<le> b" "\<forall>x. a \<le> x \<and> x \<le> b \<longrightarrow> isCont f x"
  2584   shows "\<exists>L M. (\<forall>x. a \<le> x \<and> x \<le> b \<longrightarrow> L \<le> f x \<and> f x \<le> M) \<and>
  2585     (\<forall>y. L \<le> y \<and> y \<le> M \<longrightarrow> (\<exists>x. a \<le> x \<and> x \<le> b \<and> (f x = y)))"
  2586 proof -
  2587   obtain M where M: "a \<le> M" "M \<le> b" "\<forall>x. a \<le> x \<and> x \<le> b \<longrightarrow> f x \<le> f M"
  2588     using isCont_eq_Ub[OF assms] by auto
  2589   obtain L where L: "a \<le> L" "L \<le> b" "\<forall>x. a \<le> x \<and> x \<le> b \<longrightarrow> f L \<le> f x"
  2590     using isCont_eq_Lb[OF assms] by auto
  2591   show ?thesis
  2592     using IVT[of f L _ M] IVT2[of f L _ M] M L assms
  2593     apply (rule_tac x="f L" in exI)
  2594     apply (rule_tac x="f M" in exI)
  2595     apply (cases "L \<le> M")
  2596      apply simp
  2597      apply (metis order_trans)
  2598     apply simp
  2599     apply (metis order_trans)
  2600     done
  2601 qed
  2602 
  2603 
  2604 text \<open>Continuity of inverse function.\<close>
  2605 
  2606 lemma isCont_inverse_function:
  2607   fixes f g :: "real \<Rightarrow> real"
  2608   assumes d: "0 < d"
  2609     and inj: "\<forall>z. \<bar>z-x\<bar> \<le> d \<longrightarrow> g (f z) = z"
  2610     and cont: "\<forall>z. \<bar>z-x\<bar> \<le> d \<longrightarrow> isCont f z"
  2611   shows "isCont g (f x)"
  2612 proof -
  2613   let ?A = "f (x - d)"
  2614   let ?B = "f (x + d)"
  2615   let ?D = "{x - d..x + d}"
  2616 
  2617   have f: "continuous_on ?D f"
  2618     using cont by (intro continuous_at_imp_continuous_on ballI) auto
  2619   then have g: "continuous_on (f`?D) g"
  2620     using inj by (intro continuous_on_inv) auto
  2621 
  2622   from d f have "{min ?A ?B <..< max ?A ?B} \<subseteq> f ` ?D"
  2623     by (intro connected_contains_Ioo connected_continuous_image) (auto split: split_min split_max)
  2624   with g have "continuous_on {min ?A ?B <..< max ?A ?B} g"
  2625     by (rule continuous_on_subset)
  2626   moreover
  2627   have "(?A < f x \<and> f x < ?B) \<or> (?B < f x \<and> f x < ?A)"
  2628     using d inj by (intro continuous_inj_imp_mono[OF _ _ f] inj_on_imageI2[of g, OF inj_onI]) auto
  2629   then have "f x \<in> {min ?A ?B <..< max ?A ?B}"
  2630     by auto
  2631   ultimately
  2632   show ?thesis
  2633     by (simp add: continuous_on_eq_continuous_at)
  2634 qed
  2635 
  2636 lemma isCont_inverse_function2:
  2637   fixes f g :: "real \<Rightarrow> real"
  2638   shows
  2639     "a < x \<Longrightarrow> x < b \<Longrightarrow>
  2640       \<forall>z. a \<le> z \<and> z \<le> b \<longrightarrow> g (f z) = z \<Longrightarrow>
  2641       \<forall>z. a \<le> z \<and> z \<le> b \<longrightarrow> isCont f z \<Longrightarrow> isCont g (f x)"
  2642   apply (rule isCont_inverse_function [where f=f and d="min (x - a) (b - x)"])
  2643   apply (simp_all add: abs_le_iff)
  2644   done
  2645 
  2646 (* need to rename second isCont_inverse *)
  2647 lemma isCont_inv_fun:
  2648   fixes f g :: "real \<Rightarrow> real"
  2649   shows "0 < d \<Longrightarrow> (\<forall>z. \<bar>z - x\<bar> \<le> d \<longrightarrow> g (f z) = z) \<Longrightarrow>
  2650     \<forall>z. \<bar>z - x\<bar> \<le> d \<longrightarrow> isCont f z \<Longrightarrow> isCont g (f x)"
  2651   by (rule isCont_inverse_function)
  2652 
  2653 text \<open>Bartle/Sherbert: Introduction to Real Analysis, Theorem 4.2.9, p. 110.\<close>
  2654 lemma LIM_fun_gt_zero: "f \<midarrow>c\<rightarrow> l \<Longrightarrow> 0 < l \<Longrightarrow> \<exists>r. 0 < r \<and> (\<forall>x. x \<noteq> c \<and> \<bar>c - x\<bar> < r \<longrightarrow> 0 < f x)"
  2655   for f :: "real \<Rightarrow> real"
  2656   apply (drule (1) LIM_D)
  2657   apply clarify
  2658   apply (rule_tac x = s in exI)
  2659   apply (simp add: abs_less_iff)
  2660   done
  2661 
  2662 lemma LIM_fun_less_zero: "f \<midarrow>c\<rightarrow> l \<Longrightarrow> l < 0 \<Longrightarrow> \<exists>r. 0 < r \<and> (\<forall>x. x \<noteq> c \<and> \<bar>c - x\<bar> < r \<longrightarrow> f x < 0)"
  2663   for f :: "real \<Rightarrow> real"
  2664   apply (drule LIM_D [where r="-l"])
  2665    apply simp
  2666   apply clarify
  2667   apply (rule_tac x = s in exI)
  2668   apply (simp add: abs_less_iff)
  2669   done
  2670 
  2671 lemma LIM_fun_not_zero: "f \<midarrow>c\<rightarrow> l \<Longrightarrow> l \<noteq> 0 \<Longrightarrow> \<exists>r. 0 < r \<and> (\<forall>x. x \<noteq> c \<and> \<bar>c - x\<bar> < r \<longrightarrow> f x \<noteq> 0)"
  2672   for f :: "real \<Rightarrow> real"
  2673   using LIM_fun_gt_zero[of f l c] LIM_fun_less_zero[of f l c] by (auto simp add: neq_iff)
  2674 
  2675 end