src/HOL/Transcendental.thy
author wenzelm
Thu May 24 17:25:53 2012 +0200 (2012-05-24)
changeset 47988 e4b69e10b990
parent 47489 04e7d09ade7a
child 49962 a8cc904a6820
permissions -rw-r--r--
tuned proofs;
     1 (*  Title:      HOL/Transcendental.thy
     2     Author:     Jacques D. Fleuriot, University of Cambridge, University of Edinburgh
     3     Author:     Lawrence C Paulson
     4 *)
     5 
     6 header{*Power Series, Transcendental Functions etc.*}
     7 
     8 theory Transcendental
     9 imports Fact Series Deriv NthRoot
    10 begin
    11 
    12 subsection {* Properties of Power Series *}
    13 
    14 lemma lemma_realpow_diff:
    15   fixes y :: "'a::monoid_mult"
    16   shows "p \<le> n \<Longrightarrow> y ^ (Suc n - p) = (y ^ (n - p)) * y"
    17 proof -
    18   assume "p \<le> n"
    19   hence "Suc n - p = Suc (n - p)" by (rule Suc_diff_le)
    20   thus ?thesis by (simp add: power_commutes)
    21 qed
    22 
    23 lemma lemma_realpow_diff_sumr:
    24   fixes y :: "'a::{comm_semiring_0,monoid_mult}" shows
    25      "(\<Sum>p=0..<Suc n. (x ^ p) * y ^ (Suc n - p)) =
    26       y * (\<Sum>p=0..<Suc n. (x ^ p) * y ^ (n - p))"
    27 by (simp add: setsum_right_distrib lemma_realpow_diff mult_ac
    28          del: setsum_op_ivl_Suc)
    29 
    30 lemma lemma_realpow_diff_sumr2:
    31   fixes y :: "'a::{comm_ring,monoid_mult}" shows
    32      "x ^ (Suc n) - y ^ (Suc n) =
    33       (x - y) * (\<Sum>p=0..<Suc n. (x ^ p) * y ^ (n - p))"
    34 apply (induct n, simp)
    35 apply (simp del: setsum_op_ivl_Suc)
    36 apply (subst setsum_op_ivl_Suc)
    37 apply (subst lemma_realpow_diff_sumr)
    38 apply (simp add: right_distrib del: setsum_op_ivl_Suc)
    39 apply (subst mult_left_commute [of "x - y"])
    40 apply (erule subst)
    41 apply (simp add: algebra_simps)
    42 done
    43 
    44 lemma lemma_realpow_rev_sumr:
    45      "(\<Sum>p=0..<Suc n. (x ^ p) * (y ^ (n - p))) =
    46       (\<Sum>p=0..<Suc n. (x ^ (n - p)) * (y ^ p))"
    47 apply (rule setsum_reindex_cong [where f="\<lambda>i. n - i"])
    48 apply (rule inj_onI, simp)
    49 apply auto
    50 apply (rule_tac x="n - x" in image_eqI, simp, simp)
    51 done
    52 
    53 text{*Power series has a `circle` of convergence, i.e. if it sums for @{term
    54 x}, then it sums absolutely for @{term z} with @{term "\<bar>z\<bar> < \<bar>x\<bar>"}.*}
    55 
    56 lemma powser_insidea:
    57   fixes x z :: "'a::real_normed_field"
    58   assumes 1: "summable (\<lambda>n. f n * x ^ n)"
    59   assumes 2: "norm z < norm x"
    60   shows "summable (\<lambda>n. norm (f n * z ^ n))"
    61 proof -
    62   from 2 have x_neq_0: "x \<noteq> 0" by clarsimp
    63   from 1 have "(\<lambda>n. f n * x ^ n) ----> 0"
    64     by (rule summable_LIMSEQ_zero)
    65   hence "convergent (\<lambda>n. f n * x ^ n)"
    66     by (rule convergentI)
    67   hence "Cauchy (\<lambda>n. f n * x ^ n)"
    68     by (rule convergent_Cauchy)
    69   hence "Bseq (\<lambda>n. f n * x ^ n)"
    70     by (rule Cauchy_Bseq)
    71   then obtain K where 3: "0 < K" and 4: "\<forall>n. norm (f n * x ^ n) \<le> K"
    72     by (simp add: Bseq_def, safe)
    73   have "\<exists>N. \<forall>n\<ge>N. norm (norm (f n * z ^ n)) \<le>
    74                    K * norm (z ^ n) * inverse (norm (x ^ n))"
    75   proof (intro exI allI impI)
    76     fix n::nat assume "0 \<le> n"
    77     have "norm (norm (f n * z ^ n)) * norm (x ^ n) =
    78           norm (f n * x ^ n) * norm (z ^ n)"
    79       by (simp add: norm_mult abs_mult)
    80     also have "\<dots> \<le> K * norm (z ^ n)"
    81       by (simp only: mult_right_mono 4 norm_ge_zero)
    82     also have "\<dots> = K * norm (z ^ n) * (inverse (norm (x ^ n)) * norm (x ^ n))"
    83       by (simp add: x_neq_0)
    84     also have "\<dots> = K * norm (z ^ n) * inverse (norm (x ^ n)) * norm (x ^ n)"
    85       by (simp only: mult_assoc)
    86     finally show "norm (norm (f n * z ^ n)) \<le>
    87                   K * norm (z ^ n) * inverse (norm (x ^ n))"
    88       by (simp add: mult_le_cancel_right x_neq_0)
    89   qed
    90   moreover have "summable (\<lambda>n. K * norm (z ^ n) * inverse (norm (x ^ n)))"
    91   proof -
    92     from 2 have "norm (norm (z * inverse x)) < 1"
    93       using x_neq_0
    94       by (simp add: nonzero_norm_divide divide_inverse [symmetric])
    95     hence "summable (\<lambda>n. norm (z * inverse x) ^ n)"
    96       by (rule summable_geometric)
    97     hence "summable (\<lambda>n. K * norm (z * inverse x) ^ n)"
    98       by (rule summable_mult)
    99     thus "summable (\<lambda>n. K * norm (z ^ n) * inverse (norm (x ^ n)))"
   100       using x_neq_0
   101       by (simp add: norm_mult nonzero_norm_inverse power_mult_distrib
   102                     power_inverse norm_power mult_assoc)
   103   qed
   104   ultimately show "summable (\<lambda>n. norm (f n * z ^ n))"
   105     by (rule summable_comparison_test)
   106 qed
   107 
   108 lemma powser_inside:
   109   fixes f :: "nat \<Rightarrow> 'a::{real_normed_field,banach}" shows
   110      "[| summable (%n. f(n) * (x ^ n)); norm z < norm x |]
   111       ==> summable (%n. f(n) * (z ^ n))"
   112 by (rule powser_insidea [THEN summable_norm_cancel])
   113 
   114 lemma sum_split_even_odd: fixes f :: "nat \<Rightarrow> real" shows
   115   "(\<Sum> i = 0 ..< 2 * n. if even i then f i else g i) =
   116    (\<Sum> i = 0 ..< n. f (2 * i)) + (\<Sum> i = 0 ..< n. g (2 * i + 1))"
   117 proof (induct n)
   118   case (Suc n)
   119   have "(\<Sum> i = 0 ..< 2 * Suc n. if even i then f i else g i) =
   120         (\<Sum> i = 0 ..< n. f (2 * i)) + (\<Sum> i = 0 ..< n. g (2 * i + 1)) + (f (2 * n) + g (2 * n + 1))"
   121     using Suc.hyps unfolding One_nat_def by auto
   122   also have "\<dots> = (\<Sum> i = 0 ..< Suc n. f (2 * i)) + (\<Sum> i = 0 ..< Suc n. g (2 * i + 1))" by auto
   123   finally show ?case .
   124 qed auto
   125 
   126 lemma sums_if': fixes g :: "nat \<Rightarrow> real" assumes "g sums x"
   127   shows "(\<lambda> n. if even n then 0 else g ((n - 1) div 2)) sums x"
   128   unfolding sums_def
   129 proof (rule LIMSEQ_I)
   130   fix r :: real assume "0 < r"
   131   from `g sums x`[unfolded sums_def, THEN LIMSEQ_D, OF this]
   132   obtain no where no_eq: "\<And> n. n \<ge> no \<Longrightarrow> (norm (setsum g { 0..<n } - x) < r)" by blast
   133 
   134   let ?SUM = "\<lambda> m. \<Sum> i = 0 ..< m. if even i then 0 else g ((i - 1) div 2)"
   135   { fix m assume "m \<ge> 2 * no" hence "m div 2 \<ge> no" by auto
   136     have sum_eq: "?SUM (2 * (m div 2)) = setsum g { 0 ..< m div 2 }"
   137       using sum_split_even_odd by auto
   138     hence "(norm (?SUM (2 * (m div 2)) - x) < r)" using no_eq unfolding sum_eq using `m div 2 \<ge> no` by auto
   139     moreover
   140     have "?SUM (2 * (m div 2)) = ?SUM m"
   141     proof (cases "even m")
   142       case True show ?thesis unfolding even_nat_div_two_times_two[OF True, unfolded numeral_2_eq_2[symmetric]] ..
   143     next
   144       case False hence "even (Suc m)" by auto
   145       from even_nat_div_two_times_two[OF this, unfolded numeral_2_eq_2[symmetric]] odd_nat_plus_one_div_two[OF False, unfolded numeral_2_eq_2[symmetric]]
   146       have eq: "Suc (2 * (m div 2)) = m" by auto
   147       hence "even (2 * (m div 2))" using `odd m` by auto
   148       have "?SUM m = ?SUM (Suc (2 * (m div 2)))" unfolding eq ..
   149       also have "\<dots> = ?SUM (2 * (m div 2))" using `even (2 * (m div 2))` by auto
   150       finally show ?thesis by auto
   151     qed
   152     ultimately have "(norm (?SUM m - x) < r)" by auto
   153   }
   154   thus "\<exists> no. \<forall> m \<ge> no. norm (?SUM m - x) < r" by blast
   155 qed
   156 
   157 lemma sums_if: fixes g :: "nat \<Rightarrow> real" assumes "g sums x" and "f sums y"
   158   shows "(\<lambda> n. if even n then f (n div 2) else g ((n - 1) div 2)) sums (x + y)"
   159 proof -
   160   let ?s = "\<lambda> n. if even n then 0 else f ((n - 1) div 2)"
   161   { fix B T E have "(if B then (0 :: real) else E) + (if B then T else 0) = (if B then T else E)"
   162       by (cases B) auto } note if_sum = this
   163   have g_sums: "(\<lambda> n. if even n then 0 else g ((n - 1) div 2)) sums x" using sums_if'[OF `g sums x`] .
   164   {
   165     have "?s 0 = 0" by auto
   166     have Suc_m1: "\<And> n. Suc n - 1 = n" by auto
   167     have if_eq: "\<And>B T E. (if \<not> B then T else E) = (if B then E else T)" by auto
   168 
   169     have "?s sums y" using sums_if'[OF `f sums y`] .
   170     from this[unfolded sums_def, THEN LIMSEQ_Suc]
   171     have "(\<lambda> n. if even n then f (n div 2) else 0) sums y"
   172       unfolding sums_def setsum_shift_lb_Suc0_0_upt[where f="?s", OF `?s 0 = 0`, symmetric]
   173                 image_Suc_atLeastLessThan[symmetric] setsum_reindex[OF inj_Suc, unfolded comp_def]
   174                 even_Suc Suc_m1 if_eq .
   175   } from sums_add[OF g_sums this]
   176   show ?thesis unfolding if_sum .
   177 qed
   178 
   179 subsection {* Alternating series test / Leibniz formula *}
   180 
   181 lemma sums_alternating_upper_lower:
   182   fixes a :: "nat \<Rightarrow> real"
   183   assumes mono: "\<And>n. a (Suc n) \<le> a n" and a_pos: "\<And>n. 0 \<le> a n" and "a ----> 0"
   184   shows "\<exists>l. ((\<forall>n. (\<Sum>i=0..<2*n. -1^i*a i) \<le> l) \<and> (\<lambda> n. \<Sum>i=0..<2*n. -1^i*a i) ----> l) \<and>
   185              ((\<forall>n. l \<le> (\<Sum>i=0..<2*n + 1. -1^i*a i)) \<and> (\<lambda> n. \<Sum>i=0..<2*n + 1. -1^i*a i) ----> l)"
   186   (is "\<exists>l. ((\<forall>n. ?f n \<le> l) \<and> _) \<and> ((\<forall>n. l \<le> ?g n) \<and> _)")
   187 proof -
   188   have fg_diff: "\<And>n. ?f n - ?g n = - a (2 * n)" unfolding One_nat_def by auto
   189 
   190   have "\<forall> n. ?f n \<le> ?f (Suc n)"
   191   proof fix n show "?f n \<le> ?f (Suc n)" using mono[of "2*n"] by auto qed
   192   moreover
   193   have "\<forall> n. ?g (Suc n) \<le> ?g n"
   194   proof fix n show "?g (Suc n) \<le> ?g n" using mono[of "Suc (2*n)"]
   195     unfolding One_nat_def by auto qed
   196   moreover
   197   have "\<forall> n. ?f n \<le> ?g n"
   198   proof fix n show "?f n \<le> ?g n" using fg_diff a_pos
   199     unfolding One_nat_def by auto qed
   200   moreover
   201   have "(\<lambda> n. ?f n - ?g n) ----> 0" unfolding fg_diff
   202   proof (rule LIMSEQ_I)
   203     fix r :: real assume "0 < r"
   204     with `a ----> 0`[THEN LIMSEQ_D]
   205     obtain N where "\<And> n. n \<ge> N \<Longrightarrow> norm (a n - 0) < r" by auto
   206     hence "\<forall> n \<ge> N. norm (- a (2 * n) - 0) < r" by auto
   207     thus "\<exists> N. \<forall> n \<ge> N. norm (- a (2 * n) - 0) < r" by auto
   208   qed
   209   ultimately
   210   show ?thesis by (rule lemma_nest_unique)
   211 qed
   212 
   213 lemma summable_Leibniz': fixes a :: "nat \<Rightarrow> real"
   214   assumes a_zero: "a ----> 0" and a_pos: "\<And> n. 0 \<le> a n"
   215   and a_monotone: "\<And> n. a (Suc n) \<le> a n"
   216   shows summable: "summable (\<lambda> n. (-1)^n * a n)"
   217   and "\<And>n. (\<Sum>i=0..<2*n. (-1)^i*a i) \<le> (\<Sum>i. (-1)^i*a i)"
   218   and "(\<lambda>n. \<Sum>i=0..<2*n. (-1)^i*a i) ----> (\<Sum>i. (-1)^i*a i)"
   219   and "\<And>n. (\<Sum>i. (-1)^i*a i) \<le> (\<Sum>i=0..<2*n+1. (-1)^i*a i)"
   220   and "(\<lambda>n. \<Sum>i=0..<2*n+1. (-1)^i*a i) ----> (\<Sum>i. (-1)^i*a i)"
   221 proof -
   222   let "?S n" = "(-1)^n * a n"
   223   let "?P n" = "\<Sum>i=0..<n. ?S i"
   224   let "?f n" = "?P (2 * n)"
   225   let "?g n" = "?P (2 * n + 1)"
   226   obtain l :: real where below_l: "\<forall> n. ?f n \<le> l" and "?f ----> l" and above_l: "\<forall> n. l \<le> ?g n" and "?g ----> l"
   227     using sums_alternating_upper_lower[OF a_monotone a_pos a_zero] by blast
   228 
   229   let ?Sa = "\<lambda> m. \<Sum> n = 0..<m. ?S n"
   230   have "?Sa ----> l"
   231   proof (rule LIMSEQ_I)
   232     fix r :: real assume "0 < r"
   233 
   234     with `?f ----> l`[THEN LIMSEQ_D]
   235     obtain f_no where f: "\<And> n. n \<ge> f_no \<Longrightarrow> norm (?f n - l) < r" by auto
   236 
   237     from `0 < r` `?g ----> l`[THEN LIMSEQ_D]
   238     obtain g_no where g: "\<And> n. n \<ge> g_no \<Longrightarrow> norm (?g n - l) < r" by auto
   239 
   240     { fix n :: nat
   241       assume "n \<ge> (max (2 * f_no) (2 * g_no))" hence "n \<ge> 2 * f_no" and "n \<ge> 2 * g_no" by auto
   242       have "norm (?Sa n - l) < r"
   243       proof (cases "even n")
   244         case True from even_nat_div_two_times_two[OF this]
   245         have n_eq: "2 * (n div 2) = n" unfolding numeral_2_eq_2[symmetric] by auto
   246         with `n \<ge> 2 * f_no` have "n div 2 \<ge> f_no" by auto
   247         from f[OF this]
   248         show ?thesis unfolding n_eq atLeastLessThanSuc_atLeastAtMost .
   249       next
   250         case False hence "even (n - 1)" by simp
   251         from even_nat_div_two_times_two[OF this]
   252         have n_eq: "2 * ((n - 1) div 2) = n - 1" unfolding numeral_2_eq_2[symmetric] by auto
   253         hence range_eq: "n - 1 + 1 = n" using odd_pos[OF False] by auto
   254 
   255         from n_eq `n \<ge> 2 * g_no` have "(n - 1) div 2 \<ge> g_no" by auto
   256         from g[OF this]
   257         show ?thesis unfolding n_eq atLeastLessThanSuc_atLeastAtMost range_eq .
   258       qed
   259     }
   260     thus "\<exists> no. \<forall> n \<ge> no. norm (?Sa n - l) < r" by blast
   261   qed
   262   hence sums_l: "(\<lambda>i. (-1)^i * a i) sums l" unfolding sums_def atLeastLessThanSuc_atLeastAtMost[symmetric] .
   263   thus "summable ?S" using summable_def by auto
   264 
   265   have "l = suminf ?S" using sums_unique[OF sums_l] .
   266 
   267   { fix n show "suminf ?S \<le> ?g n" unfolding sums_unique[OF sums_l, symmetric] using above_l by auto }
   268   { fix n show "?f n \<le> suminf ?S" unfolding sums_unique[OF sums_l, symmetric] using below_l by auto }
   269   show "?g ----> suminf ?S" using `?g ----> l` `l = suminf ?S` by auto
   270   show "?f ----> suminf ?S" using `?f ----> l` `l = suminf ?S` by auto
   271 qed
   272 
   273 theorem summable_Leibniz: fixes a :: "nat \<Rightarrow> real"
   274   assumes a_zero: "a ----> 0" and "monoseq a"
   275   shows "summable (\<lambda> n. (-1)^n * a n)" (is "?summable")
   276   and "0 < a 0 \<longrightarrow> (\<forall>n. (\<Sum>i. -1^i*a i) \<in> { \<Sum>i=0..<2*n. -1^i * a i .. \<Sum>i=0..<2*n+1. -1^i * a i})" (is "?pos")
   277   and "a 0 < 0 \<longrightarrow> (\<forall>n. (\<Sum>i. -1^i*a i) \<in> { \<Sum>i=0..<2*n+1. -1^i * a i .. \<Sum>i=0..<2*n. -1^i * a i})" (is "?neg")
   278   and "(\<lambda>n. \<Sum>i=0..<2*n. -1^i*a i) ----> (\<Sum>i. -1^i*a i)" (is "?f")
   279   and "(\<lambda>n. \<Sum>i=0..<2*n+1. -1^i*a i) ----> (\<Sum>i. -1^i*a i)" (is "?g")
   280 proof -
   281   have "?summable \<and> ?pos \<and> ?neg \<and> ?f \<and> ?g"
   282   proof (cases "(\<forall> n. 0 \<le> a n) \<and> (\<forall>m. \<forall>n\<ge>m. a n \<le> a m)")
   283     case True
   284     hence ord: "\<And>n m. m \<le> n \<Longrightarrow> a n \<le> a m" and ge0: "\<And> n. 0 \<le> a n" by auto
   285     { fix n have "a (Suc n) \<le> a n" using ord[where n="Suc n" and m=n] by auto }
   286     note leibniz = summable_Leibniz'[OF `a ----> 0` ge0] and mono = this
   287     from leibniz[OF mono]
   288     show ?thesis using `0 \<le> a 0` by auto
   289   next
   290     let ?a = "\<lambda> n. - a n"
   291     case False
   292     with monoseq_le[OF `monoseq a` `a ----> 0`]
   293     have "(\<forall> n. a n \<le> 0) \<and> (\<forall>m. \<forall>n\<ge>m. a m \<le> a n)" by auto
   294     hence ord: "\<And>n m. m \<le> n \<Longrightarrow> ?a n \<le> ?a m" and ge0: "\<And> n. 0 \<le> ?a n" by auto
   295     { fix n have "?a (Suc n) \<le> ?a n" using ord[where n="Suc n" and m=n] by auto }
   296     note monotone = this
   297     note leibniz = summable_Leibniz'[OF _ ge0, of "\<lambda>x. x", OF tendsto_minus[OF `a ----> 0`, unfolded minus_zero] monotone]
   298     have "summable (\<lambda> n. (-1)^n * ?a n)" using leibniz(1) by auto
   299     then obtain l where "(\<lambda> n. (-1)^n * ?a n) sums l" unfolding summable_def by auto
   300     from this[THEN sums_minus]
   301     have "(\<lambda> n. (-1)^n * a n) sums -l" by auto
   302     hence ?summable unfolding summable_def by auto
   303     moreover
   304     have "\<And> a b :: real. \<bar> - a - - b \<bar> = \<bar>a - b\<bar>" unfolding minus_diff_minus by auto
   305 
   306     from suminf_minus[OF leibniz(1), unfolded mult_minus_right minus_minus]
   307     have move_minus: "(\<Sum>n. - (-1 ^ n * a n)) = - (\<Sum>n. -1 ^ n * a n)" by auto
   308 
   309     have ?pos using `0 \<le> ?a 0` by auto
   310     moreover have ?neg using leibniz(2,4) unfolding mult_minus_right setsum_negf move_minus neg_le_iff_le by auto
   311     moreover have ?f and ?g using leibniz(3,5)[unfolded mult_minus_right setsum_negf move_minus, THEN tendsto_minus_cancel] by auto
   312     ultimately show ?thesis by auto
   313   qed
   314   from this[THEN conjunct1] this[THEN conjunct2, THEN conjunct1] this[THEN conjunct2, THEN conjunct2, THEN conjunct1] this[THEN conjunct2, THEN conjunct2, THEN conjunct2, THEN conjunct1]
   315        this[THEN conjunct2, THEN conjunct2, THEN conjunct2, THEN conjunct2]
   316   show ?summable and ?pos and ?neg and ?f and ?g .
   317 qed
   318 
   319 subsection {* Term-by-Term Differentiability of Power Series *}
   320 
   321 definition
   322   diffs :: "(nat => 'a::ring_1) => nat => 'a" where
   323   "diffs c = (%n. of_nat (Suc n) * c(Suc n))"
   324 
   325 text{*Lemma about distributing negation over it*}
   326 lemma diffs_minus: "diffs (%n. - c n) = (%n. - diffs c n)"
   327 by (simp add: diffs_def)
   328 
   329 lemma sums_Suc_imp:
   330   assumes f: "f 0 = 0"
   331   shows "(\<lambda>n. f (Suc n)) sums s \<Longrightarrow> (\<lambda>n. f n) sums s"
   332 unfolding sums_def
   333 apply (rule LIMSEQ_imp_Suc)
   334 apply (subst setsum_shift_lb_Suc0_0_upt [where f=f, OF f, symmetric])
   335 apply (simp only: setsum_shift_bounds_Suc_ivl)
   336 done
   337 
   338 lemma diffs_equiv:
   339   fixes x :: "'a::{real_normed_vector, ring_1}"
   340   shows "summable (%n. (diffs c)(n) * (x ^ n)) ==>
   341       (%n. of_nat n * c(n) * (x ^ (n - Suc 0))) sums
   342          (\<Sum>n. (diffs c)(n) * (x ^ n))"
   343 unfolding diffs_def
   344 apply (drule summable_sums)
   345 apply (rule sums_Suc_imp, simp_all)
   346 done
   347 
   348 lemma lemma_termdiff1:
   349   fixes z :: "'a :: {monoid_mult,comm_ring}" shows
   350   "(\<Sum>p=0..<m. (((z + h) ^ (m - p)) * (z ^ p)) - (z ^ m)) =
   351    (\<Sum>p=0..<m. (z ^ p) * (((z + h) ^ (m - p)) - (z ^ (m - p))))"
   352 by(auto simp add: algebra_simps power_add [symmetric])
   353 
   354 lemma sumr_diff_mult_const2:
   355   "setsum f {0..<n} - of_nat n * (r::'a::ring_1) = (\<Sum>i = 0..<n. f i - r)"
   356 by (simp add: setsum_subtractf)
   357 
   358 lemma lemma_termdiff2:
   359   fixes h :: "'a :: {field}"
   360   assumes h: "h \<noteq> 0" shows
   361   "((z + h) ^ n - z ^ n) / h - of_nat n * z ^ (n - Suc 0) =
   362    h * (\<Sum>p=0..< n - Suc 0. \<Sum>q=0..< n - Suc 0 - p.
   363         (z + h) ^ q * z ^ (n - 2 - q))" (is "?lhs = ?rhs")
   364 apply (subgoal_tac "h * ?lhs = h * ?rhs", simp add: h)
   365 apply (simp add: right_diff_distrib diff_divide_distrib h)
   366 apply (simp add: mult_assoc [symmetric])
   367 apply (cases "n", simp)
   368 apply (simp add: lemma_realpow_diff_sumr2 h
   369                  right_diff_distrib [symmetric] mult_assoc
   370             del: power_Suc setsum_op_ivl_Suc of_nat_Suc)
   371 apply (subst lemma_realpow_rev_sumr)
   372 apply (subst sumr_diff_mult_const2)
   373 apply simp
   374 apply (simp only: lemma_termdiff1 setsum_right_distrib)
   375 apply (rule setsum_cong [OF refl])
   376 apply (simp add: diff_minus [symmetric] less_iff_Suc_add)
   377 apply (clarify)
   378 apply (simp add: setsum_right_distrib lemma_realpow_diff_sumr2 mult_ac
   379             del: setsum_op_ivl_Suc power_Suc)
   380 apply (subst mult_assoc [symmetric], subst power_add [symmetric])
   381 apply (simp add: mult_ac)
   382 done
   383 
   384 lemma real_setsum_nat_ivl_bounded2:
   385   fixes K :: "'a::linordered_semidom"
   386   assumes f: "\<And>p::nat. p < n \<Longrightarrow> f p \<le> K"
   387   assumes K: "0 \<le> K"
   388   shows "setsum f {0..<n-k} \<le> of_nat n * K"
   389 apply (rule order_trans [OF setsum_mono])
   390 apply (rule f, simp)
   391 apply (simp add: mult_right_mono K)
   392 done
   393 
   394 lemma lemma_termdiff3:
   395   fixes h z :: "'a::{real_normed_field}"
   396   assumes 1: "h \<noteq> 0"
   397   assumes 2: "norm z \<le> K"
   398   assumes 3: "norm (z + h) \<le> K"
   399   shows "norm (((z + h) ^ n - z ^ n) / h - of_nat n * z ^ (n - Suc 0))
   400           \<le> of_nat n * of_nat (n - Suc 0) * K ^ (n - 2) * norm h"
   401 proof -
   402   have "norm (((z + h) ^ n - z ^ n) / h - of_nat n * z ^ (n - Suc 0)) =
   403         norm (\<Sum>p = 0..<n - Suc 0. \<Sum>q = 0..<n - Suc 0 - p.
   404           (z + h) ^ q * z ^ (n - 2 - q)) * norm h"
   405     apply (subst lemma_termdiff2 [OF 1])
   406     apply (subst norm_mult)
   407     apply (rule mult_commute)
   408     done
   409   also have "\<dots> \<le> of_nat n * (of_nat (n - Suc 0) * K ^ (n - 2)) * norm h"
   410   proof (rule mult_right_mono [OF _ norm_ge_zero])
   411     from norm_ge_zero 2 have K: "0 \<le> K" by (rule order_trans)
   412     have le_Kn: "\<And>i j n. i + j = n \<Longrightarrow> norm ((z + h) ^ i * z ^ j) \<le> K ^ n"
   413       apply (erule subst)
   414       apply (simp only: norm_mult norm_power power_add)
   415       apply (intro mult_mono power_mono 2 3 norm_ge_zero zero_le_power K)
   416       done
   417     show "norm (\<Sum>p = 0..<n - Suc 0. \<Sum>q = 0..<n - Suc 0 - p.
   418               (z + h) ^ q * z ^ (n - 2 - q))
   419           \<le> of_nat n * (of_nat (n - Suc 0) * K ^ (n - 2))"
   420       apply (intro
   421          order_trans [OF norm_setsum]
   422          real_setsum_nat_ivl_bounded2
   423          mult_nonneg_nonneg
   424          of_nat_0_le_iff
   425          zero_le_power K)
   426       apply (rule le_Kn, simp)
   427       done
   428   qed
   429   also have "\<dots> = of_nat n * of_nat (n - Suc 0) * K ^ (n - 2) * norm h"
   430     by (simp only: mult_assoc)
   431   finally show ?thesis .
   432 qed
   433 
   434 lemma lemma_termdiff4:
   435   fixes f :: "'a::{real_normed_field} \<Rightarrow>
   436               'b::real_normed_vector"
   437   assumes k: "0 < (k::real)"
   438   assumes le: "\<And>h. \<lbrakk>h \<noteq> 0; norm h < k\<rbrakk> \<Longrightarrow> norm (f h) \<le> K * norm h"
   439   shows "f -- 0 --> 0"
   440 unfolding LIM_eq diff_0_right
   441 proof (safe)
   442   let ?h = "of_real (k / 2)::'a"
   443   have "?h \<noteq> 0" and "norm ?h < k" using k by simp_all
   444   hence "norm (f ?h) \<le> K * norm ?h" by (rule le)
   445   hence "0 \<le> K * norm ?h" by (rule order_trans [OF norm_ge_zero])
   446   hence zero_le_K: "0 \<le> K" using k by (simp add: zero_le_mult_iff)
   447 
   448   fix r::real assume r: "0 < r"
   449   show "\<exists>s. 0 < s \<and> (\<forall>x. x \<noteq> 0 \<and> norm x < s \<longrightarrow> norm (f x) < r)"
   450   proof (cases)
   451     assume "K = 0"
   452     with k r le have "0 < k \<and> (\<forall>x. x \<noteq> 0 \<and> norm x < k \<longrightarrow> norm (f x) < r)"
   453       by simp
   454     thus "\<exists>s. 0 < s \<and> (\<forall>x. x \<noteq> 0 \<and> norm x < s \<longrightarrow> norm (f x) < r)" ..
   455   next
   456     assume K_neq_zero: "K \<noteq> 0"
   457     with zero_le_K have K: "0 < K" by simp
   458     show "\<exists>s. 0 < s \<and> (\<forall>x. x \<noteq> 0 \<and> norm x < s \<longrightarrow> norm (f x) < r)"
   459     proof (rule exI, safe)
   460       from k r K show "0 < min k (r * inverse K / 2)"
   461         by (simp add: mult_pos_pos positive_imp_inverse_positive)
   462     next
   463       fix x::'a
   464       assume x1: "x \<noteq> 0" and x2: "norm x < min k (r * inverse K / 2)"
   465       from x2 have x3: "norm x < k" and x4: "norm x < r * inverse K / 2"
   466         by simp_all
   467       from x1 x3 le have "norm (f x) \<le> K * norm x" by simp
   468       also from x4 K have "K * norm x < K * (r * inverse K / 2)"
   469         by (rule mult_strict_left_mono)
   470       also have "\<dots> = r / 2"
   471         using K_neq_zero by simp
   472       also have "r / 2 < r"
   473         using r by simp
   474       finally show "norm (f x) < r" .
   475     qed
   476   qed
   477 qed
   478 
   479 lemma lemma_termdiff5:
   480   fixes g :: "'a::{real_normed_field} \<Rightarrow>
   481               nat \<Rightarrow> 'b::banach"
   482   assumes k: "0 < (k::real)"
   483   assumes f: "summable f"
   484   assumes le: "\<And>h n. \<lbrakk>h \<noteq> 0; norm h < k\<rbrakk> \<Longrightarrow> norm (g h n) \<le> f n * norm h"
   485   shows "(\<lambda>h. suminf (g h)) -- 0 --> 0"
   486 proof (rule lemma_termdiff4 [OF k])
   487   fix h::'a assume "h \<noteq> 0" and "norm h < k"
   488   hence A: "\<forall>n. norm (g h n) \<le> f n * norm h"
   489     by (simp add: le)
   490   hence "\<exists>N. \<forall>n\<ge>N. norm (norm (g h n)) \<le> f n * norm h"
   491     by simp
   492   moreover from f have B: "summable (\<lambda>n. f n * norm h)"
   493     by (rule summable_mult2)
   494   ultimately have C: "summable (\<lambda>n. norm (g h n))"
   495     by (rule summable_comparison_test)
   496   hence "norm (suminf (g h)) \<le> (\<Sum>n. norm (g h n))"
   497     by (rule summable_norm)
   498   also from A C B have "(\<Sum>n. norm (g h n)) \<le> (\<Sum>n. f n * norm h)"
   499     by (rule summable_le)
   500   also from f have "(\<Sum>n. f n * norm h) = suminf f * norm h"
   501     by (rule suminf_mult2 [symmetric])
   502   finally show "norm (suminf (g h)) \<le> suminf f * norm h" .
   503 qed
   504 
   505 
   506 text{* FIXME: Long proofs*}
   507 
   508 lemma termdiffs_aux:
   509   fixes x :: "'a::{real_normed_field,banach}"
   510   assumes 1: "summable (\<lambda>n. diffs (diffs c) n * K ^ n)"
   511   assumes 2: "norm x < norm K"
   512   shows "(\<lambda>h. \<Sum>n. c n * (((x + h) ^ n - x ^ n) / h
   513              - of_nat n * x ^ (n - Suc 0))) -- 0 --> 0"
   514 proof -
   515   from dense [OF 2]
   516   obtain r where r1: "norm x < r" and r2: "r < norm K" by fast
   517   from norm_ge_zero r1 have r: "0 < r"
   518     by (rule order_le_less_trans)
   519   hence r_neq_0: "r \<noteq> 0" by simp
   520   show ?thesis
   521   proof (rule lemma_termdiff5)
   522     show "0 < r - norm x" using r1 by simp
   523   next
   524     from r r2 have "norm (of_real r::'a) < norm K"
   525       by simp
   526     with 1 have "summable (\<lambda>n. norm (diffs (diffs c) n * (of_real r ^ n)))"
   527       by (rule powser_insidea)
   528     hence "summable (\<lambda>n. diffs (diffs (\<lambda>n. norm (c n))) n * r ^ n)"
   529       using r
   530       by (simp add: diffs_def norm_mult norm_power del: of_nat_Suc)
   531     hence "summable (\<lambda>n. of_nat n * diffs (\<lambda>n. norm (c n)) n * r ^ (n - Suc 0))"
   532       by (rule diffs_equiv [THEN sums_summable])
   533     also have "(\<lambda>n. of_nat n * diffs (\<lambda>n. norm (c n)) n * r ^ (n - Suc 0))
   534       = (\<lambda>n. diffs (%m. of_nat (m - Suc 0) * norm (c m) * inverse r) n * (r ^ n))"
   535       apply (rule ext)
   536       apply (simp add: diffs_def)
   537       apply (case_tac n, simp_all add: r_neq_0)
   538       done
   539     finally have "summable
   540       (\<lambda>n. of_nat n * (of_nat (n - Suc 0) * norm (c n) * inverse r) * r ^ (n - Suc 0))"
   541       by (rule diffs_equiv [THEN sums_summable])
   542     also have
   543       "(\<lambda>n. of_nat n * (of_nat (n - Suc 0) * norm (c n) * inverse r) *
   544            r ^ (n - Suc 0)) =
   545        (\<lambda>n. norm (c n) * of_nat n * of_nat (n - Suc 0) * r ^ (n - 2))"
   546       apply (rule ext)
   547       apply (case_tac "n", simp)
   548       apply (case_tac "nat", simp)
   549       apply (simp add: r_neq_0)
   550       done
   551     finally show
   552       "summable (\<lambda>n. norm (c n) * of_nat n * of_nat (n - Suc 0) * r ^ (n - 2))" .
   553   next
   554     fix h::'a and n::nat
   555     assume h: "h \<noteq> 0"
   556     assume "norm h < r - norm x"
   557     hence "norm x + norm h < r" by simp
   558     with norm_triangle_ineq have xh: "norm (x + h) < r"
   559       by (rule order_le_less_trans)
   560     show "norm (c n * (((x + h) ^ n - x ^ n) / h - of_nat n * x ^ (n - Suc 0)))
   561           \<le> norm (c n) * of_nat n * of_nat (n - Suc 0) * r ^ (n - 2) * norm h"
   562       apply (simp only: norm_mult mult_assoc)
   563       apply (rule mult_left_mono [OF _ norm_ge_zero])
   564       apply (simp (no_asm) add: mult_assoc [symmetric])
   565       apply (rule lemma_termdiff3)
   566       apply (rule h)
   567       apply (rule r1 [THEN order_less_imp_le])
   568       apply (rule xh [THEN order_less_imp_le])
   569       done
   570   qed
   571 qed
   572 
   573 lemma termdiffs:
   574   fixes K x :: "'a::{real_normed_field,banach}"
   575   assumes 1: "summable (\<lambda>n. c n * K ^ n)"
   576   assumes 2: "summable (\<lambda>n. (diffs c) n * K ^ n)"
   577   assumes 3: "summable (\<lambda>n. (diffs (diffs c)) n * K ^ n)"
   578   assumes 4: "norm x < norm K"
   579   shows "DERIV (\<lambda>x. \<Sum>n. c n * x ^ n) x :> (\<Sum>n. (diffs c) n * x ^ n)"
   580 unfolding deriv_def
   581 proof (rule LIM_zero_cancel)
   582   show "(\<lambda>h. (suminf (\<lambda>n. c n * (x + h) ^ n) - suminf (\<lambda>n. c n * x ^ n)) / h
   583             - suminf (\<lambda>n. diffs c n * x ^ n)) -- 0 --> 0"
   584   proof (rule LIM_equal2)
   585     show "0 < norm K - norm x" using 4 by (simp add: less_diff_eq)
   586   next
   587     fix h :: 'a
   588     assume "h \<noteq> 0"
   589     assume "norm (h - 0) < norm K - norm x"
   590     hence "norm x + norm h < norm K" by simp
   591     hence 5: "norm (x + h) < norm K"
   592       by (rule norm_triangle_ineq [THEN order_le_less_trans])
   593     have A: "summable (\<lambda>n. c n * x ^ n)"
   594       by (rule powser_inside [OF 1 4])
   595     have B: "summable (\<lambda>n. c n * (x + h) ^ n)"
   596       by (rule powser_inside [OF 1 5])
   597     have C: "summable (\<lambda>n. diffs c n * x ^ n)"
   598       by (rule powser_inside [OF 2 4])
   599     show "((\<Sum>n. c n * (x + h) ^ n) - (\<Sum>n. c n * x ^ n)) / h
   600              - (\<Sum>n. diffs c n * x ^ n) =
   601           (\<Sum>n. c n * (((x + h) ^ n - x ^ n) / h - of_nat n * x ^ (n - Suc 0)))"
   602       apply (subst sums_unique [OF diffs_equiv [OF C]])
   603       apply (subst suminf_diff [OF B A])
   604       apply (subst suminf_divide [symmetric])
   605       apply (rule summable_diff [OF B A])
   606       apply (subst suminf_diff)
   607       apply (rule summable_divide)
   608       apply (rule summable_diff [OF B A])
   609       apply (rule sums_summable [OF diffs_equiv [OF C]])
   610       apply (rule arg_cong [where f="suminf"], rule ext)
   611       apply (simp add: algebra_simps)
   612       done
   613   next
   614     show "(\<lambda>h. \<Sum>n. c n * (((x + h) ^ n - x ^ n) / h -
   615                of_nat n * x ^ (n - Suc 0))) -- 0 --> 0"
   616         by (rule termdiffs_aux [OF 3 4])
   617   qed
   618 qed
   619 
   620 
   621 subsection {* Derivability of power series *}
   622 
   623 lemma DERIV_series': fixes f :: "real \<Rightarrow> nat \<Rightarrow> real"
   624   assumes DERIV_f: "\<And> n. DERIV (\<lambda> x. f x n) x0 :> (f' x0 n)"
   625   and allf_summable: "\<And> x. x \<in> {a <..< b} \<Longrightarrow> summable (f x)" and x0_in_I: "x0 \<in> {a <..< b}"
   626   and "summable (f' x0)"
   627   and "summable L" and L_def: "\<And> n x y. \<lbrakk> x \<in> { a <..< b} ; y \<in> { a <..< b} \<rbrakk> \<Longrightarrow> \<bar> f x n - f y n \<bar> \<le> L n * \<bar> x - y \<bar>"
   628   shows "DERIV (\<lambda> x. suminf (f x)) x0 :> (suminf (f' x0))"
   629   unfolding deriv_def
   630 proof (rule LIM_I)
   631   fix r :: real assume "0 < r" hence "0 < r/3" by auto
   632 
   633   obtain N_L where N_L: "\<And> n. N_L \<le> n \<Longrightarrow> \<bar> \<Sum> i. L (i + n) \<bar> < r/3"
   634     using suminf_exist_split[OF `0 < r/3` `summable L`] by auto
   635 
   636   obtain N_f' where N_f': "\<And> n. N_f' \<le> n \<Longrightarrow> \<bar> \<Sum> i. f' x0 (i + n) \<bar> < r/3"
   637     using suminf_exist_split[OF `0 < r/3` `summable (f' x0)`] by auto
   638 
   639   let ?N = "Suc (max N_L N_f')"
   640   have "\<bar> \<Sum> i. f' x0 (i + ?N) \<bar> < r/3" (is "?f'_part < r/3") and
   641     L_estimate: "\<bar> \<Sum> i. L (i + ?N) \<bar> < r/3" using N_L[of "?N"] and N_f' [of "?N"] by auto
   642 
   643   let "?diff i x" = "(f (x0 + x) i - f x0 i) / x"
   644 
   645   let ?r = "r / (3 * real ?N)"
   646   have "0 < 3 * real ?N" by auto
   647   from divide_pos_pos[OF `0 < r` this]
   648   have "0 < ?r" .
   649 
   650   let "?s n" = "SOME s. 0 < s \<and> (\<forall> x. x \<noteq> 0 \<and> \<bar> x \<bar> < s \<longrightarrow> \<bar> ?diff n x - f' x0 n \<bar> < ?r)"
   651   def S' \<equiv> "Min (?s ` { 0 ..< ?N })"
   652 
   653   have "0 < S'" unfolding S'_def
   654   proof (rule iffD2[OF Min_gr_iff])
   655     show "\<forall> x \<in> (?s ` { 0 ..< ?N }). 0 < x"
   656     proof (rule ballI)
   657       fix x assume "x \<in> ?s ` {0..<?N}"
   658       then obtain n where "x = ?s n" and "n \<in> {0..<?N}" using image_iff[THEN iffD1] by blast
   659       from DERIV_D[OF DERIV_f[where n=n], THEN LIM_D, OF `0 < ?r`, unfolded real_norm_def]
   660       obtain s where s_bound: "0 < s \<and> (\<forall>x. x \<noteq> 0 \<and> \<bar>x\<bar> < s \<longrightarrow> \<bar>?diff n x - f' x0 n\<bar> < ?r)" by auto
   661       have "0 < ?s n" by (rule someI2[where a=s], auto simp add: s_bound)
   662       thus "0 < x" unfolding `x = ?s n` .
   663     qed
   664   qed auto
   665 
   666   def S \<equiv> "min (min (x0 - a) (b - x0)) S'"
   667   hence "0 < S" and S_a: "S \<le> x0 - a" and S_b: "S \<le> b - x0" and "S \<le> S'" using x0_in_I and `0 < S'`
   668     by auto
   669 
   670   { fix x assume "x \<noteq> 0" and "\<bar> x \<bar> < S"
   671     hence x_in_I: "x0 + x \<in> { a <..< b }" using S_a S_b by auto
   672 
   673     note diff_smbl = summable_diff[OF allf_summable[OF x_in_I] allf_summable[OF x0_in_I]]
   674     note div_smbl = summable_divide[OF diff_smbl]
   675     note all_smbl = summable_diff[OF div_smbl `summable (f' x0)`]
   676     note ign = summable_ignore_initial_segment[where k="?N"]
   677     note diff_shft_smbl = summable_diff[OF ign[OF allf_summable[OF x_in_I]] ign[OF allf_summable[OF x0_in_I]]]
   678     note div_shft_smbl = summable_divide[OF diff_shft_smbl]
   679     note all_shft_smbl = summable_diff[OF div_smbl ign[OF `summable (f' x0)`]]
   680 
   681     { fix n
   682       have "\<bar> ?diff (n + ?N) x \<bar> \<le> L (n + ?N) * \<bar> (x0 + x) - x0 \<bar> / \<bar> x \<bar>"
   683         using divide_right_mono[OF L_def[OF x_in_I x0_in_I] abs_ge_zero] unfolding abs_divide .
   684       hence "\<bar> ( \<bar> ?diff (n + ?N) x \<bar>) \<bar> \<le> L (n + ?N)" using `x \<noteq> 0` by auto
   685     } note L_ge = summable_le2[OF allI[OF this] ign[OF `summable L`]]
   686     from order_trans[OF summable_rabs[OF conjunct1[OF L_ge]] L_ge[THEN conjunct2]]
   687     have "\<bar> \<Sum> i. ?diff (i + ?N) x \<bar> \<le> (\<Sum> i. L (i + ?N))" .
   688     hence "\<bar> \<Sum> i. ?diff (i + ?N) x \<bar> \<le> r / 3" (is "?L_part \<le> r/3") using L_estimate by auto
   689 
   690     have "\<bar>\<Sum>n \<in> { 0 ..< ?N}. ?diff n x - f' x0 n \<bar> \<le> (\<Sum>n \<in> { 0 ..< ?N}. \<bar>?diff n x - f' x0 n \<bar>)" ..
   691     also have "\<dots> < (\<Sum>n \<in> { 0 ..< ?N}. ?r)"
   692     proof (rule setsum_strict_mono)
   693       fix n assume "n \<in> { 0 ..< ?N}"
   694       have "\<bar> x \<bar> < S" using `\<bar> x \<bar> < S` .
   695       also have "S \<le> S'" using `S \<le> S'` .
   696       also have "S' \<le> ?s n" unfolding S'_def
   697       proof (rule Min_le_iff[THEN iffD2])
   698         have "?s n \<in> (?s ` {0..<?N}) \<and> ?s n \<le> ?s n" using `n \<in> { 0 ..< ?N}` by auto
   699         thus "\<exists> a \<in> (?s ` {0..<?N}). a \<le> ?s n" by blast
   700       qed auto
   701       finally have "\<bar> x \<bar> < ?s n" .
   702 
   703       from DERIV_D[OF DERIV_f[where n=n], THEN LIM_D, OF `0 < ?r`, unfolded real_norm_def diff_0_right, unfolded some_eq_ex[symmetric], THEN conjunct2]
   704       have "\<forall>x. x \<noteq> 0 \<and> \<bar>x\<bar> < ?s n \<longrightarrow> \<bar>?diff n x - f' x0 n\<bar> < ?r" .
   705       with `x \<noteq> 0` and `\<bar>x\<bar> < ?s n`
   706       show "\<bar>?diff n x - f' x0 n\<bar> < ?r" by blast
   707     qed auto
   708     also have "\<dots> = of_nat (card {0 ..< ?N}) * ?r" by (rule setsum_constant)
   709     also have "\<dots> = real ?N * ?r" unfolding real_eq_of_nat by auto
   710     also have "\<dots> = r/3" by auto
   711     finally have "\<bar>\<Sum>n \<in> { 0 ..< ?N}. ?diff n x - f' x0 n \<bar> < r / 3" (is "?diff_part < r / 3") .
   712 
   713     from suminf_diff[OF allf_summable[OF x_in_I] allf_summable[OF x0_in_I]]
   714     have "\<bar> (suminf (f (x0 + x)) - (suminf (f x0))) / x - suminf (f' x0) \<bar> =
   715                     \<bar> \<Sum>n. ?diff n x - f' x0 n \<bar>" unfolding suminf_diff[OF div_smbl `summable (f' x0)`, symmetric] using suminf_divide[OF diff_smbl, symmetric] by auto
   716     also have "\<dots> \<le> ?diff_part + \<bar> (\<Sum>n. ?diff (n + ?N) x) - (\<Sum> n. f' x0 (n + ?N)) \<bar>" unfolding suminf_split_initial_segment[OF all_smbl, where k="?N"] unfolding suminf_diff[OF div_shft_smbl ign[OF `summable (f' x0)`]] by (rule abs_triangle_ineq)
   717     also have "\<dots> \<le> ?diff_part + ?L_part + ?f'_part" using abs_triangle_ineq4 by auto
   718     also have "\<dots> < r /3 + r/3 + r/3"
   719       using `?diff_part < r/3` `?L_part \<le> r/3` and `?f'_part < r/3`
   720       by (rule add_strict_mono [OF add_less_le_mono])
   721     finally have "\<bar> (suminf (f (x0 + x)) - (suminf (f x0))) / x - suminf (f' x0) \<bar> < r"
   722       by auto
   723   } thus "\<exists> s > 0. \<forall> x. x \<noteq> 0 \<and> norm (x - 0) < s \<longrightarrow>
   724       norm (((\<Sum>n. f (x0 + x) n) - (\<Sum>n. f x0 n)) / x - (\<Sum>n. f' x0 n)) < r" using `0 < S`
   725     unfolding real_norm_def diff_0_right by blast
   726 qed
   727 
   728 lemma DERIV_power_series': fixes f :: "nat \<Rightarrow> real"
   729   assumes converges: "\<And> x. x \<in> {-R <..< R} \<Longrightarrow> summable (\<lambda> n. f n * real (Suc n) * x^n)"
   730   and x0_in_I: "x0 \<in> {-R <..< R}" and "0 < R"
   731   shows "DERIV (\<lambda> x. (\<Sum> n. f n * x^(Suc n))) x0 :> (\<Sum> n. f n * real (Suc n) * x0^n)"
   732   (is "DERIV (\<lambda> x. (suminf (?f x))) x0 :> (suminf (?f' x0))")
   733 proof -
   734   { fix R' assume "0 < R'" and "R' < R" and "-R' < x0" and "x0 < R'"
   735     hence "x0 \<in> {-R' <..< R'}" and "R' \<in> {-R <..< R}" and "x0 \<in> {-R <..< R}" by auto
   736     have "DERIV (\<lambda> x. (suminf (?f x))) x0 :> (suminf (?f' x0))"
   737     proof (rule DERIV_series')
   738       show "summable (\<lambda> n. \<bar>f n * real (Suc n) * R'^n\<bar>)"
   739       proof -
   740         have "(R' + R) / 2 < R" and "0 < (R' + R) / 2" using `0 < R'` `0 < R` `R' < R` by auto
   741         hence in_Rball: "(R' + R) / 2 \<in> {-R <..< R}" using `R' < R` by auto
   742         have "norm R' < norm ((R' + R) / 2)" using `0 < R'` `0 < R` `R' < R` by auto
   743         from powser_insidea[OF converges[OF in_Rball] this] show ?thesis by auto
   744       qed
   745       { fix n x y assume "x \<in> {-R' <..< R'}" and "y \<in> {-R' <..< R'}"
   746         show "\<bar>?f x n - ?f y n\<bar> \<le> \<bar>f n * real (Suc n) * R'^n\<bar> * \<bar>x-y\<bar>"
   747         proof -
   748           have "\<bar>f n * x ^ (Suc n) - f n * y ^ (Suc n)\<bar> = (\<bar>f n\<bar> * \<bar>x-y\<bar>) * \<bar>\<Sum>p = 0..<Suc n. x ^ p * y ^ (n - p)\<bar>"
   749             unfolding right_diff_distrib[symmetric] lemma_realpow_diff_sumr2 abs_mult by auto
   750           also have "\<dots> \<le> (\<bar>f n\<bar> * \<bar>x-y\<bar>) * (\<bar>real (Suc n)\<bar> * \<bar>R' ^ n\<bar>)"
   751           proof (rule mult_left_mono)
   752             have "\<bar>\<Sum>p = 0..<Suc n. x ^ p * y ^ (n - p)\<bar> \<le> (\<Sum>p = 0..<Suc n. \<bar>x ^ p * y ^ (n - p)\<bar>)" by (rule setsum_abs)
   753             also have "\<dots> \<le> (\<Sum>p = 0..<Suc n. R' ^ n)"
   754             proof (rule setsum_mono)
   755               fix p assume "p \<in> {0..<Suc n}" hence "p \<le> n" by auto
   756               { fix n fix x :: real assume "x \<in> {-R'<..<R'}"
   757                 hence "\<bar>x\<bar> \<le> R'"  by auto
   758                 hence "\<bar>x^n\<bar> \<le> R'^n" unfolding power_abs by (rule power_mono, auto)
   759               } from mult_mono[OF this[OF `x \<in> {-R'<..<R'}`, of p] this[OF `y \<in> {-R'<..<R'}`, of "n-p"]] `0 < R'`
   760               have "\<bar>x^p * y^(n-p)\<bar> \<le> R'^p * R'^(n-p)" unfolding abs_mult by auto
   761               thus "\<bar>x^p * y^(n-p)\<bar> \<le> R'^n" unfolding power_add[symmetric] using `p \<le> n` by auto
   762             qed
   763             also have "\<dots> = real (Suc n) * R' ^ n" unfolding setsum_constant card_atLeastLessThan real_of_nat_def by auto
   764             finally show "\<bar>\<Sum>p = 0..<Suc n. x ^ p * y ^ (n - p)\<bar> \<le> \<bar>real (Suc n)\<bar> * \<bar>R' ^ n\<bar>" unfolding abs_real_of_nat_cancel abs_of_nonneg[OF zero_le_power[OF less_imp_le[OF `0 < R'`]]] .
   765             show "0 \<le> \<bar>f n\<bar> * \<bar>x - y\<bar>" unfolding abs_mult[symmetric] by auto
   766           qed
   767           also have "\<dots> = \<bar>f n * real (Suc n) * R' ^ n\<bar> * \<bar>x - y\<bar>" unfolding abs_mult mult_assoc[symmetric] by algebra
   768           finally show ?thesis .
   769         qed }
   770       { fix n show "DERIV (\<lambda> x. ?f x n) x0 :> (?f' x0 n)"
   771           by (auto intro!: DERIV_intros simp del: power_Suc) }
   772       { fix x assume "x \<in> {-R' <..< R'}" hence "R' \<in> {-R <..< R}" and "norm x < norm R'" using assms `R' < R` by auto
   773         have "summable (\<lambda> n. f n * x^n)"
   774         proof (rule summable_le2[THEN conjunct1, OF _ powser_insidea[OF converges[OF `R' \<in> {-R <..< R}`] `norm x < norm R'`]], rule allI)
   775           fix n
   776           have le: "\<bar>f n\<bar> * 1 \<le> \<bar>f n\<bar> * real (Suc n)" by (rule mult_left_mono, auto)
   777           show "\<bar>f n * x ^ n\<bar> \<le> norm (f n * real (Suc n) * x ^ n)" unfolding real_norm_def abs_mult
   778             by (rule mult_right_mono, auto simp add: le[unfolded mult_1_right])
   779         qed
   780         from this[THEN summable_mult2[where c=x], unfolded mult_assoc, unfolded mult_commute]
   781         show "summable (?f x)" by auto }
   782       show "summable (?f' x0)" using converges[OF `x0 \<in> {-R <..< R}`] .
   783       show "x0 \<in> {-R' <..< R'}" using `x0 \<in> {-R' <..< R'}` .
   784     qed
   785   } note for_subinterval = this
   786   let ?R = "(R + \<bar>x0\<bar>) / 2"
   787   have "\<bar>x0\<bar> < ?R" using assms by auto
   788   hence "- ?R < x0"
   789   proof (cases "x0 < 0")
   790     case True
   791     hence "- x0 < ?R" using `\<bar>x0\<bar> < ?R` by auto
   792     thus ?thesis unfolding neg_less_iff_less[symmetric, of "- x0"] by auto
   793   next
   794     case False
   795     have "- ?R < 0" using assms by auto
   796     also have "\<dots> \<le> x0" using False by auto
   797     finally show ?thesis .
   798   qed
   799   hence "0 < ?R" "?R < R" "- ?R < x0" and "x0 < ?R" using assms by auto
   800   from for_subinterval[OF this]
   801   show ?thesis .
   802 qed
   803 
   804 subsection {* Exponential Function *}
   805 
   806 definition exp :: "'a \<Rightarrow> 'a::{real_normed_field,banach}" where
   807   "exp = (\<lambda>x. \<Sum>n. x ^ n /\<^sub>R real (fact n))"
   808 
   809 lemma summable_exp_generic:
   810   fixes x :: "'a::{real_normed_algebra_1,banach}"
   811   defines S_def: "S \<equiv> \<lambda>n. x ^ n /\<^sub>R real (fact n)"
   812   shows "summable S"
   813 proof -
   814   have S_Suc: "\<And>n. S (Suc n) = (x * S n) /\<^sub>R real (Suc n)"
   815     unfolding S_def by (simp del: mult_Suc)
   816   obtain r :: real where r0: "0 < r" and r1: "r < 1"
   817     using dense [OF zero_less_one] by fast
   818   obtain N :: nat where N: "norm x < real N * r"
   819     using reals_Archimedean3 [OF r0] by fast
   820   from r1 show ?thesis
   821   proof (rule ratio_test [rule_format])
   822     fix n :: nat
   823     assume n: "N \<le> n"
   824     have "norm x \<le> real N * r"
   825       using N by (rule order_less_imp_le)
   826     also have "real N * r \<le> real (Suc n) * r"
   827       using r0 n by (simp add: mult_right_mono)
   828     finally have "norm x * norm (S n) \<le> real (Suc n) * r * norm (S n)"
   829       using norm_ge_zero by (rule mult_right_mono)
   830     hence "norm (x * S n) \<le> real (Suc n) * r * norm (S n)"
   831       by (rule order_trans [OF norm_mult_ineq])
   832     hence "norm (x * S n) / real (Suc n) \<le> r * norm (S n)"
   833       by (simp add: pos_divide_le_eq mult_ac)
   834     thus "norm (S (Suc n)) \<le> r * norm (S n)"
   835       by (simp add: S_Suc inverse_eq_divide)
   836   qed
   837 qed
   838 
   839 lemma summable_norm_exp:
   840   fixes x :: "'a::{real_normed_algebra_1,banach}"
   841   shows "summable (\<lambda>n. norm (x ^ n /\<^sub>R real (fact n)))"
   842 proof (rule summable_norm_comparison_test [OF exI, rule_format])
   843   show "summable (\<lambda>n. norm x ^ n /\<^sub>R real (fact n))"
   844     by (rule summable_exp_generic)
   845 next
   846   fix n show "norm (x ^ n /\<^sub>R real (fact n)) \<le> norm x ^ n /\<^sub>R real (fact n)"
   847     by (simp add: norm_power_ineq)
   848 qed
   849 
   850 lemma summable_exp: "summable (%n. inverse (real (fact n)) * x ^ n)"
   851 by (insert summable_exp_generic [where x=x], simp)
   852 
   853 lemma exp_converges: "(\<lambda>n. x ^ n /\<^sub>R real (fact n)) sums exp x"
   854 unfolding exp_def by (rule summable_exp_generic [THEN summable_sums])
   855 
   856 
   857 lemma exp_fdiffs:
   858       "diffs (%n. inverse(real (fact n))) = (%n. inverse(real (fact n)))"
   859 by (simp add: diffs_def mult_assoc [symmetric] real_of_nat_def of_nat_mult
   860          del: mult_Suc of_nat_Suc)
   861 
   862 lemma diffs_of_real: "diffs (\<lambda>n. of_real (f n)) = (\<lambda>n. of_real (diffs f n))"
   863 by (simp add: diffs_def)
   864 
   865 lemma DERIV_exp [simp]: "DERIV exp x :> exp(x)"
   866 unfolding exp_def scaleR_conv_of_real
   867 apply (rule DERIV_cong)
   868 apply (rule termdiffs [where K="of_real (1 + norm x)"])
   869 apply (simp_all only: diffs_of_real scaleR_conv_of_real exp_fdiffs)
   870 apply (rule exp_converges [THEN sums_summable, unfolded scaleR_conv_of_real])+
   871 apply (simp del: of_real_add)
   872 done
   873 
   874 lemma isCont_exp: "isCont exp x"
   875   by (rule DERIV_exp [THEN DERIV_isCont])
   876 
   877 lemma isCont_exp' [simp]: "isCont f a \<Longrightarrow> isCont (\<lambda>x. exp (f x)) a"
   878   by (rule isCont_o2 [OF _ isCont_exp])
   879 
   880 lemma tendsto_exp [tendsto_intros]:
   881   "(f ---> a) F \<Longrightarrow> ((\<lambda>x. exp (f x)) ---> exp a) F"
   882   by (rule isCont_tendsto_compose [OF isCont_exp])
   883 
   884 
   885 subsubsection {* Properties of the Exponential Function *}
   886 
   887 lemma powser_zero:
   888   fixes f :: "nat \<Rightarrow> 'a::{real_normed_algebra_1}"
   889   shows "(\<Sum>n. f n * 0 ^ n) = f 0"
   890 proof -
   891   have "(\<Sum>n = 0..<1. f n * 0 ^ n) = (\<Sum>n. f n * 0 ^ n)"
   892     by (rule sums_unique [OF series_zero], simp add: power_0_left)
   893   thus ?thesis unfolding One_nat_def by simp
   894 qed
   895 
   896 lemma exp_zero [simp]: "exp 0 = 1"
   897 unfolding exp_def by (simp add: scaleR_conv_of_real powser_zero)
   898 
   899 lemma setsum_cl_ivl_Suc2:
   900   "(\<Sum>i=m..Suc n. f i) = (if Suc n < m then 0 else f m + (\<Sum>i=m..n. f (Suc i)))"
   901 by (simp add: setsum_head_Suc setsum_shift_bounds_cl_Suc_ivl
   902          del: setsum_cl_ivl_Suc)
   903 
   904 lemma exp_series_add:
   905   fixes x y :: "'a::{real_field}"
   906   defines S_def: "S \<equiv> \<lambda>x n. x ^ n /\<^sub>R real (fact n)"
   907   shows "S (x + y) n = (\<Sum>i=0..n. S x i * S y (n - i))"
   908 proof (induct n)
   909   case 0
   910   show ?case
   911     unfolding S_def by simp
   912 next
   913   case (Suc n)
   914   have S_Suc: "\<And>x n. S x (Suc n) = (x * S x n) /\<^sub>R real (Suc n)"
   915     unfolding S_def by (simp del: mult_Suc)
   916   hence times_S: "\<And>x n. x * S x n = real (Suc n) *\<^sub>R S x (Suc n)"
   917     by simp
   918 
   919   have "real (Suc n) *\<^sub>R S (x + y) (Suc n) = (x + y) * S (x + y) n"
   920     by (simp only: times_S)
   921   also have "\<dots> = (x + y) * (\<Sum>i=0..n. S x i * S y (n-i))"
   922     by (simp only: Suc)
   923   also have "\<dots> = x * (\<Sum>i=0..n. S x i * S y (n-i))
   924                 + y * (\<Sum>i=0..n. S x i * S y (n-i))"
   925     by (rule left_distrib)
   926   also have "\<dots> = (\<Sum>i=0..n. (x * S x i) * S y (n-i))
   927                 + (\<Sum>i=0..n. S x i * (y * S y (n-i)))"
   928     by (simp only: setsum_right_distrib mult_ac)
   929   also have "\<dots> = (\<Sum>i=0..n. real (Suc i) *\<^sub>R (S x (Suc i) * S y (n-i)))
   930                 + (\<Sum>i=0..n. real (Suc n-i) *\<^sub>R (S x i * S y (Suc n-i)))"
   931     by (simp add: times_S Suc_diff_le)
   932   also have "(\<Sum>i=0..n. real (Suc i) *\<^sub>R (S x (Suc i) * S y (n-i))) =
   933              (\<Sum>i=0..Suc n. real i *\<^sub>R (S x i * S y (Suc n-i)))"
   934     by (subst setsum_cl_ivl_Suc2, simp)
   935   also have "(\<Sum>i=0..n. real (Suc n-i) *\<^sub>R (S x i * S y (Suc n-i))) =
   936              (\<Sum>i=0..Suc n. real (Suc n-i) *\<^sub>R (S x i * S y (Suc n-i)))"
   937     by (subst setsum_cl_ivl_Suc, simp)
   938   also have "(\<Sum>i=0..Suc n. real i *\<^sub>R (S x i * S y (Suc n-i))) +
   939              (\<Sum>i=0..Suc n. real (Suc n-i) *\<^sub>R (S x i * S y (Suc n-i))) =
   940              (\<Sum>i=0..Suc n. real (Suc n) *\<^sub>R (S x i * S y (Suc n-i)))"
   941     by (simp only: setsum_addf [symmetric] scaleR_left_distrib [symmetric]
   942               real_of_nat_add [symmetric], simp)
   943   also have "\<dots> = real (Suc n) *\<^sub>R (\<Sum>i=0..Suc n. S x i * S y (Suc n-i))"
   944     by (simp only: scaleR_right.setsum)
   945   finally show
   946     "S (x + y) (Suc n) = (\<Sum>i=0..Suc n. S x i * S y (Suc n - i))"
   947     by (simp del: setsum_cl_ivl_Suc)
   948 qed
   949 
   950 lemma exp_add: "exp (x + y) = exp x * exp y"
   951 unfolding exp_def
   952 by (simp only: Cauchy_product summable_norm_exp exp_series_add)
   953 
   954 lemma mult_exp_exp: "exp x * exp y = exp (x + y)"
   955 by (rule exp_add [symmetric])
   956 
   957 lemma exp_of_real: "exp (of_real x) = of_real (exp x)"
   958 unfolding exp_def
   959 apply (subst suminf_of_real)
   960 apply (rule summable_exp_generic)
   961 apply (simp add: scaleR_conv_of_real)
   962 done
   963 
   964 lemma exp_not_eq_zero [simp]: "exp x \<noteq> 0"
   965 proof
   966   have "exp x * exp (- x) = 1" by (simp add: mult_exp_exp)
   967   also assume "exp x = 0"
   968   finally show "False" by simp
   969 qed
   970 
   971 lemma exp_minus: "exp (- x) = inverse (exp x)"
   972 by (rule inverse_unique [symmetric], simp add: mult_exp_exp)
   973 
   974 lemma exp_diff: "exp (x - y) = exp x / exp y"
   975   unfolding diff_minus divide_inverse
   976   by (simp add: exp_add exp_minus)
   977 
   978 
   979 subsubsection {* Properties of the Exponential Function on Reals *}
   980 
   981 text {* Comparisons of @{term "exp x"} with zero. *}
   982 
   983 text{*Proof: because every exponential can be seen as a square.*}
   984 lemma exp_ge_zero [simp]: "0 \<le> exp (x::real)"
   985 proof -
   986   have "0 \<le> exp (x/2) * exp (x/2)" by simp
   987   thus ?thesis by (simp add: exp_add [symmetric])
   988 qed
   989 
   990 lemma exp_gt_zero [simp]: "0 < exp (x::real)"
   991 by (simp add: order_less_le)
   992 
   993 lemma not_exp_less_zero [simp]: "\<not> exp (x::real) < 0"
   994 by (simp add: not_less)
   995 
   996 lemma not_exp_le_zero [simp]: "\<not> exp (x::real) \<le> 0"
   997 by (simp add: not_le)
   998 
   999 lemma abs_exp_cancel [simp]: "\<bar>exp x::real\<bar> = exp x"
  1000 by simp
  1001 
  1002 lemma exp_real_of_nat_mult: "exp(real n * x) = exp(x) ^ n"
  1003 apply (induct "n")
  1004 apply (auto simp add: real_of_nat_Suc right_distrib exp_add mult_commute)
  1005 done
  1006 
  1007 text {* Strict monotonicity of exponential. *}
  1008 
  1009 lemma exp_ge_add_one_self_aux: "0 \<le> (x::real) ==> (1 + x) \<le> exp(x)"
  1010 apply (drule order_le_imp_less_or_eq, auto)
  1011 apply (simp add: exp_def)
  1012 apply (rule order_trans)
  1013 apply (rule_tac [2] n = 2 and f = "(%n. inverse (real (fact n)) * x ^ n)" in series_pos_le)
  1014 apply (auto intro: summable_exp simp add: numeral_2_eq_2 zero_le_mult_iff)
  1015 done
  1016 
  1017 lemma exp_gt_one: "0 < (x::real) \<Longrightarrow> 1 < exp x"
  1018 proof -
  1019   assume x: "0 < x"
  1020   hence "1 < 1 + x" by simp
  1021   also from x have "1 + x \<le> exp x"
  1022     by (simp add: exp_ge_add_one_self_aux)
  1023   finally show ?thesis .
  1024 qed
  1025 
  1026 lemma exp_less_mono:
  1027   fixes x y :: real
  1028   assumes "x < y" shows "exp x < exp y"
  1029 proof -
  1030   from `x < y` have "0 < y - x" by simp
  1031   hence "1 < exp (y - x)" by (rule exp_gt_one)
  1032   hence "1 < exp y / exp x" by (simp only: exp_diff)
  1033   thus "exp x < exp y" by simp
  1034 qed
  1035 
  1036 lemma exp_less_cancel: "exp (x::real) < exp y ==> x < y"
  1037 apply (simp add: linorder_not_le [symmetric])
  1038 apply (auto simp add: order_le_less exp_less_mono)
  1039 done
  1040 
  1041 lemma exp_less_cancel_iff [iff]: "exp (x::real) < exp y \<longleftrightarrow> x < y"
  1042 by (auto intro: exp_less_mono exp_less_cancel)
  1043 
  1044 lemma exp_le_cancel_iff [iff]: "exp (x::real) \<le> exp y \<longleftrightarrow> x \<le> y"
  1045 by (auto simp add: linorder_not_less [symmetric])
  1046 
  1047 lemma exp_inj_iff [iff]: "exp (x::real) = exp y \<longleftrightarrow> x = y"
  1048 by (simp add: order_eq_iff)
  1049 
  1050 text {* Comparisons of @{term "exp x"} with one. *}
  1051 
  1052 lemma one_less_exp_iff [simp]: "1 < exp (x::real) \<longleftrightarrow> 0 < x"
  1053   using exp_less_cancel_iff [where x=0 and y=x] by simp
  1054 
  1055 lemma exp_less_one_iff [simp]: "exp (x::real) < 1 \<longleftrightarrow> x < 0"
  1056   using exp_less_cancel_iff [where x=x and y=0] by simp
  1057 
  1058 lemma one_le_exp_iff [simp]: "1 \<le> exp (x::real) \<longleftrightarrow> 0 \<le> x"
  1059   using exp_le_cancel_iff [where x=0 and y=x] by simp
  1060 
  1061 lemma exp_le_one_iff [simp]: "exp (x::real) \<le> 1 \<longleftrightarrow> x \<le> 0"
  1062   using exp_le_cancel_iff [where x=x and y=0] by simp
  1063 
  1064 lemma exp_eq_one_iff [simp]: "exp (x::real) = 1 \<longleftrightarrow> x = 0"
  1065   using exp_inj_iff [where x=x and y=0] by simp
  1066 
  1067 lemma lemma_exp_total: "1 \<le> y ==> \<exists>x. 0 \<le> x & x \<le> y - 1 & exp(x::real) = y"
  1068 proof (rule IVT)
  1069   assume "1 \<le> y"
  1070   hence "0 \<le> y - 1" by simp
  1071   hence "1 + (y - 1) \<le> exp (y - 1)" by (rule exp_ge_add_one_self_aux)
  1072   thus "y \<le> exp (y - 1)" by simp
  1073 qed (simp_all add: le_diff_eq)
  1074 
  1075 lemma exp_total: "0 < (y::real) ==> \<exists>x. exp x = y"
  1076 proof (rule linorder_le_cases [of 1 y])
  1077   assume "1 \<le> y" thus "\<exists>x. exp x = y"
  1078     by (fast dest: lemma_exp_total)
  1079 next
  1080   assume "0 < y" and "y \<le> 1"
  1081   hence "1 \<le> inverse y" by (simp add: one_le_inverse_iff)
  1082   then obtain x where "exp x = inverse y" by (fast dest: lemma_exp_total)
  1083   hence "exp (- x) = y" by (simp add: exp_minus)
  1084   thus "\<exists>x. exp x = y" ..
  1085 qed
  1086 
  1087 
  1088 subsection {* Natural Logarithm *}
  1089 
  1090 definition ln :: "real \<Rightarrow> real" where
  1091   "ln x = (THE u. exp u = x)"
  1092 
  1093 lemma ln_exp [simp]: "ln (exp x) = x"
  1094   by (simp add: ln_def)
  1095 
  1096 lemma exp_ln [simp]: "0 < x \<Longrightarrow> exp (ln x) = x"
  1097   by (auto dest: exp_total)
  1098 
  1099 lemma exp_ln_iff [simp]: "exp (ln x) = x \<longleftrightarrow> 0 < x"
  1100   by (metis exp_gt_zero exp_ln)
  1101 
  1102 lemma ln_unique: "exp y = x \<Longrightarrow> ln x = y"
  1103   by (erule subst, rule ln_exp)
  1104 
  1105 lemma ln_one [simp]: "ln 1 = 0"
  1106   by (rule ln_unique, simp)
  1107 
  1108 lemma ln_mult: "\<lbrakk>0 < x; 0 < y\<rbrakk> \<Longrightarrow> ln (x * y) = ln x + ln y"
  1109   by (rule ln_unique, simp add: exp_add)
  1110 
  1111 lemma ln_inverse: "0 < x \<Longrightarrow> ln (inverse x) = - ln x"
  1112   by (rule ln_unique, simp add: exp_minus)
  1113 
  1114 lemma ln_div: "\<lbrakk>0 < x; 0 < y\<rbrakk> \<Longrightarrow> ln (x / y) = ln x - ln y"
  1115   by (rule ln_unique, simp add: exp_diff)
  1116 
  1117 lemma ln_realpow: "0 < x \<Longrightarrow> ln (x ^ n) = real n * ln x"
  1118   by (rule ln_unique, simp add: exp_real_of_nat_mult)
  1119 
  1120 lemma ln_less_cancel_iff [simp]: "\<lbrakk>0 < x; 0 < y\<rbrakk> \<Longrightarrow> ln x < ln y \<longleftrightarrow> x < y"
  1121   by (subst exp_less_cancel_iff [symmetric], simp)
  1122 
  1123 lemma ln_le_cancel_iff [simp]: "\<lbrakk>0 < x; 0 < y\<rbrakk> \<Longrightarrow> ln x \<le> ln y \<longleftrightarrow> x \<le> y"
  1124   by (simp add: linorder_not_less [symmetric])
  1125 
  1126 lemma ln_inj_iff [simp]: "\<lbrakk>0 < x; 0 < y\<rbrakk> \<Longrightarrow> ln x = ln y \<longleftrightarrow> x = y"
  1127   by (simp add: order_eq_iff)
  1128 
  1129 lemma ln_add_one_self_le_self [simp]: "0 \<le> x \<Longrightarrow> ln (1 + x) \<le> x"
  1130   apply (rule exp_le_cancel_iff [THEN iffD1])
  1131   apply (simp add: exp_ge_add_one_self_aux)
  1132   done
  1133 
  1134 lemma ln_less_self [simp]: "0 < x \<Longrightarrow> ln x < x"
  1135   by (rule order_less_le_trans [where y="ln (1 + x)"]) simp_all
  1136 
  1137 lemma ln_ge_zero [simp]: "1 \<le> x \<Longrightarrow> 0 \<le> ln x"
  1138   using ln_le_cancel_iff [of 1 x] by simp
  1139 
  1140 lemma ln_ge_zero_imp_ge_one: "\<lbrakk>0 \<le> ln x; 0 < x\<rbrakk> \<Longrightarrow> 1 \<le> x"
  1141   using ln_le_cancel_iff [of 1 x] by simp
  1142 
  1143 lemma ln_ge_zero_iff [simp]: "0 < x \<Longrightarrow> (0 \<le> ln x) = (1 \<le> x)"
  1144   using ln_le_cancel_iff [of 1 x] by simp
  1145 
  1146 lemma ln_less_zero_iff [simp]: "0 < x \<Longrightarrow> (ln x < 0) = (x < 1)"
  1147   using ln_less_cancel_iff [of x 1] by simp
  1148 
  1149 lemma ln_gt_zero: "1 < x \<Longrightarrow> 0 < ln x"
  1150   using ln_less_cancel_iff [of 1 x] by simp
  1151 
  1152 lemma ln_gt_zero_imp_gt_one: "\<lbrakk>0 < ln x; 0 < x\<rbrakk> \<Longrightarrow> 1 < x"
  1153   using ln_less_cancel_iff [of 1 x] by simp
  1154 
  1155 lemma ln_gt_zero_iff [simp]: "0 < x \<Longrightarrow> (0 < ln x) = (1 < x)"
  1156   using ln_less_cancel_iff [of 1 x] by simp
  1157 
  1158 lemma ln_eq_zero_iff [simp]: "0 < x \<Longrightarrow> (ln x = 0) = (x = 1)"
  1159   using ln_inj_iff [of x 1] by simp
  1160 
  1161 lemma ln_less_zero: "\<lbrakk>0 < x; x < 1\<rbrakk> \<Longrightarrow> ln x < 0"
  1162   by simp
  1163 
  1164 lemma isCont_ln: "0 < x \<Longrightarrow> isCont ln x"
  1165   apply (subgoal_tac "isCont ln (exp (ln x))", simp)
  1166   apply (rule isCont_inverse_function [where f=exp], simp_all)
  1167   done
  1168 
  1169 lemma tendsto_ln [tendsto_intros]:
  1170   "\<lbrakk>(f ---> a) F; 0 < a\<rbrakk> \<Longrightarrow> ((\<lambda>x. ln (f x)) ---> ln a) F"
  1171   by (rule isCont_tendsto_compose [OF isCont_ln])
  1172 
  1173 lemma DERIV_ln: "0 < x \<Longrightarrow> DERIV ln x :> inverse x"
  1174   apply (rule DERIV_inverse_function [where f=exp and a=0 and b="x+1"])
  1175   apply (erule DERIV_cong [OF DERIV_exp exp_ln])
  1176   apply (simp_all add: abs_if isCont_ln)
  1177   done
  1178 
  1179 lemma DERIV_ln_divide: "0 < x ==> DERIV ln x :> 1 / x"
  1180   by (rule DERIV_ln[THEN DERIV_cong], simp, simp add: divide_inverse)
  1181 
  1182 lemma ln_series: assumes "0 < x" and "x < 2"
  1183   shows "ln x = (\<Sum> n. (-1)^n * (1 / real (n + 1)) * (x - 1)^(Suc n))" (is "ln x = suminf (?f (x - 1))")
  1184 proof -
  1185   let "?f' x n" = "(-1)^n * (x - 1)^n"
  1186 
  1187   have "ln x - suminf (?f (x - 1)) = ln 1 - suminf (?f (1 - 1))"
  1188   proof (rule DERIV_isconst3[where x=x])
  1189     fix x :: real assume "x \<in> {0 <..< 2}" hence "0 < x" and "x < 2" by auto
  1190     have "norm (1 - x) < 1" using `0 < x` and `x < 2` by auto
  1191     have "1 / x = 1 / (1 - (1 - x))" by auto
  1192     also have "\<dots> = (\<Sum> n. (1 - x)^n)" using geometric_sums[OF `norm (1 - x) < 1`] by (rule sums_unique)
  1193     also have "\<dots> = suminf (?f' x)" unfolding power_mult_distrib[symmetric] by (rule arg_cong[where f=suminf], rule arg_cong[where f="op ^"], auto)
  1194     finally have "DERIV ln x :> suminf (?f' x)" using DERIV_ln[OF `0 < x`] unfolding divide_inverse by auto
  1195     moreover
  1196     have repos: "\<And> h x :: real. h - 1 + x = h + x - 1" by auto
  1197     have "DERIV (\<lambda>x. suminf (?f x)) (x - 1) :> (\<Sum>n. (-1)^n * (1 / real (n + 1)) * real (Suc n) * (x - 1) ^ n)"
  1198     proof (rule DERIV_power_series')
  1199       show "x - 1 \<in> {- 1<..<1}" and "(0 :: real) < 1" using `0 < x` `x < 2` by auto
  1200       { fix x :: real assume "x \<in> {- 1<..<1}" hence "norm (-x) < 1" by auto
  1201         show "summable (\<lambda>n. -1 ^ n * (1 / real (n + 1)) * real (Suc n) * x ^ n)"
  1202           unfolding One_nat_def
  1203           by (auto simp add: power_mult_distrib[symmetric] summable_geometric[OF `norm (-x) < 1`])
  1204       }
  1205     qed
  1206     hence "DERIV (\<lambda>x. suminf (?f x)) (x - 1) :> suminf (?f' x)" unfolding One_nat_def by auto
  1207     hence "DERIV (\<lambda>x. suminf (?f (x - 1))) x :> suminf (?f' x)" unfolding DERIV_iff repos .
  1208     ultimately have "DERIV (\<lambda>x. ln x - suminf (?f (x - 1))) x :> (suminf (?f' x) - suminf (?f' x))"
  1209       by (rule DERIV_diff)
  1210     thus "DERIV (\<lambda>x. ln x - suminf (?f (x - 1))) x :> 0" by auto
  1211   qed (auto simp add: assms)
  1212   thus ?thesis by auto
  1213 qed
  1214 
  1215 subsection {* Sine and Cosine *}
  1216 
  1217 definition sin_coeff :: "nat \<Rightarrow> real" where
  1218   "sin_coeff = (\<lambda>n. if even n then 0 else -1 ^ ((n - Suc 0) div 2) / real (fact n))"
  1219 
  1220 definition cos_coeff :: "nat \<Rightarrow> real" where
  1221   "cos_coeff = (\<lambda>n. if even n then (-1 ^ (n div 2)) / real (fact n) else 0)"
  1222 
  1223 definition sin :: "real \<Rightarrow> real" where
  1224   "sin = (\<lambda>x. \<Sum>n. sin_coeff n * x ^ n)"
  1225 
  1226 definition cos :: "real \<Rightarrow> real" where
  1227   "cos = (\<lambda>x. \<Sum>n. cos_coeff n * x ^ n)"
  1228 
  1229 lemma sin_coeff_0 [simp]: "sin_coeff 0 = 0"
  1230   unfolding sin_coeff_def by simp
  1231 
  1232 lemma cos_coeff_0 [simp]: "cos_coeff 0 = 1"
  1233   unfolding cos_coeff_def by simp
  1234 
  1235 lemma sin_coeff_Suc: "sin_coeff (Suc n) = cos_coeff n / real (Suc n)"
  1236   unfolding cos_coeff_def sin_coeff_def
  1237   by (simp del: mult_Suc)
  1238 
  1239 lemma cos_coeff_Suc: "cos_coeff (Suc n) = - sin_coeff n / real (Suc n)"
  1240   unfolding cos_coeff_def sin_coeff_def
  1241   by (simp del: mult_Suc, auto simp add: odd_Suc_mult_two_ex)
  1242 
  1243 lemma summable_sin: "summable (\<lambda>n. sin_coeff n * x ^ n)"
  1244 unfolding sin_coeff_def
  1245 apply (rule summable_comparison_test [OF _ summable_exp [where x="\<bar>x\<bar>"]])
  1246 apply (auto simp add: divide_inverse abs_mult power_abs [symmetric] zero_le_mult_iff)
  1247 done
  1248 
  1249 lemma summable_cos: "summable (\<lambda>n. cos_coeff n * x ^ n)"
  1250 unfolding cos_coeff_def
  1251 apply (rule summable_comparison_test [OF _ summable_exp [where x="\<bar>x\<bar>"]])
  1252 apply (auto simp add: divide_inverse abs_mult power_abs [symmetric] zero_le_mult_iff)
  1253 done
  1254 
  1255 lemma sin_converges: "(\<lambda>n. sin_coeff n * x ^ n) sums sin(x)"
  1256 unfolding sin_def by (rule summable_sin [THEN summable_sums])
  1257 
  1258 lemma cos_converges: "(\<lambda>n. cos_coeff n * x ^ n) sums cos(x)"
  1259 unfolding cos_def by (rule summable_cos [THEN summable_sums])
  1260 
  1261 lemma diffs_sin_coeff: "diffs sin_coeff = cos_coeff"
  1262   by (simp add: diffs_def sin_coeff_Suc real_of_nat_def del: of_nat_Suc)
  1263 
  1264 lemma diffs_cos_coeff: "diffs cos_coeff = (\<lambda>n. - sin_coeff n)"
  1265   by (simp add: diffs_def cos_coeff_Suc real_of_nat_def del: of_nat_Suc)
  1266 
  1267 text{*Now at last we can get the derivatives of exp, sin and cos*}
  1268 
  1269 lemma DERIV_sin [simp]: "DERIV sin x :> cos(x)"
  1270   unfolding sin_def cos_def
  1271   apply (rule DERIV_cong, rule termdiffs [where K="1 + \<bar>x\<bar>"])
  1272   apply (simp_all add: diffs_sin_coeff diffs_cos_coeff
  1273     summable_minus summable_sin summable_cos)
  1274   done
  1275 
  1276 lemma DERIV_cos [simp]: "DERIV cos x :> -sin(x)"
  1277   unfolding cos_def sin_def
  1278   apply (rule DERIV_cong, rule termdiffs [where K="1 + \<bar>x\<bar>"])
  1279   apply (simp_all add: diffs_sin_coeff diffs_cos_coeff diffs_minus
  1280     summable_minus summable_sin summable_cos suminf_minus)
  1281   done
  1282 
  1283 lemma isCont_sin: "isCont sin x"
  1284   by (rule DERIV_sin [THEN DERIV_isCont])
  1285 
  1286 lemma isCont_cos: "isCont cos x"
  1287   by (rule DERIV_cos [THEN DERIV_isCont])
  1288 
  1289 lemma isCont_sin' [simp]: "isCont f a \<Longrightarrow> isCont (\<lambda>x. sin (f x)) a"
  1290   by (rule isCont_o2 [OF _ isCont_sin])
  1291 
  1292 lemma isCont_cos' [simp]: "isCont f a \<Longrightarrow> isCont (\<lambda>x. cos (f x)) a"
  1293   by (rule isCont_o2 [OF _ isCont_cos])
  1294 
  1295 lemma tendsto_sin [tendsto_intros]:
  1296   "(f ---> a) F \<Longrightarrow> ((\<lambda>x. sin (f x)) ---> sin a) F"
  1297   by (rule isCont_tendsto_compose [OF isCont_sin])
  1298 
  1299 lemma tendsto_cos [tendsto_intros]:
  1300   "(f ---> a) F \<Longrightarrow> ((\<lambda>x. cos (f x)) ---> cos a) F"
  1301   by (rule isCont_tendsto_compose [OF isCont_cos])
  1302 
  1303 declare
  1304   DERIV_exp[THEN DERIV_chain2, THEN DERIV_cong, DERIV_intros]
  1305   DERIV_ln_divide[THEN DERIV_chain2, THEN DERIV_cong, DERIV_intros]
  1306   DERIV_sin[THEN DERIV_chain2, THEN DERIV_cong, DERIV_intros]
  1307   DERIV_cos[THEN DERIV_chain2, THEN DERIV_cong, DERIV_intros]
  1308 
  1309 subsection {* Properties of Sine and Cosine *}
  1310 
  1311 lemma sin_zero [simp]: "sin 0 = 0"
  1312   unfolding sin_def sin_coeff_def by (simp add: powser_zero)
  1313 
  1314 lemma cos_zero [simp]: "cos 0 = 1"
  1315   unfolding cos_def cos_coeff_def by (simp add: powser_zero)
  1316 
  1317 lemma sin_cos_squared_add [simp]: "(sin x)\<twosuperior> + (cos x)\<twosuperior> = 1"
  1318 proof -
  1319   have "\<forall>x. DERIV (\<lambda>x. (sin x)\<twosuperior> + (cos x)\<twosuperior>) x :> 0"
  1320     by (auto intro!: DERIV_intros)
  1321   hence "(sin x)\<twosuperior> + (cos x)\<twosuperior> = (sin 0)\<twosuperior> + (cos 0)\<twosuperior>"
  1322     by (rule DERIV_isconst_all)
  1323   thus "(sin x)\<twosuperior> + (cos x)\<twosuperior> = 1" by simp
  1324 qed
  1325 
  1326 lemma sin_cos_squared_add2 [simp]: "(cos x)\<twosuperior> + (sin x)\<twosuperior> = 1"
  1327   by (subst add_commute, rule sin_cos_squared_add)
  1328 
  1329 lemma sin_cos_squared_add3 [simp]: "cos x * cos x + sin x * sin x = 1"
  1330   using sin_cos_squared_add2 [unfolded power2_eq_square] .
  1331 
  1332 lemma sin_squared_eq: "(sin x)\<twosuperior> = 1 - (cos x)\<twosuperior>"
  1333   unfolding eq_diff_eq by (rule sin_cos_squared_add)
  1334 
  1335 lemma cos_squared_eq: "(cos x)\<twosuperior> = 1 - (sin x)\<twosuperior>"
  1336   unfolding eq_diff_eq by (rule sin_cos_squared_add2)
  1337 
  1338 lemma abs_sin_le_one [simp]: "\<bar>sin x\<bar> \<le> 1"
  1339   by (rule power2_le_imp_le, simp_all add: sin_squared_eq)
  1340 
  1341 lemma sin_ge_minus_one [simp]: "-1 \<le> sin x"
  1342   using abs_sin_le_one [of x] unfolding abs_le_iff by simp
  1343 
  1344 lemma sin_le_one [simp]: "sin x \<le> 1"
  1345   using abs_sin_le_one [of x] unfolding abs_le_iff by simp
  1346 
  1347 lemma abs_cos_le_one [simp]: "\<bar>cos x\<bar> \<le> 1"
  1348   by (rule power2_le_imp_le, simp_all add: cos_squared_eq)
  1349 
  1350 lemma cos_ge_minus_one [simp]: "-1 \<le> cos x"
  1351   using abs_cos_le_one [of x] unfolding abs_le_iff by simp
  1352 
  1353 lemma cos_le_one [simp]: "cos x \<le> 1"
  1354   using abs_cos_le_one [of x] unfolding abs_le_iff by simp
  1355 
  1356 lemma DERIV_fun_pow: "DERIV g x :> m ==>
  1357       DERIV (%x. (g x) ^ n) x :> real n * (g x) ^ (n - 1) * m"
  1358   by (auto intro!: DERIV_intros)
  1359 
  1360 lemma DERIV_fun_exp:
  1361      "DERIV g x :> m ==> DERIV (%x. exp(g x)) x :> exp(g x) * m"
  1362   by (auto intro!: DERIV_intros)
  1363 
  1364 lemma DERIV_fun_sin:
  1365      "DERIV g x :> m ==> DERIV (%x. sin(g x)) x :> cos(g x) * m"
  1366   by (auto intro!: DERIV_intros)
  1367 
  1368 lemma DERIV_fun_cos:
  1369      "DERIV g x :> m ==> DERIV (%x. cos(g x)) x :> -sin(g x) * m"
  1370   by (auto intro!: DERIV_intros)
  1371 
  1372 lemma sin_cos_add_lemma:
  1373      "(sin (x + y) - (sin x * cos y + cos x * sin y)) ^ 2 +
  1374       (cos (x + y) - (cos x * cos y - sin x * sin y)) ^ 2 = 0"
  1375   (is "?f x = 0")
  1376 proof -
  1377   have "\<forall>x. DERIV (\<lambda>x. ?f x) x :> 0"
  1378     by (auto intro!: DERIV_intros simp add: algebra_simps)
  1379   hence "?f x = ?f 0"
  1380     by (rule DERIV_isconst_all)
  1381   thus ?thesis by simp
  1382 qed
  1383 
  1384 lemma sin_add: "sin (x + y) = sin x * cos y + cos x * sin y"
  1385   using sin_cos_add_lemma unfolding realpow_two_sum_zero_iff by simp
  1386 
  1387 lemma cos_add: "cos (x + y) = cos x * cos y - sin x * sin y"
  1388   using sin_cos_add_lemma unfolding realpow_two_sum_zero_iff by simp
  1389 
  1390 lemma sin_cos_minus_lemma:
  1391   "(sin(-x) + sin(x))\<twosuperior> + (cos(-x) - cos(x))\<twosuperior> = 0" (is "?f x = 0")
  1392 proof -
  1393   have "\<forall>x. DERIV (\<lambda>x. ?f x) x :> 0"
  1394     by (auto intro!: DERIV_intros simp add: algebra_simps)
  1395   hence "?f x = ?f 0"
  1396     by (rule DERIV_isconst_all)
  1397   thus ?thesis by simp
  1398 qed
  1399 
  1400 lemma sin_minus [simp]: "sin (-x) = -sin(x)"
  1401   using sin_cos_minus_lemma [where x=x] by simp
  1402 
  1403 lemma cos_minus [simp]: "cos (-x) = cos(x)"
  1404   using sin_cos_minus_lemma [where x=x] by simp
  1405 
  1406 lemma sin_diff: "sin (x - y) = sin x * cos y - cos x * sin y"
  1407   by (simp add: diff_minus sin_add)
  1408 
  1409 lemma sin_diff2: "sin (x - y) = cos y * sin x - sin y * cos x"
  1410   by (simp add: sin_diff mult_commute)
  1411 
  1412 lemma cos_diff: "cos (x - y) = cos x * cos y + sin x * sin y"
  1413   by (simp add: diff_minus cos_add)
  1414 
  1415 lemma cos_diff2: "cos (x - y) = cos y * cos x + sin y * sin x"
  1416   by (simp add: cos_diff mult_commute)
  1417 
  1418 lemma sin_double [simp]: "sin(2 * x) = 2* sin x * cos x"
  1419   using sin_add [where x=x and y=x] by simp
  1420 
  1421 lemma cos_double: "cos(2* x) = ((cos x)\<twosuperior>) - ((sin x)\<twosuperior>)"
  1422   using cos_add [where x=x and y=x]
  1423   by (simp add: power2_eq_square)
  1424 
  1425 
  1426 subsection {* The Constant Pi *}
  1427 
  1428 definition pi :: "real" where
  1429   "pi = 2 * (THE x. 0 \<le> (x::real) & x \<le> 2 & cos x = 0)"
  1430 
  1431 text{*Show that there's a least positive @{term x} with @{term "cos(x) = 0"};
  1432    hence define pi.*}
  1433 
  1434 lemma sin_paired:
  1435      "(%n. -1 ^ n /(real (fact (2 * n + 1))) * x ^ (2 * n + 1))
  1436       sums  sin x"
  1437 proof -
  1438   have "(\<lambda>n. \<Sum>k = n * 2..<n * 2 + 2. sin_coeff k * x ^ k) sums sin x"
  1439     by (rule sin_converges [THEN sums_group], simp)
  1440   thus ?thesis unfolding One_nat_def sin_coeff_def by (simp add: mult_ac)
  1441 qed
  1442 
  1443 lemma sin_gt_zero:
  1444   assumes "0 < x" and "x < 2" shows "0 < sin x"
  1445 proof -
  1446   let ?f = "\<lambda>n. \<Sum>k = n*2..<n*2+2. -1 ^ k / real (fact (2*k+1)) * x^(2*k+1)"
  1447   have pos: "\<forall>n. 0 < ?f n"
  1448   proof
  1449     fix n :: nat
  1450     let ?k2 = "real (Suc (Suc (4 * n)))"
  1451     let ?k3 = "real (Suc (Suc (Suc (4 * n))))"
  1452     have "x * x < ?k2 * ?k3"
  1453       using assms by (intro mult_strict_mono', simp_all)
  1454     hence "x * x * x * x ^ (n * 4) < ?k2 * ?k3 * x * x ^ (n * 4)"
  1455       by (intro mult_strict_right_mono zero_less_power `0 < x`)
  1456     thus "0 < ?f n"
  1457       by (simp del: mult_Suc,
  1458         simp add: less_divide_eq mult_pos_pos field_simps del: mult_Suc)
  1459   qed
  1460   have sums: "?f sums sin x"
  1461     by (rule sin_paired [THEN sums_group], simp)
  1462   show "0 < sin x"
  1463     unfolding sums_unique [OF sums]
  1464     using sums_summable [OF sums] pos
  1465     by (rule suminf_gt_zero)
  1466 qed
  1467 
  1468 lemma cos_double_less_one: "[| 0 < x; x < 2 |] ==> cos (2 * x) < 1"
  1469 apply (cut_tac x = x in sin_gt_zero)
  1470 apply (auto simp add: cos_squared_eq cos_double)
  1471 done
  1472 
  1473 lemma cos_paired:
  1474      "(%n. -1 ^ n /(real (fact (2 * n))) * x ^ (2 * n)) sums cos x"
  1475 proof -
  1476   have "(\<lambda>n. \<Sum>k = n * 2..<n * 2 + 2. cos_coeff k * x ^ k) sums cos x"
  1477     by (rule cos_converges [THEN sums_group], simp)
  1478   thus ?thesis unfolding cos_coeff_def by (simp add: mult_ac)
  1479 qed
  1480 
  1481 lemma real_mult_inverse_cancel:
  1482      "[|(0::real) < x; 0 < x1; x1 * y < x * u |]
  1483       ==> inverse x * y < inverse x1 * u"
  1484 apply (rule_tac c=x in mult_less_imp_less_left)
  1485 apply (auto simp add: mult_assoc [symmetric])
  1486 apply (simp (no_asm) add: mult_ac)
  1487 apply (rule_tac c=x1 in mult_less_imp_less_right)
  1488 apply (auto simp add: mult_ac)
  1489 done
  1490 
  1491 lemma real_mult_inverse_cancel2:
  1492      "[|(0::real) < x;0 < x1; x1 * y < x * u |] ==> y * inverse x < u * inverse x1"
  1493 apply (auto dest: real_mult_inverse_cancel simp add: mult_ac)
  1494 done
  1495 
  1496 lemma realpow_num_eq_if:
  1497   fixes m :: "'a::power"
  1498   shows "m ^ n = (if n=0 then 1 else m * m ^ (n - 1))"
  1499 by (cases n, auto)
  1500 
  1501 lemma cos_two_less_zero [simp]: "cos (2) < 0"
  1502 apply (cut_tac x = 2 in cos_paired)
  1503 apply (drule sums_minus)
  1504 apply (rule neg_less_iff_less [THEN iffD1])
  1505 apply (frule sums_unique, auto)
  1506 apply (rule_tac y =
  1507  "\<Sum>n=0..< Suc(Suc(Suc 0)). - (-1 ^ n / (real(fact (2*n))) * 2 ^ (2*n))"
  1508        in order_less_trans)
  1509 apply (simp (no_asm) add: fact_num_eq_if_nat realpow_num_eq_if del: fact_Suc)
  1510 apply (simp (no_asm) add: mult_assoc del: setsum_op_ivl_Suc)
  1511 apply (rule sumr_pos_lt_pair)
  1512 apply (erule sums_summable, safe)
  1513 unfolding One_nat_def
  1514 apply (simp (no_asm) add: divide_inverse real_0_less_add_iff mult_assoc [symmetric]
  1515             del: fact_Suc)
  1516 apply (simp add: inverse_eq_divide less_divide_eq del: fact_Suc)
  1517 apply (subst fact_Suc [of "Suc (Suc (Suc (Suc (Suc (Suc (Suc (4 * d)))))))"])
  1518 apply (simp only: real_of_nat_mult)
  1519 apply (rule mult_strict_mono, force)
  1520   apply (rule_tac [3] real_of_nat_ge_zero)
  1521  prefer 2 apply force
  1522 apply (rule real_of_nat_less_iff [THEN iffD2])
  1523 apply (rule fact_less_mono_nat, auto)
  1524 done
  1525 
  1526 lemmas cos_two_neq_zero [simp] = cos_two_less_zero [THEN less_imp_neq]
  1527 lemmas cos_two_le_zero [simp] = cos_two_less_zero [THEN order_less_imp_le]
  1528 
  1529 lemma cos_is_zero: "EX! x. 0 \<le> x & x \<le> 2 & cos x = 0"
  1530 proof (rule ex_ex1I)
  1531   show "\<exists>x. 0 \<le> x & x \<le> 2 & cos x = 0"
  1532     by (rule IVT2, simp_all)
  1533 next
  1534   fix x y
  1535   assume x: "0 \<le> x \<and> x \<le> 2 \<and> cos x = 0"
  1536   assume y: "0 \<le> y \<and> y \<le> 2 \<and> cos y = 0"
  1537   have [simp]: "\<forall>x. cos differentiable x"
  1538     unfolding differentiable_def by (auto intro: DERIV_cos)
  1539   from x y show "x = y"
  1540     apply (cut_tac less_linear [of x y], auto)
  1541     apply (drule_tac f = cos in Rolle)
  1542     apply (drule_tac [5] f = cos in Rolle)
  1543     apply (auto dest!: DERIV_cos [THEN DERIV_unique])
  1544     apply (metis order_less_le_trans less_le sin_gt_zero)
  1545     apply (metis order_less_le_trans less_le sin_gt_zero)
  1546     done
  1547 qed
  1548 
  1549 lemma pi_half: "pi/2 = (THE x. 0 \<le> x & x \<le> 2 & cos x = 0)"
  1550 by (simp add: pi_def)
  1551 
  1552 lemma cos_pi_half [simp]: "cos (pi / 2) = 0"
  1553 by (simp add: pi_half cos_is_zero [THEN theI'])
  1554 
  1555 lemma pi_half_gt_zero [simp]: "0 < pi / 2"
  1556 apply (rule order_le_neq_trans)
  1557 apply (simp add: pi_half cos_is_zero [THEN theI'])
  1558 apply (rule notI, drule arg_cong [where f=cos], simp)
  1559 done
  1560 
  1561 lemmas pi_half_neq_zero [simp] = pi_half_gt_zero [THEN less_imp_neq, symmetric]
  1562 lemmas pi_half_ge_zero [simp] = pi_half_gt_zero [THEN order_less_imp_le]
  1563 
  1564 lemma pi_half_less_two [simp]: "pi / 2 < 2"
  1565 apply (rule order_le_neq_trans)
  1566 apply (simp add: pi_half cos_is_zero [THEN theI'])
  1567 apply (rule notI, drule arg_cong [where f=cos], simp)
  1568 done
  1569 
  1570 lemmas pi_half_neq_two [simp] = pi_half_less_two [THEN less_imp_neq]
  1571 lemmas pi_half_le_two [simp] =  pi_half_less_two [THEN order_less_imp_le]
  1572 
  1573 lemma pi_gt_zero [simp]: "0 < pi"
  1574 by (insert pi_half_gt_zero, simp)
  1575 
  1576 lemma pi_ge_zero [simp]: "0 \<le> pi"
  1577 by (rule pi_gt_zero [THEN order_less_imp_le])
  1578 
  1579 lemma pi_neq_zero [simp]: "pi \<noteq> 0"
  1580 by (rule pi_gt_zero [THEN less_imp_neq, THEN not_sym])
  1581 
  1582 lemma pi_not_less_zero [simp]: "\<not> pi < 0"
  1583 by (simp add: linorder_not_less)
  1584 
  1585 lemma minus_pi_half_less_zero: "-(pi/2) < 0"
  1586 by simp
  1587 
  1588 lemma m2pi_less_pi: "- (2 * pi) < pi"
  1589 by simp
  1590 
  1591 lemma sin_pi_half [simp]: "sin(pi/2) = 1"
  1592 apply (cut_tac x = "pi/2" in sin_cos_squared_add2)
  1593 apply (cut_tac sin_gt_zero [OF pi_half_gt_zero pi_half_less_two])
  1594 apply (simp add: power2_eq_1_iff)
  1595 done
  1596 
  1597 lemma cos_pi [simp]: "cos pi = -1"
  1598 by (cut_tac x = "pi/2" and y = "pi/2" in cos_add, simp)
  1599 
  1600 lemma sin_pi [simp]: "sin pi = 0"
  1601 by (cut_tac x = "pi/2" and y = "pi/2" in sin_add, simp)
  1602 
  1603 lemma sin_cos_eq: "sin x = cos (pi/2 - x)"
  1604 by (simp add: cos_diff)
  1605 
  1606 lemma minus_sin_cos_eq: "-sin x = cos (x + pi/2)"
  1607 by (simp add: cos_add)
  1608 
  1609 lemma cos_sin_eq: "cos x = sin (pi/2 - x)"
  1610 by (simp add: sin_diff)
  1611 
  1612 lemma sin_periodic_pi [simp]: "sin (x + pi) = - sin x"
  1613 by (simp add: sin_add)
  1614 
  1615 lemma sin_periodic_pi2 [simp]: "sin (pi + x) = - sin x"
  1616 by (simp add: sin_add)
  1617 
  1618 lemma cos_periodic_pi [simp]: "cos (x + pi) = - cos x"
  1619 by (simp add: cos_add)
  1620 
  1621 lemma sin_periodic [simp]: "sin (x + 2*pi) = sin x"
  1622 by (simp add: sin_add cos_double)
  1623 
  1624 lemma cos_periodic [simp]: "cos (x + 2*pi) = cos x"
  1625 by (simp add: cos_add cos_double)
  1626 
  1627 lemma cos_npi [simp]: "cos (real n * pi) = -1 ^ n"
  1628 apply (induct "n")
  1629 apply (auto simp add: real_of_nat_Suc left_distrib)
  1630 done
  1631 
  1632 lemma cos_npi2 [simp]: "cos (pi * real n) = -1 ^ n"
  1633 proof -
  1634   have "cos (pi * real n) = cos (real n * pi)" by (simp only: mult_commute)
  1635   also have "... = -1 ^ n" by (rule cos_npi)
  1636   finally show ?thesis .
  1637 qed
  1638 
  1639 lemma sin_npi [simp]: "sin (real (n::nat) * pi) = 0"
  1640 apply (induct "n")
  1641 apply (auto simp add: real_of_nat_Suc left_distrib)
  1642 done
  1643 
  1644 lemma sin_npi2 [simp]: "sin (pi * real (n::nat)) = 0"
  1645 by (simp add: mult_commute [of pi])
  1646 
  1647 lemma cos_two_pi [simp]: "cos (2 * pi) = 1"
  1648 by (simp add: cos_double)
  1649 
  1650 lemma sin_two_pi [simp]: "sin (2 * pi) = 0"
  1651 by simp
  1652 
  1653 lemma sin_gt_zero2: "[| 0 < x; x < pi/2 |] ==> 0 < sin x"
  1654 apply (rule sin_gt_zero, assumption)
  1655 apply (rule order_less_trans, assumption)
  1656 apply (rule pi_half_less_two)
  1657 done
  1658 
  1659 lemma sin_less_zero:
  1660   assumes lb: "- pi/2 < x" and "x < 0" shows "sin x < 0"
  1661 proof -
  1662   have "0 < sin (- x)" using assms by (simp only: sin_gt_zero2)
  1663   thus ?thesis by simp
  1664 qed
  1665 
  1666 lemma pi_less_4: "pi < 4"
  1667 by (cut_tac pi_half_less_two, auto)
  1668 
  1669 lemma cos_gt_zero: "[| 0 < x; x < pi/2 |] ==> 0 < cos x"
  1670 apply (cut_tac pi_less_4)
  1671 apply (cut_tac f = cos and a = 0 and b = x and y = 0 in IVT2_objl, safe, simp_all)
  1672 apply (cut_tac cos_is_zero, safe)
  1673 apply (rename_tac y z)
  1674 apply (drule_tac x = y in spec)
  1675 apply (drule_tac x = "pi/2" in spec, simp)
  1676 done
  1677 
  1678 lemma cos_gt_zero_pi: "[| -(pi/2) < x; x < pi/2 |] ==> 0 < cos x"
  1679 apply (rule_tac x = x and y = 0 in linorder_cases)
  1680 apply (rule cos_minus [THEN subst])
  1681 apply (rule cos_gt_zero)
  1682 apply (auto intro: cos_gt_zero)
  1683 done
  1684 
  1685 lemma cos_ge_zero: "[| -(pi/2) \<le> x; x \<le> pi/2 |] ==> 0 \<le> cos x"
  1686 apply (auto simp add: order_le_less cos_gt_zero_pi)
  1687 apply (subgoal_tac "x = pi/2", auto)
  1688 done
  1689 
  1690 lemma sin_gt_zero_pi: "[| 0 < x; x < pi  |] ==> 0 < sin x"
  1691 by (simp add: sin_cos_eq cos_gt_zero_pi)
  1692 
  1693 lemma pi_ge_two: "2 \<le> pi"
  1694 proof (rule ccontr)
  1695   assume "\<not> 2 \<le> pi" hence "pi < 2" by auto
  1696   have "\<exists>y > pi. y < 2 \<and> y < 2 * pi"
  1697   proof (cases "2 < 2 * pi")
  1698     case True with dense[OF `pi < 2`] show ?thesis by auto
  1699   next
  1700     case False have "pi < 2 * pi" by auto
  1701     from dense[OF this] and False show ?thesis by auto
  1702   qed
  1703   then obtain y where "pi < y" and "y < 2" and "y < 2 * pi" by blast
  1704   hence "0 < sin y" using sin_gt_zero by auto
  1705   moreover
  1706   have "sin y < 0" using sin_gt_zero_pi[of "y - pi"] `pi < y` and `y < 2 * pi` sin_periodic_pi[of "y - pi"] by auto
  1707   ultimately show False by auto
  1708 qed
  1709 
  1710 lemma sin_ge_zero: "[| 0 \<le> x; x \<le> pi |] ==> 0 \<le> sin x"
  1711 by (auto simp add: order_le_less sin_gt_zero_pi)
  1712 
  1713 text {* FIXME: This proof is almost identical to lemma @{text cos_is_zero}.
  1714   It should be possible to factor out some of the common parts. *}
  1715 
  1716 lemma cos_total: "[| -1 \<le> y; y \<le> 1 |] ==> EX! x. 0 \<le> x & x \<le> pi & (cos x = y)"
  1717 proof (rule ex_ex1I)
  1718   assume y: "-1 \<le> y" "y \<le> 1"
  1719   show "\<exists>x. 0 \<le> x & x \<le> pi & cos x = y"
  1720     by (rule IVT2, simp_all add: y)
  1721 next
  1722   fix a b
  1723   assume a: "0 \<le> a \<and> a \<le> pi \<and> cos a = y"
  1724   assume b: "0 \<le> b \<and> b \<le> pi \<and> cos b = y"
  1725   have [simp]: "\<forall>x. cos differentiable x"
  1726     unfolding differentiable_def by (auto intro: DERIV_cos)
  1727   from a b show "a = b"
  1728     apply (cut_tac less_linear [of a b], auto)
  1729     apply (drule_tac f = cos in Rolle)
  1730     apply (drule_tac [5] f = cos in Rolle)
  1731     apply (auto dest!: DERIV_cos [THEN DERIV_unique])
  1732     apply (metis order_less_le_trans less_le sin_gt_zero_pi)
  1733     apply (metis order_less_le_trans less_le sin_gt_zero_pi)
  1734     done
  1735 qed
  1736 
  1737 lemma sin_total:
  1738      "[| -1 \<le> y; y \<le> 1 |] ==> EX! x. -(pi/2) \<le> x & x \<le> pi/2 & (sin x = y)"
  1739 apply (rule ccontr)
  1740 apply (subgoal_tac "\<forall>x. (- (pi/2) \<le> x & x \<le> pi/2 & (sin x = y)) = (0 \<le> (x + pi/2) & (x + pi/2) \<le> pi & (cos (x + pi/2) = -y))")
  1741 apply (erule contrapos_np)
  1742 apply simp
  1743 apply (cut_tac y="-y" in cos_total, simp) apply simp
  1744 apply (erule ex1E)
  1745 apply (rule_tac a = "x - (pi/2)" in ex1I)
  1746 apply (simp (no_asm) add: add_assoc)
  1747 apply (rotate_tac 3)
  1748 apply (drule_tac x = "xa + pi/2" in spec, safe, simp_all add: cos_add)
  1749 done
  1750 
  1751 lemma reals_Archimedean4:
  1752      "[| 0 < y; 0 \<le> x |] ==> \<exists>n. real n * y \<le> x & x < real (Suc n) * y"
  1753 apply (auto dest!: reals_Archimedean3)
  1754 apply (drule_tac x = x in spec, clarify)
  1755 apply (subgoal_tac "x < real(LEAST m::nat. x < real m * y) * y")
  1756  prefer 2 apply (erule LeastI)
  1757 apply (case_tac "LEAST m::nat. x < real m * y", simp)
  1758 apply (subgoal_tac "~ x < real nat * y")
  1759  prefer 2 apply (rule not_less_Least, simp, force)
  1760 done
  1761 
  1762 (* Pre Isabelle99-2 proof was simpler- numerals arithmetic
  1763    now causes some unwanted re-arrangements of literals!   *)
  1764 lemma cos_zero_lemma:
  1765      "[| 0 \<le> x; cos x = 0 |] ==>
  1766       \<exists>n::nat. ~even n & x = real n * (pi/2)"
  1767 apply (drule pi_gt_zero [THEN reals_Archimedean4], safe)
  1768 apply (subgoal_tac "0 \<le> x - real n * pi &
  1769                     (x - real n * pi) \<le> pi & (cos (x - real n * pi) = 0) ")
  1770 apply (auto simp add: algebra_simps real_of_nat_Suc)
  1771  prefer 2 apply (simp add: cos_diff)
  1772 apply (simp add: cos_diff)
  1773 apply (subgoal_tac "EX! x. 0 \<le> x & x \<le> pi & cos x = 0")
  1774 apply (rule_tac [2] cos_total, safe)
  1775 apply (drule_tac x = "x - real n * pi" in spec)
  1776 apply (drule_tac x = "pi/2" in spec)
  1777 apply (simp add: cos_diff)
  1778 apply (rule_tac x = "Suc (2 * n)" in exI)
  1779 apply (simp add: real_of_nat_Suc algebra_simps, auto)
  1780 done
  1781 
  1782 lemma sin_zero_lemma:
  1783      "[| 0 \<le> x; sin x = 0 |] ==>
  1784       \<exists>n::nat. even n & x = real n * (pi/2)"
  1785 apply (subgoal_tac "\<exists>n::nat. ~ even n & x + pi/2 = real n * (pi/2) ")
  1786  apply (clarify, rule_tac x = "n - 1" in exI)
  1787  apply (force simp add: odd_Suc_mult_two_ex real_of_nat_Suc left_distrib)
  1788 apply (rule cos_zero_lemma)
  1789 apply (simp_all add: cos_add)
  1790 done
  1791 
  1792 
  1793 lemma cos_zero_iff:
  1794      "(cos x = 0) =
  1795       ((\<exists>n::nat. ~even n & (x = real n * (pi/2))) |
  1796        (\<exists>n::nat. ~even n & (x = -(real n * (pi/2)))))"
  1797 apply (rule iffI)
  1798 apply (cut_tac linorder_linear [of 0 x], safe)
  1799 apply (drule cos_zero_lemma, assumption+)
  1800 apply (cut_tac x="-x" in cos_zero_lemma, simp, simp)
  1801 apply (force simp add: minus_equation_iff [of x])
  1802 apply (auto simp only: odd_Suc_mult_two_ex real_of_nat_Suc left_distrib)
  1803 apply (auto simp add: cos_add)
  1804 done
  1805 
  1806 (* ditto: but to a lesser extent *)
  1807 lemma sin_zero_iff:
  1808      "(sin x = 0) =
  1809       ((\<exists>n::nat. even n & (x = real n * (pi/2))) |
  1810        (\<exists>n::nat. even n & (x = -(real n * (pi/2)))))"
  1811 apply (rule iffI)
  1812 apply (cut_tac linorder_linear [of 0 x], safe)
  1813 apply (drule sin_zero_lemma, assumption+)
  1814 apply (cut_tac x="-x" in sin_zero_lemma, simp, simp, safe)
  1815 apply (force simp add: minus_equation_iff [of x])
  1816 apply (auto simp add: even_mult_two_ex)
  1817 done
  1818 
  1819 lemma cos_monotone_0_pi: assumes "0 \<le> y" and "y < x" and "x \<le> pi"
  1820   shows "cos x < cos y"
  1821 proof -
  1822   have "- (x - y) < 0" using assms by auto
  1823 
  1824   from MVT2[OF `y < x` DERIV_cos[THEN impI, THEN allI]]
  1825   obtain z where "y < z" and "z < x" and cos_diff: "cos x - cos y = (x - y) * - sin z" by auto
  1826   hence "0 < z" and "z < pi" using assms by auto
  1827   hence "0 < sin z" using sin_gt_zero_pi by auto
  1828   hence "cos x - cos y < 0" unfolding cos_diff minus_mult_commute[symmetric] using `- (x - y) < 0` by (rule mult_pos_neg2)
  1829   thus ?thesis by auto
  1830 qed
  1831 
  1832 lemma cos_monotone_0_pi': assumes "0 \<le> y" and "y \<le> x" and "x \<le> pi" shows "cos x \<le> cos y"
  1833 proof (cases "y < x")
  1834   case True show ?thesis using cos_monotone_0_pi[OF `0 \<le> y` True `x \<le> pi`] by auto
  1835 next
  1836   case False hence "y = x" using `y \<le> x` by auto
  1837   thus ?thesis by auto
  1838 qed
  1839 
  1840 lemma cos_monotone_minus_pi_0: assumes "-pi \<le> y" and "y < x" and "x \<le> 0"
  1841   shows "cos y < cos x"
  1842 proof -
  1843   have "0 \<le> -x" and "-x < -y" and "-y \<le> pi" using assms by auto
  1844   from cos_monotone_0_pi[OF this]
  1845   show ?thesis unfolding cos_minus .
  1846 qed
  1847 
  1848 lemma cos_monotone_minus_pi_0': assumes "-pi \<le> y" and "y \<le> x" and "x \<le> 0" shows "cos y \<le> cos x"
  1849 proof (cases "y < x")
  1850   case True show ?thesis using cos_monotone_minus_pi_0[OF `-pi \<le> y` True `x \<le> 0`] by auto
  1851 next
  1852   case False hence "y = x" using `y \<le> x` by auto
  1853   thus ?thesis by auto
  1854 qed
  1855 
  1856 lemma sin_monotone_2pi': assumes "- (pi / 2) \<le> y" and "y \<le> x" and "x \<le> pi / 2" shows "sin y \<le> sin x"
  1857 proof -
  1858   have "0 \<le> y + pi / 2" and "y + pi / 2 \<le> x + pi / 2" and "x + pi /2 \<le> pi"
  1859     using pi_ge_two and assms by auto
  1860   from cos_monotone_0_pi'[OF this] show ?thesis unfolding minus_sin_cos_eq[symmetric] by auto
  1861 qed
  1862 
  1863 subsection {* Tangent *}
  1864 
  1865 definition tan :: "real \<Rightarrow> real" where
  1866   "tan = (\<lambda>x. sin x / cos x)"
  1867 
  1868 lemma tan_zero [simp]: "tan 0 = 0"
  1869   by (simp add: tan_def)
  1870 
  1871 lemma tan_pi [simp]: "tan pi = 0"
  1872   by (simp add: tan_def)
  1873 
  1874 lemma tan_npi [simp]: "tan (real (n::nat) * pi) = 0"
  1875   by (simp add: tan_def)
  1876 
  1877 lemma tan_minus [simp]: "tan (-x) = - tan x"
  1878   by (simp add: tan_def)
  1879 
  1880 lemma tan_periodic [simp]: "tan (x + 2*pi) = tan x"
  1881   by (simp add: tan_def)
  1882 
  1883 lemma lemma_tan_add1:
  1884   "\<lbrakk>cos x \<noteq> 0; cos y \<noteq> 0\<rbrakk> \<Longrightarrow> 1 - tan x * tan y = cos (x + y)/(cos x * cos y)"
  1885   by (simp add: tan_def cos_add field_simps)
  1886 
  1887 lemma add_tan_eq:
  1888   "\<lbrakk>cos x \<noteq> 0; cos y \<noteq> 0\<rbrakk> \<Longrightarrow> tan x + tan y = sin(x + y)/(cos x * cos y)"
  1889   by (simp add: tan_def sin_add field_simps)
  1890 
  1891 lemma tan_add:
  1892      "[| cos x \<noteq> 0; cos y \<noteq> 0; cos (x + y) \<noteq> 0 |]
  1893       ==> tan(x + y) = (tan(x) + tan(y))/(1 - tan(x) * tan(y))"
  1894   by (simp add: add_tan_eq lemma_tan_add1, simp add: tan_def)
  1895 
  1896 lemma tan_double:
  1897      "[| cos x \<noteq> 0; cos (2 * x) \<noteq> 0 |]
  1898       ==> tan (2 * x) = (2 * tan x)/(1 - (tan(x) ^ 2))"
  1899   using tan_add [of x x] by (simp add: power2_eq_square)
  1900 
  1901 lemma tan_gt_zero: "[| 0 < x; x < pi/2 |] ==> 0 < tan x"
  1902 by (simp add: tan_def zero_less_divide_iff sin_gt_zero2 cos_gt_zero_pi)
  1903 
  1904 lemma tan_less_zero:
  1905   assumes lb: "- pi/2 < x" and "x < 0" shows "tan x < 0"
  1906 proof -
  1907   have "0 < tan (- x)" using assms by (simp only: tan_gt_zero)
  1908   thus ?thesis by simp
  1909 qed
  1910 
  1911 lemma tan_half: "tan x = sin (2 * x) / (cos (2 * x) + 1)"
  1912   unfolding tan_def sin_double cos_double sin_squared_eq
  1913   by (simp add: power2_eq_square)
  1914 
  1915 lemma DERIV_tan [simp]: "cos x \<noteq> 0 \<Longrightarrow> DERIV tan x :> inverse ((cos x)\<twosuperior>)"
  1916   unfolding tan_def
  1917   by (auto intro!: DERIV_intros, simp add: divide_inverse power2_eq_square)
  1918 
  1919 lemma isCont_tan: "cos x \<noteq> 0 \<Longrightarrow> isCont tan x"
  1920   by (rule DERIV_tan [THEN DERIV_isCont])
  1921 
  1922 lemma isCont_tan' [simp]:
  1923   "\<lbrakk>isCont f a; cos (f a) \<noteq> 0\<rbrakk> \<Longrightarrow> isCont (\<lambda>x. tan (f x)) a"
  1924   by (rule isCont_o2 [OF _ isCont_tan])
  1925 
  1926 lemma tendsto_tan [tendsto_intros]:
  1927   "\<lbrakk>(f ---> a) F; cos a \<noteq> 0\<rbrakk> \<Longrightarrow> ((\<lambda>x. tan (f x)) ---> tan a) F"
  1928   by (rule isCont_tendsto_compose [OF isCont_tan])
  1929 
  1930 lemma LIM_cos_div_sin: "(%x. cos(x)/sin(x)) -- pi/2 --> 0"
  1931   by (rule LIM_cong_limit, (rule tendsto_intros)+, simp_all)
  1932 
  1933 lemma lemma_tan_total: "0 < y ==> \<exists>x. 0 < x & x < pi/2 & y < tan x"
  1934 apply (cut_tac LIM_cos_div_sin)
  1935 apply (simp only: LIM_eq)
  1936 apply (drule_tac x = "inverse y" in spec, safe, force)
  1937 apply (drule_tac ?d1.0 = s in pi_half_gt_zero [THEN [2] real_lbound_gt_zero], safe)
  1938 apply (rule_tac x = "(pi/2) - e" in exI)
  1939 apply (simp (no_asm_simp))
  1940 apply (drule_tac x = "(pi/2) - e" in spec)
  1941 apply (auto simp add: tan_def sin_diff cos_diff)
  1942 apply (rule inverse_less_iff_less [THEN iffD1])
  1943 apply (auto simp add: divide_inverse)
  1944 apply (rule mult_pos_pos)
  1945 apply (subgoal_tac [3] "0 < sin e & 0 < cos e")
  1946 apply (auto intro: cos_gt_zero sin_gt_zero2 simp add: mult_commute)
  1947 done
  1948 
  1949 lemma tan_total_pos: "0 \<le> y ==> \<exists>x. 0 \<le> x & x < pi/2 & tan x = y"
  1950 apply (frule order_le_imp_less_or_eq, safe)
  1951  prefer 2 apply force
  1952 apply (drule lemma_tan_total, safe)
  1953 apply (cut_tac f = tan and a = 0 and b = x and y = y in IVT_objl)
  1954 apply (auto intro!: DERIV_tan [THEN DERIV_isCont])
  1955 apply (drule_tac y = xa in order_le_imp_less_or_eq)
  1956 apply (auto dest: cos_gt_zero)
  1957 done
  1958 
  1959 lemma lemma_tan_total1: "\<exists>x. -(pi/2) < x & x < (pi/2) & tan x = y"
  1960 apply (cut_tac linorder_linear [of 0 y], safe)
  1961 apply (drule tan_total_pos)
  1962 apply (cut_tac [2] y="-y" in tan_total_pos, safe)
  1963 apply (rule_tac [3] x = "-x" in exI)
  1964 apply (auto del: exI intro!: exI)
  1965 done
  1966 
  1967 lemma tan_total: "EX! x. -(pi/2) < x & x < (pi/2) & tan x = y"
  1968 apply (cut_tac y = y in lemma_tan_total1, auto)
  1969 apply (cut_tac x = xa and y = y in linorder_less_linear, auto)
  1970 apply (subgoal_tac [2] "\<exists>z. y < z & z < xa & DERIV tan z :> 0")
  1971 apply (subgoal_tac "\<exists>z. xa < z & z < y & DERIV tan z :> 0")
  1972 apply (rule_tac [4] Rolle)
  1973 apply (rule_tac [2] Rolle)
  1974 apply (auto del: exI intro!: DERIV_tan DERIV_isCont exI
  1975             simp add: differentiable_def)
  1976 txt{*Now, simulate TRYALL*}
  1977 apply (rule_tac [!] DERIV_tan asm_rl)
  1978 apply (auto dest!: DERIV_unique [OF _ DERIV_tan]
  1979             simp add: cos_gt_zero_pi [THEN less_imp_neq, THEN not_sym])
  1980 done
  1981 
  1982 lemma tan_monotone: assumes "- (pi / 2) < y" and "y < x" and "x < pi / 2"
  1983   shows "tan y < tan x"
  1984 proof -
  1985   have "\<forall> x'. y \<le> x' \<and> x' \<le> x \<longrightarrow> DERIV tan x' :> inverse (cos x'^2)"
  1986   proof (rule allI, rule impI)
  1987     fix x' :: real assume "y \<le> x' \<and> x' \<le> x"
  1988     hence "-(pi/2) < x'" and "x' < pi/2" using assms by auto
  1989     from cos_gt_zero_pi[OF this]
  1990     have "cos x' \<noteq> 0" by auto
  1991     thus "DERIV tan x' :> inverse (cos x'^2)" by (rule DERIV_tan)
  1992   qed
  1993   from MVT2[OF `y < x` this]
  1994   obtain z where "y < z" and "z < x" and tan_diff: "tan x - tan y = (x - y) * inverse ((cos z)\<twosuperior>)" by auto
  1995   hence "- (pi / 2) < z" and "z < pi / 2" using assms by auto
  1996   hence "0 < cos z" using cos_gt_zero_pi by auto
  1997   hence inv_pos: "0 < inverse ((cos z)\<twosuperior>)" by auto
  1998   have "0 < x - y" using `y < x` by auto
  1999   from mult_pos_pos [OF this inv_pos]
  2000   have "0 < tan x - tan y" unfolding tan_diff by auto
  2001   thus ?thesis by auto
  2002 qed
  2003 
  2004 lemma tan_monotone': assumes "- (pi / 2) < y" and "y < pi / 2" and "- (pi / 2) < x" and "x < pi / 2"
  2005   shows "(y < x) = (tan y < tan x)"
  2006 proof
  2007   assume "y < x" thus "tan y < tan x" using tan_monotone and `- (pi / 2) < y` and `x < pi / 2` by auto
  2008 next
  2009   assume "tan y < tan x"
  2010   show "y < x"
  2011   proof (rule ccontr)
  2012     assume "\<not> y < x" hence "x \<le> y" by auto
  2013     hence "tan x \<le> tan y"
  2014     proof (cases "x = y")
  2015       case True thus ?thesis by auto
  2016     next
  2017       case False hence "x < y" using `x \<le> y` by auto
  2018       from tan_monotone[OF `- (pi/2) < x` this `y < pi / 2`] show ?thesis by auto
  2019     qed
  2020     thus False using `tan y < tan x` by auto
  2021   qed
  2022 qed
  2023 
  2024 lemma tan_inverse: "1 / (tan y) = tan (pi / 2 - y)" unfolding tan_def sin_cos_eq[of y] cos_sin_eq[of y] by auto
  2025 
  2026 lemma tan_periodic_pi[simp]: "tan (x + pi) = tan x"
  2027   by (simp add: tan_def)
  2028 
  2029 lemma tan_periodic_nat[simp]: fixes n :: nat shows "tan (x + real n * pi) = tan x"
  2030 proof (induct n arbitrary: x)
  2031   case (Suc n)
  2032   have split_pi_off: "x + real (Suc n) * pi = (x + real n * pi) + pi" unfolding Suc_eq_plus1 real_of_nat_add real_of_one left_distrib by auto
  2033   show ?case unfolding split_pi_off using Suc by auto
  2034 qed auto
  2035 
  2036 lemma tan_periodic_int[simp]: fixes i :: int shows "tan (x + real i * pi) = tan x"
  2037 proof (cases "0 \<le> i")
  2038   case True hence i_nat: "real i = real (nat i)" by auto
  2039   show ?thesis unfolding i_nat by auto
  2040 next
  2041   case False hence i_nat: "real i = - real (nat (-i))" by auto
  2042   have "tan x = tan (x + real i * pi - real i * pi)" by auto
  2043   also have "\<dots> = tan (x + real i * pi)" unfolding i_nat mult_minus_left diff_minus_eq_add by (rule tan_periodic_nat)
  2044   finally show ?thesis by auto
  2045 qed
  2046 
  2047 lemma tan_periodic_n[simp]: "tan (x + numeral n * pi) = tan x"
  2048   using tan_periodic_int[of _ "numeral n" ] unfolding real_numeral .
  2049 
  2050 subsection {* Inverse Trigonometric Functions *}
  2051 
  2052 definition
  2053   arcsin :: "real => real" where
  2054   "arcsin y = (THE x. -(pi/2) \<le> x & x \<le> pi/2 & sin x = y)"
  2055 
  2056 definition
  2057   arccos :: "real => real" where
  2058   "arccos y = (THE x. 0 \<le> x & x \<le> pi & cos x = y)"
  2059 
  2060 definition
  2061   arctan :: "real => real" where
  2062   "arctan y = (THE x. -(pi/2) < x & x < pi/2 & tan x = y)"
  2063 
  2064 lemma arcsin:
  2065      "[| -1 \<le> y; y \<le> 1 |]
  2066       ==> -(pi/2) \<le> arcsin y &
  2067            arcsin y \<le> pi/2 & sin(arcsin y) = y"
  2068 unfolding arcsin_def by (rule theI' [OF sin_total])
  2069 
  2070 lemma arcsin_pi:
  2071      "[| -1 \<le> y; y \<le> 1 |]
  2072       ==> -(pi/2) \<le> arcsin y & arcsin y \<le> pi & sin(arcsin y) = y"
  2073 apply (drule (1) arcsin)
  2074 apply (force intro: order_trans)
  2075 done
  2076 
  2077 lemma sin_arcsin [simp]: "[| -1 \<le> y; y \<le> 1 |] ==> sin(arcsin y) = y"
  2078 by (blast dest: arcsin)
  2079 
  2080 lemma arcsin_bounded:
  2081      "[| -1 \<le> y; y \<le> 1 |] ==> -(pi/2) \<le> arcsin y & arcsin y \<le> pi/2"
  2082 by (blast dest: arcsin)
  2083 
  2084 lemma arcsin_lbound: "[| -1 \<le> y; y \<le> 1 |] ==> -(pi/2) \<le> arcsin y"
  2085 by (blast dest: arcsin)
  2086 
  2087 lemma arcsin_ubound: "[| -1 \<le> y; y \<le> 1 |] ==> arcsin y \<le> pi/2"
  2088 by (blast dest: arcsin)
  2089 
  2090 lemma arcsin_lt_bounded:
  2091      "[| -1 < y; y < 1 |] ==> -(pi/2) < arcsin y & arcsin y < pi/2"
  2092 apply (frule order_less_imp_le)
  2093 apply (frule_tac y = y in order_less_imp_le)
  2094 apply (frule arcsin_bounded)
  2095 apply (safe, simp)
  2096 apply (drule_tac y = "arcsin y" in order_le_imp_less_or_eq)
  2097 apply (drule_tac [2] y = "pi/2" in order_le_imp_less_or_eq, safe)
  2098 apply (drule_tac [!] f = sin in arg_cong, auto)
  2099 done
  2100 
  2101 lemma arcsin_sin: "[|-(pi/2) \<le> x; x \<le> pi/2 |] ==> arcsin(sin x) = x"
  2102 apply (unfold arcsin_def)
  2103 apply (rule the1_equality)
  2104 apply (rule sin_total, auto)
  2105 done
  2106 
  2107 lemma arccos:
  2108      "[| -1 \<le> y; y \<le> 1 |]
  2109       ==> 0 \<le> arccos y & arccos y \<le> pi & cos(arccos y) = y"
  2110 unfolding arccos_def by (rule theI' [OF cos_total])
  2111 
  2112 lemma cos_arccos [simp]: "[| -1 \<le> y; y \<le> 1 |] ==> cos(arccos y) = y"
  2113 by (blast dest: arccos)
  2114 
  2115 lemma arccos_bounded: "[| -1 \<le> y; y \<le> 1 |] ==> 0 \<le> arccos y & arccos y \<le> pi"
  2116 by (blast dest: arccos)
  2117 
  2118 lemma arccos_lbound: "[| -1 \<le> y; y \<le> 1 |] ==> 0 \<le> arccos y"
  2119 by (blast dest: arccos)
  2120 
  2121 lemma arccos_ubound: "[| -1 \<le> y; y \<le> 1 |] ==> arccos y \<le> pi"
  2122 by (blast dest: arccos)
  2123 
  2124 lemma arccos_lt_bounded:
  2125      "[| -1 < y; y < 1 |]
  2126       ==> 0 < arccos y & arccos y < pi"
  2127 apply (frule order_less_imp_le)
  2128 apply (frule_tac y = y in order_less_imp_le)
  2129 apply (frule arccos_bounded, auto)
  2130 apply (drule_tac y = "arccos y" in order_le_imp_less_or_eq)
  2131 apply (drule_tac [2] y = pi in order_le_imp_less_or_eq, auto)
  2132 apply (drule_tac [!] f = cos in arg_cong, auto)
  2133 done
  2134 
  2135 lemma arccos_cos: "[|0 \<le> x; x \<le> pi |] ==> arccos(cos x) = x"
  2136 apply (simp add: arccos_def)
  2137 apply (auto intro!: the1_equality cos_total)
  2138 done
  2139 
  2140 lemma arccos_cos2: "[|x \<le> 0; -pi \<le> x |] ==> arccos(cos x) = -x"
  2141 apply (simp add: arccos_def)
  2142 apply (auto intro!: the1_equality cos_total)
  2143 done
  2144 
  2145 lemma cos_arcsin: "\<lbrakk>-1 \<le> x; x \<le> 1\<rbrakk> \<Longrightarrow> cos (arcsin x) = sqrt (1 - x\<twosuperior>)"
  2146 apply (subgoal_tac "x\<twosuperior> \<le> 1")
  2147 apply (rule power2_eq_imp_eq)
  2148 apply (simp add: cos_squared_eq)
  2149 apply (rule cos_ge_zero)
  2150 apply (erule (1) arcsin_lbound)
  2151 apply (erule (1) arcsin_ubound)
  2152 apply simp
  2153 apply (subgoal_tac "\<bar>x\<bar>\<twosuperior> \<le> 1\<twosuperior>", simp)
  2154 apply (rule power_mono, simp, simp)
  2155 done
  2156 
  2157 lemma sin_arccos: "\<lbrakk>-1 \<le> x; x \<le> 1\<rbrakk> \<Longrightarrow> sin (arccos x) = sqrt (1 - x\<twosuperior>)"
  2158 apply (subgoal_tac "x\<twosuperior> \<le> 1")
  2159 apply (rule power2_eq_imp_eq)
  2160 apply (simp add: sin_squared_eq)
  2161 apply (rule sin_ge_zero)
  2162 apply (erule (1) arccos_lbound)
  2163 apply (erule (1) arccos_ubound)
  2164 apply simp
  2165 apply (subgoal_tac "\<bar>x\<bar>\<twosuperior> \<le> 1\<twosuperior>", simp)
  2166 apply (rule power_mono, simp, simp)
  2167 done
  2168 
  2169 lemma arctan [simp]:
  2170      "- (pi/2) < arctan y  & arctan y < pi/2 & tan (arctan y) = y"
  2171 unfolding arctan_def by (rule theI' [OF tan_total])
  2172 
  2173 lemma tan_arctan: "tan(arctan y) = y"
  2174 by auto
  2175 
  2176 lemma arctan_bounded: "- (pi/2) < arctan y  & arctan y < pi/2"
  2177 by (auto simp only: arctan)
  2178 
  2179 lemma arctan_lbound: "- (pi/2) < arctan y"
  2180 by auto
  2181 
  2182 lemma arctan_ubound: "arctan y < pi/2"
  2183 by (auto simp only: arctan)
  2184 
  2185 lemma arctan_unique:
  2186   assumes "-(pi/2) < x" and "x < pi/2" and "tan x = y"
  2187   shows "arctan y = x"
  2188   using assms arctan [of y] tan_total [of y] by (fast elim: ex1E)
  2189 
  2190 lemma arctan_tan:
  2191       "[|-(pi/2) < x; x < pi/2 |] ==> arctan(tan x) = x"
  2192   by (rule arctan_unique, simp_all)
  2193 
  2194 lemma arctan_zero_zero [simp]: "arctan 0 = 0"
  2195   by (rule arctan_unique, simp_all)
  2196 
  2197 lemma arctan_minus: "arctan (- x) = - arctan x"
  2198   apply (rule arctan_unique)
  2199   apply (simp only: neg_less_iff_less arctan_ubound)
  2200   apply (metis minus_less_iff arctan_lbound)
  2201   apply simp
  2202   done
  2203 
  2204 lemma cos_arctan_not_zero [simp]: "cos (arctan x) \<noteq> 0"
  2205   by (intro less_imp_neq [symmetric] cos_gt_zero_pi
  2206     arctan_lbound arctan_ubound)
  2207 
  2208 lemma cos_arctan: "cos (arctan x) = 1 / sqrt (1 + x\<twosuperior>)"
  2209 proof (rule power2_eq_imp_eq)
  2210   have "0 < 1 + x\<twosuperior>" by (simp add: add_pos_nonneg)
  2211   show "0 \<le> 1 / sqrt (1 + x\<twosuperior>)" by simp
  2212   show "0 \<le> cos (arctan x)"
  2213     by (intro less_imp_le cos_gt_zero_pi arctan_lbound arctan_ubound)
  2214   have "(cos (arctan x))\<twosuperior> * (1 + (tan (arctan x))\<twosuperior>) = 1"
  2215     unfolding tan_def by (simp add: right_distrib power_divide)
  2216   thus "(cos (arctan x))\<twosuperior> = (1 / sqrt (1 + x\<twosuperior>))\<twosuperior>"
  2217     using `0 < 1 + x\<twosuperior>` by (simp add: power_divide eq_divide_eq)
  2218 qed
  2219 
  2220 lemma sin_arctan: "sin (arctan x) = x / sqrt (1 + x\<twosuperior>)"
  2221   using add_pos_nonneg [OF zero_less_one zero_le_power2 [of x]]
  2222   using tan_arctan [of x] unfolding tan_def cos_arctan
  2223   by (simp add: eq_divide_eq)
  2224 
  2225 lemma tan_sec: "cos x \<noteq> 0 ==> 1 + tan(x) ^ 2 = inverse(cos x) ^ 2"
  2226 apply (rule power_inverse [THEN subst])
  2227 apply (rule_tac c1 = "(cos x)\<twosuperior>" in real_mult_right_cancel [THEN iffD1])
  2228 apply (auto dest: field_power_not_zero
  2229         simp add: power_mult_distrib left_distrib power_divide tan_def
  2230                   mult_assoc power_inverse [symmetric])
  2231 done
  2232 
  2233 lemma arctan_less_iff: "arctan x < arctan y \<longleftrightarrow> x < y"
  2234   by (metis tan_monotone' arctan_lbound arctan_ubound tan_arctan)
  2235 
  2236 lemma arctan_le_iff: "arctan x \<le> arctan y \<longleftrightarrow> x \<le> y"
  2237   by (simp only: not_less [symmetric] arctan_less_iff)
  2238 
  2239 lemma arctan_eq_iff: "arctan x = arctan y \<longleftrightarrow> x = y"
  2240   by (simp only: eq_iff [where 'a=real] arctan_le_iff)
  2241 
  2242 lemma zero_less_arctan_iff [simp]: "0 < arctan x \<longleftrightarrow> 0 < x"
  2243   using arctan_less_iff [of 0 x] by simp
  2244 
  2245 lemma arctan_less_zero_iff [simp]: "arctan x < 0 \<longleftrightarrow> x < 0"
  2246   using arctan_less_iff [of x 0] by simp
  2247 
  2248 lemma zero_le_arctan_iff [simp]: "0 \<le> arctan x \<longleftrightarrow> 0 \<le> x"
  2249   using arctan_le_iff [of 0 x] by simp
  2250 
  2251 lemma arctan_le_zero_iff [simp]: "arctan x \<le> 0 \<longleftrightarrow> x \<le> 0"
  2252   using arctan_le_iff [of x 0] by simp
  2253 
  2254 lemma arctan_eq_zero_iff [simp]: "arctan x = 0 \<longleftrightarrow> x = 0"
  2255   using arctan_eq_iff [of x 0] by simp
  2256 
  2257 lemma isCont_inverse_function2:
  2258   fixes f g :: "real \<Rightarrow> real" shows
  2259   "\<lbrakk>a < x; x < b;
  2260     \<forall>z. a \<le> z \<and> z \<le> b \<longrightarrow> g (f z) = z;
  2261     \<forall>z. a \<le> z \<and> z \<le> b \<longrightarrow> isCont f z\<rbrakk>
  2262    \<Longrightarrow> isCont g (f x)"
  2263 apply (rule isCont_inverse_function
  2264        [where f=f and d="min (x - a) (b - x)"])
  2265 apply (simp_all add: abs_le_iff)
  2266 done
  2267 
  2268 lemma isCont_arcsin: "\<lbrakk>-1 < x; x < 1\<rbrakk> \<Longrightarrow> isCont arcsin x"
  2269 apply (subgoal_tac "isCont arcsin (sin (arcsin x))", simp)
  2270 apply (rule isCont_inverse_function2 [where f=sin])
  2271 apply (erule (1) arcsin_lt_bounded [THEN conjunct1])
  2272 apply (erule (1) arcsin_lt_bounded [THEN conjunct2])
  2273 apply (fast intro: arcsin_sin, simp)
  2274 done
  2275 
  2276 lemma isCont_arccos: "\<lbrakk>-1 < x; x < 1\<rbrakk> \<Longrightarrow> isCont arccos x"
  2277 apply (subgoal_tac "isCont arccos (cos (arccos x))", simp)
  2278 apply (rule isCont_inverse_function2 [where f=cos])
  2279 apply (erule (1) arccos_lt_bounded [THEN conjunct1])
  2280 apply (erule (1) arccos_lt_bounded [THEN conjunct2])
  2281 apply (fast intro: arccos_cos, simp)
  2282 done
  2283 
  2284 lemma isCont_arctan: "isCont arctan x"
  2285 apply (rule arctan_lbound [of x, THEN dense, THEN exE], clarify)
  2286 apply (rule arctan_ubound [of x, THEN dense, THEN exE], clarify)
  2287 apply (subgoal_tac "isCont arctan (tan (arctan x))", simp)
  2288 apply (erule (1) isCont_inverse_function2 [where f=tan])
  2289 apply (metis arctan_tan order_le_less_trans order_less_le_trans)
  2290 apply (metis cos_gt_zero_pi isCont_tan order_less_le_trans less_le)
  2291 done
  2292 
  2293 lemma DERIV_arcsin:
  2294   "\<lbrakk>-1 < x; x < 1\<rbrakk> \<Longrightarrow> DERIV arcsin x :> inverse (sqrt (1 - x\<twosuperior>))"
  2295 apply (rule DERIV_inverse_function [where f=sin and a="-1" and b="1"])
  2296 apply (rule DERIV_cong [OF DERIV_sin])
  2297 apply (simp add: cos_arcsin)
  2298 apply (subgoal_tac "\<bar>x\<bar>\<twosuperior> < 1\<twosuperior>", simp)
  2299 apply (rule power_strict_mono, simp, simp, simp)
  2300 apply assumption
  2301 apply assumption
  2302 apply simp
  2303 apply (erule (1) isCont_arcsin)
  2304 done
  2305 
  2306 lemma DERIV_arccos:
  2307   "\<lbrakk>-1 < x; x < 1\<rbrakk> \<Longrightarrow> DERIV arccos x :> inverse (- sqrt (1 - x\<twosuperior>))"
  2308 apply (rule DERIV_inverse_function [where f=cos and a="-1" and b="1"])
  2309 apply (rule DERIV_cong [OF DERIV_cos])
  2310 apply (simp add: sin_arccos)
  2311 apply (subgoal_tac "\<bar>x\<bar>\<twosuperior> < 1\<twosuperior>", simp)
  2312 apply (rule power_strict_mono, simp, simp, simp)
  2313 apply assumption
  2314 apply assumption
  2315 apply simp
  2316 apply (erule (1) isCont_arccos)
  2317 done
  2318 
  2319 lemma DERIV_arctan: "DERIV arctan x :> inverse (1 + x\<twosuperior>)"
  2320 apply (rule DERIV_inverse_function [where f=tan and a="x - 1" and b="x + 1"])
  2321 apply (rule DERIV_cong [OF DERIV_tan])
  2322 apply (rule cos_arctan_not_zero)
  2323 apply (simp add: power_inverse tan_sec [symmetric])
  2324 apply (subgoal_tac "0 < 1 + x\<twosuperior>", simp)
  2325 apply (simp add: add_pos_nonneg)
  2326 apply (simp, simp, simp, rule isCont_arctan)
  2327 done
  2328 
  2329 declare
  2330   DERIV_arcsin[THEN DERIV_chain2, THEN DERIV_cong, DERIV_intros]
  2331   DERIV_arccos[THEN DERIV_chain2, THEN DERIV_cong, DERIV_intros]
  2332   DERIV_arctan[THEN DERIV_chain2, THEN DERIV_cong, DERIV_intros]
  2333 
  2334 subsection {* More Theorems about Sin and Cos *}
  2335 
  2336 lemma cos_45: "cos (pi / 4) = sqrt 2 / 2"
  2337 proof -
  2338   let ?c = "cos (pi / 4)" and ?s = "sin (pi / 4)"
  2339   have nonneg: "0 \<le> ?c"
  2340     by (simp add: cos_ge_zero)
  2341   have "0 = cos (pi / 4 + pi / 4)"
  2342     by simp
  2343   also have "cos (pi / 4 + pi / 4) = ?c\<twosuperior> - ?s\<twosuperior>"
  2344     by (simp only: cos_add power2_eq_square)
  2345   also have "\<dots> = 2 * ?c\<twosuperior> - 1"
  2346     by (simp add: sin_squared_eq)
  2347   finally have "?c\<twosuperior> = (sqrt 2 / 2)\<twosuperior>"
  2348     by (simp add: power_divide)
  2349   thus ?thesis
  2350     using nonneg by (rule power2_eq_imp_eq) simp
  2351 qed
  2352 
  2353 lemma cos_30: "cos (pi / 6) = sqrt 3 / 2"
  2354 proof -
  2355   let ?c = "cos (pi / 6)" and ?s = "sin (pi / 6)"
  2356   have pos_c: "0 < ?c"
  2357     by (rule cos_gt_zero, simp, simp)
  2358   have "0 = cos (pi / 6 + pi / 6 + pi / 6)"
  2359     by simp
  2360   also have "\<dots> = (?c * ?c - ?s * ?s) * ?c - (?s * ?c + ?c * ?s) * ?s"
  2361     by (simp only: cos_add sin_add)
  2362   also have "\<dots> = ?c * (?c\<twosuperior> - 3 * ?s\<twosuperior>)"
  2363     by (simp add: algebra_simps power2_eq_square)
  2364   finally have "?c\<twosuperior> = (sqrt 3 / 2)\<twosuperior>"
  2365     using pos_c by (simp add: sin_squared_eq power_divide)
  2366   thus ?thesis
  2367     using pos_c [THEN order_less_imp_le]
  2368     by (rule power2_eq_imp_eq) simp
  2369 qed
  2370 
  2371 lemma sin_45: "sin (pi / 4) = sqrt 2 / 2"
  2372 by (simp add: sin_cos_eq cos_45)
  2373 
  2374 lemma sin_60: "sin (pi / 3) = sqrt 3 / 2"
  2375 by (simp add: sin_cos_eq cos_30)
  2376 
  2377 lemma cos_60: "cos (pi / 3) = 1 / 2"
  2378 apply (rule power2_eq_imp_eq)
  2379 apply (simp add: cos_squared_eq sin_60 power_divide)
  2380 apply (rule cos_ge_zero, rule order_trans [where y=0], simp_all)
  2381 done
  2382 
  2383 lemma sin_30: "sin (pi / 6) = 1 / 2"
  2384 by (simp add: sin_cos_eq cos_60)
  2385 
  2386 lemma tan_30: "tan (pi / 6) = 1 / sqrt 3"
  2387 unfolding tan_def by (simp add: sin_30 cos_30)
  2388 
  2389 lemma tan_45: "tan (pi / 4) = 1"
  2390 unfolding tan_def by (simp add: sin_45 cos_45)
  2391 
  2392 lemma tan_60: "tan (pi / 3) = sqrt 3"
  2393 unfolding tan_def by (simp add: sin_60 cos_60)
  2394 
  2395 lemma sin_cos_npi [simp]: "sin (real (Suc (2 * n)) * pi / 2) = (-1) ^ n"
  2396 proof -
  2397   have "sin ((real n + 1/2) * pi) = cos (real n * pi)"
  2398     by (auto simp add: algebra_simps sin_add)
  2399   thus ?thesis
  2400     by (simp add: real_of_nat_Suc left_distrib add_divide_distrib
  2401                   mult_commute [of pi])
  2402 qed
  2403 
  2404 lemma cos_2npi [simp]: "cos (2 * real (n::nat) * pi) = 1"
  2405 by (simp add: cos_double mult_assoc power_add [symmetric] numeral_2_eq_2)
  2406 
  2407 lemma cos_3over2_pi [simp]: "cos (3 / 2 * pi) = 0"
  2408 apply (subgoal_tac "cos (pi + pi/2) = 0", simp)
  2409 apply (subst cos_add, simp)
  2410 done
  2411 
  2412 lemma sin_2npi [simp]: "sin (2 * real (n::nat) * pi) = 0"
  2413 by (auto simp add: mult_assoc)
  2414 
  2415 lemma sin_3over2_pi [simp]: "sin (3 / 2 * pi) = - 1"
  2416 apply (subgoal_tac "sin (pi + pi/2) = - 1", simp)
  2417 apply (subst sin_add, simp)
  2418 done
  2419 
  2420 lemma cos_pi_eq_zero [simp]: "cos (pi * real (Suc (2 * m)) / 2) = 0"
  2421 by (simp only: cos_add sin_add real_of_nat_Suc left_distrib right_distrib add_divide_distrib, auto)
  2422 
  2423 lemma DERIV_cos_add [simp]: "DERIV (%x. cos (x + k)) xa :> - sin (xa + k)"
  2424   by (auto intro!: DERIV_intros)
  2425 
  2426 lemma sin_zero_abs_cos_one: "sin x = 0 ==> \<bar>cos x\<bar> = 1"
  2427 by (auto simp add: sin_zero_iff even_mult_two_ex)
  2428 
  2429 lemma cos_one_sin_zero: "cos x = 1 ==> sin x = 0"
  2430 by (cut_tac x = x in sin_cos_squared_add3, auto)
  2431 
  2432 subsection {* Machins formula *}
  2433 
  2434 lemma arctan_one: "arctan 1 = pi / 4"
  2435   by (rule arctan_unique, simp_all add: tan_45 m2pi_less_pi)
  2436 
  2437 lemma tan_total_pi4: assumes "\<bar>x\<bar> < 1"
  2438   shows "\<exists> z. - (pi / 4) < z \<and> z < pi / 4 \<and> tan z = x"
  2439 proof
  2440   show "- (pi / 4) < arctan x \<and> arctan x < pi / 4 \<and> tan (arctan x) = x"
  2441     unfolding arctan_one [symmetric] arctan_minus [symmetric]
  2442     unfolding arctan_less_iff using assms by auto
  2443 qed
  2444 
  2445 lemma arctan_add: assumes "\<bar>x\<bar> \<le> 1" and "\<bar>y\<bar> < 1"
  2446   shows "arctan x + arctan y = arctan ((x + y) / (1 - x * y))"
  2447 proof (rule arctan_unique [symmetric])
  2448   have "- (pi / 4) \<le> arctan x" and "- (pi / 4) < arctan y"
  2449     unfolding arctan_one [symmetric] arctan_minus [symmetric]
  2450     unfolding arctan_le_iff arctan_less_iff using assms by auto
  2451   from add_le_less_mono [OF this]
  2452   show 1: "- (pi / 2) < arctan x + arctan y" by simp
  2453   have "arctan x \<le> pi / 4" and "arctan y < pi / 4"
  2454     unfolding arctan_one [symmetric]
  2455     unfolding arctan_le_iff arctan_less_iff using assms by auto
  2456   from add_le_less_mono [OF this]
  2457   show 2: "arctan x + arctan y < pi / 2" by simp
  2458   show "tan (arctan x + arctan y) = (x + y) / (1 - x * y)"
  2459     using cos_gt_zero_pi [OF 1 2] by (simp add: tan_add)
  2460 qed
  2461 
  2462 theorem machin: "pi / 4 = 4 * arctan (1/5) - arctan (1 / 239)"
  2463 proof -
  2464   have "\<bar>1 / 5\<bar> < (1 :: real)" by auto
  2465   from arctan_add[OF less_imp_le[OF this] this]
  2466   have "2 * arctan (1 / 5) = arctan (5 / 12)" by auto
  2467   moreover
  2468   have "\<bar>5 / 12\<bar> < (1 :: real)" by auto
  2469   from arctan_add[OF less_imp_le[OF this] this]
  2470   have "2 * arctan (5 / 12) = arctan (120 / 119)" by auto
  2471   moreover
  2472   have "\<bar>1\<bar> \<le> (1::real)" and "\<bar>1 / 239\<bar> < (1::real)" by auto
  2473   from arctan_add[OF this]
  2474   have "arctan 1 + arctan (1 / 239) = arctan (120 / 119)" by auto
  2475   ultimately have "arctan 1 + arctan (1 / 239) = 4 * arctan (1 / 5)" by auto
  2476   thus ?thesis unfolding arctan_one by algebra
  2477 qed
  2478 
  2479 subsection {* Introducing the arcus tangens power series *}
  2480 
  2481 lemma monoseq_arctan_series: fixes x :: real
  2482   assumes "\<bar>x\<bar> \<le> 1" shows "monoseq (\<lambda> n. 1 / real (n*2+1) * x^(n*2+1))" (is "monoseq ?a")
  2483 proof (cases "x = 0") case True thus ?thesis unfolding monoseq_def One_nat_def by auto
  2484 next
  2485   case False
  2486   have "norm x \<le> 1" and "x \<le> 1" and "-1 \<le> x" using assms by auto
  2487   show "monoseq ?a"
  2488   proof -
  2489     { fix n fix x :: real assume "0 \<le> x" and "x \<le> 1"
  2490       have "1 / real (Suc (Suc n * 2)) * x ^ Suc (Suc n * 2) \<le> 1 / real (Suc (n * 2)) * x ^ Suc (n * 2)"
  2491       proof (rule mult_mono)
  2492         show "1 / real (Suc (Suc n * 2)) \<le> 1 / real (Suc (n * 2))" by (rule frac_le) simp_all
  2493         show "0 \<le> 1 / real (Suc (n * 2))" by auto
  2494         show "x ^ Suc (Suc n * 2) \<le> x ^ Suc (n * 2)" by (rule power_decreasing) (simp_all add: `0 \<le> x` `x \<le> 1`)
  2495         show "0 \<le> x ^ Suc (Suc n * 2)" by (rule zero_le_power) (simp add: `0 \<le> x`)
  2496       qed
  2497     } note mono = this
  2498 
  2499     show ?thesis
  2500     proof (cases "0 \<le> x")
  2501       case True from mono[OF this `x \<le> 1`, THEN allI]
  2502       show ?thesis unfolding Suc_eq_plus1[symmetric] by (rule mono_SucI2)
  2503     next
  2504       case False hence "0 \<le> -x" and "-x \<le> 1" using `-1 \<le> x` by auto
  2505       from mono[OF this]
  2506       have "\<And>n. 1 / real (Suc (Suc n * 2)) * x ^ Suc (Suc n * 2) \<ge> 1 / real (Suc (n * 2)) * x ^ Suc (n * 2)" using `0 \<le> -x` by auto
  2507       thus ?thesis unfolding Suc_eq_plus1[symmetric] by (rule mono_SucI1[OF allI])
  2508     qed
  2509   qed
  2510 qed
  2511 
  2512 lemma zeroseq_arctan_series: fixes x :: real
  2513   assumes "\<bar>x\<bar> \<le> 1" shows "(\<lambda> n. 1 / real (n*2+1) * x^(n*2+1)) ----> 0" (is "?a ----> 0")
  2514 proof (cases "x = 0") case True thus ?thesis unfolding One_nat_def by (auto simp add: tendsto_const)
  2515 next
  2516   case False
  2517   have "norm x \<le> 1" and "x \<le> 1" and "-1 \<le> x" using assms by auto
  2518   show "?a ----> 0"
  2519   proof (cases "\<bar>x\<bar> < 1")
  2520     case True hence "norm x < 1" by auto
  2521     from tendsto_mult[OF LIMSEQ_inverse_real_of_nat LIMSEQ_power_zero[OF `norm x < 1`, THEN LIMSEQ_Suc]]
  2522     have "(\<lambda>n. 1 / real (n + 1) * x ^ (n + 1)) ----> 0"
  2523       unfolding inverse_eq_divide Suc_eq_plus1 by simp
  2524     then show ?thesis using pos2 by (rule LIMSEQ_linear)
  2525   next
  2526     case False hence "x = -1 \<or> x = 1" using `\<bar>x\<bar> \<le> 1` by auto
  2527     hence n_eq: "\<And> n. x ^ (n * 2 + 1) = x" unfolding One_nat_def by auto
  2528     from tendsto_mult[OF LIMSEQ_inverse_real_of_nat[THEN LIMSEQ_linear, OF pos2, unfolded inverse_eq_divide] tendsto_const[of x]]
  2529     show ?thesis unfolding n_eq Suc_eq_plus1 by auto
  2530   qed
  2531 qed
  2532 
  2533 lemma summable_arctan_series: fixes x :: real and n :: nat
  2534   assumes "\<bar>x\<bar> \<le> 1" shows "summable (\<lambda> k. (-1)^k * (1 / real (k*2+1) * x ^ (k*2+1)))" (is "summable (?c x)")
  2535   by (rule summable_Leibniz(1), rule zeroseq_arctan_series[OF assms], rule monoseq_arctan_series[OF assms])
  2536 
  2537 lemma less_one_imp_sqr_less_one: fixes x :: real assumes "\<bar>x\<bar> < 1" shows "x^2 < 1"
  2538 proof -
  2539   from mult_left_mono[OF less_imp_le[OF `\<bar>x\<bar> < 1`] abs_ge_zero[of x]]
  2540   have "\<bar> x^2 \<bar> < 1" using `\<bar> x \<bar> < 1` unfolding numeral_2_eq_2 power_Suc2 by auto
  2541   thus ?thesis using zero_le_power2 by auto
  2542 qed
  2543 
  2544 lemma DERIV_arctan_series: assumes "\<bar> x \<bar> < 1"
  2545   shows "DERIV (\<lambda> x'. \<Sum> k. (-1)^k * (1 / real (k*2+1) * x' ^ (k*2+1))) x :> (\<Sum> k. (-1)^k * x^(k*2))" (is "DERIV ?arctan _ :> ?Int")
  2546 proof -
  2547   let "?f n" = "if even n then (-1)^(n div 2) * 1 / real (Suc n) else 0"
  2548 
  2549   { fix n :: nat assume "even n" hence "2 * (n div 2) = n" by presburger } note n_even=this
  2550   have if_eq: "\<And> n x'. ?f n * real (Suc n) * x'^n = (if even n then (-1)^(n div 2) * x'^(2 * (n div 2)) else 0)" using n_even by auto
  2551 
  2552   { fix x :: real assume "\<bar>x\<bar> < 1" hence "x^2 < 1" by (rule less_one_imp_sqr_less_one)
  2553     have "summable (\<lambda> n. -1 ^ n * (x^2) ^n)"
  2554       by (rule summable_Leibniz(1), auto intro!: LIMSEQ_realpow_zero monoseq_realpow `x^2 < 1` order_less_imp_le[OF `x^2 < 1`])
  2555     hence "summable (\<lambda> n. -1 ^ n * x^(2*n))" unfolding power_mult .
  2556   } note summable_Integral = this
  2557 
  2558   { fix f :: "nat \<Rightarrow> real"
  2559     have "\<And> x. f sums x = (\<lambda> n. if even n then f (n div 2) else 0) sums x"
  2560     proof
  2561       fix x :: real assume "f sums x"
  2562       from sums_if[OF sums_zero this]
  2563       show "(\<lambda> n. if even n then f (n div 2) else 0) sums x" by auto
  2564     next
  2565       fix x :: real assume "(\<lambda> n. if even n then f (n div 2) else 0) sums x"
  2566       from LIMSEQ_linear[OF this[unfolded sums_def] pos2, unfolded sum_split_even_odd[unfolded mult_commute]]
  2567       show "f sums x" unfolding sums_def by auto
  2568     qed
  2569     hence "op sums f = op sums (\<lambda> n. if even n then f (n div 2) else 0)" ..
  2570   } note sums_even = this
  2571 
  2572   have Int_eq: "(\<Sum> n. ?f n * real (Suc n) * x^n) = ?Int" unfolding if_eq mult_commute[of _ 2] suminf_def sums_even[of "\<lambda> n. -1 ^ n * x ^ (2 * n)", symmetric]
  2573     by auto
  2574 
  2575   { fix x :: real
  2576     have if_eq': "\<And> n. (if even n then -1 ^ (n div 2) * 1 / real (Suc n) else 0) * x ^ Suc n =
  2577       (if even n then -1 ^ (n div 2) * (1 / real (Suc (2 * (n div 2))) * x ^ Suc (2 * (n div 2))) else 0)"
  2578       using n_even by auto
  2579     have idx_eq: "\<And> n. n * 2 + 1 = Suc (2 * n)" by auto
  2580     have "(\<Sum> n. ?f n * x^(Suc n)) = ?arctan x" unfolding if_eq' idx_eq suminf_def sums_even[of "\<lambda> n. -1 ^ n * (1 / real (Suc (2 * n)) * x ^ Suc (2 * n))", symmetric]
  2581       by auto
  2582   } note arctan_eq = this
  2583 
  2584   have "DERIV (\<lambda> x. \<Sum> n. ?f n * x^(Suc n)) x :> (\<Sum> n. ?f n * real (Suc n) * x^n)"
  2585   proof (rule DERIV_power_series')
  2586     show "x \<in> {- 1 <..< 1}" using `\<bar> x \<bar> < 1` by auto
  2587     { fix x' :: real assume x'_bounds: "x' \<in> {- 1 <..< 1}"
  2588       hence "\<bar>x'\<bar> < 1" by auto
  2589 
  2590       let ?S = "\<Sum> n. (-1)^n * x'^(2 * n)"
  2591       show "summable (\<lambda> n. ?f n * real (Suc n) * x'^n)" unfolding if_eq
  2592         by (rule sums_summable[where l="0 + ?S"], rule sums_if, rule sums_zero, rule summable_sums, rule summable_Integral[OF `\<bar>x'\<bar> < 1`])
  2593     }
  2594   qed auto
  2595   thus ?thesis unfolding Int_eq arctan_eq .
  2596 qed
  2597 
  2598 lemma arctan_series: assumes "\<bar> x \<bar> \<le> 1"
  2599   shows "arctan x = (\<Sum> k. (-1)^k * (1 / real (k*2+1) * x ^ (k*2+1)))" (is "_ = suminf (\<lambda> n. ?c x n)")
  2600 proof -
  2601   let "?c' x n" = "(-1)^n * x^(n*2)"
  2602 
  2603   { fix r x :: real assume "0 < r" and "r < 1" and "\<bar> x \<bar> < r"
  2604     have "\<bar>x\<bar> < 1" using `r < 1` and `\<bar>x\<bar> < r` by auto
  2605     from DERIV_arctan_series[OF this]
  2606     have "DERIV (\<lambda> x. suminf (?c x)) x :> (suminf (?c' x))" .
  2607   } note DERIV_arctan_suminf = this
  2608 
  2609   { fix x :: real assume "\<bar>x\<bar> \<le> 1" note summable_Leibniz[OF zeroseq_arctan_series[OF this] monoseq_arctan_series[OF this]] }
  2610   note arctan_series_borders = this
  2611 
  2612   { fix x :: real assume "\<bar>x\<bar> < 1" have "arctan x = (\<Sum> k. ?c x k)"
  2613   proof -
  2614     obtain r where "\<bar>x\<bar> < r" and "r < 1" using dense[OF `\<bar>x\<bar> < 1`] by blast
  2615     hence "0 < r" and "-r < x" and "x < r" by auto
  2616 
  2617     have suminf_eq_arctan_bounded: "\<And> x a b. \<lbrakk> -r < a ; b < r ; a < b ; a \<le> x ; x \<le> b \<rbrakk> \<Longrightarrow> suminf (?c x) - arctan x = suminf (?c a) - arctan a"
  2618     proof -
  2619       fix x a b assume "-r < a" and "b < r" and "a < b" and "a \<le> x" and "x \<le> b"
  2620       hence "\<bar>x\<bar> < r" by auto
  2621       show "suminf (?c x) - arctan x = suminf (?c a) - arctan a"
  2622       proof (rule DERIV_isconst2[of "a" "b"])
  2623         show "a < b" and "a \<le> x" and "x \<le> b" using `a < b` `a \<le> x` `x \<le> b` by auto
  2624         have "\<forall> x. -r < x \<and> x < r \<longrightarrow> DERIV (\<lambda> x. suminf (?c x) - arctan x) x :> 0"
  2625         proof (rule allI, rule impI)
  2626           fix x assume "-r < x \<and> x < r" hence "\<bar>x\<bar> < r" by auto
  2627           hence "\<bar>x\<bar> < 1" using `r < 1` by auto
  2628           have "\<bar> - (x^2) \<bar> < 1" using less_one_imp_sqr_less_one[OF `\<bar>x\<bar> < 1`] by auto
  2629           hence "(\<lambda> n. (- (x^2)) ^ n) sums (1 / (1 - (- (x^2))))" unfolding real_norm_def[symmetric] by (rule geometric_sums)
  2630           hence "(?c' x) sums (1 / (1 - (- (x^2))))" unfolding power_mult_distrib[symmetric] power_mult nat_mult_commute[of _ 2] by auto
  2631           hence suminf_c'_eq_geom: "inverse (1 + x^2) = suminf (?c' x)" using sums_unique unfolding inverse_eq_divide by auto
  2632           have "DERIV (\<lambda> x. suminf (?c x)) x :> (inverse (1 + x^2))" unfolding suminf_c'_eq_geom
  2633             by (rule DERIV_arctan_suminf[OF `0 < r` `r < 1` `\<bar>x\<bar> < r`])
  2634           from DERIV_add_minus[OF this DERIV_arctan]
  2635           show "DERIV (\<lambda> x. suminf (?c x) - arctan x) x :> 0" unfolding diff_minus by auto
  2636         qed
  2637         hence DERIV_in_rball: "\<forall> y. a \<le> y \<and> y \<le> b \<longrightarrow> DERIV (\<lambda> x. suminf (?c x) - arctan x) y :> 0" using `-r < a` `b < r` by auto
  2638         thus "\<forall> y. a < y \<and> y < b \<longrightarrow> DERIV (\<lambda> x. suminf (?c x) - arctan x) y :> 0" using `\<bar>x\<bar> < r` by auto
  2639         show "\<forall> y. a \<le> y \<and> y \<le> b \<longrightarrow> isCont (\<lambda> x. suminf (?c x) - arctan x) y" using DERIV_in_rball DERIV_isCont by auto
  2640       qed
  2641     qed
  2642 
  2643     have suminf_arctan_zero: "suminf (?c 0) - arctan 0 = 0"
  2644       unfolding Suc_eq_plus1[symmetric] power_Suc2 mult_zero_right arctan_zero_zero suminf_zero by auto
  2645 
  2646     have "suminf (?c x) - arctan x = 0"
  2647     proof (cases "x = 0")
  2648       case True thus ?thesis using suminf_arctan_zero by auto
  2649     next
  2650       case False hence "0 < \<bar>x\<bar>" and "- \<bar>x\<bar> < \<bar>x\<bar>" by auto
  2651       have "suminf (?c (-\<bar>x\<bar>)) - arctan (-\<bar>x\<bar>) = suminf (?c 0) - arctan 0"
  2652         by (rule suminf_eq_arctan_bounded[where x="0" and a="-\<bar>x\<bar>" and b="\<bar>x\<bar>", symmetric])
  2653           (simp_all only: `\<bar>x\<bar> < r` `-\<bar>x\<bar> < \<bar>x\<bar>` neg_less_iff_less)
  2654       moreover
  2655       have "suminf (?c x) - arctan x = suminf (?c (-\<bar>x\<bar>)) - arctan (-\<bar>x\<bar>)"
  2656         by (rule suminf_eq_arctan_bounded[where x="x" and a="-\<bar>x\<bar>" and b="\<bar>x\<bar>"])
  2657           (simp_all only: `\<bar>x\<bar> < r` `-\<bar>x\<bar> < \<bar>x\<bar>` neg_less_iff_less)
  2658       ultimately
  2659       show ?thesis using suminf_arctan_zero by auto
  2660     qed
  2661     thus ?thesis by auto
  2662   qed } note when_less_one = this
  2663 
  2664   show "arctan x = suminf (\<lambda> n. ?c x n)"
  2665   proof (cases "\<bar>x\<bar> < 1")
  2666     case True thus ?thesis by (rule when_less_one)
  2667   next case False hence "\<bar>x\<bar> = 1" using `\<bar>x\<bar> \<le> 1` by auto
  2668     let "?a x n" = "\<bar>1 / real (n*2+1) * x^(n*2+1)\<bar>"
  2669     let "?diff x n" = "\<bar> arctan x - (\<Sum> i = 0..<n. ?c x i)\<bar>"
  2670     { fix n :: nat
  2671       have "0 < (1 :: real)" by auto
  2672       moreover
  2673       { fix x :: real assume "0 < x" and "x < 1" hence "\<bar>x\<bar> \<le> 1" and "\<bar>x\<bar> < 1" by auto
  2674         from `0 < x` have "0 < 1 / real (0 * 2 + (1::nat)) * x ^ (0 * 2 + 1)" by auto
  2675         note bounds = mp[OF arctan_series_borders(2)[OF `\<bar>x\<bar> \<le> 1`] this, unfolded when_less_one[OF `\<bar>x\<bar> < 1`, symmetric], THEN spec]
  2676         have "0 < 1 / real (n*2+1) * x^(n*2+1)" by (rule mult_pos_pos, auto simp only: zero_less_power[OF `0 < x`], auto)
  2677         hence a_pos: "?a x n = 1 / real (n*2+1) * x^(n*2+1)" by (rule abs_of_pos)
  2678         have "?diff x n \<le> ?a x n"
  2679         proof (cases "even n")
  2680           case True hence sgn_pos: "(-1)^n = (1::real)" by auto
  2681           from `even n` obtain m where "2 * m = n" unfolding even_mult_two_ex by auto
  2682           from bounds[of m, unfolded this atLeastAtMost_iff]
  2683           have "\<bar>arctan x - (\<Sum>i = 0..<n. (?c x i))\<bar> \<le> (\<Sum>i = 0..<n + 1. (?c x i)) - (\<Sum>i = 0..<n. (?c x i))" by auto
  2684           also have "\<dots> = ?c x n" unfolding One_nat_def by auto
  2685           also have "\<dots> = ?a x n" unfolding sgn_pos a_pos by auto
  2686           finally show ?thesis .
  2687         next
  2688           case False hence sgn_neg: "(-1)^n = (-1::real)" by auto
  2689           from `odd n` obtain m where m_def: "2 * m + 1 = n" unfolding odd_Suc_mult_two_ex by auto
  2690           hence m_plus: "2 * (m + 1) = n + 1" by auto
  2691           from bounds[of "m + 1", unfolded this atLeastAtMost_iff, THEN conjunct1] bounds[of m, unfolded m_def atLeastAtMost_iff, THEN conjunct2]
  2692           have "\<bar>arctan x - (\<Sum>i = 0..<n. (?c x i))\<bar> \<le> (\<Sum>i = 0..<n. (?c x i)) - (\<Sum>i = 0..<n+1. (?c x i))" by auto
  2693           also have "\<dots> = - ?c x n" unfolding One_nat_def by auto
  2694           also have "\<dots> = ?a x n" unfolding sgn_neg a_pos by auto
  2695           finally show ?thesis .
  2696         qed
  2697         hence "0 \<le> ?a x n - ?diff x n" by auto
  2698       }
  2699       hence "\<forall> x \<in> { 0 <..< 1 }. 0 \<le> ?a x n - ?diff x n" by auto
  2700       moreover have "\<And>x. isCont (\<lambda> x. ?a x n - ?diff x n) x"
  2701         unfolding diff_minus divide_inverse
  2702         by (auto intro!: isCont_add isCont_rabs isCont_ident isCont_minus isCont_arctan isCont_inverse isCont_mult isCont_power isCont_const isCont_setsum)
  2703       ultimately have "0 \<le> ?a 1 n - ?diff 1 n" by (rule LIM_less_bound)
  2704       hence "?diff 1 n \<le> ?a 1 n" by auto
  2705     }
  2706     have "?a 1 ----> 0"
  2707       unfolding tendsto_rabs_zero_iff power_one divide_inverse One_nat_def
  2708       by (auto intro!: tendsto_mult LIMSEQ_linear LIMSEQ_inverse_real_of_nat)
  2709     have "?diff 1 ----> 0"
  2710     proof (rule LIMSEQ_I)
  2711       fix r :: real assume "0 < r"
  2712       obtain N :: nat where N_I: "\<And> n. N \<le> n \<Longrightarrow> ?a 1 n < r" using LIMSEQ_D[OF `?a 1 ----> 0` `0 < r`] by auto
  2713       { fix n assume "N \<le> n" from `?diff 1 n \<le> ?a 1 n` N_I[OF this]
  2714         have "norm (?diff 1 n - 0) < r" by auto }
  2715       thus "\<exists> N. \<forall> n \<ge> N. norm (?diff 1 n - 0) < r" by blast
  2716     qed
  2717     from this [unfolded tendsto_rabs_zero_iff, THEN tendsto_add [OF _ tendsto_const], of "- arctan 1", THEN tendsto_minus]
  2718     have "(?c 1) sums (arctan 1)" unfolding sums_def by auto
  2719     hence "arctan 1 = (\<Sum> i. ?c 1 i)" by (rule sums_unique)
  2720 
  2721     show ?thesis
  2722     proof (cases "x = 1", simp add: `arctan 1 = (\<Sum> i. ?c 1 i)`)
  2723       assume "x \<noteq> 1" hence "x = -1" using `\<bar>x\<bar> = 1` by auto
  2724 
  2725       have "- (pi / 2) < 0" using pi_gt_zero by auto
  2726       have "- (2 * pi) < 0" using pi_gt_zero by auto
  2727 
  2728       have c_minus_minus: "\<And> i. ?c (- 1) i = - ?c 1 i" unfolding One_nat_def by auto
  2729 
  2730       have "arctan (- 1) = arctan (tan (-(pi / 4)))" unfolding tan_45 tan_minus ..
  2731       also have "\<dots> = - (pi / 4)" by (rule arctan_tan, auto simp add: order_less_trans[OF `- (pi / 2) < 0` pi_gt_zero])
  2732       also have "\<dots> = - (arctan (tan (pi / 4)))" unfolding neg_equal_iff_equal by (rule arctan_tan[symmetric], auto simp add: order_less_trans[OF `- (2 * pi) < 0` pi_gt_zero])
  2733       also have "\<dots> = - (arctan 1)" unfolding tan_45 ..
  2734       also have "\<dots> = - (\<Sum> i. ?c 1 i)" using `arctan 1 = (\<Sum> i. ?c 1 i)` by auto
  2735       also have "\<dots> = (\<Sum> i. ?c (- 1) i)" using suminf_minus[OF sums_summable[OF `(?c 1) sums (arctan 1)`]] unfolding c_minus_minus by auto
  2736       finally show ?thesis using `x = -1` by auto
  2737     qed
  2738   qed
  2739 qed
  2740 
  2741 lemma arctan_half: fixes x :: real
  2742   shows "arctan x = 2 * arctan (x / (1 + sqrt(1 + x^2)))"
  2743 proof -
  2744   obtain y where low: "- (pi / 2) < y" and high: "y < pi / 2" and y_eq: "tan y = x" using tan_total by blast
  2745   hence low2: "- (pi / 2) < y / 2" and high2: "y / 2 < pi / 2" by auto
  2746 
  2747   have divide_nonzero_divide: "\<And> A B C :: real. C \<noteq> 0 \<Longrightarrow> A / B = (A / C) / (B / C)" by auto
  2748 
  2749   have "0 < cos y" using cos_gt_zero_pi[OF low high] .
  2750   hence "cos y \<noteq> 0" and cos_sqrt: "sqrt ((cos y) ^ 2) = cos y" by auto
  2751 
  2752   have "1 + (tan y)^2 = 1 + sin y^2 / cos y^2" unfolding tan_def power_divide ..
  2753   also have "\<dots> = cos y^2 / cos y^2 + sin y^2 / cos y^2" using `cos y \<noteq> 0` by auto
  2754   also have "\<dots> = 1 / cos y^2" unfolding add_divide_distrib[symmetric] sin_cos_squared_add2 ..
  2755   finally have "1 + (tan y)^2 = 1 / cos y^2" .
  2756 
  2757   have "sin y / (cos y + 1) = tan y / ((cos y + 1) / cos y)" unfolding tan_def divide_nonzero_divide[OF `cos y \<noteq> 0`, symmetric] ..
  2758   also have "\<dots> = tan y / (1 + 1 / cos y)" using `cos y \<noteq> 0` unfolding add_divide_distrib by auto
  2759   also have "\<dots> = tan y / (1 + 1 / sqrt(cos y^2))" unfolding cos_sqrt ..
  2760   also have "\<dots> = tan y / (1 + sqrt(1 / cos y^2))" unfolding real_sqrt_divide by auto
  2761   finally have eq: "sin y / (cos y + 1) = tan y / (1 + sqrt(1 + (tan y)^2))" unfolding `1 + (tan y)^2 = 1 / cos y^2` .
  2762 
  2763   have "arctan x = y" using arctan_tan low high y_eq by auto
  2764   also have "\<dots> = 2 * (arctan (tan (y/2)))" using arctan_tan[OF low2 high2] by auto
  2765   also have "\<dots> = 2 * (arctan (sin y / (cos y + 1)))" unfolding tan_half by auto
  2766   finally show ?thesis unfolding eq `tan y = x` .
  2767 qed
  2768 
  2769 lemma arctan_monotone: assumes "x < y"
  2770   shows "arctan x < arctan y"
  2771   using assms by (simp only: arctan_less_iff)
  2772 
  2773 lemma arctan_monotone': assumes "x \<le> y" shows "arctan x \<le> arctan y"
  2774   using assms by (simp only: arctan_le_iff)
  2775 
  2776 lemma arctan_inverse:
  2777   assumes "x \<noteq> 0" shows "arctan (1 / x) = sgn x * pi / 2 - arctan x"
  2778 proof (rule arctan_unique)
  2779   show "- (pi / 2) < sgn x * pi / 2 - arctan x"
  2780     using arctan_bounded [of x] assms
  2781     unfolding sgn_real_def
  2782     apply (auto simp add: algebra_simps)
  2783     apply (drule zero_less_arctan_iff [THEN iffD2])
  2784     apply arith
  2785     done
  2786   show "sgn x * pi / 2 - arctan x < pi / 2"
  2787     using arctan_bounded [of "- x"] assms
  2788     unfolding sgn_real_def arctan_minus
  2789     by auto
  2790   show "tan (sgn x * pi / 2 - arctan x) = 1 / x"
  2791     unfolding tan_inverse [of "arctan x", unfolded tan_arctan]
  2792     unfolding sgn_real_def
  2793     by (simp add: tan_def cos_arctan sin_arctan sin_diff cos_diff)
  2794 qed
  2795 
  2796 theorem pi_series: "pi / 4 = (\<Sum> k. (-1)^k * 1 / real (k*2+1))" (is "_ = ?SUM")
  2797 proof -
  2798   have "pi / 4 = arctan 1" using arctan_one by auto
  2799   also have "\<dots> = ?SUM" using arctan_series[of 1] by auto
  2800   finally show ?thesis by auto
  2801 qed
  2802 
  2803 subsection {* Existence of Polar Coordinates *}
  2804 
  2805 lemma cos_x_y_le_one: "\<bar>x / sqrt (x\<twosuperior> + y\<twosuperior>)\<bar> \<le> 1"
  2806 apply (rule power2_le_imp_le [OF _ zero_le_one])
  2807 apply (simp add: power_divide divide_le_eq not_sum_power2_lt_zero)
  2808 done
  2809 
  2810 lemma cos_arccos_abs: "\<bar>y\<bar> \<le> 1 \<Longrightarrow> cos (arccos y) = y"
  2811 by (simp add: abs_le_iff)
  2812 
  2813 lemma sin_arccos_abs: "\<bar>y\<bar> \<le> 1 \<Longrightarrow> sin (arccos y) = sqrt (1 - y\<twosuperior>)"
  2814 by (simp add: sin_arccos abs_le_iff)
  2815 
  2816 lemmas cos_arccos_lemma1 = cos_arccos_abs [OF cos_x_y_le_one]
  2817 
  2818 lemmas sin_arccos_lemma1 = sin_arccos_abs [OF cos_x_y_le_one]
  2819 
  2820 lemma polar_ex1:
  2821      "0 < y ==> \<exists>r a. x = r * cos a & y = r * sin a"
  2822 apply (rule_tac x = "sqrt (x\<twosuperior> + y\<twosuperior>)" in exI)
  2823 apply (rule_tac x = "arccos (x / sqrt (x\<twosuperior> + y\<twosuperior>))" in exI)
  2824 apply (simp add: cos_arccos_lemma1)
  2825 apply (simp add: sin_arccos_lemma1)
  2826 apply (simp add: power_divide)
  2827 apply (simp add: real_sqrt_mult [symmetric])
  2828 apply (simp add: right_diff_distrib)
  2829 done
  2830 
  2831 lemma polar_ex2:
  2832      "y < 0 ==> \<exists>r a. x = r * cos a & y = r * sin a"
  2833 apply (insert polar_ex1 [where x=x and y="-y"], simp, clarify)
  2834 apply (metis cos_minus minus_minus minus_mult_right sin_minus)
  2835 done
  2836 
  2837 lemma polar_Ex: "\<exists>r a. x = r * cos a & y = r * sin a"
  2838 apply (rule_tac x=0 and y=y in linorder_cases)
  2839 apply (erule polar_ex1)
  2840 apply (rule_tac x=x in exI, rule_tac x=0 in exI, simp)
  2841 apply (erule polar_ex2)
  2842 done
  2843 
  2844 end