src/HOL/Real_Vector_Spaces.thy
author paulson <lp15@cam.ac.uk>
Tue Apr 25 16:39:54 2017 +0100 (2017-04-25)
changeset 65578 e4997c181cce
parent 65036 ab7e11730ad8
child 65583 8d53b3bebab4
permissions -rw-r--r--
New material from PNT proof, as well as more default [simp] declarations. Also removed duplicate theorems about geometric series
     1 (*  Title:      HOL/Real_Vector_Spaces.thy
     2     Author:     Brian Huffman
     3     Author:     Johannes Hölzl
     4 *)
     5 
     6 section \<open>Vector Spaces and Algebras over the Reals\<close>
     7 
     8 theory Real_Vector_Spaces
     9 imports Real Topological_Spaces
    10 begin
    11 
    12 subsection \<open>Locale for additive functions\<close>
    13 
    14 locale additive =
    15   fixes f :: "'a::ab_group_add \<Rightarrow> 'b::ab_group_add"
    16   assumes add: "f (x + y) = f x + f y"
    17 begin
    18 
    19 lemma zero: "f 0 = 0"
    20 proof -
    21   have "f 0 = f (0 + 0)" by simp
    22   also have "\<dots> = f 0 + f 0" by (rule add)
    23   finally show "f 0 = 0" by simp
    24 qed
    25 
    26 lemma minus: "f (- x) = - f x"
    27 proof -
    28   have "f (- x) + f x = f (- x + x)" by (rule add [symmetric])
    29   also have "\<dots> = - f x + f x" by (simp add: zero)
    30   finally show "f (- x) = - f x" by (rule add_right_imp_eq)
    31 qed
    32 
    33 lemma diff: "f (x - y) = f x - f y"
    34   using add [of x "- y"] by (simp add: minus)
    35 
    36 lemma sum: "f (sum g A) = (\<Sum>x\<in>A. f (g x))"
    37   by (induct A rule: infinite_finite_induct) (simp_all add: zero add)
    38 
    39 end
    40 
    41 
    42 subsection \<open>Vector spaces\<close>
    43 
    44 locale vector_space =
    45   fixes scale :: "'a::field \<Rightarrow> 'b::ab_group_add \<Rightarrow> 'b"
    46   assumes scale_right_distrib [algebra_simps]: "scale a (x + y) = scale a x + scale a y"
    47     and scale_left_distrib [algebra_simps]: "scale (a + b) x = scale a x + scale b x"
    48     and scale_scale [simp]: "scale a (scale b x) = scale (a * b) x"
    49     and scale_one [simp]: "scale 1 x = x"
    50 begin
    51 
    52 lemma scale_left_commute: "scale a (scale b x) = scale b (scale a x)"
    53   by (simp add: mult.commute)
    54 
    55 lemma scale_zero_left [simp]: "scale 0 x = 0"
    56   and scale_minus_left [simp]: "scale (- a) x = - (scale a x)"
    57   and scale_left_diff_distrib [algebra_simps]: "scale (a - b) x = scale a x - scale b x"
    58   and scale_sum_left: "scale (sum f A) x = (\<Sum>a\<in>A. scale (f a) x)"
    59 proof -
    60   interpret s: additive "\<lambda>a. scale a x"
    61     by standard (rule scale_left_distrib)
    62   show "scale 0 x = 0" by (rule s.zero)
    63   show "scale (- a) x = - (scale a x)" by (rule s.minus)
    64   show "scale (a - b) x = scale a x - scale b x" by (rule s.diff)
    65   show "scale (sum f A) x = (\<Sum>a\<in>A. scale (f a) x)" by (rule s.sum)
    66 qed
    67 
    68 lemma scale_zero_right [simp]: "scale a 0 = 0"
    69   and scale_minus_right [simp]: "scale a (- x) = - (scale a x)"
    70   and scale_right_diff_distrib [algebra_simps]: "scale a (x - y) = scale a x - scale a y"
    71   and scale_sum_right: "scale a (sum f A) = (\<Sum>x\<in>A. scale a (f x))"
    72 proof -
    73   interpret s: additive "\<lambda>x. scale a x"
    74     by standard (rule scale_right_distrib)
    75   show "scale a 0 = 0" by (rule s.zero)
    76   show "scale a (- x) = - (scale a x)" by (rule s.minus)
    77   show "scale a (x - y) = scale a x - scale a y" by (rule s.diff)
    78   show "scale a (sum f A) = (\<Sum>x\<in>A. scale a (f x))" by (rule s.sum)
    79 qed
    80 
    81 lemma scale_eq_0_iff [simp]: "scale a x = 0 \<longleftrightarrow> a = 0 \<or> x = 0"
    82 proof (cases "a = 0")
    83   case True
    84   then show ?thesis by simp
    85 next
    86   case False
    87   have "x = 0" if "scale a x = 0"
    88   proof -
    89     from False that have "scale (inverse a) (scale a x) = 0" by simp
    90     with False show ?thesis by simp
    91   qed
    92   then show ?thesis by force
    93 qed
    94 
    95 lemma scale_left_imp_eq:
    96   assumes nonzero: "a \<noteq> 0"
    97     and scale: "scale a x = scale a y"
    98   shows "x = y"
    99 proof -
   100   from scale have "scale a (x - y) = 0"
   101      by (simp add: scale_right_diff_distrib)
   102   with nonzero have "x - y = 0" by simp
   103   then show "x = y" by (simp only: right_minus_eq)
   104 qed
   105 
   106 lemma scale_right_imp_eq:
   107   assumes nonzero: "x \<noteq> 0"
   108     and scale: "scale a x = scale b x"
   109   shows "a = b"
   110 proof -
   111   from scale have "scale (a - b) x = 0"
   112      by (simp add: scale_left_diff_distrib)
   113   with nonzero have "a - b = 0" by simp
   114   then show "a = b" by (simp only: right_minus_eq)
   115 qed
   116 
   117 lemma scale_cancel_left [simp]: "scale a x = scale a y \<longleftrightarrow> x = y \<or> a = 0"
   118   by (auto intro: scale_left_imp_eq)
   119 
   120 lemma scale_cancel_right [simp]: "scale a x = scale b x \<longleftrightarrow> a = b \<or> x = 0"
   121   by (auto intro: scale_right_imp_eq)
   122 
   123 end
   124 
   125 
   126 subsection \<open>Real vector spaces\<close>
   127 
   128 class scaleR =
   129   fixes scaleR :: "real \<Rightarrow> 'a \<Rightarrow> 'a" (infixr "*\<^sub>R" 75)
   130 begin
   131 
   132 abbreviation divideR :: "'a \<Rightarrow> real \<Rightarrow> 'a"  (infixl "'/\<^sub>R" 70)
   133   where "x /\<^sub>R r \<equiv> scaleR (inverse r) x"
   134 
   135 end
   136 
   137 class real_vector = scaleR + ab_group_add +
   138   assumes scaleR_add_right: "scaleR a (x + y) = scaleR a x + scaleR a y"
   139   and scaleR_add_left: "scaleR (a + b) x = scaleR a x + scaleR b x"
   140   and scaleR_scaleR: "scaleR a (scaleR b x) = scaleR (a * b) x"
   141   and scaleR_one: "scaleR 1 x = x"
   142 
   143 interpretation real_vector: vector_space "scaleR :: real \<Rightarrow> 'a \<Rightarrow> 'a::real_vector"
   144   apply unfold_locales
   145      apply (rule scaleR_add_right)
   146     apply (rule scaleR_add_left)
   147    apply (rule scaleR_scaleR)
   148   apply (rule scaleR_one)
   149   done
   150 
   151 text \<open>Recover original theorem names\<close>
   152 
   153 lemmas scaleR_left_commute = real_vector.scale_left_commute
   154 lemmas scaleR_zero_left = real_vector.scale_zero_left
   155 lemmas scaleR_minus_left = real_vector.scale_minus_left
   156 lemmas scaleR_diff_left = real_vector.scale_left_diff_distrib
   157 lemmas scaleR_sum_left = real_vector.scale_sum_left
   158 lemmas scaleR_zero_right = real_vector.scale_zero_right
   159 lemmas scaleR_minus_right = real_vector.scale_minus_right
   160 lemmas scaleR_diff_right = real_vector.scale_right_diff_distrib
   161 lemmas scaleR_sum_right = real_vector.scale_sum_right
   162 lemmas scaleR_eq_0_iff = real_vector.scale_eq_0_iff
   163 lemmas scaleR_left_imp_eq = real_vector.scale_left_imp_eq
   164 lemmas scaleR_right_imp_eq = real_vector.scale_right_imp_eq
   165 lemmas scaleR_cancel_left = real_vector.scale_cancel_left
   166 lemmas scaleR_cancel_right = real_vector.scale_cancel_right
   167 
   168 text \<open>Legacy names\<close>
   169 
   170 lemmas scaleR_left_distrib = scaleR_add_left
   171 lemmas scaleR_right_distrib = scaleR_add_right
   172 lemmas scaleR_left_diff_distrib = scaleR_diff_left
   173 lemmas scaleR_right_diff_distrib = scaleR_diff_right
   174 
   175 lemma scaleR_minus1_left [simp]: "scaleR (-1) x = - x"
   176   for x :: "'a::real_vector"
   177   using scaleR_minus_left [of 1 x] by simp
   178 
   179 lemma scaleR_2:
   180   fixes x :: "'a::real_vector"
   181   shows "scaleR 2 x = x + x"
   182   unfolding one_add_one [symmetric] scaleR_left_distrib by simp
   183 
   184 lemma scaleR_half_double [simp]:
   185   fixes a :: "'a::real_vector"
   186   shows "(1 / 2) *\<^sub>R (a + a) = a"
   187 proof -
   188   have "\<And>r. r *\<^sub>R (a + a) = (r * 2) *\<^sub>R a"
   189     by (metis scaleR_2 scaleR_scaleR)
   190   then show ?thesis
   191     by simp
   192 qed
   193 
   194 class real_algebra = real_vector + ring +
   195   assumes mult_scaleR_left [simp]: "scaleR a x * y = scaleR a (x * y)"
   196     and mult_scaleR_right [simp]: "x * scaleR a y = scaleR a (x * y)"
   197 
   198 class real_algebra_1 = real_algebra + ring_1
   199 
   200 class real_div_algebra = real_algebra_1 + division_ring
   201 
   202 class real_field = real_div_algebra + field
   203 
   204 instantiation real :: real_field
   205 begin
   206 
   207 definition real_scaleR_def [simp]: "scaleR a x = a * x"
   208 
   209 instance
   210   by standard (simp_all add: algebra_simps)
   211 
   212 end
   213 
   214 interpretation scaleR_left: additive "(\<lambda>a. scaleR a x :: 'a::real_vector)"
   215   by standard (rule scaleR_left_distrib)
   216 
   217 interpretation scaleR_right: additive "(\<lambda>x. scaleR a x :: 'a::real_vector)"
   218   by standard (rule scaleR_right_distrib)
   219 
   220 lemma nonzero_inverse_scaleR_distrib:
   221   "a \<noteq> 0 \<Longrightarrow> x \<noteq> 0 \<Longrightarrow> inverse (scaleR a x) = scaleR (inverse a) (inverse x)"
   222   for x :: "'a::real_div_algebra"
   223   by (rule inverse_unique) simp
   224 
   225 lemma inverse_scaleR_distrib: "inverse (scaleR a x) = scaleR (inverse a) (inverse x)"
   226   for x :: "'a::{real_div_algebra,division_ring}"
   227   apply (cases "a = 0")
   228    apply simp
   229   apply (cases "x = 0")
   230    apply simp
   231   apply (erule (1) nonzero_inverse_scaleR_distrib)
   232   done
   233 
   234 lemma sum_constant_scaleR: "(\<Sum>x\<in>A. y) = of_nat (card A) *\<^sub>R y"
   235   for y :: "'a::real_vector"
   236   by (induct A rule: infinite_finite_induct) (simp_all add: algebra_simps)
   237 
   238 named_theorems vector_add_divide_simps "to simplify sums of scaled vectors"
   239 
   240 lemma [vector_add_divide_simps]:
   241   "v + (b / z) *\<^sub>R w = (if z = 0 then v else (z *\<^sub>R v + b *\<^sub>R w) /\<^sub>R z)"
   242   "a *\<^sub>R v + (b / z) *\<^sub>R w = (if z = 0 then a *\<^sub>R v else ((a * z) *\<^sub>R v + b *\<^sub>R w) /\<^sub>R z)"
   243   "(a / z) *\<^sub>R v + w = (if z = 0 then w else (a *\<^sub>R v + z *\<^sub>R w) /\<^sub>R z)"
   244   "(a / z) *\<^sub>R v + b *\<^sub>R w = (if z = 0 then b *\<^sub>R w else (a *\<^sub>R v + (b * z) *\<^sub>R w) /\<^sub>R z)"
   245   "v - (b / z) *\<^sub>R w = (if z = 0 then v else (z *\<^sub>R v - b *\<^sub>R w) /\<^sub>R z)"
   246   "a *\<^sub>R v - (b / z) *\<^sub>R w = (if z = 0 then a *\<^sub>R v else ((a * z) *\<^sub>R v - b *\<^sub>R w) /\<^sub>R z)"
   247   "(a / z) *\<^sub>R v - w = (if z = 0 then -w else (a *\<^sub>R v - z *\<^sub>R w) /\<^sub>R z)"
   248   "(a / z) *\<^sub>R v - b *\<^sub>R w = (if z = 0 then -b *\<^sub>R w else (a *\<^sub>R v - (b * z) *\<^sub>R w) /\<^sub>R z)"
   249   for v :: "'a :: real_vector"
   250   by (simp_all add: divide_inverse_commute scaleR_add_right real_vector.scale_right_diff_distrib)
   251 
   252 
   253 lemma eq_vector_fraction_iff [vector_add_divide_simps]:
   254   fixes x :: "'a :: real_vector"
   255   shows "(x = (u / v) *\<^sub>R a) \<longleftrightarrow> (if v=0 then x = 0 else v *\<^sub>R x = u *\<^sub>R a)"
   256 by auto (metis (no_types) divide_eq_1_iff divide_inverse_commute scaleR_one scaleR_scaleR)
   257 
   258 lemma vector_fraction_eq_iff [vector_add_divide_simps]:
   259   fixes x :: "'a :: real_vector"
   260   shows "((u / v) *\<^sub>R a = x) \<longleftrightarrow> (if v=0 then x = 0 else u *\<^sub>R a = v *\<^sub>R x)"
   261 by (metis eq_vector_fraction_iff)
   262 
   263 lemma real_vector_affinity_eq:
   264   fixes x :: "'a :: real_vector"
   265   assumes m0: "m \<noteq> 0"
   266   shows "m *\<^sub>R x + c = y \<longleftrightarrow> x = inverse m *\<^sub>R y - (inverse m *\<^sub>R c)"
   267     (is "?lhs \<longleftrightarrow> ?rhs")
   268 proof
   269   assume ?lhs
   270   then have "m *\<^sub>R x = y - c" by (simp add: field_simps)
   271   then have "inverse m *\<^sub>R (m *\<^sub>R x) = inverse m *\<^sub>R (y - c)" by simp
   272   then show "x = inverse m *\<^sub>R y - (inverse m *\<^sub>R c)"
   273     using m0
   274   by (simp add: real_vector.scale_right_diff_distrib)
   275 next
   276   assume ?rhs
   277   with m0 show "m *\<^sub>R x + c = y"
   278     by (simp add: real_vector.scale_right_diff_distrib)
   279 qed
   280 
   281 lemma real_vector_eq_affinity: "m \<noteq> 0 \<Longrightarrow> y = m *\<^sub>R x + c \<longleftrightarrow> inverse m *\<^sub>R y - (inverse m *\<^sub>R c) = x"
   282   for x :: "'a::real_vector"
   283   using real_vector_affinity_eq[where m=m and x=x and y=y and c=c]
   284   by metis
   285 
   286 lemma scaleR_eq_iff [simp]: "b + u *\<^sub>R a = a + u *\<^sub>R b \<longleftrightarrow> a = b \<or> u = 1"
   287   for a :: "'a::real_vector"
   288 proof (cases "u = 1")
   289   case True
   290   then show ?thesis by auto
   291 next
   292   case False
   293   have "a = b" if "b + u *\<^sub>R a = a + u *\<^sub>R b"
   294   proof -
   295     from that have "(u - 1) *\<^sub>R a = (u - 1) *\<^sub>R b"
   296       by (simp add: algebra_simps)
   297     with False show ?thesis
   298       by auto
   299   qed
   300   then show ?thesis by auto
   301 qed
   302 
   303 lemma scaleR_collapse [simp]: "(1 - u) *\<^sub>R a + u *\<^sub>R a = a"
   304   for a :: "'a::real_vector"
   305   by (simp add: algebra_simps)
   306 
   307 
   308 subsection \<open>Embedding of the Reals into any \<open>real_algebra_1\<close>: \<open>of_real\<close>\<close>
   309 
   310 definition of_real :: "real \<Rightarrow> 'a::real_algebra_1"
   311   where "of_real r = scaleR r 1"
   312 
   313 lemma scaleR_conv_of_real: "scaleR r x = of_real r * x"
   314   by (simp add: of_real_def)
   315 
   316 lemma of_real_0 [simp]: "of_real 0 = 0"
   317   by (simp add: of_real_def)
   318 
   319 lemma of_real_1 [simp]: "of_real 1 = 1"
   320   by (simp add: of_real_def)
   321 
   322 lemma of_real_add [simp]: "of_real (x + y) = of_real x + of_real y"
   323   by (simp add: of_real_def scaleR_left_distrib)
   324 
   325 lemma of_real_minus [simp]: "of_real (- x) = - of_real x"
   326   by (simp add: of_real_def)
   327 
   328 lemma of_real_diff [simp]: "of_real (x - y) = of_real x - of_real y"
   329   by (simp add: of_real_def scaleR_left_diff_distrib)
   330 
   331 lemma of_real_mult [simp]: "of_real (x * y) = of_real x * of_real y"
   332   by (simp add: of_real_def mult.commute)
   333 
   334 lemma of_real_sum[simp]: "of_real (sum f s) = (\<Sum>x\<in>s. of_real (f x))"
   335   by (induct s rule: infinite_finite_induct) auto
   336 
   337 lemma of_real_prod[simp]: "of_real (prod f s) = (\<Prod>x\<in>s. of_real (f x))"
   338   by (induct s rule: infinite_finite_induct) auto
   339 
   340 lemma nonzero_of_real_inverse:
   341   "x \<noteq> 0 \<Longrightarrow> of_real (inverse x) = inverse (of_real x :: 'a::real_div_algebra)"
   342   by (simp add: of_real_def nonzero_inverse_scaleR_distrib)
   343 
   344 lemma of_real_inverse [simp]:
   345   "of_real (inverse x) = inverse (of_real x :: 'a::{real_div_algebra,division_ring})"
   346   by (simp add: of_real_def inverse_scaleR_distrib)
   347 
   348 lemma nonzero_of_real_divide:
   349   "y \<noteq> 0 \<Longrightarrow> of_real (x / y) = (of_real x / of_real y :: 'a::real_field)"
   350   by (simp add: divide_inverse nonzero_of_real_inverse)
   351 
   352 lemma of_real_divide [simp]:
   353   "of_real (x / y) = (of_real x / of_real y :: 'a::real_div_algebra)"
   354   by (simp add: divide_inverse)
   355 
   356 lemma of_real_power [simp]:
   357   "of_real (x ^ n) = (of_real x :: 'a::{real_algebra_1}) ^ n"
   358   by (induct n) simp_all
   359 
   360 lemma of_real_eq_iff [simp]: "of_real x = of_real y \<longleftrightarrow> x = y"
   361   by (simp add: of_real_def)
   362 
   363 lemma inj_of_real: "inj of_real"
   364   by (auto intro: injI)
   365 
   366 lemmas of_real_eq_0_iff [simp] = of_real_eq_iff [of _ 0, simplified]
   367 lemmas of_real_eq_1_iff [simp] = of_real_eq_iff [of _ 1, simplified]
   368 
   369 lemma of_real_eq_id [simp]: "of_real = (id :: real \<Rightarrow> real)"
   370   by (rule ext) (simp add: of_real_def)
   371 
   372 text \<open>Collapse nested embeddings.\<close>
   373 lemma of_real_of_nat_eq [simp]: "of_real (of_nat n) = of_nat n"
   374   by (induct n) auto
   375 
   376 lemma of_real_of_int_eq [simp]: "of_real (of_int z) = of_int z"
   377   by (cases z rule: int_diff_cases) simp
   378 
   379 lemma of_real_numeral [simp]: "of_real (numeral w) = numeral w"
   380   using of_real_of_int_eq [of "numeral w"] by simp
   381 
   382 lemma of_real_neg_numeral [simp]: "of_real (- numeral w) = - numeral w"
   383   using of_real_of_int_eq [of "- numeral w"] by simp
   384 
   385 text \<open>Every real algebra has characteristic zero.\<close>
   386 instance real_algebra_1 < ring_char_0
   387 proof
   388   from inj_of_real inj_of_nat have "inj (of_real \<circ> of_nat)"
   389     by (rule inj_comp)
   390   then show "inj (of_nat :: nat \<Rightarrow> 'a)"
   391     by (simp add: comp_def)
   392 qed
   393 
   394 lemma fraction_scaleR_times [simp]:
   395   fixes a :: "'a::real_algebra_1"
   396   shows "(numeral u / numeral v) *\<^sub>R (numeral w * a) = (numeral u * numeral w / numeral v) *\<^sub>R a"
   397 by (metis (no_types, lifting) of_real_numeral scaleR_conv_of_real scaleR_scaleR times_divide_eq_left)
   398 
   399 lemma inverse_scaleR_times [simp]:
   400   fixes a :: "'a::real_algebra_1"
   401   shows "(1 / numeral v) *\<^sub>R (numeral w * a) = (numeral w / numeral v) *\<^sub>R a"
   402 by (metis divide_inverse_commute inverse_eq_divide of_real_numeral scaleR_conv_of_real scaleR_scaleR)
   403 
   404 lemma scaleR_times [simp]:
   405   fixes a :: "'a::real_algebra_1"
   406   shows "(numeral u) *\<^sub>R (numeral w * a) = (numeral u * numeral w) *\<^sub>R a"
   407 by (simp add: scaleR_conv_of_real)
   408 
   409 instance real_field < field_char_0 ..
   410 
   411 
   412 subsection \<open>The Set of Real Numbers\<close>
   413 
   414 definition Reals :: "'a::real_algebra_1 set"  ("\<real>")
   415   where "\<real> = range of_real"
   416 
   417 lemma Reals_of_real [simp]: "of_real r \<in> \<real>"
   418   by (simp add: Reals_def)
   419 
   420 lemma Reals_of_int [simp]: "of_int z \<in> \<real>"
   421   by (subst of_real_of_int_eq [symmetric], rule Reals_of_real)
   422 
   423 lemma Reals_of_nat [simp]: "of_nat n \<in> \<real>"
   424   by (subst of_real_of_nat_eq [symmetric], rule Reals_of_real)
   425 
   426 lemma Reals_numeral [simp]: "numeral w \<in> \<real>"
   427   by (subst of_real_numeral [symmetric], rule Reals_of_real)
   428 
   429 lemma Reals_0 [simp]: "0 \<in> \<real>"
   430   apply (unfold Reals_def)
   431   apply (rule range_eqI)
   432   apply (rule of_real_0 [symmetric])
   433   done
   434 
   435 lemma Reals_1 [simp]: "1 \<in> \<real>"
   436   apply (unfold Reals_def)
   437   apply (rule range_eqI)
   438   apply (rule of_real_1 [symmetric])
   439   done
   440 
   441 lemma Reals_add [simp]: "a \<in> \<real> \<Longrightarrow> b \<in> \<real> \<Longrightarrow> a + b \<in> \<real>"
   442   apply (auto simp add: Reals_def)
   443   apply (rule range_eqI)
   444   apply (rule of_real_add [symmetric])
   445   done
   446 
   447 lemma Reals_minus [simp]: "a \<in> \<real> \<Longrightarrow> - a \<in> \<real>"
   448   apply (auto simp add: Reals_def)
   449   apply (rule range_eqI)
   450   apply (rule of_real_minus [symmetric])
   451   done
   452 
   453 lemma Reals_diff [simp]: "a \<in> \<real> \<Longrightarrow> b \<in> \<real> \<Longrightarrow> a - b \<in> \<real>"
   454   apply (auto simp add: Reals_def)
   455   apply (rule range_eqI)
   456   apply (rule of_real_diff [symmetric])
   457   done
   458 
   459 lemma Reals_mult [simp]: "a \<in> \<real> \<Longrightarrow> b \<in> \<real> \<Longrightarrow> a * b \<in> \<real>"
   460   apply (auto simp add: Reals_def)
   461   apply (rule range_eqI)
   462   apply (rule of_real_mult [symmetric])
   463   done
   464 
   465 lemma nonzero_Reals_inverse: "a \<in> \<real> \<Longrightarrow> a \<noteq> 0 \<Longrightarrow> inverse a \<in> \<real>"
   466   for a :: "'a::real_div_algebra"
   467   apply (auto simp add: Reals_def)
   468   apply (rule range_eqI)
   469   apply (erule nonzero_of_real_inverse [symmetric])
   470   done
   471 
   472 lemma Reals_inverse: "a \<in> \<real> \<Longrightarrow> inverse a \<in> \<real>"
   473   for a :: "'a::{real_div_algebra,division_ring}"
   474   apply (auto simp add: Reals_def)
   475   apply (rule range_eqI)
   476   apply (rule of_real_inverse [symmetric])
   477   done
   478 
   479 lemma Reals_inverse_iff [simp]: "inverse x \<in> \<real> \<longleftrightarrow> x \<in> \<real>"
   480   for x :: "'a::{real_div_algebra,division_ring}"
   481   by (metis Reals_inverse inverse_inverse_eq)
   482 
   483 lemma nonzero_Reals_divide: "a \<in> \<real> \<Longrightarrow> b \<in> \<real> \<Longrightarrow> b \<noteq> 0 \<Longrightarrow> a / b \<in> \<real>"
   484   for a b :: "'a::real_field"
   485   apply (auto simp add: Reals_def)
   486   apply (rule range_eqI)
   487   apply (erule nonzero_of_real_divide [symmetric])
   488   done
   489 
   490 lemma Reals_divide [simp]: "a \<in> \<real> \<Longrightarrow> b \<in> \<real> \<Longrightarrow> a / b \<in> \<real>"
   491   for a b :: "'a::{real_field,field}"
   492   apply (auto simp add: Reals_def)
   493   apply (rule range_eqI)
   494   apply (rule of_real_divide [symmetric])
   495   done
   496 
   497 lemma Reals_power [simp]: "a \<in> \<real> \<Longrightarrow> a ^ n \<in> \<real>"
   498   for a :: "'a::real_algebra_1"
   499   apply (auto simp add: Reals_def)
   500   apply (rule range_eqI)
   501   apply (rule of_real_power [symmetric])
   502   done
   503 
   504 lemma Reals_cases [cases set: Reals]:
   505   assumes "q \<in> \<real>"
   506   obtains (of_real) r where "q = of_real r"
   507   unfolding Reals_def
   508 proof -
   509   from \<open>q \<in> \<real>\<close> have "q \<in> range of_real" unfolding Reals_def .
   510   then obtain r where "q = of_real r" ..
   511   then show thesis ..
   512 qed
   513 
   514 lemma sum_in_Reals [intro,simp]: "(\<And>i. i \<in> s \<Longrightarrow> f i \<in> \<real>) \<Longrightarrow> sum f s \<in> \<real>"
   515 proof (induct s rule: infinite_finite_induct)
   516   case infinite
   517   then show ?case by (metis Reals_0 sum.infinite)
   518 qed simp_all
   519 
   520 lemma prod_in_Reals [intro,simp]: "(\<And>i. i \<in> s \<Longrightarrow> f i \<in> \<real>) \<Longrightarrow> prod f s \<in> \<real>"
   521 proof (induct s rule: infinite_finite_induct)
   522   case infinite
   523   then show ?case by (metis Reals_1 prod.infinite)
   524 qed simp_all
   525 
   526 lemma Reals_induct [case_names of_real, induct set: Reals]:
   527   "q \<in> \<real> \<Longrightarrow> (\<And>r. P (of_real r)) \<Longrightarrow> P q"
   528   by (rule Reals_cases) auto
   529 
   530 
   531 subsection \<open>Ordered real vector spaces\<close>
   532 
   533 class ordered_real_vector = real_vector + ordered_ab_group_add +
   534   assumes scaleR_left_mono: "x \<le> y \<Longrightarrow> 0 \<le> a \<Longrightarrow> a *\<^sub>R x \<le> a *\<^sub>R y"
   535     and scaleR_right_mono: "a \<le> b \<Longrightarrow> 0 \<le> x \<Longrightarrow> a *\<^sub>R x \<le> b *\<^sub>R x"
   536 begin
   537 
   538 lemma scaleR_mono: "a \<le> b \<Longrightarrow> x \<le> y \<Longrightarrow> 0 \<le> b \<Longrightarrow> 0 \<le> x \<Longrightarrow> a *\<^sub>R x \<le> b *\<^sub>R y"
   539   apply (erule scaleR_right_mono [THEN order_trans])
   540    apply assumption
   541   apply (erule scaleR_left_mono)
   542   apply assumption
   543   done
   544 
   545 lemma scaleR_mono': "a \<le> b \<Longrightarrow> c \<le> d \<Longrightarrow> 0 \<le> a \<Longrightarrow> 0 \<le> c \<Longrightarrow> a *\<^sub>R c \<le> b *\<^sub>R d"
   546   by (rule scaleR_mono) (auto intro: order.trans)
   547 
   548 lemma pos_le_divideRI:
   549   assumes "0 < c"
   550     and "c *\<^sub>R a \<le> b"
   551   shows "a \<le> b /\<^sub>R c"
   552 proof -
   553   from scaleR_left_mono[OF assms(2)] assms(1)
   554   have "c *\<^sub>R a /\<^sub>R c \<le> b /\<^sub>R c"
   555     by simp
   556   with assms show ?thesis
   557     by (simp add: scaleR_one scaleR_scaleR inverse_eq_divide)
   558 qed
   559 
   560 lemma pos_le_divideR_eq:
   561   assumes "0 < c"
   562   shows "a \<le> b /\<^sub>R c \<longleftrightarrow> c *\<^sub>R a \<le> b"
   563     (is "?lhs \<longleftrightarrow> ?rhs")
   564 proof
   565   assume ?lhs
   566   from scaleR_left_mono[OF this] assms have "c *\<^sub>R a \<le> c *\<^sub>R (b /\<^sub>R c)"
   567     by simp
   568   with assms show ?rhs
   569     by (simp add: scaleR_one scaleR_scaleR inverse_eq_divide)
   570 next
   571   assume ?rhs
   572   with assms show ?lhs by (rule pos_le_divideRI)
   573 qed
   574 
   575 lemma scaleR_image_atLeastAtMost: "c > 0 \<Longrightarrow> scaleR c ` {x..y} = {c *\<^sub>R x..c *\<^sub>R y}"
   576   apply (auto intro!: scaleR_left_mono)
   577   apply (rule_tac x = "inverse c *\<^sub>R xa" in image_eqI)
   578    apply (simp_all add: pos_le_divideR_eq[symmetric] scaleR_scaleR scaleR_one)
   579   done
   580 
   581 end
   582 
   583 lemma neg_le_divideR_eq:
   584   fixes a :: "'a :: ordered_real_vector"
   585   assumes "c < 0"
   586   shows "a \<le> b /\<^sub>R c \<longleftrightarrow> b \<le> c *\<^sub>R a"
   587   using pos_le_divideR_eq [of "-c" a "-b"] assms by simp
   588 
   589 lemma scaleR_nonneg_nonneg: "0 \<le> a \<Longrightarrow> 0 \<le> x \<Longrightarrow> 0 \<le> a *\<^sub>R x"
   590   for x :: "'a::ordered_real_vector"
   591   using scaleR_left_mono [of 0 x a] by simp
   592 
   593 lemma scaleR_nonneg_nonpos: "0 \<le> a \<Longrightarrow> x \<le> 0 \<Longrightarrow> a *\<^sub>R x \<le> 0"
   594   for x :: "'a::ordered_real_vector"
   595   using scaleR_left_mono [of x 0 a] by simp
   596 
   597 lemma scaleR_nonpos_nonneg: "a \<le> 0 \<Longrightarrow> 0 \<le> x \<Longrightarrow> a *\<^sub>R x \<le> 0"
   598   for x :: "'a::ordered_real_vector"
   599   using scaleR_right_mono [of a 0 x] by simp
   600 
   601 lemma split_scaleR_neg_le: "(0 \<le> a \<and> x \<le> 0) \<or> (a \<le> 0 \<and> 0 \<le> x) \<Longrightarrow> a *\<^sub>R x \<le> 0"
   602   for x :: "'a::ordered_real_vector"
   603   by (auto simp add: scaleR_nonneg_nonpos scaleR_nonpos_nonneg)
   604 
   605 lemma le_add_iff1: "a *\<^sub>R e + c \<le> b *\<^sub>R e + d \<longleftrightarrow> (a - b) *\<^sub>R e + c \<le> d"
   606   for c d e :: "'a::ordered_real_vector"
   607   by (simp add: algebra_simps)
   608 
   609 lemma le_add_iff2: "a *\<^sub>R e + c \<le> b *\<^sub>R e + d \<longleftrightarrow> c \<le> (b - a) *\<^sub>R e + d"
   610   for c d e :: "'a::ordered_real_vector"
   611   by (simp add: algebra_simps)
   612 
   613 lemma scaleR_left_mono_neg: "b \<le> a \<Longrightarrow> c \<le> 0 \<Longrightarrow> c *\<^sub>R a \<le> c *\<^sub>R b"
   614   for a b :: "'a::ordered_real_vector"
   615   apply (drule scaleR_left_mono [of _ _ "- c"])
   616    apply simp_all
   617   done
   618 
   619 lemma scaleR_right_mono_neg: "b \<le> a \<Longrightarrow> c \<le> 0 \<Longrightarrow> a *\<^sub>R c \<le> b *\<^sub>R c"
   620   for c :: "'a::ordered_real_vector"
   621   apply (drule scaleR_right_mono [of _ _ "- c"])
   622    apply simp_all
   623   done
   624 
   625 lemma scaleR_nonpos_nonpos: "a \<le> 0 \<Longrightarrow> b \<le> 0 \<Longrightarrow> 0 \<le> a *\<^sub>R b"
   626   for b :: "'a::ordered_real_vector"
   627   using scaleR_right_mono_neg [of a 0 b] by simp
   628 
   629 lemma split_scaleR_pos_le: "(0 \<le> a \<and> 0 \<le> b) \<or> (a \<le> 0 \<and> b \<le> 0) \<Longrightarrow> 0 \<le> a *\<^sub>R b"
   630   for b :: "'a::ordered_real_vector"
   631   by (auto simp add: scaleR_nonneg_nonneg scaleR_nonpos_nonpos)
   632 
   633 lemma zero_le_scaleR_iff:
   634   fixes b :: "'a::ordered_real_vector"
   635   shows "0 \<le> a *\<^sub>R b \<longleftrightarrow> 0 < a \<and> 0 \<le> b \<or> a < 0 \<and> b \<le> 0 \<or> a = 0"
   636     (is "?lhs = ?rhs")
   637 proof (cases "a = 0")
   638   case True
   639   then show ?thesis by simp
   640 next
   641   case False
   642   show ?thesis
   643   proof
   644     assume ?lhs
   645     from \<open>a \<noteq> 0\<close> consider "a > 0" | "a < 0" by arith
   646     then show ?rhs
   647     proof cases
   648       case 1
   649       with \<open>?lhs\<close> have "inverse a *\<^sub>R 0 \<le> inverse a *\<^sub>R (a *\<^sub>R b)"
   650         by (intro scaleR_mono) auto
   651       with 1 show ?thesis
   652         by simp
   653     next
   654       case 2
   655       with \<open>?lhs\<close> have "- inverse a *\<^sub>R 0 \<le> - inverse a *\<^sub>R (a *\<^sub>R b)"
   656         by (intro scaleR_mono) auto
   657       with 2 show ?thesis
   658         by simp
   659     qed
   660   next
   661     assume ?rhs
   662     then show ?lhs
   663       by (auto simp: not_le \<open>a \<noteq> 0\<close> intro!: split_scaleR_pos_le)
   664   qed
   665 qed
   666 
   667 lemma scaleR_le_0_iff: "a *\<^sub>R b \<le> 0 \<longleftrightarrow> 0 < a \<and> b \<le> 0 \<or> a < 0 \<and> 0 \<le> b \<or> a = 0"
   668   for b::"'a::ordered_real_vector"
   669   by (insert zero_le_scaleR_iff [of "-a" b]) force
   670 
   671 lemma scaleR_le_cancel_left: "c *\<^sub>R a \<le> c *\<^sub>R b \<longleftrightarrow> (0 < c \<longrightarrow> a \<le> b) \<and> (c < 0 \<longrightarrow> b \<le> a)"
   672   for b :: "'a::ordered_real_vector"
   673   by (auto simp add: neq_iff scaleR_left_mono scaleR_left_mono_neg
   674       dest: scaleR_left_mono[where a="inverse c"] scaleR_left_mono_neg[where c="inverse c"])
   675 
   676 lemma scaleR_le_cancel_left_pos: "0 < c \<Longrightarrow> c *\<^sub>R a \<le> c *\<^sub>R b \<longleftrightarrow> a \<le> b"
   677   for b :: "'a::ordered_real_vector"
   678   by (auto simp: scaleR_le_cancel_left)
   679 
   680 lemma scaleR_le_cancel_left_neg: "c < 0 \<Longrightarrow> c *\<^sub>R a \<le> c *\<^sub>R b \<longleftrightarrow> b \<le> a"
   681   for b :: "'a::ordered_real_vector"
   682   by (auto simp: scaleR_le_cancel_left)
   683 
   684 lemma scaleR_left_le_one_le: "0 \<le> x \<Longrightarrow> a \<le> 1 \<Longrightarrow> a *\<^sub>R x \<le> x"
   685   for x :: "'a::ordered_real_vector" and a :: real
   686   using scaleR_right_mono[of a 1 x] by simp
   687 
   688 
   689 subsection \<open>Real normed vector spaces\<close>
   690 
   691 class dist =
   692   fixes dist :: "'a \<Rightarrow> 'a \<Rightarrow> real"
   693 
   694 class norm =
   695   fixes norm :: "'a \<Rightarrow> real"
   696 
   697 class sgn_div_norm = scaleR + norm + sgn +
   698   assumes sgn_div_norm: "sgn x = x /\<^sub>R norm x"
   699 
   700 class dist_norm = dist + norm + minus +
   701   assumes dist_norm: "dist x y = norm (x - y)"
   702 
   703 class uniformity_dist = dist + uniformity +
   704   assumes uniformity_dist: "uniformity = (INF e:{0 <..}. principal {(x, y). dist x y < e})"
   705 begin
   706 
   707 lemma eventually_uniformity_metric:
   708   "eventually P uniformity \<longleftrightarrow> (\<exists>e>0. \<forall>x y. dist x y < e \<longrightarrow> P (x, y))"
   709   unfolding uniformity_dist
   710   by (subst eventually_INF_base)
   711      (auto simp: eventually_principal subset_eq intro: bexI[of _ "min _ _"])
   712 
   713 end
   714 
   715 class real_normed_vector = real_vector + sgn_div_norm + dist_norm + uniformity_dist + open_uniformity +
   716   assumes norm_eq_zero [simp]: "norm x = 0 \<longleftrightarrow> x = 0"
   717     and norm_triangle_ineq: "norm (x + y) \<le> norm x + norm y"
   718     and norm_scaleR [simp]: "norm (scaleR a x) = \<bar>a\<bar> * norm x"
   719 begin
   720 
   721 lemma norm_ge_zero [simp]: "0 \<le> norm x"
   722 proof -
   723   have "0 = norm (x + -1 *\<^sub>R x)"
   724     using scaleR_add_left[of 1 "-1" x] norm_scaleR[of 0 x] by (simp add: scaleR_one)
   725   also have "\<dots> \<le> norm x + norm (-1 *\<^sub>R x)" by (rule norm_triangle_ineq)
   726   finally show ?thesis by simp
   727 qed
   728 
   729 end
   730 
   731 class real_normed_algebra = real_algebra + real_normed_vector +
   732   assumes norm_mult_ineq: "norm (x * y) \<le> norm x * norm y"
   733 
   734 class real_normed_algebra_1 = real_algebra_1 + real_normed_algebra +
   735   assumes norm_one [simp]: "norm 1 = 1"
   736 
   737 lemma (in real_normed_algebra_1) scaleR_power [simp]: "(scaleR x y) ^ n = scaleR (x^n) (y^n)"
   738   by (induct n) (simp_all add: scaleR_one scaleR_scaleR mult_ac)
   739 
   740 class real_normed_div_algebra = real_div_algebra + real_normed_vector +
   741   assumes norm_mult: "norm (x * y) = norm x * norm y"
   742 
   743 class real_normed_field = real_field + real_normed_div_algebra
   744 
   745 instance real_normed_div_algebra < real_normed_algebra_1
   746 proof
   747   show "norm (x * y) \<le> norm x * norm y" for x y :: 'a
   748     by (simp add: norm_mult)
   749 next
   750   have "norm (1 * 1::'a) = norm (1::'a) * norm (1::'a)"
   751     by (rule norm_mult)
   752   then show "norm (1::'a) = 1" by simp
   753 qed
   754 
   755 lemma norm_zero [simp]: "norm (0::'a::real_normed_vector) = 0"
   756   by simp
   757 
   758 lemma zero_less_norm_iff [simp]: "norm x > 0 \<longleftrightarrow> x \<noteq> 0"
   759   for x :: "'a::real_normed_vector"
   760   by (simp add: order_less_le)
   761 
   762 lemma norm_not_less_zero [simp]: "\<not> norm x < 0"
   763   for x :: "'a::real_normed_vector"
   764   by (simp add: linorder_not_less)
   765 
   766 lemma norm_le_zero_iff [simp]: "norm x \<le> 0 \<longleftrightarrow> x = 0"
   767   for x :: "'a::real_normed_vector"
   768   by (simp add: order_le_less)
   769 
   770 lemma norm_minus_cancel [simp]: "norm (- x) = norm x"
   771   for x :: "'a::real_normed_vector"
   772 proof -
   773   have "norm (- x) = norm (scaleR (- 1) x)"
   774     by (simp only: scaleR_minus_left scaleR_one)
   775   also have "\<dots> = \<bar>- 1\<bar> * norm x"
   776     by (rule norm_scaleR)
   777   finally show ?thesis by simp
   778 qed
   779 
   780 lemma norm_minus_commute: "norm (a - b) = norm (b - a)"
   781   for a b :: "'a::real_normed_vector"
   782 proof -
   783   have "norm (- (b - a)) = norm (b - a)"
   784     by (rule norm_minus_cancel)
   785   then show ?thesis by simp
   786 qed
   787 
   788 lemma dist_add_cancel [simp]: "dist (a + b) (a + c) = dist b c"
   789   for a :: "'a::real_normed_vector"
   790   by (simp add: dist_norm)
   791 
   792 lemma dist_add_cancel2 [simp]: "dist (b + a) (c + a) = dist b c"
   793   for a :: "'a::real_normed_vector"
   794   by (simp add: dist_norm)
   795 
   796 lemma dist_scaleR [simp]: "dist (x *\<^sub>R a) (y *\<^sub>R a) = \<bar>x - y\<bar> * norm a"
   797   for a :: "'a::real_normed_vector"
   798   by (metis dist_norm norm_scaleR scaleR_left.diff)
   799 
   800 lemma norm_uminus_minus: "norm (- x - y :: 'a :: real_normed_vector) = norm (x + y)"
   801   by (subst (2) norm_minus_cancel[symmetric], subst minus_add_distrib) simp
   802 
   803 lemma norm_triangle_ineq2: "norm a - norm b \<le> norm (a - b)"
   804   for a b :: "'a::real_normed_vector"
   805 proof -
   806   have "norm (a - b + b) \<le> norm (a - b) + norm b"
   807     by (rule norm_triangle_ineq)
   808   then show ?thesis by simp
   809 qed
   810 
   811 lemma norm_triangle_ineq3: "\<bar>norm a - norm b\<bar> \<le> norm (a - b)"
   812   for a b :: "'a::real_normed_vector"
   813   apply (subst abs_le_iff)
   814   apply auto
   815    apply (rule norm_triangle_ineq2)
   816   apply (subst norm_minus_commute)
   817   apply (rule norm_triangle_ineq2)
   818   done
   819 
   820 lemma norm_triangle_ineq4: "norm (a - b) \<le> norm a + norm b"
   821   for a b :: "'a::real_normed_vector"
   822 proof -
   823   have "norm (a + - b) \<le> norm a + norm (- b)"
   824     by (rule norm_triangle_ineq)
   825   then show ?thesis by simp
   826 qed
   827 
   828 lemma norm_diff_ineq: "norm a - norm b \<le> norm (a + b)"
   829   for a b :: "'a::real_normed_vector"
   830 proof -
   831   have "norm a - norm (- b) \<le> norm (a - - b)"
   832     by (rule norm_triangle_ineq2)
   833   then show ?thesis by simp
   834 qed
   835 
   836 lemma norm_add_leD: "norm (a + b) \<le> c \<Longrightarrow> norm b \<le> norm a + c"
   837   for a b :: "'a::real_normed_vector"
   838   by (metis add.commute diff_le_eq norm_diff_ineq order.trans)
   839 
   840 lemma norm_diff_triangle_ineq: "norm ((a + b) - (c + d)) \<le> norm (a - c) + norm (b - d)"
   841   for a b c d :: "'a::real_normed_vector"
   842 proof -
   843   have "norm ((a + b) - (c + d)) = norm ((a - c) + (b - d))"
   844     by (simp add: algebra_simps)
   845   also have "\<dots> \<le> norm (a - c) + norm (b - d)"
   846     by (rule norm_triangle_ineq)
   847   finally show ?thesis .
   848 qed
   849 
   850 lemma norm_diff_triangle_le:
   851   fixes x y z :: "'a::real_normed_vector"
   852   assumes "norm (x - y) \<le> e1"  "norm (y - z) \<le> e2"
   853   shows "norm (x - z) \<le> e1 + e2"
   854   using norm_diff_triangle_ineq [of x y y z] assms by simp
   855 
   856 lemma norm_diff_triangle_less:
   857   fixes x y z :: "'a::real_normed_vector"
   858   assumes "norm (x - y) < e1"  "norm (y - z) < e2"
   859   shows "norm (x - z) < e1 + e2"
   860   using norm_diff_triangle_ineq [of x y y z] assms by simp
   861 
   862 lemma norm_triangle_mono:
   863   fixes a b :: "'a::real_normed_vector"
   864   shows "norm a \<le> r \<Longrightarrow> norm b \<le> s \<Longrightarrow> norm (a + b) \<le> r + s"
   865   by (metis add_mono_thms_linordered_semiring(1) norm_triangle_ineq order.trans)
   866 
   867 lemma norm_sum:
   868   fixes f :: "'a \<Rightarrow> 'b::real_normed_vector"
   869   shows "norm (sum f A) \<le> (\<Sum>i\<in>A. norm (f i))"
   870   by (induct A rule: infinite_finite_induct) (auto intro: norm_triangle_mono)
   871 
   872 lemma sum_norm_le:
   873   fixes f :: "'a \<Rightarrow> 'b::real_normed_vector"
   874   assumes fg: "\<forall>x \<in> S. norm (f x) \<le> g x"
   875   shows "norm (sum f S) \<le> sum g S"
   876   by (rule order_trans [OF norm_sum sum_mono]) (simp add: fg)
   877 
   878 lemma abs_norm_cancel [simp]: "\<bar>norm a\<bar> = norm a"
   879   for a :: "'a::real_normed_vector"
   880   by (rule abs_of_nonneg [OF norm_ge_zero])
   881 
   882 lemma norm_add_less: "norm x < r \<Longrightarrow> norm y < s \<Longrightarrow> norm (x + y) < r + s"
   883   for x y :: "'a::real_normed_vector"
   884   by (rule order_le_less_trans [OF norm_triangle_ineq add_strict_mono])
   885 
   886 lemma norm_mult_less: "norm x < r \<Longrightarrow> norm y < s \<Longrightarrow> norm (x * y) < r * s"
   887   for x y :: "'a::real_normed_algebra"
   888   by (rule order_le_less_trans [OF norm_mult_ineq]) (simp add: mult_strict_mono')
   889 
   890 lemma norm_of_real [simp]: "norm (of_real r :: 'a::real_normed_algebra_1) = \<bar>r\<bar>"
   891   by (simp add: of_real_def)
   892 
   893 lemma norm_numeral [simp]: "norm (numeral w::'a::real_normed_algebra_1) = numeral w"
   894   by (subst of_real_numeral [symmetric], subst norm_of_real, simp)
   895 
   896 lemma norm_neg_numeral [simp]: "norm (- numeral w::'a::real_normed_algebra_1) = numeral w"
   897   by (subst of_real_neg_numeral [symmetric], subst norm_of_real, simp)
   898 
   899 lemma norm_of_real_add1 [simp]: "norm (of_real x + 1 :: 'a :: real_normed_div_algebra) = \<bar>x + 1\<bar>"
   900   by (metis norm_of_real of_real_1 of_real_add)
   901 
   902 lemma norm_of_real_addn [simp]:
   903   "norm (of_real x + numeral b :: 'a :: real_normed_div_algebra) = \<bar>x + numeral b\<bar>"
   904   by (metis norm_of_real of_real_add of_real_numeral)
   905 
   906 lemma norm_of_int [simp]: "norm (of_int z::'a::real_normed_algebra_1) = \<bar>of_int z\<bar>"
   907   by (subst of_real_of_int_eq [symmetric], rule norm_of_real)
   908 
   909 lemma norm_of_nat [simp]: "norm (of_nat n::'a::real_normed_algebra_1) = of_nat n"
   910   apply (subst of_real_of_nat_eq [symmetric])
   911   apply (subst norm_of_real, simp)
   912   done
   913 
   914 lemma nonzero_norm_inverse: "a \<noteq> 0 \<Longrightarrow> norm (inverse a) = inverse (norm a)"
   915   for a :: "'a::real_normed_div_algebra"
   916   apply (rule inverse_unique [symmetric])
   917   apply (simp add: norm_mult [symmetric])
   918   done
   919 
   920 lemma norm_inverse: "norm (inverse a) = inverse (norm a)"
   921   for a :: "'a::{real_normed_div_algebra,division_ring}"
   922   apply (cases "a = 0")
   923    apply simp
   924   apply (erule nonzero_norm_inverse)
   925   done
   926 
   927 lemma nonzero_norm_divide: "b \<noteq> 0 \<Longrightarrow> norm (a / b) = norm a / norm b"
   928   for a b :: "'a::real_normed_field"
   929   by (simp add: divide_inverse norm_mult nonzero_norm_inverse)
   930 
   931 lemma norm_divide: "norm (a / b) = norm a / norm b"
   932   for a b :: "'a::{real_normed_field,field}"
   933   by (simp add: divide_inverse norm_mult norm_inverse)
   934 
   935 lemma norm_power_ineq: "norm (x ^ n) \<le> norm x ^ n"
   936   for x :: "'a::real_normed_algebra_1"
   937 proof (induct n)
   938   case 0
   939   show "norm (x ^ 0) \<le> norm x ^ 0" by simp
   940 next
   941   case (Suc n)
   942   have "norm (x * x ^ n) \<le> norm x * norm (x ^ n)"
   943     by (rule norm_mult_ineq)
   944   also from Suc have "\<dots> \<le> norm x * norm x ^ n"
   945     using norm_ge_zero by (rule mult_left_mono)
   946   finally show "norm (x ^ Suc n) \<le> norm x ^ Suc n"
   947     by simp
   948 qed
   949 
   950 lemma norm_power: "norm (x ^ n) = norm x ^ n"
   951   for x :: "'a::real_normed_div_algebra"
   952   by (induct n) (simp_all add: norm_mult)
   953 
   954 lemma power_eq_imp_eq_norm:
   955   fixes w :: "'a::real_normed_div_algebra"
   956   assumes eq: "w ^ n = z ^ n" and "n > 0"
   957     shows "norm w = norm z"
   958 proof -
   959   have "norm w ^ n = norm z ^ n"
   960     by (metis (no_types) eq norm_power)
   961   then show ?thesis
   962     using assms by (force intro: power_eq_imp_eq_base)
   963 qed
   964 
   965 lemma norm_mult_numeral1 [simp]: "norm (numeral w * a) = numeral w * norm a"
   966   for a b :: "'a::{real_normed_field,field}"
   967   by (simp add: norm_mult)
   968 
   969 lemma norm_mult_numeral2 [simp]: "norm (a * numeral w) = norm a * numeral w"
   970   for a b :: "'a::{real_normed_field,field}"
   971   by (simp add: norm_mult)
   972 
   973 lemma norm_divide_numeral [simp]: "norm (a / numeral w) = norm a / numeral w"
   974   for a b :: "'a::{real_normed_field,field}"
   975   by (simp add: norm_divide)
   976 
   977 lemma norm_of_real_diff [simp]:
   978   "norm (of_real b - of_real a :: 'a::real_normed_algebra_1) \<le> \<bar>b - a\<bar>"
   979   by (metis norm_of_real of_real_diff order_refl)
   980 
   981 text \<open>Despite a superficial resemblance, \<open>norm_eq_1\<close> is not relevant.\<close>
   982 lemma square_norm_one:
   983   fixes x :: "'a::real_normed_div_algebra"
   984   assumes "x\<^sup>2 = 1"
   985   shows "norm x = 1"
   986   by (metis assms norm_minus_cancel norm_one power2_eq_1_iff)
   987 
   988 lemma norm_less_p1: "norm x < norm (of_real (norm x) + 1 :: 'a)"
   989   for x :: "'a::real_normed_algebra_1"
   990 proof -
   991   have "norm x < norm (of_real (norm x + 1) :: 'a)"
   992     by (simp add: of_real_def)
   993   then show ?thesis
   994     by simp
   995 qed
   996 
   997 lemma prod_norm: "prod (\<lambda>x. norm (f x)) A = norm (prod f A)"
   998   for f :: "'a \<Rightarrow> 'b::{comm_semiring_1,real_normed_div_algebra}"
   999   by (induct A rule: infinite_finite_induct) (auto simp: norm_mult)
  1000 
  1001 lemma norm_prod_le:
  1002   "norm (prod f A) \<le> (\<Prod>a\<in>A. norm (f a :: 'a :: {real_normed_algebra_1,comm_monoid_mult}))"
  1003 proof (induct A rule: infinite_finite_induct)
  1004   case empty
  1005   then show ?case by simp
  1006 next
  1007   case (insert a A)
  1008   then have "norm (prod f (insert a A)) \<le> norm (f a) * norm (prod f A)"
  1009     by (simp add: norm_mult_ineq)
  1010   also have "norm (prod f A) \<le> (\<Prod>a\<in>A. norm (f a))"
  1011     by (rule insert)
  1012   finally show ?case
  1013     by (simp add: insert mult_left_mono)
  1014 next
  1015   case infinite
  1016   then show ?case by simp
  1017 qed
  1018 
  1019 lemma norm_prod_diff:
  1020   fixes z w :: "'i \<Rightarrow> 'a::{real_normed_algebra_1, comm_monoid_mult}"
  1021   shows "(\<And>i. i \<in> I \<Longrightarrow> norm (z i) \<le> 1) \<Longrightarrow> (\<And>i. i \<in> I \<Longrightarrow> norm (w i) \<le> 1) \<Longrightarrow>
  1022     norm ((\<Prod>i\<in>I. z i) - (\<Prod>i\<in>I. w i)) \<le> (\<Sum>i\<in>I. norm (z i - w i))"
  1023 proof (induction I rule: infinite_finite_induct)
  1024   case empty
  1025   then show ?case by simp
  1026 next
  1027   case (insert i I)
  1028   note insert.hyps[simp]
  1029 
  1030   have "norm ((\<Prod>i\<in>insert i I. z i) - (\<Prod>i\<in>insert i I. w i)) =
  1031     norm ((\<Prod>i\<in>I. z i) * (z i - w i) + ((\<Prod>i\<in>I. z i) - (\<Prod>i\<in>I. w i)) * w i)"
  1032     (is "_ = norm (?t1 + ?t2)")
  1033     by (auto simp add: field_simps)
  1034   also have "\<dots> \<le> norm ?t1 + norm ?t2"
  1035     by (rule norm_triangle_ineq)
  1036   also have "norm ?t1 \<le> norm (\<Prod>i\<in>I. z i) * norm (z i - w i)"
  1037     by (rule norm_mult_ineq)
  1038   also have "\<dots> \<le> (\<Prod>i\<in>I. norm (z i)) * norm(z i - w i)"
  1039     by (rule mult_right_mono) (auto intro: norm_prod_le)
  1040   also have "(\<Prod>i\<in>I. norm (z i)) \<le> (\<Prod>i\<in>I. 1)"
  1041     by (intro prod_mono) (auto intro!: insert)
  1042   also have "norm ?t2 \<le> norm ((\<Prod>i\<in>I. z i) - (\<Prod>i\<in>I. w i)) * norm (w i)"
  1043     by (rule norm_mult_ineq)
  1044   also have "norm (w i) \<le> 1"
  1045     by (auto intro: insert)
  1046   also have "norm ((\<Prod>i\<in>I. z i) - (\<Prod>i\<in>I. w i)) \<le> (\<Sum>i\<in>I. norm (z i - w i))"
  1047     using insert by auto
  1048   finally show ?case
  1049     by (auto simp add: ac_simps mult_right_mono mult_left_mono)
  1050 next
  1051   case infinite
  1052   then show ?case by simp
  1053 qed
  1054 
  1055 lemma norm_power_diff:
  1056   fixes z w :: "'a::{real_normed_algebra_1, comm_monoid_mult}"
  1057   assumes "norm z \<le> 1" "norm w \<le> 1"
  1058   shows "norm (z^m - w^m) \<le> m * norm (z - w)"
  1059 proof -
  1060   have "norm (z^m - w^m) = norm ((\<Prod> i < m. z) - (\<Prod> i < m. w))"
  1061     by (simp add: prod_constant)
  1062   also have "\<dots> \<le> (\<Sum>i<m. norm (z - w))"
  1063     by (intro norm_prod_diff) (auto simp add: assms)
  1064   also have "\<dots> = m * norm (z - w)"
  1065     by simp
  1066   finally show ?thesis .
  1067 qed
  1068 
  1069 
  1070 subsection \<open>Metric spaces\<close>
  1071 
  1072 class metric_space = uniformity_dist + open_uniformity +
  1073   assumes dist_eq_0_iff [simp]: "dist x y = 0 \<longleftrightarrow> x = y"
  1074     and dist_triangle2: "dist x y \<le> dist x z + dist y z"
  1075 begin
  1076 
  1077 lemma dist_self [simp]: "dist x x = 0"
  1078   by simp
  1079 
  1080 lemma zero_le_dist [simp]: "0 \<le> dist x y"
  1081   using dist_triangle2 [of x x y] by simp
  1082 
  1083 lemma zero_less_dist_iff: "0 < dist x y \<longleftrightarrow> x \<noteq> y"
  1084   by (simp add: less_le)
  1085 
  1086 lemma dist_not_less_zero [simp]: "\<not> dist x y < 0"
  1087   by (simp add: not_less)
  1088 
  1089 lemma dist_le_zero_iff [simp]: "dist x y \<le> 0 \<longleftrightarrow> x = y"
  1090   by (simp add: le_less)
  1091 
  1092 lemma dist_commute: "dist x y = dist y x"
  1093 proof (rule order_antisym)
  1094   show "dist x y \<le> dist y x"
  1095     using dist_triangle2 [of x y x] by simp
  1096   show "dist y x \<le> dist x y"
  1097     using dist_triangle2 [of y x y] by simp
  1098 qed
  1099 
  1100 lemma dist_commute_lessI: "dist y x < e \<Longrightarrow> dist x y < e"
  1101   by (simp add: dist_commute)
  1102 
  1103 lemma dist_triangle: "dist x z \<le> dist x y + dist y z"
  1104   using dist_triangle2 [of x z y] by (simp add: dist_commute)
  1105 
  1106 lemma dist_triangle3: "dist x y \<le> dist a x + dist a y"
  1107   using dist_triangle2 [of x y a] by (simp add: dist_commute)
  1108 
  1109 lemma dist_pos_lt: "x \<noteq> y \<Longrightarrow> 0 < dist x y"
  1110   by (simp add: zero_less_dist_iff)
  1111 
  1112 lemma dist_nz: "x \<noteq> y \<longleftrightarrow> 0 < dist x y"
  1113   by (simp add: zero_less_dist_iff)
  1114 
  1115 declare dist_nz [symmetric, simp]
  1116 
  1117 lemma dist_triangle_le: "dist x z + dist y z \<le> e \<Longrightarrow> dist x y \<le> e"
  1118   by (rule order_trans [OF dist_triangle2])
  1119 
  1120 lemma dist_triangle_lt: "dist x z + dist y z < e \<Longrightarrow> dist x y < e"
  1121   by (rule le_less_trans [OF dist_triangle2])
  1122 
  1123 lemma dist_triangle_less_add: "dist x1 y < e1 \<Longrightarrow> dist x2 y < e2 \<Longrightarrow> dist x1 x2 < e1 + e2"
  1124   by (rule dist_triangle_lt [where z=y]) simp
  1125 
  1126 lemma dist_triangle_half_l: "dist x1 y < e / 2 \<Longrightarrow> dist x2 y < e / 2 \<Longrightarrow> dist x1 x2 < e"
  1127   by (rule dist_triangle_lt [where z=y]) simp
  1128 
  1129 lemma dist_triangle_half_r: "dist y x1 < e / 2 \<Longrightarrow> dist y x2 < e / 2 \<Longrightarrow> dist x1 x2 < e"
  1130   by (rule dist_triangle_half_l) (simp_all add: dist_commute)
  1131 
  1132 lemma dist_triangle_third:
  1133   assumes "dist x1 x2 < e/3" "dist x2 x3 < e/3" "dist x3 x4 < e/3"
  1134   shows "dist x1 x4 < e"
  1135 proof -
  1136   have "dist x1 x3 < e/3 + e/3"
  1137     by (metis assms(1) assms(2) dist_commute dist_triangle_less_add)
  1138   then have "dist x1 x4 < (e/3 + e/3) + e/3"
  1139     by (metis assms(3) dist_commute dist_triangle_less_add)
  1140   then show ?thesis
  1141     by simp
  1142 qed
  1143 
  1144 subclass uniform_space
  1145 proof
  1146   fix E x
  1147   assume "eventually E uniformity"
  1148   then obtain e where E: "0 < e" "\<And>x y. dist x y < e \<Longrightarrow> E (x, y)"
  1149     by (auto simp: eventually_uniformity_metric)
  1150   then show "E (x, x)" "\<forall>\<^sub>F (x, y) in uniformity. E (y, x)"
  1151     by (auto simp: eventually_uniformity_metric dist_commute)
  1152   show "\<exists>D. eventually D uniformity \<and> (\<forall>x y z. D (x, y) \<longrightarrow> D (y, z) \<longrightarrow> E (x, z))"
  1153     using E dist_triangle_half_l[where e=e]
  1154     unfolding eventually_uniformity_metric
  1155     by (intro exI[of _ "\<lambda>(x, y). dist x y < e / 2"] exI[of _ "e/2"] conjI)
  1156       (auto simp: dist_commute)
  1157 qed
  1158 
  1159 lemma open_dist: "open S \<longleftrightarrow> (\<forall>x\<in>S. \<exists>e>0. \<forall>y. dist y x < e \<longrightarrow> y \<in> S)"
  1160   by (simp add: dist_commute open_uniformity eventually_uniformity_metric)
  1161 
  1162 lemma open_ball: "open {y. dist x y < d}"
  1163   unfolding open_dist
  1164 proof (intro ballI)
  1165   fix y
  1166   assume *: "y \<in> {y. dist x y < d}"
  1167   then show "\<exists>e>0. \<forall>z. dist z y < e \<longrightarrow> z \<in> {y. dist x y < d}"
  1168     by (auto intro!: exI[of _ "d - dist x y"] simp: field_simps dist_triangle_lt)
  1169 qed
  1170 
  1171 subclass first_countable_topology
  1172 proof
  1173   fix x
  1174   show "\<exists>A::nat \<Rightarrow> 'a set. (\<forall>i. x \<in> A i \<and> open (A i)) \<and> (\<forall>S. open S \<and> x \<in> S \<longrightarrow> (\<exists>i. A i \<subseteq> S))"
  1175   proof (safe intro!: exI[of _ "\<lambda>n. {y. dist x y < inverse (Suc n)}"])
  1176     fix S
  1177     assume "open S" "x \<in> S"
  1178     then obtain e where e: "0 < e" and "{y. dist x y < e} \<subseteq> S"
  1179       by (auto simp: open_dist subset_eq dist_commute)
  1180     moreover
  1181     from e obtain i where "inverse (Suc i) < e"
  1182       by (auto dest!: reals_Archimedean)
  1183     then have "{y. dist x y < inverse (Suc i)} \<subseteq> {y. dist x y < e}"
  1184       by auto
  1185     ultimately show "\<exists>i. {y. dist x y < inverse (Suc i)} \<subseteq> S"
  1186       by blast
  1187   qed (auto intro: open_ball)
  1188 qed
  1189 
  1190 end
  1191 
  1192 instance metric_space \<subseteq> t2_space
  1193 proof
  1194   fix x y :: "'a::metric_space"
  1195   assume xy: "x \<noteq> y"
  1196   let ?U = "{y'. dist x y' < dist x y / 2}"
  1197   let ?V = "{x'. dist y x' < dist x y / 2}"
  1198   have *: "d x z \<le> d x y + d y z \<Longrightarrow> d y z = d z y \<Longrightarrow> \<not> (d x y * 2 < d x z \<and> d z y * 2 < d x z)"
  1199     for d :: "'a \<Rightarrow> 'a \<Rightarrow> real" and x y z :: 'a
  1200     by arith
  1201   have "open ?U \<and> open ?V \<and> x \<in> ?U \<and> y \<in> ?V \<and> ?U \<inter> ?V = {}"
  1202     using dist_pos_lt[OF xy] *[of dist, OF dist_triangle dist_commute]
  1203     using open_ball[of _ "dist x y / 2"] by auto
  1204   then show "\<exists>U V. open U \<and> open V \<and> x \<in> U \<and> y \<in> V \<and> U \<inter> V = {}"
  1205     by blast
  1206 qed
  1207 
  1208 text \<open>Every normed vector space is a metric space.\<close>
  1209 instance real_normed_vector < metric_space
  1210 proof
  1211   fix x y z :: 'a
  1212   show "dist x y = 0 \<longleftrightarrow> x = y"
  1213     by (simp add: dist_norm)
  1214   show "dist x y \<le> dist x z + dist y z"
  1215     using norm_triangle_ineq4 [of "x - z" "y - z"] by (simp add: dist_norm)
  1216 qed
  1217 
  1218 
  1219 subsection \<open>Class instances for real numbers\<close>
  1220 
  1221 instantiation real :: real_normed_field
  1222 begin
  1223 
  1224 definition dist_real_def: "dist x y = \<bar>x - y\<bar>"
  1225 
  1226 definition uniformity_real_def [code del]:
  1227   "(uniformity :: (real \<times> real) filter) = (INF e:{0 <..}. principal {(x, y). dist x y < e})"
  1228 
  1229 definition open_real_def [code del]:
  1230   "open (U :: real set) \<longleftrightarrow> (\<forall>x\<in>U. eventually (\<lambda>(x', y). x' = x \<longrightarrow> y \<in> U) uniformity)"
  1231 
  1232 definition real_norm_def [simp]: "norm r = \<bar>r\<bar>"
  1233 
  1234 instance
  1235   apply intro_classes
  1236          apply (unfold real_norm_def real_scaleR_def)
  1237          apply (rule dist_real_def)
  1238         apply (simp add: sgn_real_def)
  1239        apply (rule uniformity_real_def)
  1240       apply (rule open_real_def)
  1241      apply (rule abs_eq_0)
  1242     apply (rule abs_triangle_ineq)
  1243    apply (rule abs_mult)
  1244   apply (rule abs_mult)
  1245   done
  1246 
  1247 end
  1248 
  1249 declare uniformity_Abort[where 'a=real, code]
  1250 
  1251 lemma dist_of_real [simp]: "dist (of_real x :: 'a) (of_real y) = dist x y"
  1252   for a :: "'a::real_normed_div_algebra"
  1253   by (metis dist_norm norm_of_real of_real_diff real_norm_def)
  1254 
  1255 declare [[code abort: "open :: real set \<Rightarrow> bool"]]
  1256 
  1257 instance real :: linorder_topology
  1258 proof
  1259   show "(open :: real set \<Rightarrow> bool) = generate_topology (range lessThan \<union> range greaterThan)"
  1260   proof (rule ext, safe)
  1261     fix S :: "real set"
  1262     assume "open S"
  1263     then obtain f where "\<forall>x\<in>S. 0 < f x \<and> (\<forall>y. dist y x < f x \<longrightarrow> y \<in> S)"
  1264       unfolding open_dist bchoice_iff ..
  1265     then have *: "S = (\<Union>x\<in>S. {x - f x <..} \<inter> {..< x + f x})"
  1266       by (fastforce simp: dist_real_def)
  1267     show "generate_topology (range lessThan \<union> range greaterThan) S"
  1268       apply (subst *)
  1269       apply (intro generate_topology_Union generate_topology.Int)
  1270        apply (auto intro: generate_topology.Basis)
  1271       done
  1272   next
  1273     fix S :: "real set"
  1274     assume "generate_topology (range lessThan \<union> range greaterThan) S"
  1275     moreover have "\<And>a::real. open {..<a}"
  1276       unfolding open_dist dist_real_def
  1277     proof clarify
  1278       fix x a :: real
  1279       assume "x < a"
  1280       then have "0 < a - x \<and> (\<forall>y. \<bar>y - x\<bar> < a - x \<longrightarrow> y \<in> {..<a})" by auto
  1281       then show "\<exists>e>0. \<forall>y. \<bar>y - x\<bar> < e \<longrightarrow> y \<in> {..<a}" ..
  1282     qed
  1283     moreover have "\<And>a::real. open {a <..}"
  1284       unfolding open_dist dist_real_def
  1285     proof clarify
  1286       fix x a :: real
  1287       assume "a < x"
  1288       then have "0 < x - a \<and> (\<forall>y. \<bar>y - x\<bar> < x - a \<longrightarrow> y \<in> {a<..})" by auto
  1289       then show "\<exists>e>0. \<forall>y. \<bar>y - x\<bar> < e \<longrightarrow> y \<in> {a<..}" ..
  1290     qed
  1291     ultimately show "open S"
  1292       by induct auto
  1293   qed
  1294 qed
  1295 
  1296 instance real :: linear_continuum_topology ..
  1297 
  1298 lemmas open_real_greaterThan = open_greaterThan[where 'a=real]
  1299 lemmas open_real_lessThan = open_lessThan[where 'a=real]
  1300 lemmas open_real_greaterThanLessThan = open_greaterThanLessThan[where 'a=real]
  1301 lemmas closed_real_atMost = closed_atMost[where 'a=real]
  1302 lemmas closed_real_atLeast = closed_atLeast[where 'a=real]
  1303 lemmas closed_real_atLeastAtMost = closed_atLeastAtMost[where 'a=real]
  1304 
  1305 
  1306 subsection \<open>Extra type constraints\<close>
  1307 
  1308 text \<open>Only allow @{term "open"} in class \<open>topological_space\<close>.\<close>
  1309 setup \<open>Sign.add_const_constraint
  1310   (@{const_name "open"}, SOME @{typ "'a::topological_space set \<Rightarrow> bool"})\<close>
  1311 
  1312 text \<open>Only allow @{term "uniformity"} in class \<open>uniform_space\<close>.\<close>
  1313 setup \<open>Sign.add_const_constraint
  1314   (@{const_name "uniformity"}, SOME @{typ "('a::uniformity \<times> 'a) filter"})\<close>
  1315 
  1316 text \<open>Only allow @{term dist} in class \<open>metric_space\<close>.\<close>
  1317 setup \<open>Sign.add_const_constraint
  1318   (@{const_name dist}, SOME @{typ "'a::metric_space \<Rightarrow> 'a \<Rightarrow> real"})\<close>
  1319 
  1320 text \<open>Only allow @{term norm} in class \<open>real_normed_vector\<close>.\<close>
  1321 setup \<open>Sign.add_const_constraint
  1322   (@{const_name norm}, SOME @{typ "'a::real_normed_vector \<Rightarrow> real"})\<close>
  1323 
  1324 
  1325 subsection \<open>Sign function\<close>
  1326 
  1327 lemma norm_sgn: "norm (sgn x) = (if x = 0 then 0 else 1)"
  1328   for x :: "'a::real_normed_vector"
  1329   by (simp add: sgn_div_norm)
  1330 
  1331 lemma sgn_zero [simp]: "sgn (0::'a::real_normed_vector) = 0"
  1332   by (simp add: sgn_div_norm)
  1333 
  1334 lemma sgn_zero_iff: "sgn x = 0 \<longleftrightarrow> x = 0"
  1335   for x :: "'a::real_normed_vector"
  1336   by (simp add: sgn_div_norm)
  1337 
  1338 lemma sgn_minus: "sgn (- x) = - sgn x"
  1339   for x :: "'a::real_normed_vector"
  1340   by (simp add: sgn_div_norm)
  1341 
  1342 lemma sgn_scaleR: "sgn (scaleR r x) = scaleR (sgn r) (sgn x)"
  1343   for x :: "'a::real_normed_vector"
  1344   by (simp add: sgn_div_norm ac_simps)
  1345 
  1346 lemma sgn_one [simp]: "sgn (1::'a::real_normed_algebra_1) = 1"
  1347   by (simp add: sgn_div_norm)
  1348 
  1349 lemma sgn_of_real: "sgn (of_real r :: 'a::real_normed_algebra_1) = of_real (sgn r)"
  1350   unfolding of_real_def by (simp only: sgn_scaleR sgn_one)
  1351 
  1352 lemma sgn_mult: "sgn (x * y) = sgn x * sgn y"
  1353   for x y :: "'a::real_normed_div_algebra"
  1354   by (simp add: sgn_div_norm norm_mult mult.commute)
  1355 
  1356 hide_fact (open) sgn_mult
  1357 
  1358 lemma real_sgn_eq: "sgn x = x / \<bar>x\<bar>"
  1359   for x :: real
  1360   by (simp add: sgn_div_norm divide_inverse)
  1361 
  1362 lemma zero_le_sgn_iff [simp]: "0 \<le> sgn x \<longleftrightarrow> 0 \<le> x"
  1363   for x :: real
  1364   by (cases "0::real" x rule: linorder_cases) simp_all
  1365 
  1366 lemma sgn_le_0_iff [simp]: "sgn x \<le> 0 \<longleftrightarrow> x \<le> 0"
  1367   for x :: real
  1368   by (cases "0::real" x rule: linorder_cases) simp_all
  1369 
  1370 lemma norm_conv_dist: "norm x = dist x 0"
  1371   unfolding dist_norm by simp
  1372 
  1373 declare norm_conv_dist [symmetric, simp]
  1374 
  1375 lemma dist_0_norm [simp]: "dist 0 x = norm x"
  1376   for x :: "'a::real_normed_vector"
  1377   by (simp add: dist_norm)
  1378 
  1379 lemma dist_diff [simp]: "dist a (a - b) = norm b"  "dist (a - b) a = norm b"
  1380   by (simp_all add: dist_norm)
  1381 
  1382 lemma dist_of_int: "dist (of_int m) (of_int n :: 'a :: real_normed_algebra_1) = of_int \<bar>m - n\<bar>"
  1383 proof -
  1384   have "dist (of_int m) (of_int n :: 'a) = dist (of_int m :: 'a) (of_int m - (of_int (m - n)))"
  1385     by simp
  1386   also have "\<dots> = of_int \<bar>m - n\<bar>" by (subst dist_diff, subst norm_of_int) simp
  1387   finally show ?thesis .
  1388 qed
  1389 
  1390 lemma dist_of_nat:
  1391   "dist (of_nat m) (of_nat n :: 'a :: real_normed_algebra_1) = of_int \<bar>int m - int n\<bar>"
  1392   by (subst (1 2) of_int_of_nat_eq [symmetric]) (rule dist_of_int)
  1393 
  1394 
  1395 subsection \<open>Bounded Linear and Bilinear Operators\<close>
  1396 
  1397 locale linear = additive f for f :: "'a::real_vector \<Rightarrow> 'b::real_vector" +
  1398   assumes scaleR: "f (scaleR r x) = scaleR r (f x)"
  1399 
  1400 lemma linear_imp_scaleR:
  1401   assumes "linear D"
  1402   obtains d where "D = (\<lambda>x. x *\<^sub>R d)"
  1403   by (metis assms linear.scaleR mult.commute mult.left_neutral real_scaleR_def)
  1404 
  1405 corollary real_linearD:
  1406   fixes f :: "real \<Rightarrow> real"
  1407   assumes "linear f" obtains c where "f = op* c"
  1408   by (rule linear_imp_scaleR [OF assms]) (force simp: scaleR_conv_of_real)
  1409 
  1410 lemma linearI:
  1411   assumes "\<And>x y. f (x + y) = f x + f y"
  1412     and "\<And>c x. f (c *\<^sub>R x) = c *\<^sub>R f x"
  1413   shows "linear f"
  1414   by standard (rule assms)+
  1415 
  1416 locale bounded_linear = linear f for f :: "'a::real_normed_vector \<Rightarrow> 'b::real_normed_vector" +
  1417   assumes bounded: "\<exists>K. \<forall>x. norm (f x) \<le> norm x * K"
  1418 begin
  1419 
  1420 lemma pos_bounded: "\<exists>K>0. \<forall>x. norm (f x) \<le> norm x * K"
  1421 proof -
  1422   obtain K where K: "\<And>x. norm (f x) \<le> norm x * K"
  1423     using bounded by blast
  1424   show ?thesis
  1425   proof (intro exI impI conjI allI)
  1426     show "0 < max 1 K"
  1427       by (rule order_less_le_trans [OF zero_less_one max.cobounded1])
  1428   next
  1429     fix x
  1430     have "norm (f x) \<le> norm x * K" using K .
  1431     also have "\<dots> \<le> norm x * max 1 K"
  1432       by (rule mult_left_mono [OF max.cobounded2 norm_ge_zero])
  1433     finally show "norm (f x) \<le> norm x * max 1 K" .
  1434   qed
  1435 qed
  1436 
  1437 lemma nonneg_bounded: "\<exists>K\<ge>0. \<forall>x. norm (f x) \<le> norm x * K"
  1438   using pos_bounded by (auto intro: order_less_imp_le)
  1439 
  1440 lemma linear: "linear f"
  1441   by (fact local.linear_axioms)
  1442 
  1443 end
  1444 
  1445 lemma bounded_linear_intro:
  1446   assumes "\<And>x y. f (x + y) = f x + f y"
  1447     and "\<And>r x. f (scaleR r x) = scaleR r (f x)"
  1448     and "\<And>x. norm (f x) \<le> norm x * K"
  1449   shows "bounded_linear f"
  1450   by standard (blast intro: assms)+
  1451 
  1452 locale bounded_bilinear =
  1453   fixes prod :: "'a::real_normed_vector \<Rightarrow> 'b::real_normed_vector \<Rightarrow> 'c::real_normed_vector"
  1454     (infixl "**" 70)
  1455   assumes add_left: "prod (a + a') b = prod a b + prod a' b"
  1456     and add_right: "prod a (b + b') = prod a b + prod a b'"
  1457     and scaleR_left: "prod (scaleR r a) b = scaleR r (prod a b)"
  1458     and scaleR_right: "prod a (scaleR r b) = scaleR r (prod a b)"
  1459     and bounded: "\<exists>K. \<forall>a b. norm (prod a b) \<le> norm a * norm b * K"
  1460 begin
  1461 
  1462 lemma pos_bounded: "\<exists>K>0. \<forall>a b. norm (a ** b) \<le> norm a * norm b * K"
  1463   apply (insert bounded)
  1464   apply (erule exE)
  1465   apply (rule_tac x="max 1 K" in exI)
  1466   apply safe
  1467    apply (rule order_less_le_trans [OF zero_less_one max.cobounded1])
  1468   apply (drule spec)
  1469   apply (drule spec)
  1470   apply (erule order_trans)
  1471   apply (rule mult_left_mono [OF max.cobounded2])
  1472   apply (intro mult_nonneg_nonneg norm_ge_zero)
  1473   done
  1474 
  1475 lemma nonneg_bounded: "\<exists>K\<ge>0. \<forall>a b. norm (a ** b) \<le> norm a * norm b * K"
  1476   using pos_bounded by (auto intro: order_less_imp_le)
  1477 
  1478 lemma additive_right: "additive (\<lambda>b. prod a b)"
  1479   by (rule additive.intro, rule add_right)
  1480 
  1481 lemma additive_left: "additive (\<lambda>a. prod a b)"
  1482   by (rule additive.intro, rule add_left)
  1483 
  1484 lemma zero_left: "prod 0 b = 0"
  1485   by (rule additive.zero [OF additive_left])
  1486 
  1487 lemma zero_right: "prod a 0 = 0"
  1488   by (rule additive.zero [OF additive_right])
  1489 
  1490 lemma minus_left: "prod (- a) b = - prod a b"
  1491   by (rule additive.minus [OF additive_left])
  1492 
  1493 lemma minus_right: "prod a (- b) = - prod a b"
  1494   by (rule additive.minus [OF additive_right])
  1495 
  1496 lemma diff_left: "prod (a - a') b = prod a b - prod a' b"
  1497   by (rule additive.diff [OF additive_left])
  1498 
  1499 lemma diff_right: "prod a (b - b') = prod a b - prod a b'"
  1500   by (rule additive.diff [OF additive_right])
  1501 
  1502 lemma sum_left: "prod (sum g S) x = sum ((\<lambda>i. prod (g i) x)) S"
  1503   by (rule additive.sum [OF additive_left])
  1504 
  1505 lemma sum_right: "prod x (sum g S) = sum ((\<lambda>i. (prod x (g i)))) S"
  1506   by (rule additive.sum [OF additive_right])
  1507 
  1508 
  1509 lemma bounded_linear_left: "bounded_linear (\<lambda>a. a ** b)"
  1510   apply (insert bounded)
  1511   apply safe
  1512   apply (rule_tac K="norm b * K" in bounded_linear_intro)
  1513     apply (rule add_left)
  1514    apply (rule scaleR_left)
  1515   apply (simp add: ac_simps)
  1516   done
  1517 
  1518 lemma bounded_linear_right: "bounded_linear (\<lambda>b. a ** b)"
  1519   apply (insert bounded)
  1520   apply safe
  1521   apply (rule_tac K="norm a * K" in bounded_linear_intro)
  1522     apply (rule add_right)
  1523    apply (rule scaleR_right)
  1524   apply (simp add: ac_simps)
  1525   done
  1526 
  1527 lemma prod_diff_prod: "(x ** y - a ** b) = (x - a) ** (y - b) + (x - a) ** b + a ** (y - b)"
  1528   by (simp add: diff_left diff_right)
  1529 
  1530 lemma flip: "bounded_bilinear (\<lambda>x y. y ** x)"
  1531   apply standard
  1532       apply (rule add_right)
  1533      apply (rule add_left)
  1534     apply (rule scaleR_right)
  1535    apply (rule scaleR_left)
  1536   apply (subst mult.commute)
  1537   apply (insert bounded)
  1538   apply blast
  1539   done
  1540 
  1541 lemma comp1:
  1542   assumes "bounded_linear g"
  1543   shows "bounded_bilinear (\<lambda>x. op ** (g x))"
  1544 proof unfold_locales
  1545   interpret g: bounded_linear g by fact
  1546   show "\<And>a a' b. g (a + a') ** b = g a ** b + g a' ** b"
  1547     "\<And>a b b'. g a ** (b + b') = g a ** b + g a ** b'"
  1548     "\<And>r a b. g (r *\<^sub>R a) ** b = r *\<^sub>R (g a ** b)"
  1549     "\<And>a r b. g a ** (r *\<^sub>R b) = r *\<^sub>R (g a ** b)"
  1550     by (auto simp: g.add add_left add_right g.scaleR scaleR_left scaleR_right)
  1551   from g.nonneg_bounded nonneg_bounded obtain K L
  1552     where nn: "0 \<le> K" "0 \<le> L"
  1553       and K: "\<And>x. norm (g x) \<le> norm x * K"
  1554       and L: "\<And>a b. norm (a ** b) \<le> norm a * norm b * L"
  1555     by auto
  1556   have "norm (g a ** b) \<le> norm a * K * norm b * L" for a b
  1557     by (auto intro!:  order_trans[OF K] order_trans[OF L] mult_mono simp: nn)
  1558   then show "\<exists>K. \<forall>a b. norm (g a ** b) \<le> norm a * norm b * K"
  1559     by (auto intro!: exI[where x="K * L"] simp: ac_simps)
  1560 qed
  1561 
  1562 lemma comp: "bounded_linear f \<Longrightarrow> bounded_linear g \<Longrightarrow> bounded_bilinear (\<lambda>x y. f x ** g y)"
  1563   by (rule bounded_bilinear.flip[OF bounded_bilinear.comp1[OF bounded_bilinear.flip[OF comp1]]])
  1564 
  1565 end
  1566 
  1567 lemma bounded_linear_ident[simp]: "bounded_linear (\<lambda>x. x)"
  1568   by standard (auto intro!: exI[of _ 1])
  1569 
  1570 lemma bounded_linear_zero[simp]: "bounded_linear (\<lambda>x. 0)"
  1571   by standard (auto intro!: exI[of _ 1])
  1572 
  1573 lemma bounded_linear_add:
  1574   assumes "bounded_linear f"
  1575     and "bounded_linear g"
  1576   shows "bounded_linear (\<lambda>x. f x + g x)"
  1577 proof -
  1578   interpret f: bounded_linear f by fact
  1579   interpret g: bounded_linear g by fact
  1580   show ?thesis
  1581   proof
  1582     from f.bounded obtain Kf where Kf: "norm (f x) \<le> norm x * Kf" for x
  1583       by blast
  1584     from g.bounded obtain Kg where Kg: "norm (g x) \<le> norm x * Kg" for x
  1585       by blast
  1586     show "\<exists>K. \<forall>x. norm (f x + g x) \<le> norm x * K"
  1587       using add_mono[OF Kf Kg]
  1588       by (intro exI[of _ "Kf + Kg"]) (auto simp: field_simps intro: norm_triangle_ineq order_trans)
  1589   qed (simp_all add: f.add g.add f.scaleR g.scaleR scaleR_right_distrib)
  1590 qed
  1591 
  1592 lemma bounded_linear_minus:
  1593   assumes "bounded_linear f"
  1594   shows "bounded_linear (\<lambda>x. - f x)"
  1595 proof -
  1596   interpret f: bounded_linear f by fact
  1597   show ?thesis
  1598     apply unfold_locales
  1599       apply (simp add: f.add)
  1600      apply (simp add: f.scaleR)
  1601     apply (simp add: f.bounded)
  1602     done
  1603 qed
  1604 
  1605 lemma bounded_linear_sub: "bounded_linear f \<Longrightarrow> bounded_linear g \<Longrightarrow> bounded_linear (\<lambda>x. f x - g x)"
  1606   using bounded_linear_add[of f "\<lambda>x. - g x"] bounded_linear_minus[of g]
  1607   by (auto simp add: algebra_simps)
  1608 
  1609 lemma bounded_linear_sum:
  1610   fixes f :: "'i \<Rightarrow> 'a::real_normed_vector \<Rightarrow> 'b::real_normed_vector"
  1611   shows "(\<And>i. i \<in> I \<Longrightarrow> bounded_linear (f i)) \<Longrightarrow> bounded_linear (\<lambda>x. \<Sum>i\<in>I. f i x)"
  1612   by (induct I rule: infinite_finite_induct) (auto intro!: bounded_linear_add)
  1613 
  1614 lemma bounded_linear_compose:
  1615   assumes "bounded_linear f"
  1616     and "bounded_linear g"
  1617   shows "bounded_linear (\<lambda>x. f (g x))"
  1618 proof -
  1619   interpret f: bounded_linear f by fact
  1620   interpret g: bounded_linear g by fact
  1621   show ?thesis
  1622   proof unfold_locales
  1623     show "f (g (x + y)) = f (g x) + f (g y)" for x y
  1624       by (simp only: f.add g.add)
  1625     show "f (g (scaleR r x)) = scaleR r (f (g x))" for r x
  1626       by (simp only: f.scaleR g.scaleR)
  1627     from f.pos_bounded obtain Kf where f: "\<And>x. norm (f x) \<le> norm x * Kf" and Kf: "0 < Kf"
  1628       by blast
  1629     from g.pos_bounded obtain Kg where g: "\<And>x. norm (g x) \<le> norm x * Kg"
  1630       by blast
  1631     show "\<exists>K. \<forall>x. norm (f (g x)) \<le> norm x * K"
  1632     proof (intro exI allI)
  1633       fix x
  1634       have "norm (f (g x)) \<le> norm (g x) * Kf"
  1635         using f .
  1636       also have "\<dots> \<le> (norm x * Kg) * Kf"
  1637         using g Kf [THEN order_less_imp_le] by (rule mult_right_mono)
  1638       also have "(norm x * Kg) * Kf = norm x * (Kg * Kf)"
  1639         by (rule mult.assoc)
  1640       finally show "norm (f (g x)) \<le> norm x * (Kg * Kf)" .
  1641     qed
  1642   qed
  1643 qed
  1644 
  1645 lemma bounded_bilinear_mult: "bounded_bilinear (op * :: 'a \<Rightarrow> 'a \<Rightarrow> 'a::real_normed_algebra)"
  1646   apply (rule bounded_bilinear.intro)
  1647       apply (rule distrib_right)
  1648      apply (rule distrib_left)
  1649     apply (rule mult_scaleR_left)
  1650    apply (rule mult_scaleR_right)
  1651   apply (rule_tac x="1" in exI)
  1652   apply (simp add: norm_mult_ineq)
  1653   done
  1654 
  1655 lemma bounded_linear_mult_left: "bounded_linear (\<lambda>x::'a::real_normed_algebra. x * y)"
  1656   using bounded_bilinear_mult
  1657   by (rule bounded_bilinear.bounded_linear_left)
  1658 
  1659 lemma bounded_linear_mult_right: "bounded_linear (\<lambda>y::'a::real_normed_algebra. x * y)"
  1660   using bounded_bilinear_mult
  1661   by (rule bounded_bilinear.bounded_linear_right)
  1662 
  1663 lemmas bounded_linear_mult_const =
  1664   bounded_linear_mult_left [THEN bounded_linear_compose]
  1665 
  1666 lemmas bounded_linear_const_mult =
  1667   bounded_linear_mult_right [THEN bounded_linear_compose]
  1668 
  1669 lemma bounded_linear_divide: "bounded_linear (\<lambda>x. x / y)"
  1670   for y :: "'a::real_normed_field"
  1671   unfolding divide_inverse by (rule bounded_linear_mult_left)
  1672 
  1673 lemma bounded_bilinear_scaleR: "bounded_bilinear scaleR"
  1674   apply (rule bounded_bilinear.intro)
  1675       apply (rule scaleR_left_distrib)
  1676      apply (rule scaleR_right_distrib)
  1677     apply simp
  1678    apply (rule scaleR_left_commute)
  1679   apply (rule_tac x="1" in exI)
  1680   apply simp
  1681   done
  1682 
  1683 lemma bounded_linear_scaleR_left: "bounded_linear (\<lambda>r. scaleR r x)"
  1684   using bounded_bilinear_scaleR
  1685   by (rule bounded_bilinear.bounded_linear_left)
  1686 
  1687 lemma bounded_linear_scaleR_right: "bounded_linear (\<lambda>x. scaleR r x)"
  1688   using bounded_bilinear_scaleR
  1689   by (rule bounded_bilinear.bounded_linear_right)
  1690 
  1691 lemmas bounded_linear_scaleR_const =
  1692   bounded_linear_scaleR_left[THEN bounded_linear_compose]
  1693 
  1694 lemmas bounded_linear_const_scaleR =
  1695   bounded_linear_scaleR_right[THEN bounded_linear_compose]
  1696 
  1697 lemma bounded_linear_of_real: "bounded_linear (\<lambda>r. of_real r)"
  1698   unfolding of_real_def by (rule bounded_linear_scaleR_left)
  1699 
  1700 lemma real_bounded_linear: "bounded_linear f \<longleftrightarrow> (\<exists>c::real. f = (\<lambda>x. x * c))"
  1701   for f :: "real \<Rightarrow> real"
  1702 proof -
  1703   {
  1704     fix x
  1705     assume "bounded_linear f"
  1706     then interpret bounded_linear f .
  1707     from scaleR[of x 1] have "f x = x * f 1"
  1708       by simp
  1709   }
  1710   then show ?thesis
  1711     by (auto intro: exI[of _ "f 1"] bounded_linear_mult_left)
  1712 qed
  1713 
  1714 lemma bij_linear_imp_inv_linear: "linear f \<Longrightarrow> bij f \<Longrightarrow> linear (inv f)"
  1715   by (auto simp: linear_def linear_axioms_def additive_def bij_is_surj bij_is_inj surj_f_inv_f
  1716       intro!:  Hilbert_Choice.inv_f_eq)
  1717 
  1718 instance real_normed_algebra_1 \<subseteq> perfect_space
  1719 proof
  1720   show "\<not> open {x}" for x :: 'a
  1721     apply (simp only: open_dist dist_norm)
  1722     apply clarsimp
  1723     apply (rule_tac x = "x + of_real (e/2)" in exI)
  1724     apply simp
  1725     done
  1726 qed
  1727 
  1728 
  1729 subsection \<open>Filters and Limits on Metric Space\<close>
  1730 
  1731 lemma (in metric_space) nhds_metric: "nhds x = (INF e:{0 <..}. principal {y. dist y x < e})"
  1732   unfolding nhds_def
  1733 proof (safe intro!: INF_eq)
  1734   fix S
  1735   assume "open S" "x \<in> S"
  1736   then obtain e where "{y. dist y x < e} \<subseteq> S" "0 < e"
  1737     by (auto simp: open_dist subset_eq)
  1738   then show "\<exists>e\<in>{0<..}. principal {y. dist y x < e} \<le> principal S"
  1739     by auto
  1740 qed (auto intro!: exI[of _ "{y. dist x y < e}" for e] open_ball simp: dist_commute)
  1741 
  1742 lemma (in metric_space) tendsto_iff: "(f \<longlongrightarrow> l) F \<longleftrightarrow> (\<forall>e>0. eventually (\<lambda>x. dist (f x) l < e) F)"
  1743   unfolding nhds_metric filterlim_INF filterlim_principal by auto
  1744 
  1745 lemma (in metric_space) tendstoI [intro?]:
  1746   "(\<And>e. 0 < e \<Longrightarrow> eventually (\<lambda>x. dist (f x) l < e) F) \<Longrightarrow> (f \<longlongrightarrow> l) F"
  1747   by (auto simp: tendsto_iff)
  1748 
  1749 lemma (in metric_space) tendstoD: "(f \<longlongrightarrow> l) F \<Longrightarrow> 0 < e \<Longrightarrow> eventually (\<lambda>x. dist (f x) l < e) F"
  1750   by (auto simp: tendsto_iff)
  1751 
  1752 lemma (in metric_space) eventually_nhds_metric:
  1753   "eventually P (nhds a) \<longleftrightarrow> (\<exists>d>0. \<forall>x. dist x a < d \<longrightarrow> P x)"
  1754   unfolding nhds_metric
  1755   by (subst eventually_INF_base)
  1756      (auto simp: eventually_principal Bex_def subset_eq intro: exI[of _ "min a b" for a b])
  1757 
  1758 lemma eventually_at: "eventually P (at a within S) \<longleftrightarrow> (\<exists>d>0. \<forall>x\<in>S. x \<noteq> a \<and> dist x a < d \<longrightarrow> P x)"
  1759   for a :: "'a :: metric_space"
  1760   by (auto simp: eventually_at_filter eventually_nhds_metric)
  1761 
  1762 lemma eventually_at_le: "eventually P (at a within S) \<longleftrightarrow> (\<exists>d>0. \<forall>x\<in>S. x \<noteq> a \<and> dist x a \<le> d \<longrightarrow> P x)"
  1763   for a :: "'a::metric_space"
  1764   apply (simp only: eventually_at_filter eventually_nhds_metric)
  1765   apply auto
  1766   apply (rule_tac x="d / 2" in exI)
  1767   apply auto
  1768   done
  1769 
  1770 lemma eventually_at_left_real: "a > (b :: real) \<Longrightarrow> eventually (\<lambda>x. x \<in> {b<..<a}) (at_left a)"
  1771   by (subst eventually_at, rule exI[of _ "a - b"]) (force simp: dist_real_def)
  1772 
  1773 lemma eventually_at_right_real: "a < (b :: real) \<Longrightarrow> eventually (\<lambda>x. x \<in> {a<..<b}) (at_right a)"
  1774   by (subst eventually_at, rule exI[of _ "b - a"]) (force simp: dist_real_def)
  1775 
  1776 lemma metric_tendsto_imp_tendsto:
  1777   fixes a :: "'a :: metric_space"
  1778     and b :: "'b :: metric_space"
  1779   assumes f: "(f \<longlongrightarrow> a) F"
  1780     and le: "eventually (\<lambda>x. dist (g x) b \<le> dist (f x) a) F"
  1781   shows "(g \<longlongrightarrow> b) F"
  1782 proof (rule tendstoI)
  1783   fix e :: real
  1784   assume "0 < e"
  1785   with f have "eventually (\<lambda>x. dist (f x) a < e) F" by (rule tendstoD)
  1786   with le show "eventually (\<lambda>x. dist (g x) b < e) F"
  1787     using le_less_trans by (rule eventually_elim2)
  1788 qed
  1789 
  1790 lemma filterlim_real_sequentially: "LIM x sequentially. real x :> at_top"
  1791   apply (simp only: filterlim_at_top)
  1792   apply (intro allI)
  1793   apply (rule_tac c="nat \<lceil>Z + 1\<rceil>" in eventually_sequentiallyI)
  1794   apply linarith
  1795   done
  1796 
  1797 lemma filterlim_nat_sequentially: "filterlim nat sequentially at_top"
  1798   unfolding filterlim_at_top
  1799   apply (rule allI)
  1800   subgoal for Z by (auto intro!: eventually_at_top_linorderI[where c="int Z"])
  1801   done
  1802 
  1803 lemma filterlim_floor_sequentially: "filterlim floor at_top at_top"
  1804   unfolding filterlim_at_top
  1805   apply (rule allI)
  1806   subgoal for Z by (auto simp: le_floor_iff intro!: eventually_at_top_linorderI[where c="of_int Z"])
  1807   done
  1808 
  1809 lemma filterlim_sequentially_iff_filterlim_real:
  1810   "filterlim f sequentially F \<longleftrightarrow> filterlim (\<lambda>x. real (f x)) at_top F"
  1811   apply (rule iffI)
  1812   subgoal using filterlim_compose filterlim_real_sequentially by blast
  1813   subgoal premises prems
  1814   proof -
  1815     have "filterlim (\<lambda>x. nat (floor (real (f x)))) sequentially F"
  1816       by (intro filterlim_compose[OF filterlim_nat_sequentially]
  1817           filterlim_compose[OF filterlim_floor_sequentially] prems)
  1818     then show ?thesis by simp
  1819   qed
  1820   done
  1821 
  1822 
  1823 subsubsection \<open>Limits of Sequences\<close>
  1824 
  1825 lemma lim_sequentially: "X \<longlonglongrightarrow> L \<longleftrightarrow> (\<forall>r>0. \<exists>no. \<forall>n\<ge>no. dist (X n) L < r)"
  1826   for L :: "'a::metric_space"
  1827   unfolding tendsto_iff eventually_sequentially ..
  1828 
  1829 lemmas LIMSEQ_def = lim_sequentially  (*legacy binding*)
  1830 
  1831 lemma LIMSEQ_iff_nz: "X \<longlonglongrightarrow> L \<longleftrightarrow> (\<forall>r>0. \<exists>no>0. \<forall>n\<ge>no. dist (X n) L < r)"
  1832   for L :: "'a::metric_space"
  1833   unfolding lim_sequentially by (metis Suc_leD zero_less_Suc)
  1834 
  1835 lemma metric_LIMSEQ_I: "(\<And>r. 0 < r \<Longrightarrow> \<exists>no. \<forall>n\<ge>no. dist (X n) L < r) \<Longrightarrow> X \<longlonglongrightarrow> L"
  1836   for L :: "'a::metric_space"
  1837   by (simp add: lim_sequentially)
  1838 
  1839 lemma metric_LIMSEQ_D: "X \<longlonglongrightarrow> L \<Longrightarrow> 0 < r \<Longrightarrow> \<exists>no. \<forall>n\<ge>no. dist (X n) L < r"
  1840   for L :: "'a::metric_space"
  1841   by (simp add: lim_sequentially)
  1842 
  1843 
  1844 subsubsection \<open>Limits of Functions\<close>
  1845 
  1846 lemma LIM_def: "f \<midarrow>a\<rightarrow> L \<longleftrightarrow> (\<forall>r > 0. \<exists>s > 0. \<forall>x. x \<noteq> a \<and> dist x a < s \<longrightarrow> dist (f x) L < r)"
  1847   for a :: "'a::metric_space" and L :: "'b::metric_space"
  1848   unfolding tendsto_iff eventually_at by simp
  1849 
  1850 lemma metric_LIM_I:
  1851   "(\<And>r. 0 < r \<Longrightarrow> \<exists>s>0. \<forall>x. x \<noteq> a \<and> dist x a < s \<longrightarrow> dist (f x) L < r) \<Longrightarrow> f \<midarrow>a\<rightarrow> L"
  1852   for a :: "'a::metric_space" and L :: "'b::metric_space"
  1853   by (simp add: LIM_def)
  1854 
  1855 lemma metric_LIM_D: "f \<midarrow>a\<rightarrow> L \<Longrightarrow> 0 < r \<Longrightarrow> \<exists>s>0. \<forall>x. x \<noteq> a \<and> dist x a < s \<longrightarrow> dist (f x) L < r"
  1856   for a :: "'a::metric_space" and L :: "'b::metric_space"
  1857   by (simp add: LIM_def)
  1858 
  1859 lemma metric_LIM_imp_LIM:
  1860   fixes l :: "'a::metric_space"
  1861     and m :: "'b::metric_space"
  1862   assumes f: "f \<midarrow>a\<rightarrow> l"
  1863     and le: "\<And>x. x \<noteq> a \<Longrightarrow> dist (g x) m \<le> dist (f x) l"
  1864   shows "g \<midarrow>a\<rightarrow> m"
  1865   by (rule metric_tendsto_imp_tendsto [OF f]) (auto simp add: eventually_at_topological le)
  1866 
  1867 lemma metric_LIM_equal2:
  1868   fixes a :: "'a::metric_space"
  1869   assumes "0 < R"
  1870     and "\<And>x. x \<noteq> a \<Longrightarrow> dist x a < R \<Longrightarrow> f x = g x"
  1871   shows "g \<midarrow>a\<rightarrow> l \<Longrightarrow> f \<midarrow>a\<rightarrow> l"
  1872   apply (rule topological_tendstoI)
  1873   apply (drule (2) topological_tendstoD)
  1874   apply (simp add: eventually_at)
  1875   apply safe
  1876   apply (rule_tac x="min d R" in exI)
  1877   apply safe
  1878    apply (simp add: assms(1))
  1879   apply (simp add: assms(2))
  1880   done
  1881 
  1882 lemma metric_LIM_compose2:
  1883   fixes a :: "'a::metric_space"
  1884   assumes f: "f \<midarrow>a\<rightarrow> b"
  1885     and g: "g \<midarrow>b\<rightarrow> c"
  1886     and inj: "\<exists>d>0. \<forall>x. x \<noteq> a \<and> dist x a < d \<longrightarrow> f x \<noteq> b"
  1887   shows "(\<lambda>x. g (f x)) \<midarrow>a\<rightarrow> c"
  1888   using inj by (intro tendsto_compose_eventually[OF g f]) (auto simp: eventually_at)
  1889 
  1890 lemma metric_isCont_LIM_compose2:
  1891   fixes f :: "'a :: metric_space \<Rightarrow> _"
  1892   assumes f [unfolded isCont_def]: "isCont f a"
  1893     and g: "g \<midarrow>f a\<rightarrow> l"
  1894     and inj: "\<exists>d>0. \<forall>x. x \<noteq> a \<and> dist x a < d \<longrightarrow> f x \<noteq> f a"
  1895   shows "(\<lambda>x. g (f x)) \<midarrow>a\<rightarrow> l"
  1896   by (rule metric_LIM_compose2 [OF f g inj])
  1897 
  1898 
  1899 subsection \<open>Complete metric spaces\<close>
  1900 
  1901 subsection \<open>Cauchy sequences\<close>
  1902 
  1903 lemma (in metric_space) Cauchy_def: "Cauchy X = (\<forall>e>0. \<exists>M. \<forall>m\<ge>M. \<forall>n\<ge>M. dist (X m) (X n) < e)"
  1904 proof -
  1905   have *: "eventually P (INF M. principal {(X m, X n) | n m. m \<ge> M \<and> n \<ge> M}) \<longleftrightarrow>
  1906     (\<exists>M. \<forall>m\<ge>M. \<forall>n\<ge>M. P (X m, X n))" for P
  1907     apply (subst eventually_INF_base)
  1908     subgoal by simp
  1909     subgoal for a b
  1910       by (intro bexI[of _ "max a b"]) (auto simp: eventually_principal subset_eq)
  1911     subgoal by (auto simp: eventually_principal, blast)
  1912     done
  1913   have "Cauchy X \<longleftrightarrow> (INF M. principal {(X m, X n) | n m. m \<ge> M \<and> n \<ge> M}) \<le> uniformity"
  1914     unfolding Cauchy_uniform_iff le_filter_def * ..
  1915   also have "\<dots> = (\<forall>e>0. \<exists>M. \<forall>m\<ge>M. \<forall>n\<ge>M. dist (X m) (X n) < e)"
  1916     unfolding uniformity_dist le_INF_iff by (auto simp: * le_principal)
  1917   finally show ?thesis .
  1918 qed
  1919 
  1920 lemma (in metric_space) Cauchy_altdef: "Cauchy f \<longleftrightarrow> (\<forall>e>0. \<exists>M. \<forall>m\<ge>M. \<forall>n>m. dist (f m) (f n) < e)"
  1921   (is "?lhs \<longleftrightarrow> ?rhs")
  1922 proof
  1923   assume ?rhs
  1924   show ?lhs
  1925     unfolding Cauchy_def
  1926   proof (intro allI impI)
  1927     fix e :: real assume e: "e > 0"
  1928     with \<open>?rhs\<close> obtain M where M: "m \<ge> M \<Longrightarrow> n > m \<Longrightarrow> dist (f m) (f n) < e" for m n
  1929       by blast
  1930     have "dist (f m) (f n) < e" if "m \<ge> M" "n \<ge> M" for m n
  1931       using M[of m n] M[of n m] e that by (cases m n rule: linorder_cases) (auto simp: dist_commute)
  1932     then show "\<exists>M. \<forall>m\<ge>M. \<forall>n\<ge>M. dist (f m) (f n) < e"
  1933       by blast
  1934   qed
  1935 next
  1936   assume ?lhs
  1937   show ?rhs
  1938   proof (intro allI impI)
  1939     fix e :: real
  1940     assume e: "e > 0"
  1941     with \<open>Cauchy f\<close> obtain M where "\<And>m n. m \<ge> M \<Longrightarrow> n \<ge> M \<Longrightarrow> dist (f m) (f n) < e"
  1942       unfolding Cauchy_def by blast
  1943     then show "\<exists>M. \<forall>m\<ge>M. \<forall>n>m. dist (f m) (f n) < e"
  1944       by (intro exI[of _ M]) force
  1945   qed
  1946 qed
  1947 
  1948 lemma (in metric_space) metric_CauchyI:
  1949   "(\<And>e. 0 < e \<Longrightarrow> \<exists>M. \<forall>m\<ge>M. \<forall>n\<ge>M. dist (X m) (X n) < e) \<Longrightarrow> Cauchy X"
  1950   by (simp add: Cauchy_def)
  1951 
  1952 lemma (in metric_space) CauchyI':
  1953   "(\<And>e. 0 < e \<Longrightarrow> \<exists>M. \<forall>m\<ge>M. \<forall>n>m. dist (X m) (X n) < e) \<Longrightarrow> Cauchy X"
  1954   unfolding Cauchy_altdef by blast
  1955 
  1956 lemma (in metric_space) metric_CauchyD:
  1957   "Cauchy X \<Longrightarrow> 0 < e \<Longrightarrow> \<exists>M. \<forall>m\<ge>M. \<forall>n\<ge>M. dist (X m) (X n) < e"
  1958   by (simp add: Cauchy_def)
  1959 
  1960 lemma (in metric_space) metric_Cauchy_iff2:
  1961   "Cauchy X = (\<forall>j. (\<exists>M. \<forall>m \<ge> M. \<forall>n \<ge> M. dist (X m) (X n) < inverse(real (Suc j))))"
  1962   apply (simp add: Cauchy_def)
  1963   apply auto
  1964   apply (drule reals_Archimedean)
  1965   apply safe
  1966   apply (drule_tac x = n in spec)
  1967   apply auto
  1968   apply (rule_tac x = M in exI)
  1969   apply auto
  1970   apply (drule_tac x = m in spec)
  1971   apply simp
  1972   apply (drule_tac x = na in spec)
  1973   apply auto
  1974   done
  1975 
  1976 lemma Cauchy_iff2: "Cauchy X \<longleftrightarrow> (\<forall>j. (\<exists>M. \<forall>m \<ge> M. \<forall>n \<ge> M. \<bar>X m - X n\<bar> < inverse (real (Suc j))))"
  1977   by (simp only: metric_Cauchy_iff2 dist_real_def)
  1978 
  1979 lemma lim_1_over_n: "((\<lambda>n. 1 / of_nat n) \<longlongrightarrow> (0::'a::real_normed_field)) sequentially"
  1980 proof (subst lim_sequentially, intro allI impI exI)
  1981   fix e :: real
  1982   assume e: "e > 0"
  1983   fix n :: nat
  1984   assume n: "n \<ge> nat \<lceil>inverse e + 1\<rceil>"
  1985   have "inverse e < of_nat (nat \<lceil>inverse e + 1\<rceil>)" by linarith
  1986   also note n
  1987   finally show "dist (1 / of_nat n :: 'a) 0 < e"
  1988     using e by (simp add: divide_simps mult.commute norm_divide)
  1989 qed
  1990 
  1991 lemma (in metric_space) complete_def:
  1992   shows "complete S = (\<forall>f. (\<forall>n. f n \<in> S) \<and> Cauchy f \<longrightarrow> (\<exists>l\<in>S. f \<longlonglongrightarrow> l))"
  1993   unfolding complete_uniform
  1994 proof safe
  1995   fix f :: "nat \<Rightarrow> 'a"
  1996   assume f: "\<forall>n. f n \<in> S" "Cauchy f"
  1997     and *: "\<forall>F\<le>principal S. F \<noteq> bot \<longrightarrow> cauchy_filter F \<longrightarrow> (\<exists>x\<in>S. F \<le> nhds x)"
  1998   then show "\<exists>l\<in>S. f \<longlonglongrightarrow> l"
  1999     unfolding filterlim_def using f
  2000     by (intro *[rule_format])
  2001        (auto simp: filtermap_sequentually_ne_bot le_principal eventually_filtermap Cauchy_uniform)
  2002 next
  2003   fix F :: "'a filter"
  2004   assume "F \<le> principal S" "F \<noteq> bot" "cauchy_filter F"
  2005   assume seq: "\<forall>f. (\<forall>n. f n \<in> S) \<and> Cauchy f \<longrightarrow> (\<exists>l\<in>S. f \<longlonglongrightarrow> l)"
  2006 
  2007   from \<open>F \<le> principal S\<close> \<open>cauchy_filter F\<close>
  2008   have FF_le: "F \<times>\<^sub>F F \<le> uniformity_on S"
  2009     by (simp add: cauchy_filter_def principal_prod_principal[symmetric] prod_filter_mono)
  2010 
  2011   let ?P = "\<lambda>P e. eventually P F \<and> (\<forall>x. P x \<longrightarrow> x \<in> S) \<and> (\<forall>x y. P x \<longrightarrow> P y \<longrightarrow> dist x y < e)"
  2012   have P: "\<exists>P. ?P P \<epsilon>" if "0 < \<epsilon>" for \<epsilon> :: real
  2013   proof -
  2014     from that have "eventually (\<lambda>(x, y). x \<in> S \<and> y \<in> S \<and> dist x y < \<epsilon>) (uniformity_on S)"
  2015       by (auto simp: eventually_inf_principal eventually_uniformity_metric)
  2016     from filter_leD[OF FF_le this] show ?thesis
  2017       by (auto simp: eventually_prod_same)
  2018   qed
  2019 
  2020   have "\<exists>P. \<forall>n. ?P (P n) (1 / Suc n) \<and> P (Suc n) \<le> P n"
  2021   proof (rule dependent_nat_choice)
  2022     show "\<exists>P. ?P P (1 / Suc 0)"
  2023       using P[of 1] by auto
  2024   next
  2025     fix P n assume "?P P (1/Suc n)"
  2026     moreover obtain Q where "?P Q (1 / Suc (Suc n))"
  2027       using P[of "1/Suc (Suc n)"] by auto
  2028     ultimately show "\<exists>Q. ?P Q (1 / Suc (Suc n)) \<and> Q \<le> P"
  2029       by (intro exI[of _ "\<lambda>x. P x \<and> Q x"]) (auto simp: eventually_conj_iff)
  2030   qed
  2031   then obtain P where P: "eventually (P n) F" "P n x \<Longrightarrow> x \<in> S"
  2032     "P n x \<Longrightarrow> P n y \<Longrightarrow> dist x y < 1 / Suc n" "P (Suc n) \<le> P n"
  2033     for n x y
  2034     by metis
  2035   have "antimono P"
  2036     using P(4) unfolding decseq_Suc_iff le_fun_def by blast
  2037 
  2038   obtain X where X: "P n (X n)" for n
  2039     using P(1)[THEN eventually_happens'[OF \<open>F \<noteq> bot\<close>]] by metis
  2040   have "Cauchy X"
  2041     unfolding metric_Cauchy_iff2 inverse_eq_divide
  2042   proof (intro exI allI impI)
  2043     fix j m n :: nat
  2044     assume "j \<le> m" "j \<le> n"
  2045     with \<open>antimono P\<close> X have "P j (X m)" "P j (X n)"
  2046       by (auto simp: antimono_def)
  2047     then show "dist (X m) (X n) < 1 / Suc j"
  2048       by (rule P)
  2049   qed
  2050   moreover have "\<forall>n. X n \<in> S"
  2051     using P(2) X by auto
  2052   ultimately obtain x where "X \<longlonglongrightarrow> x" "x \<in> S"
  2053     using seq by blast
  2054 
  2055   show "\<exists>x\<in>S. F \<le> nhds x"
  2056   proof (rule bexI)
  2057     have "eventually (\<lambda>y. dist y x < e) F" if "0 < e" for e :: real
  2058     proof -
  2059       from that have "(\<lambda>n. 1 / Suc n :: real) \<longlonglongrightarrow> 0 \<and> 0 < e / 2"
  2060         by (subst LIMSEQ_Suc_iff) (auto intro!: lim_1_over_n)
  2061       then have "\<forall>\<^sub>F n in sequentially. dist (X n) x < e / 2 \<and> 1 / Suc n < e / 2"
  2062         using \<open>X \<longlonglongrightarrow> x\<close>
  2063         unfolding tendsto_iff order_tendsto_iff[where 'a=real] eventually_conj_iff
  2064         by blast
  2065       then obtain n where "dist x (X n) < e / 2" "1 / Suc n < e / 2"
  2066         by (auto simp: eventually_sequentially dist_commute)
  2067       show ?thesis
  2068         using \<open>eventually (P n) F\<close>
  2069       proof eventually_elim
  2070         case (elim y)
  2071         then have "dist y (X n) < 1 / Suc n"
  2072           by (intro X P)
  2073         also have "\<dots> < e / 2" by fact
  2074         finally show "dist y x < e"
  2075           by (rule dist_triangle_half_l) fact
  2076       qed
  2077     qed
  2078     then show "F \<le> nhds x"
  2079       unfolding nhds_metric le_INF_iff le_principal by auto
  2080   qed fact
  2081 qed
  2082 
  2083 lemma (in metric_space) totally_bounded_metric:
  2084   "totally_bounded S \<longleftrightarrow> (\<forall>e>0. \<exists>k. finite k \<and> S \<subseteq> (\<Union>x\<in>k. {y. dist x y < e}))"
  2085   apply (simp only: totally_bounded_def eventually_uniformity_metric imp_ex)
  2086   apply (subst all_comm)
  2087   apply (intro arg_cong[where f=All] ext)
  2088   apply safe
  2089   subgoal for e
  2090     apply (erule allE[of _ "\<lambda>(x, y). dist x y < e"])
  2091     apply auto
  2092     done
  2093   subgoal for e P k
  2094     apply (intro exI[of _ k])
  2095     apply (force simp: subset_eq)
  2096     done
  2097   done
  2098 
  2099 
  2100 subsubsection \<open>Cauchy Sequences are Convergent\<close>
  2101 
  2102 (* TODO: update to uniform_space *)
  2103 class complete_space = metric_space +
  2104   assumes Cauchy_convergent: "Cauchy X \<Longrightarrow> convergent X"
  2105 
  2106 lemma Cauchy_convergent_iff: "Cauchy X \<longleftrightarrow> convergent X"
  2107   for X :: "nat \<Rightarrow> 'a::complete_space"
  2108   by (blast intro: Cauchy_convergent convergent_Cauchy)
  2109 
  2110 
  2111 subsection \<open>The set of real numbers is a complete metric space\<close>
  2112 
  2113 text \<open>
  2114   Proof that Cauchy sequences converge based on the one from
  2115   \<^url>\<open>http://pirate.shu.edu/~wachsmut/ira/numseq/proofs/cauconv.html\<close>
  2116 \<close>
  2117 
  2118 text \<open>
  2119   If sequence @{term "X"} is Cauchy, then its limit is the lub of
  2120   @{term "{r::real. \<exists>N. \<forall>n\<ge>N. r < X n}"}
  2121 \<close>
  2122 lemma increasing_LIMSEQ:
  2123   fixes f :: "nat \<Rightarrow> real"
  2124   assumes inc: "\<And>n. f n \<le> f (Suc n)"
  2125     and bdd: "\<And>n. f n \<le> l"
  2126     and en: "\<And>e. 0 < e \<Longrightarrow> \<exists>n. l \<le> f n + e"
  2127   shows "f \<longlonglongrightarrow> l"
  2128 proof (rule increasing_tendsto)
  2129   fix x
  2130   assume "x < l"
  2131   with dense[of 0 "l - x"] obtain e where "0 < e" "e < l - x"
  2132     by auto
  2133   from en[OF \<open>0 < e\<close>] obtain n where "l - e \<le> f n"
  2134     by (auto simp: field_simps)
  2135   with \<open>e < l - x\<close> \<open>0 < e\<close> have "x < f n"
  2136     by simp
  2137   with incseq_SucI[of f, OF inc] show "eventually (\<lambda>n. x < f n) sequentially"
  2138     by (auto simp: eventually_sequentially incseq_def intro: less_le_trans)
  2139 qed (use bdd in auto)
  2140 
  2141 lemma real_Cauchy_convergent:
  2142   fixes X :: "nat \<Rightarrow> real"
  2143   assumes X: "Cauchy X"
  2144   shows "convergent X"
  2145 proof -
  2146   define S :: "real set" where "S = {x. \<exists>N. \<forall>n\<ge>N. x < X n}"
  2147   then have mem_S: "\<And>N x. \<forall>n\<ge>N. x < X n \<Longrightarrow> x \<in> S"
  2148     by auto
  2149 
  2150   have bound_isUb: "y \<le> x" if N: "\<forall>n\<ge>N. X n < x" and "y \<in> S" for N and x y :: real
  2151   proof -
  2152     from that have "\<exists>M. \<forall>n\<ge>M. y < X n"
  2153       by (simp add: S_def)
  2154     then obtain M where "\<forall>n\<ge>M. y < X n" ..
  2155     then have "y < X (max M N)" by simp
  2156     also have "\<dots> < x" using N by simp
  2157     finally show ?thesis by (rule order_less_imp_le)
  2158   qed
  2159 
  2160   obtain N where "\<forall>m\<ge>N. \<forall>n\<ge>N. dist (X m) (X n) < 1"
  2161     using X[THEN metric_CauchyD, OF zero_less_one] by auto
  2162   then have N: "\<forall>n\<ge>N. dist (X n) (X N) < 1" by simp
  2163   have [simp]: "S \<noteq> {}"
  2164   proof (intro exI ex_in_conv[THEN iffD1])
  2165     from N have "\<forall>n\<ge>N. X N - 1 < X n"
  2166       by (simp add: abs_diff_less_iff dist_real_def)
  2167     then show "X N - 1 \<in> S" by (rule mem_S)
  2168   qed
  2169   have [simp]: "bdd_above S"
  2170   proof
  2171     from N have "\<forall>n\<ge>N. X n < X N + 1"
  2172       by (simp add: abs_diff_less_iff dist_real_def)
  2173     then show "\<And>s. s \<in> S \<Longrightarrow>  s \<le> X N + 1"
  2174       by (rule bound_isUb)
  2175   qed
  2176   have "X \<longlonglongrightarrow> Sup S"
  2177   proof (rule metric_LIMSEQ_I)
  2178     fix r :: real
  2179     assume "0 < r"
  2180     then have r: "0 < r/2" by simp
  2181     obtain N where "\<forall>n\<ge>N. \<forall>m\<ge>N. dist (X n) (X m) < r/2"
  2182       using metric_CauchyD [OF X r] by auto
  2183     then have "\<forall>n\<ge>N. dist (X n) (X N) < r/2" by simp
  2184     then have N: "\<forall>n\<ge>N. X N - r/2 < X n \<and> X n < X N + r/2"
  2185       by (simp only: dist_real_def abs_diff_less_iff)
  2186 
  2187     from N have "\<forall>n\<ge>N. X N - r/2 < X n" by blast
  2188     then have "X N - r/2 \<in> S" by (rule mem_S)
  2189     then have 1: "X N - r/2 \<le> Sup S" by (simp add: cSup_upper)
  2190 
  2191     from N have "\<forall>n\<ge>N. X n < X N + r/2" by blast
  2192     from bound_isUb[OF this]
  2193     have 2: "Sup S \<le> X N + r/2"
  2194       by (intro cSup_least) simp_all
  2195 
  2196     show "\<exists>N. \<forall>n\<ge>N. dist (X n) (Sup S) < r"
  2197     proof (intro exI allI impI)
  2198       fix n
  2199       assume n: "N \<le> n"
  2200       from N n have "X n < X N + r/2" and "X N - r/2 < X n"
  2201         by simp_all
  2202       then show "dist (X n) (Sup S) < r" using 1 2
  2203         by (simp add: abs_diff_less_iff dist_real_def)
  2204     qed
  2205   qed
  2206   then show ?thesis by (auto simp: convergent_def)
  2207 qed
  2208 
  2209 instance real :: complete_space
  2210   by intro_classes (rule real_Cauchy_convergent)
  2211 
  2212 class banach = real_normed_vector + complete_space
  2213 
  2214 instance real :: banach ..
  2215 
  2216 lemma tendsto_at_topI_sequentially:
  2217   fixes f :: "real \<Rightarrow> 'b::first_countable_topology"
  2218   assumes *: "\<And>X. filterlim X at_top sequentially \<Longrightarrow> (\<lambda>n. f (X n)) \<longlonglongrightarrow> y"
  2219   shows "(f \<longlongrightarrow> y) at_top"
  2220 proof -
  2221   obtain A where A: "decseq A" "open (A n)" "y \<in> A n" "nhds y = (INF n. principal (A n))" for n
  2222     by (rule nhds_countable[of y]) (rule that)
  2223 
  2224   have "\<forall>m. \<exists>k. \<forall>x\<ge>k. f x \<in> A m"
  2225   proof (rule ccontr)
  2226     assume "\<not> (\<forall>m. \<exists>k. \<forall>x\<ge>k. f x \<in> A m)"
  2227     then obtain m where "\<And>k. \<exists>x\<ge>k. f x \<notin> A m"
  2228       by auto
  2229     then have "\<exists>X. \<forall>n. (f (X n) \<notin> A m) \<and> max n (X n) + 1 \<le> X (Suc n)"
  2230       by (intro dependent_nat_choice) (auto simp del: max.bounded_iff)
  2231     then obtain X where X: "\<And>n. f (X n) \<notin> A m" "\<And>n. max n (X n) + 1 \<le> X (Suc n)"
  2232       by auto
  2233     have "1 \<le> n \<Longrightarrow> real n \<le> X n" for n
  2234       using X[of "n - 1"] by auto
  2235     then have "filterlim X at_top sequentially"
  2236       by (force intro!: filterlim_at_top_mono[OF filterlim_real_sequentially]
  2237           simp: eventually_sequentially)
  2238     from topological_tendstoD[OF *[OF this] A(2, 3), of m] X(1) show False
  2239       by auto
  2240   qed
  2241   then obtain k where "k m \<le> x \<Longrightarrow> f x \<in> A m" for m x
  2242     by metis
  2243   then show ?thesis
  2244     unfolding at_top_def A by (intro filterlim_base[where i=k]) auto
  2245 qed
  2246 
  2247 lemma tendsto_at_topI_sequentially_real:
  2248   fixes f :: "real \<Rightarrow> real"
  2249   assumes mono: "mono f"
  2250     and limseq: "(\<lambda>n. f (real n)) \<longlonglongrightarrow> y"
  2251   shows "(f \<longlongrightarrow> y) at_top"
  2252 proof (rule tendstoI)
  2253   fix e :: real
  2254   assume "0 < e"
  2255   with limseq obtain N :: nat where N: "N \<le> n \<Longrightarrow> \<bar>f (real n) - y\<bar> < e" for n
  2256     by (auto simp: lim_sequentially dist_real_def)
  2257   have le: "f x \<le> y" for x :: real
  2258   proof -
  2259     obtain n where "x \<le> real_of_nat n"
  2260       using real_arch_simple[of x] ..
  2261     note monoD[OF mono this]
  2262     also have "f (real_of_nat n) \<le> y"
  2263       by (rule LIMSEQ_le_const[OF limseq]) (auto intro!: exI[of _ n] monoD[OF mono])
  2264     finally show ?thesis .
  2265   qed
  2266   have "eventually (\<lambda>x. real N \<le> x) at_top"
  2267     by (rule eventually_ge_at_top)
  2268   then show "eventually (\<lambda>x. dist (f x) y < e) at_top"
  2269   proof eventually_elim
  2270     case (elim x)
  2271     with N[of N] le have "y - f (real N) < e" by auto
  2272     moreover note monoD[OF mono elim]
  2273     ultimately show "dist (f x) y < e"
  2274       using le[of x] by (auto simp: dist_real_def field_simps)
  2275   qed
  2276 qed
  2277 
  2278 end