src/HOL/Semiring_Normalization.thy
author wenzelm
Thu May 24 17:25:53 2012 +0200 (2012-05-24)
changeset 47988 e4b69e10b990
parent 47108 2a1953f0d20d
child 48891 c0eafbd55de3
permissions -rw-r--r--
tuned proofs;
     1 (*  Title:      HOL/Semiring_Normalization.thy
     2     Author:     Amine Chaieb, TU Muenchen
     3 *)
     4 
     5 header {* Semiring normalization *}
     6 
     7 theory Semiring_Normalization
     8 imports Numeral_Simprocs Nat_Transfer
     9 uses
    10   "Tools/semiring_normalizer.ML"
    11 begin
    12 
    13 text {* Prelude *}
    14 
    15 class comm_semiring_1_cancel_crossproduct = comm_semiring_1_cancel +
    16   assumes crossproduct_eq: "w * y + x * z = w * z + x * y \<longleftrightarrow> w = x \<or> y = z"
    17 begin
    18 
    19 lemma crossproduct_noteq:
    20   "a \<noteq> b \<and> c \<noteq> d \<longleftrightarrow> a * c + b * d \<noteq> a * d + b * c"
    21   by (simp add: crossproduct_eq)
    22 
    23 lemma add_scale_eq_noteq:
    24   "r \<noteq> 0 \<Longrightarrow> a = b \<and> c \<noteq> d \<Longrightarrow> a + r * c \<noteq> b + r * d"
    25 proof (rule notI)
    26   assume nz: "r\<noteq> 0" and cnd: "a = b \<and> c\<noteq>d"
    27     and eq: "a + (r * c) = b + (r * d)"
    28   have "(0 * d) + (r * c) = (0 * c) + (r * d)"
    29     using add_imp_eq eq mult_zero_left by (simp add: cnd)
    30   then show False using crossproduct_eq [of 0 d] nz cnd by simp
    31 qed
    32 
    33 lemma add_0_iff:
    34   "b = b + a \<longleftrightarrow> a = 0"
    35   using add_imp_eq [of b a 0] by auto
    36 
    37 end
    38 
    39 subclass (in idom) comm_semiring_1_cancel_crossproduct
    40 proof
    41   fix w x y z
    42   show "w * y + x * z = w * z + x * y \<longleftrightarrow> w = x \<or> y = z"
    43   proof
    44     assume "w * y + x * z = w * z + x * y"
    45     then have "w * y + x * z - w * z - x * y = 0" by (simp add: algebra_simps)
    46     then have "w * (y - z) - x * (y - z) = 0" by (simp add: algebra_simps)
    47     then have "(y - z) * (w - x) = 0" by (simp add: algebra_simps)
    48     then have "y - z = 0 \<or> w - x = 0" by (rule divisors_zero)
    49     then show "w = x \<or> y = z" by auto
    50   qed (auto simp add: add_ac)
    51 qed
    52 
    53 instance nat :: comm_semiring_1_cancel_crossproduct
    54 proof
    55   fix w x y z :: nat
    56   have aux: "\<And>y z. y < z \<Longrightarrow> w * y + x * z = w * z + x * y \<Longrightarrow> w = x"
    57   proof -
    58     fix y z :: nat
    59     assume "y < z" then have "\<exists>k. z = y + k \<and> k \<noteq> 0" by (intro exI [of _ "z - y"]) auto
    60     then obtain k where "z = y + k" and "k \<noteq> 0" by blast
    61     assume "w * y + x * z = w * z + x * y"
    62     then have "(w * y + x * y) + x * k = (w * y + x * y) + w * k" by (simp add: `z = y + k` algebra_simps)
    63     then have "x * k = w * k" by simp
    64     then show "w = x" using `k \<noteq> 0` by simp
    65   qed
    66   show "w * y + x * z = w * z + x * y \<longleftrightarrow> w = x \<or> y = z"
    67     by (auto simp add: neq_iff dest!: aux)
    68 qed
    69 
    70 text {* Semiring normalization proper *}
    71 
    72 setup Semiring_Normalizer.setup
    73 
    74 context comm_semiring_1
    75 begin
    76 
    77 lemma normalizing_semiring_ops:
    78   shows "TERM (x + y)" and "TERM (x * y)" and "TERM (x ^ n)"
    79     and "TERM 0" and "TERM 1" .
    80 
    81 lemma normalizing_semiring_rules:
    82   "(a * m) + (b * m) = (a + b) * m"
    83   "(a * m) + m = (a + 1) * m"
    84   "m + (a * m) = (a + 1) * m"
    85   "m + m = (1 + 1) * m"
    86   "0 + a = a"
    87   "a + 0 = a"
    88   "a * b = b * a"
    89   "(a + b) * c = (a * c) + (b * c)"
    90   "0 * a = 0"
    91   "a * 0 = 0"
    92   "1 * a = a"
    93   "a * 1 = a"
    94   "(lx * ly) * (rx * ry) = (lx * rx) * (ly * ry)"
    95   "(lx * ly) * (rx * ry) = lx * (ly * (rx * ry))"
    96   "(lx * ly) * (rx * ry) = rx * ((lx * ly) * ry)"
    97   "(lx * ly) * rx = (lx * rx) * ly"
    98   "(lx * ly) * rx = lx * (ly * rx)"
    99   "lx * (rx * ry) = (lx * rx) * ry"
   100   "lx * (rx * ry) = rx * (lx * ry)"
   101   "(a + b) + (c + d) = (a + c) + (b + d)"
   102   "(a + b) + c = a + (b + c)"
   103   "a + (c + d) = c + (a + d)"
   104   "(a + b) + c = (a + c) + b"
   105   "a + c = c + a"
   106   "a + (c + d) = (a + c) + d"
   107   "(x ^ p) * (x ^ q) = x ^ (p + q)"
   108   "x * (x ^ q) = x ^ (Suc q)"
   109   "(x ^ q) * x = x ^ (Suc q)"
   110   "x * x = x ^ 2"
   111   "(x * y) ^ q = (x ^ q) * (y ^ q)"
   112   "(x ^ p) ^ q = x ^ (p * q)"
   113   "x ^ 0 = 1"
   114   "x ^ 1 = x"
   115   "x * (y + z) = (x * y) + (x * z)"
   116   "x ^ (Suc q) = x * (x ^ q)"
   117   "x ^ (2*n) = (x ^ n) * (x ^ n)"
   118   "x ^ (Suc (2*n)) = x * ((x ^ n) * (x ^ n))"
   119   by (simp_all add: algebra_simps power_add power2_eq_square
   120     power_mult_distrib power_mult del: one_add_one)
   121 
   122 lemmas normalizing_comm_semiring_1_axioms =
   123   comm_semiring_1_axioms [normalizer
   124     semiring ops: normalizing_semiring_ops
   125     semiring rules: normalizing_semiring_rules]
   126 
   127 declaration
   128   {* Semiring_Normalizer.semiring_funs @{thm normalizing_comm_semiring_1_axioms} *}
   129 
   130 end
   131 
   132 context comm_ring_1
   133 begin
   134 
   135 lemma normalizing_ring_ops: shows "TERM (x- y)" and "TERM (- x)" .
   136 
   137 lemma normalizing_ring_rules:
   138   "- x = (- 1) * x"
   139   "x - y = x + (- y)"
   140   by (simp_all add: diff_minus)
   141 
   142 lemmas normalizing_comm_ring_1_axioms =
   143   comm_ring_1_axioms [normalizer
   144     semiring ops: normalizing_semiring_ops
   145     semiring rules: normalizing_semiring_rules
   146     ring ops: normalizing_ring_ops
   147     ring rules: normalizing_ring_rules]
   148 
   149 declaration
   150   {* Semiring_Normalizer.semiring_funs @{thm normalizing_comm_ring_1_axioms} *}
   151 
   152 end
   153 
   154 context comm_semiring_1_cancel_crossproduct
   155 begin
   156 
   157 declare
   158   normalizing_comm_semiring_1_axioms [normalizer del]
   159 
   160 lemmas
   161   normalizing_comm_semiring_1_cancel_crossproduct_axioms =
   162   comm_semiring_1_cancel_crossproduct_axioms [normalizer
   163     semiring ops: normalizing_semiring_ops
   164     semiring rules: normalizing_semiring_rules
   165     idom rules: crossproduct_noteq add_scale_eq_noteq]
   166 
   167 declaration
   168   {* Semiring_Normalizer.semiring_funs @{thm normalizing_comm_semiring_1_cancel_crossproduct_axioms} *}
   169 
   170 end
   171 
   172 context idom
   173 begin
   174 
   175 declare normalizing_comm_ring_1_axioms [normalizer del]
   176 
   177 lemmas normalizing_idom_axioms = idom_axioms [normalizer
   178   semiring ops: normalizing_semiring_ops
   179   semiring rules: normalizing_semiring_rules
   180   ring ops: normalizing_ring_ops
   181   ring rules: normalizing_ring_rules
   182   idom rules: crossproduct_noteq add_scale_eq_noteq
   183   ideal rules: right_minus_eq add_0_iff]
   184 
   185 declaration
   186   {* Semiring_Normalizer.semiring_funs @{thm normalizing_idom_axioms} *}
   187 
   188 end
   189 
   190 context field
   191 begin
   192 
   193 lemma normalizing_field_ops:
   194   shows "TERM (x / y)" and "TERM (inverse x)" .
   195 
   196 lemmas normalizing_field_rules = divide_inverse inverse_eq_divide
   197 
   198 lemmas normalizing_field_axioms =
   199   field_axioms [normalizer
   200     semiring ops: normalizing_semiring_ops
   201     semiring rules: normalizing_semiring_rules
   202     ring ops: normalizing_ring_ops
   203     ring rules: normalizing_ring_rules
   204     field ops: normalizing_field_ops
   205     field rules: normalizing_field_rules
   206     idom rules: crossproduct_noteq add_scale_eq_noteq
   207     ideal rules: right_minus_eq add_0_iff]
   208 
   209 declaration
   210   {* Semiring_Normalizer.field_funs @{thm normalizing_field_axioms} *}
   211 
   212 end
   213 
   214 hide_fact (open) normalizing_comm_semiring_1_axioms
   215   normalizing_comm_semiring_1_cancel_crossproduct_axioms normalizing_semiring_ops normalizing_semiring_rules
   216 
   217 hide_fact (open) normalizing_comm_ring_1_axioms
   218   normalizing_idom_axioms normalizing_ring_ops normalizing_ring_rules
   219 
   220 hide_fact (open) normalizing_field_axioms normalizing_field_ops normalizing_field_rules
   221 
   222 code_modulename SML
   223   Semiring_Normalization Arith
   224 
   225 code_modulename OCaml
   226   Semiring_Normalization Arith
   227 
   228 code_modulename Haskell
   229   Semiring_Normalization Arith
   230 
   231 end