src/HOL/Finite_Set.thy
author wenzelm
Thu May 24 17:25:53 2012 +0200 (2012-05-24)
changeset 47988 e4b69e10b990
parent 47221 7205eb4a0a05
child 48063 f02b4302d5dd
permissions -rw-r--r--
tuned proofs;
     1 (*  Title:      HOL/Finite_Set.thy
     2     Author:     Tobias Nipkow, Lawrence C Paulson and Markus Wenzel
     3                 with contributions by Jeremy Avigad
     4 *)
     5 
     6 header {* Finite sets *}
     7 
     8 theory Finite_Set
     9 imports Option Power
    10 begin
    11 
    12 subsection {* Predicate for finite sets *}
    13 
    14 inductive finite :: "'a set \<Rightarrow> bool"
    15   where
    16     emptyI [simp, intro!]: "finite {}"
    17   | insertI [simp, intro!]: "finite A \<Longrightarrow> finite (insert a A)"
    18 
    19 lemma finite_induct [case_names empty insert, induct set: finite]:
    20   -- {* Discharging @{text "x \<notin> F"} entails extra work. *}
    21   assumes "finite F"
    22   assumes "P {}"
    23     and insert: "\<And>x F. finite F \<Longrightarrow> x \<notin> F \<Longrightarrow> P F \<Longrightarrow> P (insert x F)"
    24   shows "P F"
    25 using `finite F`
    26 proof induct
    27   show "P {}" by fact
    28   fix x F assume F: "finite F" and P: "P F"
    29   show "P (insert x F)"
    30   proof cases
    31     assume "x \<in> F"
    32     hence "insert x F = F" by (rule insert_absorb)
    33     with P show ?thesis by (simp only:)
    34   next
    35     assume "x \<notin> F"
    36     from F this P show ?thesis by (rule insert)
    37   qed
    38 qed
    39 
    40 
    41 subsubsection {* Choice principles *}
    42 
    43 lemma ex_new_if_finite: -- "does not depend on def of finite at all"
    44   assumes "\<not> finite (UNIV :: 'a set)" and "finite A"
    45   shows "\<exists>a::'a. a \<notin> A"
    46 proof -
    47   from assms have "A \<noteq> UNIV" by blast
    48   then show ?thesis by blast
    49 qed
    50 
    51 text {* A finite choice principle. Does not need the SOME choice operator. *}
    52 
    53 lemma finite_set_choice:
    54   "finite A \<Longrightarrow> \<forall>x\<in>A. \<exists>y. P x y \<Longrightarrow> \<exists>f. \<forall>x\<in>A. P x (f x)"
    55 proof (induct rule: finite_induct)
    56   case empty then show ?case by simp
    57 next
    58   case (insert a A)
    59   then obtain f b where f: "ALL x:A. P x (f x)" and ab: "P a b" by auto
    60   show ?case (is "EX f. ?P f")
    61   proof
    62     show "?P(%x. if x = a then b else f x)" using f ab by auto
    63   qed
    64 qed
    65 
    66 
    67 subsubsection {* Finite sets are the images of initial segments of natural numbers *}
    68 
    69 lemma finite_imp_nat_seg_image_inj_on:
    70   assumes "finite A" 
    71   shows "\<exists>(n::nat) f. A = f ` {i. i < n} \<and> inj_on f {i. i < n}"
    72 using assms
    73 proof induct
    74   case empty
    75   show ?case
    76   proof
    77     show "\<exists>f. {} = f ` {i::nat. i < 0} \<and> inj_on f {i. i < 0}" by simp 
    78   qed
    79 next
    80   case (insert a A)
    81   have notinA: "a \<notin> A" by fact
    82   from insert.hyps obtain n f
    83     where "A = f ` {i::nat. i < n}" "inj_on f {i. i < n}" by blast
    84   hence "insert a A = f(n:=a) ` {i. i < Suc n}"
    85         "inj_on (f(n:=a)) {i. i < Suc n}" using notinA
    86     by (auto simp add: image_def Ball_def inj_on_def less_Suc_eq)
    87   thus ?case by blast
    88 qed
    89 
    90 lemma nat_seg_image_imp_finite:
    91   "A = f ` {i::nat. i < n} \<Longrightarrow> finite A"
    92 proof (induct n arbitrary: A)
    93   case 0 thus ?case by simp
    94 next
    95   case (Suc n)
    96   let ?B = "f ` {i. i < n}"
    97   have finB: "finite ?B" by(rule Suc.hyps[OF refl])
    98   show ?case
    99   proof cases
   100     assume "\<exists>k<n. f n = f k"
   101     hence "A = ?B" using Suc.prems by(auto simp:less_Suc_eq)
   102     thus ?thesis using finB by simp
   103   next
   104     assume "\<not>(\<exists> k<n. f n = f k)"
   105     hence "A = insert (f n) ?B" using Suc.prems by(auto simp:less_Suc_eq)
   106     thus ?thesis using finB by simp
   107   qed
   108 qed
   109 
   110 lemma finite_conv_nat_seg_image:
   111   "finite A \<longleftrightarrow> (\<exists>(n::nat) f. A = f ` {i::nat. i < n})"
   112   by (blast intro: nat_seg_image_imp_finite dest: finite_imp_nat_seg_image_inj_on)
   113 
   114 lemma finite_imp_inj_to_nat_seg:
   115   assumes "finite A"
   116   shows "\<exists>f n::nat. f ` A = {i. i < n} \<and> inj_on f A"
   117 proof -
   118   from finite_imp_nat_seg_image_inj_on[OF `finite A`]
   119   obtain f and n::nat where bij: "bij_betw f {i. i<n} A"
   120     by (auto simp:bij_betw_def)
   121   let ?f = "the_inv_into {i. i<n} f"
   122   have "inj_on ?f A & ?f ` A = {i. i<n}"
   123     by (fold bij_betw_def) (rule bij_betw_the_inv_into[OF bij])
   124   thus ?thesis by blast
   125 qed
   126 
   127 lemma finite_Collect_less_nat [iff]:
   128   "finite {n::nat. n < k}"
   129   by (fastforce simp: finite_conv_nat_seg_image)
   130 
   131 lemma finite_Collect_le_nat [iff]:
   132   "finite {n::nat. n \<le> k}"
   133   by (simp add: le_eq_less_or_eq Collect_disj_eq)
   134 
   135 
   136 subsubsection {* Finiteness and common set operations *}
   137 
   138 lemma rev_finite_subset:
   139   "finite B \<Longrightarrow> A \<subseteq> B \<Longrightarrow> finite A"
   140 proof (induct arbitrary: A rule: finite_induct)
   141   case empty
   142   then show ?case by simp
   143 next
   144   case (insert x F A)
   145   have A: "A \<subseteq> insert x F" and r: "A - {x} \<subseteq> F \<Longrightarrow> finite (A - {x})" by fact+
   146   show "finite A"
   147   proof cases
   148     assume x: "x \<in> A"
   149     with A have "A - {x} \<subseteq> F" by (simp add: subset_insert_iff)
   150     with r have "finite (A - {x})" .
   151     hence "finite (insert x (A - {x}))" ..
   152     also have "insert x (A - {x}) = A" using x by (rule insert_Diff)
   153     finally show ?thesis .
   154   next
   155     show "A \<subseteq> F ==> ?thesis" by fact
   156     assume "x \<notin> A"
   157     with A show "A \<subseteq> F" by (simp add: subset_insert_iff)
   158   qed
   159 qed
   160 
   161 lemma finite_subset:
   162   "A \<subseteq> B \<Longrightarrow> finite B \<Longrightarrow> finite A"
   163   by (rule rev_finite_subset)
   164 
   165 lemma finite_UnI:
   166   assumes "finite F" and "finite G"
   167   shows "finite (F \<union> G)"
   168   using assms by induct simp_all
   169 
   170 lemma finite_Un [iff]:
   171   "finite (F \<union> G) \<longleftrightarrow> finite F \<and> finite G"
   172   by (blast intro: finite_UnI finite_subset [of _ "F \<union> G"])
   173 
   174 lemma finite_insert [simp]: "finite (insert a A) \<longleftrightarrow> finite A"
   175 proof -
   176   have "finite {a} \<and> finite A \<longleftrightarrow> finite A" by simp
   177   then have "finite ({a} \<union> A) \<longleftrightarrow> finite A" by (simp only: finite_Un)
   178   then show ?thesis by simp
   179 qed
   180 
   181 lemma finite_Int [simp, intro]:
   182   "finite F \<or> finite G \<Longrightarrow> finite (F \<inter> G)"
   183   by (blast intro: finite_subset)
   184 
   185 lemma finite_Collect_conjI [simp, intro]:
   186   "finite {x. P x} \<or> finite {x. Q x} \<Longrightarrow> finite {x. P x \<and> Q x}"
   187   by (simp add: Collect_conj_eq)
   188 
   189 lemma finite_Collect_disjI [simp]:
   190   "finite {x. P x \<or> Q x} \<longleftrightarrow> finite {x. P x} \<and> finite {x. Q x}"
   191   by (simp add: Collect_disj_eq)
   192 
   193 lemma finite_Diff [simp, intro]:
   194   "finite A \<Longrightarrow> finite (A - B)"
   195   by (rule finite_subset, rule Diff_subset)
   196 
   197 lemma finite_Diff2 [simp]:
   198   assumes "finite B"
   199   shows "finite (A - B) \<longleftrightarrow> finite A"
   200 proof -
   201   have "finite A \<longleftrightarrow> finite((A - B) \<union> (A \<inter> B))" by (simp add: Un_Diff_Int)
   202   also have "\<dots> \<longleftrightarrow> finite (A - B)" using `finite B` by simp
   203   finally show ?thesis ..
   204 qed
   205 
   206 lemma finite_Diff_insert [iff]:
   207   "finite (A - insert a B) \<longleftrightarrow> finite (A - B)"
   208 proof -
   209   have "finite (A - B) \<longleftrightarrow> finite (A - B - {a})" by simp
   210   moreover have "A - insert a B = A - B - {a}" by auto
   211   ultimately show ?thesis by simp
   212 qed
   213 
   214 lemma finite_compl[simp]:
   215   "finite (A :: 'a set) \<Longrightarrow> finite (- A) \<longleftrightarrow> finite (UNIV :: 'a set)"
   216   by (simp add: Compl_eq_Diff_UNIV)
   217 
   218 lemma finite_Collect_not[simp]:
   219   "finite {x :: 'a. P x} \<Longrightarrow> finite {x. \<not> P x} \<longleftrightarrow> finite (UNIV :: 'a set)"
   220   by (simp add: Collect_neg_eq)
   221 
   222 lemma finite_Union [simp, intro]:
   223   "finite A \<Longrightarrow> (\<And>M. M \<in> A \<Longrightarrow> finite M) \<Longrightarrow> finite(\<Union>A)"
   224   by (induct rule: finite_induct) simp_all
   225 
   226 lemma finite_UN_I [intro]:
   227   "finite A \<Longrightarrow> (\<And>a. a \<in> A \<Longrightarrow> finite (B a)) \<Longrightarrow> finite (\<Union>a\<in>A. B a)"
   228   by (induct rule: finite_induct) simp_all
   229 
   230 lemma finite_UN [simp]:
   231   "finite A \<Longrightarrow> finite (UNION A B) \<longleftrightarrow> (\<forall>x\<in>A. finite (B x))"
   232   by (blast intro: finite_subset)
   233 
   234 lemma finite_Inter [intro]:
   235   "\<exists>A\<in>M. finite A \<Longrightarrow> finite (\<Inter>M)"
   236   by (blast intro: Inter_lower finite_subset)
   237 
   238 lemma finite_INT [intro]:
   239   "\<exists>x\<in>I. finite (A x) \<Longrightarrow> finite (\<Inter>x\<in>I. A x)"
   240   by (blast intro: INT_lower finite_subset)
   241 
   242 lemma finite_imageI [simp, intro]:
   243   "finite F \<Longrightarrow> finite (h ` F)"
   244   by (induct rule: finite_induct) simp_all
   245 
   246 lemma finite_image_set [simp]:
   247   "finite {x. P x} \<Longrightarrow> finite { f x | x. P x }"
   248   by (simp add: image_Collect [symmetric])
   249 
   250 lemma finite_imageD:
   251   assumes "finite (f ` A)" and "inj_on f A"
   252   shows "finite A"
   253 using assms
   254 proof (induct "f ` A" arbitrary: A)
   255   case empty then show ?case by simp
   256 next
   257   case (insert x B)
   258   then have B_A: "insert x B = f ` A" by simp
   259   then obtain y where "x = f y" and "y \<in> A" by blast
   260   from B_A `x \<notin> B` have "B = f ` A - {x}" by blast
   261   with B_A `x \<notin> B` `x = f y` `inj_on f A` `y \<in> A` have "B = f ` (A - {y})" by (simp add: inj_on_image_set_diff)
   262   moreover from `inj_on f A` have "inj_on f (A - {y})" by (rule inj_on_diff)
   263   ultimately have "finite (A - {y})" by (rule insert.hyps)
   264   then show "finite A" by simp
   265 qed
   266 
   267 lemma finite_surj:
   268   "finite A \<Longrightarrow> B \<subseteq> f ` A \<Longrightarrow> finite B"
   269   by (erule finite_subset) (rule finite_imageI)
   270 
   271 lemma finite_range_imageI:
   272   "finite (range g) \<Longrightarrow> finite (range (\<lambda>x. f (g x)))"
   273   by (drule finite_imageI) (simp add: range_composition)
   274 
   275 lemma finite_subset_image:
   276   assumes "finite B"
   277   shows "B \<subseteq> f ` A \<Longrightarrow> \<exists>C\<subseteq>A. finite C \<and> B = f ` C"
   278 using assms
   279 proof induct
   280   case empty then show ?case by simp
   281 next
   282   case insert then show ?case
   283     by (clarsimp simp del: image_insert simp add: image_insert [symmetric])
   284        blast
   285 qed
   286 
   287 lemma finite_vimage_IntI:
   288   "finite F \<Longrightarrow> inj_on h A \<Longrightarrow> finite (h -` F \<inter> A)"
   289   apply (induct rule: finite_induct)
   290    apply simp_all
   291   apply (subst vimage_insert)
   292   apply (simp add: finite_subset [OF inj_on_vimage_singleton] Int_Un_distrib2)
   293   done
   294 
   295 lemma finite_vimageI:
   296   "finite F \<Longrightarrow> inj h \<Longrightarrow> finite (h -` F)"
   297   using finite_vimage_IntI[of F h UNIV] by auto
   298 
   299 lemma finite_vimageD:
   300   assumes fin: "finite (h -` F)" and surj: "surj h"
   301   shows "finite F"
   302 proof -
   303   have "finite (h ` (h -` F))" using fin by (rule finite_imageI)
   304   also have "h ` (h -` F) = F" using surj by (rule surj_image_vimage_eq)
   305   finally show "finite F" .
   306 qed
   307 
   308 lemma finite_vimage_iff: "bij h \<Longrightarrow> finite (h -` F) \<longleftrightarrow> finite F"
   309   unfolding bij_def by (auto elim: finite_vimageD finite_vimageI)
   310 
   311 lemma finite_Collect_bex [simp]:
   312   assumes "finite A"
   313   shows "finite {x. \<exists>y\<in>A. Q x y} \<longleftrightarrow> (\<forall>y\<in>A. finite {x. Q x y})"
   314 proof -
   315   have "{x. \<exists>y\<in>A. Q x y} = (\<Union>y\<in>A. {x. Q x y})" by auto
   316   with assms show ?thesis by simp
   317 qed
   318 
   319 lemma finite_Collect_bounded_ex [simp]:
   320   assumes "finite {y. P y}"
   321   shows "finite {x. \<exists>y. P y \<and> Q x y} \<longleftrightarrow> (\<forall>y. P y \<longrightarrow> finite {x. Q x y})"
   322 proof -
   323   have "{x. EX y. P y & Q x y} = (\<Union>y\<in>{y. P y}. {x. Q x y})" by auto
   324   with assms show ?thesis by simp
   325 qed
   326 
   327 lemma finite_Plus:
   328   "finite A \<Longrightarrow> finite B \<Longrightarrow> finite (A <+> B)"
   329   by (simp add: Plus_def)
   330 
   331 lemma finite_PlusD: 
   332   fixes A :: "'a set" and B :: "'b set"
   333   assumes fin: "finite (A <+> B)"
   334   shows "finite A" "finite B"
   335 proof -
   336   have "Inl ` A \<subseteq> A <+> B" by auto
   337   then have "finite (Inl ` A :: ('a + 'b) set)" using fin by (rule finite_subset)
   338   then show "finite A" by (rule finite_imageD) (auto intro: inj_onI)
   339 next
   340   have "Inr ` B \<subseteq> A <+> B" by auto
   341   then have "finite (Inr ` B :: ('a + 'b) set)" using fin by (rule finite_subset)
   342   then show "finite B" by (rule finite_imageD) (auto intro: inj_onI)
   343 qed
   344 
   345 lemma finite_Plus_iff [simp]:
   346   "finite (A <+> B) \<longleftrightarrow> finite A \<and> finite B"
   347   by (auto intro: finite_PlusD finite_Plus)
   348 
   349 lemma finite_Plus_UNIV_iff [simp]:
   350   "finite (UNIV :: ('a + 'b) set) \<longleftrightarrow> finite (UNIV :: 'a set) \<and> finite (UNIV :: 'b set)"
   351   by (subst UNIV_Plus_UNIV [symmetric]) (rule finite_Plus_iff)
   352 
   353 lemma finite_SigmaI [simp, intro]:
   354   "finite A \<Longrightarrow> (\<And>a. a\<in>A \<Longrightarrow> finite (B a)) ==> finite (SIGMA a:A. B a)"
   355   by (unfold Sigma_def) blast
   356 
   357 lemma finite_cartesian_product:
   358   "finite A \<Longrightarrow> finite B \<Longrightarrow> finite (A \<times> B)"
   359   by (rule finite_SigmaI)
   360 
   361 lemma finite_Prod_UNIV:
   362   "finite (UNIV :: 'a set) \<Longrightarrow> finite (UNIV :: 'b set) \<Longrightarrow> finite (UNIV :: ('a \<times> 'b) set)"
   363   by (simp only: UNIV_Times_UNIV [symmetric] finite_cartesian_product)
   364 
   365 lemma finite_cartesian_productD1:
   366   assumes "finite (A \<times> B)" and "B \<noteq> {}"
   367   shows "finite A"
   368 proof -
   369   from assms obtain n f where "A \<times> B = f ` {i::nat. i < n}"
   370     by (auto simp add: finite_conv_nat_seg_image)
   371   then have "fst ` (A \<times> B) = fst ` f ` {i::nat. i < n}" by simp
   372   with `B \<noteq> {}` have "A = (fst \<circ> f) ` {i::nat. i < n}"
   373     by (simp add: image_compose)
   374   then have "\<exists>n f. A = f ` {i::nat. i < n}" by blast
   375   then show ?thesis
   376     by (auto simp add: finite_conv_nat_seg_image)
   377 qed
   378 
   379 lemma finite_cartesian_productD2:
   380   assumes "finite (A \<times> B)" and "A \<noteq> {}"
   381   shows "finite B"
   382 proof -
   383   from assms obtain n f where "A \<times> B = f ` {i::nat. i < n}"
   384     by (auto simp add: finite_conv_nat_seg_image)
   385   then have "snd ` (A \<times> B) = snd ` f ` {i::nat. i < n}" by simp
   386   with `A \<noteq> {}` have "B = (snd \<circ> f) ` {i::nat. i < n}"
   387     by (simp add: image_compose)
   388   then have "\<exists>n f. B = f ` {i::nat. i < n}" by blast
   389   then show ?thesis
   390     by (auto simp add: finite_conv_nat_seg_image)
   391 qed
   392 
   393 lemma finite_Pow_iff [iff]:
   394   "finite (Pow A) \<longleftrightarrow> finite A"
   395 proof
   396   assume "finite (Pow A)"
   397   then have "finite ((%x. {x}) ` A)" by (blast intro: finite_subset)
   398   then show "finite A" by (rule finite_imageD [unfolded inj_on_def]) simp
   399 next
   400   assume "finite A"
   401   then show "finite (Pow A)"
   402     by induct (simp_all add: Pow_insert)
   403 qed
   404 
   405 corollary finite_Collect_subsets [simp, intro]:
   406   "finite A \<Longrightarrow> finite {B. B \<subseteq> A}"
   407   by (simp add: Pow_def [symmetric])
   408 
   409 lemma finite_UnionD: "finite(\<Union>A) \<Longrightarrow> finite A"
   410   by (blast intro: finite_subset [OF subset_Pow_Union])
   411 
   412 
   413 subsubsection {* Further induction rules on finite sets *}
   414 
   415 lemma finite_ne_induct [case_names singleton insert, consumes 2]:
   416   assumes "finite F" and "F \<noteq> {}"
   417   assumes "\<And>x. P {x}"
   418     and "\<And>x F. finite F \<Longrightarrow> F \<noteq> {} \<Longrightarrow> x \<notin> F \<Longrightarrow> P F  \<Longrightarrow> P (insert x F)"
   419   shows "P F"
   420 using assms
   421 proof induct
   422   case empty then show ?case by simp
   423 next
   424   case (insert x F) then show ?case by cases auto
   425 qed
   426 
   427 lemma finite_subset_induct [consumes 2, case_names empty insert]:
   428   assumes "finite F" and "F \<subseteq> A"
   429   assumes empty: "P {}"
   430     and insert: "\<And>a F. finite F \<Longrightarrow> a \<in> A \<Longrightarrow> a \<notin> F \<Longrightarrow> P F \<Longrightarrow> P (insert a F)"
   431   shows "P F"
   432 using `finite F` `F \<subseteq> A`
   433 proof induct
   434   show "P {}" by fact
   435 next
   436   fix x F
   437   assume "finite F" and "x \<notin> F" and
   438     P: "F \<subseteq> A \<Longrightarrow> P F" and i: "insert x F \<subseteq> A"
   439   show "P (insert x F)"
   440   proof (rule insert)
   441     from i show "x \<in> A" by blast
   442     from i have "F \<subseteq> A" by blast
   443     with P show "P F" .
   444     show "finite F" by fact
   445     show "x \<notin> F" by fact
   446   qed
   447 qed
   448 
   449 lemma finite_empty_induct:
   450   assumes "finite A"
   451   assumes "P A"
   452     and remove: "\<And>a A. finite A \<Longrightarrow> a \<in> A \<Longrightarrow> P A \<Longrightarrow> P (A - {a})"
   453   shows "P {}"
   454 proof -
   455   have "\<And>B. B \<subseteq> A \<Longrightarrow> P (A - B)"
   456   proof -
   457     fix B :: "'a set"
   458     assume "B \<subseteq> A"
   459     with `finite A` have "finite B" by (rule rev_finite_subset)
   460     from this `B \<subseteq> A` show "P (A - B)"
   461     proof induct
   462       case empty
   463       from `P A` show ?case by simp
   464     next
   465       case (insert b B)
   466       have "P (A - B - {b})"
   467       proof (rule remove)
   468         from `finite A` show "finite (A - B)" by induct auto
   469         from insert show "b \<in> A - B" by simp
   470         from insert show "P (A - B)" by simp
   471       qed
   472       also have "A - B - {b} = A - insert b B" by (rule Diff_insert [symmetric])
   473       finally show ?case .
   474     qed
   475   qed
   476   then have "P (A - A)" by blast
   477   then show ?thesis by simp
   478 qed
   479 
   480 
   481 subsection {* Class @{text finite}  *}
   482 
   483 class finite =
   484   assumes finite_UNIV: "finite (UNIV \<Colon> 'a set)"
   485 begin
   486 
   487 lemma finite [simp]: "finite (A \<Colon> 'a set)"
   488   by (rule subset_UNIV finite_UNIV finite_subset)+
   489 
   490 lemma finite_code [code]: "finite (A \<Colon> 'a set) \<longleftrightarrow> True"
   491   by simp
   492 
   493 end
   494 
   495 instance prod :: (finite, finite) finite
   496   by default (simp only: UNIV_Times_UNIV [symmetric] finite_cartesian_product finite)
   497 
   498 lemma inj_graph: "inj (%f. {(x, y). y = f x})"
   499   by (rule inj_onI, auto simp add: set_eq_iff fun_eq_iff)
   500 
   501 instance "fun" :: (finite, finite) finite
   502 proof
   503   show "finite (UNIV :: ('a => 'b) set)"
   504   proof (rule finite_imageD)
   505     let ?graph = "%f::'a => 'b. {(x, y). y = f x}"
   506     have "range ?graph \<subseteq> Pow UNIV" by simp
   507     moreover have "finite (Pow (UNIV :: ('a * 'b) set))"
   508       by (simp only: finite_Pow_iff finite)
   509     ultimately show "finite (range ?graph)"
   510       by (rule finite_subset)
   511     show "inj ?graph" by (rule inj_graph)
   512   qed
   513 qed
   514 
   515 instance bool :: finite
   516   by default (simp add: UNIV_bool)
   517 
   518 instance set :: (finite) finite
   519   by default (simp only: Pow_UNIV [symmetric] finite_Pow_iff finite)
   520 
   521 instance unit :: finite
   522   by default (simp add: UNIV_unit)
   523 
   524 instance sum :: (finite, finite) finite
   525   by default (simp only: UNIV_Plus_UNIV [symmetric] finite_Plus finite)
   526 
   527 lemma finite_option_UNIV [simp]:
   528   "finite (UNIV :: 'a option set) = finite (UNIV :: 'a set)"
   529   by (auto simp add: UNIV_option_conv elim: finite_imageD intro: inj_Some)
   530 
   531 instance option :: (finite) finite
   532   by default (simp add: UNIV_option_conv)
   533 
   534 
   535 subsection {* A basic fold functional for finite sets *}
   536 
   537 text {* The intended behaviour is
   538 @{text "fold f z {x\<^isub>1, ..., x\<^isub>n} = f x\<^isub>1 (\<dots> (f x\<^isub>n z)\<dots>)"}
   539 if @{text f} is ``left-commutative'':
   540 *}
   541 
   542 locale comp_fun_commute =
   543   fixes f :: "'a \<Rightarrow> 'b \<Rightarrow> 'b"
   544   assumes comp_fun_commute: "f y \<circ> f x = f x \<circ> f y"
   545 begin
   546 
   547 lemma fun_left_comm: "f x (f y z) = f y (f x z)"
   548   using comp_fun_commute by (simp add: fun_eq_iff)
   549 
   550 end
   551 
   552 inductive fold_graph :: "('a \<Rightarrow> 'b \<Rightarrow> 'b) \<Rightarrow> 'b \<Rightarrow> 'a set \<Rightarrow> 'b \<Rightarrow> bool"
   553 for f :: "'a \<Rightarrow> 'b \<Rightarrow> 'b" and z :: 'b where
   554   emptyI [intro]: "fold_graph f z {} z" |
   555   insertI [intro]: "x \<notin> A \<Longrightarrow> fold_graph f z A y
   556       \<Longrightarrow> fold_graph f z (insert x A) (f x y)"
   557 
   558 inductive_cases empty_fold_graphE [elim!]: "fold_graph f z {} x"
   559 
   560 definition fold :: "('a \<Rightarrow> 'b \<Rightarrow> 'b) \<Rightarrow> 'b \<Rightarrow> 'a set \<Rightarrow> 'b" where
   561   "fold f z A = (THE y. fold_graph f z A y)"
   562 
   563 text{*A tempting alternative for the definiens is
   564 @{term "if finite A then THE y. fold_graph f z A y else e"}.
   565 It allows the removal of finiteness assumptions from the theorems
   566 @{text fold_comm}, @{text fold_reindex} and @{text fold_distrib}.
   567 The proofs become ugly. It is not worth the effort. (???) *}
   568 
   569 lemma finite_imp_fold_graph: "finite A \<Longrightarrow> \<exists>x. fold_graph f z A x"
   570 by (induct rule: finite_induct) auto
   571 
   572 
   573 subsubsection{*From @{const fold_graph} to @{term fold}*}
   574 
   575 context comp_fun_commute
   576 begin
   577 
   578 lemma fold_graph_insertE_aux:
   579   "fold_graph f z A y \<Longrightarrow> a \<in> A \<Longrightarrow> \<exists>y'. y = f a y' \<and> fold_graph f z (A - {a}) y'"
   580 proof (induct set: fold_graph)
   581   case (insertI x A y) show ?case
   582   proof (cases "x = a")
   583     assume "x = a" with insertI show ?case by auto
   584   next
   585     assume "x \<noteq> a"
   586     then obtain y' where y: "y = f a y'" and y': "fold_graph f z (A - {a}) y'"
   587       using insertI by auto
   588     have "f x y = f a (f x y')"
   589       unfolding y by (rule fun_left_comm)
   590     moreover have "fold_graph f z (insert x A - {a}) (f x y')"
   591       using y' and `x \<noteq> a` and `x \<notin> A`
   592       by (simp add: insert_Diff_if fold_graph.insertI)
   593     ultimately show ?case by fast
   594   qed
   595 qed simp
   596 
   597 lemma fold_graph_insertE:
   598   assumes "fold_graph f z (insert x A) v" and "x \<notin> A"
   599   obtains y where "v = f x y" and "fold_graph f z A y"
   600 using assms by (auto dest: fold_graph_insertE_aux [OF _ insertI1])
   601 
   602 lemma fold_graph_determ:
   603   "fold_graph f z A x \<Longrightarrow> fold_graph f z A y \<Longrightarrow> y = x"
   604 proof (induct arbitrary: y set: fold_graph)
   605   case (insertI x A y v)
   606   from `fold_graph f z (insert x A) v` and `x \<notin> A`
   607   obtain y' where "v = f x y'" and "fold_graph f z A y'"
   608     by (rule fold_graph_insertE)
   609   from `fold_graph f z A y'` have "y' = y" by (rule insertI)
   610   with `v = f x y'` show "v = f x y" by simp
   611 qed fast
   612 
   613 lemma fold_equality:
   614   "fold_graph f z A y \<Longrightarrow> fold f z A = y"
   615 by (unfold fold_def) (blast intro: fold_graph_determ)
   616 
   617 lemma fold_graph_fold:
   618   assumes "finite A"
   619   shows "fold_graph f z A (fold f z A)"
   620 proof -
   621   from assms have "\<exists>x. fold_graph f z A x" by (rule finite_imp_fold_graph)
   622   moreover note fold_graph_determ
   623   ultimately have "\<exists>!x. fold_graph f z A x" by (rule ex_ex1I)
   624   then have "fold_graph f z A (The (fold_graph f z A))" by (rule theI')
   625   then show ?thesis by (unfold fold_def)
   626 qed
   627 
   628 text{* The base case for @{text fold}: *}
   629 
   630 lemma (in -) fold_empty [simp]: "fold f z {} = z"
   631 by (unfold fold_def) blast
   632 
   633 text{* The various recursion equations for @{const fold}: *}
   634 
   635 lemma fold_insert [simp]:
   636   assumes "finite A" and "x \<notin> A"
   637   shows "fold f z (insert x A) = f x (fold f z A)"
   638 proof (rule fold_equality)
   639   from `finite A` have "fold_graph f z A (fold f z A)" by (rule fold_graph_fold)
   640   with `x \<notin> A`show "fold_graph f z (insert x A) (f x (fold f z A))" by (rule fold_graph.insertI)
   641 qed
   642 
   643 lemma fold_fun_comm:
   644   "finite A \<Longrightarrow> f x (fold f z A) = fold f (f x z) A"
   645 proof (induct rule: finite_induct)
   646   case empty then show ?case by simp
   647 next
   648   case (insert y A) then show ?case
   649     by (simp add: fun_left_comm[of x])
   650 qed
   651 
   652 lemma fold_insert2:
   653   "finite A \<Longrightarrow> x \<notin> A \<Longrightarrow> fold f z (insert x A) = fold f (f x z) A"
   654 by (simp add: fold_fun_comm)
   655 
   656 lemma fold_rec:
   657   assumes "finite A" and "x \<in> A"
   658   shows "fold f z A = f x (fold f z (A - {x}))"
   659 proof -
   660   have A: "A = insert x (A - {x})" using `x \<in> A` by blast
   661   then have "fold f z A = fold f z (insert x (A - {x}))" by simp
   662   also have "\<dots> = f x (fold f z (A - {x}))"
   663     by (rule fold_insert) (simp add: `finite A`)+
   664   finally show ?thesis .
   665 qed
   666 
   667 lemma fold_insert_remove:
   668   assumes "finite A"
   669   shows "fold f z (insert x A) = f x (fold f z (A - {x}))"
   670 proof -
   671   from `finite A` have "finite (insert x A)" by auto
   672   moreover have "x \<in> insert x A" by auto
   673   ultimately have "fold f z (insert x A) = f x (fold f z (insert x A - {x}))"
   674     by (rule fold_rec)
   675   then show ?thesis by simp
   676 qed
   677 
   678 end
   679 
   680 text{* A simplified version for idempotent functions: *}
   681 
   682 locale comp_fun_idem = comp_fun_commute +
   683   assumes comp_fun_idem: "f x o f x = f x"
   684 begin
   685 
   686 lemma fun_left_idem: "f x (f x z) = f x z"
   687   using comp_fun_idem by (simp add: fun_eq_iff)
   688 
   689 lemma fold_insert_idem:
   690   assumes fin: "finite A"
   691   shows "fold f z (insert x A) = f x (fold f z A)"
   692 proof cases
   693   assume "x \<in> A"
   694   then obtain B where "A = insert x B" and "x \<notin> B" by (rule set_insert)
   695   then show ?thesis using assms by (simp add:fun_left_idem)
   696 next
   697   assume "x \<notin> A" then show ?thesis using assms by simp
   698 qed
   699 
   700 declare fold_insert[simp del] fold_insert_idem[simp]
   701 
   702 lemma fold_insert_idem2:
   703   "finite A \<Longrightarrow> fold f z (insert x A) = fold f (f x z) A"
   704 by(simp add:fold_fun_comm)
   705 
   706 end
   707 
   708 
   709 subsubsection {* Expressing set operations via @{const fold} *}
   710 
   711 lemma (in comp_fun_commute) comp_comp_fun_commute:
   712   "comp_fun_commute (f \<circ> g)"
   713 proof
   714 qed (simp_all add: comp_fun_commute)
   715 
   716 lemma (in comp_fun_idem) comp_comp_fun_idem:
   717   "comp_fun_idem (f \<circ> g)"
   718   by (rule comp_fun_idem.intro, rule comp_comp_fun_commute, unfold_locales)
   719     (simp_all add: comp_fun_idem)
   720 
   721 lemma comp_fun_idem_insert:
   722   "comp_fun_idem insert"
   723 proof
   724 qed auto
   725 
   726 lemma comp_fun_idem_remove:
   727   "comp_fun_idem Set.remove"
   728 proof
   729 qed auto
   730 
   731 lemma (in semilattice_inf) comp_fun_idem_inf:
   732   "comp_fun_idem inf"
   733 proof
   734 qed (auto simp add: inf_left_commute)
   735 
   736 lemma (in semilattice_sup) comp_fun_idem_sup:
   737   "comp_fun_idem sup"
   738 proof
   739 qed (auto simp add: sup_left_commute)
   740 
   741 lemma union_fold_insert:
   742   assumes "finite A"
   743   shows "A \<union> B = fold insert B A"
   744 proof -
   745   interpret comp_fun_idem insert by (fact comp_fun_idem_insert)
   746   from `finite A` show ?thesis by (induct A arbitrary: B) simp_all
   747 qed
   748 
   749 lemma minus_fold_remove:
   750   assumes "finite A"
   751   shows "B - A = fold Set.remove B A"
   752 proof -
   753   interpret comp_fun_idem Set.remove by (fact comp_fun_idem_remove)
   754   from `finite A` have "fold Set.remove B A = B - A" by (induct A arbitrary: B) auto
   755   then show ?thesis ..
   756 qed
   757 
   758 context complete_lattice
   759 begin
   760 
   761 lemma inf_Inf_fold_inf:
   762   assumes "finite A"
   763   shows "inf B (Inf A) = fold inf B A"
   764 proof -
   765   interpret comp_fun_idem inf by (fact comp_fun_idem_inf)
   766   from `finite A` show ?thesis by (induct A arbitrary: B)
   767     (simp_all add: inf_commute fold_fun_comm)
   768 qed
   769 
   770 lemma sup_Sup_fold_sup:
   771   assumes "finite A"
   772   shows "sup B (Sup A) = fold sup B A"
   773 proof -
   774   interpret comp_fun_idem sup by (fact comp_fun_idem_sup)
   775   from `finite A` show ?thesis by (induct A arbitrary: B)
   776     (simp_all add: sup_commute fold_fun_comm)
   777 qed
   778 
   779 lemma Inf_fold_inf:
   780   assumes "finite A"
   781   shows "Inf A = fold inf top A"
   782   using assms inf_Inf_fold_inf [of A top] by (simp add: inf_absorb2)
   783 
   784 lemma Sup_fold_sup:
   785   assumes "finite A"
   786   shows "Sup A = fold sup bot A"
   787   using assms sup_Sup_fold_sup [of A bot] by (simp add: sup_absorb2)
   788 
   789 lemma inf_INF_fold_inf:
   790   assumes "finite A"
   791   shows "inf B (INFI A f) = fold (inf \<circ> f) B A" (is "?inf = ?fold") 
   792 proof (rule sym)
   793   interpret comp_fun_idem inf by (fact comp_fun_idem_inf)
   794   interpret comp_fun_idem "inf \<circ> f" by (fact comp_comp_fun_idem)
   795   from `finite A` show "?fold = ?inf"
   796     by (induct A arbitrary: B)
   797       (simp_all add: INF_def inf_left_commute)
   798 qed
   799 
   800 lemma sup_SUP_fold_sup:
   801   assumes "finite A"
   802   shows "sup B (SUPR A f) = fold (sup \<circ> f) B A" (is "?sup = ?fold") 
   803 proof (rule sym)
   804   interpret comp_fun_idem sup by (fact comp_fun_idem_sup)
   805   interpret comp_fun_idem "sup \<circ> f" by (fact comp_comp_fun_idem)
   806   from `finite A` show "?fold = ?sup"
   807     by (induct A arbitrary: B)
   808       (simp_all add: SUP_def sup_left_commute)
   809 qed
   810 
   811 lemma INF_fold_inf:
   812   assumes "finite A"
   813   shows "INFI A f = fold (inf \<circ> f) top A"
   814   using assms inf_INF_fold_inf [of A top] by simp
   815 
   816 lemma SUP_fold_sup:
   817   assumes "finite A"
   818   shows "SUPR A f = fold (sup \<circ> f) bot A"
   819   using assms sup_SUP_fold_sup [of A bot] by simp
   820 
   821 end
   822 
   823 
   824 subsection {* The derived combinator @{text fold_image} *}
   825 
   826 definition fold_image :: "('b \<Rightarrow> 'b \<Rightarrow> 'b) \<Rightarrow> ('a \<Rightarrow> 'b) \<Rightarrow> 'b \<Rightarrow> 'a set \<Rightarrow> 'b"
   827   where "fold_image f g = fold (\<lambda>x y. f (g x) y)"
   828 
   829 lemma fold_image_empty[simp]: "fold_image f g z {} = z"
   830   by (simp add:fold_image_def)
   831 
   832 context ab_semigroup_mult
   833 begin
   834 
   835 lemma fold_image_insert[simp]:
   836   assumes "finite A" and "a \<notin> A"
   837   shows "fold_image times g z (insert a A) = g a * (fold_image times g z A)"
   838 proof -
   839   interpret comp_fun_commute "%x y. (g x) * y"
   840     by default (simp add: fun_eq_iff mult_ac)
   841   from assms show ?thesis by (simp add: fold_image_def)
   842 qed
   843 
   844 lemma fold_image_reindex:
   845   assumes "finite A"
   846   shows "inj_on h A \<Longrightarrow> fold_image times g z (h ` A) = fold_image times (g \<circ> h) z A"
   847   using assms by induct auto
   848 
   849 lemma fold_image_cong:
   850   assumes "finite A" and g_h: "\<And>x. x\<in>A \<Longrightarrow> g x = h x"
   851   shows "fold_image times g z A = fold_image times h z A"
   852 proof -
   853   from `finite A`
   854   have "\<And>C. C <= A --> (ALL x:C. g x = h x) --> fold_image times g z C = fold_image times h z C"
   855   proof (induct arbitrary: C)
   856     case empty then show ?case by simp
   857   next
   858     case (insert x F) then show ?case apply -
   859     apply (simp add: subset_insert_iff, clarify)
   860     apply (subgoal_tac "finite C")
   861       prefer 2 apply (blast dest: finite_subset [COMP swap_prems_rl])
   862     apply (subgoal_tac "C = insert x (C - {x})")
   863       prefer 2 apply blast
   864     apply (erule ssubst)
   865     apply (simp add: Ball_def del: insert_Diff_single)
   866     done
   867   qed
   868   with g_h show ?thesis by simp
   869 qed
   870 
   871 end
   872 
   873 context comm_monoid_mult
   874 begin
   875 
   876 lemma fold_image_1:
   877   "finite S \<Longrightarrow> (\<forall>x\<in>S. f x = 1) \<Longrightarrow> fold_image op * f 1 S = 1"
   878   apply (induct rule: finite_induct)
   879   apply simp by auto
   880 
   881 lemma fold_image_Un_Int:
   882   "finite A ==> finite B ==>
   883     fold_image times g 1 A * fold_image times g 1 B =
   884     fold_image times g 1 (A Un B) * fold_image times g 1 (A Int B)"
   885   apply (induct rule: finite_induct)
   886 by (induct set: finite) 
   887    (auto simp add: mult_ac insert_absorb Int_insert_left)
   888 
   889 lemma fold_image_Un_one:
   890   assumes fS: "finite S" and fT: "finite T"
   891   and I0: "\<forall>x \<in> S\<inter>T. f x = 1"
   892   shows "fold_image (op *) f 1 (S \<union> T) = fold_image (op *) f 1 S * fold_image (op *) f 1 T"
   893 proof-
   894   have "fold_image op * f 1 (S \<inter> T) = 1" 
   895     apply (rule fold_image_1)
   896     using fS fT I0 by auto 
   897   with fold_image_Un_Int[OF fS fT] show ?thesis by simp
   898 qed
   899 
   900 corollary fold_Un_disjoint:
   901   "finite A ==> finite B ==> A Int B = {} ==>
   902    fold_image times g 1 (A Un B) =
   903    fold_image times g 1 A * fold_image times g 1 B"
   904 by (simp add: fold_image_Un_Int)
   905 
   906 lemma fold_image_UN_disjoint:
   907   "\<lbrakk> finite I; ALL i:I. finite (A i);
   908      ALL i:I. ALL j:I. i \<noteq> j --> A i Int A j = {} \<rbrakk>
   909    \<Longrightarrow> fold_image times g 1 (UNION I A) =
   910        fold_image times (%i. fold_image times g 1 (A i)) 1 I"
   911 apply (induct rule: finite_induct)
   912 apply simp
   913 apply atomize
   914 apply (subgoal_tac "ALL i:F. x \<noteq> i")
   915  prefer 2 apply blast
   916 apply (subgoal_tac "A x Int UNION F A = {}")
   917  prefer 2 apply blast
   918 apply (simp add: fold_Un_disjoint)
   919 done
   920 
   921 lemma fold_image_Sigma: "finite A ==> ALL x:A. finite (B x) ==>
   922   fold_image times (%x. fold_image times (g x) 1 (B x)) 1 A =
   923   fold_image times (split g) 1 (SIGMA x:A. B x)"
   924 apply (subst Sigma_def)
   925 apply (subst fold_image_UN_disjoint, assumption, simp)
   926  apply blast
   927 apply (erule fold_image_cong)
   928 apply (subst fold_image_UN_disjoint, simp, simp)
   929  apply blast
   930 apply simp
   931 done
   932 
   933 lemma fold_image_distrib: "finite A \<Longrightarrow>
   934    fold_image times (%x. g x * h x) 1 A =
   935    fold_image times g 1 A *  fold_image times h 1 A"
   936 by (erule finite_induct) (simp_all add: mult_ac)
   937 
   938 lemma fold_image_related: 
   939   assumes Re: "R e e" 
   940   and Rop: "\<forall>x1 y1 x2 y2. R x1 x2 \<and> R y1 y2 \<longrightarrow> R (x1 * y1) (x2 * y2)" 
   941   and fS: "finite S" and Rfg: "\<forall>x\<in>S. R (h x) (g x)"
   942   shows "R (fold_image (op *) h e S) (fold_image (op *) g e S)"
   943   using fS by (rule finite_subset_induct) (insert assms, auto)
   944 
   945 lemma  fold_image_eq_general:
   946   assumes fS: "finite S"
   947   and h: "\<forall>y\<in>S'. \<exists>!x. x\<in> S \<and> h(x) = y" 
   948   and f12:  "\<forall>x\<in>S. h x \<in> S' \<and> f2(h x) = f1 x"
   949   shows "fold_image (op *) f1 e S = fold_image (op *) f2 e S'"
   950 proof-
   951   from h f12 have hS: "h ` S = S'" by auto
   952   {fix x y assume H: "x \<in> S" "y \<in> S" "h x = h y"
   953     from f12 h H  have "x = y" by auto }
   954   hence hinj: "inj_on h S" unfolding inj_on_def Ex1_def by blast
   955   from f12 have th: "\<And>x. x \<in> S \<Longrightarrow> (f2 \<circ> h) x = f1 x" by auto 
   956   from hS have "fold_image (op *) f2 e S' = fold_image (op *) f2 e (h ` S)" by simp
   957   also have "\<dots> = fold_image (op *) (f2 o h) e S" 
   958     using fold_image_reindex[OF fS hinj, of f2 e] .
   959   also have "\<dots> = fold_image (op *) f1 e S " using th fold_image_cong[OF fS, of "f2 o h" f1 e]
   960     by blast
   961   finally show ?thesis ..
   962 qed
   963 
   964 lemma fold_image_eq_general_inverses:
   965   assumes fS: "finite S" 
   966   and kh: "\<And>y. y \<in> T \<Longrightarrow> k y \<in> S \<and> h (k y) = y"
   967   and hk: "\<And>x. x \<in> S \<Longrightarrow> h x \<in> T \<and> k (h x) = x  \<and> g (h x) = f x"
   968   shows "fold_image (op *) f e S = fold_image (op *) g e T"
   969   (* metis solves it, but not yet available here *)
   970   apply (rule fold_image_eq_general[OF fS, of T h g f e])
   971   apply (rule ballI)
   972   apply (frule kh)
   973   apply (rule ex1I[])
   974   apply blast
   975   apply clarsimp
   976   apply (drule hk) apply simp
   977   apply (rule sym)
   978   apply (erule conjunct1[OF conjunct2[OF hk]])
   979   apply (rule ballI)
   980   apply (drule  hk)
   981   apply blast
   982   done
   983 
   984 end
   985 
   986 
   987 subsection {* A fold functional for non-empty sets *}
   988 
   989 text{* Does not require start value. *}
   990 
   991 inductive
   992   fold1Set :: "('a => 'a => 'a) => 'a set => 'a => bool"
   993   for f :: "'a => 'a => 'a"
   994 where
   995   fold1Set_insertI [intro]:
   996    "\<lbrakk> fold_graph f a A x; a \<notin> A \<rbrakk> \<Longrightarrow> fold1Set f (insert a A) x"
   997 
   998 definition fold1 :: "('a => 'a => 'a) => 'a set => 'a" where
   999   "fold1 f A == THE x. fold1Set f A x"
  1000 
  1001 lemma fold1Set_nonempty:
  1002   "fold1Set f A x \<Longrightarrow> A \<noteq> {}"
  1003 by(erule fold1Set.cases, simp_all)
  1004 
  1005 inductive_cases empty_fold1SetE [elim!]: "fold1Set f {} x"
  1006 
  1007 inductive_cases insert_fold1SetE [elim!]: "fold1Set f (insert a X) x"
  1008 
  1009 
  1010 lemma fold1Set_sing [iff]: "(fold1Set f {a} b) = (a = b)"
  1011 by (blast elim: fold_graph.cases)
  1012 
  1013 lemma fold1_singleton [simp]: "fold1 f {a} = a"
  1014 by (unfold fold1_def) blast
  1015 
  1016 lemma finite_nonempty_imp_fold1Set:
  1017   "\<lbrakk> finite A; A \<noteq> {} \<rbrakk> \<Longrightarrow> EX x. fold1Set f A x"
  1018 apply (induct A rule: finite_induct)
  1019 apply (auto dest: finite_imp_fold_graph [of _ f])
  1020 done
  1021 
  1022 text{*First, some lemmas about @{const fold_graph}.*}
  1023 
  1024 context ab_semigroup_mult
  1025 begin
  1026 
  1027 lemma comp_fun_commute: "comp_fun_commute (op *)"
  1028   by default (simp add: fun_eq_iff mult_ac)
  1029 
  1030 lemma fold_graph_insert_swap:
  1031 assumes fold: "fold_graph times (b::'a) A y" and "b \<notin> A"
  1032 shows "fold_graph times z (insert b A) (z * y)"
  1033 proof -
  1034   interpret comp_fun_commute "op *::'a \<Rightarrow> 'a \<Rightarrow> 'a" by (rule comp_fun_commute)
  1035 from assms show ?thesis
  1036 proof (induct rule: fold_graph.induct)
  1037   case emptyI show ?case by (subst mult_commute [of z b], fast)
  1038 next
  1039   case (insertI x A y)
  1040     have "fold_graph times z (insert x (insert b A)) (x * (z * y))"
  1041       using insertI by force  --{*how does @{term id} get unfolded?*}
  1042     thus ?case by (simp add: insert_commute mult_ac)
  1043 qed
  1044 qed
  1045 
  1046 lemma fold_graph_permute_diff:
  1047 assumes fold: "fold_graph times b A x"
  1048 shows "!!a. \<lbrakk>a \<in> A; b \<notin> A\<rbrakk> \<Longrightarrow> fold_graph times a (insert b (A-{a})) x"
  1049 using fold
  1050 proof (induct rule: fold_graph.induct)
  1051   case emptyI thus ?case by simp
  1052 next
  1053   case (insertI x A y)
  1054   have "a = x \<or> a \<in> A" using insertI by simp
  1055   thus ?case
  1056   proof
  1057     assume "a = x"
  1058     with insertI show ?thesis
  1059       by (simp add: id_def [symmetric], blast intro: fold_graph_insert_swap)
  1060   next
  1061     assume ainA: "a \<in> A"
  1062     hence "fold_graph times a (insert x (insert b (A - {a}))) (x * y)"
  1063       using insertI by force
  1064     moreover
  1065     have "insert x (insert b (A - {a})) = insert b (insert x A - {a})"
  1066       using ainA insertI by blast
  1067     ultimately show ?thesis by simp
  1068   qed
  1069 qed
  1070 
  1071 lemma fold1_eq_fold:
  1072 assumes "finite A" "a \<notin> A" shows "fold1 times (insert a A) = fold times a A"
  1073 proof -
  1074   interpret comp_fun_commute "op *::'a \<Rightarrow> 'a \<Rightarrow> 'a" by (rule comp_fun_commute)
  1075   from assms show ?thesis
  1076 apply (simp add: fold1_def fold_def)
  1077 apply (rule the_equality)
  1078 apply (best intro: fold_graph_determ theI dest: finite_imp_fold_graph [of _ times])
  1079 apply (rule sym, clarify)
  1080 apply (case_tac "Aa=A")
  1081  apply (best intro: fold_graph_determ)
  1082 apply (subgoal_tac "fold_graph times a A x")
  1083  apply (best intro: fold_graph_determ)
  1084 apply (subgoal_tac "insert aa (Aa - {a}) = A")
  1085  prefer 2 apply (blast elim: equalityE)
  1086 apply (auto dest: fold_graph_permute_diff [where a=a])
  1087 done
  1088 qed
  1089 
  1090 lemma nonempty_iff: "(A \<noteq> {}) = (\<exists>x B. A = insert x B & x \<notin> B)"
  1091 apply safe
  1092  apply simp
  1093  apply (drule_tac x=x in spec)
  1094  apply (drule_tac x="A-{x}" in spec, auto)
  1095 done
  1096 
  1097 lemma fold1_insert:
  1098   assumes nonempty: "A \<noteq> {}" and A: "finite A" "x \<notin> A"
  1099   shows "fold1 times (insert x A) = x * fold1 times A"
  1100 proof -
  1101   interpret comp_fun_commute "op *::'a \<Rightarrow> 'a \<Rightarrow> 'a" by (rule comp_fun_commute)
  1102   from nonempty obtain a A' where "A = insert a A' & a ~: A'"
  1103     by (auto simp add: nonempty_iff)
  1104   with A show ?thesis
  1105     by (simp add: insert_commute [of x] fold1_eq_fold eq_commute)
  1106 qed
  1107 
  1108 end
  1109 
  1110 context ab_semigroup_idem_mult
  1111 begin
  1112 
  1113 lemma comp_fun_idem: "comp_fun_idem (op *)"
  1114   by default (simp_all add: fun_eq_iff mult_left_commute)
  1115 
  1116 lemma fold1_insert_idem [simp]:
  1117   assumes nonempty: "A \<noteq> {}" and A: "finite A" 
  1118   shows "fold1 times (insert x A) = x * fold1 times A"
  1119 proof -
  1120   interpret comp_fun_idem "op *::'a \<Rightarrow> 'a \<Rightarrow> 'a"
  1121     by (rule comp_fun_idem)
  1122   from nonempty obtain a A' where A': "A = insert a A' & a ~: A'"
  1123     by (auto simp add: nonempty_iff)
  1124   show ?thesis
  1125   proof cases
  1126     assume a: "a = x"
  1127     show ?thesis
  1128     proof cases
  1129       assume "A' = {}"
  1130       with A' a show ?thesis by simp
  1131     next
  1132       assume "A' \<noteq> {}"
  1133       with A A' a show ?thesis
  1134         by (simp add: fold1_insert mult_assoc [symmetric])
  1135     qed
  1136   next
  1137     assume "a \<noteq> x"
  1138     with A A' show ?thesis
  1139       by (simp add: insert_commute fold1_eq_fold)
  1140   qed
  1141 qed
  1142 
  1143 lemma hom_fold1_commute:
  1144 assumes hom: "!!x y. h (x * y) = h x * h y"
  1145 and N: "finite N" "N \<noteq> {}" shows "h (fold1 times N) = fold1 times (h ` N)"
  1146 using N
  1147 proof (induct rule: finite_ne_induct)
  1148   case singleton thus ?case by simp
  1149 next
  1150   case (insert n N)
  1151   then have "h (fold1 times (insert n N)) = h (n * fold1 times N)" by simp
  1152   also have "\<dots> = h n * h (fold1 times N)" by(rule hom)
  1153   also have "h (fold1 times N) = fold1 times (h ` N)" by(rule insert)
  1154   also have "times (h n) \<dots> = fold1 times (insert (h n) (h ` N))"
  1155     using insert by(simp)
  1156   also have "insert (h n) (h ` N) = h ` insert n N" by simp
  1157   finally show ?case .
  1158 qed
  1159 
  1160 lemma fold1_eq_fold_idem:
  1161   assumes "finite A"
  1162   shows "fold1 times (insert a A) = fold times a A"
  1163 proof (cases "a \<in> A")
  1164   case False
  1165   with assms show ?thesis by (simp add: fold1_eq_fold)
  1166 next
  1167   interpret comp_fun_idem times by (fact comp_fun_idem)
  1168   case True then obtain b B
  1169     where A: "A = insert a B" and "a \<notin> B" by (rule set_insert)
  1170   with assms have "finite B" by auto
  1171   then have "fold times a (insert a B) = fold times (a * a) B"
  1172     using `a \<notin> B` by (rule fold_insert2)
  1173   then show ?thesis
  1174     using `a \<notin> B` `finite B` by (simp add: fold1_eq_fold A)
  1175 qed
  1176 
  1177 end
  1178 
  1179 
  1180 text{* Now the recursion rules for definitions: *}
  1181 
  1182 lemma fold1_singleton_def: "g = fold1 f \<Longrightarrow> g {a} = a"
  1183 by simp
  1184 
  1185 lemma (in ab_semigroup_mult) fold1_insert_def:
  1186   "\<lbrakk> g = fold1 times; finite A; x \<notin> A; A \<noteq> {} \<rbrakk> \<Longrightarrow> g (insert x A) = x * g A"
  1187 by (simp add:fold1_insert)
  1188 
  1189 lemma (in ab_semigroup_idem_mult) fold1_insert_idem_def:
  1190   "\<lbrakk> g = fold1 times; finite A; A \<noteq> {} \<rbrakk> \<Longrightarrow> g (insert x A) = x * g A"
  1191 by simp
  1192 
  1193 subsubsection{* Determinacy for @{term fold1Set} *}
  1194 
  1195 (*Not actually used!!*)
  1196 (*
  1197 context ab_semigroup_mult
  1198 begin
  1199 
  1200 lemma fold_graph_permute:
  1201   "[|fold_graph times id b (insert a A) x; a \<notin> A; b \<notin> A|]
  1202    ==> fold_graph times id a (insert b A) x"
  1203 apply (cases "a=b") 
  1204 apply (auto dest: fold_graph_permute_diff) 
  1205 done
  1206 
  1207 lemma fold1Set_determ:
  1208   "fold1Set times A x ==> fold1Set times A y ==> y = x"
  1209 proof (clarify elim!: fold1Set.cases)
  1210   fix A x B y a b
  1211   assume Ax: "fold_graph times id a A x"
  1212   assume By: "fold_graph times id b B y"
  1213   assume anotA:  "a \<notin> A"
  1214   assume bnotB:  "b \<notin> B"
  1215   assume eq: "insert a A = insert b B"
  1216   show "y=x"
  1217   proof cases
  1218     assume same: "a=b"
  1219     hence "A=B" using anotA bnotB eq by (blast elim!: equalityE)
  1220     thus ?thesis using Ax By same by (blast intro: fold_graph_determ)
  1221   next
  1222     assume diff: "a\<noteq>b"
  1223     let ?D = "B - {a}"
  1224     have B: "B = insert a ?D" and A: "A = insert b ?D"
  1225      and aB: "a \<in> B" and bA: "b \<in> A"
  1226       using eq anotA bnotB diff by (blast elim!:equalityE)+
  1227     with aB bnotB By
  1228     have "fold_graph times id a (insert b ?D) y" 
  1229       by (auto intro: fold_graph_permute simp add: insert_absorb)
  1230     moreover
  1231     have "fold_graph times id a (insert b ?D) x"
  1232       by (simp add: A [symmetric] Ax) 
  1233     ultimately show ?thesis by (blast intro: fold_graph_determ) 
  1234   qed
  1235 qed
  1236 
  1237 lemma fold1Set_equality: "fold1Set times A y ==> fold1 times A = y"
  1238   by (unfold fold1_def) (blast intro: fold1Set_determ)
  1239 
  1240 end
  1241 *)
  1242 
  1243 declare
  1244   empty_fold_graphE [rule del]  fold_graph.intros [rule del]
  1245   empty_fold1SetE [rule del]  insert_fold1SetE [rule del]
  1246   -- {* No more proofs involve these relations. *}
  1247 
  1248 subsubsection {* Lemmas about @{text fold1} *}
  1249 
  1250 context ab_semigroup_mult
  1251 begin
  1252 
  1253 lemma fold1_Un:
  1254 assumes A: "finite A" "A \<noteq> {}"
  1255 shows "finite B \<Longrightarrow> B \<noteq> {} \<Longrightarrow> A Int B = {} \<Longrightarrow>
  1256        fold1 times (A Un B) = fold1 times A * fold1 times B"
  1257 using A by (induct rule: finite_ne_induct)
  1258   (simp_all add: fold1_insert mult_assoc)
  1259 
  1260 lemma fold1_in:
  1261   assumes A: "finite (A)" "A \<noteq> {}" and elem: "\<And>x y. x * y \<in> {x,y}"
  1262   shows "fold1 times A \<in> A"
  1263 using A
  1264 proof (induct rule:finite_ne_induct)
  1265   case singleton thus ?case by simp
  1266 next
  1267   case insert thus ?case using elem by (force simp add:fold1_insert)
  1268 qed
  1269 
  1270 end
  1271 
  1272 lemma (in ab_semigroup_idem_mult) fold1_Un2:
  1273 assumes A: "finite A" "A \<noteq> {}"
  1274 shows "finite B \<Longrightarrow> B \<noteq> {} \<Longrightarrow>
  1275        fold1 times (A Un B) = fold1 times A * fold1 times B"
  1276 using A
  1277 proof(induct rule:finite_ne_induct)
  1278   case singleton thus ?case by simp
  1279 next
  1280   case insert thus ?case by (simp add: mult_assoc)
  1281 qed
  1282 
  1283 
  1284 subsection {* Locales as mini-packages for fold operations *}
  1285 
  1286 subsubsection {* The natural case *}
  1287 
  1288 locale folding =
  1289   fixes f :: "'a \<Rightarrow> 'b \<Rightarrow> 'b"
  1290   fixes F :: "'a set \<Rightarrow> 'b \<Rightarrow> 'b"
  1291   assumes comp_fun_commute: "f y \<circ> f x = f x \<circ> f y"
  1292   assumes eq_fold: "finite A \<Longrightarrow> F A s = fold f s A"
  1293 begin
  1294 
  1295 lemma empty [simp]:
  1296   "F {} = id"
  1297   by (simp add: eq_fold fun_eq_iff)
  1298 
  1299 lemma insert [simp]:
  1300   assumes "finite A" and "x \<notin> A"
  1301   shows "F (insert x A) = F A \<circ> f x"
  1302 proof -
  1303   interpret comp_fun_commute f
  1304     by default (insert comp_fun_commute, simp add: fun_eq_iff)
  1305   from fold_insert2 assms
  1306   have "\<And>s. fold f s (insert x A) = fold f (f x s) A" .
  1307   with `finite A` show ?thesis by (simp add: eq_fold fun_eq_iff)
  1308 qed
  1309 
  1310 lemma remove:
  1311   assumes "finite A" and "x \<in> A"
  1312   shows "F A = F (A - {x}) \<circ> f x"
  1313 proof -
  1314   from `x \<in> A` obtain B where A: "A = insert x B" and "x \<notin> B"
  1315     by (auto dest: mk_disjoint_insert)
  1316   moreover from `finite A` this have "finite B" by simp
  1317   ultimately show ?thesis by simp
  1318 qed
  1319 
  1320 lemma insert_remove:
  1321   assumes "finite A"
  1322   shows "F (insert x A) = F (A - {x}) \<circ> f x"
  1323   using assms by (cases "x \<in> A") (simp_all add: remove insert_absorb)
  1324 
  1325 lemma commute_left_comp:
  1326   "f y \<circ> (f x \<circ> g) = f x \<circ> (f y \<circ> g)"
  1327   by (simp add: o_assoc comp_fun_commute)
  1328 
  1329 lemma comp_fun_commute':
  1330   assumes "finite A"
  1331   shows "f x \<circ> F A = F A \<circ> f x"
  1332   using assms by (induct A)
  1333     (simp, simp del: o_apply add: o_assoc, simp del: o_apply add: o_assoc [symmetric] comp_fun_commute)
  1334 
  1335 lemma commute_left_comp':
  1336   assumes "finite A"
  1337   shows "f x \<circ> (F A \<circ> g) = F A \<circ> (f x \<circ> g)"
  1338   using assms by (simp add: o_assoc comp_fun_commute')
  1339 
  1340 lemma comp_fun_commute'':
  1341   assumes "finite A" and "finite B"
  1342   shows "F B \<circ> F A = F A \<circ> F B"
  1343   using assms by (induct A)
  1344     (simp_all add: o_assoc, simp add: o_assoc [symmetric] comp_fun_commute')
  1345 
  1346 lemma commute_left_comp'':
  1347   assumes "finite A" and "finite B"
  1348   shows "F B \<circ> (F A \<circ> g) = F A \<circ> (F B \<circ> g)"
  1349   using assms by (simp add: o_assoc comp_fun_commute'')
  1350 
  1351 lemmas comp_fun_commutes = o_assoc [symmetric] comp_fun_commute commute_left_comp
  1352   comp_fun_commute' commute_left_comp' comp_fun_commute'' commute_left_comp''
  1353 
  1354 lemma union_inter:
  1355   assumes "finite A" and "finite B"
  1356   shows "F (A \<union> B) \<circ> F (A \<inter> B) = F A \<circ> F B"
  1357   using assms by (induct A)
  1358     (simp_all del: o_apply add: insert_absorb Int_insert_left comp_fun_commutes,
  1359       simp add: o_assoc)
  1360 
  1361 lemma union:
  1362   assumes "finite A" and "finite B"
  1363   and "A \<inter> B = {}"
  1364   shows "F (A \<union> B) = F A \<circ> F B"
  1365 proof -
  1366   from union_inter `finite A` `finite B` have "F (A \<union> B) \<circ> F (A \<inter> B) = F A \<circ> F B" .
  1367   with `A \<inter> B = {}` show ?thesis by simp
  1368 qed
  1369 
  1370 end
  1371 
  1372 
  1373 subsubsection {* The natural case with idempotency *}
  1374 
  1375 locale folding_idem = folding +
  1376   assumes idem_comp: "f x \<circ> f x = f x"
  1377 begin
  1378 
  1379 lemma idem_left_comp:
  1380   "f x \<circ> (f x \<circ> g) = f x \<circ> g"
  1381   by (simp add: o_assoc idem_comp)
  1382 
  1383 lemma in_comp_idem:
  1384   assumes "finite A" and "x \<in> A"
  1385   shows "F A \<circ> f x = F A"
  1386 using assms by (induct A)
  1387   (auto simp add: comp_fun_commutes idem_comp, simp add: commute_left_comp' [symmetric] comp_fun_commute')
  1388 
  1389 lemma subset_comp_idem:
  1390   assumes "finite A" and "B \<subseteq> A"
  1391   shows "F A \<circ> F B = F A"
  1392 proof -
  1393   from assms have "finite B" by (blast dest: finite_subset)
  1394   then show ?thesis using `B \<subseteq> A` by (induct B)
  1395     (simp_all add: o_assoc in_comp_idem `finite A`)
  1396 qed
  1397 
  1398 declare insert [simp del]
  1399 
  1400 lemma insert_idem [simp]:
  1401   assumes "finite A"
  1402   shows "F (insert x A) = F A \<circ> f x"
  1403   using assms by (cases "x \<in> A") (simp_all add: insert in_comp_idem insert_absorb)
  1404 
  1405 lemma union_idem:
  1406   assumes "finite A" and "finite B"
  1407   shows "F (A \<union> B) = F A \<circ> F B"
  1408 proof -
  1409   from assms have "finite (A \<union> B)" and "A \<inter> B \<subseteq> A \<union> B" by auto
  1410   then have "F (A \<union> B) \<circ> F (A \<inter> B) = F (A \<union> B)" by (rule subset_comp_idem)
  1411   with assms show ?thesis by (simp add: union_inter)
  1412 qed
  1413 
  1414 end
  1415 
  1416 
  1417 subsubsection {* The image case with fixed function *}
  1418 
  1419 no_notation times (infixl "*" 70)
  1420 no_notation Groups.one ("1")
  1421 
  1422 locale folding_image_simple = comm_monoid +
  1423   fixes g :: "('b \<Rightarrow> 'a)"
  1424   fixes F :: "'b set \<Rightarrow> 'a"
  1425   assumes eq_fold_g: "finite A \<Longrightarrow> F A = fold_image f g 1 A"
  1426 begin
  1427 
  1428 lemma empty [simp]:
  1429   "F {} = 1"
  1430   by (simp add: eq_fold_g)
  1431 
  1432 lemma insert [simp]:
  1433   assumes "finite A" and "x \<notin> A"
  1434   shows "F (insert x A) = g x * F A"
  1435 proof -
  1436   interpret comp_fun_commute "%x y. (g x) * y"
  1437     by default (simp add: ac_simps fun_eq_iff)
  1438   from assms have "fold_image (op *) g 1 (insert x A) = g x * fold_image (op *) g 1 A"
  1439     by (simp add: fold_image_def)
  1440   with `finite A` show ?thesis by (simp add: eq_fold_g)
  1441 qed
  1442 
  1443 lemma remove:
  1444   assumes "finite A" and "x \<in> A"
  1445   shows "F A = g x * F (A - {x})"
  1446 proof -
  1447   from `x \<in> A` obtain B where A: "A = insert x B" and "x \<notin> B"
  1448     by (auto dest: mk_disjoint_insert)
  1449   moreover from `finite A` this have "finite B" by simp
  1450   ultimately show ?thesis by simp
  1451 qed
  1452 
  1453 lemma insert_remove:
  1454   assumes "finite A"
  1455   shows "F (insert x A) = g x * F (A - {x})"
  1456   using assms by (cases "x \<in> A") (simp_all add: remove insert_absorb)
  1457 
  1458 lemma neutral:
  1459   assumes "finite A" and "\<forall>x\<in>A. g x = 1"
  1460   shows "F A = 1"
  1461   using assms by (induct A) simp_all
  1462 
  1463 lemma union_inter:
  1464   assumes "finite A" and "finite B"
  1465   shows "F (A \<union> B) * F (A \<inter> B) = F A * F B"
  1466 using assms proof (induct A)
  1467   case empty then show ?case by simp
  1468 next
  1469   case (insert x A) then show ?case
  1470     by (auto simp add: insert_absorb Int_insert_left commute [of _ "g x"] assoc left_commute)
  1471 qed
  1472 
  1473 corollary union_inter_neutral:
  1474   assumes "finite A" and "finite B"
  1475   and I0: "\<forall>x \<in> A\<inter>B. g x = 1"
  1476   shows "F (A \<union> B) = F A * F B"
  1477   using assms by (simp add: union_inter [symmetric] neutral)
  1478 
  1479 corollary union_disjoint:
  1480   assumes "finite A" and "finite B"
  1481   assumes "A \<inter> B = {}"
  1482   shows "F (A \<union> B) = F A * F B"
  1483   using assms by (simp add: union_inter_neutral)
  1484 
  1485 end
  1486 
  1487 
  1488 subsubsection {* The image case with flexible function *}
  1489 
  1490 locale folding_image = comm_monoid +
  1491   fixes F :: "('b \<Rightarrow> 'a) \<Rightarrow> 'b set \<Rightarrow> 'a"
  1492   assumes eq_fold: "\<And>g. finite A \<Longrightarrow> F g A = fold_image f g 1 A"
  1493 
  1494 sublocale folding_image < folding_image_simple "op *" 1 g "F g" proof
  1495 qed (fact eq_fold)
  1496 
  1497 context folding_image
  1498 begin
  1499 
  1500 lemma reindex: (* FIXME polymorhism *)
  1501   assumes "finite A" and "inj_on h A"
  1502   shows "F g (h ` A) = F (g \<circ> h) A"
  1503   using assms by (induct A) auto
  1504 
  1505 lemma cong:
  1506   assumes "finite A" and "\<And>x. x \<in> A \<Longrightarrow> g x = h x"
  1507   shows "F g A = F h A"
  1508 proof -
  1509   from assms have "ALL C. C <= A --> (ALL x:C. g x = h x) --> F g C = F h C"
  1510   apply - apply (erule finite_induct) apply simp
  1511   apply (simp add: subset_insert_iff, clarify)
  1512   apply (subgoal_tac "finite C")
  1513   prefer 2 apply (blast dest: finite_subset [COMP swap_prems_rl])
  1514   apply (subgoal_tac "C = insert x (C - {x})")
  1515   prefer 2 apply blast
  1516   apply (erule ssubst)
  1517   apply (drule spec)
  1518   apply (erule (1) notE impE)
  1519   apply (simp add: Ball_def del: insert_Diff_single)
  1520   done
  1521   with assms show ?thesis by simp
  1522 qed
  1523 
  1524 lemma UNION_disjoint:
  1525   assumes "finite I" and "\<forall>i\<in>I. finite (A i)"
  1526   and "\<forall>i\<in>I. \<forall>j\<in>I. i \<noteq> j \<longrightarrow> A i \<inter> A j = {}"
  1527   shows "F g (UNION I A) = F (F g \<circ> A) I"
  1528 apply (insert assms)
  1529 apply (induct rule: finite_induct)
  1530 apply simp
  1531 apply atomize
  1532 apply (subgoal_tac "\<forall>i\<in>Fa. x \<noteq> i")
  1533  prefer 2 apply blast
  1534 apply (subgoal_tac "A x Int UNION Fa A = {}")
  1535  prefer 2 apply blast
  1536 apply (simp add: union_disjoint)
  1537 done
  1538 
  1539 lemma distrib:
  1540   assumes "finite A"
  1541   shows "F (\<lambda>x. g x * h x) A = F g A * F h A"
  1542   using assms by (rule finite_induct) (simp_all add: assoc commute left_commute)
  1543 
  1544 lemma related: 
  1545   assumes Re: "R 1 1" 
  1546   and Rop: "\<forall>x1 y1 x2 y2. R x1 x2 \<and> R y1 y2 \<longrightarrow> R (x1 * y1) (x2 * y2)" 
  1547   and fS: "finite S" and Rfg: "\<forall>x\<in>S. R (h x) (g x)"
  1548   shows "R (F h S) (F g S)"
  1549   using fS by (rule finite_subset_induct) (insert assms, auto)
  1550 
  1551 lemma eq_general:
  1552   assumes fS: "finite S"
  1553   and h: "\<forall>y\<in>S'. \<exists>!x. x \<in> S \<and> h x = y" 
  1554   and f12:  "\<forall>x\<in>S. h x \<in> S' \<and> f2 (h x) = f1 x"
  1555   shows "F f1 S = F f2 S'"
  1556 proof-
  1557   from h f12 have hS: "h ` S = S'" by blast
  1558   {fix x y assume H: "x \<in> S" "y \<in> S" "h x = h y"
  1559     from f12 h H  have "x = y" by auto }
  1560   hence hinj: "inj_on h S" unfolding inj_on_def Ex1_def by blast
  1561   from f12 have th: "\<And>x. x \<in> S \<Longrightarrow> (f2 \<circ> h) x = f1 x" by auto 
  1562   from hS have "F f2 S' = F f2 (h ` S)" by simp
  1563   also have "\<dots> = F (f2 o h) S" using reindex [OF fS hinj, of f2] .
  1564   also have "\<dots> = F f1 S " using th cong [OF fS, of "f2 o h" f1]
  1565     by blast
  1566   finally show ?thesis ..
  1567 qed
  1568 
  1569 lemma eq_general_inverses:
  1570   assumes fS: "finite S" 
  1571   and kh: "\<And>y. y \<in> T \<Longrightarrow> k y \<in> S \<and> h (k y) = y"
  1572   and hk: "\<And>x. x \<in> S \<Longrightarrow> h x \<in> T \<and> k (h x) = x \<and> g (h x) = j x"
  1573   shows "F j S = F g T"
  1574   (* metis solves it, but not yet available here *)
  1575   apply (rule eq_general [OF fS, of T h g j])
  1576   apply (rule ballI)
  1577   apply (frule kh)
  1578   apply (rule ex1I[])
  1579   apply blast
  1580   apply clarsimp
  1581   apply (drule hk) apply simp
  1582   apply (rule sym)
  1583   apply (erule conjunct1[OF conjunct2[OF hk]])
  1584   apply (rule ballI)
  1585   apply (drule hk)
  1586   apply blast
  1587   done
  1588 
  1589 end
  1590 
  1591 
  1592 subsubsection {* The image case with fixed function and idempotency *}
  1593 
  1594 locale folding_image_simple_idem = folding_image_simple +
  1595   assumes idem: "x * x = x"
  1596 
  1597 sublocale folding_image_simple_idem < semilattice proof
  1598 qed (fact idem)
  1599 
  1600 context folding_image_simple_idem
  1601 begin
  1602 
  1603 lemma in_idem:
  1604   assumes "finite A" and "x \<in> A"
  1605   shows "g x * F A = F A"
  1606   using assms by (induct A) (auto simp add: left_commute)
  1607 
  1608 lemma subset_idem:
  1609   assumes "finite A" and "B \<subseteq> A"
  1610   shows "F B * F A = F A"
  1611 proof -
  1612   from assms have "finite B" by (blast dest: finite_subset)
  1613   then show ?thesis using `B \<subseteq> A` by (induct B)
  1614     (auto simp add: assoc in_idem `finite A`)
  1615 qed
  1616 
  1617 declare insert [simp del]
  1618 
  1619 lemma insert_idem [simp]:
  1620   assumes "finite A"
  1621   shows "F (insert x A) = g x * F A"
  1622   using assms by (cases "x \<in> A") (simp_all add: insert in_idem insert_absorb)
  1623 
  1624 lemma union_idem:
  1625   assumes "finite A" and "finite B"
  1626   shows "F (A \<union> B) = F A * F B"
  1627 proof -
  1628   from assms have "finite (A \<union> B)" and "A \<inter> B \<subseteq> A \<union> B" by auto
  1629   then have "F (A \<inter> B) * F (A \<union> B) = F (A \<union> B)" by (rule subset_idem)
  1630   with assms show ?thesis by (simp add: union_inter [of A B, symmetric] commute)
  1631 qed
  1632 
  1633 end
  1634 
  1635 
  1636 subsubsection {* The image case with flexible function and idempotency *}
  1637 
  1638 locale folding_image_idem = folding_image +
  1639   assumes idem: "x * x = x"
  1640 
  1641 sublocale folding_image_idem < folding_image_simple_idem "op *" 1 g "F g" proof
  1642 qed (fact idem)
  1643 
  1644 
  1645 subsubsection {* The neutral-less case *}
  1646 
  1647 locale folding_one = abel_semigroup +
  1648   fixes F :: "'a set \<Rightarrow> 'a"
  1649   assumes eq_fold: "finite A \<Longrightarrow> F A = fold1 f A"
  1650 begin
  1651 
  1652 lemma singleton [simp]:
  1653   "F {x} = x"
  1654   by (simp add: eq_fold)
  1655 
  1656 lemma eq_fold':
  1657   assumes "finite A" and "x \<notin> A"
  1658   shows "F (insert x A) = fold (op *) x A"
  1659 proof -
  1660   interpret ab_semigroup_mult "op *" by default (simp_all add: ac_simps)
  1661   from assms show ?thesis by (simp add: eq_fold fold1_eq_fold)
  1662 qed
  1663 
  1664 lemma insert [simp]:
  1665   assumes "finite A" and "x \<notin> A" and "A \<noteq> {}"
  1666   shows "F (insert x A) = x * F A"
  1667 proof -
  1668   from `A \<noteq> {}` obtain b where "b \<in> A" by blast
  1669   then obtain B where *: "A = insert b B" "b \<notin> B" by (blast dest: mk_disjoint_insert)
  1670   with `finite A` have "finite B" by simp
  1671   interpret fold: folding "op *" "\<lambda>a b. fold (op *) b a" proof
  1672   qed (simp_all add: fun_eq_iff ac_simps)
  1673   thm fold.comp_fun_commute' [of B b, simplified fun_eq_iff, simplified]
  1674   from `finite B` fold.comp_fun_commute' [of B x]
  1675     have "op * x \<circ> (\<lambda>b. fold op * b B) = (\<lambda>b. fold op * b B) \<circ> op * x" by simp
  1676   then have A: "x * fold op * b B = fold op * (b * x) B" by (simp add: fun_eq_iff commute)
  1677   from `finite B` * fold.insert [of B b]
  1678     have "(\<lambda>x. fold op * x (insert b B)) = (\<lambda>x. fold op * x B) \<circ> op * b" by simp
  1679   then have B: "fold op * x (insert b B) = fold op * (b * x) B" by (simp add: fun_eq_iff)
  1680   from A B assms * show ?thesis by (simp add: eq_fold' del: fold.insert)
  1681 qed
  1682 
  1683 lemma remove:
  1684   assumes "finite A" and "x \<in> A"
  1685   shows "F A = (if A - {x} = {} then x else x * F (A - {x}))"
  1686 proof -
  1687   from assms obtain B where "A = insert x B" and "x \<notin> B" by (blast dest: mk_disjoint_insert)
  1688   with assms show ?thesis by simp
  1689 qed
  1690 
  1691 lemma insert_remove:
  1692   assumes "finite A"
  1693   shows "F (insert x A) = (if A - {x} = {} then x else x * F (A - {x}))"
  1694   using assms by (cases "x \<in> A") (simp_all add: insert_absorb remove)
  1695 
  1696 lemma union_disjoint:
  1697   assumes "finite A" "A \<noteq> {}" and "finite B" "B \<noteq> {}" and "A \<inter> B = {}"
  1698   shows "F (A \<union> B) = F A * F B"
  1699   using assms by (induct A rule: finite_ne_induct) (simp_all add: ac_simps)
  1700 
  1701 lemma union_inter:
  1702   assumes "finite A" and "finite B" and "A \<inter> B \<noteq> {}"
  1703   shows "F (A \<union> B) * F (A \<inter> B) = F A * F B"
  1704 proof -
  1705   from assms have "A \<noteq> {}" and "B \<noteq> {}" by auto
  1706   from `finite A` `A \<noteq> {}` `A \<inter> B \<noteq> {}` show ?thesis proof (induct A rule: finite_ne_induct)
  1707     case (singleton x) then show ?case by (simp add: insert_absorb ac_simps)
  1708   next
  1709     case (insert x A) show ?case proof (cases "x \<in> B")
  1710       case True then have "B \<noteq> {}" by auto
  1711       with insert True `finite B` show ?thesis by (cases "A \<inter> B = {}")
  1712         (simp_all add: insert_absorb ac_simps union_disjoint)
  1713     next
  1714       case False with insert have "F (A \<union> B) * F (A \<inter> B) = F A * F B" by simp
  1715       moreover from False `finite B` insert have "finite (A \<union> B)" "x \<notin> A \<union> B" "A \<union> B \<noteq> {}"
  1716         by auto
  1717       ultimately show ?thesis using False `finite A` `x \<notin> A` `A \<noteq> {}` by (simp add: assoc)
  1718     qed
  1719   qed
  1720 qed
  1721 
  1722 lemma closed:
  1723   assumes "finite A" "A \<noteq> {}" and elem: "\<And>x y. x * y \<in> {x, y}"
  1724   shows "F A \<in> A"
  1725 using `finite A` `A \<noteq> {}` proof (induct rule: finite_ne_induct)
  1726   case singleton then show ?case by simp
  1727 next
  1728   case insert with elem show ?case by force
  1729 qed
  1730 
  1731 end
  1732 
  1733 
  1734 subsubsection {* The neutral-less case with idempotency *}
  1735 
  1736 locale folding_one_idem = folding_one +
  1737   assumes idem: "x * x = x"
  1738 
  1739 sublocale folding_one_idem < semilattice proof
  1740 qed (fact idem)
  1741 
  1742 context folding_one_idem
  1743 begin
  1744 
  1745 lemma in_idem:
  1746   assumes "finite A" and "x \<in> A"
  1747   shows "x * F A = F A"
  1748 proof -
  1749   from assms have "A \<noteq> {}" by auto
  1750   with `finite A` show ?thesis using `x \<in> A` by (induct A rule: finite_ne_induct) (auto simp add: ac_simps)
  1751 qed
  1752 
  1753 lemma subset_idem:
  1754   assumes "finite A" "B \<noteq> {}" and "B \<subseteq> A"
  1755   shows "F B * F A = F A"
  1756 proof -
  1757   from assms have "finite B" by (blast dest: finite_subset)
  1758   then show ?thesis using `B \<noteq> {}` `B \<subseteq> A` by (induct B rule: finite_ne_induct)
  1759     (simp_all add: assoc in_idem `finite A`)
  1760 qed
  1761 
  1762 lemma eq_fold_idem':
  1763   assumes "finite A"
  1764   shows "F (insert a A) = fold (op *) a A"
  1765 proof -
  1766   interpret ab_semigroup_idem_mult "op *" by default (simp_all add: ac_simps)
  1767   from assms show ?thesis by (simp add: eq_fold fold1_eq_fold_idem)
  1768 qed
  1769 
  1770 lemma insert_idem [simp]:
  1771   assumes "finite A" and "A \<noteq> {}"
  1772   shows "F (insert x A) = x * F A"
  1773 proof (cases "x \<in> A")
  1774   case False from `finite A` `x \<notin> A` `A \<noteq> {}` show ?thesis by (rule insert)
  1775 next
  1776   case True
  1777   from `finite A` `A \<noteq> {}` show ?thesis by (simp add: in_idem insert_absorb True)
  1778 qed
  1779   
  1780 lemma union_idem:
  1781   assumes "finite A" "A \<noteq> {}" and "finite B" "B \<noteq> {}"
  1782   shows "F (A \<union> B) = F A * F B"
  1783 proof (cases "A \<inter> B = {}")
  1784   case True with assms show ?thesis by (simp add: union_disjoint)
  1785 next
  1786   case False
  1787   from assms have "finite (A \<union> B)" and "A \<inter> B \<subseteq> A \<union> B" by auto
  1788   with False have "F (A \<inter> B) * F (A \<union> B) = F (A \<union> B)" by (auto intro: subset_idem)
  1789   with assms False show ?thesis by (simp add: union_inter [of A B, symmetric] commute)
  1790 qed
  1791 
  1792 lemma hom_commute:
  1793   assumes hom: "\<And>x y. h (x * y) = h x * h y"
  1794   and N: "finite N" "N \<noteq> {}" shows "h (F N) = F (h ` N)"
  1795 using N proof (induct rule: finite_ne_induct)
  1796   case singleton thus ?case by simp
  1797 next
  1798   case (insert n N)
  1799   then have "h (F (insert n N)) = h (n * F N)" by simp
  1800   also have "\<dots> = h n * h (F N)" by (rule hom)
  1801   also have "h (F N) = F (h ` N)" by(rule insert)
  1802   also have "h n * \<dots> = F (insert (h n) (h ` N))"
  1803     using insert by(simp)
  1804   also have "insert (h n) (h ` N) = h ` insert n N" by simp
  1805   finally show ?case .
  1806 qed
  1807 
  1808 end
  1809 
  1810 notation times (infixl "*" 70)
  1811 notation Groups.one ("1")
  1812 
  1813 
  1814 subsection {* Finite cardinality *}
  1815 
  1816 text {* This definition, although traditional, is ugly to work with:
  1817 @{text "card A == LEAST n. EX f. A = {f i | i. i < n}"}.
  1818 But now that we have @{text fold_image} things are easy:
  1819 *}
  1820 
  1821 definition card :: "'a set \<Rightarrow> nat" where
  1822   "card A = (if finite A then fold_image (op +) (\<lambda>x. 1) 0 A else 0)"
  1823 
  1824 interpretation card: folding_image_simple "op +" 0 "\<lambda>x. 1" card proof
  1825 qed (simp add: card_def)
  1826 
  1827 lemma card_infinite [simp]:
  1828   "\<not> finite A \<Longrightarrow> card A = 0"
  1829   by (simp add: card_def)
  1830 
  1831 lemma card_empty:
  1832   "card {} = 0"
  1833   by (fact card.empty)
  1834 
  1835 lemma card_insert_disjoint:
  1836   "finite A ==> x \<notin> A ==> card (insert x A) = Suc (card A)"
  1837   by simp
  1838 
  1839 lemma card_insert_if:
  1840   "finite A ==> card (insert x A) = (if x \<in> A then card A else Suc (card A))"
  1841   by auto (simp add: card.insert_remove card.remove)
  1842 
  1843 lemma card_ge_0_finite:
  1844   "card A > 0 \<Longrightarrow> finite A"
  1845   by (rule ccontr) simp
  1846 
  1847 lemma card_0_eq [simp, no_atp]:
  1848   "finite A \<Longrightarrow> card A = 0 \<longleftrightarrow> A = {}"
  1849   by (auto dest: mk_disjoint_insert)
  1850 
  1851 lemma finite_UNIV_card_ge_0:
  1852   "finite (UNIV :: 'a set) \<Longrightarrow> card (UNIV :: 'a set) > 0"
  1853   by (rule ccontr) simp
  1854 
  1855 lemma card_eq_0_iff:
  1856   "card A = 0 \<longleftrightarrow> A = {} \<or> \<not> finite A"
  1857   by auto
  1858 
  1859 lemma card_gt_0_iff:
  1860   "0 < card A \<longleftrightarrow> A \<noteq> {} \<and> finite A"
  1861   by (simp add: neq0_conv [symmetric] card_eq_0_iff) 
  1862 
  1863 lemma card_Suc_Diff1: "finite A ==> x: A ==> Suc (card (A - {x})) = card A"
  1864 apply(rule_tac t = A in insert_Diff [THEN subst], assumption)
  1865 apply(simp del:insert_Diff_single)
  1866 done
  1867 
  1868 lemma card_Diff_singleton:
  1869   "finite A ==> x: A ==> card (A - {x}) = card A - 1"
  1870 by (simp add: card_Suc_Diff1 [symmetric])
  1871 
  1872 lemma card_Diff_singleton_if:
  1873   "finite A ==> card (A - {x}) = (if x : A then card A - 1 else card A)"
  1874 by (simp add: card_Diff_singleton)
  1875 
  1876 lemma card_Diff_insert[simp]:
  1877 assumes "finite A" and "a:A" and "a ~: B"
  1878 shows "card(A - insert a B) = card(A - B) - 1"
  1879 proof -
  1880   have "A - insert a B = (A - B) - {a}" using assms by blast
  1881   then show ?thesis using assms by(simp add:card_Diff_singleton)
  1882 qed
  1883 
  1884 lemma card_insert: "finite A ==> card (insert x A) = Suc (card (A - {x}))"
  1885 by (simp add: card_insert_if card_Suc_Diff1 del:card_Diff_insert)
  1886 
  1887 lemma card_insert_le: "finite A ==> card A <= card (insert x A)"
  1888 by (simp add: card_insert_if)
  1889 
  1890 lemma card_Collect_less_nat[simp]: "card{i::nat. i < n} = n"
  1891 by (induct n) (simp_all add:less_Suc_eq Collect_disj_eq)
  1892 
  1893 lemma card_Collect_le_nat[simp]: "card{i::nat. i <= n} = Suc n"
  1894 using card_Collect_less_nat[of "Suc n"] by(simp add: less_Suc_eq_le)
  1895 
  1896 lemma card_mono:
  1897   assumes "finite B" and "A \<subseteq> B"
  1898   shows "card A \<le> card B"
  1899 proof -
  1900   from assms have "finite A" by (auto intro: finite_subset)
  1901   then show ?thesis using assms proof (induct A arbitrary: B)
  1902     case empty then show ?case by simp
  1903   next
  1904     case (insert x A)
  1905     then have "x \<in> B" by simp
  1906     from insert have "A \<subseteq> B - {x}" and "finite (B - {x})" by auto
  1907     with insert.hyps have "card A \<le> card (B - {x})" by auto
  1908     with `finite A` `x \<notin> A` `finite B` `x \<in> B` show ?case by simp (simp only: card.remove)
  1909   qed
  1910 qed
  1911 
  1912 lemma card_seteq: "finite B ==> (!!A. A <= B ==> card B <= card A ==> A = B)"
  1913 apply (induct rule: finite_induct)
  1914 apply simp
  1915 apply clarify
  1916 apply (subgoal_tac "finite A & A - {x} <= F")
  1917  prefer 2 apply (blast intro: finite_subset, atomize)
  1918 apply (drule_tac x = "A - {x}" in spec)
  1919 apply (simp add: card_Diff_singleton_if split add: split_if_asm)
  1920 apply (case_tac "card A", auto)
  1921 done
  1922 
  1923 lemma psubset_card_mono: "finite B ==> A < B ==> card A < card B"
  1924 apply (simp add: psubset_eq linorder_not_le [symmetric])
  1925 apply (blast dest: card_seteq)
  1926 done
  1927 
  1928 lemma card_Un_Int: "finite A ==> finite B
  1929     ==> card A + card B = card (A Un B) + card (A Int B)"
  1930   by (fact card.union_inter [symmetric])
  1931 
  1932 lemma card_Un_disjoint: "finite A ==> finite B
  1933     ==> A Int B = {} ==> card (A Un B) = card A + card B"
  1934   by (fact card.union_disjoint)
  1935 
  1936 lemma card_Diff_subset:
  1937   assumes "finite B" and "B \<subseteq> A"
  1938   shows "card (A - B) = card A - card B"
  1939 proof (cases "finite A")
  1940   case False with assms show ?thesis by simp
  1941 next
  1942   case True with assms show ?thesis by (induct B arbitrary: A) simp_all
  1943 qed
  1944 
  1945 lemma card_Diff_subset_Int:
  1946   assumes AB: "finite (A \<inter> B)" shows "card (A - B) = card A - card (A \<inter> B)"
  1947 proof -
  1948   have "A - B = A - A \<inter> B" by auto
  1949   thus ?thesis
  1950     by (simp add: card_Diff_subset AB) 
  1951 qed
  1952 
  1953 lemma diff_card_le_card_Diff:
  1954 assumes "finite B" shows "card A - card B \<le> card(A - B)"
  1955 proof-
  1956   have "card A - card B \<le> card A - card (A \<inter> B)"
  1957     using card_mono[OF assms Int_lower2, of A] by arith
  1958   also have "\<dots> = card(A-B)" using assms by(simp add: card_Diff_subset_Int)
  1959   finally show ?thesis .
  1960 qed
  1961 
  1962 lemma card_Diff1_less: "finite A ==> x: A ==> card (A - {x}) < card A"
  1963 apply (rule Suc_less_SucD)
  1964 apply (simp add: card_Suc_Diff1 del:card_Diff_insert)
  1965 done
  1966 
  1967 lemma card_Diff2_less:
  1968   "finite A ==> x: A ==> y: A ==> card (A - {x} - {y}) < card A"
  1969 apply (case_tac "x = y")
  1970  apply (simp add: card_Diff1_less del:card_Diff_insert)
  1971 apply (rule less_trans)
  1972  prefer 2 apply (auto intro!: card_Diff1_less simp del:card_Diff_insert)
  1973 done
  1974 
  1975 lemma card_Diff1_le: "finite A ==> card (A - {x}) <= card A"
  1976 apply (case_tac "x : A")
  1977  apply (simp_all add: card_Diff1_less less_imp_le)
  1978 done
  1979 
  1980 lemma card_psubset: "finite B ==> A \<subseteq> B ==> card A < card B ==> A < B"
  1981 by (erule psubsetI, blast)
  1982 
  1983 lemma insert_partition:
  1984   "\<lbrakk> x \<notin> F; \<forall>c1 \<in> insert x F. \<forall>c2 \<in> insert x F. c1 \<noteq> c2 \<longrightarrow> c1 \<inter> c2 = {} \<rbrakk>
  1985   \<Longrightarrow> x \<inter> \<Union> F = {}"
  1986 by auto
  1987 
  1988 lemma finite_psubset_induct[consumes 1, case_names psubset]:
  1989   assumes fin: "finite A" 
  1990   and     major: "\<And>A. finite A \<Longrightarrow> (\<And>B. B \<subset> A \<Longrightarrow> P B) \<Longrightarrow> P A" 
  1991   shows "P A"
  1992 using fin
  1993 proof (induct A taking: card rule: measure_induct_rule)
  1994   case (less A)
  1995   have fin: "finite A" by fact
  1996   have ih: "\<And>B. \<lbrakk>card B < card A; finite B\<rbrakk> \<Longrightarrow> P B" by fact
  1997   { fix B 
  1998     assume asm: "B \<subset> A"
  1999     from asm have "card B < card A" using psubset_card_mono fin by blast
  2000     moreover
  2001     from asm have "B \<subseteq> A" by auto
  2002     then have "finite B" using fin finite_subset by blast
  2003     ultimately 
  2004     have "P B" using ih by simp
  2005   }
  2006   with fin show "P A" using major by blast
  2007 qed
  2008 
  2009 text{* main cardinality theorem *}
  2010 lemma card_partition [rule_format]:
  2011   "finite C ==>
  2012      finite (\<Union> C) -->
  2013      (\<forall>c\<in>C. card c = k) -->
  2014      (\<forall>c1 \<in> C. \<forall>c2 \<in> C. c1 \<noteq> c2 --> c1 \<inter> c2 = {}) -->
  2015      k * card(C) = card (\<Union> C)"
  2016 apply (erule finite_induct, simp)
  2017 apply (simp add: card_Un_disjoint insert_partition 
  2018        finite_subset [of _ "\<Union> (insert x F)"])
  2019 done
  2020 
  2021 lemma card_eq_UNIV_imp_eq_UNIV:
  2022   assumes fin: "finite (UNIV :: 'a set)"
  2023   and card: "card A = card (UNIV :: 'a set)"
  2024   shows "A = (UNIV :: 'a set)"
  2025 proof
  2026   show "A \<subseteq> UNIV" by simp
  2027   show "UNIV \<subseteq> A"
  2028   proof
  2029     fix x
  2030     show "x \<in> A"
  2031     proof (rule ccontr)
  2032       assume "x \<notin> A"
  2033       then have "A \<subset> UNIV" by auto
  2034       with fin have "card A < card (UNIV :: 'a set)" by (fact psubset_card_mono)
  2035       with card show False by simp
  2036     qed
  2037   qed
  2038 qed
  2039 
  2040 text{*The form of a finite set of given cardinality*}
  2041 
  2042 lemma card_eq_SucD:
  2043 assumes "card A = Suc k"
  2044 shows "\<exists>b B. A = insert b B & b \<notin> B & card B = k & (k=0 \<longrightarrow> B={})"
  2045 proof -
  2046   have fin: "finite A" using assms by (auto intro: ccontr)
  2047   moreover have "card A \<noteq> 0" using assms by auto
  2048   ultimately obtain b where b: "b \<in> A" by auto
  2049   show ?thesis
  2050   proof (intro exI conjI)
  2051     show "A = insert b (A-{b})" using b by blast
  2052     show "b \<notin> A - {b}" by blast
  2053     show "card (A - {b}) = k" and "k = 0 \<longrightarrow> A - {b} = {}"
  2054       using assms b fin by(fastforce dest:mk_disjoint_insert)+
  2055   qed
  2056 qed
  2057 
  2058 lemma card_Suc_eq:
  2059   "(card A = Suc k) =
  2060    (\<exists>b B. A = insert b B & b \<notin> B & card B = k & (k=0 \<longrightarrow> B={}))"
  2061 apply(rule iffI)
  2062  apply(erule card_eq_SucD)
  2063 apply(auto)
  2064 apply(subst card_insert)
  2065  apply(auto intro:ccontr)
  2066 done
  2067 
  2068 lemma card_le_Suc_iff: "finite A \<Longrightarrow>
  2069   Suc n \<le> card A = (\<exists>a B. A = insert a B \<and> a \<notin> B \<and> n \<le> card B \<and> finite B)"
  2070 by (fastforce simp: card_Suc_eq less_eq_nat.simps(2) insert_eq_iff
  2071   dest: subset_singletonD split: nat.splits if_splits)
  2072 
  2073 lemma finite_fun_UNIVD2:
  2074   assumes fin: "finite (UNIV :: ('a \<Rightarrow> 'b) set)"
  2075   shows "finite (UNIV :: 'b set)"
  2076 proof -
  2077   from fin have "\<And>arbitrary. finite (range (\<lambda>f :: 'a \<Rightarrow> 'b. f arbitrary))"
  2078     by (rule finite_imageI)
  2079   moreover have "\<And>arbitrary. UNIV = range (\<lambda>f :: 'a \<Rightarrow> 'b. f arbitrary)"
  2080     by (rule UNIV_eq_I) auto
  2081   ultimately show "finite (UNIV :: 'b set)" by simp
  2082 qed
  2083 
  2084 lemma card_UNIV_unit: "card (UNIV :: unit set) = 1"
  2085   unfolding UNIV_unit by simp
  2086 
  2087 lemma card_UNIV_bool [simp]: "card (UNIV :: bool set) = 2"
  2088   unfolding UNIV_bool by simp
  2089 
  2090 
  2091 subsubsection {* Cardinality of image *}
  2092 
  2093 lemma card_image_le: "finite A ==> card (f ` A) <= card A"
  2094 apply (induct rule: finite_induct)
  2095  apply simp
  2096 apply (simp add: le_SucI card_insert_if)
  2097 done
  2098 
  2099 lemma card_image:
  2100   assumes "inj_on f A"
  2101   shows "card (f ` A) = card A"
  2102 proof (cases "finite A")
  2103   case True then show ?thesis using assms by (induct A) simp_all
  2104 next
  2105   case False then have "\<not> finite (f ` A)" using assms by (auto dest: finite_imageD)
  2106   with False show ?thesis by simp
  2107 qed
  2108 
  2109 lemma bij_betw_same_card: "bij_betw f A B \<Longrightarrow> card A = card B"
  2110 by(auto simp: card_image bij_betw_def)
  2111 
  2112 lemma endo_inj_surj: "finite A ==> f ` A \<subseteq> A ==> inj_on f A ==> f ` A = A"
  2113 by (simp add: card_seteq card_image)
  2114 
  2115 lemma eq_card_imp_inj_on:
  2116   "[| finite A; card(f ` A) = card A |] ==> inj_on f A"
  2117 apply (induct rule:finite_induct)
  2118 apply simp
  2119 apply(frule card_image_le[where f = f])
  2120 apply(simp add:card_insert_if split:if_splits)
  2121 done
  2122 
  2123 lemma inj_on_iff_eq_card:
  2124   "finite A ==> inj_on f A = (card(f ` A) = card A)"
  2125 by(blast intro: card_image eq_card_imp_inj_on)
  2126 
  2127 
  2128 lemma card_inj_on_le:
  2129   "[|inj_on f A; f ` A \<subseteq> B; finite B |] ==> card A \<le> card B"
  2130 apply (subgoal_tac "finite A") 
  2131  apply (force intro: card_mono simp add: card_image [symmetric])
  2132 apply (blast intro: finite_imageD dest: finite_subset) 
  2133 done
  2134 
  2135 lemma card_bij_eq:
  2136   "[|inj_on f A; f ` A \<subseteq> B; inj_on g B; g ` B \<subseteq> A;
  2137      finite A; finite B |] ==> card A = card B"
  2138 by (auto intro: le_antisym card_inj_on_le)
  2139 
  2140 lemma bij_betw_finite:
  2141   assumes "bij_betw f A B"
  2142   shows "finite A \<longleftrightarrow> finite B"
  2143 using assms unfolding bij_betw_def
  2144 using finite_imageD[of f A] by auto
  2145 
  2146 
  2147 subsubsection {* Pigeonhole Principles *}
  2148 
  2149 lemma pigeonhole: "card A > card(f ` A) \<Longrightarrow> ~ inj_on f A "
  2150 by (auto dest: card_image less_irrefl_nat)
  2151 
  2152 lemma pigeonhole_infinite:
  2153 assumes  "~ finite A" and "finite(f`A)"
  2154 shows "EX a0:A. ~finite{a:A. f a = f a0}"
  2155 proof -
  2156   have "finite(f`A) \<Longrightarrow> ~ finite A \<Longrightarrow> EX a0:A. ~finite{a:A. f a = f a0}"
  2157   proof(induct "f`A" arbitrary: A rule: finite_induct)
  2158     case empty thus ?case by simp
  2159   next
  2160     case (insert b F)
  2161     show ?case
  2162     proof cases
  2163       assume "finite{a:A. f a = b}"
  2164       hence "~ finite(A - {a:A. f a = b})" using `\<not> finite A` by simp
  2165       also have "A - {a:A. f a = b} = {a:A. f a \<noteq> b}" by blast
  2166       finally have "~ finite({a:A. f a \<noteq> b})" .
  2167       from insert(3)[OF _ this]
  2168       show ?thesis using insert(2,4) by simp (blast intro: rev_finite_subset)
  2169     next
  2170       assume 1: "~finite{a:A. f a = b}"
  2171       hence "{a \<in> A. f a = b} \<noteq> {}" by force
  2172       thus ?thesis using 1 by blast
  2173     qed
  2174   qed
  2175   from this[OF assms(2,1)] show ?thesis .
  2176 qed
  2177 
  2178 lemma pigeonhole_infinite_rel:
  2179 assumes "~finite A" and "finite B" and "ALL a:A. EX b:B. R a b"
  2180 shows "EX b:B. ~finite{a:A. R a b}"
  2181 proof -
  2182    let ?F = "%a. {b:B. R a b}"
  2183    from finite_Pow_iff[THEN iffD2, OF `finite B`]
  2184    have "finite(?F ` A)" by(blast intro: rev_finite_subset)
  2185    from pigeonhole_infinite[where f = ?F, OF assms(1) this]
  2186    obtain a0 where "a0\<in>A" and 1: "\<not> finite {a\<in>A. ?F a = ?F a0}" ..
  2187    obtain b0 where "b0 : B" and "R a0 b0" using `a0:A` assms(3) by blast
  2188    { assume "finite{a:A. R a b0}"
  2189      then have "finite {a\<in>A. ?F a = ?F a0}"
  2190        using `b0 : B` `R a0 b0` by(blast intro: rev_finite_subset)
  2191    }
  2192    with 1 `b0 : B` show ?thesis by blast
  2193 qed
  2194 
  2195 
  2196 subsubsection {* Cardinality of sums *}
  2197 
  2198 lemma card_Plus:
  2199   assumes "finite A" and "finite B"
  2200   shows "card (A <+> B) = card A + card B"
  2201 proof -
  2202   have "Inl`A \<inter> Inr`B = {}" by fast
  2203   with assms show ?thesis
  2204     unfolding Plus_def
  2205     by (simp add: card_Un_disjoint card_image)
  2206 qed
  2207 
  2208 lemma card_Plus_conv_if:
  2209   "card (A <+> B) = (if finite A \<and> finite B then card A + card B else 0)"
  2210   by (auto simp add: card_Plus)
  2211 
  2212 
  2213 subsubsection {* Cardinality of the Powerset *}
  2214 
  2215 lemma card_Pow: "finite A ==> card (Pow A) = 2 ^ card A"
  2216 apply (induct rule: finite_induct)
  2217  apply (simp_all add: Pow_insert)
  2218 apply (subst card_Un_disjoint, blast)
  2219   apply (blast, blast)
  2220 apply (subgoal_tac "inj_on (insert x) (Pow F)")
  2221  apply (subst mult_2)
  2222  apply (simp add: card_image Pow_insert)
  2223 apply (unfold inj_on_def)
  2224 apply (blast elim!: equalityE)
  2225 done
  2226 
  2227 text {* Relates to equivalence classes.  Based on a theorem of F. Kamm\"uller.  *}
  2228 
  2229 lemma dvd_partition:
  2230   "finite (Union C) ==>
  2231     ALL c : C. k dvd card c ==>
  2232     (ALL c1: C. ALL c2: C. c1 \<noteq> c2 --> c1 Int c2 = {}) ==>
  2233   k dvd card (Union C)"
  2234 apply (frule finite_UnionD)
  2235 apply (rotate_tac -1)
  2236 apply (induct rule: finite_induct)
  2237 apply simp_all
  2238 apply clarify
  2239 apply (subst card_Un_disjoint)
  2240    apply (auto simp add: disjoint_eq_subset_Compl)
  2241 done
  2242 
  2243 
  2244 subsubsection {* Relating injectivity and surjectivity *}
  2245 
  2246 lemma finite_surj_inj: "finite A \<Longrightarrow> A \<subseteq> f ` A \<Longrightarrow> inj_on f A"
  2247 apply(rule eq_card_imp_inj_on, assumption)
  2248 apply(frule finite_imageI)
  2249 apply(drule (1) card_seteq)
  2250  apply(erule card_image_le)
  2251 apply simp
  2252 done
  2253 
  2254 lemma finite_UNIV_surj_inj: fixes f :: "'a \<Rightarrow> 'a"
  2255 shows "finite(UNIV:: 'a set) \<Longrightarrow> surj f \<Longrightarrow> inj f"
  2256 by (blast intro: finite_surj_inj subset_UNIV)
  2257 
  2258 lemma finite_UNIV_inj_surj: fixes f :: "'a \<Rightarrow> 'a"
  2259 shows "finite(UNIV:: 'a set) \<Longrightarrow> inj f \<Longrightarrow> surj f"
  2260 by(fastforce simp:surj_def dest!: endo_inj_surj)
  2261 
  2262 corollary infinite_UNIV_nat[iff]: "~finite(UNIV::nat set)"
  2263 proof
  2264   assume "finite(UNIV::nat set)"
  2265   with finite_UNIV_inj_surj[of Suc]
  2266   show False by simp (blast dest: Suc_neq_Zero surjD)
  2267 qed
  2268 
  2269 (* Often leads to bogus ATP proofs because of reduced type information, hence no_atp *)
  2270 lemma infinite_UNIV_char_0[no_atp]:
  2271   "\<not> finite (UNIV::'a::semiring_char_0 set)"
  2272 proof
  2273   assume "finite (UNIV::'a set)"
  2274   with subset_UNIV have "finite (range of_nat::'a set)"
  2275     by (rule finite_subset)
  2276   moreover have "inj (of_nat::nat \<Rightarrow> 'a)"
  2277     by (simp add: inj_on_def)
  2278   ultimately have "finite (UNIV::nat set)"
  2279     by (rule finite_imageD)
  2280   then show "False"
  2281     by simp
  2282 qed
  2283 
  2284 hide_const (open) Finite_Set.fold
  2285 
  2286 end