src/HOL/Limits.thy
author wenzelm
Thu May 24 17:25:53 2012 +0200 (2012-05-24)
changeset 47988 e4b69e10b990
parent 47432 e1576d13e933
child 49834 b27bbb021df1
permissions -rw-r--r--
tuned proofs;
     1 (*  Title       : Limits.thy
     2     Author      : Brian Huffman
     3 *)
     4 
     5 header {* Filters and Limits *}
     6 
     7 theory Limits
     8 imports RealVector
     9 begin
    10 
    11 subsection {* Filters *}
    12 
    13 text {*
    14   This definition also allows non-proper filters.
    15 *}
    16 
    17 locale is_filter =
    18   fixes F :: "('a \<Rightarrow> bool) \<Rightarrow> bool"
    19   assumes True: "F (\<lambda>x. True)"
    20   assumes conj: "F (\<lambda>x. P x) \<Longrightarrow> F (\<lambda>x. Q x) \<Longrightarrow> F (\<lambda>x. P x \<and> Q x)"
    21   assumes mono: "\<forall>x. P x \<longrightarrow> Q x \<Longrightarrow> F (\<lambda>x. P x) \<Longrightarrow> F (\<lambda>x. Q x)"
    22 
    23 typedef (open) 'a filter = "{F :: ('a \<Rightarrow> bool) \<Rightarrow> bool. is_filter F}"
    24 proof
    25   show "(\<lambda>x. True) \<in> ?filter" by (auto intro: is_filter.intro)
    26 qed
    27 
    28 lemma is_filter_Rep_filter: "is_filter (Rep_filter F)"
    29   using Rep_filter [of F] by simp
    30 
    31 lemma Abs_filter_inverse':
    32   assumes "is_filter F" shows "Rep_filter (Abs_filter F) = F"
    33   using assms by (simp add: Abs_filter_inverse)
    34 
    35 
    36 subsection {* Eventually *}
    37 
    38 definition eventually :: "('a \<Rightarrow> bool) \<Rightarrow> 'a filter \<Rightarrow> bool"
    39   where "eventually P F \<longleftrightarrow> Rep_filter F P"
    40 
    41 lemma eventually_Abs_filter:
    42   assumes "is_filter F" shows "eventually P (Abs_filter F) = F P"
    43   unfolding eventually_def using assms by (simp add: Abs_filter_inverse)
    44 
    45 lemma filter_eq_iff:
    46   shows "F = F' \<longleftrightarrow> (\<forall>P. eventually P F = eventually P F')"
    47   unfolding Rep_filter_inject [symmetric] fun_eq_iff eventually_def ..
    48 
    49 lemma eventually_True [simp]: "eventually (\<lambda>x. True) F"
    50   unfolding eventually_def
    51   by (rule is_filter.True [OF is_filter_Rep_filter])
    52 
    53 lemma always_eventually: "\<forall>x. P x \<Longrightarrow> eventually P F"
    54 proof -
    55   assume "\<forall>x. P x" hence "P = (\<lambda>x. True)" by (simp add: ext)
    56   thus "eventually P F" by simp
    57 qed
    58 
    59 lemma eventually_mono:
    60   "(\<forall>x. P x \<longrightarrow> Q x) \<Longrightarrow> eventually P F \<Longrightarrow> eventually Q F"
    61   unfolding eventually_def
    62   by (rule is_filter.mono [OF is_filter_Rep_filter])
    63 
    64 lemma eventually_conj:
    65   assumes P: "eventually (\<lambda>x. P x) F"
    66   assumes Q: "eventually (\<lambda>x. Q x) F"
    67   shows "eventually (\<lambda>x. P x \<and> Q x) F"
    68   using assms unfolding eventually_def
    69   by (rule is_filter.conj [OF is_filter_Rep_filter])
    70 
    71 lemma eventually_mp:
    72   assumes "eventually (\<lambda>x. P x \<longrightarrow> Q x) F"
    73   assumes "eventually (\<lambda>x. P x) F"
    74   shows "eventually (\<lambda>x. Q x) F"
    75 proof (rule eventually_mono)
    76   show "\<forall>x. (P x \<longrightarrow> Q x) \<and> P x \<longrightarrow> Q x" by simp
    77   show "eventually (\<lambda>x. (P x \<longrightarrow> Q x) \<and> P x) F"
    78     using assms by (rule eventually_conj)
    79 qed
    80 
    81 lemma eventually_rev_mp:
    82   assumes "eventually (\<lambda>x. P x) F"
    83   assumes "eventually (\<lambda>x. P x \<longrightarrow> Q x) F"
    84   shows "eventually (\<lambda>x. Q x) F"
    85 using assms(2) assms(1) by (rule eventually_mp)
    86 
    87 lemma eventually_conj_iff:
    88   "eventually (\<lambda>x. P x \<and> Q x) F \<longleftrightarrow> eventually P F \<and> eventually Q F"
    89   by (auto intro: eventually_conj elim: eventually_rev_mp)
    90 
    91 lemma eventually_elim1:
    92   assumes "eventually (\<lambda>i. P i) F"
    93   assumes "\<And>i. P i \<Longrightarrow> Q i"
    94   shows "eventually (\<lambda>i. Q i) F"
    95   using assms by (auto elim!: eventually_rev_mp)
    96 
    97 lemma eventually_elim2:
    98   assumes "eventually (\<lambda>i. P i) F"
    99   assumes "eventually (\<lambda>i. Q i) F"
   100   assumes "\<And>i. P i \<Longrightarrow> Q i \<Longrightarrow> R i"
   101   shows "eventually (\<lambda>i. R i) F"
   102   using assms by (auto elim!: eventually_rev_mp)
   103 
   104 lemma eventually_subst:
   105   assumes "eventually (\<lambda>n. P n = Q n) F"
   106   shows "eventually P F = eventually Q F" (is "?L = ?R")
   107 proof -
   108   from assms have "eventually (\<lambda>x. P x \<longrightarrow> Q x) F"
   109       and "eventually (\<lambda>x. Q x \<longrightarrow> P x) F"
   110     by (auto elim: eventually_elim1)
   111   then show ?thesis by (auto elim: eventually_elim2)
   112 qed
   113 
   114 ML {*
   115   fun eventually_elim_tac ctxt thms thm =
   116     let
   117       val thy = Proof_Context.theory_of ctxt
   118       val mp_thms = thms RL [@{thm eventually_rev_mp}]
   119       val raw_elim_thm =
   120         (@{thm allI} RS @{thm always_eventually})
   121         |> fold (fn thm1 => fn thm2 => thm2 RS thm1) mp_thms
   122         |> fold (fn _ => fn thm => @{thm impI} RS thm) thms
   123       val cases_prop = prop_of (raw_elim_thm RS thm)
   124       val cases = (Rule_Cases.make_common (thy, cases_prop) [(("elim", []), [])])
   125     in
   126       CASES cases (rtac raw_elim_thm 1) thm
   127     end
   128 *}
   129 
   130 method_setup eventually_elim = {*
   131   Scan.succeed (fn ctxt => METHOD_CASES (eventually_elim_tac ctxt))
   132 *} "elimination of eventually quantifiers"
   133 
   134 
   135 subsection {* Finer-than relation *}
   136 
   137 text {* @{term "F \<le> F'"} means that filter @{term F} is finer than
   138 filter @{term F'}. *}
   139 
   140 instantiation filter :: (type) complete_lattice
   141 begin
   142 
   143 definition le_filter_def:
   144   "F \<le> F' \<longleftrightarrow> (\<forall>P. eventually P F' \<longrightarrow> eventually P F)"
   145 
   146 definition
   147   "(F :: 'a filter) < F' \<longleftrightarrow> F \<le> F' \<and> \<not> F' \<le> F"
   148 
   149 definition
   150   "top = Abs_filter (\<lambda>P. \<forall>x. P x)"
   151 
   152 definition
   153   "bot = Abs_filter (\<lambda>P. True)"
   154 
   155 definition
   156   "sup F F' = Abs_filter (\<lambda>P. eventually P F \<and> eventually P F')"
   157 
   158 definition
   159   "inf F F' = Abs_filter
   160       (\<lambda>P. \<exists>Q R. eventually Q F \<and> eventually R F' \<and> (\<forall>x. Q x \<and> R x \<longrightarrow> P x))"
   161 
   162 definition
   163   "Sup S = Abs_filter (\<lambda>P. \<forall>F\<in>S. eventually P F)"
   164 
   165 definition
   166   "Inf S = Sup {F::'a filter. \<forall>F'\<in>S. F \<le> F'}"
   167 
   168 lemma eventually_top [simp]: "eventually P top \<longleftrightarrow> (\<forall>x. P x)"
   169   unfolding top_filter_def
   170   by (rule eventually_Abs_filter, rule is_filter.intro, auto)
   171 
   172 lemma eventually_bot [simp]: "eventually P bot"
   173   unfolding bot_filter_def
   174   by (subst eventually_Abs_filter, rule is_filter.intro, auto)
   175 
   176 lemma eventually_sup:
   177   "eventually P (sup F F') \<longleftrightarrow> eventually P F \<and> eventually P F'"
   178   unfolding sup_filter_def
   179   by (rule eventually_Abs_filter, rule is_filter.intro)
   180      (auto elim!: eventually_rev_mp)
   181 
   182 lemma eventually_inf:
   183   "eventually P (inf F F') \<longleftrightarrow>
   184    (\<exists>Q R. eventually Q F \<and> eventually R F' \<and> (\<forall>x. Q x \<and> R x \<longrightarrow> P x))"
   185   unfolding inf_filter_def
   186   apply (rule eventually_Abs_filter, rule is_filter.intro)
   187   apply (fast intro: eventually_True)
   188   apply clarify
   189   apply (intro exI conjI)
   190   apply (erule (1) eventually_conj)
   191   apply (erule (1) eventually_conj)
   192   apply simp
   193   apply auto
   194   done
   195 
   196 lemma eventually_Sup:
   197   "eventually P (Sup S) \<longleftrightarrow> (\<forall>F\<in>S. eventually P F)"
   198   unfolding Sup_filter_def
   199   apply (rule eventually_Abs_filter, rule is_filter.intro)
   200   apply (auto intro: eventually_conj elim!: eventually_rev_mp)
   201   done
   202 
   203 instance proof
   204   fix F F' F'' :: "'a filter" and S :: "'a filter set"
   205   { show "F < F' \<longleftrightarrow> F \<le> F' \<and> \<not> F' \<le> F"
   206     by (rule less_filter_def) }
   207   { show "F \<le> F"
   208     unfolding le_filter_def by simp }
   209   { assume "F \<le> F'" and "F' \<le> F''" thus "F \<le> F''"
   210     unfolding le_filter_def by simp }
   211   { assume "F \<le> F'" and "F' \<le> F" thus "F = F'"
   212     unfolding le_filter_def filter_eq_iff by fast }
   213   { show "F \<le> top"
   214     unfolding le_filter_def eventually_top by (simp add: always_eventually) }
   215   { show "bot \<le> F"
   216     unfolding le_filter_def by simp }
   217   { show "F \<le> sup F F'" and "F' \<le> sup F F'"
   218     unfolding le_filter_def eventually_sup by simp_all }
   219   { assume "F \<le> F''" and "F' \<le> F''" thus "sup F F' \<le> F''"
   220     unfolding le_filter_def eventually_sup by simp }
   221   { show "inf F F' \<le> F" and "inf F F' \<le> F'"
   222     unfolding le_filter_def eventually_inf by (auto intro: eventually_True) }
   223   { assume "F \<le> F'" and "F \<le> F''" thus "F \<le> inf F' F''"
   224     unfolding le_filter_def eventually_inf
   225     by (auto elim!: eventually_mono intro: eventually_conj) }
   226   { assume "F \<in> S" thus "F \<le> Sup S"
   227     unfolding le_filter_def eventually_Sup by simp }
   228   { assume "\<And>F. F \<in> S \<Longrightarrow> F \<le> F'" thus "Sup S \<le> F'"
   229     unfolding le_filter_def eventually_Sup by simp }
   230   { assume "F'' \<in> S" thus "Inf S \<le> F''"
   231     unfolding le_filter_def Inf_filter_def eventually_Sup Ball_def by simp }
   232   { assume "\<And>F'. F' \<in> S \<Longrightarrow> F \<le> F'" thus "F \<le> Inf S"
   233     unfolding le_filter_def Inf_filter_def eventually_Sup Ball_def by simp }
   234 qed
   235 
   236 end
   237 
   238 lemma filter_leD:
   239   "F \<le> F' \<Longrightarrow> eventually P F' \<Longrightarrow> eventually P F"
   240   unfolding le_filter_def by simp
   241 
   242 lemma filter_leI:
   243   "(\<And>P. eventually P F' \<Longrightarrow> eventually P F) \<Longrightarrow> F \<le> F'"
   244   unfolding le_filter_def by simp
   245 
   246 lemma eventually_False:
   247   "eventually (\<lambda>x. False) F \<longleftrightarrow> F = bot"
   248   unfolding filter_eq_iff by (auto elim: eventually_rev_mp)
   249 
   250 abbreviation (input) trivial_limit :: "'a filter \<Rightarrow> bool"
   251   where "trivial_limit F \<equiv> F = bot"
   252 
   253 lemma trivial_limit_def: "trivial_limit F \<longleftrightarrow> eventually (\<lambda>x. False) F"
   254   by (rule eventually_False [symmetric])
   255 
   256 
   257 subsection {* Map function for filters *}
   258 
   259 definition filtermap :: "('a \<Rightarrow> 'b) \<Rightarrow> 'a filter \<Rightarrow> 'b filter"
   260   where "filtermap f F = Abs_filter (\<lambda>P. eventually (\<lambda>x. P (f x)) F)"
   261 
   262 lemma eventually_filtermap:
   263   "eventually P (filtermap f F) = eventually (\<lambda>x. P (f x)) F"
   264   unfolding filtermap_def
   265   apply (rule eventually_Abs_filter)
   266   apply (rule is_filter.intro)
   267   apply (auto elim!: eventually_rev_mp)
   268   done
   269 
   270 lemma filtermap_ident: "filtermap (\<lambda>x. x) F = F"
   271   by (simp add: filter_eq_iff eventually_filtermap)
   272 
   273 lemma filtermap_filtermap:
   274   "filtermap f (filtermap g F) = filtermap (\<lambda>x. f (g x)) F"
   275   by (simp add: filter_eq_iff eventually_filtermap)
   276 
   277 lemma filtermap_mono: "F \<le> F' \<Longrightarrow> filtermap f F \<le> filtermap f F'"
   278   unfolding le_filter_def eventually_filtermap by simp
   279 
   280 lemma filtermap_bot [simp]: "filtermap f bot = bot"
   281   by (simp add: filter_eq_iff eventually_filtermap)
   282 
   283 
   284 subsection {* Sequentially *}
   285 
   286 definition sequentially :: "nat filter"
   287   where "sequentially = Abs_filter (\<lambda>P. \<exists>k. \<forall>n\<ge>k. P n)"
   288 
   289 lemma eventually_sequentially:
   290   "eventually P sequentially \<longleftrightarrow> (\<exists>N. \<forall>n\<ge>N. P n)"
   291 unfolding sequentially_def
   292 proof (rule eventually_Abs_filter, rule is_filter.intro)
   293   fix P Q :: "nat \<Rightarrow> bool"
   294   assume "\<exists>i. \<forall>n\<ge>i. P n" and "\<exists>j. \<forall>n\<ge>j. Q n"
   295   then obtain i j where "\<forall>n\<ge>i. P n" and "\<forall>n\<ge>j. Q n" by auto
   296   then have "\<forall>n\<ge>max i j. P n \<and> Q n" by simp
   297   then show "\<exists>k. \<forall>n\<ge>k. P n \<and> Q n" ..
   298 qed auto
   299 
   300 lemma sequentially_bot [simp, intro]: "sequentially \<noteq> bot"
   301   unfolding filter_eq_iff eventually_sequentially by auto
   302 
   303 lemmas trivial_limit_sequentially = sequentially_bot
   304 
   305 lemma eventually_False_sequentially [simp]:
   306   "\<not> eventually (\<lambda>n. False) sequentially"
   307   by (simp add: eventually_False)
   308 
   309 lemma le_sequentially:
   310   "F \<le> sequentially \<longleftrightarrow> (\<forall>N. eventually (\<lambda>n. N \<le> n) F)"
   311   unfolding le_filter_def eventually_sequentially
   312   by (safe, fast, drule_tac x=N in spec, auto elim: eventually_rev_mp)
   313 
   314 lemma eventually_sequentiallyI:
   315   assumes "\<And>x. c \<le> x \<Longrightarrow> P x"
   316   shows "eventually P sequentially"
   317 using assms by (auto simp: eventually_sequentially)
   318 
   319 
   320 subsection {* Standard filters *}
   321 
   322 definition within :: "'a filter \<Rightarrow> 'a set \<Rightarrow> 'a filter" (infixr "within" 70)
   323   where "F within S = Abs_filter (\<lambda>P. eventually (\<lambda>x. x \<in> S \<longrightarrow> P x) F)"
   324 
   325 definition (in topological_space) nhds :: "'a \<Rightarrow> 'a filter"
   326   where "nhds a = Abs_filter (\<lambda>P. \<exists>S. open S \<and> a \<in> S \<and> (\<forall>x\<in>S. P x))"
   327 
   328 definition (in topological_space) at :: "'a \<Rightarrow> 'a filter"
   329   where "at a = nhds a within - {a}"
   330 
   331 lemma eventually_within:
   332   "eventually P (F within S) = eventually (\<lambda>x. x \<in> S \<longrightarrow> P x) F"
   333   unfolding within_def
   334   by (rule eventually_Abs_filter, rule is_filter.intro)
   335      (auto elim!: eventually_rev_mp)
   336 
   337 lemma within_UNIV [simp]: "F within UNIV = F"
   338   unfolding filter_eq_iff eventually_within by simp
   339 
   340 lemma within_empty [simp]: "F within {} = bot"
   341   unfolding filter_eq_iff eventually_within by simp
   342 
   343 lemma eventually_nhds:
   344   "eventually P (nhds a) \<longleftrightarrow> (\<exists>S. open S \<and> a \<in> S \<and> (\<forall>x\<in>S. P x))"
   345 unfolding nhds_def
   346 proof (rule eventually_Abs_filter, rule is_filter.intro)
   347   have "open UNIV \<and> a \<in> UNIV \<and> (\<forall>x\<in>UNIV. True)" by simp
   348   thus "\<exists>S. open S \<and> a \<in> S \<and> (\<forall>x\<in>S. True)" by - rule
   349 next
   350   fix P Q
   351   assume "\<exists>S. open S \<and> a \<in> S \<and> (\<forall>x\<in>S. P x)"
   352      and "\<exists>T. open T \<and> a \<in> T \<and> (\<forall>x\<in>T. Q x)"
   353   then obtain S T where
   354     "open S \<and> a \<in> S \<and> (\<forall>x\<in>S. P x)"
   355     "open T \<and> a \<in> T \<and> (\<forall>x\<in>T. Q x)" by auto
   356   hence "open (S \<inter> T) \<and> a \<in> S \<inter> T \<and> (\<forall>x\<in>(S \<inter> T). P x \<and> Q x)"
   357     by (simp add: open_Int)
   358   thus "\<exists>S. open S \<and> a \<in> S \<and> (\<forall>x\<in>S. P x \<and> Q x)" by - rule
   359 qed auto
   360 
   361 lemma eventually_nhds_metric:
   362   "eventually P (nhds a) \<longleftrightarrow> (\<exists>d>0. \<forall>x. dist x a < d \<longrightarrow> P x)"
   363 unfolding eventually_nhds open_dist
   364 apply safe
   365 apply fast
   366 apply (rule_tac x="{x. dist x a < d}" in exI, simp)
   367 apply clarsimp
   368 apply (rule_tac x="d - dist x a" in exI, clarsimp)
   369 apply (simp only: less_diff_eq)
   370 apply (erule le_less_trans [OF dist_triangle])
   371 done
   372 
   373 lemma nhds_neq_bot [simp]: "nhds a \<noteq> bot"
   374   unfolding trivial_limit_def eventually_nhds by simp
   375 
   376 lemma eventually_at_topological:
   377   "eventually P (at a) \<longleftrightarrow> (\<exists>S. open S \<and> a \<in> S \<and> (\<forall>x\<in>S. x \<noteq> a \<longrightarrow> P x))"
   378 unfolding at_def eventually_within eventually_nhds by simp
   379 
   380 lemma eventually_at:
   381   fixes a :: "'a::metric_space"
   382   shows "eventually P (at a) \<longleftrightarrow> (\<exists>d>0. \<forall>x. x \<noteq> a \<and> dist x a < d \<longrightarrow> P x)"
   383 unfolding at_def eventually_within eventually_nhds_metric by auto
   384 
   385 lemma at_eq_bot_iff: "at a = bot \<longleftrightarrow> open {a}"
   386   unfolding trivial_limit_def eventually_at_topological
   387   by (safe, case_tac "S = {a}", simp, fast, fast)
   388 
   389 lemma at_neq_bot [simp]: "at (a::'a::perfect_space) \<noteq> bot"
   390   by (simp add: at_eq_bot_iff not_open_singleton)
   391 
   392 
   393 subsection {* Boundedness *}
   394 
   395 definition Bfun :: "('a \<Rightarrow> 'b::real_normed_vector) \<Rightarrow> 'a filter \<Rightarrow> bool"
   396   where "Bfun f F = (\<exists>K>0. eventually (\<lambda>x. norm (f x) \<le> K) F)"
   397 
   398 lemma BfunI:
   399   assumes K: "eventually (\<lambda>x. norm (f x) \<le> K) F" shows "Bfun f F"
   400 unfolding Bfun_def
   401 proof (intro exI conjI allI)
   402   show "0 < max K 1" by simp
   403 next
   404   show "eventually (\<lambda>x. norm (f x) \<le> max K 1) F"
   405     using K by (rule eventually_elim1, simp)
   406 qed
   407 
   408 lemma BfunE:
   409   assumes "Bfun f F"
   410   obtains B where "0 < B" and "eventually (\<lambda>x. norm (f x) \<le> B) F"
   411 using assms unfolding Bfun_def by fast
   412 
   413 
   414 subsection {* Convergence to Zero *}
   415 
   416 definition Zfun :: "('a \<Rightarrow> 'b::real_normed_vector) \<Rightarrow> 'a filter \<Rightarrow> bool"
   417   where "Zfun f F = (\<forall>r>0. eventually (\<lambda>x. norm (f x) < r) F)"
   418 
   419 lemma ZfunI:
   420   "(\<And>r. 0 < r \<Longrightarrow> eventually (\<lambda>x. norm (f x) < r) F) \<Longrightarrow> Zfun f F"
   421   unfolding Zfun_def by simp
   422 
   423 lemma ZfunD:
   424   "\<lbrakk>Zfun f F; 0 < r\<rbrakk> \<Longrightarrow> eventually (\<lambda>x. norm (f x) < r) F"
   425   unfolding Zfun_def by simp
   426 
   427 lemma Zfun_ssubst:
   428   "eventually (\<lambda>x. f x = g x) F \<Longrightarrow> Zfun g F \<Longrightarrow> Zfun f F"
   429   unfolding Zfun_def by (auto elim!: eventually_rev_mp)
   430 
   431 lemma Zfun_zero: "Zfun (\<lambda>x. 0) F"
   432   unfolding Zfun_def by simp
   433 
   434 lemma Zfun_norm_iff: "Zfun (\<lambda>x. norm (f x)) F = Zfun (\<lambda>x. f x) F"
   435   unfolding Zfun_def by simp
   436 
   437 lemma Zfun_imp_Zfun:
   438   assumes f: "Zfun f F"
   439   assumes g: "eventually (\<lambda>x. norm (g x) \<le> norm (f x) * K) F"
   440   shows "Zfun (\<lambda>x. g x) F"
   441 proof (cases)
   442   assume K: "0 < K"
   443   show ?thesis
   444   proof (rule ZfunI)
   445     fix r::real assume "0 < r"
   446     hence "0 < r / K"
   447       using K by (rule divide_pos_pos)
   448     then have "eventually (\<lambda>x. norm (f x) < r / K) F"
   449       using ZfunD [OF f] by fast
   450     with g show "eventually (\<lambda>x. norm (g x) < r) F"
   451     proof eventually_elim
   452       case (elim x)
   453       hence "norm (f x) * K < r"
   454         by (simp add: pos_less_divide_eq K)
   455       thus ?case
   456         by (simp add: order_le_less_trans [OF elim(1)])
   457     qed
   458   qed
   459 next
   460   assume "\<not> 0 < K"
   461   hence K: "K \<le> 0" by (simp only: not_less)
   462   show ?thesis
   463   proof (rule ZfunI)
   464     fix r :: real
   465     assume "0 < r"
   466     from g show "eventually (\<lambda>x. norm (g x) < r) F"
   467     proof eventually_elim
   468       case (elim x)
   469       also have "norm (f x) * K \<le> norm (f x) * 0"
   470         using K norm_ge_zero by (rule mult_left_mono)
   471       finally show ?case
   472         using `0 < r` by simp
   473     qed
   474   qed
   475 qed
   476 
   477 lemma Zfun_le: "\<lbrakk>Zfun g F; \<forall>x. norm (f x) \<le> norm (g x)\<rbrakk> \<Longrightarrow> Zfun f F"
   478   by (erule_tac K="1" in Zfun_imp_Zfun, simp)
   479 
   480 lemma Zfun_add:
   481   assumes f: "Zfun f F" and g: "Zfun g F"
   482   shows "Zfun (\<lambda>x. f x + g x) F"
   483 proof (rule ZfunI)
   484   fix r::real assume "0 < r"
   485   hence r: "0 < r / 2" by simp
   486   have "eventually (\<lambda>x. norm (f x) < r/2) F"
   487     using f r by (rule ZfunD)
   488   moreover
   489   have "eventually (\<lambda>x. norm (g x) < r/2) F"
   490     using g r by (rule ZfunD)
   491   ultimately
   492   show "eventually (\<lambda>x. norm (f x + g x) < r) F"
   493   proof eventually_elim
   494     case (elim x)
   495     have "norm (f x + g x) \<le> norm (f x) + norm (g x)"
   496       by (rule norm_triangle_ineq)
   497     also have "\<dots> < r/2 + r/2"
   498       using elim by (rule add_strict_mono)
   499     finally show ?case
   500       by simp
   501   qed
   502 qed
   503 
   504 lemma Zfun_minus: "Zfun f F \<Longrightarrow> Zfun (\<lambda>x. - f x) F"
   505   unfolding Zfun_def by simp
   506 
   507 lemma Zfun_diff: "\<lbrakk>Zfun f F; Zfun g F\<rbrakk> \<Longrightarrow> Zfun (\<lambda>x. f x - g x) F"
   508   by (simp only: diff_minus Zfun_add Zfun_minus)
   509 
   510 lemma (in bounded_linear) Zfun:
   511   assumes g: "Zfun g F"
   512   shows "Zfun (\<lambda>x. f (g x)) F"
   513 proof -
   514   obtain K where "\<And>x. norm (f x) \<le> norm x * K"
   515     using bounded by fast
   516   then have "eventually (\<lambda>x. norm (f (g x)) \<le> norm (g x) * K) F"
   517     by simp
   518   with g show ?thesis
   519     by (rule Zfun_imp_Zfun)
   520 qed
   521 
   522 lemma (in bounded_bilinear) Zfun:
   523   assumes f: "Zfun f F"
   524   assumes g: "Zfun g F"
   525   shows "Zfun (\<lambda>x. f x ** g x) F"
   526 proof (rule ZfunI)
   527   fix r::real assume r: "0 < r"
   528   obtain K where K: "0 < K"
   529     and norm_le: "\<And>x y. norm (x ** y) \<le> norm x * norm y * K"
   530     using pos_bounded by fast
   531   from K have K': "0 < inverse K"
   532     by (rule positive_imp_inverse_positive)
   533   have "eventually (\<lambda>x. norm (f x) < r) F"
   534     using f r by (rule ZfunD)
   535   moreover
   536   have "eventually (\<lambda>x. norm (g x) < inverse K) F"
   537     using g K' by (rule ZfunD)
   538   ultimately
   539   show "eventually (\<lambda>x. norm (f x ** g x) < r) F"
   540   proof eventually_elim
   541     case (elim x)
   542     have "norm (f x ** g x) \<le> norm (f x) * norm (g x) * K"
   543       by (rule norm_le)
   544     also have "norm (f x) * norm (g x) * K < r * inverse K * K"
   545       by (intro mult_strict_right_mono mult_strict_mono' norm_ge_zero elim K)
   546     also from K have "r * inverse K * K = r"
   547       by simp
   548     finally show ?case .
   549   qed
   550 qed
   551 
   552 lemma (in bounded_bilinear) Zfun_left:
   553   "Zfun f F \<Longrightarrow> Zfun (\<lambda>x. f x ** a) F"
   554   by (rule bounded_linear_left [THEN bounded_linear.Zfun])
   555 
   556 lemma (in bounded_bilinear) Zfun_right:
   557   "Zfun f F \<Longrightarrow> Zfun (\<lambda>x. a ** f x) F"
   558   by (rule bounded_linear_right [THEN bounded_linear.Zfun])
   559 
   560 lemmas Zfun_mult = bounded_bilinear.Zfun [OF bounded_bilinear_mult]
   561 lemmas Zfun_mult_right = bounded_bilinear.Zfun_right [OF bounded_bilinear_mult]
   562 lemmas Zfun_mult_left = bounded_bilinear.Zfun_left [OF bounded_bilinear_mult]
   563 
   564 
   565 subsection {* Limits *}
   566 
   567 definition (in topological_space)
   568   tendsto :: "('b \<Rightarrow> 'a) \<Rightarrow> 'a \<Rightarrow> 'b filter \<Rightarrow> bool" (infixr "--->" 55) where
   569   "(f ---> l) F \<longleftrightarrow> (\<forall>S. open S \<longrightarrow> l \<in> S \<longrightarrow> eventually (\<lambda>x. f x \<in> S) F)"
   570 
   571 definition real_tendsto_inf :: "('a \<Rightarrow> real) \<Rightarrow> 'a filter \<Rightarrow> bool" where
   572   "real_tendsto_inf f F \<equiv> \<forall>x. eventually (\<lambda>y. x < f y) F"
   573 
   574 ML {*
   575 structure Tendsto_Intros = Named_Thms
   576 (
   577   val name = @{binding tendsto_intros}
   578   val description = "introduction rules for tendsto"
   579 )
   580 *}
   581 
   582 setup Tendsto_Intros.setup
   583 
   584 lemma tendsto_mono: "F \<le> F' \<Longrightarrow> (f ---> l) F' \<Longrightarrow> (f ---> l) F"
   585   unfolding tendsto_def le_filter_def by fast
   586 
   587 lemma topological_tendstoI:
   588   "(\<And>S. open S \<Longrightarrow> l \<in> S \<Longrightarrow> eventually (\<lambda>x. f x \<in> S) F)
   589     \<Longrightarrow> (f ---> l) F"
   590   unfolding tendsto_def by auto
   591 
   592 lemma topological_tendstoD:
   593   "(f ---> l) F \<Longrightarrow> open S \<Longrightarrow> l \<in> S \<Longrightarrow> eventually (\<lambda>x. f x \<in> S) F"
   594   unfolding tendsto_def by auto
   595 
   596 lemma tendstoI:
   597   assumes "\<And>e. 0 < e \<Longrightarrow> eventually (\<lambda>x. dist (f x) l < e) F"
   598   shows "(f ---> l) F"
   599   apply (rule topological_tendstoI)
   600   apply (simp add: open_dist)
   601   apply (drule (1) bspec, clarify)
   602   apply (drule assms)
   603   apply (erule eventually_elim1, simp)
   604   done
   605 
   606 lemma tendstoD:
   607   "(f ---> l) F \<Longrightarrow> 0 < e \<Longrightarrow> eventually (\<lambda>x. dist (f x) l < e) F"
   608   apply (drule_tac S="{x. dist x l < e}" in topological_tendstoD)
   609   apply (clarsimp simp add: open_dist)
   610   apply (rule_tac x="e - dist x l" in exI, clarsimp)
   611   apply (simp only: less_diff_eq)
   612   apply (erule le_less_trans [OF dist_triangle])
   613   apply simp
   614   apply simp
   615   done
   616 
   617 lemma tendsto_iff:
   618   "(f ---> l) F \<longleftrightarrow> (\<forall>e>0. eventually (\<lambda>x. dist (f x) l < e) F)"
   619   using tendstoI tendstoD by fast
   620 
   621 lemma tendsto_Zfun_iff: "(f ---> a) F = Zfun (\<lambda>x. f x - a) F"
   622   by (simp only: tendsto_iff Zfun_def dist_norm)
   623 
   624 lemma tendsto_bot [simp]: "(f ---> a) bot"
   625   unfolding tendsto_def by simp
   626 
   627 lemma tendsto_ident_at [tendsto_intros]: "((\<lambda>x. x) ---> a) (at a)"
   628   unfolding tendsto_def eventually_at_topological by auto
   629 
   630 lemma tendsto_ident_at_within [tendsto_intros]:
   631   "((\<lambda>x. x) ---> a) (at a within S)"
   632   unfolding tendsto_def eventually_within eventually_at_topological by auto
   633 
   634 lemma tendsto_const [tendsto_intros]: "((\<lambda>x. k) ---> k) F"
   635   by (simp add: tendsto_def)
   636 
   637 lemma tendsto_unique:
   638   fixes f :: "'a \<Rightarrow> 'b::t2_space"
   639   assumes "\<not> trivial_limit F" and "(f ---> a) F" and "(f ---> b) F"
   640   shows "a = b"
   641 proof (rule ccontr)
   642   assume "a \<noteq> b"
   643   obtain U V where "open U" "open V" "a \<in> U" "b \<in> V" "U \<inter> V = {}"
   644     using hausdorff [OF `a \<noteq> b`] by fast
   645   have "eventually (\<lambda>x. f x \<in> U) F"
   646     using `(f ---> a) F` `open U` `a \<in> U` by (rule topological_tendstoD)
   647   moreover
   648   have "eventually (\<lambda>x. f x \<in> V) F"
   649     using `(f ---> b) F` `open V` `b \<in> V` by (rule topological_tendstoD)
   650   ultimately
   651   have "eventually (\<lambda>x. False) F"
   652   proof eventually_elim
   653     case (elim x)
   654     hence "f x \<in> U \<inter> V" by simp
   655     with `U \<inter> V = {}` show ?case by simp
   656   qed
   657   with `\<not> trivial_limit F` show "False"
   658     by (simp add: trivial_limit_def)
   659 qed
   660 
   661 lemma tendsto_const_iff:
   662   fixes a b :: "'a::t2_space"
   663   assumes "\<not> trivial_limit F" shows "((\<lambda>x. a) ---> b) F \<longleftrightarrow> a = b"
   664   by (safe intro!: tendsto_const tendsto_unique [OF assms tendsto_const])
   665 
   666 lemma tendsto_compose:
   667   assumes g: "(g ---> g l) (at l)"
   668   assumes f: "(f ---> l) F"
   669   shows "((\<lambda>x. g (f x)) ---> g l) F"
   670 proof (rule topological_tendstoI)
   671   fix B assume B: "open B" "g l \<in> B"
   672   obtain A where A: "open A" "l \<in> A"
   673     and gB: "\<forall>y. y \<in> A \<longrightarrow> g y \<in> B"
   674     using topological_tendstoD [OF g B] B(2)
   675     unfolding eventually_at_topological by fast
   676   hence "\<forall>x. f x \<in> A \<longrightarrow> g (f x) \<in> B" by simp
   677   from this topological_tendstoD [OF f A]
   678   show "eventually (\<lambda>x. g (f x) \<in> B) F"
   679     by (rule eventually_mono)
   680 qed
   681 
   682 lemma tendsto_compose_eventually:
   683   assumes g: "(g ---> m) (at l)"
   684   assumes f: "(f ---> l) F"
   685   assumes inj: "eventually (\<lambda>x. f x \<noteq> l) F"
   686   shows "((\<lambda>x. g (f x)) ---> m) F"
   687 proof (rule topological_tendstoI)
   688   fix B assume B: "open B" "m \<in> B"
   689   obtain A where A: "open A" "l \<in> A"
   690     and gB: "\<And>y. y \<in> A \<Longrightarrow> y \<noteq> l \<Longrightarrow> g y \<in> B"
   691     using topological_tendstoD [OF g B]
   692     unfolding eventually_at_topological by fast
   693   show "eventually (\<lambda>x. g (f x) \<in> B) F"
   694     using topological_tendstoD [OF f A] inj
   695     by (rule eventually_elim2) (simp add: gB)
   696 qed
   697 
   698 lemma metric_tendsto_imp_tendsto:
   699   assumes f: "(f ---> a) F"
   700   assumes le: "eventually (\<lambda>x. dist (g x) b \<le> dist (f x) a) F"
   701   shows "(g ---> b) F"
   702 proof (rule tendstoI)
   703   fix e :: real assume "0 < e"
   704   with f have "eventually (\<lambda>x. dist (f x) a < e) F" by (rule tendstoD)
   705   with le show "eventually (\<lambda>x. dist (g x) b < e) F"
   706     using le_less_trans by (rule eventually_elim2)
   707 qed
   708 
   709 lemma real_tendsto_inf_real: "real_tendsto_inf real sequentially"
   710 proof (unfold real_tendsto_inf_def, rule allI)
   711   fix x show "eventually (\<lambda>y. x < real y) sequentially"
   712     by (rule eventually_sequentiallyI[of "natceiling (x + 1)"])
   713         (simp add: natceiling_le_eq)
   714 qed
   715 
   716 
   717 
   718 subsubsection {* Distance and norms *}
   719 
   720 lemma tendsto_dist [tendsto_intros]:
   721   assumes f: "(f ---> l) F" and g: "(g ---> m) F"
   722   shows "((\<lambda>x. dist (f x) (g x)) ---> dist l m) F"
   723 proof (rule tendstoI)
   724   fix e :: real assume "0 < e"
   725   hence e2: "0 < e/2" by simp
   726   from tendstoD [OF f e2] tendstoD [OF g e2]
   727   show "eventually (\<lambda>x. dist (dist (f x) (g x)) (dist l m) < e) F"
   728   proof (eventually_elim)
   729     case (elim x)
   730     then show "dist (dist (f x) (g x)) (dist l m) < e"
   731       unfolding dist_real_def
   732       using dist_triangle2 [of "f x" "g x" "l"]
   733       using dist_triangle2 [of "g x" "l" "m"]
   734       using dist_triangle3 [of "l" "m" "f x"]
   735       using dist_triangle [of "f x" "m" "g x"]
   736       by arith
   737   qed
   738 qed
   739 
   740 lemma norm_conv_dist: "norm x = dist x 0"
   741   unfolding dist_norm by simp
   742 
   743 lemma tendsto_norm [tendsto_intros]:
   744   "(f ---> a) F \<Longrightarrow> ((\<lambda>x. norm (f x)) ---> norm a) F"
   745   unfolding norm_conv_dist by (intro tendsto_intros)
   746 
   747 lemma tendsto_norm_zero:
   748   "(f ---> 0) F \<Longrightarrow> ((\<lambda>x. norm (f x)) ---> 0) F"
   749   by (drule tendsto_norm, simp)
   750 
   751 lemma tendsto_norm_zero_cancel:
   752   "((\<lambda>x. norm (f x)) ---> 0) F \<Longrightarrow> (f ---> 0) F"
   753   unfolding tendsto_iff dist_norm by simp
   754 
   755 lemma tendsto_norm_zero_iff:
   756   "((\<lambda>x. norm (f x)) ---> 0) F \<longleftrightarrow> (f ---> 0) F"
   757   unfolding tendsto_iff dist_norm by simp
   758 
   759 lemma tendsto_rabs [tendsto_intros]:
   760   "(f ---> (l::real)) F \<Longrightarrow> ((\<lambda>x. \<bar>f x\<bar>) ---> \<bar>l\<bar>) F"
   761   by (fold real_norm_def, rule tendsto_norm)
   762 
   763 lemma tendsto_rabs_zero:
   764   "(f ---> (0::real)) F \<Longrightarrow> ((\<lambda>x. \<bar>f x\<bar>) ---> 0) F"
   765   by (fold real_norm_def, rule tendsto_norm_zero)
   766 
   767 lemma tendsto_rabs_zero_cancel:
   768   "((\<lambda>x. \<bar>f x\<bar>) ---> (0::real)) F \<Longrightarrow> (f ---> 0) F"
   769   by (fold real_norm_def, rule tendsto_norm_zero_cancel)
   770 
   771 lemma tendsto_rabs_zero_iff:
   772   "((\<lambda>x. \<bar>f x\<bar>) ---> (0::real)) F \<longleftrightarrow> (f ---> 0) F"
   773   by (fold real_norm_def, rule tendsto_norm_zero_iff)
   774 
   775 subsubsection {* Addition and subtraction *}
   776 
   777 lemma tendsto_add [tendsto_intros]:
   778   fixes a b :: "'a::real_normed_vector"
   779   shows "\<lbrakk>(f ---> a) F; (g ---> b) F\<rbrakk> \<Longrightarrow> ((\<lambda>x. f x + g x) ---> a + b) F"
   780   by (simp only: tendsto_Zfun_iff add_diff_add Zfun_add)
   781 
   782 lemma tendsto_add_zero:
   783   fixes f g :: "'a::type \<Rightarrow> 'b::real_normed_vector"
   784   shows "\<lbrakk>(f ---> 0) F; (g ---> 0) F\<rbrakk> \<Longrightarrow> ((\<lambda>x. f x + g x) ---> 0) F"
   785   by (drule (1) tendsto_add, simp)
   786 
   787 lemma tendsto_minus [tendsto_intros]:
   788   fixes a :: "'a::real_normed_vector"
   789   shows "(f ---> a) F \<Longrightarrow> ((\<lambda>x. - f x) ---> - a) F"
   790   by (simp only: tendsto_Zfun_iff minus_diff_minus Zfun_minus)
   791 
   792 lemma tendsto_minus_cancel:
   793   fixes a :: "'a::real_normed_vector"
   794   shows "((\<lambda>x. - f x) ---> - a) F \<Longrightarrow> (f ---> a) F"
   795   by (drule tendsto_minus, simp)
   796 
   797 lemma tendsto_diff [tendsto_intros]:
   798   fixes a b :: "'a::real_normed_vector"
   799   shows "\<lbrakk>(f ---> a) F; (g ---> b) F\<rbrakk> \<Longrightarrow> ((\<lambda>x. f x - g x) ---> a - b) F"
   800   by (simp add: diff_minus tendsto_add tendsto_minus)
   801 
   802 lemma tendsto_setsum [tendsto_intros]:
   803   fixes f :: "'a \<Rightarrow> 'b \<Rightarrow> 'c::real_normed_vector"
   804   assumes "\<And>i. i \<in> S \<Longrightarrow> (f i ---> a i) F"
   805   shows "((\<lambda>x. \<Sum>i\<in>S. f i x) ---> (\<Sum>i\<in>S. a i)) F"
   806 proof (cases "finite S")
   807   assume "finite S" thus ?thesis using assms
   808     by (induct, simp add: tendsto_const, simp add: tendsto_add)
   809 next
   810   assume "\<not> finite S" thus ?thesis
   811     by (simp add: tendsto_const)
   812 qed
   813 
   814 lemma real_tendsto_sandwich:
   815   fixes f g h :: "'a \<Rightarrow> real"
   816   assumes ev: "eventually (\<lambda>n. f n \<le> g n) net" "eventually (\<lambda>n. g n \<le> h n) net"
   817   assumes lim: "(f ---> c) net" "(h ---> c) net"
   818   shows "(g ---> c) net"
   819 proof -
   820   have "((\<lambda>n. g n - f n) ---> 0) net"
   821   proof (rule metric_tendsto_imp_tendsto)
   822     show "eventually (\<lambda>n. dist (g n - f n) 0 \<le> dist (h n - f n) 0) net"
   823       using ev by (rule eventually_elim2) (simp add: dist_real_def)
   824     show "((\<lambda>n. h n - f n) ---> 0) net"
   825       using tendsto_diff[OF lim(2,1)] by simp
   826   qed
   827   from tendsto_add[OF this lim(1)] show ?thesis by simp
   828 qed
   829 
   830 subsubsection {* Linear operators and multiplication *}
   831 
   832 lemma (in bounded_linear) tendsto:
   833   "(g ---> a) F \<Longrightarrow> ((\<lambda>x. f (g x)) ---> f a) F"
   834   by (simp only: tendsto_Zfun_iff diff [symmetric] Zfun)
   835 
   836 lemma (in bounded_linear) tendsto_zero:
   837   "(g ---> 0) F \<Longrightarrow> ((\<lambda>x. f (g x)) ---> 0) F"
   838   by (drule tendsto, simp only: zero)
   839 
   840 lemma (in bounded_bilinear) tendsto:
   841   "\<lbrakk>(f ---> a) F; (g ---> b) F\<rbrakk> \<Longrightarrow> ((\<lambda>x. f x ** g x) ---> a ** b) F"
   842   by (simp only: tendsto_Zfun_iff prod_diff_prod
   843                  Zfun_add Zfun Zfun_left Zfun_right)
   844 
   845 lemma (in bounded_bilinear) tendsto_zero:
   846   assumes f: "(f ---> 0) F"
   847   assumes g: "(g ---> 0) F"
   848   shows "((\<lambda>x. f x ** g x) ---> 0) F"
   849   using tendsto [OF f g] by (simp add: zero_left)
   850 
   851 lemma (in bounded_bilinear) tendsto_left_zero:
   852   "(f ---> 0) F \<Longrightarrow> ((\<lambda>x. f x ** c) ---> 0) F"
   853   by (rule bounded_linear.tendsto_zero [OF bounded_linear_left])
   854 
   855 lemma (in bounded_bilinear) tendsto_right_zero:
   856   "(f ---> 0) F \<Longrightarrow> ((\<lambda>x. c ** f x) ---> 0) F"
   857   by (rule bounded_linear.tendsto_zero [OF bounded_linear_right])
   858 
   859 lemmas tendsto_of_real [tendsto_intros] =
   860   bounded_linear.tendsto [OF bounded_linear_of_real]
   861 
   862 lemmas tendsto_scaleR [tendsto_intros] =
   863   bounded_bilinear.tendsto [OF bounded_bilinear_scaleR]
   864 
   865 lemmas tendsto_mult [tendsto_intros] =
   866   bounded_bilinear.tendsto [OF bounded_bilinear_mult]
   867 
   868 lemmas tendsto_mult_zero =
   869   bounded_bilinear.tendsto_zero [OF bounded_bilinear_mult]
   870 
   871 lemmas tendsto_mult_left_zero =
   872   bounded_bilinear.tendsto_left_zero [OF bounded_bilinear_mult]
   873 
   874 lemmas tendsto_mult_right_zero =
   875   bounded_bilinear.tendsto_right_zero [OF bounded_bilinear_mult]
   876 
   877 lemma tendsto_power [tendsto_intros]:
   878   fixes f :: "'a \<Rightarrow> 'b::{power,real_normed_algebra}"
   879   shows "(f ---> a) F \<Longrightarrow> ((\<lambda>x. f x ^ n) ---> a ^ n) F"
   880   by (induct n) (simp_all add: tendsto_const tendsto_mult)
   881 
   882 lemma tendsto_setprod [tendsto_intros]:
   883   fixes f :: "'a \<Rightarrow> 'b \<Rightarrow> 'c::{real_normed_algebra,comm_ring_1}"
   884   assumes "\<And>i. i \<in> S \<Longrightarrow> (f i ---> L i) F"
   885   shows "((\<lambda>x. \<Prod>i\<in>S. f i x) ---> (\<Prod>i\<in>S. L i)) F"
   886 proof (cases "finite S")
   887   assume "finite S" thus ?thesis using assms
   888     by (induct, simp add: tendsto_const, simp add: tendsto_mult)
   889 next
   890   assume "\<not> finite S" thus ?thesis
   891     by (simp add: tendsto_const)
   892 qed
   893 
   894 subsubsection {* Inverse and division *}
   895 
   896 lemma (in bounded_bilinear) Zfun_prod_Bfun:
   897   assumes f: "Zfun f F"
   898   assumes g: "Bfun g F"
   899   shows "Zfun (\<lambda>x. f x ** g x) F"
   900 proof -
   901   obtain K where K: "0 \<le> K"
   902     and norm_le: "\<And>x y. norm (x ** y) \<le> norm x * norm y * K"
   903     using nonneg_bounded by fast
   904   obtain B where B: "0 < B"
   905     and norm_g: "eventually (\<lambda>x. norm (g x) \<le> B) F"
   906     using g by (rule BfunE)
   907   have "eventually (\<lambda>x. norm (f x ** g x) \<le> norm (f x) * (B * K)) F"
   908   using norm_g proof eventually_elim
   909     case (elim x)
   910     have "norm (f x ** g x) \<le> norm (f x) * norm (g x) * K"
   911       by (rule norm_le)
   912     also have "\<dots> \<le> norm (f x) * B * K"
   913       by (intro mult_mono' order_refl norm_g norm_ge_zero
   914                 mult_nonneg_nonneg K elim)
   915     also have "\<dots> = norm (f x) * (B * K)"
   916       by (rule mult_assoc)
   917     finally show "norm (f x ** g x) \<le> norm (f x) * (B * K)" .
   918   qed
   919   with f show ?thesis
   920     by (rule Zfun_imp_Zfun)
   921 qed
   922 
   923 lemma (in bounded_bilinear) flip:
   924   "bounded_bilinear (\<lambda>x y. y ** x)"
   925   apply default
   926   apply (rule add_right)
   927   apply (rule add_left)
   928   apply (rule scaleR_right)
   929   apply (rule scaleR_left)
   930   apply (subst mult_commute)
   931   using bounded by fast
   932 
   933 lemma (in bounded_bilinear) Bfun_prod_Zfun:
   934   assumes f: "Bfun f F"
   935   assumes g: "Zfun g F"
   936   shows "Zfun (\<lambda>x. f x ** g x) F"
   937   using flip g f by (rule bounded_bilinear.Zfun_prod_Bfun)
   938 
   939 lemma Bfun_inverse_lemma:
   940   fixes x :: "'a::real_normed_div_algebra"
   941   shows "\<lbrakk>r \<le> norm x; 0 < r\<rbrakk> \<Longrightarrow> norm (inverse x) \<le> inverse r"
   942   apply (subst nonzero_norm_inverse, clarsimp)
   943   apply (erule (1) le_imp_inverse_le)
   944   done
   945 
   946 lemma Bfun_inverse:
   947   fixes a :: "'a::real_normed_div_algebra"
   948   assumes f: "(f ---> a) F"
   949   assumes a: "a \<noteq> 0"
   950   shows "Bfun (\<lambda>x. inverse (f x)) F"
   951 proof -
   952   from a have "0 < norm a" by simp
   953   hence "\<exists>r>0. r < norm a" by (rule dense)
   954   then obtain r where r1: "0 < r" and r2: "r < norm a" by fast
   955   have "eventually (\<lambda>x. dist (f x) a < r) F"
   956     using tendstoD [OF f r1] by fast
   957   hence "eventually (\<lambda>x. norm (inverse (f x)) \<le> inverse (norm a - r)) F"
   958   proof eventually_elim
   959     case (elim x)
   960     hence 1: "norm (f x - a) < r"
   961       by (simp add: dist_norm)
   962     hence 2: "f x \<noteq> 0" using r2 by auto
   963     hence "norm (inverse (f x)) = inverse (norm (f x))"
   964       by (rule nonzero_norm_inverse)
   965     also have "\<dots> \<le> inverse (norm a - r)"
   966     proof (rule le_imp_inverse_le)
   967       show "0 < norm a - r" using r2 by simp
   968     next
   969       have "norm a - norm (f x) \<le> norm (a - f x)"
   970         by (rule norm_triangle_ineq2)
   971       also have "\<dots> = norm (f x - a)"
   972         by (rule norm_minus_commute)
   973       also have "\<dots> < r" using 1 .
   974       finally show "norm a - r \<le> norm (f x)" by simp
   975     qed
   976     finally show "norm (inverse (f x)) \<le> inverse (norm a - r)" .
   977   qed
   978   thus ?thesis by (rule BfunI)
   979 qed
   980 
   981 lemma tendsto_inverse [tendsto_intros]:
   982   fixes a :: "'a::real_normed_div_algebra"
   983   assumes f: "(f ---> a) F"
   984   assumes a: "a \<noteq> 0"
   985   shows "((\<lambda>x. inverse (f x)) ---> inverse a) F"
   986 proof -
   987   from a have "0 < norm a" by simp
   988   with f have "eventually (\<lambda>x. dist (f x) a < norm a) F"
   989     by (rule tendstoD)
   990   then have "eventually (\<lambda>x. f x \<noteq> 0) F"
   991     unfolding dist_norm by (auto elim!: eventually_elim1)
   992   with a have "eventually (\<lambda>x. inverse (f x) - inverse a =
   993     - (inverse (f x) * (f x - a) * inverse a)) F"
   994     by (auto elim!: eventually_elim1 simp: inverse_diff_inverse)
   995   moreover have "Zfun (\<lambda>x. - (inverse (f x) * (f x - a) * inverse a)) F"
   996     by (intro Zfun_minus Zfun_mult_left
   997       bounded_bilinear.Bfun_prod_Zfun [OF bounded_bilinear_mult]
   998       Bfun_inverse [OF f a] f [unfolded tendsto_Zfun_iff])
   999   ultimately show ?thesis
  1000     unfolding tendsto_Zfun_iff by (rule Zfun_ssubst)
  1001 qed
  1002 
  1003 lemma tendsto_divide [tendsto_intros]:
  1004   fixes a b :: "'a::real_normed_field"
  1005   shows "\<lbrakk>(f ---> a) F; (g ---> b) F; b \<noteq> 0\<rbrakk>
  1006     \<Longrightarrow> ((\<lambda>x. f x / g x) ---> a / b) F"
  1007   by (simp add: tendsto_mult tendsto_inverse divide_inverse)
  1008 
  1009 lemma tendsto_sgn [tendsto_intros]:
  1010   fixes l :: "'a::real_normed_vector"
  1011   shows "\<lbrakk>(f ---> l) F; l \<noteq> 0\<rbrakk> \<Longrightarrow> ((\<lambda>x. sgn (f x)) ---> sgn l) F"
  1012   unfolding sgn_div_norm by (simp add: tendsto_intros)
  1013 
  1014 end