src/HOL/Power.thy
author wenzelm
Thu May 24 17:25:53 2012 +0200 (2012-05-24)
changeset 47988 e4b69e10b990
parent 47255 30a1692557b0
child 49824 c26665a197dc
permissions -rw-r--r--
tuned proofs;
     1 (*  Title:      HOL/Power.thy
     2     Author:     Lawrence C Paulson, Cambridge University Computer Laboratory
     3     Copyright   1997  University of Cambridge
     4 *)
     5 
     6 header {* Exponentiation *}
     7 
     8 theory Power
     9 imports Num
    10 begin
    11 
    12 subsection {* Powers for Arbitrary Monoids *}
    13 
    14 class power = one + times
    15 begin
    16 
    17 primrec power :: "'a \<Rightarrow> nat \<Rightarrow> 'a" (infixr "^" 80) where
    18     power_0: "a ^ 0 = 1"
    19   | power_Suc: "a ^ Suc n = a * a ^ n"
    20 
    21 notation (latex output)
    22   power ("(_\<^bsup>_\<^esup>)" [1000] 1000)
    23 
    24 notation (HTML output)
    25   power ("(_\<^bsup>_\<^esup>)" [1000] 1000)
    26 
    27 text {* Special syntax for squares. *}
    28 
    29 abbreviation (xsymbols)
    30   power2 :: "'a \<Rightarrow> 'a"  ("(_\<twosuperior>)" [1000] 999) where
    31   "x\<twosuperior> \<equiv> x ^ 2"
    32 
    33 notation (latex output)
    34   power2  ("(_\<twosuperior>)" [1000] 999)
    35 
    36 notation (HTML output)
    37   power2  ("(_\<twosuperior>)" [1000] 999)
    38 
    39 end
    40 
    41 context monoid_mult
    42 begin
    43 
    44 subclass power .
    45 
    46 lemma power_one [simp]:
    47   "1 ^ n = 1"
    48   by (induct n) simp_all
    49 
    50 lemma power_one_right [simp]:
    51   "a ^ 1 = a"
    52   by simp
    53 
    54 lemma power_commutes:
    55   "a ^ n * a = a * a ^ n"
    56   by (induct n) (simp_all add: mult_assoc)
    57 
    58 lemma power_Suc2:
    59   "a ^ Suc n = a ^ n * a"
    60   by (simp add: power_commutes)
    61 
    62 lemma power_add:
    63   "a ^ (m + n) = a ^ m * a ^ n"
    64   by (induct m) (simp_all add: algebra_simps)
    65 
    66 lemma power_mult:
    67   "a ^ (m * n) = (a ^ m) ^ n"
    68   by (induct n) (simp_all add: power_add)
    69 
    70 lemma power2_eq_square: "a\<twosuperior> = a * a"
    71   by (simp add: numeral_2_eq_2)
    72 
    73 lemma power3_eq_cube: "a ^ 3 = a * a * a"
    74   by (simp add: numeral_3_eq_3 mult_assoc)
    75 
    76 lemma power_even_eq:
    77   "a ^ (2*n) = (a ^ n) ^ 2"
    78   by (subst mult_commute) (simp add: power_mult)
    79 
    80 lemma power_odd_eq:
    81   "a ^ Suc (2*n) = a * (a ^ n) ^ 2"
    82   by (simp add: power_even_eq)
    83 
    84 lemma power_numeral_even:
    85   "z ^ numeral (Num.Bit0 w) = (let w = z ^ (numeral w) in w * w)"
    86   unfolding numeral_Bit0 power_add Let_def ..
    87 
    88 lemma power_numeral_odd:
    89   "z ^ numeral (Num.Bit1 w) = (let w = z ^ (numeral w) in z * w * w)"
    90   unfolding numeral_Bit1 One_nat_def add_Suc_right add_0_right
    91   unfolding power_Suc power_add Let_def mult_assoc ..
    92 
    93 end
    94 
    95 context comm_monoid_mult
    96 begin
    97 
    98 lemma power_mult_distrib:
    99   "(a * b) ^ n = (a ^ n) * (b ^ n)"
   100   by (induct n) (simp_all add: mult_ac)
   101 
   102 end
   103 
   104 context semiring_numeral
   105 begin
   106 
   107 lemma numeral_sqr: "numeral (Num.sqr k) = numeral k * numeral k"
   108   by (simp only: sqr_conv_mult numeral_mult)
   109 
   110 lemma numeral_pow: "numeral (Num.pow k l) = numeral k ^ numeral l"
   111   by (induct l, simp_all only: numeral_class.numeral.simps pow.simps
   112     numeral_sqr numeral_mult power_add power_one_right)
   113 
   114 lemma power_numeral [simp]: "numeral k ^ numeral l = numeral (Num.pow k l)"
   115   by (rule numeral_pow [symmetric])
   116 
   117 end
   118 
   119 context semiring_1
   120 begin
   121 
   122 lemma of_nat_power:
   123   "of_nat (m ^ n) = of_nat m ^ n"
   124   by (induct n) (simp_all add: of_nat_mult)
   125 
   126 lemma power_zero_numeral [simp]: "(0::'a) ^ numeral k = 0"
   127   by (simp add: numeral_eq_Suc)
   128 
   129 lemma zero_power2: "0\<twosuperior> = 0" (* delete? *)
   130   by (rule power_zero_numeral)
   131 
   132 lemma one_power2: "1\<twosuperior> = 1" (* delete? *)
   133   by (rule power_one)
   134 
   135 end
   136 
   137 context comm_semiring_1
   138 begin
   139 
   140 text {* The divides relation *}
   141 
   142 lemma le_imp_power_dvd:
   143   assumes "m \<le> n" shows "a ^ m dvd a ^ n"
   144 proof
   145   have "a ^ n = a ^ (m + (n - m))"
   146     using `m \<le> n` by simp
   147   also have "\<dots> = a ^ m * a ^ (n - m)"
   148     by (rule power_add)
   149   finally show "a ^ n = a ^ m * a ^ (n - m)" .
   150 qed
   151 
   152 lemma power_le_dvd:
   153   "a ^ n dvd b \<Longrightarrow> m \<le> n \<Longrightarrow> a ^ m dvd b"
   154   by (rule dvd_trans [OF le_imp_power_dvd])
   155 
   156 lemma dvd_power_same:
   157   "x dvd y \<Longrightarrow> x ^ n dvd y ^ n"
   158   by (induct n) (auto simp add: mult_dvd_mono)
   159 
   160 lemma dvd_power_le:
   161   "x dvd y \<Longrightarrow> m \<ge> n \<Longrightarrow> x ^ n dvd y ^ m"
   162   by (rule power_le_dvd [OF dvd_power_same])
   163 
   164 lemma dvd_power [simp]:
   165   assumes "n > (0::nat) \<or> x = 1"
   166   shows "x dvd (x ^ n)"
   167 using assms proof
   168   assume "0 < n"
   169   then have "x ^ n = x ^ Suc (n - 1)" by simp
   170   then show "x dvd (x ^ n)" by simp
   171 next
   172   assume "x = 1"
   173   then show "x dvd (x ^ n)" by simp
   174 qed
   175 
   176 end
   177 
   178 context ring_1
   179 begin
   180 
   181 lemma power_minus:
   182   "(- a) ^ n = (- 1) ^ n * a ^ n"
   183 proof (induct n)
   184   case 0 show ?case by simp
   185 next
   186   case (Suc n) then show ?case
   187     by (simp del: power_Suc add: power_Suc2 mult_assoc)
   188 qed
   189 
   190 lemma power_minus_Bit0:
   191   "(- x) ^ numeral (Num.Bit0 k) = x ^ numeral (Num.Bit0 k)"
   192   by (induct k, simp_all only: numeral_class.numeral.simps power_add
   193     power_one_right mult_minus_left mult_minus_right minus_minus)
   194 
   195 lemma power_minus_Bit1:
   196   "(- x) ^ numeral (Num.Bit1 k) = - (x ^ numeral (Num.Bit1 k))"
   197   by (simp only: eval_nat_numeral(3) power_Suc power_minus_Bit0 mult_minus_left)
   198 
   199 lemma power_neg_numeral_Bit0 [simp]:
   200   "neg_numeral k ^ numeral (Num.Bit0 l) = numeral (Num.pow k (Num.Bit0 l))"
   201   by (simp only: neg_numeral_def power_minus_Bit0 power_numeral)
   202 
   203 lemma power_neg_numeral_Bit1 [simp]:
   204   "neg_numeral k ^ numeral (Num.Bit1 l) = neg_numeral (Num.pow k (Num.Bit1 l))"
   205   by (simp only: neg_numeral_def power_minus_Bit1 power_numeral pow.simps)
   206 
   207 lemma power2_minus [simp]:
   208   "(- a)\<twosuperior> = a\<twosuperior>"
   209   by (rule power_minus_Bit0)
   210 
   211 lemma power_minus1_even [simp]:
   212   "-1 ^ (2*n) = 1"
   213 proof (induct n)
   214   case 0 show ?case by simp
   215 next
   216   case (Suc n) then show ?case by (simp add: power_add power2_eq_square)
   217 qed
   218 
   219 lemma power_minus1_odd:
   220   "-1 ^ Suc (2*n) = -1"
   221   by simp
   222 
   223 lemma power_minus_even [simp]:
   224   "(-a) ^ (2*n) = a ^ (2*n)"
   225   by (simp add: power_minus [of a])
   226 
   227 end
   228 
   229 context ring_1_no_zero_divisors
   230 begin
   231 
   232 lemma field_power_not_zero:
   233   "a \<noteq> 0 \<Longrightarrow> a ^ n \<noteq> 0"
   234   by (induct n) auto
   235 
   236 lemma zero_eq_power2 [simp]:
   237   "a\<twosuperior> = 0 \<longleftrightarrow> a = 0"
   238   unfolding power2_eq_square by simp
   239 
   240 lemma power2_eq_1_iff:
   241   "a\<twosuperior> = 1 \<longleftrightarrow> a = 1 \<or> a = - 1"
   242   unfolding power2_eq_square by (rule square_eq_1_iff)
   243 
   244 end
   245 
   246 context idom
   247 begin
   248 
   249 lemma power2_eq_iff: "x\<twosuperior> = y\<twosuperior> \<longleftrightarrow> x = y \<or> x = - y"
   250   unfolding power2_eq_square by (rule square_eq_iff)
   251 
   252 end
   253 
   254 context division_ring
   255 begin
   256 
   257 text {* FIXME reorient or rename to @{text nonzero_inverse_power} *}
   258 lemma nonzero_power_inverse:
   259   "a \<noteq> 0 \<Longrightarrow> inverse (a ^ n) = (inverse a) ^ n"
   260   by (induct n)
   261     (simp_all add: nonzero_inverse_mult_distrib power_commutes field_power_not_zero)
   262 
   263 end
   264 
   265 context field
   266 begin
   267 
   268 lemma nonzero_power_divide:
   269   "b \<noteq> 0 \<Longrightarrow> (a / b) ^ n = a ^ n / b ^ n"
   270   by (simp add: divide_inverse power_mult_distrib nonzero_power_inverse)
   271 
   272 end
   273 
   274 
   275 subsection {* Exponentiation on ordered types *}
   276 
   277 context linordered_ring (* TODO: move *)
   278 begin
   279 
   280 lemma sum_squares_ge_zero:
   281   "0 \<le> x * x + y * y"
   282   by (intro add_nonneg_nonneg zero_le_square)
   283 
   284 lemma not_sum_squares_lt_zero:
   285   "\<not> x * x + y * y < 0"
   286   by (simp add: not_less sum_squares_ge_zero)
   287 
   288 end
   289 
   290 context linordered_semidom
   291 begin
   292 
   293 lemma zero_less_power [simp]:
   294   "0 < a \<Longrightarrow> 0 < a ^ n"
   295   by (induct n) (simp_all add: mult_pos_pos)
   296 
   297 lemma zero_le_power [simp]:
   298   "0 \<le> a \<Longrightarrow> 0 \<le> a ^ n"
   299   by (induct n) (simp_all add: mult_nonneg_nonneg)
   300 
   301 lemma power_mono:
   302   "a \<le> b \<Longrightarrow> 0 \<le> a \<Longrightarrow> a ^ n \<le> b ^ n"
   303   by (induct n) (auto intro: mult_mono order_trans [of 0 a b])
   304 
   305 lemma one_le_power [simp]: "1 \<le> a \<Longrightarrow> 1 \<le> a ^ n"
   306   using power_mono [of 1 a n] by simp
   307 
   308 lemma power_le_one: "\<lbrakk>0 \<le> a; a \<le> 1\<rbrakk> \<Longrightarrow> a ^ n \<le> 1"
   309   using power_mono [of a 1 n] by simp
   310 
   311 lemma power_gt1_lemma:
   312   assumes gt1: "1 < a"
   313   shows "1 < a * a ^ n"
   314 proof -
   315   from gt1 have "0 \<le> a"
   316     by (fact order_trans [OF zero_le_one less_imp_le])
   317   have "1 * 1 < a * 1" using gt1 by simp
   318   also have "\<dots> \<le> a * a ^ n" using gt1
   319     by (simp only: mult_mono `0 \<le> a` one_le_power order_less_imp_le
   320         zero_le_one order_refl)
   321   finally show ?thesis by simp
   322 qed
   323 
   324 lemma power_gt1:
   325   "1 < a \<Longrightarrow> 1 < a ^ Suc n"
   326   by (simp add: power_gt1_lemma)
   327 
   328 lemma one_less_power [simp]:
   329   "1 < a \<Longrightarrow> 0 < n \<Longrightarrow> 1 < a ^ n"
   330   by (cases n) (simp_all add: power_gt1_lemma)
   331 
   332 lemma power_le_imp_le_exp:
   333   assumes gt1: "1 < a"
   334   shows "a ^ m \<le> a ^ n \<Longrightarrow> m \<le> n"
   335 proof (induct m arbitrary: n)
   336   case 0
   337   show ?case by simp
   338 next
   339   case (Suc m)
   340   show ?case
   341   proof (cases n)
   342     case 0
   343     with Suc.prems Suc.hyps have "a * a ^ m \<le> 1" by simp
   344     with gt1 show ?thesis
   345       by (force simp only: power_gt1_lemma
   346           not_less [symmetric])
   347   next
   348     case (Suc n)
   349     with Suc.prems Suc.hyps show ?thesis
   350       by (force dest: mult_left_le_imp_le
   351           simp add: less_trans [OF zero_less_one gt1])
   352   qed
   353 qed
   354 
   355 text{*Surely we can strengthen this? It holds for @{text "0<a<1"} too.*}
   356 lemma power_inject_exp [simp]:
   357   "1 < a \<Longrightarrow> a ^ m = a ^ n \<longleftrightarrow> m = n"
   358   by (force simp add: order_antisym power_le_imp_le_exp)
   359 
   360 text{*Can relax the first premise to @{term "0<a"} in the case of the
   361 natural numbers.*}
   362 lemma power_less_imp_less_exp:
   363   "1 < a \<Longrightarrow> a ^ m < a ^ n \<Longrightarrow> m < n"
   364   by (simp add: order_less_le [of m n] less_le [of "a^m" "a^n"]
   365     power_le_imp_le_exp)
   366 
   367 lemma power_strict_mono [rule_format]:
   368   "a < b \<Longrightarrow> 0 \<le> a \<Longrightarrow> 0 < n \<longrightarrow> a ^ n < b ^ n"
   369   by (induct n)
   370    (auto simp add: mult_strict_mono le_less_trans [of 0 a b])
   371 
   372 text{*Lemma for @{text power_strict_decreasing}*}
   373 lemma power_Suc_less:
   374   "0 < a \<Longrightarrow> a < 1 \<Longrightarrow> a * a ^ n < a ^ n"
   375   by (induct n)
   376     (auto simp add: mult_strict_left_mono)
   377 
   378 lemma power_strict_decreasing [rule_format]:
   379   "n < N \<Longrightarrow> 0 < a \<Longrightarrow> a < 1 \<longrightarrow> a ^ N < a ^ n"
   380 proof (induct N)
   381   case 0 then show ?case by simp
   382 next
   383   case (Suc N) then show ?case 
   384   apply (auto simp add: power_Suc_less less_Suc_eq)
   385   apply (subgoal_tac "a * a^N < 1 * a^n")
   386   apply simp
   387   apply (rule mult_strict_mono) apply auto
   388   done
   389 qed
   390 
   391 text{*Proof resembles that of @{text power_strict_decreasing}*}
   392 lemma power_decreasing [rule_format]:
   393   "n \<le> N \<Longrightarrow> 0 \<le> a \<Longrightarrow> a \<le> 1 \<longrightarrow> a ^ N \<le> a ^ n"
   394 proof (induct N)
   395   case 0 then show ?case by simp
   396 next
   397   case (Suc N) then show ?case 
   398   apply (auto simp add: le_Suc_eq)
   399   apply (subgoal_tac "a * a^N \<le> 1 * a^n", simp)
   400   apply (rule mult_mono) apply auto
   401   done
   402 qed
   403 
   404 lemma power_Suc_less_one:
   405   "0 < a \<Longrightarrow> a < 1 \<Longrightarrow> a ^ Suc n < 1"
   406   using power_strict_decreasing [of 0 "Suc n" a] by simp
   407 
   408 text{*Proof again resembles that of @{text power_strict_decreasing}*}
   409 lemma power_increasing [rule_format]:
   410   "n \<le> N \<Longrightarrow> 1 \<le> a \<Longrightarrow> a ^ n \<le> a ^ N"
   411 proof (induct N)
   412   case 0 then show ?case by simp
   413 next
   414   case (Suc N) then show ?case 
   415   apply (auto simp add: le_Suc_eq)
   416   apply (subgoal_tac "1 * a^n \<le> a * a^N", simp)
   417   apply (rule mult_mono) apply (auto simp add: order_trans [OF zero_le_one])
   418   done
   419 qed
   420 
   421 text{*Lemma for @{text power_strict_increasing}*}
   422 lemma power_less_power_Suc:
   423   "1 < a \<Longrightarrow> a ^ n < a * a ^ n"
   424   by (induct n) (auto simp add: mult_strict_left_mono less_trans [OF zero_less_one])
   425 
   426 lemma power_strict_increasing [rule_format]:
   427   "n < N \<Longrightarrow> 1 < a \<longrightarrow> a ^ n < a ^ N"
   428 proof (induct N)
   429   case 0 then show ?case by simp
   430 next
   431   case (Suc N) then show ?case 
   432   apply (auto simp add: power_less_power_Suc less_Suc_eq)
   433   apply (subgoal_tac "1 * a^n < a * a^N", simp)
   434   apply (rule mult_strict_mono) apply (auto simp add: less_trans [OF zero_less_one] less_imp_le)
   435   done
   436 qed
   437 
   438 lemma power_increasing_iff [simp]:
   439   "1 < b \<Longrightarrow> b ^ x \<le> b ^ y \<longleftrightarrow> x \<le> y"
   440   by (blast intro: power_le_imp_le_exp power_increasing less_imp_le)
   441 
   442 lemma power_strict_increasing_iff [simp]:
   443   "1 < b \<Longrightarrow> b ^ x < b ^ y \<longleftrightarrow> x < y"
   444 by (blast intro: power_less_imp_less_exp power_strict_increasing) 
   445 
   446 lemma power_le_imp_le_base:
   447   assumes le: "a ^ Suc n \<le> b ^ Suc n"
   448     and ynonneg: "0 \<le> b"
   449   shows "a \<le> b"
   450 proof (rule ccontr)
   451   assume "~ a \<le> b"
   452   then have "b < a" by (simp only: linorder_not_le)
   453   then have "b ^ Suc n < a ^ Suc n"
   454     by (simp only: assms power_strict_mono)
   455   from le and this show False
   456     by (simp add: linorder_not_less [symmetric])
   457 qed
   458 
   459 lemma power_less_imp_less_base:
   460   assumes less: "a ^ n < b ^ n"
   461   assumes nonneg: "0 \<le> b"
   462   shows "a < b"
   463 proof (rule contrapos_pp [OF less])
   464   assume "~ a < b"
   465   hence "b \<le> a" by (simp only: linorder_not_less)
   466   hence "b ^ n \<le> a ^ n" using nonneg by (rule power_mono)
   467   thus "\<not> a ^ n < b ^ n" by (simp only: linorder_not_less)
   468 qed
   469 
   470 lemma power_inject_base:
   471   "a ^ Suc n = b ^ Suc n \<Longrightarrow> 0 \<le> a \<Longrightarrow> 0 \<le> b \<Longrightarrow> a = b"
   472 by (blast intro: power_le_imp_le_base antisym eq_refl sym)
   473 
   474 lemma power_eq_imp_eq_base:
   475   "a ^ n = b ^ n \<Longrightarrow> 0 \<le> a \<Longrightarrow> 0 \<le> b \<Longrightarrow> 0 < n \<Longrightarrow> a = b"
   476   by (cases n) (simp_all del: power_Suc, rule power_inject_base)
   477 
   478 lemma power2_le_imp_le:
   479   "x\<twosuperior> \<le> y\<twosuperior> \<Longrightarrow> 0 \<le> y \<Longrightarrow> x \<le> y"
   480   unfolding numeral_2_eq_2 by (rule power_le_imp_le_base)
   481 
   482 lemma power2_less_imp_less:
   483   "x\<twosuperior> < y\<twosuperior> \<Longrightarrow> 0 \<le> y \<Longrightarrow> x < y"
   484   by (rule power_less_imp_less_base)
   485 
   486 lemma power2_eq_imp_eq:
   487   "x\<twosuperior> = y\<twosuperior> \<Longrightarrow> 0 \<le> x \<Longrightarrow> 0 \<le> y \<Longrightarrow> x = y"
   488   unfolding numeral_2_eq_2 by (erule (2) power_eq_imp_eq_base) simp
   489 
   490 end
   491 
   492 context linordered_ring_strict
   493 begin
   494 
   495 lemma sum_squares_eq_zero_iff:
   496   "x * x + y * y = 0 \<longleftrightarrow> x = 0 \<and> y = 0"
   497   by (simp add: add_nonneg_eq_0_iff)
   498 
   499 lemma sum_squares_le_zero_iff:
   500   "x * x + y * y \<le> 0 \<longleftrightarrow> x = 0 \<and> y = 0"
   501   by (simp add: le_less not_sum_squares_lt_zero sum_squares_eq_zero_iff)
   502 
   503 lemma sum_squares_gt_zero_iff:
   504   "0 < x * x + y * y \<longleftrightarrow> x \<noteq> 0 \<or> y \<noteq> 0"
   505   by (simp add: not_le [symmetric] sum_squares_le_zero_iff)
   506 
   507 end
   508 
   509 context linordered_idom
   510 begin
   511 
   512 lemma power_abs:
   513   "abs (a ^ n) = abs a ^ n"
   514   by (induct n) (auto simp add: abs_mult)
   515 
   516 lemma abs_power_minus [simp]:
   517   "abs ((-a) ^ n) = abs (a ^ n)"
   518   by (simp add: power_abs)
   519 
   520 lemma zero_less_power_abs_iff [simp, no_atp]:
   521   "0 < abs a ^ n \<longleftrightarrow> a \<noteq> 0 \<or> n = 0"
   522 proof (induct n)
   523   case 0 show ?case by simp
   524 next
   525   case (Suc n) show ?case by (auto simp add: Suc zero_less_mult_iff)
   526 qed
   527 
   528 lemma zero_le_power_abs [simp]:
   529   "0 \<le> abs a ^ n"
   530   by (rule zero_le_power [OF abs_ge_zero])
   531 
   532 lemma zero_le_power2 [simp]:
   533   "0 \<le> a\<twosuperior>"
   534   by (simp add: power2_eq_square)
   535 
   536 lemma zero_less_power2 [simp]:
   537   "0 < a\<twosuperior> \<longleftrightarrow> a \<noteq> 0"
   538   by (force simp add: power2_eq_square zero_less_mult_iff linorder_neq_iff)
   539 
   540 lemma power2_less_0 [simp]:
   541   "\<not> a\<twosuperior> < 0"
   542   by (force simp add: power2_eq_square mult_less_0_iff)
   543 
   544 lemma abs_power2 [simp]:
   545   "abs (a\<twosuperior>) = a\<twosuperior>"
   546   by (simp add: power2_eq_square abs_mult abs_mult_self)
   547 
   548 lemma power2_abs [simp]:
   549   "(abs a)\<twosuperior> = a\<twosuperior>"
   550   by (simp add: power2_eq_square abs_mult_self)
   551 
   552 lemma odd_power_less_zero:
   553   "a < 0 \<Longrightarrow> a ^ Suc (2*n) < 0"
   554 proof (induct n)
   555   case 0
   556   then show ?case by simp
   557 next
   558   case (Suc n)
   559   have "a ^ Suc (2 * Suc n) = (a*a) * a ^ Suc(2*n)"
   560     by (simp add: mult_ac power_add power2_eq_square)
   561   thus ?case
   562     by (simp del: power_Suc add: Suc mult_less_0_iff mult_neg_neg)
   563 qed
   564 
   565 lemma odd_0_le_power_imp_0_le:
   566   "0 \<le> a ^ Suc (2*n) \<Longrightarrow> 0 \<le> a"
   567   using odd_power_less_zero [of a n]
   568     by (force simp add: linorder_not_less [symmetric]) 
   569 
   570 lemma zero_le_even_power'[simp]:
   571   "0 \<le> a ^ (2*n)"
   572 proof (induct n)
   573   case 0
   574     show ?case by simp
   575 next
   576   case (Suc n)
   577     have "a ^ (2 * Suc n) = (a*a) * a ^ (2*n)" 
   578       by (simp add: mult_ac power_add power2_eq_square)
   579     thus ?case
   580       by (simp add: Suc zero_le_mult_iff)
   581 qed
   582 
   583 lemma sum_power2_ge_zero:
   584   "0 \<le> x\<twosuperior> + y\<twosuperior>"
   585   by (intro add_nonneg_nonneg zero_le_power2)
   586 
   587 lemma not_sum_power2_lt_zero:
   588   "\<not> x\<twosuperior> + y\<twosuperior> < 0"
   589   unfolding not_less by (rule sum_power2_ge_zero)
   590 
   591 lemma sum_power2_eq_zero_iff:
   592   "x\<twosuperior> + y\<twosuperior> = 0 \<longleftrightarrow> x = 0 \<and> y = 0"
   593   unfolding power2_eq_square by (simp add: add_nonneg_eq_0_iff)
   594 
   595 lemma sum_power2_le_zero_iff:
   596   "x\<twosuperior> + y\<twosuperior> \<le> 0 \<longleftrightarrow> x = 0 \<and> y = 0"
   597   by (simp add: le_less sum_power2_eq_zero_iff not_sum_power2_lt_zero)
   598 
   599 lemma sum_power2_gt_zero_iff:
   600   "0 < x\<twosuperior> + y\<twosuperior> \<longleftrightarrow> x \<noteq> 0 \<or> y \<noteq> 0"
   601   unfolding not_le [symmetric] by (simp add: sum_power2_le_zero_iff)
   602 
   603 end
   604 
   605 
   606 subsection {* Miscellaneous rules *}
   607 
   608 lemma power_eq_if: "p ^ m = (if m=0 then 1 else p * (p ^ (m - 1)))"
   609   unfolding One_nat_def by (cases m) simp_all
   610 
   611 lemma power2_sum:
   612   fixes x y :: "'a::comm_semiring_1"
   613   shows "(x + y)\<twosuperior> = x\<twosuperior> + y\<twosuperior> + 2 * x * y"
   614   by (simp add: algebra_simps power2_eq_square mult_2_right)
   615 
   616 lemma power2_diff:
   617   fixes x y :: "'a::comm_ring_1"
   618   shows "(x - y)\<twosuperior> = x\<twosuperior> + y\<twosuperior> - 2 * x * y"
   619   by (simp add: ring_distribs power2_eq_square mult_2) (rule mult_commute)
   620 
   621 lemma power_0_Suc [simp]:
   622   "(0::'a::{power, semiring_0}) ^ Suc n = 0"
   623   by simp
   624 
   625 text{*It looks plausible as a simprule, but its effect can be strange.*}
   626 lemma power_0_left:
   627   "0 ^ n = (if n = 0 then 1 else (0::'a::{power, semiring_0}))"
   628   by (induct n) simp_all
   629 
   630 lemma power_eq_0_iff [simp]:
   631   "a ^ n = 0 \<longleftrightarrow>
   632      a = (0::'a::{mult_zero,zero_neq_one,no_zero_divisors,power}) \<and> n \<noteq> 0"
   633   by (induct n)
   634     (auto simp add: no_zero_divisors elim: contrapos_pp)
   635 
   636 lemma (in field) power_diff:
   637   assumes nz: "a \<noteq> 0"
   638   shows "n \<le> m \<Longrightarrow> a ^ (m - n) = a ^ m / a ^ n"
   639   by (induct m n rule: diff_induct) (simp_all add: nz field_power_not_zero)
   640 
   641 text{*Perhaps these should be simprules.*}
   642 lemma power_inverse:
   643   fixes a :: "'a::division_ring_inverse_zero"
   644   shows "inverse (a ^ n) = inverse a ^ n"
   645 apply (cases "a = 0")
   646 apply (simp add: power_0_left)
   647 apply (simp add: nonzero_power_inverse)
   648 done (* TODO: reorient or rename to inverse_power *)
   649 
   650 lemma power_one_over:
   651   "1 / (a::'a::{field_inverse_zero, power}) ^ n =  (1 / a) ^ n"
   652   by (simp add: divide_inverse) (rule power_inverse)
   653 
   654 lemma power_divide:
   655   "(a / b) ^ n = (a::'a::field_inverse_zero) ^ n / b ^ n"
   656 apply (cases "b = 0")
   657 apply (simp add: power_0_left)
   658 apply (rule nonzero_power_divide)
   659 apply assumption
   660 done
   661 
   662 text {* Simprules for comparisons where common factors can be cancelled. *}
   663 
   664 lemmas zero_compare_simps =
   665     add_strict_increasing add_strict_increasing2 add_increasing
   666     zero_le_mult_iff zero_le_divide_iff 
   667     zero_less_mult_iff zero_less_divide_iff 
   668     mult_le_0_iff divide_le_0_iff 
   669     mult_less_0_iff divide_less_0_iff 
   670     zero_le_power2 power2_less_0
   671 
   672 
   673 subsection {* Exponentiation for the Natural Numbers *}
   674 
   675 lemma nat_one_le_power [simp]:
   676   "Suc 0 \<le> i \<Longrightarrow> Suc 0 \<le> i ^ n"
   677   by (rule one_le_power [of i n, unfolded One_nat_def])
   678 
   679 lemma nat_zero_less_power_iff [simp]:
   680   "x ^ n > 0 \<longleftrightarrow> x > (0::nat) \<or> n = 0"
   681   by (induct n) auto
   682 
   683 lemma nat_power_eq_Suc_0_iff [simp]: 
   684   "x ^ m = Suc 0 \<longleftrightarrow> m = 0 \<or> x = Suc 0"
   685   by (induct m) auto
   686 
   687 lemma power_Suc_0 [simp]:
   688   "Suc 0 ^ n = Suc 0"
   689   by simp
   690 
   691 text{*Valid for the naturals, but what if @{text"0<i<1"}?
   692 Premises cannot be weakened: consider the case where @{term "i=0"},
   693 @{term "m=1"} and @{term "n=0"}.*}
   694 lemma nat_power_less_imp_less:
   695   assumes nonneg: "0 < (i\<Colon>nat)"
   696   assumes less: "i ^ m < i ^ n"
   697   shows "m < n"
   698 proof (cases "i = 1")
   699   case True with less power_one [where 'a = nat] show ?thesis by simp
   700 next
   701   case False with nonneg have "1 < i" by auto
   702   from power_strict_increasing_iff [OF this] less show ?thesis ..
   703 qed
   704 
   705 lemma power_dvd_imp_le:
   706   "i ^ m dvd i ^ n \<Longrightarrow> (1::nat) < i \<Longrightarrow> m \<le> n"
   707   apply (rule power_le_imp_le_exp, assumption)
   708   apply (erule dvd_imp_le, simp)
   709   done
   710 
   711 
   712 subsection {* Code generator tweak *}
   713 
   714 lemma power_power_power [code]:
   715   "power = power.power (1::'a::{power}) (op *)"
   716   unfolding power_def power.power_def ..
   717 
   718 declare power.power.simps [code]
   719 
   720 code_modulename SML
   721   Power Arith
   722 
   723 code_modulename OCaml
   724   Power Arith
   725 
   726 code_modulename Haskell
   727   Power Arith
   728 
   729 end