src/HOL/Orderings.thy
author paulson <lp15@cam.ac.uk>
Tue Apr 25 16:39:54 2017 +0100 (2017-04-25)
changeset 65578 e4997c181cce
parent 64758 3b33d2fc5fc0
child 65963 ca1e636fa716
permissions -rw-r--r--
New material from PNT proof, as well as more default [simp] declarations. Also removed duplicate theorems about geometric series
     1 (*  Title:      HOL/Orderings.thy
     2     Author:     Tobias Nipkow, Markus Wenzel, and Larry Paulson
     3 *)
     4 
     5 section \<open>Abstract orderings\<close>
     6 
     7 theory Orderings
     8 imports HOL
     9 keywords "print_orders" :: diag
    10 begin
    11 
    12 ML_file "~~/src/Provers/order.ML"
    13 ML_file "~~/src/Provers/quasi.ML"  (* FIXME unused? *)
    14 
    15 subsection \<open>Abstract ordering\<close>
    16 
    17 locale ordering =
    18   fixes less_eq :: "'a \<Rightarrow> 'a \<Rightarrow> bool" (infix "\<^bold>\<le>" 50)
    19    and less :: "'a \<Rightarrow> 'a \<Rightarrow> bool" (infix "\<^bold><" 50)
    20   assumes strict_iff_order: "a \<^bold>< b \<longleftrightarrow> a \<^bold>\<le> b \<and> a \<noteq> b"
    21   assumes refl: "a \<^bold>\<le> a" \<comment> \<open>not \<open>iff\<close>: makes problems due to multiple (dual) interpretations\<close>
    22     and antisym: "a \<^bold>\<le> b \<Longrightarrow> b \<^bold>\<le> a \<Longrightarrow> a = b"
    23     and trans: "a \<^bold>\<le> b \<Longrightarrow> b \<^bold>\<le> c \<Longrightarrow> a \<^bold>\<le> c"
    24 begin
    25 
    26 lemma strict_implies_order:
    27   "a \<^bold>< b \<Longrightarrow> a \<^bold>\<le> b"
    28   by (simp add: strict_iff_order)
    29 
    30 lemma strict_implies_not_eq:
    31   "a \<^bold>< b \<Longrightarrow> a \<noteq> b"
    32   by (simp add: strict_iff_order)
    33 
    34 lemma not_eq_order_implies_strict:
    35   "a \<noteq> b \<Longrightarrow> a \<^bold>\<le> b \<Longrightarrow> a \<^bold>< b"
    36   by (simp add: strict_iff_order)
    37 
    38 lemma order_iff_strict:
    39   "a \<^bold>\<le> b \<longleftrightarrow> a \<^bold>< b \<or> a = b"
    40   by (auto simp add: strict_iff_order refl)
    41 
    42 lemma irrefl: \<comment> \<open>not \<open>iff\<close>: makes problems due to multiple (dual) interpretations\<close>
    43   "\<not> a \<^bold>< a"
    44   by (simp add: strict_iff_order)
    45 
    46 lemma asym:
    47   "a \<^bold>< b \<Longrightarrow> b \<^bold>< a \<Longrightarrow> False"
    48   by (auto simp add: strict_iff_order intro: antisym)
    49 
    50 lemma strict_trans1:
    51   "a \<^bold>\<le> b \<Longrightarrow> b \<^bold>< c \<Longrightarrow> a \<^bold>< c"
    52   by (auto simp add: strict_iff_order intro: trans antisym)
    53 
    54 lemma strict_trans2:
    55   "a \<^bold>< b \<Longrightarrow> b \<^bold>\<le> c \<Longrightarrow> a \<^bold>< c"
    56   by (auto simp add: strict_iff_order intro: trans antisym)
    57 
    58 lemma strict_trans:
    59   "a \<^bold>< b \<Longrightarrow> b \<^bold>< c \<Longrightarrow> a \<^bold>< c"
    60   by (auto intro: strict_trans1 strict_implies_order)
    61 
    62 end
    63 
    64 text \<open>Alternative introduction rule with bias towards strict order\<close>
    65 
    66 lemma ordering_strictI:
    67   fixes less_eq (infix "\<^bold>\<le>" 50)
    68     and less (infix "\<^bold><" 50)
    69   assumes less_eq_less: "\<And>a b. a \<^bold>\<le> b \<longleftrightarrow> a \<^bold>< b \<or> a = b"
    70     assumes asym: "\<And>a b. a \<^bold>< b \<Longrightarrow> \<not> b \<^bold>< a"
    71   assumes irrefl: "\<And>a. \<not> a \<^bold>< a"
    72   assumes trans: "\<And>a b c. a \<^bold>< b \<Longrightarrow> b \<^bold>< c \<Longrightarrow> a \<^bold>< c"
    73   shows "ordering less_eq less"
    74 proof
    75   fix a b
    76   show "a \<^bold>< b \<longleftrightarrow> a \<^bold>\<le> b \<and> a \<noteq> b"
    77     by (auto simp add: less_eq_less asym irrefl)
    78 next
    79   fix a
    80   show "a \<^bold>\<le> a"
    81     by (auto simp add: less_eq_less)
    82 next
    83   fix a b c
    84   assume "a \<^bold>\<le> b" and "b \<^bold>\<le> c" then show "a \<^bold>\<le> c"
    85     by (auto simp add: less_eq_less intro: trans)
    86 next
    87   fix a b
    88   assume "a \<^bold>\<le> b" and "b \<^bold>\<le> a" then show "a = b"
    89     by (auto simp add: less_eq_less asym)
    90 qed
    91 
    92 lemma ordering_dualI:
    93   fixes less_eq (infix "\<^bold>\<le>" 50)
    94     and less (infix "\<^bold><" 50)
    95   assumes "ordering (\<lambda>a b. b \<^bold>\<le> a) (\<lambda>a b. b \<^bold>< a)"
    96   shows "ordering less_eq less"
    97 proof -
    98   from assms interpret ordering "\<lambda>a b. b \<^bold>\<le> a" "\<lambda>a b. b \<^bold>< a" .
    99   show ?thesis
   100     by standard (auto simp: strict_iff_order refl intro: antisym trans)
   101 qed
   102 
   103 locale ordering_top = ordering +
   104   fixes top :: "'a"  ("\<^bold>\<top>")
   105   assumes extremum [simp]: "a \<^bold>\<le> \<^bold>\<top>"
   106 begin
   107 
   108 lemma extremum_uniqueI:
   109   "\<^bold>\<top> \<^bold>\<le> a \<Longrightarrow> a = \<^bold>\<top>"
   110   by (rule antisym) auto
   111 
   112 lemma extremum_unique:
   113   "\<^bold>\<top> \<^bold>\<le> a \<longleftrightarrow> a = \<^bold>\<top>"
   114   by (auto intro: antisym)
   115 
   116 lemma extremum_strict [simp]:
   117   "\<not> (\<^bold>\<top> \<^bold>< a)"
   118   using extremum [of a] by (auto simp add: order_iff_strict intro: asym irrefl)
   119 
   120 lemma not_eq_extremum:
   121   "a \<noteq> \<^bold>\<top> \<longleftrightarrow> a \<^bold>< \<^bold>\<top>"
   122   by (auto simp add: order_iff_strict intro: not_eq_order_implies_strict extremum)
   123 
   124 end
   125 
   126 
   127 subsection \<open>Syntactic orders\<close>
   128 
   129 class ord =
   130   fixes less_eq :: "'a \<Rightarrow> 'a \<Rightarrow> bool"
   131     and less :: "'a \<Rightarrow> 'a \<Rightarrow> bool"
   132 begin
   133 
   134 notation
   135   less_eq  ("op \<le>") and
   136   less_eq  ("(_/ \<le> _)"  [51, 51] 50) and
   137   less  ("op <") and
   138   less  ("(_/ < _)"  [51, 51] 50)
   139 
   140 abbreviation (input)
   141   greater_eq  (infix "\<ge>" 50)
   142   where "x \<ge> y \<equiv> y \<le> x"
   143 
   144 abbreviation (input)
   145   greater  (infix ">" 50)
   146   where "x > y \<equiv> y < x"
   147 
   148 notation (ASCII)
   149   less_eq  ("op <=") and
   150   less_eq  ("(_/ <= _)" [51, 51] 50)
   151 
   152 notation (input)
   153   greater_eq  (infix ">=" 50)
   154 
   155 end
   156 
   157 
   158 subsection \<open>Quasi orders\<close>
   159 
   160 class preorder = ord +
   161   assumes less_le_not_le: "x < y \<longleftrightarrow> x \<le> y \<and> \<not> (y \<le> x)"
   162   and order_refl [iff]: "x \<le> x"
   163   and order_trans: "x \<le> y \<Longrightarrow> y \<le> z \<Longrightarrow> x \<le> z"
   164 begin
   165 
   166 text \<open>Reflexivity.\<close>
   167 
   168 lemma eq_refl: "x = y \<Longrightarrow> x \<le> y"
   169     \<comment> \<open>This form is useful with the classical reasoner.\<close>
   170 by (erule ssubst) (rule order_refl)
   171 
   172 lemma less_irrefl [iff]: "\<not> x < x"
   173 by (simp add: less_le_not_le)
   174 
   175 lemma less_imp_le: "x < y \<Longrightarrow> x \<le> y"
   176 by (simp add: less_le_not_le)
   177 
   178 
   179 text \<open>Asymmetry.\<close>
   180 
   181 lemma less_not_sym: "x < y \<Longrightarrow> \<not> (y < x)"
   182 by (simp add: less_le_not_le)
   183 
   184 lemma less_asym: "x < y \<Longrightarrow> (\<not> P \<Longrightarrow> y < x) \<Longrightarrow> P"
   185 by (drule less_not_sym, erule contrapos_np) simp
   186 
   187 
   188 text \<open>Transitivity.\<close>
   189 
   190 lemma less_trans: "x < y \<Longrightarrow> y < z \<Longrightarrow> x < z"
   191 by (auto simp add: less_le_not_le intro: order_trans)
   192 
   193 lemma le_less_trans: "x \<le> y \<Longrightarrow> y < z \<Longrightarrow> x < z"
   194 by (auto simp add: less_le_not_le intro: order_trans)
   195 
   196 lemma less_le_trans: "x < y \<Longrightarrow> y \<le> z \<Longrightarrow> x < z"
   197 by (auto simp add: less_le_not_le intro: order_trans)
   198 
   199 
   200 text \<open>Useful for simplification, but too risky to include by default.\<close>
   201 
   202 lemma less_imp_not_less: "x < y \<Longrightarrow> (\<not> y < x) \<longleftrightarrow> True"
   203 by (blast elim: less_asym)
   204 
   205 lemma less_imp_triv: "x < y \<Longrightarrow> (y < x \<longrightarrow> P) \<longleftrightarrow> True"
   206 by (blast elim: less_asym)
   207 
   208 
   209 text \<open>Transitivity rules for calculational reasoning\<close>
   210 
   211 lemma less_asym': "a < b \<Longrightarrow> b < a \<Longrightarrow> P"
   212 by (rule less_asym)
   213 
   214 
   215 text \<open>Dual order\<close>
   216 
   217 lemma dual_preorder:
   218   "class.preorder (op \<ge>) (op >)"
   219   by standard (auto simp add: less_le_not_le intro: order_trans)
   220 
   221 end
   222 
   223 
   224 subsection \<open>Partial orders\<close>
   225 
   226 class order = preorder +
   227   assumes antisym: "x \<le> y \<Longrightarrow> y \<le> x \<Longrightarrow> x = y"
   228 begin
   229 
   230 lemma less_le: "x < y \<longleftrightarrow> x \<le> y \<and> x \<noteq> y"
   231   by (auto simp add: less_le_not_le intro: antisym)
   232 
   233 sublocale order: ordering less_eq less + dual_order: ordering greater_eq greater
   234 proof -
   235   interpret ordering less_eq less
   236     by standard (auto intro: antisym order_trans simp add: less_le)
   237   show "ordering less_eq less"
   238     by (fact ordering_axioms)
   239   then show "ordering greater_eq greater"
   240     by (rule ordering_dualI)
   241 qed
   242 
   243 text \<open>Reflexivity.\<close>
   244 
   245 lemma le_less: "x \<le> y \<longleftrightarrow> x < y \<or> x = y"
   246     \<comment> \<open>NOT suitable for iff, since it can cause PROOF FAILED.\<close>
   247 by (fact order.order_iff_strict)
   248 
   249 lemma le_imp_less_or_eq: "x \<le> y \<Longrightarrow> x < y \<or> x = y"
   250 by (simp add: less_le)
   251 
   252 
   253 text \<open>Useful for simplification, but too risky to include by default.\<close>
   254 
   255 lemma less_imp_not_eq: "x < y \<Longrightarrow> (x = y) \<longleftrightarrow> False"
   256 by auto
   257 
   258 lemma less_imp_not_eq2: "x < y \<Longrightarrow> (y = x) \<longleftrightarrow> False"
   259 by auto
   260 
   261 
   262 text \<open>Transitivity rules for calculational reasoning\<close>
   263 
   264 lemma neq_le_trans: "a \<noteq> b \<Longrightarrow> a \<le> b \<Longrightarrow> a < b"
   265 by (fact order.not_eq_order_implies_strict)
   266 
   267 lemma le_neq_trans: "a \<le> b \<Longrightarrow> a \<noteq> b \<Longrightarrow> a < b"
   268 by (rule order.not_eq_order_implies_strict)
   269 
   270 
   271 text \<open>Asymmetry.\<close>
   272 
   273 lemma eq_iff: "x = y \<longleftrightarrow> x \<le> y \<and> y \<le> x"
   274 by (blast intro: antisym)
   275 
   276 lemma antisym_conv: "y \<le> x \<Longrightarrow> x \<le> y \<longleftrightarrow> x = y"
   277 by (blast intro: antisym)
   278 
   279 lemma less_imp_neq: "x < y \<Longrightarrow> x \<noteq> y"
   280 by (fact order.strict_implies_not_eq)
   281 
   282 
   283 text \<open>Least value operator\<close>
   284 
   285 definition (in ord)
   286   Least :: "('a \<Rightarrow> bool) \<Rightarrow> 'a" (binder "LEAST " 10) where
   287   "Least P = (THE x. P x \<and> (\<forall>y. P y \<longrightarrow> x \<le> y))"
   288 
   289 lemma Least_equality:
   290   assumes "P x"
   291     and "\<And>y. P y \<Longrightarrow> x \<le> y"
   292   shows "Least P = x"
   293 unfolding Least_def by (rule the_equality)
   294   (blast intro: assms antisym)+
   295 
   296 lemma LeastI2_order:
   297   assumes "P x"
   298     and "\<And>y. P y \<Longrightarrow> x \<le> y"
   299     and "\<And>x. P x \<Longrightarrow> \<forall>y. P y \<longrightarrow> x \<le> y \<Longrightarrow> Q x"
   300   shows "Q (Least P)"
   301 unfolding Least_def by (rule theI2)
   302   (blast intro: assms antisym)+
   303 
   304 end
   305 
   306 lemma ordering_orderI:
   307   fixes less_eq (infix "\<^bold>\<le>" 50)
   308     and less (infix "\<^bold><" 50)
   309   assumes "ordering less_eq less"
   310   shows "class.order less_eq less"
   311 proof -
   312   from assms interpret ordering less_eq less .
   313   show ?thesis
   314     by standard (auto intro: antisym trans simp add: refl strict_iff_order)
   315 qed
   316 
   317 lemma order_strictI:
   318   fixes less (infix "\<sqsubset>" 50)
   319     and less_eq (infix "\<sqsubseteq>" 50)
   320   assumes "\<And>a b. a \<sqsubseteq> b \<longleftrightarrow> a \<sqsubset> b \<or> a = b"
   321     assumes "\<And>a b. a \<sqsubset> b \<Longrightarrow> \<not> b \<sqsubset> a"
   322   assumes "\<And>a. \<not> a \<sqsubset> a"
   323   assumes "\<And>a b c. a \<sqsubset> b \<Longrightarrow> b \<sqsubset> c \<Longrightarrow> a \<sqsubset> c"
   324   shows "class.order less_eq less"
   325   by (rule ordering_orderI) (rule ordering_strictI, (fact assms)+)
   326 
   327 context order
   328 begin
   329 
   330 text \<open>Dual order\<close>
   331 
   332 lemma dual_order:
   333   "class.order (op \<ge>) (op >)"
   334   using dual_order.ordering_axioms by (rule ordering_orderI)
   335 
   336 end
   337 
   338 
   339 subsection \<open>Linear (total) orders\<close>
   340 
   341 class linorder = order +
   342   assumes linear: "x \<le> y \<or> y \<le> x"
   343 begin
   344 
   345 lemma less_linear: "x < y \<or> x = y \<or> y < x"
   346 unfolding less_le using less_le linear by blast
   347 
   348 lemma le_less_linear: "x \<le> y \<or> y < x"
   349 by (simp add: le_less less_linear)
   350 
   351 lemma le_cases [case_names le ge]:
   352   "(x \<le> y \<Longrightarrow> P) \<Longrightarrow> (y \<le> x \<Longrightarrow> P) \<Longrightarrow> P"
   353 using linear by blast
   354 
   355 lemma (in linorder) le_cases3:
   356   "\<lbrakk>\<lbrakk>x \<le> y; y \<le> z\<rbrakk> \<Longrightarrow> P; \<lbrakk>y \<le> x; x \<le> z\<rbrakk> \<Longrightarrow> P; \<lbrakk>x \<le> z; z \<le> y\<rbrakk> \<Longrightarrow> P;
   357     \<lbrakk>z \<le> y; y \<le> x\<rbrakk> \<Longrightarrow> P; \<lbrakk>y \<le> z; z \<le> x\<rbrakk> \<Longrightarrow> P; \<lbrakk>z \<le> x; x \<le> y\<rbrakk> \<Longrightarrow> P\<rbrakk> \<Longrightarrow> P"
   358 by (blast intro: le_cases)
   359 
   360 lemma linorder_cases [case_names less equal greater]:
   361   "(x < y \<Longrightarrow> P) \<Longrightarrow> (x = y \<Longrightarrow> P) \<Longrightarrow> (y < x \<Longrightarrow> P) \<Longrightarrow> P"
   362 using less_linear by blast
   363 
   364 lemma linorder_wlog[case_names le sym]:
   365   "(\<And>a b. a \<le> b \<Longrightarrow> P a b) \<Longrightarrow> (\<And>a b. P b a \<Longrightarrow> P a b) \<Longrightarrow> P a b"
   366   by (cases rule: le_cases[of a b]) blast+
   367 
   368 lemma not_less: "\<not> x < y \<longleftrightarrow> y \<le> x"
   369 apply (simp add: less_le)
   370 using linear apply (blast intro: antisym)
   371 done
   372 
   373 lemma not_less_iff_gr_or_eq:
   374  "\<not>(x < y) \<longleftrightarrow> (x > y | x = y)"
   375 apply(simp add:not_less le_less)
   376 apply blast
   377 done
   378 
   379 lemma not_le: "\<not> x \<le> y \<longleftrightarrow> y < x"
   380 apply (simp add: less_le)
   381 using linear apply (blast intro: antisym)
   382 done
   383 
   384 lemma neq_iff: "x \<noteq> y \<longleftrightarrow> x < y \<or> y < x"
   385 by (cut_tac x = x and y = y in less_linear, auto)
   386 
   387 lemma neqE: "x \<noteq> y \<Longrightarrow> (x < y \<Longrightarrow> R) \<Longrightarrow> (y < x \<Longrightarrow> R) \<Longrightarrow> R"
   388 by (simp add: neq_iff) blast
   389 
   390 lemma antisym_conv1: "\<not> x < y \<Longrightarrow> x \<le> y \<longleftrightarrow> x = y"
   391 by (blast intro: antisym dest: not_less [THEN iffD1])
   392 
   393 lemma antisym_conv2: "x \<le> y \<Longrightarrow> \<not> x < y \<longleftrightarrow> x = y"
   394 by (blast intro: antisym dest: not_less [THEN iffD1])
   395 
   396 lemma antisym_conv3: "\<not> y < x \<Longrightarrow> \<not> x < y \<longleftrightarrow> x = y"
   397 by (blast intro: antisym dest: not_less [THEN iffD1])
   398 
   399 lemma leI: "\<not> x < y \<Longrightarrow> y \<le> x"
   400 unfolding not_less .
   401 
   402 lemma leD: "y \<le> x \<Longrightarrow> \<not> x < y"
   403 unfolding not_less .
   404 
   405 lemma not_le_imp_less: "\<not> y \<le> x \<Longrightarrow> x < y"
   406 unfolding not_le .
   407 
   408 lemma linorder_less_wlog[case_names less refl sym]:
   409      "\<lbrakk>\<And>a b. a < b \<Longrightarrow> P a b;  \<And>a. P a a;  \<And>a b. P b a \<Longrightarrow> P a b\<rbrakk> \<Longrightarrow> P a b"
   410   using antisym_conv3 by blast
   411 
   412 text \<open>Dual order\<close>
   413 
   414 lemma dual_linorder:
   415   "class.linorder (op \<ge>) (op >)"
   416 by (rule class.linorder.intro, rule dual_order) (unfold_locales, rule linear)
   417 
   418 end
   419 
   420 
   421 text \<open>Alternative introduction rule with bias towards strict order\<close>
   422 
   423 lemma linorder_strictI:
   424   fixes less_eq (infix "\<^bold>\<le>" 50)
   425     and less (infix "\<^bold><" 50)
   426   assumes "class.order less_eq less"
   427   assumes trichotomy: "\<And>a b. a \<^bold>< b \<or> a = b \<or> b \<^bold>< a"
   428   shows "class.linorder less_eq less"
   429 proof -
   430   interpret order less_eq less
   431     by (fact \<open>class.order less_eq less\<close>)
   432   show ?thesis
   433   proof
   434     fix a b
   435     show "a \<^bold>\<le> b \<or> b \<^bold>\<le> a"
   436       using trichotomy by (auto simp add: le_less)
   437   qed
   438 qed
   439 
   440 
   441 subsection \<open>Reasoning tools setup\<close>
   442 
   443 ML \<open>
   444 signature ORDERS =
   445 sig
   446   val print_structures: Proof.context -> unit
   447   val order_tac: Proof.context -> thm list -> int -> tactic
   448   val add_struct: string * term list -> string -> attribute
   449   val del_struct: string * term list -> attribute
   450 end;
   451 
   452 structure Orders: ORDERS =
   453 struct
   454 
   455 (* context data *)
   456 
   457 fun struct_eq ((s1: string, ts1), (s2, ts2)) =
   458   s1 = s2 andalso eq_list (op aconv) (ts1, ts2);
   459 
   460 structure Data = Generic_Data
   461 (
   462   type T = ((string * term list) * Order_Tac.less_arith) list;
   463     (* Order structures:
   464        identifier of the structure, list of operations and record of theorems
   465        needed to set up the transitivity reasoner,
   466        identifier and operations identify the structure uniquely. *)
   467   val empty = [];
   468   val extend = I;
   469   fun merge data = AList.join struct_eq (K fst) data;
   470 );
   471 
   472 fun print_structures ctxt =
   473   let
   474     val structs = Data.get (Context.Proof ctxt);
   475     fun pretty_term t = Pretty.block
   476       [Pretty.quote (Syntax.pretty_term ctxt t), Pretty.brk 1,
   477         Pretty.str "::", Pretty.brk 1,
   478         Pretty.quote (Syntax.pretty_typ ctxt (type_of t))];
   479     fun pretty_struct ((s, ts), _) = Pretty.block
   480       [Pretty.str s, Pretty.str ":", Pretty.brk 1,
   481        Pretty.enclose "(" ")" (Pretty.breaks (map pretty_term ts))];
   482   in
   483     Pretty.writeln (Pretty.big_list "order structures:" (map pretty_struct structs))
   484   end;
   485 
   486 val _ =
   487   Outer_Syntax.command @{command_keyword print_orders}
   488     "print order structures available to transitivity reasoner"
   489     (Scan.succeed (Toplevel.keep (print_structures o Toplevel.context_of)));
   490 
   491 
   492 (* tactics *)
   493 
   494 fun struct_tac ((s, ops), thms) ctxt facts =
   495   let
   496     val [eq, le, less] = ops;
   497     fun decomp thy (@{const Trueprop} $ t) =
   498           let
   499             fun excluded t =
   500               (* exclude numeric types: linear arithmetic subsumes transitivity *)
   501               let val T = type_of t
   502               in
   503                 T = HOLogic.natT orelse T = HOLogic.intT orelse T = HOLogic.realT
   504               end;
   505             fun rel (bin_op $ t1 $ t2) =
   506                   if excluded t1 then NONE
   507                   else if Pattern.matches thy (eq, bin_op) then SOME (t1, "=", t2)
   508                   else if Pattern.matches thy (le, bin_op) then SOME (t1, "<=", t2)
   509                   else if Pattern.matches thy (less, bin_op) then SOME (t1, "<", t2)
   510                   else NONE
   511               | rel _ = NONE;
   512             fun dec (Const (@{const_name Not}, _) $ t) =
   513                   (case rel t of NONE =>
   514                     NONE
   515                   | SOME (t1, rel, t2) => SOME (t1, "~" ^ rel, t2))
   516               | dec x = rel x;
   517           in dec t end
   518       | decomp _ _ = NONE;
   519   in
   520     (case s of
   521       "order" => Order_Tac.partial_tac decomp thms ctxt facts
   522     | "linorder" => Order_Tac.linear_tac decomp thms ctxt facts
   523     | _ => error ("Unknown order kind " ^ quote s ^ " encountered in transitivity reasoner"))
   524   end
   525 
   526 fun order_tac ctxt facts =
   527   FIRST' (map (fn s => CHANGED o struct_tac s ctxt facts) (Data.get (Context.Proof ctxt)));
   528 
   529 
   530 (* attributes *)
   531 
   532 fun add_struct s tag =
   533   Thm.declaration_attribute
   534     (fn thm => Data.map (AList.map_default struct_eq (s, Order_Tac.empty TrueI) (Order_Tac.update tag thm)));
   535 fun del_struct s =
   536   Thm.declaration_attribute
   537     (fn _ => Data.map (AList.delete struct_eq s));
   538 
   539 end;
   540 \<close>
   541 
   542 attribute_setup order = \<open>
   543   Scan.lift ((Args.add -- Args.name >> (fn (_, s) => SOME s) || Args.del >> K NONE) --|
   544     Args.colon (* FIXME || Scan.succeed true *) ) -- Scan.lift Args.name --
   545     Scan.repeat Args.term
   546     >> (fn ((SOME tag, n), ts) => Orders.add_struct (n, ts) tag
   547          | ((NONE, n), ts) => Orders.del_struct (n, ts))
   548 \<close> "theorems controlling transitivity reasoner"
   549 
   550 method_setup order = \<open>
   551   Scan.succeed (fn ctxt => SIMPLE_METHOD' (Orders.order_tac ctxt []))
   552 \<close> "transitivity reasoner"
   553 
   554 
   555 text \<open>Declarations to set up transitivity reasoner of partial and linear orders.\<close>
   556 
   557 context order
   558 begin
   559 
   560 (* The type constraint on @{term op =} below is necessary since the operation
   561    is not a parameter of the locale. *)
   562 
   563 declare less_irrefl [THEN notE, order add less_reflE: order "op = :: 'a \<Rightarrow> 'a \<Rightarrow> bool" "op <=" "op <"]
   564 
   565 declare order_refl  [order add le_refl: order "op = :: 'a => 'a => bool" "op <=" "op <"]
   566 
   567 declare less_imp_le [order add less_imp_le: order "op = :: 'a => 'a => bool" "op <=" "op <"]
   568 
   569 declare antisym [order add eqI: order "op = :: 'a => 'a => bool" "op <=" "op <"]
   570 
   571 declare eq_refl [order add eqD1: order "op = :: 'a => 'a => bool" "op <=" "op <"]
   572 
   573 declare sym [THEN eq_refl, order add eqD2: order "op = :: 'a => 'a => bool" "op <=" "op <"]
   574 
   575 declare less_trans [order add less_trans: order "op = :: 'a => 'a => bool" "op <=" "op <"]
   576 
   577 declare less_le_trans [order add less_le_trans: order "op = :: 'a => 'a => bool" "op <=" "op <"]
   578 
   579 declare le_less_trans [order add le_less_trans: order "op = :: 'a => 'a => bool" "op <=" "op <"]
   580 
   581 declare order_trans [order add le_trans: order "op = :: 'a => 'a => bool" "op <=" "op <"]
   582 
   583 declare le_neq_trans [order add le_neq_trans: order "op = :: 'a => 'a => bool" "op <=" "op <"]
   584 
   585 declare neq_le_trans [order add neq_le_trans: order "op = :: 'a => 'a => bool" "op <=" "op <"]
   586 
   587 declare less_imp_neq [order add less_imp_neq: order "op = :: 'a => 'a => bool" "op <=" "op <"]
   588 
   589 declare eq_neq_eq_imp_neq [order add eq_neq_eq_imp_neq: order "op = :: 'a => 'a => bool" "op <=" "op <"]
   590 
   591 declare not_sym [order add not_sym: order "op = :: 'a => 'a => bool" "op <=" "op <"]
   592 
   593 end
   594 
   595 context linorder
   596 begin
   597 
   598 declare [[order del: order "op = :: 'a => 'a => bool" "op <=" "op <"]]
   599 
   600 declare less_irrefl [THEN notE, order add less_reflE: linorder "op = :: 'a => 'a => bool" "op <=" "op <"]
   601 
   602 declare order_refl [order add le_refl: linorder "op = :: 'a => 'a => bool" "op <=" "op <"]
   603 
   604 declare less_imp_le [order add less_imp_le: linorder "op = :: 'a => 'a => bool" "op <=" "op <"]
   605 
   606 declare not_less [THEN iffD2, order add not_lessI: linorder "op = :: 'a => 'a => bool" "op <=" "op <"]
   607 
   608 declare not_le [THEN iffD2, order add not_leI: linorder "op = :: 'a => 'a => bool" "op <=" "op <"]
   609 
   610 declare not_less [THEN iffD1, order add not_lessD: linorder "op = :: 'a => 'a => bool" "op <=" "op <"]
   611 
   612 declare not_le [THEN iffD1, order add not_leD: linorder "op = :: 'a => 'a => bool" "op <=" "op <"]
   613 
   614 declare antisym [order add eqI: linorder "op = :: 'a => 'a => bool" "op <=" "op <"]
   615 
   616 declare eq_refl [order add eqD1: linorder "op = :: 'a => 'a => bool" "op <=" "op <"]
   617 
   618 declare sym [THEN eq_refl, order add eqD2: linorder "op = :: 'a => 'a => bool" "op <=" "op <"]
   619 
   620 declare less_trans [order add less_trans: linorder "op = :: 'a => 'a => bool" "op <=" "op <"]
   621 
   622 declare less_le_trans [order add less_le_trans: linorder "op = :: 'a => 'a => bool" "op <=" "op <"]
   623 
   624 declare le_less_trans [order add le_less_trans: linorder "op = :: 'a => 'a => bool" "op <=" "op <"]
   625 
   626 declare order_trans [order add le_trans: linorder "op = :: 'a => 'a => bool" "op <=" "op <"]
   627 
   628 declare le_neq_trans [order add le_neq_trans: linorder "op = :: 'a => 'a => bool" "op <=" "op <"]
   629 
   630 declare neq_le_trans [order add neq_le_trans: linorder "op = :: 'a => 'a => bool" "op <=" "op <"]
   631 
   632 declare less_imp_neq [order add less_imp_neq: linorder "op = :: 'a => 'a => bool" "op <=" "op <"]
   633 
   634 declare eq_neq_eq_imp_neq [order add eq_neq_eq_imp_neq: linorder "op = :: 'a => 'a => bool" "op <=" "op <"]
   635 
   636 declare not_sym [order add not_sym: linorder "op = :: 'a => 'a => bool" "op <=" "op <"]
   637 
   638 end
   639 
   640 setup \<open>
   641   map_theory_simpset (fn ctxt0 => ctxt0 addSolver
   642     mk_solver "Transitivity" (fn ctxt => Orders.order_tac ctxt (Simplifier.prems_of ctxt)))
   643   (*Adding the transitivity reasoners also as safe solvers showed a slight
   644     speed up, but the reasoning strength appears to be not higher (at least
   645     no breaking of additional proofs in the entire HOL distribution, as
   646     of 5 March 2004, was observed).*)
   647 \<close>
   648 
   649 ML \<open>
   650 local
   651   fun prp t thm = Thm.prop_of thm = t;  (* FIXME proper aconv!? *)
   652 in
   653 
   654 fun antisym_le_simproc ctxt ct =
   655   (case Thm.term_of ct of
   656     (le as Const (_, T)) $ r $ s =>
   657      (let
   658         val prems = Simplifier.prems_of ctxt;
   659         val less = Const (@{const_name less}, T);
   660         val t = HOLogic.mk_Trueprop(le $ s $ r);
   661       in
   662         (case find_first (prp t) prems of
   663           NONE =>
   664             let val t = HOLogic.mk_Trueprop(HOLogic.Not $ (less $ r $ s)) in
   665               (case find_first (prp t) prems of
   666                 NONE => NONE
   667               | SOME thm => SOME(mk_meta_eq(thm RS @{thm linorder_class.antisym_conv1})))
   668              end
   669          | SOME thm => SOME (mk_meta_eq (thm RS @{thm order_class.antisym_conv})))
   670       end handle THM _ => NONE)
   671   | _ => NONE);
   672 
   673 fun antisym_less_simproc ctxt ct =
   674   (case Thm.term_of ct of
   675     NotC $ ((less as Const(_,T)) $ r $ s) =>
   676      (let
   677        val prems = Simplifier.prems_of ctxt;
   678        val le = Const (@{const_name less_eq}, T);
   679        val t = HOLogic.mk_Trueprop(le $ r $ s);
   680       in
   681         (case find_first (prp t) prems of
   682           NONE =>
   683             let val t = HOLogic.mk_Trueprop (NotC $ (less $ s $ r)) in
   684               (case find_first (prp t) prems of
   685                 NONE => NONE
   686               | SOME thm => SOME (mk_meta_eq(thm RS @{thm linorder_class.antisym_conv3})))
   687             end
   688         | SOME thm => SOME (mk_meta_eq (thm RS @{thm linorder_class.antisym_conv2})))
   689       end handle THM _ => NONE)
   690   | _ => NONE);
   691 
   692 end;
   693 \<close>
   694 
   695 simproc_setup antisym_le ("(x::'a::order) \<le> y") = "K antisym_le_simproc"
   696 simproc_setup antisym_less ("\<not> (x::'a::linorder) < y") = "K antisym_less_simproc"
   697 
   698 
   699 subsection \<open>Bounded quantifiers\<close>
   700 
   701 syntax (ASCII)
   702   "_All_less" :: "[idt, 'a, bool] => bool"    ("(3ALL _<_./ _)"  [0, 0, 10] 10)
   703   "_Ex_less" :: "[idt, 'a, bool] => bool"    ("(3EX _<_./ _)"  [0, 0, 10] 10)
   704   "_All_less_eq" :: "[idt, 'a, bool] => bool"    ("(3ALL _<=_./ _)" [0, 0, 10] 10)
   705   "_Ex_less_eq" :: "[idt, 'a, bool] => bool"    ("(3EX _<=_./ _)" [0, 0, 10] 10)
   706 
   707   "_All_greater" :: "[idt, 'a, bool] => bool"    ("(3ALL _>_./ _)"  [0, 0, 10] 10)
   708   "_Ex_greater" :: "[idt, 'a, bool] => bool"    ("(3EX _>_./ _)"  [0, 0, 10] 10)
   709   "_All_greater_eq" :: "[idt, 'a, bool] => bool"    ("(3ALL _>=_./ _)" [0, 0, 10] 10)
   710   "_Ex_greater_eq" :: "[idt, 'a, bool] => bool"    ("(3EX _>=_./ _)" [0, 0, 10] 10)
   711 
   712 syntax
   713   "_All_less" :: "[idt, 'a, bool] => bool"    ("(3\<forall>_<_./ _)"  [0, 0, 10] 10)
   714   "_Ex_less" :: "[idt, 'a, bool] => bool"    ("(3\<exists>_<_./ _)"  [0, 0, 10] 10)
   715   "_All_less_eq" :: "[idt, 'a, bool] => bool"    ("(3\<forall>_\<le>_./ _)" [0, 0, 10] 10)
   716   "_Ex_less_eq" :: "[idt, 'a, bool] => bool"    ("(3\<exists>_\<le>_./ _)" [0, 0, 10] 10)
   717 
   718   "_All_greater" :: "[idt, 'a, bool] => bool"    ("(3\<forall>_>_./ _)"  [0, 0, 10] 10)
   719   "_Ex_greater" :: "[idt, 'a, bool] => bool"    ("(3\<exists>_>_./ _)"  [0, 0, 10] 10)
   720   "_All_greater_eq" :: "[idt, 'a, bool] => bool"    ("(3\<forall>_\<ge>_./ _)" [0, 0, 10] 10)
   721   "_Ex_greater_eq" :: "[idt, 'a, bool] => bool"    ("(3\<exists>_\<ge>_./ _)" [0, 0, 10] 10)
   722 
   723 syntax (input)
   724   "_All_less" :: "[idt, 'a, bool] => bool"    ("(3! _<_./ _)"  [0, 0, 10] 10)
   725   "_Ex_less" :: "[idt, 'a, bool] => bool"    ("(3? _<_./ _)"  [0, 0, 10] 10)
   726   "_All_less_eq" :: "[idt, 'a, bool] => bool"    ("(3! _<=_./ _)" [0, 0, 10] 10)
   727   "_Ex_less_eq" :: "[idt, 'a, bool] => bool"    ("(3? _<=_./ _)" [0, 0, 10] 10)
   728 
   729 translations
   730   "ALL x<y. P"   =>  "ALL x. x < y \<longrightarrow> P"
   731   "EX x<y. P"    =>  "EX x. x < y \<and> P"
   732   "ALL x<=y. P"  =>  "ALL x. x <= y \<longrightarrow> P"
   733   "EX x<=y. P"   =>  "EX x. x <= y \<and> P"
   734   "ALL x>y. P"   =>  "ALL x. x > y \<longrightarrow> P"
   735   "EX x>y. P"    =>  "EX x. x > y \<and> P"
   736   "ALL x>=y. P"  =>  "ALL x. x >= y \<longrightarrow> P"
   737   "EX x>=y. P"   =>  "EX x. x >= y \<and> P"
   738 
   739 print_translation \<open>
   740 let
   741   val All_binder = Mixfix.binder_name @{const_syntax All};
   742   val Ex_binder = Mixfix.binder_name @{const_syntax Ex};
   743   val impl = @{const_syntax HOL.implies};
   744   val conj = @{const_syntax HOL.conj};
   745   val less = @{const_syntax less};
   746   val less_eq = @{const_syntax less_eq};
   747 
   748   val trans =
   749    [((All_binder, impl, less),
   750     (@{syntax_const "_All_less"}, @{syntax_const "_All_greater"})),
   751     ((All_binder, impl, less_eq),
   752     (@{syntax_const "_All_less_eq"}, @{syntax_const "_All_greater_eq"})),
   753     ((Ex_binder, conj, less),
   754     (@{syntax_const "_Ex_less"}, @{syntax_const "_Ex_greater"})),
   755     ((Ex_binder, conj, less_eq),
   756     (@{syntax_const "_Ex_less_eq"}, @{syntax_const "_Ex_greater_eq"}))];
   757 
   758   fun matches_bound v t =
   759     (case t of
   760       Const (@{syntax_const "_bound"}, _) $ Free (v', _) => v = v'
   761     | _ => false);
   762   fun contains_var v = Term.exists_subterm (fn Free (x, _) => x = v | _ => false);
   763   fun mk x c n P = Syntax.const c $ Syntax_Trans.mark_bound_body x $ n $ P;
   764 
   765   fun tr' q = (q, fn _ =>
   766     (fn [Const (@{syntax_const "_bound"}, _) $ Free (v, T),
   767         Const (c, _) $ (Const (d, _) $ t $ u) $ P] =>
   768         (case AList.lookup (op =) trans (q, c, d) of
   769           NONE => raise Match
   770         | SOME (l, g) =>
   771             if matches_bound v t andalso not (contains_var v u) then mk (v, T) l u P
   772             else if matches_bound v u andalso not (contains_var v t) then mk (v, T) g t P
   773             else raise Match)
   774       | _ => raise Match));
   775 in [tr' All_binder, tr' Ex_binder] end
   776 \<close>
   777 
   778 
   779 subsection \<open>Transitivity reasoning\<close>
   780 
   781 context ord
   782 begin
   783 
   784 lemma ord_le_eq_trans: "a \<le> b \<Longrightarrow> b = c \<Longrightarrow> a \<le> c"
   785   by (rule subst)
   786 
   787 lemma ord_eq_le_trans: "a = b \<Longrightarrow> b \<le> c \<Longrightarrow> a \<le> c"
   788   by (rule ssubst)
   789 
   790 lemma ord_less_eq_trans: "a < b \<Longrightarrow> b = c \<Longrightarrow> a < c"
   791   by (rule subst)
   792 
   793 lemma ord_eq_less_trans: "a = b \<Longrightarrow> b < c \<Longrightarrow> a < c"
   794   by (rule ssubst)
   795 
   796 end
   797 
   798 lemma order_less_subst2: "(a::'a::order) < b ==> f b < (c::'c::order) ==>
   799   (!!x y. x < y ==> f x < f y) ==> f a < c"
   800 proof -
   801   assume r: "!!x y. x < y ==> f x < f y"
   802   assume "a < b" hence "f a < f b" by (rule r)
   803   also assume "f b < c"
   804   finally (less_trans) show ?thesis .
   805 qed
   806 
   807 lemma order_less_subst1: "(a::'a::order) < f b ==> (b::'b::order) < c ==>
   808   (!!x y. x < y ==> f x < f y) ==> a < f c"
   809 proof -
   810   assume r: "!!x y. x < y ==> f x < f y"
   811   assume "a < f b"
   812   also assume "b < c" hence "f b < f c" by (rule r)
   813   finally (less_trans) show ?thesis .
   814 qed
   815 
   816 lemma order_le_less_subst2: "(a::'a::order) <= b ==> f b < (c::'c::order) ==>
   817   (!!x y. x <= y ==> f x <= f y) ==> f a < c"
   818 proof -
   819   assume r: "!!x y. x <= y ==> f x <= f y"
   820   assume "a <= b" hence "f a <= f b" by (rule r)
   821   also assume "f b < c"
   822   finally (le_less_trans) show ?thesis .
   823 qed
   824 
   825 lemma order_le_less_subst1: "(a::'a::order) <= f b ==> (b::'b::order) < c ==>
   826   (!!x y. x < y ==> f x < f y) ==> a < f c"
   827 proof -
   828   assume r: "!!x y. x < y ==> f x < f y"
   829   assume "a <= f b"
   830   also assume "b < c" hence "f b < f c" by (rule r)
   831   finally (le_less_trans) show ?thesis .
   832 qed
   833 
   834 lemma order_less_le_subst2: "(a::'a::order) < b ==> f b <= (c::'c::order) ==>
   835   (!!x y. x < y ==> f x < f y) ==> f a < c"
   836 proof -
   837   assume r: "!!x y. x < y ==> f x < f y"
   838   assume "a < b" hence "f a < f b" by (rule r)
   839   also assume "f b <= c"
   840   finally (less_le_trans) show ?thesis .
   841 qed
   842 
   843 lemma order_less_le_subst1: "(a::'a::order) < f b ==> (b::'b::order) <= c ==>
   844   (!!x y. x <= y ==> f x <= f y) ==> a < f c"
   845 proof -
   846   assume r: "!!x y. x <= y ==> f x <= f y"
   847   assume "a < f b"
   848   also assume "b <= c" hence "f b <= f c" by (rule r)
   849   finally (less_le_trans) show ?thesis .
   850 qed
   851 
   852 lemma order_subst1: "(a::'a::order) <= f b ==> (b::'b::order) <= c ==>
   853   (!!x y. x <= y ==> f x <= f y) ==> a <= f c"
   854 proof -
   855   assume r: "!!x y. x <= y ==> f x <= f y"
   856   assume "a <= f b"
   857   also assume "b <= c" hence "f b <= f c" by (rule r)
   858   finally (order_trans) show ?thesis .
   859 qed
   860 
   861 lemma order_subst2: "(a::'a::order) <= b ==> f b <= (c::'c::order) ==>
   862   (!!x y. x <= y ==> f x <= f y) ==> f a <= c"
   863 proof -
   864   assume r: "!!x y. x <= y ==> f x <= f y"
   865   assume "a <= b" hence "f a <= f b" by (rule r)
   866   also assume "f b <= c"
   867   finally (order_trans) show ?thesis .
   868 qed
   869 
   870 lemma ord_le_eq_subst: "a <= b ==> f b = c ==>
   871   (!!x y. x <= y ==> f x <= f y) ==> f a <= c"
   872 proof -
   873   assume r: "!!x y. x <= y ==> f x <= f y"
   874   assume "a <= b" hence "f a <= f b" by (rule r)
   875   also assume "f b = c"
   876   finally (ord_le_eq_trans) show ?thesis .
   877 qed
   878 
   879 lemma ord_eq_le_subst: "a = f b ==> b <= c ==>
   880   (!!x y. x <= y ==> f x <= f y) ==> a <= f c"
   881 proof -
   882   assume r: "!!x y. x <= y ==> f x <= f y"
   883   assume "a = f b"
   884   also assume "b <= c" hence "f b <= f c" by (rule r)
   885   finally (ord_eq_le_trans) show ?thesis .
   886 qed
   887 
   888 lemma ord_less_eq_subst: "a < b ==> f b = c ==>
   889   (!!x y. x < y ==> f x < f y) ==> f a < c"
   890 proof -
   891   assume r: "!!x y. x < y ==> f x < f y"
   892   assume "a < b" hence "f a < f b" by (rule r)
   893   also assume "f b = c"
   894   finally (ord_less_eq_trans) show ?thesis .
   895 qed
   896 
   897 lemma ord_eq_less_subst: "a = f b ==> b < c ==>
   898   (!!x y. x < y ==> f x < f y) ==> a < f c"
   899 proof -
   900   assume r: "!!x y. x < y ==> f x < f y"
   901   assume "a = f b"
   902   also assume "b < c" hence "f b < f c" by (rule r)
   903   finally (ord_eq_less_trans) show ?thesis .
   904 qed
   905 
   906 text \<open>
   907   Note that this list of rules is in reverse order of priorities.
   908 \<close>
   909 
   910 lemmas [trans] =
   911   order_less_subst2
   912   order_less_subst1
   913   order_le_less_subst2
   914   order_le_less_subst1
   915   order_less_le_subst2
   916   order_less_le_subst1
   917   order_subst2
   918   order_subst1
   919   ord_le_eq_subst
   920   ord_eq_le_subst
   921   ord_less_eq_subst
   922   ord_eq_less_subst
   923   forw_subst
   924   back_subst
   925   rev_mp
   926   mp
   927 
   928 lemmas (in order) [trans] =
   929   neq_le_trans
   930   le_neq_trans
   931 
   932 lemmas (in preorder) [trans] =
   933   less_trans
   934   less_asym'
   935   le_less_trans
   936   less_le_trans
   937   order_trans
   938 
   939 lemmas (in order) [trans] =
   940   antisym
   941 
   942 lemmas (in ord) [trans] =
   943   ord_le_eq_trans
   944   ord_eq_le_trans
   945   ord_less_eq_trans
   946   ord_eq_less_trans
   947 
   948 lemmas [trans] =
   949   trans
   950 
   951 lemmas order_trans_rules =
   952   order_less_subst2
   953   order_less_subst1
   954   order_le_less_subst2
   955   order_le_less_subst1
   956   order_less_le_subst2
   957   order_less_le_subst1
   958   order_subst2
   959   order_subst1
   960   ord_le_eq_subst
   961   ord_eq_le_subst
   962   ord_less_eq_subst
   963   ord_eq_less_subst
   964   forw_subst
   965   back_subst
   966   rev_mp
   967   mp
   968   neq_le_trans
   969   le_neq_trans
   970   less_trans
   971   less_asym'
   972   le_less_trans
   973   less_le_trans
   974   order_trans
   975   antisym
   976   ord_le_eq_trans
   977   ord_eq_le_trans
   978   ord_less_eq_trans
   979   ord_eq_less_trans
   980   trans
   981 
   982 text \<open>These support proving chains of decreasing inequalities
   983     a >= b >= c ... in Isar proofs.\<close>
   984 
   985 lemma xt1 [no_atp]:
   986   "a = b ==> b > c ==> a > c"
   987   "a > b ==> b = c ==> a > c"
   988   "a = b ==> b >= c ==> a >= c"
   989   "a >= b ==> b = c ==> a >= c"
   990   "(x::'a::order) >= y ==> y >= x ==> x = y"
   991   "(x::'a::order) >= y ==> y >= z ==> x >= z"
   992   "(x::'a::order) > y ==> y >= z ==> x > z"
   993   "(x::'a::order) >= y ==> y > z ==> x > z"
   994   "(a::'a::order) > b ==> b > a ==> P"
   995   "(x::'a::order) > y ==> y > z ==> x > z"
   996   "(a::'a::order) >= b ==> a ~= b ==> a > b"
   997   "(a::'a::order) ~= b ==> a >= b ==> a > b"
   998   "a = f b ==> b > c ==> (!!x y. x > y ==> f x > f y) ==> a > f c"
   999   "a > b ==> f b = c ==> (!!x y. x > y ==> f x > f y) ==> f a > c"
  1000   "a = f b ==> b >= c ==> (!!x y. x >= y ==> f x >= f y) ==> a >= f c"
  1001   "a >= b ==> f b = c ==> (!! x y. x >= y ==> f x >= f y) ==> f a >= c"
  1002   by auto
  1003 
  1004 lemma xt2 [no_atp]:
  1005   "(a::'a::order) >= f b ==> b >= c ==> (!!x y. x >= y ==> f x >= f y) ==> a >= f c"
  1006 by (subgoal_tac "f b >= f c", force, force)
  1007 
  1008 lemma xt3 [no_atp]: "(a::'a::order) >= b ==> (f b::'b::order) >= c ==>
  1009     (!!x y. x >= y ==> f x >= f y) ==> f a >= c"
  1010 by (subgoal_tac "f a >= f b", force, force)
  1011 
  1012 lemma xt4 [no_atp]: "(a::'a::order) > f b ==> (b::'b::order) >= c ==>
  1013   (!!x y. x >= y ==> f x >= f y) ==> a > f c"
  1014 by (subgoal_tac "f b >= f c", force, force)
  1015 
  1016 lemma xt5 [no_atp]: "(a::'a::order) > b ==> (f b::'b::order) >= c==>
  1017     (!!x y. x > y ==> f x > f y) ==> f a > c"
  1018 by (subgoal_tac "f a > f b", force, force)
  1019 
  1020 lemma xt6 [no_atp]: "(a::'a::order) >= f b ==> b > c ==>
  1021     (!!x y. x > y ==> f x > f y) ==> a > f c"
  1022 by (subgoal_tac "f b > f c", force, force)
  1023 
  1024 lemma xt7 [no_atp]: "(a::'a::order) >= b ==> (f b::'b::order) > c ==>
  1025     (!!x y. x >= y ==> f x >= f y) ==> f a > c"
  1026 by (subgoal_tac "f a >= f b", force, force)
  1027 
  1028 lemma xt8 [no_atp]: "(a::'a::order) > f b ==> (b::'b::order) > c ==>
  1029     (!!x y. x > y ==> f x > f y) ==> a > f c"
  1030 by (subgoal_tac "f b > f c", force, force)
  1031 
  1032 lemma xt9 [no_atp]: "(a::'a::order) > b ==> (f b::'b::order) > c ==>
  1033     (!!x y. x > y ==> f x > f y) ==> f a > c"
  1034 by (subgoal_tac "f a > f b", force, force)
  1035 
  1036 lemmas xtrans = xt1 xt2 xt3 xt4 xt5 xt6 xt7 xt8 xt9
  1037 
  1038 (*
  1039   Since "a >= b" abbreviates "b <= a", the abbreviation "..." stands
  1040   for the wrong thing in an Isar proof.
  1041 
  1042   The extra transitivity rules can be used as follows:
  1043 
  1044 lemma "(a::'a::order) > z"
  1045 proof -
  1046   have "a >= b" (is "_ >= ?rhs")
  1047     sorry
  1048   also have "?rhs >= c" (is "_ >= ?rhs")
  1049     sorry
  1050   also (xtrans) have "?rhs = d" (is "_ = ?rhs")
  1051     sorry
  1052   also (xtrans) have "?rhs >= e" (is "_ >= ?rhs")
  1053     sorry
  1054   also (xtrans) have "?rhs > f" (is "_ > ?rhs")
  1055     sorry
  1056   also (xtrans) have "?rhs > z"
  1057     sorry
  1058   finally (xtrans) show ?thesis .
  1059 qed
  1060 
  1061   Alternatively, one can use "declare xtrans [trans]" and then
  1062   leave out the "(xtrans)" above.
  1063 *)
  1064 
  1065 
  1066 subsection \<open>Monotonicity\<close>
  1067 
  1068 context order
  1069 begin
  1070 
  1071 definition mono :: "('a \<Rightarrow> 'b::order) \<Rightarrow> bool" where
  1072   "mono f \<longleftrightarrow> (\<forall>x y. x \<le> y \<longrightarrow> f x \<le> f y)"
  1073 
  1074 lemma monoI [intro?]:
  1075   fixes f :: "'a \<Rightarrow> 'b::order"
  1076   shows "(\<And>x y. x \<le> y \<Longrightarrow> f x \<le> f y) \<Longrightarrow> mono f"
  1077   unfolding mono_def by iprover
  1078 
  1079 lemma monoD [dest?]:
  1080   fixes f :: "'a \<Rightarrow> 'b::order"
  1081   shows "mono f \<Longrightarrow> x \<le> y \<Longrightarrow> f x \<le> f y"
  1082   unfolding mono_def by iprover
  1083 
  1084 lemma monoE:
  1085   fixes f :: "'a \<Rightarrow> 'b::order"
  1086   assumes "mono f"
  1087   assumes "x \<le> y"
  1088   obtains "f x \<le> f y"
  1089 proof
  1090   from assms show "f x \<le> f y" by (simp add: mono_def)
  1091 qed
  1092 
  1093 definition antimono :: "('a \<Rightarrow> 'b::order) \<Rightarrow> bool" where
  1094   "antimono f \<longleftrightarrow> (\<forall>x y. x \<le> y \<longrightarrow> f x \<ge> f y)"
  1095 
  1096 lemma antimonoI [intro?]:
  1097   fixes f :: "'a \<Rightarrow> 'b::order"
  1098   shows "(\<And>x y. x \<le> y \<Longrightarrow> f x \<ge> f y) \<Longrightarrow> antimono f"
  1099   unfolding antimono_def by iprover
  1100 
  1101 lemma antimonoD [dest?]:
  1102   fixes f :: "'a \<Rightarrow> 'b::order"
  1103   shows "antimono f \<Longrightarrow> x \<le> y \<Longrightarrow> f x \<ge> f y"
  1104   unfolding antimono_def by iprover
  1105 
  1106 lemma antimonoE:
  1107   fixes f :: "'a \<Rightarrow> 'b::order"
  1108   assumes "antimono f"
  1109   assumes "x \<le> y"
  1110   obtains "f x \<ge> f y"
  1111 proof
  1112   from assms show "f x \<ge> f y" by (simp add: antimono_def)
  1113 qed
  1114 
  1115 definition strict_mono :: "('a \<Rightarrow> 'b::order) \<Rightarrow> bool" where
  1116   "strict_mono f \<longleftrightarrow> (\<forall>x y. x < y \<longrightarrow> f x < f y)"
  1117 
  1118 lemma strict_monoI [intro?]:
  1119   assumes "\<And>x y. x < y \<Longrightarrow> f x < f y"
  1120   shows "strict_mono f"
  1121   using assms unfolding strict_mono_def by auto
  1122 
  1123 lemma strict_monoD [dest?]:
  1124   "strict_mono f \<Longrightarrow> x < y \<Longrightarrow> f x < f y"
  1125   unfolding strict_mono_def by auto
  1126 
  1127 lemma strict_mono_mono [dest?]:
  1128   assumes "strict_mono f"
  1129   shows "mono f"
  1130 proof (rule monoI)
  1131   fix x y
  1132   assume "x \<le> y"
  1133   show "f x \<le> f y"
  1134   proof (cases "x = y")
  1135     case True then show ?thesis by simp
  1136   next
  1137     case False with \<open>x \<le> y\<close> have "x < y" by simp
  1138     with assms strict_monoD have "f x < f y" by auto
  1139     then show ?thesis by simp
  1140   qed
  1141 qed
  1142 
  1143 end
  1144 
  1145 context linorder
  1146 begin
  1147 
  1148 lemma mono_invE:
  1149   fixes f :: "'a \<Rightarrow> 'b::order"
  1150   assumes "mono f"
  1151   assumes "f x < f y"
  1152   obtains "x \<le> y"
  1153 proof
  1154   show "x \<le> y"
  1155   proof (rule ccontr)
  1156     assume "\<not> x \<le> y"
  1157     then have "y \<le> x" by simp
  1158     with \<open>mono f\<close> obtain "f y \<le> f x" by (rule monoE)
  1159     with \<open>f x < f y\<close> show False by simp
  1160   qed
  1161 qed
  1162 
  1163 lemma strict_mono_eq:
  1164   assumes "strict_mono f"
  1165   shows "f x = f y \<longleftrightarrow> x = y"
  1166 proof
  1167   assume "f x = f y"
  1168   show "x = y" proof (cases x y rule: linorder_cases)
  1169     case less with assms strict_monoD have "f x < f y" by auto
  1170     with \<open>f x = f y\<close> show ?thesis by simp
  1171   next
  1172     case equal then show ?thesis .
  1173   next
  1174     case greater with assms strict_monoD have "f y < f x" by auto
  1175     with \<open>f x = f y\<close> show ?thesis by simp
  1176   qed
  1177 qed simp
  1178 
  1179 lemma strict_mono_less_eq:
  1180   assumes "strict_mono f"
  1181   shows "f x \<le> f y \<longleftrightarrow> x \<le> y"
  1182 proof
  1183   assume "x \<le> y"
  1184   with assms strict_mono_mono monoD show "f x \<le> f y" by auto
  1185 next
  1186   assume "f x \<le> f y"
  1187   show "x \<le> y" proof (rule ccontr)
  1188     assume "\<not> x \<le> y" then have "y < x" by simp
  1189     with assms strict_monoD have "f y < f x" by auto
  1190     with \<open>f x \<le> f y\<close> show False by simp
  1191   qed
  1192 qed
  1193 
  1194 lemma strict_mono_less:
  1195   assumes "strict_mono f"
  1196   shows "f x < f y \<longleftrightarrow> x < y"
  1197   using assms
  1198     by (auto simp add: less_le Orderings.less_le strict_mono_eq strict_mono_less_eq)
  1199 
  1200 end
  1201 
  1202 
  1203 subsection \<open>min and max -- fundamental\<close>
  1204 
  1205 definition (in ord) min :: "'a \<Rightarrow> 'a \<Rightarrow> 'a" where
  1206   "min a b = (if a \<le> b then a else b)"
  1207 
  1208 definition (in ord) max :: "'a \<Rightarrow> 'a \<Rightarrow> 'a" where
  1209   "max a b = (if a \<le> b then b else a)"
  1210 
  1211 lemma min_absorb1: "x \<le> y \<Longrightarrow> min x y = x"
  1212   by (simp add: min_def)
  1213 
  1214 lemma max_absorb2: "x \<le> y \<Longrightarrow> max x y = y"
  1215   by (simp add: max_def)
  1216 
  1217 lemma min_absorb2: "(y::'a::order) \<le> x \<Longrightarrow> min x y = y"
  1218   by (simp add:min_def)
  1219 
  1220 lemma max_absorb1: "(y::'a::order) \<le> x \<Longrightarrow> max x y = x"
  1221   by (simp add: max_def)
  1222 
  1223 lemma max_min_same [simp]:
  1224   fixes x y :: "'a :: linorder"
  1225   shows "max x (min x y) = x" "max (min x y) x = x" "max (min x y) y = y" "max y (min x y) = y"
  1226 by(auto simp add: max_def min_def)
  1227 
  1228 subsection \<open>(Unique) top and bottom elements\<close>
  1229 
  1230 class bot =
  1231   fixes bot :: 'a ("\<bottom>")
  1232 
  1233 class order_bot = order + bot +
  1234   assumes bot_least: "\<bottom> \<le> a"
  1235 begin
  1236 
  1237 sublocale bot: ordering_top greater_eq greater bot
  1238   by standard (fact bot_least)
  1239 
  1240 lemma le_bot:
  1241   "a \<le> \<bottom> \<Longrightarrow> a = \<bottom>"
  1242   by (fact bot.extremum_uniqueI)
  1243 
  1244 lemma bot_unique:
  1245   "a \<le> \<bottom> \<longleftrightarrow> a = \<bottom>"
  1246   by (fact bot.extremum_unique)
  1247 
  1248 lemma not_less_bot:
  1249   "\<not> a < \<bottom>"
  1250   by (fact bot.extremum_strict)
  1251 
  1252 lemma bot_less:
  1253   "a \<noteq> \<bottom> \<longleftrightarrow> \<bottom> < a"
  1254   by (fact bot.not_eq_extremum)
  1255 
  1256 end
  1257 
  1258 class top =
  1259   fixes top :: 'a ("\<top>")
  1260 
  1261 class order_top = order + top +
  1262   assumes top_greatest: "a \<le> \<top>"
  1263 begin
  1264 
  1265 sublocale top: ordering_top less_eq less top
  1266   by standard (fact top_greatest)
  1267 
  1268 lemma top_le:
  1269   "\<top> \<le> a \<Longrightarrow> a = \<top>"
  1270   by (fact top.extremum_uniqueI)
  1271 
  1272 lemma top_unique:
  1273   "\<top> \<le> a \<longleftrightarrow> a = \<top>"
  1274   by (fact top.extremum_unique)
  1275 
  1276 lemma not_top_less:
  1277   "\<not> \<top> < a"
  1278   by (fact top.extremum_strict)
  1279 
  1280 lemma less_top:
  1281   "a \<noteq> \<top> \<longleftrightarrow> a < \<top>"
  1282   by (fact top.not_eq_extremum)
  1283 
  1284 end
  1285 
  1286 
  1287 subsection \<open>Dense orders\<close>
  1288 
  1289 class dense_order = order +
  1290   assumes dense: "x < y \<Longrightarrow> (\<exists>z. x < z \<and> z < y)"
  1291 
  1292 class dense_linorder = linorder + dense_order
  1293 begin
  1294 
  1295 lemma dense_le:
  1296   fixes y z :: 'a
  1297   assumes "\<And>x. x < y \<Longrightarrow> x \<le> z"
  1298   shows "y \<le> z"
  1299 proof (rule ccontr)
  1300   assume "\<not> ?thesis"
  1301   hence "z < y" by simp
  1302   from dense[OF this]
  1303   obtain x where "x < y" and "z < x" by safe
  1304   moreover have "x \<le> z" using assms[OF \<open>x < y\<close>] .
  1305   ultimately show False by auto
  1306 qed
  1307 
  1308 lemma dense_le_bounded:
  1309   fixes x y z :: 'a
  1310   assumes "x < y"
  1311   assumes *: "\<And>w. \<lbrakk> x < w ; w < y \<rbrakk> \<Longrightarrow> w \<le> z"
  1312   shows "y \<le> z"
  1313 proof (rule dense_le)
  1314   fix w assume "w < y"
  1315   from dense[OF \<open>x < y\<close>] obtain u where "x < u" "u < y" by safe
  1316   from linear[of u w]
  1317   show "w \<le> z"
  1318   proof (rule disjE)
  1319     assume "u \<le> w"
  1320     from less_le_trans[OF \<open>x < u\<close> \<open>u \<le> w\<close>] \<open>w < y\<close>
  1321     show "w \<le> z" by (rule *)
  1322   next
  1323     assume "w \<le> u"
  1324     from \<open>w \<le> u\<close> *[OF \<open>x < u\<close> \<open>u < y\<close>]
  1325     show "w \<le> z" by (rule order_trans)
  1326   qed
  1327 qed
  1328 
  1329 lemma dense_ge:
  1330   fixes y z :: 'a
  1331   assumes "\<And>x. z < x \<Longrightarrow> y \<le> x"
  1332   shows "y \<le> z"
  1333 proof (rule ccontr)
  1334   assume "\<not> ?thesis"
  1335   hence "z < y" by simp
  1336   from dense[OF this]
  1337   obtain x where "x < y" and "z < x" by safe
  1338   moreover have "y \<le> x" using assms[OF \<open>z < x\<close>] .
  1339   ultimately show False by auto
  1340 qed
  1341 
  1342 lemma dense_ge_bounded:
  1343   fixes x y z :: 'a
  1344   assumes "z < x"
  1345   assumes *: "\<And>w. \<lbrakk> z < w ; w < x \<rbrakk> \<Longrightarrow> y \<le> w"
  1346   shows "y \<le> z"
  1347 proof (rule dense_ge)
  1348   fix w assume "z < w"
  1349   from dense[OF \<open>z < x\<close>] obtain u where "z < u" "u < x" by safe
  1350   from linear[of u w]
  1351   show "y \<le> w"
  1352   proof (rule disjE)
  1353     assume "w \<le> u"
  1354     from \<open>z < w\<close> le_less_trans[OF \<open>w \<le> u\<close> \<open>u < x\<close>]
  1355     show "y \<le> w" by (rule *)
  1356   next
  1357     assume "u \<le> w"
  1358     from *[OF \<open>z < u\<close> \<open>u < x\<close>] \<open>u \<le> w\<close>
  1359     show "y \<le> w" by (rule order_trans)
  1360   qed
  1361 qed
  1362 
  1363 end
  1364 
  1365 class no_top = order +
  1366   assumes gt_ex: "\<exists>y. x < y"
  1367 
  1368 class no_bot = order +
  1369   assumes lt_ex: "\<exists>y. y < x"
  1370 
  1371 class unbounded_dense_linorder = dense_linorder + no_top + no_bot
  1372 
  1373 
  1374 subsection \<open>Wellorders\<close>
  1375 
  1376 class wellorder = linorder +
  1377   assumes less_induct [case_names less]: "(\<And>x. (\<And>y. y < x \<Longrightarrow> P y) \<Longrightarrow> P x) \<Longrightarrow> P a"
  1378 begin
  1379 
  1380 lemma wellorder_Least_lemma:
  1381   fixes k :: 'a
  1382   assumes "P k"
  1383   shows LeastI: "P (LEAST x. P x)" and Least_le: "(LEAST x. P x) \<le> k"
  1384 proof -
  1385   have "P (LEAST x. P x) \<and> (LEAST x. P x) \<le> k"
  1386   using assms proof (induct k rule: less_induct)
  1387     case (less x) then have "P x" by simp
  1388     show ?case proof (rule classical)
  1389       assume assm: "\<not> (P (LEAST a. P a) \<and> (LEAST a. P a) \<le> x)"
  1390       have "\<And>y. P y \<Longrightarrow> x \<le> y"
  1391       proof (rule classical)
  1392         fix y
  1393         assume "P y" and "\<not> x \<le> y"
  1394         with less have "P (LEAST a. P a)" and "(LEAST a. P a) \<le> y"
  1395           by (auto simp add: not_le)
  1396         with assm have "x < (LEAST a. P a)" and "(LEAST a. P a) \<le> y"
  1397           by auto
  1398         then show "x \<le> y" by auto
  1399       qed
  1400       with \<open>P x\<close> have Least: "(LEAST a. P a) = x"
  1401         by (rule Least_equality)
  1402       with \<open>P x\<close> show ?thesis by simp
  1403     qed
  1404   qed
  1405   then show "P (LEAST x. P x)" and "(LEAST x. P x) \<le> k" by auto
  1406 qed
  1407 
  1408 \<comment> "The following 3 lemmas are due to Brian Huffman"
  1409 lemma LeastI_ex: "\<exists>x. P x \<Longrightarrow> P (Least P)"
  1410   by (erule exE) (erule LeastI)
  1411 
  1412 lemma LeastI2:
  1413   "P a \<Longrightarrow> (\<And>x. P x \<Longrightarrow> Q x) \<Longrightarrow> Q (Least P)"
  1414   by (blast intro: LeastI)
  1415 
  1416 lemma LeastI2_ex:
  1417   "\<exists>a. P a \<Longrightarrow> (\<And>x. P x \<Longrightarrow> Q x) \<Longrightarrow> Q (Least P)"
  1418   by (blast intro: LeastI_ex)
  1419 
  1420 lemma LeastI2_wellorder:
  1421   assumes "P a"
  1422   and "\<And>a. \<lbrakk> P a; \<forall>b. P b \<longrightarrow> a \<le> b \<rbrakk> \<Longrightarrow> Q a"
  1423   shows "Q (Least P)"
  1424 proof (rule LeastI2_order)
  1425   show "P (Least P)" using \<open>P a\<close> by (rule LeastI)
  1426 next
  1427   fix y assume "P y" thus "Least P \<le> y" by (rule Least_le)
  1428 next
  1429   fix x assume "P x" "\<forall>y. P y \<longrightarrow> x \<le> y" thus "Q x" by (rule assms(2))
  1430 qed
  1431 
  1432 lemma LeastI2_wellorder_ex:
  1433   assumes "\<exists>x. P x"
  1434   and "\<And>a. \<lbrakk> P a; \<forall>b. P b \<longrightarrow> a \<le> b \<rbrakk> \<Longrightarrow> Q a"
  1435   shows "Q (Least P)"
  1436 using assms by clarify (blast intro!: LeastI2_wellorder)
  1437 
  1438 lemma not_less_Least: "k < (LEAST x. P x) \<Longrightarrow> \<not> P k"
  1439 apply (simp add: not_le [symmetric])
  1440 apply (erule contrapos_nn)
  1441 apply (erule Least_le)
  1442 done
  1443 
  1444 lemma exists_least_iff: "(\<exists>n. P n) \<longleftrightarrow> (\<exists>n. P n \<and> (\<forall>m < n. \<not> P m))" (is "?lhs \<longleftrightarrow> ?rhs")
  1445 proof
  1446   assume ?rhs thus ?lhs by blast
  1447 next
  1448   assume H: ?lhs then obtain n where n: "P n" by blast
  1449   let ?x = "Least P"
  1450   { fix m assume m: "m < ?x"
  1451     from not_less_Least[OF m] have "\<not> P m" . }
  1452   with LeastI_ex[OF H] show ?rhs by blast
  1453 qed
  1454 
  1455 end
  1456 
  1457 
  1458 subsection \<open>Order on @{typ bool}\<close>
  1459 
  1460 instantiation bool :: "{order_bot, order_top, linorder}"
  1461 begin
  1462 
  1463 definition
  1464   le_bool_def [simp]: "P \<le> Q \<longleftrightarrow> P \<longrightarrow> Q"
  1465 
  1466 definition
  1467   [simp]: "(P::bool) < Q \<longleftrightarrow> \<not> P \<and> Q"
  1468 
  1469 definition
  1470   [simp]: "\<bottom> \<longleftrightarrow> False"
  1471 
  1472 definition
  1473   [simp]: "\<top> \<longleftrightarrow> True"
  1474 
  1475 instance proof
  1476 qed auto
  1477 
  1478 end
  1479 
  1480 lemma le_boolI: "(P \<Longrightarrow> Q) \<Longrightarrow> P \<le> Q"
  1481   by simp
  1482 
  1483 lemma le_boolI': "P \<longrightarrow> Q \<Longrightarrow> P \<le> Q"
  1484   by simp
  1485 
  1486 lemma le_boolE: "P \<le> Q \<Longrightarrow> P \<Longrightarrow> (Q \<Longrightarrow> R) \<Longrightarrow> R"
  1487   by simp
  1488 
  1489 lemma le_boolD: "P \<le> Q \<Longrightarrow> P \<longrightarrow> Q"
  1490   by simp
  1491 
  1492 lemma bot_boolE: "\<bottom> \<Longrightarrow> P"
  1493   by simp
  1494 
  1495 lemma top_boolI: \<top>
  1496   by simp
  1497 
  1498 lemma [code]:
  1499   "False \<le> b \<longleftrightarrow> True"
  1500   "True \<le> b \<longleftrightarrow> b"
  1501   "False < b \<longleftrightarrow> b"
  1502   "True < b \<longleftrightarrow> False"
  1503   by simp_all
  1504 
  1505 
  1506 subsection \<open>Order on @{typ "_ \<Rightarrow> _"}\<close>
  1507 
  1508 instantiation "fun" :: (type, ord) ord
  1509 begin
  1510 
  1511 definition
  1512   le_fun_def: "f \<le> g \<longleftrightarrow> (\<forall>x. f x \<le> g x)"
  1513 
  1514 definition
  1515   "(f::'a \<Rightarrow> 'b) < g \<longleftrightarrow> f \<le> g \<and> \<not> (g \<le> f)"
  1516 
  1517 instance ..
  1518 
  1519 end
  1520 
  1521 instance "fun" :: (type, preorder) preorder proof
  1522 qed (auto simp add: le_fun_def less_fun_def
  1523   intro: order_trans antisym)
  1524 
  1525 instance "fun" :: (type, order) order proof
  1526 qed (auto simp add: le_fun_def intro: antisym)
  1527 
  1528 instantiation "fun" :: (type, bot) bot
  1529 begin
  1530 
  1531 definition
  1532   "\<bottom> = (\<lambda>x. \<bottom>)"
  1533 
  1534 instance ..
  1535 
  1536 end
  1537 
  1538 instantiation "fun" :: (type, order_bot) order_bot
  1539 begin
  1540 
  1541 lemma bot_apply [simp, code]:
  1542   "\<bottom> x = \<bottom>"
  1543   by (simp add: bot_fun_def)
  1544 
  1545 instance proof
  1546 qed (simp add: le_fun_def)
  1547 
  1548 end
  1549 
  1550 instantiation "fun" :: (type, top) top
  1551 begin
  1552 
  1553 definition
  1554   [no_atp]: "\<top> = (\<lambda>x. \<top>)"
  1555 
  1556 instance ..
  1557 
  1558 end
  1559 
  1560 instantiation "fun" :: (type, order_top) order_top
  1561 begin
  1562 
  1563 lemma top_apply [simp, code]:
  1564   "\<top> x = \<top>"
  1565   by (simp add: top_fun_def)
  1566 
  1567 instance proof
  1568 qed (simp add: le_fun_def)
  1569 
  1570 end
  1571 
  1572 lemma le_funI: "(\<And>x. f x \<le> g x) \<Longrightarrow> f \<le> g"
  1573   unfolding le_fun_def by simp
  1574 
  1575 lemma le_funE: "f \<le> g \<Longrightarrow> (f x \<le> g x \<Longrightarrow> P) \<Longrightarrow> P"
  1576   unfolding le_fun_def by simp
  1577 
  1578 lemma le_funD: "f \<le> g \<Longrightarrow> f x \<le> g x"
  1579   by (rule le_funE)
  1580 
  1581 lemma mono_compose: "mono Q \<Longrightarrow> mono (\<lambda>i x. Q i (f x))"
  1582   unfolding mono_def le_fun_def by auto
  1583 
  1584 
  1585 subsection \<open>Order on unary and binary predicates\<close>
  1586 
  1587 lemma predicate1I:
  1588   assumes PQ: "\<And>x. P x \<Longrightarrow> Q x"
  1589   shows "P \<le> Q"
  1590   apply (rule le_funI)
  1591   apply (rule le_boolI)
  1592   apply (rule PQ)
  1593   apply assumption
  1594   done
  1595 
  1596 lemma predicate1D:
  1597   "P \<le> Q \<Longrightarrow> P x \<Longrightarrow> Q x"
  1598   apply (erule le_funE)
  1599   apply (erule le_boolE)
  1600   apply assumption+
  1601   done
  1602 
  1603 lemma rev_predicate1D:
  1604   "P x \<Longrightarrow> P \<le> Q \<Longrightarrow> Q x"
  1605   by (rule predicate1D)
  1606 
  1607 lemma predicate2I:
  1608   assumes PQ: "\<And>x y. P x y \<Longrightarrow> Q x y"
  1609   shows "P \<le> Q"
  1610   apply (rule le_funI)+
  1611   apply (rule le_boolI)
  1612   apply (rule PQ)
  1613   apply assumption
  1614   done
  1615 
  1616 lemma predicate2D:
  1617   "P \<le> Q \<Longrightarrow> P x y \<Longrightarrow> Q x y"
  1618   apply (erule le_funE)+
  1619   apply (erule le_boolE)
  1620   apply assumption+
  1621   done
  1622 
  1623 lemma rev_predicate2D:
  1624   "P x y \<Longrightarrow> P \<le> Q \<Longrightarrow> Q x y"
  1625   by (rule predicate2D)
  1626 
  1627 lemma bot1E [no_atp]: "\<bottom> x \<Longrightarrow> P"
  1628   by (simp add: bot_fun_def)
  1629 
  1630 lemma bot2E: "\<bottom> x y \<Longrightarrow> P"
  1631   by (simp add: bot_fun_def)
  1632 
  1633 lemma top1I: "\<top> x"
  1634   by (simp add: top_fun_def)
  1635 
  1636 lemma top2I: "\<top> x y"
  1637   by (simp add: top_fun_def)
  1638 
  1639 
  1640 subsection \<open>Name duplicates\<close>
  1641 
  1642 lemmas order_eq_refl = preorder_class.eq_refl
  1643 lemmas order_less_irrefl = preorder_class.less_irrefl
  1644 lemmas order_less_imp_le = preorder_class.less_imp_le
  1645 lemmas order_less_not_sym = preorder_class.less_not_sym
  1646 lemmas order_less_asym = preorder_class.less_asym
  1647 lemmas order_less_trans = preorder_class.less_trans
  1648 lemmas order_le_less_trans = preorder_class.le_less_trans
  1649 lemmas order_less_le_trans = preorder_class.less_le_trans
  1650 lemmas order_less_imp_not_less = preorder_class.less_imp_not_less
  1651 lemmas order_less_imp_triv = preorder_class.less_imp_triv
  1652 lemmas order_less_asym' = preorder_class.less_asym'
  1653 
  1654 lemmas order_less_le = order_class.less_le
  1655 lemmas order_le_less = order_class.le_less
  1656 lemmas order_le_imp_less_or_eq = order_class.le_imp_less_or_eq
  1657 lemmas order_less_imp_not_eq = order_class.less_imp_not_eq
  1658 lemmas order_less_imp_not_eq2 = order_class.less_imp_not_eq2
  1659 lemmas order_neq_le_trans = order_class.neq_le_trans
  1660 lemmas order_le_neq_trans = order_class.le_neq_trans
  1661 lemmas order_antisym = order_class.antisym
  1662 lemmas order_eq_iff = order_class.eq_iff
  1663 lemmas order_antisym_conv = order_class.antisym_conv
  1664 
  1665 lemmas linorder_linear = linorder_class.linear
  1666 lemmas linorder_less_linear = linorder_class.less_linear
  1667 lemmas linorder_le_less_linear = linorder_class.le_less_linear
  1668 lemmas linorder_le_cases = linorder_class.le_cases
  1669 lemmas linorder_not_less = linorder_class.not_less
  1670 lemmas linorder_not_le = linorder_class.not_le
  1671 lemmas linorder_neq_iff = linorder_class.neq_iff
  1672 lemmas linorder_neqE = linorder_class.neqE
  1673 lemmas linorder_antisym_conv1 = linorder_class.antisym_conv1
  1674 lemmas linorder_antisym_conv2 = linorder_class.antisym_conv2
  1675 lemmas linorder_antisym_conv3 = linorder_class.antisym_conv3
  1676 
  1677 end