src/HOL/Analysis/Complex_Analysis_Basics.thy
author nipkow
Sun Nov 11 16:08:59 2018 +0100 (6 months ago)
changeset 69286 e4d5a07fecb6
parent 69180 922833cc6839
child 69508 2a4c8a2a3f8e
permissions -rw-r--r--
tuned
     1 (*  Author: John Harrison, Marco Maggesi, Graziano Gentili, Gianni Ciolli, Valentina Bruno
     2     Ported from "hol_light/Multivariate/canal.ml" by L C Paulson (2014)
     3 *)
     4 
     5 section \<open>Complex Analysis Basics\<close>
     6 
     7 theory Complex_Analysis_Basics
     8 imports Equivalence_Lebesgue_Henstock_Integration "HOL-Library.Nonpos_Ints"
     9 begin
    10 
    11 (* TODO FIXME: A lot of the things in here have nothing to do with complex analysis *)
    12 
    13 subsection%unimportant\<open>General lemmas\<close>
    14 
    15 lemma nonneg_Reals_cmod_eq_Re: "z \<in> \<real>\<^sub>\<ge>\<^sub>0 \<Longrightarrow> norm z = Re z"
    16   by (simp add: complex_nonneg_Reals_iff cmod_eq_Re)
    17 
    18 lemma has_derivative_mult_right:
    19   fixes c:: "'a :: real_normed_algebra"
    20   shows "(((*) c) has_derivative ((*) c)) F"
    21 by (rule has_derivative_mult_right [OF has_derivative_ident])
    22 
    23 lemma has_derivative_of_real[derivative_intros, simp]:
    24   "(f has_derivative f') F \<Longrightarrow> ((\<lambda>x. of_real (f x)) has_derivative (\<lambda>x. of_real (f' x))) F"
    25   using bounded_linear.has_derivative[OF bounded_linear_of_real] .
    26 
    27 lemma has_vector_derivative_real_field:
    28   "DERIV f (of_real a) :> f' \<Longrightarrow> ((\<lambda>x. f (of_real x)) has_vector_derivative f') (at a within s)"
    29   using has_derivative_compose[of of_real of_real a _ f "(*) f'"]
    30   by (simp add: scaleR_conv_of_real ac_simps has_vector_derivative_def has_field_derivative_def)
    31 lemmas has_vector_derivative_real_complex = has_vector_derivative_real_field
    32 
    33 lemma fact_cancel:
    34   fixes c :: "'a::real_field"
    35   shows "of_nat (Suc n) * c / (fact (Suc n)) = c / (fact n)"
    36   using of_nat_neq_0 by force
    37 
    38 lemma bilinear_times:
    39   fixes c::"'a::real_algebra" shows "bilinear (\<lambda>x y::'a. x*y)"
    40   by (auto simp: bilinear_def distrib_left distrib_right intro!: linearI)
    41 
    42 lemma linear_cnj: "linear cnj"
    43   using bounded_linear.linear[OF bounded_linear_cnj] .
    44 
    45 lemma vector_derivative_cnj_within:
    46   assumes "at x within A \<noteq> bot" and "f differentiable at x within A"
    47   shows   "vector_derivative (\<lambda>z. cnj (f z)) (at x within A) = 
    48              cnj (vector_derivative f (at x within A))" (is "_ = cnj ?D")
    49 proof -
    50   let ?D = "vector_derivative f (at x within A)"
    51   from assms have "(f has_vector_derivative ?D) (at x within A)"
    52     by (subst (asm) vector_derivative_works)
    53   hence "((\<lambda>x. cnj (f x)) has_vector_derivative cnj ?D) (at x within A)"
    54     by (rule has_vector_derivative_cnj)
    55   thus ?thesis using assms by (auto dest: vector_derivative_within)
    56 qed
    57 
    58 lemma vector_derivative_cnj:
    59   assumes "f differentiable at x"
    60   shows   "vector_derivative (\<lambda>z. cnj (f z)) (at x) = cnj (vector_derivative f (at x))"
    61   using assms by (intro vector_derivative_cnj_within) auto
    62 
    63 lemma lambda_zero: "(\<lambda>h::'a::mult_zero. 0) = (*) 0"
    64   by auto
    65 
    66 lemma lambda_one: "(\<lambda>x::'a::monoid_mult. x) = (*) 1"
    67   by auto
    68 
    69 lemma uniformly_continuous_on_cmul_right [continuous_intros]:
    70   fixes f :: "'a::real_normed_vector \<Rightarrow> 'b::real_normed_algebra"
    71   shows "uniformly_continuous_on s f \<Longrightarrow> uniformly_continuous_on s (\<lambda>x. f x * c)"
    72   using bounded_linear.uniformly_continuous_on[OF bounded_linear_mult_left] .
    73 
    74 lemma uniformly_continuous_on_cmul_left[continuous_intros]:
    75   fixes f :: "'a::real_normed_vector \<Rightarrow> 'b::real_normed_algebra"
    76   assumes "uniformly_continuous_on s f"
    77     shows "uniformly_continuous_on s (\<lambda>x. c * f x)"
    78 by (metis assms bounded_linear.uniformly_continuous_on bounded_linear_mult_right)
    79 
    80 lemma continuous_within_norm_id [continuous_intros]: "continuous (at x within S) norm"
    81   by (rule continuous_norm [OF continuous_ident])
    82 
    83 lemma continuous_on_norm_id [continuous_intros]: "continuous_on S norm"
    84   by (intro continuous_on_id continuous_on_norm)
    85 
    86 (*MOVE? But not to Finite_Cartesian_Product*)
    87 lemma sums_vec_nth :
    88   assumes "f sums a"
    89   shows "(\<lambda>x. f x $ i) sums a $ i"
    90 using assms unfolding sums_def
    91 by (auto dest: tendsto_vec_nth [where i=i])
    92 
    93 lemma summable_vec_nth :
    94   assumes "summable f"
    95   shows "summable (\<lambda>x. f x $ i)"
    96 using assms unfolding summable_def
    97 by (blast intro: sums_vec_nth)
    98 
    99 (* TODO: Move? *)
   100 lemma DERIV_zero_connected_constant:
   101   fixes f :: "'a::{real_normed_field,euclidean_space} \<Rightarrow> 'a"
   102   assumes "connected S"
   103       and "open S"
   104       and "finite K"
   105       and "continuous_on S f"
   106       and "\<forall>x\<in>(S - K). DERIV f x :> 0"
   107     obtains c where "\<And>x. x \<in> S \<Longrightarrow> f(x) = c"
   108 using has_derivative_zero_connected_constant [OF assms(1-4)] assms
   109 by (metis DERIV_const has_derivative_const Diff_iff at_within_open frechet_derivative_at has_field_derivative_def)
   110 
   111 lemmas DERIV_zero_constant = has_field_derivative_zero_constant
   112 
   113 lemma DERIV_zero_unique:
   114   assumes "convex S"
   115       and d0: "\<And>x. x\<in>S \<Longrightarrow> (f has_field_derivative 0) (at x within S)"
   116       and "a \<in> S"
   117       and "x \<in> S"
   118     shows "f x = f a"
   119   by (rule has_derivative_zero_unique [OF assms(1) _ assms(4,3)])
   120      (metis d0 has_field_derivative_imp_has_derivative lambda_zero)
   121 
   122 lemma DERIV_zero_connected_unique:
   123   assumes "connected S"
   124       and "open S"
   125       and d0: "\<And>x. x\<in>S \<Longrightarrow> DERIV f x :> 0"
   126       and "a \<in> S"
   127       and "x \<in> S"
   128     shows "f x = f a"
   129     by (rule has_derivative_zero_unique_connected [OF assms(2,1) _ assms(5,4)])
   130        (metis has_field_derivative_def lambda_zero d0)
   131 
   132 lemma DERIV_transform_within:
   133   assumes "(f has_field_derivative f') (at a within S)"
   134       and "0 < d" "a \<in> S"
   135       and "\<And>x. x\<in>S \<Longrightarrow> dist x a < d \<Longrightarrow> f x = g x"
   136     shows "(g has_field_derivative f') (at a within S)"
   137   using assms unfolding has_field_derivative_def
   138   by (blast intro: has_derivative_transform_within)
   139 
   140 lemma DERIV_transform_within_open:
   141   assumes "DERIV f a :> f'"
   142       and "open S" "a \<in> S"
   143       and "\<And>x. x\<in>S \<Longrightarrow> f x = g x"
   144     shows "DERIV g a :> f'"
   145   using assms unfolding has_field_derivative_def
   146 by (metis has_derivative_transform_within_open)
   147 
   148 lemma DERIV_transform_at:
   149   assumes "DERIV f a :> f'"
   150       and "0 < d"
   151       and "\<And>x. dist x a < d \<Longrightarrow> f x = g x"
   152     shows "DERIV g a :> f'"
   153   by (blast intro: assms DERIV_transform_within)
   154 
   155 (*generalising DERIV_isconst_all, which requires type real (using the ordering)*)
   156 lemma DERIV_zero_UNIV_unique:
   157   "(\<And>x. DERIV f x :> 0) \<Longrightarrow> f x = f a"
   158   by (metis DERIV_zero_unique UNIV_I convex_UNIV)
   159 
   160 lemma
   161   shows open_halfspace_Re_lt: "open {z. Re(z) < b}"
   162     and open_halfspace_Re_gt: "open {z. Re(z) > b}"
   163     and closed_halfspace_Re_ge: "closed {z. Re(z) \<ge> b}"
   164     and closed_halfspace_Re_le: "closed {z. Re(z) \<le> b}"
   165     and closed_halfspace_Re_eq: "closed {z. Re(z) = b}"
   166     and open_halfspace_Im_lt: "open {z. Im(z) < b}"
   167     and open_halfspace_Im_gt: "open {z. Im(z) > b}"
   168     and closed_halfspace_Im_ge: "closed {z. Im(z) \<ge> b}"
   169     and closed_halfspace_Im_le: "closed {z. Im(z) \<le> b}"
   170     and closed_halfspace_Im_eq: "closed {z. Im(z) = b}"
   171   by (intro open_Collect_less closed_Collect_le closed_Collect_eq continuous_on_Re
   172             continuous_on_Im continuous_on_id continuous_on_const)+
   173 
   174 lemma closed_complex_Reals: "closed (\<real> :: complex set)"
   175 proof -
   176   have "(\<real> :: complex set) = {z. Im z = 0}"
   177     by (auto simp: complex_is_Real_iff)
   178   then show ?thesis
   179     by (metis closed_halfspace_Im_eq)
   180 qed
   181 
   182 lemma closed_Real_halfspace_Re_le: "closed (\<real> \<inter> {w. Re w \<le> x})"
   183   by (simp add: closed_Int closed_complex_Reals closed_halfspace_Re_le)
   184 
   185 lemma closed_nonpos_Reals_complex [simp]: "closed (\<real>\<^sub>\<le>\<^sub>0 :: complex set)"
   186 proof -
   187   have "\<real>\<^sub>\<le>\<^sub>0 = \<real> \<inter> {z. Re(z) \<le> 0}"
   188     using complex_nonpos_Reals_iff complex_is_Real_iff by auto
   189   then show ?thesis
   190     by (metis closed_Real_halfspace_Re_le)
   191 qed
   192 
   193 lemma closed_Real_halfspace_Re_ge: "closed (\<real> \<inter> {w. x \<le> Re(w)})"
   194   using closed_halfspace_Re_ge
   195   by (simp add: closed_Int closed_complex_Reals)
   196 
   197 lemma closed_nonneg_Reals_complex [simp]: "closed (\<real>\<^sub>\<ge>\<^sub>0 :: complex set)"
   198 proof -
   199   have "\<real>\<^sub>\<ge>\<^sub>0 = \<real> \<inter> {z. Re(z) \<ge> 0}"
   200     using complex_nonneg_Reals_iff complex_is_Real_iff by auto
   201   then show ?thesis
   202     by (metis closed_Real_halfspace_Re_ge)
   203 qed
   204 
   205 lemma closed_real_abs_le: "closed {w \<in> \<real>. \<bar>Re w\<bar> \<le> r}"
   206 proof -
   207   have "{w \<in> \<real>. \<bar>Re w\<bar> \<le> r} = (\<real> \<inter> {w. Re w \<le> r}) \<inter> (\<real> \<inter> {w. Re w \<ge> -r})"
   208     by auto
   209   then show "closed {w \<in> \<real>. \<bar>Re w\<bar> \<le> r}"
   210     by (simp add: closed_Int closed_Real_halfspace_Re_ge closed_Real_halfspace_Re_le)
   211 qed
   212 
   213 lemma real_lim:
   214   fixes l::complex
   215   assumes "(f \<longlongrightarrow> l) F" and "~(trivial_limit F)" and "eventually P F" and "\<And>a. P a \<Longrightarrow> f a \<in> \<real>"
   216   shows  "l \<in> \<real>"
   217 proof (rule Lim_in_closed_set[OF closed_complex_Reals _ assms(2,1)])
   218   show "eventually (\<lambda>x. f x \<in> \<real>) F"
   219     using assms(3, 4) by (auto intro: eventually_mono)
   220 qed
   221 
   222 lemma real_lim_sequentially:
   223   fixes l::complex
   224   shows "(f \<longlongrightarrow> l) sequentially \<Longrightarrow> (\<exists>N. \<forall>n\<ge>N. f n \<in> \<real>) \<Longrightarrow> l \<in> \<real>"
   225 by (rule real_lim [where F=sequentially]) (auto simp: eventually_sequentially)
   226 
   227 lemma real_series:
   228   fixes l::complex
   229   shows "f sums l \<Longrightarrow> (\<And>n. f n \<in> \<real>) \<Longrightarrow> l \<in> \<real>"
   230 unfolding sums_def
   231 by (metis real_lim_sequentially sum_in_Reals)
   232 
   233 lemma Lim_null_comparison_Re:
   234   assumes "eventually (\<lambda>x. norm(f x) \<le> Re(g x)) F" "(g \<longlongrightarrow> 0) F" shows "(f \<longlongrightarrow> 0) F"
   235   by (rule Lim_null_comparison[OF assms(1)] tendsto_eq_intros assms(2))+ simp
   236 
   237 subsection\<open>Holomorphic functions\<close>
   238 
   239 definition%important holomorphic_on :: "[complex \<Rightarrow> complex, complex set] \<Rightarrow> bool"
   240            (infixl "(holomorphic'_on)" 50)
   241   where "f holomorphic_on s \<equiv> \<forall>x\<in>s. f field_differentiable (at x within s)"
   242 
   243 named_theorems%important holomorphic_intros "structural introduction rules for holomorphic_on"
   244 
   245 lemma holomorphic_onI [intro?]: "(\<And>x. x \<in> s \<Longrightarrow> f field_differentiable (at x within s)) \<Longrightarrow> f holomorphic_on s"
   246   by (simp add: holomorphic_on_def)
   247 
   248 lemma holomorphic_onD [dest?]: "\<lbrakk>f holomorphic_on s; x \<in> s\<rbrakk> \<Longrightarrow> f field_differentiable (at x within s)"
   249   by (simp add: holomorphic_on_def)
   250 
   251 lemma holomorphic_on_imp_differentiable_on:
   252     "f holomorphic_on s \<Longrightarrow> f differentiable_on s"
   253   unfolding holomorphic_on_def differentiable_on_def
   254   by (simp add: field_differentiable_imp_differentiable)
   255 
   256 lemma holomorphic_on_imp_differentiable_at:
   257    "\<lbrakk>f holomorphic_on s; open s; x \<in> s\<rbrakk> \<Longrightarrow> f field_differentiable (at x)"
   258 using at_within_open holomorphic_on_def by fastforce
   259 
   260 lemma holomorphic_on_empty [holomorphic_intros]: "f holomorphic_on {}"
   261   by (simp add: holomorphic_on_def)
   262 
   263 lemma holomorphic_on_open:
   264     "open s \<Longrightarrow> f holomorphic_on s \<longleftrightarrow> (\<forall>x \<in> s. \<exists>f'. DERIV f x :> f')"
   265   by (auto simp: holomorphic_on_def field_differentiable_def has_field_derivative_def at_within_open [of _ s])
   266 
   267 lemma holomorphic_on_imp_continuous_on:
   268     "f holomorphic_on s \<Longrightarrow> continuous_on s f"
   269   by (metis field_differentiable_imp_continuous_at continuous_on_eq_continuous_within holomorphic_on_def)
   270 
   271 lemma holomorphic_on_subset [elim]:
   272     "f holomorphic_on s \<Longrightarrow> t \<subseteq> s \<Longrightarrow> f holomorphic_on t"
   273   unfolding holomorphic_on_def
   274   by (metis field_differentiable_within_subset subsetD)
   275 
   276 lemma holomorphic_transform: "\<lbrakk>f holomorphic_on s; \<And>x. x \<in> s \<Longrightarrow> f x = g x\<rbrakk> \<Longrightarrow> g holomorphic_on s"
   277   by (metis field_differentiable_transform_within linordered_field_no_ub holomorphic_on_def)
   278 
   279 lemma holomorphic_cong: "s = t ==> (\<And>x. x \<in> s \<Longrightarrow> f x = g x) \<Longrightarrow> f holomorphic_on s \<longleftrightarrow> g holomorphic_on t"
   280   by (metis holomorphic_transform)
   281 
   282 lemma holomorphic_on_linear [simp, holomorphic_intros]: "((*) c) holomorphic_on s"
   283   unfolding holomorphic_on_def by (metis field_differentiable_linear)
   284 
   285 lemma holomorphic_on_const [simp, holomorphic_intros]: "(\<lambda>z. c) holomorphic_on s"
   286   unfolding holomorphic_on_def by (metis field_differentiable_const)
   287 
   288 lemma holomorphic_on_ident [simp, holomorphic_intros]: "(\<lambda>x. x) holomorphic_on s"
   289   unfolding holomorphic_on_def by (metis field_differentiable_ident)
   290 
   291 lemma holomorphic_on_id [simp, holomorphic_intros]: "id holomorphic_on s"
   292   unfolding id_def by (rule holomorphic_on_ident)
   293 
   294 lemma holomorphic_on_compose:
   295   "f holomorphic_on s \<Longrightarrow> g holomorphic_on (f ` s) \<Longrightarrow> (g o f) holomorphic_on s"
   296   using field_differentiable_compose_within[of f _ s g]
   297   by (auto simp: holomorphic_on_def)
   298 
   299 lemma holomorphic_on_compose_gen:
   300   "f holomorphic_on s \<Longrightarrow> g holomorphic_on t \<Longrightarrow> f ` s \<subseteq> t \<Longrightarrow> (g o f) holomorphic_on s"
   301   by (metis holomorphic_on_compose holomorphic_on_subset)
   302 
   303 lemma holomorphic_on_balls_imp_entire:
   304   assumes "\<not>bdd_above A" "\<And>r. r \<in> A \<Longrightarrow> f holomorphic_on ball c r"
   305   shows   "f holomorphic_on B"
   306 proof (rule holomorphic_on_subset)
   307   show "f holomorphic_on UNIV" unfolding holomorphic_on_def
   308   proof
   309     fix z :: complex
   310     from \<open>\<not>bdd_above A\<close> obtain r where r: "r \<in> A" "r > norm (z - c)"
   311       by (meson bdd_aboveI not_le)
   312     with assms(2) have "f holomorphic_on ball c r" by blast
   313     moreover from r have "z \<in> ball c r" by (auto simp: dist_norm norm_minus_commute)
   314     ultimately show "f field_differentiable at z"
   315       by (auto simp: holomorphic_on_def at_within_open[of _ "ball c r"])
   316   qed
   317 qed auto
   318 
   319 lemma holomorphic_on_balls_imp_entire':
   320   assumes "\<And>r. r > 0 \<Longrightarrow> f holomorphic_on ball c r"
   321   shows   "f holomorphic_on B"
   322 proof (rule holomorphic_on_balls_imp_entire)
   323   {
   324     fix M :: real
   325     have "\<exists>x. x > max M 0" by (intro gt_ex)
   326     hence "\<exists>x>0. x > M" by auto
   327   }
   328   thus "\<not>bdd_above {(0::real)<..}" unfolding bdd_above_def
   329     by (auto simp: not_le)
   330 qed (insert assms, auto)
   331 
   332 lemma holomorphic_on_minus [holomorphic_intros]: "f holomorphic_on s \<Longrightarrow> (\<lambda>z. -(f z)) holomorphic_on s"
   333   by (metis field_differentiable_minus holomorphic_on_def)
   334 
   335 lemma holomorphic_on_add [holomorphic_intros]:
   336   "\<lbrakk>f holomorphic_on s; g holomorphic_on s\<rbrakk> \<Longrightarrow> (\<lambda>z. f z + g z) holomorphic_on s"
   337   unfolding holomorphic_on_def by (metis field_differentiable_add)
   338 
   339 lemma holomorphic_on_diff [holomorphic_intros]:
   340   "\<lbrakk>f holomorphic_on s; g holomorphic_on s\<rbrakk> \<Longrightarrow> (\<lambda>z. f z - g z) holomorphic_on s"
   341   unfolding holomorphic_on_def by (metis field_differentiable_diff)
   342 
   343 lemma holomorphic_on_mult [holomorphic_intros]:
   344   "\<lbrakk>f holomorphic_on s; g holomorphic_on s\<rbrakk> \<Longrightarrow> (\<lambda>z. f z * g z) holomorphic_on s"
   345   unfolding holomorphic_on_def by (metis field_differentiable_mult)
   346 
   347 lemma holomorphic_on_inverse [holomorphic_intros]:
   348   "\<lbrakk>f holomorphic_on s; \<And>z. z \<in> s \<Longrightarrow> f z \<noteq> 0\<rbrakk> \<Longrightarrow> (\<lambda>z. inverse (f z)) holomorphic_on s"
   349   unfolding holomorphic_on_def by (metis field_differentiable_inverse)
   350 
   351 lemma holomorphic_on_divide [holomorphic_intros]:
   352   "\<lbrakk>f holomorphic_on s; g holomorphic_on s; \<And>z. z \<in> s \<Longrightarrow> g z \<noteq> 0\<rbrakk> \<Longrightarrow> (\<lambda>z. f z / g z) holomorphic_on s"
   353   unfolding holomorphic_on_def by (metis field_differentiable_divide)
   354 
   355 lemma holomorphic_on_power [holomorphic_intros]:
   356   "f holomorphic_on s \<Longrightarrow> (\<lambda>z. (f z)^n) holomorphic_on s"
   357   unfolding holomorphic_on_def by (metis field_differentiable_power)
   358 
   359 lemma holomorphic_on_sum [holomorphic_intros]:
   360   "(\<And>i. i \<in> I \<Longrightarrow> (f i) holomorphic_on s) \<Longrightarrow> (\<lambda>x. sum (\<lambda>i. f i x) I) holomorphic_on s"
   361   unfolding holomorphic_on_def by (metis field_differentiable_sum)
   362 
   363 lemma holomorphic_on_prod [holomorphic_intros]:
   364   "(\<And>i. i \<in> I \<Longrightarrow> (f i) holomorphic_on s) \<Longrightarrow> (\<lambda>x. prod (\<lambda>i. f i x) I) holomorphic_on s"
   365   by (induction I rule: infinite_finite_induct) (auto intro: holomorphic_intros)
   366 
   367 lemma holomorphic_pochhammer [holomorphic_intros]:
   368   "f holomorphic_on A \<Longrightarrow> (\<lambda>s. pochhammer (f s) n) holomorphic_on A"
   369   by (induction n) (auto intro!: holomorphic_intros simp: pochhammer_Suc)
   370 
   371 lemma holomorphic_on_scaleR [holomorphic_intros]:
   372   "f holomorphic_on A \<Longrightarrow> (\<lambda>x. c *\<^sub>R f x) holomorphic_on A"
   373   by (auto simp: scaleR_conv_of_real intro!: holomorphic_intros)
   374 
   375 lemma holomorphic_on_Un [holomorphic_intros]:
   376   assumes "f holomorphic_on A" "f holomorphic_on B" "open A" "open B"
   377   shows   "f holomorphic_on (A \<union> B)"
   378   using assms by (auto simp: holomorphic_on_def  at_within_open[of _ A]
   379                              at_within_open[of _ B]  at_within_open[of _ "A \<union> B"] open_Un)
   380 
   381 lemma holomorphic_on_If_Un [holomorphic_intros]:
   382   assumes "f holomorphic_on A" "g holomorphic_on B" "open A" "open B"
   383   assumes "\<And>z. z \<in> A \<Longrightarrow> z \<in> B \<Longrightarrow> f z = g z"
   384   shows   "(\<lambda>z. if z \<in> A then f z else g z) holomorphic_on (A \<union> B)" (is "?h holomorphic_on _")
   385 proof (intro holomorphic_on_Un)
   386   note \<open>f holomorphic_on A\<close>
   387   also have "f holomorphic_on A \<longleftrightarrow> ?h holomorphic_on A"
   388     by (intro holomorphic_cong) auto
   389   finally show \<dots> .
   390 next
   391   note \<open>g holomorphic_on B\<close>
   392   also have "g holomorphic_on B \<longleftrightarrow> ?h holomorphic_on B"
   393     using assms by (intro holomorphic_cong) auto
   394   finally show \<dots> .
   395 qed (insert assms, auto)
   396 
   397 lemma leibniz_rule_holomorphic:
   398   fixes f::"complex \<Rightarrow> 'b::euclidean_space \<Rightarrow> complex"
   399   assumes "\<And>x t. x \<in> U \<Longrightarrow> t \<in> cbox a b \<Longrightarrow> ((\<lambda>x. f x t) has_field_derivative fx x t) (at x within U)"
   400   assumes "\<And>x. x \<in> U \<Longrightarrow> (f x) integrable_on cbox a b"
   401   assumes "continuous_on (U \<times> (cbox a b)) (\<lambda>(x, t). fx x t)"
   402   assumes "convex U"
   403   shows "(\<lambda>x. integral (cbox a b) (f x)) holomorphic_on U"
   404   using leibniz_rule_field_differentiable[OF assms(1-3) _ assms(4)]
   405   by (auto simp: holomorphic_on_def)
   406 
   407 lemma DERIV_deriv_iff_field_differentiable:
   408   "DERIV f x :> deriv f x \<longleftrightarrow> f field_differentiable at x"
   409   unfolding field_differentiable_def by (metis DERIV_imp_deriv)
   410 
   411 lemma holomorphic_derivI:
   412      "\<lbrakk>f holomorphic_on S; open S; x \<in> S\<rbrakk>
   413       \<Longrightarrow> (f has_field_derivative deriv f x) (at x within T)"
   414 by (metis DERIV_deriv_iff_field_differentiable at_within_open  holomorphic_on_def has_field_derivative_at_within)
   415 
   416 lemma complex_derivative_chain:
   417   "f field_differentiable at x \<Longrightarrow> g field_differentiable at (f x)
   418     \<Longrightarrow> deriv (g o f) x = deriv g (f x) * deriv f x"
   419   by (metis DERIV_deriv_iff_field_differentiable DERIV_chain DERIV_imp_deriv)
   420 
   421 lemma deriv_linear [simp]: "deriv (\<lambda>w. c * w) = (\<lambda>z. c)"
   422   by (metis DERIV_imp_deriv DERIV_cmult_Id)
   423 
   424 lemma deriv_ident [simp]: "deriv (\<lambda>w. w) = (\<lambda>z. 1)"
   425   by (metis DERIV_imp_deriv DERIV_ident)
   426 
   427 lemma deriv_id [simp]: "deriv id = (\<lambda>z. 1)"
   428   by (simp add: id_def)
   429 
   430 lemma deriv_const [simp]: "deriv (\<lambda>w. c) = (\<lambda>z. 0)"
   431   by (metis DERIV_imp_deriv DERIV_const)
   432 
   433 lemma deriv_add [simp]:
   434   "\<lbrakk>f field_differentiable at z; g field_differentiable at z\<rbrakk>
   435    \<Longrightarrow> deriv (\<lambda>w. f w + g w) z = deriv f z + deriv g z"
   436   unfolding DERIV_deriv_iff_field_differentiable[symmetric]
   437   by (auto intro!: DERIV_imp_deriv derivative_intros)
   438 
   439 lemma deriv_diff [simp]:
   440   "\<lbrakk>f field_differentiable at z; g field_differentiable at z\<rbrakk>
   441    \<Longrightarrow> deriv (\<lambda>w. f w - g w) z = deriv f z - deriv g z"
   442   unfolding DERIV_deriv_iff_field_differentiable[symmetric]
   443   by (auto intro!: DERIV_imp_deriv derivative_intros)
   444 
   445 lemma deriv_mult [simp]:
   446   "\<lbrakk>f field_differentiable at z; g field_differentiable at z\<rbrakk>
   447    \<Longrightarrow> deriv (\<lambda>w. f w * g w) z = f z * deriv g z + deriv f z * g z"
   448   unfolding DERIV_deriv_iff_field_differentiable[symmetric]
   449   by (auto intro!: DERIV_imp_deriv derivative_eq_intros)
   450 
   451 lemma deriv_cmult:
   452   "f field_differentiable at z \<Longrightarrow> deriv (\<lambda>w. c * f w) z = c * deriv f z"
   453   by simp
   454 
   455 lemma deriv_cmult_right:
   456   "f field_differentiable at z \<Longrightarrow> deriv (\<lambda>w. f w * c) z = deriv f z * c"
   457   by simp
   458 
   459 lemma deriv_inverse [simp]:
   460   "\<lbrakk>f field_differentiable at z; f z \<noteq> 0\<rbrakk>
   461    \<Longrightarrow> deriv (\<lambda>w. inverse (f w)) z = - deriv f z / f z ^ 2"
   462   unfolding DERIV_deriv_iff_field_differentiable[symmetric]
   463   by (safe intro!: DERIV_imp_deriv derivative_eq_intros) (auto simp: divide_simps power2_eq_square)
   464 
   465 lemma deriv_divide [simp]:
   466   "\<lbrakk>f field_differentiable at z; g field_differentiable at z; g z \<noteq> 0\<rbrakk>
   467    \<Longrightarrow> deriv (\<lambda>w. f w / g w) z = (deriv f z * g z - f z * deriv g z) / g z ^ 2"
   468   by (simp add: field_class.field_divide_inverse field_differentiable_inverse)
   469      (simp add: divide_simps power2_eq_square)
   470 
   471 lemma deriv_cdivide_right:
   472   "f field_differentiable at z \<Longrightarrow> deriv (\<lambda>w. f w / c) z = deriv f z / c"
   473   by (simp add: field_class.field_divide_inverse)
   474 
   475 lemma complex_derivative_transform_within_open:
   476   "\<lbrakk>f holomorphic_on s; g holomorphic_on s; open s; z \<in> s; \<And>w. w \<in> s \<Longrightarrow> f w = g w\<rbrakk>
   477    \<Longrightarrow> deriv f z = deriv g z"
   478   unfolding holomorphic_on_def
   479   by (rule DERIV_imp_deriv)
   480      (metis DERIV_deriv_iff_field_differentiable DERIV_transform_within_open at_within_open)
   481 
   482 lemma deriv_compose_linear:
   483   "f field_differentiable at (c * z) \<Longrightarrow> deriv (\<lambda>w. f (c * w)) z = c * deriv f (c * z)"
   484 apply (rule DERIV_imp_deriv)
   485   unfolding DERIV_deriv_iff_field_differentiable [symmetric]
   486   by (metis (full_types) DERIV_chain2 DERIV_cmult_Id mult.commute)
   487 
   488 
   489 lemma nonzero_deriv_nonconstant:
   490   assumes df: "DERIV f \<xi> :> df" and S: "open S" "\<xi> \<in> S" and "df \<noteq> 0"
   491     shows "\<not> f constant_on S"
   492 unfolding constant_on_def
   493 by (metis \<open>df \<noteq> 0\<close> DERIV_transform_within_open [OF df S] DERIV_const DERIV_unique)
   494 
   495 lemma holomorphic_nonconstant:
   496   assumes holf: "f holomorphic_on S" and "open S" "\<xi> \<in> S" "deriv f \<xi> \<noteq> 0"
   497     shows "\<not> f constant_on S"
   498   by (rule nonzero_deriv_nonconstant [of f "deriv f \<xi>" \<xi> S])
   499     (use assms in \<open>auto simp: holomorphic_derivI\<close>)
   500 
   501 subsection%unimportant\<open>Caratheodory characterization\<close>
   502 
   503 lemma field_differentiable_caratheodory_at:
   504   "f field_differentiable (at z) \<longleftrightarrow>
   505          (\<exists>g. (\<forall>w. f(w) - f(z) = g(w) * (w - z)) \<and> continuous (at z) g)"
   506   using CARAT_DERIV [of f]
   507   by (simp add: field_differentiable_def has_field_derivative_def)
   508 
   509 lemma field_differentiable_caratheodory_within:
   510   "f field_differentiable (at z within s) \<longleftrightarrow>
   511          (\<exists>g. (\<forall>w. f(w) - f(z) = g(w) * (w - z)) \<and> continuous (at z within s) g)"
   512   using DERIV_caratheodory_within [of f]
   513   by (simp add: field_differentiable_def has_field_derivative_def)
   514 
   515 subsection\<open>Analyticity on a set\<close>
   516 
   517 definition%important analytic_on (infixl "(analytic'_on)" 50)
   518   where "f analytic_on S \<equiv> \<forall>x \<in> S. \<exists>e. 0 < e \<and> f holomorphic_on (ball x e)"
   519 
   520 named_theorems%important analytic_intros "introduction rules for proving analyticity"
   521 
   522 lemma analytic_imp_holomorphic: "f analytic_on S \<Longrightarrow> f holomorphic_on S"
   523   by (simp add: at_within_open [OF _ open_ball] analytic_on_def holomorphic_on_def)
   524      (metis centre_in_ball field_differentiable_at_within)
   525 
   526 lemma analytic_on_open: "open S \<Longrightarrow> f analytic_on S \<longleftrightarrow> f holomorphic_on S"
   527 apply (auto simp: analytic_imp_holomorphic)
   528 apply (auto simp: analytic_on_def holomorphic_on_def)
   529 by (metis holomorphic_on_def holomorphic_on_subset open_contains_ball)
   530 
   531 lemma analytic_on_imp_differentiable_at:
   532   "f analytic_on S \<Longrightarrow> x \<in> S \<Longrightarrow> f field_differentiable (at x)"
   533  apply (auto simp: analytic_on_def holomorphic_on_def)
   534 by (metis open_ball centre_in_ball field_differentiable_within_open)
   535 
   536 lemma analytic_on_subset: "f analytic_on S \<Longrightarrow> T \<subseteq> S \<Longrightarrow> f analytic_on T"
   537   by (auto simp: analytic_on_def)
   538 
   539 lemma analytic_on_Un: "f analytic_on (S \<union> T) \<longleftrightarrow> f analytic_on S \<and> f analytic_on T"
   540   by (auto simp: analytic_on_def)
   541 
   542 lemma analytic_on_Union: "f analytic_on (\<Union>\<T>) \<longleftrightarrow> (\<forall>T \<in> \<T>. f analytic_on T)"
   543   by (auto simp: analytic_on_def)
   544 
   545 lemma analytic_on_UN: "f analytic_on (\<Union>i\<in>I. S i) \<longleftrightarrow> (\<forall>i\<in>I. f analytic_on (S i))"
   546   by (auto simp: analytic_on_def)
   547 
   548 lemma analytic_on_holomorphic:
   549   "f analytic_on S \<longleftrightarrow> (\<exists>T. open T \<and> S \<subseteq> T \<and> f holomorphic_on T)"
   550   (is "?lhs = ?rhs")
   551 proof -
   552   have "?lhs \<longleftrightarrow> (\<exists>T. open T \<and> S \<subseteq> T \<and> f analytic_on T)"
   553   proof safe
   554     assume "f analytic_on S"
   555     then show "\<exists>T. open T \<and> S \<subseteq> T \<and> f analytic_on T"
   556       apply (simp add: analytic_on_def)
   557       apply (rule exI [where x="\<Union>{U. open U \<and> f analytic_on U}"], auto)
   558       apply (metis open_ball analytic_on_open centre_in_ball)
   559       by (metis analytic_on_def)
   560   next
   561     fix T
   562     assume "open T" "S \<subseteq> T" "f analytic_on T"
   563     then show "f analytic_on S"
   564         by (metis analytic_on_subset)
   565   qed
   566   also have "... \<longleftrightarrow> ?rhs"
   567     by (auto simp: analytic_on_open)
   568   finally show ?thesis .
   569 qed
   570 
   571 lemma analytic_on_linear [analytic_intros,simp]: "((*) c) analytic_on S"
   572   by (auto simp add: analytic_on_holomorphic)
   573 
   574 lemma analytic_on_const [analytic_intros,simp]: "(\<lambda>z. c) analytic_on S"
   575   by (metis analytic_on_def holomorphic_on_const zero_less_one)
   576 
   577 lemma analytic_on_ident [analytic_intros,simp]: "(\<lambda>x. x) analytic_on S"
   578   by (simp add: analytic_on_def gt_ex)
   579 
   580 lemma analytic_on_id [analytic_intros]: "id analytic_on S"
   581   unfolding id_def by (rule analytic_on_ident)
   582 
   583 lemma analytic_on_compose:
   584   assumes f: "f analytic_on S"
   585       and g: "g analytic_on (f ` S)"
   586     shows "(g o f) analytic_on S"
   587 unfolding analytic_on_def
   588 proof (intro ballI)
   589   fix x
   590   assume x: "x \<in> S"
   591   then obtain e where e: "0 < e" and fh: "f holomorphic_on ball x e" using f
   592     by (metis analytic_on_def)
   593   obtain e' where e': "0 < e'" and gh: "g holomorphic_on ball (f x) e'" using g
   594     by (metis analytic_on_def g image_eqI x)
   595   have "isCont f x"
   596     by (metis analytic_on_imp_differentiable_at field_differentiable_imp_continuous_at f x)
   597   with e' obtain d where d: "0 < d" and fd: "f ` ball x d \<subseteq> ball (f x) e'"
   598      by (auto simp: continuous_at_ball)
   599   have "g \<circ> f holomorphic_on ball x (min d e)"
   600     apply (rule holomorphic_on_compose)
   601     apply (metis fh holomorphic_on_subset min.bounded_iff order_refl subset_ball)
   602     by (metis fd gh holomorphic_on_subset image_mono min.cobounded1 subset_ball)
   603   then show "\<exists>e>0. g \<circ> f holomorphic_on ball x e"
   604     by (metis d e min_less_iff_conj)
   605 qed
   606 
   607 lemma analytic_on_compose_gen:
   608   "f analytic_on S \<Longrightarrow> g analytic_on T \<Longrightarrow> (\<And>z. z \<in> S \<Longrightarrow> f z \<in> T)
   609              \<Longrightarrow> g o f analytic_on S"
   610 by (metis analytic_on_compose analytic_on_subset image_subset_iff)
   611 
   612 lemma analytic_on_neg [analytic_intros]:
   613   "f analytic_on S \<Longrightarrow> (\<lambda>z. -(f z)) analytic_on S"
   614 by (metis analytic_on_holomorphic holomorphic_on_minus)
   615 
   616 lemma analytic_on_add [analytic_intros]:
   617   assumes f: "f analytic_on S"
   618       and g: "g analytic_on S"
   619     shows "(\<lambda>z. f z + g z) analytic_on S"
   620 unfolding analytic_on_def
   621 proof (intro ballI)
   622   fix z
   623   assume z: "z \<in> S"
   624   then obtain e where e: "0 < e" and fh: "f holomorphic_on ball z e" using f
   625     by (metis analytic_on_def)
   626   obtain e' where e': "0 < e'" and gh: "g holomorphic_on ball z e'" using g
   627     by (metis analytic_on_def g z)
   628   have "(\<lambda>z. f z + g z) holomorphic_on ball z (min e e')"
   629     apply (rule holomorphic_on_add)
   630     apply (metis fh holomorphic_on_subset min.bounded_iff order_refl subset_ball)
   631     by (metis gh holomorphic_on_subset min.bounded_iff order_refl subset_ball)
   632   then show "\<exists>e>0. (\<lambda>z. f z + g z) holomorphic_on ball z e"
   633     by (metis e e' min_less_iff_conj)
   634 qed
   635 
   636 lemma analytic_on_diff [analytic_intros]:
   637   assumes f: "f analytic_on S"
   638       and g: "g analytic_on S"
   639     shows "(\<lambda>z. f z - g z) analytic_on S"
   640 unfolding analytic_on_def
   641 proof (intro ballI)
   642   fix z
   643   assume z: "z \<in> S"
   644   then obtain e where e: "0 < e" and fh: "f holomorphic_on ball z e" using f
   645     by (metis analytic_on_def)
   646   obtain e' where e': "0 < e'" and gh: "g holomorphic_on ball z e'" using g
   647     by (metis analytic_on_def g z)
   648   have "(\<lambda>z. f z - g z) holomorphic_on ball z (min e e')"
   649     apply (rule holomorphic_on_diff)
   650     apply (metis fh holomorphic_on_subset min.bounded_iff order_refl subset_ball)
   651     by (metis gh holomorphic_on_subset min.bounded_iff order_refl subset_ball)
   652   then show "\<exists>e>0. (\<lambda>z. f z - g z) holomorphic_on ball z e"
   653     by (metis e e' min_less_iff_conj)
   654 qed
   655 
   656 lemma analytic_on_mult [analytic_intros]:
   657   assumes f: "f analytic_on S"
   658       and g: "g analytic_on S"
   659     shows "(\<lambda>z. f z * g z) analytic_on S"
   660 unfolding analytic_on_def
   661 proof (intro ballI)
   662   fix z
   663   assume z: "z \<in> S"
   664   then obtain e where e: "0 < e" and fh: "f holomorphic_on ball z e" using f
   665     by (metis analytic_on_def)
   666   obtain e' where e': "0 < e'" and gh: "g holomorphic_on ball z e'" using g
   667     by (metis analytic_on_def g z)
   668   have "(\<lambda>z. f z * g z) holomorphic_on ball z (min e e')"
   669     apply (rule holomorphic_on_mult)
   670     apply (metis fh holomorphic_on_subset min.bounded_iff order_refl subset_ball)
   671     by (metis gh holomorphic_on_subset min.bounded_iff order_refl subset_ball)
   672   then show "\<exists>e>0. (\<lambda>z. f z * g z) holomorphic_on ball z e"
   673     by (metis e e' min_less_iff_conj)
   674 qed
   675 
   676 lemma analytic_on_inverse [analytic_intros]:
   677   assumes f: "f analytic_on S"
   678       and nz: "(\<And>z. z \<in> S \<Longrightarrow> f z \<noteq> 0)"
   679     shows "(\<lambda>z. inverse (f z)) analytic_on S"
   680 unfolding analytic_on_def
   681 proof (intro ballI)
   682   fix z
   683   assume z: "z \<in> S"
   684   then obtain e where e: "0 < e" and fh: "f holomorphic_on ball z e" using f
   685     by (metis analytic_on_def)
   686   have "continuous_on (ball z e) f"
   687     by (metis fh holomorphic_on_imp_continuous_on)
   688   then obtain e' where e': "0 < e'" and nz': "\<And>y. dist z y < e' \<Longrightarrow> f y \<noteq> 0"
   689     by (metis open_ball centre_in_ball continuous_on_open_avoid e z nz)
   690   have "(\<lambda>z. inverse (f z)) holomorphic_on ball z (min e e')"
   691     apply (rule holomorphic_on_inverse)
   692     apply (metis fh holomorphic_on_subset min.cobounded2 min.commute subset_ball)
   693     by (metis nz' mem_ball min_less_iff_conj)
   694   then show "\<exists>e>0. (\<lambda>z. inverse (f z)) holomorphic_on ball z e"
   695     by (metis e e' min_less_iff_conj)
   696 qed
   697 
   698 lemma analytic_on_divide [analytic_intros]:
   699   assumes f: "f analytic_on S"
   700       and g: "g analytic_on S"
   701       and nz: "(\<And>z. z \<in> S \<Longrightarrow> g z \<noteq> 0)"
   702     shows "(\<lambda>z. f z / g z) analytic_on S"
   703 unfolding divide_inverse
   704 by (metis analytic_on_inverse analytic_on_mult f g nz)
   705 
   706 lemma analytic_on_power [analytic_intros]:
   707   "f analytic_on S \<Longrightarrow> (\<lambda>z. (f z) ^ n) analytic_on S"
   708 by (induct n) (auto simp: analytic_on_mult)
   709 
   710 lemma analytic_on_sum [analytic_intros]:
   711   "(\<And>i. i \<in> I \<Longrightarrow> (f i) analytic_on S) \<Longrightarrow> (\<lambda>x. sum (\<lambda>i. f i x) I) analytic_on S"
   712   by (induct I rule: infinite_finite_induct) (auto simp: analytic_on_const analytic_on_add)
   713 
   714 lemma deriv_left_inverse:
   715   assumes "f holomorphic_on S" and "g holomorphic_on T"
   716       and "open S" and "open T"
   717       and "f ` S \<subseteq> T"
   718       and [simp]: "\<And>z. z \<in> S \<Longrightarrow> g (f z) = z"
   719       and "w \<in> S"
   720     shows "deriv f w * deriv g (f w) = 1"
   721 proof -
   722   have "deriv f w * deriv g (f w) = deriv g (f w) * deriv f w"
   723     by (simp add: algebra_simps)
   724   also have "... = deriv (g o f) w"
   725     using assms
   726     by (metis analytic_on_imp_differentiable_at analytic_on_open complex_derivative_chain image_subset_iff)
   727   also have "... = deriv id w"
   728   proof (rule complex_derivative_transform_within_open [where s=S])
   729     show "g \<circ> f holomorphic_on S"
   730       by (rule assms holomorphic_on_compose_gen holomorphic_intros)+
   731   qed (use assms in auto)
   732   also have "... = 1"
   733     by simp
   734   finally show ?thesis .
   735 qed
   736 
   737 subsection%unimportant\<open>Analyticity at a point\<close>
   738 
   739 lemma analytic_at_ball:
   740   "f analytic_on {z} \<longleftrightarrow> (\<exists>e. 0<e \<and> f holomorphic_on ball z e)"
   741 by (metis analytic_on_def singleton_iff)
   742 
   743 lemma analytic_at:
   744     "f analytic_on {z} \<longleftrightarrow> (\<exists>s. open s \<and> z \<in> s \<and> f holomorphic_on s)"
   745 by (metis analytic_on_holomorphic empty_subsetI insert_subset)
   746 
   747 lemma analytic_on_analytic_at:
   748     "f analytic_on s \<longleftrightarrow> (\<forall>z \<in> s. f analytic_on {z})"
   749 by (metis analytic_at_ball analytic_on_def)
   750 
   751 lemma analytic_at_two:
   752   "f analytic_on {z} \<and> g analytic_on {z} \<longleftrightarrow>
   753    (\<exists>s. open s \<and> z \<in> s \<and> f holomorphic_on s \<and> g holomorphic_on s)"
   754   (is "?lhs = ?rhs")
   755 proof
   756   assume ?lhs
   757   then obtain s t
   758     where st: "open s" "z \<in> s" "f holomorphic_on s"
   759               "open t" "z \<in> t" "g holomorphic_on t"
   760     by (auto simp: analytic_at)
   761   show ?rhs
   762     apply (rule_tac x="s \<inter> t" in exI)
   763     using st
   764     apply (auto simp: holomorphic_on_subset)
   765     done
   766 next
   767   assume ?rhs
   768   then show ?lhs
   769     by (force simp add: analytic_at)
   770 qed
   771 
   772 subsection%unimportant\<open>Combining theorems for derivative with ``analytic at'' hypotheses\<close>
   773 
   774 lemma
   775   assumes "f analytic_on {z}" "g analytic_on {z}"
   776   shows complex_derivative_add_at: "deriv (\<lambda>w. f w + g w) z = deriv f z + deriv g z"
   777     and complex_derivative_diff_at: "deriv (\<lambda>w. f w - g w) z = deriv f z - deriv g z"
   778     and complex_derivative_mult_at: "deriv (\<lambda>w. f w * g w) z =
   779            f z * deriv g z + deriv f z * g z"
   780 proof -
   781   obtain s where s: "open s" "z \<in> s" "f holomorphic_on s" "g holomorphic_on s"
   782     using assms by (metis analytic_at_two)
   783   show "deriv (\<lambda>w. f w + g w) z = deriv f z + deriv g z"
   784     apply (rule DERIV_imp_deriv [OF DERIV_add])
   785     using s
   786     apply (auto simp: holomorphic_on_open field_differentiable_def DERIV_deriv_iff_field_differentiable)
   787     done
   788   show "deriv (\<lambda>w. f w - g w) z = deriv f z - deriv g z"
   789     apply (rule DERIV_imp_deriv [OF DERIV_diff])
   790     using s
   791     apply (auto simp: holomorphic_on_open field_differentiable_def DERIV_deriv_iff_field_differentiable)
   792     done
   793   show "deriv (\<lambda>w. f w * g w) z = f z * deriv g z + deriv f z * g z"
   794     apply (rule DERIV_imp_deriv [OF DERIV_mult'])
   795     using s
   796     apply (auto simp: holomorphic_on_open field_differentiable_def DERIV_deriv_iff_field_differentiable)
   797     done
   798 qed
   799 
   800 lemma deriv_cmult_at:
   801   "f analytic_on {z} \<Longrightarrow>  deriv (\<lambda>w. c * f w) z = c * deriv f z"
   802 by (auto simp: complex_derivative_mult_at deriv_const analytic_on_const)
   803 
   804 lemma deriv_cmult_right_at:
   805   "f analytic_on {z} \<Longrightarrow>  deriv (\<lambda>w. f w * c) z = deriv f z * c"
   806 by (auto simp: complex_derivative_mult_at deriv_const analytic_on_const)
   807 
   808 subsection%unimportant\<open>Complex differentiation of sequences and series\<close>
   809 
   810 (* TODO: Could probably be simplified using Uniform_Limit *)
   811 lemma has_complex_derivative_sequence:
   812   fixes S :: "complex set"
   813   assumes cvs: "convex S"
   814       and df:  "\<And>n x. x \<in> S \<Longrightarrow> (f n has_field_derivative f' n x) (at x within S)"
   815       and conv: "\<And>e. 0 < e \<Longrightarrow> \<exists>N. \<forall>n x. n \<ge> N \<longrightarrow> x \<in> S \<longrightarrow> norm (f' n x - g' x) \<le> e"
   816       and "\<exists>x l. x \<in> S \<and> ((\<lambda>n. f n x) \<longlongrightarrow> l) sequentially"
   817     shows "\<exists>g. \<forall>x \<in> S. ((\<lambda>n. f n x) \<longlongrightarrow> g x) sequentially \<and>
   818                        (g has_field_derivative (g' x)) (at x within S)"
   819 proof -
   820   from assms obtain x l where x: "x \<in> S" and tf: "((\<lambda>n. f n x) \<longlongrightarrow> l) sequentially"
   821     by blast
   822   { fix e::real assume e: "e > 0"
   823     then obtain N where N: "\<forall>n\<ge>N. \<forall>x. x \<in> S \<longrightarrow> cmod (f' n x - g' x) \<le> e"
   824       by (metis conv)
   825     have "\<exists>N. \<forall>n\<ge>N. \<forall>x\<in>S. \<forall>h. cmod (f' n x * h - g' x * h) \<le> e * cmod h"
   826     proof (rule exI [of _ N], clarify)
   827       fix n y h
   828       assume "N \<le> n" "y \<in> S"
   829       then have "cmod (f' n y - g' y) \<le> e"
   830         by (metis N)
   831       then have "cmod h * cmod (f' n y - g' y) \<le> cmod h * e"
   832         by (auto simp: antisym_conv2 mult_le_cancel_left norm_triangle_ineq2)
   833       then show "cmod (f' n y * h - g' y * h) \<le> e * cmod h"
   834         by (simp add: norm_mult [symmetric] field_simps)
   835     qed
   836   } note ** = this
   837   show ?thesis
   838     unfolding has_field_derivative_def
   839   proof (rule has_derivative_sequence [OF cvs _ _ x])
   840     show "(\<lambda>n. f n x) \<longlonglongrightarrow> l"
   841       by (rule tf)
   842   next show "\<And>e. e > 0 \<Longrightarrow> \<forall>\<^sub>F n in sequentially. \<forall>x\<in>S. \<forall>h. cmod (f' n x * h - g' x * h) \<le> e * cmod h"
   843       unfolding eventually_sequentially by (blast intro: **)
   844   qed (metis has_field_derivative_def df)
   845 qed
   846 
   847 lemma has_complex_derivative_series:
   848   fixes S :: "complex set"
   849   assumes cvs: "convex S"
   850       and df:  "\<And>n x. x \<in> S \<Longrightarrow> (f n has_field_derivative f' n x) (at x within S)"
   851       and conv: "\<And>e. 0 < e \<Longrightarrow> \<exists>N. \<forall>n x. n \<ge> N \<longrightarrow> x \<in> S
   852                 \<longrightarrow> cmod ((\<Sum>i<n. f' i x) - g' x) \<le> e"
   853       and "\<exists>x l. x \<in> S \<and> ((\<lambda>n. f n x) sums l)"
   854     shows "\<exists>g. \<forall>x \<in> S. ((\<lambda>n. f n x) sums g x) \<and> ((g has_field_derivative g' x) (at x within S))"
   855 proof -
   856   from assms obtain x l where x: "x \<in> S" and sf: "((\<lambda>n. f n x) sums l)"
   857     by blast
   858   { fix e::real assume e: "e > 0"
   859     then obtain N where N: "\<forall>n x. n \<ge> N \<longrightarrow> x \<in> S
   860             \<longrightarrow> cmod ((\<Sum>i<n. f' i x) - g' x) \<le> e"
   861       by (metis conv)
   862     have "\<exists>N. \<forall>n\<ge>N. \<forall>x\<in>S. \<forall>h. cmod ((\<Sum>i<n. h * f' i x) - g' x * h) \<le> e * cmod h"
   863     proof (rule exI [of _ N], clarify)
   864       fix n y h
   865       assume "N \<le> n" "y \<in> S"
   866       then have "cmod ((\<Sum>i<n. f' i y) - g' y) \<le> e"
   867         by (metis N)
   868       then have "cmod h * cmod ((\<Sum>i<n. f' i y) - g' y) \<le> cmod h * e"
   869         by (auto simp: antisym_conv2 mult_le_cancel_left norm_triangle_ineq2)
   870       then show "cmod ((\<Sum>i<n. h * f' i y) - g' y * h) \<le> e * cmod h"
   871         by (simp add: norm_mult [symmetric] field_simps sum_distrib_left)
   872     qed
   873   } note ** = this
   874   show ?thesis
   875   unfolding has_field_derivative_def
   876   proof (rule has_derivative_series [OF cvs _ _ x])
   877     fix n x
   878     assume "x \<in> S"
   879     then show "((f n) has_derivative (\<lambda>z. z * f' n x)) (at x within S)"
   880       by (metis df has_field_derivative_def mult_commute_abs)
   881   next show " ((\<lambda>n. f n x) sums l)"
   882     by (rule sf)
   883   next show "\<And>e. e>0 \<Longrightarrow> \<forall>\<^sub>F n in sequentially. \<forall>x\<in>S. \<forall>h. cmod ((\<Sum>i<n. h * f' i x) - g' x * h) \<le> e * cmod h"
   884       unfolding eventually_sequentially by (blast intro: **)
   885   qed
   886 qed
   887 
   888 
   889 lemma field_differentiable_series:
   890   fixes f :: "nat \<Rightarrow> 'a::{real_normed_field,banach} \<Rightarrow> 'a"
   891   assumes "convex S" "open S"
   892   assumes "\<And>n x. x \<in> S \<Longrightarrow> (f n has_field_derivative f' n x) (at x)"
   893   assumes "uniformly_convergent_on S (\<lambda>n x. \<Sum>i<n. f' i x)"
   894   assumes "x0 \<in> S" "summable (\<lambda>n. f n x0)" and x: "x \<in> S"
   895   shows  "(\<lambda>x. \<Sum>n. f n x) field_differentiable (at x)"
   896 proof -
   897   from assms(4) obtain g' where A: "uniform_limit S (\<lambda>n x. \<Sum>i<n. f' i x) g' sequentially"
   898     unfolding uniformly_convergent_on_def by blast
   899   from x and \<open>open S\<close> have S: "at x within S = at x" by (rule at_within_open)
   900   have "\<exists>g. \<forall>x\<in>S. (\<lambda>n. f n x) sums g x \<and> (g has_field_derivative g' x) (at x within S)"
   901     by (intro has_field_derivative_series[of S f f' g' x0] assms A has_field_derivative_at_within)
   902   then obtain g where g: "\<And>x. x \<in> S \<Longrightarrow> (\<lambda>n. f n x) sums g x"
   903     "\<And>x. x \<in> S \<Longrightarrow> (g has_field_derivative g' x) (at x within S)" by blast
   904   from g(2)[OF x] have g': "(g has_derivative (*) (g' x)) (at x)"
   905     by (simp add: has_field_derivative_def S)
   906   have "((\<lambda>x. \<Sum>n. f n x) has_derivative (*) (g' x)) (at x)"
   907     by (rule has_derivative_transform_within_open[OF g' \<open>open S\<close> x])
   908        (insert g, auto simp: sums_iff)
   909   thus "(\<lambda>x. \<Sum>n. f n x) field_differentiable (at x)" unfolding differentiable_def
   910     by (auto simp: summable_def field_differentiable_def has_field_derivative_def)
   911 qed
   912 
   913 subsection%unimportant\<open>Bound theorem\<close>
   914 
   915 lemma field_differentiable_bound:
   916   fixes S :: "'a::real_normed_field set"
   917   assumes cvs: "convex S"
   918       and df:  "\<And>z. z \<in> S \<Longrightarrow> (f has_field_derivative f' z) (at z within S)"
   919       and dn:  "\<And>z. z \<in> S \<Longrightarrow> norm (f' z) \<le> B"
   920       and "x \<in> S"  "y \<in> S"
   921     shows "norm(f x - f y) \<le> B * norm(x - y)"
   922   apply (rule differentiable_bound [OF cvs])
   923   apply (erule df [unfolded has_field_derivative_def])
   924   apply (rule onorm_le, simp_all add: norm_mult mult_right_mono assms)
   925   done
   926 
   927 subsection%unimportant\<open>Inverse function theorem for complex derivatives\<close>
   928 
   929 lemma has_field_derivative_inverse_basic:
   930   shows "DERIV f (g y) :> f' \<Longrightarrow>
   931         f' \<noteq> 0 \<Longrightarrow>
   932         continuous (at y) g \<Longrightarrow>
   933         open t \<Longrightarrow>
   934         y \<in> t \<Longrightarrow>
   935         (\<And>z. z \<in> t \<Longrightarrow> f (g z) = z)
   936         \<Longrightarrow> DERIV g y :> inverse (f')"
   937   unfolding has_field_derivative_def
   938   apply (rule has_derivative_inverse_basic)
   939   apply (auto simp:  bounded_linear_mult_right)
   940   done
   941 
   942 lemma has_field_derivative_inverse_strong:
   943   fixes f :: "'a::{euclidean_space,real_normed_field} \<Rightarrow> 'a"
   944   shows "DERIV f x :> f' \<Longrightarrow>
   945          f' \<noteq> 0 \<Longrightarrow>
   946          open S \<Longrightarrow>
   947          x \<in> S \<Longrightarrow>
   948          continuous_on S f \<Longrightarrow>
   949          (\<And>z. z \<in> S \<Longrightarrow> g (f z) = z)
   950          \<Longrightarrow> DERIV g (f x) :> inverse (f')"
   951   unfolding has_field_derivative_def
   952   apply (rule has_derivative_inverse_strong [of S x f g ])
   953   by auto
   954 
   955 lemma has_field_derivative_inverse_strong_x:
   956   fixes f :: "'a::{euclidean_space,real_normed_field} \<Rightarrow> 'a"
   957   shows  "DERIV f (g y) :> f' \<Longrightarrow>
   958           f' \<noteq> 0 \<Longrightarrow>
   959           open S \<Longrightarrow>
   960           continuous_on S f \<Longrightarrow>
   961           g y \<in> S \<Longrightarrow> f(g y) = y \<Longrightarrow>
   962           (\<And>z. z \<in> S \<Longrightarrow> g (f z) = z)
   963           \<Longrightarrow> DERIV g y :> inverse (f')"
   964   unfolding has_field_derivative_def
   965   apply (rule has_derivative_inverse_strong_x [of S g y f])
   966   by auto
   967 
   968 subsection%unimportant \<open>Taylor on Complex Numbers\<close>
   969 
   970 lemma sum_Suc_reindex:
   971   fixes f :: "nat \<Rightarrow> 'a::ab_group_add"
   972     shows  "sum f {0..n} = f 0 - f (Suc n) + sum (\<lambda>i. f (Suc i)) {0..n}"
   973 by (induct n) auto
   974 
   975 lemma field_taylor:
   976   assumes S: "convex S"
   977       and f: "\<And>i x. x \<in> S \<Longrightarrow> i \<le> n \<Longrightarrow> (f i has_field_derivative f (Suc i) x) (at x within S)"
   978       and B: "\<And>x. x \<in> S \<Longrightarrow> norm (f (Suc n) x) \<le> B"
   979       and w: "w \<in> S"
   980       and z: "z \<in> S"
   981     shows "norm(f 0 z - (\<Sum>i\<le>n. f i w * (z-w) ^ i / (fact i)))
   982           \<le> B * norm(z - w)^(Suc n) / fact n"
   983 proof -
   984   have wzs: "closed_segment w z \<subseteq> S" using assms
   985     by (metis convex_contains_segment)
   986   { fix u
   987     assume "u \<in> closed_segment w z"
   988     then have "u \<in> S"
   989       by (metis wzs subsetD)
   990     have "(\<Sum>i\<le>n. f i u * (- of_nat i * (z-u)^(i - 1)) / (fact i) +
   991                       f (Suc i) u * (z-u)^i / (fact i)) =
   992               f (Suc n) u * (z-u) ^ n / (fact n)"
   993     proof (induction n)
   994       case 0 show ?case by simp
   995     next
   996       case (Suc n)
   997       have "(\<Sum>i\<le>Suc n. f i u * (- of_nat i * (z-u) ^ (i - 1)) / (fact i) +
   998                              f (Suc i) u * (z-u) ^ i / (fact i)) =
   999            f (Suc n) u * (z-u) ^ n / (fact n) +
  1000            f (Suc (Suc n)) u * ((z-u) * (z-u) ^ n) / (fact (Suc n)) -
  1001            f (Suc n) u * ((1 + of_nat n) * (z-u) ^ n) / (fact (Suc n))"
  1002         using Suc by simp
  1003       also have "... = f (Suc (Suc n)) u * (z-u) ^ Suc n / (fact (Suc n))"
  1004       proof -
  1005         have "(fact(Suc n)) *
  1006              (f(Suc n) u *(z-u) ^ n / (fact n) +
  1007                f(Suc(Suc n)) u *((z-u) *(z-u) ^ n) / (fact(Suc n)) -
  1008                f(Suc n) u *((1 + of_nat n) *(z-u) ^ n) / (fact(Suc n))) =
  1009             ((fact(Suc n)) *(f(Suc n) u *(z-u) ^ n)) / (fact n) +
  1010             ((fact(Suc n)) *(f(Suc(Suc n)) u *((z-u) *(z-u) ^ n)) / (fact(Suc n))) -
  1011             ((fact(Suc n)) *(f(Suc n) u *(of_nat(Suc n) *(z-u) ^ n))) / (fact(Suc n))"
  1012           by (simp add: algebra_simps del: fact_Suc)
  1013         also have "... = ((fact (Suc n)) * (f (Suc n) u * (z-u) ^ n)) / (fact n) +
  1014                          (f (Suc (Suc n)) u * ((z-u) * (z-u) ^ n)) -
  1015                          (f (Suc n) u * ((1 + of_nat n) * (z-u) ^ n))"
  1016           by (simp del: fact_Suc)
  1017         also have "... = (of_nat (Suc n) * (f (Suc n) u * (z-u) ^ n)) +
  1018                          (f (Suc (Suc n)) u * ((z-u) * (z-u) ^ n)) -
  1019                          (f (Suc n) u * ((1 + of_nat n) * (z-u) ^ n))"
  1020           by (simp only: fact_Suc of_nat_mult ac_simps) simp
  1021         also have "... = f (Suc (Suc n)) u * ((z-u) * (z-u) ^ n)"
  1022           by (simp add: algebra_simps)
  1023         finally show ?thesis
  1024         by (simp add: mult_left_cancel [where c = "(fact (Suc n))", THEN iffD1] del: fact_Suc)
  1025       qed
  1026       finally show ?case .
  1027     qed
  1028     then have "((\<lambda>v. (\<Sum>i\<le>n. f i v * (z - v)^i / (fact i)))
  1029                 has_field_derivative f (Suc n) u * (z-u) ^ n / (fact n))
  1030                (at u within S)"
  1031       apply (intro derivative_eq_intros)
  1032       apply (blast intro: assms \<open>u \<in> S\<close>)
  1033       apply (rule refl)+
  1034       apply (auto simp: field_simps)
  1035       done
  1036   } note sum_deriv = this
  1037   { fix u
  1038     assume u: "u \<in> closed_segment w z"
  1039     then have us: "u \<in> S"
  1040       by (metis wzs subsetD)
  1041     have "norm (f (Suc n) u) * norm (z - u) ^ n \<le> norm (f (Suc n) u) * norm (u - z) ^ n"
  1042       by (metis norm_minus_commute order_refl)
  1043     also have "... \<le> norm (f (Suc n) u) * norm (z - w) ^ n"
  1044       by (metis mult_left_mono norm_ge_zero power_mono segment_bound [OF u])
  1045     also have "... \<le> B * norm (z - w) ^ n"
  1046       by (metis norm_ge_zero zero_le_power mult_right_mono  B [OF us])
  1047     finally have "norm (f (Suc n) u) * norm (z - u) ^ n \<le> B * norm (z - w) ^ n" .
  1048   } note cmod_bound = this
  1049   have "(\<Sum>i\<le>n. f i z * (z - z) ^ i / (fact i)) = (\<Sum>i\<le>n. (f i z / (fact i)) * 0 ^ i)"
  1050     by simp
  1051   also have "\<dots> = f 0 z / (fact 0)"
  1052     by (subst sum_zero_power) simp
  1053   finally have "norm (f 0 z - (\<Sum>i\<le>n. f i w * (z - w) ^ i / (fact i)))
  1054                 \<le> norm ((\<Sum>i\<le>n. f i w * (z - w) ^ i / (fact i)) -
  1055                         (\<Sum>i\<le>n. f i z * (z - z) ^ i / (fact i)))"
  1056     by (simp add: norm_minus_commute)
  1057   also have "... \<le> B * norm (z - w) ^ n / (fact n) * norm (w - z)"
  1058     apply (rule field_differentiable_bound
  1059       [where f' = "\<lambda>w. f (Suc n) w * (z - w)^n / (fact n)"
  1060          and S = "closed_segment w z", OF convex_closed_segment])
  1061     apply (auto simp: ends_in_segment DERIV_subset [OF sum_deriv wzs]
  1062                   norm_divide norm_mult norm_power divide_le_cancel cmod_bound)
  1063     done
  1064   also have "...  \<le> B * norm (z - w) ^ Suc n / (fact n)"
  1065     by (simp add: algebra_simps norm_minus_commute)
  1066   finally show ?thesis .
  1067 qed
  1068 
  1069 lemma complex_taylor:
  1070   assumes S: "convex S"
  1071       and f: "\<And>i x. x \<in> S \<Longrightarrow> i \<le> n \<Longrightarrow> (f i has_field_derivative f (Suc i) x) (at x within S)"
  1072       and B: "\<And>x. x \<in> S \<Longrightarrow> cmod (f (Suc n) x) \<le> B"
  1073       and w: "w \<in> S"
  1074       and z: "z \<in> S"
  1075     shows "cmod(f 0 z - (\<Sum>i\<le>n. f i w * (z-w) ^ i / (fact i)))
  1076           \<le> B * cmod(z - w)^(Suc n) / fact n"
  1077   using assms by (rule field_taylor)
  1078 
  1079 
  1080 text\<open>Something more like the traditional MVT for real components\<close>
  1081 
  1082 lemma complex_mvt_line:
  1083   assumes "\<And>u. u \<in> closed_segment w z \<Longrightarrow> (f has_field_derivative f'(u)) (at u)"
  1084     shows "\<exists>u. u \<in> closed_segment w z \<and> Re(f z) - Re(f w) = Re(f'(u) * (z - w))"
  1085 proof -
  1086   have twz: "\<And>t. (1 - t) *\<^sub>R w + t *\<^sub>R z = w + t *\<^sub>R (z - w)"
  1087     by (simp add: real_vector.scale_left_diff_distrib real_vector.scale_right_diff_distrib)
  1088   note assms[unfolded has_field_derivative_def, derivative_intros]
  1089   show ?thesis
  1090     apply (cut_tac mvt_simple
  1091                      [of 0 1 "Re o f o (\<lambda>t. (1 - t) *\<^sub>R w +  t *\<^sub>R z)"
  1092                       "\<lambda>u. Re o (\<lambda>h. f'((1 - u) *\<^sub>R w + u *\<^sub>R z) * h) o (\<lambda>t. t *\<^sub>R (z - w))"])
  1093     apply auto
  1094     apply (rule_tac x="(1 - x) *\<^sub>R w + x *\<^sub>R z" in exI)
  1095     apply (auto simp: closed_segment_def twz) []
  1096     apply (intro derivative_eq_intros has_derivative_at_withinI, simp_all)
  1097     apply (simp add: fun_eq_iff real_vector.scale_right_diff_distrib)
  1098     apply (force simp: twz closed_segment_def)
  1099     done
  1100 qed
  1101 
  1102 lemma complex_taylor_mvt:
  1103   assumes "\<And>i x. \<lbrakk>x \<in> closed_segment w z; i \<le> n\<rbrakk> \<Longrightarrow> ((f i) has_field_derivative f (Suc i) x) (at x)"
  1104     shows "\<exists>u. u \<in> closed_segment w z \<and>
  1105             Re (f 0 z) =
  1106             Re ((\<Sum>i = 0..n. f i w * (z - w) ^ i / (fact i)) +
  1107                 (f (Suc n) u * (z-u)^n / (fact n)) * (z - w))"
  1108 proof -
  1109   { fix u
  1110     assume u: "u \<in> closed_segment w z"
  1111     have "(\<Sum>i = 0..n.
  1112                (f (Suc i) u * (z-u) ^ i - of_nat i * (f i u * (z-u) ^ (i - Suc 0))) /
  1113                (fact i)) =
  1114           f (Suc 0) u -
  1115              (f (Suc (Suc n)) u * ((z-u) ^ Suc n) - (of_nat (Suc n)) * (z-u) ^ n * f (Suc n) u) /
  1116              (fact (Suc n)) +
  1117              (\<Sum>i = 0..n.
  1118                  (f (Suc (Suc i)) u * ((z-u) ^ Suc i) - of_nat (Suc i) * (f (Suc i) u * (z-u) ^ i)) /
  1119                  (fact (Suc i)))"
  1120        by (subst sum_Suc_reindex) simp
  1121     also have "... = f (Suc 0) u -
  1122              (f (Suc (Suc n)) u * ((z-u) ^ Suc n) - (of_nat (Suc n)) * (z-u) ^ n * f (Suc n) u) /
  1123              (fact (Suc n)) +
  1124              (\<Sum>i = 0..n.
  1125                  f (Suc (Suc i)) u * ((z-u) ^ Suc i) / (fact (Suc i))  -
  1126                  f (Suc i) u * (z-u) ^ i / (fact i))"
  1127       by (simp only: diff_divide_distrib fact_cancel ac_simps)
  1128     also have "... = f (Suc 0) u -
  1129              (f (Suc (Suc n)) u * (z-u) ^ Suc n - of_nat (Suc n) * (z-u) ^ n * f (Suc n) u) /
  1130              (fact (Suc n)) +
  1131              f (Suc (Suc n)) u * (z-u) ^ Suc n / (fact (Suc n)) - f (Suc 0) u"
  1132       by (subst sum_Suc_diff) auto
  1133     also have "... = f (Suc n) u * (z-u) ^ n / (fact n)"
  1134       by (simp only: algebra_simps diff_divide_distrib fact_cancel)
  1135     finally have "(\<Sum>i = 0..n. (f (Suc i) u * (z - u) ^ i
  1136                              - of_nat i * (f i u * (z-u) ^ (i - Suc 0))) / (fact i)) =
  1137                   f (Suc n) u * (z - u) ^ n / (fact n)" .
  1138     then have "((\<lambda>u. \<Sum>i = 0..n. f i u * (z - u) ^ i / (fact i)) has_field_derivative
  1139                 f (Suc n) u * (z - u) ^ n / (fact n))  (at u)"
  1140       apply (intro derivative_eq_intros)+
  1141       apply (force intro: u assms)
  1142       apply (rule refl)+
  1143       apply (auto simp: ac_simps)
  1144       done
  1145   }
  1146   then show ?thesis
  1147     apply (cut_tac complex_mvt_line [of w z "\<lambda>u. \<Sum>i = 0..n. f i u * (z-u) ^ i / (fact i)"
  1148                "\<lambda>u. (f (Suc n) u * (z-u)^n / (fact n))"])
  1149     apply (auto simp add: intro: open_closed_segment)
  1150     done
  1151 qed
  1152 
  1153 
  1154 subsection%unimportant \<open>Polynomal function extremal theorem, from HOL Light\<close>
  1155 
  1156 lemma polyfun_extremal_lemma: (*COMPLEX_POLYFUN_EXTREMAL_LEMMA in HOL Light*)
  1157     fixes c :: "nat \<Rightarrow> 'a::real_normed_div_algebra"
  1158   assumes "0 < e"
  1159     shows "\<exists>M. \<forall>z. M \<le> norm(z) \<longrightarrow> norm (\<Sum>i\<le>n. c(i) * z^i) \<le> e * norm(z) ^ (Suc n)"
  1160 proof (induct n)
  1161   case 0 with assms
  1162   show ?case
  1163     apply (rule_tac x="norm (c 0) / e" in exI)
  1164     apply (auto simp: field_simps)
  1165     done
  1166 next
  1167   case (Suc n)
  1168   obtain M where M: "\<And>z. M \<le> norm z \<Longrightarrow> norm (\<Sum>i\<le>n. c i * z^i) \<le> e * norm z ^ Suc n"
  1169     using Suc assms by blast
  1170   show ?case
  1171   proof (rule exI [where x= "max M (1 + norm(c(Suc n)) / e)"], clarsimp simp del: power_Suc)
  1172     fix z::'a
  1173     assume z1: "M \<le> norm z" and "1 + norm (c (Suc n)) / e \<le> norm z"
  1174     then have z2: "e + norm (c (Suc n)) \<le> e * norm z"
  1175       using assms by (simp add: field_simps)
  1176     have "norm (\<Sum>i\<le>n. c i * z^i) \<le> e * norm z ^ Suc n"
  1177       using M [OF z1] by simp
  1178     then have "norm (\<Sum>i\<le>n. c i * z^i) + norm (c (Suc n) * z ^ Suc n) \<le> e * norm z ^ Suc n + norm (c (Suc n) * z ^ Suc n)"
  1179       by simp
  1180     then have "norm ((\<Sum>i\<le>n. c i * z^i) + c (Suc n) * z ^ Suc n) \<le> e * norm z ^ Suc n + norm (c (Suc n) * z ^ Suc n)"
  1181       by (blast intro: norm_triangle_le elim: )
  1182     also have "... \<le> (e + norm (c (Suc n))) * norm z ^ Suc n"
  1183       by (simp add: norm_power norm_mult algebra_simps)
  1184     also have "... \<le> (e * norm z) * norm z ^ Suc n"
  1185       by (metis z2 mult.commute mult_left_mono norm_ge_zero norm_power)
  1186     finally show "norm ((\<Sum>i\<le>n. c i * z^i) + c (Suc n) * z ^ Suc n) \<le> e * norm z ^ Suc (Suc n)"
  1187       by simp
  1188   qed
  1189 qed
  1190 
  1191 lemma polyfun_extremal: (*COMPLEX_POLYFUN_EXTREMAL in HOL Light*)
  1192     fixes c :: "nat \<Rightarrow> 'a::real_normed_div_algebra"
  1193   assumes k: "c k \<noteq> 0" "1\<le>k" and kn: "k\<le>n"
  1194     shows "eventually (\<lambda>z. norm (\<Sum>i\<le>n. c(i) * z^i) \<ge> B) at_infinity"
  1195 using kn
  1196 proof (induction n)
  1197   case 0
  1198   then show ?case
  1199     using k  by simp
  1200 next
  1201   case (Suc m)
  1202   let ?even = ?case
  1203   show ?even
  1204   proof (cases "c (Suc m) = 0")
  1205     case True
  1206     then show ?even using Suc k
  1207       by auto (metis antisym_conv less_eq_Suc_le not_le)
  1208   next
  1209     case False
  1210     then obtain M where M:
  1211           "\<And>z. M \<le> norm z \<Longrightarrow> norm (\<Sum>i\<le>m. c i * z^i) \<le> norm (c (Suc m)) / 2 * norm z ^ Suc m"
  1212       using polyfun_extremal_lemma [of "norm(c (Suc m)) / 2" c m] Suc
  1213       by auto
  1214     have "\<exists>b. \<forall>z. b \<le> norm z \<longrightarrow> B \<le> norm (\<Sum>i\<le>Suc m. c i * z^i)"
  1215     proof (rule exI [where x="max M (max 1 (\<bar>B\<bar> / (norm(c (Suc m)) / 2)))"], clarsimp simp del: power_Suc)
  1216       fix z::'a
  1217       assume z1: "M \<le> norm z" "1 \<le> norm z"
  1218          and "\<bar>B\<bar> * 2 / norm (c (Suc m)) \<le> norm z"
  1219       then have z2: "\<bar>B\<bar> \<le> norm (c (Suc m)) * norm z / 2"
  1220         using False by (simp add: field_simps)
  1221       have nz: "norm z \<le> norm z ^ Suc m"
  1222         by (metis \<open>1 \<le> norm z\<close> One_nat_def less_eq_Suc_le power_increasing power_one_right zero_less_Suc)
  1223       have *: "\<And>y x. norm (c (Suc m)) * norm z / 2 \<le> norm y - norm x \<Longrightarrow> B \<le> norm (x + y)"
  1224         by (metis abs_le_iff add.commute norm_diff_ineq order_trans z2)
  1225       have "norm z * norm (c (Suc m)) + 2 * norm (\<Sum>i\<le>m. c i * z^i)
  1226             \<le> norm (c (Suc m)) * norm z + norm (c (Suc m)) * norm z ^ Suc m"
  1227         using M [of z] Suc z1  by auto
  1228       also have "... \<le> 2 * (norm (c (Suc m)) * norm z ^ Suc m)"
  1229         using nz by (simp add: mult_mono del: power_Suc)
  1230       finally show "B \<le> norm ((\<Sum>i\<le>m. c i * z^i) + c (Suc m) * z ^ Suc m)"
  1231         using Suc.IH
  1232         apply (auto simp: eventually_at_infinity)
  1233         apply (rule *)
  1234         apply (simp add: field_simps norm_mult norm_power)
  1235         done
  1236     qed
  1237     then show ?even
  1238       by (simp add: eventually_at_infinity)
  1239   qed
  1240 qed
  1241 
  1242 end