src/HOL/Univ.ML
author paulson
Wed Nov 05 13:23:46 1997 +0100 (1997-11-05)
changeset 4153 e534c4c32d54
parent 4089 96fba19bcbe2
child 4356 0dfd34f0d33d
permissions -rw-r--r--
Ran expandshort, especially to introduce Safe_tac
     1 (*  Title:      HOL/Univ
     2     ID:         $Id$
     3     Author:     Lawrence C Paulson, Cambridge University Computer Laboratory
     4     Copyright   1991  University of Cambridge
     5 
     6 For univ.thy
     7 *)
     8 
     9 open Univ;
    10 
    11 (** apfst -- can be used in similar type definitions **)
    12 
    13 goalw Univ.thy [apfst_def] "apfst f (a,b) = (f(a),b)";
    14 by (rtac split 1);
    15 qed "apfst_conv";
    16 
    17 val [major,minor] = goal Univ.thy
    18     "[| q = apfst f p;  !!x y. [| p = (x,y);  q = (f(x),y) |] ==> R \
    19 \    |] ==> R";
    20 by (rtac PairE 1);
    21 by (rtac minor 1);
    22 by (assume_tac 1);
    23 by (rtac (major RS trans) 1);
    24 by (etac ssubst 1);
    25 by (rtac apfst_conv 1);
    26 qed "apfst_convE";
    27 
    28 (** Push -- an injection, analogous to Cons on lists **)
    29 
    30 val [major] = goalw Univ.thy [Push_def] "Push i f = Push j g  ==> i=j";
    31 by (rtac (major RS fun_cong RS box_equals RS Suc_inject) 1);
    32 by (rtac nat_case_0 1);
    33 by (rtac nat_case_0 1);
    34 qed "Push_inject1";
    35 
    36 val [major] = goalw Univ.thy [Push_def] "Push i f = Push j g  ==> f=g";
    37 by (rtac (major RS fun_cong RS ext RS box_equals) 1);
    38 by (rtac (nat_case_Suc RS ext) 1);
    39 by (rtac (nat_case_Suc RS ext) 1);
    40 qed "Push_inject2";
    41 
    42 val [major,minor] = goal Univ.thy
    43     "[| Push i f =Push j g;  [| i=j;  f=g |] ==> P \
    44 \    |] ==> P";
    45 by (rtac ((major RS Push_inject2) RS ((major RS Push_inject1) RS minor)) 1);
    46 qed "Push_inject";
    47 
    48 val [major] = goalw Univ.thy [Push_def] "Push k f =(%z.0) ==> P";
    49 by (rtac (major RS fun_cong RS box_equals RS Suc_neq_Zero) 1);
    50 by (rtac nat_case_0 1);
    51 by (rtac refl 1);
    52 qed "Push_neq_K0";
    53 
    54 (*** Isomorphisms ***)
    55 
    56 goal Univ.thy "inj(Rep_Node)";
    57 by (rtac inj_inverseI 1);       (*cannot combine by RS: multiple unifiers*)
    58 by (rtac Rep_Node_inverse 1);
    59 qed "inj_Rep_Node";
    60 
    61 goal Univ.thy "inj_onto Abs_Node Node";
    62 by (rtac inj_onto_inverseI 1);
    63 by (etac Abs_Node_inverse 1);
    64 qed "inj_onto_Abs_Node";
    65 
    66 val Abs_Node_inject = inj_onto_Abs_Node RS inj_ontoD;
    67 
    68 
    69 (*** Introduction rules for Node ***)
    70 
    71 goalw Univ.thy [Node_def] "(%k. 0,a) : Node";
    72 by (Blast_tac 1);
    73 qed "Node_K0_I";
    74 
    75 goalw Univ.thy [Node_def,Push_def]
    76     "!!p. p: Node ==> apfst (Push i) p : Node";
    77 by (blast_tac (claset() addSIs [apfst_conv, nat_case_Suc RS trans]) 1);
    78 qed "Node_Push_I";
    79 
    80 
    81 (*** Distinctness of constructors ***)
    82 
    83 (** Scons vs Atom **)
    84 
    85 goalw Univ.thy [Atom_def,Scons_def,Push_Node_def] "(M$N) ~= Atom(a)";
    86 by (rtac notI 1);
    87 by (etac (equalityD2 RS subsetD RS UnE) 1);
    88 by (rtac singletonI 1);
    89 by (REPEAT (eresolve_tac [imageE, Abs_Node_inject RS apfst_convE, 
    90                           Pair_inject, sym RS Push_neq_K0] 1
    91      ORELSE resolve_tac [Node_K0_I, Rep_Node RS Node_Push_I] 1));
    92 qed "Scons_not_Atom";
    93 bind_thm ("Atom_not_Scons", Scons_not_Atom RS not_sym);
    94 
    95 
    96 (*** Injectiveness ***)
    97 
    98 (** Atomic nodes **)
    99 
   100 goalw Univ.thy [Atom_def, inj_def] "inj(Atom)";
   101 by (blast_tac (claset() addSIs [Node_K0_I] addSDs [Abs_Node_inject]) 1);
   102 qed "inj_Atom";
   103 val Atom_inject = inj_Atom RS injD;
   104 
   105 goal Univ.thy "(Atom(a)=Atom(b)) = (a=b)";
   106 by (blast_tac (claset() addSDs [Atom_inject]) 1);
   107 qed "Atom_Atom_eq";
   108 AddIffs [Atom_Atom_eq];
   109 
   110 goalw Univ.thy [Leaf_def,o_def] "inj(Leaf)";
   111 by (rtac injI 1);
   112 by (etac (Atom_inject RS Inl_inject) 1);
   113 qed "inj_Leaf";
   114 
   115 val Leaf_inject = inj_Leaf RS injD;
   116 AddSDs [Leaf_inject];
   117 
   118 goalw Univ.thy [Numb_def,o_def] "inj(Numb)";
   119 by (rtac injI 1);
   120 by (etac (Atom_inject RS Inr_inject) 1);
   121 qed "inj_Numb";
   122 
   123 val Numb_inject = inj_Numb RS injD;
   124 AddSDs [Numb_inject];
   125 
   126 (** Injectiveness of Push_Node **)
   127 
   128 val [major,minor] = goalw Univ.thy [Push_Node_def]
   129     "[| Push_Node i m =Push_Node j n;  [| i=j;  m=n |] ==> P \
   130 \    |] ==> P";
   131 by (rtac (major RS Abs_Node_inject RS apfst_convE) 1);
   132 by (REPEAT (resolve_tac [Rep_Node RS Node_Push_I] 1));
   133 by (etac (sym RS apfst_convE) 1);
   134 by (rtac minor 1);
   135 by (etac Pair_inject 1);
   136 by (etac (Push_inject1 RS sym) 1);
   137 by (rtac (inj_Rep_Node RS injD) 1);
   138 by (etac trans 1);
   139 by (safe_tac (claset() addSEs [Push_inject,sym]));
   140 qed "Push_Node_inject";
   141 
   142 
   143 (** Injectiveness of Scons **)
   144 
   145 goalw Univ.thy [Scons_def] "!!M. M$N <= M'$N' ==> M<=M'";
   146 by (blast_tac (claset() addSDs [Push_Node_inject]) 1);
   147 qed "Scons_inject_lemma1";
   148 
   149 goalw Univ.thy [Scons_def] "!!M. M$N <= M'$N' ==> N<=N'";
   150 by (blast_tac (claset() addSDs [Push_Node_inject]) 1);
   151 qed "Scons_inject_lemma2";
   152 
   153 val [major] = goal Univ.thy "M$N = M'$N' ==> M=M'";
   154 by (rtac (major RS equalityE) 1);
   155 by (REPEAT (ares_tac [equalityI, Scons_inject_lemma1] 1));
   156 qed "Scons_inject1";
   157 
   158 val [major] = goal Univ.thy "M$N = M'$N' ==> N=N'";
   159 by (rtac (major RS equalityE) 1);
   160 by (REPEAT (ares_tac [equalityI, Scons_inject_lemma2] 1));
   161 qed "Scons_inject2";
   162 
   163 val [major,minor] = goal Univ.thy
   164     "[| M$N = M'$N';  [| M=M';  N=N' |] ==> P \
   165 \    |] ==> P";
   166 by (rtac ((major RS Scons_inject2) RS ((major RS Scons_inject1) RS minor)) 1);
   167 qed "Scons_inject";
   168 
   169 goal Univ.thy "(M$N = M'$N') = (M=M' & N=N')";
   170 by (blast_tac (claset() addSEs [Scons_inject]) 1);
   171 qed "Scons_Scons_eq";
   172 
   173 (*** Distinctness involving Leaf and Numb ***)
   174 
   175 (** Scons vs Leaf **)
   176 
   177 goalw Univ.thy [Leaf_def,o_def] "(M$N) ~= Leaf(a)";
   178 by (rtac Scons_not_Atom 1);
   179 qed "Scons_not_Leaf";
   180 bind_thm ("Leaf_not_Scons", Scons_not_Leaf RS not_sym);
   181 
   182 AddIffs [Scons_not_Leaf, Leaf_not_Scons];
   183 
   184 
   185 (** Scons vs Numb **)
   186 
   187 goalw Univ.thy [Numb_def,o_def] "(M$N) ~= Numb(k)";
   188 by (rtac Scons_not_Atom 1);
   189 qed "Scons_not_Numb";
   190 bind_thm ("Numb_not_Scons", Scons_not_Numb RS not_sym);
   191 
   192 AddIffs [Scons_not_Numb, Numb_not_Scons];
   193 
   194 
   195 (** Leaf vs Numb **)
   196 
   197 goalw Univ.thy [Leaf_def,Numb_def] "Leaf(a) ~= Numb(k)";
   198 by (simp_tac (simpset() addsimps [Inl_not_Inr]) 1);
   199 qed "Leaf_not_Numb";
   200 bind_thm ("Numb_not_Leaf", Leaf_not_Numb RS not_sym);
   201 
   202 AddIffs [Leaf_not_Numb, Numb_not_Leaf];
   203 
   204 
   205 (*** ndepth -- the depth of a node ***)
   206 
   207 Addsimps [apfst_conv];
   208 AddIffs  [Scons_not_Atom, Atom_not_Scons, Scons_Scons_eq];
   209 
   210 
   211 goalw Univ.thy [ndepth_def] "ndepth (Abs_Node((%k.0, x))) = 0";
   212 by (EVERY1[stac (Node_K0_I RS Abs_Node_inverse), stac split]);
   213 by (rtac Least_equality 1);
   214 by (rtac refl 1);
   215 by (etac less_zeroE 1);
   216 qed "ndepth_K0";
   217 
   218 goal Univ.thy "k < Suc(LEAST x. f(x)=0) --> nat_case (Suc i) f k ~= 0";
   219 by (nat_ind_tac "k" 1);
   220 by (ALLGOALS Simp_tac);
   221 by (rtac impI 1);
   222 by (etac not_less_Least 1);
   223 qed "ndepth_Push_lemma";
   224 
   225 goalw Univ.thy [ndepth_def,Push_Node_def]
   226     "ndepth (Push_Node i n) = Suc(ndepth(n))";
   227 by (stac (Rep_Node RS Node_Push_I RS Abs_Node_inverse) 1);
   228 by (cut_facts_tac [rewrite_rule [Node_def] Rep_Node] 1);
   229 by Safe_tac;
   230 by (etac ssubst 1);  (*instantiates type variables!*)
   231 by (Simp_tac 1);
   232 by (rtac Least_equality 1);
   233 by (rewtac Push_def);
   234 by (rtac (nat_case_Suc RS trans) 1);
   235 by (etac LeastI 1);
   236 by (etac (ndepth_Push_lemma RS mp) 1);
   237 qed "ndepth_Push_Node";
   238 
   239 
   240 (*** ntrunc applied to the various node sets ***)
   241 
   242 goalw Univ.thy [ntrunc_def] "ntrunc 0 M = {}";
   243 by (Blast_tac 1);
   244 qed "ntrunc_0";
   245 
   246 goalw Univ.thy [Atom_def,ntrunc_def] "ntrunc (Suc k) (Atom a) = Atom(a)";
   247 by (fast_tac (claset() addss (simpset() addsimps [ndepth_K0])) 1);
   248 qed "ntrunc_Atom";
   249 
   250 goalw Univ.thy [Leaf_def,o_def] "ntrunc (Suc k) (Leaf a) = Leaf(a)";
   251 by (rtac ntrunc_Atom 1);
   252 qed "ntrunc_Leaf";
   253 
   254 goalw Univ.thy [Numb_def,o_def] "ntrunc (Suc k) (Numb i) = Numb(i)";
   255 by (rtac ntrunc_Atom 1);
   256 qed "ntrunc_Numb";
   257 
   258 goalw Univ.thy [Scons_def,ntrunc_def]
   259     "ntrunc (Suc k) (M$N) = ntrunc k M $ ntrunc k N";
   260 by (safe_tac (claset() addSIs [imageI]));
   261 by (REPEAT (stac ndepth_Push_Node 3 THEN etac Suc_mono 3));
   262 by (REPEAT (rtac Suc_less_SucD 1 THEN 
   263             rtac (ndepth_Push_Node RS subst) 1 THEN 
   264             assume_tac 1));
   265 qed "ntrunc_Scons";
   266 
   267 (** Injection nodes **)
   268 
   269 goalw Univ.thy [In0_def] "ntrunc (Suc 0) (In0 M) = {}";
   270 by (simp_tac (simpset() addsimps [ntrunc_Scons,ntrunc_0]) 1);
   271 by (rewtac Scons_def);
   272 by (Blast_tac 1);
   273 qed "ntrunc_one_In0";
   274 
   275 goalw Univ.thy [In0_def]
   276     "ntrunc (Suc (Suc k)) (In0 M) = In0 (ntrunc (Suc k) M)";
   277 by (simp_tac (simpset() addsimps [ntrunc_Scons,ntrunc_Numb]) 1);
   278 qed "ntrunc_In0";
   279 
   280 goalw Univ.thy [In1_def] "ntrunc (Suc 0) (In1 M) = {}";
   281 by (simp_tac (simpset() addsimps [ntrunc_Scons,ntrunc_0]) 1);
   282 by (rewtac Scons_def);
   283 by (Blast_tac 1);
   284 qed "ntrunc_one_In1";
   285 
   286 goalw Univ.thy [In1_def]
   287     "ntrunc (Suc (Suc k)) (In1 M) = In1 (ntrunc (Suc k) M)";
   288 by (simp_tac (simpset() addsimps [ntrunc_Scons,ntrunc_Numb]) 1);
   289 qed "ntrunc_In1";
   290 
   291 
   292 (*** Cartesian Product ***)
   293 
   294 goalw Univ.thy [uprod_def] "!!M N. [| M:A;  N:B |] ==> (M$N) : A<*>B";
   295 by (REPEAT (ares_tac [singletonI,UN_I] 1));
   296 qed "uprodI";
   297 
   298 (*The general elimination rule*)
   299 val major::prems = goalw Univ.thy [uprod_def]
   300     "[| c : A<*>B;  \
   301 \       !!x y. [| x:A;  y:B;  c=x$y |] ==> P \
   302 \    |] ==> P";
   303 by (cut_facts_tac [major] 1);
   304 by (REPEAT (eresolve_tac [asm_rl,singletonE,UN_E] 1
   305      ORELSE resolve_tac prems 1));
   306 qed "uprodE";
   307 
   308 (*Elimination of a pair -- introduces no eigenvariables*)
   309 val prems = goal Univ.thy
   310     "[| (M$N) : A<*>B;      [| M:A;  N:B |] ==> P   \
   311 \    |] ==> P";
   312 by (rtac uprodE 1);
   313 by (REPEAT (ares_tac prems 1 ORELSE eresolve_tac [Scons_inject,ssubst] 1));
   314 qed "uprodE2";
   315 
   316 
   317 (*** Disjoint Sum ***)
   318 
   319 goalw Univ.thy [usum_def] "!!M. M:A ==> In0(M) : A<+>B";
   320 by (Blast_tac 1);
   321 qed "usum_In0I";
   322 
   323 goalw Univ.thy [usum_def] "!!N. N:B ==> In1(N) : A<+>B";
   324 by (Blast_tac 1);
   325 qed "usum_In1I";
   326 
   327 val major::prems = goalw Univ.thy [usum_def]
   328     "[| u : A<+>B;  \
   329 \       !!x. [| x:A;  u=In0(x) |] ==> P; \
   330 \       !!y. [| y:B;  u=In1(y) |] ==> P \
   331 \    |] ==> P";
   332 by (rtac (major RS UnE) 1);
   333 by (REPEAT (rtac refl 1 
   334      ORELSE eresolve_tac (prems@[imageE,ssubst]) 1));
   335 qed "usumE";
   336 
   337 
   338 (** Injection **)
   339 
   340 goalw Univ.thy [In0_def,In1_def] "In0(M) ~= In1(N)";
   341 by (rtac notI 1);
   342 by (etac (Scons_inject1 RS Numb_inject RS Zero_neq_Suc) 1);
   343 qed "In0_not_In1";
   344 
   345 bind_thm ("In1_not_In0", In0_not_In1 RS not_sym);
   346 
   347 AddIffs [In0_not_In1, In1_not_In0];
   348 
   349 val [major] = goalw Univ.thy [In0_def] "In0(M) = In0(N) ==>  M=N";
   350 by (rtac (major RS Scons_inject2) 1);
   351 qed "In0_inject";
   352 
   353 val [major] = goalw Univ.thy [In1_def] "In1(M) = In1(N) ==>  M=N";
   354 by (rtac (major RS Scons_inject2) 1);
   355 qed "In1_inject";
   356 
   357 goal Univ.thy "(In0 M = In0 N) = (M=N)";
   358 by (blast_tac (claset() addSDs [In0_inject]) 1);
   359 qed "In0_eq";
   360 
   361 goal Univ.thy "(In1 M = In1 N) = (M=N)";
   362 by (blast_tac (claset() addSDs [In1_inject]) 1);
   363 qed "In1_eq";
   364 
   365 AddIffs [In0_eq, In1_eq];
   366 
   367 goalw Univ.thy [inj_def] "inj In0";
   368 by (Blast_tac 1);
   369 qed "inj_In0";
   370 
   371 goalw Univ.thy [inj_def] "inj In1";
   372 by (Blast_tac 1);
   373 qed "inj_In1";
   374 
   375 
   376 (*** proving equality of sets and functions using ntrunc ***)
   377 
   378 goalw Univ.thy [ntrunc_def] "ntrunc k M <= M";
   379 by (Blast_tac 1);
   380 qed "ntrunc_subsetI";
   381 
   382 val [major] = goalw Univ.thy [ntrunc_def]
   383     "(!!k. ntrunc k M <= N) ==> M<=N";
   384 by (blast_tac (claset() addIs [less_add_Suc1, less_add_Suc2, 
   385                             major RS subsetD]) 1);
   386 qed "ntrunc_subsetD";
   387 
   388 (*A generalized form of the take-lemma*)
   389 val [major] = goal Univ.thy "(!!k. ntrunc k M = ntrunc k N) ==> M=N";
   390 by (rtac equalityI 1);
   391 by (ALLGOALS (rtac ntrunc_subsetD));
   392 by (ALLGOALS (rtac (ntrunc_subsetI RSN (2, subset_trans))));
   393 by (rtac (major RS equalityD1) 1);
   394 by (rtac (major RS equalityD2) 1);
   395 qed "ntrunc_equality";
   396 
   397 val [major] = goalw Univ.thy [o_def]
   398     "[| !!k. (ntrunc(k) o h1) = (ntrunc(k) o h2) |] ==> h1=h2";
   399 by (rtac (ntrunc_equality RS ext) 1);
   400 by (rtac (major RS fun_cong) 1);
   401 qed "ntrunc_o_equality";
   402 
   403 (*** Monotonicity ***)
   404 
   405 goalw Univ.thy [uprod_def] "!!A B. [| A<=A';  B<=B' |] ==> A<*>B <= A'<*>B'";
   406 by (Blast_tac 1);
   407 qed "uprod_mono";
   408 
   409 goalw Univ.thy [usum_def] "!!A B. [| A<=A';  B<=B' |] ==> A<+>B <= A'<+>B'";
   410 by (Blast_tac 1);
   411 qed "usum_mono";
   412 
   413 goalw Univ.thy [Scons_def] "!!M N. [| M<=M';  N<=N' |] ==> M$N <= M'$N'";
   414 by (Blast_tac 1);
   415 qed "Scons_mono";
   416 
   417 goalw Univ.thy [In0_def] "!!M N. M<=N ==> In0(M) <= In0(N)";
   418 by (REPEAT (ares_tac [subset_refl,Scons_mono] 1));
   419 qed "In0_mono";
   420 
   421 goalw Univ.thy [In1_def] "!!M N. M<=N ==> In1(M) <= In1(N)";
   422 by (REPEAT (ares_tac [subset_refl,Scons_mono] 1));
   423 qed "In1_mono";
   424 
   425 
   426 (*** Split and Case ***)
   427 
   428 goalw Univ.thy [Split_def] "Split c (M$N) = c M N";
   429 by (blast_tac (claset() addIs [select_equality]) 1);
   430 qed "Split";
   431 
   432 goalw Univ.thy [Case_def] "Case c d (In0 M) = c(M)";
   433 by (blast_tac (claset() addIs [select_equality]) 1);
   434 qed "Case_In0";
   435 
   436 goalw Univ.thy [Case_def] "Case c d (In1 N) = d(N)";
   437 by (blast_tac (claset() addIs [select_equality]) 1);
   438 qed "Case_In1";
   439 
   440 (**** UN x. B(x) rules ****)
   441 
   442 goalw Univ.thy [ntrunc_def] "ntrunc k (UN x. f(x)) = (UN x. ntrunc k (f x))";
   443 by (Blast_tac 1);
   444 qed "ntrunc_UN1";
   445 
   446 goalw Univ.thy [Scons_def] "(UN x. f(x)) $ M = (UN x. f(x) $ M)";
   447 by (Blast_tac 1);
   448 qed "Scons_UN1_x";
   449 
   450 goalw Univ.thy [Scons_def] "M $ (UN x. f(x)) = (UN x. M $ f(x))";
   451 by (Blast_tac 1);
   452 qed "Scons_UN1_y";
   453 
   454 goalw Univ.thy [In0_def] "In0(UN x. f(x)) = (UN x. In0(f(x)))";
   455 by (rtac Scons_UN1_y 1);
   456 qed "In0_UN1";
   457 
   458 goalw Univ.thy [In1_def] "In1(UN x. f(x)) = (UN x. In1(f(x)))";
   459 by (rtac Scons_UN1_y 1);
   460 qed "In1_UN1";
   461 
   462 
   463 (*** Equality : the diagonal relation ***)
   464 
   465 goalw Univ.thy [diag_def] "!!a A. [| a=b;  a:A |] ==> (a,b) : diag(A)";
   466 by (Blast_tac 1);
   467 qed "diag_eqI";
   468 
   469 val diagI = refl RS diag_eqI |> standard;
   470 
   471 (*The general elimination rule*)
   472 val major::prems = goalw Univ.thy [diag_def]
   473     "[| c : diag(A);  \
   474 \       !!x y. [| x:A;  c = (x,x) |] ==> P \
   475 \    |] ==> P";
   476 by (rtac (major RS UN_E) 1);
   477 by (REPEAT (eresolve_tac [asm_rl,singletonE] 1 ORELSE resolve_tac prems 1));
   478 qed "diagE";
   479 
   480 (*** Equality for Cartesian Product ***)
   481 
   482 goalw Univ.thy [dprod_def]
   483     "!!r s. [| (M,M'):r;  (N,N'):s |] ==> (M$N, M'$N') : r<**>s";
   484 by (Blast_tac 1);
   485 qed "dprodI";
   486 
   487 (*The general elimination rule*)
   488 val major::prems = goalw Univ.thy [dprod_def]
   489     "[| c : r<**>s;  \
   490 \       !!x y x' y'. [| (x,x') : r;  (y,y') : s;  c = (x$y,x'$y') |] ==> P \
   491 \    |] ==> P";
   492 by (cut_facts_tac [major] 1);
   493 by (REPEAT_FIRST (eresolve_tac [asm_rl, UN_E, mem_splitE, singletonE]));
   494 by (REPEAT (ares_tac prems 1 ORELSE hyp_subst_tac 1));
   495 qed "dprodE";
   496 
   497 
   498 (*** Equality for Disjoint Sum ***)
   499 
   500 goalw Univ.thy [dsum_def]  "!!r. (M,M'):r ==> (In0(M), In0(M')) : r<++>s";
   501 by (Blast_tac 1);
   502 qed "dsum_In0I";
   503 
   504 goalw Univ.thy [dsum_def]  "!!r. (N,N'):s ==> (In1(N), In1(N')) : r<++>s";
   505 by (Blast_tac 1);
   506 qed "dsum_In1I";
   507 
   508 val major::prems = goalw Univ.thy [dsum_def]
   509     "[| w : r<++>s;  \
   510 \       !!x x'. [| (x,x') : r;  w = (In0(x), In0(x')) |] ==> P; \
   511 \       !!y y'. [| (y,y') : s;  w = (In1(y), In1(y')) |] ==> P \
   512 \    |] ==> P";
   513 by (cut_facts_tac [major] 1);
   514 by (REPEAT_FIRST (eresolve_tac [asm_rl, UN_E, UnE, mem_splitE, singletonE]));
   515 by (DEPTH_SOLVE (ares_tac prems 1 ORELSE hyp_subst_tac 1));
   516 qed "dsumE";
   517 
   518 
   519 AddSIs [diagI, uprodI, dprodI];
   520 AddIs  [usum_In0I, usum_In1I, dsum_In0I, dsum_In1I];
   521 AddSEs [diagE, uprodE, dprodE, usumE, dsumE];
   522 
   523 (*** Monotonicity ***)
   524 
   525 goal Univ.thy "!!r s. [| r<=r';  s<=s' |] ==> r<**>s <= r'<**>s'";
   526 by (Blast_tac 1);
   527 qed "dprod_mono";
   528 
   529 goal Univ.thy "!!r s. [| r<=r';  s<=s' |] ==> r<++>s <= r'<++>s'";
   530 by (Blast_tac 1);
   531 qed "dsum_mono";
   532 
   533 
   534 (*** Bounding theorems ***)
   535 
   536 goal Univ.thy "diag(A) <= A Times A";
   537 by (Blast_tac 1);
   538 qed "diag_subset_Sigma";
   539 
   540 goal Univ.thy "((A Times B) <**> (C Times D)) <= (A<*>C) Times (B<*>D)";
   541 by (Blast_tac 1);
   542 qed "dprod_Sigma";
   543 
   544 val dprod_subset_Sigma = [dprod_mono, dprod_Sigma] MRS subset_trans |>standard;
   545 
   546 (*Dependent version*)
   547 goal Univ.thy
   548     "(Sigma A B <**> Sigma C D) <= Sigma (A<*>C) (Split(%x y. B(x)<*>D(y)))";
   549 by Safe_tac;
   550 by (stac Split 1);
   551 by (Blast_tac 1);
   552 qed "dprod_subset_Sigma2";
   553 
   554 goal Univ.thy "(A Times B <++> C Times D) <= (A<+>C) Times (B<+>D)";
   555 by (Blast_tac 1);
   556 qed "dsum_Sigma";
   557 
   558 val dsum_subset_Sigma = [dsum_mono, dsum_Sigma] MRS subset_trans |> standard;
   559 
   560 
   561 (*** Domain ***)
   562 
   563 goal Univ.thy "fst `` diag(A) = A";
   564 by (Blast_tac 1);
   565 qed "fst_image_diag";
   566 
   567 goal Univ.thy "fst `` (r<**>s) = (fst``r) <*> (fst``s)";
   568 by (Blast_tac 1);
   569 qed "fst_image_dprod";
   570 
   571 goal Univ.thy "fst `` (r<++>s) = (fst``r) <+> (fst``s)";
   572 by (Blast_tac 1);
   573 qed "fst_image_dsum";
   574 
   575 Addsimps [fst_image_diag, fst_image_dprod, fst_image_dsum];