src/HOL/HOL.thy
author wenzelm
Thu May 24 17:25:53 2012 +0200 (2012-05-24)
changeset 47988 e4b69e10b990
parent 47657 1ba213363d0c
child 48073 1b609a7837ef
permissions -rw-r--r--
tuned proofs;
     1 (*  Title:      HOL/HOL.thy
     2     Author:     Tobias Nipkow, Markus Wenzel, and Larry Paulson
     3 *)
     4 
     5 header {* The basis of Higher-Order Logic *}
     6 
     7 theory HOL
     8 imports Pure "~~/src/Tools/Code_Generator"
     9 keywords
    10   "try" "solve_direct" "quickcheck"
    11     "print_coercions" "print_coercion_maps" "print_claset" "print_induct_rules" :: diag and
    12   "quickcheck_params" :: thy_decl
    13 uses
    14   ("Tools/hologic.ML")
    15   "~~/src/Tools/misc_legacy.ML"
    16   "~~/src/Tools/try.ML"
    17   "~~/src/Tools/quickcheck.ML"
    18   "~~/src/Tools/solve_direct.ML"
    19   "~~/src/Tools/IsaPlanner/zipper.ML"
    20   "~~/src/Tools/IsaPlanner/isand.ML"
    21   "~~/src/Tools/IsaPlanner/rw_tools.ML"
    22   "~~/src/Tools/IsaPlanner/rw_inst.ML"
    23   "~~/src/Provers/hypsubst.ML"
    24   "~~/src/Provers/splitter.ML"
    25   "~~/src/Provers/classical.ML"
    26   "~~/src/Provers/blast.ML"
    27   "~~/src/Provers/clasimp.ML"
    28   "~~/src/Tools/coherent.ML"
    29   "~~/src/Tools/eqsubst.ML"
    30   "~~/src/Provers/quantifier1.ML"
    31   ("Tools/simpdata.ML")
    32   "~~/src/Tools/atomize_elim.ML"
    33   "~~/src/Tools/induct.ML"
    34   "~~/src/Tools/cong_tac.ML"
    35   "~~/src/Tools/intuitionistic.ML"
    36   "~~/src/Tools/project_rule.ML"
    37   ("~~/src/Tools/induction.ML")
    38   ("~~/src/Tools/induct_tacs.ML")
    39   ("Tools/cnf_funcs.ML")
    40   "~~/src/Tools/subtyping.ML"
    41   "~~/src/Tools/case_product.ML"
    42 begin
    43 
    44 setup {*
    45   Intuitionistic.method_setup @{binding iprover}
    46   #> Quickcheck.setup
    47   #> Solve_Direct.setup
    48   #> Subtyping.setup
    49   #> Case_Product.setup
    50 *}
    51 
    52 subsection {* Primitive logic *}
    53 
    54 subsubsection {* Core syntax *}
    55 
    56 classes type
    57 default_sort type
    58 setup {* Object_Logic.add_base_sort @{sort type} *}
    59 
    60 arities
    61   "fun" :: (type, type) type
    62   itself :: (type) type
    63 
    64 typedecl bool
    65 
    66 judgment
    67   Trueprop      :: "bool => prop"                   ("(_)" 5)
    68 
    69 axiomatization
    70   implies       :: "[bool, bool] => bool"           (infixr "-->" 25)  and
    71   eq            :: "['a, 'a] => bool"               (infixl "=" 50)  and
    72   The           :: "('a => bool) => 'a"
    73 
    74 consts
    75   True          :: bool
    76   False         :: bool
    77   Not           :: "bool => bool"                   ("~ _" [40] 40)
    78 
    79   conj          :: "[bool, bool] => bool"           (infixr "&" 35)
    80   disj          :: "[bool, bool] => bool"           (infixr "|" 30)
    81 
    82   All           :: "('a => bool) => bool"           (binder "ALL " 10)
    83   Ex            :: "('a => bool) => bool"           (binder "EX " 10)
    84   Ex1           :: "('a => bool) => bool"           (binder "EX! " 10)
    85 
    86 
    87 subsubsection {* Additional concrete syntax *}
    88 
    89 notation (output)
    90   eq  (infix "=" 50)
    91 
    92 abbreviation
    93   not_equal :: "['a, 'a] => bool"  (infixl "~=" 50) where
    94   "x ~= y == ~ (x = y)"
    95 
    96 notation (output)
    97   not_equal  (infix "~=" 50)
    98 
    99 notation (xsymbols)
   100   Not  ("\<not> _" [40] 40) and
   101   conj  (infixr "\<and>" 35) and
   102   disj  (infixr "\<or>" 30) and
   103   implies  (infixr "\<longrightarrow>" 25) and
   104   not_equal  (infix "\<noteq>" 50)
   105 
   106 notation (HTML output)
   107   Not  ("\<not> _" [40] 40) and
   108   conj  (infixr "\<and>" 35) and
   109   disj  (infixr "\<or>" 30) and
   110   not_equal  (infix "\<noteq>" 50)
   111 
   112 abbreviation (iff)
   113   iff :: "[bool, bool] => bool"  (infixr "<->" 25) where
   114   "A <-> B == A = B"
   115 
   116 notation (xsymbols)
   117   iff  (infixr "\<longleftrightarrow>" 25)
   118 
   119 syntax "_The" :: "[pttrn, bool] => 'a"  ("(3THE _./ _)" [0, 10] 10)
   120 translations "THE x. P" == "CONST The (%x. P)"
   121 print_translation {*
   122   [(@{const_syntax The}, fn [Abs abs] =>
   123       let val (x, t) = Syntax_Trans.atomic_abs_tr' abs
   124       in Syntax.const @{syntax_const "_The"} $ x $ t end)]
   125 *}  -- {* To avoid eta-contraction of body *}
   126 
   127 nonterminal letbinds and letbind
   128 syntax
   129   "_bind"       :: "[pttrn, 'a] => letbind"              ("(2_ =/ _)" 10)
   130   ""            :: "letbind => letbinds"                 ("_")
   131   "_binds"      :: "[letbind, letbinds] => letbinds"     ("_;/ _")
   132   "_Let"        :: "[letbinds, 'a] => 'a"                ("(let (_)/ in (_))" [0, 10] 10)
   133 
   134 nonterminal case_syn and cases_syn
   135 syntax
   136   "_case_syntax" :: "['a, cases_syn] => 'b"  ("(case _ of/ _)" 10)
   137   "_case1" :: "['a, 'b] => case_syn"  ("(2_ =>/ _)" 10)
   138   "" :: "case_syn => cases_syn"  ("_")
   139   "_case2" :: "[case_syn, cases_syn] => cases_syn"  ("_/ | _")
   140 syntax (xsymbols)
   141   "_case1" :: "['a, 'b] => case_syn"  ("(2_ \<Rightarrow>/ _)" 10)
   142 
   143 notation (xsymbols)
   144   All  (binder "\<forall>" 10) and
   145   Ex  (binder "\<exists>" 10) and
   146   Ex1  (binder "\<exists>!" 10)
   147 
   148 notation (HTML output)
   149   All  (binder "\<forall>" 10) and
   150   Ex  (binder "\<exists>" 10) and
   151   Ex1  (binder "\<exists>!" 10)
   152 
   153 notation (HOL)
   154   All  (binder "! " 10) and
   155   Ex  (binder "? " 10) and
   156   Ex1  (binder "?! " 10)
   157 
   158 
   159 subsubsection {* Axioms and basic definitions *}
   160 
   161 axiomatization where
   162   refl: "t = (t::'a)" and
   163   subst: "s = t \<Longrightarrow> P s \<Longrightarrow> P t" and
   164   ext: "(!!x::'a. (f x ::'b) = g x) ==> (%x. f x) = (%x. g x)"
   165     -- {*Extensionality is built into the meta-logic, and this rule expresses
   166          a related property.  It is an eta-expanded version of the traditional
   167          rule, and similar to the ABS rule of HOL*} and
   168 
   169   the_eq_trivial: "(THE x. x = a) = (a::'a)"
   170 
   171 axiomatization where
   172   impI: "(P ==> Q) ==> P-->Q" and
   173   mp: "[| P-->Q;  P |] ==> Q" and
   174 
   175   iff: "(P-->Q) --> (Q-->P) --> (P=Q)" and
   176   True_or_False: "(P=True) | (P=False)"
   177 
   178 defs
   179   True_def:     "True      == ((%x::bool. x) = (%x. x))"
   180   All_def:      "All(P)    == (P = (%x. True))"
   181   Ex_def:       "Ex(P)     == !Q. (!x. P x --> Q) --> Q"
   182   False_def:    "False     == (!P. P)"
   183   not_def:      "~ P       == P-->False"
   184   and_def:      "P & Q     == !R. (P-->Q-->R) --> R"
   185   or_def:       "P | Q     == !R. (P-->R) --> (Q-->R) --> R"
   186   Ex1_def:      "Ex1(P)    == ? x. P(x) & (! y. P(y) --> y=x)"
   187 
   188 definition If :: "bool \<Rightarrow> 'a \<Rightarrow> 'a \<Rightarrow> 'a" ("(if (_)/ then (_)/ else (_))" [0, 0, 10] 10)
   189   where "If P x y \<equiv> (THE z::'a. (P=True --> z=x) & (P=False --> z=y))"
   190 
   191 definition Let :: "'a \<Rightarrow> ('a \<Rightarrow> 'b) \<Rightarrow> 'b"
   192   where "Let s f \<equiv> f s"
   193 
   194 translations
   195   "_Let (_binds b bs) e"  == "_Let b (_Let bs e)"
   196   "let x = a in e"        == "CONST Let a (%x. e)"
   197 
   198 axiomatization undefined :: 'a
   199 
   200 class default = fixes default :: 'a
   201 
   202 
   203 subsection {* Fundamental rules *}
   204 
   205 subsubsection {* Equality *}
   206 
   207 lemma sym: "s = t ==> t = s"
   208   by (erule subst) (rule refl)
   209 
   210 lemma ssubst: "t = s ==> P s ==> P t"
   211   by (drule sym) (erule subst)
   212 
   213 lemma trans: "[| r=s; s=t |] ==> r=t"
   214   by (erule subst)
   215 
   216 lemma trans_sym [Pure.elim?]: "r = s ==> t = s ==> r = t"
   217   by (rule trans [OF _ sym])
   218 
   219 lemma meta_eq_to_obj_eq: 
   220   assumes meq: "A == B"
   221   shows "A = B"
   222   by (unfold meq) (rule refl)
   223 
   224 text {* Useful with @{text erule} for proving equalities from known equalities. *}
   225      (* a = b
   226         |   |
   227         c = d   *)
   228 lemma box_equals: "[| a=b;  a=c;  b=d |] ==> c=d"
   229 apply (rule trans)
   230 apply (rule trans)
   231 apply (rule sym)
   232 apply assumption+
   233 done
   234 
   235 text {* For calculational reasoning: *}
   236 
   237 lemma forw_subst: "a = b ==> P b ==> P a"
   238   by (rule ssubst)
   239 
   240 lemma back_subst: "P a ==> a = b ==> P b"
   241   by (rule subst)
   242 
   243 
   244 subsubsection {* Congruence rules for application *}
   245 
   246 text {* Similar to @{text AP_THM} in Gordon's HOL. *}
   247 lemma fun_cong: "(f::'a=>'b) = g ==> f(x)=g(x)"
   248 apply (erule subst)
   249 apply (rule refl)
   250 done
   251 
   252 text {* Similar to @{text AP_TERM} in Gordon's HOL and FOL's @{text subst_context}. *}
   253 lemma arg_cong: "x=y ==> f(x)=f(y)"
   254 apply (erule subst)
   255 apply (rule refl)
   256 done
   257 
   258 lemma arg_cong2: "\<lbrakk> a = b; c = d \<rbrakk> \<Longrightarrow> f a c = f b d"
   259 apply (erule ssubst)+
   260 apply (rule refl)
   261 done
   262 
   263 lemma cong: "[| f = g; (x::'a) = y |] ==> f x = g y"
   264 apply (erule subst)+
   265 apply (rule refl)
   266 done
   267 
   268 ML {* val cong_tac = Cong_Tac.cong_tac @{thm cong} *}
   269 
   270 
   271 subsubsection {* Equality of booleans -- iff *}
   272 
   273 lemma iffI: assumes "P ==> Q" and "Q ==> P" shows "P=Q"
   274   by (iprover intro: iff [THEN mp, THEN mp] impI assms)
   275 
   276 lemma iffD2: "[| P=Q; Q |] ==> P"
   277   by (erule ssubst)
   278 
   279 lemma rev_iffD2: "[| Q; P=Q |] ==> P"
   280   by (erule iffD2)
   281 
   282 lemma iffD1: "Q = P \<Longrightarrow> Q \<Longrightarrow> P"
   283   by (drule sym) (rule iffD2)
   284 
   285 lemma rev_iffD1: "Q \<Longrightarrow> Q = P \<Longrightarrow> P"
   286   by (drule sym) (rule rev_iffD2)
   287 
   288 lemma iffE:
   289   assumes major: "P=Q"
   290     and minor: "[| P --> Q; Q --> P |] ==> R"
   291   shows R
   292   by (iprover intro: minor impI major [THEN iffD2] major [THEN iffD1])
   293 
   294 
   295 subsubsection {*True*}
   296 
   297 lemma TrueI: "True"
   298   unfolding True_def by (rule refl)
   299 
   300 lemma eqTrueI: "P ==> P = True"
   301   by (iprover intro: iffI TrueI)
   302 
   303 lemma eqTrueE: "P = True ==> P"
   304   by (erule iffD2) (rule TrueI)
   305 
   306 
   307 subsubsection {*Universal quantifier*}
   308 
   309 lemma allI: assumes "!!x::'a. P(x)" shows "ALL x. P(x)"
   310   unfolding All_def by (iprover intro: ext eqTrueI assms)
   311 
   312 lemma spec: "ALL x::'a. P(x) ==> P(x)"
   313 apply (unfold All_def)
   314 apply (rule eqTrueE)
   315 apply (erule fun_cong)
   316 done
   317 
   318 lemma allE:
   319   assumes major: "ALL x. P(x)"
   320     and minor: "P(x) ==> R"
   321   shows R
   322   by (iprover intro: minor major [THEN spec])
   323 
   324 lemma all_dupE:
   325   assumes major: "ALL x. P(x)"
   326     and minor: "[| P(x); ALL x. P(x) |] ==> R"
   327   shows R
   328   by (iprover intro: minor major major [THEN spec])
   329 
   330 
   331 subsubsection {* False *}
   332 
   333 text {*
   334   Depends upon @{text spec}; it is impossible to do propositional
   335   logic before quantifiers!
   336 *}
   337 
   338 lemma FalseE: "False ==> P"
   339   apply (unfold False_def)
   340   apply (erule spec)
   341   done
   342 
   343 lemma False_neq_True: "False = True ==> P"
   344   by (erule eqTrueE [THEN FalseE])
   345 
   346 
   347 subsubsection {* Negation *}
   348 
   349 lemma notI:
   350   assumes "P ==> False"
   351   shows "~P"
   352   apply (unfold not_def)
   353   apply (iprover intro: impI assms)
   354   done
   355 
   356 lemma False_not_True: "False ~= True"
   357   apply (rule notI)
   358   apply (erule False_neq_True)
   359   done
   360 
   361 lemma True_not_False: "True ~= False"
   362   apply (rule notI)
   363   apply (drule sym)
   364   apply (erule False_neq_True)
   365   done
   366 
   367 lemma notE: "[| ~P;  P |] ==> R"
   368   apply (unfold not_def)
   369   apply (erule mp [THEN FalseE])
   370   apply assumption
   371   done
   372 
   373 lemma notI2: "(P \<Longrightarrow> \<not> Pa) \<Longrightarrow> (P \<Longrightarrow> Pa) \<Longrightarrow> \<not> P"
   374   by (erule notE [THEN notI]) (erule meta_mp)
   375 
   376 
   377 subsubsection {*Implication*}
   378 
   379 lemma impE:
   380   assumes "P-->Q" "P" "Q ==> R"
   381   shows "R"
   382 by (iprover intro: assms mp)
   383 
   384 (* Reduces Q to P-->Q, allowing substitution in P. *)
   385 lemma rev_mp: "[| P;  P --> Q |] ==> Q"
   386 by (iprover intro: mp)
   387 
   388 lemma contrapos_nn:
   389   assumes major: "~Q"
   390       and minor: "P==>Q"
   391   shows "~P"
   392 by (iprover intro: notI minor major [THEN notE])
   393 
   394 (*not used at all, but we already have the other 3 combinations *)
   395 lemma contrapos_pn:
   396   assumes major: "Q"
   397       and minor: "P ==> ~Q"
   398   shows "~P"
   399 by (iprover intro: notI minor major notE)
   400 
   401 lemma not_sym: "t ~= s ==> s ~= t"
   402   by (erule contrapos_nn) (erule sym)
   403 
   404 lemma eq_neq_eq_imp_neq: "[| x = a ; a ~= b; b = y |] ==> x ~= y"
   405   by (erule subst, erule ssubst, assumption)
   406 
   407 (*still used in HOLCF*)
   408 lemma rev_contrapos:
   409   assumes pq: "P ==> Q"
   410       and nq: "~Q"
   411   shows "~P"
   412 apply (rule nq [THEN contrapos_nn])
   413 apply (erule pq)
   414 done
   415 
   416 subsubsection {*Existential quantifier*}
   417 
   418 lemma exI: "P x ==> EX x::'a. P x"
   419 apply (unfold Ex_def)
   420 apply (iprover intro: allI allE impI mp)
   421 done
   422 
   423 lemma exE:
   424   assumes major: "EX x::'a. P(x)"
   425       and minor: "!!x. P(x) ==> Q"
   426   shows "Q"
   427 apply (rule major [unfolded Ex_def, THEN spec, THEN mp])
   428 apply (iprover intro: impI [THEN allI] minor)
   429 done
   430 
   431 
   432 subsubsection {*Conjunction*}
   433 
   434 lemma conjI: "[| P; Q |] ==> P&Q"
   435 apply (unfold and_def)
   436 apply (iprover intro: impI [THEN allI] mp)
   437 done
   438 
   439 lemma conjunct1: "[| P & Q |] ==> P"
   440 apply (unfold and_def)
   441 apply (iprover intro: impI dest: spec mp)
   442 done
   443 
   444 lemma conjunct2: "[| P & Q |] ==> Q"
   445 apply (unfold and_def)
   446 apply (iprover intro: impI dest: spec mp)
   447 done
   448 
   449 lemma conjE:
   450   assumes major: "P&Q"
   451       and minor: "[| P; Q |] ==> R"
   452   shows "R"
   453 apply (rule minor)
   454 apply (rule major [THEN conjunct1])
   455 apply (rule major [THEN conjunct2])
   456 done
   457 
   458 lemma context_conjI:
   459   assumes "P" "P ==> Q" shows "P & Q"
   460 by (iprover intro: conjI assms)
   461 
   462 
   463 subsubsection {*Disjunction*}
   464 
   465 lemma disjI1: "P ==> P|Q"
   466 apply (unfold or_def)
   467 apply (iprover intro: allI impI mp)
   468 done
   469 
   470 lemma disjI2: "Q ==> P|Q"
   471 apply (unfold or_def)
   472 apply (iprover intro: allI impI mp)
   473 done
   474 
   475 lemma disjE:
   476   assumes major: "P|Q"
   477       and minorP: "P ==> R"
   478       and minorQ: "Q ==> R"
   479   shows "R"
   480 by (iprover intro: minorP minorQ impI
   481                  major [unfolded or_def, THEN spec, THEN mp, THEN mp])
   482 
   483 
   484 subsubsection {*Classical logic*}
   485 
   486 lemma classical:
   487   assumes prem: "~P ==> P"
   488   shows "P"
   489 apply (rule True_or_False [THEN disjE, THEN eqTrueE])
   490 apply assumption
   491 apply (rule notI [THEN prem, THEN eqTrueI])
   492 apply (erule subst)
   493 apply assumption
   494 done
   495 
   496 lemmas ccontr = FalseE [THEN classical]
   497 
   498 (*notE with premises exchanged; it discharges ~R so that it can be used to
   499   make elimination rules*)
   500 lemma rev_notE:
   501   assumes premp: "P"
   502       and premnot: "~R ==> ~P"
   503   shows "R"
   504 apply (rule ccontr)
   505 apply (erule notE [OF premnot premp])
   506 done
   507 
   508 (*Double negation law*)
   509 lemma notnotD: "~~P ==> P"
   510 apply (rule classical)
   511 apply (erule notE)
   512 apply assumption
   513 done
   514 
   515 lemma contrapos_pp:
   516   assumes p1: "Q"
   517       and p2: "~P ==> ~Q"
   518   shows "P"
   519 by (iprover intro: classical p1 p2 notE)
   520 
   521 
   522 subsubsection {*Unique existence*}
   523 
   524 lemma ex1I:
   525   assumes "P a" "!!x. P(x) ==> x=a"
   526   shows "EX! x. P(x)"
   527 by (unfold Ex1_def, iprover intro: assms exI conjI allI impI)
   528 
   529 text{*Sometimes easier to use: the premises have no shared variables.  Safe!*}
   530 lemma ex_ex1I:
   531   assumes ex_prem: "EX x. P(x)"
   532       and eq: "!!x y. [| P(x); P(y) |] ==> x=y"
   533   shows "EX! x. P(x)"
   534 by (iprover intro: ex_prem [THEN exE] ex1I eq)
   535 
   536 lemma ex1E:
   537   assumes major: "EX! x. P(x)"
   538       and minor: "!!x. [| P(x);  ALL y. P(y) --> y=x |] ==> R"
   539   shows "R"
   540 apply (rule major [unfolded Ex1_def, THEN exE])
   541 apply (erule conjE)
   542 apply (iprover intro: minor)
   543 done
   544 
   545 lemma ex1_implies_ex: "EX! x. P x ==> EX x. P x"
   546 apply (erule ex1E)
   547 apply (rule exI)
   548 apply assumption
   549 done
   550 
   551 
   552 subsubsection {*THE: definite description operator*}
   553 
   554 lemma the_equality:
   555   assumes prema: "P a"
   556       and premx: "!!x. P x ==> x=a"
   557   shows "(THE x. P x) = a"
   558 apply (rule trans [OF _ the_eq_trivial])
   559 apply (rule_tac f = "The" in arg_cong)
   560 apply (rule ext)
   561 apply (rule iffI)
   562  apply (erule premx)
   563 apply (erule ssubst, rule prema)
   564 done
   565 
   566 lemma theI:
   567   assumes "P a" and "!!x. P x ==> x=a"
   568   shows "P (THE x. P x)"
   569 by (iprover intro: assms the_equality [THEN ssubst])
   570 
   571 lemma theI': "EX! x. P x ==> P (THE x. P x)"
   572 apply (erule ex1E)
   573 apply (erule theI)
   574 apply (erule allE)
   575 apply (erule mp)
   576 apply assumption
   577 done
   578 
   579 (*Easier to apply than theI: only one occurrence of P*)
   580 lemma theI2:
   581   assumes "P a" "!!x. P x ==> x=a" "!!x. P x ==> Q x"
   582   shows "Q (THE x. P x)"
   583 by (iprover intro: assms theI)
   584 
   585 lemma the1I2: assumes "EX! x. P x" "\<And>x. P x \<Longrightarrow> Q x" shows "Q (THE x. P x)"
   586 by(iprover intro:assms(2) theI2[where P=P and Q=Q] ex1E[OF assms(1)]
   587            elim:allE impE)
   588 
   589 lemma the1_equality [elim?]: "[| EX!x. P x; P a |] ==> (THE x. P x) = a"
   590 apply (rule the_equality)
   591 apply  assumption
   592 apply (erule ex1E)
   593 apply (erule all_dupE)
   594 apply (drule mp)
   595 apply  assumption
   596 apply (erule ssubst)
   597 apply (erule allE)
   598 apply (erule mp)
   599 apply assumption
   600 done
   601 
   602 lemma the_sym_eq_trivial: "(THE y. x=y) = x"
   603 apply (rule the_equality)
   604 apply (rule refl)
   605 apply (erule sym)
   606 done
   607 
   608 
   609 subsubsection {*Classical intro rules for disjunction and existential quantifiers*}
   610 
   611 lemma disjCI:
   612   assumes "~Q ==> P" shows "P|Q"
   613 apply (rule classical)
   614 apply (iprover intro: assms disjI1 disjI2 notI elim: notE)
   615 done
   616 
   617 lemma excluded_middle: "~P | P"
   618 by (iprover intro: disjCI)
   619 
   620 text {*
   621   case distinction as a natural deduction rule.
   622   Note that @{term "~P"} is the second case, not the first
   623 *}
   624 lemma case_split [case_names True False]:
   625   assumes prem1: "P ==> Q"
   626       and prem2: "~P ==> Q"
   627   shows "Q"
   628 apply (rule excluded_middle [THEN disjE])
   629 apply (erule prem2)
   630 apply (erule prem1)
   631 done
   632 
   633 (*Classical implies (-->) elimination. *)
   634 lemma impCE:
   635   assumes major: "P-->Q"
   636       and minor: "~P ==> R" "Q ==> R"
   637   shows "R"
   638 apply (rule excluded_middle [of P, THEN disjE])
   639 apply (iprover intro: minor major [THEN mp])+
   640 done
   641 
   642 (*This version of --> elimination works on Q before P.  It works best for
   643   those cases in which P holds "almost everywhere".  Can't install as
   644   default: would break old proofs.*)
   645 lemma impCE':
   646   assumes major: "P-->Q"
   647       and minor: "Q ==> R" "~P ==> R"
   648   shows "R"
   649 apply (rule excluded_middle [of P, THEN disjE])
   650 apply (iprover intro: minor major [THEN mp])+
   651 done
   652 
   653 (*Classical <-> elimination. *)
   654 lemma iffCE:
   655   assumes major: "P=Q"
   656       and minor: "[| P; Q |] ==> R"  "[| ~P; ~Q |] ==> R"
   657   shows "R"
   658 apply (rule major [THEN iffE])
   659 apply (iprover intro: minor elim: impCE notE)
   660 done
   661 
   662 lemma exCI:
   663   assumes "ALL x. ~P(x) ==> P(a)"
   664   shows "EX x. P(x)"
   665 apply (rule ccontr)
   666 apply (iprover intro: assms exI allI notI notE [of "\<exists>x. P x"])
   667 done
   668 
   669 
   670 subsubsection {* Intuitionistic Reasoning *}
   671 
   672 lemma impE':
   673   assumes 1: "P --> Q"
   674     and 2: "Q ==> R"
   675     and 3: "P --> Q ==> P"
   676   shows R
   677 proof -
   678   from 3 and 1 have P .
   679   with 1 have Q by (rule impE)
   680   with 2 show R .
   681 qed
   682 
   683 lemma allE':
   684   assumes 1: "ALL x. P x"
   685     and 2: "P x ==> ALL x. P x ==> Q"
   686   shows Q
   687 proof -
   688   from 1 have "P x" by (rule spec)
   689   from this and 1 show Q by (rule 2)
   690 qed
   691 
   692 lemma notE':
   693   assumes 1: "~ P"
   694     and 2: "~ P ==> P"
   695   shows R
   696 proof -
   697   from 2 and 1 have P .
   698   with 1 show R by (rule notE)
   699 qed
   700 
   701 lemma TrueE: "True ==> P ==> P" .
   702 lemma notFalseE: "~ False ==> P ==> P" .
   703 
   704 lemmas [Pure.elim!] = disjE iffE FalseE conjE exE TrueE notFalseE
   705   and [Pure.intro!] = iffI conjI impI TrueI notI allI refl
   706   and [Pure.elim 2] = allE notE' impE'
   707   and [Pure.intro] = exI disjI2 disjI1
   708 
   709 lemmas [trans] = trans
   710   and [sym] = sym not_sym
   711   and [Pure.elim?] = iffD1 iffD2 impE
   712 
   713 use "Tools/hologic.ML"
   714 
   715 
   716 subsubsection {* Atomizing meta-level connectives *}
   717 
   718 axiomatization where
   719   eq_reflection: "x = y \<Longrightarrow> x \<equiv> y" (*admissible axiom*)
   720 
   721 lemma atomize_all [atomize]: "(!!x. P x) == Trueprop (ALL x. P x)"
   722 proof
   723   assume "!!x. P x"
   724   then show "ALL x. P x" ..
   725 next
   726   assume "ALL x. P x"
   727   then show "!!x. P x" by (rule allE)
   728 qed
   729 
   730 lemma atomize_imp [atomize]: "(A ==> B) == Trueprop (A --> B)"
   731 proof
   732   assume r: "A ==> B"
   733   show "A --> B" by (rule impI) (rule r)
   734 next
   735   assume "A --> B" and A
   736   then show B by (rule mp)
   737 qed
   738 
   739 lemma atomize_not: "(A ==> False) == Trueprop (~A)"
   740 proof
   741   assume r: "A ==> False"
   742   show "~A" by (rule notI) (rule r)
   743 next
   744   assume "~A" and A
   745   then show False by (rule notE)
   746 qed
   747 
   748 lemma atomize_eq [atomize, code]: "(x == y) == Trueprop (x = y)"
   749 proof
   750   assume "x == y"
   751   show "x = y" by (unfold `x == y`) (rule refl)
   752 next
   753   assume "x = y"
   754   then show "x == y" by (rule eq_reflection)
   755 qed
   756 
   757 lemma atomize_conj [atomize]: "(A &&& B) == Trueprop (A & B)"
   758 proof
   759   assume conj: "A &&& B"
   760   show "A & B"
   761   proof (rule conjI)
   762     from conj show A by (rule conjunctionD1)
   763     from conj show B by (rule conjunctionD2)
   764   qed
   765 next
   766   assume conj: "A & B"
   767   show "A &&& B"
   768   proof -
   769     from conj show A ..
   770     from conj show B ..
   771   qed
   772 qed
   773 
   774 lemmas [symmetric, rulify] = atomize_all atomize_imp
   775   and [symmetric, defn] = atomize_all atomize_imp atomize_eq
   776 
   777 
   778 subsubsection {* Atomizing elimination rules *}
   779 
   780 setup AtomizeElim.setup
   781 
   782 lemma atomize_exL[atomize_elim]: "(!!x. P x ==> Q) == ((EX x. P x) ==> Q)"
   783   by rule iprover+
   784 
   785 lemma atomize_conjL[atomize_elim]: "(A ==> B ==> C) == (A & B ==> C)"
   786   by rule iprover+
   787 
   788 lemma atomize_disjL[atomize_elim]: "((A ==> C) ==> (B ==> C) ==> C) == ((A | B ==> C) ==> C)"
   789   by rule iprover+
   790 
   791 lemma atomize_elimL[atomize_elim]: "(!!B. (A ==> B) ==> B) == Trueprop A" ..
   792 
   793 
   794 subsection {* Package setup *}
   795 
   796 subsubsection {* Sledgehammer setup *}
   797 
   798 text {*
   799 Theorems blacklisted to Sledgehammer. These theorems typically produce clauses
   800 that are prolific (match too many equality or membership literals) and relate to
   801 seldom-used facts. Some duplicate other rules.
   802 *}
   803 
   804 ML {*
   805 structure No_ATPs = Named_Thms
   806 (
   807   val name = @{binding no_atp}
   808   val description = "theorems that should be filtered out by Sledgehammer"
   809 )
   810 *}
   811 
   812 setup {* No_ATPs.setup *}
   813 
   814 
   815 subsubsection {* Classical Reasoner setup *}
   816 
   817 lemma imp_elim: "P --> Q ==> (~ R ==> P) ==> (Q ==> R) ==> R"
   818   by (rule classical) iprover
   819 
   820 lemma swap: "~ P ==> (~ R ==> P) ==> R"
   821   by (rule classical) iprover
   822 
   823 lemma thin_refl:
   824   "\<And>X. \<lbrakk> x=x; PROP W \<rbrakk> \<Longrightarrow> PROP W" .
   825 
   826 ML {*
   827 structure Hypsubst = Hypsubst
   828 (
   829   val dest_eq = HOLogic.dest_eq
   830   val dest_Trueprop = HOLogic.dest_Trueprop
   831   val dest_imp = HOLogic.dest_imp
   832   val eq_reflection = @{thm eq_reflection}
   833   val rev_eq_reflection = @{thm meta_eq_to_obj_eq}
   834   val imp_intr = @{thm impI}
   835   val rev_mp = @{thm rev_mp}
   836   val subst = @{thm subst}
   837   val sym = @{thm sym}
   838   val thin_refl = @{thm thin_refl};
   839 );
   840 open Hypsubst;
   841 
   842 structure Classical = Classical
   843 (
   844   val imp_elim = @{thm imp_elim}
   845   val not_elim = @{thm notE}
   846   val swap = @{thm swap}
   847   val classical = @{thm classical}
   848   val sizef = Drule.size_of_thm
   849   val hyp_subst_tacs = [Hypsubst.hyp_subst_tac]
   850 );
   851 
   852 structure Basic_Classical: BASIC_CLASSICAL = Classical; 
   853 open Basic_Classical;
   854 *}
   855 
   856 setup {*
   857   ML_Antiquote.value @{binding claset}
   858     (Scan.succeed "Classical.claset_of (ML_Context.the_local_context ())")
   859 *}
   860 
   861 setup Classical.setup
   862 
   863 setup {*
   864 let
   865   fun non_bool_eq (@{const_name HOL.eq}, Type (_, [T, _])) = T <> @{typ bool}
   866     | non_bool_eq _ = false;
   867   val hyp_subst_tac' =
   868     SUBGOAL (fn (goal, i) =>
   869       if Term.exists_Const non_bool_eq goal
   870       then Hypsubst.hyp_subst_tac i
   871       else no_tac);
   872 in
   873   Hypsubst.hypsubst_setup
   874   (*prevent substitution on bool*)
   875   #> Context_Rules.addSWrapper (fn tac => hyp_subst_tac' ORELSE' tac)
   876 end
   877 *}
   878 
   879 declare iffI [intro!]
   880   and notI [intro!]
   881   and impI [intro!]
   882   and disjCI [intro!]
   883   and conjI [intro!]
   884   and TrueI [intro!]
   885   and refl [intro!]
   886 
   887 declare iffCE [elim!]
   888   and FalseE [elim!]
   889   and impCE [elim!]
   890   and disjE [elim!]
   891   and conjE [elim!]
   892 
   893 declare ex_ex1I [intro!]
   894   and allI [intro!]
   895   and the_equality [intro]
   896   and exI [intro]
   897 
   898 declare exE [elim!]
   899   allE [elim]
   900 
   901 ML {* val HOL_cs = @{claset} *}
   902 
   903 lemma contrapos_np: "~ Q ==> (~ P ==> Q) ==> P"
   904   apply (erule swap)
   905   apply (erule (1) meta_mp)
   906   done
   907 
   908 declare ex_ex1I [rule del, intro! 2]
   909   and ex1I [intro]
   910 
   911 declare ext [intro]
   912 
   913 lemmas [intro?] = ext
   914   and [elim?] = ex1_implies_ex
   915 
   916 (*Better then ex1E for classical reasoner: needs no quantifier duplication!*)
   917 lemma alt_ex1E [elim!]:
   918   assumes major: "\<exists>!x. P x"
   919       and prem: "\<And>x. \<lbrakk> P x; \<forall>y y'. P y \<and> P y' \<longrightarrow> y = y' \<rbrakk> \<Longrightarrow> R"
   920   shows R
   921 apply (rule ex1E [OF major])
   922 apply (rule prem)
   923 apply (tactic {* ares_tac @{thms allI} 1 *})+
   924 apply (tactic {* etac (Classical.dup_elim @{thm allE}) 1 *})
   925 apply iprover
   926 done
   927 
   928 ML {*
   929   structure Blast = Blast
   930   (
   931     structure Classical = Classical
   932     val Trueprop_const = dest_Const @{const Trueprop}
   933     val equality_name = @{const_name HOL.eq}
   934     val not_name = @{const_name Not}
   935     val notE = @{thm notE}
   936     val ccontr = @{thm ccontr}
   937     val hyp_subst_tac = Hypsubst.blast_hyp_subst_tac
   938   );
   939   val blast_tac = Blast.blast_tac;
   940 *}
   941 
   942 setup Blast.setup
   943 
   944 
   945 subsubsection {* Simplifier *}
   946 
   947 lemma eta_contract_eq: "(%s. f s) = f" ..
   948 
   949 lemma simp_thms:
   950   shows not_not: "(~ ~ P) = P"
   951   and Not_eq_iff: "((~P) = (~Q)) = (P = Q)"
   952   and
   953     "(P ~= Q) = (P = (~Q))"
   954     "(P | ~P) = True"    "(~P | P) = True"
   955     "(x = x) = True"
   956   and not_True_eq_False [code]: "(\<not> True) = False"
   957   and not_False_eq_True [code]: "(\<not> False) = True"
   958   and
   959     "(~P) ~= P"  "P ~= (~P)"
   960     "(True=P) = P"
   961   and eq_True: "(P = True) = P"
   962   and "(False=P) = (~P)"
   963   and eq_False: "(P = False) = (\<not> P)"
   964   and
   965     "(True --> P) = P"  "(False --> P) = True"
   966     "(P --> True) = True"  "(P --> P) = True"
   967     "(P --> False) = (~P)"  "(P --> ~P) = (~P)"
   968     "(P & True) = P"  "(True & P) = P"
   969     "(P & False) = False"  "(False & P) = False"
   970     "(P & P) = P"  "(P & (P & Q)) = (P & Q)"
   971     "(P & ~P) = False"    "(~P & P) = False"
   972     "(P | True) = True"  "(True | P) = True"
   973     "(P | False) = P"  "(False | P) = P"
   974     "(P | P) = P"  "(P | (P | Q)) = (P | Q)" and
   975     "(ALL x. P) = P"  "(EX x. P) = P"  "EX x. x=t"  "EX x. t=x"
   976   and
   977     "!!P. (EX x. x=t & P(x)) = P(t)"
   978     "!!P. (EX x. t=x & P(x)) = P(t)"
   979     "!!P. (ALL x. x=t --> P(x)) = P(t)"
   980     "!!P. (ALL x. t=x --> P(x)) = P(t)"
   981   by (blast, blast, blast, blast, blast, iprover+)
   982 
   983 lemma disj_absorb: "(A | A) = A"
   984   by blast
   985 
   986 lemma disj_left_absorb: "(A | (A | B)) = (A | B)"
   987   by blast
   988 
   989 lemma conj_absorb: "(A & A) = A"
   990   by blast
   991 
   992 lemma conj_left_absorb: "(A & (A & B)) = (A & B)"
   993   by blast
   994 
   995 lemma eq_ac:
   996   shows eq_commute: "(a=b) = (b=a)"
   997     and eq_left_commute: "(P=(Q=R)) = (Q=(P=R))"
   998     and eq_assoc: "((P=Q)=R) = (P=(Q=R))" by (iprover, blast+)
   999 lemma neq_commute: "(a~=b) = (b~=a)" by iprover
  1000 
  1001 lemma conj_comms:
  1002   shows conj_commute: "(P&Q) = (Q&P)"
  1003     and conj_left_commute: "(P&(Q&R)) = (Q&(P&R))" by iprover+
  1004 lemma conj_assoc: "((P&Q)&R) = (P&(Q&R))" by iprover
  1005 
  1006 lemmas conj_ac = conj_commute conj_left_commute conj_assoc
  1007 
  1008 lemma disj_comms:
  1009   shows disj_commute: "(P|Q) = (Q|P)"
  1010     and disj_left_commute: "(P|(Q|R)) = (Q|(P|R))" by iprover+
  1011 lemma disj_assoc: "((P|Q)|R) = (P|(Q|R))" by iprover
  1012 
  1013 lemmas disj_ac = disj_commute disj_left_commute disj_assoc
  1014 
  1015 lemma conj_disj_distribL: "(P&(Q|R)) = (P&Q | P&R)" by iprover
  1016 lemma conj_disj_distribR: "((P|Q)&R) = (P&R | Q&R)" by iprover
  1017 
  1018 lemma disj_conj_distribL: "(P|(Q&R)) = ((P|Q) & (P|R))" by iprover
  1019 lemma disj_conj_distribR: "((P&Q)|R) = ((P|R) & (Q|R))" by iprover
  1020 
  1021 lemma imp_conjR: "(P --> (Q&R)) = ((P-->Q) & (P-->R))" by iprover
  1022 lemma imp_conjL: "((P&Q) -->R)  = (P --> (Q --> R))" by iprover
  1023 lemma imp_disjL: "((P|Q) --> R) = ((P-->R)&(Q-->R))" by iprover
  1024 
  1025 text {* These two are specialized, but @{text imp_disj_not1} is useful in @{text "Auth/Yahalom"}. *}
  1026 lemma imp_disj_not1: "(P --> Q | R) = (~Q --> P --> R)" by blast
  1027 lemma imp_disj_not2: "(P --> Q | R) = (~R --> P --> Q)" by blast
  1028 
  1029 lemma imp_disj1: "((P-->Q)|R) = (P--> Q|R)" by blast
  1030 lemma imp_disj2: "(Q|(P-->R)) = (P--> Q|R)" by blast
  1031 
  1032 lemma imp_cong: "(P = P') ==> (P' ==> (Q = Q')) ==> ((P --> Q) = (P' --> Q'))"
  1033   by iprover
  1034 
  1035 lemma de_Morgan_disj: "(~(P | Q)) = (~P & ~Q)" by iprover
  1036 lemma de_Morgan_conj: "(~(P & Q)) = (~P | ~Q)" by blast
  1037 lemma not_imp: "(~(P --> Q)) = (P & ~Q)" by blast
  1038 lemma not_iff: "(P~=Q) = (P = (~Q))" by blast
  1039 lemma disj_not1: "(~P | Q) = (P --> Q)" by blast
  1040 lemma disj_not2: "(P | ~Q) = (Q --> P)"  -- {* changes orientation :-( *}
  1041   by blast
  1042 lemma imp_conv_disj: "(P --> Q) = ((~P) | Q)" by blast
  1043 
  1044 lemma iff_conv_conj_imp: "(P = Q) = ((P --> Q) & (Q --> P))" by iprover
  1045 
  1046 
  1047 lemma cases_simp: "((P --> Q) & (~P --> Q)) = Q"
  1048   -- {* Avoids duplication of subgoals after @{text split_if}, when the true and false *}
  1049   -- {* cases boil down to the same thing. *}
  1050   by blast
  1051 
  1052 lemma not_all: "(~ (! x. P(x))) = (? x.~P(x))" by blast
  1053 lemma imp_all: "((! x. P x) --> Q) = (? x. P x --> Q)" by blast
  1054 lemma not_ex: "(~ (? x. P(x))) = (! x.~P(x))" by iprover
  1055 lemma imp_ex: "((? x. P x) --> Q) = (! x. P x --> Q)" by iprover
  1056 lemma all_not_ex: "(ALL x. P x) = (~ (EX x. ~ P x ))" by blast
  1057 
  1058 declare All_def [no_atp]
  1059 
  1060 lemma ex_disj_distrib: "(? x. P(x) | Q(x)) = ((? x. P(x)) | (? x. Q(x)))" by iprover
  1061 lemma all_conj_distrib: "(!x. P(x) & Q(x)) = ((! x. P(x)) & (! x. Q(x)))" by iprover
  1062 
  1063 text {*
  1064   \medskip The @{text "&"} congruence rule: not included by default!
  1065   May slow rewrite proofs down by as much as 50\% *}
  1066 
  1067 lemma conj_cong:
  1068     "(P = P') ==> (P' ==> (Q = Q')) ==> ((P & Q) = (P' & Q'))"
  1069   by iprover
  1070 
  1071 lemma rev_conj_cong:
  1072     "(Q = Q') ==> (Q' ==> (P = P')) ==> ((P & Q) = (P' & Q'))"
  1073   by iprover
  1074 
  1075 text {* The @{text "|"} congruence rule: not included by default! *}
  1076 
  1077 lemma disj_cong:
  1078     "(P = P') ==> (~P' ==> (Q = Q')) ==> ((P | Q) = (P' | Q'))"
  1079   by blast
  1080 
  1081 
  1082 text {* \medskip if-then-else rules *}
  1083 
  1084 lemma if_True [code]: "(if True then x else y) = x"
  1085   by (unfold If_def) blast
  1086 
  1087 lemma if_False [code]: "(if False then x else y) = y"
  1088   by (unfold If_def) blast
  1089 
  1090 lemma if_P: "P ==> (if P then x else y) = x"
  1091   by (unfold If_def) blast
  1092 
  1093 lemma if_not_P: "~P ==> (if P then x else y) = y"
  1094   by (unfold If_def) blast
  1095 
  1096 lemma split_if: "P (if Q then x else y) = ((Q --> P(x)) & (~Q --> P(y)))"
  1097   apply (rule case_split [of Q])
  1098    apply (simplesubst if_P)
  1099     prefer 3 apply (simplesubst if_not_P, blast+)
  1100   done
  1101 
  1102 lemma split_if_asm: "P (if Q then x else y) = (~((Q & ~P x) | (~Q & ~P y)))"
  1103 by (simplesubst split_if, blast)
  1104 
  1105 lemmas if_splits [no_atp] = split_if split_if_asm
  1106 
  1107 lemma if_cancel: "(if c then x else x) = x"
  1108 by (simplesubst split_if, blast)
  1109 
  1110 lemma if_eq_cancel: "(if x = y then y else x) = x"
  1111 by (simplesubst split_if, blast)
  1112 
  1113 lemma if_bool_eq_conj:
  1114 "(if P then Q else R) = ((P-->Q) & (~P-->R))"
  1115   -- {* This form is useful for expanding @{text "if"}s on the RIGHT of the @{text "==>"} symbol. *}
  1116   by (rule split_if)
  1117 
  1118 lemma if_bool_eq_disj: "(if P then Q else R) = ((P&Q) | (~P&R))"
  1119   -- {* And this form is useful for expanding @{text "if"}s on the LEFT. *}
  1120   apply (simplesubst split_if, blast)
  1121   done
  1122 
  1123 lemma Eq_TrueI: "P ==> P == True" by (unfold atomize_eq) iprover
  1124 lemma Eq_FalseI: "~P ==> P == False" by (unfold atomize_eq) iprover
  1125 
  1126 text {* \medskip let rules for simproc *}
  1127 
  1128 lemma Let_folded: "f x \<equiv> g x \<Longrightarrow>  Let x f \<equiv> Let x g"
  1129   by (unfold Let_def)
  1130 
  1131 lemma Let_unfold: "f x \<equiv> g \<Longrightarrow>  Let x f \<equiv> g"
  1132   by (unfold Let_def)
  1133 
  1134 text {*
  1135   The following copy of the implication operator is useful for
  1136   fine-tuning congruence rules.  It instructs the simplifier to simplify
  1137   its premise.
  1138 *}
  1139 
  1140 definition simp_implies :: "[prop, prop] => prop"  (infixr "=simp=>" 1) where
  1141   "simp_implies \<equiv> op ==>"
  1142 
  1143 lemma simp_impliesI:
  1144   assumes PQ: "(PROP P \<Longrightarrow> PROP Q)"
  1145   shows "PROP P =simp=> PROP Q"
  1146   apply (unfold simp_implies_def)
  1147   apply (rule PQ)
  1148   apply assumption
  1149   done
  1150 
  1151 lemma simp_impliesE:
  1152   assumes PQ: "PROP P =simp=> PROP Q"
  1153   and P: "PROP P"
  1154   and QR: "PROP Q \<Longrightarrow> PROP R"
  1155   shows "PROP R"
  1156   apply (rule QR)
  1157   apply (rule PQ [unfolded simp_implies_def])
  1158   apply (rule P)
  1159   done
  1160 
  1161 lemma simp_implies_cong:
  1162   assumes PP' :"PROP P == PROP P'"
  1163   and P'QQ': "PROP P' ==> (PROP Q == PROP Q')"
  1164   shows "(PROP P =simp=> PROP Q) == (PROP P' =simp=> PROP Q')"
  1165 proof (unfold simp_implies_def, rule equal_intr_rule)
  1166   assume PQ: "PROP P \<Longrightarrow> PROP Q"
  1167   and P': "PROP P'"
  1168   from PP' [symmetric] and P' have "PROP P"
  1169     by (rule equal_elim_rule1)
  1170   then have "PROP Q" by (rule PQ)
  1171   with P'QQ' [OF P'] show "PROP Q'" by (rule equal_elim_rule1)
  1172 next
  1173   assume P'Q': "PROP P' \<Longrightarrow> PROP Q'"
  1174   and P: "PROP P"
  1175   from PP' and P have P': "PROP P'" by (rule equal_elim_rule1)
  1176   then have "PROP Q'" by (rule P'Q')
  1177   with P'QQ' [OF P', symmetric] show "PROP Q"
  1178     by (rule equal_elim_rule1)
  1179 qed
  1180 
  1181 lemma uncurry:
  1182   assumes "P \<longrightarrow> Q \<longrightarrow> R"
  1183   shows "P \<and> Q \<longrightarrow> R"
  1184   using assms by blast
  1185 
  1186 lemma iff_allI:
  1187   assumes "\<And>x. P x = Q x"
  1188   shows "(\<forall>x. P x) = (\<forall>x. Q x)"
  1189   using assms by blast
  1190 
  1191 lemma iff_exI:
  1192   assumes "\<And>x. P x = Q x"
  1193   shows "(\<exists>x. P x) = (\<exists>x. Q x)"
  1194   using assms by blast
  1195 
  1196 lemma all_comm:
  1197   "(\<forall>x y. P x y) = (\<forall>y x. P x y)"
  1198   by blast
  1199 
  1200 lemma ex_comm:
  1201   "(\<exists>x y. P x y) = (\<exists>y x. P x y)"
  1202   by blast
  1203 
  1204 use "Tools/simpdata.ML"
  1205 ML {* open Simpdata *}
  1206 
  1207 setup {* Simplifier.map_simpset_global (K HOL_basic_ss) *}
  1208 
  1209 simproc_setup defined_Ex ("EX x. P x") = {* fn _ => Quantifier1.rearrange_ex *}
  1210 simproc_setup defined_All ("ALL x. P x") = {* fn _ => Quantifier1.rearrange_all *}
  1211 
  1212 setup {*
  1213   Simplifier.method_setup Splitter.split_modifiers
  1214   #> Splitter.setup
  1215   #> clasimp_setup
  1216   #> EqSubst.setup
  1217 *}
  1218 
  1219 text {* Simproc for proving @{text "(y = x) == False"} from premise @{text "~(x = y)"}: *}
  1220 
  1221 simproc_setup neq ("x = y") = {* fn _ =>
  1222 let
  1223   val neq_to_EQ_False = @{thm not_sym} RS @{thm Eq_FalseI};
  1224   fun is_neq eq lhs rhs thm =
  1225     (case Thm.prop_of thm of
  1226       _ $ (Not $ (eq' $ l' $ r')) =>
  1227         Not = HOLogic.Not andalso eq' = eq andalso
  1228         r' aconv lhs andalso l' aconv rhs
  1229     | _ => false);
  1230   fun proc ss ct =
  1231     (case Thm.term_of ct of
  1232       eq $ lhs $ rhs =>
  1233         (case find_first (is_neq eq lhs rhs) (Simplifier.prems_of ss) of
  1234           SOME thm => SOME (thm RS neq_to_EQ_False)
  1235         | NONE => NONE)
  1236      | _ => NONE);
  1237 in proc end;
  1238 *}
  1239 
  1240 simproc_setup let_simp ("Let x f") = {*
  1241 let
  1242   val (f_Let_unfold, x_Let_unfold) =
  1243     let val [(_ $ (f $ x) $ _)] = prems_of @{thm Let_unfold}
  1244     in (cterm_of @{theory} f, cterm_of @{theory} x) end
  1245   val (f_Let_folded, x_Let_folded) =
  1246     let val [(_ $ (f $ x) $ _)] = prems_of @{thm Let_folded}
  1247     in (cterm_of @{theory} f, cterm_of @{theory} x) end;
  1248   val g_Let_folded =
  1249     let val [(_ $ _ $ (g $ _))] = prems_of @{thm Let_folded}
  1250     in cterm_of @{theory} g end;
  1251   fun count_loose (Bound i) k = if i >= k then 1 else 0
  1252     | count_loose (s $ t) k = count_loose s k + count_loose t k
  1253     | count_loose (Abs (_, _, t)) k = count_loose  t (k + 1)
  1254     | count_loose _ _ = 0;
  1255   fun is_trivial_let (Const (@{const_name Let}, _) $ x $ t) =
  1256    case t
  1257     of Abs (_, _, t') => count_loose t' 0 <= 1
  1258      | _ => true;
  1259 in fn _ => fn ss => fn ct => if is_trivial_let (Thm.term_of ct)
  1260   then SOME @{thm Let_def} (*no or one ocurrence of bound variable*)
  1261   else let (*Norbert Schirmer's case*)
  1262     val ctxt = Simplifier.the_context ss;
  1263     val thy = Proof_Context.theory_of ctxt;
  1264     val t = Thm.term_of ct;
  1265     val ([t'], ctxt') = Variable.import_terms false [t] ctxt;
  1266   in Option.map (hd o Variable.export ctxt' ctxt o single)
  1267     (case t' of Const (@{const_name Let},_) $ x $ f => (* x and f are already in normal form *)
  1268       if is_Free x orelse is_Bound x orelse is_Const x
  1269       then SOME @{thm Let_def}
  1270       else
  1271         let
  1272           val n = case f of (Abs (x, _, _)) => x | _ => "x";
  1273           val cx = cterm_of thy x;
  1274           val {T = xT, ...} = rep_cterm cx;
  1275           val cf = cterm_of thy f;
  1276           val fx_g = Simplifier.rewrite ss (Thm.apply cf cx);
  1277           val (_ $ _ $ g) = prop_of fx_g;
  1278           val g' = abstract_over (x,g);
  1279         in (if (g aconv g')
  1280              then
  1281                 let
  1282                   val rl =
  1283                     cterm_instantiate [(f_Let_unfold, cf), (x_Let_unfold, cx)] @{thm Let_unfold};
  1284                 in SOME (rl OF [fx_g]) end
  1285              else if Term.betapply (f, x) aconv g then NONE (*avoid identity conversion*)
  1286              else let
  1287                    val abs_g'= Abs (n,xT,g');
  1288                    val g'x = abs_g'$x;
  1289                    val g_g'x = Thm.symmetric (Thm.beta_conversion false (cterm_of thy g'x));
  1290                    val rl = cterm_instantiate
  1291                              [(f_Let_folded, cterm_of thy f), (x_Let_folded, cx),
  1292                               (g_Let_folded, cterm_of thy abs_g')]
  1293                              @{thm Let_folded};
  1294                  in SOME (rl OF [Thm.transitive fx_g g_g'x])
  1295                  end)
  1296         end
  1297     | _ => NONE)
  1298   end
  1299 end *}
  1300 
  1301 lemma True_implies_equals: "(True \<Longrightarrow> PROP P) \<equiv> PROP P"
  1302 proof
  1303   assume "True \<Longrightarrow> PROP P"
  1304   from this [OF TrueI] show "PROP P" .
  1305 next
  1306   assume "PROP P"
  1307   then show "PROP P" .
  1308 qed
  1309 
  1310 lemma ex_simps:
  1311   "!!P Q. (EX x. P x & Q)   = ((EX x. P x) & Q)"
  1312   "!!P Q. (EX x. P & Q x)   = (P & (EX x. Q x))"
  1313   "!!P Q. (EX x. P x | Q)   = ((EX x. P x) | Q)"
  1314   "!!P Q. (EX x. P | Q x)   = (P | (EX x. Q x))"
  1315   "!!P Q. (EX x. P x --> Q) = ((ALL x. P x) --> Q)"
  1316   "!!P Q. (EX x. P --> Q x) = (P --> (EX x. Q x))"
  1317   -- {* Miniscoping: pushing in existential quantifiers. *}
  1318   by (iprover | blast)+
  1319 
  1320 lemma all_simps:
  1321   "!!P Q. (ALL x. P x & Q)   = ((ALL x. P x) & Q)"
  1322   "!!P Q. (ALL x. P & Q x)   = (P & (ALL x. Q x))"
  1323   "!!P Q. (ALL x. P x | Q)   = ((ALL x. P x) | Q)"
  1324   "!!P Q. (ALL x. P | Q x)   = (P | (ALL x. Q x))"
  1325   "!!P Q. (ALL x. P x --> Q) = ((EX x. P x) --> Q)"
  1326   "!!P Q. (ALL x. P --> Q x) = (P --> (ALL x. Q x))"
  1327   -- {* Miniscoping: pushing in universal quantifiers. *}
  1328   by (iprover | blast)+
  1329 
  1330 lemmas [simp] =
  1331   triv_forall_equality (*prunes params*)
  1332   True_implies_equals  (*prune asms `True'*)
  1333   if_True
  1334   if_False
  1335   if_cancel
  1336   if_eq_cancel
  1337   imp_disjL
  1338   (*In general it seems wrong to add distributive laws by default: they
  1339     might cause exponential blow-up.  But imp_disjL has been in for a while
  1340     and cannot be removed without affecting existing proofs.  Moreover,
  1341     rewriting by "(P|Q --> R) = ((P-->R)&(Q-->R))" might be justified on the
  1342     grounds that it allows simplification of R in the two cases.*)
  1343   conj_assoc
  1344   disj_assoc
  1345   de_Morgan_conj
  1346   de_Morgan_disj
  1347   imp_disj1
  1348   imp_disj2
  1349   not_imp
  1350   disj_not1
  1351   not_all
  1352   not_ex
  1353   cases_simp
  1354   the_eq_trivial
  1355   the_sym_eq_trivial
  1356   ex_simps
  1357   all_simps
  1358   simp_thms
  1359 
  1360 lemmas [cong] = imp_cong simp_implies_cong
  1361 lemmas [split] = split_if
  1362 
  1363 ML {* val HOL_ss = @{simpset} *}
  1364 
  1365 text {* Simplifies x assuming c and y assuming ~c *}
  1366 lemma if_cong:
  1367   assumes "b = c"
  1368       and "c \<Longrightarrow> x = u"
  1369       and "\<not> c \<Longrightarrow> y = v"
  1370   shows "(if b then x else y) = (if c then u else v)"
  1371   using assms by simp
  1372 
  1373 text {* Prevents simplification of x and y:
  1374   faster and allows the execution of functional programs. *}
  1375 lemma if_weak_cong [cong]:
  1376   assumes "b = c"
  1377   shows "(if b then x else y) = (if c then x else y)"
  1378   using assms by (rule arg_cong)
  1379 
  1380 text {* Prevents simplification of t: much faster *}
  1381 lemma let_weak_cong:
  1382   assumes "a = b"
  1383   shows "(let x = a in t x) = (let x = b in t x)"
  1384   using assms by (rule arg_cong)
  1385 
  1386 text {* To tidy up the result of a simproc.  Only the RHS will be simplified. *}
  1387 lemma eq_cong2:
  1388   assumes "u = u'"
  1389   shows "(t \<equiv> u) \<equiv> (t \<equiv> u')"
  1390   using assms by simp
  1391 
  1392 lemma if_distrib:
  1393   "f (if c then x else y) = (if c then f x else f y)"
  1394   by simp
  1395 
  1396 text{*As a simplification rule, it replaces all function equalities by
  1397   first-order equalities.*}
  1398 lemma fun_eq_iff: "f = g \<longleftrightarrow> (\<forall>x. f x = g x)"
  1399   by auto
  1400 
  1401 
  1402 subsubsection {* Generic cases and induction *}
  1403 
  1404 text {* Rule projections: *}
  1405 
  1406 ML {*
  1407 structure Project_Rule = Project_Rule
  1408 (
  1409   val conjunct1 = @{thm conjunct1}
  1410   val conjunct2 = @{thm conjunct2}
  1411   val mp = @{thm mp}
  1412 )
  1413 *}
  1414 
  1415 definition induct_forall where
  1416   "induct_forall P == \<forall>x. P x"
  1417 
  1418 definition induct_implies where
  1419   "induct_implies A B == A \<longrightarrow> B"
  1420 
  1421 definition induct_equal where
  1422   "induct_equal x y == x = y"
  1423 
  1424 definition induct_conj where
  1425   "induct_conj A B == A \<and> B"
  1426 
  1427 definition induct_true where
  1428   "induct_true == True"
  1429 
  1430 definition induct_false where
  1431   "induct_false == False"
  1432 
  1433 lemma induct_forall_eq: "(!!x. P x) == Trueprop (induct_forall (\<lambda>x. P x))"
  1434   by (unfold atomize_all induct_forall_def)
  1435 
  1436 lemma induct_implies_eq: "(A ==> B) == Trueprop (induct_implies A B)"
  1437   by (unfold atomize_imp induct_implies_def)
  1438 
  1439 lemma induct_equal_eq: "(x == y) == Trueprop (induct_equal x y)"
  1440   by (unfold atomize_eq induct_equal_def)
  1441 
  1442 lemma induct_conj_eq: "(A &&& B) == Trueprop (induct_conj A B)"
  1443   by (unfold atomize_conj induct_conj_def)
  1444 
  1445 lemmas induct_atomize' = induct_forall_eq induct_implies_eq induct_conj_eq
  1446 lemmas induct_atomize = induct_atomize' induct_equal_eq
  1447 lemmas induct_rulify' [symmetric] = induct_atomize'
  1448 lemmas induct_rulify [symmetric] = induct_atomize
  1449 lemmas induct_rulify_fallback =
  1450   induct_forall_def induct_implies_def induct_equal_def induct_conj_def
  1451   induct_true_def induct_false_def
  1452 
  1453 
  1454 lemma induct_forall_conj: "induct_forall (\<lambda>x. induct_conj (A x) (B x)) =
  1455     induct_conj (induct_forall A) (induct_forall B)"
  1456   by (unfold induct_forall_def induct_conj_def) iprover
  1457 
  1458 lemma induct_implies_conj: "induct_implies C (induct_conj A B) =
  1459     induct_conj (induct_implies C A) (induct_implies C B)"
  1460   by (unfold induct_implies_def induct_conj_def) iprover
  1461 
  1462 lemma induct_conj_curry: "(induct_conj A B ==> PROP C) == (A ==> B ==> PROP C)"
  1463 proof
  1464   assume r: "induct_conj A B ==> PROP C" and A B
  1465   show "PROP C" by (rule r) (simp add: induct_conj_def `A` `B`)
  1466 next
  1467   assume r: "A ==> B ==> PROP C" and "induct_conj A B"
  1468   show "PROP C" by (rule r) (simp_all add: `induct_conj A B` [unfolded induct_conj_def])
  1469 qed
  1470 
  1471 lemmas induct_conj = induct_forall_conj induct_implies_conj induct_conj_curry
  1472 
  1473 lemma induct_trueI: "induct_true"
  1474   by (simp add: induct_true_def)
  1475 
  1476 text {* Method setup. *}
  1477 
  1478 ML {*
  1479 structure Induct = Induct
  1480 (
  1481   val cases_default = @{thm case_split}
  1482   val atomize = @{thms induct_atomize}
  1483   val rulify = @{thms induct_rulify'}
  1484   val rulify_fallback = @{thms induct_rulify_fallback}
  1485   val equal_def = @{thm induct_equal_def}
  1486   fun dest_def (Const (@{const_name induct_equal}, _) $ t $ u) = SOME (t, u)
  1487     | dest_def _ = NONE
  1488   val trivial_tac = match_tac @{thms induct_trueI}
  1489 )
  1490 *}
  1491 
  1492 use "~~/src/Tools/induction.ML"
  1493 
  1494 setup {*
  1495   Induct.setup #> Induction.setup #>
  1496   Context.theory_map (Induct.map_simpset (fn ss => ss
  1497     addsimprocs
  1498       [Simplifier.simproc_global @{theory} "swap_induct_false"
  1499          ["induct_false ==> PROP P ==> PROP Q"]
  1500          (fn _ => fn _ =>
  1501             (fn _ $ (P as _ $ @{const induct_false}) $ (_ $ Q $ _) =>
  1502                   if P <> Q then SOME Drule.swap_prems_eq else NONE
  1503               | _ => NONE)),
  1504        Simplifier.simproc_global @{theory} "induct_equal_conj_curry"
  1505          ["induct_conj P Q ==> PROP R"]
  1506          (fn _ => fn _ =>
  1507             (fn _ $ (_ $ P) $ _ =>
  1508                 let
  1509                   fun is_conj (@{const induct_conj} $ P $ Q) =
  1510                         is_conj P andalso is_conj Q
  1511                     | is_conj (Const (@{const_name induct_equal}, _) $ _ $ _) = true
  1512                     | is_conj @{const induct_true} = true
  1513                     | is_conj @{const induct_false} = true
  1514                     | is_conj _ = false
  1515                 in if is_conj P then SOME @{thm induct_conj_curry} else NONE end
  1516               | _ => NONE))]
  1517     |> Simplifier.set_mksimps (fn ss => Simpdata.mksimps Simpdata.mksimps_pairs ss #>
  1518       map (Simplifier.rewrite_rule (map Thm.symmetric
  1519         @{thms induct_rulify_fallback})))))
  1520 *}
  1521 
  1522 text {* Pre-simplification of induction and cases rules *}
  1523 
  1524 lemma [induct_simp]: "(!!x. induct_equal x t ==> PROP P x) == PROP P t"
  1525   unfolding induct_equal_def
  1526 proof
  1527   assume R: "!!x. x = t ==> PROP P x"
  1528   show "PROP P t" by (rule R [OF refl])
  1529 next
  1530   fix x assume "PROP P t" "x = t"
  1531   then show "PROP P x" by simp
  1532 qed
  1533 
  1534 lemma [induct_simp]: "(!!x. induct_equal t x ==> PROP P x) == PROP P t"
  1535   unfolding induct_equal_def
  1536 proof
  1537   assume R: "!!x. t = x ==> PROP P x"
  1538   show "PROP P t" by (rule R [OF refl])
  1539 next
  1540   fix x assume "PROP P t" "t = x"
  1541   then show "PROP P x" by simp
  1542 qed
  1543 
  1544 lemma [induct_simp]: "(induct_false ==> P) == Trueprop induct_true"
  1545   unfolding induct_false_def induct_true_def
  1546   by (iprover intro: equal_intr_rule)
  1547 
  1548 lemma [induct_simp]: "(induct_true ==> PROP P) == PROP P"
  1549   unfolding induct_true_def
  1550 proof
  1551   assume R: "True \<Longrightarrow> PROP P"
  1552   from TrueI show "PROP P" by (rule R)
  1553 next
  1554   assume "PROP P"
  1555   then show "PROP P" .
  1556 qed
  1557 
  1558 lemma [induct_simp]: "(PROP P ==> induct_true) == Trueprop induct_true"
  1559   unfolding induct_true_def
  1560   by (iprover intro: equal_intr_rule)
  1561 
  1562 lemma [induct_simp]: "(!!x. induct_true) == Trueprop induct_true"
  1563   unfolding induct_true_def
  1564   by (iprover intro: equal_intr_rule)
  1565 
  1566 lemma [induct_simp]: "induct_implies induct_true P == P"
  1567   by (simp add: induct_implies_def induct_true_def)
  1568 
  1569 lemma [induct_simp]: "(x = x) = True" 
  1570   by (rule simp_thms)
  1571 
  1572 hide_const induct_forall induct_implies induct_equal induct_conj induct_true induct_false
  1573 
  1574 use "~~/src/Tools/induct_tacs.ML"
  1575 setup Induct_Tacs.setup
  1576 
  1577 
  1578 subsubsection {* Coherent logic *}
  1579 
  1580 ML {*
  1581 structure Coherent = Coherent
  1582 (
  1583   val atomize_elimL = @{thm atomize_elimL}
  1584   val atomize_exL = @{thm atomize_exL}
  1585   val atomize_conjL = @{thm atomize_conjL}
  1586   val atomize_disjL = @{thm atomize_disjL}
  1587   val operator_names =
  1588     [@{const_name HOL.disj}, @{const_name HOL.conj}, @{const_name Ex}]
  1589 );
  1590 *}
  1591 
  1592 setup Coherent.setup
  1593 
  1594 
  1595 subsubsection {* Reorienting equalities *}
  1596 
  1597 ML {*
  1598 signature REORIENT_PROC =
  1599 sig
  1600   val add : (term -> bool) -> theory -> theory
  1601   val proc : morphism -> simpset -> cterm -> thm option
  1602 end;
  1603 
  1604 structure Reorient_Proc : REORIENT_PROC =
  1605 struct
  1606   structure Data = Theory_Data
  1607   (
  1608     type T = ((term -> bool) * stamp) list;
  1609     val empty = [];
  1610     val extend = I;
  1611     fun merge data : T = Library.merge (eq_snd op =) data;
  1612   );
  1613   fun add m = Data.map (cons (m, stamp ()));
  1614   fun matches thy t = exists (fn (m, _) => m t) (Data.get thy);
  1615 
  1616   val meta_reorient = @{thm eq_commute [THEN eq_reflection]};
  1617   fun proc phi ss ct =
  1618     let
  1619       val ctxt = Simplifier.the_context ss;
  1620       val thy = Proof_Context.theory_of ctxt;
  1621     in
  1622       case Thm.term_of ct of
  1623         (_ $ t $ u) => if matches thy u then NONE else SOME meta_reorient
  1624       | _ => NONE
  1625     end;
  1626 end;
  1627 *}
  1628 
  1629 
  1630 subsection {* Other simple lemmas and lemma duplicates *}
  1631 
  1632 lemma ex1_eq [iff]: "EX! x. x = t" "EX! x. t = x"
  1633   by blast+
  1634 
  1635 lemma choice_eq: "(ALL x. EX! y. P x y) = (EX! f. ALL x. P x (f x))"
  1636   apply (rule iffI)
  1637   apply (rule_tac a = "%x. THE y. P x y" in ex1I)
  1638   apply (fast dest!: theI')
  1639   apply (fast intro: the1_equality [symmetric])
  1640   apply (erule ex1E)
  1641   apply (rule allI)
  1642   apply (rule ex1I)
  1643   apply (erule spec)
  1644   apply (erule_tac x = "%z. if z = x then y else f z" in allE)
  1645   apply (erule impE)
  1646   apply (rule allI)
  1647   apply (case_tac "xa = x")
  1648   apply (drule_tac [3] x = x in fun_cong, simp_all)
  1649   done
  1650 
  1651 lemmas eq_sym_conv = eq_commute
  1652 
  1653 lemma nnf_simps:
  1654   "(\<not>(P \<and> Q)) = (\<not> P \<or> \<not> Q)" "(\<not> (P \<or> Q)) = (\<not> P \<and> \<not>Q)" "(P \<longrightarrow> Q) = (\<not>P \<or> Q)" 
  1655   "(P = Q) = ((P \<and> Q) \<or> (\<not>P \<and> \<not> Q))" "(\<not>(P = Q)) = ((P \<and> \<not> Q) \<or> (\<not>P \<and> Q))" 
  1656   "(\<not> \<not>(P)) = P"
  1657 by blast+
  1658 
  1659 subsection {* Basic ML bindings *}
  1660 
  1661 ML {*
  1662 val FalseE = @{thm FalseE}
  1663 val Let_def = @{thm Let_def}
  1664 val TrueI = @{thm TrueI}
  1665 val allE = @{thm allE}
  1666 val allI = @{thm allI}
  1667 val all_dupE = @{thm all_dupE}
  1668 val arg_cong = @{thm arg_cong}
  1669 val box_equals = @{thm box_equals}
  1670 val ccontr = @{thm ccontr}
  1671 val classical = @{thm classical}
  1672 val conjE = @{thm conjE}
  1673 val conjI = @{thm conjI}
  1674 val conjunct1 = @{thm conjunct1}
  1675 val conjunct2 = @{thm conjunct2}
  1676 val disjCI = @{thm disjCI}
  1677 val disjE = @{thm disjE}
  1678 val disjI1 = @{thm disjI1}
  1679 val disjI2 = @{thm disjI2}
  1680 val eq_reflection = @{thm eq_reflection}
  1681 val ex1E = @{thm ex1E}
  1682 val ex1I = @{thm ex1I}
  1683 val ex1_implies_ex = @{thm ex1_implies_ex}
  1684 val exE = @{thm exE}
  1685 val exI = @{thm exI}
  1686 val excluded_middle = @{thm excluded_middle}
  1687 val ext = @{thm ext}
  1688 val fun_cong = @{thm fun_cong}
  1689 val iffD1 = @{thm iffD1}
  1690 val iffD2 = @{thm iffD2}
  1691 val iffI = @{thm iffI}
  1692 val impE = @{thm impE}
  1693 val impI = @{thm impI}
  1694 val meta_eq_to_obj_eq = @{thm meta_eq_to_obj_eq}
  1695 val mp = @{thm mp}
  1696 val notE = @{thm notE}
  1697 val notI = @{thm notI}
  1698 val not_all = @{thm not_all}
  1699 val not_ex = @{thm not_ex}
  1700 val not_iff = @{thm not_iff}
  1701 val not_not = @{thm not_not}
  1702 val not_sym = @{thm not_sym}
  1703 val refl = @{thm refl}
  1704 val rev_mp = @{thm rev_mp}
  1705 val spec = @{thm spec}
  1706 val ssubst = @{thm ssubst}
  1707 val subst = @{thm subst}
  1708 val sym = @{thm sym}
  1709 val trans = @{thm trans}
  1710 *}
  1711 
  1712 use "Tools/cnf_funcs.ML"
  1713 
  1714 subsection {* Code generator setup *}
  1715 
  1716 subsubsection {* Generic code generator preprocessor setup *}
  1717 
  1718 setup {*
  1719   Code_Preproc.map_pre (K HOL_basic_ss)
  1720   #> Code_Preproc.map_post (K HOL_basic_ss)
  1721   #> Code_Simp.map_ss (K HOL_basic_ss)
  1722 *}
  1723 
  1724 subsubsection {* Equality *}
  1725 
  1726 class equal =
  1727   fixes equal :: "'a \<Rightarrow> 'a \<Rightarrow> bool"
  1728   assumes equal_eq: "equal x y \<longleftrightarrow> x = y"
  1729 begin
  1730 
  1731 lemma equal: "equal = (op =)"
  1732   by (rule ext equal_eq)+
  1733 
  1734 lemma equal_refl: "equal x x \<longleftrightarrow> True"
  1735   unfolding equal by rule+
  1736 
  1737 lemma eq_equal: "(op =) \<equiv> equal"
  1738   by (rule eq_reflection) (rule ext, rule ext, rule sym, rule equal_eq)
  1739 
  1740 end
  1741 
  1742 declare eq_equal [symmetric, code_post]
  1743 declare eq_equal [code]
  1744 
  1745 setup {*
  1746   Code_Preproc.map_pre (fn simpset =>
  1747     simpset addsimprocs [Simplifier.simproc_global_i @{theory} "equal" [@{term HOL.eq}]
  1748       (fn thy => fn _ =>
  1749         fn Const (_, Type ("fun", [Type _, _])) => SOME @{thm eq_equal} | _ => NONE)])
  1750 *}
  1751 
  1752 
  1753 subsubsection {* Generic code generator foundation *}
  1754 
  1755 text {* Datatype @{typ bool} *}
  1756 
  1757 code_datatype True False
  1758 
  1759 lemma [code]:
  1760   shows "False \<and> P \<longleftrightarrow> False"
  1761     and "True \<and> P \<longleftrightarrow> P"
  1762     and "P \<and> False \<longleftrightarrow> False"
  1763     and "P \<and> True \<longleftrightarrow> P" by simp_all
  1764 
  1765 lemma [code]:
  1766   shows "False \<or> P \<longleftrightarrow> P"
  1767     and "True \<or> P \<longleftrightarrow> True"
  1768     and "P \<or> False \<longleftrightarrow> P"
  1769     and "P \<or> True \<longleftrightarrow> True" by simp_all
  1770 
  1771 lemma [code]:
  1772   shows "(False \<longrightarrow> P) \<longleftrightarrow> True"
  1773     and "(True \<longrightarrow> P) \<longleftrightarrow> P"
  1774     and "(P \<longrightarrow> False) \<longleftrightarrow> \<not> P"
  1775     and "(P \<longrightarrow> True) \<longleftrightarrow> True" by simp_all
  1776 
  1777 text {* More about @{typ prop} *}
  1778 
  1779 lemma [code nbe]:
  1780   shows "(True \<Longrightarrow> PROP Q) \<equiv> PROP Q" 
  1781     and "(PROP Q \<Longrightarrow> True) \<equiv> Trueprop True"
  1782     and "(P \<Longrightarrow> R) \<equiv> Trueprop (P \<longrightarrow> R)" by (auto intro!: equal_intr_rule)
  1783 
  1784 lemma Trueprop_code [code]:
  1785   "Trueprop True \<equiv> Code_Generator.holds"
  1786   by (auto intro!: equal_intr_rule holds)
  1787 
  1788 declare Trueprop_code [symmetric, code_post]
  1789 
  1790 text {* Equality *}
  1791 
  1792 declare simp_thms(6) [code nbe]
  1793 
  1794 instantiation itself :: (type) equal
  1795 begin
  1796 
  1797 definition equal_itself :: "'a itself \<Rightarrow> 'a itself \<Rightarrow> bool" where
  1798   "equal_itself x y \<longleftrightarrow> x = y"
  1799 
  1800 instance proof
  1801 qed (fact equal_itself_def)
  1802 
  1803 end
  1804 
  1805 lemma equal_itself_code [code]:
  1806   "equal TYPE('a) TYPE('a) \<longleftrightarrow> True"
  1807   by (simp add: equal)
  1808 
  1809 setup {*
  1810   Sign.add_const_constraint (@{const_name equal}, SOME @{typ "'a\<Colon>type \<Rightarrow> 'a \<Rightarrow> bool"})
  1811 *}
  1812 
  1813 lemma equal_alias_cert: "OFCLASS('a, equal_class) \<equiv> ((op = :: 'a \<Rightarrow> 'a \<Rightarrow> bool) \<equiv> equal)" (is "?ofclass \<equiv> ?equal")
  1814 proof
  1815   assume "PROP ?ofclass"
  1816   show "PROP ?equal"
  1817     by (tactic {* ALLGOALS (rtac (Thm.unconstrainT @{thm eq_equal})) *})
  1818       (fact `PROP ?ofclass`)
  1819 next
  1820   assume "PROP ?equal"
  1821   show "PROP ?ofclass" proof
  1822   qed (simp add: `PROP ?equal`)
  1823 qed
  1824   
  1825 setup {*
  1826   Sign.add_const_constraint (@{const_name equal}, SOME @{typ "'a\<Colon>equal \<Rightarrow> 'a \<Rightarrow> bool"})
  1827 *}
  1828 
  1829 setup {*
  1830   Nbe.add_const_alias @{thm equal_alias_cert}
  1831 *}
  1832 
  1833 text {* Cases *}
  1834 
  1835 lemma Let_case_cert:
  1836   assumes "CASE \<equiv> (\<lambda>x. Let x f)"
  1837   shows "CASE x \<equiv> f x"
  1838   using assms by simp_all
  1839 
  1840 setup {*
  1841   Code.add_case @{thm Let_case_cert}
  1842   #> Code.add_undefined @{const_name undefined}
  1843 *}
  1844 
  1845 code_abort undefined
  1846 
  1847 
  1848 subsubsection {* Generic code generator target languages *}
  1849 
  1850 text {* type @{typ bool} *}
  1851 
  1852 code_type bool
  1853   (SML "bool")
  1854   (OCaml "bool")
  1855   (Haskell "Bool")
  1856   (Scala "Boolean")
  1857 
  1858 code_const True and False and Not and HOL.conj and HOL.disj and HOL.implies and If 
  1859   (SML "true" and "false" and "not"
  1860     and infixl 1 "andalso" and infixl 0 "orelse"
  1861     and "!(if (_)/ then (_)/ else true)"
  1862     and "!(if (_)/ then (_)/ else (_))")
  1863   (OCaml "true" and "false" and "not"
  1864     and infixl 3 "&&" and infixl 2 "||"
  1865     and "!(if (_)/ then (_)/ else true)"
  1866     and "!(if (_)/ then (_)/ else (_))")
  1867   (Haskell "True" and "False" and "not"
  1868     and infixr 3 "&&" and infixr 2 "||"
  1869     and "!(if (_)/ then (_)/ else True)"
  1870     and "!(if (_)/ then (_)/ else (_))")
  1871   (Scala "true" and "false" and "'! _"
  1872     and infixl 3 "&&" and infixl 1 "||"
  1873     and "!(if ((_))/ (_)/ else true)"
  1874     and "!(if ((_))/ (_)/ else (_))")
  1875 
  1876 code_reserved SML
  1877   bool true false not
  1878 
  1879 code_reserved OCaml
  1880   bool not
  1881 
  1882 code_reserved Scala
  1883   Boolean
  1884 
  1885 code_modulename SML Pure HOL
  1886 code_modulename OCaml Pure HOL
  1887 code_modulename Haskell Pure HOL
  1888 
  1889 text {* using built-in Haskell equality *}
  1890 
  1891 code_class equal
  1892   (Haskell "Eq")
  1893 
  1894 code_const "HOL.equal"
  1895   (Haskell infix 4 "==")
  1896 
  1897 code_const HOL.eq
  1898   (Haskell infix 4 "==")
  1899 
  1900 text {* undefined *}
  1901 
  1902 code_const undefined
  1903   (SML "!(raise/ Fail/ \"undefined\")")
  1904   (OCaml "failwith/ \"undefined\"")
  1905   (Haskell "error/ \"undefined\"")
  1906   (Scala "!error(\"undefined\")")
  1907 
  1908 subsubsection {* Evaluation and normalization by evaluation *}
  1909 
  1910 ML {*
  1911 fun eval_tac ctxt =
  1912   let val conv = Code_Runtime.dynamic_holds_conv (Proof_Context.theory_of ctxt)
  1913   in CONVERSION (Conv.params_conv ~1 (K (Conv.concl_conv ~1 conv)) ctxt) THEN' rtac TrueI end
  1914 *}
  1915 
  1916 method_setup eval = {* Scan.succeed (SIMPLE_METHOD' o eval_tac) *}
  1917   "solve goal by evaluation"
  1918 
  1919 method_setup normalization = {*
  1920   Scan.succeed (fn ctxt =>
  1921     SIMPLE_METHOD'
  1922       (CHANGED_PROP o
  1923         (CONVERSION (Nbe.dynamic_conv (Proof_Context.theory_of ctxt))
  1924           THEN_ALL_NEW (TRY o rtac TrueI))))
  1925 *} "solve goal by normalization"
  1926 
  1927 
  1928 subsection {* Counterexample Search Units *}
  1929 
  1930 subsubsection {* Quickcheck *}
  1931 
  1932 quickcheck_params [size = 5, iterations = 50]
  1933 
  1934 
  1935 subsubsection {* Nitpick setup *}
  1936 
  1937 ML {*
  1938 structure Nitpick_Unfolds = Named_Thms
  1939 (
  1940   val name = @{binding nitpick_unfold}
  1941   val description = "alternative definitions of constants as needed by Nitpick"
  1942 )
  1943 structure Nitpick_Simps = Named_Thms
  1944 (
  1945   val name = @{binding nitpick_simp}
  1946   val description = "equational specification of constants as needed by Nitpick"
  1947 )
  1948 structure Nitpick_Psimps = Named_Thms
  1949 (
  1950   val name = @{binding nitpick_psimp}
  1951   val description = "partial equational specification of constants as needed by Nitpick"
  1952 )
  1953 structure Nitpick_Choice_Specs = Named_Thms
  1954 (
  1955   val name = @{binding nitpick_choice_spec}
  1956   val description = "choice specification of constants as needed by Nitpick"
  1957 )
  1958 *}
  1959 
  1960 setup {*
  1961   Nitpick_Unfolds.setup
  1962   #> Nitpick_Simps.setup
  1963   #> Nitpick_Psimps.setup
  1964   #> Nitpick_Choice_Specs.setup
  1965 *}
  1966 
  1967 declare if_bool_eq_conj [nitpick_unfold, no_atp]
  1968         if_bool_eq_disj [no_atp]
  1969 
  1970 
  1971 subsection {* Preprocessing for the predicate compiler *}
  1972 
  1973 ML {*
  1974 structure Predicate_Compile_Alternative_Defs = Named_Thms
  1975 (
  1976   val name = @{binding code_pred_def}
  1977   val description = "alternative definitions of constants for the Predicate Compiler"
  1978 )
  1979 structure Predicate_Compile_Inline_Defs = Named_Thms
  1980 (
  1981   val name = @{binding code_pred_inline}
  1982   val description = "inlining definitions for the Predicate Compiler"
  1983 )
  1984 structure Predicate_Compile_Simps = Named_Thms
  1985 (
  1986   val name = @{binding code_pred_simp}
  1987   val description = "simplification rules for the optimisations in the Predicate Compiler"
  1988 )
  1989 *}
  1990 
  1991 setup {*
  1992   Predicate_Compile_Alternative_Defs.setup
  1993   #> Predicate_Compile_Inline_Defs.setup
  1994   #> Predicate_Compile_Simps.setup
  1995 *}
  1996 
  1997 
  1998 subsection {* Legacy tactics and ML bindings *}
  1999 
  2000 ML {*
  2001 fun strip_tac i = REPEAT (resolve_tac [impI, allI] i);
  2002 
  2003 (* combination of (spec RS spec RS ...(j times) ... spec RS mp) *)
  2004 local
  2005   fun wrong_prem (Const (@{const_name All}, _) $ Abs (_, _, t)) = wrong_prem t
  2006     | wrong_prem (Bound _) = true
  2007     | wrong_prem _ = false;
  2008   val filter_right = filter (not o wrong_prem o HOLogic.dest_Trueprop o hd o Thm.prems_of);
  2009 in
  2010   fun smp i = funpow i (fn m => filter_right ([spec] RL m)) ([mp]);
  2011   fun smp_tac j = EVERY'[dresolve_tac (smp j), atac];
  2012 end;
  2013 
  2014 val nnf_conv = Simplifier.rewrite (HOL_basic_ss addsimps @{thms simp_thms nnf_simps});
  2015 *}
  2016 
  2017 hide_const (open) eq equal
  2018 
  2019 end
  2020