src/HOL/Hilbert_Choice.thy
author wenzelm
Thu May 24 17:25:53 2012 +0200 (2012-05-24)
changeset 47988 e4b69e10b990
parent 46950 d0181abdbdac
child 48891 c0eafbd55de3
permissions -rw-r--r--
tuned proofs;
     1 (*  Title:      HOL/Hilbert_Choice.thy
     2     Author:     Lawrence C Paulson, Tobias Nipkow
     3     Copyright   2001  University of Cambridge
     4 *)
     5 
     6 header {* Hilbert's Epsilon-Operator and the Axiom of Choice *}
     7 
     8 theory Hilbert_Choice
     9 imports Nat Wellfounded Plain
    10 keywords "specification" "ax_specification" :: thy_goal
    11 uses ("Tools/choice_specification.ML")
    12 begin
    13 
    14 subsection {* Hilbert's epsilon *}
    15 
    16 axiomatization Eps :: "('a => bool) => 'a" where
    17   someI: "P x ==> P (Eps P)"
    18 
    19 syntax (epsilon)
    20   "_Eps"        :: "[pttrn, bool] => 'a"    ("(3\<some>_./ _)" [0, 10] 10)
    21 syntax (HOL)
    22   "_Eps"        :: "[pttrn, bool] => 'a"    ("(3@ _./ _)" [0, 10] 10)
    23 syntax
    24   "_Eps"        :: "[pttrn, bool] => 'a"    ("(3SOME _./ _)" [0, 10] 10)
    25 translations
    26   "SOME x. P" == "CONST Eps (%x. P)"
    27 
    28 print_translation {*
    29   [(@{const_syntax Eps}, fn [Abs abs] =>
    30       let val (x, t) = Syntax_Trans.atomic_abs_tr' abs
    31       in Syntax.const @{syntax_const "_Eps"} $ x $ t end)]
    32 *} -- {* to avoid eta-contraction of body *}
    33 
    34 definition inv_into :: "'a set => ('a => 'b) => ('b => 'a)" where
    35 "inv_into A f == %x. SOME y. y : A & f y = x"
    36 
    37 abbreviation inv :: "('a => 'b) => ('b => 'a)" where
    38 "inv == inv_into UNIV"
    39 
    40 
    41 subsection {*Hilbert's Epsilon-operator*}
    42 
    43 text{*Easier to apply than @{text someI} if the witness comes from an
    44 existential formula*}
    45 lemma someI_ex [elim?]: "\<exists>x. P x ==> P (SOME x. P x)"
    46 apply (erule exE)
    47 apply (erule someI)
    48 done
    49 
    50 text{*Easier to apply than @{text someI} because the conclusion has only one
    51 occurrence of @{term P}.*}
    52 lemma someI2: "[| P a;  !!x. P x ==> Q x |] ==> Q (SOME x. P x)"
    53 by (blast intro: someI)
    54 
    55 text{*Easier to apply than @{text someI2} if the witness comes from an
    56 existential formula*}
    57 lemma someI2_ex: "[| \<exists>a. P a; !!x. P x ==> Q x |] ==> Q (SOME x. P x)"
    58 by (blast intro: someI2)
    59 
    60 lemma some_equality [intro]:
    61      "[| P a;  !!x. P x ==> x=a |] ==> (SOME x. P x) = a"
    62 by (blast intro: someI2)
    63 
    64 lemma some1_equality: "[| EX!x. P x; P a |] ==> (SOME x. P x) = a"
    65 by blast
    66 
    67 lemma some_eq_ex: "P (SOME x. P x) =  (\<exists>x. P x)"
    68 by (blast intro: someI)
    69 
    70 lemma some_eq_trivial [simp]: "(SOME y. y=x) = x"
    71 apply (rule some_equality)
    72 apply (rule refl, assumption)
    73 done
    74 
    75 lemma some_sym_eq_trivial [simp]: "(SOME y. x=y) = x"
    76 apply (rule some_equality)
    77 apply (rule refl)
    78 apply (erule sym)
    79 done
    80 
    81 
    82 subsection{*Axiom of Choice, Proved Using the Description Operator*}
    83 
    84 lemma choice: "\<forall>x. \<exists>y. Q x y ==> \<exists>f. \<forall>x. Q x (f x)"
    85 by (fast elim: someI)
    86 
    87 lemma bchoice: "\<forall>x\<in>S. \<exists>y. Q x y ==> \<exists>f. \<forall>x\<in>S. Q x (f x)"
    88 by (fast elim: someI)
    89 
    90 
    91 subsection {*Function Inverse*}
    92 
    93 lemma inv_def: "inv f = (%y. SOME x. f x = y)"
    94 by(simp add: inv_into_def)
    95 
    96 lemma inv_into_into: "x : f ` A ==> inv_into A f x : A"
    97 apply (simp add: inv_into_def)
    98 apply (fast intro: someI2)
    99 done
   100 
   101 lemma inv_id [simp]: "inv id = id"
   102 by (simp add: inv_into_def id_def)
   103 
   104 lemma inv_into_f_f [simp]:
   105   "[| inj_on f A;  x : A |] ==> inv_into A f (f x) = x"
   106 apply (simp add: inv_into_def inj_on_def)
   107 apply (blast intro: someI2)
   108 done
   109 
   110 lemma inv_f_f: "inj f ==> inv f (f x) = x"
   111 by simp
   112 
   113 lemma f_inv_into_f: "y : f`A  ==> f (inv_into A f y) = y"
   114 apply (simp add: inv_into_def)
   115 apply (fast intro: someI2)
   116 done
   117 
   118 lemma inv_into_f_eq: "[| inj_on f A; x : A; f x = y |] ==> inv_into A f y = x"
   119 apply (erule subst)
   120 apply (fast intro: inv_into_f_f)
   121 done
   122 
   123 lemma inv_f_eq: "[| inj f; f x = y |] ==> inv f y = x"
   124 by (simp add:inv_into_f_eq)
   125 
   126 lemma inj_imp_inv_eq: "[| inj f; ALL x. f(g x) = x |] ==> inv f = g"
   127   by (blast intro: inv_into_f_eq)
   128 
   129 text{*But is it useful?*}
   130 lemma inj_transfer:
   131   assumes injf: "inj f" and minor: "!!y. y \<in> range(f) ==> P(inv f y)"
   132   shows "P x"
   133 proof -
   134   have "f x \<in> range f" by auto
   135   hence "P(inv f (f x))" by (rule minor)
   136   thus "P x" by (simp add: inv_into_f_f [OF injf])
   137 qed
   138 
   139 lemma inj_iff: "(inj f) = (inv f o f = id)"
   140 apply (simp add: o_def fun_eq_iff)
   141 apply (blast intro: inj_on_inverseI inv_into_f_f)
   142 done
   143 
   144 lemma inv_o_cancel[simp]: "inj f ==> inv f o f = id"
   145 by (simp add: inj_iff)
   146 
   147 lemma o_inv_o_cancel[simp]: "inj f ==> g o inv f o f = g"
   148 by (simp add: o_assoc[symmetric])
   149 
   150 lemma inv_into_image_cancel[simp]:
   151   "inj_on f A ==> S <= A ==> inv_into A f ` f ` S = S"
   152 by(fastforce simp: image_def)
   153 
   154 lemma inj_imp_surj_inv: "inj f ==> surj (inv f)"
   155 by (blast intro!: surjI inv_into_f_f)
   156 
   157 lemma surj_f_inv_f: "surj f ==> f(inv f y) = y"
   158 by (simp add: f_inv_into_f)
   159 
   160 lemma inv_into_injective:
   161   assumes eq: "inv_into A f x = inv_into A f y"
   162       and x: "x: f`A"
   163       and y: "y: f`A"
   164   shows "x=y"
   165 proof -
   166   have "f (inv_into A f x) = f (inv_into A f y)" using eq by simp
   167   thus ?thesis by (simp add: f_inv_into_f x y)
   168 qed
   169 
   170 lemma inj_on_inv_into: "B <= f`A ==> inj_on (inv_into A f) B"
   171 by (blast intro: inj_onI dest: inv_into_injective injD)
   172 
   173 lemma bij_betw_inv_into: "bij_betw f A B ==> bij_betw (inv_into A f) B A"
   174 by (auto simp add: bij_betw_def inj_on_inv_into)
   175 
   176 lemma surj_imp_inj_inv: "surj f ==> inj (inv f)"
   177 by (simp add: inj_on_inv_into)
   178 
   179 lemma surj_iff: "(surj f) = (f o inv f = id)"
   180 by (auto intro!: surjI simp: surj_f_inv_f fun_eq_iff[where 'b='a])
   181 
   182 lemma surj_iff_all: "surj f \<longleftrightarrow> (\<forall>x. f (inv f x) = x)"
   183   unfolding surj_iff by (simp add: o_def fun_eq_iff)
   184 
   185 lemma surj_imp_inv_eq: "[| surj f; \<forall>x. g(f x) = x |] ==> inv f = g"
   186 apply (rule ext)
   187 apply (drule_tac x = "inv f x" in spec)
   188 apply (simp add: surj_f_inv_f)
   189 done
   190 
   191 lemma bij_imp_bij_inv: "bij f ==> bij (inv f)"
   192 by (simp add: bij_def inj_imp_surj_inv surj_imp_inj_inv)
   193 
   194 lemma inv_equality: "[| !!x. g (f x) = x;  !!y. f (g y) = y |] ==> inv f = g"
   195 apply (rule ext)
   196 apply (auto simp add: inv_into_def)
   197 done
   198 
   199 lemma inv_inv_eq: "bij f ==> inv (inv f) = f"
   200 apply (rule inv_equality)
   201 apply (auto simp add: bij_def surj_f_inv_f)
   202 done
   203 
   204 (** bij(inv f) implies little about f.  Consider f::bool=>bool such that
   205     f(True)=f(False)=True.  Then it's consistent with axiom someI that
   206     inv f could be any function at all, including the identity function.
   207     If inv f=id then inv f is a bijection, but inj f, surj(f) and
   208     inv(inv f)=f all fail.
   209 **)
   210 
   211 lemma inv_into_comp:
   212   "[| inj_on f (g ` A); inj_on g A; x : f ` g ` A |] ==>
   213   inv_into A (f o g) x = (inv_into A g o inv_into (g ` A) f) x"
   214 apply (rule inv_into_f_eq)
   215   apply (fast intro: comp_inj_on)
   216  apply (simp add: inv_into_into)
   217 apply (simp add: f_inv_into_f inv_into_into)
   218 done
   219 
   220 lemma o_inv_distrib: "[| bij f; bij g |] ==> inv (f o g) = inv g o inv f"
   221 apply (rule inv_equality)
   222 apply (auto simp add: bij_def surj_f_inv_f)
   223 done
   224 
   225 lemma image_surj_f_inv_f: "surj f ==> f ` (inv f ` A) = A"
   226 by (simp add: image_eq_UN surj_f_inv_f)
   227 
   228 lemma image_inv_f_f: "inj f ==> (inv f) ` (f ` A) = A"
   229 by (simp add: image_eq_UN)
   230 
   231 lemma inv_image_comp: "inj f ==> inv f ` (f`X) = X"
   232 by (auto simp add: image_def)
   233 
   234 lemma bij_image_Collect_eq: "bij f ==> f ` Collect P = {y. P (inv f y)}"
   235 apply auto
   236 apply (force simp add: bij_is_inj)
   237 apply (blast intro: bij_is_surj [THEN surj_f_inv_f, symmetric])
   238 done
   239 
   240 lemma bij_vimage_eq_inv_image: "bij f ==> f -` A = inv f ` A" 
   241 apply (auto simp add: bij_is_surj [THEN surj_f_inv_f])
   242 apply (blast intro: bij_is_inj [THEN inv_into_f_f, symmetric])
   243 done
   244 
   245 lemma finite_fun_UNIVD1:
   246   assumes fin: "finite (UNIV :: ('a \<Rightarrow> 'b) set)"
   247   and card: "card (UNIV :: 'b set) \<noteq> Suc 0"
   248   shows "finite (UNIV :: 'a set)"
   249 proof -
   250   from fin have finb: "finite (UNIV :: 'b set)" by (rule finite_fun_UNIVD2)
   251   with card have "card (UNIV :: 'b set) \<ge> Suc (Suc 0)"
   252     by (cases "card (UNIV :: 'b set)") (auto simp add: card_eq_0_iff)
   253   then obtain n where "card (UNIV :: 'b set) = Suc (Suc n)" "n = card (UNIV :: 'b set) - Suc (Suc 0)" by auto
   254   then obtain b1 b2 where b1b2: "(b1 :: 'b) \<noteq> (b2 :: 'b)" by (auto simp add: card_Suc_eq)
   255   from fin have "finite (range (\<lambda>f :: 'a \<Rightarrow> 'b. inv f b1))" by (rule finite_imageI)
   256   moreover have "UNIV = range (\<lambda>f :: 'a \<Rightarrow> 'b. inv f b1)"
   257   proof (rule UNIV_eq_I)
   258     fix x :: 'a
   259     from b1b2 have "x = inv (\<lambda>y. if y = x then b1 else b2) b1" by (simp add: inv_into_def)
   260     thus "x \<in> range (\<lambda>f\<Colon>'a \<Rightarrow> 'b. inv f b1)" by blast
   261   qed
   262   ultimately show "finite (UNIV :: 'a set)" by simp
   263 qed
   264 
   265 lemma image_inv_into_cancel:
   266   assumes SURJ: "f`A=A'" and SUB: "B' \<le> A'"
   267   shows "f `((inv_into A f)`B') = B'"
   268   using assms
   269 proof (auto simp add: f_inv_into_f)
   270   let ?f' = "(inv_into A f)"
   271   fix a' assume *: "a' \<in> B'"
   272   then have "a' \<in> A'" using SUB by auto
   273   then have "a' = f (?f' a')"
   274     using SURJ by (auto simp add: f_inv_into_f)
   275   then show "a' \<in> f ` (?f' ` B')" using * by blast
   276 qed
   277 
   278 lemma inv_into_inv_into_eq:
   279   assumes "bij_betw f A A'" "a \<in> A"
   280   shows "inv_into A' (inv_into A f) a = f a"
   281 proof -
   282   let ?f' = "inv_into A f"   let ?f'' = "inv_into A' ?f'"
   283   have 1: "bij_betw ?f' A' A" using assms
   284   by (auto simp add: bij_betw_inv_into)
   285   obtain a' where 2: "a' \<in> A'" and 3: "?f' a' = a"
   286     using 1 `a \<in> A` unfolding bij_betw_def by force
   287   hence "?f'' a = a'"
   288     using `a \<in> A` 1 3 by (auto simp add: f_inv_into_f bij_betw_def)
   289   moreover have "f a = a'" using assms 2 3
   290     by (auto simp add: bij_betw_def)
   291   ultimately show "?f'' a = f a" by simp
   292 qed
   293 
   294 lemma inj_on_iff_surj:
   295   assumes "A \<noteq> {}"
   296   shows "(\<exists>f. inj_on f A \<and> f ` A \<le> A') \<longleftrightarrow> (\<exists>g. g ` A' = A)"
   297 proof safe
   298   fix f assume INJ: "inj_on f A" and INCL: "f ` A \<le> A'"
   299   let ?phi = "\<lambda>a' a. a \<in> A \<and> f a = a'"  let ?csi = "\<lambda>a. a \<in> A"
   300   let ?g = "\<lambda>a'. if a' \<in> f ` A then (SOME a. ?phi a' a) else (SOME a. ?csi a)"
   301   have "?g ` A' = A"
   302   proof
   303     show "?g ` A' \<le> A"
   304     proof clarify
   305       fix a' assume *: "a' \<in> A'"
   306       show "?g a' \<in> A"
   307       proof cases
   308         assume Case1: "a' \<in> f ` A"
   309         then obtain a where "?phi a' a" by blast
   310         hence "?phi a' (SOME a. ?phi a' a)" using someI[of "?phi a'" a] by blast
   311         with Case1 show ?thesis by auto
   312       next
   313         assume Case2: "a' \<notin> f ` A"
   314         hence "?csi (SOME a. ?csi a)" using assms someI_ex[of ?csi] by blast
   315         with Case2 show ?thesis by auto
   316       qed
   317     qed
   318   next
   319     show "A \<le> ?g ` A'"
   320     proof-
   321       {fix a assume *: "a \<in> A"
   322        let ?b = "SOME aa. ?phi (f a) aa"
   323        have "?phi (f a) a" using * by auto
   324        hence 1: "?phi (f a) ?b" using someI[of "?phi(f a)" a] by blast
   325        hence "?g(f a) = ?b" using * by auto
   326        moreover have "a = ?b" using 1 INJ * by (auto simp add: inj_on_def)
   327        ultimately have "?g(f a) = a" by simp
   328        with INCL * have "?g(f a) = a \<and> f a \<in> A'" by auto
   329       }
   330       thus ?thesis by force
   331     qed
   332   qed
   333   thus "\<exists>g. g ` A' = A" by blast
   334 next
   335   fix g  let ?f = "inv_into A' g"
   336   have "inj_on ?f (g ` A')"
   337     by (auto simp add: inj_on_inv_into)
   338   moreover
   339   {fix a' assume *: "a' \<in> A'"
   340    let ?phi = "\<lambda> b'. b' \<in> A' \<and> g b' = g a'"
   341    have "?phi a'" using * by auto
   342    hence "?phi(SOME b'. ?phi b')" using someI[of ?phi] by blast
   343    hence "?f(g a') \<in> A'" unfolding inv_into_def by auto
   344   }
   345   ultimately show "\<exists>f. inj_on f (g ` A') \<and> f ` g ` A' \<subseteq> A'" by auto
   346 qed
   347 
   348 lemma Ex_inj_on_UNION_Sigma:
   349   "\<exists>f. (inj_on f (\<Union> i \<in> I. A i) \<and> f ` (\<Union> i \<in> I. A i) \<le> (SIGMA i : I. A i))"
   350 proof
   351   let ?phi = "\<lambda> a i. i \<in> I \<and> a \<in> A i"
   352   let ?sm = "\<lambda> a. SOME i. ?phi a i"
   353   let ?f = "\<lambda>a. (?sm a, a)"
   354   have "inj_on ?f (\<Union> i \<in> I. A i)" unfolding inj_on_def by auto
   355   moreover
   356   { { fix i a assume "i \<in> I" and "a \<in> A i"
   357       hence "?sm a \<in> I \<and> a \<in> A(?sm a)" using someI[of "?phi a" i] by auto
   358     }
   359     hence "?f ` (\<Union> i \<in> I. A i) \<le> (SIGMA i : I. A i)" by auto
   360   }
   361   ultimately
   362   show "inj_on ?f (\<Union> i \<in> I. A i) \<and> ?f ` (\<Union> i \<in> I. A i) \<le> (SIGMA i : I. A i)"
   363   by auto
   364 qed
   365 
   366 subsection {* The Cantor-Bernstein Theorem *}
   367 
   368 lemma Cantor_Bernstein_aux:
   369   shows "\<exists>A' h. A' \<le> A \<and>
   370                 (\<forall>a \<in> A'. a \<notin> g`(B - f ` A')) \<and>
   371                 (\<forall>a \<in> A'. h a = f a) \<and>
   372                 (\<forall>a \<in> A - A'. h a \<in> B - (f ` A') \<and> a = g(h a))"
   373 proof-
   374   obtain H where H_def: "H = (\<lambda> A'. A - (g`(B - (f ` A'))))" by blast
   375   have 0: "mono H" unfolding mono_def H_def by blast
   376   then obtain A' where 1: "H A' = A'" using lfp_unfold by blast
   377   hence 2: "A' = A - (g`(B - (f ` A')))" unfolding H_def by simp
   378   hence 3: "A' \<le> A" by blast
   379   have 4: "\<forall>a \<in> A'.  a \<notin> g`(B - f ` A')"
   380   using 2 by blast
   381   have 5: "\<forall>a \<in> A - A'. \<exists>b \<in> B - (f ` A'). a = g b"
   382   using 2 by blast
   383   (*  *)
   384   obtain h where h_def:
   385   "h = (\<lambda> a. if a \<in> A' then f a else (SOME b. b \<in> B - (f ` A') \<and> a = g b))" by blast
   386   hence "\<forall>a \<in> A'. h a = f a" by auto
   387   moreover
   388   have "\<forall>a \<in> A - A'. h a \<in> B - (f ` A') \<and> a = g(h a)"
   389   proof
   390     fix a assume *: "a \<in> A - A'"
   391     let ?phi = "\<lambda> b. b \<in> B - (f ` A') \<and> a = g b"
   392     have "h a = (SOME b. ?phi b)" using h_def * by auto
   393     moreover have "\<exists>b. ?phi b" using 5 *  by auto
   394     ultimately show  "?phi (h a)" using someI_ex[of ?phi] by auto
   395   qed
   396   ultimately show ?thesis using 3 4 by blast
   397 qed
   398 
   399 theorem Cantor_Bernstein:
   400   assumes INJ1: "inj_on f A" and SUB1: "f ` A \<le> B" and
   401           INJ2: "inj_on g B" and SUB2: "g ` B \<le> A"
   402   shows "\<exists>h. bij_betw h A B"
   403 proof-
   404   obtain A' and h where 0: "A' \<le> A" and
   405   1: "\<forall>a \<in> A'. a \<notin> g`(B - f ` A')" and
   406   2: "\<forall>a \<in> A'. h a = f a" and
   407   3: "\<forall>a \<in> A - A'. h a \<in> B - (f ` A') \<and> a = g(h a)"
   408   using Cantor_Bernstein_aux[of A g B f] by blast
   409   have "inj_on h A"
   410   proof (intro inj_onI)
   411     fix a1 a2
   412     assume 4: "a1 \<in> A" and 5: "a2 \<in> A" and 6: "h a1 = h a2"
   413     show "a1 = a2"
   414     proof(cases "a1 \<in> A'")
   415       assume Case1: "a1 \<in> A'"
   416       show ?thesis
   417       proof(cases "a2 \<in> A'")
   418         assume Case11: "a2 \<in> A'"
   419         hence "f a1 = f a2" using Case1 2 6 by auto
   420         thus ?thesis using INJ1 Case1 Case11 0
   421         unfolding inj_on_def by blast
   422       next
   423         assume Case12: "a2 \<notin> A'"
   424         hence False using 3 5 2 6 Case1 by force
   425         thus ?thesis by simp
   426       qed
   427     next
   428     assume Case2: "a1 \<notin> A'"
   429       show ?thesis
   430       proof(cases "a2 \<in> A'")
   431         assume Case21: "a2 \<in> A'"
   432         hence False using 3 4 2 6 Case2 by auto
   433         thus ?thesis by simp
   434       next
   435         assume Case22: "a2 \<notin> A'"
   436         hence "a1 = g(h a1) \<and> a2 = g(h a2)" using Case2 4 5 3 by auto
   437         thus ?thesis using 6 by simp
   438       qed
   439     qed
   440   qed
   441   (*  *)
   442   moreover
   443   have "h ` A = B"
   444   proof safe
   445     fix a assume "a \<in> A"
   446     thus "h a \<in> B" using SUB1 2 3 by (cases "a \<in> A'") auto
   447   next
   448     fix b assume *: "b \<in> B"
   449     show "b \<in> h ` A"
   450     proof(cases "b \<in> f ` A'")
   451       assume Case1: "b \<in> f ` A'"
   452       then obtain a where "a \<in> A' \<and> b = f a" by blast
   453       thus ?thesis using 2 0 by force
   454     next
   455       assume Case2: "b \<notin> f ` A'"
   456       hence "g b \<notin> A'" using 1 * by auto
   457       hence 4: "g b \<in> A - A'" using * SUB2 by auto
   458       hence "h(g b) \<in> B \<and> g(h(g b)) = g b"
   459       using 3 by auto
   460       hence "h(g b) = b" using * INJ2 unfolding inj_on_def by auto
   461       thus ?thesis using 4 by force
   462     qed
   463   qed
   464   (*  *)
   465   ultimately show ?thesis unfolding bij_betw_def by auto
   466 qed
   467 
   468 subsection {*Other Consequences of Hilbert's Epsilon*}
   469 
   470 text {*Hilbert's Epsilon and the @{term split} Operator*}
   471 
   472 text{*Looping simprule*}
   473 lemma split_paired_Eps: "(SOME x. P x) = (SOME (a,b). P(a,b))"
   474   by simp
   475 
   476 lemma Eps_split: "Eps (split P) = (SOME xy. P (fst xy) (snd xy))"
   477   by (simp add: split_def)
   478 
   479 lemma Eps_split_eq [simp]: "(@(x',y'). x = x' & y = y') = (x,y)"
   480   by blast
   481 
   482 
   483 text{*A relation is wellfounded iff it has no infinite descending chain*}
   484 lemma wf_iff_no_infinite_down_chain:
   485   "wf r = (~(\<exists>f. \<forall>i. (f(Suc i),f i) \<in> r))"
   486 apply (simp only: wf_eq_minimal)
   487 apply (rule iffI)
   488  apply (rule notI)
   489  apply (erule exE)
   490  apply (erule_tac x = "{w. \<exists>i. w=f i}" in allE, blast)
   491 apply (erule contrapos_np, simp, clarify)
   492 apply (subgoal_tac "\<forall>n. nat_rec x (%i y. @z. z:Q & (z,y) :r) n \<in> Q")
   493  apply (rule_tac x = "nat_rec x (%i y. @z. z:Q & (z,y) :r)" in exI)
   494  apply (rule allI, simp)
   495  apply (rule someI2_ex, blast, blast)
   496 apply (rule allI)
   497 apply (induct_tac "n", simp_all)
   498 apply (rule someI2_ex, blast+)
   499 done
   500 
   501 lemma wf_no_infinite_down_chainE:
   502   assumes "wf r" obtains k where "(f (Suc k), f k) \<notin> r"
   503 using `wf r` wf_iff_no_infinite_down_chain[of r] by blast
   504 
   505 
   506 text{*A dynamically-scoped fact for TFL *}
   507 lemma tfl_some: "\<forall>P x. P x --> P (Eps P)"
   508   by (blast intro: someI)
   509 
   510 
   511 subsection {* Least value operator *}
   512 
   513 definition
   514   LeastM :: "['a => 'b::ord, 'a => bool] => 'a" where
   515   "LeastM m P == SOME x. P x & (\<forall>y. P y --> m x <= m y)"
   516 
   517 syntax
   518   "_LeastM" :: "[pttrn, 'a => 'b::ord, bool] => 'a"    ("LEAST _ WRT _. _" [0, 4, 10] 10)
   519 translations
   520   "LEAST x WRT m. P" == "CONST LeastM m (%x. P)"
   521 
   522 lemma LeastMI2:
   523   "P x ==> (!!y. P y ==> m x <= m y)
   524     ==> (!!x. P x ==> \<forall>y. P y --> m x \<le> m y ==> Q x)
   525     ==> Q (LeastM m P)"
   526   apply (simp add: LeastM_def)
   527   apply (rule someI2_ex, blast, blast)
   528   done
   529 
   530 lemma LeastM_equality:
   531   "P k ==> (!!x. P x ==> m k <= m x)
   532     ==> m (LEAST x WRT m. P x) = (m k::'a::order)"
   533   apply (rule LeastMI2, assumption, blast)
   534   apply (blast intro!: order_antisym)
   535   done
   536 
   537 lemma wf_linord_ex_has_least:
   538   "wf r ==> \<forall>x y. ((x,y):r^+) = ((y,x)~:r^*) ==> P k
   539     ==> \<exists>x. P x & (!y. P y --> (m x,m y):r^*)"
   540   apply (drule wf_trancl [THEN wf_eq_minimal [THEN iffD1]])
   541   apply (drule_tac x = "m`Collect P" in spec, force)
   542   done
   543 
   544 lemma ex_has_least_nat:
   545     "P k ==> \<exists>x. P x & (\<forall>y. P y --> m x <= (m y::nat))"
   546   apply (simp only: pred_nat_trancl_eq_le [symmetric])
   547   apply (rule wf_pred_nat [THEN wf_linord_ex_has_least])
   548    apply (simp add: less_eq linorder_not_le pred_nat_trancl_eq_le, assumption)
   549   done
   550 
   551 lemma LeastM_nat_lemma:
   552     "P k ==> P (LeastM m P) & (\<forall>y. P y --> m (LeastM m P) <= (m y::nat))"
   553   apply (simp add: LeastM_def)
   554   apply (rule someI_ex)
   555   apply (erule ex_has_least_nat)
   556   done
   557 
   558 lemmas LeastM_natI = LeastM_nat_lemma [THEN conjunct1]
   559 
   560 lemma LeastM_nat_le: "P x ==> m (LeastM m P) <= (m x::nat)"
   561 by (rule LeastM_nat_lemma [THEN conjunct2, THEN spec, THEN mp], assumption, assumption)
   562 
   563 
   564 subsection {* Greatest value operator *}
   565 
   566 definition
   567   GreatestM :: "['a => 'b::ord, 'a => bool] => 'a" where
   568   "GreatestM m P == SOME x. P x & (\<forall>y. P y --> m y <= m x)"
   569 
   570 definition
   571   Greatest :: "('a::ord => bool) => 'a" (binder "GREATEST " 10) where
   572   "Greatest == GreatestM (%x. x)"
   573 
   574 syntax
   575   "_GreatestM" :: "[pttrn, 'a => 'b::ord, bool] => 'a"
   576       ("GREATEST _ WRT _. _" [0, 4, 10] 10)
   577 translations
   578   "GREATEST x WRT m. P" == "CONST GreatestM m (%x. P)"
   579 
   580 lemma GreatestMI2:
   581   "P x ==> (!!y. P y ==> m y <= m x)
   582     ==> (!!x. P x ==> \<forall>y. P y --> m y \<le> m x ==> Q x)
   583     ==> Q (GreatestM m P)"
   584   apply (simp add: GreatestM_def)
   585   apply (rule someI2_ex, blast, blast)
   586   done
   587 
   588 lemma GreatestM_equality:
   589  "P k ==> (!!x. P x ==> m x <= m k)
   590     ==> m (GREATEST x WRT m. P x) = (m k::'a::order)"
   591   apply (rule_tac m = m in GreatestMI2, assumption, blast)
   592   apply (blast intro!: order_antisym)
   593   done
   594 
   595 lemma Greatest_equality:
   596   "P (k::'a::order) ==> (!!x. P x ==> x <= k) ==> (GREATEST x. P x) = k"
   597   apply (simp add: Greatest_def)
   598   apply (erule GreatestM_equality, blast)
   599   done
   600 
   601 lemma ex_has_greatest_nat_lemma:
   602   "P k ==> \<forall>x. P x --> (\<exists>y. P y & ~ ((m y::nat) <= m x))
   603     ==> \<exists>y. P y & ~ (m y < m k + n)"
   604   apply (induct n, force)
   605   apply (force simp add: le_Suc_eq)
   606   done
   607 
   608 lemma ex_has_greatest_nat:
   609   "P k ==> \<forall>y. P y --> m y < b
   610     ==> \<exists>x. P x & (\<forall>y. P y --> (m y::nat) <= m x)"
   611   apply (rule ccontr)
   612   apply (cut_tac P = P and n = "b - m k" in ex_has_greatest_nat_lemma)
   613     apply (subgoal_tac [3] "m k <= b", auto)
   614   done
   615 
   616 lemma GreatestM_nat_lemma:
   617   "P k ==> \<forall>y. P y --> m y < b
   618     ==> P (GreatestM m P) & (\<forall>y. P y --> (m y::nat) <= m (GreatestM m P))"
   619   apply (simp add: GreatestM_def)
   620   apply (rule someI_ex)
   621   apply (erule ex_has_greatest_nat, assumption)
   622   done
   623 
   624 lemmas GreatestM_natI = GreatestM_nat_lemma [THEN conjunct1]
   625 
   626 lemma GreatestM_nat_le:
   627   "P x ==> \<forall>y. P y --> m y < b
   628     ==> (m x::nat) <= m (GreatestM m P)"
   629   apply (blast dest: GreatestM_nat_lemma [THEN conjunct2, THEN spec, of P])
   630   done
   631 
   632 
   633 text {* \medskip Specialization to @{text GREATEST}. *}
   634 
   635 lemma GreatestI: "P (k::nat) ==> \<forall>y. P y --> y < b ==> P (GREATEST x. P x)"
   636   apply (simp add: Greatest_def)
   637   apply (rule GreatestM_natI, auto)
   638   done
   639 
   640 lemma Greatest_le:
   641     "P x ==> \<forall>y. P y --> y < b ==> (x::nat) <= (GREATEST x. P x)"
   642   apply (simp add: Greatest_def)
   643   apply (rule GreatestM_nat_le, auto)
   644   done
   645 
   646 
   647 subsection {* Specification package -- Hilbertized version *}
   648 
   649 lemma exE_some: "[| Ex P ; c == Eps P |] ==> P c"
   650   by (simp only: someI_ex)
   651 
   652 use "Tools/choice_specification.ML"
   653 
   654 end